x86inc: Be more verbose in assertion failures
[x264/x264-sandbox.git] / common / x86 / x86inc.asm
1 ;*****************************************************************************
2 ;* x86inc.asm: x264asm abstraction layer
3 ;*****************************************************************************
4 ;* Copyright (C) 2005-2015 x264 project
5 ;*
6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
8 ;*          Fiona Glaser <fiona@x264.com>
9 ;*          Henrik Gramner <henrik@gramner.com>
10 ;*
11 ;* Permission to use, copy, modify, and/or distribute this software for any
12 ;* purpose with or without fee is hereby granted, provided that the above
13 ;* copyright notice and this permission notice appear in all copies.
14 ;*
15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
22 ;*****************************************************************************
23
24 ; This is a header file for the x264ASM assembly language, which uses
25 ; NASM/YASM syntax combined with a large number of macros to provide easy
26 ; abstraction between different calling conventions (x86_32, win64, linux64).
27 ; It also has various other useful features to simplify writing the kind of
28 ; DSP functions that are most often used in x264.
29
30 ; Unlike the rest of x264, this file is available under an ISC license, as it
31 ; has significant usefulness outside of x264 and we want it to be available
32 ; to the largest audience possible.  Of course, if you modify it for your own
33 ; purposes to add a new feature, we strongly encourage contributing a patch
34 ; as this feature might be useful for others as well.  Send patches or ideas
35 ; to x264-devel@videolan.org .
36
37 %ifndef private_prefix
38     %define private_prefix x264
39 %endif
40
41 %ifndef public_prefix
42     %define public_prefix private_prefix
43 %endif
44
45 %ifndef STACK_ALIGNMENT
46     %if ARCH_X86_64
47         %define STACK_ALIGNMENT 16
48     %else
49         %define STACK_ALIGNMENT 4
50     %endif
51 %endif
52
53 %define WIN64  0
54 %define UNIX64 0
55 %if ARCH_X86_64
56     %ifidn __OUTPUT_FORMAT__,win32
57         %define WIN64  1
58     %elifidn __OUTPUT_FORMAT__,win64
59         %define WIN64  1
60     %elifidn __OUTPUT_FORMAT__,x64
61         %define WIN64  1
62     %else
63         %define UNIX64 1
64     %endif
65 %endif
66
67 %define FORMAT_ELF 0
68 %ifidn __OUTPUT_FORMAT__,elf
69     %define FORMAT_ELF 1
70 %elifidn __OUTPUT_FORMAT__,elf32
71     %define FORMAT_ELF 1
72 %elifidn __OUTPUT_FORMAT__,elf64
73     %define FORMAT_ELF 1
74 %endif
75
76 %ifdef PREFIX
77     %define mangle(x) _ %+ x
78 %else
79     %define mangle(x) x
80 %endif
81
82 %macro SECTION_RODATA 0-1 16
83     SECTION .rodata align=%1
84 %endmacro
85
86 %if WIN64
87     %define PIC
88 %elif ARCH_X86_64 == 0
89 ; x86_32 doesn't require PIC.
90 ; Some distros prefer shared objects to be PIC, but nothing breaks if
91 ; the code contains a few textrels, so we'll skip that complexity.
92     %undef PIC
93 %endif
94 %ifdef PIC
95     default rel
96 %endif
97
98 %ifdef __NASM_VER__
99     %use smartalign
100 %endif
101
102 ; Macros to eliminate most code duplication between x86_32 and x86_64:
103 ; Currently this works only for leaf functions which load all their arguments
104 ; into registers at the start, and make no other use of the stack. Luckily that
105 ; covers most of x264's asm.
106
107 ; PROLOGUE:
108 ; %1 = number of arguments. loads them from stack if needed.
109 ; %2 = number of registers used. pushes callee-saved regs if needed.
110 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
111 ; %4 = (optional) stack size to be allocated. The stack will be aligned before
112 ;      allocating the specified stack size. If the required stack alignment is
113 ;      larger than the known stack alignment the stack will be manually aligned
114 ;      and an extra register will be allocated to hold the original stack
115 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
116 ;      register as stack pointer, request a negative stack size.
117 ; %4+/%5+ = list of names to define to registers
118 ; PROLOGUE can also be invoked by adding the same options to cglobal
119
120 ; e.g.
121 ; cglobal foo, 2,3,7,0x40, dst, src, tmp
122 ; declares a function (foo) that automatically loads two arguments (dst and
123 ; src) into registers, uses one additional register (tmp) plus 7 vector
124 ; registers (m0-m6) and allocates 0x40 bytes of stack space.
125
126 ; TODO Some functions can use some args directly from the stack. If they're the
127 ; last args then you can just not declare them, but if they're in the middle
128 ; we need more flexible macro.
129
130 ; RET:
131 ; Pops anything that was pushed by PROLOGUE, and returns.
132
133 ; REP_RET:
134 ; Use this instead of RET if it's a branch target.
135
136 ; registers:
137 ; rN and rNq are the native-size register holding function argument N
138 ; rNd, rNw, rNb are dword, word, and byte size
139 ; rNh is the high 8 bits of the word size
140 ; rNm is the original location of arg N (a register or on the stack), dword
141 ; rNmp is native size
142
143 %macro DECLARE_REG 2-3
144     %define r%1q %2
145     %define r%1d %2d
146     %define r%1w %2w
147     %define r%1b %2b
148     %define r%1h %2h
149     %define %2q %2
150     %if %0 == 2
151         %define r%1m  %2d
152         %define r%1mp %2
153     %elif ARCH_X86_64 ; memory
154         %define r%1m [rstk + stack_offset + %3]
155         %define r%1mp qword r %+ %1 %+ m
156     %else
157         %define r%1m [rstk + stack_offset + %3]
158         %define r%1mp dword r %+ %1 %+ m
159     %endif
160     %define r%1  %2
161 %endmacro
162
163 %macro DECLARE_REG_SIZE 3
164     %define r%1q r%1
165     %define e%1q r%1
166     %define r%1d e%1
167     %define e%1d e%1
168     %define r%1w %1
169     %define e%1w %1
170     %define r%1h %3
171     %define e%1h %3
172     %define r%1b %2
173     %define e%1b %2
174 %if ARCH_X86_64 == 0
175     %define r%1  e%1
176 %endif
177 %endmacro
178
179 DECLARE_REG_SIZE ax, al, ah
180 DECLARE_REG_SIZE bx, bl, bh
181 DECLARE_REG_SIZE cx, cl, ch
182 DECLARE_REG_SIZE dx, dl, dh
183 DECLARE_REG_SIZE si, sil, null
184 DECLARE_REG_SIZE di, dil, null
185 DECLARE_REG_SIZE bp, bpl, null
186
187 ; t# defines for when per-arch register allocation is more complex than just function arguments
188
189 %macro DECLARE_REG_TMP 1-*
190     %assign %%i 0
191     %rep %0
192         CAT_XDEFINE t, %%i, r%1
193         %assign %%i %%i+1
194         %rotate 1
195     %endrep
196 %endmacro
197
198 %macro DECLARE_REG_TMP_SIZE 0-*
199     %rep %0
200         %define t%1q t%1 %+ q
201         %define t%1d t%1 %+ d
202         %define t%1w t%1 %+ w
203         %define t%1h t%1 %+ h
204         %define t%1b t%1 %+ b
205         %rotate 1
206     %endrep
207 %endmacro
208
209 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
210
211 %if ARCH_X86_64
212     %define gprsize 8
213 %else
214     %define gprsize 4
215 %endif
216
217 %macro PUSH 1
218     push %1
219     %ifidn rstk, rsp
220         %assign stack_offset stack_offset+gprsize
221     %endif
222 %endmacro
223
224 %macro POP 1
225     pop %1
226     %ifidn rstk, rsp
227         %assign stack_offset stack_offset-gprsize
228     %endif
229 %endmacro
230
231 %macro PUSH_IF_USED 1-*
232     %rep %0
233         %if %1 < regs_used
234             PUSH r%1
235         %endif
236         %rotate 1
237     %endrep
238 %endmacro
239
240 %macro POP_IF_USED 1-*
241     %rep %0
242         %if %1 < regs_used
243             pop r%1
244         %endif
245         %rotate 1
246     %endrep
247 %endmacro
248
249 %macro LOAD_IF_USED 1-*
250     %rep %0
251         %if %1 < num_args
252             mov r%1, r %+ %1 %+ mp
253         %endif
254         %rotate 1
255     %endrep
256 %endmacro
257
258 %macro SUB 2
259     sub %1, %2
260     %ifidn %1, rstk
261         %assign stack_offset stack_offset+(%2)
262     %endif
263 %endmacro
264
265 %macro ADD 2
266     add %1, %2
267     %ifidn %1, rstk
268         %assign stack_offset stack_offset-(%2)
269     %endif
270 %endmacro
271
272 %macro movifnidn 2
273     %ifnidn %1, %2
274         mov %1, %2
275     %endif
276 %endmacro
277
278 %macro movsxdifnidn 2
279     %ifnidn %1, %2
280         movsxd %1, %2
281     %endif
282 %endmacro
283
284 %macro ASSERT 1
285     %if (%1) == 0
286         %error assertion ``%1'' failed
287     %endif
288 %endmacro
289
290 %macro DEFINE_ARGS 0-*
291     %ifdef n_arg_names
292         %assign %%i 0
293         %rep n_arg_names
294             CAT_UNDEF arg_name %+ %%i, q
295             CAT_UNDEF arg_name %+ %%i, d
296             CAT_UNDEF arg_name %+ %%i, w
297             CAT_UNDEF arg_name %+ %%i, h
298             CAT_UNDEF arg_name %+ %%i, b
299             CAT_UNDEF arg_name %+ %%i, m
300             CAT_UNDEF arg_name %+ %%i, mp
301             CAT_UNDEF arg_name, %%i
302             %assign %%i %%i+1
303         %endrep
304     %endif
305
306     %xdefine %%stack_offset stack_offset
307     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
308     %assign %%i 0
309     %rep %0
310         %xdefine %1q r %+ %%i %+ q
311         %xdefine %1d r %+ %%i %+ d
312         %xdefine %1w r %+ %%i %+ w
313         %xdefine %1h r %+ %%i %+ h
314         %xdefine %1b r %+ %%i %+ b
315         %xdefine %1m r %+ %%i %+ m
316         %xdefine %1mp r %+ %%i %+ mp
317         CAT_XDEFINE arg_name, %%i, %1
318         %assign %%i %%i+1
319         %rotate 1
320     %endrep
321     %xdefine stack_offset %%stack_offset
322     %assign n_arg_names %0
323 %endmacro
324
325 %define required_stack_alignment ((mmsize + 15) & ~15)
326
327 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
328     %ifnum %1
329         %if %1 != 0
330             %assign %%pad 0
331             %assign stack_size %1
332             %if stack_size < 0
333                 %assign stack_size -stack_size
334             %endif
335             %if WIN64
336                 %assign %%pad %%pad + 32 ; shadow space
337                 %if mmsize != 8
338                     %assign xmm_regs_used %2
339                     %if xmm_regs_used > 8
340                         %assign %%pad %%pad + (xmm_regs_used-8)*16 ; callee-saved xmm registers
341                     %endif
342                 %endif
343             %endif
344             %if required_stack_alignment <= STACK_ALIGNMENT
345                 ; maintain the current stack alignment
346                 %assign stack_size_padded stack_size + %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
347                 SUB rsp, stack_size_padded
348             %else
349                 %assign %%reg_num (regs_used - 1)
350                 %xdefine rstk r %+ %%reg_num
351                 ; align stack, and save original stack location directly above
352                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
353                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
354                 ; rsp, [rsp+stack_size_padded])
355                 %if %1 < 0 ; need to store rsp on stack
356                     %xdefine rstkm [rsp + stack_size + %%pad]
357                     %assign %%pad %%pad + gprsize
358                 %else ; can keep rsp in rstk during whole function
359                     %xdefine rstkm rstk
360                 %endif
361                 %assign stack_size_padded stack_size + ((%%pad + required_stack_alignment-1) & ~(required_stack_alignment-1))
362                 mov rstk, rsp
363                 and rsp, ~(required_stack_alignment-1)
364                 sub rsp, stack_size_padded
365                 movifnidn rstkm, rstk
366             %endif
367             WIN64_PUSH_XMM
368         %endif
369     %endif
370 %endmacro
371
372 %macro SETUP_STACK_POINTER 1
373     %ifnum %1
374         %if %1 != 0 && required_stack_alignment > STACK_ALIGNMENT
375             %if %1 > 0
376                 %assign regs_used (regs_used + 1)
377             %elif ARCH_X86_64 && regs_used == num_args && num_args <= 4 + UNIX64 * 2
378                 %warning "Stack pointer will overwrite register argument"
379             %endif
380         %endif
381     %endif
382 %endmacro
383
384 %macro DEFINE_ARGS_INTERNAL 3+
385     %ifnum %2
386         DEFINE_ARGS %3
387     %elif %1 == 4
388         DEFINE_ARGS %2
389     %elif %1 > 4
390         DEFINE_ARGS %2, %3
391     %endif
392 %endmacro
393
394 %if WIN64 ; Windows x64 ;=================================================
395
396 DECLARE_REG 0,  rcx
397 DECLARE_REG 1,  rdx
398 DECLARE_REG 2,  R8
399 DECLARE_REG 3,  R9
400 DECLARE_REG 4,  R10, 40
401 DECLARE_REG 5,  R11, 48
402 DECLARE_REG 6,  rax, 56
403 DECLARE_REG 7,  rdi, 64
404 DECLARE_REG 8,  rsi, 72
405 DECLARE_REG 9,  rbx, 80
406 DECLARE_REG 10, rbp, 88
407 DECLARE_REG 11, R12, 96
408 DECLARE_REG 12, R13, 104
409 DECLARE_REG 13, R14, 112
410 DECLARE_REG 14, R15, 120
411
412 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
413     %assign num_args %1
414     %assign regs_used %2
415     ASSERT regs_used >= num_args
416     SETUP_STACK_POINTER %4
417     ASSERT regs_used <= 15
418     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
419     ALLOC_STACK %4, %3
420     %if mmsize != 8 && stack_size == 0
421         WIN64_SPILL_XMM %3
422     %endif
423     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
424     DEFINE_ARGS_INTERNAL %0, %4, %5
425 %endmacro
426
427 %macro WIN64_PUSH_XMM 0
428     ; Use the shadow space to store XMM6 and XMM7, the rest needs stack space allocated.
429     %if xmm_regs_used > 6
430         movaps [rstk + stack_offset +  8], xmm6
431     %endif
432     %if xmm_regs_used > 7
433         movaps [rstk + stack_offset + 24], xmm7
434     %endif
435     %if xmm_regs_used > 8
436         %assign %%i 8
437         %rep xmm_regs_used-8
438             movaps [rsp + (%%i-8)*16 + stack_size + 32], xmm %+ %%i
439             %assign %%i %%i+1
440         %endrep
441     %endif
442 %endmacro
443
444 %macro WIN64_SPILL_XMM 1
445     %assign xmm_regs_used %1
446     ASSERT xmm_regs_used <= 16
447     %if xmm_regs_used > 8
448         ; Allocate stack space for callee-saved xmm registers plus shadow space and align the stack.
449         %assign %%pad (xmm_regs_used-8)*16 + 32
450         %assign stack_size_padded %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
451         SUB rsp, stack_size_padded
452     %endif
453     WIN64_PUSH_XMM
454 %endmacro
455
456 %macro WIN64_RESTORE_XMM_INTERNAL 1
457     %assign %%pad_size 0
458     %if xmm_regs_used > 8
459         %assign %%i xmm_regs_used
460         %rep xmm_regs_used-8
461             %assign %%i %%i-1
462             movaps xmm %+ %%i, [%1 + (%%i-8)*16 + stack_size + 32]
463         %endrep
464     %endif
465     %if stack_size_padded > 0
466         %if stack_size > 0 && required_stack_alignment > STACK_ALIGNMENT
467             mov rsp, rstkm
468         %else
469             add %1, stack_size_padded
470             %assign %%pad_size stack_size_padded
471         %endif
472     %endif
473     %if xmm_regs_used > 7
474         movaps xmm7, [%1 + stack_offset - %%pad_size + 24]
475     %endif
476     %if xmm_regs_used > 6
477         movaps xmm6, [%1 + stack_offset - %%pad_size +  8]
478     %endif
479 %endmacro
480
481 %macro WIN64_RESTORE_XMM 1
482     WIN64_RESTORE_XMM_INTERNAL %1
483     %assign stack_offset (stack_offset-stack_size_padded)
484     %assign xmm_regs_used 0
485 %endmacro
486
487 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
488
489 %macro RET 0
490     WIN64_RESTORE_XMM_INTERNAL rsp
491     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
492 %if mmsize == 32
493     vzeroupper
494 %endif
495     AUTO_REP_RET
496 %endmacro
497
498 %elif ARCH_X86_64 ; *nix x64 ;=============================================
499
500 DECLARE_REG 0,  rdi
501 DECLARE_REG 1,  rsi
502 DECLARE_REG 2,  rdx
503 DECLARE_REG 3,  rcx
504 DECLARE_REG 4,  R8
505 DECLARE_REG 5,  R9
506 DECLARE_REG 6,  rax, 8
507 DECLARE_REG 7,  R10, 16
508 DECLARE_REG 8,  R11, 24
509 DECLARE_REG 9,  rbx, 32
510 DECLARE_REG 10, rbp, 40
511 DECLARE_REG 11, R12, 48
512 DECLARE_REG 12, R13, 56
513 DECLARE_REG 13, R14, 64
514 DECLARE_REG 14, R15, 72
515
516 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
517     %assign num_args %1
518     %assign regs_used %2
519     ASSERT regs_used >= num_args
520     SETUP_STACK_POINTER %4
521     ASSERT regs_used <= 15
522     PUSH_IF_USED 9, 10, 11, 12, 13, 14
523     ALLOC_STACK %4
524     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
525     DEFINE_ARGS_INTERNAL %0, %4, %5
526 %endmacro
527
528 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
529
530 %macro RET 0
531 %if stack_size_padded > 0
532 %if required_stack_alignment > STACK_ALIGNMENT
533     mov rsp, rstkm
534 %else
535     add rsp, stack_size_padded
536 %endif
537 %endif
538     POP_IF_USED 14, 13, 12, 11, 10, 9
539 %if mmsize == 32
540     vzeroupper
541 %endif
542     AUTO_REP_RET
543 %endmacro
544
545 %else ; X86_32 ;==============================================================
546
547 DECLARE_REG 0, eax, 4
548 DECLARE_REG 1, ecx, 8
549 DECLARE_REG 2, edx, 12
550 DECLARE_REG 3, ebx, 16
551 DECLARE_REG 4, esi, 20
552 DECLARE_REG 5, edi, 24
553 DECLARE_REG 6, ebp, 28
554 %define rsp esp
555
556 %macro DECLARE_ARG 1-*
557     %rep %0
558         %define r%1m [rstk + stack_offset + 4*%1 + 4]
559         %define r%1mp dword r%1m
560         %rotate 1
561     %endrep
562 %endmacro
563
564 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
565
566 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
567     %assign num_args %1
568     %assign regs_used %2
569     ASSERT regs_used >= num_args
570     %if num_args > 7
571         %assign num_args 7
572     %endif
573     %if regs_used > 7
574         %assign regs_used 7
575     %endif
576     SETUP_STACK_POINTER %4
577     ASSERT regs_used <= 7
578     PUSH_IF_USED 3, 4, 5, 6
579     ALLOC_STACK %4
580     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
581     DEFINE_ARGS_INTERNAL %0, %4, %5
582 %endmacro
583
584 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
585
586 %macro RET 0
587 %if stack_size_padded > 0
588 %if required_stack_alignment > STACK_ALIGNMENT
589     mov rsp, rstkm
590 %else
591     add rsp, stack_size_padded
592 %endif
593 %endif
594     POP_IF_USED 6, 5, 4, 3
595 %if mmsize == 32
596     vzeroupper
597 %endif
598     AUTO_REP_RET
599 %endmacro
600
601 %endif ;======================================================================
602
603 %if WIN64 == 0
604 %macro WIN64_SPILL_XMM 1
605 %endmacro
606 %macro WIN64_RESTORE_XMM 1
607 %endmacro
608 %macro WIN64_PUSH_XMM 0
609 %endmacro
610 %endif
611
612 ; On AMD cpus <=K10, an ordinary ret is slow if it immediately follows either
613 ; a branch or a branch target. So switch to a 2-byte form of ret in that case.
614 ; We can automatically detect "follows a branch", but not a branch target.
615 ; (SSSE3 is a sufficient condition to know that your cpu doesn't have this problem.)
616 %macro REP_RET 0
617     %if has_epilogue
618         RET
619     %else
620         rep ret
621     %endif
622 %endmacro
623
624 %define last_branch_adr $$
625 %macro AUTO_REP_RET 0
626     %ifndef cpuflags
627         times ((last_branch_adr-$)>>31)+1 rep ; times 1 iff $ != last_branch_adr.
628     %elif notcpuflag(ssse3)
629         times ((last_branch_adr-$)>>31)+1 rep
630     %endif
631     ret
632 %endmacro
633
634 %macro BRANCH_INSTR 0-*
635     %rep %0
636         %macro %1 1-2 %1
637             %2 %1
638             %%branch_instr:
639             %xdefine last_branch_adr %%branch_instr
640         %endmacro
641         %rotate 1
642     %endrep
643 %endmacro
644
645 BRANCH_INSTR jz, je, jnz, jne, jl, jle, jnl, jnle, jg, jge, jng, jnge, ja, jae, jna, jnae, jb, jbe, jnb, jnbe, jc, jnc, js, jns, jo, jno, jp, jnp
646
647 %macro TAIL_CALL 2 ; callee, is_nonadjacent
648     %if has_epilogue
649         call %1
650         RET
651     %elif %2
652         jmp %1
653     %endif
654 %endmacro
655
656 ;=============================================================================
657 ; arch-independent part
658 ;=============================================================================
659
660 %assign function_align 16
661
662 ; Begin a function.
663 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
664 ; subsequent uses of the function name automatically refer to the mangled version.
665 ; Appends cpuflags to the function name if cpuflags has been specified.
666 ; The "" empty default parameter is a workaround for nasm, which fails if SUFFIX
667 ; is empty and we call cglobal_internal with just %1 %+ SUFFIX (without %2).
668 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
669     cglobal_internal 1, %1 %+ SUFFIX, %2
670 %endmacro
671 %macro cvisible 1-2+ "" ; name, [PROLOGUE args]
672     cglobal_internal 0, %1 %+ SUFFIX, %2
673 %endmacro
674 %macro cglobal_internal 2-3+
675     %if %1
676         %xdefine %%FUNCTION_PREFIX private_prefix
677         %xdefine %%VISIBILITY hidden
678     %else
679         %xdefine %%FUNCTION_PREFIX public_prefix
680         %xdefine %%VISIBILITY
681     %endif
682     %ifndef cglobaled_%2
683         %xdefine %2 mangle(%%FUNCTION_PREFIX %+ _ %+ %2)
684         %xdefine %2.skip_prologue %2 %+ .skip_prologue
685         CAT_XDEFINE cglobaled_, %2, 1
686     %endif
687     %xdefine current_function %2
688     %if FORMAT_ELF
689         global %2:function %%VISIBILITY
690     %else
691         global %2
692     %endif
693     align function_align
694     %2:
695     RESET_MM_PERMUTATION        ; needed for x86-64, also makes disassembly somewhat nicer
696     %xdefine rstk rsp           ; copy of the original stack pointer, used when greater alignment than the known stack alignment is required
697     %assign stack_offset 0      ; stack pointer offset relative to the return address
698     %assign stack_size 0        ; amount of stack space that can be freely used inside a function
699     %assign stack_size_padded 0 ; total amount of allocated stack space, including space for callee-saved xmm registers on WIN64 and alignment padding
700     %assign xmm_regs_used 0     ; number of XMM registers requested, used for dealing with callee-saved registers on WIN64
701     %ifnidn %3, ""
702         PROLOGUE %3
703     %endif
704 %endmacro
705
706 %macro cextern 1
707     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
708     CAT_XDEFINE cglobaled_, %1, 1
709     extern %1
710 %endmacro
711
712 ; like cextern, but without the prefix
713 %macro cextern_naked 1
714     %ifdef PREFIX
715         %xdefine %1 mangle(%1)
716     %endif
717     CAT_XDEFINE cglobaled_, %1, 1
718     extern %1
719 %endmacro
720
721 %macro const 1-2+
722     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
723     %if FORMAT_ELF
724         global %1:data hidden
725     %else
726         global %1
727     %endif
728     %1: %2
729 %endmacro
730
731 ; This is needed for ELF, otherwise the GNU linker assumes the stack is executable by default.
732 %if FORMAT_ELF
733     [SECTION .note.GNU-stack noalloc noexec nowrite progbits]
734 %endif
735
736 ; cpuflags
737
738 %assign cpuflags_mmx      (1<<0)
739 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
740 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
741 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
742 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
743 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
744 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
745 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
746 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
747 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
748 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
749 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
750 %assign cpuflags_xop      (1<<12)| cpuflags_avx
751 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
752 %assign cpuflags_fma3     (1<<14)| cpuflags_avx
753 %assign cpuflags_avx2     (1<<15)| cpuflags_fma3
754
755 %assign cpuflags_cache32  (1<<16)
756 %assign cpuflags_cache64  (1<<17)
757 %assign cpuflags_slowctz  (1<<18)
758 %assign cpuflags_lzcnt    (1<<19)
759 %assign cpuflags_aligned  (1<<20) ; not a cpu feature, but a function variant
760 %assign cpuflags_atom     (1<<21)
761 %assign cpuflags_bmi1     (1<<22)|cpuflags_lzcnt
762 %assign cpuflags_bmi2     (1<<23)|cpuflags_bmi1
763
764 ; Returns a boolean value expressing whether or not the specified cpuflag is enabled.
765 %define    cpuflag(x) (((((cpuflags & (cpuflags_ %+ x)) ^ (cpuflags_ %+ x)) - 1) >> 31) & 1)
766 %define notcpuflag(x) (cpuflag(x) ^ 1)
767
768 ; Takes an arbitrary number of cpuflags from the above list.
769 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
770 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
771 %macro INIT_CPUFLAGS 0-*
772     %xdefine SUFFIX
773     %undef cpuname
774     %assign cpuflags 0
775
776     %if %0 >= 1
777         %rep %0
778             %ifdef cpuname
779                 %xdefine cpuname cpuname %+ _%1
780             %else
781                 %xdefine cpuname %1
782             %endif
783             %assign cpuflags cpuflags | cpuflags_%1
784             %rotate 1
785         %endrep
786         %xdefine SUFFIX _ %+ cpuname
787
788         %if cpuflag(avx)
789             %assign avx_enabled 1
790         %endif
791         %if (mmsize == 16 && notcpuflag(sse2)) || (mmsize == 32 && notcpuflag(avx2))
792             %define mova movaps
793             %define movu movups
794             %define movnta movntps
795         %endif
796         %if cpuflag(aligned)
797             %define movu mova
798         %elif cpuflag(sse3) && notcpuflag(ssse3)
799             %define movu lddqu
800         %endif
801     %endif
802
803     %if ARCH_X86_64 || cpuflag(sse2)
804         %ifdef __NASM_VER__
805             ALIGNMODE k8
806         %else
807             CPU amdnop
808         %endif
809     %else
810         %ifdef __NASM_VER__
811             ALIGNMODE nop
812         %else
813             CPU basicnop
814         %endif
815     %endif
816 %endmacro
817
818 ; Merge mmx and sse*
819 ; m# is a simd register of the currently selected size
820 ; xm# is the corresponding xmm register if mmsize >= 16, otherwise the same as m#
821 ; ym# is the corresponding ymm register if mmsize >= 32, otherwise the same as m#
822 ; (All 3 remain in sync through SWAP.)
823
824 %macro CAT_XDEFINE 3
825     %xdefine %1%2 %3
826 %endmacro
827
828 %macro CAT_UNDEF 2
829     %undef %1%2
830 %endmacro
831
832 %macro INIT_MMX 0-1+
833     %assign avx_enabled 0
834     %define RESET_MM_PERMUTATION INIT_MMX %1
835     %define mmsize 8
836     %define num_mmregs 8
837     %define mova movq
838     %define movu movq
839     %define movh movd
840     %define movnta movntq
841     %assign %%i 0
842     %rep 8
843     CAT_XDEFINE m, %%i, mm %+ %%i
844     CAT_XDEFINE nnmm, %%i, %%i
845     %assign %%i %%i+1
846     %endrep
847     %rep 8
848     CAT_UNDEF m, %%i
849     CAT_UNDEF nnmm, %%i
850     %assign %%i %%i+1
851     %endrep
852     INIT_CPUFLAGS %1
853 %endmacro
854
855 %macro INIT_XMM 0-1+
856     %assign avx_enabled 0
857     %define RESET_MM_PERMUTATION INIT_XMM %1
858     %define mmsize 16
859     %define num_mmregs 8
860     %if ARCH_X86_64
861     %define num_mmregs 16
862     %endif
863     %define mova movdqa
864     %define movu movdqu
865     %define movh movq
866     %define movnta movntdq
867     %assign %%i 0
868     %rep num_mmregs
869     CAT_XDEFINE m, %%i, xmm %+ %%i
870     CAT_XDEFINE nnxmm, %%i, %%i
871     %assign %%i %%i+1
872     %endrep
873     INIT_CPUFLAGS %1
874 %endmacro
875
876 %macro INIT_YMM 0-1+
877     %assign avx_enabled 1
878     %define RESET_MM_PERMUTATION INIT_YMM %1
879     %define mmsize 32
880     %define num_mmregs 8
881     %if ARCH_X86_64
882     %define num_mmregs 16
883     %endif
884     %define mova movdqa
885     %define movu movdqu
886     %undef movh
887     %define movnta movntdq
888     %assign %%i 0
889     %rep num_mmregs
890     CAT_XDEFINE m, %%i, ymm %+ %%i
891     CAT_XDEFINE nnymm, %%i, %%i
892     %assign %%i %%i+1
893     %endrep
894     INIT_CPUFLAGS %1
895 %endmacro
896
897 INIT_XMM
898
899 %macro DECLARE_MMCAST 1
900     %define  mmmm%1   mm%1
901     %define  mmxmm%1  mm%1
902     %define  mmymm%1  mm%1
903     %define xmmmm%1   mm%1
904     %define xmmxmm%1 xmm%1
905     %define xmmymm%1 xmm%1
906     %define ymmmm%1   mm%1
907     %define ymmxmm%1 xmm%1
908     %define ymmymm%1 ymm%1
909     %define xm%1 xmm %+ m%1
910     %define ym%1 ymm %+ m%1
911 %endmacro
912
913 %assign i 0
914 %rep 16
915     DECLARE_MMCAST i
916 %assign i i+1
917 %endrep
918
919 ; I often want to use macros that permute their arguments. e.g. there's no
920 ; efficient way to implement butterfly or transpose or dct without swapping some
921 ; arguments.
922 ;
923 ; I would like to not have to manually keep track of the permutations:
924 ; If I insert a permutation in the middle of a function, it should automatically
925 ; change everything that follows. For more complex macros I may also have multiple
926 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
927 ;
928 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
929 ; permutes its arguments. It's equivalent to exchanging the contents of the
930 ; registers, except that this way you exchange the register names instead, so it
931 ; doesn't cost any cycles.
932
933 %macro PERMUTE 2-* ; takes a list of pairs to swap
934 %rep %0/2
935     %xdefine %%tmp%2 m%2
936     %rotate 2
937 %endrep
938 %rep %0/2
939     %xdefine m%1 %%tmp%2
940     CAT_XDEFINE nn, m%1, %1
941     %rotate 2
942 %endrep
943 %endmacro
944
945 %macro SWAP 2+ ; swaps a single chain (sometimes more concise than pairs)
946 %ifnum %1 ; SWAP 0, 1, ...
947     SWAP_INTERNAL_NUM %1, %2
948 %else ; SWAP m0, m1, ...
949     SWAP_INTERNAL_NAME %1, %2
950 %endif
951 %endmacro
952
953 %macro SWAP_INTERNAL_NUM 2-*
954     %rep %0-1
955         %xdefine %%tmp m%1
956         %xdefine m%1 m%2
957         %xdefine m%2 %%tmp
958         CAT_XDEFINE nn, m%1, %1
959         CAT_XDEFINE nn, m%2, %2
960     %rotate 1
961     %endrep
962 %endmacro
963
964 %macro SWAP_INTERNAL_NAME 2-*
965     %xdefine %%args nn %+ %1
966     %rep %0-1
967         %xdefine %%args %%args, nn %+ %2
968     %rotate 1
969     %endrep
970     SWAP_INTERNAL_NUM %%args
971 %endmacro
972
973 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
974 ; calls to that function will automatically load the permutation, so values can
975 ; be returned in mmregs.
976 %macro SAVE_MM_PERMUTATION 0-1
977     %if %0
978         %xdefine %%f %1_m
979     %else
980         %xdefine %%f current_function %+ _m
981     %endif
982     %assign %%i 0
983     %rep num_mmregs
984         CAT_XDEFINE %%f, %%i, m %+ %%i
985     %assign %%i %%i+1
986     %endrep
987 %endmacro
988
989 %macro LOAD_MM_PERMUTATION 1 ; name to load from
990     %ifdef %1_m0
991         %assign %%i 0
992         %rep num_mmregs
993             CAT_XDEFINE m, %%i, %1_m %+ %%i
994             CAT_XDEFINE nn, m %+ %%i, %%i
995         %assign %%i %%i+1
996         %endrep
997     %endif
998 %endmacro
999
1000 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
1001 %macro call 1
1002     call_internal %1 %+ SUFFIX, %1
1003 %endmacro
1004 %macro call_internal 2
1005     %xdefine %%i %2
1006     %ifndef cglobaled_%2
1007         %ifdef cglobaled_%1
1008             %xdefine %%i %1
1009         %endif
1010     %endif
1011     call %%i
1012     LOAD_MM_PERMUTATION %%i
1013 %endmacro
1014
1015 ; Substitutions that reduce instruction size but are functionally equivalent
1016 %macro add 2
1017     %ifnum %2
1018         %if %2==128
1019             sub %1, -128
1020         %else
1021             add %1, %2
1022         %endif
1023     %else
1024         add %1, %2
1025     %endif
1026 %endmacro
1027
1028 %macro sub 2
1029     %ifnum %2
1030         %if %2==128
1031             add %1, -128
1032         %else
1033             sub %1, %2
1034         %endif
1035     %else
1036         sub %1, %2
1037     %endif
1038 %endmacro
1039
1040 ;=============================================================================
1041 ; AVX abstraction layer
1042 ;=============================================================================
1043
1044 %assign i 0
1045 %rep 16
1046     %if i < 8
1047         CAT_XDEFINE sizeofmm, i, 8
1048     %endif
1049     CAT_XDEFINE sizeofxmm, i, 16
1050     CAT_XDEFINE sizeofymm, i, 32
1051 %assign i i+1
1052 %endrep
1053 %undef i
1054
1055 %macro CHECK_AVX_INSTR_EMU 3-*
1056     %xdefine %%opcode %1
1057     %xdefine %%dst %2
1058     %rep %0-2
1059         %ifidn %%dst, %3
1060             %error non-avx emulation of ``%%opcode'' is not supported
1061         %endif
1062         %rotate 1
1063     %endrep
1064 %endmacro
1065
1066 ;%1 == instruction
1067 ;%2 == minimal instruction set
1068 ;%3 == 1 if float, 0 if int
1069 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1070 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1071 ;%6+: operands
1072 %macro RUN_AVX_INSTR 6-9+
1073     %ifnum sizeof%7
1074         %assign __sizeofreg sizeof%7
1075     %elifnum sizeof%6
1076         %assign __sizeofreg sizeof%6
1077     %else
1078         %assign __sizeofreg mmsize
1079     %endif
1080     %assign __emulate_avx 0
1081     %if avx_enabled && __sizeofreg >= 16
1082         %xdefine __instr v%1
1083     %else
1084         %xdefine __instr %1
1085         %if %0 >= 8+%4
1086             %assign __emulate_avx 1
1087         %endif
1088     %endif
1089     %ifnidn %2, fnord
1090         %ifdef cpuname
1091             %if notcpuflag(%2)
1092                 %error use of ``%1'' %2 instruction in cpuname function: current_function
1093             %elif cpuflags_%2 < cpuflags_sse && notcpuflag(sse2) && __sizeofreg > 8
1094                 %error use of ``%1'' sse2 instruction in cpuname function: current_function
1095             %endif
1096         %endif
1097     %endif
1098
1099     %if __emulate_avx
1100         %xdefine __src1 %7
1101         %xdefine __src2 %8
1102         %ifnidn %6, %7
1103             %if %0 >= 9
1104                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8, %9}, %6, %8, %9
1105             %else
1106                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8}, %6, %8
1107             %endif
1108             %if %5 && %4 == 0
1109                 %ifnid %8
1110                     ; 3-operand AVX instructions with a memory arg can only have it in src2,
1111                     ; whereas SSE emulation prefers to have it in src1 (i.e. the mov).
1112                     ; So, if the instruction is commutative with a memory arg, swap them.
1113                     %xdefine __src1 %8
1114                     %xdefine __src2 %7
1115                 %endif
1116             %endif
1117             %if __sizeofreg == 8
1118                 MOVQ %6, __src1
1119             %elif %3
1120                 MOVAPS %6, __src1
1121             %else
1122                 MOVDQA %6, __src1
1123             %endif
1124         %endif
1125         %if %0 >= 9
1126             %1 %6, __src2, %9
1127         %else
1128             %1 %6, __src2
1129         %endif
1130     %elif %0 >= 9
1131         __instr %6, %7, %8, %9
1132     %elif %0 == 8
1133         __instr %6, %7, %8
1134     %elif %0 == 7
1135         __instr %6, %7
1136     %else
1137         __instr %6
1138     %endif
1139 %endmacro
1140
1141 ;%1 == instruction
1142 ;%2 == minimal instruction set
1143 ;%3 == 1 if float, 0 if int
1144 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1145 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1146 %macro AVX_INSTR 1-5 fnord, 0, 1, 0
1147     %macro %1 1-10 fnord, fnord, fnord, fnord, %1, %2, %3, %4, %5
1148         %ifidn %2, fnord
1149             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1
1150         %elifidn %3, fnord
1151             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2
1152         %elifidn %4, fnord
1153             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3
1154         %elifidn %5, fnord
1155             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4
1156         %else
1157             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4, %5
1158         %endif
1159     %endmacro
1160 %endmacro
1161
1162 ; Instructions with both VEX and non-VEX encodings
1163 ; Non-destructive instructions are written without parameters
1164 AVX_INSTR addpd, sse2, 1, 0, 1
1165 AVX_INSTR addps, sse, 1, 0, 1
1166 AVX_INSTR addsd, sse2, 1, 0, 1
1167 AVX_INSTR addss, sse, 1, 0, 1
1168 AVX_INSTR addsubpd, sse3, 1, 0, 0
1169 AVX_INSTR addsubps, sse3, 1, 0, 0
1170 AVX_INSTR aesdec, fnord, 0, 0, 0
1171 AVX_INSTR aesdeclast, fnord, 0, 0, 0
1172 AVX_INSTR aesenc, fnord, 0, 0, 0
1173 AVX_INSTR aesenclast, fnord, 0, 0, 0
1174 AVX_INSTR aesimc
1175 AVX_INSTR aeskeygenassist
1176 AVX_INSTR andnpd, sse2, 1, 0, 0
1177 AVX_INSTR andnps, sse, 1, 0, 0
1178 AVX_INSTR andpd, sse2, 1, 0, 1
1179 AVX_INSTR andps, sse, 1, 0, 1
1180 AVX_INSTR blendpd, sse4, 1, 0, 0
1181 AVX_INSTR blendps, sse4, 1, 0, 0
1182 AVX_INSTR blendvpd, sse4, 1, 0, 0
1183 AVX_INSTR blendvps, sse4, 1, 0, 0
1184 AVX_INSTR cmppd, sse2, 1, 1, 0
1185 AVX_INSTR cmpps, sse, 1, 1, 0
1186 AVX_INSTR cmpsd, sse2, 1, 1, 0
1187 AVX_INSTR cmpss, sse, 1, 1, 0
1188 AVX_INSTR comisd, sse2
1189 AVX_INSTR comiss, sse
1190 AVX_INSTR cvtdq2pd, sse2
1191 AVX_INSTR cvtdq2ps, sse2
1192 AVX_INSTR cvtpd2dq, sse2
1193 AVX_INSTR cvtpd2ps, sse2
1194 AVX_INSTR cvtps2dq, sse2
1195 AVX_INSTR cvtps2pd, sse2
1196 AVX_INSTR cvtsd2si, sse2
1197 AVX_INSTR cvtsd2ss, sse2
1198 AVX_INSTR cvtsi2sd, sse2
1199 AVX_INSTR cvtsi2ss, sse
1200 AVX_INSTR cvtss2sd, sse2
1201 AVX_INSTR cvtss2si, sse
1202 AVX_INSTR cvttpd2dq, sse2
1203 AVX_INSTR cvttps2dq, sse2
1204 AVX_INSTR cvttsd2si, sse2
1205 AVX_INSTR cvttss2si, sse
1206 AVX_INSTR divpd, sse2, 1, 0, 0
1207 AVX_INSTR divps, sse, 1, 0, 0
1208 AVX_INSTR divsd, sse2, 1, 0, 0
1209 AVX_INSTR divss, sse, 1, 0, 0
1210 AVX_INSTR dppd, sse4, 1, 1, 0
1211 AVX_INSTR dpps, sse4, 1, 1, 0
1212 AVX_INSTR extractps, sse4
1213 AVX_INSTR haddpd, sse3, 1, 0, 0
1214 AVX_INSTR haddps, sse3, 1, 0, 0
1215 AVX_INSTR hsubpd, sse3, 1, 0, 0
1216 AVX_INSTR hsubps, sse3, 1, 0, 0
1217 AVX_INSTR insertps, sse4, 1, 1, 0
1218 AVX_INSTR lddqu, sse3
1219 AVX_INSTR ldmxcsr, sse
1220 AVX_INSTR maskmovdqu, sse2
1221 AVX_INSTR maxpd, sse2, 1, 0, 1
1222 AVX_INSTR maxps, sse, 1, 0, 1
1223 AVX_INSTR maxsd, sse2, 1, 0, 1
1224 AVX_INSTR maxss, sse, 1, 0, 1
1225 AVX_INSTR minpd, sse2, 1, 0, 1
1226 AVX_INSTR minps, sse, 1, 0, 1
1227 AVX_INSTR minsd, sse2, 1, 0, 1
1228 AVX_INSTR minss, sse, 1, 0, 1
1229 AVX_INSTR movapd, sse2
1230 AVX_INSTR movaps, sse
1231 AVX_INSTR movd, mmx
1232 AVX_INSTR movddup, sse3
1233 AVX_INSTR movdqa, sse2
1234 AVX_INSTR movdqu, sse2
1235 AVX_INSTR movhlps, sse, 1, 0, 0
1236 AVX_INSTR movhpd, sse2, 1, 0, 0
1237 AVX_INSTR movhps, sse, 1, 0, 0
1238 AVX_INSTR movlhps, sse, 1, 0, 0
1239 AVX_INSTR movlpd, sse2, 1, 0, 0
1240 AVX_INSTR movlps, sse, 1, 0, 0
1241 AVX_INSTR movmskpd, sse2
1242 AVX_INSTR movmskps, sse
1243 AVX_INSTR movntdq, sse2
1244 AVX_INSTR movntdqa, sse4
1245 AVX_INSTR movntpd, sse2
1246 AVX_INSTR movntps, sse
1247 AVX_INSTR movq, mmx
1248 AVX_INSTR movsd, sse2, 1, 0, 0
1249 AVX_INSTR movshdup, sse3
1250 AVX_INSTR movsldup, sse3
1251 AVX_INSTR movss, sse, 1, 0, 0
1252 AVX_INSTR movupd, sse2
1253 AVX_INSTR movups, sse
1254 AVX_INSTR mpsadbw, sse4
1255 AVX_INSTR mulpd, sse2, 1, 0, 1
1256 AVX_INSTR mulps, sse, 1, 0, 1
1257 AVX_INSTR mulsd, sse2, 1, 0, 1
1258 AVX_INSTR mulss, sse, 1, 0, 1
1259 AVX_INSTR orpd, sse2, 1, 0, 1
1260 AVX_INSTR orps, sse, 1, 0, 1
1261 AVX_INSTR pabsb, ssse3
1262 AVX_INSTR pabsd, ssse3
1263 AVX_INSTR pabsw, ssse3
1264 AVX_INSTR packsswb, mmx, 0, 0, 0
1265 AVX_INSTR packssdw, mmx, 0, 0, 0
1266 AVX_INSTR packuswb, mmx, 0, 0, 0
1267 AVX_INSTR packusdw, sse4, 0, 0, 0
1268 AVX_INSTR paddb, mmx, 0, 0, 1
1269 AVX_INSTR paddw, mmx, 0, 0, 1
1270 AVX_INSTR paddd, mmx, 0, 0, 1
1271 AVX_INSTR paddq, sse2, 0, 0, 1
1272 AVX_INSTR paddsb, mmx, 0, 0, 1
1273 AVX_INSTR paddsw, mmx, 0, 0, 1
1274 AVX_INSTR paddusb, mmx, 0, 0, 1
1275 AVX_INSTR paddusw, mmx, 0, 0, 1
1276 AVX_INSTR palignr, ssse3
1277 AVX_INSTR pand, mmx, 0, 0, 1
1278 AVX_INSTR pandn, mmx, 0, 0, 0
1279 AVX_INSTR pavgb, mmx2, 0, 0, 1
1280 AVX_INSTR pavgw, mmx2, 0, 0, 1
1281 AVX_INSTR pblendvb, sse4, 0, 0, 0
1282 AVX_INSTR pblendw, sse4
1283 AVX_INSTR pclmulqdq
1284 AVX_INSTR pcmpestri, sse42
1285 AVX_INSTR pcmpestrm, sse42
1286 AVX_INSTR pcmpistri, sse42
1287 AVX_INSTR pcmpistrm, sse42
1288 AVX_INSTR pcmpeqb, mmx, 0, 0, 1
1289 AVX_INSTR pcmpeqw, mmx, 0, 0, 1
1290 AVX_INSTR pcmpeqd, mmx, 0, 0, 1
1291 AVX_INSTR pcmpeqq, sse4, 0, 0, 1
1292 AVX_INSTR pcmpgtb, mmx, 0, 0, 0
1293 AVX_INSTR pcmpgtw, mmx, 0, 0, 0
1294 AVX_INSTR pcmpgtd, mmx, 0, 0, 0
1295 AVX_INSTR pcmpgtq, sse42, 0, 0, 0
1296 AVX_INSTR pextrb, sse4
1297 AVX_INSTR pextrd, sse4
1298 AVX_INSTR pextrq, sse4
1299 AVX_INSTR pextrw, mmx2
1300 AVX_INSTR phaddw, ssse3, 0, 0, 0
1301 AVX_INSTR phaddd, ssse3, 0, 0, 0
1302 AVX_INSTR phaddsw, ssse3, 0, 0, 0
1303 AVX_INSTR phminposuw, sse4
1304 AVX_INSTR phsubw, ssse3, 0, 0, 0
1305 AVX_INSTR phsubd, ssse3, 0, 0, 0
1306 AVX_INSTR phsubsw, ssse3, 0, 0, 0
1307 AVX_INSTR pinsrb, sse4
1308 AVX_INSTR pinsrd, sse4
1309 AVX_INSTR pinsrq, sse4
1310 AVX_INSTR pinsrw, mmx2
1311 AVX_INSTR pmaddwd, mmx, 0, 0, 1
1312 AVX_INSTR pmaddubsw, ssse3, 0, 0, 0
1313 AVX_INSTR pmaxsb, sse4, 0, 0, 1
1314 AVX_INSTR pmaxsw, mmx2, 0, 0, 1
1315 AVX_INSTR pmaxsd, sse4, 0, 0, 1
1316 AVX_INSTR pmaxub, mmx2, 0, 0, 1
1317 AVX_INSTR pmaxuw, sse4, 0, 0, 1
1318 AVX_INSTR pmaxud, sse4, 0, 0, 1
1319 AVX_INSTR pminsb, sse4, 0, 0, 1
1320 AVX_INSTR pminsw, mmx2, 0, 0, 1
1321 AVX_INSTR pminsd, sse4, 0, 0, 1
1322 AVX_INSTR pminub, mmx2, 0, 0, 1
1323 AVX_INSTR pminuw, sse4, 0, 0, 1
1324 AVX_INSTR pminud, sse4, 0, 0, 1
1325 AVX_INSTR pmovmskb, mmx2
1326 AVX_INSTR pmovsxbw, sse4
1327 AVX_INSTR pmovsxbd, sse4
1328 AVX_INSTR pmovsxbq, sse4
1329 AVX_INSTR pmovsxwd, sse4
1330 AVX_INSTR pmovsxwq, sse4
1331 AVX_INSTR pmovsxdq, sse4
1332 AVX_INSTR pmovzxbw, sse4
1333 AVX_INSTR pmovzxbd, sse4
1334 AVX_INSTR pmovzxbq, sse4
1335 AVX_INSTR pmovzxwd, sse4
1336 AVX_INSTR pmovzxwq, sse4
1337 AVX_INSTR pmovzxdq, sse4
1338 AVX_INSTR pmuldq, sse4, 0, 0, 1
1339 AVX_INSTR pmulhrsw, ssse3, 0, 0, 1
1340 AVX_INSTR pmulhuw, mmx2, 0, 0, 1
1341 AVX_INSTR pmulhw, mmx, 0, 0, 1
1342 AVX_INSTR pmullw, mmx, 0, 0, 1
1343 AVX_INSTR pmulld, sse4, 0, 0, 1
1344 AVX_INSTR pmuludq, sse2, 0, 0, 1
1345 AVX_INSTR por, mmx, 0, 0, 1
1346 AVX_INSTR psadbw, mmx2, 0, 0, 1
1347 AVX_INSTR pshufb, ssse3, 0, 0, 0
1348 AVX_INSTR pshufd, sse2
1349 AVX_INSTR pshufhw, sse2
1350 AVX_INSTR pshuflw, sse2
1351 AVX_INSTR psignb, ssse3, 0, 0, 0
1352 AVX_INSTR psignw, ssse3, 0, 0, 0
1353 AVX_INSTR psignd, ssse3, 0, 0, 0
1354 AVX_INSTR psllw, mmx, 0, 0, 0
1355 AVX_INSTR pslld, mmx, 0, 0, 0
1356 AVX_INSTR psllq, mmx, 0, 0, 0
1357 AVX_INSTR pslldq, sse2, 0, 0, 0
1358 AVX_INSTR psraw, mmx, 0, 0, 0
1359 AVX_INSTR psrad, mmx, 0, 0, 0
1360 AVX_INSTR psrlw, mmx, 0, 0, 0
1361 AVX_INSTR psrld, mmx, 0, 0, 0
1362 AVX_INSTR psrlq, mmx, 0, 0, 0
1363 AVX_INSTR psrldq, sse2, 0, 0, 0
1364 AVX_INSTR psubb, mmx, 0, 0, 0
1365 AVX_INSTR psubw, mmx, 0, 0, 0
1366 AVX_INSTR psubd, mmx, 0, 0, 0
1367 AVX_INSTR psubq, sse2, 0, 0, 0
1368 AVX_INSTR psubsb, mmx, 0, 0, 0
1369 AVX_INSTR psubsw, mmx, 0, 0, 0
1370 AVX_INSTR psubusb, mmx, 0, 0, 0
1371 AVX_INSTR psubusw, mmx, 0, 0, 0
1372 AVX_INSTR ptest, sse4
1373 AVX_INSTR punpckhbw, mmx, 0, 0, 0
1374 AVX_INSTR punpckhwd, mmx, 0, 0, 0
1375 AVX_INSTR punpckhdq, mmx, 0, 0, 0
1376 AVX_INSTR punpckhqdq, sse2, 0, 0, 0
1377 AVX_INSTR punpcklbw, mmx, 0, 0, 0
1378 AVX_INSTR punpcklwd, mmx, 0, 0, 0
1379 AVX_INSTR punpckldq, mmx, 0, 0, 0
1380 AVX_INSTR punpcklqdq, sse2, 0, 0, 0
1381 AVX_INSTR pxor, mmx, 0, 0, 1
1382 AVX_INSTR rcpps, sse, 1, 0, 0
1383 AVX_INSTR rcpss, sse, 1, 0, 0
1384 AVX_INSTR roundpd, sse4
1385 AVX_INSTR roundps, sse4
1386 AVX_INSTR roundsd, sse4
1387 AVX_INSTR roundss, sse4
1388 AVX_INSTR rsqrtps, sse, 1, 0, 0
1389 AVX_INSTR rsqrtss, sse, 1, 0, 0
1390 AVX_INSTR shufpd, sse2, 1, 1, 0
1391 AVX_INSTR shufps, sse, 1, 1, 0
1392 AVX_INSTR sqrtpd, sse2, 1, 0, 0
1393 AVX_INSTR sqrtps, sse, 1, 0, 0
1394 AVX_INSTR sqrtsd, sse2, 1, 0, 0
1395 AVX_INSTR sqrtss, sse, 1, 0, 0
1396 AVX_INSTR stmxcsr, sse
1397 AVX_INSTR subpd, sse2, 1, 0, 0
1398 AVX_INSTR subps, sse, 1, 0, 0
1399 AVX_INSTR subsd, sse2, 1, 0, 0
1400 AVX_INSTR subss, sse, 1, 0, 0
1401 AVX_INSTR ucomisd, sse2
1402 AVX_INSTR ucomiss, sse
1403 AVX_INSTR unpckhpd, sse2, 1, 0, 0
1404 AVX_INSTR unpckhps, sse, 1, 0, 0
1405 AVX_INSTR unpcklpd, sse2, 1, 0, 0
1406 AVX_INSTR unpcklps, sse, 1, 0, 0
1407 AVX_INSTR xorpd, sse2, 1, 0, 1
1408 AVX_INSTR xorps, sse, 1, 0, 1
1409
1410 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1411 AVX_INSTR pfadd, 3dnow, 1, 0, 1
1412 AVX_INSTR pfsub, 3dnow, 1, 0, 0
1413 AVX_INSTR pfmul, 3dnow, 1, 0, 1
1414
1415 ; base-4 constants for shuffles
1416 %assign i 0
1417 %rep 256
1418     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1419     %if j < 10
1420         CAT_XDEFINE q000, j, i
1421     %elif j < 100
1422         CAT_XDEFINE q00, j, i
1423     %elif j < 1000
1424         CAT_XDEFINE q0, j, i
1425     %else
1426         CAT_XDEFINE q, j, i
1427     %endif
1428 %assign i i+1
1429 %endrep
1430 %undef i
1431 %undef j
1432
1433 %macro FMA_INSTR 3
1434     %macro %1 4-7 %1, %2, %3
1435         %if cpuflag(xop)
1436             v%5 %1, %2, %3, %4
1437         %elifnidn %1, %4
1438             %6 %1, %2, %3
1439             %7 %1, %4
1440         %else
1441             %error non-xop emulation of ``%5 %1, %2, %3, %4'' is not supported
1442         %endif
1443     %endmacro
1444 %endmacro
1445
1446 FMA_INSTR  pmacsww,  pmullw, paddw
1447 FMA_INSTR  pmacsdd,  pmulld, paddd ; sse4 emulation
1448 FMA_INSTR pmacsdql,  pmuldq, paddq ; sse4 emulation
1449 FMA_INSTR pmadcswd, pmaddwd, paddd
1450
1451 ; convert FMA4 to FMA3 if possible
1452 %macro FMA4_INSTR 4
1453     %macro %1 4-8 %1, %2, %3, %4
1454         %if cpuflag(fma4)
1455             v%5 %1, %2, %3, %4
1456         %elifidn %1, %2
1457             v%6 %1, %4, %3 ; %1 = %1 * %3 + %4
1458         %elifidn %1, %3
1459             v%7 %1, %2, %4 ; %1 = %2 * %1 + %4
1460         %elifidn %1, %4
1461             v%8 %1, %2, %3 ; %1 = %2 * %3 + %1
1462         %else
1463             %error fma3 emulation of ``%5 %1, %2, %3, %4'' is not supported
1464         %endif
1465     %endmacro
1466 %endmacro
1467
1468 FMA4_INSTR fmaddpd, fmadd132pd, fmadd213pd, fmadd231pd
1469 FMA4_INSTR fmaddps, fmadd132ps, fmadd213ps, fmadd231ps
1470 FMA4_INSTR fmaddsd, fmadd132sd, fmadd213sd, fmadd231sd
1471 FMA4_INSTR fmaddss, fmadd132ss, fmadd213ss, fmadd231ss
1472
1473 FMA4_INSTR fmaddsubpd, fmaddsub132pd, fmaddsub213pd, fmaddsub231pd
1474 FMA4_INSTR fmaddsubps, fmaddsub132ps, fmaddsub213ps, fmaddsub231ps
1475 FMA4_INSTR fmsubaddpd, fmsubadd132pd, fmsubadd213pd, fmsubadd231pd
1476 FMA4_INSTR fmsubaddps, fmsubadd132ps, fmsubadd213ps, fmsubadd231ps
1477
1478 FMA4_INSTR fmsubpd, fmsub132pd, fmsub213pd, fmsub231pd
1479 FMA4_INSTR fmsubps, fmsub132ps, fmsub213ps, fmsub231ps
1480 FMA4_INSTR fmsubsd, fmsub132sd, fmsub213sd, fmsub231sd
1481 FMA4_INSTR fmsubss, fmsub132ss, fmsub213ss, fmsub231ss
1482
1483 FMA4_INSTR fnmaddpd, fnmadd132pd, fnmadd213pd, fnmadd231pd
1484 FMA4_INSTR fnmaddps, fnmadd132ps, fnmadd213ps, fnmadd231ps
1485 FMA4_INSTR fnmaddsd, fnmadd132sd, fnmadd213sd, fnmadd231sd
1486 FMA4_INSTR fnmaddss, fnmadd132ss, fnmadd213ss, fnmadd231ss
1487
1488 FMA4_INSTR fnmsubpd, fnmsub132pd, fnmsub213pd, fnmsub231pd
1489 FMA4_INSTR fnmsubps, fnmsub132ps, fnmsub213ps, fnmsub231ps
1490 FMA4_INSTR fnmsubsd, fnmsub132sd, fnmsub213sd, fnmsub231sd
1491 FMA4_INSTR fnmsubss, fnmsub132ss, fnmsub213ss, fnmsub231ss
1492
1493 ; workaround: vpbroadcastq is broken in x86_32 due to a yasm bug (fixed in 1.3.0)
1494 %ifdef __YASM_VER__
1495     %if __YASM_VERSION_ID__ < 0x01030000 && ARCH_X86_64 == 0
1496         %macro vpbroadcastq 2
1497             %if sizeof%1 == 16
1498                 movddup %1, %2
1499             %else
1500                 vbroadcastsd %1, %2
1501             %endif
1502         %endmacro
1503     %endif
1504 %endif