bfin: Refactor duplicated assembly-related macros
[ffmpeg.git] / libavcodec / bfin / vp3_idct_bfin.S
1 /*
2  * vp3_idct BlackFin
3  *
4  * Copyright (C) 2007 Marc Hoffman <marc.hoffman@analog.com>
5  *
6  * This file is part of Libav.
7  *
8  * Libav is free software; you can redistribute it and/or
9  * modify it under the terms of the GNU Lesser General Public
10  * License as published by the Free Software Foundation; either
11  * version 2.1 of the License, or (at your option) any later version.
12  *
13  * Libav is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16  * Lesser General Public License for more details.
17  *
18  * You should have received a copy of the GNU Lesser General Public
19  * License along with Libav; if not, write to the Free Software
20  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21  */
22 /*
23    This blackfin DSP code implements an 8x8 inverse type II DCT.
24
25 Prototype       : void ff_bfin_vp3_idct(int16_t *in)
26
27 Registers Used  : A0, A1, R0-R7, I0-I3, B0, B2, B3, M0-M2, L0-L3, P0-P5, LC0.
28
29 */
30
31 #include "libavutil/bfin/asm.h"
32
33 SECTION_L1_DATA_B
34
35 .align 4;
36 coefs:
37 .short 0x5a82;           //  C4
38 .short 0x5a82;           //  C4
39 .short 0x30FC;           //cos(3pi/8)  C6
40 .short 0x7642;           //cos(pi/8)   C2
41 .short 0x18F9;           //cos(7pi/16)
42 .short 0x7D8A;           //cos(pi/16)
43 .short 0x471D;           //cos(5pi/16)
44 .short 0x6A6E;           //cos(3pi/16)
45 .short 0x18F9;           //cos(7pi/16)
46 .short 0x7D8A;           //cos(pi/16)
47
48 SECTION_L1_DATA_A
49
50 vtmp: .space 256
51
52 #define TMP0 FP-8
53 #define TMP1 FP-12
54 #define TMP2 FP-16
55
56
57 .text
58 DEFUN(vp3_idct,mL1,
59         (int16_t *block)):
60
61 /********************** Function Prologue *********************************/
62     link 16;
63     [--SP] = (R7:4, P5:3);   // Push the registers onto the stack.
64     B0 = R0;                 // Pointer to Input matrix
65     RELOC(R1, P3, coefs);    // Pointer to Coefficients
66     RELOC(R2, P3, vtmp);     // Pointer to Temporary matrix
67     B3 = R1;
68     B2 = R2;
69     L3 = 20;                // L3 is used for making the coefficient array
70                             // circular.
71                             // MUST BE RESTORED TO ZERO at function exit.
72     M1 = 16 (X);            // All these registers are initialized for
73     M3 = 8(X);              // modifying address offsets.
74
75     I0 = B0;                // I0 points to Input Element (0, 0).
76     I2 = B0;                // I2 points to Input Element (0, 0).
77     I2 += M3 || R0.H = W[I0];
78                             // Element 0 is read into R0.H
79     I1 = I2;                // I1 points to input Element (0, 6).
80     I1 += 4  || R0.L = W[I2++];
81                             // I2 points to input Element (0, 4).
82                             // Element 4 is read into R0.L.
83     P2 = 8 (X);
84     P3 = 32 (X);
85     P4 = -32 (X);
86     P5 = 98 (X);
87     R7 = 0x8000(Z);
88     I3 = B3;                // I3 points to Coefficients
89     P0 = B2;                // P0 points to array Element (0, 0) of temp
90     P1 = B2;
91     R7 = [I3++] || [TMP2]=R7;            // Coefficient C4 is read into R7.H and R7.L.
92     MNOP;
93     NOP;
94
95     /*
96      *   A1 =      Y0 * cos(pi/4)
97      *   A0 =      Y0 * cos(pi/4)
98      *   A1 = A1 + Y4 * cos(pi/4)
99      *   A0 = A0 - Y4 * cos(pi/4)
100      *   load:
101      *     R1=(Y2,Y6)
102      *     R7=(C2,C6)
103      *   res:
104      *     R3=Y0, R2=Y4
105      */
106     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+= 4       || R1.L=W[I1++];
107     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
108
109     LSETUP (.0, .1) LC0 = P2; // perform 8 1d idcts
110
111     P2 = 112 (X);
112     P1 = P1 + P2;           // P1 points to element (7, 0) of temp buffer.
113     P2 = -94(X);
114
115 .0:
116        /*
117         *   A1 =      Y2 * cos(3pi/8)
118         *   A0 =      Y2 * cos(pi/8)
119         *   A1 = A1 - Y6 * cos(pi/8)
120         *   A0 = A0 + Y6 * cos(3pi/8)
121         *      R5 = (Y1,Y7)
122         *      R7 = (C1,C7)
123         *   res:
124         *      R1=Y2, R0=Y6
125         */
126         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
127         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
128         /*
129         *   Y0 = Y0 + Y6.
130         *   Y4 = Y4 + Y2.
131         *   Y2 = Y4 - Y2.
132         *   Y6 = Y0 - Y6.
133         *     R3 is saved
134         *     R6.l=Y3
135         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
136         */
137         R3=R3+R0, R0=R3-R0;
138         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
139         /*
140          *  Compute the odd portion (1,3,5,7) even is done.
141          *
142          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
143          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
144          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
145          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
146          */
147         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
148         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
149         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
150         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
151         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
152         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
153         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
154         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
155         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
156         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
157
158         /* Transpose write column. */
159         R5.H=R4+R2 (RND12);                                   // Y0=Y0+Y7
160         R5.L=R4-R2 (RND12) || R4 = [TMP1];                    // Y7=Y7-Y0
161         R2.H=R1+R7 (RND12) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
162         R2.L=R1-R7 (RND12) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
163         R5.H=R0-R3 (RND12) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
164         R5.L=R0+R3 (RND12) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
165         R3.H=R4-R6 (RND12) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
166         R3.L=R4+R6 (RND12) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
167
168         /* pipeline loop start, + drain Y3, Y4 */
169         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
170 .1:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
171
172
173
174     I0 = B2;                // I0 points to Input Element (0, 0)
175     I2 = B2;                // I2 points to Input Element (0, 0)
176     I2 += M3 || R0.H = W[I0];
177                             // Y0 is read in R0.H
178     I1 = I2;                // I1 points to input Element (0, 6)
179     I1 += 4  || R0.L = W[I2++];
180                             // I2 points to input Element (0, 4)
181                             // Y4 is read in R0.L
182     P2 = 8 (X);
183     I3 = B3;                // I3 points to Coefficients
184     P0 = B0;                // P0 points to array Element (0, 0) for writing
185                             // output
186     P1 = B0;
187     R7 = [I3++];            // R7.H = C4 and R7.L = C4
188     NOP;
189
190     /*
191      *   A1 =      Y0 * cos(pi/4)
192      *   A0 =      Y0 * cos(pi/4)
193      *   A1 = A1 + Y4 * cos(pi/4)
194      *   A0 = A0 - Y4 * cos(pi/4)
195      *   load:
196      *     R1=(Y2,Y6)
197      *     R7=(C2,C6)
198      *   res:
199      *     R3=Y0, R2=Y4
200      */
201     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+=4        || R1.L=W[I1++];
202     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
203
204     LSETUP (.2, .3) LC0 = P2; // peform 8 1d idcts
205     P2 = 112 (X);
206     P1 = P1 + P2;
207     P2 = -94(X);
208
209 .2:
210         /*
211          *   A1 =      Y2 * cos(3pi/8)
212          *   A0 =      Y2 * cos(pi/8)
213          *   A1 = A1 - Y6 * cos(pi/8)
214          *   A0 = A0 + Y6 * cos(3pi/8)
215          *      R5 = (Y1,Y7)
216          *      R7 = (C1,C7)
217          *   res:
218          *      R1=Y2, R0=Y6
219          */
220         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
221         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
222         /*
223         *   Y0 = Y0 + Y6.
224         *   Y4 = Y4 + Y2.
225         *   Y2 = Y4 - Y2.
226         *   Y6 = Y0 - Y6.
227         *     R3 is saved
228         *     R6.l=Y3
229         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
230         */
231         R3=R3+R0, R0=R3-R0;
232         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
233         /*
234          *  Compute the odd portion (1,3,5,7) even is done.
235          *
236          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
237          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
238          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
239          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
240          */
241         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
242         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
243         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
244         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
245         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
246         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
247         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
248         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
249         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
250         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
251
252         /* Transpose write column. */
253         R5.H=R4+R2 (RND20);                                   // Y0=Y0+Y7
254         R5.L=R4-R2 (RND20) || R4 = [TMP1];                    // Y7=Y7-Y0
255         R5=R5>>>2(v);
256         R2.H=R1+R7 (RND20) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
257         R2.L=R1-R7 (RND20) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
258         R2=R2>>>2(v);
259         R5.H=R0-R3 (RND20) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
260         R5.L=R0+R3 (RND20) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
261         R5=R5>>>2(v);
262         R3.H=R4-R6 (RND20) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
263         R3.L=R4+R6 (RND20) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
264         R3=R3>>>2(v);
265         /* pipeline loop start, + drain Y3, Y4 */
266         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
267 .3:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
268
269     L3 = 0;
270     (R7:4,P5:3)=[SP++];
271     unlink;
272     RTS;
273 DEFUN_END(vp3_idct)