x86inc: Use more consistent indentation
[x264/x264-sandbox.git] / common / x86 / x86inc.asm
1 ;*****************************************************************************
2 ;* x86inc.asm: x264asm abstraction layer
3 ;*****************************************************************************
4 ;* Copyright (C) 2005-2015 x264 project
5 ;*
6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
8 ;*          Fiona Glaser <fiona@x264.com>
9 ;*          Henrik Gramner <henrik@gramner.com>
10 ;*
11 ;* Permission to use, copy, modify, and/or distribute this software for any
12 ;* purpose with or without fee is hereby granted, provided that the above
13 ;* copyright notice and this permission notice appear in all copies.
14 ;*
15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
22 ;*****************************************************************************
23
24 ; This is a header file for the x264ASM assembly language, which uses
25 ; NASM/YASM syntax combined with a large number of macros to provide easy
26 ; abstraction between different calling conventions (x86_32, win64, linux64).
27 ; It also has various other useful features to simplify writing the kind of
28 ; DSP functions that are most often used in x264.
29
30 ; Unlike the rest of x264, this file is available under an ISC license, as it
31 ; has significant usefulness outside of x264 and we want it to be available
32 ; to the largest audience possible.  Of course, if you modify it for your own
33 ; purposes to add a new feature, we strongly encourage contributing a patch
34 ; as this feature might be useful for others as well.  Send patches or ideas
35 ; to x264-devel@videolan.org .
36
37 %ifndef private_prefix
38     %define private_prefix x264
39 %endif
40
41 %ifndef public_prefix
42     %define public_prefix private_prefix
43 %endif
44
45 %ifndef STACK_ALIGNMENT
46     %if ARCH_X86_64
47         %define STACK_ALIGNMENT 16
48     %else
49         %define STACK_ALIGNMENT 4
50     %endif
51 %endif
52
53 %define WIN64  0
54 %define UNIX64 0
55 %if ARCH_X86_64
56     %ifidn __OUTPUT_FORMAT__,win32
57         %define WIN64  1
58     %elifidn __OUTPUT_FORMAT__,win64
59         %define WIN64  1
60     %elifidn __OUTPUT_FORMAT__,x64
61         %define WIN64  1
62     %else
63         %define UNIX64 1
64     %endif
65 %endif
66
67 %define FORMAT_ELF 0
68 %ifidn __OUTPUT_FORMAT__,elf
69     %define FORMAT_ELF 1
70 %elifidn __OUTPUT_FORMAT__,elf32
71     %define FORMAT_ELF 1
72 %elifidn __OUTPUT_FORMAT__,elf64
73     %define FORMAT_ELF 1
74 %endif
75
76 %ifdef PREFIX
77     %define mangle(x) _ %+ x
78 %else
79     %define mangle(x) x
80 %endif
81
82 %macro SECTION_RODATA 0-1 16
83     SECTION .rodata align=%1
84 %endmacro
85
86 %if WIN64
87     %define PIC
88 %elif ARCH_X86_64 == 0
89 ; x86_32 doesn't require PIC.
90 ; Some distros prefer shared objects to be PIC, but nothing breaks if
91 ; the code contains a few textrels, so we'll skip that complexity.
92     %undef PIC
93 %endif
94 %ifdef PIC
95     default rel
96 %endif
97
98 %ifdef __NASM_VER__
99     %use smartalign
100 %endif
101
102 ; Macros to eliminate most code duplication between x86_32 and x86_64:
103 ; Currently this works only for leaf functions which load all their arguments
104 ; into registers at the start, and make no other use of the stack. Luckily that
105 ; covers most of x264's asm.
106
107 ; PROLOGUE:
108 ; %1 = number of arguments. loads them from stack if needed.
109 ; %2 = number of registers used. pushes callee-saved regs if needed.
110 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
111 ; %4 = (optional) stack size to be allocated. The stack will be aligned before
112 ;      allocating the specified stack size. If the required stack alignment is
113 ;      larger than the known stack alignment the stack will be manually aligned
114 ;      and an extra register will be allocated to hold the original stack
115 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
116 ;      register as stack pointer, request a negative stack size.
117 ; %4+/%5+ = list of names to define to registers
118 ; PROLOGUE can also be invoked by adding the same options to cglobal
119
120 ; e.g.
121 ; cglobal foo, 2,3,7,0x40, dst, src, tmp
122 ; declares a function (foo) that automatically loads two arguments (dst and
123 ; src) into registers, uses one additional register (tmp) plus 7 vector
124 ; registers (m0-m6) and allocates 0x40 bytes of stack space.
125
126 ; TODO Some functions can use some args directly from the stack. If they're the
127 ; last args then you can just not declare them, but if they're in the middle
128 ; we need more flexible macro.
129
130 ; RET:
131 ; Pops anything that was pushed by PROLOGUE, and returns.
132
133 ; REP_RET:
134 ; Use this instead of RET if it's a branch target.
135
136 ; registers:
137 ; rN and rNq are the native-size register holding function argument N
138 ; rNd, rNw, rNb are dword, word, and byte size
139 ; rNh is the high 8 bits of the word size
140 ; rNm is the original location of arg N (a register or on the stack), dword
141 ; rNmp is native size
142
143 %macro DECLARE_REG 2-3
144     %define r%1q %2
145     %define r%1d %2d
146     %define r%1w %2w
147     %define r%1b %2b
148     %define r%1h %2h
149     %define %2q %2
150     %if %0 == 2
151         %define r%1m  %2d
152         %define r%1mp %2
153     %elif ARCH_X86_64 ; memory
154         %define r%1m [rstk + stack_offset + %3]
155         %define r%1mp qword r %+ %1 %+ m
156     %else
157         %define r%1m [rstk + stack_offset + %3]
158         %define r%1mp dword r %+ %1 %+ m
159     %endif
160     %define r%1  %2
161 %endmacro
162
163 %macro DECLARE_REG_SIZE 3
164     %define r%1q r%1
165     %define e%1q r%1
166     %define r%1d e%1
167     %define e%1d e%1
168     %define r%1w %1
169     %define e%1w %1
170     %define r%1h %3
171     %define e%1h %3
172     %define r%1b %2
173     %define e%1b %2
174     %if ARCH_X86_64 == 0
175         %define r%1 e%1
176     %endif
177 %endmacro
178
179 DECLARE_REG_SIZE ax, al, ah
180 DECLARE_REG_SIZE bx, bl, bh
181 DECLARE_REG_SIZE cx, cl, ch
182 DECLARE_REG_SIZE dx, dl, dh
183 DECLARE_REG_SIZE si, sil, null
184 DECLARE_REG_SIZE di, dil, null
185 DECLARE_REG_SIZE bp, bpl, null
186
187 ; t# defines for when per-arch register allocation is more complex than just function arguments
188
189 %macro DECLARE_REG_TMP 1-*
190     %assign %%i 0
191     %rep %0
192         CAT_XDEFINE t, %%i, r%1
193         %assign %%i %%i+1
194         %rotate 1
195     %endrep
196 %endmacro
197
198 %macro DECLARE_REG_TMP_SIZE 0-*
199     %rep %0
200         %define t%1q t%1 %+ q
201         %define t%1d t%1 %+ d
202         %define t%1w t%1 %+ w
203         %define t%1h t%1 %+ h
204         %define t%1b t%1 %+ b
205         %rotate 1
206     %endrep
207 %endmacro
208
209 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
210
211 %if ARCH_X86_64
212     %define gprsize 8
213 %else
214     %define gprsize 4
215 %endif
216
217 %macro PUSH 1
218     push %1
219     %ifidn rstk, rsp
220         %assign stack_offset stack_offset+gprsize
221     %endif
222 %endmacro
223
224 %macro POP 1
225     pop %1
226     %ifidn rstk, rsp
227         %assign stack_offset stack_offset-gprsize
228     %endif
229 %endmacro
230
231 %macro PUSH_IF_USED 1-*
232     %rep %0
233         %if %1 < regs_used
234             PUSH r%1
235         %endif
236         %rotate 1
237     %endrep
238 %endmacro
239
240 %macro POP_IF_USED 1-*
241     %rep %0
242         %if %1 < regs_used
243             pop r%1
244         %endif
245         %rotate 1
246     %endrep
247 %endmacro
248
249 %macro LOAD_IF_USED 1-*
250     %rep %0
251         %if %1 < num_args
252             mov r%1, r %+ %1 %+ mp
253         %endif
254         %rotate 1
255     %endrep
256 %endmacro
257
258 %macro SUB 2
259     sub %1, %2
260     %ifidn %1, rstk
261         %assign stack_offset stack_offset+(%2)
262     %endif
263 %endmacro
264
265 %macro ADD 2
266     add %1, %2
267     %ifidn %1, rstk
268         %assign stack_offset stack_offset-(%2)
269     %endif
270 %endmacro
271
272 %macro movifnidn 2
273     %ifnidn %1, %2
274         mov %1, %2
275     %endif
276 %endmacro
277
278 %macro movsxdifnidn 2
279     %ifnidn %1, %2
280         movsxd %1, %2
281     %endif
282 %endmacro
283
284 %macro ASSERT 1
285     %if (%1) == 0
286         %error assertion ``%1'' failed
287     %endif
288 %endmacro
289
290 %macro DEFINE_ARGS 0-*
291     %ifdef n_arg_names
292         %assign %%i 0
293         %rep n_arg_names
294             CAT_UNDEF arg_name %+ %%i, q
295             CAT_UNDEF arg_name %+ %%i, d
296             CAT_UNDEF arg_name %+ %%i, w
297             CAT_UNDEF arg_name %+ %%i, h
298             CAT_UNDEF arg_name %+ %%i, b
299             CAT_UNDEF arg_name %+ %%i, m
300             CAT_UNDEF arg_name %+ %%i, mp
301             CAT_UNDEF arg_name, %%i
302             %assign %%i %%i+1
303         %endrep
304     %endif
305
306     %xdefine %%stack_offset stack_offset
307     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
308     %assign %%i 0
309     %rep %0
310         %xdefine %1q r %+ %%i %+ q
311         %xdefine %1d r %+ %%i %+ d
312         %xdefine %1w r %+ %%i %+ w
313         %xdefine %1h r %+ %%i %+ h
314         %xdefine %1b r %+ %%i %+ b
315         %xdefine %1m r %+ %%i %+ m
316         %xdefine %1mp r %+ %%i %+ mp
317         CAT_XDEFINE arg_name, %%i, %1
318         %assign %%i %%i+1
319         %rotate 1
320     %endrep
321     %xdefine stack_offset %%stack_offset
322     %assign n_arg_names %0
323 %endmacro
324
325 %define required_stack_alignment ((mmsize + 15) & ~15)
326
327 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
328     %ifnum %1
329         %if %1 != 0
330             %assign %%pad 0
331             %assign stack_size %1
332             %if stack_size < 0
333                 %assign stack_size -stack_size
334             %endif
335             %if WIN64
336                 %assign %%pad %%pad + 32 ; shadow space
337                 %if mmsize != 8
338                     %assign xmm_regs_used %2
339                     %if xmm_regs_used > 8
340                         %assign %%pad %%pad + (xmm_regs_used-8)*16 ; callee-saved xmm registers
341                     %endif
342                 %endif
343             %endif
344             %if required_stack_alignment <= STACK_ALIGNMENT
345                 ; maintain the current stack alignment
346                 %assign stack_size_padded stack_size + %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
347                 SUB rsp, stack_size_padded
348             %else
349                 %assign %%reg_num (regs_used - 1)
350                 %xdefine rstk r %+ %%reg_num
351                 ; align stack, and save original stack location directly above
352                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
353                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
354                 ; rsp, [rsp+stack_size_padded])
355                 %if %1 < 0 ; need to store rsp on stack
356                     %xdefine rstkm [rsp + stack_size + %%pad]
357                     %assign %%pad %%pad + gprsize
358                 %else ; can keep rsp in rstk during whole function
359                     %xdefine rstkm rstk
360                 %endif
361                 %assign stack_size_padded stack_size + ((%%pad + required_stack_alignment-1) & ~(required_stack_alignment-1))
362                 mov rstk, rsp
363                 and rsp, ~(required_stack_alignment-1)
364                 sub rsp, stack_size_padded
365                 movifnidn rstkm, rstk
366             %endif
367             WIN64_PUSH_XMM
368         %endif
369     %endif
370 %endmacro
371
372 %macro SETUP_STACK_POINTER 1
373     %ifnum %1
374         %if %1 != 0 && required_stack_alignment > STACK_ALIGNMENT
375             %if %1 > 0
376                 %assign regs_used (regs_used + 1)
377             %endif
378             %if ARCH_X86_64 && regs_used < 5 + UNIX64 * 3
379                 ; Ensure that we don't clobber any registers containing arguments
380                 %assign regs_used 5 + UNIX64 * 3
381             %endif
382         %endif
383     %endif
384 %endmacro
385
386 %macro DEFINE_ARGS_INTERNAL 3+
387     %ifnum %2
388         DEFINE_ARGS %3
389     %elif %1 == 4
390         DEFINE_ARGS %2
391     %elif %1 > 4
392         DEFINE_ARGS %2, %3
393     %endif
394 %endmacro
395
396 %if WIN64 ; Windows x64 ;=================================================
397
398 DECLARE_REG 0,  rcx
399 DECLARE_REG 1,  rdx
400 DECLARE_REG 2,  R8
401 DECLARE_REG 3,  R9
402 DECLARE_REG 4,  R10, 40
403 DECLARE_REG 5,  R11, 48
404 DECLARE_REG 6,  rax, 56
405 DECLARE_REG 7,  rdi, 64
406 DECLARE_REG 8,  rsi, 72
407 DECLARE_REG 9,  rbx, 80
408 DECLARE_REG 10, rbp, 88
409 DECLARE_REG 11, R12, 96
410 DECLARE_REG 12, R13, 104
411 DECLARE_REG 13, R14, 112
412 DECLARE_REG 14, R15, 120
413
414 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
415     %assign num_args %1
416     %assign regs_used %2
417     ASSERT regs_used >= num_args
418     SETUP_STACK_POINTER %4
419     ASSERT regs_used <= 15
420     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
421     ALLOC_STACK %4, %3
422     %if mmsize != 8 && stack_size == 0
423         WIN64_SPILL_XMM %3
424     %endif
425     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
426     DEFINE_ARGS_INTERNAL %0, %4, %5
427 %endmacro
428
429 %macro WIN64_PUSH_XMM 0
430     ; Use the shadow space to store XMM6 and XMM7, the rest needs stack space allocated.
431     %if xmm_regs_used > 6
432         movaps [rstk + stack_offset +  8], xmm6
433     %endif
434     %if xmm_regs_used > 7
435         movaps [rstk + stack_offset + 24], xmm7
436     %endif
437     %if xmm_regs_used > 8
438         %assign %%i 8
439         %rep xmm_regs_used-8
440             movaps [rsp + (%%i-8)*16 + stack_size + 32], xmm %+ %%i
441             %assign %%i %%i+1
442         %endrep
443     %endif
444 %endmacro
445
446 %macro WIN64_SPILL_XMM 1
447     %assign xmm_regs_used %1
448     ASSERT xmm_regs_used <= 16
449     %if xmm_regs_used > 8
450         ; Allocate stack space for callee-saved xmm registers plus shadow space and align the stack.
451         %assign %%pad (xmm_regs_used-8)*16 + 32
452         %assign stack_size_padded %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
453         SUB rsp, stack_size_padded
454     %endif
455     WIN64_PUSH_XMM
456 %endmacro
457
458 %macro WIN64_RESTORE_XMM_INTERNAL 1
459     %assign %%pad_size 0
460     %if xmm_regs_used > 8
461         %assign %%i xmm_regs_used
462         %rep xmm_regs_used-8
463             %assign %%i %%i-1
464             movaps xmm %+ %%i, [%1 + (%%i-8)*16 + stack_size + 32]
465         %endrep
466     %endif
467     %if stack_size_padded > 0
468         %if stack_size > 0 && required_stack_alignment > STACK_ALIGNMENT
469             mov rsp, rstkm
470         %else
471             add %1, stack_size_padded
472             %assign %%pad_size stack_size_padded
473         %endif
474     %endif
475     %if xmm_regs_used > 7
476         movaps xmm7, [%1 + stack_offset - %%pad_size + 24]
477     %endif
478     %if xmm_regs_used > 6
479         movaps xmm6, [%1 + stack_offset - %%pad_size +  8]
480     %endif
481 %endmacro
482
483 %macro WIN64_RESTORE_XMM 1
484     WIN64_RESTORE_XMM_INTERNAL %1
485     %assign stack_offset (stack_offset-stack_size_padded)
486     %assign xmm_regs_used 0
487 %endmacro
488
489 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
490
491 %macro RET 0
492     WIN64_RESTORE_XMM_INTERNAL rsp
493     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
494     %if mmsize == 32
495         vzeroupper
496     %endif
497     AUTO_REP_RET
498 %endmacro
499
500 %elif ARCH_X86_64 ; *nix x64 ;=============================================
501
502 DECLARE_REG 0,  rdi
503 DECLARE_REG 1,  rsi
504 DECLARE_REG 2,  rdx
505 DECLARE_REG 3,  rcx
506 DECLARE_REG 4,  R8
507 DECLARE_REG 5,  R9
508 DECLARE_REG 6,  rax, 8
509 DECLARE_REG 7,  R10, 16
510 DECLARE_REG 8,  R11, 24
511 DECLARE_REG 9,  rbx, 32
512 DECLARE_REG 10, rbp, 40
513 DECLARE_REG 11, R12, 48
514 DECLARE_REG 12, R13, 56
515 DECLARE_REG 13, R14, 64
516 DECLARE_REG 14, R15, 72
517
518 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
519     %assign num_args %1
520     %assign regs_used %2
521     ASSERT regs_used >= num_args
522     SETUP_STACK_POINTER %4
523     ASSERT regs_used <= 15
524     PUSH_IF_USED 9, 10, 11, 12, 13, 14
525     ALLOC_STACK %4
526     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
527     DEFINE_ARGS_INTERNAL %0, %4, %5
528 %endmacro
529
530 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
531
532 %macro RET 0
533     %if stack_size_padded > 0
534         %if required_stack_alignment > STACK_ALIGNMENT
535             mov rsp, rstkm
536         %else
537             add rsp, stack_size_padded
538         %endif
539     %endif
540     POP_IF_USED 14, 13, 12, 11, 10, 9
541     %if mmsize == 32
542         vzeroupper
543     %endif
544     AUTO_REP_RET
545 %endmacro
546
547 %else ; X86_32 ;==============================================================
548
549 DECLARE_REG 0, eax, 4
550 DECLARE_REG 1, ecx, 8
551 DECLARE_REG 2, edx, 12
552 DECLARE_REG 3, ebx, 16
553 DECLARE_REG 4, esi, 20
554 DECLARE_REG 5, edi, 24
555 DECLARE_REG 6, ebp, 28
556 %define rsp esp
557
558 %macro DECLARE_ARG 1-*
559     %rep %0
560         %define r%1m [rstk + stack_offset + 4*%1 + 4]
561         %define r%1mp dword r%1m
562         %rotate 1
563     %endrep
564 %endmacro
565
566 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
567
568 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
569     %assign num_args %1
570     %assign regs_used %2
571     ASSERT regs_used >= num_args
572     %if num_args > 7
573         %assign num_args 7
574     %endif
575     %if regs_used > 7
576         %assign regs_used 7
577     %endif
578     SETUP_STACK_POINTER %4
579     ASSERT regs_used <= 7
580     PUSH_IF_USED 3, 4, 5, 6
581     ALLOC_STACK %4
582     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
583     DEFINE_ARGS_INTERNAL %0, %4, %5
584 %endmacro
585
586 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
587
588 %macro RET 0
589     %if stack_size_padded > 0
590         %if required_stack_alignment > STACK_ALIGNMENT
591             mov rsp, rstkm
592         %else
593             add rsp, stack_size_padded
594         %endif
595     %endif
596     POP_IF_USED 6, 5, 4, 3
597     %if mmsize == 32
598         vzeroupper
599     %endif
600     AUTO_REP_RET
601 %endmacro
602
603 %endif ;======================================================================
604
605 %if WIN64 == 0
606     %macro WIN64_SPILL_XMM 1
607     %endmacro
608     %macro WIN64_RESTORE_XMM 1
609     %endmacro
610     %macro WIN64_PUSH_XMM 0
611     %endmacro
612 %endif
613
614 ; On AMD cpus <=K10, an ordinary ret is slow if it immediately follows either
615 ; a branch or a branch target. So switch to a 2-byte form of ret in that case.
616 ; We can automatically detect "follows a branch", but not a branch target.
617 ; (SSSE3 is a sufficient condition to know that your cpu doesn't have this problem.)
618 %macro REP_RET 0
619     %if has_epilogue
620         RET
621     %else
622         rep ret
623     %endif
624 %endmacro
625
626 %define last_branch_adr $$
627 %macro AUTO_REP_RET 0
628     %ifndef cpuflags
629         times ((last_branch_adr-$)>>31)+1 rep ; times 1 iff $ != last_branch_adr.
630     %elif notcpuflag(ssse3)
631         times ((last_branch_adr-$)>>31)+1 rep
632     %endif
633     ret
634 %endmacro
635
636 %macro BRANCH_INSTR 0-*
637     %rep %0
638         %macro %1 1-2 %1
639             %2 %1
640             %%branch_instr:
641             %xdefine last_branch_adr %%branch_instr
642         %endmacro
643         %rotate 1
644     %endrep
645 %endmacro
646
647 BRANCH_INSTR jz, je, jnz, jne, jl, jle, jnl, jnle, jg, jge, jng, jnge, ja, jae, jna, jnae, jb, jbe, jnb, jnbe, jc, jnc, js, jns, jo, jno, jp, jnp
648
649 %macro TAIL_CALL 2 ; callee, is_nonadjacent
650     %if has_epilogue
651         call %1
652         RET
653     %elif %2
654         jmp %1
655     %endif
656 %endmacro
657
658 ;=============================================================================
659 ; arch-independent part
660 ;=============================================================================
661
662 %assign function_align 16
663
664 ; Begin a function.
665 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
666 ; subsequent uses of the function name automatically refer to the mangled version.
667 ; Appends cpuflags to the function name if cpuflags has been specified.
668 ; The "" empty default parameter is a workaround for nasm, which fails if SUFFIX
669 ; is empty and we call cglobal_internal with just %1 %+ SUFFIX (without %2).
670 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
671     cglobal_internal 1, %1 %+ SUFFIX, %2
672 %endmacro
673 %macro cvisible 1-2+ "" ; name, [PROLOGUE args]
674     cglobal_internal 0, %1 %+ SUFFIX, %2
675 %endmacro
676 %macro cglobal_internal 2-3+
677     %if %1
678         %xdefine %%FUNCTION_PREFIX private_prefix
679         %xdefine %%VISIBILITY hidden
680     %else
681         %xdefine %%FUNCTION_PREFIX public_prefix
682         %xdefine %%VISIBILITY
683     %endif
684     %ifndef cglobaled_%2
685         %xdefine %2 mangle(%%FUNCTION_PREFIX %+ _ %+ %2)
686         %xdefine %2.skip_prologue %2 %+ .skip_prologue
687         CAT_XDEFINE cglobaled_, %2, 1
688     %endif
689     %xdefine current_function %2
690     %if FORMAT_ELF
691         global %2:function %%VISIBILITY
692     %else
693         global %2
694     %endif
695     align function_align
696     %2:
697     RESET_MM_PERMUTATION        ; needed for x86-64, also makes disassembly somewhat nicer
698     %xdefine rstk rsp           ; copy of the original stack pointer, used when greater alignment than the known stack alignment is required
699     %assign stack_offset 0      ; stack pointer offset relative to the return address
700     %assign stack_size 0        ; amount of stack space that can be freely used inside a function
701     %assign stack_size_padded 0 ; total amount of allocated stack space, including space for callee-saved xmm registers on WIN64 and alignment padding
702     %assign xmm_regs_used 0     ; number of XMM registers requested, used for dealing with callee-saved registers on WIN64
703     %ifnidn %3, ""
704         PROLOGUE %3
705     %endif
706 %endmacro
707
708 %macro cextern 1
709     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
710     CAT_XDEFINE cglobaled_, %1, 1
711     extern %1
712 %endmacro
713
714 ; like cextern, but without the prefix
715 %macro cextern_naked 1
716     %ifdef PREFIX
717         %xdefine %1 mangle(%1)
718     %endif
719     CAT_XDEFINE cglobaled_, %1, 1
720     extern %1
721 %endmacro
722
723 %macro const 1-2+
724     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
725     %if FORMAT_ELF
726         global %1:data hidden
727     %else
728         global %1
729     %endif
730     %1: %2
731 %endmacro
732
733 ; This is needed for ELF, otherwise the GNU linker assumes the stack is executable by default.
734 %if FORMAT_ELF
735     [SECTION .note.GNU-stack noalloc noexec nowrite progbits]
736 %endif
737
738 ; cpuflags
739
740 %assign cpuflags_mmx      (1<<0)
741 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
742 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
743 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
744 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
745 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
746 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
747 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
748 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
749 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
750 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
751 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
752 %assign cpuflags_xop      (1<<12)| cpuflags_avx
753 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
754 %assign cpuflags_fma3     (1<<14)| cpuflags_avx
755 %assign cpuflags_avx2     (1<<15)| cpuflags_fma3
756
757 %assign cpuflags_cache32  (1<<16)
758 %assign cpuflags_cache64  (1<<17)
759 %assign cpuflags_slowctz  (1<<18)
760 %assign cpuflags_lzcnt    (1<<19)
761 %assign cpuflags_aligned  (1<<20) ; not a cpu feature, but a function variant
762 %assign cpuflags_atom     (1<<21)
763 %assign cpuflags_bmi1     (1<<22)|cpuflags_lzcnt
764 %assign cpuflags_bmi2     (1<<23)|cpuflags_bmi1
765
766 ; Returns a boolean value expressing whether or not the specified cpuflag is enabled.
767 %define    cpuflag(x) (((((cpuflags & (cpuflags_ %+ x)) ^ (cpuflags_ %+ x)) - 1) >> 31) & 1)
768 %define notcpuflag(x) (cpuflag(x) ^ 1)
769
770 ; Takes an arbitrary number of cpuflags from the above list.
771 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
772 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
773 %macro INIT_CPUFLAGS 0-*
774     %xdefine SUFFIX
775     %undef cpuname
776     %assign cpuflags 0
777
778     %if %0 >= 1
779         %rep %0
780             %ifdef cpuname
781                 %xdefine cpuname cpuname %+ _%1
782             %else
783                 %xdefine cpuname %1
784             %endif
785             %assign cpuflags cpuflags | cpuflags_%1
786             %rotate 1
787         %endrep
788         %xdefine SUFFIX _ %+ cpuname
789
790         %if cpuflag(avx)
791             %assign avx_enabled 1
792         %endif
793         %if (mmsize == 16 && notcpuflag(sse2)) || (mmsize == 32 && notcpuflag(avx2))
794             %define mova movaps
795             %define movu movups
796             %define movnta movntps
797         %endif
798         %if cpuflag(aligned)
799             %define movu mova
800         %elif cpuflag(sse3) && notcpuflag(ssse3)
801             %define movu lddqu
802         %endif
803     %endif
804
805     %if ARCH_X86_64 || cpuflag(sse2)
806         %ifdef __NASM_VER__
807             ALIGNMODE k8
808         %else
809             CPU amdnop
810         %endif
811     %else
812         %ifdef __NASM_VER__
813             ALIGNMODE nop
814         %else
815             CPU basicnop
816         %endif
817     %endif
818 %endmacro
819
820 ; Merge mmx and sse*
821 ; m# is a simd register of the currently selected size
822 ; xm# is the corresponding xmm register if mmsize >= 16, otherwise the same as m#
823 ; ym# is the corresponding ymm register if mmsize >= 32, otherwise the same as m#
824 ; (All 3 remain in sync through SWAP.)
825
826 %macro CAT_XDEFINE 3
827     %xdefine %1%2 %3
828 %endmacro
829
830 %macro CAT_UNDEF 2
831     %undef %1%2
832 %endmacro
833
834 %macro INIT_MMX 0-1+
835     %assign avx_enabled 0
836     %define RESET_MM_PERMUTATION INIT_MMX %1
837     %define mmsize 8
838     %define num_mmregs 8
839     %define mova movq
840     %define movu movq
841     %define movh movd
842     %define movnta movntq
843     %assign %%i 0
844     %rep 8
845         CAT_XDEFINE m, %%i, mm %+ %%i
846         CAT_XDEFINE nnmm, %%i, %%i
847         %assign %%i %%i+1
848     %endrep
849     %rep 8
850         CAT_UNDEF m, %%i
851         CAT_UNDEF nnmm, %%i
852         %assign %%i %%i+1
853     %endrep
854     INIT_CPUFLAGS %1
855 %endmacro
856
857 %macro INIT_XMM 0-1+
858     %assign avx_enabled 0
859     %define RESET_MM_PERMUTATION INIT_XMM %1
860     %define mmsize 16
861     %define num_mmregs 8
862     %if ARCH_X86_64
863         %define num_mmregs 16
864     %endif
865     %define mova movdqa
866     %define movu movdqu
867     %define movh movq
868     %define movnta movntdq
869     %assign %%i 0
870     %rep num_mmregs
871         CAT_XDEFINE m, %%i, xmm %+ %%i
872         CAT_XDEFINE nnxmm, %%i, %%i
873         %assign %%i %%i+1
874     %endrep
875     INIT_CPUFLAGS %1
876 %endmacro
877
878 %macro INIT_YMM 0-1+
879     %assign avx_enabled 1
880     %define RESET_MM_PERMUTATION INIT_YMM %1
881     %define mmsize 32
882     %define num_mmregs 8
883     %if ARCH_X86_64
884         %define num_mmregs 16
885     %endif
886     %define mova movdqa
887     %define movu movdqu
888     %undef movh
889     %define movnta movntdq
890     %assign %%i 0
891     %rep num_mmregs
892         CAT_XDEFINE m, %%i, ymm %+ %%i
893         CAT_XDEFINE nnymm, %%i, %%i
894         %assign %%i %%i+1
895     %endrep
896     INIT_CPUFLAGS %1
897 %endmacro
898
899 INIT_XMM
900
901 %macro DECLARE_MMCAST 1
902     %define  mmmm%1   mm%1
903     %define  mmxmm%1  mm%1
904     %define  mmymm%1  mm%1
905     %define xmmmm%1   mm%1
906     %define xmmxmm%1 xmm%1
907     %define xmmymm%1 xmm%1
908     %define ymmmm%1   mm%1
909     %define ymmxmm%1 xmm%1
910     %define ymmymm%1 ymm%1
911     %define xm%1 xmm %+ m%1
912     %define ym%1 ymm %+ m%1
913 %endmacro
914
915 %assign i 0
916 %rep 16
917     DECLARE_MMCAST i
918     %assign i i+1
919 %endrep
920
921 ; I often want to use macros that permute their arguments. e.g. there's no
922 ; efficient way to implement butterfly or transpose or dct without swapping some
923 ; arguments.
924 ;
925 ; I would like to not have to manually keep track of the permutations:
926 ; If I insert a permutation in the middle of a function, it should automatically
927 ; change everything that follows. For more complex macros I may also have multiple
928 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
929 ;
930 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
931 ; permutes its arguments. It's equivalent to exchanging the contents of the
932 ; registers, except that this way you exchange the register names instead, so it
933 ; doesn't cost any cycles.
934
935 %macro PERMUTE 2-* ; takes a list of pairs to swap
936     %rep %0/2
937         %xdefine %%tmp%2 m%2
938         %rotate 2
939     %endrep
940     %rep %0/2
941         %xdefine m%1 %%tmp%2
942         CAT_XDEFINE nn, m%1, %1
943         %rotate 2
944     %endrep
945 %endmacro
946
947 %macro SWAP 2+ ; swaps a single chain (sometimes more concise than pairs)
948     %ifnum %1 ; SWAP 0, 1, ...
949         SWAP_INTERNAL_NUM %1, %2
950     %else ; SWAP m0, m1, ...
951         SWAP_INTERNAL_NAME %1, %2
952     %endif
953 %endmacro
954
955 %macro SWAP_INTERNAL_NUM 2-*
956     %rep %0-1
957         %xdefine %%tmp m%1
958         %xdefine m%1 m%2
959         %xdefine m%2 %%tmp
960         CAT_XDEFINE nn, m%1, %1
961         CAT_XDEFINE nn, m%2, %2
962         %rotate 1
963     %endrep
964 %endmacro
965
966 %macro SWAP_INTERNAL_NAME 2-*
967     %xdefine %%args nn %+ %1
968     %rep %0-1
969         %xdefine %%args %%args, nn %+ %2
970         %rotate 1
971     %endrep
972     SWAP_INTERNAL_NUM %%args
973 %endmacro
974
975 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
976 ; calls to that function will automatically load the permutation, so values can
977 ; be returned in mmregs.
978 %macro SAVE_MM_PERMUTATION 0-1
979     %if %0
980         %xdefine %%f %1_m
981     %else
982         %xdefine %%f current_function %+ _m
983     %endif
984     %assign %%i 0
985     %rep num_mmregs
986         CAT_XDEFINE %%f, %%i, m %+ %%i
987         %assign %%i %%i+1
988     %endrep
989 %endmacro
990
991 %macro LOAD_MM_PERMUTATION 1 ; name to load from
992     %ifdef %1_m0
993         %assign %%i 0
994         %rep num_mmregs
995             CAT_XDEFINE m, %%i, %1_m %+ %%i
996             CAT_XDEFINE nn, m %+ %%i, %%i
997             %assign %%i %%i+1
998         %endrep
999     %endif
1000 %endmacro
1001
1002 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
1003 %macro call 1
1004     call_internal %1 %+ SUFFIX, %1
1005 %endmacro
1006 %macro call_internal 2
1007     %xdefine %%i %2
1008     %ifndef cglobaled_%2
1009         %ifdef cglobaled_%1
1010             %xdefine %%i %1
1011         %endif
1012     %endif
1013     call %%i
1014     LOAD_MM_PERMUTATION %%i
1015 %endmacro
1016
1017 ; Substitutions that reduce instruction size but are functionally equivalent
1018 %macro add 2
1019     %ifnum %2
1020         %if %2==128
1021             sub %1, -128
1022         %else
1023             add %1, %2
1024         %endif
1025     %else
1026         add %1, %2
1027     %endif
1028 %endmacro
1029
1030 %macro sub 2
1031     %ifnum %2
1032         %if %2==128
1033             add %1, -128
1034         %else
1035             sub %1, %2
1036         %endif
1037     %else
1038         sub %1, %2
1039     %endif
1040 %endmacro
1041
1042 ;=============================================================================
1043 ; AVX abstraction layer
1044 ;=============================================================================
1045
1046 %assign i 0
1047 %rep 16
1048     %if i < 8
1049         CAT_XDEFINE sizeofmm, i, 8
1050     %endif
1051     CAT_XDEFINE sizeofxmm, i, 16
1052     CAT_XDEFINE sizeofymm, i, 32
1053     %assign i i+1
1054 %endrep
1055 %undef i
1056
1057 %macro CHECK_AVX_INSTR_EMU 3-*
1058     %xdefine %%opcode %1
1059     %xdefine %%dst %2
1060     %rep %0-2
1061         %ifidn %%dst, %3
1062             %error non-avx emulation of ``%%opcode'' is not supported
1063         %endif
1064         %rotate 1
1065     %endrep
1066 %endmacro
1067
1068 ;%1 == instruction
1069 ;%2 == minimal instruction set
1070 ;%3 == 1 if float, 0 if int
1071 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1072 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1073 ;%6+: operands
1074 %macro RUN_AVX_INSTR 6-9+
1075     %ifnum sizeof%7
1076         %assign __sizeofreg sizeof%7
1077     %elifnum sizeof%6
1078         %assign __sizeofreg sizeof%6
1079     %else
1080         %assign __sizeofreg mmsize
1081     %endif
1082     %assign __emulate_avx 0
1083     %if avx_enabled && __sizeofreg >= 16
1084         %xdefine __instr v%1
1085     %else
1086         %xdefine __instr %1
1087         %if %0 >= 8+%4
1088             %assign __emulate_avx 1
1089         %endif
1090     %endif
1091     %ifnidn %2, fnord
1092         %ifdef cpuname
1093             %if notcpuflag(%2)
1094                 %error use of ``%1'' %2 instruction in cpuname function: current_function
1095             %elif cpuflags_%2 < cpuflags_sse && notcpuflag(sse2) && __sizeofreg > 8
1096                 %error use of ``%1'' sse2 instruction in cpuname function: current_function
1097             %endif
1098         %endif
1099     %endif
1100
1101     %if __emulate_avx
1102         %xdefine __src1 %7
1103         %xdefine __src2 %8
1104         %ifnidn %6, %7
1105             %if %0 >= 9
1106                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8, %9}, %6, %8, %9
1107             %else
1108                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8}, %6, %8
1109             %endif
1110             %if %5 && %4 == 0
1111                 %ifnid %8
1112                     ; 3-operand AVX instructions with a memory arg can only have it in src2,
1113                     ; whereas SSE emulation prefers to have it in src1 (i.e. the mov).
1114                     ; So, if the instruction is commutative with a memory arg, swap them.
1115                     %xdefine __src1 %8
1116                     %xdefine __src2 %7
1117                 %endif
1118             %endif
1119             %if __sizeofreg == 8
1120                 MOVQ %6, __src1
1121             %elif %3
1122                 MOVAPS %6, __src1
1123             %else
1124                 MOVDQA %6, __src1
1125             %endif
1126         %endif
1127         %if %0 >= 9
1128             %1 %6, __src2, %9
1129         %else
1130             %1 %6, __src2
1131         %endif
1132     %elif %0 >= 9
1133         __instr %6, %7, %8, %9
1134     %elif %0 == 8
1135         __instr %6, %7, %8
1136     %elif %0 == 7
1137         __instr %6, %7
1138     %else
1139         __instr %6
1140     %endif
1141 %endmacro
1142
1143 ;%1 == instruction
1144 ;%2 == minimal instruction set
1145 ;%3 == 1 if float, 0 if int
1146 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1147 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1148 %macro AVX_INSTR 1-5 fnord, 0, 1, 0
1149     %macro %1 1-10 fnord, fnord, fnord, fnord, %1, %2, %3, %4, %5
1150         %ifidn %2, fnord
1151             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1
1152         %elifidn %3, fnord
1153             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2
1154         %elifidn %4, fnord
1155             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3
1156         %elifidn %5, fnord
1157             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4
1158         %else
1159             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4, %5
1160         %endif
1161     %endmacro
1162 %endmacro
1163
1164 ; Instructions with both VEX and non-VEX encodings
1165 ; Non-destructive instructions are written without parameters
1166 AVX_INSTR addpd, sse2, 1, 0, 1
1167 AVX_INSTR addps, sse, 1, 0, 1
1168 AVX_INSTR addsd, sse2, 1, 0, 1
1169 AVX_INSTR addss, sse, 1, 0, 1
1170 AVX_INSTR addsubpd, sse3, 1, 0, 0
1171 AVX_INSTR addsubps, sse3, 1, 0, 0
1172 AVX_INSTR aesdec, fnord, 0, 0, 0
1173 AVX_INSTR aesdeclast, fnord, 0, 0, 0
1174 AVX_INSTR aesenc, fnord, 0, 0, 0
1175 AVX_INSTR aesenclast, fnord, 0, 0, 0
1176 AVX_INSTR aesimc
1177 AVX_INSTR aeskeygenassist
1178 AVX_INSTR andnpd, sse2, 1, 0, 0
1179 AVX_INSTR andnps, sse, 1, 0, 0
1180 AVX_INSTR andpd, sse2, 1, 0, 1
1181 AVX_INSTR andps, sse, 1, 0, 1
1182 AVX_INSTR blendpd, sse4, 1, 0, 0
1183 AVX_INSTR blendps, sse4, 1, 0, 0
1184 AVX_INSTR blendvpd, sse4, 1, 0, 0
1185 AVX_INSTR blendvps, sse4, 1, 0, 0
1186 AVX_INSTR cmppd, sse2, 1, 1, 0
1187 AVX_INSTR cmpps, sse, 1, 1, 0
1188 AVX_INSTR cmpsd, sse2, 1, 1, 0
1189 AVX_INSTR cmpss, sse, 1, 1, 0
1190 AVX_INSTR comisd, sse2
1191 AVX_INSTR comiss, sse
1192 AVX_INSTR cvtdq2pd, sse2
1193 AVX_INSTR cvtdq2ps, sse2
1194 AVX_INSTR cvtpd2dq, sse2
1195 AVX_INSTR cvtpd2ps, sse2
1196 AVX_INSTR cvtps2dq, sse2
1197 AVX_INSTR cvtps2pd, sse2
1198 AVX_INSTR cvtsd2si, sse2
1199 AVX_INSTR cvtsd2ss, sse2
1200 AVX_INSTR cvtsi2sd, sse2
1201 AVX_INSTR cvtsi2ss, sse
1202 AVX_INSTR cvtss2sd, sse2
1203 AVX_INSTR cvtss2si, sse
1204 AVX_INSTR cvttpd2dq, sse2
1205 AVX_INSTR cvttps2dq, sse2
1206 AVX_INSTR cvttsd2si, sse2
1207 AVX_INSTR cvttss2si, sse
1208 AVX_INSTR divpd, sse2, 1, 0, 0
1209 AVX_INSTR divps, sse, 1, 0, 0
1210 AVX_INSTR divsd, sse2, 1, 0, 0
1211 AVX_INSTR divss, sse, 1, 0, 0
1212 AVX_INSTR dppd, sse4, 1, 1, 0
1213 AVX_INSTR dpps, sse4, 1, 1, 0
1214 AVX_INSTR extractps, sse4
1215 AVX_INSTR haddpd, sse3, 1, 0, 0
1216 AVX_INSTR haddps, sse3, 1, 0, 0
1217 AVX_INSTR hsubpd, sse3, 1, 0, 0
1218 AVX_INSTR hsubps, sse3, 1, 0, 0
1219 AVX_INSTR insertps, sse4, 1, 1, 0
1220 AVX_INSTR lddqu, sse3
1221 AVX_INSTR ldmxcsr, sse
1222 AVX_INSTR maskmovdqu, sse2
1223 AVX_INSTR maxpd, sse2, 1, 0, 1
1224 AVX_INSTR maxps, sse, 1, 0, 1
1225 AVX_INSTR maxsd, sse2, 1, 0, 1
1226 AVX_INSTR maxss, sse, 1, 0, 1
1227 AVX_INSTR minpd, sse2, 1, 0, 1
1228 AVX_INSTR minps, sse, 1, 0, 1
1229 AVX_INSTR minsd, sse2, 1, 0, 1
1230 AVX_INSTR minss, sse, 1, 0, 1
1231 AVX_INSTR movapd, sse2
1232 AVX_INSTR movaps, sse
1233 AVX_INSTR movd, mmx
1234 AVX_INSTR movddup, sse3
1235 AVX_INSTR movdqa, sse2
1236 AVX_INSTR movdqu, sse2
1237 AVX_INSTR movhlps, sse, 1, 0, 0
1238 AVX_INSTR movhpd, sse2, 1, 0, 0
1239 AVX_INSTR movhps, sse, 1, 0, 0
1240 AVX_INSTR movlhps, sse, 1, 0, 0
1241 AVX_INSTR movlpd, sse2, 1, 0, 0
1242 AVX_INSTR movlps, sse, 1, 0, 0
1243 AVX_INSTR movmskpd, sse2
1244 AVX_INSTR movmskps, sse
1245 AVX_INSTR movntdq, sse2
1246 AVX_INSTR movntdqa, sse4
1247 AVX_INSTR movntpd, sse2
1248 AVX_INSTR movntps, sse
1249 AVX_INSTR movq, mmx
1250 AVX_INSTR movsd, sse2, 1, 0, 0
1251 AVX_INSTR movshdup, sse3
1252 AVX_INSTR movsldup, sse3
1253 AVX_INSTR movss, sse, 1, 0, 0
1254 AVX_INSTR movupd, sse2
1255 AVX_INSTR movups, sse
1256 AVX_INSTR mpsadbw, sse4
1257 AVX_INSTR mulpd, sse2, 1, 0, 1
1258 AVX_INSTR mulps, sse, 1, 0, 1
1259 AVX_INSTR mulsd, sse2, 1, 0, 1
1260 AVX_INSTR mulss, sse, 1, 0, 1
1261 AVX_INSTR orpd, sse2, 1, 0, 1
1262 AVX_INSTR orps, sse, 1, 0, 1
1263 AVX_INSTR pabsb, ssse3
1264 AVX_INSTR pabsd, ssse3
1265 AVX_INSTR pabsw, ssse3
1266 AVX_INSTR packsswb, mmx, 0, 0, 0
1267 AVX_INSTR packssdw, mmx, 0, 0, 0
1268 AVX_INSTR packuswb, mmx, 0, 0, 0
1269 AVX_INSTR packusdw, sse4, 0, 0, 0
1270 AVX_INSTR paddb, mmx, 0, 0, 1
1271 AVX_INSTR paddw, mmx, 0, 0, 1
1272 AVX_INSTR paddd, mmx, 0, 0, 1
1273 AVX_INSTR paddq, sse2, 0, 0, 1
1274 AVX_INSTR paddsb, mmx, 0, 0, 1
1275 AVX_INSTR paddsw, mmx, 0, 0, 1
1276 AVX_INSTR paddusb, mmx, 0, 0, 1
1277 AVX_INSTR paddusw, mmx, 0, 0, 1
1278 AVX_INSTR palignr, ssse3
1279 AVX_INSTR pand, mmx, 0, 0, 1
1280 AVX_INSTR pandn, mmx, 0, 0, 0
1281 AVX_INSTR pavgb, mmx2, 0, 0, 1
1282 AVX_INSTR pavgw, mmx2, 0, 0, 1
1283 AVX_INSTR pblendvb, sse4, 0, 0, 0
1284 AVX_INSTR pblendw, sse4
1285 AVX_INSTR pclmulqdq
1286 AVX_INSTR pcmpestri, sse42
1287 AVX_INSTR pcmpestrm, sse42
1288 AVX_INSTR pcmpistri, sse42
1289 AVX_INSTR pcmpistrm, sse42
1290 AVX_INSTR pcmpeqb, mmx, 0, 0, 1
1291 AVX_INSTR pcmpeqw, mmx, 0, 0, 1
1292 AVX_INSTR pcmpeqd, mmx, 0, 0, 1
1293 AVX_INSTR pcmpeqq, sse4, 0, 0, 1
1294 AVX_INSTR pcmpgtb, mmx, 0, 0, 0
1295 AVX_INSTR pcmpgtw, mmx, 0, 0, 0
1296 AVX_INSTR pcmpgtd, mmx, 0, 0, 0
1297 AVX_INSTR pcmpgtq, sse42, 0, 0, 0
1298 AVX_INSTR pextrb, sse4
1299 AVX_INSTR pextrd, sse4
1300 AVX_INSTR pextrq, sse4
1301 AVX_INSTR pextrw, mmx2
1302 AVX_INSTR phaddw, ssse3, 0, 0, 0
1303 AVX_INSTR phaddd, ssse3, 0, 0, 0
1304 AVX_INSTR phaddsw, ssse3, 0, 0, 0
1305 AVX_INSTR phminposuw, sse4
1306 AVX_INSTR phsubw, ssse3, 0, 0, 0
1307 AVX_INSTR phsubd, ssse3, 0, 0, 0
1308 AVX_INSTR phsubsw, ssse3, 0, 0, 0
1309 AVX_INSTR pinsrb, sse4
1310 AVX_INSTR pinsrd, sse4
1311 AVX_INSTR pinsrq, sse4
1312 AVX_INSTR pinsrw, mmx2
1313 AVX_INSTR pmaddwd, mmx, 0, 0, 1
1314 AVX_INSTR pmaddubsw, ssse3, 0, 0, 0
1315 AVX_INSTR pmaxsb, sse4, 0, 0, 1
1316 AVX_INSTR pmaxsw, mmx2, 0, 0, 1
1317 AVX_INSTR pmaxsd, sse4, 0, 0, 1
1318 AVX_INSTR pmaxub, mmx2, 0, 0, 1
1319 AVX_INSTR pmaxuw, sse4, 0, 0, 1
1320 AVX_INSTR pmaxud, sse4, 0, 0, 1
1321 AVX_INSTR pminsb, sse4, 0, 0, 1
1322 AVX_INSTR pminsw, mmx2, 0, 0, 1
1323 AVX_INSTR pminsd, sse4, 0, 0, 1
1324 AVX_INSTR pminub, mmx2, 0, 0, 1
1325 AVX_INSTR pminuw, sse4, 0, 0, 1
1326 AVX_INSTR pminud, sse4, 0, 0, 1
1327 AVX_INSTR pmovmskb, mmx2
1328 AVX_INSTR pmovsxbw, sse4
1329 AVX_INSTR pmovsxbd, sse4
1330 AVX_INSTR pmovsxbq, sse4
1331 AVX_INSTR pmovsxwd, sse4
1332 AVX_INSTR pmovsxwq, sse4
1333 AVX_INSTR pmovsxdq, sse4
1334 AVX_INSTR pmovzxbw, sse4
1335 AVX_INSTR pmovzxbd, sse4
1336 AVX_INSTR pmovzxbq, sse4
1337 AVX_INSTR pmovzxwd, sse4
1338 AVX_INSTR pmovzxwq, sse4
1339 AVX_INSTR pmovzxdq, sse4
1340 AVX_INSTR pmuldq, sse4, 0, 0, 1
1341 AVX_INSTR pmulhrsw, ssse3, 0, 0, 1
1342 AVX_INSTR pmulhuw, mmx2, 0, 0, 1
1343 AVX_INSTR pmulhw, mmx, 0, 0, 1
1344 AVX_INSTR pmullw, mmx, 0, 0, 1
1345 AVX_INSTR pmulld, sse4, 0, 0, 1
1346 AVX_INSTR pmuludq, sse2, 0, 0, 1
1347 AVX_INSTR por, mmx, 0, 0, 1
1348 AVX_INSTR psadbw, mmx2, 0, 0, 1
1349 AVX_INSTR pshufb, ssse3, 0, 0, 0
1350 AVX_INSTR pshufd, sse2
1351 AVX_INSTR pshufhw, sse2
1352 AVX_INSTR pshuflw, sse2
1353 AVX_INSTR psignb, ssse3, 0, 0, 0
1354 AVX_INSTR psignw, ssse3, 0, 0, 0
1355 AVX_INSTR psignd, ssse3, 0, 0, 0
1356 AVX_INSTR psllw, mmx, 0, 0, 0
1357 AVX_INSTR pslld, mmx, 0, 0, 0
1358 AVX_INSTR psllq, mmx, 0, 0, 0
1359 AVX_INSTR pslldq, sse2, 0, 0, 0
1360 AVX_INSTR psraw, mmx, 0, 0, 0
1361 AVX_INSTR psrad, mmx, 0, 0, 0
1362 AVX_INSTR psrlw, mmx, 0, 0, 0
1363 AVX_INSTR psrld, mmx, 0, 0, 0
1364 AVX_INSTR psrlq, mmx, 0, 0, 0
1365 AVX_INSTR psrldq, sse2, 0, 0, 0
1366 AVX_INSTR psubb, mmx, 0, 0, 0
1367 AVX_INSTR psubw, mmx, 0, 0, 0
1368 AVX_INSTR psubd, mmx, 0, 0, 0
1369 AVX_INSTR psubq, sse2, 0, 0, 0
1370 AVX_INSTR psubsb, mmx, 0, 0, 0
1371 AVX_INSTR psubsw, mmx, 0, 0, 0
1372 AVX_INSTR psubusb, mmx, 0, 0, 0
1373 AVX_INSTR psubusw, mmx, 0, 0, 0
1374 AVX_INSTR ptest, sse4
1375 AVX_INSTR punpckhbw, mmx, 0, 0, 0
1376 AVX_INSTR punpckhwd, mmx, 0, 0, 0
1377 AVX_INSTR punpckhdq, mmx, 0, 0, 0
1378 AVX_INSTR punpckhqdq, sse2, 0, 0, 0
1379 AVX_INSTR punpcklbw, mmx, 0, 0, 0
1380 AVX_INSTR punpcklwd, mmx, 0, 0, 0
1381 AVX_INSTR punpckldq, mmx, 0, 0, 0
1382 AVX_INSTR punpcklqdq, sse2, 0, 0, 0
1383 AVX_INSTR pxor, mmx, 0, 0, 1
1384 AVX_INSTR rcpps, sse, 1, 0, 0
1385 AVX_INSTR rcpss, sse, 1, 0, 0
1386 AVX_INSTR roundpd, sse4
1387 AVX_INSTR roundps, sse4
1388 AVX_INSTR roundsd, sse4
1389 AVX_INSTR roundss, sse4
1390 AVX_INSTR rsqrtps, sse, 1, 0, 0
1391 AVX_INSTR rsqrtss, sse, 1, 0, 0
1392 AVX_INSTR shufpd, sse2, 1, 1, 0
1393 AVX_INSTR shufps, sse, 1, 1, 0
1394 AVX_INSTR sqrtpd, sse2, 1, 0, 0
1395 AVX_INSTR sqrtps, sse, 1, 0, 0
1396 AVX_INSTR sqrtsd, sse2, 1, 0, 0
1397 AVX_INSTR sqrtss, sse, 1, 0, 0
1398 AVX_INSTR stmxcsr, sse
1399 AVX_INSTR subpd, sse2, 1, 0, 0
1400 AVX_INSTR subps, sse, 1, 0, 0
1401 AVX_INSTR subsd, sse2, 1, 0, 0
1402 AVX_INSTR subss, sse, 1, 0, 0
1403 AVX_INSTR ucomisd, sse2
1404 AVX_INSTR ucomiss, sse
1405 AVX_INSTR unpckhpd, sse2, 1, 0, 0
1406 AVX_INSTR unpckhps, sse, 1, 0, 0
1407 AVX_INSTR unpcklpd, sse2, 1, 0, 0
1408 AVX_INSTR unpcklps, sse, 1, 0, 0
1409 AVX_INSTR xorpd, sse2, 1, 0, 1
1410 AVX_INSTR xorps, sse, 1, 0, 1
1411
1412 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1413 AVX_INSTR pfadd, 3dnow, 1, 0, 1
1414 AVX_INSTR pfsub, 3dnow, 1, 0, 0
1415 AVX_INSTR pfmul, 3dnow, 1, 0, 1
1416
1417 ; base-4 constants for shuffles
1418 %assign i 0
1419 %rep 256
1420     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1421     %if j < 10
1422         CAT_XDEFINE q000, j, i
1423     %elif j < 100
1424         CAT_XDEFINE q00, j, i
1425     %elif j < 1000
1426         CAT_XDEFINE q0, j, i
1427     %else
1428         CAT_XDEFINE q, j, i
1429     %endif
1430     %assign i i+1
1431 %endrep
1432 %undef i
1433 %undef j
1434
1435 %macro FMA_INSTR 3
1436     %macro %1 4-7 %1, %2, %3
1437         %if cpuflag(xop)
1438             v%5 %1, %2, %3, %4
1439         %elifnidn %1, %4
1440             %6 %1, %2, %3
1441             %7 %1, %4
1442         %else
1443             %error non-xop emulation of ``%5 %1, %2, %3, %4'' is not supported
1444         %endif
1445     %endmacro
1446 %endmacro
1447
1448 FMA_INSTR  pmacsww,  pmullw, paddw
1449 FMA_INSTR  pmacsdd,  pmulld, paddd ; sse4 emulation
1450 FMA_INSTR pmacsdql,  pmuldq, paddq ; sse4 emulation
1451 FMA_INSTR pmadcswd, pmaddwd, paddd
1452
1453 ; Macros for consolidating FMA3 and FMA4 using 4-operand (dst, src1, src2, src3) syntax.
1454 ; FMA3 is only possible if dst is the same as one of the src registers.
1455 ; Either src2 or src3 can be a memory operand.
1456 %macro FMA4_INSTR 2-*
1457     %push fma4_instr
1458     %xdefine %$prefix %1
1459     %rep %0 - 1
1460         %macro %$prefix%2 4-6 %$prefix, %2
1461             %if notcpuflag(fma3) && notcpuflag(fma4)
1462                 %error use of ``%5%6'' fma instruction in cpuname function: current_function
1463             %elif cpuflag(fma4)
1464                 v%5%6 %1, %2, %3, %4
1465             %elifidn %1, %2
1466                 ; If %3 or %4 is a memory operand it needs to be encoded as the last operand.
1467                 %ifid %3
1468                     v%{5}213%6 %2, %3, %4
1469                 %else
1470                     v%{5}132%6 %2, %4, %3
1471                 %endif
1472             %elifidn %1, %3
1473                 v%{5}213%6 %3, %2, %4
1474             %elifidn %1, %4
1475                 v%{5}231%6 %4, %2, %3
1476             %else
1477                 %error fma3 emulation of ``%5%6 %1, %2, %3, %4'' is not supported
1478             %endif
1479         %endmacro
1480         %rotate 1
1481     %endrep
1482     %pop
1483 %endmacro
1484
1485 FMA4_INSTR fmadd,    pd, ps, sd, ss
1486 FMA4_INSTR fmaddsub, pd, ps
1487 FMA4_INSTR fmsub,    pd, ps, sd, ss
1488 FMA4_INSTR fmsubadd, pd, ps
1489 FMA4_INSTR fnmadd,   pd, ps, sd, ss
1490 FMA4_INSTR fnmsub,   pd, ps, sd, ss
1491
1492 ; workaround: vpbroadcastq is broken in x86_32 due to a yasm bug (fixed in 1.3.0)
1493 %ifdef __YASM_VER__
1494     %if __YASM_VERSION_ID__ < 0x01030000 && ARCH_X86_64 == 0
1495         %macro vpbroadcastq 2
1496             %if sizeof%1 == 16
1497                 movddup %1, %2
1498             %else
1499                 vbroadcastsd %1, %2
1500             %endif
1501         %endmacro
1502     %endif
1503 %endif