qt: playlist: use item title if available
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2021 VLC authors and VideoLAN])
4
5 AC_INIT([vlc], [4.0.0-dev])
6 VERSION_MAJOR=4
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=dev
11
12 PKGDIR="vlc"
13 AC_SUBST([PKGDIR])
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Otto Chriek"
17 COPYRIGHT_YEARS="1996-2021"
18
19 AC_CONFIG_SRCDIR([src/libvlc.c])
20 AC_CONFIG_AUX_DIR([autotools])
21 AC_CONFIG_MACRO_DIR([m4])
22 AC_CONFIG_LIBOBJ_DIR([compat])
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE([tar-ustar color-tests foreign])
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Check for tools
35 dnl
36 AC_PROG_CC
37 AC_USE_SYSTEM_EXTENSIONS
38 VLC_PROG_CC_C11
39 AH_VERBATIM([FORTIFY_SOURCE],
40   [/* Enable compile-time and run-time bounds-checking, and some warnings,
41    without upsetting glibc 2.15+ or toolchains predefining _FORTIFY_SOURCE */
42 #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
43 # define _FORTIFY_SOURCE 2
44 #endif])
45 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
46 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
47 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
48
49 AC_PROG_CXX
50 AC_PROG_CPP
51 AC_PROG_OBJC
52 AC_PROG_EGREP
53 AC_PROG_MAKE_SET
54 AC_PROG_INSTALL
55 AM_PROG_AS
56 AC_PROG_LEX
57 AC_PROG_YACC
58
59 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
60 AC_CHECK_PROGS([DESKTOP_FILE_VALIDATE], [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
61 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
62 AC_CHECK_PROGS([BUILDCC], [c11-gcc c11 c99-gcc c99], [false])
63 AS_IF([test "$BUILDCC" = "false"], [
64   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
65 ])
66
67 dnl Check for compiler properties
68 AC_C_CONST
69 AC_C_INLINE
70 AC_C_RESTRICT
71 AX_CXX_COMPILE_STDCXX_14([noext], [mandatory])
72
73 dnl Check the compiler supports atomics in C
74 AC_MSG_CHECKING([C atomics])
75 VLC_SAVE_FLAGS
76 ATOMIC_LIB=""
77 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdatomic.h>],[
78  atomic_uintmax_t test;
79  atomic_init(&test, 0);
80  atomic_fetch_add_explicit(&test, 2u, memory_order_relaxed);
81 ])], [AC_MSG_RESULT([built-in])], [
82   LDFLAGS="$LDFLAGS -latomic"
83   AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdatomic.h>],[
84 atomic_uintmax_t test;
85 atomic_init(&test, 0);
86 atomic_fetch_add_explicit(&test, 2u, memory_order_relaxed);
87 ])],[
88     AC_MSG_RESULT([using -latomic])
89     ATOMIC_LIB="-latomic"
90   ],[
91   AC_MSG_ERROR([VLC requires atomics support])
92   ])
93 ])
94 VLC_RESTORE_FLAGS
95 AC_SUBST([ATOMIC_LIB])
96
97 dnl Extend the --help string at the current spot.
98 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
99
100 dnl Allow binary package maintainer to pass a custom string to avoid
101 dnl cache problem
102 AC_ARG_WITH([binary-version],
103     AS_HELP_STRING([--with-binary-version=STRING],
104          [To avoid plugins cache problem between binary version]),[],[])
105 AS_IF([test -n "${with_binary_version}"],[
106     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
107          [Binary specific version])
108 ])
109
110 dnl Prevent clang from accepting unknown flags with a mere warning
111 AX_CHECK_COMPILE_FLAG([-Werror=invalid-command-line-argument], [
112   AX_APPEND_FLAG([-Werror=invalid-command-line-argument], [CFLAGS])
113   AX_APPEND_FLAG([-Werror=invalid-command-line-argument], [CXXFLAGS])
114   AX_APPEND_FLAG([-Werror=invalid-command-line-argument], [OBJCFLAGS])
115 ])
116 AX_CHECK_COMPILE_FLAG([-Werror=unknown-warning-option], [
117   AX_APPEND_FLAG([-Werror=unknown-warning-option], [CFLAGS])
118   AX_APPEND_FLAG([-Werror=unknown-warning-option], [CXXFLAGS])
119   AX_APPEND_FLAG([-Werror=unknown-warning-option], [OBJCFLAGS])
120 ])
121
122 dnl Some Qt version are generating tons of warning that cannot be
123 dnl avoided so mute them...
124 AX_CHECK_COMPILE_FLAG([-Wno-deprecated-copy], [
125   VLC_ADD_CXXFLAGS([qt],[-Wno-deprecated-copy])
126 ])
127
128
129 dnl
130 dnl  Check the operating system
131 dnl
132 HAVE_WIN64="0"
133 HAVE_IOS="0"
134 HAVE_OSX="0"
135 HAVE_TVOS="0"
136
137 dnl  Set x86 asm flags and defines
138 X86ASMFLAGS=""
139 case "${host_cpu}" in
140     i?86)
141     X86ASMFLAGS="-f elf32"
142     X86ASMDEFS="-DARCH_X86_32=1 -DARCH_X86_64=0"
143         ;;
144     x86_64)
145     X86ASMFLAGS="-f elf64"
146     X86ASMDEFS="-DARCH_X86_32=0 -DARCH_X86_64=1"
147         ;;
148 esac
149
150 case "${host_os}" in
151   "")
152     SYS=unknown
153     ;;
154   linux*)
155     SYS=linux
156     CFLAGS="${CFLAGS} -pthread"
157     ;;
158   bsdi*)
159     SYS=bsdi
160     CFLAGS="${CFLAGS} -pthread"
161     ;;
162   freebsd*)
163     SYS=freebsd
164     CFLAGS="${CFLAGS} -pthread"
165     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
166     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
167     ac_cv_ld_z_defs=no
168     ;;
169   openbsd*)
170     SYS=openbsd
171     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
172     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
173     ;;
174   netbsd*)
175     SYS=netbsd
176     ;;
177   dragonfly*)
178     SYS=dragonfly
179     ;;
180   darwin*)
181     SYS=darwin
182
183     dnl Work around an Xcode 11 bug, fixed in Xcode 11.3.1
184     AX_APPEND_FLAG([-fno-stack-check], [CFLAGS])
185     AX_APPEND_FLAG([-fno-stack-check], [CXXFLAGS])
186     AX_APPEND_FLAG([-fno-stack-check], [OBJCFLAGS])
187
188     case "${host_cpu}" in
189       i?86)
190         X86ASMFLAGS="-f macho32"
191         AX_APPEND_FLAG([-DPREFIX], [X86ASMDEFS])
192       ;;
193       x86_64)
194         X86ASMFLAGS="-f macho64"
195         AX_APPEND_FLAG([-DPREFIX], [X86ASMDEFS])
196       ;;
197       arm*)
198         ac_cv_c_bigendian="no"
199         ac_cv_c_attribute_packed="no"
200       ;;
201     esac
202
203     AX_APPEND_FLAG([-D_INTL_REDIRECT_MACROS], [CPPFLAGS])
204     AX_APPEND_FLAG([-stdlib=libc++], [CXXFLAGS])
205     AX_APPEND_FLAG([-Werror=partial-availability], [OBJCFLAGS])
206     AX_APPEND_FLAG([-Wl,-headerpad_max_install_names], [LDFLAGS])
207
208     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
209     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation])
210
211     AC_EGREP_CPP(yes,
212             [#import <TargetConditionals.h>
213              #if TARGET_OS_IPHONE
214              yes
215              #endif],
216              [HAVE_IOS="1"
217              ac_cv_func_wordexp=no],
218              [HAVE_OSX="1"])
219
220     AC_EGREP_CPP(yes,
221             [#import <TargetConditionals.h>
222              #if TARGET_OS_TV
223              yes
224              #endif],
225              [HAVE_TVOS="1"
226              HAVE_IOS="0"
227              HAVE_OSX="0"
228              ac_cv_func_fork=no
229              ],)
230
231     AS_IF([test "${HAVE_OSX}" = "1"],[VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreServices])])
232
233     dnl
234     dnl  Handle Mac OS X SDK flags
235     dnl
236     AC_ARG_WITH(macosx-sdk,
237       AS_HELP_STRING([--with-macosx-sdk=DIR],
238         [compile using the SDK in DIR]))
239     if test "${with_macosx_sdk}" != "" ; then
240         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
241         CPP="${CPP} -isysroot ${with_macosx_sdk}"
242         CC="${CC} -isysroot ${with_macosx_sdk}"
243         CXX="${CXX} -isysroot ${with_macosx_sdk}"
244         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
245         LD="${LD} -syslibroot ${with_macosx_sdk}"
246     fi
247     AC_ARG_WITH(macosx-version-min,
248       AS_HELP_STRING([--with-macosx-version-min=VERSION],
249         [compile for Mac OS X VERSION and above]))
250     if test "${with_macosx_version_min}" != "" ; then
251         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
252         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
253         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
254         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
255         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
256     fi
257     ;;
258   *mingw32* | *cygwin* | *wince* | *mingwce*)
259     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
260     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
261     CXXFLAGS="${CXXFLAGS} -static-libgcc"
262     AC_CHECK_TOOL(WINDRES, windres, :)
263     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
264     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
265       [[#ifdef _WIN32_WINNT
266        # error _WIN32_WINNT already defined
267        #else
268        # include <windows.h>
269        # if defined(_WIN32_WINNT) && _WIN32_WINNT >= 0x0601
270        #  error _WIN32_WINNT toolchain default high enough
271        # endif
272        #endif
273       ]],[[;]])
274     ],[
275       AC_DEFINE([_WIN32_WINNT], [0x0601], [Define to '0x0601' for Windows 7 APIs.])
276     ])
277     AC_MSG_CHECKING([if libsynchronization is needed])
278     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
279       [[#if _WIN32_WINNT >= 0x0602
280        # error building for Win8+ and above
281        #endif
282       ]],[[;]])
283     ],[
284       AC_MSG_RESULT([no])
285     ],[
286       AC_MSG_RESULT([yes])
287       VLC_ADD_LIBS([libvlccore], [-lsynchronization])
288     ])
289     AC_DEFINE([_WIN32_IE], [0x0600], [Define to '0x0600' for IE 6.0 (and shell) APIs.])
290     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
291     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
292     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
293     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
294     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
295     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
296     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
297     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
298     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
299
300     case "${host_os}" in
301       *mingw32*)
302         SYS=mingw32
303         ;;
304       *cygwin*)
305         dnl Check if we are using the mno-cygwin mode in which case we are
306         dnl actually dealing with a mingw32 compiler.
307         AC_EGREP_CPP(yes,
308             [#ifdef _WIN32
309              yes
310              #endif],
311             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
312         ;;
313     esac
314
315     if test "${SYS}" = "mingw32"; then
316         # DEP, ASLR, NO SEH
317         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
318
319         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
320         ac_default_prefix="`pwd`/_win32"
321         DESTDIR="`pwd`/_win32/"
322
323         dnl
324         dnl NSIS/MSI Installer prefix and WIN64
325         dnl
326         case "${host_cpu}" in
327             aarch64)
328                 HAVE_WIN64="1"
329                 WINDOWS_ARCH="arm64"
330                 PROGRAMFILES="PROGRAMFILES64"
331                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
332             ;;
333             amd64|x86_64)
334                 HAVE_WIN64="1"
335                 WINDOWS_ARCH="x64"
336                 PROGRAMFILES="PROGRAMFILES64"
337                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
338                 X86ASMFLAGS="-f win64"
339             ;;
340             armv7)
341                 WINDOWS_ARCH="arm"
342                 PROGRAMFILES="PROGRAMFILES"
343             ;;
344             *)
345                 WINDOWS_ARCH="x86"
346                 PROGRAMFILES="PROGRAMFILES"
347                 X86ASMFLAGS="-f win32"
348                 X86ASMDEFS="${X86ASMDEFS} -DPREFIX"
349             ;;
350         esac
351         AC_SUBST([WINDOWS_ARCH])
352         AC_SUBST([PROGRAMFILES])
353
354     fi
355     ;;
356   *nto*)
357     SYS=nto
358     ;;
359   solaris*)
360     SYS=solaris
361     ;;
362   hpux*)
363     SYS=hpux
364     ;;
365   *os2*)
366     SYS=os2
367     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
368     AC_LIBOBJ([freeaddrinfo])
369     AC_LIBOBJ([gai_strerror])
370     AC_CHECK_FUNCS([if_nametoindex])
371     X86ASMFLAGS="-f aout"
372     X86ASMDEFS="-DARCH_X86_32=1 -DARCH_X86_64=0 -DPREFIX"
373     ;;
374   *nacl*)
375     SYS=nacl
376     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
377     AC_LIBOBJ([sigwait])
378     AC_LIBOBJ([recvmsg])
379     AC_LIBOBJ([sendmsg])
380     ;;
381   *)
382     SYS="${host_os}"
383     ;;
384 esac
385
386 dnl WinRT
387 AC_ARG_ENABLE([winstore_app],
388      AS_HELP_STRING([--enable-winstore-app],
389                     [Build targetted for Windows Store apps (default disabled)]))
390
391 vlc_winstore_app=0
392 AS_IF([test "${SYS}" = "mingw32"],[
393   LIBCOM="-lole32"
394   AS_IF([test "${enable_winstore_app}" = "yes"], [
395     vlc_winstore_app=1
396     LIBCOM=""
397     AX_APPEND_FLAG([-DWINSTORECOMPAT],[CFLAGS])
398     AX_APPEND_FLAG([-DWINSTORECOMPAT],[CPPFLAGS])
399     AX_APPEND_FLAG([-DWINSTORECOMPAT],[CXXFLAGS])
400     LDFLAGS="${LDFLAGS} -lwindowsappcompat"
401     VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
402     AC_LIBOBJ([gai_strerror])
403   ],[])
404   AC_SUBST([LIBCOM])
405   ])
406 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
407
408 vlc_build_pdb=0
409 AC_ARG_ENABLE([pdb],
410      AS_HELP_STRING([--enable-pdb],
411                     [Build PDB files for windows targets (default off)]))
412 AS_IF([test "${SYS}" = "mingw32"],[
413   AS_IF([test "${enable_pdb}" = "yes"], [
414     vlc_build_pdb=1
415     AX_APPEND_FLAG([-g -gcodeview],[CFLAGS])
416     AX_APPEND_FLAG([-g -gcodeview],[CXXFLAGS])
417     LDFLAGS="${LDFLAGS} -Wl,-pdb="
418   ],[])
419 ])
420
421 AM_CONDITIONAL([HAVE_FREEBSD], [test "${SYS}" = "freebsd"])
422 AM_CONDITIONAL([HAVE_LINUX],   [test "${SYS}" = "linux"])
423 AM_CONDITIONAL([HAVE_OS2],     [test "${SYS}" = "os2"])
424
425 AM_CONDITIONAL([HAVE_DARWIN],  [test "${SYS}" = "darwin"])
426 AM_CONDITIONAL([HAVE_IOS],     [test "${HAVE_IOS}" = "1"])
427 AM_CONDITIONAL([HAVE_OSX],     [test "${HAVE_OSX}" = "1"])
428 AM_CONDITIONAL([HAVE_TVOS],    [test "${HAVE_TVOS}" = "1"])
429
430 AM_CONDITIONAL([HAVE_NACL],    [test "${SYS}" = "nacl"])
431 AM_CONDITIONAL([HAVE_LIBANL],  [test "${HAVE_LIBANL}" = "1"])
432
433 AM_CONDITIONAL([HAVE_WIN32],   [test "${SYS}" = "mingw32"])
434 AM_CONDITIONAL([HAVE_WIN64],   [test "${HAVE_WIN64}" = "1"]) dnl Only used for the packaging
435 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
436 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
437 AM_CONDITIONAL([ENABLE_PDB],   [test "$vlc_build_pdb" = "1"])
438
439 dnl Use nasm/yasm only on x86
440 AC_CHECK_PROGS(X86ASM, [nasm yasm])
441 AM_CONDITIONAL([HAVE_X86ASM], [test -n "${X86ASM}" && test -n "${X86ASMFLAGS}"])
442 AM_COND_IF([HAVE_X86ASM], [
443   AC_DEFINE([HAVE_X86ASM], [1], [Use external asm on x86.])
444 ])
445
446 dnl  Because DOLT is not able to handle --with-pic
447 dnl  correctly, manually add -DPIC to the options for
448 dnl  nasm / yasm here.
449 AS_IF([test x$with_pic = xyes], [X86ASMDEFS="${X86ASMDEFS} -DPIC"])
450
451 AC_SUBST([X86ASMFLAGS])
452 AC_SUBST([X86ASMDEFS])
453
454 dnl
455 dnl Sadly autoconf does not think about testing foo.exe when ask to test
456 dnl for program foo on win32
457 case "${build_os}" in
458     cygwin|msys|mingw32)
459         ac_executable_extensions=".exe"
460         BUILDEXEEXT=".exe"
461     ;;
462     os2*)
463         BUILDEXEEXT=".exe"
464     ;;
465     *)
466     ;;
467 esac
468 AC_SUBST([BUILDEXEEXT])
469
470 dnl Android is linux, but a bit different
471 AS_IF([test "$SYS" = linux],[
472     AC_MSG_CHECKING([for an Android system])
473     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
474         [[#ifndef __ANDROID__
475          # error Not Android
476          #endif
477         ]],[[;]])
478     ],[
479       HAVE_ANDROID="1"
480       AC_MSG_RESULT([yes])
481     ],[
482       AC_MSG_RESULT([no])
483     ])
484 ])
485 AM_CONDITIONAL([HAVE_ANDROID], [test "${HAVE_ANDROID}" = "1"])
486
487 dnl
488 dnl  Check for the contrib directory
489 dnl
490 AC_ARG_WITH(contrib,
491   AS_HELP_STRING([--with-contrib[=DIR]],
492     [search for 3rd party libraries in DIR/include and DIR/lib])
493 )
494 AC_MSG_CHECKING([for 3rd party libraries path])
495 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
496   CONTRIB_DIR="${srcdir}/contrib/${host}"
497   AS_IF([test ! -d "${CONTRIB_DIR}"], [
498     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
499     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
500     AS_IF([test ! -d "${CONTRIB_DIR}"], [
501       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
502       CONTRIB_DIR=""
503       AC_MSG_RESULT([not found])
504     ])
505   ])
506 ], [
507   AS_IF([test "${with_contrib}" != "no"], [
508     CONTRIB_DIR="${with_contrib}"
509   ], [
510     CONTRIB_DIR=""
511     AC_MSG_RESULT([disabled])
512   ])
513 ])
514 AS_IF([test -n "${CONTRIB_DIR}"], [
515   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
516     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
517   ], [
518     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
519     CONTRIB_DIR=""
520     AC_MSG_RESULT([not usable])
521   ])
522
523 ])
524 AS_IF([test -n "${CONTRIB_DIR}"], [
525   AC_MSG_RESULT([${CONTRIB_DIR}])
526   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
527   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
528   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
529   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include -F${CONTRIB_DIR} -F${CONTRIB_DIR}/Frameworks"
530   PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:${CONTRIB_DIR}/share/pkgconfig:${PKG_CONFIG_PATH}"
531   case "${build_os}" in
532       mingw32)
533           export PKG_CONFIG_PATH=`cygpath -mp ${PKG_CONFIG_PATH}`
534       ;;
535       *)
536           export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
537       ;;
538   esac
539   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
540
541   AS_IF([test -z "$LUAC"], [
542     dnl Old contribs mixed cross-tools and cross-compiled executables
543     AS_IF([test -x "${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"], [
544       LUAC="${CONTRIB_DIR}/bin/luac${BUILDEXEEXT}"
545     ])
546
547     dnl Newer contribs follow usual name space rules
548     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"], [
549       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac${BUILDEXEEXT}"
550     ])
551   ])
552
553   AS_IF([test "${SYS}" = "darwin"], [
554     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
555     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
556   ])
557 ], [
558   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
559     AC_MSG_ERROR([Third party libraries not found!])
560   ])
561 ])
562 AC_SUBST([CONTRIB_DIR])
563
564 dnl Add extras/tools to the PATH
565 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
566 AS_IF([test -d "${TOOLS_DIR}"], [
567     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
568     export PATH="${TOOLS_DIR}":$PATH
569 ])
570
571 dnl
572 dnl  Libtool
573 dnl  It's very bad, but our former custom system was worst
574 dnl  -- Courmisch
575 dnl
576
577 dnl override platform specific check for dependent libraries
578 dnl otherwise libtool linking of shared libraries will
579 dnl fail on anything other than pass_all.
580 AC_CACHE_VAL(lt_cv_deplibs_check_method,
581     [lt_cv_deplibs_check_method=pass_all])
582
583 LT_INIT([dlopen win32-dll shared disable-static])
584 LT_LANG([C++])
585 LT_LANG([Windows Resource])
586
587 DOLT
588
589 lt_cv_deplibs_check_method=pass_all
590
591 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
592   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
593 ])
594
595 dnl
596 dnl Gettext stuff
597 dnl
598 AM_GNU_GETTEXT_VERSION([0.19.8])
599 AM_GNU_GETTEXT([external], [need-formatstring-macros])
600
601 dnl
602 dnl Iconv stuff
603 dnl
604 AM_ICONV
605
606 dnl
607 dnl checks for mingw
608 AS_IF([test "${SYS}" = "mingw32"], [
609
610 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
611 #if !defined(__MINGW32__)
612 # error Not compiling with mingw
613 #endif
614     ])], [
615
616 dnl Check for broken versions of mingw-runtime compatability library
617     AC_MSG_CHECKING(for broken mingw-runtime)
618     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
619 #include <_mingw.h>
620 #if defined(__MINGW64_VERSION_MAJOR)
621 # if __MINGW64_VERSION_MAJOR < 5
622 #  error Update your mingw-w64! This one is too old.
623 # endif
624 #else
625 # error You cannot compile with Mingw. Use Mingw-w64!
626 #endif
627     ])], [
628         AC_MSG_RESULT([ok])
629     ], [
630         AC_MSG_RESULT([present])
631         AC_MSG_ERROR([LibVLC requires Mingw-w64 version 5.0 or higher!])
632     ])
633
634     dnl force use of mingw provided c99 *printf over msvcrt
635     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
636
637     dnl Check for the need to include the mingwex lib for mingw32
638     VLC_SAVE_FLAGS
639     AC_CHECK_LIB([mingwex], [opendir],
640         AC_CHECK_LIB([mingw32], [opendir],,
641             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
642     )
643     VLC_RESTORE_FLAGS
644     ], [
645         AC_MSG_RESULT([Not compiling with mingw])
646     ])
647
648     dnl Check for fnative-struct or mms-bitfields support for mingw32
649     AX_CHECK_COMPILE_FLAG([-mms-bitfields], [
650         AX_APPEND_FLAG([-mms-bitfields], [CFLAGS])
651         AX_APPEND_FLAG([-mms-bitfields], [CXXFLAGS])
652         # Check for the warning flag without "-Wno-", GCC accepts
653         # -Wno-<anything> for unsupported warnings, which can trigger
654         # other warnings instead.
655         AX_CHECK_COMPILE_FLAG([-Wincompatible-ms-struct], [
656             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CFLAGS])
657             AX_APPEND_FLAG([-Wno-incompatible-ms-struct], [CXXFLAGS])
658         ])
659     ], [
660         AX_CHECK_COMPILE_FLAG([-fnative-struct], [
661             AX_APPEND_FLAG([-fnative-struct], [CFLAGS])
662             AX_APPEND_FLAG([-fnative-struct], [CXXFLAGS])
663         ])
664     ])
665 ])
666
667
668 dnl
669 dnl Buggy glibc prevention. Purposedly not cached.
670 dnl See sourceware.org bugs 5058 and 5443.
671 dnl Ubuntu alone has 20 bug numbers for this...
672 dnl
673 AC_MSG_CHECKING(for buggy GNU/libc versions)
674 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
675 #include <limits.h>
676 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
677   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
678 # error GNU/libc with dcgettext killer bug!
679 #endif
680 ])], [
681   AC_MSG_RESULT([not present])
682 ], [
683   AC_MSG_RESULT([found])
684   AS_IF([test "x${enable_nls}" != "xno"], [
685     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
686 work-around for this. Check with your distribution vendor on how to update the
687 glibc run-time. Alternatively, build with --disable-nls.])
688   ])
689 ])
690
691 dnl Plugin compilation stuff
692
693 VLC_LIBRARY_SUFFIX
694
695 dnl Check for system libs needed
696 need_libc=false
697
698 dnl Check for usual libc functions
699 AC_CHECK_FUNCS([accept4 dup3 fcntl flock fstatat fstatvfs fork getmntent_r getenv getpwuid_r isatty memalign mkostemp mmap open_memstream newlocale pipe2 pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale wordexp])
700 AC_REPLACE_FUNCS([aligned_alloc atof atoll dirfd fdopendir flockfile fsync getdelim getpid lfind lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy tfind timegm timespec_get strverscmp pathconf])
701 AC_REPLACE_FUNCS([gettimeofday])
702 AC_CHECK_FUNC(fdatasync,,
703   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
704 ])
705
706 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
707
708 dnl mingw64 implements those as static inline, not functions with C linkage
709 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
710 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
711 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
712 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
713
714 dnl C11 static_assert()
715 AC_MSG_CHECKING([for static_assert in assert.h])
716 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
717 static_assert(1, "The impossible happened.");
718 ])], [
719   AC_MSG_RESULT([yes])
720   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
721 ], [
722   AC_MSG_RESULT([no])
723 ])
724
725 # Windows CE does not have strcoll()
726 AC_FUNC_STRCOLL
727
728 dnl Check for non-standard system calls
729 case "$SYS" in
730   "linux")
731     AC_CHECK_FUNCS([eventfd vmsplice sched_getaffinity recvmmsg memfd_create])
732     ;;
733   "mingw32")
734     AC_CHECK_FUNCS([_lock_file])
735     ;;
736 esac
737
738 AH_BOTTOM([#include <vlc_fixups.h>])
739
740 dnl Check for struct timespec
741 AC_CHECK_TYPES([struct timespec],,,
742 [#include <time.h>])
743
744 dnl Check for max_align_t
745 AC_CHECK_TYPES([max_align_t],,,
746 [#include <stddef.h>])
747
748 dnl Checks for socket stuff
749 VLC_SAVE_FLAGS
750 SOCKET_LIBS=""
751 AC_SEARCH_LIBS(connect, [socket], [
752   AS_IF([test "$ac_cv_search_connect" != "none required"], [
753     SOCKET_LIBS="$ac_cv_search_connect"
754   ])
755 ], [
756   AS_IF([test "${SYS}" = "mingw32"], [
757     SOCKET_LIBS="-lws2_32 -liphlpapi"
758   ])
759 ])
760
761 AC_SEARCH_LIBS([inet_pton], [nsl], [
762  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
763     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
764   ])
765 ],, [${SOCKET_LIBS}])
766
767 LIBS="${LIBS} ${SOCKET_LIBS}"
768 AC_LINK_IFELSE([
769     AC_LANG_PROGRAM([#ifdef _WIN32
770         #include <ws2tcpip.h>
771         #include <windows.h>
772         # if _WIN32_WINNT < 0x600
773         #  error Needs vista+
774         # endif
775         #else
776         #include <sys/socket.h>
777         #include <arpa/inet.h>
778         #endif], [
779         char dst[[sizeof(struct in_addr)]];
780         inet_pton(AF_INET, "127.0.0.1", dst);
781     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
782 AC_CHECK_TYPES([struct if_nameindex],,,[#include <net/if.h>])
783 AC_CHECK_FUNCS([if_nameindex])
784 VLC_RESTORE_FLAGS
785 AC_SUBST([SOCKET_LIBS])
786
787 dnl Check for socklen_t
788 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
789 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
790 ac_cv_type_socklen_t,
791 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
792 [#include <sys/types.h>
793 #ifdef _WIN32
794 # include <winsock2.h>
795 # include <ws2tcpip.h>
796 #else
797 # include <sys/socket.h>
798 #endif]], [[socklen_t len; len = 0;]])],
799 ac_cv_type_socklen_t=yes,
800 ac_cv_type_socklen_t=no)])
801 AS_IF([test "$ac_cv_type_socklen_t" = no], [
802   AC_COMPILE_IFELSE([
803     AC_LANG_PROGRAM([[
804 #include <sys/types.h>
805 #ifdef _WIN32
806 # include <winsock2.h>
807 # include <ws2tcpip.h>
808 #else
809 # include <sys/socket.h>
810 #endif
811     ]], [[
812 _Generic(getpeername, int (*)(int, struct sockaddr *, int *): 0);
813     ]])
814   ], AC_DEFINE(socklen_t, int), AC_DEFINE(socklen_t, unsigned int))
815 ])
816
817 dnl Check for struct sockaddr_storage
818 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
819 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
820 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
821   [AC_TRY_COMPILE(
822     [#include <sys/types.h>
823      #if defined( _WIN32 )
824      # include <winsock2.h>
825      #else
826      # include <sys/socket.h>
827      #endif], [struct sockaddr_storage addr;],
828      ac_cv_struct_sockaddr_storage=yes,
829      ac_cv_struct_sockaddr_storage=no)])
830 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
831   AC_DEFINE(sockaddr_storage, sockaddr)
832   AC_DEFINE(ss_family, sa_family)
833 ])
834
835 dnl FreeBSD has a gnugetopt library for this:
836 GNUGETOPT_LIBS=""
837 AC_CHECK_FUNC(getopt_long,, [
838   AC_CHECK_LIB([gnugetopt],[getopt_long], [
839     GNUGETOPT_LIBS="-lgnugetopt"
840   ])
841 ])
842 AC_SUBST([GNUGETOPT_LIBS])
843
844 AC_CHECK_LIB([m], [cos], [
845   LIBM="-lm"
846 ], [
847   LIBM=""
848 ])
849 AC_SUBST([LIBM])
850
851 AC_CHECK_LIB([m], [lrintf], [
852   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
853   VLC_ADD_LIBS([skins2],[-lm])
854 ])
855 AC_CHECK_LIB([m], [nanf],
856   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
857 )
858 AC_CHECK_LIB([m], [sincos], [
859   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
860 ], [
861   AC_LIBOBJ([sincos])
862 ])
863
864 AC_MSG_CHECKING([broken qsort_r prototype])
865 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <stdlib.h>
866
867 _Static_assert(_Generic((qsort_r),
868     void (*)(void *, size_t, size_t, void *,
869              int (*)(void *, const void *, const void *)) : 1, default: 0),
870     "Bad prototype not matched");
871 ])], [
872   AC_MSG_RESULT([broken])
873   AC_DEFINE([HAVE_BROKEN_QSORT_R], 1, [Defined to 1 if the qsort_r() prototype contradicts the upcoming POSIX standard.])
874 ], [
875   AC_MSG_RESULT([no])
876 ])
877
878 AC_MSG_CHECKING([_Thread_local support])
879 AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Thread_local int foo = 0;
880                    int main() {}])], [
881     AC_MSG_RESULT([ok])
882     AC_DEFINE(HAVE_THREAD_LOCAL, 1, [Defined to 1 if C11 _Thread_local storage qualifier is supported])
883 ],[ AC_MSG_RESULT([no])])
884
885 dnl __STDC_NO_THREADS__ can't be trusted on some platforms.
886 dnl check for its availability explicitely
887 AC_CHECK_HEADERS([threads.h])
888
889 AC_CHECK_LIB([anl],[getaddrinfo_a],[
890   AC_DEFINE(HAVE_LIBANL, 1, [Define to 1 if you have the anl library])
891 ])
892
893 dnl Check for dynamic plugins
894 LIBDL=""
895 have_dynamic_objects="no"
896 VLC_SAVE_FLAGS
897 AC_SEARCH_LIBS(dlsym, [dl svld], [
898   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
899     LIBDL="$ac_cv_search_dlsym"
900   ])
901   have_dynamic_objects="yes"
902 ])
903 VLC_RESTORE_FLAGS
904
905 # Windows
906 AS_IF([test "${SYS}" = "mingw32"], [
907   LIBDL=""
908   have_dynamic_objects="yes" #assume we can use shared objects
909 ])
910
911 AC_ARG_WITH([libfuzzer],
912     AS_HELP_STRING([--with-libfuzzer=DIR],
913         [use libFuzzer library from DIR and triggers sanitize coverage (default disabled)]),
914      [],
915      [with_libfuzzer=no])
916 AS_VAR_IF(with_libfuzzer, no, [], [
917     enable_shared=no
918     enable_static=yes
919     enable_vlc=no
920 ])
921 AM_CONDITIONAL([HAVE_LIBFUZZER], [test "${with_libfuzzer}" != "no"])
922
923 AS_IF([test "${enable_shared}" = "no"], [
924   have_dynamic_objects=no
925 ])
926 AM_CONDITIONAL([HAVE_DYNAMIC_PLUGINS], [test "${have_dynamic_objects}" != "no"])
927
928 AC_SUBST([LIBDL])
929
930 AS_IF([test "${SYS}" != "mingw32"], [
931   AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
932     AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
933       LIBRT="$ac_cv_search_clock_nanosleep"
934     ])
935   ], [
936     AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
937       AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
938         LIBRT="$ac_cv_search_nanosleep"
939       ])
940     ])
941   ])
942 ])
943 AC_SUBST([LIBRT])
944
945 dnl  Check for clock_* functions, needs to be done here,
946 dnl  after the -lrt check
947 AC_REPLACE_FUNCS([clock_gettime clock_nanosleep clock_getres])
948
949 dnl
950 dnl Check for headers
951 dnl
952
953 dnl  POSIX
954 AC_CHECK_HEADERS([arpa/inet.h poll.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h wordexp.h])
955 AC_CHECK_HEADERS([net/if.h], [], [],
956 [
957 #include <sys/types.h>
958 #include <sys/socket.h>
959 ])
960 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
961 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
962
963 dnl  BSD
964 AC_CHECK_HEADERS([netinet/tcp.h netinet/udplite.h sys/param.h sys/mount.h])
965
966 dnl  GNU/Linux
967 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h sys/eventfd.h])
968
969 dnl  MacOS
970 AC_CHECK_HEADERS([xlocale.h])
971
972 dnl Check for struct pollfd
973 AC_CHECK_TYPES([struct pollfd],,,
974 [#include <sys/types.h>
975 #if HAVE_POLL_H
976 # include <poll.h>
977 #elif defined (_WIN32)
978 # include <winsock2.h>
979 #endif
980 ])
981
982 dnl Check if C++ headers define locale_t
983 AC_LANG_PUSH(C++)
984 AC_CACHE_CHECK([if C++ headers define locale_t],
985   [ac_cv_cxx_locale_t],
986   [ac_cv_cxx_locale_t=no
987    AC_TRY_COMPILE([#include <locale>], [locale_t loc;],
988                     [ac_cv_cxx_locale_t=yes])])
989 if test "${ac_cv_cxx_locale_t}" != "no"; then
990   AC_DEFINE(HAVE_CXX_LOCALE_T, 1, Define to 1 if C++ headers define locale_t)
991 fi
992 AC_LANG_POP(C++)
993
994 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
995 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
996 AC_CHECK_TYPE(ssize_t,, [
997   AC_DEFINE(ssize_t, int)
998 ])
999
1000 dnl It seems that autoconf detects pkg-config only during the first
1001 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
1002 dnl it is nested within a conditional block, so it was not working right.
1003 PKG_PROG_PKG_CONFIG()
1004
1005 dnl On some OS we need static linking
1006 AS_IF([test -n "${PKG_CONFIG}" ],[
1007     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
1008         PKG_CONFIG="${PKG_CONFIG} --static"
1009     ])
1010 ])
1011
1012
1013 dnl
1014 dnl Check for zlib.h and -lz if available
1015 dnl
1016 AC_CHECK_HEADERS([zlib.h], [ have_zlib=yes ], [ have_zlib=no ])
1017 AM_CONDITIONAL([HAVE_ZLIB], [ test "${have_zlib}" = "yes" ])
1018 if test "${have_zlib}" = "yes"
1019 then
1020   VLC_ADD_LIBS([sap],[-lz])
1021 fi
1022
1023
1024 dnl
1025 dnl Domain name i18n support via GNU libidn
1026 dnl
1027 PKG_CHECK_MODULES([IDN], [libidn], [
1028   have_libidn="yes"
1029   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
1030 ], [
1031   have_libidn="no"
1032 ])
1033
1034
1035 dnl Check for dbus
1036 AC_ARG_ENABLE([dbus],
1037   AS_HELP_STRING([--enable-dbus],
1038     [compile D-Bus message bus support (default enabled)]))
1039 have_dbus="no"
1040 AS_IF([test "${enable_dbus}" != "no"], [
1041   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
1042     have_dbus="yes"
1043   ], [
1044     AS_IF([test -n "${enable_dbus}"], [
1045       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
1046     ], [
1047       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
1048     ])
1049   ])
1050 ])
1051 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
1052
1053
1054 dnl Check for systemd
1055 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
1056   have_systemd="yes"
1057 ], [
1058   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
1059 ])
1060 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
1061
1062
1063 EXTEND_HELP_STRING([Optimization options:])
1064 dnl
1065 dnl  Compiler warnings
1066 dnl
1067
1068 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CFLAGS])
1069 AX_APPEND_COMPILE_FLAGS([-Wall -Wextra -Wsign-compare -Wundef -Wpointer-arith -Wvolatile-register-var -Wformat -Wformat-security -Wduplicated-branches -Wduplicated-cond], [CXXFLAGS])
1070
1071 dnl -Werror-implicit-function-declaration is used for the if_nametoindex detection with winstore
1072 AX_APPEND_COMPILE_FLAGS([-Wbad-function-cast -Wwrite-strings -Wmissing-prototypes -Werror-implicit-function-declaration -Winit-self -Wlogical-op -Wshadow=local -Wmultistatement-macros], [CFLAGS])
1073 AX_APPEND_COMPILE_FLAGS([-pipe], [CFLAGS])
1074
1075 dnl UWP forbidden checks
1076 AS_IF([test "${SYS}" = "mingw32"], [
1077   AC_MSG_CHECKING(for if_nametoindex availability)
1078   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1079       [[#include <windows.h>
1080         #if defined(__MINGW64_VERSION_MAJOR) && __MINGW64_VERSION_MAJOR < 6
1081         # include <wincrypt.h>
1082         #endif
1083         #include <iphlpapi.h>
1084         static void test (void) {
1085           if_nametoindex("");
1086         }
1087       ]],[[;]])
1088     ],[
1089       AC_MSG_RESULT([present])
1090       AC_DEFINE([HAVE_IF_NAMETOINDEX], [1], [Define to 1 if you have if_nametoindex function])
1091     ],[
1092       AC_MSG_RESULT([not present])
1093     ])
1094 ])
1095
1096 dnl
1097 dnl  Debugging mode
1098 dnl
1099 AC_ARG_ENABLE([debug],
1100   AS_HELP_STRING([--disable-debug],
1101     [disable run-time assertions (default enabled)]),,
1102   [enable_debug="yes"])
1103 AH_TEMPLATE(NDEBUG,
1104             [Define to 1 if debug code should NOT be compiled])
1105 AS_IF([test "${enable_debug}" != "no"], [
1106   AC_CHECK_HEADERS([valgrind/valgrind.h])
1107 ], [
1108   AC_DEFINE(NDEBUG)
1109 ])
1110
1111 dnl
1112 dnl  Profiling
1113 dnl
1114 AC_ARG_ENABLE([gprof],
1115   AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)]),,
1116   [enable_gprof="no"])
1117 AS_IF([test "${enable_gprof}" != "no"], [
1118   CFLAGS="${CFLAGS} -pg"
1119   CXXFLAGS="${CXXFLAGS} -pg"
1120   OBJCFLAGS="${OBJCFLAGS} -pg"
1121   LDFLAGS="${LDFLAGS} -pg"
1122 ])
1123
1124 AC_ARG_ENABLE([cprof],
1125   AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)]),,
1126   [enable_cprof="no"])
1127 AS_IF([test "${enable_gprof}" != "no"], [
1128   CFLAGS="${CFLAGS} -finstrument-functions"
1129   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
1130   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
1131   LDFLAGS="${LDFLAGS} -finstrument-functions"
1132 ])
1133
1134 dnl
1135 dnl  Test coverage
1136 dnl
1137 AC_ARG_ENABLE([coverage],
1138   AS_HELP_STRING([--enable-coverage],
1139     [build for test coverage (default disabled)]),,
1140   [enable_coverage="no"])
1141 AS_IF([test "${enable_coverage}" != "no"], [
1142   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1143   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1144   LDFLAGS="-lgcov ${LDFLAGS}"
1145 ])
1146
1147 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
1148   VLC_SAVE_FLAGS
1149   CFLAGS="${CFLAGS} -fvisibility=hidden"
1150   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1151   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1152   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1153                  [ac_cv_c_visibility_hidden], [
1154     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1155       ac_cv_c_visibility_hidden=yes
1156     ], [
1157       ac_cv_c_visibility_hidden=no
1158     ])
1159   ])
1160   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1161 ])
1162
1163 dnl
1164 dnl Sanitizer flags
1165 dnl
1166 AC_ARG_WITH([sanitizer],
1167     AS_HELP_STRING([--with-sanitizer=(address/memory/undefined/thread)],
1168         [build with sanitizer flags (default disabled)]),
1169      [],
1170      [with_sanitizer=no])
1171
1172 AS_VAR_IF(with_sanitizer, no, [], [
1173     AX_CHECK_COMPILE_FLAG([-fsanitize=${with_sanitizer}], [
1174         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}])
1175         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [CXXFLAGS])
1176         AX_APPEND_FLAG([-fsanitize=${with_sanitizer}], [LDFLAGS])
1177     ], [
1178         AC_MSG_ERROR(["-fsanitize=${with_sanitizer} not supported!"])
1179     ])
1180     AX_APPEND_FLAG([-g])
1181     AX_APPEND_FLAG([-g], [CXXFLAGS])
1182
1183     AS_IF([test -z "${with_sanitizer##*address*}" ], [
1184        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract])
1185        AX_APPEND_COMPILE_FLAGS([-fsanitize-address-use-after-scope -fno-omit-frame-pointer -fsanitize=pointer-compare -fsanitize=pointer-subtract], [CXXFLAGS])
1186     ])
1187     AS_IF([test -z "${with_sanitizer##*memory*}" ], [
1188         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1189         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1190     ])
1191     AS_IF([test -z "${with_sanitizer##*thread*}" ], [
1192         AX_APPEND_COMPILE_FLAGS([-fPIE -pie])
1193         AX_APPEND_COMPILE_FLAGS([-fPIE -pie], [CXXFLAGS])
1194     ])
1195 ])
1196
1197 dnl
1198 dnl  Enable/disable optimizations
1199 dnl
1200 AC_ARG_ENABLE([optimizations],
1201   AS_HELP_STRING([--disable-optimizations],
1202     [disable compiler optimizations (default enabled)]),,
1203   [enable_optimizations="yes"])
1204
1205 dnl Check for various optimization flags
1206 AS_IF([test "${enable_optimizations}" != "no"], [
1207
1208   dnl -O3 only in production builds
1209   AS_IF([test "${enable_debug}" = "no"], [
1210     VLC_SAVE_FLAGS
1211     CFLAGS="${CFLAGS} -O3"
1212     CXXFLAGS="${CXXFLAGS} -O3"
1213     OBJCFLAGS="${OBJCFLAGS} -O3"
1214     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1215       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1216         ac_cv_c_o3=yes
1217       ], [
1218         ac_cv_c_o3=no
1219       ])
1220     ])
1221     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1222   ])
1223
1224   dnl Check for fast maths
1225   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CFLAGS])
1226   AX_APPEND_COMPILE_FLAGS([-fno-math-errno -funsafe-math-optimizations -fno-rounding-math -fno-signaling-nans -fcx-limited-range], [CXXFLAGS])
1227
1228 AH_BOTTOM([
1229 #if defined(_MSC_VER) && !defined(__clang__)
1230 # pragma fenv_access(off)
1231 # pragma fp_contract(on)
1232 #elif defined(__GNUC__)
1233 /* Not supported so far */
1234 #else
1235 # pragma STDC FENV_ACCESS OFF
1236 # pragma STDC FP_CONTRACT ON
1237 #endif
1238 ])
1239
1240   dnl Check for -funroll-loops
1241   VLC_SAVE_FLAGS
1242   CFLAGS="${CFLAGS} -funroll-loops"
1243   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1244   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1245   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1246     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1247       ac_cv_c_unroll_loops=yes
1248     ], [
1249       ac_cv_c_unroll_loops=no
1250     ])
1251   ])
1252   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1253
1254   AS_IF([test "$enable_debug" = "no"], [
1255     dnl Check for -fomit-frame-pointer
1256     VLC_SAVE_FLAGS
1257     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1258     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1259     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1260     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1261       [ac_cv_c_omit_frame_pointer], [
1262       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1263         ac_cv_c_omit_frame_pointer=yes
1264       ], [
1265         ac_cv_c_omit_frame_pointer=no
1266       ])
1267     ])
1268     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1269   ])
1270
1271 ])
1272
1273 AC_ARG_ENABLE([ssp],
1274   AS_HELP_STRING([--disable-ssp],
1275   [disable stack smashing protection (default enabled for optimized builds)]), [],
1276   [enable_ssp="yes"])
1277
1278 AS_IF([test "${enable_ssp}" != "no" -a "${enable_optimizations}" != "no"], [
1279   VLC_SAVE_FLAGS
1280   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong])
1281   AX_APPEND_COMPILE_FLAGS([-fstack-protector-strong], [CXXFLAGS])
1282   dnl Win32 requires linking to ssp for stack-protection
1283   AS_IF([test "${SYS}" = "mingw32"], [
1284       LDFLAGS="${LDFLAGS} -lssp"
1285       AC_CACHE_CHECK([if linker supports stack protectors], [ac_cv_ld_ssp], [
1286         AC_TRY_LINK([#include <stdio.h>],[char buf[100]; fgets(buf, sizeof(buf), stdin);], [
1287           ac_cv_ld_ssp="yes"
1288         ], [
1289           ac_cv_ld_ssp="no"
1290         ])
1291       ])
1292       AS_IF([test "${ac_cv_ld_ssp}" = "no"], [VLC_RESTORE_FLAGS])
1293   ])
1294 ])
1295
1296 AS_IF([test "${SYS}" = "mingw32"], [
1297     dnl library for BCrypt APIs
1298     AS_IF([test "${vlc_winstore_app}" = 1],
1299           VLC_ADD_LIBS([libvlccore], [-lbcrypt]))
1300 ])
1301
1302 VLC_SAVE_FLAGS
1303 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1304 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1305   AC_TRY_LINK([],, [
1306     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1307   ], [
1308     ac_cv_ld_bsymbolic=""
1309   ])
1310 ])
1311 VLC_RESTORE_FLAGS
1312 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1313 AC_SUBST([SYMBOLIC_LDFLAGS])
1314
1315 VLC_SAVE_FLAGS
1316 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1317 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1318   AC_TRY_LINK([],, [
1319     ac_cv_ld_z_defs="yes"
1320   ], [
1321     ac_cv_ld_z_defs="no"
1322   ])
1323 ])
1324 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1325
1326 dnl Check for __attribute__((packed))
1327 AC_CACHE_CHECK([for __attribute__((packed))],
1328   [ac_cv_c_attribute_packed],
1329   [ac_cv_c_attribute_packed=no
1330    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1331                     [ac_cv_c_attribute_packed=yes])])
1332 if test "${ac_cv_c_attribute_packed}" != "no"; then
1333   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1334 fi
1335
1336 dnl
1337 dnl  Check the CPU
1338 dnl
1339 case "${host_cpu}" in
1340   "")
1341     ARCH=unknown
1342     ;;
1343   armv*)
1344     ARCH="arm"
1345     host_cpu="arm"
1346     ;;
1347   *)
1348     ARCH="${host_cpu}"
1349     ;;
1350 esac
1351
1352 dnl Check for backtrace() support
1353 AC_CHECK_HEADERS([execinfo.h])
1354 AC_CHECK_FUNCS([backtrace])
1355
1356 dnl
1357 dnl  default modules
1358 dnl
1359 ALIASES="${ALIASES} cvlc rvlc"
1360
1361 dnl
1362 dnl  Accelerated modules
1363 dnl
1364
1365 dnl  Check for fully working MMX intrinsics
1366 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1367 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1368 AC_ARG_ENABLE([mmx],
1369   AS_HELP_STRING([--disable-mmx],
1370     [disable MMX optimizations (default auto)]),,[
1371   case "${host_cpu}" in
1372     i?86|x86_64)
1373       enable_mmx="yes"
1374       ;;
1375     *)
1376       enable_mmx="no"
1377       ;;
1378   esac
1379 ])
1380 have_mmx="no"
1381 have_mmxext="no"
1382 AS_IF([test "${enable_mmx}" != "no"], [
1383   ARCH="${ARCH} mmx"
1384   VLC_SAVE_FLAGS
1385   CFLAGS="${CFLAGS} -mmmx"
1386   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1387     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1388 [#include <mmintrin.h>
1389 #include <stdint.h>
1390 uint64_t frobzor;]], [
1391 [__m64 a, b, c;
1392 a = b = c = (__m64)frobzor;
1393 a = _mm_slli_pi16(a, 3);
1394 a = _mm_adds_pi16(a, b);
1395 c = _mm_srli_pi16(c, 8);
1396 c = _mm_slli_pi16(c, 3);
1397 b = _mm_adds_pi16(b, c);
1398 a = _mm_unpacklo_pi8(a, b);
1399 frobzor = (uint64_t)a;]])], [
1400       ac_cv_c_mmx_intrinsics=yes
1401     ], [
1402       ac_cv_c_mmx_intrinsics=no
1403     ])
1404   ])
1405   VLC_RESTORE_FLAGS
1406   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1407     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1408   ])
1409
1410   VLC_SAVE_FLAGS
1411   CFLAGS="${CFLAGS} -mmmx"
1412   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1413     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1414 void *p;
1415 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1416 ]])
1417     ], [
1418       ac_cv_mmx_inline=yes
1419     ], [
1420       ac_cv_mmx_inline=no
1421     ])
1422   ])
1423   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1424     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1425     have_mmx="yes"
1426   ])
1427
1428   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1429                  [ac_cv_mmxext_inline], [
1430     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1431 void *p;
1432 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1433 ]])
1434     ], [
1435       ac_cv_mmxext_inline=yes
1436     ], [
1437       ac_cv_mmxext_inline=no
1438     ])
1439   ])
1440   VLC_RESTORE_FLAGS
1441   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1442     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1443     have_mmxext="yes"
1444   ])
1445 ])
1446 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1447 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1448
1449 dnl  Check for fully workin SSE2 intrinsics
1450 dnl  We need support for -msse[2], we need <emmintrin.h>, and we also need a
1451 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1452 AC_ARG_ENABLE([sse],
1453   AS_HELP_STRING([--disable-sse],
1454     [disable SSE (1-4) optimizations (default auto)]),, [
1455   case "${host_cpu}" in
1456     i?86|x86_64)
1457       enable_sse=yes
1458       ;;
1459     *)
1460       enable_sse=no
1461       ;;
1462   esac
1463 ])
1464 have_sse2="no"
1465 AS_IF([test "${enable_sse}" != "no"], [
1466   ARCH="${ARCH} sse sse2"
1467
1468   VLC_SAVE_FLAGS
1469   CFLAGS="${CFLAGS} -msse2"
1470   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1471     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1472 [#include <emmintrin.h>
1473 #include <stdint.h>
1474 uint64_t frobzor;]], [
1475 [__m128i a, b, c;
1476 a = b = c = _mm_set1_epi64((__m64)frobzor);
1477 a = _mm_slli_epi16(a, 3);
1478 a = _mm_adds_epi16(a, b);
1479 c = _mm_srli_epi16(c, 8);
1480 c = _mm_slli_epi16(c, 3);
1481 b = _mm_adds_epi16(b, c);
1482 a = _mm_unpacklo_epi8(a, b);
1483 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1484       ac_cv_c_sse2_intrinsics=yes
1485     ], [
1486       ac_cv_c_sse2_intrinsics=no
1487     ])
1488   ])
1489   VLC_RESTORE_FLAGS
1490   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1491     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1492   ])
1493
1494   VLC_SAVE_FLAGS
1495   CFLAGS="${CFLAGS} -msse"
1496   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1497     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1498 void *p;
1499 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1500 ]])
1501     ], [
1502       ac_cv_sse_inline=yes
1503     ], [
1504       ac_cv_sse_inline=no
1505     ])
1506   ])
1507
1508   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1509     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1510   ])
1511
1512   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1513     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1514 void *p;
1515 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1516 ]])
1517     ], [
1518       ac_cv_sse2_inline=yes
1519     ], [
1520       ac_cv_sse2_inline=no
1521     ])
1522   ])
1523   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1524     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1525     have_sse2="yes"
1526   ])
1527
1528   # SSE3
1529   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1530     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1531 void *p;
1532 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1533 ]])
1534     ], [
1535       ac_cv_sse3_inline=yes
1536     ], [
1537       ac_cv_sse3_inline=no
1538     ])
1539   ])
1540
1541   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1542     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1543
1544   # SSSE3
1545   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1546     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1547 void *p;
1548 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1549 ]])
1550     ], [
1551       ac_cv_ssse3_inline=yes
1552     ], [
1553       ac_cv_ssse3_inline=no
1554     ])
1555   ])
1556
1557   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1558     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1559
1560   # SSE4.1
1561   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1562                  [ac_cv_sse4_1_inline], [
1563     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1564 void *p;
1565 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1566 ]])
1567     ], [
1568       ac_cv_sse4_1_inline=yes
1569     ], [
1570       ac_cv_sse4_1_inline=no
1571     ])
1572   ])
1573
1574   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1575     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1576
1577   # SSE4.2
1578   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1579                  [ac_cv_sse4_2_inline], [
1580     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1581 void *p;
1582 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1583 ]])
1584     ], [
1585       ac_cv_sse4_2_inline=yes
1586     ], [
1587       ac_cv_sse4_2_inline=no
1588     ])
1589   ])
1590
1591   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1592     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1593
1594   # SSE4A
1595   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1596     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1597 void *p;
1598 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1599 ]])
1600     ], [
1601       ac_cv_sse4a_inline=yes
1602     ], [
1603       ac_cv_sse4a_inline=no
1604     ])
1605   ])
1606   VLC_RESTORE_FLAGS
1607   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1608     AC_DEFINE([CAN_COMPILE_SSE4A], [1], [Define to 1 if SSE4A inline assembly is available.]) ])
1609 ])
1610 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1611
1612 dnl  Check for fully workin AVX2 intrinsics
1613 dnl  We need support for -mavx[2], we need <immintrin.h>, and we also need a
1614 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1615 AC_ARG_ENABLE([avx],
1616   AS_HELP_STRING([--disable-avx],
1617     [disable AVX (1-2) optimizations (default auto)]),, [
1618   case "${host_cpu}" in
1619     i?86|x86_64)
1620       enable_avx=yes
1621       ;;
1622     *)
1623       enable_avx=no
1624       ;;
1625   esac
1626 ])
1627 have_avx2="no"
1628 AS_IF([test "${enable_avx}" != "no"], [
1629   ARCH="${ARCH} avx avx2"
1630
1631   VLC_SAVE_FLAGS
1632   CFLAGS="${CFLAGS} -mavx2"
1633   AC_CACHE_CHECK([if $CC groks AVX2 intrinsics], [ac_cv_c_avx2_intrinsics], [
1634     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1635 [#include <immintrin.h>
1636 #include <stdint.h>
1637 uint64_t frobzor;]], [
1638 [__m256i a, b, c;
1639 a = b = c = _mm256_set1_epi64x((int64_t)frobzor);
1640 a = _mm256_slli_epi16(a, 3);
1641 a = _mm256_adds_epi16(a, b);
1642 c = _mm256_srli_epi16(c, 8);
1643 c = _mm256_slli_epi16(c, 3);
1644 b = _mm256_adds_epi16(b, c);
1645 a = _mm256_unpacklo_epi8(a, b);
1646 frobzor = (uint64_t)_mm256_extract_epi64(a, 0);]])], [
1647       ac_cv_c_avx2_intrinsics=yes
1648     ], [
1649       ac_cv_c_avx2_intrinsics=no
1650     ])
1651   ])
1652   VLC_RESTORE_FLAGS
1653   AS_IF([test "${ac_cv_c_avx2_intrinsics}" != "no"], [
1654     AC_DEFINE(HAVE_AVX2_INTRINSICS, 1, [Define to 1 if AVX2 intrinsics are available.])
1655   ])
1656
1657   VLC_SAVE_FLAGS
1658   CFLAGS="${CFLAGS} -mavx"
1659   AC_CACHE_CHECK([if $CC groks AVX inline assembly], [ac_cv_avx_inline], [
1660     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1661 void *p;
1662 asm volatile("xorps256 %%ymm1,%%ymm2"::"r"(p):"ymm1", "ymm2");
1663 ]])
1664     ], [
1665       ac_cv_avx_inline=yes
1666     ], [
1667       ac_cv_avx_inline=no
1668     ])
1669   ])
1670
1671   AS_IF([test "${ac_cv_avx_inline}" != "no" -a "${SYS}" != "solaris"], [
1672     AC_DEFINE(CAN_COMPILE_AVX, 1, [Define to 1 if AVX inline assembly is available.])
1673   ])
1674
1675   AC_CACHE_CHECK([if $CC groks AVX2 inline assembly], [ac_cv_avx2_inline], [
1676     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1677 void *p;
1678 asm volatile("punpckhqdq256 %%ymm1,%%ymm2"::"r"(p):"ymm1", "ymm2");
1679 ]])
1680     ], [
1681       ac_cv_avx2_inline=yes
1682     ], [
1683       ac_cv_avx2_inline=no
1684     ])
1685   ])
1686   VLC_RESTORE_FLAGS
1687   AS_IF([test "${ac_cv_avx2_inline}" != "no" -a "${SYS}" != "solaris"], [
1688     AC_DEFINE(CAN_COMPILE_AVX2, 1, [Define to 1 if AVX2 inline assembly is available.])
1689     have_avx2="yes"
1690   ])
1691 ])
1692 AM_CONDITIONAL([HAVE_AVX2], [test "$have_avx2" = "yes"])
1693
1694 VLC_SAVE_FLAGS
1695 CFLAGS="${CFLAGS} -mmmx"
1696 have_3dnow="no"
1697 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1698   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1699 void *p;
1700 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1701 ]])
1702   ], [
1703     ac_cv_3dnow_inline=yes
1704   ], [
1705     ac_cv_3dnow_inline=no
1706   ])
1707 ])
1708 VLC_RESTORE_FLAGS
1709 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1710   AC_DEFINE([CAN_COMPILE_3DNOW], 1,
1711             [Define to 1 if 3D Now! inline assembly is available.])
1712   have_3dnow="yes"
1713 ])
1714 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1715
1716
1717 AC_ARG_ENABLE([neon],
1718   AS_HELP_STRING([--disable-neon],
1719     [disable ARM NEON optimizations (default auto)]),, [
1720   case "${host_cpu}" in
1721     "arm")
1722       enable_neon="32"
1723       ;;
1724     "aarch64")
1725       enable_neon="64"
1726       ;;
1727     *)
1728       enable_neon="no"
1729       ;;
1730   esac
1731 ])
1732 AS_IF([test "${enable_neon}" != "no"], [
1733   VLC_SAVE_FLAGS
1734   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1735     AS_IF([test "${enable_neon}" != "64"], [
1736       CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1737       AC_COMPILE_IFELSE([
1738         AC_LANG_PROGRAM(,[[
1739 asm volatile("vqmovun.s64 d0, q1":::"d0");
1740 ]])
1741       ], [
1742         ac_cv_arm_neon="32"
1743       ], [
1744         ac_cv_arm_neon="no"
1745       ])
1746     ], [
1747       CFLAGS="${CFLAGS} -march=armv8-a+simd"
1748       AC_COMPILE_IFELSE([
1749         AC_LANG_PROGRAM(,[[
1750 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1751 ]])
1752       ], [
1753         ac_cv_arm_neon="64"
1754       ], [
1755         ac_cv_arm_neon="no"
1756       ])
1757     ])
1758   ])
1759   VLC_RESTORE_FLAGS
1760 ])
1761 AM_CONDITIONAL([HAVE_NEON], [test "${ac_cv_arm_neon}" = "32"])
1762 AM_CONDITIONAL([HAVE_ARM64], [test "${ac_cv_arm_neon}" = "64"])
1763
1764 AC_ARG_ENABLE([sve],
1765   AS_HELP_STRING([--disable-sve],
1766     [disable ARM SVE optimizations (default auto)]),, [
1767   AS_IF([test "${host_cpu}" = "aarch64"], [enable_sve="yes"] ,[enable_sve="no"])
1768 ])
1769 AS_IF([test "${enable_sve}" != "no"], [
1770   VLC_SAVE_FLAGS
1771   CFLAGS="${CFLAGS} -march=armv8-a+sve"
1772   AC_CACHE_CHECK([if $CCAS groks ARM SVE assembly], [ac_cv_arm_sve], [
1773     AC_COMPILE_IFELSE([
1774       AC_LANG_PROGRAM(,[[
1775 asm volatile("ptrue p0.s" ::: "p0");
1776 ]])
1777     ], [
1778       ac_cv_arm_sve="yes"
1779     ], [
1780       ac_cv_arm_sve="no"
1781     ])
1782   ])
1783   VLC_RESTORE_FLAGS
1784 ])
1785 AM_CONDITIONAL([HAVE_SVE], [test "${ac_cv_arm_sve}" = "yes"])
1786
1787 AC_ARG_ENABLE([branch-protection],
1788   AS_HELP_STRING([--disable-branch-protection],
1789     [disable AArch64 branch protection (default auto)]),, [
1790   AS_IF([test "${host_cpu}" = "aarch64"],
1791     [enable_branch_protection="yes"], [enable_branch_protection="no"])
1792 ])
1793 AS_IF([test "${enable_branch_protection}" != "no"], [
1794   AX_CHECK_COMPILE_FLAG([-mbranch-protection=standard], [
1795     AX_APPEND_FLAG([-mbranch-protection=standard], [CFLAGS])
1796     AX_APPEND_FLAG([-mbranch-protection=standard], [CXXFLAGS])
1797   ])
1798 ])
1799
1800
1801 AC_ARG_ENABLE([altivec],
1802   AS_HELP_STRING([--disable-altivec],
1803     [disable AltiVec optimizations (default auto)]),, [
1804   AS_CASE("${host_cpu}", [powerpc*],
1805         [enable_altivec=yes], [enable_altivec=no])
1806 ])
1807 have_altivec="no"
1808 ALTIVEC_CFLAGS=""
1809 AS_IF([test "${enable_altivec}" = "yes"], [
1810   ARCH="${ARCH} altivec";
1811   VLC_SAVE_FLAGS
1812   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1813     [ac_cv_altivec_inline],
1814     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1815          ac_cv_altivec_inline="yes",
1816          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1817           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1818             [ac_cv_altivec_inline="-Wa,-maltivec"],
1819             ac_cv_altivec_inline=no)
1820          ])])
1821   VLC_RESTORE_FLAGS
1822   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1823     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1824               [Define to 1 if AltiVec inline assembly is available.])
1825     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1826       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1827       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1828     ])
1829     have_altivec="yes"
1830   ])
1831
1832   VLC_SAVE_FLAGS
1833   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1834   [ac_cv_c_altivec], [
1835     CFLAGS="${CFLAGS} -maltivec"
1836     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1837 [#include <altivec.h>]], [
1838 [vec_ld(0, (unsigned char *)0);]])], [
1839       ac_cv_c_altivec="-maltivec"
1840     ], [
1841       ac_cv_c_altivec="no"
1842     ])
1843   ])
1844   VLC_RESTORE_FLAGS
1845   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1846     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1847     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1848     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1849     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1850     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1851     have_altivec="yes"
1852   ])
1853   AC_CHECK_HEADERS([altivec.h])
1854
1855   VLC_SAVE_FLAGS
1856   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1857   AC_CACHE_CHECK([if linker needs -framework vecLib],
1858     [ac_cv_ld_altivec],
1859     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1860   VLC_RESTORE_FLAGS
1861   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1862     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1863   ])
1864 ])
1865 AC_SUBST([ALTIVEC_CFLAGS])
1866 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1867
1868 dnl
1869 dnl  Memory usage
1870 dnl
1871 AC_ARG_ENABLE([optimize-memory],
1872   AS_HELP_STRING([--enable-optimize-memory],
1873     [optimize memory usage over performance]))
1874 if test "${enable_optimize_memory}" = "yes"; then
1875   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1876 fi
1877
1878 dnl
1879 dnl Allow running as root (useful for people running on embedded platforms)
1880 dnl
1881 AC_ARG_ENABLE([run-as-root],
1882   AS_HELP_STRING([--enable-run-as-root],
1883     [allow running VLC as root (default disabled)]))
1884 AS_IF([test "${enable_run_as_root}" = "yes"],[
1885     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1886               [Define to 1 to allow running VLC as root (uid 0).])
1887 ])
1888
1889 dnl
1890 dnl Stream output
1891 dnl
1892 AC_ARG_ENABLE([sout],
1893   AS_HELP_STRING([--disable-sout],
1894     [disable streaming output (default enabled)]))
1895 AS_IF([test "${enable_sout}" != "no"], [
1896   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1897 ])
1898 AM_CONDITIONAL([ENABLE_SOUT], [test "${enable_sout}" != "no"])
1899
1900 dnl Lua modules
1901 AC_ARG_ENABLE([lua],
1902   AS_HELP_STRING([--disable-lua],
1903     [disable LUA scripting support (default enabled)]))
1904 if test "${enable_lua}" != "no"
1905 then
1906   PKG_CHECK_MODULES(LUA, lua5.2, [ have_lua=yes ], [:])
1907
1908   AS_IF([test "${have_lua}" != "yes"], [
1909     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1910     PKG_CHECK_MODULES(LUA, lua5.1, [ have_lua=yes ], [:]) ])
1911
1912   AS_IF([test "${have_lua}" != "yes"], [
1913     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1914     PKG_CHECK_MODULES(LUA, lua >= 5.1, [ have_lua=yes ], [:]) ])
1915
1916   AS_IF([test "${have_lua}" != "yes"], [
1917      AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1918      have_lua_lib=no
1919      AC_CHECK_LIB( lua5.2 , luaL_newstate, [
1920        LUA_LIBS="-llua5.2"
1921        have_lua_lib=yes], [])
1922
1923      AS_IF([test "${have_lua_lib}" != "yes"], [
1924        AC_CHECK_LIB( lua5.1 , luaL_newstate, [
1925          LUA_LIBS="-llua5.1"
1926          have_lua_lib=yes], [] ) ])
1927
1928      AS_IF([test "${have_lua_lib}" != "yes"], [
1929        AC_CHECK_LIB( lua51 , luaL_newstate, [
1930          LUA_LIBS="-llua51"
1931          have_lua_lib=yes], [] ) ])
1932
1933      AS_IF([test "${have_lua_lib}" != "yes"], [
1934        AC_CHECK_LIB( lua , luaL_newstate,
1935          [LUA_LIBS="-llua"],
1936          [ have_lua=no ], [-lm] ) ])
1937
1938      dnl If we found any lib, check that we have the headers too
1939      AS_IF([test "${have_lua_lib}" = "yes"], [
1940        AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h], [ have_lua=yes ], []) ])
1941   ])
1942
1943   if test "x${have_lua}" != "xyes" ;  then
1944       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1945   fi
1946   AC_ARG_VAR([LUAC], [LUA byte compiler])
1947   AS_IF([test -z "$LUAC"], [
1948      AC_CHECK_TOOL(LUAC, [luac], [false])
1949   ])
1950   AS_IF([test "${LUAC}" = "false"], [
1951     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1952   ])
1953   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1954     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1955   ])
1956 fi
1957 AM_CONDITIONAL([BUILD_LUA], [test "${have_lua}" = "yes"])
1958
1959
1960 dnl
1961 dnl VideoLAN manager
1962 dnl
1963 AC_ARG_ENABLE([vlm],
1964   AS_HELP_STRING([--disable-vlm],
1965     [disable the stream manager (default enabled)]),,
1966   [enable_vlm="${enable_sout}"])
1967 AS_IF([test "${enable_vlm}" != "no"], [
1968   AS_IF([test "${enable_sout}" = "no"], [
1969     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1970   ])
1971   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1972 ])
1973 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1974
1975
1976 dnl
1977 dnl Addons manager storage and repositories modules
1978 dnl
1979 AC_ARG_ENABLE([addonmanagermodules],
1980   AS_HELP_STRING([--disable-addonmanagermodules],
1981     [disable the addons manager modules (default enabled)]))
1982 if test "${enable_addonmanagermodules}" != "no"
1983 then
1984   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1985 fi
1986 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1987
1988
1989 dnl
1990 dnl  Input plugins
1991 dnl
1992
1993 EXTEND_HELP_STRING([Input plugins:])
1994
1995 dnl
1996 dnl  libarchive access module
1997 dnl
1998 PKG_ENABLE_MODULES_VLC([ARCHIVE], [archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1999
2000 dnl
2001 dnl  live555 input
2002 dnl
2003 AC_ARG_ENABLE([live555],
2004   AS_HELP_STRING([--enable-live555],
2005     [enable RTSP input through live555 (default enabled)]))
2006
2007 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
2008   PKG_CHECK_MODULES(LIVE555, live555, [
2009     VLC_ADD_PLUGIN([live555])
2010     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
2011     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
2012   ], [
2013     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
2014
2015     AC_LANG_PUSH(C++)
2016     VLC_SAVE_FLAGS
2017
2018     dnl detect include paths
2019     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment/UsageEnvironment.hh"], [
2020       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
2021     ], [
2022       AS_IF([test "${SYS}" != "os2"], [
2023         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
2024         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
2025       ], [
2026         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
2027         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
2028         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
2029       ])
2030     ])
2031
2032     dnl CPP Flags
2033     AS_IF([test "${SYS}" = "solaris"], [
2034       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
2035     ])
2036     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
2037     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
2038
2039     dnl version check
2040     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
2041       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
2042 [#include <liveMedia_version.hh>
2043 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
2044 # error BOOM
2045 #endif]])
2046       ], [
2047         ac_cv_live555="yes"
2048       ], [
2049         ac_cv_live555="no"
2050       ])
2051     ])
2052
2053     AS_IF([test "$ac_cv_live555" = "no"], [
2054       AC_MSG_WARN([live555 is missing or its installed version is too old:
2055 Version 2011.12.23 or later is required to proceed.
2056 You can get an updated one from http://www.live555.com/liveMedia .])
2057       AS_IF([test -n "${enable_live555}"], [
2058         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
2059       ])
2060     ], [
2061       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
2062       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
2063       AS_IF([test "${SYS}" = "mingw32"], [
2064         # add ws2_32 for closesocket, select, recv
2065         other_libs="$other_libs -lws2_32"
2066       ])
2067
2068       dnl We need to check for pic because live555 don't provide shared libs
2069       dnl and we want to build a plugins so we need -fPIC on some arch.
2070       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
2071       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
2072       AC_CHECK_LIB([liveMedia_pic], [main], [
2073         VLC_ADD_PLUGIN([live555])
2074         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
2075       ],[
2076         AC_CHECK_LIB([liveMedia], [main], [
2077           VLC_ADD_PLUGIN([live555])
2078           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
2079         ],[],[${other_libs}])
2080       ],[${other_libs_pic}])
2081     ])
2082     VLC_RESTORE_FLAGS
2083     AC_LANG_POP(C++)
2084   ])
2085 ])
2086
2087 dnl
2088 dnl IIDC and DV FireWire input modules
2089 dnl
2090 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
2091 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
2092
2093 dnl
2094 dnl - linsys modules: access module check for libzvbi
2095 dnl
2096 AC_ARG_ENABLE([linsys],
2097   AS_HELP_STRING([--enable-linsys],
2098     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)]))
2099 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
2100   VLC_ADD_PLUGIN([linsys_hdsdi])
2101   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
2102     VLC_ADD_PLUGIN([linsys_sdi])
2103   ], [
2104     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
2105   ])
2106 ])
2107
2108 dnl
2109 dnl dvdread module: check for libdvdread
2110 dnl
2111 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 6.0.0], [dvdread input module], [auto])
2112
2113 dnl
2114 dnl libdvdnav plugin
2115 dnl
2116 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav >= 6.0.0], [DVD with navigation input module (dvdnav)], [auto])
2117
2118 dnl
2119 dnl  Blu-ray Disc Support with libbluray
2120 dnl
2121 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
2122
2123 dnl
2124 dnl  OpenCV wrapper and example filters
2125 dnl
2126 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
2127
2128
2129 dnl
2130 dnl  libsmbclient plugin
2131 dnl
2132 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smbc], [smbclient], (SMB/CIFS support), [auto])
2133
2134 dnl
2135 dnl  liBDSM access module
2136 dnl
2137 AM_CONDITIONAL([HAVE_DSM], [test "$AS_TR_SH(with_dsm)" = "yes"])
2138 PKG_WITH_MODULES([DSM], [libdsm >= 0.2.0], [
2139        VLC_ADD_PLUGIN([dsm])
2140        VLC_ADD_CFLAGS([dsm], [$DSM_CFLAGS])
2141        VLC_ADD_LIBS([dsm], [$DSM_LIBS])
2142        have_dsm="yes"
2143    ],,[libdsm SMB/CIFS access/sd module], [auto])
2144 AM_CONDITIONAL([HAVE_DSM], [test "${have_dsm}" = "yes"])
2145
2146 dnl
2147 dnl sftp access support
2148 dnl
2149 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
2150
2151 dnl
2152 dnl nfs access support
2153 dnl
2154 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
2155
2156 dnl
2157 dnl smb2 access support
2158 dnl
2159 PKG_ENABLE_MODULES_VLC([SMB2], [smb2], [libsmb2 >= 3.0.0], (support smb2 protocol via libsmb2), [auto])
2160
2161 dnl
2162 dnl  Video4Linux 2
2163 dnl
2164 AC_ARG_ENABLE([v4l2], AS_HELP_STRING([--disable-v4l2],
2165   [disable Video4Linux version 2 (default auto)]))
2166 have_v4l2="no"
2167 AS_IF([test "$enable_v4l2" != "no"], [
2168   AC_CHECK_HEADERS([linux/videodev2.h], [
2169     have_v4l2="yes"
2170   ])
2171 ])
2172 AM_CONDITIONAL([HAVE_V4L2], [test "${have_v4l2}" != "no"])
2173
2174 dnl
2175 dnl  NVDEC decoder/encoder
2176 dnl
2177 AC_ARG_ENABLE([nvdec], AS_HELP_STRING([--disable-nvdec],
2178   [disable NVDEC decoder (default auto)]))
2179 have_nvdec="no"
2180 AS_IF([test "$enable_nvdec" != "no"], [
2181   AC_CHECK_HEADERS([ffnvcodec/dynlink_loader.h], [
2182     have_nvdec="yes"
2183   ])
2184 ])
2185 AM_CONDITIONAL([HAVE_NVDEC], [test "${have_nvdec}" != "no"])
2186
2187 dnl
2188 dnl special access module for Blackmagic SDI cards
2189 dnl
2190 AC_ARG_ENABLE([decklink],
2191   AS_HELP_STRING([--disable-decklink],
2192     [disable Blackmagic DeckLink SDI input (default auto)]))
2193 AC_ARG_WITH([decklink_sdk],
2194   AS_HELP_STRING([--with-decklink-sdk=DIR],
2195     [location of Blackmagic DeckLink SDI SDK]))
2196 have_decklink=no
2197 if test "${enable_decklink}" != "no"
2198 then
2199   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
2200   then
2201     VLC_ADD_CPPFLAGS([decklink decklinkoutput stream_out_sdi],[-I${with_decklink_sdk}/include])
2202   fi
2203   VLC_SAVE_FLAGS
2204   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
2205   AC_LANG_PUSH([C++])
2206   AC_CHECK_HEADERS([DeckLinkAPIDispatch.cpp], [
2207       have_decklink=yes
2208       AS_IF([test "${SYS}" = "darwin"], [
2209         VLC_ADD_LIBS([decklink decklinkoutput],[-Wl,-framework,CoreFoundation])
2210       ])
2211   ], [
2212       AS_IF([test "${enable_decklink}" = "yes"], [
2213         AC_MSG_ERROR([Blackmagic DeckLink SDI include files not found!])
2214       ], [
2215         AC_MSG_WARN([Blackmagic DeckLink SDI include files not found, decklink disabled])
2216       ])
2217   ])
2218   AC_LANG_POP([C++])
2219   VLC_RESTORE_FLAGS
2220 fi
2221 AM_CONDITIONAL([HAVE_DECKLINK], [ test "${have_decklink}" != "no" ])
2222
2223
2224 dnl
2225 dnl  Built-in CD-DA and VCD module
2226 dnl
2227 AC_ARG_ENABLE([vcd],
2228   AS_HELP_STRING([--disable-vcd],
2229     [disable built-in VCD and CD-DA support (default enabled)]))
2230
2231 AC_ARG_ENABLE([libcddb],
2232   AS_HELP_STRING([--disable-libcddb],
2233     [disable CDDB for Audio CD (default enabled)]))
2234
2235 if test "${enable_vcd}" != "no" -a "${enable_winstore_app}" != "yes"
2236 then
2237   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2238   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2239     AC_MSG_RESULT(yes)
2240     VLC_ADD_PLUGIN([vcd cdda])
2241   ],[
2242     AC_MSG_RESULT(no)
2243   ])
2244
2245   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2246   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2247     AC_MSG_RESULT(yes)
2248     VLC_ADD_PLUGIN([vcd cdda])
2249     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2250   ],[
2251     AC_MSG_RESULT(no)
2252   ])
2253
2254   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2255   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2256     AC_MSG_RESULT(yes)
2257     VLC_ADD_PLUGIN([vcd cdda])
2258     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2259   ],[
2260     AC_MSG_RESULT(no)
2261   ])
2262
2263   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
2264   then
2265     VLC_ADD_PLUGIN([vcd cdda])
2266   fi
2267
2268   if test "$enable_libcddb" != "no"; then
2269     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
2270       HAVE_LIBCDDB=yes
2271       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2272       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2273       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2274       ],:
2275       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
2276       HAVE_LIBCDDB=no])
2277   fi
2278 fi
2279
2280 dnl
2281 dnl Linux DVB
2282 dnl
2283 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
2284   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
2285 [#include <linux/dvb/version.h>
2286 #if (DVB_API_VERSION < 5)
2287 # error Linux DVB API v3.2 and older are not supported.
2288 #endif
2289 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
2290 # error Linux DVB API v5.0 is unsupported. Please update.
2291 #endif
2292 ]])], [
2293   ac_cv_linux_dvb_5_1=yes
2294 ], [
2295   ac_cv_linux_dvb_5_1=no
2296 ])])
2297 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
2298
2299 dnl
2300 dnl  Screen capture module
2301 dnl
2302 AC_ARG_ENABLE([screen],
2303   AS_HELP_STRING([--enable-screen],
2304     [disable screen capture (default enabled)]))
2305 if test "${enable_screen}" != "no"; then
2306   if test "${SYS}" = "darwin"; then
2307     AC_CHECK_HEADERS([ApplicationServices/ApplicationServices.h], [
2308       VLC_ADD_PLUGIN([screen])
2309     ])
2310   fi
2311 fi
2312 AM_CONDITIONAL([HAVE_MAC_SCREEN], [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
2313
2314 dnl
2315 dnl  VNC/RFB access module
2316 dnl
2317 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
2318
2319 dnl  RDP/Remote Desktop access module
2320 dnl
2321 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
2322
2323 dnl
2324 dnl AVFoundation
2325 AC_SUBST([have_avfoundation], ["no"])
2326 AC_ARG_ENABLE([macosx-avfoundation],
2327   AS_HELP_STRING([--enable-macosx-avfoundation], [Mac OS X avcapture (video) module (default enabled on Mac OS X)]))
2328 if test "x${enable_macosx_avfoundation}" != "xno" &&
2329   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2330 then
2331   SAVED_LIBS="${LIBS}"
2332   LIBS="-framework AVFoundation"
2333   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2334   LIBS="${SAVED_LIBS}"
2335   if test "${have_avfoundation}" != "no"
2336   then
2337     VLC_ADD_PLUGIN([avcapture])
2338   fi
2339 fi
2340 AM_CONDITIONAL([HAVE_AVFOUNDATION], [test "${have_avfoundation}" != "no"])
2341
2342 dnl
2343 dnl  DCP plugin (using asdcplib)
2344 dnl
2345 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2346 AM_CONDITIONAL([HAVE_ASDCP], [test "${have_asdcp}" = "yes"])
2347
2348 dnl
2349 dnl  Demux plugins
2350 dnl
2351
2352 EXTEND_HELP_STRING([Mux/Demux plugins:])
2353
2354 dnl
2355 dnl  libdvbpsi check for ts mux/demux
2356 dnl
2357 have_dvbpsi="no"
2358 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2359 AM_CONDITIONAL([HAVE_DVBPSI], [test "${have_dvbpsi}" = "yes"])
2360
2361
2362 dnl
2363 dnl  GME demux plugin
2364 dnl
2365 AC_ARG_ENABLE([gme],
2366   AS_HELP_STRING([--enable-gme],
2367     [use Game Music Emu (default auto)]))
2368 AS_IF([test "${enable_gme}" != "no"], [
2369   AC_CHECK_HEADER([gme/gme.h], [
2370     AC_CHECK_LIB([gme], [gme_identify_header], [
2371       VLC_ADD_PLUGIN([gme])
2372     ], [
2373       AC_CHECK_LIB([gme], [gme_identify_extension], [
2374          VLC_ADD_LIBS([gme], [-lstdc++ $LIBM])
2375          VLC_ADD_PLUGIN([gme])
2376       ],, [-lstdc++ $LIBM])
2377     ])
2378     VLC_ADD_LIBS([gme], [-lgme])
2379   ], [
2380     AS_IF([test "x${enable_gme}" != "x"], [
2381       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2382     ])
2383   ])
2384 ])
2385
2386
2387 dnl
2388 dnl  SIDPlay plugin
2389 dnl
2390 AC_ARG_ENABLE([sid],
2391     AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)]))
2392 AS_IF([test "${enable_sid}" != "no"], [
2393     PKG_CHECK_MODULES(SID, [libsidplay2], [
2394         AC_LANG_PUSH(C++)
2395         oldCPPFLAGS="$CPPFLAGS"
2396         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2397         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2398             VLC_ADD_PLUGIN([sid])
2399             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2400             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2401         ], [
2402             AS_IF([test -n "${enable_sid}"],
2403                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2404                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2405                 )
2406         ])
2407         CPPFLAGS="$oldCPPFLAGS"
2408         AC_LANG_POP(C++)
2409     ], [
2410         AS_IF([test "x${enable_sid}" = "xyes"],
2411             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2412             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2413             )
2414     ])
2415 ])
2416
2417
2418 dnl
2419 dnl  ogg demux plugin
2420 dnl
2421 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2422 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2423     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2424 ],[true])
2425 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2426 if test "${enable_sout}" != "no"; then
2427 dnl Check for libshout
2428     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2429 fi
2430
2431 dnl
2432 dnl  matroska demux plugin
2433 dnl
2434 PKG_WITH_MODULES([MATROSKA], [libebml >= 1.3.6 libmatroska], [
2435        VLC_ADD_PLUGIN([mkv])
2436        VLC_ADD_CFLAGS([mkv], [$MATROSKA_CFLAGS])
2437        VLC_ADD_LIBS([mkv], [$MATROSKA_LIBS])
2438        have_matroska="yes"
2439    ],,[MKV format support], [auto])
2440 AM_CONDITIONAL([HAVE_MATROSKA], [test "${have_matroska}" = "yes"])
2441
2442 dnl
2443 dnl  modplug demux plugin
2444 dnl
2445 AC_ARG_ENABLE([mod],
2446   AS_HELP_STRING([--disable-mod],
2447     [do not use libmodplug (default auto)]))
2448 if test "${enable_mod}" != "no" ; then
2449     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.9.0], [
2450           VLC_ADD_PLUGIN([mod])
2451           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2452           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2453           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2454     ],[
2455        AS_IF([test -n "${enable_mod}"],
2456          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2457          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2458     ])
2459 fi
2460
2461 dnl
2462 dnl  mpc demux plugin
2463 dnl
2464 AC_ARG_ENABLE([mpc],
2465   AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)]))
2466 if test "${enable_mpc}" != "no"
2467 then
2468     AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2469     VLC_ADD_PLUGIN([mpc])
2470     VLC_ADD_LIBS([mpc],[-lmpcdec])])
2471 fi
2472
2473 dnl
2474 dnl  Codec plugins
2475 dnl
2476
2477 EXTEND_HELP_STRING([Codec plugins:])
2478
2479 dnl
2480 dnl shine encoder plugin
2481 dnl
2482 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2483
2484
2485 dnl
2486 dnl openmax il codec plugin
2487 dnl
2488 AC_ARG_ENABLE([omxil],
2489   AS_HELP_STRING([--enable-omxil], [openmax il codec module (default disabled)]))
2490 if test "${enable_omxil}" = "yes"
2491 then
2492   VLC_ADD_PLUGIN([omxil])
2493 fi
2494
2495 dnl
2496 dnl raspberry pi openmax il configuration
2497 dnl
2498 AC_ARG_ENABLE([rpi-omxil],
2499   AS_HELP_STRING([--enable-rpi-omxil], [openmax il configured for raspberry pi (default disabled)]))
2500 if test "${enable_rpi_omxil}" = "yes"
2501 then
2502   VLC_ADD_PLUGIN([omxil])
2503   VLC_ADD_CFLAGS([omxil],[-DRPI_OMX])
2504 fi
2505
2506 dnl
2507 dnl  mad plugin
2508 dnl
2509 have_mad="no"
2510 MAD_CFLAGS=""
2511 MAD_LIBS=""
2512
2513 AC_ARG_WITH(mad, AS_HELP_STRING([--with-mad=PATH], [path to libmad]), [
2514   enable_mad="yes"
2515 ], [
2516   with_mad="no"
2517 ])
2518 AS_IF([test "${with_mad}" != "no"], [
2519   MAD_CFLAGS="-I${with_mad}/include"
2520   MAD_LIBS="-L${with_mad}/lib"
2521 ])
2522
2523 AC_ARG_ENABLE([mad],
2524   AS_HELP_STRING([--enable-mad], [libmad module (default enabled)]))
2525 AS_IF([test "${enable_mad}" != "no"], [
2526   VLC_SAVE_FLAGS
2527   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2528   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2529   AC_CHECK_HEADERS([mad.h], [
2530     AC_CHECK_LIB([mad], [mad_bit_init], [
2531       have_mad="yes"
2532       MAD_LIBS="${MAD_LIBS} -lmad"
2533     ])
2534   ])
2535   VLC_RESTORE_FLAGS
2536   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2537     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2538   ])
2539 ])
2540 AC_SUBST([MAD_CFLAGS])
2541 AC_SUBST([MAD_LIBS])
2542 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2543
2544 dnl  mpg123 plugin
2545 dnl
2546 dnl
2547 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2548
2549 dnl
2550 dnl gstreamer stuff
2551 dnl
2552 AC_ARG_ENABLE([gst-decode],
2553   AS_HELP_STRING([--enable-gst-decode], [GStreamer based decoding support (currently supports only video decoding) (default auto)]))
2554
2555 have_gst_decode="no"
2556 AS_IF([test "${enable_gst_decode}" != "no"], [
2557   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2558     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2559       have_gst_decode="yes"
2560     ], [
2561       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2562     ])
2563   ], [
2564     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2565   ])
2566 ])
2567 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2568
2569 dnl
2570 dnl  avcodec decoder/encoder plugin
2571 dnl
2572 AC_ARG_ENABLE([merge-ffmpeg],
2573 AS_HELP_STRING([--enable-merge-ffmpeg], [merge FFmpeg-based plugins (default disabled)]),, [
2574   enable_merge_ffmpeg="no"
2575 ])
2576 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2577
2578 AC_MSG_CHECKING([for libavutil variant])
2579 PKG_CHECK_EXISTS([libavutil], [
2580   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2581   libavutil_micro="${libavutil_version##*.}"
2582   AS_IF([test ${libavutil_micro} -le 99], [
2583     avfork="libav"
2584   ], [
2585     avfork="ffmpeg"
2586   ])
2587 ], [
2588   avfork="none"
2589 ])
2590 AC_MSG_RESULT([${avfork}])
2591
2592 AC_ARG_ENABLE([avcodec],
2593 AS_HELP_STRING([--enable-avcodec], [libavcodec codec (default enabled)]))
2594 AS_IF([test "${enable_avcodec}" != "no"], [
2595   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2596   case "${avfork}" in
2597     libav) av_codec_ver="57.16.0" ;;
2598     dnl 05f66706d182eb0c36af54d72614bf4c33e957a9  includes libavutil 55.9.0
2599     ffmpeg) av_codec_ver="57.37.100" ;;
2600     dnl 7fc329e2dd6226dfecaa4a1d7adf353bf2773726  include libavutil 55.22.101
2601     *) AC_MSG_ERROR([Missing libav or FFmpeg. Pass --disable-avcodec to ignore this error.])
2602   esac
2603   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 55.9.0], [
2604     VLC_SAVE_FLAGS
2605     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2606     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2607     AC_CHECK_HEADERS([libavcodec/avcodec.h])
2608     AC_CHECK_HEADERS([libavutil/avutil.h])
2609     VLC_RESTORE_FLAGS
2610     have_avcodec="yes"
2611   ],[
2612     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2613   ])
2614 ], [
2615   have_avcodec="no"
2616 ])
2617 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2618
2619 dnl
2620 dnl libva needs avcodec
2621 dnl
2622 AC_ARG_ENABLE([libva],
2623   AS_HELP_STRING([--enable-libva], [VAAPI GPU decoding support (libVA) (default auto)]))
2624
2625 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2626   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2627 ])
2628
2629 have_vaapi="no"
2630 have_vaapi_drm="no"
2631 have_vaapi_x11="no"
2632 have_vaapi_wl="no"
2633 AS_IF([test "${enable_libva}" != "no"], [
2634   PKG_CHECK_MODULES([LIBVA], [libva >= 1.0], [
2635     have_vaapi="yes"
2636   ], [
2637     AS_IF([test -n "${enable_libva}"], [
2638       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2639     ], [
2640       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2641     ])
2642   ])
2643   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2644     have_vaapi_drm="yes"
2645   ], [
2646     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2647   ])
2648   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2649     have_vaapi_x11="yes"
2650   ], [
2651     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2652   ])
2653   PKG_CHECK_MODULES(LIBVA_WL, [libva-wayland], [
2654     have_vaapi_wl="yes"
2655   ], [
2656     AC_MSG_WARN([${LIBVA_WL_PKG_ERRORS}.])
2657   ])
2658 ])
2659 AM_CONDITIONAL([HAVE_VAAPI], [test "${have_vaapi}" = "yes"])
2660 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2661 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2662 AM_CONDITIONAL([HAVE_VAAPI_WL], [test "${have_vaapi_wl}" = "yes"])
2663
2664 have_avcodec_vaapi="no"
2665 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2666   VLC_SAVE_FLAGS
2667   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2668   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2669   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2670     AC_MSG_NOTICE([VA API acceleration activated])
2671     have_avcodec_vaapi="yes"
2672   ],[
2673     AS_IF([test -n "${enable_libva}"], [
2674       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2675     ], [
2676       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2677     ])
2678   ])
2679   VLC_RESTORE_FLAGS
2680 ])
2681 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2682
2683 dnl
2684 dnl dxva2 needs avcodec
2685 dnl
2686 AC_ARG_ENABLE([dxva2],
2687   AS_HELP_STRING([--enable-dxva2], [DxVA2 GPU decoding support (default auto)]))
2688
2689 have_avcodec_dxva2="no"
2690 AS_IF([test "${enable_dxva2}" != "no"], [
2691   if test "${SYS}" = "mingw32"; then
2692   AS_IF([test "x${have_avcodec}" = "xyes"], [
2693     AC_CHECK_HEADERS([dxva2api.h],
2694       [
2695         AC_CHECK_HEADERS([libavcodec/dxva2.h], [
2696            AC_MSG_NOTICE([DxVA2 acceleration activated])
2697            have_avcodec_dxva2="yes"
2698         ],[
2699     AS_IF([test "${enable_dxva2}" = "yes"],
2700           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2701               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2702         ], [#undef _WIN32_WINNT
2703             /* DXVA2 is only available in Vista and above */
2704             #define _WIN32_WINNT 0x600])
2705       ],[
2706     AS_IF([test "${enable_dxva2}" = "yes"],
2707               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2708               [AC_MSG_WARN([dxva2api.h not found])])
2709       ],[#include <d3d9.h>])
2710   ],[
2711     AS_IF([test "x${enable_dxva2}" != "x"], [
2712       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2713     ])
2714   ])
2715   fi
2716 ])
2717 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2718
2719 dnl
2720 dnl d3d11va needs avcodec
2721 dnl
2722 AC_ARG_ENABLE([d3d11va],
2723   AS_HELP_STRING([--enable-d3d11va], [D3D11 GPU decoding support (default auto)]))
2724
2725 have_avcodec_d3d11va="no"
2726 AS_IF([test "${enable_d3d11va}" != "no"], [
2727   if test "${SYS}" = "mingw32"; then
2728   AS_IF([test "x${have_avcodec}" = "xyes"], [
2729         AC_CHECK_TYPES([ID3D11VideoDecoder],
2730           [
2731             AC_CHECK_HEADERS([dxva2api.h],
2732               [
2733                 AC_CHECK_HEADERS([libavcodec/d3d11va.h], [
2734                    AC_MSG_NOTICE([D3D11 acceleration activated])
2735                    AC_DEFINE([HAVE_AVCODEC_D3D11VA], [1], [Define if the d3d11va module is built])
2736                    have_avcodec_d3d11va="yes"
2737                 ],[
2738                   AS_IF([test "${enable_d3d11va}" = "yes"],
2739                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2740                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2741                   ], [#undef _WIN32_WINNT
2742                       /* D3D11 is only available in Vista and above */
2743                       #define _WIN32_WINNT 0x600])
2744                   ],[
2745                     AS_IF([test "${enable_d3d11va}" = "yes"],
2746                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2747                           [AC_MSG_WARN([dxva2api.h not found])])
2748                   ],[#include <d3d9.h>])
2749           ],[
2750             AS_IF([test "${enable_d3d11va}" = "yes"],
2751                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2752                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2753           ], [#include <d3d11.h>])
2754   ],[
2755     AS_IF([test "x${enable_d3d11va}" != "x"], [
2756       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2757     ])
2758   ])
2759   fi
2760 ])
2761 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2762
2763 dnl
2764 dnl DXGI debug
2765 dnl
2766 AC_CHECK_HEADERS([dxgidebug.h dxgi1_6.h d3d11_4.h])
2767
2768 dnl
2769 dnl IApplicationData2
2770 dnl
2771 have_iapplication_data2="no"
2772 AC_CHECK_TYPES([IApplicationData2],[],[],[#include <windows.storage.h>])
2773
2774 dnl
2775 dnl DirectComposition
2776 dnl
2777 AC_LANG_PUSH([C++])
2778 AC_CHECK_HEADERS([dcomp.h], [
2779     have_dcomp="yes"
2780 ], [], [
2781   #include <windows.h>
2782 ])
2783 AC_LANG_POP([C++])
2784 AM_CONDITIONAL([HAVE_DCOMP], [test "${have_dcomp}" = "yes"])
2785
2786
2787 dnl
2788 dnl  avformat demuxer/muxer plugin
2789 dnl
2790
2791 AC_ARG_ENABLE([avformat],
2792 AS_HELP_STRING([--enable-avformat], [libavformat containers (default enabled)]),, [
2793   enable_avformat="${have_avcodec}"
2794 ])
2795 have_avformat="no"
2796 AS_IF([test "${enable_avformat}" != "no"], [
2797   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2798       have_avformat="yes"
2799       VLC_SAVE_FLAGS
2800       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2801       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2802       AC_CHECK_HEADERS([libavformat/avformat.h libavformat/avio.h])
2803       AC_CHECK_HEADERS([libavcodec/avcodec.h])
2804       AC_CHECK_HEADERS([libavutil/avutil.h])
2805       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2806         have_avformat="no"
2807       ])
2808       VLC_RESTORE_FLAGS
2809     ],[
2810       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2811   ])
2812 ])
2813 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2814
2815 dnl
2816 dnl  swscale image scaling and conversion plugin
2817 dnl
2818
2819 AC_ARG_ENABLE([swscale],
2820   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2821           (default enabled)]))
2822 if test "${enable_swscale}" != "no"
2823 then
2824   PKG_CHECK_MODULES(SWSCALE,[libswscale >= 0.5.0],
2825     [
2826       VLC_SAVE_FLAGS
2827       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2828       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2829       AC_CHECK_HEADERS([libswscale/swscale.h])
2830       AC_CHECK_HEADERS([libavutil/avutil.h])
2831       VLC_ADD_PLUGIN([swscale])
2832       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2833       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2834       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2835         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2836       ])
2837       VLC_RESTORE_FLAGS
2838     ],[
2839       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2840   ])
2841 fi
2842
2843 dnl
2844 dnl  postproc plugin
2845 dnl
2846
2847 AC_ARG_ENABLE([postproc],
2848 AS_HELP_STRING([--enable-postproc], [libpostproc image post-processing (default auto)]))
2849 if test "${enable_postproc}" != "no"
2850 then
2851   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2852     [
2853       VLC_SAVE_FLAGS
2854       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2855       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2856       AC_CHECK_HEADERS([postproc/postprocess.h])
2857       VLC_ADD_PLUGIN([postproc])
2858       VLC_RESTORE_FLAGS
2859     ],[
2860       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2861   ])
2862 fi
2863
2864 dnl
2865 dnl  faad decoder plugin
2866 dnl
2867 PKG_WITH_MODULES([FAAD],[faad2],
2868   VLC_ADD_PLUGIN(faad)
2869   VLC_ADD_CFLAGS(faad, [$FAAD_CFLAGS])
2870   VLC_ADD_LIBS(faad,[$FAAD_LIBS]),
2871   AS_IF([test "x${enable_faad}" != "xno"],[
2872     AC_CHECK_HEADERS([neaacdec.h], [
2873       AC_CHECK_LIB([faad], [NeAACDecOpen],[
2874                       VLC_ADD_PLUGIN([faad])
2875                       VLC_ADD_LIBS([faad],[-lfaad])
2876                       found_faad="yes"
2877                    ],[], [$LIBM])
2878     ])
2879     AS_IF([test "x${found_faad}" != "xyes"],
2880         AS_IF([test "x${enable_faad}" == "xyes"],
2881             AC_MSG_ERROR([${FAAD_PKG_ERRORS}.]),
2882             AC_MSG_WARN([${FAAD_PKG_ERRORS}.]))
2883     )
2884   ]),
2885 [faad AAC audio decoder])
2886
2887 dnl
2888 dnl  AOM encoder/decoder plugin
2889 dnl
2890 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [libaom AV1 encoder and decoder (default auto)])
2891
2892 dnl
2893 dnl  Rav1e encoder plugin
2894 dnl
2895 PKG_ENABLE_MODULES_VLC([RAV1E], [], [rav1e], [rav1e encoder module codec (default auto)])
2896
2897 dnl
2898 dnl  Dav1d decoder plugin
2899 dnl
2900 PKG_ENABLE_MODULES_VLC([DAV1D], [], [dav1d >= 0.5.0], [AV1 decoder (default auto)])
2901
2902 dnl
2903 dnl libvpx decoder plugin
2904 dnl
2905 AC_ARG_ENABLE([vpx],
2906     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2907 AS_IF([test "${enable_vpx}" != "no"],[
2908     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2909         VLC_ADD_PLUGIN([vpx])
2910         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2911         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2912         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2913             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2914         ], [], [${VPX_LIBS}])
2915         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2916             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2917         ], [], [${VPX_LIBS}])
2918         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2919             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2920         ], [], [${VPX_LIBS}])
2921         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2922             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2923         ], [], [${VPX_LIBS}])
2924     ], [
2925     AS_IF([test "${enable_vpx}" = "yes"],[
2926         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2927     ])])
2928 ])
2929
2930 dnl
2931 dnl twolame encoder plugin
2932 dnl
2933 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2934
2935 dnl
2936 dnl fdk-aac encoder plugin
2937 dnl
2938 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2939
2940
2941 dnl
2942 dnl A52/AC3 decoder plugin
2943 dnl
2944 AC_ARG_ENABLE([a52],
2945   AS_HELP_STRING([--enable-a52], [A/52 support with liba52 (default enabled)]))
2946 if test "${enable_a52}" != "no"
2947 then
2948   AC_ARG_WITH([a52],
2949     AS_HELP_STRING([--with-a52=PATH], [a52 headers and libraries]))
2950     if test -z "${with_a52}"
2951     then
2952       LDFLAGS_test=""
2953       CPPFLAGS_test=""
2954     else
2955       LDFLAGS_test="-L${with_a52}/lib"
2956       CPPFLAGS_test="-I${with_a52}/include"
2957     fi
2958     VLC_SAVE_FLAGS
2959     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2960     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2961     AC_CHECK_HEADERS([a52dec/a52.h], [
2962       AC_CHECK_LIB([a52], [a52_free], [
2963         VLC_ADD_PLUGIN([a52])
2964         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52 $LIBM])
2965         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2966       ],[
2967         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2968         ], [$LIBM])
2969     ],[
2970       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2971     ])
2972     VLC_RESTORE_FLAGS
2973 fi
2974
2975 dnl
2976 dnl DTS Coherent Acoustics decoder plugin
2977 dnl
2978 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2979
2980 dnl
2981 dnl  Flac plugin
2982 dnl
2983 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2984
2985 dnl
2986 dnl  Libmpeg2 plugin
2987 dnl
2988 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2989
2990 dnl
2991 dnl  Vorbis plugin
2992 dnl
2993 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2994
2995 dnl
2996 dnl  Tremor plugin
2997 dnl
2998 AC_ARG_ENABLE([tremor],
2999   AS_HELP_STRING([--enable-tremor], [Tremor decoder support (default disabled)]))
3000 if test "${enable_tremor}" = "yes"
3001 then
3002   AC_CHECK_HEADERS([tremor/ivorbiscodec.h], [
3003     VLC_ADD_PLUGIN([tremor])
3004    ],[])
3005 fi
3006
3007 dnl
3008 dnl  Speex plugins
3009 dnl
3010 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
3011 have_speexdsp="no"
3012 AS_IF([test "${enable_speex}" != "no"], [
3013   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
3014     have_speexdsp="yes"
3015   ], [
3016     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
3017   ])
3018 ])
3019 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
3020
3021 dnl
3022 dnl  RNNoise plugin - Recurrent neural network for audio noise reduction
3023 dnl
3024 PKG_ENABLE_MODULES_VLC([RNNOISE], [], [rnnoise], [Rnnoise denoiser], [auto])
3025
3026 dnl
3027 dnl  Opus plugin
3028 dnl
3029 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
3030
3031 dnl
3032 dnl  Ambisonic channel mixer and binauralizer plugin
3033 dnl
3034 PKG_ENABLE_MODULES_VLC([SPATIALAUDIO], [], [spatialaudio], [Ambisonic channel mixer and binauralizer], [auto])
3035
3036 dnl
3037 dnl  theora decoder plugin
3038 dnl
3039 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
3040
3041 dnl
3042 dnl  OggSpots decoder plugin
3043 dnl
3044 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
3045
3046 dnl
3047 dnl  Daala decoder plugin
3048 dnl
3049 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
3050
3051 dnl
3052 dnl  schroedinger decoder plugin (for dirac format video)
3053 dnl
3054 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
3055
3056 dnl
3057 dnl  PNG decoder module
3058 dnl
3059 AC_ARG_ENABLE([png],
3060   AS_HELP_STRING([--enable-png], [PNG support (default enabled)]))
3061 AS_IF([test "${enable_png}" != "no"], [
3062 AC_CHECK_HEADERS([png.h], [
3063   VLC_SAVE_FLAGS
3064   LDFLAGS="${LDFLAGS} -lz $LIBM"
3065   AC_CHECK_LIB([png], [png_set_alpha_mode], [
3066     VLC_ADD_PLUGIN([png])
3067   ], [], [-lz $LIBM])
3068   VLC_RESTORE_FLAGS
3069   ])
3070 ])
3071
3072 dnl
3073 dnl  JPEG decoder module
3074 dnl
3075 AC_ARG_ENABLE([jpeg],
3076   AS_HELP_STRING([--enable-jpeg], [JPEG support (default enabled)]))
3077 AS_IF([test "${enable_jpeg}" != "no"], [
3078 AC_CHECK_HEADERS([jpeglib.h], [
3079   VLC_ADD_PLUGIN([jpeg])
3080   ])
3081 ])
3082
3083 dnl
3084 dnl  BPG decoder module
3085 dnl
3086 AC_ARG_ENABLE([bpg],
3087   AS_HELP_STRING([--enable-bpg], [BPG support (default disabled)]))
3088 AS_IF([test "${enable_bpg}" != "no"], [
3089 AC_CHECK_HEADERS([libbpg.h], [
3090   VLC_ADD_PLUGIN([bpg])
3091   ])
3092 ])
3093
3094 dnl
3095 dnl H262 encoder plugin (lib262)
3096 dnl
3097 AC_ARG_ENABLE([x262],
3098   AS_HELP_STRING([--enable-x262], [H262 encoding support with static libx262 (default disabled)]))
3099 if test "${enable_x262}" != "no"; then
3100     PKG_CHECK_MODULES(X262, x262, [
3101         VLC_ADD_PLUGIN([x262])
3102         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
3103         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
3104           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
3105         ])
3106         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
3107         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
3108           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
3109         fi
3110     ], [
3111        if test "${enable_x262}" = "yes"; then
3112         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
3113        fi
3114     ])
3115 fi
3116
3117 dnl x265 encoder
3118 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
3119
3120 dnl
3121 dnl H264 encoder plugin (using libx264)
3122 dnl
3123 AC_ARG_ENABLE([x264],
3124   AS_HELP_STRING([--enable-x264], [H264 encoding support with libx264 (default enabled)]))
3125 if test "${enable_x264}" != "no"; then
3126       PKG_CHECK_MODULES(X264,x264 >= 0.148, [
3127         VLC_ADD_PLUGIN([x264])
3128         VLC_ADD_LIBS([x264],[${X264_LIBS}])
3129
3130         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
3131           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
3132         ])
3133
3134         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
3135         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3136           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
3137         fi
3138       ],[
3139         if test "${enable_x264}" = "yes"; then
3140             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
3141           fi
3142       ])
3143 fi
3144
3145 dnl
3146 dnl H264 encoder plugin (libx264 > 153)
3147 dnl
3148 AC_ARG_ENABLE([x26410b],
3149   AS_HELP_STRING([--enable-x26410b], [H264 10-bit encoding support with libx264 (default enabled)]))
3150 if test "${enable_x26410b}" != "no"; then
3151       PKG_CHECK_MODULES(X26410b,x264 >= 0.153, [
3152         VLC_ADD_PLUGIN([x26410b])
3153         VLC_ADD_LIBS([x26410b],[${X264_LIBS}])
3154
3155         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
3156           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
3157         ])
3158
3159         VLC_ADD_CFLAGS([x26410b],[${X264_CFLAGS}])
3160         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3161           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
3162         fi
3163       ],[
3164         if test "${enable_x26410b}" = "yes"; then
3165             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
3166           fi
3167       ])
3168 fi
3169
3170
3171 dnl
3172 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
3173 dnl
3174 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
3175
3176 dnl
3177 dnl libfluidsynth (MIDI synthetizer) plugin
3178 dnl
3179 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
3180 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
3181 AC_CHECK_HEADERS([fluidlite.h], [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
3182
3183 dnl
3184 dnl Teletext Modules
3185 dnl vbi decoder plugin (using libzbvi)
3186 dnl telx module
3187 dnl uncompatible
3188 dnl
3189 AC_ARG_ENABLE([zvbi],
3190   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
3191                   libzvbi (default enabled)]))
3192 AC_ARG_ENABLE([telx],
3193   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
3194                   zvbi) (default enabled if zvbi is absent)]))
3195
3196 AS_IF( [test "${enable_zvbi}" != "no"],[
3197     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
3198         [
3199           VLC_ADD_PLUGIN([zvbi])
3200           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
3201           have_zvbi="yes"
3202           AS_IF( [test "${enable_telx}" = "yes"],[
3203                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
3204                   ])
3205         ],[
3206           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
3207         ])
3208     ])
3209 AM_CONDITIONAL([HAVE_ZVBI], [test "x${have_zvbi}" = x"yes"])
3210
3211 AS_IF( [test "${enable_telx}" != "no" ],[
3212   VLC_ADD_PLUGIN([telx])
3213   have_telx="yes"
3214   AC_DEFINE(TELX_COMPILED, 1, [Define if the telx module is built])
3215   ])
3216 AM_CONDITIONAL([HAVE_TELX], [test "x${have_telx}" = x"yes"])
3217
3218 dnl
3219 dnl ARIB subtitles rendering module
3220 dnl
3221 AC_ARG_ENABLE([aribsub],
3222   AS_HELP_STRING([--enable-aribsub],[ARIB Subtitles support (default enabled)]))
3223 AS_IF( [test "${enable_aribsub}" != "no" ],[
3224   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
3225       have_aribb24="yes"
3226       VLC_ADD_PLUGIN([aribsub])
3227       VLC_ADD_LIBS([aribsub],[-laribb24])
3228       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
3229     ],[
3230       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
3231       have_aribb24="no"
3232   ])
3233 ])
3234 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
3235
3236 dnl
3237 dnl ARIB B25
3238 dnl
3239 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
3240
3241 dnl
3242 dnl  kate decoder plugin
3243 dnl
3244 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
3245
3246 dnl
3247 dnl  tiger rendering for kate decoder plugin
3248 dnl
3249 AC_ARG_ENABLE([tiger],
3250 AS_HELP_STRING([--enable-tiger], [Tiger rendering library for Kate streams (default auto)]))
3251 AS_IF([test "${enable_tiger}" != "no"], [
3252   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3253       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
3254         AS_IF([test -n "${enable_tiger}"], [
3255           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
3256         ])
3257   ])
3258 ])
3259
3260 dnl
3261 dnl  check if we can build the css selector engine
3262 dnl
3263 AC_ARG_ENABLE([css],
3264 AS_HELP_STRING([--enable-css], [CSS selector engine (default auto)]))
3265 AS_IF([test "${enable_css}" != "no"], [
3266   with_css="yes"
3267   AC_DEFINE(HAVE_CSS, 1, [Define if CSS engine is built])
3268 ])
3269 AM_CONDITIONAL([ENABLE_CSS], [test "${with_css}" = "yes"])
3270
3271
3272 dnl
3273 dnl  Video plugins
3274 dnl
3275
3276 EXTEND_HELP_STRING([Video plugins:])
3277
3278 dnl
3279 dnl  libplacebo support
3280 dnl
3281 AC_ARG_ENABLE([libplacebo],
3282   AS_HELP_STRING([--disable-libplacebo],
3283       [disable libplacebo support (default auto)]))
3284
3285 AS_IF([test "$enable_libplacebo" != "no"], [
3286   PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 0.5], [
3287     AC_DEFINE([HAVE_LIBPLACEBO], [1], [Define to 1 if libplacebo is enabled.])
3288     PKG_CHECK_MODULES([LIBPLACEBO], [libplacebo >= 1.7],
3289       [have_libplacebo_vk="yes"], [have_libplacebo_vk="no"])
3290   ], [
3291     AS_IF([test -n "${enable_libplacebo}"], [
3292       AC_MSG_ERROR([${LIBPLACEBO_PKG_ERRORS}.])
3293     ])
3294     enable_libplacebo="no"
3295   ])
3296 ])
3297 AM_CONDITIONAL([HAVE_LIBPLACEBO], [test "$enable_libplacebo" != "no"])
3298
3299 dnl
3300 dnl  OpenGL
3301 dnl
3302 PKG_CHECK_MODULES([EGL], [egl], [
3303   have_egl="yes"
3304 ], [
3305   have_egl="no"
3306 ])
3307 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3308
3309 have_gl="no"
3310 PKG_CHECK_MODULES([GL], [gl], [
3311   have_gl="yes"
3312 ], [
3313   AC_MSG_CHECKING([for OpenGL])
3314   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3315 #ifdef _WIN32
3316 # include <GL/glew.h>
3317 #endif
3318 #include <GL/gl.h>
3319 ]], [
3320     [int t0 = GL_TEXTURE0;]])
3321   ], [
3322     GL_CFLAGS=""
3323     have_gl="yes"
3324     AS_IF([test "${SYS}" != "mingw32"], [
3325       GL_LIBS="-lGL"
3326     ], [
3327       GL_LIBS="-lopengl32"
3328     ])
3329   ])
3330   AC_MSG_RESULT([${have_gl}])
3331 ])
3332 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3333 AS_IF([test "${have_gl}" = "yes"], [
3334   AC_DEFINE([HAVE_GL], 1, [Defined if having OpenGL])
3335 ])
3336
3337 dnl OpenGL ES 2: depends on EGL 1.1
3338 have_gles2="no"
3339 AC_ARG_ENABLE(gles2,
3340   [AS_HELP_STRING([--enable-gles2],
3341       [enable GLES2 support (default disabled)])])
3342 AS_IF([test "$enable_gles2" = "yes"], [
3343   PKG_CHECK_MODULES([GLES2], [glesv2], [have_gles2="yes"], [])
3344   ])
3345 AM_CONDITIONAL([HAVE_GLES2], [test "${have_gles2}" = "yes"])
3346
3347 dnl
3348 dnl Vulkan
3349 dnl
3350 AC_ARG_ENABLE(vulkan,
3351   [AS_HELP_STRING([--disable-vulkan],
3352       [disable Vulkan support (default auto)])])
3353
3354 AS_IF([test "$enable_vulkan" != "no"], [
3355   AS_IF([test "$have_libplacebo_vk" = "yes"], [
3356     PKG_CHECK_MODULES([VULKAN], [vulkan >= 1.0.26], [
3357       AC_DEFINE([HAVE_VULKAN], [1], [Define to 1 if vulkan is enabled.])
3358     ], [
3359       AS_IF([test -n "${enable_vulkan}"], [
3360         AC_MSG_ERROR([${VULKAN_PKG_ERRORS}.])
3361       ])
3362       enable_vulkan="no"
3363     ])
3364   ], [
3365     AS_IF([test -n "${enable_vulkan}"], [
3366       AC_MSG_ERROR([Vulkan support requires libplacebo 1.7 as well. Do not use --disable-libplacebo.])
3367     ])
3368     enable_vulkan="no"
3369   ])
3370 ])
3371 AM_CONDITIONAL(HAVE_VULKAN, [test "$enable_vulkan" != "no"])
3372
3373 dnl
3374 dnl  Xlib
3375 dnl
3376
3377 AC_PATH_XTRA()
3378 AC_CHECK_HEADERS([X11/Xlib.h])
3379
3380 dnl
3381 dnl  X C Bindings modules
3382 dnl
3383 AC_ARG_ENABLE([xcb],
3384   AS_HELP_STRING([--enable-xcb], [X11 support with XCB (default enabled)]),, [
3385   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3386     enable_xcb="yes"
3387   ], [
3388     enable_xcb="no"
3389   ])
3390 ])
3391
3392 have_xcb="no"
3393 have_xkbcommon_x11="no"
3394 have_xcb_keysyms="no"
3395 AS_IF([test "${enable_xcb}" != "no"], [
3396   xcb_err=""
3397
3398   dnl libxcb
3399   PKG_CHECK_MODULES([XCB], [xcb >= 1.6],, [
3400     xcb_err="$xcb_err ${XCB_PKG_ERRORS}."])
3401   PKG_CHECK_MODULES([XCB_COMPOSITE], [xcb-composite],, [
3402     xcb_err="$xcb_err ${XCB_COMPOSITE_PKG_ERRORS}."])
3403   PKG_CHECK_MODULES([XCB_RANDR], [xcb-randr >= 1.3],, [
3404     xcb_err="$xcb_err ${XCB_RANDR_PKG_ERRORS}."])
3405   PKG_CHECK_MODULES([XCB_RENDER], [xcb-render],, [
3406     xcb_err="$xcb_err ${XCB_RENDER_PKG_ERRORS}."])
3407   PKG_CHECK_MODULES([XCB_SHM], [xcb-shm >= 1.9.2],, [
3408     xcb_err="$xcb_err ${XCB_SHM_PKG_ERRORS}."])
3409   PKG_CHECK_MODULES([XCB_XKB], [xcb-xkb],, [
3410     xcb_err="$xcb_err ${XCB_XKB_PKG_ERRORS}."])
3411
3412   dnl xproto
3413   PKG_CHECK_MODULES(XPROTO, [xproto],, [
3414     xcb_err="$xcb_err ${XPROTO_PKG_ERRORS}."])
3415
3416   AS_IF([test -n "$xcb_err"], [
3417     AC_MSG_ERROR([$xcb_err Pass --disable-xcb to skip X11 support.])
3418   ])
3419
3420   dnl xkbcommon
3421   PKG_CHECK_MODULES([XKBCOMMON_X11], [xkbcommon-x11], [
3422     have_xkbcommon_x11="yes"
3423   ], [
3424     AC_MSG_WARN([${XKBCOMMON_X11_PKG_ERRORS}. Hotkeys are disabled.])
3425   ])
3426
3427   dnl xcb-utils
3428   PKG_CHECK_MODULES([XCB_KEYSYMS], [xcb-keysyms >= 0.3.4], [
3429     have_xcb_keysyms="yes"
3430   ], [
3431     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Global hotkeys are disabled.])
3432   ])
3433
3434   have_xcb="yes"
3435 ])
3436 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3437 AM_CONDITIONAL([HAVE_XKBCOMMON_X11], [test "${have_xkbcommon_x11}" = "yes"])
3438 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3439
3440
3441 dnl
3442 dnl VDPAU needs X11
3443 dnl
3444 AC_ARG_ENABLE([vdpau],
3445   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3446 have_vdpau="no"
3447 AS_IF([test "${enable_vdpau}" != "no"], [
3448   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3449     have_vdpau="yes"
3450     AS_IF([test "${no_x}" = "yes"], [
3451       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3452     ])
3453   ], [
3454     AS_IF([test -n "${enable_vdpau}"], [
3455       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3456     ])
3457   ])
3458 ])
3459 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3460
3461 have_avcodec_vdpau="no"
3462 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3463   case "${avfork}" in
3464     libav) av_vdpau_ver="56.10.0" ;;
3465     ffmpeg) av_vdpau_ver="56.19.100" ;;
3466   esac
3467   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3468     have_avcodec_vdpau="yes"
3469     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3470   ], [
3471     AS_IF([test -n "${enable_vdpau}"], [
3472       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3473     ], [
3474       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3475     ])
3476   ])
3477 ])
3478 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3479
3480
3481 dnl
3482 dnl  Wayland
3483 dnl
3484 AC_ARG_ENABLE([wayland],
3485   AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)]))
3486
3487 have_wayland="no"
3488 AS_IF([test "${enable_wayland}" != "no"], [
3489   wl_err=""
3490
3491   dnl wayland
3492   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91],, [
3493     wl_err="$wl_err ${WAYLAND_CLIENT_PKG_ERRORS}."
3494   ])
3495   PKG_CHECK_MODULES([WAYLAND_CURSOR], [wayland-cursor],, [
3496     wl_err="$wl_err ${WAYLAND_CURSOR_PKG_ERRORS}."
3497   ])
3498   PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl],, [
3499     wl_err="$wl_err ${WAYLAND_EGL_PKG_ERRORS}."
3500   ])
3501   PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner >= 1.15], [
3502     WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3503   ], [
3504     wl_err="$wl_err ${WAYLAND_SCANNER_PKG_ERRORS}."
3505   ])
3506
3507   dnl wayland-protocols
3508   PKG_CHECK_MODULES([WAYLAND_PROTOCOLS], [wayland-protocols >= 1.15], [
3509     WAYLAND_PROTOCOLS="$(${PKG_CONFIG} wayland-protocols --variable pkgdatadir)"
3510   ], [
3511     wl_err="$wl_err ${WAYLAND_PROTOCOLS_PKG_ERRORS}."
3512   ])
3513
3514   AS_IF([test -n "$wl_err"], [
3515     AS_IF([test -n "$enable_wayland"], [
3516       AC_MSG_ERROR([$wl_err])
3517     ], [
3518       AC_MSG_WARN([$wl_err])
3519     ])
3520   ], [
3521     have_wayland="yes"
3522   ])
3523
3524   dnl xkbcommon
3525   PKG_CHECK_MODULES([XKBCOMMON], [xkbcommon], [
3526     have_xkbcommon="yes"
3527   ], [
3528     AC_MSG_WARN([${XKBCOMMON_PKG_ERRORS}. Hotkeys are disabled.])
3529   ])
3530 ])
3531 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3532 AC_SUBST([WAYLAND_PROTOCOLS])
3533 AC_SUBST([WAYLAND_SCANNER])
3534 AM_CONDITIONAL([HAVE_XKBCOMMON], [test "${have_xkbcommon}" = "yes"])
3535
3536
3537 dnl
3538 dnl  freetype module
3539 dnl
3540 AC_ARG_ENABLE([freetype],
3541   AS_HELP_STRING([--enable-freetype],   [freetype support   (default auto)]))
3542 AC_ARG_ENABLE([fribidi],
3543   AS_HELP_STRING([--enable-fribidi],    [fribidi support    (default auto)]))
3544 AC_ARG_ENABLE([harfbuzz],
3545   AS_HELP_STRING([--enable-harfbuzz],   [harfbuzz support   (default auto)]))
3546 AC_ARG_ENABLE([fontconfig],
3547   AS_HELP_STRING([--enable-fontconfig], [fontconfig support (default auto)]))
3548
3549 AC_ARG_WITH([default-font],
3550     AS_HELP_STRING([--with-default-font=PATH],
3551         [Path to the default font]),
3552         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3553             "$withval", [Default font])])
3554 AC_ARG_WITH([default-monospace-font],
3555     AS_HELP_STRING([--with-default-monospace-font=PATH],
3556         [Path to the default font]),
3557         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3558             "$withval", [Default monospace font])])
3559
3560 AC_ARG_WITH([default-font-family],
3561     AS_HELP_STRING([--with-default-font-family=NAME],
3562         [Name of the default font family]),
3563         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3564             "$withval", [Default font family])])
3565 AC_ARG_WITH([default-monospace-font-family],
3566     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3567         [Name of the default font family]),
3568         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3569             "$withval", [Default monospace font family])])
3570
3571 have_freetype="no"
3572 have_fontconfig="no"
3573 have_fribidi="no"
3574 have_harfbuzz="no"
3575
3576 if test "${enable_freetype}" != "no"; then
3577    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3578       have_freetype="yes"
3579       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3580       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3581
3582     dnl fontconfig support
3583     AS_IF([test "${enable_fontconfig}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3584       PKG_CHECK_MODULES(FONTCONFIG, [fontconfig >= 2.11], [
3585         have_fontconfig="yes"
3586       ], [
3587         AC_MSG_WARN([${FONTCONFIG_PKG_ERRORS}. Styles will be disabled in FreeType.])
3588       ])
3589     ])
3590
3591       dnl fribidi support
3592       if test "${enable_fribidi}" != "no"; then
3593         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3594           have_fribidi="yes"
3595           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3596           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3597         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3598       fi
3599
3600       dnl harfbuzz support
3601       if test "${have_fribidi}" != "no"; then
3602         if test "${enable_harfbuzz}" != "no"; then
3603           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3604             have_harfbuzz="yes"
3605             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3606             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3607           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3608         fi
3609       fi
3610   ],[
3611   AS_IF([test -n "${enable_freetype}"],[
3612     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3613     ])
3614   ])
3615 fi
3616
3617 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3618 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3619 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3620 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3621
3622 dnl
3623 dnl libass subtitle rendering module
3624 dnl
3625 AC_ARG_ENABLE([libass],
3626   AS_HELP_STRING([--enable-libass], [Subtitle support using libass (default enabled)]))
3627 AS_IF( [test "${enable_libass}" != "no"], [
3628   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
3629       [
3630         VLC_ADD_PLUGIN([libass])
3631
3632         if test "${have_fontconfig}" != "no"; then
3633             VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3634             VLC_ADD_LIBS([libass],[${FONTCONFIG_LIBS}])
3635         fi
3636       ],[
3637         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3638       ])
3639   ])
3640
3641 dnl
3642 dnl SAPI (text to Speech renderer for Windows)
3643 dnl
3644 AC_LANG_PUSH([C++])
3645 AC_CHECK_TYPES([ISpObjectToken],[
3646               have_sapi="yes"
3647             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3648               [#include <windows.h>
3649                #include <sapi.h>
3650                #include <sphelper.h>])
3651 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3652 AC_LANG_POP([C++])
3653
3654 dnl
3655 dnl  SVG module (text rendering and image decoding)
3656 dnl
3657 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3658 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3659
3660 dnl
3661 dnl  Windows DirectX module
3662 dnl
3663
3664 AC_ARG_ENABLE([directx],
3665   AS_HELP_STRING([--enable-directx],
3666     [Microsoft DirectX support (default enabled on Windows)]),, [
3667   AS_IF([test "${SYS}" = "mingw32"], [
3668     enable_directx="yes"
3669   ], [
3670     enable_directx="no"
3671   ])
3672 ])
3673 AS_IF([test "${enable_directx}" != "no"], [
3674   dnl OpenGL
3675   AC_CHECK_HEADERS([GL/glew.h], [
3676     AC_CHECK_HEADERS([GL/wglew.h], [
3677         VLC_ADD_PLUGIN([glwin32 wgl])
3678       ],, [
3679         #include <windows.h>
3680         #include <GL/glew.h>
3681       ])],, [
3682       #include <windows.h>
3683    ])
3684
3685   dnl Direct3D11
3686   AC_CHECK_HEADERS([d3d11.h], [
3687     VLC_ADD_PLUGIN([direct3d11 direct3d11_filters])
3688   ])
3689
3690   dnl Direct3D9
3691   AC_CHECK_HEADERS([d3d9.h], [
3692     VLC_ADD_PLUGIN([direct3d9])
3693     AC_CHECK_HEADERS([d3dx9effect.h])
3694
3695     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
3696         [[#define COBJMACROS
3697           #include <d3d9.h>
3698           #include <dxva2api.h>
3699           #ifndef IDirectXVideoProcessorService_GetVideoProcessorDeviceGuids
3700           # error dxva2 too old
3701           #endif
3702         ]],[[;]])
3703       ],[
3704         VLC_ADD_PLUGIN([direct3d9_filters])
3705       ],
3706       [AC_MSG_WARN([Could not find required IDirectXVideoDecoder in dxva2api.h])])
3707
3708   ])
3709 ])
3710
3711 dnl
3712 dnl  Linux framebuffer module
3713 dnl
3714 AC_CHECK_HEADER([linux/fb.h], [
3715   VLC_ADD_PLUGIN([fb])
3716 ])
3717
3718 dnl
3719 dnl  Linux kernel mode setting module
3720 dnl
3721 PKG_ENABLE_MODULES_VLC([KMS], [], [libdrm >= 2.4.83], [Linux kernel mode setting output], [auto])
3722
3723 dnl
3724 dnl  libcaca plugin
3725 dnl
3726 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3727
3728 dnl
3729 dnl  OS/2 KVA plugin
3730 dnl
3731 AC_ARG_ENABLE([kva],
3732   AS_HELP_STRING([--enable-kva],
3733     [support the K Video Accelerator KVA (default enabled on OS/2)]),, [
3734   AS_IF([test "$SYS" = "os2"], [
3735     enable_kva="yes"
3736   ])
3737 ])
3738 have_kva="no"
3739 KVA_LIBS=""
3740 AS_IF([test "$enable_kva" != "no"], [
3741   AC_CHECK_HEADERS([kva.h], [
3742     have_kva="yes"
3743     AC_CHECK_LIB([kva], [main], [
3744       KVA_LIBS="-lkva"
3745     ])
3746   ])
3747 ])
3748 AC_SUBST([KVA_LIBS])
3749 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3750
3751 dnl
3752 dnl MMAL plugin
3753 dnl
3754 AC_ARG_ENABLE([mmal],
3755   AS_HELP_STRING([--enable-mmal],
3756     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3757 if test "${enable_mmal}" != "no"; then
3758   VLC_SAVE_FLAGS
3759   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3760   CPPFLAGS="${CPPFLAGS} -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux"
3761   AC_CHECK_HEADERS([interface/mmal/mmal.h],
3762     [ AC_CHECK_LIB([bcm_host], [vc_tv_unregister_callback_full], [
3763         have_mmal="yes"
3764         VLC_ADD_PLUGIN([mmal])
3765         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3766         VLC_ADD_CFLAGS([mmal],[ -isystem /opt/vc/include -isystem /opt/vc/include/interface/vcos/pthreads -isystem /opt/vc/include/interface/vmcs_host/linux ])
3767         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lmmal_core -lmmal_components -lmmal_util -lvchostif -lvcsm -lvchiq_arm ]) ], [
3768           AS_IF([test "${enable_mmal}" = "yes"],
3769             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3770             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3771           ],
3772         [])
3773     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3774       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3775       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3776   VLC_RESTORE_FLAGS
3777 fi
3778 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3779
3780 dnl
3781 dnl  Audio plugins
3782 dnl
3783
3784 EXTEND_HELP_STRING([Audio plugins:])
3785
3786 dnl
3787 dnl  Pulseaudio module
3788 dnl
3789 AC_ARG_ENABLE([pulse],
3790   AS_HELP_STRING([--enable-pulse],
3791     [use the PulseAudio client library (default auto)]))
3792 have_pulse="no"
3793 AS_IF([test "${enable_pulse}" != "no"], [
3794   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3795     have_pulse="yes"
3796   ], [
3797     AS_IF([test "x${enable_pulse}" != "x"], [
3798       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3799     ])
3800   ])
3801 ])
3802 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3803
3804 dnl
3805 dnl  ALSA module
3806 dnl
3807 AC_ARG_ENABLE([alsa],
3808   AS_HELP_STRING([--enable-alsa],
3809     [support the Advanced Linux Sound Architecture (default auto)]),, [
3810   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3811     enable_alsa="yes"
3812   ])
3813 ])
3814 have_alsa="no"
3815 AS_IF([test "${enable_alsa}" != "no"], [
3816   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3817     have_alsa="yes"
3818   ], [
3819     AS_IF([test "x${enable_alsa}" != "x"], [
3820       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required. Pass --disable-alsa to ignore this error.])
3821     ])
3822   ])
3823 ])
3824 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3825
3826 dnl
3827 dnl  Open Sound System module
3828 dnl
3829 AC_ARG_ENABLE([oss],
3830   AS_HELP_STRING([--enable-oss],
3831     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)]),, [
3832   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3833     enable_oss="no"
3834   ])
3835 ])
3836 have_oss="no"
3837 OSS_LIBS=""
3838 AS_IF([test "$enable_oss" != "no"], [
3839   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3840     have_oss="yes"
3841     AC_CHECK_LIB([ossaudio], [main], [
3842       OSS_LIBS="-lossaudio"
3843     ])
3844   ])
3845 ])
3846 AC_SUBST([OSS_LIBS])
3847 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3848
3849 dnl
3850 dnl  OpenBSD sndio module
3851 dnl
3852 AC_ARG_ENABLE([sndio],
3853   AS_HELP_STRING([--disable-sndio],
3854     [support the OpenBSD sndio (default auto)]),, [
3855   AS_IF([test "$SYS" = "openbsd"], [
3856     enable_sndio="yes"
3857   ])
3858 ])
3859 have_sndio="no"
3860 AS_IF([test "$enable_sndio" != "no"], [
3861   AC_CHECK_HEADER([sndio.h], [
3862     have_sndio="yes"
3863   ])
3864 ])
3865 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3866
3867 dnl
3868 dnl  Windows Audio Session plugin
3869 dnl
3870 AC_ARG_ENABLE([wasapi],
3871   AS_HELP_STRING([--enable-wasapi],
3872     [use the Windows Audio Session API (default auto)])
3873 )
3874 have_wasapi="no"
3875 AS_IF([test "$enable_wasapi" != "no"], [
3876   AC_CHECK_HEADER([audioclient.h], [
3877     have_wasapi="yes"
3878   ], [
3879     AS_IF([test "x${enable_wasapi}" != "x"], [
3880       AC_MSG_ERROR([Windows Audio Session API not found.])
3881     ])
3882   ])
3883 ])
3884 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3885
3886 dnl
3887 dnl  JACK modules
3888 dnl
3889 AC_ARG_ENABLE([jack],
3890   AS_HELP_STRING([--disable-jack],
3891     [do not use jack (default auto)]))
3892 have_jack="no"
3893 AS_IF([test "${enable_jack}" != "no"], [
3894     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3895       [ have_jack=yes ],
3896       [
3897       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3898
3899       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3900       [ have_jack=yes ],
3901       [
3902       AS_IF([test -n "${enable_jack}"],
3903          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3904          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3905       ])
3906     ])
3907 ])
3908 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3909
3910 dnl
3911 dnl  OpenSLES Android
3912 dnl
3913 AC_ARG_ENABLE([opensles],
3914   AS_HELP_STRING([--enable-opensles], [Android OpenSL ES audio module (default disabled)]))
3915 if test "${HAVE_ANDROID}" = "1"; then
3916   if test "${enable_opensles}" = "yes"; then
3917       AC_CHECK_HEADERS([SLES/OpenSLES.h],
3918         [ VLC_ADD_PLUGIN([opensles_android]) ],
3919         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3920   fi
3921 fi
3922
3923 dnl
3924 dnl libsamplerate plugin
3925 dnl
3926 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3927
3928 dnl
3929 dnl  soxr module
3930 dnl
3931 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3932
3933 dnl
3934 dnl  libebur128 module
3935 dnl
3936 PKG_ENABLE_MODULES_VLC([EBUR128], [], [libebur128 >= 1.2.4], [EBU R 128 standard for loudness normalisation], [auto])
3937
3938 dnl
3939 dnl  OS/2 KAI plugin
3940 dnl
3941 AC_ARG_ENABLE([kai],
3942   AS_HELP_STRING([--enable-kai],
3943     [support the K Audio Interface KAI (default enabled on OS/2)]),, [
3944   AS_IF([test "$SYS" = "os2"], [
3945     enable_kai="yes"
3946   ])
3947 ])
3948 have_kai="no"
3949 KAI_LIBS=""
3950 AS_IF([test "$enable_kai" != "no"], [
3951   AC_CHECK_HEADERS([kai.h], [
3952     have_kai="yes"
3953     AC_CHECK_LIB([kai], [main], [
3954       KAI_LIBS="-lkai"
3955     ])
3956   ])
3957 ])
3958 AC_SUBST([KAI_LIBS])
3959 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3960
3961 dnl
3962 dnl  chromaprint audio track fingerprinter
3963 dnl
3964 PKG_ENABLE_MODULES_VLC([CHROMAPRINT], [stream_out_chromaprint], [libchromaprint >= 0.6.0], [Chromaprint audio fingeprinter], [auto])
3965
3966 dnl
3967 dnl  Chromecast streaming support
3968 dnl
3969 m4_pushdef([protobuf_lite_version], 2.5.0)
3970 AC_ARG_VAR(PROTOC, [protobuf compiler])
3971 AC_CHECK_PROGS(PROTOC, protoc, no)
3972 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3973     AS_IF([test "x${PROTOC}" != "xno"], [
3974         build_chromecast="yes"
3975     ], [
3976     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3977     ])
3978 ], [
3979     AS_IF([test "${enable_chromecast}" = "yes"],
3980         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3981         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3982     )
3983     enable_chromecast="no"
3984 ], [(Chromecast streaming support)], [auto])
3985 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3986 m4_popdef([protobuf_lite_version])
3987
3988 dnl
3989 dnl  Interface plugins
3990 dnl
3991
3992 EXTEND_HELP_STRING([Interface plugins:])
3993
3994 dnl
3995 dnl QT
3996 dnl
3997 AC_ARG_ENABLE([qt],
3998   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)]),, [
3999   AS_IF([test "${enable_vlc}" != "no"], [enable_qt="yes"])
4000   AS_IF([test "${SYS}" = "darwin"], [
4001     enable_qt="no"
4002   ])
4003 ])
4004 have_qt5_x11="no"
4005 AS_IF([test "${enable_qt}" != "no"], [
4006   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.11.0 Qt5Widgets Qt5Gui Qt5Quick Qt5QuickWidgets Qt5QuickControls2 Qt5Svg], [
4007       PKG_CHECK_MODULES([QT5_X11], [Qt5X11Extras], [
4008           have_qt5_x11="yes"
4009       ],[
4010           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
4011       ])
4012       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
4013       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
4014       QT_VERSION="$(eval $PKG_CONFIG --modversion Qt5Gui)"
4015       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
4016       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
4017       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
4018       AC_PATH_PROGS(QMLCACHE, [qmlcachegen-qt5 qmlcachegen], no, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
4019       AS_IF([test "x${QMLCACHE}" = "xno"], [
4020           AC_MSG_WARN([qmlcachegen not found])
4021       ])
4022     ], [
4023       AS_IF([test -n "${enable_qt}"],[
4024         AC_MSG_ERROR([${QT_PKG_ERRORS}. If you want to build VLC without GUI, pass --disable-qt.])
4025       ],[
4026         AC_MSG_WARN([${QT_PKG_ERRORS}.])
4027       ])
4028       enable_qt="no"
4029     ])
4030 ])
4031
4032 AC_ARG_ENABLE([qt-qml-cache],
4033   AS_HELP_STRING([--enable-qt-qml-cache],
4034     [enable qml cache generation]))
4035 AM_CONDITIONAL([HAVE_QMLCACHE], [test "${enable_qt_qml_cache}" = "yes" && test "x$QMLCACHE" != "xno"])
4036
4037 AC_ARG_ENABLE([qt-qml-debug],
4038   AS_HELP_STRING([--enable-qt-qml-debug], [enable qml debuger]))
4039 AM_CONDITIONAL(QT_QML_DEBUG, [test "${enable_qt_qml_debug}" = "yes"])
4040
4041 AS_IF([test "${enable_qt}" != "no"], [
4042   ALIASES="${ALIASES} qvlc"
4043 ])
4044 AC_SUBST([QT_VERSION])
4045 AM_CONDITIONAL([ENABLE_QT], [test "$enable_qt" != "no"])
4046 AM_CONDITIONAL([HAVE_QT5_X11], [test "${have_qt5_x11}" = "yes"])
4047
4048 dnl
4049 dnl detect kde4-config patch (used for kde solids).
4050 dnl
4051 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4052 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4053   KDE4_CONFIG="kde4-config"
4054 ])
4055
4056 dnl
4057 dnl Simple test for skins2 dependency
4058 dnl
4059 AS_IF([test "$enable_qt" = "no"], [
4060   AS_IF([test "${enable_skins2}" = "yes"], [
4061     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
4062   ], [
4063     enable_skins2="no"
4064     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
4065   ])
4066 ])
4067
4068 dnl
4069 dnl Skins2 module
4070 dnl
4071 AC_ARG_ENABLE([skins2],
4072   AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)]))
4073 AS_IF([test "${enable_skins2}" != "no"], [
4074   have_skins_deps="yes"
4075
4076   dnl Win32
4077   AS_IF([test "${SYS}" = "mingw32"], [
4078     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
4079     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
4080   dnl OS/2
4081   ], [test "${SYS}" = "os2"], [
4082     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
4083   dnl Linux/Unix
4084   ], [
4085     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
4086     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
4087     PKG_CHECK_MODULES([XCURSOR], [xcursor],, [have_skins_deps="no"])
4088     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
4089     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
4090     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} ${XCURSOR_LIBS} -lX11])
4091   ])
4092
4093   dnl we need freetype
4094   AS_IF([test "${have_freetype}" != "yes"], [
4095     have_skins_deps="no"
4096   ])
4097
4098   AS_IF([test "${have_skins_deps}" = "no"], [
4099     AS_IF([test "x${enable_skins2}" = "x"], [
4100       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
4101     ], [
4102       AC_MSG_ERROR([Skins2 interface requires FreeType, libxcursor, libxpm, libxext and libxinerama])
4103     ])
4104     enable_skins2="no"
4105   ], [
4106     ALIASES="${ALIASES} svlc"
4107     enable_skins2="yes"
4108   ])
4109 ])
4110 AM_CONDITIONAL([BUILD_SKINS], [test "${enable_skins2}" = "yes"])
4111
4112 AC_ARG_ENABLE([libtar],
4113   AS_HELP_STRING([--enable-libtar], [libtar support for skins2 (default auto)]))
4114 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
4115   AC_CHECK_HEADERS([libtar.h], [
4116     VLC_ADD_LIBS([skins2],[-ltar])
4117   ])
4118 ])
4119
4120 dnl
4121 dnl  MacOS X gui module
4122 dnl
4123 AC_ARG_ENABLE([macosx],
4124   AS_HELP_STRING([--enable-macosx], [Mac OS X gui support (default enabled on Mac OS X)]))
4125 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
4126 then
4127
4128   dnl
4129   dnl If possible, use xcrun to find the right ibtool
4130   dnl
4131
4132   AC_PATH_PROG([XCRUN], [xcrun], [no])
4133   AS_IF([test ! "x${XCRUN}" = "xno"], [
4134     AC_MSG_CHECKING([for ibtool (using xcrun)])
4135     XIB="$(eval $XCRUN -f ibtool 2>/dev/null || echo no)"
4136     AC_MSG_RESULT([${XIB}])
4137   ], [
4138     AC_MSG_WARN([Looking for tools without using xcrun])
4139   ])
4140
4141   AS_IF([test "x${XIB}" = "xno"], [
4142     AC_PATH_PROG(XIB, [ibtool], [no])
4143     AS_IF([test "x${XIB}" = "xno"], [
4144       AC_MSG_ERROR([ibtool was not found, but is required for --enable-macosx])
4145     ])
4146   ])
4147 fi
4148 AM_CONDITIONAL([ENABLE_MACOSX_UI], [test "$enable_macosx" != "no" -a "${SYS}" = "darwin"])
4149
4150 dnl
4151 dnl  MacOS X sparkle update support
4152 dnl
4153 AC_ARG_ENABLE([sparkle],
4154   AS_HELP_STRING([--enable-sparkle], [Sparkle update support for OS X (default enabled on Mac OS X)]))
4155 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
4156 then
4157   if test ! -d ${CONTRIB_DIR}/Sparkle.framework -a ! -d ${CONTRIB_DIR}/Frameworks/Sparkle.framework
4158   then
4159     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
4160   fi
4161
4162   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
4163 fi
4164 AM_CONDITIONAL([HAVE_SPARKLE], [test "$enable_sparkle" != "no"])
4165
4166 dnl
4167 dnl  MacOS X breakpad creash reporter support
4168 dnl
4169 AC_ARG_WITH([breakpad],
4170   AS_HELP_STRING([--with-breakpad=URL], [Enable Breakpad reporter using given URL]), [], [with_breakpad=no])
4171
4172 AS_IF([test "$with_breakpad" != "no"], [
4173
4174   AS_IF([test "$with_breakpad" = "yes"], [
4175     AC_MSG_ERROR([You need to supply the CrashDragon Server URL as value for --with-breakpad])
4176   ])
4177
4178   AS_IF([test "$HAVE_OSX" = "1"], [
4179     AC_MSG_CHECKING([for Breakpad framework])
4180     AS_IF([test ! -d ${CONTRIB_DIR}/Breakpad.framework -a \
4181                 ! -d ${CONTRIB_DIR}/Frameworks/Breakpad.framework], [
4182       AC_MSG_RESULT([no])
4183       with_breakpad="no"
4184       AC_MSG_ERROR([Breakpad framework is required and was not found in ${CONTRIB_DIR}])
4185     ], [
4186       AC_MSG_RESULT([yes])
4187     ])
4188   ],[
4189     PKG_CHECK_MODULES([BREAKPAD], [breakpad-client], [
4190       LDFLAGS="${LDFLAGS} -Wl,--build-id"
4191     ], [
4192       AC_MSG_ERROR(["breakpad not found"])
4193     ])
4194   ])
4195 ])
4196
4197 AM_CONDITIONAL([HAVE_BREAKPAD], [test "$with_breakpad" != "no"])
4198 AS_IF([test "$with_breakpad" != "no"], [
4199   AC_SUBST([BREAKPAD_URL], ["${with_breakpad}"])
4200 ])
4201
4202 dnl
4203 dnl  Minimal Mac OS X module
4204 dnl
4205 AC_ARG_ENABLE([minimal-macosx],
4206   AS_HELP_STRING([--enable-minimal-macosx], [Minimal Mac OS X support (default disabled)]))
4207 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
4208 then
4209   VLC_ADD_PLUGIN([minimal_macosx])
4210 fi
4211
4212 dnl
4213 dnl Mac OS X fancy dmg build tool
4214 dnl
4215 if test "${HAVE_OSX}" = "1"
4216 then
4217   AC_PATH_PROG(DMGBUILD, dmgbuild, no)
4218   AS_IF([test "x${DMGBUILD}" = "xno"], [
4219     AC_MSG_WARN([dmgbuild not found -- unable to build fancy DMGs])
4220   ])
4221 fi
4222 AM_CONDITIONAL([HAVE_DMGBUILD], [test "x$DMGBUILD" != "xno" -a "${HAVE_OSX}" = "1"])
4223
4224 dnl
4225 dnl  VideoToolbox plugins
4226 AC_CHECK_HEADERS([VideoToolbox/VideoToolbox.h], [
4227     VLC_ADD_PLUGIN([videotoolbox])
4228     VLC_ADD_PLUGIN([cvpx])
4229   ])
4230
4231 dnl
4232 dnl  AudioToolbox MIDI plugin
4233 AC_CHECK_HEADERS([AudioToolbox/AudioToolbox.h], [
4234   VLC_ADD_PLUGIN([audiotoolboxmidi])
4235 ])
4236
4237 dnl
4238 dnl  ncurses module
4239 dnl
4240 AC_ARG_ENABLE([ncurses],
4241 AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)]))
4242 have_ncurses="no"
4243 AS_IF([test "${enable_ncurses}" != "no"] ,[
4244   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
4245     have_ncurses="yes"
4246     ALIASES="${ALIASES} nvlc"
4247   ], [
4248     AS_IF([test -n "${enable_ncurses}"], [
4249       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
4250     ])
4251   ])
4252 ])
4253 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
4254
4255 dnl
4256 dnl  Lirc plugin
4257 dnl
4258 AC_ARG_ENABLE([lirc],
4259   AS_HELP_STRING([--enable-lirc], [lirc support (default disabled)]))
4260 have_lirc="no"
4261 AS_IF([test "${enable_lirc}" = "yes"], [
4262   AC_CHECK_HEADER(lirc/lirc_client.h, [
4263     AC_CHECK_LIB([lirc_client], [lirc_init], [
4264       have_lirc="yes"
4265     ])
4266   ])
4267 ])
4268 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
4269
4270 dnl
4271 dnl  Bitstream
4272 dnl
4273 PKG_CHECK_MODULES([BITSTREAM], [bitstream > 1.4],[have_bitstream="yes"], [have_bitstream="no"])
4274 AM_CONDITIONAL([HAVE_BITSTREAM], [test "${have_bitstream}" = "yes"])
4275
4276 dnl
4277 dnl  SRT plugin
4278 dnl
4279 PKG_ENABLE_MODULES_VLC([SRT], [access_srt access_output_srt], [srt >= 1.3.0], [SRT input/output plugin], [auto], [], [], [-DENABLE_SRT])
4280
4281 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
4282 dnl
4283 dnl  goom visualization plugin
4284 dnl
4285 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
4286
4287 dnl
4288 dnl libprojectM visualization plugin
4289 dnl
4290 AC_ARG_ENABLE([projectm],
4291   AS_HELP_STRING([--enable-projectm], [projectM visualization plugin (default enabled)]))
4292 AS_IF([test "${enable_projectm}" != "no"],
4293   [
4294     PKG_CHECK_MODULES(PROJECTM, libprojectM,
4295     [
4296       VLC_ADD_PLUGIN([projectm])
4297       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
4298         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
4299         [ AC_MSG_WARN( [Using libprojectM version 1] )
4300       ])
4301     ],[
4302       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
4303     ])
4304   ])
4305
4306 dnl
4307 dnl Vovoid VSXu visualization plugin
4308 dnl
4309 AC_ARG_ENABLE([vsxu],
4310   AS_HELP_STRING([--enable-vsxu], [Vovoid VSXu visualization plugin (default auto)]))
4311 AS_IF([test "${enable_vsxu}" != "no"],
4312   [
4313     PKG_CHECK_MODULES(VSXU, libvsxu,
4314     [
4315       VLC_ADD_PLUGIN([vsxu])
4316     ],[
4317       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4318     ])
4319   ])
4320
4321 EXTEND_HELP_STRING([Service Discovery plugins:])
4322 dnl
4323 dnl  Avahi-Zeroconf services discovery
4324 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4325
4326 dnl
4327 dnl  libudev services discovery
4328 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4329
4330 dnl
4331 dnl MTP devices services discovery
4332 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4333
4334 dnl
4335 dnl UPnP Plugin (Intel SDK)
4336 dnl
4337 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4338
4339 dnl
4340 dnl mDNS using libmicrodns
4341 dnl
4342 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns >= 0.1.2], [mDNS services discovery], [auto])
4343
4344
4345 EXTEND_HELP_STRING([Misc options:])
4346
4347 dnl
4348 dnl  libxml2 module
4349 dnl
4350 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4351
4352
4353 dnl
4354 dnl libgcrypt
4355 dnl
4356 AC_ARG_ENABLE([libgcrypt],
4357   AS_HELP_STRING([--disable-libgcrypt], [gcrypt support (default enabled)]))
4358 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4359 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4360
4361 # require libgcrypt >= 1.6.0
4362 AS_IF([test "${enable_libgcrypt}" != "no"], [
4363   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4364     VLC_SAVE_FLAGS
4365     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4366     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4367 [#include <gcrypt.h>
4368 #if GCRYPT_VERSION_NUMBER < 0x010600
4369 #error
4370 #endif]])], [
4371       ac_cv_lib_gcrypt=yes
4372     ], [
4373       ac_cv_lib_gcrypt=no
4374     ])
4375     VLC_RESTORE_FLAGS
4376   ])
4377
4378   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4379     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4380   ], [
4381     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4382       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4383     ])
4384   ])
4385 ])
4386
4387 AS_IF([test -z "$GCRYPT_LIBS"], [
4388   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4389 ])
4390
4391 AC_SUBST([GCRYPT_CFLAGS])
4392 AC_SUBST([GCRYPT_LIBS])
4393 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4394
4395 dnl
4396 dnl TLS/SSL
4397 dnl
4398 AC_ARG_ENABLE([gnutls],
4399   AS_HELP_STRING([--enable-gnutls], [GNU TLS TLS/SSL support (default enabled)]))
4400 AS_IF([test "${enable_gnutls}" != "no"], [
4401   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.5.0], [
4402     VLC_ADD_PLUGIN([gnutls])
4403   ], [
4404     AS_IF([test -n "${enable_gnutls}"], [
4405       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4406     ])
4407   ])
4408 ])
4409
4410
4411 dnl
4412 dnl Taglib plugin
4413 dnl
4414 AC_ARG_ENABLE([taglib],
4415   AS_HELP_STRING([--disable-taglib],
4416     [do not use TagLib (default enabled)]))
4417 AS_IF([test "${enable_taglib}" != "no"], [
4418   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.11, [
4419     VLC_ADD_PLUGIN([taglib])
4420   ], [
4421     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4422 ])
4423
4424 dnl
4425 dnl  libsecret
4426 dnl
4427 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4428
4429 dnl
4430 dnl  kwallet
4431 dnl
4432 AC_ARG_ENABLE([kwallet],
4433   AS_HELP_STRING([--enable-kwallet],
4434     [use kwallet (via D-Bus) for keystore (default enabled)]))
4435 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4436   VLC_ADD_PLUGIN([kwallet])
4437 ])
4438
4439 dnl
4440 dnl update checking system
4441 dnl
4442 AC_ARG_ENABLE([update-check],
4443   AS_HELP_STRING([--enable-update-check], [update checking system (default disabled)]))
4444 if test "${enable_update_check}" = "yes"
4445 then
4446  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4447     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4448 fi
4449 AM_CONDITIONAL([UPDATE_CHECK], [test "${enable_update_check}" = "yes"])
4450
4451 dnl
4452 dnl OS X notification plugin
4453 dnl
4454 AC_ARG_ENABLE([osx_notifications],
4455   AS_HELP_STRING([--enable-osx-notifications],
4456     [macOS notification plugin (default disabled)]),,
4457   [enable_osx_notifications=no])
4458 AS_IF([test "${enable_osx_notifications}" != "no"], [
4459   VLC_ADD_PLUGIN([osx_notifications])
4460 ])
4461
4462 dnl
4463 dnl Libnotify notification plugin
4464 dnl
4465 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify], [libnotify notification], [auto])
4466
4467 PKG_ENABLE_MODULES_VLC([MEDIALIBRARY], [medialibrary], [medialibrary >= 0.9.0], (medialibrary support), [auto])
4468
4469 dnl
4470 dnl  Endianness check
4471 dnl
4472 AC_C_BIGENDIAN
4473 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4474   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4475 ], [
4476   DEFS_BIGENDIAN=""
4477 ])
4478 AC_SUBST([DEFS_BIGENDIAN])
4479
4480 dnl
4481 dnl Where to install KDE solid .desktop
4482 dnl
4483 AC_ARG_WITH(kde-solid,
4484   AS_HELP_STRING([--with-kde-solid=PATH],
4485                  [KDE Solid actions directory (auto)]),, [
4486
4487 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${HAVE_ANDROID}" != "1" ; then
4488   with_kde_solid="yes"
4489 fi
4490 ])
4491 soliddatadir=""
4492 AS_IF([test "${with_kde_solid}" != "no"], [
4493   AS_IF([test "${with_kde_solid}" = "yes"], [
4494     kde4datadir="`${KDE4_CONFIG} --install data`"
4495     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4496     soliddatadir="${kde4datadir}/solid/actions"
4497   ], [
4498     soliddatadir="${with_kde_solid}"
4499   ])
4500 ])