Add a SAPI synthetizer for Windows
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2015 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2015"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
42
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
59
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
69
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
77
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, optional)
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl
98 dnl  Check the operating system
99 dnl
100 HAVE_WIN64="0"
101 HAVE_IOS="0"
102 HAVE_OSX="0"
103 HAVE_TVOS="0"
104
105 case "${host_os}" in
106   "")
107     SYS=unknown
108     ;;
109   linux*)
110     SYS=linux
111     ;;
112   bsdi*)
113     SYS=bsdi
114     CFLAGS="${CFLAGS} -pthread"
115     ;;
116   freebsd*)
117     SYS=freebsd
118     CFLAGS="${CFLAGS} -pthread"
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
121     ;;
122   openbsd*)
123     SYS=openbsd
124     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
125     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
126     ;;
127   netbsd*)
128     SYS=netbsd
129     ;;
130   dragonfly*)
131     SYS=dragonfly
132     ;;
133   darwin*)
134
135     dnl Force gcc "-arch" flag
136     ARCH_flag=""
137     case "${host}" in
138       i?86*)
139         ARCH_flag="-arch i386"
140       ;;
141       ppc64*)
142         ARCH_flag="-arch ppc64"
143       ;;
144       ppc*)
145         ARCH_flag="-arch ppc"
146       ;;
147       x86_64*)
148         ARCH_flag="-arch x86_64"
149       ;;
150       arm*)
151         ac_cv_c_bigendian="no"
152         ac_cv_c_attribute_packed="no"
153       ;;
154     esac
155
156     SYS=darwin
157     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
158     CXX="${CXX} -stdlib=libc++ -std=c++11"
159     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
160     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
161     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
162     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
163     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
164     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
165
166     AC_EGREP_CPP(yes,
167             [#import <TargetConditionals.h>
168              #if TARGET_OS_IPHONE
169              yes
170              #endif],
171              [HAVE_IOS="1"],
172              [HAVE_OSX="1"])
173
174     AC_EGREP_CPP(yes,
175             [#import <TargetConditionals.h>
176              #if TARGET_OS_TV
177              yes
178              #endif],
179              [HAVE_TVOS="1"
180              HAVE_IOS="0"
181              HAVE_OSX="0"
182              ],)
183
184     dnl Allow binaries created on Lion to run on earlier releases
185     AC_EGREP_CPP(yes,
186            [#import <Cocoa/Cocoa.h>
187             #ifdef MAC_OS_X_VERSION_10_7
188             yes
189             #endif],
190             [AC_MSG_RESULT([yes])
191             AC_LIBOBJ([getdelim])
192             AC_LIBOBJ([strndup])
193             AC_LIBOBJ([strnlen])],)
194
195     dnl
196     dnl  Handle Mac OS X SDK flags
197     dnl
198     AC_ARG_WITH(macosx-sdk,
199       [AS_HELP_STRING([--with-macosx-sdk=DIR],
200         [compile using the SDK in DIR])])
201     if test "${with_macosx_sdk}" != "" ; then
202         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
203         CPP="${CPP} -isysroot ${with_macosx_sdk}"
204         CC="${CC} -isysroot ${with_macosx_sdk}"
205         CXX="${CXX} -isysroot ${with_macosx_sdk}"
206         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
207         LD="${LD} -syslibroot ${with_macosx_sdk}"
208     fi
209     AC_ARG_WITH(macosx-version-min,
210       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
211         [compile for Mac OS X VERSION and above])])
212     if test "${with_macosx_version_min}" != "" ; then
213         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
214         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
215         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
216         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
217         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
218     fi
219     ;;
220   *mingw32* | *cygwin* | *wince* | *mingwce*)
221     AC_CHECK_TOOL(WINDRES, windres, :)
222     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
223     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
224     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
225     AH_TOP([#endif])
226     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
227     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
228     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
229     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
230     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
231     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
232     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
233     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
234     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
235     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
236     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
237
238     case "${host_os}" in
239       *mingw32*)
240         SYS=mingw32
241         ;;
242       *cygwin*)
243         dnl Check if we are using the mno-cygwin mode in which case we are
244         dnl actually dealing with a mingw32 compiler.
245         AC_EGREP_CPP(yes,
246             [#ifdef _WIN32
247              yes
248              #endif],
249             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
250         ;;
251     esac
252
253     if test "${SYS}" = "mingw32"; then
254         # DEP, ASLR, NO SEH
255         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
256
257         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
258         ac_default_prefix="`pwd`/_win32"
259         DESTDIR="`pwd`/_win32/"
260
261         dnl
262         dnl NSIS/MSI Installer prefix and WIN64
263         dnl
264         case "${host}" in
265             amd64*|x86_64*)
266                 HAVE_WIN64="1"
267                 WINDOWS_ARCH="x64"
268                 PROGRAMFILES="PROGRAMFILES64"
269             ;;
270             *)
271                 WINDOWS_ARCH="x86"
272                 PROGRAMFILES="PROGRAMFILES"
273             ;;
274         esac
275         AC_SUBST(WINDOWS_ARCH)
276         AC_SUBST(PROGRAMFILES)
277
278     fi
279     ;;
280   *nto*)
281     SYS=nto
282     ;;
283   solaris*)
284     SYS=solaris
285     ;;
286   hpux*)
287     SYS=hpux
288     ;;
289   *os2*)
290     SYS=os2
291     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
292     AC_LIBOBJ([freeaddrinfo])
293     ;;
294   *)
295     SYS="${host_os}"
296     ;;
297 esac
298 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
299 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
300 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
301 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
302 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
303 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
304 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
305 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
306
307 dnl
308 dnl Sadly autoconf does not think about testing foo.exe when ask to test
309 dnl for program foo on win32
310 case "${build_os}" in
311     cygwin|msys)
312         ac_executable_extensions=".exe"
313     ;;
314     os2*)
315         BUILDEXEEXT=".exe"
316     ;;
317     *)
318     ;;
319 esac
320 AC_SUBST(BUILDEXEEXT)
321
322 dnl Android is linux, but a bit different
323 AS_IF([test "$SYS" = linux],[
324     AC_MSG_CHECKING([for an Android system])
325     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
326         [[#ifndef __ANDROID__
327          # error Not Android
328          #endif
329         ]],[[;]])
330     ],[
331       HAVE_ANDROID="1"
332       AC_MSG_RESULT([yes])
333     ],[
334       AC_MSG_RESULT([no])
335     ])
336 ])
337 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
338
339 dnl Tizen (minimum SDK version: 2.3)
340 AS_IF([test "$SYS" = linux],[
341     AC_MSG_CHECKING([for Tizen])
342     AC_TRY_COMPILE([#include <tizen.h>
343 #if !defined(TIZEN_SDK_MAJOR) && !defined(TIZEN_SDK_MINOR)
344 # error Not Tizen
345 #endif
346 #if TIZEN_SDK_MAJOR < 2 || (TIZEN_SDK_MAJOR == 2 && TIZEN_SDK_MINOR < 3)
347 # error Tizen SDK too old
348 #endif
349     ],[],[
350       HAVE_TIZEN="1"
351       AC_MSG_RESULT([yes])
352     ],[
353       AC_MSG_RESULT([no])
354     ])
355 ])
356 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
357
358 dnl
359 dnl  Check for the contrib directory
360 dnl
361 AC_ARG_WITH(contrib,
362   [AS_HELP_STRING([--with-contrib[=DIR]],
363     [search for 3rd party libraries in DIR/include and DIR/lib])
364 ])
365 AC_MSG_CHECKING([for 3rd party libraries path])
366 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
367   CONTRIB_DIR="${srcdir}/contrib/${host}"
368   AS_IF([test ! -d "${CONTRIB_DIR}"], [
369     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
370     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
371     AS_IF([test ! -d "${CONTRIB_DIR}"], [
372       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
373       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
374       AS_IF([test ! -d "${CONTRIB_DIR}"], [
375         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
376         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
377         AS_IF([test ! -d "${CONTRIB_DIR}"], [
378           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
379           CONTRIB_DIR=""
380           AC_MSG_RESULT([not found])
381         ])
382       ])
383     ])
384   ])
385 ], [
386   AS_IF([test "${with_contrib}" != "no"], [
387     CONTRIB_DIR="${with_contrib}"
388   ], [
389     CONTRIB_DIR=""
390     AC_MSG_RESULT([disabled])
391   ])
392 ])
393 AS_IF([test -n "${CONTRIB_DIR}"], [
394   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
395     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
396   ], [
397     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
398     CONTRIB_DIR=""
399     AC_MSG_RESULT([not usable])
400   ])
401
402 ])
403 AS_IF([test -n "${CONTRIB_DIR}"], [
404   AC_MSG_RESULT([${CONTRIB_DIR}])
405   export PATH=${CONTRIB_DIR}/bin:$PATH
406   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
407   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
408   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
409   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
410   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
411   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
412
413   AS_IF([test "${SYS}" = "darwin"], [
414     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
415     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
416   ])
417 ], [
418   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
419     AC_MSG_ERROR([Third party libraries not found!])
420   ])
421 ])
422 AC_SUBST(CONTRIB_DIR)
423
424 dnl Add extras/tools to the PATH
425 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
426 AS_IF([test -d "${TOOLS_DIR}"], [
427     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
428     export PATH="${TOOLS_DIR}":$PATH
429 ])
430
431 dnl
432 dnl  Libtool
433 dnl  It's very bad, but our former custom system was worst
434 dnl  -- Courmisch
435 dnl
436
437 dnl override platform specific check for dependent libraries
438 dnl otherwise libtool linking of shared libraries will
439 dnl fail on anything other than pass_all.
440 AC_CACHE_VAL(lt_cv_deplibs_check_method,
441     [lt_cv_deplibs_check_method=pass_all])
442
443 LT_INIT([dlopen win32-dll shared disable-static])
444 LT_LANG([C++])
445 LT_LANG([Windows Resource])
446
447 DOLT
448
449 lt_cv_deplibs_check_method=pass_all
450
451 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
452   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
453 ])
454
455 dnl
456 dnl Gettext stuff
457 dnl
458 AM_GNU_GETTEXT_VERSION([0.19.4])
459 AM_GNU_GETTEXT([external], [need-ngettext])
460
461 dnl
462 dnl Iconv stuff
463 dnl
464 AM_ICONV
465
466 dnl
467 dnl checks for mingw
468 AS_IF([test "${SYS}" = "mingw32"], [
469
470 dnl Check for broken versions of mingw-runtime compatability library
471     AC_MSG_CHECKING(for broken mingw-runtime)
472     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
473 #include <_mingw.h>
474 #if defined(__MINGW64_VERSION_MAJOR)
475 # if __MINGW64_VERSION_MAJOR < 3
476 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
477 # endif
478 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
479 # error Attempting to use mingw-runtime with broken vsnprintf support
480 #endif
481     ])], [
482         AC_MSG_RESULT([ok])
483     ], [
484         AC_MSG_RESULT([present])
485         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
486     ])
487
488     dnl force use of mingw provided c99 *printf over msvcrt
489     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
490
491     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
492     VLC_ADD_LDFLAGS([vlc],[-mwindows])
493
494     dnl Check for the need to include the mingwex lib for mingw32
495     VLC_SAVE_FLAGS
496     AC_CHECK_LIB(mingwex,opendir,
497         AC_CHECK_LIB(mingw32,opendir,,
498             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
499     )
500     VLC_RESTORE_FLAGS
501
502     dnl Check for fnative-struct or mms-bitfields support for mingw32
503     VLC_SAVE_FLAGS
504     CFLAGS="${CFLAGS} -mms-bitfields"
505     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
506     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
507         [ac_cv_c_mms_bitfields],
508         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
509     if test "${ac_cv_c_mms_bitfields}" = "no"; then
510         VLC_RESTORE_FLAGS
511         CFLAGS="${CFLAGS} -fnative-struct"
512         CXXFLAGS="${CXXFLAGS} -fnative-struct"
513         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
514             [ac_cv_c_fnative_struct],
515             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
516         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
517     fi
518 ])
519
520 AC_ARG_ENABLE(winstore_app,
521      AS_HELP_STRING([--enable-winstore-app],
522                     [Build targetted for Windows Store apps (default disabled)]))
523
524 vlc_winstore_app=0
525 AS_IF([test "${SYS}" = "mingw32"],[
526   AS_IF([test "${enable_winstore_app}" = "yes"], [
527     vlc_winstore_app=1
528      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
529     ],[
530      VLC_ADD_LIBS([libvlccore],[-lwinmm])
531     ])
532   ])
533 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
534 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
535
536
537 dnl
538 dnl Buggy glibc prevention. Purposedly not cached.
539 dnl See sourceware.org bugs 5058 and 5443.
540 dnl Ubuntu alone has 20 bug numbers for this...
541 dnl
542 AC_MSG_CHECKING(for buggy GNU/libc versions)
543 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
544 #include <limits.h>
545 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
546   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
547 # error GNU/libc with dcgettext killer bug!
548 #endif
549 ])], [
550   AC_MSG_RESULT([not present])
551 ], [
552   AC_MSG_RESULT([found])
553   AS_IF([test "x${enable_nls}" != "xno"], [
554     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
555 work-around for this. Check with your distribution vendor on how to update the
556 glibc run-time. Alternatively, build with --disable-nls.])
557   ])
558 ])
559
560 dnl Plugin compilation stuff
561
562 VLC_LIBRARY_SUFFIX
563
564 dnl Check for system libs needed
565 need_libc=false
566
567 dnl Check for usual libc functions
568 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
569 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
570 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy strverscmp])
571 AC_CHECK_FUNCS(fdatasync,,
572   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
573 ])
574
575 dnl mingw64 implements those as static inline, not functions with C linkage
576 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
577 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
578 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
579 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
580
581 dnl C11 static_assert()
582 AC_MSG_CHECKING([for static_assert in assert.h])
583 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
584 static_assert(1, "The impossible happened.");
585 ])], [
586   AC_MSG_RESULT([yes])
587   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
588 ], [
589   AC_MSG_RESULT([no])
590 ])
591
592 # Windows CE does not have strcoll()
593 AC_FUNC_STRCOLL
594
595 dnl Check for non-standard system calls
596 case "$SYS" in
597   "linux")
598     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
599     ;;
600   "mingw32")
601     AC_CHECK_FUNCS([_lock_file])
602     ;;
603 esac
604
605 AH_BOTTOM([#include <vlc_fixups.h>])
606
607 dnl Check for struct pollfd
608 AC_CHECK_TYPES([struct pollfd],,,
609 [#include <sys/types.h>
610 #if HAVE_POLL
611 # include <poll.h>
612 #elif defined (_WIN32)
613 # include <winsock2.h>
614 #endif
615 ])
616
617 dnl Checks for socket stuff
618 VLC_SAVE_FLAGS
619 SOCKET_LIBS=""
620 AC_SEARCH_LIBS(connect, [socket], [
621   AS_IF([test "$ac_cv_search_connect" != "none required"], [
622     SOCKET_LIBS="$ac_cv_search_connect"
623   ])
624 ], [
625   AS_IF([test "${SYS}" = "mingw32"], [
626     SOCKET_LIBS="-lws2_32"
627   ])
628 ])
629
630 AC_SEARCH_LIBS([inet_pton], [nsl], [
631  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
632     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
633   ])
634 ],, [${SOCKET_LIBS}])
635
636 LIBS="${LIBS} ${SOCKET_LIBS}"
637 AC_LINK_IFELSE([
638     AC_LANG_PROGRAM([#ifdef _WIN32
639         # if _WIN32_WINNT < 0x600
640         #  error Needs vista+
641         # endif
642         #include <ws2tcpip.h>
643         #else
644         #include <sys/socket.h>
645         #include <arpa/inet.h>
646         #endif], [
647         char dst[[sizeof(struct in_addr)]];
648         inet_pton(AF_INET, "127.0.0.1", dst);
649     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
650 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
651 VLC_RESTORE_FLAGS
652 AC_SUBST(SOCKET_LIBS)
653
654 dnl Check for socklen_t
655 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
656 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
657 ac_cv_type_socklen_t,
658 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
659 [#include <sys/types.h>
660 #ifdef _WIN32
661 # include <winsock2.h>
662 # include <ws2tcpip.h>
663 #else
664 # include <sys/socket.h>
665 #endif]], [[socklen_t len; len = 0;]])],
666 ac_cv_type_socklen_t=yes,
667 ac_cv_type_socklen_t=no)])
668 AS_IF([test "$ac_cv_type_socklen_t" = no],
669  [AC_DEFINE(socklen_t, int)])
670
671 dnl Check for struct sockaddr_storage
672 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
673 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
674 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
675   [AC_TRY_COMPILE(
676     [#include <sys/types.h>
677      #if defined( _WIN32 )
678      # include <winsock2.h>
679      #else
680      # include <sys/socket.h>
681      #endif], [struct sockaddr_storage addr;],
682      ac_cv_struct_sockaddr_storage=yes,
683      ac_cv_struct_sockaddr_storage=no)])
684 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
685   AC_DEFINE(sockaddr_storage, sockaddr)
686   AC_DEFINE(ss_family, sa_family)
687 ])
688
689 dnl FreeBSD has a gnugetopt library for this:
690 GNUGETOPT_LIBS=""
691 AC_CHECK_FUNC(getopt_long,, [
692   AC_CHECK_LIB([gnugetopt],[getopt_long], [
693     GNUGETOPT_LIBS="-lgnugetopt"
694   ])
695 ])
696 AC_SUBST(GNUGETOPT_LIBS)
697
698 AC_CHECK_LIB(m,cos,[
699   LIBM="-lm"
700 ], [
701   LIBM=""
702 ])
703 AC_SUBST(LIBM)
704
705 AC_CHECK_LIB(m,lrintf, [
706   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
707   VLC_ADD_LIBS([skins2],[-lm])
708 ])
709 AC_CHECK_LIB(m,nanf,
710   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
711 )
712
713 dnl Check for dynamic plugins
714 LIBDL=""
715 have_dynamic_objects="no"
716 VLC_SAVE_FLAGS
717 AC_SEARCH_LIBS(dlsym, [dl svld], [
718   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
719     LIBDL="$ac_cv_search_dlsym"
720   ])
721   have_dynamic_objects="yes"
722 ])
723 VLC_RESTORE_FLAGS
724
725 # Windows
726 AS_IF([test "${SYS}" = "mingw32"], [
727   LIBDL=""
728   have_dynamic_objects="yes" #assume we can use shared objects
729 ])
730
731 AS_IF([test "${enable_shared}" = "no"], [
732   have_dynamic_objects=no
733 ])
734 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
735
736 AC_SUBST(LIBDL)
737
738 dnl Check for thread library
739 LIBPTHREAD=""
740 AS_IF([test "${SYS}" != "mingw32"], [
741   VLC_SAVE_FLAGS
742   LIBS=""
743   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
744     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
745       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
746     ])
747   ])
748   VLC_RESTORE_FLAGS
749
750   AC_CHECK_LIB(rt, clock_nanosleep, [
751     VLC_ADD_LIBS([libvlccore],[-lrt])
752   ], [
753     AC_CHECK_FUNC(nanosleep,,[
754       AC_CHECK_LIB(rt,nanosleep, [
755         VLC_ADD_LIBS([libvlccore],[-lrt])
756       ], [
757         AC_CHECK_LIB(posix4,nanosleep, [
758           VLC_ADD_LIBS([libvlccore],[-lposix4])
759         ])
760       ])
761     ])
762     dnl HP/UX port
763     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
764   ])
765 ])
766 AC_SUBST(LIBPTHREAD)
767
768 dnl
769 dnl Check for headers
770 dnl
771
772 dnl  POSIX
773 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h])
774 AC_CHECK_HEADERS([net/if.h], [], [],
775 [
776 #include <sys/types.h>
777 #include <sys/socket.h>
778 ])
779 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
780 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
781
782 dnl  BSD
783 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
784
785 dnl  GNU/Linux
786 AC_CHECK_HEADERS([getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
787
788 dnl  MacOS
789 AC_CHECK_HEADERS([xlocale.h])
790
791 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
792 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
793 AC_CHECK_TYPE(ssize_t,, [
794   AC_DEFINE(ssize_t, int)
795 ])
796
797 dnl It seems that autoconf detects pkg-config only during the first
798 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
799 dnl it is nested within a conditional block, so it was not working right.
800 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
801 AC_ARG_VAR(PKG_CONFIG_PATH,
802        [Paths where to find .pc not at the default location])
803 PKG_PROG_PKG_CONFIG()
804
805 dnl On some OS we need static linking
806 AS_IF([test -n "${PKG_CONFIG}" ],[
807     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
808         PKG_CONFIG="${PKG_CONFIG} --static"
809     ])
810 ])
811
812
813 dnl
814 dnl Check for zlib.h and -lz along with system -lminizip if available
815 dnl
816 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
817 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
818 if test "${have_zlib}" = "yes"
819 then
820   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
821   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
822     AC_CHECK_HEADERS([unzip.h], [
823       have_minizip=yes
824       MINIZIP_LIBS="-lminizip -lz"
825     ], [
826       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
827       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
828       have_minizip=no
829     ])
830   ])
831   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
832   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
833 fi
834 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
835
836
837 dnl
838 dnl Domain name i18n support via GNU libidn
839 dnl
840 PKG_CHECK_MODULES([IDN], [libidn], [
841   have_libidn="yes"
842   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
843 ], [
844   have_libidn="no"
845 ])
846
847
848 dnl Check for dbus
849 AC_ARG_ENABLE(dbus,
850   [AS_HELP_STRING([--enable-dbus],
851     [compile D-Bus message bus support (default enabled)])])
852 have_dbus="no"
853 AS_IF([test "${enable_dbus}" != "no"], [
854   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
855     have_dbus="yes"
856   ], [
857     AS_IF([test -n "${enable_dbus}"], [
858       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
859     ], [
860       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
861     ])
862   ])
863 ])
864 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
865
866
867 dnl Check for systemd
868 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
869   have_systemd="yes"
870 ], [
871   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
872 ])
873 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
874
875
876 dnl Check for ntohl, etc.
877 VLC_SAVE_FLAGS
878 CFLAGS="${CFLAGS} -Wall -Werror"
879 AC_CACHE_CHECK([for ntohl in sys/param.h],
880     [ac_cv_c_ntohl_sys_param_h],
881     [     AC_TRY_COMPILE([#include <sys/param.h>],
882         [int meuh; ntohl(meuh);],
883         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
884 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
885     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
886 fi
887 VLC_RESTORE_FLAGS
888
889 EXTEND_HELP_STRING([Optimization options:])
890 dnl
891 dnl  Compiler warnings
892 dnl
893
894 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op])
895 RDC_PROG_CC_FLAGS([-pipe])
896 AC_LANG_PUSH([C++])
897 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
898 AC_LANG_POP([C++])
899
900 dnl
901 dnl  Debugging mode
902 dnl
903 AC_ARG_ENABLE(debug,
904   [AS_HELP_STRING([--enable-debug],
905     [build with run-time assertions (default disabled)])],,
906   [enable_debug="no"])
907 AH_TEMPLATE(NDEBUG,
908             [Define to 1 if debug code should NOT be compiled])
909 AS_IF([test "${enable_debug}" != "no"], [
910   AC_CHECK_HEADERS([valgrind/valgrind.h])
911 ], [
912   AC_DEFINE(NDEBUG)
913 ])
914
915 dnl
916 dnl  Profiling
917 dnl
918 AC_ARG_ENABLE(gprof,
919   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
920   [enable_gprof="no"])
921 AS_IF([test "${enable_gprof}" != "no"], [
922   CFLAGS="${CFLAGS} -pg"
923   CXXFLAGS="${CXXFLAGS} -pg"
924   OBJCFLAGS="${OBJCFLAGS} -pg"
925   LDFLAGS="${LDFLAGS} -pg"
926 ])
927
928 AC_ARG_ENABLE(cprof,
929   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
930   [enable_cprof="no"])
931 AS_IF([test "${enable_gprof}" != "no"], [
932   CFLAGS="${CFLAGS} -finstrument-functions"
933   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
934   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
935   LDFLAGS="${LDFLAGS} -finstrument-functions"
936 ])
937
938 dnl
939 dnl  Test coverage
940 dnl
941 AC_ARG_ENABLE(coverage,
942   [AS_HELP_STRING([--enable-coverage],
943     [build for test coverage (default disabled)])],,
944   [enable_coverage="no"])
945 AS_IF([test "${enable_coverage}" != "no"], [
946   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
947   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
948   LDFLAGS="-lgcov ${LDFLAGS}"
949 ])
950
951 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
952   VLC_SAVE_FLAGS
953   CFLAGS="${CFLAGS} -fvisibility=hidden"
954   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
955   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
956   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
957                  [ac_cv_c_visibility_hidden], [
958     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
959       ac_cv_c_visibility_hidden=yes
960     ], [
961       ac_cv_c_visibility_hidden=no
962     ])
963   ])
964   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
965 ])
966
967
968 dnl
969 dnl  Enable/disable optimizations
970 dnl
971 AC_ARG_ENABLE(optimizations,
972   [AS_HELP_STRING([--disable-optimizations],
973     [disable compiler optimizations (default enabled)])],,
974   [enable_optimizations="yes"])
975
976 dnl Check for various optimization flags
977 AS_IF([test "${enable_optimizations}" != "no"], [
978
979   dnl -O3 only in production builds
980   AS_IF([test "${enable_debug}" = "no"], [
981     VLC_SAVE_FLAGS
982     CFLAGS="${CFLAGS} -O3"
983     CXXFLAGS="${CXXFLAGS} -O3"
984     OBJCFLAGS="${OBJCFLAGS} -O3"
985     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
986       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
987         ac_cv_c_o3=yes
988       ], [
989         ac_cv_c_o3=no
990       ])
991     ])
992     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
993   ])
994
995   dnl Check for -ffast-math
996   VLC_SAVE_FLAGS
997   CFLAGS="${CFLAGS} -ffast-math"
998   CXXFLAGS="${CXXFLAGS} -ffast-math"
999   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
1000   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
1001     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1002       ac_cv_c_fast_math=yes
1003     ], [
1004       ac_cv_c_fast_math=no
1005     ])
1006   ])
1007   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
1008   AH_BOTTOM([
1009 #ifndef __FAST_MATH__
1010 # ifndef _MSC_VER
1011 #  pragma STDC FENV_ACCESS OFF
1012 #  pragma STDC FP_CONTRACT ON
1013 # else
1014 #  pragma fenv_access(off)
1015 #  pragma fp_contract(on)
1016 # endif
1017 #endif
1018 ])
1019
1020   dnl Check for -funroll-loops
1021   VLC_SAVE_FLAGS
1022   CFLAGS="${CFLAGS} -funroll-loops"
1023   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1024   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1025   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1026     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1027       ac_cv_c_unroll_loops=yes
1028     ], [
1029       ac_cv_c_unroll_loops=no
1030     ])
1031   ])
1032   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1033
1034   AS_IF([test "$enable_debug" = "no"], [
1035     dnl Check for -fomit-frame-pointer
1036     VLC_SAVE_FLAGS
1037     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1038     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1039     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1040     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1041       [ac_cv_c_omit_frame_pointer], [
1042       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1043         ac_cv_c_omit_frame_pointer=yes
1044       ], [
1045         ac_cv_c_omit_frame_pointer=no
1046       ])
1047     ])
1048     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1049   ])
1050 ])
1051
1052 VLC_SAVE_FLAGS
1053 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1054 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1055   AC_TRY_LINK([],, [
1056     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1057   ], [
1058     ac_cv_ld_bsymbolic=""
1059   ])
1060 ])
1061 VLC_RESTORE_FLAGS
1062 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1063 AC_SUBST(SYMBOLIC_LDFLAGS)
1064
1065 dnl Checks for __attribute__(aligned()) directive
1066 VLC_SAVE_FLAGS
1067 CFLAGS="${CFLAGS} -Werror"
1068 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1069     [ac_cv_c_attribute_aligned],
1070     [ac_cv_c_attribute_aligned=0
1071     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1072         AC_TRY_COMPILE([],
1073         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1074         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1075     done])
1076 VLC_RESTORE_FLAGS
1077 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1078     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1079         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1080 fi
1081
1082 dnl Check for __attribute__((packed))
1083 AC_CACHE_CHECK([for __attribute__((packed))],
1084   [ac_cv_c_attribute_packed],
1085   [ac_cv_c_attribute_packed=no
1086    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1087                     [ac_cv_c_attribute_packed=yes])])
1088 if test "${ac_cv_c_attribute_packed}" != "no"; then
1089   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1090 fi
1091
1092 dnl
1093 dnl  Check the CPU
1094 dnl
1095 case "${host_cpu}" in
1096   "")
1097     ARCH=unknown
1098     ;;
1099   *)
1100     ARCH="${host_cpu}"
1101     ;;
1102 esac
1103
1104 dnl Check for backtrace() support
1105 AC_CHECK_HEADERS(execinfo.h)
1106 AC_CHECK_FUNCS(backtrace)
1107
1108 dnl
1109 dnl  default modules
1110 dnl
1111 ALIASES="${ALIASES} cvlc rvlc"
1112
1113 dnl
1114 dnl  Accelerated modules
1115 dnl
1116
1117 dnl  Check for fully working MMX intrinsics
1118 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1119 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1120 AC_ARG_ENABLE(mmx,
1121   [AS_HELP_STRING([--disable-mmx],
1122     [disable MMX optimizations (default auto)])],,[
1123   case "${host_cpu}" in
1124     i?86|x86_64)
1125       enable_mmx="yes"
1126       ;;
1127     *)
1128       enable_mmx="no"
1129       ;;
1130   esac
1131 ])
1132 have_mmx="no"
1133 have_mmxext="no"
1134 AS_IF([test "${enable_mmx}" != "no"], [
1135   ARCH="${ARCH} mmx"
1136   VLC_SAVE_FLAGS
1137   CFLAGS="${CFLAGS} -mmmx"
1138   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1139     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1140 [#include <mmintrin.h>
1141 #include <stdint.h>
1142 uint64_t frobzor;]], [
1143 [__m64 a, b, c;
1144 a = b = c = (__m64)frobzor;
1145 a = _mm_slli_pi16(a, 3);
1146 a = _mm_adds_pi16(a, b);
1147 c = _mm_srli_pi16(c, 8);
1148 c = _mm_slli_pi16(c, 3);
1149 b = _mm_adds_pi16(b, c);
1150 a = _mm_unpacklo_pi8(a, b);
1151 frobzor = (uint64_t)a;]])], [
1152       ac_cv_c_mmx_intrinsics=yes
1153     ], [
1154       ac_cv_c_mmx_intrinsics=no
1155     ])
1156   ])
1157   VLC_RESTORE_FLAGS
1158   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1159     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1160   ])
1161
1162   VLC_SAVE_FLAGS
1163   CFLAGS="${CFLAGS} -mmmx"
1164   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1165     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1166 void *p;
1167 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1168 ]])
1169     ], [
1170       ac_cv_mmx_inline=yes
1171     ], [
1172       ac_cv_mmx_inline=no
1173     ])
1174   ])
1175   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1176     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1177     have_mmx="yes"
1178   ])
1179
1180   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1181                  [ac_cv_mmxext_inline], [
1182     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1183 void *p;
1184 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1185 ]])
1186     ], [
1187       ac_cv_mmxext_inline=yes
1188     ], [
1189       ac_cv_mmxext_inline=no
1190     ])
1191   ])
1192   VLC_RESTORE_FLAGS
1193   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1194     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1195     have_mmxext="yes"
1196   ])
1197 ])
1198 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1199 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1200
1201 dnl  Check for fully workin SSE2 intrinsics
1202 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1203 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1204 AC_ARG_ENABLE(sse,
1205   [AS_HELP_STRING([--disable-sse],
1206     [disable SSE (1-4) optimizations (default auto)])],, [
1207   case "${host_cpu}" in
1208     i?86|x86_64)
1209       enable_sse=yes
1210       ;;
1211     *)
1212       enable_sse=no
1213       ;;
1214   esac
1215 ])
1216 have_sse2="no"
1217 AS_IF([test "${enable_sse}" != "no"], [
1218   ARCH="${ARCH} sse sse2"
1219
1220   VLC_SAVE_FLAGS
1221   CFLAGS="${CFLAGS} -msse2"
1222   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1223     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1224 [#include <emmintrin.h>
1225 #include <stdint.h>
1226 uint64_t frobzor;]], [
1227 [__m128i a, b, c;
1228 a = b = c = _mm_set1_epi64((__m64)frobzor);
1229 a = _mm_slli_epi16(a, 3);
1230 a = _mm_adds_epi16(a, b);
1231 c = _mm_srli_epi16(c, 8);
1232 c = _mm_slli_epi16(c, 3);
1233 b = _mm_adds_epi16(b, c);
1234 a = _mm_unpacklo_epi8(a, b);
1235 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1236       ac_cv_c_sse2_intrinsics=yes
1237     ], [
1238       ac_cv_c_sse2_intrinsics=no
1239     ])
1240   ])
1241   VLC_RESTORE_FLAGS
1242   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1243     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1244   ])
1245
1246   VLC_SAVE_FLAGS
1247   CFLAGS="${CFLAGS} -msse"
1248   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1249     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1250 void *p;
1251 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1252 ]])
1253     ], [
1254       ac_cv_sse_inline=yes
1255     ], [
1256       ac_cv_sse_inline=no
1257     ])
1258   ])
1259
1260   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1261     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1262   ])
1263
1264   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1265     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1266 void *p;
1267 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1268 ]])
1269     ], [
1270       ac_cv_sse2_inline=yes
1271     ], [
1272       ac_cv_sse2_inline=no
1273     ])
1274   ])
1275   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1276     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1277     have_sse2="yes"
1278   ])
1279
1280   # SSE3
1281   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1282     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1283 void *p;
1284 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1285 ]])
1286     ], [
1287       ac_cv_sse3_inline=yes
1288     ], [
1289       ac_cv_sse3_inline=no
1290     ])
1291   ])
1292
1293   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1294     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1295   # SSSE3
1296   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1297     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1298 void *p;
1299 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1300 ]])
1301     ], [
1302       ac_cv_ssse3_inline=yes
1303     ], [
1304       ac_cv_ssse3_inline=no
1305     ])
1306   ])
1307
1308   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1309     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1310
1311   # SSE4.1
1312   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1313                  [ac_cv_sse4_1_inline], [
1314     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1315 void *p;
1316 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1317 ]])
1318     ], [
1319       ac_cv_sse4_1_inline=yes
1320     ], [
1321       ac_cv_sse4_1_inline=no
1322     ])
1323   ])
1324
1325   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1326     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1327
1328   # SSE4.2
1329   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1330                  [ac_cv_sse4_2_inline], [
1331     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1332 void *p;
1333 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1334 ]])
1335     ], [
1336       ac_cv_sse4_2_inline=yes
1337     ], [
1338       ac_cv_sse4_2_inline=no
1339     ])
1340   ])
1341
1342   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1343     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1344
1345   # SSE4A
1346   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1347     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1348 void *p;
1349 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1350 ]])
1351     ], [
1352       ac_cv_sse4a_inline=yes
1353     ], [
1354       ac_cv_sse4a_inline=no
1355     ])
1356   ])
1357   VLC_RESTORE_FLAGS
1358   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1359     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1360 ])
1361 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1362
1363 VLC_SAVE_FLAGS
1364 CFLAGS="${CFLAGS} -mmmx"
1365 have_3dnow="no"
1366 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1367   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1368 void *p;
1369 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1370 ]])
1371   ], [
1372     ac_cv_3dnow_inline=yes
1373   ], [
1374     ac_cv_3dnow_inline=no
1375   ])
1376 ])
1377 VLC_RESTORE_FLAGS
1378 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1379   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1380             [Define to 1 if 3D Now! inline assembly is available.])
1381   have_3dnow="yes"
1382 ])
1383 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1384
1385
1386 AC_ARG_ENABLE(neon,
1387   [AS_HELP_STRING([--disable-neon],
1388     [disable NEON optimizations (default auto)])],, [
1389   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1390 ])
1391 AS_IF([test "${enable_neon}" != "no"], [
1392   VLC_SAVE_FLAGS
1393   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1394   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1395     AC_COMPILE_IFELSE([
1396       AC_LANG_PROGRAM(,[[
1397 asm volatile("vqmovun.s64 d0, q1":::"d0");
1398 ]])
1399     ], [
1400       ac_cv_arm_neon="yes"
1401     ], [
1402       ac_cv_arm_neon="no"
1403     ])
1404   ])
1405   VLC_RESTORE_FLAGS
1406 ])
1407 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1408
1409
1410 AC_ARG_ENABLE(altivec,
1411   [AS_HELP_STRING([--disable-altivec],
1412     [disable AltiVec optimizations (default auto)])],, [
1413   AS_CASE("${host_cpu}", [powerpc*],
1414         [enable_altivec=yes], [enable_altivec=no])
1415 ])
1416 have_altivec="no"
1417 ALTIVEC_CFLAGS=""
1418 AS_IF([test "${enable_altivec}" = "yes"], [
1419   ARCH="${ARCH} altivec";
1420   VLC_SAVE_FLAGS
1421   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1422     [ac_cv_altivec_inline],
1423     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1424          ac_cv_altivec_inline="yes",
1425          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1426           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1427             [ac_cv_altivec_inline="-Wa,-maltivec"],
1428             ac_cv_altivec_inline=no)
1429          ])])
1430   VLC_RESTORE_FLAGS
1431   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1432     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1433               [Define to 1 if AltiVec inline assembly is available.])
1434     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1435       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1436       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1437     ])
1438     have_altivec="yes"
1439   ])
1440
1441   VLC_SAVE_FLAGS
1442   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1443   [ac_cv_c_altivec], [
1444     CFLAGS="${CFLAGS} -maltivec"
1445     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1446 [#include <altivec.h>]], [
1447 [vec_ld(0, (unsigned char *)0);]])], [
1448       ac_cv_c_altivec="-maltivec"
1449     ], [
1450       ac_cv_c_altivec="no"
1451     ])
1452   ])
1453   VLC_RESTORE_FLAGS
1454   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1455     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1456     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1457     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1458     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1459     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1460     have_altivec="yes"
1461   ])
1462   AC_CHECK_HEADERS(altivec.h)
1463
1464   VLC_SAVE_FLAGS
1465   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1466   AC_CACHE_CHECK([if linker needs -framework vecLib],
1467     [ac_cv_ld_altivec],
1468     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1469   VLC_RESTORE_FLAGS
1470   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1471     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1472   ])
1473 ])
1474 AC_SUBST(ALTIVEC_CFLAGS)
1475 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1476
1477 dnl
1478 dnl  Memory usage
1479 dnl
1480 AC_ARG_ENABLE(optimize-memory,
1481   [AS_HELP_STRING([--enable-optimize-memory],
1482     [optimize memory usage over performance])])
1483 if test "${enable_optimize_memory}" = "yes"; then
1484   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1485 fi
1486
1487 dnl
1488 dnl Allow running as root (useful for people running on embedded platforms)
1489 dnl
1490 AC_ARG_ENABLE(run-as-root,
1491   [AS_HELP_STRING([--enable-run-as-root],
1492     [allow running VLC as root (default disabled)])])
1493 AS_IF([test "${enable_run_as_root}" = "yes"],[
1494     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1495               [Define to 1 to allow running VLC as root (uid 0).])
1496 ])
1497
1498 dnl
1499 dnl Stream output
1500 dnl
1501 AC_ARG_ENABLE(sout,
1502   [AS_HELP_STRING([--disable-sout],
1503     [disable streaming output (default enabled)])])
1504 AS_IF([test "${enable_sout}" != "no"], [
1505   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1506 ])
1507 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1508
1509 dnl Lua modules
1510 AC_ARG_ENABLE(lua,
1511   [AS_HELP_STRING([--disable-lua],
1512     [disable LUA scripting support (default enabled)])])
1513 if test "${enable_lua}" != "no"
1514 then
1515   PKG_CHECK_MODULES(LUA, lua5.2,
1516     [ have_lua=yes ],
1517     [
1518     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1519
1520     PKG_CHECK_MODULES(LUA, lua5.1,
1521       [ have_lua=yes ],
1522       [
1523       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1524       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1525         [ have_lua=yes ],
1526         [
1527           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1528           have_lua=yes
1529           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1530             [],
1531             [ have_lua=no ] )
1532           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1533             [LUA_LIBS="-llua5.2"],
1534           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1535             [LUA_LIBS="-llua5.1"],
1536             AC_CHECK_LIB( lua51 , luaL_newstate,
1537               [LUA_LIBS="-llua51"],
1538               AC_CHECK_LIB( lua , luaL_newstate,
1539                 [LUA_LIBS="-llua"],
1540                 [ have_lua=no
1541                 ], [-lm])
1542             )))
1543         ])
1544       ])
1545     ])
1546   if test "x${have_lua}" != "xyes" ;  then
1547       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1548   fi
1549   AC_ARG_VAR([LUAC], [LUA byte compiler])
1550   AC_CHECK_PROGS(LUAC, [${LUAC} luac], [false])
1551   AS_IF([test "${LUAC}" = "false"], [
1552     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1553   ])
1554   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1555     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1556   ])
1557 fi
1558 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1559
1560
1561 dnl
1562 dnl HTTP daemon
1563 dnl
1564 AC_ARG_ENABLE(httpd,
1565   [AS_HELP_STRING([--disable-httpd],
1566     [disable the built-in HTTP server (default enabled)])])
1567 if test "${enable_httpd}" != "no"
1568 then
1569   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1570 fi
1571 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1572
1573
1574 dnl
1575 dnl VideoLAN manager
1576 dnl
1577 AC_ARG_ENABLE(vlm,
1578   [AS_HELP_STRING([--disable-vlm],
1579     [disable the stream manager (default enabled)])],,
1580   [enable_vlm="${enable_sout}"])
1581 AS_IF([test "${enable_vlm}" != "no"], [
1582   AS_IF([test "${enable_sout}" = "no"], [
1583     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1584   ])
1585   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1586 ])
1587 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1588
1589
1590 dnl
1591 dnl Addons manager storage and repositories modules
1592 dnl
1593 AC_ARG_ENABLE(addonmanagermodules,
1594   [AS_HELP_STRING([--disable-addonmanagermodules],
1595     [disable the addons manager modules (default enabled)])])
1596 if test "${enable_addonmanagermodules}" != "no"
1597 then
1598   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1599 fi
1600 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1601
1602
1603 dnl
1604 dnl  Input plugins
1605 dnl
1606
1607 EXTEND_HELP_STRING([Input plugins:])
1608
1609 dnl
1610 dnl  libarchive access module
1611 dnl
1612 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1613
1614 dnl
1615 dnl  live555 input
1616 dnl
1617 AC_ARG_ENABLE(live555,
1618   [AS_HELP_STRING([--enable-live555],
1619     [enable RTSP input through live555 (default enabled)])])
1620
1621 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1622   PKG_CHECK_MODULES(LIVE555, live555, [
1623     VLC_ADD_PLUGIN([live555])
1624     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1625     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1626   ], [
1627     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1628
1629     AC_LANG_PUSH(C++)
1630     VLC_SAVE_FLAGS
1631
1632     dnl detect include paths
1633     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1634       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1635     ], [
1636       AS_IF([test "${SYS}" != "os2"], [
1637         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1638         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1639       ], [
1640         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1641         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1642         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1643       ])
1644     ])
1645
1646     dnl CPP Flags
1647     AS_IF([test "${SYS}" = "solaris"], [
1648       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1649     ])
1650     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1651     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1652
1653     dnl version check
1654     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1655       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1656 [#include <liveMedia_version.hh>
1657 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1658 # error BOOM
1659 #endif]])
1660       ], [
1661         ac_cv_live555="yes"
1662       ], [
1663         ac_cv_live555="no"
1664       ])
1665     ])
1666
1667     AS_IF([test "$ac_cv_live555" = "no"], [
1668       AC_MSG_WARN([live555 is missing or its installed version is too old:
1669 Version 2011.12.23 or later is required to proceed.
1670 You can get an updated one from http://www.live555.com/liveMedia .])
1671       AS_IF([test -n "${enable_live555}"], [
1672         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1673       ])
1674     ], [
1675       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1676       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1677       AS_IF([test "${SYS}" = "mingw32"], [
1678         # add ws2_32 for closesocket, select, recv
1679         other_libs="$other_libs -lws2_32"
1680       ])
1681
1682       dnl We need to check for pic because live555 don't provide shared libs
1683       dnl and we want to build a plugins so we need -fPIC on some arch.
1684       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1685       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1686       AC_CHECK_LIB(liveMedia_pic, main, [
1687         VLC_ADD_PLUGIN([live555])
1688         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1689       ],[
1690         AC_CHECK_LIB(liveMedia, main, [
1691           VLC_ADD_PLUGIN([live555])
1692           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1693         ],[],[${other_libs}])
1694       ],[${other_libs_pic}])
1695     ])
1696     VLC_RESTORE_FLAGS
1697     AC_LANG_POP(C++)
1698   ])
1699 ])
1700
1701 dnl
1702 dnl IIDC and DV FireWire input modules
1703 dnl
1704 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1705 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1706
1707 dnl
1708 dnl - linsys modules: access module check for libzvbi
1709 dnl
1710 AC_ARG_ENABLE(linsys,
1711   [AS_HELP_STRING([--enable-linsys],
1712     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1713 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1714   VLC_ADD_PLUGIN([linsys_hdsdi])
1715   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1716     VLC_ADD_PLUGIN([linsys_sdi])
1717   ], [
1718     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1719   ])
1720 ])
1721
1722 dnl
1723 dnl dvdread module: check for libdvdread
1724 dnl
1725 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1726
1727 dnl
1728 dnl libdvdnav plugin
1729 dnl
1730 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1731 AS_IF([test "${enable_dvdnav}" != "no"], [
1732   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1733     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1734       AC_MSG_RESULT(yes)
1735       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1736       ],[
1737       AC_MSG_RESULT(no)
1738     ])
1739 ])
1740
1741 dnl
1742 dnl  Blu-ray Disc Support with libbluray
1743 dnl
1744 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1745
1746 dnl
1747 dnl  OpenCV wrapper and example filters
1748 dnl
1749 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1750
1751
1752 dnl
1753 dnl  libsmbclient plugin
1754 dnl
1755 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1756 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([smb]) ])
1757
1758 dnl
1759 dnl  liBDSM access module
1760 dnl
1761 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.0.4], [libdsm SMB/CIFS access/sd module], [auto])
1762
1763 dnl
1764 dnl sftp access support
1765 dnl
1766 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1767
1768 dnl
1769 dnl  Video4Linux 2
1770 dnl
1771 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1772   [disable Video4Linux version 2 (default auto)])])
1773 have_v4l2="no"
1774 AS_IF([test "$enable_v4l2" != "no"], [
1775   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1776     have_v4l2="yes"
1777   ])
1778 ])
1779 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1780
1781 dnl
1782 dnl special access module for Blackmagic SDI cards
1783 dnl
1784 AC_ARG_ENABLE(decklink,
1785   [AS_HELP_STRING([--disable-decklink],
1786     [disable Blackmagic DeckLink SDI input (default auto)])])
1787 AC_ARG_WITH(decklink_sdk,
1788   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1789     [                        location of Blackmagic DeckLink SDI SDK])])
1790 have_decklink=no
1791 if test "${enable_decklink}" != "no"
1792 then
1793   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1794   then
1795     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1796   fi
1797   VLC_SAVE_FLAGS
1798   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1799   AC_LANG_PUSH(C++)
1800   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1801       have_decklink=yes
1802   ], [
1803       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1804   ])
1805   AC_LANG_POP(C++)
1806   VLC_RESTORE_FLAGS
1807 fi
1808 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1809
1810
1811 dnl
1812 dnl  VCDX modules
1813 dnl
1814 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1815
1816 dnl
1817 dnl  Built-in CD-DA and VCD module
1818 dnl
1819 AC_ARG_ENABLE(vcd,
1820   [AS_HELP_STRING([--disable-vcd],
1821     [disable built-in VCD and CD-DA support (default enabled)])])
1822
1823 AC_ARG_ENABLE(libcddb,
1824   [AS_HELP_STRING([--disable-libcddb],
1825     [disable CDDB for Audio CD (default enabled)])])
1826
1827 if test "${enable_vcd}" != "no"
1828 then
1829   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1830   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1831     AC_MSG_RESULT(yes)
1832     VLC_ADD_PLUGIN([vcd cdda])
1833   ],[
1834     AC_MSG_RESULT(no)
1835   ])
1836
1837   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1838   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1839     AC_MSG_RESULT(yes)
1840     VLC_ADD_PLUGIN([vcd cdda])
1841     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1842   ],[
1843     AC_MSG_RESULT(no)
1844   ])
1845
1846   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1847   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1848     AC_MSG_RESULT(yes)
1849     VLC_ADD_PLUGIN([vcd cdda])
1850     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1851   ],[
1852     AC_MSG_RESULT(no)
1853   ])
1854
1855   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1856   then
1857     VLC_ADD_PLUGIN([vcd cdda])
1858   fi
1859
1860   if test "$enable_libcddb" != "no"; then
1861     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1862       HAVE_LIBCDDB=yes
1863       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1864       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1865       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1866       ],:
1867       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1868       HAVE_LIBCDDB=no])
1869   fi
1870 fi
1871
1872 dnl
1873 dnl Linux DVB
1874 dnl
1875 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1876   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1877 [#include <linux/dvb/version.h>
1878 #if (DVB_API_VERSION < 5)
1879 # error Linux DVB API v3.2 and older are not supported.
1880 #endif
1881 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1882 # error Linux DVB API v5.0 is unsupported. Please update.
1883 #endif
1884 ]])], [
1885   ac_cv_linux_dvb_5_1=yes
1886 ], [
1887   ac_cv_linux_dvb_5_1=no
1888 ])])
1889 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1890
1891 dnl
1892 dnl  Screen capture module
1893 dnl
1894 AC_ARG_ENABLE(screen,
1895   [AS_HELP_STRING([--enable-screen],
1896     [disable screen capture (default enabled)])])
1897 if test "${enable_screen}" != "no"; then
1898   if test "${SYS}" = "darwin"; then
1899     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1900       VLC_ADD_PLUGIN([screen])
1901     ])
1902   fi
1903 fi
1904 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1905
1906 dnl
1907 dnl  VNC/RFB access module
1908 dnl
1909 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1910
1911 dnl  RDP/Remote Desktop access module
1912 dnl
1913 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1914
1915 dnl
1916 dnl  Real RTSP plugin
1917 dnl
1918 AC_ARG_ENABLE(realrtsp,
1919   [  --enable-realrtsp       Real RTSP module (default disabled)])
1920 if test "${enable_realrtsp}" = "yes"; then
1921   VLC_ADD_PLUGIN([access_realrtsp])
1922 fi
1923
1924 dnl
1925 dnl MacOS eyeTV
1926 AC_ARG_ENABLE(macosx-eyetv,
1927   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1928 if test "x${enable_macosx_eyetv}" != "xno" &&
1929   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1930 then
1931   VLC_ADD_PLUGIN([access_eyetv])
1932 fi
1933
1934 dnl
1935 dnl QTKit
1936 AC_ARG_ENABLE(macosx-qtkit,
1937   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X)])
1938 if test "x${enable_macosx_qtkit}" != "xno" &&
1939   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1940 then
1941   VLC_ADD_PLUGIN([qtsound])
1942 fi
1943 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1944
1945 dnl
1946 dnl AVFoundation
1947 AC_SUBST(have_avfoundation, ["no"])
1948 AC_ARG_ENABLE(macosx-avfoundation,
1949   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1950 if test "x${enable_macosx_avfoundation}" != "xno" &&
1951   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1952 then
1953   SAVED_LIBS="${LIBS}"
1954   LIBS="-framework AVFoundation"
1955   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1956   LIBS="${SAVED_LIBS}"
1957   if test "${have_avfoundation}" != "no"
1958   then
1959     VLC_ADD_PLUGIN([avcapture])
1960   fi
1961 fi
1962 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1963
1964 dnl
1965 dnl  DCP plugin (using asdcplib)
1966 dnl
1967 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1968 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1969
1970 dnl
1971 dnl  Demux plugins
1972 dnl
1973
1974 EXTEND_HELP_STRING([Mux/Demux plugins:])
1975
1976 dnl
1977 dnl  libdvbpsi check for ts mux/demux
1978 dnl
1979 have_dvbpsi="no"
1980 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.0.0], [have_dvbpsi="yes"])
1981 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1982
1983
1984 dnl
1985 dnl  GME demux plugin
1986 dnl
1987 AC_ARG_ENABLE(gme,
1988   [AS_HELP_STRING([--enable-gme],
1989     [use Game Music Emu (default auto)])])
1990 AS_IF([test "${enable_gme}" != "no"], [
1991   AC_CHECK_HEADER([gme/gme.h], [
1992     VLC_ADD_LIBS([gme], [-lgme])
1993     VLC_ADD_PLUGIN([gme])
1994   ], [
1995     AS_IF([test "x${enable_gme}" != "x"], [
1996       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1997     ])
1998   ])
1999 ])
2000
2001
2002 dnl
2003 dnl  SIDPlay plugin
2004 dnl
2005 AC_ARG_ENABLE(sid,
2006     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2007 AS_IF([test "${enable_sid}" != "no"], [
2008     PKG_CHECK_MODULES(SID, [libsidplay2], [
2009         AC_LANG_PUSH(C++)
2010         oldCPPFLAGS="$CPPFLAGS"
2011         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2012         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2013             VLC_ADD_PLUGIN([sid])
2014             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2015             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2016         ], [
2017             AS_IF([test -n "${enable_sid}"],
2018                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2019                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2020                 )
2021         ])
2022         CPPFLAGS="$oldCPPFLAGS"
2023         AC_LANG_POP(C++)
2024     ], [
2025         AS_IF([test "x${enable_sid}" = "xyes"],
2026             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2027             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2028             )
2029     ])
2030 ])
2031
2032
2033 dnl
2034 dnl  ogg demux plugin
2035 dnl
2036 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2037 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2038     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2039 ],[true])
2040 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2041 if test "${enable_sout}" != "no"; then
2042 dnl Check for libshout
2043     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2044 fi
2045
2046 dnl
2047 dnl  matroska demux plugin
2048 dnl
2049 AC_ARG_ENABLE(mkv,
2050   [AS_HELP_STRING([--disable-mkv],
2051     [do not use libmatroska (default auto)])])
2052 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2053   AC_LANG_PUSH(C++)
2054   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2055     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2056     AC_EGREP_CPP(yes,
2057       [#include <ebml/EbmlVersion.h>
2058        #ifdef LIBEBML_VERSION
2059        #if LIBEBML_VERSION >= 0x010000
2060        yes
2061        #endif
2062        #endif],
2063       [AC_MSG_RESULT([yes])
2064         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2065           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2066           AC_EGREP_CPP(yes,
2067             [#include <matroska/KaxVersion.h>
2068              #ifdef LIBMATROSKA_VERSION
2069              #if LIBMATROSKA_VERSION >= 0x010000
2070              yes
2071              #endif
2072              #endif],
2073             [AC_MSG_RESULT([yes])
2074               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2075               AC_CHECK_LIB(ebml_pic, main, [
2076                 VLC_ADD_PLUGIN([mkv])
2077                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2078               ],[
2079                 AC_CHECK_LIB(ebml, main, [
2080                   VLC_ADD_PLUGIN([mkv])
2081                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2082                 ])
2083               ])
2084             ], [
2085               AC_MSG_RESULT([no])
2086               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2087           ])
2088         ])
2089       ],
2090       [AC_MSG_RESULT([no])
2091         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2092     ])
2093   ])
2094   AC_LANG_POP(C++)
2095 fi
2096
2097 dnl
2098 dnl  modplug demux plugin
2099 dnl
2100 AC_ARG_ENABLE(mod,
2101   [AS_HELP_STRING([--disable-mod],
2102     [do not use libmodplug (default auto)])])
2103 if test "${enable_mod}" != "no" ; then
2104     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2105           VLC_ADD_PLUGIN([mod])
2106           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2107           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2108           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2109     ],[
2110        AS_IF([test -n "${enable_mod}"],
2111          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2112          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2113     ])
2114 fi
2115
2116 dnl
2117 dnl  mpc demux plugin
2118 dnl
2119 AC_ARG_ENABLE(mpc,
2120   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2121 if test "${enable_mpc}" != "no"
2122 then
2123   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2124     VLC_ADD_PLUGIN([mpc])
2125     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2126     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2127     VLC_ADD_PLUGIN([mpc])
2128     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2129 fi
2130
2131 dnl
2132 dnl  Codec plugins
2133 dnl
2134
2135 EXTEND_HELP_STRING([Codec plugins:])
2136
2137 dnl
2138 dnl wmafixed plugin
2139 dnl
2140 AC_ARG_ENABLE(wma-fixed,
2141   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2142 if test "${enable_wma_fixed}" = "yes"
2143 then
2144   VLC_ADD_PLUGIN([wma_fixed])
2145 fi
2146
2147 dnl
2148 dnl shine encoder plugin
2149 dnl
2150 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2151
2152
2153 dnl
2154 dnl openmax il codec plugin
2155 dnl
2156 AC_ARG_ENABLE(omxil,
2157   [  --enable-omxil          openmax il codec module (default disabled)])
2158 if test "${enable_omxil}" = "yes"
2159 then
2160   VLC_ADD_PLUGIN([omxil])
2161 fi
2162
2163 dnl
2164 dnl openmax il vout plugin
2165 dnl
2166 AC_ARG_ENABLE(omxil-vout,
2167   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2168 if test "${enable_omxil_vout}" = "yes"
2169 then
2170   VLC_ADD_PLUGIN([omxil_vout])
2171 fi
2172
2173 dnl
2174 dnl raspberry pi openmax il configuration
2175 dnl
2176 AC_ARG_ENABLE(rpi-omxil,
2177   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2178 if test "${enable_rpi_omxil}" = "yes"
2179 then
2180   VLC_ADD_PLUGIN([omxil omxil_vout])
2181   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2182 fi
2183
2184 dnl
2185 dnl CrystalHD codec plugin
2186 dnl
2187 AC_ARG_ENABLE(crystalhd,
2188   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2189 if test "${enable_crystalhd}" != "no"; then
2190     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2191       VLC_ADD_PLUGIN([crystalhd])
2192       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2193     ],[
2194       if test "${SYS}" = "mingw32" ; then
2195         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2196           VLC_ADD_PLUGIN([crystalhd])
2197           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2198             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2199             ])
2200         ],[
2201           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2202                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2203                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2204         ],[#define __LINUX_USER__
2205                #include <libcrystalhd/bc_dts_types.h>
2206         ])
2207       fi
2208     ],[
2209        #include <libcrystalhd/bc_dts_types.h>
2210       ])
2211 fi
2212
2213 dnl
2214 dnl  mad plugin
2215 dnl
2216 have_mad="no"
2217 MAD_CFLAGS=""
2218 MAD_LIBS=""
2219
2220 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2221   enable_mad="yes"
2222 ], [
2223   with_mad="no"
2224 ])
2225 AS_IF([test "${with_mad}" != "no"], [
2226   MAD_CFLAGS="-I${with_mad}/include"
2227   MAD_LIBS="-L${with_mad}/lib"
2228 ])
2229
2230 AC_ARG_ENABLE(mad,
2231   [  --enable-mad            libmad module (default enabled)])
2232 AS_IF([test "${enable_mad}" != "no"], [
2233   VLC_SAVE_FLAGS
2234   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2235   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2236   AC_CHECK_HEADERS(mad.h, [
2237     AC_CHECK_LIB(mad, mad_bit_init, [
2238       have_mad="yes"
2239       MAD_LIBS="${MAD_LIBS} -lmad"
2240     ])
2241   ])
2242   VLC_RESTORE_FLAGS
2243   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2244     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2245   ])
2246 ])
2247 AC_SUBST(MAD_CFLAGS)
2248 AC_SUBST(MAD_LIBS)
2249 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2250
2251 dnl  mpg123 plugin
2252 dnl
2253 dnl
2254 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2255
2256
2257 AC_ARG_ENABLE(merge-ffmpeg,
2258 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2259   enable_merge_ffmpeg="no"
2260 ])
2261 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2262
2263 AC_MSG_CHECKING([for libavutil variant])
2264 PKG_CHECK_EXISTS([libavutil], [
2265   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2266   libavutil_micro="${libavutil_version##*.}"
2267   AS_IF([test ${libavutil_micro} -le 99], [
2268     avfork="libav"
2269   ], [
2270     avfork="ffmpeg"
2271   ])
2272 ], [
2273   avfork="none"
2274 ])
2275 AC_MSG_RESULT([${avfork}])
2276
2277 dnl
2278 dnl gstreamer stuff
2279 dnl
2280 AC_ARG_ENABLE(gst-decode,
2281   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2282
2283 have_gst_decode="no"
2284 AS_IF([test "${enable_gst_decode}" != "no"], [
2285   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2286     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2287       have_gst_decode="yes"
2288     ], [
2289       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2290     ])
2291   ], [
2292     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2293   ])
2294 ])
2295 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2296
2297 dnl
2298 dnl  avcodec decoder/encoder plugin
2299 dnl
2300 AC_ARG_ENABLE(avcodec,
2301 [  --enable-avcodec        libavcodec codec (default enabled)])
2302 AS_IF([test "${enable_avcodec}" != "no"], [
2303   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 55.0.0 libavutil >= 52.0.0], [
2304     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2305     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2306     dnl ])
2307     VLC_SAVE_FLAGS
2308     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2309     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2310     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2311     AC_CHECK_HEADERS(libavutil/avutil.h)
2312     VLC_RESTORE_FLAGS
2313     have_avcodec="yes"
2314   ],[
2315     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2316   ])
2317 ], [
2318   have_avcodec="no"
2319 ])
2320 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2321
2322 dnl
2323 dnl libva needs avcodec
2324 dnl
2325 AC_ARG_ENABLE(libva,
2326   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2327
2328 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2329   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2330 ])
2331
2332 have_vaapi="no"
2333 have_vaapi_drm="no"
2334 have_vaapi_x11="no"
2335 AS_IF([test "${enable_libva}" != "no"], [
2336   PKG_CHECK_EXISTS([libva], [
2337     have_vaapi="yes"
2338   ], [
2339     AS_IF([test -n "${enable_libva}"], [
2340       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2341     ], [
2342       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2343     ])
2344   ])
2345   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2346     have_vaapi_drm="yes"
2347   ], [
2348     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2349   ])
2350   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2351     have_vaapi_x11="yes"
2352   ], [
2353     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2354   ])
2355 ])
2356 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2357 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2358
2359 have_avcodec_vaapi="no"
2360 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2361   VLC_SAVE_FLAGS
2362   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2363   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2364   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2365     AC_MSG_NOTICE([VAAPI acceleration activated])
2366     have_avcodec_vaapi="yes"
2367   ],[
2368     AS_IF([test -n "${enable_libva}"], [
2369       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2370     ], [
2371       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2372     ])
2373   ])
2374   VLC_RESTORE_FLAGS
2375 ])
2376 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2377
2378 dnl
2379 dnl dxva2 needs avcodec
2380 dnl
2381 AC_ARG_ENABLE(dxva2,
2382   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2383
2384 have_avcodec_dxva2="no"
2385 AS_IF([test "${enable_dxva2}" != "no"], [
2386   if test "${SYS}" = "mingw32"; then
2387   AS_IF([test "x${have_avcodec}" = "xyes"], [
2388     AC_CHECK_HEADERS(dxva2api.h,
2389       [
2390         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2391            AC_MSG_NOTICE([DxVA2 acceleration activated])
2392            have_avcodec_dxva2="yes"
2393         ],[
2394     AS_IF([test "${enable_dxva2}" = "yes"],
2395           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2396               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2397         ], [#undef _WIN32_WINNT
2398             /* DXVA2 is only available in Vista and above */
2399             #define _WIN32_WINNT 0x600])
2400       ],[
2401     AS_IF([test "${enable_dxva2}" = "yes"],
2402               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2403               [AC_MSG_WARN([dxva2api.h not found])])
2404       ])
2405   ],[
2406     AS_IF([test "x${enable_dxva2}" != "x"], [
2407       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2408     ])
2409   ])
2410   fi
2411 ])
2412 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2413
2414 dnl
2415 dnl d3d11va needs avcodec
2416 dnl
2417 AC_ARG_ENABLE(d3d11va,
2418   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2419
2420 have_avcodec_d3d11va="no"
2421 AS_IF([test "${enable_d3d11va}" != "no"], [
2422   if test "${SYS}" = "mingw32"; then
2423   AS_IF([test "x${have_avcodec}" = "xyes"], [
2424         AC_CHECK_TYPES([ID3D11VideoDecoder],
2425           [
2426             AC_CHECK_HEADERS(dxva2api.h,
2427               [
2428                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2429                    AC_MSG_NOTICE([D3D11 acceleration activated])
2430                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2431                    have_avcodec_d3d11va="yes"
2432                 ],[
2433                   AS_IF([test "${enable_d3d11va}" = "yes"],
2434                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2435                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2436                   ], [#undef _WIN32_WINNT
2437                       /* D3D11 is only available in Vista and above */
2438                       #define _WIN32_WINNT 0x600])
2439                   ],[
2440                     AS_IF([test "${enable_d3d11va}" = "yes"],
2441                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2442                           [AC_MSG_WARN([dxva2api.h not found])])
2443                   ])
2444           ],[
2445             AS_IF([test "${enable_d3d11va}" = "yes"],
2446                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2447                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2448           ], [#include <d3d11.h>])
2449   ],[
2450     AS_IF([test "x${enable_d3d11va}" != "x"], [
2451       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2452     ])
2453   ])
2454   fi
2455 ])
2456 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2457
2458 dnl
2459 dnl DXGI debug
2460 dnl
2461 AC_CHECK_HEADERS(dxgidebug.h)
2462
2463 dnl
2464 dnl vda needs avcodec
2465 dnl
2466 AC_ARG_ENABLE(vda,
2467   [  --enable-vda          VDA  support (default auto)])
2468
2469 have_avcodec_vda="no"
2470 AS_IF([test "${enable_vda}" != "no"], [
2471   if test "${SYS}" = "darwin"; then
2472   AS_IF([test "x${have_avcodec}" = "xyes"], [
2473     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2474       [
2475         AC_CHECK_HEADERS(libavcodec/vda.h, [
2476            have_avcodec_vda="yes"
2477         ],[
2478         AS_IF([test "${enable_vda}" = "yes"],
2479               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2480               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2481         ])
2482   ],[
2483         AS_IF([test "${enable_vda}" = "yes"],
2484               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2485               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2486       ])
2487   ],[
2488     AS_IF([test "x${enable_vda}" != "x"], [
2489       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2490     ])
2491  ])
2492  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2493      SAVE_LIBS=$LIBS
2494      LIBS="$LIBS $AVCODEC_LIBS"
2495      AC_CHECK_FUNCS([av_vda_alloc_context])
2496      LIBS=$SAVE_LIBS
2497  ])
2498  fi
2499 ])
2500 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2501
2502 dnl
2503 dnl  avformat demuxer/muxer plugin
2504 dnl
2505
2506 AC_ARG_ENABLE(avformat,
2507 [  --enable-avformat       libavformat containers (default enabled)],, [
2508   enable_avformat="${have_avcodec}"
2509 ])
2510 have_avformat="no"
2511 AS_IF([test "${enable_avformat}" != "no"], [
2512   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2513       have_avformat="yes"
2514       VLC_SAVE_FLAGS
2515       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2516       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2517       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2518       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2519       AC_CHECK_HEADERS(libavutil/avutil.h)
2520       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2521         have_avformat="no"
2522       ])
2523       VLC_RESTORE_FLAGS
2524     ],[
2525       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2526   ])
2527 ])
2528 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2529
2530 dnl
2531 dnl  swscale image scaling and conversion plugin
2532 dnl
2533
2534 AC_ARG_ENABLE(swscale,
2535   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2536           (default enabled)]))
2537 if test "${enable_swscale}" != "no"
2538 then
2539   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2540     [
2541       VLC_SAVE_FLAGS
2542       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2543       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2544       AC_CHECK_HEADERS(libswscale/swscale.h)
2545       AC_CHECK_HEADERS(libavutil/avutil.h)
2546       VLC_ADD_PLUGIN([swscale])
2547       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2548       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2549       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2550         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2551       ])
2552       VLC_RESTORE_FLAGS
2553     ],[
2554       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2555   ])
2556 fi
2557
2558 dnl
2559 dnl  postproc plugin
2560 dnl
2561
2562 AC_ARG_ENABLE(postproc,
2563 [  --enable-postproc       libpostproc image post-processing (default auto)])
2564 if test "${enable_postproc}" != "no"
2565 then
2566   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2567     [
2568       VLC_SAVE_FLAGS
2569       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2570       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2571       AC_CHECK_HEADERS(postproc/postprocess.h)
2572       VLC_ADD_PLUGIN([postproc])
2573       VLC_RESTORE_FLAGS
2574     ],[
2575       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2576   ])
2577 fi
2578
2579 dnl
2580 dnl  faad decoder plugin
2581 dnl
2582 AC_ARG_ENABLE(faad,
2583 [  --enable-faad           faad codec (default auto)])
2584 have_faad="no"
2585 AS_IF([test "${enable_faad}" != "no"], [
2586   AC_CHECK_HEADERS([neaacdec.h], [
2587     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2588
2589     AS_IF([test "${have_faad}" = "yes"], [
2590       VLC_ADD_PLUGIN([faad])
2591       VLC_ADD_LIBS([faad],[-lfaad])
2592     ], [
2593       AS_IF([test "${enable_faad}" = "yes"], [
2594         AC_MSG_ERROR([cannot find FAAD library])
2595       ], [
2596         AC_MSG_WARN([cannot find FAAD library])
2597       ])
2598     ])
2599   ])
2600 ])
2601
2602 dnl
2603 dnl libvpx decoder plugin
2604 dnl
2605 AC_ARG_ENABLE(vpx,
2606     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 decoder (default auto)]))
2607 AS_IF([test "${enable_vpx}" != "no"],[
2608     PKG_CHECK_MODULES([VPX], [vpx] , [
2609         VLC_ADD_PLUGIN([vpx])
2610         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2611         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2612         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2613             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2614         ], [], [${VPX_LIBS}])
2615         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2616             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2617         ], [], [${VPX_LIBS}])
2618     ], [
2619     AS_IF([test "${enable_vpx}" = "yes"],[
2620         AC_MSG_ERROR([libvpx was not found])
2621     ])])
2622 ])
2623
2624 dnl
2625 dnl twolame encoder plugin
2626 dnl
2627 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2628
2629 dnl
2630 dnl fdk-aac encoder plugin
2631 dnl
2632 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2633
2634 dnl
2635 dnl  QuickTime plugin
2636 dnl
2637 AC_ARG_ENABLE(quicktime,
2638   [  --enable-quicktime      QuickTime module (deprecated)])
2639 if test "${enable_quicktime}" = "yes"; then
2640   if test "${SYS}" = "mingw32"; then
2641     VLC_ADD_PLUGIN([quicktime])
2642   else
2643   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2644     [ VLC_ADD_PLUGIN([quicktime])
2645       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2646     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2647   fi
2648 fi
2649
2650 dnl
2651 dnl A52/AC3 decoder plugin
2652 dnl
2653 AC_ARG_ENABLE(a52,
2654   [  --enable-a52            A/52 support with liba52 (default enabled)])
2655 if test "${enable_a52}" != "no"
2656 then
2657   AC_ARG_WITH(a52,
2658     [  --with-a52=PATH         a52 headers and libraries])
2659     if test -z "${with_a52}"
2660     then
2661       LDFLAGS_test=""
2662       CPPFLAGS_test=""
2663     else
2664       LDFLAGS_test="-L${with_a52}/lib"
2665       CPPFLAGS_test="-I${with_a52}/include"
2666     fi
2667     VLC_SAVE_FLAGS
2668     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2669     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2670     AC_CHECK_HEADERS(a52dec/a52.h, [
2671       AC_CHECK_LIB(a52, a52_free, [
2672         VLC_ADD_PLUGIN([a52tofloat32])
2673         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2674         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2675       ],[
2676         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2677         ], [$LIBM])
2678     ],[
2679       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2680     ])
2681     VLC_RESTORE_FLAGS
2682 fi
2683
2684 dnl
2685 dnl DTS Coherent Acoustics decoder plugin
2686 dnl
2687 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2688
2689 dnl
2690 dnl  Flac plugin
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2693
2694 dnl
2695 dnl  Libmpeg2 plugin
2696 dnl
2697 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2698
2699 dnl
2700 dnl  Vorbis plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2703
2704 dnl
2705 dnl  Tremor plugin
2706 dnl
2707 AC_ARG_ENABLE(tremor,
2708   [  --enable-tremor         Tremor decoder support (default disabled)])
2709 if test "${enable_tremor}" = "yes"
2710 then
2711   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2712     VLC_ADD_PLUGIN([tremor])
2713    ],[])
2714 fi
2715
2716 dnl
2717 dnl  Speex plugins
2718 dnl
2719 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2720 have_speexdsp="no"
2721 AS_IF([test "${enable_speex}" != "no"], [
2722   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2723     have_speexdsp="yes"
2724   ], [
2725     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2726   ])
2727 ])
2728 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2729
2730 dnl
2731 dnl  Opus plugin
2732 dnl
2733 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2734
2735 dnl
2736 dnl  theora decoder plugin
2737 dnl
2738 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2739
2740 dnl
2741 dnl  Daala decoder plugin
2742 dnl
2743 PKG_ENABLE_MODULES_VLC([DAALA], [], [ogg daaladec daalaenc], [experimental daala codec], [disabled])
2744
2745 dnl
2746 dnl  schroedinger decoder plugin (for dirac format video)
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2749
2750 dnl
2751 dnl  PNG decoder module
2752 dnl
2753 AC_ARG_ENABLE(png,
2754   [  --enable-png            PNG support (default enabled)])
2755 AS_IF([test "${enable_png}" != "no"], [
2756 AC_CHECK_HEADERS(png.h, [
2757   VLC_SAVE_FLAGS
2758   LDFLAGS="${LDFLAGS} -lz $LIBM"
2759   AC_CHECK_LIB(png, png_set_rows, [
2760     VLC_ADD_PLUGIN([png])
2761   ], [], [-lz $LIBM])
2762   VLC_RESTORE_FLAGS
2763   ])
2764 ])
2765
2766 dnl
2767 dnl  JPEG decoder module
2768 dnl
2769 AC_ARG_ENABLE(jpeg,
2770   [  --enable-jpeg           JPEG support (default enabled)])
2771 AS_IF([test "${enable_jpeg}" != "no"], [
2772 AC_CHECK_HEADERS(jpeglib.h, [
2773   VLC_ADD_PLUGIN([jpeg])
2774   ])
2775 ])
2776
2777 dnl
2778 dnl  BPG decoder module
2779 dnl
2780 AC_ARG_ENABLE(bpg,
2781   [  --enable-bpg           BPG support (default disabled)])
2782 AS_IF([test "${enable_bpg}" != "no"], [
2783 AC_CHECK_HEADERS(libbpg.h, [
2784   VLC_ADD_PLUGIN([bpg])
2785   ])
2786 ])
2787
2788 dnl
2789 dnl H262 encoder plugin (lib262)
2790 dnl
2791 AC_ARG_ENABLE(x262,
2792   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2793 if test "${enable_x262}" != "no"; then
2794     PKG_CHECK_MODULES(X262, x262, [
2795         VLC_ADD_PLUGIN([x262])
2796         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2797         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2798           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2799         ])
2800         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2801         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2802           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2803         fi
2804     ], [
2805        if test "${enable_x262}" = "yes"; then
2806         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2807        fi
2808     ])
2809 fi
2810
2811 dnl x265 encoder
2812 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2813
2814 dnl
2815 dnl H264 encoder plugin (10-bit lib264)
2816 dnl
2817 AC_ARG_ENABLE(x26410b,
2818   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2819 if test "${enable_x26410b}" != "no"; then
2820     PKG_CHECK_MODULES(X26410B, x26410b, [
2821         VLC_ADD_PLUGIN([x26410b])
2822         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2823         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2824           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2825         ])
2826         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2827         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2828           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2829         fi
2830     ], [
2831        if test "${enable_x26410b}" = "yes"; then
2832         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2833        fi
2834     ])
2835 fi
2836
2837
2838 dnl
2839 dnl H264 encoder plugin (using libx264)
2840 dnl
2841 AC_ARG_ENABLE(x264,
2842   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2843 if test "${enable_x264}" != "no"; then
2844       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2845         VLC_ADD_PLUGIN([x264])
2846         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2847
2848         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2849           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2850         ])
2851
2852         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2853         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2854           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2855         fi
2856       ],[
2857         if test "${enable_x264}" = "yes"; then
2858             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2859           fi
2860       ])
2861 fi
2862
2863 dnl
2864 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2865 dnl
2866 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2867
2868 dnl
2869 dnl libfluidsynth (MIDI synthetizer) plugin
2870 dnl
2871 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2872
2873 dnl
2874 dnl Teletext Modules
2875 dnl vbi decoder plugin (using libzbvi)
2876 dnl telx module
2877 dnl uncompatible
2878 dnl
2879 AC_ARG_ENABLE(zvbi,
2880   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2881                   libzvbi (default enabled)]))
2882 AC_ARG_ENABLE(telx,
2883   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2884                   zvbi) (default enabled if zvbi is absent)]))
2885
2886 AS_IF( [test "${enable_zvbi}" != "no"],[
2887     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2888         [
2889           VLC_ADD_PLUGIN([zvbi])
2890           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2891           AS_IF( [test "${enable_telx}" = "yes"],[
2892                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2893                   ])
2894         ],[
2895           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2896         ])
2897     ])
2898 AS_IF( [test "${enable_telx}" != "no" ],[
2899   VLC_ADD_PLUGIN([telx])
2900   ])
2901
2902 dnl
2903 dnl libass subtitle rendering module
2904 dnl
2905 AC_ARG_ENABLE(libass,
2906   [  --enable-libass         Subtitle support using libass (default enabled)])
2907 AS_IF( [test "${enable_libass}" != "no"], [
2908   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2909       [
2910         VLC_ADD_PLUGIN([libass])
2911
2912         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2913           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2914            VLC_ADD_LIBS([libass],[-lfontconfig])
2915        ])
2916       ],[
2917         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2918       ])
2919   ])
2920
2921 dnl
2922 dnl ARIB subtitles rendering module
2923 dnl
2924 AC_ARG_ENABLE(aribsub,
2925   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2926 AS_IF( [test "${enable_aribsub}" != "no" ],[
2927   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2928       have_aribb24="yes"
2929       VLC_ADD_PLUGIN([aribsub])
2930       VLC_ADD_LIBS([aribsub],[-laribb24])
2931       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2932     ],[
2933       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2934       have_aribb24="no"
2935   ])
2936 ])
2937 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2938
2939 dnl
2940 dnl ARIB B25
2941 dnl
2942 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2943
2944 dnl
2945 dnl  kate decoder plugin
2946 dnl
2947 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2948
2949 dnl
2950 dnl  tiger rendering for kate decoder plugin
2951 dnl
2952 AC_ARG_ENABLE(tiger,
2953 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2954 AS_IF([test "${enable_tiger}" != "no"], [
2955   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2956       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2957         AS_IF([test -n "${enable_tiger}"], [
2958           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2959         ])
2960   ])
2961 ])
2962
2963
2964 dnl
2965 dnl  Video plugins
2966 dnl
2967
2968 EXTEND_HELP_STRING([Video plugins:])
2969
2970 dnl
2971 dnl  OpenGL
2972 dnl
2973 PKG_CHECK_MODULES([EGL], [egl], [
2974   have_egl="yes"
2975 ], [
2976   have_egl="no"
2977 ])
2978 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2979
2980 have_gl="no"
2981 PKG_CHECK_MODULES([GL], [gl], [
2982   have_gl="yes"
2983 ], [
2984   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2985 #ifdef _WIN32
2986 # include <GL/glew.h>
2987 #endif
2988 #include <GL/gl.h>
2989 ]], [
2990     [int t0 = GL_TEXTURE0;]])
2991   ], [
2992     GL_CFLAGS=""
2993     have_gl="yes"
2994     AS_IF([test "${SYS}" != "mingw32"], [
2995       GL_LIBS="-lGL"
2996     ], [
2997       GL_LIBS="-lopengl32"
2998     ])
2999   ])
3000 ])
3001 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3002
3003 dnl OpenGL ES 2: depends on EGL 1.1
3004 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3005 dnl OpenGL ES 1: depends on EGL 1.0
3006 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3007
3008 dnl
3009 dnl  Xlib
3010 dnl
3011
3012 AC_PATH_XTRA()
3013 AC_CHECK_HEADERS(X11/Xlib.h)
3014
3015 dnl
3016 dnl  X C Bindings modules
3017 dnl
3018 AC_ARG_ENABLE(xcb,
3019   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3020   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3021     enable_xcb="yes"
3022   ], [
3023     enable_xcb="no"
3024   ])
3025 ])
3026 AC_ARG_ENABLE(xvideo,
3027   [  --enable-xvideo         XVideo support (default enabled)],, [
3028     enable_xvideo="$enable_xcb"
3029 ])
3030
3031 have_xcb="no"
3032 have_xcb_keysyms="no"
3033 have_xcb_randr="no"
3034 have_xcb_xvideo="no"
3035 AS_IF([test "${enable_xcb}" != "no"], [
3036   dnl libxcb
3037   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3038   have_xcb="yes"
3039   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3040   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3041   PKG_CHECK_MODULES(XPROTO, [xproto])
3042
3043   AS_IF([test "${enable_xvideo}" != "no"], [
3044     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3045   ])
3046
3047   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3048
3049   dnl xcb-utils
3050   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3051     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3052   ])
3053 ])
3054 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3055 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3056 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3057 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3058
3059
3060 dnl
3061 dnl VDPAU needs X11
3062 dnl
3063 AC_ARG_ENABLE(vdpau,
3064   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3065 have_vdpau="no"
3066 AS_IF([test "${enable_vdpau}" != "no"], [
3067   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3068     have_vdpau="yes"
3069     AS_IF([test "${no_x}" = "yes"], [
3070       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3071     ])
3072   ], [
3073     AS_IF([test -n "${enable_vdpau}"], [
3074       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3075     ])
3076   ])
3077 ])
3078 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3079
3080 have_avcodec_vdpau="no"
3081 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3082   case "${avfork}" in
3083     libav) av_vdpau_ver="55.26.0" ;;
3084     ffmpeg) av_vdpau_ver="55.42.100" ;;
3085   esac
3086   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3087     have_avcodec_vdpau="yes"
3088     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3089   ], [
3090     AS_IF([test -n "${enable_vdpau}"], [
3091       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3092     ], [
3093       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3094     ])
3095   ])
3096 ])
3097 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3098
3099
3100 dnl
3101 dnl  Wayland
3102 dnl
3103 AC_ARG_ENABLE(wayland,
3104   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3105 have_wayland="no"
3106 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3107
3108 AS_IF([test "${enable_wayland}" != "no"], [
3109   AC_MSG_CHECKING([for the Wayland scanner])
3110   AS_IF([test -z "$WAYLAND_SCANNER"], [
3111     PKG_CHECK_EXISTS([wayland-scanner], [
3112       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3113     ], [
3114       WAYLAND_SCANNER="wayland-scanner"
3115     ])
3116   ])
3117   AC_MSG_RESULT([$WAYLAND_SCANNER])
3118
3119   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3120     have_wayland="yes"
3121   ], [
3122     AS_IF([test -n "${enable_wayland}"], [
3123       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3124     ])
3125   ])
3126
3127   AS_IF([test "${have_egl}" = "yes"], [
3128     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3129       have_wayland_egl="yes"
3130     ], [
3131       AS_IF([test -n "${enable_wayland}"], [
3132         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3133       ])
3134     ])
3135   ])
3136 ])
3137 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3138 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3139
3140
3141 dnl
3142 dnl  SDL module
3143 dnl
3144 AC_ARG_ENABLE(sdl,
3145   [  --enable-sdl            SDL support (default enabled)])
3146 AC_ARG_ENABLE(sdl-image,
3147   [  --enable-sdl-image      SDL image support (default enabled)])
3148 if test "${enable_sdl}" != "no"
3149 then
3150    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3151       # SDL on Darwin is heavily patched and can only run SDL_image
3152       if test "${SYS}" != "darwin"; then
3153         VLC_ADD_PLUGIN([vout_sdl])
3154       fi
3155
3156       # SDL_image
3157       AS_IF([ test "${enable_sdl_image}" != "no"],[
3158         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3159           VLC_ADD_PLUGIN([sdl_image])],
3160           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3161           ])
3162       ])
3163    ],[
3164      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3165    ])
3166 fi
3167
3168 dnl
3169 dnl  freetype module
3170 dnl
3171 AC_ARG_ENABLE(freetype,
3172   [  --enable-freetype       freetype support   (default auto)])
3173 AC_ARG_ENABLE(fribidi,
3174   [  --enable-fribidi        fribidi support    (default auto)])
3175 AC_ARG_ENABLE(harfbuzz,
3176   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3177 AC_ARG_ENABLE(fontconfig,
3178   [  --enable-fontconfig     fontconfig support (default auto)])
3179
3180 AC_ARG_WITH([default-font],
3181     AS_HELP_STRING([--with-default-font=PATH],
3182         [Path to the default font]),
3183         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3184             "$withval", [Default font])])
3185 AC_ARG_WITH([default-monospace-font],
3186     AS_HELP_STRING([--with-default-monospace-font=PATH],
3187         [Path to the default font]),
3188         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3189             "$withval", [Default monospace font])])
3190
3191 AC_ARG_WITH([default-font-family],
3192     AS_HELP_STRING([--with-default-font-family=NAME],
3193         [Path to the default font family]),
3194         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3195             "$withval", [Default font family])])
3196 AC_ARG_WITH([default-monospace-font-family],
3197     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3198         [Path to the default font family]),
3199         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3200             "$withval", [Default monospace font family])])
3201
3202 have_freetype="no"
3203 have_fontconfig="no"
3204 have_fribidi="no"
3205 have_harfbuzz="no"
3206
3207 if test "${enable_freetype}" != "no"; then
3208    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3209       have_freetype="yes"
3210       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3211       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3212
3213       dnl fontconfig support
3214       if test "${SYS}" != "mingw32"; then
3215           if test "${enable_fontconfig}" != "no"; then
3216             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3217               have_fontconfig="yes"
3218             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3219           fi
3220       fi
3221
3222       dnl fribidi support
3223       if test "${enable_fribidi}" != "no"; then
3224         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3225           have_fribidi="yes"
3226           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3227           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3228         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3229       fi
3230
3231       dnl harfbuzz support
3232       if test "${have_fribidi}" != "no"; then
3233         if test "${enable_harfbuzz}" != "no"; then
3234           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3235             have_harfbuzz="yes"
3236             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3237             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3238           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3239         fi
3240       fi
3241   ],[
3242   AS_IF([test -n "${enable_freetype}"],[
3243     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3244     ])
3245   ])
3246 fi
3247
3248 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3249 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3250 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3251 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3252
3253
3254 dnl
3255 dnl  QuartzText vout module (iOS/Mac OS)
3256 dnl
3257 AC_ARG_ENABLE(macosx-quartztext,
3258   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3259 if test "x${enable_macosx_quartztext}" != "xno" &&
3260   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3261 then
3262   VLC_ADD_PLUGIN([quartztext])
3263 fi
3264
3265 dnl
3266 dnl  SVG module (text rendering and image decoding)
3267 dnl
3268 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3269 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3270
3271 dnl
3272 dnl  Windows DirectX module
3273 dnl
3274
3275 AC_ARG_ENABLE(directx,
3276   [AS_HELP_STRING([--enable-directx],
3277     [Microsoft DirectX support (default enabled on Windows)])],, [
3278   AS_IF([test "${SYS}" = "mingw32"], [
3279     enable_directx="yes"
3280   ], [
3281     enable_directx="no"
3282   ])
3283 ])
3284 have_directx="no"
3285 AS_IF([test "${enable_directx}" != "no"], [
3286   dnl DirectDraw
3287   AC_CHECK_HEADERS(ddraw.h, [
3288     have_directx="yes"
3289   ], [
3290     AC_MSG_ERROR([Cannot find DirectX headers!])
3291   ])
3292
3293   dnl OpenGL
3294   AC_CHECK_HEADERS(GL/wglew.h, [
3295     VLC_ADD_PLUGIN([glwin32])
3296   ],, [
3297     #include <windows.h>
3298     #include <GL/gl.h>
3299   ])
3300
3301   dnl Direct3D11
3302   AC_CHECK_HEADERS(d3d11.h, [
3303     VLC_ADD_PLUGIN([direct3d11])
3304   ])
3305
3306   dnl Direct3D9
3307   AC_CHECK_HEADERS(d3d9.h, [
3308     VLC_ADD_PLUGIN([direct3d9])
3309   ])
3310
3311   dnl Direct2D
3312   AC_CHECK_HEADERS(d2d1.h, [
3313     VLC_ADD_PLUGIN([direct2d])
3314   ])
3315 ])
3316 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3317
3318 dnl
3319 dnl  Linux framebuffer module
3320 dnl
3321 AC_CHECK_HEADER([linux/fb.h], [
3322   VLC_ADD_PLUGIN([fb])
3323 ])
3324
3325
3326 dnl
3327 dnl  DirectFB module
3328 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3329 dnl  TODO: support for static linking
3330 dnl
3331 AC_ARG_ENABLE(directfb,
3332   [  --enable-directfb       DirectFB support (default disabled)])
3333 AC_ARG_WITH(directfb,
3334   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3335
3336 if test "${enable_directfb}" = "yes"; then
3337     have_directfb="false"
3338     CPPFLAGS_mydirectfb=
3339     LIBS_mydirectfb=
3340     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3341         dnl Trying the given location
3342         VLC_SAVE_FLAGS
3343
3344         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3345         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3346
3347         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3348         LIBS="${LIBS} ${LIBS_new}"
3349
3350         dnl FIXME: too obscure
3351         AC_CHECK_HEADER([directfb.h], [
3352             AC_CHECK_LIB([direct],[direct_initialize], [
3353                 AC_CHECK_LIB([fusion], [fusion_enter], [
3354                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3355                 ], have_directfb="false")
3356             ], have_directfb="false")
3357         ], have_directfb="false")
3358
3359         VLC_RESTORE_FLAGS
3360
3361         if test "${have_directfb}" = "true"; then
3362             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3363             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3364         fi
3365     else
3366         dnl Look for directfb-config
3367         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3368         if test "${DIRECTFB_CONFIG}" != "no"; then
3369             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3370             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3371             have_directfb="true"
3372         else
3373             dnl Trying with pkg-config
3374             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3375                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3376                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3377                 have_directfb="true"
3378                 ], [have_directfb="false"])
3379         fi
3380     fi
3381     if test "${have_directfb}" = "true"; then
3382         VLC_ADD_PLUGIN([directfb])
3383         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3384         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3385     else
3386         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3387     fi
3388 fi
3389
3390 dnl
3391 dnl  AA plugin
3392 dnl
3393 AC_ARG_ENABLE(aa,
3394   [  --enable-aa             aalib output (default disabled)])
3395 if test "${enable_aa}" = "yes"
3396 then
3397   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3398   if test "${have_aa}" = "true"
3399   then
3400     VLC_ADD_PLUGIN([aa])
3401   fi
3402 fi
3403
3404 dnl
3405 dnl  libcaca plugin
3406 dnl
3407 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3408
3409 dnl
3410 dnl  OS/2 KVA plugin
3411 dnl
3412 AC_ARG_ENABLE(kva,
3413   [AS_HELP_STRING([--enable-kva],
3414     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3415   AS_IF([test "$SYS" = "os2"], [
3416     enable_kva="yes"
3417   ])
3418 ])
3419 have_kva="no"
3420 KVA_LIBS=""
3421 AS_IF([test "$enable_kva" != "no"], [
3422   AC_CHECK_HEADERS([kva.h], [
3423     have_kva="yes"
3424     AC_CHECK_LIB(kva, main, [
3425       KVA_LIBS="-lkva"
3426     ])
3427   ])
3428 ])
3429 AC_SUBST(KVA_LIBS)
3430 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3431
3432 dnl
3433 dnl MMAL plugin
3434 dnl
3435 AC_ARG_ENABLE(mmal,
3436   AS_HELP_STRING([--enable-mmal],
3437     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3438 if test "${enable_mmal}" != "no"; then
3439   VLC_SAVE_FLAGS
3440   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3441   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3442   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3443     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3444         have_mmal="yes"
3445         VLC_ADD_PLUGIN([mmal])
3446         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3447         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3448         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3449           AS_IF([test "${enable_mmal}" = "yes"],
3450             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3451             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3452           ],
3453         [])
3454     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3455       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3456       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3457   VLC_RESTORE_FLAGS
3458 fi
3459 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3460
3461 dnl
3462 dnl  Audio plugins
3463 dnl
3464
3465 EXTEND_HELP_STRING([Audio plugins:])
3466
3467 dnl
3468 dnl  Pulseaudio module
3469 dnl
3470 AC_ARG_ENABLE(pulse,
3471   [AS_HELP_STRING([--enable-pulse],
3472     [use the PulseAudio client library (default auto)])])
3473 have_pulse="no"
3474 AS_IF([test "${enable_pulse}" != "no"], [
3475   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3476     have_pulse="yes"
3477   ], [
3478     AS_IF([test "x${enable_pulse}" != "x"], [
3479       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3480     ])
3481   ])
3482 ])
3483 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3484
3485 dnl
3486 dnl  ALSA module
3487 dnl
3488 AC_ARG_ENABLE(alsa,
3489   [AS_HELP_STRING([--enable-alsa],
3490     [support the Advanced Linux Sound Architecture (default auto)])],, [
3491   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3492     enable_alsa="yes"
3493   ])
3494 ])
3495 have_alsa="no"
3496 AS_IF([test "${enable_alsa}" != "no"], [
3497   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3498     have_alsa="yes"
3499   ], [
3500     AS_IF([test "x${enable_alsa}" != "x"], [
3501       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3502     ])
3503   ])
3504 ])
3505 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3506
3507 dnl
3508 dnl  Open Sound System module
3509 dnl
3510 AC_ARG_ENABLE(oss,
3511   [AS_HELP_STRING([--enable-oss],
3512     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3513   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3514     enable_oss="no"
3515   ])
3516 ])
3517 have_oss="no"
3518 OSS_LIBS=""
3519 AS_IF([test "$enable_oss" != "no"], [
3520   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3521     have_oss="yes"
3522     AC_CHECK_LIB(ossaudio, main, [
3523       OSS_LIBS="-lossaudio"
3524     ])
3525   ])
3526 ])
3527 AC_SUBST(OSS_LIBS)
3528 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3529
3530 dnl
3531 dnl  OpenBSD sndio module
3532 dnl
3533 AC_ARG_ENABLE([sndio],
3534   [AS_HELP_STRING([--disable-sndio],
3535     [support the OpenBSD sndio (default auto)])],, [
3536   AS_IF([test "$SYS" = "openbsd"], [
3537     enable_sndio="yes"
3538   ])
3539 ])
3540 have_sndio="no"
3541 AS_IF([test "$enable_sndio" != "no"], [
3542   AC_CHECK_HEADER([sndio.h], [
3543     have_sndio="yes"
3544   ])
3545 ])
3546 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3547
3548 dnl
3549 dnl  Windows Audio Session plugin
3550 dnl
3551 AC_ARG_ENABLE([wasapi],
3552   [AS_HELP_STRING([--enable-wasapi],
3553     [use the Windows Audio Session API (default auto)])
3554 ])
3555 have_wasapi="no"
3556 AS_IF([test "$enable_wasapi" != "no"], [
3557   AC_CHECK_HEADER([audioclient.h], [
3558     have_wasapi="yes"
3559   ], [
3560     AS_IF([test "x${enable_wasapi}" != "x"], [
3561       AC_MSG_ERROR([Windows Audio Session API not found.])
3562     ])
3563   ])
3564 ])
3565 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3566
3567 dnl
3568 dnl  AudioQueue plugin
3569 dnl
3570 AC_ARG_ENABLE(audioqueue,
3571   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3572 if test "${enable_audioqueue}" = "yes"
3573 then
3574   VLC_ADD_PLUGIN([audioqueue])
3575 fi
3576
3577 dnl
3578 dnl  JACK modules
3579 dnl
3580 AC_ARG_ENABLE(jack,
3581   [AS_HELP_STRING([--disable-jack],
3582     [do not use jack (default auto)])])
3583 have_jack="no"
3584 AS_IF([test "${enable_jack}" != "no"], [
3585     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3586       [ have_jack=yes ],
3587       [
3588       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3589
3590       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3591       [ have_jack=yes ],
3592       [
3593       AS_IF([test -n "${enable_jack}"],
3594          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3595          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3596       ])
3597     ])
3598 ])
3599 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3600
3601 dnl
3602 dnl  OpenSLES Android
3603 dnl
3604 AC_ARG_ENABLE(opensles,
3605   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3606 if test "${HAVE_ANDROID}" = "1"; then
3607   if test "${enable_opensles}" = "yes"; then
3608       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3609         [ VLC_ADD_PLUGIN([opensles_android]) ],
3610         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3611   fi
3612 fi
3613
3614 dnl
3615 dnl  Tizen audio
3616 dnl
3617 AC_ARG_ENABLE(tizen_audio,
3618   [AS_HELP_STRING([--enable-tizen-audio],
3619     [Tizen audio module (default enabled on Tizen)])],, [
3620   AS_IF([test "$HAVE_TIZEN" = "1"], [
3621     enable_tizen_audio="yes"
3622   ])
3623 ])
3624 if test "${enable_tizen_audio}" = "yes"; then
3625   AC_CHECK_HEADERS(audio_io.h,
3626     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3627     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3628 fi
3629
3630 dnl
3631 dnl libsamplerate plugin
3632 dnl
3633 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3634
3635 dnl
3636 dnl  OS/2 KAI plugin
3637 dnl
3638 AC_ARG_ENABLE(kai,
3639   [AS_HELP_STRING([--enable-kai],
3640     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3641   AS_IF([test "$SYS" = "os2"], [
3642     enable_kai="yes"
3643   ])
3644 ])
3645 have_kai="no"
3646 KAI_LIBS=""
3647 AS_IF([test "$enable_kai" != "no"], [
3648   AC_CHECK_HEADERS([kai.h], [
3649     have_kai="yes"
3650     AC_CHECK_LIB(kai, main, [
3651       KAI_LIBS="-lkai"
3652     ])
3653   ])
3654 ])
3655 AC_SUBST(KAI_LIBS)
3656 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3657
3658 dnl
3659 dnl  chromaprint audio track fingerprinter
3660 dnl
3661 m4_pushdef([libchromaprint_version], 0.6.0)
3662 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3663     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3664     AS_IF([test "${enable_chromaprint}" = "yes"],
3665         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3666         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3667          ),
3668     [(Chromaprint based audio fingerprinter)],[auto])
3669 m4_popdef([libchromaprint_version])
3670
3671 dnl
3672 dnl  Chromecast streaming support
3673 dnl
3674 m4_pushdef([protobuf_lite_version], 2.5.0)
3675 AC_ARG_VAR(PROTOC, [protobuf compiler])
3676 AC_CHECK_PROGS(PROTOC, protoc, no)
3677 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3678     AS_IF([test "x${PROTOC}" != "xno"], [
3679         build_chromecast="yes"
3680     ], [
3681     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3682     ])
3683 ], [
3684     AS_IF([test "${enable_chromecast}" = "yes"],
3685         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3686         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3687     )
3688     enable_chromecast="no"
3689 ], [(Chromecast streaming support)], [auto])
3690 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3691 m4_popdef([protobuf_lite_version])
3692
3693 dnl
3694 dnl  Interface plugins
3695 dnl
3696
3697 EXTEND_HELP_STRING([Interface plugins:])
3698
3699 dnl
3700 dnl QT
3701 dnl
3702 AC_ARG_ENABLE(qt, [
3703   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3704   AS_IF([test "${SYS}" = "darwin"], [
3705     enable_qt="no"
3706   ])
3707 ])
3708 AS_IF([test "${enable_qt}" != "no"], [
3709   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3710       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3711           VLC_ADD_LIBS([qt4],[${QTX11_LIBS}])
3712           VLC_ADD_CXXFLAGS([qt4],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3713       ],[
3714           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3715       ])
3716       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3717       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3718       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3719       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3720       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3721     ], [
3722       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3723         AS_IF([test -n "${enable_qt}"],[
3724           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3725         ],[
3726           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3727         ])
3728         enable_qt="no"
3729       ])
3730       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3731       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3732       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3733       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3734     ])
3735 ])
3736 AS_IF([test "${enable_qt}" != "no"], [
3737   VLC_ADD_PLUGIN([qt4])
3738   ALIASES="${ALIASES} qvlc"
3739 ])
3740 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3741
3742 dnl
3743 dnl Simple test for skins2 dependency
3744 dnl
3745 AS_IF([test "$enable_qt" = "no"], [
3746   AS_IF([test "${enable_skins2}" = "yes"], [
3747     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3748   ], [
3749     enable_skins2="no"
3750     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3751   ])
3752 ])
3753
3754 dnl
3755 dnl Skins2 module
3756 dnl
3757 AC_ARG_ENABLE(skins2,
3758   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3759 AS_IF([test "${enable_skins2}" != "no"], [
3760   have_skins_deps="yes"
3761
3762   dnl Win32
3763   AS_IF([test "${SYS}" = "mingw32"], [
3764     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3765     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3766   dnl MacOS
3767   ], [test "${SYS}" = "darwin"], [
3768     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3769     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3770   dnl OS/2
3771   ], [test "${SYS}" = "os2"], [
3772     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3773   dnl Linux/Unix
3774   ], [
3775     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3776     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3777     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3778     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3779     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3780   ])
3781
3782   dnl for All OSes
3783   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3784
3785   dnl we need freetype
3786   AS_IF([test "${have_freetype}" != "yes"], [
3787     have_skins_deps="no"
3788   ])
3789
3790   AS_IF([test "${have_skins_deps}" = "no"], [
3791     AS_IF([test "x${enable_skins2}" = "x"], [
3792       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3793     ], [
3794       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3795     ])
3796     enable_skins2="no"
3797   ], [
3798     VLC_ADD_PLUGIN([skins2])
3799     ALIASES="${ALIASES} svlc"
3800     enable_skins2="yes"
3801   ])
3802 ])
3803 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3804
3805 AC_ARG_ENABLE(libtar,
3806   [  --enable-libtar         libtar support for skins2 (default auto)])
3807 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3808   AC_CHECK_HEADERS(libtar.h, [
3809     VLC_ADD_LIBS([skins2],[-ltar])
3810   ])
3811 ])
3812
3813 dnl
3814 dnl  MacOS X gui module
3815 dnl
3816 AC_ARG_ENABLE(macosx,
3817   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3818 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3819 then
3820   VLC_ADD_PLUGIN([macosx])
3821
3822   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3823   then
3824     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3825   fi
3826 fi
3827 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3828
3829 dnl
3830 dnl  MacOS X sparkle update support
3831 dnl
3832 AC_ARG_ENABLE(sparkle,
3833   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3834 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3835 then
3836   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3837   then
3838     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3839   fi
3840
3841   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3842 fi
3843 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3844
3845
3846 dnl
3847 dnl  Minimal Mac OS X module
3848 dnl
3849 AC_ARG_ENABLE(minimal-macosx,
3850   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3851 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3852 then
3853   VLC_ADD_PLUGIN([minimal_macosx])
3854 fi
3855
3856 dnl
3857 dnl  MacOS X dialog provider
3858 dnl
3859 AC_ARG_ENABLE(macosx-dialog-provider,
3860   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3861 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3862   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3863 then
3864   VLC_ADD_PLUGIN([macosx_dialog_provider])
3865 fi
3866
3867 dnl
3868 dnl  VideoToolbox plugins
3869 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3870     VLC_ADD_PLUGIN([videotoolbox])
3871     VLC_ADD_PLUGIN([cvpx_i420])
3872   ])
3873
3874 dnl