dbus: Rework the main loop
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 2002-2011 the VideoLAN team])
4
5 AC_INIT(vlc, 1.2.0-git)
6 VERSION_MAJOR="1"
7 VERSION_MINOR="2"
8 VERSION_REVISION="0"
9 VERSION_EXTRA="-git"
10 PKGDIR="vlc"
11 AC_SUBST(PKGDIR)
12
13 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
14 CODENAME="Twoflower"
15 COPYRIGHT_YEARS="1996-2011"
16
17 AC_CONFIG_SRCDIR(src/libvlc.c)
18 AC_CONFIG_AUX_DIR(autotools)
19 AC_CONFIG_MACRO_DIR(m4)
20 AC_CONFIG_LIBOBJ_DIR(compat)
21 AC_CANONICAL_BUILD
22 AC_CANONICAL_HOST
23 AC_PRESERVE_HELP_ORDER
24
25 AM_INIT_AUTOMAKE(tar-ustar color-tests)
26 AM_CONFIG_HEADER(config.h)
27
28 # Disable with "./configure --disable-silent-rules" or "make V=1"
29 AM_SILENT_RULES([yes])
30
31 dnl Too many people are not aware of maintainer mode:
32 dnl If you want to use it, you definitely know what you are doing, so
33 dnl you can specify "--disable-maintainer-mode". But if you want the default
34 dnl automake behavior, you've likely never heard of maintainer mode, so we
35 dnl can't expect you to enable it manually.
36 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
37     [enable_maintainer_mode="yes"])
38 AM_MAINTAINER_MODE
39
40 dnl
41 dnl Directories
42 dnl
43 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
44 dnl AC_SUBST(vlcincludedir)
45 vlcdatadir="\${datadir}/\${PKGDIR}"
46 AC_SUBST(vlcdatadir)
47 vlclibdir="\${libdir}/\${PKGDIR}"
48 AC_SUBST(vlclibdir)
49
50 dnl
51 dnl  Save *FLAGS
52 dnl
53 VLC_SAVE_FLAGS
54
55 dnl
56 dnl Check for tools
57 dnl
58 AC_PROG_CC_C99
59 AC_USE_SYSTEM_EXTENSIONS
60 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to '2' to get glibc warnings.])
61
62 AM_PROG_CC_C_O
63 AC_PROG_CXX
64 AC_PROG_CPP
65 AC_PROG_OBJC
66 _AM_DEPENDENCIES([OBJC])
67 AC_PROG_EGREP
68 AC_PROG_MAKE_SET
69 AC_PROG_INSTALL
70 AM_PROG_AS
71
72 dnl Find the right ranlib, even when cross-compiling
73 AC_CHECK_TOOL(RANLIB, ranlib, :)
74 AC_CHECK_TOOL(STRIP, strip, :)
75 AC_CHECK_TOOL(AR, ar, :)
76 AC_CHECK_TOOL(LD, ld, :)
77 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
78
79 dnl Check for compiler properties
80 AC_C_CONST
81 AC_C_INLINE
82 AC_C_RESTRICT
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl Check how we are asked to build
98 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
99   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
100 ])
101
102 AC_ARG_ENABLE(static-modules,
103    [  --enable-static-modules  Allow module to be linked statically. This produces a non working vlc.])  
104 AS_IF([test "${enable_static_modules}" = yes], [
105    enable_shared="no"
106    enable_static="yes"
107    VLC_DEFAULT_PLUGIN_TYPE="builtin"
108    AS_IF([test "${enable_vlc}" != "no"],
109      [AC_MSG_WARN([Building modules as static. VLC will not work.])])
110 ], [
111    VLC_DEFAULT_PLUGIN_TYPE="plugin"
112 ])
113
114 AC_SUBST(VLC_DEFAULT_PLUGIN_TYPE)
115
116 dnl
117 dnl  Check for the contrib directory
118 dnl
119 AC_ARG_WITH(contrib,
120     [  --without-contrib       do not use the libraries in CONTRIB_DIR],[],[])
121 AC_ARG_VAR([CONTRIB_DIR], [directory containing pre-built contrib, overriding extras/contrib])
122 AS_IF([test "${with_contrib}" != "no"],[
123   AS_IF([test -z "$CONTRIB_DIR"], [
124       topdir="`dirname $0`"
125       if test "`echo \"$topdir\" | cut -c 1`" != "/"; then
126          topdir="`pwd`/$topdir"
127       fi
128       CONTRIB_DIR="${topdir}/extras/contrib/hosts/${host}"
129       if ! test -d "$CONTRIB_DIR"
130       then
131         gccmachine=`$CC -dumpmachine`
132         CONTRIB_DIR="${topdir}/extras/contrib/hosts/${gccmachine}"
133       fi
134   ])
135   AC_MSG_CHECKING([for libs in ${CONTRIB_DIR}])
136   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
137     AC_MSG_RESULT([yes])
138     AC_SUBST(CONTRIB_DIR)
139     export PATH=${CONTRIB_DIR}/bin:$PATH
140     CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
141     CPPFLAGS_save="${CPPFLAGS_save} -I${CONTRIB_DIR}/include"
142     CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
143     CFLAGS_save="${CFLAGS_save} -I${CONTRIB_DIR}/include"
144     CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
145     CXXFLAGS_save="${CXXFLAGS_save} -I${CONTRIB_DIR}/include"
146     OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
147     OBJCFLAGS_save="${OBJCFLAGS_save} -I${CONTRIB_DIR}/include"
148     if test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"; then
149         export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
150     else
151         export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
152     fi
153     LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
154     LDFLAGS_save="${LDFLAGS_save} -L${CONTRIB_DIR}/lib"
155
156     if test "${SYS}" = "darwin"; then
157       export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
158       export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
159     fi
160   ],[
161     AC_MSG_RESULT([no])
162     CONTRIB_DIR=""
163   ])
164 ])
165
166 dnl
167 dnl  Set default values
168 dnl
169 LDFLAGS_vlc="${LDFLAGS}"
170
171 dnl
172 dnl  Check the operating system
173 dnl
174 HAVE_WIN64="0"
175 case "${host_os}" in
176   "")
177     SYS=unknown
178     ;;
179   linux*)
180     SYS=linux
181     ;;
182   bsdi*)
183     SYS=bsdi
184     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
185     VLC_ADD_LIBS([vcd cdda vcdx],[-ldvd])
186     ;;
187   *bsd*)
188     SYS="${host_os}"
189     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
190     case "${host_os}" in
191       freebsd*)
192         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include"
193         CPPFLAGS="${CPPFLAGS_save}"
194         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib"
195         LDFLAGS="${LDFLAGS_save}"
196         ;;
197       openbsd*)
198         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include -I/usr/X11R6/include"
199         CPPFLAGS="${CPPFLAGS_save}"
200         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib -L/usr/X11R6/lib/"
201         LDFLAGS="${LDFLAGS_save}"
202         ;;
203     esac
204     ;;
205   darwin*)
206
207     dnl Force gcc "-arch" flag
208     ARCH_flag=""
209     case "${host}" in
210       i386*)
211         ARCH_flag="-arch i386"
212       ;;
213       ppc64*)
214         ARCH_flag="-arch ppc64"
215       ;;
216       ppc*)
217         ARCH_flag="-arch ppc"
218       ;;
219       x86_64*)
220         ARCH_flag="-arch x86_64"
221       ;;
222     esac
223
224     SYS=darwin
225     CFLAGS_save="${CFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CFLAGS="${CFLAGS_save}"
226     CXXFLAGS_save="${CXXFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CXXFLAGS="${CXXFLAGS_save}"
227     CPPFLAGS_save="${CPPFLAGS_save} ${ARCH_flag}"; CPPFLAGS="${CPPFLAGS_save}"
228     OBJCFLAGS_save="${OBJCFLAGS_save} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"; OBJCFLAGS="${OBJCFLAGS_save}"
229     LDFLAGS_save="${LDFLAGS_save} -Wl,-headerpad_max_install_names ${ARCH_flag}"; LDFLAGS="${LDFLAGS_save}"
230     VLC_ADD_LDFLAGS([mkv mp4 motion], [-Wl,-framework,IOKit,-framework,CoreFoundation])
231     VLC_ADD_LDFLAGS([libvlc vlc],[-Wl,-undefined,dynamic_lookup])
232     VLC_ADD_LDFLAGS([avcodec avformat access_avio swscale postproc i420_rgb_mmx x264],[-Wl,-read_only_relocs,suppress])
233     VLC_ADD_CFLAGS([motion],[-fconstant-cfstrings])
234     VLC_ADD_LDFLAGS([libvlccore],[-Wl,-framework,CoreFoundation])
235     AC_ARG_ENABLE(macosx-defaults,
236       AS_HELP_STRING([--enable-macosx-defaults],[Build the default configuration on Mac OS X (default enabled)]))
237     if test "x${enable_macosx_defaults}" != "xno"
238     then
239         echo ""
240         echo "Building with Mac OS X defaults:"
241         with_macosx_version_min="10.5"
242         echo "  Assuming --with-macosx-version-min=10.5"
243         with_macosx_sdk="/Developer/SDKs/MacOSX${with_macosx_version_min}.sdk"
244         echo "  Assuming --with-macosx-sdk=/Developer/SDKs/MacOSX${with_macosx_version_min}.sdk"
245         build_dir=`pwd`
246         echo "  Assuming --prefix=${build_dir}/vlc_install_dir"
247         ac_default_prefix="${build_dir}/vlc_install_dir"
248         enable_faad="yes"
249         echo "  Assuming --enable-faad"
250         enable_flac="yes"
251         echo "  Assuming --enable-flac"
252         enable_theora="yes"
253         echo "  Assuming --enable-theora"
254         enable_shout="yes"
255         echo "  Assuming --enable-shout"
256         enable_vcdx="yes"
257         echo "  Assuming --enable-vcdx"
258         enable_caca="yes"
259         echo "  Assuming --enable-caca"
260         enable_ncurses="yes"
261         echo "  Assuming --enable-ncurses"
262         enable_twolame="yes"
263         echo "  Assuming --enable-twolame"
264         enable_realrtsp="yes"
265         echo "  Assuming --enable-realrtsp"
266         enable_libass="yes"
267         echo "  Assuming --enable-libass"
268
269         enable_skins2="no"
270         echo "  Assuming --disable-skins2"
271         enable_xcb="no"
272         echo "  Assuming --disable-xcb"
273     fi
274     dnl
275     dnl  Check for Mac OS X SDK settings
276     dnl
277     AC_ARG_WITH(macosx-sdk,
278        [  --with-macosx-sdk=DIR   compile using the SDK in DIR])
279     if test "${with_macosx_sdk}" != "" ; then
280         CPP="${CPP} -isysroot ${with_macosx_sdk}"
281         CC="${CC} -isysroot ${with_macosx_sdk}"
282         CXX="${CXX} -isysroot ${with_macosx_sdk}"
283         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
284         LD="${LD} -syslibroot ${with_macosx_sdk}"
285     fi
286     AC_ARG_WITH(macosx-version-min,
287        [  --with-macosx-version-min=VERSION compile for MacOSX VERSION and above])
288     if test "${with_macosx_version_min}" != "" ; then
289         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
290         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
291         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
292         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
293         LD="${LD} -macosx_version_min=${with_macosx_version_min}"
294         CFLAGS_save="${CFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CFLAGS="${CFLAGS_save}"
295         CXXFLAGS_save="${CXXFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CXXFLAGS="${CXXFLAGS_save}"
296         OBJCFLAGS_save="${OBJCFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; OBJCFLAGS="${OBJCFLAGS_save}"
297         MACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}
298         export MACOSX_DEPLOYMENT_TARGET
299     fi
300     ;;
301   *mingw32* | *cygwin* | *wince* | *mingwce*)
302     AC_CHECK_TOOL(WINDRES, windres, :)
303     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
304
305     case "${host_os}" in
306       *wince* | *mingwce* | *mingw32ce*)
307         SYS=mingwce
308         dnl Sadly CeGCC still needs non-wince macros
309         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0500' for Windows 2000 APIs.])
310         ;;
311       *mingw32*)
312         SYS=mingw32
313         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0500' for Windows XP APIs.])
314         ;;
315       *cygwin*)
316         dnl Check if we are using the mno-cygwin mode in which case we are
317         dnl actually dealing with a mingw32 compiler.
318         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0501' for Windows XP APIs.])
319         AC_EGREP_CPP(yes,
320             [#ifdef WIN32
321              yes
322              #endif],
323             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
324         ;;
325     esac
326
327     if test "${SYS}" = "mingw32"; then
328         # add ws2_32 for closesocket, select, recv
329         VLC_ADD_LIBS([libvlccore],[-lws2_32 -lnetapi32 -lwinmm])
330         VLC_ADD_LDFLAGS([vlc],[-mwindows])
331         VLC_ADD_LIBS([win32text],[-lgdi32])
332         VLC_ADD_LIBS([cdda vcdx sdl_image aout_sdl vout_sdl],[-lwinmm])
333         VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_shout access_output_rtmp sap oldhttp stream_out_standard stream_out_select stream_out_rtp stream_out_raop vod_rtsp access_realrtsp rtp oldrc netsync gnutls growl_udp flac ts audioscrobbler lua remoteosd zvbi audiobargraph_a netsync],[-lws2_32])
334         VLC_ADD_LIBS([filesystem], [-lshlwapi])
335         dnl
336         dnl DEP and ASLR options
337         dnl
338         AC_ARG_ENABLE(peflags,
339           [  --enable-peflags        peflags use (default enabled on Windows)])
340         if test "${enable_peflags}" != "no" ; then
341           AC_PATH_TOOL(PEFLAGS, peflags, :)
342         fi
343         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
344         ac_default_prefix="`pwd`/_win32"
345         DESTDIR="`pwd`/_win32/"
346
347         dnl
348         dnl NSIS Installer prefix and WIN64
349         dnl
350         case "${host}" in
351             amd64*|i686-w64*|x86_64*)
352                 HAVE_WIN64="1"
353                 PROGRAMFILES="PROGRAMFILES64"
354             ;;
355             *)
356                 PROGRAMFILES="PROGRAMFILES"
357             ;;
358         esac
359         AC_SUBST(PROGRAMFILES)
360
361     fi
362     if test "${SYS}" = "mingwce"; then
363         # add ws2 for closesocket, select, recv
364         VLC_ADD_LIBS([libvlccore access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_rtmp sap oldhttp netsync audioscrobbler growl rtp stream_out_standard stream_out_select stream_out_rtp remoteosd ts audiobargraph_a netsync],[-lws2])
365         VLC_ADD_LIBS([libvlccore],[-lmmtimer])
366         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
367         ac_default_prefix="`pwd`/_wince"
368         DESTDIR="`pwd`/_wince/"
369     fi
370     ;;
371   *nto*)
372     SYS=nto
373     ;;
374   solaris*)
375     SYS=solaris
376     ;;
377   hpux*)
378     SYS=hpux
379     ;;
380   symbian*)
381     SYS=symbian
382     ;;
383   *)
384     SYS="${host_os}"
385     ;;
386 esac
387 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
388 AM_CONDITIONAL(HAVE_LINUX, [test "${SYS}" = "linux"])
389 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
390 AM_CONDITIONAL(HAVE_WIN64, test "${HAVE_WIN64}" = "1")
391 AM_CONDITIONAL(HAVE_WINCE, test "${SYS}" = "mingwce")
392 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
393 AM_CONDITIONAL(USE_PEFLAGS, [test "${enable_peflags}" = "yes"])
394
395 dnl
396 dnl Sadly autoconf doesn't think about testing foo.exe when ask to test
397 dnl for program foo on win32
398
399 case "${build_os}" in
400     cygwin|msys)
401         ac_executable_extensions=".exe"
402     ;;
403     *)
404     ;;
405 esac
406
407 dnl
408 dnl  Libtool
409 dnl  It's very bad, but our former custom system was worst
410 dnl  -- Courmisch
411 dnl
412
413 dnl override platform specific check for dependent libraries
414 dnl otherwise libtool linking of shared libraries will
415 dnl fail on anything other than pass_all.
416 AC_CACHE_VAL(lt_cv_deplibs_check_method,
417     [lt_cv_deplibs_check_method=pass_all])
418
419 AC_DISABLE_STATIC
420 dnl AC_DISABLE_FAST_INSTALL
421 AC_LIBTOOL_DLOPEN
422 AC_LIBTOOL_WIN32_DLL
423 m4_undefine([AC_PROG_F77])
424 m4_defun([AC_PROG_F77],[])
425 AC_PROG_LIBTOOL
426
427 m4_undefine([AC_DEPLIBS_CHECK_METHOD])
428 m4_defun([AC_DEPLIBS_CHECK_METHOD],[])
429
430 lt_cv_deplibs_check_method=pass_all
431
432 dnl
433 dnl Gettext stuff
434 dnl
435 AM_GNU_GETTEXT_VERSION([0.18.1])
436 AM_GNU_GETTEXT([external])
437 VLC_ADD_LIBS([libvlccore vlc], [${LTLIBINTL}])
438
439 dnl
440 dnl Iconv stuff
441 dnl
442 AM_ICONV
443 VLC_ADD_CFLAGS([libvlccore],[${INCICONV}])
444 VLC_ADD_LIBS([libvlccore],[${LTLIBICONV}])
445
446 dnl Check for broken versions of mingw-runtime compatability library
447 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
448     AC_MSG_CHECKING(for broken mingw-runtime)
449     AC_PREPROC_IFELSE([
450 #include <_mingw.h>
451 #if (__MINGW32_MAJOR_VERSION == 3) && (__MINGW32_MINOR_VERSION < 15)
452 #ifndef __MINGW64_VERSION_MAJOR
453 # error Attempting to use mingw-runtime with broken vsnprintf support
454 #endif
455 #endif
456     ], [
457         AC_MSG_RESULT([ok])
458     ], [
459         AC_MSG_RESULT([present])
460         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher!])
461     ])
462     dnl force use of mingw provided c99 *printf over msvcrt
463     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
464     CPPFLAGS_save="${CPPFLAGS_save} -D__USE_MINGW_ANSI_STDIO=1"
465 ])
466
467 dnl Check for the need to include the mingwex lib for mingw32
468 if test "${SYS}" = "mingw32" ; then
469     AC_CHECK_LIB(mingwex,opendir,
470         AC_CHECK_LIB(mingw32,opendir,,
471             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
472     )
473 fi
474
475 dnl Check for fnative-struct or mms-bitfields support for mingw32
476 if test "${SYS}" = "mingw32" ; then
477     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
478         [ac_cv_c_mms_bitfields],
479         [CFLAGS="${CFLAGS_save} -mms-bitfields"
480          AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
481     if test "${ac_cv_c_mms_bitfields}" != "no"; then
482         CFLAGS_save="${CFLAGS_save} -mms-bitfields";
483         CXXFLAGS_save="${CXXFLAGS_save} -mms-bitfields";
484     else
485         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
486             [ac_cv_c_fnative_struct],
487             [CFLAGS="${CFLAGS_save} -fnative-struct"
488              AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
489         if test "${ac_cv_c_fnative_struct}" != "no"; then
490             CFLAGS_save="${CFLAGS_save} -fnative-struct";
491             CXXFLAGS_save="${CXXFLAGS_save} -fnative-struct";
492         fi
493     fi
494
495     CFLAGS="${CFLAGS_save}"; CXXFLAGS="${CXXFLAGS_save}"
496 fi
497
498 dnl Check for fvtable-thunks support for mingw32
499 if test "${SYS}" = "mingw32" -a "${CXX}" != "" ; then
500     AC_LANG_PUSH(C++)
501     AC_CACHE_CHECK([if \$CXX accepts -fvtable-thunks],
502         [ac_cv_cxx_fvtable_thunks],
503         [CXXFLAGS="${CXXFLAGS_save} -Wall -Werror -fvtable-thunks"
504          AC_TRY_COMPILE([],,ac_cv_cxx_fvtable_thunks=yes,
505                         ac_cv_cxx_fvtable_thunks=no)])
506     if test "${ac_cv_cxx_fvtable_thunks}" = "yes"; then
507         CXXFLAGS_mingw32_special="-fvtable-thunks"
508     fi
509
510     CXXFLAGS_save="${CXXFLAGS_save} ${CXXFLAGS_mingw32_special}"; CXXFLAGS="${CXXFLAGS_save}"
511     AC_LANG_POP(C++)
512 fi
513
514 dnl
515 dnl Buggy glibc prevention. Purposedly not cached.
516 dnl See sourceware.org bugs 5058 and 5443.
517 dnl Ubuntu alone has 20 bug numbers for this...
518 dnl
519 AC_MSG_CHECKING(for buggy GNU/libc versions)
520 AC_PREPROC_IFELSE([
521 #include <limits.h>
522 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
523   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
524 # error GNU/libc with dcgettext killer bug!
525 #endif
526 ], [
527   AC_MSG_RESULT([not present])
528 ], [
529   AC_MSG_RESULT([found])
530   AS_IF([test "x${enable_nls}" != "xno"], [
531     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
532 work-around for this. Check with your distribution vendor on how to update the
533 glibc run-time. Alternatively, build with --disable-nls.])
534   ], [
535     AC_DEFINE(DISABLE_BUGGY_GLIBC_CHECK, 1, [Disables runtime check for buggy glibc.])
536   ])
537 ])
538
539 dnl Plugin compilation stuff
540
541 VLC_LIBRARY_SUFFIX
542
543 dnl The -DSYS_FOO flag
544 CPPFLAGS_save="${CPPFLAGS_save} -DSYS_`echo ${SYS} | sed -e 's/-.*//' | tr 'abcdefghijklmnopqrstuvwxyz.' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`"; CPPFLAGS="${CPPFLAGS_save}"
545
546 dnl Check for system libs needed
547 need_libc=false
548
549 dnl Check for usual libc functions
550 AC_CHECK_FUNCS([daemon fcntl fdopendir fstatvfs fork getenv getpwuid_r gettimeofday isatty lstat memalign mmap openat pread posix_fadvise posix_madvise posix_memalign setlocale stricmp strnicmp uselocale])
551 AC_REPLACE_FUNCS([asprintf atof atoll getcwd getdelim getpid gmtime_r lldiv localtime_r nrand48 rewind setenv strcasecmp strcasestr strdup strlcpy strncasecmp strndup strnlen strsep strtof strtok_r strtoll swab tdestroy vasprintf])
552 AC_CHECK_FUNCS(fdatasync,,
553   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
554 ])
555
556 # Windows CE doesn't have strcoll()
557 AC_FUNC_STRCOLL
558
559 dnl Check for non-standard system calls
560 AC_CHECK_FUNCS([accept4 dup3 pipe2 eventfd vmsplice sched_getaffinity])
561
562 AH_BOTTOM([#include <vlc_fixups.h>])
563
564 SOCKET_LIBS=""
565 AC_CHECK_FUNCS(connect,,[
566   AC_CHECK_LIB(socket,connect,[
567     VLC_ADD_LIBS([libvlccore cdda],-lsocket)
568     SOCKET_LIBS="-lsocket"
569   ])
570 ])
571 AC_SUBST(SOCKET_LIBS)
572
573 AC_CHECK_FUNCS(send,,[
574   AC_CHECK_LIB(socket,send,[
575     VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp sap access_output_udp access_output_rtmp stream_out_standard growl_udp remoteosd netsync],[-lsocket])
576   ])
577 ])
578
579
580 dnl Check for socklen_t
581 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
582 AC_CACHE_CHECK([for socklen_t in sys/socket.h],
583 ac_cv_type_socklen_t,
584 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
585 [#include <sys/types.h>
586 #ifdef WIN32
587 # include <winsock2.h>
588 # include <ws2tcpip.h>
589 #else
590 # include <sys/socket.h>
591 #endif]], [[socklen_t len; len = 0;]])],
592 ac_cv_type_socklen_t=yes,
593 ac_cv_type_socklen_t=no)])
594 AS_IF([test "$ac_cv_type_socklen_t" = no],
595  [AC_DEFINE(socklen_t, int)])
596
597 dnl Check for struct sockaddr_storage
598 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.])
599 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.])
600 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
601   [AC_TRY_COMPILE(
602     [#include <sys/types.h>
603      #if defined( UNDER_CE )
604      # include <winsock2.h>
605      #elif defined( WIN32 )
606      # include <winsock2.h>
607      #else
608      # include <sys/socket.h>
609      #endif], [struct sockaddr_storage addr;],
610      ac_cv_struct_sockaddr_storage=yes,
611      ac_cv_struct_sockaddr_storage=no)])
612 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
613   AC_DEFINE(sockaddr_storage, sockaddr)
614   AC_DEFINE(ss_family, sa_family)
615 ])
616
617 dnl getaddrinfo, getnameinfo and gai_strerror check
618 dnl  -lnsl and -lsocket are needed on Solaris;
619 dnl  we purposedly make the test fail on Windows
620 LIBS_save="${LIBS}"
621 AC_SEARCH_LIBS([getaddrinfo], [nsl],,, [${SOCKET_LIBS}])
622 LIBS="${LIBS_save}"
623
624 dnl Check for va_copy
625 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
626   AC_TRY_LINK(
627     [#include <stdarg.h>],
628     [va_list ap1, ap2; va_copy(ap1,ap2);],
629     [ac_cv_c_va_copy="yes"],
630     [ac_cv_c_va_copy="no"]))
631 if test "${ac_cv_c_va_copy}" = "yes"; then
632   AC_DEFINE(HAVE_VA_COPY, 1, [Define if <stdarg.h> defines va_copy.])
633 fi
634 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
635   AC_TRY_LINK(
636     [#include <stdarg.h>],
637     [va_list ap1, ap2; __va_copy(ap1,ap2);],
638     [ac_cv_c___va_copy="yes"],
639     [ac_cv_c___va_copy="no"]))
640 if test "${ac_cv_c___va_copy}" = "yes"; then
641   AC_DEFINE(HAVE___VA_COPY, 1, [Define if <stdarg.h> defines __va_copy.])
642 fi
643
644 AC_CHECK_FUNCS(inet_aton,,[
645   AC_CHECK_LIB(resolv,inet_aton,[
646     VLC_ADD_LIBS([libvlccore],[-lresolv])
647   ])
648 ])
649
650 dnl FreeBSD has a gnugetopt library for this:
651 GNUGETOPT_LIBS=""
652 AC_CHECK_FUNC(getopt_long,, [
653   AC_CHECK_LIB([gnugetopt],[getopt_long], [
654     GNUGETOPT_LIBS="-lgnugetopt"
655   ])
656 ])
657 AC_SUBST(GNUGETOPT_LIBS)
658
659 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
660 AC_CHECK_LIB(m,cos,[
661   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom visual panoramix rotate noise grain scene kate flac lua chorus_flanger],[-lm])
662 ])
663 AC_CHECK_LIB(m,pow,[
664   VLC_ADD_LIBS([avcodec avformat access_avio swscale postproc ffmpegaltivec i420_rgb faad twolame equalizer spatializer param_eq libvlccore freetype mod mpc dmo quicktime realvideo qt4],[-lm])
665 ])
666 AC_CHECK_LIB(m,sqrt,[
667   VLC_ADD_LIBS([compressor headphone_channel_mixer normvol audiobargraph_a speex mono colorthres extract ball],[-lm])
668 ])
669 AC_CHECK_LIB(m,ceil,[
670   VLC_ADD_LIBS([access_imem hotkeys mosaic swscale_omap],[-lm])
671 ])
672 AC_CHECK_LIB(m,exp,[
673   VLC_ADD_LIBS([gaussianblur],[-lm])
674 ])
675 AC_CHECK_LIB(m,round,[
676   VLC_ADD_LIBS([dbus],[-lm])
677 ])
678 AC_CHECK_LIB(m,sqrtf,[
679   VLC_ADD_LIBS([x264],[-lm])
680 ])
681 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
682
683 AC_CHECK_LIB(m,lrintf, [
684   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
685   VLC_ADD_LIBS([skins2],[-lm])
686 ])
687
688 dnl Check for dynamic plugins
689 ac_cv_have_plugins=no
690
691 # HP-UX style
692 if test "${ac_cv_have_plugins}" = "no"; then
693   AC_CHECK_HEADERS(dl.h)
694   ac_cv_my_have_shl_load=no
695   AC_CHECK_FUNC(shl_load,
696    [ac_cv_my_have_shl_load=yes,
697     AC_CHECK_LIB(dld, shl_load,
698      [ac_cv_my_have_shl_load=yes
699       VLC_ADD_LIBS([libvlccore],[-ldld])])])
700   if test "${ac_cv_my_have_shl_load}" = "yes"; then
701     AC_DEFINE(HAVE_DL_SHL_LOAD, 1, [Define if you have the shl_load API])
702     ac_cv_have_plugins=yes
703   fi
704 fi
705
706 # Win32 style
707 if test "${ac_cv_have_plugins}" = "no"; then
708   if test "${SYS}" = "mingw32" ; then
709     AC_CHECK_LIB(kernel32, main,
710      [VLC_ADD_LIBS([libvlccore],[-lkernel32])
711       AC_DEFINE(HAVE_DL_WINDOWS, 1, [Define if you have Windows' LoadLibrary])
712       ac_cv_have_plugins=yes])
713   fi
714 fi
715
716 # WinCE style
717 if test "${ac_cv_have_plugins}" = "no"; then
718   if test "${SYS}" = "mingwce"; then
719     AC_DEFINE(HAVE_DL_WINDOWS, 1, [Define if you have Windows' LoadLibrary])
720     ac_cv_have_plugins=yes
721   fi
722 fi
723
724 # Only test for dlopen() if the others didn't work
725 LIBDL=""
726 if test "${ac_cv_have_plugins}" = "no" -o "${SYS}" = "darwin"; then
727   AC_CHECK_HEADERS(dlfcn.h sys/dl.h)
728   ac_cv_my_have_dlopen=no
729   AC_CHECK_FUNC(dlopen, [
730     ac_cv_my_have_dlopen=yes
731   ], [
732     AC_CHECK_LIB(dl, dlopen, [
733       ac_cv_my_have_dlopen=yes
734       LIBDL="-ldl"
735     ], [
736       AC_CHECK_LIB(svld, dlopen, [
737         ac_cv_my_have_dlopen=yes
738         LIBDL="-lsvld"
739       ])
740     ])
741   ])
742   if test "${ac_cv_my_have_dlopen}" = "yes"; then
743     AC_DEFINE(HAVE_DL_DLOPEN, 1, [Define if you have the dlopen API])
744     ac_cv_have_plugins=yes
745     VLC_ADD_LIBS([libvlccore realvideo lua],[$LIBDL])
746   fi
747 fi
748 AC_SUBST(LIBDL)
749
750 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
751   dnl Check for pthreads - borrowed from XMMS
752   THREAD_LIB=error
753   if test "${THREAD_LIB}" = "error"; then
754     AC_CHECK_LIB(pthread,main,THREAD_LIB="-lpthread")
755   fi
756   if test "${THREAD_LIB}" = "error"; then
757     AC_CHECK_LIB(pthreads,main,THREAD_LIB="-lpthreads")
758   fi
759   if test "${THREAD_LIB}" = "error"; then
760     AC_CHECK_LIB(c_r,main,THREAD_LIB="-lc_r")
761   fi
762   if test "${THREAD_LIB}" = "error"; then
763     AC_CHECK_FUNCS(pthread_mutex_lock)
764     THREAD_LIB=""
765   fi
766
767   VLC_ADD_LIBS([libvlccore libvlc vlc plugin],[${THREAD_LIB}])
768
769   AC_CHECK_LIB(rt, clock_nanosleep, [
770     VLC_ADD_LIBS([libvlccore],[-lrt])
771     AC_DEFINE(HAVE_CLOCK_NANOSLEEP, 1, [Define to 1 if you have clock_nanosleep.])
772   ], [
773     dnl HP/UX port
774     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
775   ])
776
777   have_nanosleep=false
778   AC_CHECK_FUNCS(nanosleep,have_nanosleep=:,[
779     AC_CHECK_LIB(rt,nanosleep,
780       [VLC_ADD_LIBS([libvlccore],[-lrt]) have_nanosleep=:],
781       [AC_CHECK_LIB(posix4,nanosleep,
782           [VLC_ADD_LIBS([libvlccore],[-lposix4]) have_nanosleep=:])]
783     )
784   ])
785   if ${have_nanosleep}; then
786     AC_DEFINE(HAVE_NANOSLEEP, 1, [Define if nanosleep is available.])
787   fi
788 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
789
790 dnl Check for misc headers
791 AC_MSG_CHECKING(for strncasecmp in strings.h)
792 AC_EGREP_HEADER(strncasecmp,strings.h,[
793   AC_MSG_RESULT(yes)
794   AC_DEFINE(STRNCASECMP_IN_STRINGS_H, 1,
795             Define if <strings.h> defines strncasecmp.)],[
796   AC_MSG_RESULT(no)])
797
798 dnl Check for headers
799 AC_CHECK_HEADERS([search.h])
800 AC_CHECK_HEADERS(getopt.h strings.h locale.h xlocale.h)
801 AC_CHECK_HEADERS(fcntl.h sys/time.h sys/ioctl.h sys/stat.h)
802 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h netinet/udplite.h sys/eventfd.h])
803 AC_CHECK_HEADERS([net/if.h], [], [],
804   [
805     #include <sys/types.h>
806     #include <sys/socket.h>
807   ])
808 AC_CHECK_HEADERS([sys/mount.h], [], [],
809   [
810     #include <sys/param.h>
811   ])
812
813 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
814   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
815   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
816   AC_CHECK_HEADERS(syslog.h)
817 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
818
819 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
820 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.])
821 AC_CHECK_TYPE(ssize_t,, [
822   AC_DEFINE(ssize_t, int)
823 ])
824
825 dnl Check for poll
826 AC_SEARCH_LIBS(poll, [poll], [AC_DEFINE(HAVE_POLL, 1, [Define to 1 if the OS is usabl... err, has poll().])], [
827 if test ${SYS} != "mingw32" -a ${SYS} != "mingwce"
828 then
829     AC_MSG_WARN([Your platform does not support poll(). VLC has it's own poll() implementation, but it is only intended to be used on Windows. VLC might crash or be insecure when you see this message. Either switch to an OS with a proper poll() implementation, or implement one for your OS in VLC])
830 fi
831 ])
832
833 dnl Mac OS X and other OSes don't have declaration for nanosleep
834 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
835   AC_MSG_CHECKING(for nanosleep in time.h)
836   AC_EGREP_HEADER(nanosleep,time.h,[
837     AC_MSG_RESULT(yes)
838     AC_DEFINE(HAVE_DECL_NANOSLEEP, 1,
839               Define if <time.h> defines nanosleep.)
840   ],[
841     AC_MSG_RESULT(no)
842   ])
843 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
844
845 dnl Make sure we have timespecs
846 AC_MSG_CHECKING(for timespec in sys/time.h)
847 AC_EGREP_HEADER(timespec,sys/time.h,[
848   AC_MSG_RESULT(yes)
849   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
850             Define if <sys/time.h> defines struct timespec.)
851 ],[
852   AC_MSG_RESULT(no)
853 ])
854
855 dnl Check for threads library
856 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
857   AC_CHECK_HEADERS(pthread.h)
858 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
859
860 dnl It seems that autoconf detects pkg-config only during the first
861 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
862 dnl it is nested within a conditional block, so it was not working right.
863 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
864 AC_ARG_VAR(PKG_CONFIG_PATH,
865        [Paths where to find .pc not at the default location])
866 PKG_PROG_PKG_CONFIG()
867
868 dnl On some OS we need static linking 
869 AS_IF([test -n "${PKG_CONFIG}" ],[
870     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce" -o "${SYS}" = "darwin" ],[
871         PKG_CONFIG="${PKG_CONFIG} --static"
872     ])
873 ])
874
875
876 dnl
877 dnl Check for zlib.h and -lz along with system -lminizip if available
878 dnl
879 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
880 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
881 if test "${have_zlib}" = "yes"
882 then
883   VLC_ADD_LIBS([access_http mp4 skins2 sap mkv unzip zip],[-lz])
884   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
885     AC_CHECK_HEADERS([unzip.h], [ 
886       have_minizip=yes
887       MINIZIP_LIBS="-lminizip -lz"
888     ], [
889       have_minizip=no
890       MINIZIP_CFLAGS="-I\\\${top_srcdir}/libs/unzip"
891       MINIZIP_LIBS="\\\${top_builddir}/libs/unzip/libunzip.la"
892     ])
893   ])
894   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
895   VLC_ADD_CFLAGS([zip],[$MINIZIP_CFLAGS])
896   VLC_ADD_LIBS([skins2 zip],[$MINIZIP_LIBS])
897   VLC_ADD_PLUGIN([unzip zip])
898 fi
899 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
900
901
902 dnl Manual switch for UTF-8
903 AC_ARG_ENABLE(non-utf8,
904   [  --enable-non-utf8       Legacy non-UTF-8 systems support (default disabled)],, [
905   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
906     enable_non_utf8="no"
907   ])
908 ])
909 AS_IF([test "${enable_non_utf8}" != "no"], [
910   AC_DEFINE([ASSUME_UTF8], [1],
911             [Define to 1 if the operating system uses UTF-8 internally])
912 ])
913
914
915 dnl Check for dbus
916 AC_ARG_ENABLE(dbus,
917   [  --enable-dbus           Linux D-BUS message bus system (default enabled)])
918 case "${SYS}" in
919     linux*|*bsd*)
920 if test "${enable_dbus}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
921 then
922   dnl api stable dbus
923   PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0.0,
924     [ AC_DEFINE( HAVE_DBUS, 1, [Define if you have the D-BUS library] )
925       VLC_ADD_LIBS([libvlccore],[$DBUS_LIBS])
926       VLC_ADD_CFLAGS([libvlccore],[$DBUS_CFLAGS])
927       dnl Check for dbus control interface
928         AC_ARG_ENABLE(dbus-control, [  --disable-dbus-control  D-BUS control interface (default enabled)])
929         if test "${enable_dbus_control}" != "no"
930         then
931           VLC_ADD_PLUGIN([dbus])
932           VLC_ADD_LIBS([dbus],[$DBUS_LIBS])
933           VLC_ADD_CFLAGS([dbus],[$DBUS_CFLAGS])
934         fi
935       dnl Check for Telepathy
936         AC_ARG_ENABLE(telepathy,
937           AS_HELP_STRING([--enable-telepathy],[Telepathy Presence plugin through DBus(default enabled)]))
938         if test "${enable_telepathy}" != "no"; then
939           VLC_ADD_PLUGIN([telepathy])
940           VLC_ADD_LIBS([telepathy],[$DBUS_LIBS])
941           VLC_ADD_CFLAGS([telepathy],[$DBUS_CFLAGS])
942         fi
943         dnl Power Management Inhibiter
944         VLC_ADD_PLUGIN([inhibit])
945         VLC_ADD_LIBS([inhibit],[$DBUS_LIBS])
946         VLC_ADD_CFLAGS([inhibit],[$DBUS_CFLAGS])
947     ],
948     [AC_MSG_ERROR([Couldn't find DBus >= 1.0.0, install libdbus-dev ?])]
949   )
950 fi
951 ;;
952 esac
953
954 dnl Check for ntohl, etc.
955 AC_CACHE_CHECK([for ntohl in sys/param.h],
956     [ac_cv_c_ntohl_sys_param_h],
957     [CFLAGS="${CFLAGS_save} -Wall -Werror"
958      AC_TRY_COMPILE([#include <sys/param.h>],
959         [int meuh; ntohl(meuh);],
960         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
961 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
962     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
963 fi
964 CFLAGS="${CFLAGS_save}"
965
966 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
967 RDC_PROG_CC_FLAGS([-pipe])
968
969 dnl Check for various optimization flags
970 AC_CACHE_CHECK([if \$CC accepts -Os],
971     [ac_cv_c_os],
972     [CFLAGS="${CFLAGS_save} -Os"
973      AC_TRY_COMPILE([],,ac_cv_c_os=yes, ac_cv_c_os=no)])
974 if test "${ac_cv_c_os}" != "no"; then
975     CFLAGS_OPTIM_SIZE="${CFLAGS_OPTIM_SIZE} -Os"
976 else
977     AC_CACHE_CHECK([if \$CC accepts -O],
978         [ac_cv_c_o],
979         [CFLAGS="${CFLAGS_save} -O"
980          AC_TRY_COMPILE([],,ac_cv_c_o=yes, ac_cv_c_o=no)])
981     if test "${ac_cv_c_o}" != "no"; then
982         if test "${ac_cv_c_o3}" = "no"; then
983             CFLAGS_OPTIM_SIZE="${CFLAGS_OPTIM_SIZE} -O"
984         fi
985     fi
986 fi
987
988 AC_CACHE_CHECK([if \$CC accepts -O4],
989     [ac_cv_c_o4],
990     [CFLAGS="${CFLAGS_save} -O4"
991      AC_TRY_COMPILE([],,ac_cv_c_o4=yes, ac_cv_c_o4=no)])
992 if test "${ac_cv_c_o4}" != "no" -a "x${enable_debug}" = "xno"; then
993     CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O4"
994 else
995     AC_CACHE_CHECK([if \$CC accepts -O3],
996         [ac_cv_c_o3],
997         [CFLAGS="${CFLAGS_save} -O3"
998          AC_TRY_COMPILE([],,ac_cv_c_o3=yes, ac_cv_c_o3=no)])
999     if test "${ac_cv_c_o3}" != "no" -a "x${enable_debug}" = "xno"; then
1000         CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O3"
1001     else
1002         AC_CACHE_CHECK([if \$CC accepts -O2],
1003             [ac_cv_c_o2],
1004             [CFLAGS="${CFLAGS_save} -O2"
1005              AC_TRY_COMPILE([],,ac_cv_c_o2=yes, ac_cv_c_o2=no)])
1006         if test "${ac_cv_c_o2}" != "no"; then
1007             CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O2"
1008         else
1009             AC_CACHE_CHECK([if \$CC accepts -O],
1010                 [ac_cv_c_o],
1011                 [CFLAGS="${CFLAGS_save} -O"
1012                  AC_TRY_COMPILE([],,ac_cv_c_o=yes, ac_cv_c_o=no)])
1013             if test "${ac_cv_c_o}" != "no"; then
1014                 CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O"
1015             fi
1016         fi
1017     fi
1018 fi
1019
1020 AC_CACHE_CHECK([if \$CC accepts -O0],
1021     [ac_cv_c_o0],
1022     [CFLAGS="${CFLAGS_save} -O0"
1023      AC_TRY_COMPILE([],,ac_cv_c_o0=yes, ac_cv_c_o0=no)])
1024 if test "${ac_cv_c_o0}" != "no"; then
1025     CFLAGS_NOOPTIM="${CFLAGS_NOOPTIM} -O0"
1026 fi
1027
1028 dnl Check for -ffast-math
1029 AC_CACHE_CHECK([if \$CC accepts -ffast-math],
1030     [ac_cv_c_fast_math],
1031     [CFLAGS="${CFLAGS_save} -ffast-math"
1032      AC_TRY_COMPILE([],,ac_cv_c_fast_math=yes, ac_cv_c_fast_math=no)])
1033 if test "${ac_cv_c_fast_math}" != "no"; then
1034     CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -ffast-math"
1035 fi
1036
1037 dnl Check for -funroll-loops
1038 AC_CACHE_CHECK([if \$CC accepts -funroll-loops],
1039     [ac_cv_c_unroll_loops],
1040     [CFLAGS="${CFLAGS_save} -funroll-loops"
1041      AC_TRY_COMPILE([],,ac_cv_c_unroll_loops=yes, ac_cv_c_unroll_loops=no)])
1042 if test "${ac_cv_c_unroll_loops}" != "no"; then
1043     CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -funroll-loops"
1044 fi
1045
1046 dnl Check for -fomit-frame-pointer
1047 AC_CACHE_CHECK([if \$CC accepts -fomit-frame-pointer],
1048     [ac_cv_c_omit_frame_pointer],
1049     [CFLAGS="${CFLAGS_save} -fomit-frame-pointer"
1050      AC_TRY_COMPILE([],,ac_cv_c_omit_frame_pointer=yes, ac_cv_c_omit_frame_pointer=no)])
1051 if test "${ac_cv_c_omit_frame_pointer}" != "no"; then
1052  if test "${SYS}" != "darwin"; then
1053     CFLAGS_OPTIM_NODEBUG="${CFLAGS_OPTIM_NODEBUG} -fomit-frame-pointer"
1054  else
1055     dnl On darwin we explicitely disable it.
1056     CFLAGS_OPTIM_NODEBUG="${CFLAGS_OPTIM_NODEBUG} -fno-omit-frame-pointer"
1057  fi
1058 fi
1059
1060 dnl Check for Darwin plugin linking flags
1061 AC_CACHE_CHECK([if \$CC accepts -bundle -undefined error],
1062     [ac_cv_ld_darwin],
1063     [CFLAGS="${CFLAGS_save} -bundle -undefined error"
1064      AC_TRY_COMPILE([],,ac_cv_ld_darwin=yes, ac_cv_ld_darwin=no)])
1065 if test "${ac_cv_ld_darwin}" != "no"; then
1066     VLC_ADD_LDFLAGS([plugin],[-bundle -undefined error])
1067 fi
1068
1069 dnl Checks for __attribute__(aligned()) directive
1070 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1071     [ac_cv_c_attribute_aligned],
1072     [ac_cv_c_attribute_aligned=0
1073         CFLAGS="${CFLAGS_save} -Werror"
1074     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1075         AC_TRY_COMPILE([],
1076         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1077         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1078     done
1079         CFLAGS="${CFLAGS_save}"])
1080 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1081     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1082         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1083 fi
1084
1085 dnl Check for __attribute__((packed))
1086 AC_CACHE_CHECK([for __attribute__((packed))],
1087   [ac_cv_c_attribute_packed],
1088   [ac_cv_c_attribute_packed=no
1089    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1090                     [ac_cv_c_attribute_packed=yes])])
1091 if test "${ac_cv_c_attribute_packed}" != "no"; then
1092   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1093 fi
1094
1095 dnl
1096 dnl  Check the CPU
1097 dnl
1098 case "${host_cpu}" in
1099   "")
1100     ARCH=unknown
1101     ;;
1102   *)
1103     ARCH="${host_cpu}"
1104     ;;
1105 esac
1106
1107 dnl Check for backtrace() support
1108 AC_CHECK_HEADERS(execinfo.h)
1109 AC_CHECK_FUNCS(backtrace)
1110
1111 dnl
1112 dnl  Enable profiling
1113 dnl
1114 AC_ARG_ENABLE(gprof,
1115 [  --enable-gprof          gprof profiling (default disabled)])
1116 AC_ARG_ENABLE(cprof,
1117 [  --enable-cprof          cprof profiling (default disabled)])
1118 test "${enable_gprof}" != "yes" && enable_gprof="no"
1119 test "${enable_cprof}" != "yes" && enable_cprof="no"
1120
1121 dnl
1122 dnl  default modules
1123 dnl
1124 ALIASES="${ALIASES} cvlc rvlc"
1125
1126 dnl
1127 dnl Some plugins aren't useful on some platforms
1128 dnl
1129 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
1130     VLC_ADD_PLUGIN([dynamicoverlay access_shm])
1131 elif test "${SYS}" != "mingwce"; then
1132     VLC_ADD_PLUGIN([access_smb dmo globalhotkeys])
1133     VLC_ADD_LIBS([dmo],[-lole32 -luuid])
1134 fi
1135 if test "${SYS}" = "darwin"; then
1136     VLC_ADD_LDFLAGS([quartztext],[-Wl,-framework,ApplicationServices])
1137 fi
1138
1139 dnl
1140 dnl  Accelerated modules
1141 dnl
1142 EXTEND_HELP_STRING([Optimization options:])
1143
1144 dnl  Check for fully working MMX intrinsics
1145 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1146 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1147 AC_ARG_ENABLE(mmx,
1148 [  --disable-mmx           disable MMX optimizations (default auto)],,[
1149   case "${host_cpu}" in
1150     i?86|x86_64)
1151       enable_mmx="yes"
1152       ;;
1153     *)
1154       enable_mmx="no"
1155       ;;
1156   esac
1157 ])
1158 have_mmx="no"
1159 have_mmxext="no"
1160 AS_IF([test "${enable_mmx}" != "no"], [
1161   ARCH="${ARCH} mmx"
1162
1163   AC_CACHE_CHECK([if $CC groks MMX intrinsics],
1164     [ac_cv_c_mmx_intrinsics],
1165     [CFLAGS="${CFLAGS_save} -O -mmmx"
1166      AC_TRY_COMPILE([#include <mmintrin.h>
1167                      #include <stdint.h>
1168                      uint64_t frobzor;],
1169                     [__m64 a, b, c;
1170                      a = b = c = (__m64)frobzor;
1171                      a = _mm_slli_pi16(a, 3);
1172                      a = _mm_adds_pi16(a, b);
1173                      c = _mm_srli_pi16(c, 8);
1174                      c = _mm_slli_pi16(c, 3);
1175                      b = _mm_adds_pi16(b, c);
1176                      a = _mm_unpacklo_pi8(a, b);
1177                      frobzor = (uint64_t)a;],
1178                     [ac_cv_c_mmx_intrinsics=yes],
1179                     [ac_cv_c_mmx_intrinsics=no])])
1180   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1181     AC_DEFINE(HAVE_MMX_INTRINSICS, 1,
1182               [Define to 1 if MMX intrinsics are available.])
1183     MMX_CFLAGS="-mmmx"
1184   ])
1185
1186   AC_CACHE_CHECK([if $CC groks MMX inline assembly],
1187     [ac_cv_mmx_inline],
1188     [CFLAGS="${CFLAGS_save}"
1189      AC_TRY_COMPILE(,[void *p;asm volatile("packuswb %%mm1,%%mm2"::"r"(p));],
1190                     ac_cv_mmx_inline=yes, ac_cv_mmx_inline=no)])
1191   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1192     AC_DEFINE(CAN_COMPILE_MMX, 1,
1193               [Define to 1 inline MMX assembly is available.])
1194     have_mmx="yes"
1195   ])
1196
1197   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1198     [ac_cv_mmxext_inline],
1199     [CFLAGS="${CFLAGS_save}"
1200      AC_TRY_COMPILE(,[void *p;asm volatile("maskmovq %%mm1,%%mm2"::"r"(p));],
1201                     ac_cv_mmxext_inline=yes, ac_cv_mmxext_inline=no)])
1202   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1203     AC_DEFINE(CAN_COMPILE_MMXEXT, 1,
1204               [Define to 1 if MMX EXT inline assembly is available.])
1205     have_mmxext="yes"
1206   ])
1207 ])
1208 AC_SUBST(MMX_CFLAGS)
1209 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1210 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1211
1212 dnl  Check for fully workin SSE2 intrinsics
1213 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1214 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1215 AC_ARG_ENABLE(sse,
1216 [  --disable-sse           disable SSE (1, 2, 3 and 4) optimizations (default auto)],
1217 , [
1218   case "${host_cpu}" in
1219     i686|x86_64)
1220       enable_sse=yes
1221       ;;
1222     *)
1223       enable_sse=no
1224       ;;
1225   esac
1226 ])
1227 have_sse2="no"
1228 AS_IF([test "${enable_sse}" != "no"], [
1229   ARCH="${ARCH} sse sse2"
1230
1231   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics],
1232     [ac_cv_c_sse2_intrinsics],
1233     [CFLAGS="${CFLAGS_save} -O -msse2"
1234      AC_TRY_COMPILE([#include <emmintrin.h>
1235                      #include <stdint.h>
1236                      uint64_t frobzor;],
1237                     [__m128i a, b, c;
1238                      a = b = c = _mm_set1_epi64((__m64)frobzor);
1239                      a = _mm_slli_epi16(a, 3);
1240                      a = _mm_adds_epi16(a, b);
1241                      c = _mm_srli_epi16(c, 8);
1242                      c = _mm_slli_epi16(c, 3);
1243                      b = _mm_adds_epi16(b, c);
1244                      a = _mm_unpacklo_epi8(a, b);
1245                      frobzor = (uint64_t)_mm_movepi64_pi64(a);],
1246                     [ac_cv_c_sse2_intrinsics=yes],
1247                     [ac_cv_c_sse2_intrinsics=no])])
1248   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1249     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1,
1250               [Define to 1 if SSE2 intrinsics are available.])
1251     SSE2_CFLAGS="-msse2"
1252   ])
1253
1254   AC_CACHE_CHECK([if $CC groks SSE inline assembly],
1255     [ac_cv_sse_inline],
1256     [CFLAGS="${CFLAGS_save}"
1257      AC_TRY_COMPILE(,[void *p;asm volatile("xorps %%xmm1,%%xmm2"::"r"(p));],
1258                     ac_cv_sse_inline=yes, ac_cv_sse_inline=no)])
1259   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1260     AC_DEFINE(CAN_COMPILE_SSE, 1,
1261               [Define to 1 if SSE inline assembly is available.])
1262   ])
1263
1264   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly],
1265     [ac_cv_sse2_inline],
1266     [CFLAGS="${CFLAGS_save}"
1267      AC_TRY_COMPILE(,[void *p;asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p));],
1268                     ac_cv_sse2_inline=yes, ac_cv_sse2_inline=no)])
1269   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1270     AC_DEFINE(CAN_COMPILE_SSE2, 1,
1271               [Define to 1 if SSE2 inline assembly is available.])
1272     have_sse2="yes"
1273   ])
1274
1275   # SSE3
1276   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly],
1277     [ac_cv_sse3_inline],
1278     [CFLAGS="${CFLAGS_save}"
1279      AC_TRY_COMPILE(,[void *p;asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p));],
1280                     ac_cv_sse3_inline=yes, ac_cv_sse3_inline=no)])
1281   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1282     AC_DEFINE(CAN_COMPILE_SSE3, 1,
1283               [Define to 1 if SSE3 inline assembly is available.]) ])
1284   # SSSE3
1285   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly],
1286     [ac_cv_ssse3_inline],
1287     [CFLAGS="${CFLAGS_save}"
1288      AC_TRY_COMPILE(,[void *p;asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p));],
1289                     ac_cv_ssse3_inline=yes, ac_cv_ssse3_inline=no)])
1290   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1291     AC_DEFINE(CAN_COMPILE_SSSE3, 1,
1292               [Define to 1 if SSSE3 inline assembly is available.]) ])
1293
1294   # SSE4.1
1295   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1296     [ac_cv_sse4_1_inline],
1297     [CFLAGS="${CFLAGS_save}"
1298      AC_TRY_COMPILE(,[void *p;asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p));],
1299                     ac_cv_sse4_1_inline=yes, ac_cv_sse4_1_inline=no)])
1300   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1301     AC_DEFINE(CAN_COMPILE_SSE4_1, 1,
1302               [Define to 1 if SSE4_1 inline assembly is available.]) ])
1303
1304   # SSE4.2
1305   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1306     [ac_cv_sse4_2_inline],
1307     [CFLAGS="${CFLAGS_save}"
1308      AC_TRY_COMPILE(,[void *p;asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p));],
1309                     ac_cv_sse4_2_inline=yes, ac_cv_sse4_2_inline=no)])
1310   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1311     AC_DEFINE(CAN_COMPILE_SSE4_2, 1,
1312               [Define to 1 if SSE4_2 inline assembly is available.]) ])
1313
1314   # SSE4A
1315   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly],
1316     [ac_cv_sse4a_inline],
1317     [CFLAGS="${CFLAGS_save}"
1318      AC_TRY_COMPILE(,[void *p;asm volatile("insertq %%xmm1,%%xmm0"::"r"(p));],
1319                     ac_cv_sse4a_inline=yes, ac_cv_sse4a_inline=no)])
1320   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1321     AC_DEFINE(CAN_COMPILE_SSE4A, 1,
1322               [Define to 1 if SSE4A inline assembly is available.]) ])
1323 ])
1324 AC_SUBST(SSE2_CFLAGS)
1325 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1326
1327 have_3dnow="no"
1328 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly],
1329     [ac_cv_3dnow_inline],
1330     [CFLAGS="${CFLAGS_save}"
1331      AC_TRY_COMPILE(,[void *p;asm volatile("pfadd %%mm1,%%mm2"::"r"(p));],
1332                     ac_cv_3dnow_inline=yes, ac_cv_3dnow_inline=no)])
1333 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1334   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1335             [Define to 1 if 3D Now! inline assembly is available.])
1336   have_3dnow="yes"
1337 ])
1338 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1339
1340
1341 AC_ARG_ENABLE(neon,
1342 [  --disable-neon          disable NEON optimizations (default auto)],, [
1343   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1344 ])
1345 AS_IF([test "${enable_neon}" != "no"], [
1346   AC_CACHE_CHECK([if $CC groks NEON inline assembly], [ac_cv_neon_inline], [
1347     CFLAGS="${CFLAGS_save} -mfpu=neon"
1348     AC_COMPILE_IFELSE([
1349       AC_LANG_PROGRAM(,[[
1350 asm volatile("vqmovun.s64 d0, q1":::"d0");
1351 asm volatile("ssat r0, #1, r0":::"r0"); /* assume ARMv6 */
1352 ]])
1353     ], [
1354       ac_cv_neon_inline="-mfpu=neon"
1355     ], [
1356       ac_cv_neon_inline="no"
1357     ])
1358     CFLAGS="${CFLAGS_save}"
1359   ])
1360   ARM_NEON_CFLAGS="$ac_cv_neon_inline"
1361 ], [
1362   ac_cv_neon_inline="no"
1363 ])
1364 AC_SUBST(ARM_NEON_CFLAGS)
1365 AM_CONDITIONAL(HAVE_ARM_NEON, [test "${ac_cv_neon_inline}" != "no"])
1366
1367
1368 AC_ARG_ENABLE(altivec,
1369 [  --disable-altivec       disable AltiVec optimizations (default auto)],, [
1370   AS_IF([test "${host_cpu}" = "powerpc"],
1371         [enable_altivec=yes], [enable_altivec=no])
1372 ])
1373 have_altivec="no"
1374 AS_IF([test "${enable_altivec}" = "yes"], [
1375   ARCH="${ARCH} altivec";
1376   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1377     [ac_cv_altivec_inline],
1378     [CFLAGS="${CFLAGS_save}"
1379      AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1380          ac_cv_altivec_inline="yes",
1381          [CFLAGS="${CFLAGS_save} -Wa,-m7400"
1382           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1383             [ac_cv_altivec_inline="-Wa,-m7400"],
1384             ac_cv_altivec_inline=no)
1385          ])])
1386   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1387     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1388               [Define to 1 if AltiVec inline assembly is available.])
1389     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1390       VLC_ADD_CFLAGS([idctaltivec],[${ac_cv_altivec_inline}])
1391       VLC_ADD_CFLAGS([motionaltivec],[${ac_cv_altivec_inline}])
1392       VLC_ADD_CFLAGS([memcpyaltivec],[${ac_cv_altivec_inline}])
1393       VLC_ADD_CFLAGS([i420_yuy2_altivec],[${ac_cv_altivec_inline}])
1394       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1395     ])
1396     have_altivec="yes"
1397   ])
1398
1399 dnl The AltiVec C extensions
1400 dnl
1401 dnl There are several possible cases:
1402 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1403 dnl                      need <altivec.h>
1404 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1405 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1406 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1407 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1408 dnl - Others: test should fail
1409   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1410   [ac_cv_c_altivec],
1411   [# OS X/PPC test (gcc 4.x)
1412    CFLAGS="${CFLAGS_save} -mpim-altivec -force_cpusubtype_ALL"
1413    AC_TRY_COMPILE([vector unsigned char foo;],
1414      [vec_ld(0, (unsigned char *)0);],
1415      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1416      [# OS X/PPC test (gcc 3.x)
1417       CFLAGS="${CFLAGS_save} -faltivec"
1418       AC_TRY_COMPILE([vector unsigned char foo;],
1419         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1420         [ac_cv_c_altivec="-faltivec"],
1421         dnl Below this are the Linux tests
1422         [# Linux/PPC test (gcc 4.x)
1423          CFLAGS="${CFLAGS_save} -maltivec"
1424          AC_TRY_COMPILE([#include <altivec.h>],
1425            [vec_ld(0, (unsigned char *)0);],
1426            [ac_cv_c_altivec="-maltivec"],
1427            [# Linux/PPC test (gcc 3.3)
1428             CFLAGS="${CFLAGS_save} -maltivec -mabi=altivec"
1429             AC_TRY_COMPILE([#include <altivec.h>],
1430               [vec_ld(0, (unsigned char *)0);],
1431               [ac_cv_c_altivec=""
1432                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1433               [# Linux/PPC test (gcc 3.3)
1434                CFLAGS="${CFLAGS_save} -fvec"
1435                AC_TRY_COMPILE([#include <altivec.h>],
1436                  [vec_ld(0, (unsigned char *)0);],
1437                  [ac_cv_c_altivec="-fvec"],
1438                  [ac_cv_c_altivec=no])
1439               ])
1440            ])
1441         ])
1442      ])
1443    CFLAGS="${CFLAGS_save}"
1444   ])
1445   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1446     CPPFLAGS="${CPPFLAGS_save} ${ac_cv_c_altivec}"
1447   ])
1448
1449   AC_CHECK_HEADERS(altivec.h)
1450   CPPFLAGS="${CPPFLAGS_save}"
1451
1452   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1453     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1,
1454               [Define to 1 if C AltiVec extensions are available.])
1455     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1456     VLC_ADD_CFLAGS([idctaltivec motionaltivec],[${ac_cv_c_altivec}])
1457     VLC_ADD_CFLAGS([i420_yuy2_altivec memcpyaltivec deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1458     have_altivec="yes"
1459   ])
1460
1461   AC_CACHE_CHECK([if linker needs -framework vecLib],
1462     [ac_cv_ld_altivec],
1463     [LDFLAGS="${LDFLAGS_vlc} -Wl,-framework,vecLib"
1464      AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)
1465      LDFLAGS="${LDFLAGS_save}"
1466     ])
1467   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1468     VLC_ADD_LDFLAGS([libvlccore idctaltivec motionaltivec memcpyaltivec],[-Wl,-framework,vecLib])
1469   ])
1470 ])
1471 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1472
1473 dnl
1474 dnl  Special arch tuning
1475 dnl
1476 AC_ARG_WITH(tuning,
1477 [  --with-tuning=ARCH      enable special tuning for an architecture
1478                           (default Pentium 2 on IA-32 and G4 on PPC)])
1479 if test -n "${with_tuning}"; then
1480     if test "${with_tuning}" != "no"; then
1481         CFLAGS_TUNING="-mtune=${with_tuning}"
1482     fi
1483 else
1484     if test "${SYS}" = "darwin" -a "${host_cpu}" = "i686"; then
1485         CFLAGS_TUNING="-march=prescott -mtune=generic"
1486     elif test "${SYS}" = "darwin" -a "${host_cpu}" = "x86_64"; then
1487         CFLAGS_TUNING="-march=core2 -mtune=core2"
1488     elif test "${host_cpu}" = "i686" -o "${host_cpu}" = "i586" -o "${host_cpu}" = "i486" -o "${host_cpu}" = "i386"; then
1489         CFLAGS_TUNING="-mtune=pentium2"
1490     elif test "${host_cpu}" = "x86_64"; then
1491         CFLAGS_TUNING="-mtune=athlon64"
1492     elif test "${host_cpu}" = "powerpc"; then
1493         CFLAGS_TUNING="-mtune=G4";
1494     fi
1495 fi
1496
1497 dnl NOTE: this can't be cached cleanly
1498 AS_IF([test "${CFLAGS_TUNING}"],
1499    [CFLAGS_save="${CFLAGS}"
1500     CFLAGS="${CFLAGS} ${CFLAGS_TUNING}"
1501
1502     AC_MSG_CHECKING([whether $CC accepts ${CFLAGS_TUNING}])
1503     AC_COMPILE_IFELSE([ ],
1504                       [tuning="yes"],
1505                       [CFLAGS_TUNING=""; tuning="no"
1506                        AS_IF([test "${with_tuning}"],
1507                              [AC_MSG_ERROR([requested tuning not supported])])])
1508
1509     AC_MSG_RESULT([$tuning])
1510     CFLAGS="${CFLAGS_save}"
1511 ])
1512
1513 dnl
1514 dnl  Memory usage
1515 dnl
1516 AC_ARG_ENABLE(optimize-memory,
1517 [  --enable-optimize-memory optimize memory usage over performance])
1518 if test "${enable_optimize_memory}" = "yes"; then
1519   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1520 fi
1521
1522 dnl
1523 dnl  Enable/disable optimizations
1524 dnl
1525 AC_ARG_ENABLE(optimizations,
1526 [  --disable-optimizations disable compiler optimizations (default enabled)])
1527 if test "${enable_optimizations}" != "no"; then
1528    if test "${enable_optimize_memory}" = "yes"; then
1529       enable_optimizations="size"
1530    else
1531       enable_optimizations="speed"
1532    fi
1533 fi
1534
1535 dnl
1536 dnl  Debugging mode
1537 dnl
1538 AC_ARG_ENABLE(debug,
1539 [  --enable-debug          debug mode (default disabled)])
1540 test "${enable_debug}" != "yes" && enable_debug="no"
1541 AH_TEMPLATE(NDEBUG,
1542             [Define to 1 if debug code should NOT be compiled])
1543 AS_IF([test "x${enable_debug}" = "xno"], [
1544   AC_DEFINE(NDEBUG)
1545 ], [
1546   AC_CHECK_HEADERS([valgrind/valgrind.h])
1547 ])
1548
1549 dnl
1550 dnl Allow running as root (useful for people running on embedded platforms)
1551 dnl
1552 AC_ARG_ENABLE(run-as-root,
1553 [  --enable-run-as-root    allow running VLC as root (default disabled)])
1554 AS_IF([test "${enable_run_as_root}" = "yes"],[
1555     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1556               [Define to 1 to allow running VLC as root (uid 0).])
1557 ])
1558
1559 dnl
1560 dnl  Test coverage
1561 dnl
1562 AC_ARG_ENABLE(coverage,
1563         [  --enable-coverage       build for test coverage (default disabled)],,
1564         [enable_coverage="no"])
1565 AS_IF([test "${enable_coverage}" != "no"], [
1566         CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1567         CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1568         LDFLAGS="-lgcov ${LDFLAGS}"
1569         dnl ugly...
1570         CFLAGS_save="${CFLAGS}"
1571         CXXFLAGS_save="${CXXFLAGS}"
1572         LDFLAGS_save="${LDFLAGS}"
1573 ])
1574
1575 dnl
1576 dnl Stream output
1577 dnl
1578 AC_ARG_ENABLE(sout,
1579   [  --enable-sout           Stream output modules (default enabled)])
1580 AS_IF([test "${enable_sout}" != "no"], [
1581   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1582 ])
1583 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1584
1585 dnl Lua modules
1586 AC_ARG_ENABLE(lua,
1587   AS_HELP_STRING([--enable-lua],[lua playlist, metafetcher and interface
1588                   plugins (default enabled)]))
1589 if test "${enable_lua}" != "no"
1590 then
1591   PKG_CHECK_MODULES(LUA, lua5.1,
1592     [ have_lua=yes ],
1593     [
1594     AC_MSG_WARN([lua5.1 not found, trying lua >= 5.1 instead])
1595     PKG_CHECK_MODULES(LUA, lua >= 5.1,
1596       [ have_lua=yes ],
1597       [
1598         have_lua=yes
1599         AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1600           [],
1601           [ have_lua=no ] )
1602         AC_CHECK_LIB(  lua5.1 , luaL_newstate,
1603           [LUA_LIBS="-llua5.1"],
1604           AC_CHECK_LIB( lua51 , luaL_newstate,
1605             [LUA_LIBS="-llua51"],
1606             AC_CHECK_LIB( lua , luaL_newstate,
1607               [LUA_LIBS="-llua"],
1608               [ have_lua=no
1609               ], [-lm])
1610           )
1611         )
1612       ])
1613     ])
1614   if test "x${have_lua}" = "xyes" ;  then
1615      VLC_ADD_LIBS([lua],[$LUA_LIBS])
1616      VLC_ADD_CFLAGS([lua],[$LUA_CFLAGS])
1617   else
1618       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1619   fi
1620   AC_ARG_VAR([LUAC], [LUA byte compiler])
1621   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1622   AS_IF([test "${LUAC}" = "false"], [
1623     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1624   ])
1625 fi
1626 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1627
1628 dnl
1629 dnl HTTP daemon
1630 dnl
1631 AC_ARG_ENABLE(httpd,
1632   [  --enable-httpd          HTTP daemon (default enabled)])
1633 if test "${enable_httpd}" != "no"
1634 then
1635   VLC_ADD_PLUGIN([oldhttp])
1636   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP dameon support)
1637 fi
1638 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1639
1640 dnl
1641 dnl libproxy support
1642 dnl
1643 AC_ARG_ENABLE(libproxy,
1644   [  --enable-libproxy       libproxy support (default auto)])
1645 AS_IF([test "${enable_libproxy}" != "no"], [
1646   PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0, [
1647     AC_DEFINE(HAVE_LIBPROXY, 1, [Define if libproxy is available])
1648     VLC_ADD_CFLAGS([access_http],[$LIBPROXY_CFLAGS])
1649     VLC_ADD_LIBS([access_http],[$LIBPROXY_LIBS])
1650   ], [
1651     AS_IF([test "x${enable_libproxy}" != "x"], [
1652       AC_MSG_ERROR([libproxy could not be found on your system])
1653     ])
1654   ])
1655 ])
1656
1657
1658 dnl
1659 dnl VideoLAN manager
1660 dnl
1661 AC_ARG_ENABLE(vlm,
1662   [  --enable-vlm            VideoLAN manager (default enabled)],,
1663   [enable_vlm="${enable_sout}"])
1664 AS_IF([test "${enable_vlm}" != "no"], [
1665   AS_IF([test "${enable_sout}" = "no"], [
1666     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1667   ])
1668   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1669 ])
1670 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1671
1672 dnl
1673 dnl Growl notification plugin
1674 dnl
1675 AC_ARG_ENABLE(growl,
1676   [  --enable-growl          growl notification plugin (default disabled)],,
1677   [enable_growl=no])
1678 AS_IF([test "${enable_growl}" != "no"], [
1679     VLC_ADD_PLUGIN([growl_udp])
1680     AC_CHECK_HEADERS(Growl/GrowlDefines.h, [
1681       VLC_ADD_PLUGIN([growl])
1682       VLC_ADD_LDFLAGS([growl], [-Wl,-framework,Growl,-framework,AppKit])
1683       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
1684     ])
1685   ]
1686 )
1687
1688 dnl
1689 dnl Libnotify notification plugin
1690 dnl
1691 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
1692
1693 dnl
1694 dnl Taglibplugin
1695 dnl
1696 AC_ARG_ENABLE(taglib,
1697   [  --disable-taglib        Taglib support (default enabled) ])
1698   AS_IF([test "${enable_taglib}" != "no"],[
1699     PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5,
1700       [ VLC_ADD_PLUGIN([taglib])
1701         VLC_ADD_LIBS([taglib],[$TAGLIB_LIBS -lz])
1702         VLC_ADD_CXXFLAGS([taglib],[$TAGLIB_CFLAGS])
1703         AC_LANG_PUSH(C++)
1704         AC_CHECK_HEADERS(taglib/mp4coverart.h)
1705         AC_LANG_POP(C++)
1706       ],
1707       [AC_MSG_WARN(TagLib library not found)])
1708   ])
1709
1710 dnl
1711 dnl  Input plugins
1712 dnl
1713
1714 EXTEND_HELP_STRING([Input plugins:])
1715
1716 dnl  live555 input
1717 dnl
1718 AC_ARG_ENABLE(live555,
1719 [  --enable-live555        live555 RTSP input plugin (default enabled)])
1720 if test "${enable_live555}" != "no"; then
1721   AC_ARG_WITH(live555-tree,
1722     [  --with-live555-tree=PATH live.com tree for static linking])
1723
1724   dnl
1725   dnl test for --with-live555-tree
1726   dnl
1727   if test -z "${with_live555_tree}" -a "${CXX}" != ""; then
1728     AC_LANG_PUSH(C++)
1729     CPPFLAGS_save="${CPPFLAGS}"
1730     if test -z "${CONTRIB_DIR}"; then
1731         CPPFLAGS_live555="-I/usr/include/liveMedia -I/usr/include/groupsock -I/usr/include/BasicUsageEnvironment -I/usr/include/UsageEnvironment"
1732     else
1733         CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1734     fi
1735     if test "${SYS}" = "solaris"; then
1736       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1737     fi
1738     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1739
1740     AC_CHECK_HEADERS(liveMedia_version.hh, [
1741       AC_MSG_CHECKING(for liveMedia version >= 1275091200 )
1742       AC_EGREP_CPP(yes,
1743         [#include <liveMedia_version.hh>
1744          #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1745          #if LIVEMEDIA_LIBRARY_VERSION_INT < 1275091200
1746          yes
1747          #endif
1748          #endif],
1749         [AC_MSG_RESULT([no])
1750           AC_MSG_WARN([The installed liveMedia version is too old:
1751 Version 2010.05.29 or later is required to proceed.
1752 You can get an updated one from http://www.live555.com/liveMedia .])
1753           AS_IF([test "${enable_live555}" == "yes"], [
1754             AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable the plugin.])
1755           ])
1756         ],[
1757           AC_MSG_RESULT([yes])
1758           other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1759           other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1760           if test "${SYS}" = "mingw32"; then
1761             # add ws2_32 for closesocket, select, recv
1762             other_libs="$other_libs -lws2_32"
1763           elif test "${SYS}" = "mingwce"; then
1764             # add ws2 for closesocket, select, recv
1765             other_libs="$other_libs -lws2"
1766           fi
1767
1768           dnl We need to check for pic because live555 don't provide shared libs
1769           dnl and we want to build a plugins so we need -fPIC on some arch.
1770           VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1771           AC_CHECK_LIB(liveMedia_pic, main, [
1772             VLC_ADD_PLUGIN([live555])
1773             VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1774           ],[
1775             AC_CHECK_LIB(liveMedia, main, [
1776             VLC_ADD_PLUGIN([live555])
1777             VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1778           ],[],[${other_libs}]) ],[${other_libs_pic}])
1779
1780           CPPFLAGS="${CPPFLAGS_save}"
1781           AC_LANG_POP(C++)
1782         ])
1783       ])
1784   else
1785     AC_MSG_CHECKING(for liveMedia/libliveMedia.a in ${with_live555_tree})
1786     real_live555_tree="`cd ${with_live555_tree} 2>/dev/null && pwd`"
1787     if test -z "${real_live555_tree}"; then
1788       dnl  The given directory can't be found
1789       AC_MSG_RESULT(no)
1790       AC_MSG_ERROR([cannot cd to ${with_live555_tree}])
1791     fi
1792     if test -f "${real_live555_tree}/liveMedia/libliveMedia.a"; then
1793       AC_MSG_RESULT(${real_live555_tree}/liveMedia/libliveMedia.a)
1794
1795       AC_CHECK_HEADERS(${real_live555_tree}/liveMedia/include/liveMedia_version.hh,[
1796         AC_MSG_CHECKING(for liveMedia version >= 1275091200 )
1797         AC_EGREP_CPP(yes,
1798           [#include "${real_live555_tree}/liveMedia/include/liveMedia_version.hh"
1799            #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1800            #if LIVEMEDIA_LIBRARY_VERSION_INT < 1275091200
1801            yes
1802            #endif
1803            #endif],
1804           [AC_MSG_RESULT([no])
1805            AC_MSG_ERROR([Your version of liveMedia is too old: you may get a more recent one from http://www.live555.com/liveMedia.
1806 lternatively you can use --disable-live555 to disable the liveMedia plugin.])
1807         ],[
1808            AC_MSG_RESULT([yes])
1809            ])
1810       ])
1811
1812       VLC_ADD_PLUGIN([live555])
1813
1814       if test "${SYS}" = "mingw32"; then
1815         # add ws2_32 for closesocket, select, recv
1816         VLC_ADD_LIBS([live555],[-lws2_32])
1817       fi
1818
1819       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/UsageEnvironment -lUsageEnvironment])
1820       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/BasicUsageEnvironment -lBasicUsageEnvironment])
1821       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/groupsock -lgroupsock])
1822       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/liveMedia -lliveMedia])
1823
1824       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/BasicUsageEnvironment/include])
1825       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/groupsock/include])
1826       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/liveMedia/include])
1827       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/UsageEnvironment/include ])
1828       if test "${SYS}" = "solaris"; then
1829         VLC_ADD_CXXFLAGS([live555],[-DSOLARIS])
1830       fi
1831     else
1832       dnl  The given live555 wasn't built
1833         AC_MSG_RESULT(no)
1834       if test "${enable_live555}" = "yes"; then
1835         AC_MSG_ERROR([cannot find ${real_live555_tree}/liveMedia/libliveMedia.a, make sure you compiled live555 in ${with_live555_tree}])
1836       fi        
1837     fi
1838   fi
1839 fi
1840
1841 dnl
1842 dnl - special access module for dc1394 input
1843 dnl - dv module: digital video module check for libraw1394
1844 dnl - linsys modules: access module check for libzvbi
1845 dnl
1846 PKG_ENABLE_MODULES_VLC([DC1394], [], [libraw1394 >= 2.0.1 libdc1394-2 >= 2.1.0], [dc1394 access module], [auto])
1847 PKG_ENABLE_MODULES_VLC([DV], [access_dv], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV input module], [auto])
1848
1849 AC_ARG_ENABLE(linsys,
1850   [  --enable-linsys         Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])
1851 case "${SYS}" in
1852     linux*)
1853 if test "${enable_linsys}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
1854   VLC_ADD_PLUGIN([linsys_hdsdi])
1855   PKG_CHECK_MODULES(LINSYS_SDI, zvbi-0.2 >= 0.2.28,
1856     [ VLC_ADD_LIBS([linsys_sdi],[$LINSYS_SDI_LIBS])
1857       VLC_ADD_CFLAGS([linsys_sdi],[$LINSYS_SDI_CFLAGS])
1858       VLC_ADD_PLUGIN([linsys_sdi]) ],
1859     [AC_MSG_WARN([Couldn't find zvbi >= 0.2.28, install libzvbi-dev ?])]
1860   )
1861 fi
1862 ;;
1863 esac
1864
1865 dnl
1866 dnl dvdread module: check for libdvdread
1867 dnl
1868 dnl prepend -ldvdcss on OS that need it
1869 AS_CASE(["${SYS}"], [mingw32|darwin], [VLC_ADD_LIBS([dvdread], [-ldvdcss])])
1870 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1871
1872 dnl
1873 dnl libdvdnav plugin
1874 dnl
1875 AC_ARG_ENABLE(dvdnav,
1876   [  --enable-dvdnav         dvdnav input module (default enabled)])
1877 if test "${enable_dvdnav}" != "no"
1878 then
1879   dnl prepend -ldvdcss on OS that need it
1880   AS_CASE(["${SYS}"], [mingw32|darwin], [VLC_ADD_LIBS([dvdnav], [-ldvdcss])])
1881
1882   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1883     VLC_ADD_PLUGIN([dvdnav])
1884     VLC_ADD_CFLAGS([dvdnav],[${DVDNAV_CFLAGS}])
1885     VLC_ADD_LIBS([dvdnav],[${DVDNAV_LIBS}])
1886     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1887       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1888         [], [${LIBS_dvdnav}])
1889     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1890       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1891         [], [${LIBS_dvdnav}])],
1892       [AC_MSG_WARN(dvdnav library not found)])
1893 fi
1894
1895 dnl
1896 dnl  Windows DirectShow access module
1897 dnl
1898 AC_ARG_ENABLE(dshow,
1899   [  --enable-dshow          Win32 DirectShow support (default enabled on Win32)])
1900 if test "${enable_dshow}" != "no"
1901 then
1902   if test "${SYS}" = "mingw32"
1903   then
1904     AC_LANG_PUSH(C++)
1905       AC_CHECK_HEADERS(dshow.h,
1906       [ VLC_ADD_PLUGIN([dshow])
1907         VLC_ADD_CXXFLAGS([dshow],[])
1908         VLC_ADD_LIBS([dshow],[-lole32 -loleaut32 -luuid]) ])
1909     AC_LANG_POP(C++)
1910   fi
1911 fi
1912
1913 dnl
1914 dnl  Windows DirectShow BDA access module
1915 dnl
1916 AC_ARG_ENABLE(bda,
1917   AS_HELP_STRING([--enable-bda],[Win32 DirectShow BDA support (default
1918                   enabled on Win32)]))
1919 if test "${enable_bda}" != "no"
1920 then
1921   if test "${SYS}" = "mingw32"
1922   then
1923       AC_CHECK_HEADERS(dshow.h,
1924       [ VLC_ADD_PLUGIN([bda])
1925         VLC_ADD_CXXFLAGS([bda],[])
1926         VLC_ADD_LIBS([bda],[-lstrmiids -lole32 -loleaut32 -luuid]) ])
1927   fi
1928 fi
1929
1930
1931 dnl
1932 dnl  Blu-ray Disc Support with libbluray
1933 dnl
1934 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2 ], (libbluray for Blu-ray disc support ) )
1935
1936 dnl
1937 dnl  OpenCV wrapper and example filters
1938 dnl
1939 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example], [opencv], (OpenCV (computer vision) filter), [off])
1940
1941
1942 dnl
1943 dnl  libsmbclient plugin
1944 dnl
1945 AC_ARG_ENABLE(smb,
1946   [  --enable-smb            smb input module (default enabled)])
1947 if test "${enable_smb}" != "no"; then
1948   AC_CHECK_HEADERS(libsmbclient.h,
1949     [ VLC_ADD_PLUGIN([access_smb])
1950       VLC_ADD_LIBS([access_smb],[-lsmbclient]) ],
1951     [ if test -n "${enable_smb}"; then
1952         AC_MSG_ERROR([cannot find libsmbclient headers])
1953      fi ])
1954 fi
1955
1956
1957 dnl
1958 dnl sftp access support
1959 dnl
1960 AC_ARG_ENABLE(sftp,
1961   [  --enable-sftp           sftp input access module (default disable)])
1962 if test "${enable_sftp}" = "yes"; then
1963   AC_CHECK_HEADERS(libssh2.h, [
1964     VLC_ADD_PLUGIN([access_sftp])
1965     VLC_ADD_LIBS([access_sftp], [-lssh2])
1966   ])
1967 fi
1968
1969 dnl
1970 dnl  libdvbpsi ts demux/mux
1971 dnl
1972 AC_ARG_ENABLE(dvbpsi,
1973   [  --enable-dvbpsi         dvbpsi ts mux and demux module (default enabled)])
1974 have_dvbpsi=no
1975 if test "${enable_dvbpsi}" != "no"
1976 then
1977   AC_ARG_WITH(dvbpsi,
1978   [  --with-dvbpsi=PATH      libdvbpsi headers and libraries])
1979   AC_ARG_WITH(dvbpsi,
1980   [  --with-dvbpsi-tree=PATH libdvbpsi tree for static linking])
1981   case "${with_dvbpsi}" in
1982   ""|yes)
1983     if test -z "${with_dvbpsi_tree}"
1984     then
1985       AC_CHECK_HEADERS(dvbpsi/dr.h,
1986         [ VLC_ADD_PLUGIN([ts])
1987           if test "${enable_sout}" != "no"; then
1988             VLC_ADD_PLUGIN([mux_ts])
1989           fi
1990           VLC_ADD_LIBS([mux_ts ts dvb],[-ldvbpsi])
1991           have_dvbpsi=yes],
1992         [  AC_MSG_WARN([cannot find libdvbpsi headers]) ],
1993         [#if defined( HAVE_STDINT_H )
1994 #   include <stdint.h>
1995 #elif defined( HAVE_INTTYPES_H )
1996 #   include <inttypes.h>
1997 #endif
1998 #include <dvbpsi/dvbpsi.h>
1999 #include <dvbpsi/descriptor.h>
2000 #include <dvbpsi/pat.h>
2001 #include <dvbpsi/pmt.h>])
2002     else
2003       AC_MSG_CHECKING(for libdvbpsi.a in ${with_dvbpsi_tree})
2004       real_dvbpsi_tree="`cd ${with_dvbpsi_tree} 2>/dev/null && pwd`"
2005       if test -z "${real_dvbpsi_tree}"
2006       then
2007         dnl  The given directory can't be found
2008         AC_MSG_RESULT(no)
2009         AC_MSG_ERROR([cannot cd to ${with_dvbpsi_tree}])
2010       fi
2011       if test -f "${real_dvbpsi_tree}/src/.libs/libdvbpsi.a"
2012       then
2013         dnl  Use a custom libdvbpsi
2014         AC_MSG_RESULT(${real_dvbpsi_tree}/src/.libs/libdvbpsi.a)
2015         VLC_ADD_PLUGIN([ts])
2016         if test "${enable_sout}" != "no"; then
2017           VLC_ADD_PLUGIN([mux_ts])
2018         fi
2019         VLC_ADD_CPPFLAGS([mux_ts ts dvb],[-I${real_dvbpsi_tree}/src])
2020         VLC_ADD_LIBS([mux_ts ts dvb],[${real_dvbpsi_tree}/src/.libs/libdvbpsi.a])
2021         have_dvbpsi=yes
2022       else
2023         dnl  The given libdvbpsi wasn't built
2024         AC_MSG_RESULT(no)
2025         AC_MSG_ERROR([cannot find ${real_dvbpsi_tree}/src/.libs/libdvbpsi.a, make sure you compiled libdvbpsi in ${with_dvbpsi_tree}])
2026       fi
2027     fi
2028   ;;
2029   no)
2030     dnl  Compile without dvbpsi
2031   ;;
2032   *)
2033     AC_MSG_CHECKING(for dvbpsi headers in ${with_dvbpsi})
2034     if test -z "${with_dvbpsi}"
2035     then
2036       LDFLAGS_test=""
2037       CPPFLAGS_test=""
2038     else
2039       LDFLAGS_test="-L${with_dvbpsi}/lib"
2040       CPPFLAGS_test="-I${with_dvbpsi}/include"
2041     fi
2042     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_test}"
2043     AC_CHECK_HEADERS([dvbpsi/dr.h],[
2044       VLC_ADD_PLUGIN([ts])
2045       if test "${enable_sout}" != "no"; then
2046         AC_CHECK_LIB(dvbpsi, dvbpsi_SDTServiceAddDescriptor,
2047            [VLC_ADD_PLUGIN([mux_ts])], [], [${LDFLAGS_test} -ldvbpsi])
2048       fi
2049       VLC_ADD_CPPFLAGS([mux_ts ts dvb],[${CPPFLAGS_test}])
2050       VLC_ADD_LIBS([mux_ts ts dvb],[${LDFLAGS_test} -ldvbpsi])
2051       have_dvbpsi=yes
2052     ],[
2053       if test -n "${enable_dvbpsi}"
2054       then
2055         AC_MSG_ERROR([Could not find libdvbpsi on your system: you may get it from www.videolan.org, you'll need at least version 0.1.6])
2056       fi
2057     ],
2058     [#if defined( HAVE_STDINT_H )
2059 #   include <stdint.h>
2060 #elif defined( HAVE_INTTYPES_H )
2061 #   include <inttypes.h>
2062 #endif
2063 #include <dvbpsi/dvbpsi.h>
2064 #include <dvbpsi/descriptor.h>
2065 #include <dvbpsi/pat.h>
2066 #include <dvbpsi/pmt.h>])
2067     CPPFLAGS="${CPPFLAGS_save}"
2068   ;;
2069   esac
2070   AC_CHECK_LIB(dvbpsi, dvbpsi_GenSDTSections, [
2071     AC_DEFINE(HAVE_DVBPSI_SDT, 1, [Define if you have dvbpsi_GenSDTSections.])
2072   ], [], [${LIBS_ts}])
2073
2074 fi
2075
2076 dnl
2077 dnl  Video4Linux2 plugin
2078 dnl
2079 AC_ARG_ENABLE(v4l2,
2080   [  --enable-v4l2           Video4Linux2 input support (default enabled)])
2081 if test "${enable_v4l2}" != "no"
2082 then
2083   AC_ARG_WITH(v4l2,
2084     [  --with-v4l2=PATH        path to a v4l2-enabled kernel tree],[],[])
2085   if test "${with_v4l2}" != "no" -a -n "${with_v4l2}"
2086   then
2087     VLC_ADD_CPPFLAGS([v4l2],[-I${with_v4l2}/include])
2088   fi
2089
2090   CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_v4l2}"
2091   AC_CHECK_HEADERS(linux/videodev2.h sys/videoio.h, [
2092     VLC_ADD_PLUGIN([v4l2])
2093   ],[])
2094   CPPFLAGS="${CPPFLAGS_save}"
2095 fi
2096
2097 dnl
2098 dnl libv4l2 support for video4linux.
2099 dnl
2100 AC_ARG_ENABLE( libv4l2,
2101   [  --enable-libv4l2        Libv4l2 Video4Linux2 support (default enabled)])
2102 if test "${enable_libv4l2}" != "no" -a "${enable_v4l2}" != "no"
2103 then
2104     PKG_CHECK_MODULES( LIBV4L2, libv4l2, [
2105       VLC_ADD_LDFLAGS([v4l2],[${LIBV4L2_LIBS}])
2106       VLC_ADD_CFLAGS([v4l2],[${LIBV4L2_CFLAGS}])
2107       AC_DEFINE(HAVE_LIBV4L2, 1, Define if libv4l2 is available)],
2108       AC_MSG_WARN([LibV4L2 support disabled because libv4l2 development headers were not found])
2109     )
2110 fi
2111
2112 dnl
2113 dnl  special access module for Hauppauge PVR cards
2114 dnl
2115 AC_ARG_ENABLE(pvr,
2116   [  --enable-pvr            PVR cards access module (default disabled)])
2117 if test "${enable_pvr}" = "yes"
2118 then
2119   VLC_ADD_PLUGIN([pvr])
2120 fi
2121
2122 dnl
2123 dnl special access module for Blackmagic SDI cards
2124 dnl
2125 AC_ARG_ENABLE(decklink,
2126   [  --enable-decklink       Blackmagic DeckLink SDI access module (default enabled)])
2127 if test "${enable_decklink}" != "no"
2128 then
2129   AC_ARG_WITH(decklink_sdk,
2130     [  --with-decklink-sdk=DIR      Location of Blackmagic DeckLink SDI SDK],[],[])
2131   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
2132   then
2133     VLC_ADD_CPPFLAGS([decklink],[-I${with_decklink_sdk}/include])
2134   fi
2135   CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_decklink}"
2136   AC_LANG_PUSH(C++)
2137   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
2138     VLC_ADD_PLUGIN([decklink])
2139   ],[AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)])
2140   AC_LANG_POP(C++)
2141   CPPFLAGS="${CPPFLAGS_save}"
2142 fi
2143
2144
2145 dnl
2146 dnl  gnomeVFS access module
2147 dnl
2148 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [access_gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
2149
2150 dnl
2151 dnl  VCDX modules
2152 dnl
2153 AC_ARG_ENABLE(vcdx,
2154   [  --enable-vcdx           VCD with navigation via libvcdinfo (default disabled)])
2155
2156 if test "${enable_vcdx}" = "yes"
2157 then
2158         PKG_CHECK_MODULES(LIBCDIO, [libcdio >= 0.78.2 libiso9660 >= 0.72],
2159           [VLC_ADD_LIBS([vcdx],[$LIBCDIO_LIBS])
2160                  VLC_ADD_CFLAGS([vcdx],[$LIBCDIO_CFLAGS])],
2161                 [AC_MSG_ERROR([vcdx plugin requires libcdio >= 0.78.2 and libiso9660 >= 0.72])])
2162         PKG_CHECK_MODULES(LIBVCDINFO, libvcdinfo >= 0.7.22,
2163                 [VLC_ADD_LIBS([vcdx],[$LIBVCDINFO_LIBS])
2164                  VLC_ADD_CFLAGS([vcdx],[$LIBVCDINFO_CFLAGS])],
2165           [AC_MSG_ERROR([vcdx plugin requires libvcdinfo library >= 0.7.22])])
2166         VLC_ADD_PLUGIN([vcdx])
2167 fi
2168
2169 dnl
2170 dnl  Built-in CD-DA and VCD module
2171 dnl
2172 AC_ARG_ENABLE(vcd,
2173   [  --enable-vcd            built-in VCD and CD-DA (default enabled)])
2174
2175 AC_ARG_ENABLE(libcddb,
2176   [  --enable-libcddb        CDDB support for libcdio audio CD (default enabled)])
2177
2178 if test "${enable_vcd}" != "no"
2179 then
2180   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2181   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2182     AC_MSG_RESULT(yes)
2183     VLC_ADD_PLUGIN([vcd cdda])
2184   ],[
2185     AC_MSG_RESULT(no)
2186   ])
2187
2188   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2189   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2190     AC_MSG_RESULT(yes)
2191     VLC_ADD_PLUGIN([vcd cdda])
2192     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2193   ],[
2194     AC_MSG_RESULT(no)
2195   ])
2196
2197   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2198   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2199     AC_MSG_RESULT(yes)
2200     VLC_ADD_PLUGIN([vcd cdda])
2201     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2202   ],[
2203     AC_MSG_RESULT(no)
2204   ])
2205
2206   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32"
2207   then
2208     VLC_ADD_PLUGIN([vcd cdda])
2209   fi
2210
2211   if test "${SYS}" = "darwin"
2212   then
2213     VLC_ADD_PLUGIN([vcd cdda])
2214     VLC_ADD_LDFLAGS([vcd vcdx cdda],[-Wl,-framework,IOKit,-framework,CoreFoundation])
2215     VLC_ADD_LIBS([vcdx cdda],[-liconv])
2216   fi
2217
2218   if test "$enable_libcddb" != "no"; then
2219     PKG_CHECK_MODULES(LIBCDDB, libcddb >= 0.9.5, [
2220       HAVE_LIBCDDB=yes
2221       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2222       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2223       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2224       ],:
2225       [AC_MSG_WARN(new enough libcddb not found. CDDB access disabled)
2226       HAVE_LIBCDDB=no])
2227   fi
2228 fi
2229
2230 dnl
2231 dnl  DVB-S/DVB-T/DVB-C satellite/teresterial/cable input using v4l2
2232 dnl
2233 AC_ARG_ENABLE(dvb,
2234   [  --enable-dvb            DVB-S/T/C card support (default enabled)])
2235
2236 if test "${enable_dvb}" != "no"
2237 then
2238     AS_IF([test "${have_dvbpsi}" = "yes" ],[
2239     AC_ARG_WITH(dvb,
2240      [  --with-dvb=PATH         path to a dvb- and v4l2-enabled kernel tree],[],[])
2241      if test "${with_dvb}" != "no" -a -n "${with_dvb}"
2242      then
2243        VLC_ADD_CFLAGS([dvb],[-I${with_dvb}/include])
2244      fi
2245      CPPFLAGS="${CPPFLAGS_save} -I${with_dvb}/include"
2246      AC_CHECK_HEADERS(linux/dvb/version.h linux/dvb/frontend.h, [
2247      VLC_ADD_PLUGIN([dvb])
2248      ],[AC_MSG_WARN(linux-dvb headers not found, dvb disabled)])
2249      CPPFLAGS="${CPPFLAGS_save}"
2250    ],[
2251      AC_MSG_WARN([the dvb access module requires libdvbpsi])
2252     ])
2253 fi
2254
2255 dnl
2256 dnl  Screen capture module
2257 dnl
2258 AC_ARG_ENABLE(screen,
2259   [  --enable-screen         Screen capture support (default enabled)])
2260 if test "${enable_screen}" != "no"; then
2261   if test "${SYS}" = "darwin"; then
2262     AC_CHECK_HEADERS(OpenGL/gl.h, [
2263       AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2264         VLC_ADD_PLUGIN([screen])
2265         VLC_ADD_LDFLAGS([screen],[-Wl,-framework,OpenGL,-framework,ApplicationServices])
2266       ])
2267     ])
2268   elif test "${SYS}" = "mingw32"; then
2269     VLC_ADD_PLUGIN([screen])
2270     VLC_ADD_LIBS([screen],[-lgdi32])
2271   elif test "${SYS}" = "mingwce"; then
2272     CPPFLAGS="${CPPFLAGS_save}"
2273   fi
2274 fi
2275
2276 dnl
2277 dnl  ipv6 plugin
2278 dnl
2279 have_ipv6=no
2280 AC_CHECK_FUNCS(inet_pton,[have_ipv6=yes],[
2281   AC_CHECK_LIB(nsl,inet_pton, [have_ipv6=yes])
2282 ])
2283
2284 AS_IF([test "${have_ipv6}" = "yes"], [
2285   AC_DEFINE(HAVE_INET_PTON, 1, [Define to 1 if you have inet_pton().])])
2286
2287
2288 AC_CHECK_FUNCS(inet_ntop,[
2289   AC_DEFINE(HAVE_INET_NTOP, 1, [Define to 1 if you have inet_ntop().])])
2290
2291
2292 dnl
2293 dnl  GME demux plugin
2294 dnl
2295 AC_ARG_ENABLE(gme,
2296   [  --enable-gme            Game Music Emu support (default auto)])
2297 AS_IF([test "${enable_gme}" != "no"], [
2298   AC_CHECK_HEADER([gme/gme.h], [
2299     VLC_ADD_LIBS([gme], [-lgme])
2300     VLC_ADD_PLUGIN([gme])
2301   ], [
2302     AS_IF([test "x${enable_gme}" != "x"], [
2303       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2304     ])
2305   ])
2306 ])
2307
2308
2309 dnl
2310 dnl  SIDPlay plugin
2311 dnl
2312 PKG_ENABLE_MODULES_VLC([SID], [], [libsidplay2], [C64 sid demux support], [auto], [], [-lresid-builder])
2313
2314
2315 dnl
2316 dnl  ogg demux plugin
2317 dnl
2318 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2319 if test "${enable_sout}" != "no"; then
2320     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2321 fi
2322
2323 if test "${enable_sout}" != "no"; then
2324 dnl Check for libshout
2325 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2326 fi
2327
2328 dnl
2329 dnl  matroska demux plugin
2330 dnl
2331 AC_ARG_ENABLE(mkv,
2332   [  --enable-mkv            Matroska demux support (default enabled)])
2333 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2334   AC_LANG_PUSH(C++)
2335   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2336     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2337     AC_EGREP_CPP(yes,
2338       [#include <ebml/EbmlVersion.h>
2339        #ifdef LIBEBML_VERSION
2340        #if LIBEBML_VERSION >= 0x010000
2341        yes
2342        #endif
2343        #endif],
2344       [AC_MSG_RESULT([yes])
2345         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2346           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2347           AC_EGREP_CPP(yes,
2348             [#include <matroska/KaxVersion.h>
2349              #ifdef LIBMATROSKA_VERSION
2350              #if LIBMATROSKA_VERSION >= 0x010000
2351              yes
2352              #endif
2353              #endif],
2354             [AC_MSG_RESULT([yes])
2355               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2356               VLC_ADD_CXXFLAGS([mkv],[])
2357               if test "${SYS}" = "darwin"; then
2358                 VLC_ADD_CXXFLAGS([mkv],[-O1])
2359               fi
2360               AC_CHECK_LIB(ebml_pic, main, [
2361                 VLC_ADD_PLUGIN([mkv])
2362                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2363               ],[
2364                 AC_CHECK_LIB(ebml, main, [
2365                   VLC_ADD_PLUGIN([mkv])
2366                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2367                 ])
2368               ])
2369             ], [
2370               AC_MSG_RESULT([no])
2371               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2372           ])
2373         ])
2374       ],
2375       [AC_MSG_RESULT([no])
2376         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2377     ])
2378   ])
2379   AC_LANG_POP(C++)
2380 fi
2381
2382 dnl
2383 dnl  modplug demux plugin
2384 dnl
2385 AC_ARG_ENABLE(mod,
2386   [  --enable-mod            Mod demux support (default auto)])
2387 if test "${enable_mod}" != "no" ; then
2388     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2389           VLC_ADD_PLUGIN([mod])
2390           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2391           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2392     ],[
2393        AS_IF([test x"${enable_mod}" = "xyes"],
2394          [AC_MSG_ERROR(libmodplug not found or a broken version (0.8.8.0) was found!)],
2395          [AC_MSG_WARN(libmodplug not found or a broken version (0.8.8.0) was found!)])
2396     ])
2397 fi
2398
2399 dnl
2400 dnl  mpc demux plugin
2401 dnl
2402 AC_ARG_ENABLE(mpc,
2403   [  --enable-mpc            Mpc demux support (default enabled)])
2404 if test "${enable_mpc}" != "no"
2405 then
2406   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2407     VLC_ADD_PLUGIN([mpc])
2408     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2409     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2410     VLC_ADD_PLUGIN([mpc])
2411     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2412 fi
2413
2414 dnl
2415 dnl  Codec plugins
2416 dnl
2417
2418 EXTEND_HELP_STRING([Codec plugins:])
2419
2420 dnl
2421 dnl wmafixed plugin
2422 dnl
2423 AC_ARG_ENABLE(wma-fixed,
2424   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2425 if test "${enable_wma_fixed}" = "yes"
2426 then
2427   VLC_ADD_PLUGIN([wma_fixed])
2428 fi
2429
2430 dnl
2431 dnl shine fixed point mp3 encoder
2432 dnl
2433 AC_ARG_ENABLE(shine,
2434   [  --enable-shine          shine mp3 encoding module (default disabled)])
2435 if test "${enable_shine}" = "yes"
2436 then
2437   VLC_ADD_PLUGIN([shine])
2438 fi
2439
2440 dnl
2441 dnl openmax il codec plugin
2442 dnl
2443 AC_ARG_ENABLE(omxil,
2444   [  --enable-omxil          openmax il codec module (default disabled)])
2445 if test "${enable_omxil}" = "yes"
2446 then
2447   VLC_ADD_PLUGIN([omxil])
2448   VLC_ADD_LIBS([omxil], [$LIBDL])
2449 fi
2450
2451 dnl
2452 dnl CrystalHD codec plugin
2453 dnl
2454 AC_ARG_ENABLE(crystalhd,
2455   [  --enable-crystalhd       crystalhd codec plugin (default disabled)])
2456 if test "${enable_crystalhd}" == "yes"; then
2457     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2458       VLC_ADD_PLUGIN([crystalhd])
2459       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2460     ],[
2461       if test "${SYS}" = "mingw32" ; then
2462         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2463           VLC_ADD_PLUGIN([crystalhd])
2464           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2465             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2466             ])
2467         ],[
2468           AC_MSG_ERROR("Could not find CrystalHD development headers")
2469         ])
2470       fi
2471     ],[#define __LINUX_USER__
2472        #include <libcrystalhd/bc_dts_types.h>
2473       ])
2474 fi
2475
2476 dnl
2477 dnl  mad plugin
2478 dnl
2479 AC_ARG_ENABLE(mad,
2480   [  --enable-mad            libmad module (default enabled)])
2481 if test "${enable_mad}" != "no"
2482 then
2483   AC_ARG_WITH(mad,
2484     [  --with-mad=PATH         path to libmad],[],[])
2485   if test "${with_mad}" != "no" -a -n "${with_mad}"
2486   then
2487     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2488     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2489   fi
2490
2491   AC_ARG_WITH(mad-tree,
2492     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2493   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2494   then
2495     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2496     if test -z "${real_mad_tree}"
2497     then
2498       dnl  The given directory can't be found
2499       AC_MSG_RESULT(no)
2500       AC_MSG_ERROR([${with_mad_tree} directory doesn't exist])
2501     fi
2502     dnl  Use a custom libmad
2503     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2504     if test -f ${real_mad_tree}/mad.h
2505     then
2506       AC_MSG_RESULT(yes)
2507       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2508       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2509       LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2510       AC_CHECK_LIB(mad, mad_bit_init, [
2511         VLC_ADD_PLUGIN([mpgatofixed32])
2512         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2513         ],[ AC_MSG_ERROR([the specified tree hasn't been compiled ])
2514       ],[])
2515       LDFLAGS="${LDFLAGS_save}"
2516     else
2517       AC_MSG_RESULT(no)
2518       AC_MSG_ERROR([the specified tree doesn't have mad.h])
2519     fi
2520   else
2521     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_mpgatofixed32}"
2522     LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2523     AC_CHECK_HEADERS(mad.h, ,
2524       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2525     AC_CHECK_LIB(mad, mad_bit_init, [
2526       VLC_ADD_PLUGIN([mpgatofixed32])
2527       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2528       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2529     CPPFLAGS="${CPPFLAGS_save}"
2530     LDFLAGS="${LDFLAGS_save}"
2531   fi
2532 fi
2533
2534
2535 AC_ARG_ENABLE(merge-ffmpeg,
2536 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2537   enable_merge_ffmpeg="no"
2538 ])
2539 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2540
2541 AC_CACHE_CHECK([if linker supports -Bsymbolic],
2542   [ac_cv_ld_bsymbolic],
2543   [LDFLAGS="${LDFLAGS_vlc} -Wl,-Bsymbolic"
2544     AC_TRY_LINK([],,ac_cv_ld_bsymbolic=yes,ac_cv_ld_bsymbolic=no)
2545     LDFLAGS="${LDFLAGS_save}"
2546   ])
2547
2548 dnl
2549 dnl  avcodec decoder/encoder plugin
2550 dnl
2551 AC_ARG_ENABLE(avcodec,
2552 [  --enable-avcodec        libavcodec codec (default enabled)])
2553 AS_IF([test "${enable_avcodec}" != "no"], [
2554   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 52.25.0 libavutil],
2555     [
2556       VLC_SAVE_FLAGS
2557       CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2558       CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2559       AC_CHECK_HEADERS(libavcodec/avcodec.h ffmpeg/avcodec.h)
2560       AC_CHECK_HEADERS(libavutil/avutil.h ffmpeg/avutil.h)
2561       VLC_ADD_PLUGIN([avcodec])
2562       VLC_ADD_LIBS([avcodec],[$AVCODEC_LIBS])
2563       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2564         VLC_ADD_LDFLAGS([avcodec],[-Wl,-Bsymbolic])
2565       ])
2566       VLC_ADD_CFLAGS([avcodec],[$AVCODEC_CFLAGS])
2567       VLC_RESTORE_FLAGS
2568       have_avcodec="yes"
2569     ],[
2570       AC_MSG_ERROR([Could not find libavcodec or libavutil. Use --disable-avcodec to ignore this error.])
2571   ])
2572 ], [
2573   have_avcodec="no"
2574 ])
2575
2576 dnl
2577 dnl libva needs avcodec
2578 dnl
2579 AC_ARG_ENABLE(libva,
2580   [  --enable-libva          libva VAAPI support (default auto)])
2581
2582 AS_IF([test "${enable_libva}" != "no"], [
2583   AS_IF([test "x${have_avcodec}" = "xyes"], [
2584     PKG_CHECK_MODULES(LIBVA, [libva libva-x11],
2585       [
2586         VLC_SAVE_FLAGS
2587         CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2588         CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2589         AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2590            VLC_ADD_LIBS([avcodec],[$LIBVA_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11])
2591            VLC_ADD_CFLAGS([avcodec],[$LIBVA_CFLAGS ${X_CFLAGS}])
2592            AC_DEFINE(HAVE_AVCODEC_VAAPI, 1, [Define if avcodec has to be built with VAAPI support.])
2593            echo "VAAPI acceleration activated"
2594         ],[
2595         AS_IF([test "${enable_libva}" == "yes"],
2596               [AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])],
2597               [AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])])
2598         ])
2599         VLC_RESTORE_FLAGS
2600       ],[
2601         AS_IF([test "${enable_libva}" == "yes"],
2602               [AC_MSG_ERROR([Could not find required libva.])],
2603               [AC_MSG_WARN([libva not found  ])])
2604       ])
2605   ],[
2606     AS_IF([test "x${enable_libva}" != "x"], [
2607       AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive.])
2608     ])
2609   ])
2610 ])
2611
2612 dnl
2613 dnl dxva2 needs avcodec
2614 dnl
2615 AC_ARG_ENABLE(dxva2,
2616   [  --enable-dxva2          DxVA2  support (default auto)])
2617
2618 AS_IF([test "${enable_dxva2}" != "no"], [
2619   if test "${SYS}" = "mingw32"; then
2620   AS_IF([test "x${have_avcodec}" = "xyes"], [
2621     AC_CHECK_HEADERS(dxva2api.h, 
2622       [
2623         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2624            VLC_ADD_LIBS([avcodec],[-lole32 -lshlwapi -luuid])
2625            AC_DEFINE(HAVE_AVCODEC_DXVA2, 1, [Define if avcodec has to be built with DxVA2 support.])
2626            echo "DxVA2 acceleration activated"
2627         ],[
2628         AS_IF([test "${enable_dxva2}" == "yes"],
2629               [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2630               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2631         ])
2632       ],[
2633         AS_IF([test "${enable_dxva2}" == "yes"],
2634               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2635               [AC_MSG_WARN([dxva2api.h not found])])
2636       ])
2637   ],[
2638     AS_IF([test "x${enable_dxva2}" != "x"], [
2639       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2640     ])
2641   ])
2642   fi
2643 ])
2644
2645
2646 dnl
2647 dnl stream_out switcher needs libavcodec
2648 dnl
2649 AC_ARG_ENABLE(switcher,
2650   [  --enable-switcher       Stream-out switcher plugin (default disabled)])
2651 AS_IF([test "${enable_switcher}" = "yes"], [
2652   AS_IF([test "x${have_avcodec}" = "xyes"], [
2653     VLC_ADD_PLUGIN([stream_out_switcher])
2654     VLC_ADD_LIBS([stream_out_switcher],[$AVCODEC_LIBS $AVUTIL_LIBS])
2655     VLC_ADD_CFLAGS([stream_out_switcher],[$AVCODEC_CFLAGS $AVUTIL_CFLAGS])
2656   ],[AC_MSG_ERROR([Stream_out switcher depends on avcodec])
2657   ])
2658 ])
2659
2660
2661 dnl
2662 dnl  avformat demuxer/muxer plugin
2663 dnl
2664
2665 AC_ARG_ENABLE(avformat,
2666 [  --enable-avformat       libavformat containers (default enabled)],, [
2667   enable_avformat="${have_avcodec}"
2668 ])
2669 if test "${enable_avformat}" != "no"
2670 then
2671   PKG_CHECK_MODULES(AVFORMAT,[libavformat > 52.30.0 libavcodec libavutil],
2672     [
2673       VLC_SAVE_FLAGS
2674       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2675       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2676       AC_CHECK_HEADERS(libavformat/avformat.h ffmpeg/avformat.h libavformat/avio.h)
2677       AC_CHECK_HEADERS(libavutil/avutil.h ffmpeg/avutil.h)
2678       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2679         VLC_ADD_PLUGIN([avformat access_avio])
2680         VLC_ADD_LIBS([avformat access_avio],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2681         VLC_ADD_CFLAGS([avformat access_avio],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2682         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2683           VLC_ADD_LDFLAGS([avformat access_avio],[-Wl,-Bsymbolic])
2684         ])
2685       ], [
2686         VLC_ADD_LIBS([avcodec],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2687         VLC_ADD_CFLAGS([avcodec],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2688       ])
2689       VLC_RESTORE_FLAGS
2690     ],[
2691       AC_MSG_ERROR([Could not find libavformat or libavutil. Use --disable-avformat to ignore this error.])
2692   ])
2693 fi
2694
2695 dnl
2696 dnl  swscale image scaling and conversion plugin
2697 dnl
2698
2699 AC_ARG_ENABLE(swscale,
2700   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2701                   (default enabled)]))
2702 if test "${enable_swscale}" != "no"
2703 then
2704   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2705     [
2706       VLC_SAVE_FLAGS
2707       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2708       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2709       AC_CHECK_HEADERS(libswscale/swscale.h ffmpeg/swscale.h)
2710       VLC_ADD_PLUGIN([swscale])
2711       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2712       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2713       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2714         VLC_ADD_LDFLAGS([swscale],[-Wl,-Bsymbolic])
2715       ])
2716       VLC_RESTORE_FLAGS
2717     ],[
2718       AC_MSG_ERROR([Could not find libswscale. Use --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2719   ])
2720 fi
2721
2722 dnl
2723 dnl  postproc plugin
2724 dnl
2725
2726 AC_ARG_ENABLE(postproc,
2727 [  --enable-postproc       libpostproc image post-processing (default enabled)])
2728 if test "${enable_postproc}" != "no"
2729 then
2730   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2731     [
2732       VLC_SAVE_FLAGS
2733       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2734       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2735       AC_CHECK_HEADERS(postproc/postprocess.h)
2736       VLC_ADD_PLUGIN([postproc])
2737       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2738       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2739       VLC_RESTORE_FLAGS
2740     ],[
2741       AC_MSG_ERROR([Could not find libpostproc. Use --disable-postproc to ignore this error.])
2742   ])
2743 fi
2744
2745 dnl
2746 dnl  faad decoder plugin
2747 dnl
2748 AC_ARG_ENABLE(faad,
2749 [  --enable-faad           faad codec (default disabled)])
2750 if test "${enable_faad}" = "yes"
2751 then
2752   AC_ARG_WITH(faad-tree,
2753   [  --with-faad-tree=PATH   faad tree for static linking])
2754   if test -n "${with_faad_tree}"
2755   then
2756     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2757     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2758     if test -z "${real_faad_tree}"
2759     then
2760       dnl  The given directory can't be found
2761       AC_MSG_RESULT(no)
2762       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2763     fi
2764     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"
2765     then
2766       dnl  Use a custom faad
2767       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2768       VLC_ADD_PLUGIN([faad])
2769       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2770       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2771     else
2772       dnl  The given libfaad wasn't built
2773       AC_MSG_RESULT(no)
2774       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2775     fi
2776   else
2777     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_faad}"
2778     LDFLAGS="${LDFLAGS_save} ${LIBS_faad}"
2779     AC_CHECK_HEADERS(faad.h, ,
2780       [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ])
2781     AC_CHECK_LIB(faad, faacDecOpen, [
2782       VLC_ADD_PLUGIN([faad])
2783       VLC_ADD_LIBS([faad],[-lfaad]) ],
2784       AC_CHECK_LIB(faad, NeAACDecOpen, [
2785         VLC_ADD_PLUGIN([faad])
2786         VLC_ADD_LIBS([faad],[-lfaad]) ],
2787         [ AC_MSG_ERROR([Cannot find libfaad library...]) ]))
2788     LDFLAGS="${LDFLAGS_save}"
2789     CPPFLAGS="${CPPFLAGS_save}"
2790   fi
2791 fi
2792
2793 dnl
2794 dnl twolame encoder plugin
2795 dnl
2796 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2797
2798 dnl
2799 dnl  QuickTime plugin
2800 dnl
2801 AC_ARG_ENABLE(quicktime,
2802   [  --enable-quicktime      QuickTime module (deprecated)])
2803 if test "${enable_quicktime}" = "yes"; then
2804   if test "${SYS}" = "mingw32"; then
2805     VLC_ADD_PLUGIN([quicktime])
2806   else
2807   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2808     [ VLC_ADD_PLUGIN([quicktime])
2809       VLC_ADD_LDFLAGS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2810     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2811   fi
2812 fi
2813
2814 dnl
2815 dnl  Real plugin
2816 dnl
2817 AC_ARG_ENABLE(real,
2818   [  --enable-real           Real media module (default disabled)])
2819 if test "${enable_real}" = "yes"; then
2820   VLC_ADD_PLUGIN([realvideo])
2821 fi
2822
2823 dnl
2824 dnl  Real RTSP plugin
2825 dnl
2826 AC_ARG_ENABLE(realrtsp,
2827   [  --enable-realrtsp       Real RTSP module (default disabled)])
2828 if test "${enable_realrtsp}" = "yes"; then
2829   VLC_ADD_PLUGIN([access_realrtsp])
2830 fi
2831
2832 dnl
2833 dnl A52/AC3 decoder plugin
2834 dnl
2835 AC_ARG_ENABLE(a52,
2836   [  --enable-a52            A/52 support with liba52 (default enabled)])
2837 if test "${enable_a52}" != "no"
2838 then
2839   AC_ARG_WITH(a52,
2840     [  --with-a52=PATH         a52 headers and libraries])
2841   AC_ARG_WITH(a52-tree,
2842     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2843   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2844   then
2845     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2846     if test -z "${real_a52_tree}"
2847     then
2848       dnl  The given directory can't be found
2849       AC_MSG_RESULT(no)
2850       AC_MSG_ERROR([${with_a52_tree} directory doesn't exist])
2851     fi
2852     dnl  Use a custom a52dec
2853     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2854     if test -f ${real_a52_tree}/include/a52.h
2855     then
2856       AC_MSG_RESULT(yes)
2857       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2858       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2859       LDFLAGS="${LDFLAGS_save} ${LIBS_a52tofloat32}"
2860       AC_CHECK_LIB(a52, a52_free, [
2861         VLC_ADD_PLUGIN([a52tofloat32])
2862         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2863         VLC_ADD_LIBS([a52tofloat32],[-la52])
2864         ],[
2865         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2866         then
2867           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2868         else
2869           AC_MSG_ERROR([the specified tree hasn't been compiled])
2870         fi
2871       ])
2872       LDFLAGS="${LDFLAGS_save}"
2873     else
2874       AC_MSG_RESULT(no)
2875       AC_MSG_ERROR([the specified tree doesn't have a52.h])
2876     fi
2877   else
2878     if test -z "${with_a52}"
2879     then
2880       LDFLAGS_test=""
2881       CPPFLAGS_test=""
2882     else
2883       LDFLAGS_test="-L${with_a52}/lib"
2884       CPPFLAGS_test="-I${with_a52}/include"
2885     fi
2886     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2887     LDFLAGS="${LDFLAGS_save} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2888     AC_CHECK_HEADERS(a52dec/a52.h, [
2889       AC_CHECK_LIB(a52, a52_free, [
2890         VLC_ADD_PLUGIN([a52tofloat32])
2891         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2892         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2893       ],[
2894         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2895         ])
2896     ],[
2897       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2898     ])
2899     CPPFLAGS="${CPPFLAGS_save}"
2900     LDFLAGS="${LDFLAGS_save}"
2901   fi
2902 fi
2903
2904 AC_ARG_WITH(a52-fixed,
2905       [  --with-a52-fixed        specify if liba52 has been compiled with fixed point support],
2906       [
2907         VLC_ADD_CPPFLAGS([a52tofloat32],[-DLIBA52_FIXED]) ])
2908
2909 dnl
2910 dnl DTS Coherent Acoustics decoder plugin
2911 dnl
2912 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2913
2914 dnl
2915 dnl  Flac plugin
2916 dnl
2917 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2918
2919 dnl
2920 dnl  Libmpeg2 plugin
2921 dnl
2922 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2923
2924 dnl
2925 dnl  Vorbis plugin
2926 dnl
2927 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2928
2929 dnl
2930 dnl  Tremor plugin
2931 dnl
2932 AC_ARG_ENABLE(tremor,
2933   [  --enable-tremor         Tremor decoder support (default disabled)])
2934 if test "${enable_tremor}" = "yes"
2935 then
2936   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2937     VLC_ADD_PLUGIN([tremor])
2938     VLC_ADD_LIBS([tremor],[-lvorbisidec -logg])
2939    ],[])
2940 fi
2941
2942 dnl
2943 dnl  Speex plugin
2944 dnl
2945 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex decoder support], [auto])
2946
2947 dnl
2948 dnl  theora decoder plugin
2949 dnl
2950 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theora >= 1.0], [experimental theora codec], [auto])
2951
2952 dnl
2953 dnl  dirac encoder plugin
2954 dnl
2955 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2956
2957 dnl
2958 dnl  schroedinger decoder plugin (for dirac format video)
2959 dnl
2960 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2961
2962 dnl
2963 dnl  PNG decoder module
2964 dnl
2965 AC_ARG_ENABLE(png,
2966   [  --enable-png            PNG support (default enabled)])
2967 if test "${enable_png}" != "no"; then
2968 AC_CHECK_HEADERS(png.h, [
2969   LDFLAGS="${LDFLAGS_save} -lz"
2970   AC_CHECK_LIB(png, png_set_rows, [
2971     VLC_ADD_LIBS([png],[-lpng -lz])
2972     VLC_ADD_PLUGIN([png osdmenu osd_parser])],
2973     [],[-lz])
2974     LDFLAGS="${LDFLAGS_save}"
2975   ])
2976 fi
2977 AM_CONDITIONAL(BUILD_OSDMENU, [test "${enable_png}" != "no"])
2978
2979 dnl
2980 dnl H264 encoder plugin (using libx264)
2981 dnl
2982 AC_ARG_ENABLE(x264,
2983   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2984 if test "${enable_x264}" != "no"; then
2985   AC_ARG_WITH(x264-tree,
2986     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2987   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2988   then
2989     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2990     if test -z "${real_x264_tree}"
2991     then
2992       dnl  The given directory can't be found
2993       AC_MSG_RESULT(no)
2994       AC_MSG_ERROR([${with_x264_tree} directory doesn't exist])
2995     fi
2996     dnl  Use a custom libx264
2997     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2998     if test -f ${real_x264_tree}/x264.h
2999     then
3000       AC_MSG_RESULT(yes)
3001       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
3002       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
3003       PKG_CHECK_MODULES(X264,x264, [
3004         VLC_ADD_PLUGIN([x264])
3005         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
3006         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
3007         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3008           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
3009         fi
3010       ],[
3011         AC_MSG_ERROR([the specified tree hasn't been compiled])
3012       ])
3013       LDFLAGS="${LDFLAGS_save}"
3014     else
3015       AC_MSG_RESULT(no)
3016       AC_MSG_ERROR([the specified tree doesn't have x264.h])
3017     fi
3018   else
3019       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
3020         VLC_ADD_PLUGIN([x264])
3021         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
3022
3023         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
3024           VLC_ADD_LDFLAGS([x264],[-Wl,-Bsymbolic])
3025         ])
3026
3027         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
3028         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3029           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
3030         fi
3031       ],[
3032         if test "${enable_x264}" = "yes"; then
3033             AC_MSG_ERROR([Could not find libx264 >= 0.86 on your system: you may get it from http://www.videolan.org/x264.html])
3034           fi
3035       ])
3036     LDFLAGS="${LDFLAGS_save}"
3037   fi
3038 fi
3039
3040 dnl
3041 dnl libfluidsynth (MIDI synthetizer) plugin
3042 dnl
3043 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth], [MIDI synthetiser with libfluidsynth], [auto])
3044
3045 dnl
3046 dnl Teletext Modules
3047 dnl vbi decoder plugin (using libzbvi)
3048 dnl telx module
3049 dnl uncompatible
3050 dnl
3051 AC_ARG_ENABLE(zvbi,
3052   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
3053                   libzvbi (default enabled)]))
3054 AC_ARG_ENABLE(telx,
3055   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
3056                   zvbi) (default enabled if zvbi is absent)]))
3057
3058 AS_IF( [test "${enable_zvbi}" != "no"],[
3059     PKG_CHECK_MODULES(ZVBI,
3060         zvbi-0.2 >= 0.2.28,
3061         [
3062           VLC_ADD_LIBS([zvbi],[$ZVBI_LIBS])
3063           if test "${SYS}" = "mingw32"; then
3064               VLC_ADD_LIBS([zvbi],[ -lpthreadGC2])
3065           fi
3066           VLC_ADD_CFLAGS([zvbi],[$ZVBI_CFLAGS])
3067           VLC_ADD_PLUGIN([zvbi])
3068           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
3069           AS_IF( [test "${enable_telx}" = "yes"],[
3070                   AC_MSG_WARN([The zvbi and telx modules are uncompatibles.
3071                                Using zvbi.])
3072                   ])
3073         ],[
3074           AC_MSG_WARN(ZVBI library not found. Enabling the telx module instead)
3075         ])
3076     ])
3077 AS_IF( [test "${enable_telx}" != "no" ],[
3078   VLC_ADD_PLUGIN([telx])
3079   ])
3080
3081 dnl
3082 dnl libass subtitle rendering module
3083 dnl
3084 AC_ARG_ENABLE(libass,
3085   [  --enable-libass         Subtitle support using libass (default enabled)])
3086 AS_IF( [test "${enable_libass}" != "no"], [
3087   PKG_CHECK_MODULES(LIBASS, libass >= 0.9.6,
3088       [
3089         VLC_ADD_LIBS([libass],[$LIBASS_LIBS])
3090         VLC_ADD_CFLAGS([libass],[$LIBASS_CFLAGS])
3091         VLC_ADD_PLUGIN([libass])
3092
3093         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3094           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3095            VLC_ADD_LIBS([libass],[-lfontconfig])
3096        ])
3097       ],[
3098         AC_MSG_WARN([LIBASS library not found])
3099       ])
3100   ])
3101
3102 dnl
3103 dnl  kate decoder plugin
3104 dnl
3105 AC_ARG_ENABLE(kate,
3106 [  --enable-kate           kate codec (default enabled)])
3107 AS_IF([test "${enable_kate}" != "no"], [
3108   PKG_CHECK_MODULES(KATE,[kate >= 0.1.5], [
3109       VLC_ADD_PLUGIN([kate])
3110       VLC_ADD_CFLAGS([kate],[$KATE_CFLAGS])
3111       VLC_ADD_LIBS([kate],[$KATE_LIBS]) ],[
3112         AC_CHECK_HEADERS(kate/kate.h, [
3113           AC_CHECK_LIB(kate, kate_decode_init, [
3114             VLC_ADD_PLUGIN([kate])
3115             kate_libs="-lkate -logg"
3116             VLC_ADD_LDFLAGS([kate],[${kate_libs}]) ],[
3117             AS_IF([test "x${enable_kate}" != "x"], [
3118               AC_MSG_ERROR([libkate doesn't appear to be installed on your system.
3119               You also need to check that you have a libogg posterior to the 1.0 release.])
3120             ])
3121           ], [-lkate -logg])
3122         ],[
3123           AS_IF([test "x${enable_kate}" != "x"], [
3124             AC_MSG_ERROR([libkate headers do not appear to be installed on your system.
3125             You also need to check that you have a libogg posterior to the 1.0 release.])
3126           ])
3127         ])
3128   ])
3129 ])
3130
3131
3132 dnl
3133 dnl  tiger rendering for kate decoder plugin
3134 dnl
3135 AC_ARG_ENABLE(tiger,
3136 [  --enable-tiger          Tiger rendering library for Kate streams (default enabled)])
3137 AS_IF([test "${enable_tiger}" != "no"], [
3138   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3139       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])
3140       VLC_ADD_CFLAGS([kate],[$TIGER_CFLAGS])
3141       VLC_ADD_LIBS([kate],[$TIGER_LIBS]) ],[
3142         AS_IF([test "x${enable_tiger}" != "x"], [
3143           AC_MSG_ERROR([libtiger does not appear to be installed on your system.])
3144         ])
3145   ])
3146 ])
3147
3148
3149
3150 dnl
3151 dnl  Video plugins
3152 dnl
3153
3154 EXTEND_HELP_STRING([Video plugins:])
3155
3156 dnl
3157 dnl  Xlib
3158 dnl
3159
3160 AC_PATH_XTRA()
3161 AC_CHECK_HEADERS(X11/Xlib.h)
3162
3163 dnl
3164 dnl  X C Bindings modules
3165 dnl
3166 AC_ARG_ENABLE(xcb,
3167   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3168   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
3169     enable_xcb="yes"
3170   ], [
3171     enable_xcb="no"
3172   ])
3173 ])
3174 AC_ARG_ENABLE(xvideo,
3175   [  --enable-xvideo         XVideo support (default enabled)],, [
3176     enable_xvideo="$enable_xcb"
3177 ])
3178
3179 need_xid_provider="no"
3180 have_xcb="no"
3181 AS_IF([test "${enable_xcb}" != "no"], [
3182   dnl libxcb
3183   PKG_CHECK_MODULES(XCB, [xcb])
3184   have_xcb="yes"
3185   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3186
3187   AS_IF([test "${enable_xvideo}" != "no"], [
3188     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [
3189       VLC_ADD_PLUGIN([xcb_xv])
3190     ], [
3191       PKG_CHECK_MODULES(XCB_XV, [xcb-xv], [
3192         VLC_ADD_PLUGIN([xcb_xv])
3193         VLC_ADD_CFLAGS([xcb_xv], [-DXCB_XV_OLD])
3194       ])
3195     ])
3196   ])
3197
3198   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [
3199     VLC_ADD_PLUGIN([panoramix])
3200     VLC_ADD_LIBS([panoramix],[${XCB_RANDR_LIBS} ${XCB_LIBS}])
3201     VLC_ADD_CFLAGS([panoramix],[${XCB_RANDR_CFLAGS} ${XCB_CFLAGS}])
3202   ], [
3203     AC_MSG_WARN([libxcb-randr not found. Panoramix filter will not be supported.])
3204   ])
3205
3206   dnl xcb-utils
3207   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [
3208     have_xcb_keysyms="yes"
3209   ], [
3210     PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms], [
3211       have_xcb_keysyms="yes"
3212       VLC_ADD_CFLAGS([globalhotkeys], [-DXCB_KEYSYM_OLD_API])
3213     ], [
3214       have_xcb_keysyms="no"
3215       need_xid_provider="yes"
3216       AC_MSG_WARN([libxcb-keysyms not found. Hotkeys will not be supported.])
3217     ])
3218   ])
3219
3220   AS_IF([test "${have_xcb_keysyms}" = "yes"], [
3221     PKG_CHECK_MODULES(XPROTO, [xproto])
3222     VLC_ADD_PLUGIN([globalhotkeys])
3223     VLC_ADD_CFLAGS([globalhotkeys], [${XCB_KEYSYMS_CFLAGS} ${XCB_CFLAGS}])
3224     VLC_ADD_LIBS([globalhotkeys], [${XCB_KEYSYMS_LIBS} ${XCB_LIBS}])
3225     VLC_ADD_CFLAGS([xcb_window], [-DHAVE_XCB_KEYSYMS])
3226   ])
3227 ])
3228 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3229
3230 AC_ARG_ENABLE(glx,
3231   [  --enable-glx            X11 OpenGL (GLX) support (default enabled)],, [
3232   enable_glx="$enable_xcb"
3233 ])
3234 AS_IF([test "${enable_glx}" != "no"], [
3235   PKG_CHECK_MODULES(XLIB_XCB, [x11-xcb])
3236   PKG_CHECK_MODULES(GL, [gl],, [
3237     AC_CHECK_HEADER([GL/gl.h], [
3238       GL_CFLAGS=""
3239       GL_LIBS="-lGL"
3240     ], [
3241       AC_MSG_ERROR([GLX (libGL) cannot be found. If you do not need OpenGL with X11, use --disable-glx.])
3242     ])
3243   ])
3244   VLC_ADD_PLUGIN([xcb_glx])
3245 ])
3246 AC_SUBST([GL_CFLAGS])
3247 AC_SUBST([GL_LIBS])
3248
3249 dnl
3250 dnl  OpenGL
3251 dnl
3252 PKG_ENABLE_MODULES_VLC([GL], [], [gl], [OpenGL support], [auto])
3253 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [auto])
3254 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [auto])
3255 PKG_ENABLE_MODULES_VLC([EGL], [], [egl], [EGL support], [auto])
3256
3257 dnl
3258 dnl  SDL module
3259 dnl
3260 AC_ARG_ENABLE(sdl,
3261   [  --enable-sdl            SDL support (default enabled)])
3262 AC_ARG_ENABLE(sdl-image,
3263   [  --enable-sdl-image      SDL image support (default enabled)])
3264 if test "${enable_sdl}" != "no"
3265 then
3266    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3267       # SDL on Darwin is heavily patched and can only run SDL_image
3268       if test "${SYS}" != "darwin"; then
3269         VLC_ADD_PLUGIN([vout_sdl aout_sdl])
3270       fi
3271       if test "${SYS}" != "mingw32"; then
3272         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3273       fi
3274       VLC_ADD_CFLAGS([vout_sdl aout_sdl],[${SDL_CFLAGS}])
3275       VLC_ADD_LIBS([vout_sdl aout_sdl],[${SDL_LIBS}])
3276
3277       # SDL_image
3278       AS_IF([ test "${enable_sdl_image}" != "no"],[
3279         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3280           VLC_ADD_PLUGIN([sdl_image])
3281           VLC_ADD_LIBS([sdl_image],[${SDL_IMAGE_LIBS}])
3282           VLC_ADD_CFLAGS([sdl_image], [${SDL_IMAGE_CFLAGS}])],
3283           [ AC_MSG_WARN([The development package for SDL_image is not installed.
3284     You should install it alongside your SDL package.])
3285           ])
3286       ])
3287    ],[
3288      AC_MSG_WARN([The development package for SDL is not present or too old.
3289                   You need 1.2.10. Alternatively you can also configure with
3290                   --disable-sdl.])
3291    ])
3292 fi
3293
3294 dnl
3295 dnl  freetype module
3296 dnl
3297 AC_ARG_ENABLE(freetype,
3298   [  --enable-freetype       freetype support (default enabled)])
3299 AC_ARG_ENABLE(fribidi,
3300   [  --enable-fribidi        fribidi support (default enabled)])
3301 AC_ARG_ENABLE(fontconfig,
3302   [  --enable-fontconfig     fontconfig support (default enabled)])
3303 if test "${enable_freetype}" != "no"
3304 then
3305    PKG_CHECK_MODULES(FREETYPE, freetype2,[
3306       VLC_ADD_PLUGIN([freetype])
3307       have_freetype=yes
3308       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3309       if test "${SYS}" = "mingw32"; then
3310         VLC_ADD_LIBS([freetype],[-liconv -lz])
3311       fi
3312       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3313       if test "${enable_fontconfig}" != "no"
3314       then
3315         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3316           [VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3317            VLC_ADD_LIBS([freetype],[-lfontconfig])])
3318         AC_CHECK_HEADERS(Carbon/Carbon.h,
3319           [VLC_ADD_LDFLAGS([freetype],[-Wl,-framework,Carbon])])
3320       fi
3321
3322      dnl fribidi support
3323       if test "${enable_fribidi}" != "no"
3324       then
3325         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3326           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3327           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3328         ])
3329       fi
3330
3331   ],[
3332   have_freetype=no
3333   AS_IF([ test "${enable_freetype}" =  "yes"],[
3334     AC_MSG_ERROR([I couldn't find the freetype package. You can download libfreetype2
3335 from http://www.freetype.org/, or configure with --disable-freetype. Have a nice day.
3336       ])
3337     ])
3338   ])
3339
3340 fi
3341
3342 dnl
3343 dnl  libxml2 module
3344 dnl
3345 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3346
3347 dnl
3348 dnl  SVG module
3349 dnl
3350 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3351
3352 dnl
3353 dnl Snapshot vout module (with cache)
3354 dnl
3355 AC_ARG_ENABLE(snapshot,
3356   [  --enable-snapshot       snapshot module (default disabled)])
3357 if test "${enable_snapshot}" = "yes"
3358 then
3359   VLC_ADD_PLUGIN([snapshot])
3360 fi
3361
3362 dnl
3363 dnl  iOS vout module
3364 dnl
3365 AC_ARG_ENABLE(ios-vout,
3366   [  --enable-ios-vout    iOS video output module (default disabled)])
3367 if test "${enable_ios_vout}" = "yes"
3368 then
3369   VLC_ADD_PLUGIN([vout_ios])
3370   VLC_ADD_CFLAGS([vout_ios], [-DUSE_OPENGL_ES=1])
3371   VLC_ADD_LDFLAGS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3372 fi
3373
3374 dnl
3375 dnl  QuartzText vout module (iOS/Mac OS)
3376 dnl
3377 AC_ARG_ENABLE(macosx-quartztext,
3378   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3379 if test "x${enable_macosx_quartztext}" != "xno" &&
3380   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3381 then
3382   VLC_ADD_PLUGIN([quartztext])
3383   VLC_ADD_LDFLAGS([quartztext],[-Wl,-framework,ApplicationServices])
3384 fi
3385
3386 dnl
3387 dnl  Windows DirectX module
3388 dnl
3389
3390 if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3391 then
3392   VLC_ADD_PLUGIN([panoramix])
3393 fi
3394
3395 AC_ARG_ENABLE(directx,
3396   [  --enable-directx        Win32 DirectX support (default enabled on Win32)])
3397 if test "${enable_directx}" != "no"
3398 then
3399   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3400   then
3401       VLC_ADD_LIBS([directx],[-luser32])
3402       AC_CHECK_HEADERS(ddraw.h,
3403       [ VLC_ADD_PLUGIN([directx aout_directx])
3404         VLC_ADD_LIBS([directx],[-lgdi32])
3405       ],[AC_MSG_ERROR([Cannot find DirectX headers!])]
3406       )
3407       AC_CHECK_HEADERS(GL/gl.h,
3408       [ VLC_ADD_PLUGIN([glwin32])
3409         VLC_ADD_LIBS([glwin32],[-lopengl32 -lgdi32])
3410       ])
3411       AC_CHECK_HEADERS(d3d9.h,
3412       [ VLC_ADD_PLUGIN([direct3d])
3413         VLC_ADD_LIBS([direct3d],[-lgdi32])
3414       ])
3415       VLC_ADD_LIBS([direct3d directx glwin32],[-lole32])
3416   fi
3417 fi
3418
3419 dnl
3420 dnl  Windows Direct2D plugin
3421 dnl
3422 AC_ARG_ENABLE(direct2d,
3423   [  --enable-direct2d         Win7/VistaPU Direct2D support (default auto on Win32)])
3424 if test "${enable_direct2d}" != "no"; then
3425   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3426   then
3427     AC_CHECK_HEADERS(d2d1.h,
3428       [
3429         VLC_ADD_PLUGIN([direct2d])
3430         VLC_ADD_LIBS([direct2d],[-lgdi32 -lole32])
3431       ], [AC_MSG_WARN([Cannot find Direct2D headers!])]
3432     )
3433   fi
3434 fi
3435
3436 dnl
3437 dnl  win32 GDI plugin
3438 dnl
3439 AC_ARG_ENABLE(wingdi,
3440   [  --enable-wingdi         Win32 GDI module (default enabled on Win32)])
3441 if test "${enable_wingdi}" != "no"; then
3442   if test "${SYS}" = "mingw32"; then
3443     VLC_ADD_PLUGIN([wingdi])
3444     VLC_ADD_LIBS([wingdi],[-lgdi32 -lole32])
3445   fi
3446   if test "${SYS}" = "mingwce"; then
3447     VLC_ADD_PLUGIN([wingdi wingapi])
3448     VLC_ADD_LIBS([wingdi],[-laygshell])
3449     VLC_ADD_LIBS([wingapi],[-laygshell])
3450   fi
3451 fi
3452
3453
3454 dnl
3455 dnl  Linux framebuffer module
3456 dnl
3457 AC_ARG_ENABLE(fb,
3458   [  --enable-fb             Linux framebuffer support (default enabled on Linux)])
3459     if test "${enable_fb}" != "no"
3460     then
3461       AC_CHECK_HEADERS(linux/fb.h, [
3462         VLC_ADD_PLUGIN([fb])
3463       ])
3464     fi
3465
3466 dnl
3467 dnl  DirectFB module
3468 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3469 dnl  TODO: support for static linking
3470 dnl
3471 AC_ARG_ENABLE(directfb,
3472   [  --enable-directfb       DirectFB support (default disabled)])
3473 AC_ARG_WITH(directfb,
3474   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3475
3476 if test "${enable_directfb}" = "yes"; then
3477     have_directfb="false"
3478     CPPFLAGS_mydirectfb=
3479     LIBS_mydirectfb=
3480     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3481         dnl Trying the given location
3482         CPPFLAGS_save="${CPPFLAGS}"
3483         LIBS_save="${LIBS}"
3484
3485         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3486         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/"
3487         LIBS_new="${LIBS_new} -L${with_directfb}/src/.libs/"
3488
3489         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3490         LIBS="${LIBS} ${LIBS_new}"
3491
3492         dnl FIXME: too obscure
3493         AC_CHECK_HEADER([directfb.h], [
3494             AC_CHECK_LIB([direct],[direct_initialize], [
3495                 AC_CHECK_LIB([fusion], [fusion_enter], [
3496                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3497                 ], have_directfb="false")
3498             ], have_directfb="false")
3499         ], have_directfb="false")
3500
3501         dnl Restore flags
3502         CPPFLAGS="${CPPFLAGS_save}"
3503         LIBS="${LIBS_save}"
3504
3505         if test "${have_directfb}" = "true"; then
3506             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3507             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3508         fi
3509     else
3510         dnl Look for directfb-config
3511         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3512         if test "${DIRECTFB_CONFIG}" != "no"; then
3513             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3514             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3515             have_directfb="true"
3516         else
3517             dnl Trying with pkg-config
3518             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3519                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3520                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3521                 have_directfb="true"
3522                 ], [have_directfb="false"])
3523         fi
3524     fi
3525     if test "${have_directfb}" = "true"; then
3526         VLC_ADD_PLUGIN([directfb])
3527         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3528         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3529     else
3530         AC_MSG_ERROR([cannot find directfb headers and/or libraries ])
3531     fi
3532 fi
3533
3534 dnl
3535 dnl  AA plugin
3536 dnl
3537 AC_ARG_ENABLE(aa,
3538   [  --enable-aa             aalib output (default disabled)])
3539 if test "${enable_aa}" = "yes"
3540 then
3541   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3542   if test "${have_aa}" = "true"
3543   then
3544     VLC_ADD_PLUGIN([aa])
3545     VLC_ADD_LIBS([aa],[-laa])
3546     if test "${SYS}" != "mingw32"; then
3547       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3548     fi
3549   fi
3550 fi
3551
3552 dnl
3553 dnl  libcaca plugin
3554 dnl
3555 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3556
3557 dnl
3558 dnl  Audio plugins
3559 dnl
3560
3561 EXTEND_HELP_STRING([Audio plugins:])
3562
3563 dnl
3564 dnl  OSS /dev/dsp module (enabled by default except on win32)
3565 dnl
3566 AC_ARG_ENABLE(oss,
3567   [  --enable-oss            Open Sound System OSS support (default enabled)])
3568
3569 if test "${enable_oss}" != "no" &&
3570   (test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" ||
3571    test "${enable_oss}" = "yes")
3572 then
3573   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3574     VLC_ADD_PLUGIN([oss access_oss])
3575     AC_CHECK_LIB(ossaudio,main,[VLC_ADD_LIBS([oss access_oss],[-lossaudio])])
3576   ])
3577 fi
3578
3579 dnl
3580 dnl  Pulseaudio module
3581 dnl
3582 PKG_ENABLE_MODULES_VLC([PULSE], [], [libpulse >= 0.9.22], [PulseAudio support], [auto])
3583
3584 dnl
3585 dnl  Portaudio module
3586 dnl
3587 PKG_ENABLE_MODULES_VLC([PORTAUDIO], [], [portaudio-2.0], [Portaudio library support], [auto])
3588
3589 dnl
3590 dnl  ALSA module
3591 dnl
3592 AC_ARG_ENABLE(alsa,
3593   [  --enable-alsa           Advanced Linux Sound Architecture (default auto)])
3594 have_alsa="no"
3595 AS_IF([test "${enable_alsa}" != "no"], [
3596   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.0], [
3597     have_alsa="yes"
3598   ], [
3599     AS_IF([test "x${enable_alsa}" != "x"], [
3600       AC_MSG_ERROR([alsa-lib not found])
3601     ])
3602   ])
3603 ])
3604 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3605
3606 dnl
3607 dnl  win32 waveOut plugin
3608 dnl
3609 AC_ARG_ENABLE(waveout,
3610   [  --enable-waveout        Win32 waveOut module (default enabled on Win32)])
3611 if test "${enable_waveout}" != "no"; then
3612   if test "${SYS}" = "mingw32"; then
3613     VLC_ADD_PLUGIN([waveout])
3614     VLC_ADD_LIBS([waveout],[-lwinmm])
3615   fi
3616   if test "${SYS}" = "mingwce"; then
3617     VLC_ADD_PLUGIN([waveout])
3618   fi
3619 fi
3620
3621 dnl
3622 dnl  CoreAudio plugin
3623 dnl
3624 AC_ARG_ENABLE(macosx-audio,
3625   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3626 if test "x${enable_macosx_audio}" != "xno" &&
3627   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3628 then
3629   AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,
3630     [ VLC_ADD_PLUGIN([auhal])
3631       VLC_ADD_LDFLAGS([auhal],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,Carbon])
3632     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3633 fi
3634
3635 dnl
3636 dnl  AudioQueue plugin
3637 dnl
3638 AC_ARG_ENABLE(audioqueue,
3639   [  --enable-audioqueue       AudioQueue audio module (default disabled)])
3640 if test "${enable_audioqueue}" = "yes"
3641 then
3642   VLC_ADD_PLUGIN([audioqueue])
3643   VLC_ADD_LDFLAGS([audioqueue], [-Wl,-framework,AudioToolbox,-framework,CoreFoundation])
3644 fi
3645
3646 dnl
3647 dnl  JACK modules
3648 dnl
3649 PKG_ENABLE_MODULES_VLC([JACK], [jack access_jack], [jack], [JACK audio I/O modules],[auto])
3650
3651 dnl
3652 dnl UPnP Plugin (Intel SDK)
3653 dnl
3654 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPnp SDK],[auto])
3655 VLC_ADD_CXXFLAGS([upnp],[${UPNP_CFLAGS}])
3656
3657 dnl
3658 dnl  Interface plugins
3659 dnl
3660
3661 EXTEND_HELP_STRING([Interface plugins:])
3662
3663 dnl
3664 dnl Skins2 module
3665 dnl
3666 AC_ARG_ENABLE(libtar,
3667   [  --enable-libtar         libtar support for skins2 (default auto)])
3668 AS_IF([test "${enable_libtar}" != "no"], [
3669   AC_CHECK_HEADERS(libtar.h, [
3670     VLC_ADD_LIBS([skins2],[-ltar])
3671   ])
3672 ])
3673
3674 AC_ARG_ENABLE(skins2,
3675   [AS_HELP_STRING([--enable-skins2],[Skins2 interface module (default
3676    enabled except on MacOSX and WinCE)])],, [
3677   AS_IF([test "${SYS}" != "darwin" && test "${SYS}" != "mingwce"], [
3678     enable_skins2="yes"
3679   ], [
3680     enable_skins2="no"
3681   ])
3682 ])
3683 AS_IF([test "${enable_skins2}" = "yes"], [
3684   dnl freetype
3685   AS_IF([test "${have_freetype}" != "yes"], [
3686     AC_MSG_ERROR([Could not find FreeType (required for skins2)])
3687   ])
3688
3689   AS_IF([test "${SYS}" = "mingw32"], [
3690     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -Imodules/gui/skins2 -DWIN32_SKINS])
3691     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3692     VLC_ADD_LIBS([skins2],[-loleaut32 -lwinspool -lwinmm -lshell32 -lctl3d32 -ladvapi32 -lwsock32 -lgdi32 -lcomdlg32 -lole32 -luuid -lcomctl32  -lmsimg32 -luser32])
3693
3694   ], [test "${SYS}" = "darwin"], [
3695     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 -DMACOSX_SKINS])
3696     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3697     VLC_ADD_LDFLAGS([skins2],[-Wl,-framework,Carbon])
3698
3699   ], [
3700     PKG_CHECK_MODULES([XPM], [xpm])
3701     PKG_CHECK_MODULES([XEXT], [xext])
3702     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 ${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3703     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3704     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} -lX11])
3705     need_xid_provider="no"
3706
3707   ])
3708   VLC_ADD_PLUGIN([skins2])
3709   ALIASES="${ALIASES} svlc"
3710 ])
3711 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3712
3713 dnl
3714 dnl Hildon UI
3715 dnl
3716 AC_ARG_ENABLE(hildon,
3717   [  --enable-hildon         Hildon touchscreen UI (default disabled)])
3718 AS_IF([test "${enable_hildon}" = "yes"], [
3719   PKG_CHECK_MODULES(HILDON, [hildon-1], [
3720     PKG_CHECK_MODULES(HILDON_FM, hildon-fm-2, [
3721       VLC_ADD_CFLAGS([hildon],[${HILDON_FM_CFLAGS} -DHAVE_HILDON_FM])
3722       VLC_ADD_LIBS([hildon],[${HILDON_FM_LIBS}])
3723     ], [
3724       AC_MSG_WARN(hildon-fm-2 not found)
3725     ])
3726     VLC_ADD_CFLAGS([hildon],[${HILDON_CFLAGS} ${X_CFLAGS}])
3727     VLC_ADD_LIBS([hildon],[${HILDON_LIBS} ${X_LIBS} ${X_PRE_LIBS} -lX11])
3728     VLC_ADD_PLUGIN([hildon])
3729     ALIASES="${ALIASES} mvlc"
3730     need_xid_provider="no"
3731   ], [
3732     AS_IF([test "${enable_hildon}" = "yes"],[
3733       AC_MSG_ERROR([Hildon libraries not found])
3734     ])
3735     enable_hildon="no"
3736   ])
3737 ])
3738 AM_CONDITIONAL(BUILD_HILDON, [test "${enable_hildon}" = "yes"])
3739
3740 dnl
3741 dnl QT 4
3742 dnl
3743 AC_ARG_ENABLE(qt4,
3744   [  --enable-qt4            Qt 4 support (default enabled) ],, [
3745   AS_IF([test "${SYS}" = "darwin"], [enable_qt4=no])
3746 ])
3747 AS_IF([test "${enable_qt4}" != "no"], [
3748   PKG_CHECK_MODULES(QT4, [QtCore QtGui >= 4.4.0], [
3749     VLC_ADD_PLUGIN([qt4])
3750     VLC_ADD_LIBS([qt4],[${QT4_LIBS}])
3751     VLC_ADD_CXXFLAGS([qt4],[${QT4_CFLAGS}])
3752     ALIASES="${ALIASES} qvlc"
3753
3754     AC_LANG_PUSH([C++])
3755     CPPFLAGS_save="${CPPFLAGS}"
3756
3757     AC_MSG_CHECKING([whether Qt uses X11])
3758     CPPFLAGS="${CPPFLAGS} ${QT4_CFLAGS}"
3759     AC_PREPROC_IFELSE([
3760 #include <QWidget>
3761 #if !defined (Q_WS_X11)
3762 # error Fail
3763 #endif
3764     ], [
3765       AC_MSG_RESULT([yes])