dbus fixes
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 2002-2011 the VideoLAN team])
4
5 AC_INIT(vlc, 1.2.0-git)
6 VERSION_MAJOR="1"
7 VERSION_MINOR="2"
8 VERSION_REVISION="0"
9 VERSION_EXTRA="-git"
10 PKGDIR="vlc"
11 AC_SUBST(PKGDIR)
12
13 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
14 CODENAME="Twoflower"
15 COPYRIGHT_YEARS="1996-2011"
16
17 AC_CONFIG_SRCDIR(src/libvlc.c)
18 AC_CONFIG_AUX_DIR(autotools)
19 AC_CONFIG_MACRO_DIR(m4)
20 AC_CONFIG_LIBOBJ_DIR(compat)
21 AC_CANONICAL_BUILD
22 AC_CANONICAL_HOST
23 AC_PRESERVE_HELP_ORDER
24
25 AM_INIT_AUTOMAKE(tar-ustar color-tests)
26 AM_CONFIG_HEADER(config.h)
27
28 # Disable with "./configure --disable-silent-rules" or "make V=1"
29 AM_SILENT_RULES([yes])
30
31 dnl Too many people are not aware of maintainer mode:
32 dnl If you want to use it, you definitely know what you are doing, so
33 dnl you can specify "--disable-maintainer-mode". But if you want the default
34 dnl automake behavior, you've likely never heard of maintainer mode, so we
35 dnl can't expect you to enable it manually.
36 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
37     [enable_maintainer_mode="yes"])
38 AM_MAINTAINER_MODE
39
40 dnl
41 dnl Directories
42 dnl
43 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
44 dnl AC_SUBST(vlcincludedir)
45 vlcdatadir="\${datadir}/\${PKGDIR}"
46 AC_SUBST(vlcdatadir)
47 vlclibdir="\${libdir}/\${PKGDIR}"
48 AC_SUBST(vlclibdir)
49
50 dnl
51 dnl  Save *FLAGS
52 dnl
53 VLC_SAVE_FLAGS
54
55 dnl
56 dnl Check for tools
57 dnl
58 AC_PROG_CC_C99
59 AC_USE_SYSTEM_EXTENSIONS
60 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
61 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
62 AC_DEFINE([_REENTRANT],, [Define to expose reentrant functions.])
63 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
64 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
65
66 AM_PROG_CC_C_O
67 AC_PROG_CXX
68 AC_PROG_CPP
69 AC_PROG_OBJC
70 _AM_DEPENDENCIES([OBJC])
71 AC_PROG_EGREP
72 AC_PROG_MAKE_SET
73 AC_PROG_INSTALL
74 AM_PROG_AS
75
76 dnl Find the right ranlib, even when cross-compiling
77 AC_CHECK_TOOL(RANLIB, ranlib, :)
78 AC_CHECK_TOOL(STRIP, strip, :)
79 AC_CHECK_TOOL(AR, ar, :)
80 AC_CHECK_TOOL(LD, ld, :)
81 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
82
83 dnl Check for compiler properties
84 AC_C_CONST
85 AC_C_INLINE
86 AC_C_RESTRICT
87
88 dnl Extend the --help string at the current spot.
89 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
90
91 dnl Allow binary package maintainer to pass a custom string to avoid
92 dnl cache problem
93 AC_ARG_WITH(binary-version,
94     AS_HELP_STRING([--with-binary-version=STRING],
95          [To avoid plugins cache problem between binary version]),[],[])
96 AS_IF([test -n "${with_binary_version}"],[
97     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
98          [Binary specific version])
99 ])
100
101 dnl
102 dnl  Check for the contrib directory
103 dnl
104 AC_ARG_WITH(contrib,
105   [AS_HELP_STRING([--without-contrib],
106     [do not use the libraries in CONTRIB_DIR])])
107 AC_ARG_VAR([CONTRIB_DIR], [directory containing pre-built contrib, overriding extras/contrib])
108 AS_IF([test "${with_contrib}" != "no"],[
109   AS_IF([test -z "$CONTRIB_DIR"], [
110       topdir="`dirname $0`"
111       if test "`echo \"$topdir\" | cut -c 1`" != "/"; then
112          topdir="`pwd`/$topdir"
113       fi
114       CONTRIB_DIR="${topdir}/extras/contrib/hosts/${host}"
115       if ! test -d "$CONTRIB_DIR"
116       then
117         gccmachine=`$CC -dumpmachine`
118         CONTRIB_DIR="${topdir}/extras/contrib/hosts/${gccmachine}"
119       fi
120   ])
121   AC_MSG_CHECKING([for libs in ${CONTRIB_DIR}])
122   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
123     AC_MSG_RESULT([yes])
124     AC_SUBST(CONTRIB_DIR)
125     export PATH=${CONTRIB_DIR}/bin:$PATH
126     CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
127     CPPFLAGS_save="${CPPFLAGS_save} -I${CONTRIB_DIR}/include"
128     CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
129     CFLAGS_save="${CFLAGS_save} -I${CONTRIB_DIR}/include"
130     CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
131     CXXFLAGS_save="${CXXFLAGS_save} -I${CONTRIB_DIR}/include"
132     OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
133     OBJCFLAGS_save="${OBJCFLAGS_save} -I${CONTRIB_DIR}/include"
134     if test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"; then
135         export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
136     else
137         export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
138     fi
139     LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
140     LDFLAGS_save="${LDFLAGS_save} -L${CONTRIB_DIR}/lib"
141
142     if test "${SYS}" = "darwin"; then
143       export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
144       export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
145     fi
146   ],[
147     AC_MSG_RESULT([no])
148     CONTRIB_DIR=""
149   ])
150 ])
151
152 dnl
153 dnl  Set default values
154 dnl
155 LDFLAGS_vlc="${LDFLAGS}"
156
157 dnl
158 dnl  Check the operating system
159 dnl
160 HAVE_WIN64="0"
161 case "${host_os}" in
162   "")
163     SYS=unknown
164     ;;
165   linux*)
166     SYS=linux
167     ;;
168   bsdi*)
169     SYS=bsdi
170     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
171     VLC_ADD_LIBS([vcd cdda vcdx],[-ldvd])
172     ;;
173   *bsd*)
174     SYS="${host_os}"
175     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
176     case "${host_os}" in
177       freebsd*)
178         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include"
179         CPPFLAGS="${CPPFLAGS_save}"
180         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib"
181         LDFLAGS="${LDFLAGS_save}"
182         ;;
183       openbsd*)
184         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include -I/usr/X11R6/include"
185         CPPFLAGS="${CPPFLAGS_save}"
186         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib -L/usr/X11R6/lib/"
187         LDFLAGS="${LDFLAGS_save}"
188         ;;
189     esac
190     ;;
191   darwin*)
192
193     dnl Force gcc "-arch" flag
194     ARCH_flag=""
195     case "${host}" in
196       i386*)
197         ARCH_flag="-arch i386"
198       ;;
199       ppc64*)
200         ARCH_flag="-arch ppc64"
201       ;;
202       ppc*)
203         ARCH_flag="-arch ppc"
204       ;;
205       x86_64*)
206         ARCH_flag="-arch x86_64"
207       ;;
208     esac
209
210     SYS=darwin
211     CFLAGS_save="${CFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CFLAGS="${CFLAGS_save}"
212     CXXFLAGS_save="${CXXFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CXXFLAGS="${CXXFLAGS_save}"
213     CPPFLAGS_save="${CPPFLAGS_save} ${ARCH_flag}"; CPPFLAGS="${CPPFLAGS_save}"
214     OBJCFLAGS_save="${OBJCFLAGS_save} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"; OBJCFLAGS="${OBJCFLAGS_save}"
215     LDFLAGS_save="${LDFLAGS_save} -Wl,-headerpad_max_install_names ${ARCH_flag}"; LDFLAGS="${LDFLAGS_save}"
216     VLC_ADD_LDFLAGS([mkv mp4 motion], [-Wl,-framework,IOKit,-framework,CoreFoundation])
217     VLC_ADD_LDFLAGS([libvlc vlc],[-Wl,-undefined,dynamic_lookup])
218     VLC_ADD_LDFLAGS([avcodec avformat access_avio swscale postproc i420_rgb_mmx x264],[-Wl,-read_only_relocs,suppress])
219     VLC_ADD_CFLAGS([motion],[-fconstant-cfstrings])
220     VLC_ADD_LDFLAGS([libvlccore],[-Wl,-framework,CoreFoundation])
221     AC_ARG_ENABLE(macosx-defaults,
222       AS_HELP_STRING([--enable-macosx-defaults],[Build the default configuration on Mac OS X (default enabled)]))
223     if test "x${enable_macosx_defaults}" != "xno"
224     then
225         echo ""
226         echo "Building with Mac OS X defaults:"
227         build_dir=`pwd`
228         echo "  Assuming --prefix=${build_dir}/vlc_install_dir"
229         ac_default_prefix="${build_dir}/vlc_install_dir"
230         enable_faad="yes"
231         echo "  Assuming --enable-faad"
232         enable_flac="yes"
233         echo "  Assuming --enable-flac"
234         enable_theora="yes"
235         echo "  Assuming --enable-theora"
236         enable_shout="yes"
237         echo "  Assuming --enable-shout"
238         enable_vcdx="yes"
239         echo "  Assuming --enable-vcdx"
240         enable_caca="yes"
241         echo "  Assuming --enable-caca"
242         enable_ncurses="yes"
243         echo "  Assuming --enable-ncurses"
244         enable_twolame="yes"
245         echo "  Assuming --enable-twolame"
246         enable_realrtsp="yes"
247         echo "  Assuming --enable-realrtsp"
248         enable_libass="yes"
249         echo "  Assuming --enable-libass"
250
251         enable_skins2="no"
252         echo "  Assuming --disable-skins2"
253         enable_xcb="no"
254         echo "  Assuming --disable-xcb"
255     fi
256     dnl
257     dnl  Check for Mac OS X SDK settings
258     dnl
259     AC_ARG_WITH(macosx-sdk,
260       [AS_HELP_STRING([--with-macosx-sdk=DIR],
261         [compile using the SDK in DIR])])
262     if test "${with_macosx_sdk}" != "" ; then
263         CPP="${CPP} -isysroot ${with_macosx_sdk}"
264         CC="${CC} -isysroot ${with_macosx_sdk}"
265         CXX="${CXX} -isysroot ${with_macosx_sdk}"
266         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
267         LD="${LD} -syslibroot ${with_macosx_sdk}"
268     else
269         echo "  No desired SDK version given, falling back to 10.5"
270         CPP="${CPP} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
271         CC="${CC} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
272         CXX="${CXX} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
273         OBJC="${OBJC} -isysroot /Developer/SDKs/MacOSX10.5.sdk"
274         LD="${LD} -syslibroot /Developer/SDKs/MacOSX10.5.sdk"
275         with_macosx_version_min="10.5"
276         echo "  Assuming --with-macosx-version-min=10.5"
277     fi
278     AC_ARG_WITH(macosx-version-min,
279       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
280         [compile for MacOS X VERSION and above])])
281     if test "${with_macosx_version_min}" != "" ; then
282         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
283         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
284         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
285         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
286         LD="${LD} -macosx_version_min=${with_macosx_version_min}"
287         CFLAGS_save="${CFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CFLAGS="${CFLAGS_save}"
288         CXXFLAGS_save="${CXXFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CXXFLAGS="${CXXFLAGS_save}"
289         OBJCFLAGS_save="${OBJCFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; OBJCFLAGS="${OBJCFLAGS_save}"
290         MACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}
291         export MACOSX_DEPLOYMENT_TARGET
292     fi
293     ;;
294   *mingw32* | *cygwin* | *wince* | *mingwce*)
295     AC_CHECK_TOOL(WINDRES, windres, :)
296     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
297
298     case "${host_os}" in
299       *wince* | *mingwce* | *mingw32ce*)
300         SYS=mingwce
301         dnl Sadly CeGCC still needs non-wince macros
302         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0500' for Windows 2000 APIs.])
303         ;;
304       *mingw32*)
305         SYS=mingw32
306         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0500' for Windows XP APIs.])
307         ;;
308       *cygwin*)
309         dnl Check if we are using the mno-cygwin mode in which case we are
310         dnl actually dealing with a mingw32 compiler.
311         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0501' for Windows XP APIs.])
312         AC_EGREP_CPP(yes,
313             [#ifdef WIN32
314              yes
315              #endif],
316             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
317         ;;
318     esac
319
320     if test "${SYS}" = "mingw32"; then
321         # add ws2_32 for closesocket, select, recv
322         VLC_ADD_LIBS([libvlccore],[-lws2_32 -lnetapi32 -lwinmm])
323         VLC_ADD_LDFLAGS([vlc],[-mwindows])
324         VLC_ADD_LIBS([win32text],[-lgdi32])
325         VLC_ADD_LIBS([cdda vcdx sdl_image aout_sdl vout_sdl],[-lwinmm])
326         VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_shout access_output_rtmp sap stream_out_standard stream_out_select stream_out_rtp stream_out_raop vod_rtsp access_realrtsp rtp oldrc netsync gnutls growl_udp flac ts audioscrobbler lua remoteosd zvbi audiobargraph_a netsync],[-lws2_32])
327         VLC_ADD_LIBS([filesystem], [-lshlwapi])
328         dnl
329         dnl DEP and ASLR options
330         dnl
331         AC_ARG_WITH(peflags,
332           [AS_HELP_STRING([--with-peflags],
333             [use peflags (default enabled on Windows)])])
334         if test "${with_peflags}" != "no" ; then
335           AC_PATH_TOOL(PEFLAGS, peflags, :)
336         fi
337         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
338         ac_default_prefix="`pwd`/_win32"
339         DESTDIR="`pwd`/_win32/"
340
341         dnl
342         dnl NSIS Installer prefix and WIN64
343         dnl
344         case "${host}" in
345             amd64*|i686-w64*|x86_64*)
346                 HAVE_WIN64="1"
347                 PROGRAMFILES="PROGRAMFILES64"
348             ;;
349             *)
350                 PROGRAMFILES="PROGRAMFILES"
351             ;;
352         esac
353         AC_SUBST(PROGRAMFILES)
354
355     fi
356     if test "${SYS}" = "mingwce"; then
357         # add ws2 for closesocket, select, recv
358         VLC_ADD_LIBS([libvlccore access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_rtmp sap netsync audioscrobbler growl rtp stream_out_standard stream_out_select stream_out_rtp remoteosd ts audiobargraph_a netsync],[-lws2])
359         VLC_ADD_LIBS([libvlccore],[-lmmtimer])
360         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
361         ac_default_prefix="`pwd`/_wince"
362         DESTDIR="`pwd`/_wince/"
363     fi
364     ;;
365   *nto*)
366     SYS=nto
367     ;;
368   solaris*)
369     SYS=solaris
370     ;;
371   hpux*)
372     SYS=hpux
373     ;;
374   symbian*)
375     SYS=symbian
376     ;;
377   *os2*)
378     SYS=os2
379     LDFLAGS_save="${LDFLAGS_save} -Zomf -Zbin-files -Zargs-wild"; LDFLAGS="${LDFLAGS_save}"
380     ;;
381   *)
382     SYS="${host_os}"
383     ;;
384 esac
385 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
386 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
387 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
388 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
389 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
390 AM_CONDITIONAL(HAVE_WINCE,   test "${SYS}" = "mingwce")
391 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
392 AM_CONDITIONAL(USE_PEFLAGS,  test "${with_peflags}" = "yes")
393
394 dnl
395 dnl Sadly autoconf doesn't think about testing foo.exe when ask to test
396 dnl for program foo on win32
397
398 case "${build_os}" in
399     cygwin|msys)
400         ac_executable_extensions=".exe"
401     ;;
402     *)
403     ;;
404 esac
405
406 dnl
407 dnl  Libtool
408 dnl  It's very bad, but our former custom system was worst
409 dnl  -- Courmisch
410 dnl
411
412 dnl override platform specific check for dependent libraries
413 dnl otherwise libtool linking of shared libraries will
414 dnl fail on anything other than pass_all.
415 AC_CACHE_VAL(lt_cv_deplibs_check_method,
416     [lt_cv_deplibs_check_method=pass_all])
417
418 AC_DISABLE_STATIC
419 dnl AC_DISABLE_FAST_INSTALL
420 AC_LIBTOOL_DLOPEN
421 AC_LIBTOOL_WIN32_DLL
422 m4_undefine([AC_PROG_F77])
423 m4_defun([AC_PROG_F77],[])
424 AC_PROG_LIBTOOL
425
426 m4_undefine([AC_DEPLIBS_CHECK_METHOD])
427 m4_defun([AC_DEPLIBS_CHECK_METHOD],[])
428
429 lt_cv_deplibs_check_method=pass_all
430
431 AS_IF([test "${enable_shared}" = "no"], [
432   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
433 ])
434
435 dnl
436 dnl Gettext stuff
437 dnl
438 AM_GNU_GETTEXT_VERSION([0.18.1])
439 AM_GNU_GETTEXT([external])
440 VLC_ADD_LIBS([libvlccore vlc], [${LTLIBINTL}])
441
442 dnl
443 dnl Iconv stuff
444 dnl
445 AM_ICONV
446 VLC_ADD_CFLAGS([libvlccore],[${INCICONV}])
447 VLC_ADD_LIBS([libvlccore],[${LTLIBICONV}])
448
449 dnl Check for broken versions of mingw-runtime compatability library
450 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
451     AC_MSG_CHECKING(for broken mingw-runtime)
452     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
453 #include <_mingw.h>
454 #if (__MINGW32_MAJOR_VERSION == 3) && (__MINGW32_MINOR_VERSION < 15)
455 #ifndef __MINGW64_VERSION_MAJOR
456 # error Attempting to use mingw-runtime with broken vsnprintf support
457 #endif
458 #endif
459     ])], [
460         AC_MSG_RESULT([ok])
461     ], [
462         AC_MSG_RESULT([present])
463         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher!])
464     ])
465     dnl force use of mingw provided c99 *printf over msvcrt
466     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
467     CPPFLAGS_save="${CPPFLAGS_save} -D__USE_MINGW_ANSI_STDIO=1"
468 ])
469
470 dnl Check for the need to include the mingwex lib for mingw32
471 if test "${SYS}" = "mingw32" ; then
472     AC_CHECK_LIB(mingwex,opendir,
473         AC_CHECK_LIB(mingw32,opendir,,
474             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
475     )
476 fi
477
478 dnl Check for fnative-struct or mms-bitfields support for mingw32
479 if test "${SYS}" = "mingw32" ; then
480     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
481         [ac_cv_c_mms_bitfields],
482         [CFLAGS="${CFLAGS_save} -mms-bitfields"
483          AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
484     if test "${ac_cv_c_mms_bitfields}" != "no"; then
485         CFLAGS_save="${CFLAGS_save} -mms-bitfields";
486         CXXFLAGS_save="${CXXFLAGS_save} -mms-bitfields";
487     else
488         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
489             [ac_cv_c_fnative_struct],
490             [CFLAGS="${CFLAGS_save} -fnative-struct"
491              AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
492         if test "${ac_cv_c_fnative_struct}" != "no"; then
493             CFLAGS_save="${CFLAGS_save} -fnative-struct";
494             CXXFLAGS_save="${CXXFLAGS_save} -fnative-struct";
495         fi
496     fi
497
498     CFLAGS="${CFLAGS_save}"; CXXFLAGS="${CXXFLAGS_save}"
499 fi
500
501 dnl Check for fvtable-thunks support for mingw32
502 if test "${SYS}" = "mingw32" -a "${CXX}" != "" ; then
503     AC_LANG_PUSH(C++)
504     AC_CACHE_CHECK([if \$CXX accepts -fvtable-thunks],
505         [ac_cv_cxx_fvtable_thunks],
506         [CXXFLAGS="${CXXFLAGS_save} -Wall -Werror -fvtable-thunks"
507          AC_TRY_COMPILE([],,ac_cv_cxx_fvtable_thunks=yes,
508                         ac_cv_cxx_fvtable_thunks=no)])
509     if test "${ac_cv_cxx_fvtable_thunks}" = "yes"; then
510         CXXFLAGS_mingw32_special="-fvtable-thunks"
511     fi
512
513     CXXFLAGS_save="${CXXFLAGS_save} ${CXXFLAGS_mingw32_special}"; CXXFLAGS="${CXXFLAGS_save}"
514     AC_LANG_POP(C++)
515 fi
516
517 dnl
518 dnl Buggy glibc prevention. Purposedly not cached.
519 dnl See sourceware.org bugs 5058 and 5443.
520 dnl Ubuntu alone has 20 bug numbers for this...
521 dnl
522 AC_MSG_CHECKING(for buggy GNU/libc versions)
523 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
524 #include <limits.h>
525 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
526   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
527 # error GNU/libc with dcgettext killer bug!
528 #endif
529 ])], [
530   AC_MSG_RESULT([not present])
531 ], [
532   AC_MSG_RESULT([found])
533   AS_IF([test "x${enable_nls}" != "xno"], [
534     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
535 work-around for this. Check with your distribution vendor on how to update the
536 glibc run-time. Alternatively, build with --disable-nls.])
537   ], [
538     AC_DEFINE(DISABLE_BUGGY_GLIBC_CHECK, 1, [Disables runtime check for buggy glibc.])
539   ])
540 ])
541
542 dnl Plugin compilation stuff
543
544 VLC_LIBRARY_SUFFIX
545
546 dnl The -DSYS_FOO flag
547 CPPFLAGS_save="${CPPFLAGS_save} -DSYS_`echo ${SYS} | sed -e 's/-.*//' | tr 'abcdefghijklmnopqrstuvwxyz.' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`"; CPPFLAGS="${CPPFLAGS_save}"
548
549 dnl Check for system libs needed
550 need_libc=false
551
552 dnl Check for usual libc functions
553 AC_CHECK_FUNCS([daemon fcntl fdopendir fstatvfs fork getenv getpwuid_r gettimeofday isatty lstat memalign mmap openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp uselocale])
554 AC_REPLACE_FUNCS([asprintf atof atoll dirfd flockfile getcwd getdelim getpid gmtime_r lldiv localtime_r nrand48 rewind setenv strcasecmp strcasestr strdup strlcpy strncasecmp strndup strnlen strsep strtof strtok_r strtoll swab tdestroy vasprintf])
555 AC_CHECK_FUNCS(fdatasync,,
556   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
557 ])
558
559 # Windows CE doesn't have strcoll()
560 AC_FUNC_STRCOLL
561
562 dnl Check for non-standard system calls
563 AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
564
565 AH_BOTTOM([#include <vlc_fixups.h>])
566
567 SOCKET_LIBS=""
568 AC_CHECK_FUNCS(connect,,[
569   AC_CHECK_LIB(socket,connect,[
570     VLC_ADD_LIBS([libvlccore cdda],-lsocket)
571     SOCKET_LIBS="-lsocket"
572   ])
573 ])
574 AC_SUBST(SOCKET_LIBS)
575
576 AC_CHECK_FUNCS(send,,[
577   AC_CHECK_LIB(socket,send,[
578     VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp sap access_output_udp access_output_rtmp stream_out_standard growl_udp remoteosd netsync],[-lsocket])
579   ])
580 ])
581
582
583 dnl Check for socklen_t
584 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
585 AC_CACHE_CHECK([for socklen_t in sys/socket.h],
586 ac_cv_type_socklen_t,
587 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
588 [#include <sys/types.h>
589 #ifdef WIN32
590 # include <winsock2.h>
591 # include <ws2tcpip.h>
592 #else
593 # include <sys/socket.h>
594 #endif]], [[socklen_t len; len = 0;]])],
595 ac_cv_type_socklen_t=yes,
596 ac_cv_type_socklen_t=no)])
597 AS_IF([test "$ac_cv_type_socklen_t" = no],
598  [AC_DEFINE(socklen_t, int)])
599
600 dnl Check for struct sockaddr_storage
601 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.])
602 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.])
603 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
604   [AC_TRY_COMPILE(
605     [#include <sys/types.h>
606      #if defined( UNDER_CE )
607      # include <winsock2.h>
608      #elif defined( WIN32 )
609      # include <winsock2.h>
610      #else
611      # include <sys/socket.h>
612      #endif], [struct sockaddr_storage addr;],
613      ac_cv_struct_sockaddr_storage=yes,
614      ac_cv_struct_sockaddr_storage=no)])
615 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
616   AC_DEFINE(sockaddr_storage, sockaddr)
617   AC_DEFINE(ss_family, sa_family)
618 ])
619
620 dnl getaddrinfo, getnameinfo and gai_strerror check
621 dnl  -lnsl and -lsocket are needed on Solaris;
622 dnl  we purposedly make the test fail on Windows
623 LIBS_save="${LIBS}"
624 AC_SEARCH_LIBS([getaddrinfo], [nsl],,, [${SOCKET_LIBS}])
625 LIBS="${LIBS_save}"
626
627 dnl Check for va_copy
628 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
629   AC_TRY_LINK(
630     [#include <stdarg.h>],
631     [va_list ap1, ap2; va_copy(ap1,ap2);],
632     [ac_cv_c_va_copy="yes"],
633     [ac_cv_c_va_copy="no"]))
634 if test "${ac_cv_c_va_copy}" = "yes"; then
635   AC_DEFINE(HAVE_VA_COPY, 1, [Define if <stdarg.h> defines va_copy.])
636 fi
637 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
638   AC_TRY_LINK(
639     [#include <stdarg.h>],
640     [va_list ap1, ap2; __va_copy(ap1,ap2);],
641     [ac_cv_c___va_copy="yes"],
642     [ac_cv_c___va_copy="no"]))
643 if test "${ac_cv_c___va_copy}" = "yes"; then
644   AC_DEFINE(HAVE___VA_COPY, 1, [Define if <stdarg.h> defines __va_copy.])
645 fi
646
647 AC_CHECK_FUNCS(inet_aton,,[
648   AC_CHECK_LIB(resolv,inet_aton,[
649     VLC_ADD_LIBS([libvlccore],[-lresolv])
650   ])
651 ])
652
653 dnl FreeBSD has a gnugetopt library for this:
654 GNUGETOPT_LIBS=""
655 AC_CHECK_FUNC(getopt_long,, [
656   AC_CHECK_LIB([gnugetopt],[getopt_long], [
657     GNUGETOPT_LIBS="-lgnugetopt"
658   ])
659 ])
660 AC_SUBST(GNUGETOPT_LIBS)
661
662 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
663 AC_CHECK_LIB(m,cos,[
664   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom visual panoramix rotate noise grain scene kate flac lua chorus_flanger],[-lm])
665 ])
666 AC_CHECK_LIB(m,pow,[
667   VLC_ADD_LIBS([avcodec avformat access_avio swscale postproc i420_rgb faad twolame equalizer spatializer param_eq libvlccore freetype mod mpc dmo quicktime realvideo qt4],[-lm])
668 ])
669 AC_CHECK_LIB(m,sqrt,[
670   VLC_ADD_LIBS([compressor headphone_channel_mixer normvol audiobargraph_a speex mono colorthres extract ball],[-lm])
671 ])
672 AC_CHECK_LIB(m,ceil,[
673   VLC_ADD_LIBS([access_imem hotkeys mosaic],[-lm])
674 ])
675 AC_CHECK_LIB(m,exp,[
676   VLC_ADD_LIBS([gaussianblur],[-lm])
677 ])
678 AC_CHECK_LIB(m,round,[
679   VLC_ADD_LIBS([dbus],[-lm])
680 ])
681 AC_CHECK_LIB(m,sqrtf,[
682   VLC_ADD_LIBS([x264],[-lm])
683 ])
684 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
685
686 AC_CHECK_LIB(m,lrintf, [
687   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
688   VLC_ADD_LIBS([skins2],[-lm])
689 ])
690
691 dnl Check for dynamic plugins
692 ac_cv_have_plugins=no
693
694 # Win32 style
695 if test "${ac_cv_have_plugins}" = "no"; then
696   if test "${SYS}" = "mingw32" ; then
697     AC_CHECK_LIB(kernel32, main,
698      [VLC_ADD_LIBS([libvlccore],[-lkernel32])
699       AC_DEFINE(HAVE_DL_WINDOWS, 1, [Define if you have Windows' LoadLibrary])
700       ac_cv_have_plugins=yes])
701   fi
702 fi
703
704 # WinCE style
705 if test "${ac_cv_have_plugins}" = "no"; then
706   if test "${SYS}" = "mingwce"; then
707     AC_DEFINE(HAVE_DL_WINDOWS, 1, [Define if you have Windows' LoadLibrary])
708     ac_cv_have_plugins=yes
709   fi
710 fi
711
712 # Only test for dlopen() if the others didn't work
713 LIBDL=""
714 if test "${ac_cv_have_plugins}" = "no" -o "${SYS}" = "darwin"; then
715   AC_CHECK_HEADERS(dlfcn.h sys/dl.h)
716   ac_cv_my_have_dlopen=no
717   AC_CHECK_FUNC(dlopen, [
718     ac_cv_my_have_dlopen=yes
719   ], [
720     AC_CHECK_LIB(dl, dlopen, [
721       ac_cv_my_have_dlopen=yes
722       LIBDL="-ldl"
723     ], [
724       AC_CHECK_LIB(svld, dlopen, [
725         ac_cv_my_have_dlopen=yes
726         LIBDL="-lsvld"
727       ])
728     ])
729   ])
730   if test "${ac_cv_my_have_dlopen}" = "yes"; then
731     AC_DEFINE(HAVE_DL_DLOPEN, 1, [Define if you have the dlopen API])
732     ac_cv_have_plugins=yes
733     VLC_ADD_LIBS([libvlccore realvideo lua],[$LIBDL])
734   fi
735 fi
736 AC_SUBST(LIBDL)
737
738 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
739   dnl Check for pthreads - borrowed from XMMS
740   THREAD_LIB=error
741   if test "${THREAD_LIB}" = "error"; then
742     AC_CHECK_LIB(pthread,main,THREAD_LIB="-lpthread")
743   fi
744   if test "${THREAD_LIB}" = "error"; then
745     AC_CHECK_LIB(pthreads,main,THREAD_LIB="-lpthreads")
746   fi
747   if test "${THREAD_LIB}" = "error"; then
748     AC_CHECK_LIB(c_r,main,THREAD_LIB="-lc_r")
749   fi
750   if test "${THREAD_LIB}" = "error"; then
751     AC_CHECK_FUNCS(pthread_mutex_lock)
752     THREAD_LIB=""
753   fi
754
755   VLC_ADD_LIBS([libvlccore libvlc vlc plugin],[${THREAD_LIB}])
756
757   AC_CHECK_LIB(rt, clock_nanosleep, [
758     VLC_ADD_LIBS([libvlccore],[-lrt])
759     AC_DEFINE(HAVE_CLOCK_NANOSLEEP, 1, [Define to 1 if you have clock_nanosleep.])
760   ], [
761     dnl HP/UX port
762     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
763   ])
764
765   have_nanosleep=false
766   AC_CHECK_FUNCS(nanosleep,have_nanosleep=:,[
767     AC_CHECK_LIB(rt,nanosleep,
768       [VLC_ADD_LIBS([libvlccore],[-lrt]) have_nanosleep=:],
769       [AC_CHECK_LIB(posix4,nanosleep,
770           [VLC_ADD_LIBS([libvlccore],[-lposix4]) have_nanosleep=:])]
771     )
772   ])
773   if ${have_nanosleep}; then
774     AC_DEFINE(HAVE_NANOSLEEP, 1, [Define if nanosleep is available.])
775   fi
776 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
777
778 dnl Check for misc headers
779 AC_MSG_CHECKING(for strncasecmp in strings.h)
780 AC_EGREP_HEADER(strncasecmp,strings.h,[
781   AC_MSG_RESULT(yes)
782   AC_DEFINE(STRNCASECMP_IN_STRINGS_H, 1,
783             Define if <strings.h> defines strncasecmp.)],[
784   AC_MSG_RESULT(no)])
785
786 dnl Check for headers
787 AC_CHECK_HEADERS([search.h])
788 AC_CHECK_HEADERS(getopt.h strings.h locale.h xlocale.h)
789 AC_CHECK_HEADERS(fcntl.h sys/time.h sys/ioctl.h sys/stat.h)
790 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h netinet/udplite.h sys/eventfd.h])
791 AC_CHECK_HEADERS([net/if.h], [], [],
792   [
793     #include <sys/types.h>
794     #include <sys/socket.h>
795   ])
796 AC_CHECK_HEADERS([sys/mount.h], [], [],
797   [
798     #include <sys/param.h>
799   ])
800
801 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
802   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
803   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
804   AC_CHECK_HEADERS(syslog.h)
805 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
806
807 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
808 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.])
809 AC_CHECK_TYPE(ssize_t,, [
810   AC_DEFINE(ssize_t, int)
811 ])
812
813 dnl Check for poll
814 AC_SEARCH_LIBS(poll, [poll], [AC_DEFINE(HAVE_POLL, 1, [Define to 1 if the OS is usabl... err, has poll().])], [
815 if test ${SYS} != "mingw32" -a ${SYS} != "mingwce"
816 then
817     AC_MSG_WARN([Your platform does not support poll(). VLC has it's own poll() implementation, but it is only intended to be used on Windows. VLC might crash or be insecure when you see this message. Either switch to an OS with a proper poll() implementation, or implement one for your OS in VLC])
818 fi
819 ])
820
821 dnl Mac OS X and other OSes don't have declaration for nanosleep
822 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
823   AC_MSG_CHECKING(for nanosleep in time.h)
824   AC_EGREP_HEADER(nanosleep,time.h,[
825     AC_MSG_RESULT(yes)
826     AC_DEFINE(HAVE_DECL_NANOSLEEP, 1,
827               Define if <time.h> defines nanosleep.)
828   ],[
829     AC_MSG_RESULT(no)
830   ])
831 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
832
833 dnl Make sure we have timespecs
834 AC_MSG_CHECKING(for timespec in sys/time.h)
835 AC_EGREP_HEADER(timespec,sys/time.h,[
836   AC_MSG_RESULT(yes)
837   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
838             Define if <sys/time.h> defines struct timespec.)
839 ],[
840   AC_MSG_RESULT(no)
841 ])
842
843 dnl Check for threads library
844 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
845   AC_CHECK_HEADERS(pthread.h)
846 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
847
848 dnl It seems that autoconf detects pkg-config only during the first
849 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
850 dnl it is nested within a conditional block, so it was not working right.
851 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
852 AC_ARG_VAR(PKG_CONFIG_PATH,
853        [Paths where to find .pc not at the default location])
854 PKG_PROG_PKG_CONFIG()
855
856 dnl On some OS we need static linking 
857 AS_IF([test -n "${PKG_CONFIG}" ],[
858     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce" -o "${SYS}" = "darwin" ],[
859         PKG_CONFIG="${PKG_CONFIG} --static"
860     ])
861 ])
862
863
864 dnl
865 dnl Check for zlib.h and -lz along with system -lminizip if available
866 dnl
867 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
868 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
869 if test "${have_zlib}" = "yes"
870 then
871   VLC_ADD_LIBS([access_http mp4 skins2 sap mkv unzip zip],[-lz])
872   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
873     AC_CHECK_HEADERS([unzip.h], [ 
874       have_minizip=yes
875       MINIZIP_LIBS="-lminizip -lz"
876     ], [
877       have_minizip=no
878       MINIZIP_CFLAGS="-I\\\${top_srcdir}/libs/unzip"
879       MINIZIP_LIBS="\\\${top_builddir}/libs/unzip/libunzip.la"
880     ])
881   ])
882   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
883   VLC_ADD_CFLAGS([zip],[$MINIZIP_CFLAGS])
884   VLC_ADD_LIBS([skins2 zip],[$MINIZIP_LIBS])
885   VLC_ADD_PLUGIN([unzip zip])
886 fi
887 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
888
889
890 dnl Manual switch for UTF-8
891 AC_ARG_ENABLE(non-utf8,
892   [AS_HELP_STRING([--enable-non-utf8],
893     [support legacy non-UTF-8 systems (default disabled)])],, [
894   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
895     enable_non_utf8="no"
896   ])
897 ])
898 AS_IF([test "${enable_non_utf8}" != "no"], [
899   AC_DEFINE([ASSUME_UTF8], [1],
900             [Define to 1 if the operating system uses UTF-8 internally])
901 ])
902
903
904 dnl Check for dbus
905 AC_ARG_ENABLE(dbus,
906   [AS_HELP_STRING([--enable-dbus],
907     [compile D-Bus message bus support (default enabled)])])
908 case "${SYS}" in
909     linux*|*bsd*)
910 if test "${enable_dbus}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
911 then
912   dnl api stable dbus
913   PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0.0,
914     [ AC_DEFINE( HAVE_DBUS, 1, [Define if you have the D-BUS library] )
915       VLC_ADD_LIBS([libvlccore],[$DBUS_LIBS])
916       VLC_ADD_CFLAGS([libvlccore],[$DBUS_CFLAGS])
917       dnl Check for dbus control interface
918         AC_ARG_ENABLE(dbus-control,
919           [AS_HELP_STRING([--disable-dbus-control],
920             [D-Bus control interface (default enabled)])])
921         if test "${enable_dbus_control}" != "no"
922         then
923           VLC_ADD_PLUGIN([dbus])
924           VLC_ADD_LIBS([dbus],[$DBUS_LIBS])
925           VLC_ADD_CFLAGS([dbus],[$DBUS_CFLAGS])
926         fi
927       dnl Check for Telepathy
928         AC_ARG_ENABLE(telepathy,
929           AS_HELP_STRING([--enable-telepathy],[Telepathy Presence plugin through DBus(default enabled)]))
930         if test "${enable_telepathy}" != "no"; then
931           VLC_ADD_PLUGIN([telepathy])
932           VLC_ADD_LIBS([telepathy],[$DBUS_LIBS])
933           VLC_ADD_CFLAGS([telepathy],[$DBUS_CFLAGS])
934         fi
935         dnl Power Management Inhibiter
936         VLC_ADD_PLUGIN([inhibit])
937         VLC_ADD_LIBS([inhibit],[$DBUS_LIBS])
938         VLC_ADD_CFLAGS([inhibit],[$DBUS_CFLAGS])
939     ],
940     [AC_MSG_ERROR([Couldn't find DBus >= 1.0.0, install libdbus-dev ?])]
941   )
942 fi
943 ;;
944 esac
945
946 dnl Check for ntohl, etc.
947 AC_CACHE_CHECK([for ntohl in sys/param.h],
948     [ac_cv_c_ntohl_sys_param_h],
949     [CFLAGS="${CFLAGS_save} -Wall -Werror"
950      AC_TRY_COMPILE([#include <sys/param.h>],
951         [int meuh; ntohl(meuh);],
952         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
953 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
954     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
955 fi
956
957 EXTEND_HELP_STRING([Optimization options:])
958 VLC_RESTORE_FLAGS
959 dnl
960 dnl  Compiler warnings
961 dnl
962
963 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
964 RDC_PROG_CC_FLAGS([-pipe])
965 AC_LANG_PUSH([C++])
966 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
967 AC_LANG_POP([C++])
968
969 dnl
970 dnl  Debugging mode
971 dnl
972 AC_ARG_ENABLE(debug,
973   [AS_HELP_STRING([--enable-debug],
974     [build with run-time assertions and debug symbols (default disabled)])],,
975   [enable_debug="no"])
976 AH_TEMPLATE(NDEBUG,
977             [Define to 1 if debug code should NOT be compiled])
978 AS_IF([test "${enable_debug}" != "no"], [
979   AC_CHECK_HEADERS([valgrind/valgrind.h])
980   CFLAGS="${CFLAGS} -g"
981   CXXFLAGS="${CXXFLAGS} -g"
982   OBJCFLAGS="${OBJCFLAGS} -g"
983   LDFLAGS="${LDFLAGS} -g"
984 ], [
985   AC_DEFINE(NDEBUG)
986 ])
987
988 dnl
989 dnl  Profiling
990 dnl
991 AC_ARG_ENABLE(gprof,
992   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
993   [enable_gprof="no"])
994 AS_IF([test "${enable_gprof}" != "no"], [
995   CFLAGS="${CFLAGS} -pg"
996   CXXFLAGS="${CXXFLAGS} -pg"
997   OBJCFLAGS="${OBJCFLAGS} -pg"
998   LDFLAGS="${LDFLAGS} -pg"
999 ])
1000
1001 AC_ARG_ENABLE(cprof,
1002   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
1003   [enable_cprof="no"])
1004 AS_IF([test "${enable_gprof}" != "no"], [
1005   CFLAGS="${CFLAGS} -finstrument-functions"
1006   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
1007   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
1008   LDFLAGS="${LDFLAGS} -finstrument-functions"
1009 ])
1010
1011 dnl
1012 dnl  Test coverage
1013 dnl
1014 AC_ARG_ENABLE(coverage,
1015   [AS_HELP_STRING([--enable-coverage],
1016     [build for test coverage (default disabled)])],,
1017   [enable_coverage="no"])
1018 AS_IF([test "${enable_coverage}" != "no"], [
1019   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1020   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1021   LDFLAGS="-lgcov ${LDFLAGS}"
1022   CFLAGS_save="${CFLAGS}"
1023   CXXFLAGS_save="${CXXFLAGS}"
1024   LDFLAGS_save="${LDFLAGS}"
1025 ])
1026
1027 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"], [
1028   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1029                  [ac_cv_c_visibility_hidden], [
1030     CFLAGS="${CFLAGS_save} -ffast-math"
1031     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1032       ac_cv_c_visibility_hidden=yes
1033     ], [
1034       ac_cv_c_visibility_hidden=no
1035     ])
1036   ])
1037   AS_IF([test "${ac_cv_c_visibility_hidden}" != "no"], [
1038     CFLAGS="${CFLAGS} -fvisibility=hidden"
1039     CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
1040     OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1041   ])
1042 ])
1043
1044 VLC_SAVE_FLAGS
1045
1046 dnl
1047 dnl  Enable/disable optimizations
1048 dnl
1049 AC_ARG_ENABLE(optimizations,
1050   [AS_HELP_STRING([--disable-optimizations],
1051     [disable compiler optimizations (default enabled)])],,
1052   [enable_optimizations="yes"])
1053 AS_IF([test "${enable_optimizations}" != "no"], [
1054   enable_optimizations="speed"
1055 ])
1056
1057 dnl Check for various optimization flags
1058 AS_IF([test "${enable_optimizations}" != "no"], [
1059
1060   C_O=""
1061   dnl -O4 and -O3 only in production builds
1062   AS_IF([test "{enable_debug}" = "no"], [
1063     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
1064       CFLAGS="${CFLAGS_save} -O4"
1065       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1066         ac_cv_c_o4=yes
1067       ], [
1068         ac_cv_c_o4=no
1069       ])
1070     ])
1071     AS_IF([test "${ac_cv_c_o4}" != "no"], [
1072       C_O="-O4"
1073     ], [
1074       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1075         CFLAGS="${CFLAGS_save} -O3"
1076         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1077           ac_cv_c_o3=yes
1078         ], [
1079           ac_cv_c_o3=no
1080         ])
1081       ])
1082       AS_IF([test "${ac_cv_c_o3}" != "no"], [
1083         C_O="-O3"
1084       ])
1085     ])
1086   ])
1087
1088   dnl -O2 and -O in both production and debug builds
1089   AS_IF([test "x$C_O" = "x"], [
1090     AC_CACHE_CHECK([if \$CC accepts -O2], [ac_cv_c_o2], [
1091       CFLAGS="${CFLAGS_save} -O2"
1092       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1093         ac_cv_c_o2=yes
1094       ], [
1095         ac_cv_c_o2=no
1096       ])
1097     ])
1098     AS_IF([test "${ac_cv_c_o2}" != "no"], [
1099       C_O="-O2"
1100     ], [
1101       AC_CACHE_CHECK([if \$CC accepts -O], [ac_cv_c_o], [
1102         CFLAGS="${CFLAGS_save} -O"
1103         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1104           ac_cv_c_o=yes
1105         ], [
1106           ac_cv_c_o=no
1107         ])
1108       ])
1109       AS_IF([test "${ac_cv_c_o}" != "no"], [
1110         C_O="-O"
1111       ])
1112     ])
1113   ])
1114
1115   VLC_RESTORE_FLAGS
1116   CFLAGS="${CFLAGS} ${C_O}"
1117   CXXFLAGS="${CXXFLAGS} ${C_O}"
1118   OBJCFLAGS="${OBJCFLAGS} ${C_O}"
1119   VLC_SAVE_FLAGS
1120
1121   dnl Check for -ffast-math
1122   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
1123     CFLAGS="${CFLAGS_save} -ffast-math"
1124     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1125       ac_cv_c_fast_math=yes
1126     ], [
1127       ac_cv_c_fast_math=no
1128     ])
1129   ])
1130   AS_IF([test "${ac_cv_c_fast_math}" != "no"], [
1131     VLC_RESTORE_FLAGS
1132     CFLAGS="${CFLAGS} -ffast-math"
1133     CXXFLAGS="${CXXFLAGS} -ffast-math"
1134     OBJCFLAGS="${OBJCFLAGS} -ffast-math"
1135     VLC_SAVE_FLAGS
1136   ])
1137
1138   dnl Check for -funroll-loops
1139   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1140     CFLAGS="${CFLAGS_save} -funroll-loops"
1141     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1142       ac_cv_c_unroll_loops=yes
1143     ], [
1144       ac_cv_c_unroll_loops=no
1145     ])
1146   ])
1147   AS_IF([test "${ac_cv_c_unroll_loops}" != "no"], [
1148     VLC_RESTORE_FLAGS
1149     CFLAGS="${CFLAGS} -funroll-loops"
1150     CXXFLAGS="${CXXFLAGS} -funroll-loops"
1151     OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1152     VLC_SAVE_FLAGS
1153   ])
1154
1155   AS_IF([test "$enable_debug" = "no"], [
1156     dnl Check for -fomit-frame-pointer
1157     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1158       [ac_cv_c_omit_frame_pointer], [
1159       CFLAGS="${CFLAGS_save} -fomit-frame-pointer"
1160       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1161         ac_cv_c_omit_frame_pointer=yes
1162       ], [
1163         ac_cv_c_omit_frame_pointer=no
1164       ])
1165     ])
1166     AS_IF([test "${ac_cv_c_omit_frame_pointer}" != "no"], [
1167       VLC_RESTORE_FLAGS
1168       AS_IF([test "${SYS}" != "darwin"], [
1169         CFLAGS="${CFLAGS} -fomit-frame-pointer"
1170         CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1171       ], [
1172         dnl On darwin we explicitely disable it.
1173         CFLAGS="${CFLAGS} -fno-omit-frame-pointer"
1174         CXXFLAGS="${CXXFLAGS} -fno-omit-frame-pointer"
1175         OBJCFLAGS="${OBJCFLAGS} -fno-omit-frame-pointer"
1176       ])
1177       VLC_SAVE_FLAGS
1178     ])
1179   ])
1180 ])
1181
1182 dnl Check for Darwin plugin linking flags
1183 AS_IF([test "${SYS}" = "darwin"], [
1184   AC_CACHE_CHECK([if $CC accepts -bundle -undefined error],
1185     [ac_cv_ld_darwin], [
1186     CFLAGS="${CFLAGS_save} -bundle -undefined error"
1187     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1188       ac_cv_ld_darwin=yes
1189     ], [
1190       ac_cv_ld_darwin=no
1191     ])
1192   ])
1193   AS_IF([test "${ac_cv_ld_darwin}" != "no"], [
1194     VLC_ADD_LDFLAGS([plugin],[-bundle -undefined error])
1195   ])
1196 ])
1197
1198 dnl Checks for __attribute__(aligned()) directive
1199 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1200     [ac_cv_c_attribute_aligned],
1201     [ac_cv_c_attribute_aligned=0
1202         CFLAGS="${CFLAGS_save} -Werror"
1203     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1204         AC_TRY_COMPILE([],
1205         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1206         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1207     done
1208         CFLAGS="${CFLAGS_save}"])
1209 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1210     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1211         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1212 fi
1213
1214 dnl Check for __attribute__((packed))
1215 AC_CACHE_CHECK([for __attribute__((packed))],
1216   [ac_cv_c_attribute_packed],
1217   [ac_cv_c_attribute_packed=no
1218    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1219                     [ac_cv_c_attribute_packed=yes])])
1220 if test "${ac_cv_c_attribute_packed}" != "no"; then
1221   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1222 fi
1223
1224 dnl
1225 dnl  Check the CPU
1226 dnl
1227 case "${host_cpu}" in
1228   "")
1229     ARCH=unknown
1230     ;;
1231   *)
1232     ARCH="${host_cpu}"
1233     ;;
1234 esac
1235
1236 dnl Check for backtrace() support
1237 AC_CHECK_HEADERS(execinfo.h)
1238 AC_CHECK_FUNCS(backtrace)
1239
1240 dnl
1241 dnl  default modules
1242 dnl
1243 ALIASES="${ALIASES} cvlc rvlc"
1244
1245 dnl
1246 dnl Some plugins aren't useful on some platforms
1247 dnl
1248 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
1249     VLC_ADD_PLUGIN([dynamicoverlay access_shm])
1250 elif test "${SYS}" != "mingwce"; then
1251     VLC_ADD_PLUGIN([access_smb dmo globalhotkeys])
1252     VLC_ADD_LIBS([dmo],[-lole32 -luuid])
1253 fi
1254 if test "${SYS}" = "darwin"; then
1255     VLC_ADD_LDFLAGS([quartztext],[-Wl,-framework,ApplicationServices])
1256 fi
1257
1258 dnl
1259 dnl  Accelerated modules
1260 dnl
1261
1262 dnl  Check for fully working MMX intrinsics
1263 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1264 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1265 AC_ARG_ENABLE(mmx,
1266   [AS_HELP_STRING([--disable-mmx],
1267     [disable MMX optimizations (default auto)])],,[
1268   case "${host_cpu}" in
1269     i?86|x86_64)
1270       enable_mmx="yes"
1271       ;;
1272     *)
1273       enable_mmx="no"
1274       ;;
1275   esac
1276 ])
1277 have_mmx="no"
1278 have_mmxext="no"
1279 AS_IF([test "${enable_mmx}" != "no"], [
1280   ARCH="${ARCH} mmx"
1281
1282   AC_CACHE_CHECK([if $CC groks MMX intrinsics],
1283     [ac_cv_c_mmx_intrinsics],
1284     [CFLAGS="${CFLAGS_save} -O -mmmx"
1285      AC_TRY_COMPILE([#include <mmintrin.h>
1286                      #include <stdint.h>
1287                      uint64_t frobzor;],
1288                     [__m64 a, b, c;
1289                      a = b = c = (__m64)frobzor;
1290                      a = _mm_slli_pi16(a, 3);
1291                      a = _mm_adds_pi16(a, b);
1292                      c = _mm_srli_pi16(c, 8);
1293                      c = _mm_slli_pi16(c, 3);
1294                      b = _mm_adds_pi16(b, c);
1295                      a = _mm_unpacklo_pi8(a, b);
1296                      frobzor = (uint64_t)a;],
1297                     [ac_cv_c_mmx_intrinsics=yes],
1298                     [ac_cv_c_mmx_intrinsics=no])])
1299   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1300     AC_DEFINE(HAVE_MMX_INTRINSICS, 1,
1301               [Define to 1 if MMX intrinsics are available.])
1302   ])
1303
1304   AC_CACHE_CHECK([if $CC groks MMX inline assembly],
1305     [ac_cv_mmx_inline],
1306     [CFLAGS="${CFLAGS_save}"
1307      AC_TRY_COMPILE(,[void *p;asm volatile("packuswb %%mm1,%%mm2"::"r"(p));],
1308                     ac_cv_mmx_inline=yes, ac_cv_mmx_inline=no)])
1309   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1310     AC_DEFINE(CAN_COMPILE_MMX, 1,
1311               [Define to 1 inline MMX assembly is available.])
1312     have_mmx="yes"
1313   ])
1314
1315   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1316     [ac_cv_mmxext_inline],
1317     [CFLAGS="${CFLAGS_save}"
1318      AC_TRY_COMPILE(,[void *p;asm volatile("maskmovq %%mm1,%%mm2"::"r"(p));],
1319                     ac_cv_mmxext_inline=yes, ac_cv_mmxext_inline=no)])
1320   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1321     AC_DEFINE(CAN_COMPILE_MMXEXT, 1,
1322               [Define to 1 if MMX EXT inline assembly is available.])
1323     have_mmxext="yes"
1324   ])
1325 ])
1326 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1327 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1328
1329 dnl  Check for fully workin SSE2 intrinsics
1330 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1331 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1332 AC_ARG_ENABLE(sse,
1333   [AS_HELP_STRING([--disable-sse],
1334     [disable SSE (1-4) optimizations (default auto)])],, [
1335   case "${host_cpu}" in
1336     i?86|x86_64)
1337       enable_sse=yes
1338       ;;
1339     *)
1340       enable_sse=no
1341       ;;
1342   esac
1343 ])
1344 have_sse2="no"
1345 AS_IF([test "${enable_sse}" != "no"], [
1346   ARCH="${ARCH} sse sse2"
1347
1348   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics],
1349     [ac_cv_c_sse2_intrinsics],
1350     [CFLAGS="${CFLAGS_save} -O -msse2"
1351      AC_TRY_COMPILE([#include <emmintrin.h>
1352                      #include <stdint.h>
1353                      uint64_t frobzor;],
1354                     [__m128i a, b, c;
1355                      a = b = c = _mm_set1_epi64((__m64)frobzor);
1356                      a = _mm_slli_epi16(a, 3);
1357                      a = _mm_adds_epi16(a, b);
1358                      c = _mm_srli_epi16(c, 8);
1359                      c = _mm_slli_epi16(c, 3);
1360                      b = _mm_adds_epi16(b, c);
1361                      a = _mm_unpacklo_epi8(a, b);
1362                      frobzor = (uint64_t)_mm_movepi64_pi64(a);],
1363                     [ac_cv_c_sse2_intrinsics=yes],
1364                     [ac_cv_c_sse2_intrinsics=no])])
1365   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1366     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1,
1367               [Define to 1 if SSE2 intrinsics are available.])
1368   ])
1369
1370   AC_CACHE_CHECK([if $CC groks SSE inline assembly],
1371     [ac_cv_sse_inline],
1372     [CFLAGS="${CFLAGS_save}"
1373      AC_TRY_COMPILE(,[void *p;asm volatile("xorps %%xmm1,%%xmm2"::"r"(p));],
1374                     ac_cv_sse_inline=yes, ac_cv_sse_inline=no)])
1375   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1376     AC_DEFINE(CAN_COMPILE_SSE, 1,
1377               [Define to 1 if SSE inline assembly is available.])
1378   ])
1379
1380   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly],
1381     [ac_cv_sse2_inline],
1382     [CFLAGS="${CFLAGS_save}"
1383      AC_TRY_COMPILE(,[void *p;asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p));],
1384                     ac_cv_sse2_inline=yes, ac_cv_sse2_inline=no)])
1385   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1386     AC_DEFINE(CAN_COMPILE_SSE2, 1,
1387               [Define to 1 if SSE2 inline assembly is available.])
1388     have_sse2="yes"
1389   ])
1390
1391   # SSE3
1392   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly],
1393     [ac_cv_sse3_inline],
1394     [CFLAGS="${CFLAGS_save}"
1395      AC_TRY_COMPILE(,[void *p;asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p));],
1396                     ac_cv_sse3_inline=yes, ac_cv_sse3_inline=no)])
1397   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1398     AC_DEFINE(CAN_COMPILE_SSE3, 1,
1399               [Define to 1 if SSE3 inline assembly is available.]) ])
1400   # SSSE3
1401   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly],
1402     [ac_cv_ssse3_inline],
1403     [CFLAGS="${CFLAGS_save}"
1404      AC_TRY_COMPILE(,[void *p;asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p));],
1405                     ac_cv_ssse3_inline=yes, ac_cv_ssse3_inline=no)])
1406   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1407     AC_DEFINE(CAN_COMPILE_SSSE3, 1,
1408               [Define to 1 if SSSE3 inline assembly is available.]) ])
1409
1410   # SSE4.1
1411   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1412     [ac_cv_sse4_1_inline],
1413     [CFLAGS="${CFLAGS_save}"
1414      AC_TRY_COMPILE(,[void *p;asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p));],
1415                     ac_cv_sse4_1_inline=yes, ac_cv_sse4_1_inline=no)])
1416   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1417     AC_DEFINE(CAN_COMPILE_SSE4_1, 1,
1418               [Define to 1 if SSE4_1 inline assembly is available.]) ])
1419
1420   # SSE4.2
1421   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1422     [ac_cv_sse4_2_inline],
1423     [CFLAGS="${CFLAGS_save}"
1424      AC_TRY_COMPILE(,[void *p;asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p));],
1425                     ac_cv_sse4_2_inline=yes, ac_cv_sse4_2_inline=no)])
1426   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1427     AC_DEFINE(CAN_COMPILE_SSE4_2, 1,
1428               [Define to 1 if SSE4_2 inline assembly is available.]) ])
1429
1430   # SSE4A
1431   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly],
1432     [ac_cv_sse4a_inline],
1433     [CFLAGS="${CFLAGS_save}"
1434      AC_TRY_COMPILE(,[void *p;asm volatile("insertq %%xmm1,%%xmm0"::"r"(p));],
1435                     ac_cv_sse4a_inline=yes, ac_cv_sse4a_inline=no)])
1436   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1437     AC_DEFINE(CAN_COMPILE_SSE4A, 1,
1438               [Define to 1 if SSE4A inline assembly is available.]) ])
1439 ])
1440 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1441
1442 have_3dnow="no"
1443 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly],
1444     [ac_cv_3dnow_inline],
1445     [CFLAGS="${CFLAGS_save}"
1446      AC_TRY_COMPILE(,[void *p;asm volatile("pfadd %%mm1,%%mm2"::"r"(p));],
1447                     ac_cv_3dnow_inline=yes, ac_cv_3dnow_inline=no)])
1448 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1449   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1450             [Define to 1 if 3D Now! inline assembly is available.])
1451   have_3dnow="yes"
1452 ])
1453 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1454
1455
1456 AC_ARG_ENABLE(neon,
1457   [AS_HELP_STRING([--disable-neon],
1458     [disable NEON optimizations (default auto)])],, [
1459   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1460 ])
1461 AS_IF([test "${enable_neon}" != "no"], [
1462   AC_CACHE_CHECK([if $CC groks NEON inline assembly], [ac_cv_neon_inline], [
1463     CFLAGS="${CFLAGS_save} -mfpu=neon"
1464     AC_COMPILE_IFELSE([
1465       AC_LANG_PROGRAM(,[[
1466 asm volatile("vqmovun.s64 d0, q1":::"d0");
1467 asm volatile("ssat r0, #1, r0":::"r0"); /* assume ARMv6 */
1468 ]])
1469     ], [
1470       ac_cv_neon_inline="-mfpu=neon"
1471     ], [
1472       ac_cv_neon_inline="no"
1473     ])
1474     CFLAGS="${CFLAGS_save}"
1475   ])
1476   ARM_NEON_CFLAGS="$ac_cv_neon_inline"
1477 ], [
1478   ac_cv_neon_inline="no"
1479 ])
1480 AC_SUBST(ARM_NEON_CFLAGS)
1481 AM_CONDITIONAL(HAVE_ARM_NEON, [test "${ac_cv_neon_inline}" != "no"])
1482
1483
1484 AC_ARG_ENABLE(altivec,
1485   [AS_HELP_STRING([--disable-altivec],
1486     [disable AltiVec optimizations (default auto)])],, [
1487   AS_IF([test "${host_cpu}" = "powerpc"],
1488         [enable_altivec=yes], [enable_altivec=no])
1489 ])
1490 have_altivec="no"
1491 AS_IF([test "${enable_altivec}" = "yes"], [
1492   ARCH="${ARCH} altivec";
1493   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1494     [ac_cv_altivec_inline],
1495     [CFLAGS="${CFLAGS_save}"
1496      AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1497          ac_cv_altivec_inline="yes",
1498          [CFLAGS="${CFLAGS_save} -Wa,-m7400"
1499           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1500             [ac_cv_altivec_inline="-Wa,-m7400"],
1501             ac_cv_altivec_inline=no)
1502          ])])
1503   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1504     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1505               [Define to 1 if AltiVec inline assembly is available.])
1506     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1507       VLC_ADD_CFLAGS([memcpyaltivec],[${ac_cv_altivec_inline}])
1508       VLC_ADD_CFLAGS([i420_yuy2_altivec],[${ac_cv_altivec_inline}])
1509       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1510     ])
1511     have_altivec="yes"
1512   ])
1513
1514 dnl The AltiVec C extensions
1515 dnl
1516 dnl There are several possible cases:
1517 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1518 dnl                      need <altivec.h>
1519 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1520 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1521 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1522 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1523 dnl - Others: test should fail
1524   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1525   [ac_cv_c_altivec],
1526   [# OS X/PPC test (gcc 4.x)
1527    CFLAGS="${CFLAGS_save} -mpim-altivec -force_cpusubtype_ALL"
1528    AC_TRY_COMPILE([vector unsigned char foo;],
1529      [vec_ld(0, (unsigned char *)0);],
1530      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1531      [# OS X/PPC test (gcc 3.x)
1532       CFLAGS="${CFLAGS_save} -faltivec"
1533       AC_TRY_COMPILE([vector unsigned char foo;],
1534         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1535         [ac_cv_c_altivec="-faltivec"],
1536         dnl Below this are the Linux tests
1537         [# Linux/PPC test (gcc 4.x)
1538          CFLAGS="${CFLAGS_save} -maltivec"
1539          AC_TRY_COMPILE([#include <altivec.h>],
1540            [vec_ld(0, (unsigned char *)0);],
1541            [ac_cv_c_altivec="-maltivec"],
1542            [# Linux/PPC test (gcc 3.3)
1543             CFLAGS="${CFLAGS_save} -maltivec -mabi=altivec"
1544             AC_TRY_COMPILE([#include <altivec.h>],
1545               [vec_ld(0, (unsigned char *)0);],
1546               [ac_cv_c_altivec=""
1547                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1548               [# Linux/PPC test (gcc 3.3)
1549                CFLAGS="${CFLAGS_save} -fvec"
1550                AC_TRY_COMPILE([#include <altivec.h>],
1551                  [vec_ld(0, (unsigned char *)0);],
1552                  [ac_cv_c_altivec="-fvec"],
1553                  [ac_cv_c_altivec=no])
1554               ])
1555            ])
1556         ])
1557      ])
1558    CFLAGS="${CFLAGS_save}"
1559   ])
1560   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1561     CPPFLAGS="${CPPFLAGS_save} ${ac_cv_c_altivec}"
1562   ])
1563
1564   AC_CHECK_HEADERS(altivec.h)
1565   CPPFLAGS="${CPPFLAGS_save}"
1566
1567   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1568     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1,
1569               [Define to 1 if C AltiVec extensions are available.])
1570     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1571     VLC_ADD_CFLAGS([i420_yuy2_altivec memcpyaltivec deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1572     have_altivec="yes"
1573   ])
1574
1575   AC_CACHE_CHECK([if linker needs -framework vecLib],
1576     [ac_cv_ld_altivec],
1577     [LDFLAGS="${LDFLAGS_vlc} -Wl,-framework,vecLib"
1578      AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)
1579      LDFLAGS="${LDFLAGS_save}"
1580     ])
1581   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1582     VLC_ADD_LDFLAGS([libvlccore memcpyaltivec],[-Wl,-framework,vecLib])
1583   ])
1584 ])
1585 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1586
1587 dnl
1588 dnl  Special arch tuning
1589 dnl
1590 AC_ARG_WITH(tuning,
1591   [AS_HELP_STRING([--with-tuning=ARCH],
1592     [tune compilation for an architecture (default varies)])])
1593 if test -n "${with_tuning}"; then
1594     if test "${with_tuning}" != "no"; then
1595         CFLAGS_TUNING="-mtune=${with_tuning}"
1596     fi
1597 else
1598     if test "${SYS}" = "darwin" -a "${host_cpu}" = "i686"; then
1599         CFLAGS_TUNING="-march=prescott -mtune=generic"
1600     elif test "${SYS}" = "darwin" -a "${host_cpu}" = "x86_64"; then
1601         CFLAGS_TUNING="-march=core2 -mtune=core2"
1602     elif test "${host_cpu}" = "i686" -o "${host_cpu}" = "i586" -o "${host_cpu}" = "i486" -o "${host_cpu}" = "i386"; then
1603         CFLAGS_TUNING="-mtune=pentium2"
1604     elif test "${host_cpu}" = "x86_64"; then
1605         CFLAGS_TUNING="-mtune=athlon64"
1606     elif test "${host_cpu}" = "powerpc"; then
1607         CFLAGS_TUNING="-mtune=G4";
1608     fi
1609 fi
1610
1611 dnl NOTE: this can't be cached cleanly
1612 AS_IF([test "${CFLAGS_TUNING}"],
1613    [CFLAGS_save="${CFLAGS}"
1614     CFLAGS="${CFLAGS} ${CFLAGS_TUNING}"
1615
1616     AC_MSG_CHECKING([whether $CC accepts ${CFLAGS_TUNING}])
1617     AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
1618                       [tuning="yes"],
1619                       [CFLAGS_TUNING=""; tuning="no"
1620                        AS_IF([test "${with_tuning}"],
1621                              [AC_MSG_ERROR([requested tuning not supported])])])
1622
1623     AC_MSG_RESULT([$tuning])
1624     CFLAGS="${CFLAGS_save}"
1625 ])
1626
1627 dnl
1628 dnl  Memory usage
1629 dnl
1630 AC_ARG_ENABLE(optimize-memory,
1631   [AS_HELP_STRING([--enable-optimize-memory],
1632     [optimize memory usage over performance])])
1633 if test "${enable_optimize_memory}" = "yes"; then
1634   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1635 fi
1636
1637 dnl
1638 dnl Allow running as root (useful for people running on embedded platforms)
1639 dnl
1640 AC_ARG_ENABLE(run-as-root,
1641   [AS_HELP_STRING([--enable-run-as-root],
1642     [allow running VLC as root (default disabled)])])
1643 AS_IF([test "${enable_run_as_root}" = "yes"],[
1644     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1645               [Define to 1 to allow running VLC as root (uid 0).])
1646 ])
1647
1648 dnl
1649 dnl Stream output
1650 dnl
1651 AC_ARG_ENABLE(sout,
1652   [AS_HELP_STRING([--disable-sout],
1653     [disable streaming output (default enabled)])])
1654 AS_IF([test "${enable_sout}" != "no"], [
1655   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1656 ])
1657 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1658
1659 dnl Lua modules
1660 AC_ARG_ENABLE(lua,
1661   [AS_HELP_STRING([--disable-lua],
1662     [disable LUA scripting support (default enabled)])])
1663 if test "${enable_lua}" != "no"
1664 then
1665   PKG_CHECK_MODULES(LUA, lua5.1,
1666     [ have_lua=yes ],
1667     [
1668     AC_MSG_WARN([lua5.1 not found, trying lua >= 5.1 instead])
1669     PKG_CHECK_MODULES(LUA, lua >= 5.1,
1670       [ have_lua=yes ],
1671       [
1672         have_lua=yes
1673         AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1674           [],
1675           [ have_lua=no ] )
1676         AC_CHECK_LIB(  lua5.1 , luaL_newstate,
1677           [LUA_LIBS="-llua5.1"],
1678           AC_CHECK_LIB( lua51 , luaL_newstate,
1679             [LUA_LIBS="-llua51"],
1680             AC_CHECK_LIB( lua , luaL_newstate,
1681               [LUA_LIBS="-llua"],
1682               [ have_lua=no
1683               ], [-lm])
1684           )
1685         )
1686       ])
1687     ])
1688   if test "x${have_lua}" = "xyes" ;  then
1689      VLC_ADD_LIBS([lua],[$LUA_LIBS])
1690      VLC_ADD_CFLAGS([lua],[$LUA_CFLAGS])
1691   else
1692       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1693   fi
1694   AC_ARG_VAR([LUAC], [LUA byte compiler])
1695   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1696   AS_IF([test "${LUAC}" = "false"], [
1697     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1698   ])
1699 fi
1700 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1701
1702 dnl
1703 dnl HTTP daemon
1704 dnl
1705 AC_ARG_ENABLE(httpd,
1706   [AS_HELP_STRING([--disable-httpd],
1707     [disable the built-in HTTP server (default enabled)])])
1708 if test "${enable_httpd}" != "no"
1709 then
1710   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP dameon support)
1711 fi
1712 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1713
1714 dnl
1715 dnl VideoLAN manager
1716 dnl
1717 AC_ARG_ENABLE(vlm,
1718   [AS_HELP_STRING([--disable-vlm],
1719     [disable the stream manager (default enabled)])],,
1720   [enable_vlm="${enable_sout}"])
1721 AS_IF([test "${enable_vlm}" != "no"], [
1722   AS_IF([test "${enable_sout}" = "no"], [
1723     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1724   ])
1725   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1726 ])
1727 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1728
1729 dnl
1730 dnl Growl notification plugin
1731 dnl
1732 AC_ARG_ENABLE(growl,
1733   [  --enable-growl          growl notification plugin (default disabled)],,
1734   [enable_growl=no])
1735 AS_IF([test "${enable_growl}" != "no"], [
1736     VLC_ADD_PLUGIN([growl_udp])
1737     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl/Growl.framework/Versions/A/Headers/GrowlDefines.h, [
1738       VLC_ADD_PLUGIN([growl])
1739       VLC_ADD_LDFLAGS([growl], [-F${CONTRIB_DIR}/Growl -Wl,-framework,Growl,-framework,CoreFoundation])
1740       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}/Growl])
1741       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
1742     ])
1743   ]
1744 )
1745
1746 dnl
1747 dnl Libnotify notification plugin
1748 dnl
1749 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
1750
1751 dnl
1752 dnl Taglib plugin
1753 dnl
1754 AC_ARG_ENABLE(taglib,
1755   [AS_HELP_STRING([--disable-taglib],
1756     [do not use TagLib (default enabled)])])
1757 AS_IF([test "${enable_taglib}" != "no"], [
1758   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5, [
1759     VLC_ADD_PLUGIN([taglib])
1760     VLC_ADD_LIBS([taglib],[$TAGLIB_LIBS -lz])
1761     VLC_ADD_CXXFLAGS([taglib],[$TAGLIB_CFLAGS])
1762     AC_LANG_PUSH(C++)
1763     AC_CHECK_HEADERS(taglib/mp4coverart.h)
1764     AC_CHECK_HEADERS(taglib/apefile.h)
1765     AC_LANG_POP(C++)
1766   ], [
1767     AC_MSG_WARN(TagLib library not found)])
1768 ])
1769
1770 dnl
1771 dnl  Input plugins
1772 dnl
1773
1774 EXTEND_HELP_STRING([Input plugins:])
1775
1776 dnl
1777 dnl libproxy support
1778 dnl
1779 AC_ARG_ENABLE(libproxy,
1780   [AS_HELP_STRING([--enable-libproxy],[support libproxy (default auto)])])
1781 AS_IF([test "${enable_libproxy}" != "no"], [
1782   PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0, [
1783     AC_DEFINE(HAVE_LIBPROXY, 1, [Define if libproxy is available])
1784     VLC_ADD_CFLAGS([access_http],[$LIBPROXY_CFLAGS])
1785     VLC_ADD_LIBS([access_http],[$LIBPROXY_LIBS])
1786   ], [
1787     AS_IF([test "x${enable_libproxy}" != "x"], [
1788       AC_MSG_ERROR([libproxy could not be found on your system])
1789     ])
1790   ])
1791 ])
1792
1793 dnl
1794 dnl  live555 input
1795 dnl
1796 AC_ARG_ENABLE(live555,
1797   [AS_HELP_STRING([--enable-live555],
1798     [enable RTSP input through live555 (default enabled)])])
1799 AC_ARG_WITH(live555-tree,
1800   [AS_HELP_STRING([--with-live555-tree=PATH],
1801     [live555 tree for static linking])])
1802 if test "${enable_live555}" != "no"; then
1803
1804   dnl
1805   dnl test for --with-live555-tree
1806   dnl
1807   if test -z "${with_live555_tree}" -a "${CXX}" != ""; then
1808     AC_LANG_PUSH(C++)
1809     CPPFLAGS_save="${CPPFLAGS}"
1810     if test -z "${CONTRIB_DIR}"; then
1811         CPPFLAGS_live555="-I/usr/include/liveMedia -I/usr/include/groupsock -I/usr/include/BasicUsageEnvironment -I/usr/include/UsageEnvironment"
1812     else
1813         CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1814     fi
1815     if test "${SYS}" = "solaris"; then
1816       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1817     fi
1818     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1819
1820     AC_CHECK_HEADERS(liveMedia_version.hh, [
1821       AC_MSG_CHECKING(for liveMedia version >= 1275091200 )
1822       AC_EGREP_CPP(yes,
1823         [#include <liveMedia_version.hh>
1824          #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1825          #if LIVEMEDIA_LIBRARY_VERSION_INT < 1275091200
1826          yes
1827          #endif
1828          #endif],
1829         [AC_MSG_RESULT([no])
1830           AC_MSG_WARN([The installed liveMedia version is too old:
1831 Version 2010.05.29 or later is required to proceed.
1832 You can get an updated one from http://www.live555.com/liveMedia .])
1833           AS_IF([test "${enable_live555}" == "yes"], [
1834             AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable the plugin.])
1835           ])
1836         ],[
1837           AC_MSG_RESULT([yes])
1838           other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1839           other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1840           if test "${SYS}" = "mingw32"; then
1841             # add ws2_32 for closesocket, select, recv
1842             other_libs="$other_libs -lws2_32"
1843           elif test "${SYS}" = "mingwce"; then
1844             # add ws2 for closesocket, select, recv
1845             other_libs="$other_libs -lws2"
1846           fi
1847
1848           dnl We need to check for pic because live555 don't provide shared libs
1849           dnl and we want to build a plugins so we need -fPIC on some arch.
1850           VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1851           AC_CHECK_LIB(liveMedia_pic, main, [
1852             VLC_ADD_PLUGIN([live555])
1853             VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1854           ],[
1855             AC_CHECK_LIB(liveMedia, main, [
1856             VLC_ADD_PLUGIN([live555])
1857             VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1858           ],[],[${other_libs}]) ],[${other_libs_pic}])
1859
1860           CPPFLAGS="${CPPFLAGS_save}"
1861           AC_LANG_POP(C++)
1862         ])
1863       ])
1864   else
1865     AC_MSG_CHECKING(for liveMedia/libliveMedia.a in ${with_live555_tree})
1866     real_live555_tree="`cd ${with_live555_tree} 2>/dev/null && pwd`"
1867     if test -z "${real_live555_tree}"; then
1868       dnl  The given directory can't be found
1869       AC_MSG_RESULT(no)
1870       AC_MSG_ERROR([cannot cd to ${with_live555_tree}])
1871     fi
1872     if test -f "${real_live555_tree}/liveMedia/libliveMedia.a"; then
1873       AC_MSG_RESULT(${real_live555_tree}/liveMedia/libliveMedia.a)
1874
1875       AC_CHECK_HEADERS(${real_live555_tree}/liveMedia/include/liveMedia_version.hh,[
1876         AC_MSG_CHECKING(for liveMedia version >= 1275091200 )
1877         AC_EGREP_CPP(yes,
1878           [#include "${real_live555_tree}/liveMedia/include/liveMedia_version.hh"
1879            #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1880            #if LIVEMEDIA_LIBRARY_VERSION_INT < 1275091200
1881            yes
1882            #endif
1883            #endif],
1884           [AC_MSG_RESULT([no])
1885            AC_MSG_ERROR([Your version of liveMedia is too old: you may get a more recent one from http://www.live555.com/liveMedia.
1886 lternatively you can use --disable-live555 to disable the liveMedia plugin.])
1887         ],[
1888            AC_MSG_RESULT([yes])
1889            ])
1890       ])
1891
1892       VLC_ADD_PLUGIN([live555])
1893
1894       if test "${SYS}" = "mingw32"; then
1895         # add ws2_32 for closesocket, select, recv
1896         VLC_ADD_LIBS([live555],[-lws2_32])
1897       fi
1898
1899       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/UsageEnvironment -lUsageEnvironment])
1900       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/BasicUsageEnvironment -lBasicUsageEnvironment])
1901       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/groupsock -lgroupsock])
1902       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/liveMedia -lliveMedia])
1903
1904       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/BasicUsageEnvironment/include])
1905       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/groupsock/include])
1906       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/liveMedia/include])
1907       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/UsageEnvironment/include ])
1908       if test "${SYS}" = "solaris"; then
1909         VLC_ADD_CXXFLAGS([live555],[-DSOLARIS])
1910       fi
1911     else
1912       dnl  The given live555 wasn't built
1913         AC_MSG_RESULT(no)
1914       if test "${enable_live555}" = "yes"; then
1915         AC_MSG_ERROR([cannot find ${real_live555_tree}/liveMedia/libliveMedia.a, make sure you compiled live555 in ${with_live555_tree}])
1916       fi        
1917     fi
1918   fi
1919 fi
1920
1921 dnl
1922 dnl - special access module for dc1394 input
1923 dnl - dv module: digital video module check for libraw1394
1924 dnl - linsys modules: access module check for libzvbi
1925 dnl
1926 PKG_ENABLE_MODULES_VLC([DC1394], [], [libraw1394 >= 2.0.1 libdc1394-2 >= 2.1.0], [dc1394 access module], [auto])
1927 PKG_ENABLE_MODULES_VLC([DV], [access_dv], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV input module], [auto])
1928
1929 AC_ARG_ENABLE(linsys,
1930   [AS_HELP_STRING([--enable-linsys],
1931     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1932 if test "$SYS" = "linux" -a "${enable_linsys}" != "no"; then
1933   VLC_ADD_PLUGIN([linsys_hdsdi])
1934   PKG_CHECK_MODULES(LINSYS_SDI, zvbi-0.2 >= 0.2.28,
1935     [ VLC_ADD_LIBS([linsys_sdi],[$LINSYS_SDI_LIBS])
1936       VLC_ADD_CFLAGS([linsys_sdi],[$LINSYS_SDI_CFLAGS])
1937       VLC_ADD_PLUGIN([linsys_sdi]) ],
1938     [AC_MSG_WARN([Could not find zvbi >= 0.2.28, install libzvbi-dev ?])]
1939   )
1940 fi
1941
1942 dnl
1943 dnl dvdread module: check for libdvdread
1944 dnl
1945 dnl prepend -ldvdcss on OS that need it
1946 AS_CASE(["${SYS}"], [mingw32|darwin], [VLC_ADD_LIBS([dvdread], [-ldvdcss])])
1947 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1948
1949 dnl
1950 dnl libdvdnav plugin
1951 dnl
1952 AC_ARG_ENABLE(dvdnav,
1953   [AS_HELP_STRING([--disable-dvdnav],
1954     [disable DVD navigation with libdvdnav (default auto)])])
1955 if test "${enable_dvdnav}" != "no"
1956 then
1957   dnl prepend -ldvdcss on OS that need it
1958   AS_CASE(["${SYS}"], [mingw32|darwin], [VLC_ADD_LIBS([dvdnav], [-ldvdcss])])
1959
1960   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1961     VLC_ADD_PLUGIN([dvdnav])
1962     VLC_ADD_CFLAGS([dvdnav],[${DVDNAV_CFLAGS}])
1963     VLC_ADD_LIBS([dvdnav],[${DVDNAV_LIBS}])
1964     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1965       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1966         [], [${LIBS_dvdnav}])
1967     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1968       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1969         [], [${LIBS_dvdnav}])],
1970       [AC_MSG_WARN(dvdnav library not found)])
1971 fi
1972
1973 dnl
1974 dnl  Windows DirectShow access module
1975 dnl
1976 AC_ARG_ENABLE(dshow,
1977   [AS_HELP_STRING([--disable-dshow],
1978     [support DirectShow (default auto)])])
1979 if test "${enable_dshow}" != "no"
1980 then
1981   if test "${SYS}" = "mingw32"
1982   then
1983     AC_LANG_PUSH(C++)
1984       AC_CHECK_HEADERS(dshow.h,
1985       [ VLC_ADD_PLUGIN([dshow])
1986         VLC_ADD_CXXFLAGS([dshow],[])
1987         VLC_ADD_LIBS([dshow],[-lole32 -loleaut32 -luuid]) ])
1988     AC_LANG_POP(C++)
1989   fi
1990 fi
1991
1992 dnl
1993 dnl  Blu-ray Disc Support with libbluray
1994 dnl
1995 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2 libxml-2.0 >= 2.6 ], (libbluray for Blu-ray disc support ) )
1996
1997 dnl
1998 dnl  OpenCV wrapper and example filters
1999 dnl
2000 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv], (OpenCV (computer vision) filter), [off])
2001
2002
2003 dnl
2004 dnl  libsmbclient plugin
2005 dnl
2006 AC_ARG_ENABLE(smb,
2007   [AS_HELP_STRING([--disable-smb], [disable SMB/CIFS support (default auto)])])
2008 if test "${enable_smb}" != "no"; then
2009   AC_CHECK_HEADERS(libsmbclient.h,
2010     [ VLC_ADD_PLUGIN([access_smb])
2011       VLC_ADD_LIBS([access_smb],[-lsmbclient]) ],
2012     [ if test -n "${enable_smb}"; then
2013         AC_MSG_ERROR([cannot find libsmbclient headers])
2014      fi ])
2015 fi
2016
2017
2018 dnl
2019 dnl sftp access support
2020 dnl
2021 AC_ARG_ENABLE(sftp,
2022   [AS_HELP_STRING([--enable-sftp],
2023     [support SFTP file transfer via libssh2 (default disabled)])])
2024 if test "${enable_sftp}" = "yes"; then
2025   AC_CHECK_HEADERS(libssh2.h, [
2026     VLC_ADD_PLUGIN([access_sftp])
2027     VLC_ADD_LIBS([access_sftp], [-lssh2])
2028   ])
2029 fi
2030
2031 dnl
2032 dnl  Video4Linux2 plugin
2033 dnl
2034 AC_ARG_ENABLE(v4l2,
2035   [AS_HELP_STRING([--disable-v4l2],
2036     [do not support Video4Linux version 2 (default auto)])])
2037 AC_ARG_WITH(v4l2,
2038   [AS_HELP_STRING([--with-v4l2=PATH], [path to a V4L2-enabled kernel tree])])
2039 if test "${enable_v4l2}" != "no"
2040 then
2041   if test "${with_v4l2}" != "no" -a -n "${with_v4l2}"
2042   then
2043     VLC_ADD_CPPFLAGS([v4l2],[-I${with_v4l2}/include])
2044   fi
2045
2046   CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_v4l2}"
2047   AC_CHECK_HEADERS(linux/videodev2.h sys/videoio.h, [
2048     VLC_ADD_PLUGIN([v4l2])
2049   ],[])
2050   CPPFLAGS="${CPPFLAGS_save}"
2051 fi
2052
2053 dnl
2054 dnl libv4l2 support for video4linux.
2055 dnl
2056 AC_ARG_ENABLE(libv4l2,
2057   [AS_HELP_STRING([--enable-libv4l2],
2058     [use V4L2 through libv4l2 (default auto)])])
2059 if test "${enable_libv4l2}" != "no" -a "${enable_v4l2}" != "no"
2060 then
2061     PKG_CHECK_MODULES( LIBV4L2, libv4l2, [
2062       VLC_ADD_LDFLAGS([v4l2],[${LIBV4L2_LIBS}])
2063       VLC_ADD_CFLAGS([v4l2],[${LIBV4L2_CFLAGS}])
2064       AC_DEFINE(HAVE_LIBV4L2, 1, Define if libv4l2 is available)],
2065       AC_MSG_WARN([LibV4L2 support disabled because libv4l2 development headers were not found])
2066     )
2067 fi
2068
2069 dnl
2070 dnl  special access module for Hauppauge PVR cards
2071 dnl
2072 AC_ARG_ENABLE(pvr,
2073   [AS_HELP_STRING([--enable-pvr],
2074     [support PVR V4L2 cards (default disabled)])])
2075 if test "${enable_pvr}" = "yes"
2076 then
2077   VLC_ADD_PLUGIN([pvr])
2078 fi
2079
2080 dnl
2081 dnl special access module for Blackmagic SDI cards
2082 dnl
2083 AC_ARG_ENABLE(decklink,
2084   [AS_HELP_STRING([--disable-decklink],
2085     [disable Blackmagic DeckLink SDI input (default auto)])])
2086 AC_ARG_WITH(decklink_sdk,
2087   [AS_HELP_STRING[--with-decklink-sdk=DIR],
2088     [location of Blackmagic DeckLink SDI SDK])])
2089 if test "${enable_decklink}" != "no"
2090 then
2091   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
2092   then
2093     VLC_ADD_CPPFLAGS([decklink],[-I${with_decklink_sdk}/include])
2094   fi
2095   CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_decklink}"
2096   AC_LANG_PUSH(C++)
2097   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
2098     VLC_ADD_PLUGIN([decklink])
2099   ],[AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)])
2100   AC_LANG_POP(C++)
2101   CPPFLAGS="${CPPFLAGS_save}"
2102 fi
2103
2104
2105 dnl
2106 dnl  gnomeVFS access module
2107 dnl
2108 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [access_gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
2109
2110 dnl
2111 dnl  VCDX modules
2112 dnl
2113 AC_ARG_ENABLE(vcdx,
2114   [AS_HELP_STRING([--enable-vcdx],
2115     [navigate VCD with libvcdinfo (default disabled)])])
2116 if test "${enable_vcdx}" = "yes"
2117 then
2118         PKG_CHECK_MODULES(LIBCDIO, [libcdio >= 0.78.2 libiso9660 >= 0.72],
2119           [VLC_ADD_LIBS([vcdx],[$LIBCDIO_LIBS])
2120                  VLC_ADD_CFLAGS([vcdx],[$LIBCDIO_CFLAGS])],
2121                 [AC_MSG_ERROR([vcdx plugin requires libcdio >= 0.78.2 and libiso9660 >= 0.72])])
2122         PKG_CHECK_MODULES(LIBVCDINFO, libvcdinfo >= 0.7.22,
2123                 [VLC_ADD_LIBS([vcdx],[$LIBVCDINFO_LIBS])
2124                  VLC_ADD_CFLAGS([vcdx],[$LIBVCDINFO_CFLAGS])],
2125           [AC_MSG_ERROR([vcdx plugin requires libvcdinfo library >= 0.7.22])])
2126         VLC_ADD_PLUGIN([vcdx])
2127 fi
2128
2129 dnl
2130 dnl  Built-in CD-DA and VCD module
2131 dnl
2132 AC_ARG_ENABLE(vcd,
2133   [AS_HELP_STRING([--disable-vcd],
2134     [disable built-in VCD and CD-DA support (default enabled)])])
2135
2136 AC_ARG_ENABLE(libcddb,
2137   [AS_HELP_STRING([--disable-libcddb],
2138     [disable CDDB for Audio CD (default enabled)])])
2139
2140 if test "${enable_vcd}" != "no"
2141 then
2142   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2143   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2144     AC_MSG_RESULT(yes)
2145     VLC_ADD_PLUGIN([vcd cdda])
2146   ],[
2147     AC_MSG_RESULT(no)
2148   ])
2149
2150   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2151   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2152     AC_MSG_RESULT(yes)
2153     VLC_ADD_PLUGIN([vcd cdda])
2154     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2155   ],[
2156     AC_MSG_RESULT(no)
2157   ])
2158
2159   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2160   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2161     AC_MSG_RESULT(yes)
2162     VLC_ADD_PLUGIN([vcd cdda])
2163     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2164   ],[
2165     AC_MSG_RESULT(no)
2166   ])
2167
2168   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32"
2169   then
2170     VLC_ADD_PLUGIN([vcd cdda])
2171   fi
2172
2173   if test "${SYS}" = "darwin"
2174   then
2175     VLC_ADD_PLUGIN([vcd cdda])
2176     VLC_ADD_LDFLAGS([vcd vcdx cdda],[-Wl,-framework,IOKit,-framework,CoreFoundation])
2177     VLC_ADD_LIBS([vcdx cdda],[-liconv])
2178   fi
2179
2180   if test "$enable_libcddb" != "no"; then
2181     PKG_CHECK_MODULES(LIBCDDB, libcddb >= 0.9.5, [
2182       HAVE_LIBCDDB=yes
2183       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2184       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2185       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2186       ],:
2187       [AC_MSG_WARN(new enough libcddb not found. CDDB access disabled)
2188       HAVE_LIBCDDB=no])
2189   fi
2190 fi
2191
2192 dnl
2193 dnl  libdvbpsi check for ts mux/demux
2194 dnl
2195 have_dvbpsi="no"
2196 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
2197 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2198
2199 dnl
2200 dnl  Screen capture module
2201 dnl
2202 AC_ARG_ENABLE(screen,
2203   [AS_HELP_STRING([--enable-screen],
2204     [disable screen capture (default enabled)])])
2205 if test "${enable_screen}" != "no"; then
2206   if test "${SYS}" = "darwin"; then
2207     AC_CHECK_HEADERS(OpenGL/gl.h, [
2208       AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2209         VLC_ADD_PLUGIN([screen])
2210         VLC_ADD_LDFLAGS([screen],[-Wl,-framework,OpenGL,-framework,ApplicationServices])
2211       ])
2212     ])
2213   elif test "${SYS}" = "mingw32"; then
2214     VLC_ADD_PLUGIN([screen])
2215     VLC_ADD_LIBS([screen],[-lgdi32])
2216   elif test "${SYS}" = "mingwce"; then
2217     CPPFLAGS="${CPPFLAGS_save}"
2218   fi
2219 fi
2220
2221 dnl
2222 dnl  ipv6 support
2223 dnl
2224 have_ipv6=no
2225 AC_CHECK_FUNCS(inet_pton,[have_ipv6=yes],[
2226   AC_CHECK_LIB(nsl,inet_pton, [have_ipv6=yes])
2227 ])
2228
2229 AS_IF([test "${have_ipv6}" = "yes"], [
2230   AC_DEFINE(HAVE_INET_PTON, 1, [Define to 1 if you have inet_pton().])])
2231
2232
2233 AC_CHECK_FUNCS(inet_ntop,[
2234   AC_DEFINE(HAVE_INET_NTOP, 1, [Define to 1 if you have inet_ntop().])])
2235
2236
2237 dnl
2238 dnl  GME demux plugin
2239 dnl
2240 AC_ARG_ENABLE(gme,
2241   [AS_HELP_STRING([--enable-gme],
2242     [use Game Music Emu (default auto)])])
2243 AS_IF([test "${enable_gme}" != "no"], [
2244   AC_CHECK_HEADER([gme/gme.h], [
2245     VLC_ADD_LIBS([gme], [-lgme])
2246     VLC_ADD_PLUGIN([gme])
2247   ], [
2248     AS_IF([test "x${enable_gme}" != "x"], [
2249       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2250     ])
2251   ])
2252 ])
2253
2254
2255 dnl
2256 dnl  SIDPlay plugin
2257 dnl
2258 PKG_WITH_MODULES([SID], [libsidplay2],
2259                 AC_LANG_PUSH(C++)
2260                 oldCPPFLAGS="$CPPFLAGS"
2261                 CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2262                 AC_CHECK_HEADER([sidplay/builders/resid.h], [
2263                         VLC_ADD_PLUGIN([sid])
2264                         VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2265                         VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2266                 ], [
2267                         AS_IF([test "x${enable_sid}" = "xyes"],
2268                                 [AC_MSG_ERROR(Library libresid-builder needed for sid was not found)],
2269                                 [AC_MSG_WARN(Library libresid-builder needed for sid was not found)]
2270                                 )
2271                 ])
2272                 CPPFLAGS="$oldCPPFLAGS"
2273                 AC_LANG_POP(C++),
2274                 AS_IF([test "x${enable_sid}" = "xyes"],
2275                         [AC_MSG_ERROR(Library libsidplay2 needed for sid was not found)],
2276                         [AC_MSG_WARN(Library libsidplay2 needed for sid was not found)]
2277                         ),
2278                 [C64 sid demux support], [auto])
2279
2280
2281 dnl
2282 dnl  ogg demux plugin
2283 dnl
2284 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2285 if test "${enable_sout}" != "no"; then
2286     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2287 fi
2288
2289 if test "${enable_sout}" != "no"; then
2290 dnl Check for libshout
2291 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2292 fi
2293
2294 dnl
2295 dnl  matroska demux plugin
2296 dnl
2297 AC_ARG_ENABLE(mkv,
2298   [AS_HELP_STRING([--disable-mkv],
2299     [do not use libmatroska (default auto)])])
2300 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2301   AC_LANG_PUSH(C++)
2302   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2303     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2304     AC_EGREP_CPP(yes,
2305       [#include <ebml/EbmlVersion.h>
2306        #ifdef LIBEBML_VERSION
2307        #if LIBEBML_VERSION >= 0x010000
2308        yes
2309        #endif
2310        #endif],
2311       [AC_MSG_RESULT([yes])
2312         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2313           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2314           AC_EGREP_CPP(yes,
2315             [#include <matroska/KaxVersion.h>
2316              #ifdef LIBMATROSKA_VERSION
2317              #if LIBMATROSKA_VERSION >= 0x010000
2318              yes
2319              #endif
2320              #endif],
2321             [AC_MSG_RESULT([yes])
2322               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2323               VLC_ADD_CXXFLAGS([mkv],[])
2324               if test "${SYS}" = "darwin"; then
2325                 VLC_ADD_CXXFLAGS([mkv],[-O1])
2326               fi
2327               AC_CHECK_LIB(ebml_pic, main, [
2328                 VLC_ADD_PLUGIN([mkv])
2329                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2330               ],[
2331                 AC_CHECK_LIB(ebml, main, [
2332                   VLC_ADD_PLUGIN([mkv])
2333                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2334                 ])
2335               ])
2336             ], [
2337               AC_MSG_RESULT([no])
2338               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2339           ])
2340         ])
2341       ],
2342       [AC_MSG_RESULT([no])
2343         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2344     ])
2345   ])
2346   AC_LANG_POP(C++)
2347 fi
2348
2349 dnl
2350 dnl  modplug demux plugin
2351 dnl
2352 AC_ARG_ENABLE(mod,
2353   [AS_HELP_STRING([--disable-mod],
2354     [do not use libmodplug (default auto)])])
2355 if test "${enable_mod}" != "no" ; then
2356     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2357           VLC_ADD_PLUGIN([mod])
2358           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2359           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2360     ],[
2361        AS_IF([test x"${enable_mod}" = "xyes"],
2362          [AC_MSG_ERROR(libmodplug not found or a broken version (0.8.8.0) was found!)],
2363          [AC_MSG_WARN(libmodplug not found or a broken version (0.8.8.0) was found!)])
2364     ])
2365 fi
2366
2367 dnl
2368 dnl  mpc demux plugin
2369 dnl
2370 AC_ARG_ENABLE(mpc,
2371   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2372 if test "${enable_mpc}" != "no"
2373 then
2374   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2375     VLC_ADD_PLUGIN([mpc])
2376     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2377     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2378     VLC_ADD_PLUGIN([mpc])
2379     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2380 fi
2381
2382 dnl
2383 dnl  Codec plugins
2384 dnl
2385
2386 EXTEND_HELP_STRING([Codec plugins:])
2387
2388 dnl
2389 dnl wmafixed plugin
2390 dnl
2391 AC_ARG_ENABLE(wma-fixed,
2392   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2393 if test "${enable_wma_fixed}" = "yes"
2394 then
2395   VLC_ADD_PLUGIN([wma_fixed])
2396 fi
2397
2398 dnl
2399 dnl shine fixed point mp3 encoder
2400 dnl
2401 AC_ARG_ENABLE(shine,
2402   [  --enable-shine          shine mp3 encoding module (default disabled)])
2403 if test "${enable_shine}" = "yes"
2404 then
2405   VLC_ADD_PLUGIN([shine])
2406 fi
2407
2408 dnl
2409 dnl openmax il codec plugin
2410 dnl
2411 AC_ARG_ENABLE(omxil,
2412   [  --enable-omxil          openmax il codec module (default disabled)])
2413 if test "${enable_omxil}" = "yes"
2414 then
2415   VLC_ADD_PLUGIN([omxil])
2416   VLC_ADD_LIBS([omxil], [$LIBDL])
2417 fi
2418
2419 dnl
2420 dnl CrystalHD codec plugin
2421 dnl
2422 AC_ARG_ENABLE(crystalhd,
2423   [  --enable-crystalhd       crystalhd codec plugin (default auto)])
2424 if test "${enable_crystalhd}" != "no"; then
2425     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2426       VLC_ADD_PLUGIN([crystalhd])
2427       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2428     ],[
2429       if test "${SYS}" = "mingw32" ; then
2430         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2431           VLC_ADD_PLUGIN([crystalhd])
2432           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2433             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2434             ])
2435         ],[
2436           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2437                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2438                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2439         ],[#define __LINUX_USER__
2440                #include <libcrystalhd/bc_dts_types.h>
2441         ])
2442       fi
2443     ],[
2444        #include <libcrystalhd/bc_dts_types.h>
2445       ])
2446 fi
2447
2448 dnl
2449 dnl  mad plugin
2450 dnl
2451 AC_ARG_ENABLE(mad,
2452   [  --enable-mad            libmad module (default enabled)])
2453 if test "${enable_mad}" != "no"
2454 then
2455   AC_ARG_WITH(mad,
2456     [  --with-mad=PATH         path to libmad],[],[])
2457   if test "${with_mad}" != "no" -a -n "${with_mad}"
2458   then
2459     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2460     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2461   fi
2462
2463   AC_ARG_WITH(mad-tree,
2464     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2465   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2466   then
2467     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2468     if test -z "${real_mad_tree}"
2469     then
2470       dnl  The given directory can't be found
2471       AC_MSG_RESULT(no)
2472       AC_MSG_ERROR([${with_mad_tree} directory doesn't exist])
2473     fi
2474     dnl  Use a custom libmad
2475     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2476     if test -f ${real_mad_tree}/mad.h
2477     then
2478       AC_MSG_RESULT(yes)
2479       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2480       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2481       LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2482       AC_CHECK_LIB(mad, mad_bit_init, [
2483         VLC_ADD_PLUGIN([mpgatofixed32])
2484         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2485         ],[ AC_MSG_ERROR([the specified tree hasn't been compiled ])
2486       ],[])
2487       LDFLAGS="${LDFLAGS_save}"
2488     else
2489       AC_MSG_RESULT(no)
2490       AC_MSG_ERROR([the specified tree doesn't have mad.h])
2491     fi
2492   else
2493     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_mpgatofixed32}"
2494     LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2495     AC_CHECK_HEADERS(mad.h, ,
2496       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2497     AC_CHECK_LIB(mad, mad_bit_init, [
2498       VLC_ADD_PLUGIN([mpgatofixed32])
2499       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2500       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2501     CPPFLAGS="${CPPFLAGS_save}"
2502     LDFLAGS="${LDFLAGS_save}"
2503   fi
2504 fi
2505
2506
2507 AC_ARG_ENABLE(merge-ffmpeg,
2508 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2509   enable_merge_ffmpeg="no"
2510 ])
2511 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2512
2513 AC_CACHE_CHECK([if linker supports -Bsymbolic],
2514   [ac_cv_ld_bsymbolic],
2515   [LDFLAGS="${LDFLAGS_vlc} -Wl,-Bsymbolic"
2516     AC_TRY_LINK([],,ac_cv_ld_bsymbolic=yes,ac_cv_ld_bsymbolic=no)
2517     LDFLAGS="${LDFLAGS_save}"
2518   ])
2519
2520 dnl
2521 dnl  avcodec decoder/encoder plugin
2522 dnl
2523 AC_ARG_ENABLE(avcodec,
2524 [  --enable-avcodec        libavcodec codec (default enabled)])
2525 AS_IF([test "${enable_avcodec}" != "no"], [
2526   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 52.25.0 libavutil],
2527     [
2528       VLC_SAVE_FLAGS
2529       CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2530       CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2531       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2532       AC_CHECK_HEADERS(libavutil/avutil.h)
2533       VLC_ADD_PLUGIN([avcodec])
2534       VLC_ADD_LIBS([avcodec],[$AVCODEC_LIBS])
2535       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2536         VLC_ADD_LDFLAGS([avcodec],[-Wl,-Bsymbolic])
2537       ])
2538       VLC_ADD_CFLAGS([avcodec],[$AVCODEC_CFLAGS])
2539       VLC_RESTORE_FLAGS
2540       have_avcodec="yes"
2541     ],[
2542       AC_MSG_ERROR([Could not find libavcodec or libavutil. Use --disable-avcodec to ignore this error.])
2543   ])
2544 ], [
2545   have_avcodec="no"
2546 ])
2547
2548 dnl
2549 dnl libva needs avcodec
2550 dnl
2551 AC_ARG_ENABLE(libva,
2552   [  --enable-libva          libva VAAPI support (default auto)])
2553
2554 AS_IF([test "${enable_libva}" != "no"], [
2555   AS_IF([test "x${have_avcodec}" = "xyes"], [
2556     PKG_CHECK_MODULES(LIBVA, [libva libva-x11],
2557       [
2558         VLC_SAVE_FLAGS
2559         CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2560         CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2561         AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2562            VLC_ADD_LIBS([avcodec],[$LIBVA_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11])
2563            VLC_ADD_CFLAGS([avcodec],[$LIBVA_CFLAGS ${X_CFLAGS}])
2564            AC_DEFINE(HAVE_AVCODEC_VAAPI, 1, [Define if avcodec has to be built with VAAPI support.])
2565            echo "VAAPI acceleration activated"
2566         ],[
2567         AS_IF([test "${enable_libva}" == "yes"],
2568               [AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])],
2569               [AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])])
2570         ])
2571         VLC_RESTORE_FLAGS
2572       ],[
2573         AS_IF([test "${enable_libva}" == "yes"],
2574               [AC_MSG_ERROR([Could not find required libva.])],
2575               [AC_MSG_WARN([libva not found  ])])
2576       ])
2577   ],[
2578     AS_IF([test "x${enable_libva}" != "x"], [
2579       AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive.])
2580     ])
2581   ])
2582 ])
2583
2584 dnl
2585 dnl dxva2 needs avcodec
2586 dnl
2587 AC_ARG_ENABLE(dxva2,
2588   [  --enable-dxva2          DxVA2  support (default auto)])
2589
2590 AS_IF([test "${enable_dxva2}" != "no"], [
2591   if test "${SYS}" = "mingw32"; then
2592   AS_IF([test "x${have_avcodec}" = "xyes"], [
2593     AC_CHECK_HEADERS(dxva2api.h, 
2594       [
2595         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2596            VLC_ADD_LIBS([avcodec],[-lole32 -lshlwapi -luuid])
2597            AC_DEFINE(HAVE_AVCODEC_DXVA2, 1, [Define if avcodec has to be built with DxVA2 support.])
2598            echo "DxVA2 acceleration activated"
2599         ],[
2600         AS_IF([test "${enable_dxva2}" == "yes"],
2601               [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2602               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2603         ])
2604       ],[
2605         AS_IF([test "${enable_dxva2}" == "yes"],
2606               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2607               [AC_MSG_WARN([dxva2api.h not found])])
2608       ])
2609   ],[
2610     AS_IF([test "x${enable_dxva2}" != "x"], [
2611       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2612     ])
2613   ])
2614   fi
2615 ])
2616
2617
2618 dnl
2619 dnl stream_out switcher needs libavcodec
2620 dnl
2621 AC_ARG_ENABLE(switcher,
2622   [  --enable-switcher       Stream-out switcher plugin (default disabled)])
2623 AS_IF([test "${enable_switcher}" = "yes"], [
2624   AS_IF([test "x${have_avcodec}" = "xyes"], [
2625     VLC_ADD_PLUGIN([stream_out_switcher])
2626     VLC_ADD_LIBS([stream_out_switcher],[$AVCODEC_LIBS $AVUTIL_LIBS])
2627     VLC_ADD_CFLAGS([stream_out_switcher],[$AVCODEC_CFLAGS $AVUTIL_CFLAGS])
2628   ],[AC_MSG_ERROR([Stream_out switcher depends on avcodec])
2629   ])
2630 ])
2631
2632
2633 dnl
2634 dnl  avformat demuxer/muxer plugin
2635 dnl
2636
2637 AC_ARG_ENABLE(avformat,
2638 [  --enable-avformat       libavformat containers (default enabled)],, [
2639   enable_avformat="${have_avcodec}"
2640 ])
2641 if test "${enable_avformat}" != "no"
2642 then
2643   PKG_CHECK_MODULES(AVFORMAT,[libavformat > 52.30.0 libavcodec libavutil],
2644     [
2645       VLC_SAVE_FLAGS
2646       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2647       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2648       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2649       AC_CHECK_HEADERS(libavutil/avutil.h)
2650       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2651         VLC_ADD_PLUGIN([avformat access_avio])
2652         VLC_ADD_LIBS([avformat access_avio],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2653         VLC_ADD_CFLAGS([avformat access_avio],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2654         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2655           VLC_ADD_LDFLAGS([avformat access_avio],[-Wl,-Bsymbolic])
2656         ])
2657       ], [
2658         VLC_ADD_LIBS([avcodec],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2659         VLC_ADD_CFLAGS([avcodec],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2660       ])
2661       VLC_RESTORE_FLAGS
2662     ],[
2663       AC_MSG_ERROR([Could not find libavformat or libavutil. Use --disable-avformat to ignore this error.])
2664   ])
2665 fi
2666
2667 dnl
2668 dnl  swscale image scaling and conversion plugin
2669 dnl
2670
2671 AC_ARG_ENABLE(swscale,
2672   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2673                   (default enabled)]))
2674 if test "${enable_swscale}" != "no"
2675 then
2676   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2677     [
2678       VLC_SAVE_FLAGS
2679       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2680       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2681       AC_CHECK_HEADERS(libswscale/swscale.h)
2682       VLC_ADD_PLUGIN([swscale])
2683       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2684       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2685       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2686         VLC_ADD_LDFLAGS([swscale],[-Wl,-Bsymbolic])
2687       ])
2688       VLC_RESTORE_FLAGS
2689     ],[
2690       AC_MSG_ERROR([Could not find libswscale. Use --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2691   ])
2692 fi
2693
2694 dnl
2695 dnl  postproc plugin
2696 dnl
2697
2698 AC_ARG_ENABLE(postproc,
2699 [  --enable-postproc       libpostproc image post-processing (default enabled)])
2700 if test "${enable_postproc}" != "no"
2701 then
2702   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2703     [
2704       VLC_SAVE_FLAGS
2705       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2706       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2707       AC_CHECK_HEADERS(postproc/postprocess.h)
2708       VLC_ADD_PLUGIN([postproc])
2709       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2710       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2711       VLC_RESTORE_FLAGS
2712     ],[
2713       AC_MSG_ERROR([Could not find libpostproc. Use --disable-postproc to ignore this error.])
2714   ])
2715 fi
2716
2717 dnl
2718 dnl  faad decoder plugin
2719 dnl
2720 AC_ARG_ENABLE(faad,
2721 [  --enable-faad           faad codec (default disabled)])
2722 if test "${enable_faad}" = "yes"
2723 then
2724   AC_ARG_WITH(faad-tree,
2725   [  --with-faad-tree=PATH   faad tree for static linking])
2726   if test -n "${with_faad_tree}"
2727   then
2728     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2729     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2730     if test -z "${real_faad_tree}"
2731     then
2732       dnl  The given directory can't be found
2733       AC_MSG_RESULT(no)
2734       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2735     fi
2736     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"
2737     then
2738       dnl  Use a custom faad
2739       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2740       VLC_ADD_PLUGIN([faad])
2741       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2742       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2743     else
2744       dnl  The given libfaad wasn't built
2745       AC_MSG_RESULT(no)
2746       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2747     fi
2748   else
2749     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_faad}"
2750     LDFLAGS="${LDFLAGS_save} ${LIBS_faad}"
2751     AC_CHECK_HEADERS(faad.h, ,
2752       [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ])
2753     AC_CHECK_LIB(faad, faacDecOpen, [
2754       VLC_ADD_PLUGIN([faad])
2755       VLC_ADD_LIBS([faad],[-lfaad]) ],
2756       AC_CHECK_LIB(faad, NeAACDecOpen, [
2757         VLC_ADD_PLUGIN([faad])
2758         VLC_ADD_LIBS([faad],[-lfaad]) ],
2759         [ AC_MSG_ERROR([Cannot find libfaad library...]) ]))
2760     LDFLAGS="${LDFLAGS_save}"
2761     CPPFLAGS="${CPPFLAGS_save}"
2762   fi
2763 fi
2764
2765 dnl
2766 dnl twolame encoder plugin
2767 dnl
2768 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2769
2770 dnl
2771 dnl  QuickTime plugin
2772 dnl
2773 AC_ARG_ENABLE(quicktime,
2774   [  --enable-quicktime      QuickTime module (deprecated)])
2775 if test "${enable_quicktime}" = "yes"; then
2776   if test "${SYS}" = "mingw32"; then
2777     VLC_ADD_PLUGIN([quicktime])
2778   else
2779   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2780     [ VLC_ADD_PLUGIN([quicktime])
2781       VLC_ADD_LDFLAGS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2782     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2783   fi
2784 fi
2785
2786 dnl
2787 dnl  Real plugin
2788 dnl
2789 AC_ARG_ENABLE(real,
2790   [  --enable-real           Real media module (default disabled)])
2791 if test "${enable_real}" = "yes"; then
2792   VLC_ADD_PLUGIN([realvideo])
2793 fi
2794
2795 dnl
2796 dnl  Real RTSP plugin
2797 dnl
2798 AC_ARG_ENABLE(realrtsp,
2799   [  --enable-realrtsp       Real RTSP module (default disabled)])
2800 if test "${enable_realrtsp}" = "yes"; then
2801   VLC_ADD_PLUGIN([access_realrtsp])
2802 fi
2803
2804 dnl
2805 dnl A52/AC3 decoder plugin
2806 dnl
2807 AC_ARG_ENABLE(a52,
2808   [  --enable-a52            A/52 support with liba52 (default enabled)])
2809 if test "${enable_a52}" != "no"
2810 then
2811   AC_ARG_WITH(a52,
2812     [  --with-a52=PATH         a52 headers and libraries])
2813   AC_ARG_WITH(a52-tree,
2814     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2815   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2816   then
2817     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2818     if test -z "${real_a52_tree}"
2819     then
2820       dnl  The given directory can't be found
2821       AC_MSG_RESULT(no)
2822       AC_MSG_ERROR([${with_a52_tree} directory doesn't exist])
2823     fi
2824     dnl  Use a custom a52dec
2825     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2826     if test -f ${real_a52_tree}/include/a52.h
2827     then
2828       AC_MSG_RESULT(yes)
2829       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2830       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2831       LDFLAGS="${LDFLAGS_save} ${LIBS_a52tofloat32}"
2832       AC_CHECK_LIB(a52, a52_free, [
2833         VLC_ADD_PLUGIN([a52tofloat32])
2834         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2835         VLC_ADD_LIBS([a52tofloat32],[-la52])
2836         ],[
2837         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2838         then
2839           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2840         else
2841           AC_MSG_ERROR([the specified tree hasn't been compiled])
2842         fi
2843       ])
2844       LDFLAGS="${LDFLAGS_save}"
2845     else
2846       AC_MSG_RESULT(no)
2847       AC_MSG_ERROR([the specified tree doesn't have a52.h])
2848     fi
2849   else
2850     if test -z "${with_a52}"
2851     then
2852       LDFLAGS_test=""
2853       CPPFLAGS_test=""
2854     else
2855       LDFLAGS_test="-L${with_a52}/lib"
2856       CPPFLAGS_test="-I${with_a52}/include"
2857     fi
2858     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2859     LDFLAGS="${LDFLAGS_save} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2860     AC_CHECK_HEADERS(a52dec/a52.h, [
2861       AC_CHECK_LIB(a52, a52_free, [
2862         VLC_ADD_PLUGIN([a52tofloat32])
2863         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2864         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2865       ],[
2866         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2867         ])
2868     ],[
2869       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2870     ])
2871     CPPFLAGS="${CPPFLAGS_save}"
2872     LDFLAGS="${LDFLAGS_save}"
2873   fi
2874 fi
2875
2876 AC_ARG_WITH(a52-fixed,
2877       [  --with-a52-fixed        specify if liba52 has been compiled with fixed point support],
2878       [
2879         VLC_ADD_CPPFLAGS([a52tofloat32],[-DLIBA52_FIXED]) ])
2880
2881 dnl
2882 dnl DTS Coherent Acoustics decoder plugin
2883 dnl
2884 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2885
2886 dnl
2887 dnl  Flac plugin
2888 dnl
2889 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2890
2891 dnl
2892 dnl  Libmpeg2 plugin
2893 dnl
2894 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2895
2896 dnl
2897 dnl  Vorbis plugin
2898 dnl
2899 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2900
2901 dnl
2902 dnl  Tremor plugin
2903 dnl
2904 AC_ARG_ENABLE(tremor,
2905   [  --enable-tremor         Tremor decoder support (default disabled)])
2906 if test "${enable_tremor}" = "yes"
2907 then
2908   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2909     VLC_ADD_PLUGIN([tremor])
2910     VLC_ADD_LIBS([tremor],[-lvorbisidec -logg])
2911    ],[])
2912 fi
2913
2914 dnl
2915 dnl  Speex plugin
2916 dnl
2917 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex decoder support], [auto])
2918
2919 dnl
2920 dnl  theora decoder plugin
2921 dnl
2922 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theora >= 1.0], [experimental theora codec], [auto])
2923
2924 dnl
2925 dnl  dirac encoder plugin
2926 dnl
2927 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2928
2929 dnl
2930 dnl  schroedinger decoder plugin (for dirac format video)
2931 dnl
2932 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2933
2934 dnl
2935 dnl  PNG decoder module
2936 dnl
2937 AC_ARG_ENABLE(png,
2938   [  --enable-png            PNG support (default enabled)])
2939 if test "${enable_png}" != "no"; then
2940 AC_CHECK_HEADERS(png.h, [
2941   LDFLAGS="${LDFLAGS_save} -lz"
2942   AC_CHECK_LIB(png, png_set_rows, [
2943     VLC_ADD_LIBS([png],[-lpng -lz])
2944     VLC_ADD_PLUGIN([png osdmenu osd_parser])],
2945     [],[-lz])
2946     LDFLAGS="${LDFLAGS_save}"
2947   ])
2948 fi
2949 AM_CONDITIONAL(BUILD_OSDMENU, [test "${enable_png}" != "no"])
2950
2951 dnl
2952 dnl H264 encoder plugin (using libx264)
2953 dnl
2954 AC_ARG_ENABLE(x264,
2955   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2956 if test "${enable_x264}" != "no"; then
2957   AC_ARG_WITH(x264-tree,
2958     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2959   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2960   then
2961     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2962     if test -z "${real_x264_tree}"
2963     then
2964       dnl  The given directory can't be found
2965       AC_MSG_RESULT(no)
2966       AC_MSG_ERROR([${with_x264_tree} directory doesn't exist])
2967     fi
2968     dnl  Use a custom libx264
2969     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2970     if test -f ${real_x264_tree}/x264.h
2971     then
2972       AC_MSG_RESULT(yes)
2973       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2974       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2975       PKG_CHECK_MODULES(X264,x264, [
2976         VLC_ADD_PLUGIN([x264])
2977         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
2978         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2979         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2980           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2981         fi
2982       ],[
2983         AC_MSG_ERROR([the specified tree hasn't been compiled])
2984       ])
2985       LDFLAGS="${LDFLAGS_save}"
2986     else
2987       AC_MSG_RESULT(no)
2988       AC_MSG_ERROR([the specified tree doesn't have x264.h])
2989     fi
2990   else
2991       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2992         VLC_ADD_PLUGIN([x264])
2993         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
2994
2995         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2996           VLC_ADD_LDFLAGS([x264],[-Wl,-Bsymbolic])
2997         ])
2998
2999         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
3000         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3001           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
3002         fi
3003       ],[
3004         if test "${enable_x264}" = "yes"; then
3005             AC_MSG_ERROR([Could not find libx264 >= 0.86 on your system: you may get it from http://www.videolan.org/x264.html])
3006           fi
3007       ])
3008     LDFLAGS="${LDFLAGS_save}"
3009   fi
3010 fi
3011
3012 dnl
3013 dnl libfluidsynth (MIDI synthetizer) plugin
3014 dnl
3015 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth], [MIDI synthetiser with libfluidsynth], [auto])
3016
3017 dnl
3018 dnl Teletext Modules
3019 dnl vbi decoder plugin (using libzbvi)
3020 dnl telx module
3021 dnl uncompatible
3022 dnl
3023 AC_ARG_ENABLE(zvbi,
3024   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
3025                   libzvbi (default enabled)]))
3026 AC_ARG_ENABLE(telx,
3027   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
3028                   zvbi) (default enabled if zvbi is absent)]))
3029
3030 AS_IF( [test "${enable_zvbi}" != "no"],[
3031     PKG_CHECK_MODULES(ZVBI,
3032         zvbi-0.2 >= 0.2.28,
3033         [
3034           VLC_ADD_LIBS([zvbi],[$ZVBI_LIBS])
3035           if test "${SYS}" = "mingw32"; then
3036               VLC_ADD_LIBS([zvbi],[ -lpthreadGC2])
3037           fi
3038           VLC_ADD_CFLAGS([zvbi],[$ZVBI_CFLAGS])
3039           VLC_ADD_PLUGIN([zvbi])
3040           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
3041           AS_IF( [test "${enable_telx}" = "yes"],[
3042                   AC_MSG_WARN([The zvbi and telx modules are uncompatibles.
3043                                Using zvbi.])
3044                   ])
3045         ],[
3046           AC_MSG_WARN(ZVBI library not found. Enabling the telx module instead)
3047         ])
3048     ])
3049 AS_IF( [test "${enable_telx}" != "no" ],[
3050   VLC_ADD_PLUGIN([telx])
3051   ])
3052
3053 dnl
3054 dnl libass subtitle rendering module
3055 dnl
3056 AC_ARG_ENABLE(libass,
3057   [  --enable-libass         Subtitle support using libass (default enabled)])
3058 AS_IF( [test "${enable_libass}" != "no"], [
3059   PKG_CHECK_MODULES(LIBASS, libass >= 0.9.8,
3060       [
3061         VLC_ADD_LIBS([libass],[$LIBASS_LIBS])
3062         VLC_ADD_CFLAGS([libass],[$LIBASS_CFLAGS])
3063         VLC_ADD_PLUGIN([libass])
3064
3065         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3066           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3067            VLC_ADD_LIBS([libass],[-lfontconfig])
3068        ])
3069       ],[
3070         AC_MSG_WARN([LIBASS library not found])
3071       ])
3072   ])
3073
3074 dnl
3075 dnl  kate decoder plugin
3076 dnl
3077 AC_ARG_ENABLE(kate,
3078 [  --enable-kate           kate codec (default enabled)])
3079 AS_IF([test "${enable_kate}" != "no"], [
3080   PKG_CHECK_MODULES(KATE,[kate >= 0.1.5], [
3081       VLC_ADD_PLUGIN([kate])
3082       VLC_ADD_CFLAGS([kate],[$KATE_CFLAGS])
3083       VLC_ADD_LIBS([kate],[$KATE_LIBS]) ],[
3084         AC_CHECK_HEADERS(kate/kate.h, [
3085           AC_CHECK_LIB(kate, kate_decode_init, [
3086             VLC_ADD_PLUGIN([kate])
3087             kate_libs="-lkate -logg"
3088             VLC_ADD_LDFLAGS([kate],[${kate_libs}]) ],[
3089             AS_IF([test "x${enable_kate}" != "x"], [
3090               AC_MSG_ERROR([libkate doesn't appear to be installed on your system.
3091               You also need to check that you have a libogg posterior to the 1.0 release.])
3092             ])
3093           ], [-lkate -logg])
3094         ],[
3095           AS_IF([test "x${enable_kate}" != "x"], [
3096             AC_MSG_ERROR([libkate headers do not appear to be installed on your system.
3097             You also need to check that you have a libogg posterior to the 1.0 release.])
3098           ])
3099         ])
3100   ])
3101 ])
3102
3103
3104 dnl
3105 dnl  tiger rendering for kate decoder plugin
3106 dnl
3107 AC_ARG_ENABLE(tiger,
3108 [  --enable-tiger          Tiger rendering library for Kate streams (default enabled)])
3109 AS_IF([test "${enable_tiger}" != "no"], [
3110   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3111       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])
3112       VLC_ADD_CFLAGS([kate],[$TIGER_CFLAGS])
3113       VLC_ADD_LIBS([kate],[$TIGER_LIBS]) ],[
3114         AS_IF([test "x${enable_tiger}" != "x"], [
3115           AC_MSG_ERROR([libtiger does not appear to be installed on your system.])
3116         ])
3117   ])
3118 ])
3119
3120
3121
3122 dnl
3123 dnl  Video plugins
3124 dnl
3125
3126 EXTEND_HELP_STRING([Video plugins:])
3127
3128 dnl
3129 dnl  Xlib
3130 dnl
3131
3132 AC_PATH_XTRA()
3133 AC_CHECK_HEADERS(X11/Xlib.h)
3134
3135 dnl
3136 dnl  X C Bindings modules
3137 dnl
3138 AC_ARG_ENABLE(xcb,
3139   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3140   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
3141     enable_xcb="yes"
3142   ], [
3143     enable_xcb="no"
3144   ])
3145 ])
3146 AC_ARG_ENABLE(xvideo,
3147   [  --enable-xvideo         XVideo support (default enabled)],, [
3148     enable_xvideo="$enable_xcb"
3149 ])
3150
3151 have_xcb="no"
3152 AS_IF([test "${enable_xcb}" != "no"], [
3153   dnl libxcb
3154   PKG_CHECK_MODULES(XCB, [xcb])
3155   have_xcb="yes"
3156   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3157
3158   AS_IF([test "${enable_xvideo}" != "no"], [
3159     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [
3160       VLC_ADD_PLUGIN([xcb_xv])
3161     ])
3162   ])
3163
3164   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [
3165     VLC_ADD_PLUGIN([panoramix])
3166     VLC_ADD_LIBS([panoramix],[${XCB_RANDR_LIBS} ${XCB_LIBS}])
3167     VLC_ADD_CFLAGS([panoramix],[${XCB_RANDR_CFLAGS} ${XCB_CFLAGS}])
3168   ], [
3169     AC_MSG_WARN([libxcb-randr not found. Panoramix filter will not be supported.])
3170   ])
3171
3172   dnl xcb-utils
3173   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [
3174     PKG_CHECK_MODULES(XPROTO, [xproto])
3175     VLC_ADD_PLUGIN([globalhotkeys])
3176     VLC_ADD_CFLAGS([globalhotkeys], [${XCB_KEYSYMS_CFLAGS} ${XCB_CFLAGS}])
3177     VLC_ADD_LIBS([globalhotkeys], [${XCB_KEYSYMS_LIBS} ${XCB_LIBS}])
3178     VLC_ADD_CFLAGS([xcb_window], [-DHAVE_XCB_KEYSYMS])
3179   ], [
3180     AC_MSG_WARN([libxcb-keysyms (0.3.4 or later) not found. Hotkeys will not work.])
3181   ])
3182 ])
3183 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3184
3185 AC_ARG_ENABLE(glx,
3186   [  --enable-glx            X11 OpenGL (GLX) support (default enabled)],, [
3187   enable_glx="$enable_xcb"
3188 ])
3189 AS_IF([test "${enable_glx}" != "no"], [
3190   PKG_CHECK_MODULES(XLIB_XCB, [x11-xcb])
3191   PKG_CHECK_MODULES(GL, [gl],, [
3192     AC_CHECK_HEADER([GL/gl.h], [
3193       GL_CFLAGS=""
3194       GL_LIBS="-lGL"
3195     ], [
3196       AC_MSG_ERROR([GLX (libGL) cannot be found. If you do not need OpenGL with X11, use --disable-glx.])
3197     ])
3198   ])
3199   VLC_ADD_PLUGIN([xcb_glx])
3200 ])
3201
3202 dnl
3203 dnl  OpenGL
3204 dnl
3205 PKG_ENABLE_MODULES_VLC([GL], [], [gl], [OpenGL support], [auto])
3206 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [auto])
3207 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [auto])
3208 PKG_ENABLE_MODULES_VLC([EGL], [], [egl], [EGL support], [auto])
3209
3210 dnl
3211 dnl  SDL module
3212 dnl
3213 AC_ARG_ENABLE(sdl,
3214   [  --enable-sdl            SDL support (default enabled)])
3215 AC_ARG_ENABLE(sdl-image,
3216   [  --enable-sdl-image      SDL image support (default enabled)])
3217 if test "${enable_sdl}" != "no"
3218 then
3219    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3220       # SDL on Darwin is heavily patched and can only run SDL_image
3221       if test "${SYS}" != "darwin"; then
3222         VLC_ADD_PLUGIN([vout_sdl aout_sdl])
3223       fi
3224       if test "${SYS}" != "mingw32"; then
3225         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3226       fi
3227       VLC_ADD_CFLAGS([vout_sdl aout_sdl],[${SDL_CFLAGS}])
3228       VLC_ADD_LIBS([vout_sdl aout_sdl],[${SDL_LIBS}])
3229
3230       # SDL_image
3231       AS_IF([ test "${enable_sdl_image}" != "no"],[
3232         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3233           VLC_ADD_PLUGIN([sdl_image])
3234           VLC_ADD_LIBS([sdl_image],[${SDL_IMAGE_LIBS}])
3235           VLC_ADD_CFLAGS([sdl_image], [${SDL_IMAGE_CFLAGS}])],
3236           [ AC_MSG_WARN([The development package for SDL_image is not installed.
3237     You should install it alongside your SDL package.])
3238           ])
3239       ])
3240    ],[
3241      AC_MSG_WARN([The development package for SDL is not present or too old.
3242                   You need 1.2.10. Alternatively you can also configure with
3243                   --disable-sdl.])
3244    ])
3245 fi
3246
3247 dnl
3248 dnl  freetype module
3249 dnl
3250 AC_ARG_ENABLE(freetype,
3251   [  --enable-freetype       freetype support   (default auto)])
3252 AC_ARG_ENABLE(fribidi,
3253   [  --enable-fribidi        fribidi support    (default auto)])
3254 AC_ARG_ENABLE(fontconfig,
3255   [  --enable-fontconfig     fontconfig support (default auto)])
3256
3257 if test "${enable_freetype}" != "no"; then
3258    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3259       have_freetype=yes
3260       VLC_ADD_PLUGIN([freetype])
3261       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3262       if test "${SYS}" = "mingw32"; then
3263         VLC_ADD_LIBS([freetype],[-liconv -lz])
3264       fi
3265       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3266
3267       AC_CHECK_HEADERS(Carbon/Carbon.h,
3268                        [VLC_ADD_LDFLAGS([freetype],[-Wl,-framework,Carbon])])
3269
3270       dnl fontconfig support
3271       if test "${SYS}" != "mingw32"; then
3272           if test "${enable_fontconfig}" != "no"; then
3273             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3274               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3275               VLC_ADD_LIBS([freetype],[-lfontconfig])
3276             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3277           fi
3278       else
3279           VLC_ADD_LIBS([freetype],[-lgdi32])
3280       fi
3281
3282       dnl fribidi support
3283       if test "${enable_fribidi}" != "no"; then
3284         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3285           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3286           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3287         ],[AC_MSG_WARN([library fribidi not found. Bidirectional support will be disabled in freetype])])
3288       fi
3289
3290   ],[
3291   have_freetype=no
3292   AS_IF([ test "${enable_freetype}" = "yes"],[
3293     AC_MSG_ERROR([Freetype2 package cannot be detected. Install Freetype2 development or configure with --disable-freetype.])
3294     ])
3295   ])
3296 fi
3297
3298 dnl
3299 dnl  libxml2 module
3300 dnl
3301 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3302
3303 dnl
3304 dnl  SVG module
3305 dnl
3306 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3307
3308 dnl
3309 dnl  iOS vout module
3310 dnl
3311 AC_ARG_ENABLE(ios-vout,
3312   [  --enable-ios-vout    iOS video output module (default disabled)])
3313 if test "${enable_ios_vout}" = "yes"
3314 then
3315   VLC_ADD_PLUGIN([vout_ios])
3316   VLC_ADD_CFLAGS([vout_ios], [-DUSE_OPENGL_ES=1])
3317   VLC_ADD_LDFLAGS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3318 fi
3319
3320 dnl
3321 dnl  QuartzText vout module (iOS/Mac OS)
3322 dnl
3323 AC_ARG_ENABLE(macosx-quartztext,
3324   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3325 if test "x${enable_macosx_quartztext}" != "xno" &&
3326   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3327 then
3328   VLC_ADD_PLUGIN([quartztext])
3329   VLC_ADD_LDFLAGS([quartztext],[-Wl,-framework,ApplicationServices])
3330 fi
3331
3332 dnl
3333 dnl  Windows DirectX module
3334 dnl
3335
3336 if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3337 then
3338   VLC_ADD_PLUGIN([panoramix])
3339 fi
3340
3341 AC_ARG_ENABLE(directx,
3342   [  --enable-directx        Win32 DirectX support (default enabled on Win32)])
3343 if test "${enable_directx}" != "no"
3344 then
3345   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3346   then
3347       VLC_ADD_LIBS([directx],[-luser32])
3348       AC_CHECK_HEADERS(ddraw.h,
3349       [ VLC_ADD_PLUGIN([directx aout_directx])
3350         VLC_ADD_LIBS([directx],[-lgdi32])
3351       ],[AC_MSG_ERROR([Cannot find DirectX headers!])]
3352       )
3353       AC_CHECK_HEADERS(GL/gl.h,
3354       [ VLC_ADD_PLUGIN([glwin32])
3355         VLC_ADD_LIBS([glwin32],[-lopengl32 -lgdi32])
3356       ])
3357       AC_CHECK_HEADERS(d3d9.h,
3358       [ VLC_ADD_PLUGIN([direct3d])
3359         VLC_ADD_LIBS([direct3d],[-lgdi32])
3360       ])
3361       VLC_ADD_LIBS([direct3d directx glwin32],[-lole32])
3362   fi
3363 fi
3364
3365 dnl
3366 dnl  Windows Direct2D plugin
3367 dnl
3368 AC_ARG_ENABLE(direct2d,
3369   [  --enable-direct2d         Win7/VistaPU Direct2D support (default auto on Win32)])
3370 if test "${enable_direct2d}" != "no"; then
3371   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3372   then
3373     AC_CHECK_HEADERS(d2d1.h,
3374       [
3375         VLC_ADD_PLUGIN([direct2d])
3376         VLC_ADD_LIBS([direct2d],[-lgdi32 -lole32])
3377       ], [AC_MSG_WARN([Cannot find Direct2D headers!])]
3378     )
3379   fi
3380 fi
3381
3382 dnl
3383 dnl  win32 GDI plugin
3384 dnl
3385 AC_ARG_ENABLE(wingdi,
3386   [  --enable-wingdi         Win32 GDI module (default enabled on Win32)])
3387 if test "${enable_wingdi}" != "no"; then
3388   if test "${SYS}" = "mingw32"; then
3389     VLC_ADD_PLUGIN([wingdi])
3390     VLC_ADD_LIBS([wingdi],[-lgdi32 -lole32])
3391   fi
3392   if test "${SYS}" = "mingwce"; then
3393     VLC_ADD_PLUGIN([wingdi wingapi])
3394     VLC_ADD_LIBS([wingdi],[-laygshell])
3395     VLC_ADD_LIBS([wingapi],[-laygshell])
3396   fi
3397 fi
3398
3399
3400 dnl
3401 dnl  Linux framebuffer module
3402 dnl
3403 AC_CHECK_HEADER([linux/fb.h], [
3404   VLC_ADD_PLUGIN([fb])
3405 ])
3406
3407
3408 dnl
3409 dnl  DirectFB module
3410 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3411 dnl  TODO: support for static linking
3412 dnl
3413 AC_ARG_ENABLE(directfb,
3414   [  --enable-directfb       DirectFB support (default disabled)])
3415 AC_ARG_WITH(directfb,
3416   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3417
3418 if test "${enable_directfb}" = "yes"; then
3419     have_directfb="false"
3420     CPPFLAGS_mydirectfb=
3421     LIBS_mydirectfb=
3422     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3423         dnl Trying the given location
3424         CPPFLAGS_save="${CPPFLAGS}"
3425         LIBS_save="${LIBS}"
3426
3427         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3428         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/"
3429         LIBS_new="${LIBS_new} -L${with_directfb}/src/.libs/"
3430
3431         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3432         LIBS="${LIBS} ${LIBS_new}"
3433
3434         dnl FIXME: too obscure
3435         AC_CHECK_HEADER([directfb.h], [
3436             AC_CHECK_LIB([direct],[direct_initialize], [
3437                 AC_CHECK_LIB([fusion], [fusion_enter], [
3438                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3439                 ], have_directfb="false")
3440             ], have_directfb="false")
3441         ], have_directfb="false")
3442
3443         dnl Restore flags
3444         CPPFLAGS="${CPPFLAGS_save}"
3445         LIBS="${LIBS_save}"
3446
3447         if test "${have_directfb}" = "true"; then
3448             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3449             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3450         fi
3451     else
3452         dnl Look for directfb-config
3453         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3454         if test "${DIRECTFB_CONFIG}" != "no"; then
3455             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3456             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3457             have_directfb="true"
3458         else
3459             dnl Trying with pkg-config
3460             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3461                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3462                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3463                 have_directfb="true"
3464                 ], [have_directfb="false"])
3465         fi
3466     fi
3467     if test "${have_directfb}" = "true"; then
3468         VLC_ADD_PLUGIN([directfb])
3469         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3470         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3471     else
3472         AC_MSG_ERROR([cannot find directfb headers and/or libraries ])
3473     fi
3474 fi
3475
3476 dnl
3477 dnl  AA plugin
3478 dnl
3479 AC_ARG_ENABLE(aa,
3480   [  --enable-aa             aalib output (default disabled)])
3481 if test "${enable_aa}" = "yes"
3482 then
3483   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3484   if test "${have_aa}" = "true"
3485   then
3486     VLC_ADD_PLUGIN([aa])
3487     VLC_ADD_LIBS([aa],[-laa])
3488     if test "${SYS}" != "mingw32"; then
3489       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3490     fi
3491   fi
3492 fi
3493
3494 dnl
3495 dnl  libcaca plugin
3496 dnl
3497 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3498
3499 dnl
3500 dnl  Audio plugins
3501 dnl
3502
3503 EXTEND_HELP_STRING([Audio plugins:])
3504
3505 dnl
3506 dnl  Pulseaudio module
3507 dnl
3508 AC_ARG_ENABLE(pulse,
3509   [AS_HELP_STRING([--enable-pulse],
3510     [use the PulseAudio client library (default auto)])])
3511 have_pulse="no"
3512 AS_IF([test "${enable_pulse}" != "no"], [
3513   PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.22], [
3514     have_pulse="yes"
3515   ], [
3516     AS_IF([test "x${enable_pulse}" != "x"], [
3517       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 0.9.22 or later required.])
3518     ])
3519   ])
3520 ])
3521 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3522
3523 dnl
3524 dnl  ALSA module
3525 dnl
3526 AC_ARG_ENABLE(alsa,
3527   [AS_HELP_STRING([--enable-alsa],
3528     [support the Advanced Linux Sound Architecture (default auto)])],, [
3529   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3530     enable_alsa="yes"
3531   ])
3532 ])
3533 have_alsa="no"
3534 AS_IF([test "${enable_alsa}" != "no"], [
3535   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.16], [
3536     have_alsa="yes"
3537   ], [
3538     AS_IF([test "x${enable_alsa}" != "x"], [
3539       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.16 or later required.])
3540     ])
3541   ])
3542 ])
3543 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3544
3545 dnl
3546 dnl  Open Sound System module
3547 dnl
3548 AC_ARG_ENABLE(oss,
3549   [AS_HELP_STRING([--enable-oss],
3550     [support the Open Sound System OSS (default enabled on BSD)])],, [
3551   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "mingwce" -o "$SYS" = "linux"], [
3552     enable_oss="no"
3553   ])
3554 ])
3555 have_oss="no"
3556 OSS_LIBS=""
3557 AS_IF([test "$enable_oss" != "no"], [
3558   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3559     have_oss="yes"
3560     AC_CHECK_LIB(ossaudio, main, [
3561       OSS_LIBS="-lossaudio"
3562     ])
3563   ])
3564 ])
3565 AC_SUBST(OSS_LIBS)
3566 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3567
3568 dnl
3569 dnl  Portaudio module
3570 dnl
3571 PKG_ENABLE_MODULES_VLC([PORTAUDIO], [], [portaudio-2.0], [Portaudio library support], [auto])
3572
3573 dnl
3574 dnl  win32 waveOut plugin
3575 dnl
3576 AC_ARG_ENABLE(waveout,
3577   [  --enable-waveout        Win32 waveOut module (default enabled on Win32)])
3578 if test "${enable_waveout}" != "no"; then
3579   if test "${SYS}" = "mingw32"; then
3580     VLC_ADD_PLUGIN([waveout])
3581     VLC_ADD_LIBS([waveout],[-lwinmm])
3582   fi
3583   if test "${SYS}" = "mingwce"; then
3584     VLC_ADD_PLUGIN([waveout])
3585   fi
3586 fi
3587
3588 dnl
3589 dnl  CoreAudio plugin
3590 dnl
3591 AC_ARG_ENABLE(macosx-audio,
3592   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3593 if test "x${enable_macosx_audio}" != "xno" &&
3594   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3595 then
3596   AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,
3597     [ VLC_ADD_PLUGIN([auhal])
3598       VLC_ADD_LDFLAGS([auhal],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,Carbon])
3599     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3600 fi
3601
3602 dnl
3603 dnl  AudioQueue plugin
3604 dnl
3605 AC_ARG_ENABLE(audioqueue,
3606   [  --enable-audioqueue       AudioQueue audio module (default disabled)])
3607 if test "${enable_audioqueue}" = "yes"
3608 then
3609   VLC_ADD_PLUGIN([audioqueue])
3610   VLC_ADD_LDFLAGS([audioqueue], [-Wl,-framework,AudioToolbox,-framework,CoreFoundation])
3611 fi
3612
3613 dnl
3614 dnl  JACK modules
3615 dnl
3616 PKG_ENABLE_MODULES_VLC([JACK], [jack access_jack], [jack], [JACK audio I/O modules],[auto])
3617
3618 dnl
3619 dnl UPnP Plugin (Intel SDK)
3620 dnl
3621 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPnp SDK],[auto])
3622 VLC_ADD_CXXFLAGS([upnp],[${UPNP_CFLAGS}])
3623
3624 dnl
3625 dnl  Interface plugins
3626 dnl
3627
3628 EXTEND_HELP_STRING([Interface plugins:])
3629
3630 dnl
3631 dnl Skins2 module
3632 dnl
3633 AC_ARG_ENABLE(libtar,
3634   [  --enable-libtar         libtar support for skins2 (default auto)])
3635 AS_IF([test "${enable_libtar}" != "no"], [
3636   AC_CHECK_HEADERS(libtar.h, [
3637     VLC_ADD_LIBS([skins2],[-ltar])
3638   ])
3639 ])
3640
3641 AC_ARG_ENABLE(skins2,
3642   [AS_HELP_STRING([--enable-skins2],[Skins2 interface module (default
3643    enabled except on MacOSX and WinCE)])],, [
3644   AS_IF([test "${SYS}" != "darwin" && test "${SYS}" != "mingwce"], [
3645     enable_skins2="yes"
3646   ], [
3647     enable_skins2="no"
3648   ])
3649 ])
3650 AS_IF([test "${enable_skins2}" = "yes"], [
3651   dnl freetype
3652   AS_IF([test "${have_freetype}" != "yes"], [
3653     AC_MSG_ERROR([Could not find FreeType (required for skins2)])
3654   ])
3655
3656   AS_IF([test "${SYS}" = "mingw32"], [
3657     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -Imodules/gui/skins2 -DWIN32_SKINS])
3658     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3659     VLC_ADD_LIBS([skins2],[-loleaut32 -lwinspool -lwinmm -lshell32 -lctl3d32 -ladvapi32 -lwsock32 -lgdi32 -lcomdlg32 -lole32 -luuid -lcomctl32  -lmsimg32 -luser32])
3660
3661   ], [test "${SYS}" = "darwin"], [
3662     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 -DMACOSX_SKINS])
3663     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3664     VLC_ADD_LDFLAGS([skins2],[-Wl,-framework,Carbon])
3665
3666   ], [
3667     PKG_CHECK_MODULES([XPM], [xpm])
3668     PKG_CHECK_MODULES([XEXT], [xext])
3669     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 ${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3670     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3671     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} -lX11])
3672
3673   ])
3674   VLC_ADD_PLUGIN([skins2])
3675   ALIASES="${ALIASES} svlc"
3676 ])
3677 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3678
3679 dnl
3680 dnl Hildon UI
3681 dnl
3682 AC_ARG_ENABLE(hildon,
3683   [  --enable-hildon         Hildon touchscreen UI (default disabled)])
3684 AS_IF([test "${enable_hildon}" = "yes"], [
3685   PKG_CHECK_MODULES(HILDON, [hildon-1], [
3686     PKG_CHECK_MODULES(HILDON_FM, hildon-fm-2, [
3687       VLC_ADD_CFLAGS([hildon],[${HILDON_FM_CFLAGS} -DHAVE_HILDON_FM])
3688       VLC_ADD_LIBS([hildon],[${HILDON_FM_LIBS}])
3689     ], [
3690       AC_MSG_WARN(hildon-fm-2 not found)
3691     ])
3692     VLC_ADD_CFLAGS([hildon],[${HILDON_CFLAGS} ${X_CFLAGS}])
3693     VLC_ADD_LIBS([hildon],[${HILDON_LIBS} ${X_LIBS} ${X_PRE_LIBS} -lX11])
3694     VLC_ADD_PLUGIN([hildon])
3695     ALIASES="${ALIASES} mvlc"
3696   ], [
3697     AS_IF([test "${enable_hildon}" = "yes"],[
3698       AC_MSG_ERROR([Hildon libraries not found])
3699     ])
3700     enable_hildon="no"
3701   ])
3702 ])
3703 AM_CONDITIONAL(BUILD_HILDON, [test "${enable_hildon}" = "yes"])
3704
3705 dnl
3706 dnl QT 4
3707 dnl
3708 AC_ARG_ENABLE(qt4,
3709   [  --enable-qt4            Qt 4 support (default enabled) ],, [
3710   AS_IF([test "${SYS}" = "darwin"], [enable_qt4=no])
3711 ])
3712 AS_IF([test "${enable_qt4}" != "no"], [
3713   PKG_CHECK_MODULES(QT4, [QtCore QtGui >= 4.4.0], [
3714     VLC_ADD_PLUGIN([qt4])
3715     VLC_ADD_LIBS([qt4],[${QT4_LIBS}])
3716     VLC_ADD_CXXFLAGS([qt4],[${QT4_CFLAGS}])
3717     ALIASES="${ALIASES} qvlc"
3718
3719     AC_LANG_PUSH([C++])
3720     CPPFLAGS_save="${CPPFLAGS}"
3721
3722     AC_MSG_CHECKING([whether Qt uses X11])
3723     CPPFLAGS="${CPPFLAGS} ${QT4_CFLAGS}"
3724     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
3725 #include <QWidget>
3726 #if !defined (Q_WS_X11)
3727 # error Fail
3728 #endif
3729     ])], [
3730       AC_MSG_RESULT([yes])
3731       VLC_ADD_LIBS([qt4],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3732       VLC_ADD_CXXFLAGS([qt4],[${X_CFLAGS}])
3733     ], [
3734       AC_MSG_RESULT([no])
3735     ])
3736
3737     CPPFLAGS="${CPPFLAGS_save}"
3738     AC_LANG_POP([C++])
3739
3740     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
3741         VLC_ADD_LIBS([qt4],[-lole32])
3742     ])
3743     AS_IF([test "${SYS}" = "darwin" ],[
3744          VLC_ADD_LDFLAGS([qt4], [-Wl,-framework,Cocoa])
3745     ])
3746     AC_PATH_PROGS(MOC, [moc-qt4 moc], moc,`eval $PKG_CONFIG --variable=exec_prefix QtCore`/bin)
3747     AC_PATH_PROG(RCC, rcc, rcc,`eval $PKG_CONFIG --variable=exec_prefix QtCore`/bin)
3748     AC_PATH_PROGS(UIC, [uic-qt4 uic], uic,`eval $PKG_CONFIG --variable=exec_prefix QtCore`/bin)
3749   ], [
3750     AS_IF([test "${enable_qt4}" = "yes"],[
3751       AC_MSG_ERROR([Qt 4 library not found])
3752     ],[
3753       AC_MSG_WARN([Qt 4 library not found])
3754     ])
3755     enable_qt4="no"
3756   ])
3757 ])
3758 AM_CONDITIONAL(ENABLE_QT4, [test "x$enable_qt4" != "xno"])
3759
3760 dnl
3761 dnl Simple test for skins2 dependency
3762 dnl
3763 AS_IF([test "${enable_skins2}" != "no" && test "x$enable_qt4" = "xno"], [
3764   AC_MSG_ERROR([The skins2 module depends on a the Qt4 development package. Without it you won't be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3765 ])
3766
3767 dnl
3768 dnl  MacOS X video output/gui modules
3769 dnl
3770 AC_ARG_ENABLE(macosx,
3771   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3772 if test "x${enable_macosx}" = "xyes"