asm cosmetics: base-4 constants for shuffles
[x262.git] / common / x86 / x86inc.asm
1 ;*****************************************************************************
2 ;* x86inc.asm: x264asm abstraction layer
3 ;*****************************************************************************
4 ;* Copyright (C) 2005-2011 x264 project
5 ;*
6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
8 ;*          Jason Garrett-Glaser <darkshikari@gmail.com>
9 ;*
10 ;* Permission to use, copy, modify, and/or distribute this software for any
11 ;* purpose with or without fee is hereby granted, provided that the above
12 ;* copyright notice and this permission notice appear in all copies.
13 ;*
14 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
15 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
16 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
17 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
18 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
19 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
20 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
21 ;*****************************************************************************
22
23 ; This is a header file for the x264ASM assembly language, which uses
24 ; NASM/YASM syntax combined with a large number of macros to provide easy
25 ; abstraction between different calling conventions (x86_32, win64, linux64).
26 ; It also has various other useful features to simplify writing the kind of
27 ; DSP functions that are most often used in x264.
28
29 ; Unlike the rest of x264, this file is available under an ISC license, as it
30 ; has significant usefulness outside of x264 and we want it to be available
31 ; to the largest audience possible.  Of course, if you modify it for your own
32 ; purposes to add a new feature, we strongly encourage contributing a patch
33 ; as this feature might be useful for others as well.  Send patches or ideas
34 ; to x264-devel@videolan.org .
35
36 %define program_name x264
37
38 %ifdef ARCH_X86_64
39     %ifidn __OUTPUT_FORMAT__,win32
40         %define WIN64
41     %else
42         %define UNIX64
43     %endif
44 %endif
45
46 %ifdef PREFIX
47     %define mangle(x) _ %+ x
48 %else
49     %define mangle(x) x
50 %endif
51
52 ; FIXME: All of the 64bit asm functions that take a stride as an argument
53 ; via register, assume that the high dword of that register is filled with 0.
54 ; This is true in practice (since we never do any 64bit arithmetic on strides,
55 ; and x264's strides are all positive), but is not guaranteed by the ABI.
56
57 ; Name of the .rodata section.
58 ; Kludge: Something on OS X fails to align .rodata even given an align attribute,
59 ; so use a different read-only section.
60 %macro SECTION_RODATA 0-1 16
61     %ifidn __OUTPUT_FORMAT__,macho64
62         SECTION .text align=%1
63     %elifidn __OUTPUT_FORMAT__,macho
64         SECTION .text align=%1
65         fakegot:
66     %elifidn __OUTPUT_FORMAT__,aout
67         section .text
68     %else
69         SECTION .rodata align=%1
70     %endif
71 %endmacro
72
73 ; aout does not support align=
74 %macro SECTION_TEXT 0-1 16
75     %ifidn __OUTPUT_FORMAT__,aout
76         SECTION .text
77     %else
78         SECTION .text align=%1
79     %endif
80 %endmacro
81
82 %ifdef WIN64
83     %define PIC
84 %elifndef ARCH_X86_64
85 ; x86_32 doesn't require PIC.
86 ; Some distros prefer shared objects to be PIC, but nothing breaks if
87 ; the code contains a few textrels, so we'll skip that complexity.
88     %undef PIC
89 %endif
90 %ifdef PIC
91     default rel
92 %endif
93
94 ; Macros to eliminate most code duplication between x86_32 and x86_64:
95 ; Currently this works only for leaf functions which load all their arguments
96 ; into registers at the start, and make no other use of the stack. Luckily that
97 ; covers most of x264's asm.
98
99 ; PROLOGUE:
100 ; %1 = number of arguments. loads them from stack if needed.
101 ; %2 = number of registers used. pushes callee-saved regs if needed.
102 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
103 ; %4 = list of names to define to registers
104 ; PROLOGUE can also be invoked by adding the same options to cglobal
105
106 ; e.g.
107 ; cglobal foo, 2,3,0, dst, src, tmp
108 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
109
110 ; TODO Some functions can use some args directly from the stack. If they're the
111 ; last args then you can just not declare them, but if they're in the middle
112 ; we need more flexible macro.
113
114 ; RET:
115 ; Pops anything that was pushed by PROLOGUE, and returns.
116
117 ; REP_RET:
118 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
119 ; which are slow when a normal ret follows a branch.
120
121 ; registers:
122 ; rN and rNq are the native-size register holding function argument N
123 ; rNd, rNw, rNb are dword, word, and byte size
124 ; rNm is the original location of arg N (a register or on the stack), dword
125 ; rNmp is native size
126
127 %macro DECLARE_REG 6
128     %define r%1q %2
129     %define r%1d %3
130     %define r%1w %4
131     %define r%1b %5
132     %define r%1m %6
133     %ifid %6 ; i.e. it's a register
134         %define r%1mp %2
135     %elifdef ARCH_X86_64 ; memory
136         %define r%1mp qword %6
137     %else
138         %define r%1mp dword %6
139     %endif
140     %define r%1  %2
141 %endmacro
142
143 %macro DECLARE_REG_SIZE 2
144     %define r%1q r%1
145     %define e%1q r%1
146     %define r%1d e%1
147     %define e%1d e%1
148     %define r%1w %1
149     %define e%1w %1
150     %define r%1b %2
151     %define e%1b %2
152 %ifndef ARCH_X86_64
153     %define r%1  e%1
154 %endif
155 %endmacro
156
157 DECLARE_REG_SIZE ax, al
158 DECLARE_REG_SIZE bx, bl
159 DECLARE_REG_SIZE cx, cl
160 DECLARE_REG_SIZE dx, dl
161 DECLARE_REG_SIZE si, sil
162 DECLARE_REG_SIZE di, dil
163 DECLARE_REG_SIZE bp, bpl
164
165 ; t# defines for when per-arch register allocation is more complex than just function arguments
166
167 %macro DECLARE_REG_TMP 1-*
168     %assign %%i 0
169     %rep %0
170         CAT_XDEFINE t, %%i, r%1
171         %assign %%i %%i+1
172         %rotate 1
173     %endrep
174 %endmacro
175
176 %macro DECLARE_REG_TMP_SIZE 0-*
177     %rep %0
178         %define t%1q t%1 %+ q
179         %define t%1d t%1 %+ d
180         %define t%1w t%1 %+ w
181         %define t%1b t%1 %+ b
182         %rotate 1
183     %endrep
184 %endmacro
185
186 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9
187
188 %ifdef ARCH_X86_64
189     %define gprsize 8
190 %else
191     %define gprsize 4
192 %endif
193
194 %macro PUSH 1
195     push %1
196     %assign stack_offset stack_offset+gprsize
197 %endmacro
198
199 %macro POP 1
200     pop %1
201     %assign stack_offset stack_offset-gprsize
202 %endmacro
203
204 %macro SUB 2
205     sub %1, %2
206     %ifidn %1, rsp
207         %assign stack_offset stack_offset+(%2)
208     %endif
209 %endmacro
210
211 %macro ADD 2
212     add %1, %2
213     %ifidn %1, rsp
214         %assign stack_offset stack_offset-(%2)
215     %endif
216 %endmacro
217
218 %macro movifnidn 2
219     %ifnidn %1, %2
220         mov %1, %2
221     %endif
222 %endmacro
223
224 %macro movsxdifnidn 2
225     %ifnidn %1, %2
226         movsxd %1, %2
227     %endif
228 %endmacro
229
230 %macro ASSERT 1
231     %if (%1) == 0
232         %error assert failed
233     %endif
234 %endmacro
235
236 %macro DEFINE_ARGS 0-*
237     %ifdef n_arg_names
238         %assign %%i 0
239         %rep n_arg_names
240             CAT_UNDEF arg_name %+ %%i, q
241             CAT_UNDEF arg_name %+ %%i, d
242             CAT_UNDEF arg_name %+ %%i, w
243             CAT_UNDEF arg_name %+ %%i, b
244             CAT_UNDEF arg_name %+ %%i, m
245             CAT_UNDEF arg_name, %%i
246             %assign %%i %%i+1
247         %endrep
248     %endif
249
250     %assign %%i 0
251     %rep %0
252         %xdefine %1q r %+ %%i %+ q
253         %xdefine %1d r %+ %%i %+ d
254         %xdefine %1w r %+ %%i %+ w
255         %xdefine %1b r %+ %%i %+ b
256         %xdefine %1m r %+ %%i %+ m
257         CAT_XDEFINE arg_name, %%i, %1
258         %assign %%i %%i+1
259         %rotate 1
260     %endrep
261     %assign n_arg_names %%i
262 %endmacro
263
264 %ifdef WIN64 ; Windows x64 ;=================================================
265
266 DECLARE_REG 0, rcx, ecx, cx,  cl,  ecx
267 DECLARE_REG 1, rdx, edx, dx,  dl,  edx
268 DECLARE_REG 2, r8,  r8d, r8w, r8b, r8d
269 DECLARE_REG 3, r9,  r9d, r9w, r9b, r9d
270 DECLARE_REG 4, rdi, edi, di,  dil, [rsp + stack_offset + 40]
271 DECLARE_REG 5, rsi, esi, si,  sil, [rsp + stack_offset + 48]
272 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 56]
273 %define r7m [rsp + stack_offset + 64]
274 %define r8m [rsp + stack_offset + 72]
275
276 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
277     %if %1 < %2
278         mov r%1, [rsp + stack_offset + 8 + %1*8]
279     %endif
280 %endmacro
281
282 %macro PROLOGUE 2-4+ 0 ; #args, #regs, #xmm_regs, arg_names...
283     ASSERT %2 >= %1
284     %assign regs_used %2
285     ASSERT regs_used <= 7
286     %if regs_used > 4
287         push r4
288         push r5
289         %assign stack_offset stack_offset+16
290     %endif
291     WIN64_SPILL_XMM %3
292     LOAD_IF_USED 4, %1
293     LOAD_IF_USED 5, %1
294     LOAD_IF_USED 6, %1
295     DEFINE_ARGS %4
296 %endmacro
297
298 %macro WIN64_SPILL_XMM 1
299     %assign xmm_regs_used %1
300     %if mmsize == 8
301         %assign xmm_regs_used 0
302     %endif
303     ASSERT xmm_regs_used <= 16
304     %if xmm_regs_used > 6
305         sub rsp, (xmm_regs_used-6)*16+16
306         %assign stack_offset stack_offset+(xmm_regs_used-6)*16+16
307         %assign %%i xmm_regs_used
308         %rep (xmm_regs_used-6)
309             %assign %%i %%i-1
310             movdqa [rsp + (%%i-6)*16+8], xmm %+ %%i
311         %endrep
312     %endif
313 %endmacro
314
315 %macro WIN64_RESTORE_XMM_INTERNAL 1
316     %if xmm_regs_used > 6
317         %assign %%i xmm_regs_used
318         %rep (xmm_regs_used-6)
319             %assign %%i %%i-1
320             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+8]
321         %endrep
322         add %1, (xmm_regs_used-6)*16+16
323     %endif
324 %endmacro
325
326 %macro WIN64_RESTORE_XMM 1
327     WIN64_RESTORE_XMM_INTERNAL %1
328     %assign stack_offset stack_offset-(xmm_regs_used-6)*16+16
329     %assign xmm_regs_used 0
330 %endmacro
331
332 %macro RET 0
333     WIN64_RESTORE_XMM_INTERNAL rsp
334     %if regs_used > 4
335         pop r5
336         pop r4
337     %endif
338     ret
339 %endmacro
340
341 %macro REP_RET 0
342     %if regs_used > 4 || xmm_regs_used > 6
343         RET
344     %else
345         rep ret
346     %endif
347 %endmacro
348
349 %elifdef ARCH_X86_64 ; *nix x64 ;=============================================
350
351 DECLARE_REG 0, rdi, edi, di,  dil, edi
352 DECLARE_REG 1, rsi, esi, si,  sil, esi
353 DECLARE_REG 2, rdx, edx, dx,  dl,  edx
354 DECLARE_REG 3, rcx, ecx, cx,  cl,  ecx
355 DECLARE_REG 4, r8,  r8d, r8w, r8b, r8d
356 DECLARE_REG 5, r9,  r9d, r9w, r9b, r9d
357 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 8]
358 %define r7m [rsp + stack_offset + 16]
359 %define r8m [rsp + stack_offset + 24]
360
361 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
362     %if %1 < %2
363         mov r%1, [rsp - 40 + %1*8]
364     %endif
365 %endmacro
366
367 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
368     ASSERT %2 >= %1
369     ASSERT %2 <= 7
370     LOAD_IF_USED 6, %1
371     DEFINE_ARGS %4
372 %endmacro
373
374 %macro RET 0
375     ret
376 %endmacro
377
378 %macro REP_RET 0
379     rep ret
380 %endmacro
381
382 %else ; X86_32 ;==============================================================
383
384 DECLARE_REG 0, eax, eax, ax, al,   [esp + stack_offset + 4]
385 DECLARE_REG 1, ecx, ecx, cx, cl,   [esp + stack_offset + 8]
386 DECLARE_REG 2, edx, edx, dx, dl,   [esp + stack_offset + 12]
387 DECLARE_REG 3, ebx, ebx, bx, bl,   [esp + stack_offset + 16]
388 DECLARE_REG 4, esi, esi, si, null, [esp + stack_offset + 20]
389 DECLARE_REG 5, edi, edi, di, null, [esp + stack_offset + 24]
390 DECLARE_REG 6, ebp, ebp, bp, null, [esp + stack_offset + 28]
391 %define r7m [esp + stack_offset + 32]
392 %define r8m [esp + stack_offset + 36]
393 %define rsp esp
394
395 %macro PUSH_IF_USED 1 ; reg_id
396     %if %1 < regs_used
397         push r%1
398         %assign stack_offset stack_offset+4
399     %endif
400 %endmacro
401
402 %macro POP_IF_USED 1 ; reg_id
403     %if %1 < regs_used
404         pop r%1
405     %endif
406 %endmacro
407
408 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
409     %if %1 < %2
410         mov r%1, [esp + stack_offset + 4 + %1*4]
411     %endif
412 %endmacro
413
414 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
415     ASSERT %2 >= %1
416     %assign regs_used %2
417     ASSERT regs_used <= 7
418     PUSH_IF_USED 3
419     PUSH_IF_USED 4
420     PUSH_IF_USED 5
421     PUSH_IF_USED 6
422     LOAD_IF_USED 0, %1
423     LOAD_IF_USED 1, %1
424     LOAD_IF_USED 2, %1
425     LOAD_IF_USED 3, %1
426     LOAD_IF_USED 4, %1
427     LOAD_IF_USED 5, %1
428     LOAD_IF_USED 6, %1
429     DEFINE_ARGS %4
430 %endmacro
431
432 %macro RET 0
433     POP_IF_USED 6
434     POP_IF_USED 5
435     POP_IF_USED 4
436     POP_IF_USED 3
437     ret
438 %endmacro
439
440 %macro REP_RET 0
441     %if regs_used > 3
442         RET
443     %else
444         rep ret
445     %endif
446 %endmacro
447
448 %endif ;======================================================================
449
450 %ifndef WIN64
451 %macro WIN64_SPILL_XMM 1
452 %endmacro
453 %macro WIN64_RESTORE_XMM 1
454 %endmacro
455 %endif
456
457
458
459 ;=============================================================================
460 ; arch-independent part
461 ;=============================================================================
462
463 %assign function_align 16
464
465 ; Begin a function.
466 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
467 ; subsequent uses of the function name automatically refer to the mangled version.
468 ; Appends cpuflags to the function name if cpuflags has been specified.
469 %macro cglobal 1-2+ ; name, [PROLOGUE args]
470 %if %0 == 1
471     cglobal_internal %1 %+ SUFFIX
472 %else
473     cglobal_internal %1 %+ SUFFIX, %2
474 %endif
475 %endmacro
476 %macro cglobal_internal 1-2+
477     %ifndef cglobaled_%1
478         %xdefine %1 mangle(program_name %+ _ %+ %1)
479         %xdefine %1.skip_prologue %1 %+ .skip_prologue
480         CAT_XDEFINE cglobaled_, %1, 1
481     %endif
482     %xdefine current_function %1
483     %ifidn __OUTPUT_FORMAT__,elf
484         global %1:function hidden
485     %else
486         global %1
487     %endif
488     align function_align
489     %1:
490     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
491     %assign stack_offset 0
492     %if %0 > 1
493         PROLOGUE %2
494     %endif
495 %endmacro
496
497 %macro cextern 1
498     %xdefine %1 mangle(program_name %+ _ %+ %1)
499     CAT_XDEFINE cglobaled_, %1, 1
500     extern %1
501 %endmacro
502
503 ; like cextern, but without the prefix
504 %macro cextern_naked 1
505     %xdefine %1 mangle(%1)
506     CAT_XDEFINE cglobaled_, %1, 1
507     extern %1
508 %endmacro
509
510 %macro const 2+
511     %xdefine %1 mangle(program_name %+ _ %+ %1)
512     global %1
513     %1: %2
514 %endmacro
515
516 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
517 ; executable by default.
518 %ifidn __OUTPUT_FORMAT__,elf
519 SECTION .note.GNU-stack noalloc noexec nowrite progbits
520 %endif
521
522 ; cpuflags
523
524 %assign cpuflags_mmx      (1<<0)
525 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
526 %assign cpuflags_sse      (1<<2) | cpuflags_mmx2
527 %assign cpuflags_sse2     (1<<3) | cpuflags_sse
528 %assign cpuflags_sse2slow (1<<4) | cpuflags_sse2
529 %assign cpuflags_sse3     (1<<5) | cpuflags_sse2
530 %assign cpuflags_ssse3    (1<<6) | cpuflags_sse3
531 %assign cpuflags_sse4     (1<<7) | cpuflags_ssse3
532 %assign cpuflags_sse42    (1<<8) | cpuflags_sse4
533 %assign cpuflags_avx      (1<<9) | cpuflags_sse42
534
535 %assign cpuflags_cache32  (1<<16)
536 %assign cpuflags_cache64  (1<<17)
537 %assign cpuflags_slowctz  (1<<18)
538 %assign cpuflags_lzcnt    (1<<19)
539 %assign cpuflags_misalign (1<<20)
540 %assign cpuflags_aligned  (1<<21) ; not a cpu feature, but a function variant
541
542 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
543 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
544
545 ; Takes up to 2 cpuflags from the above list.
546 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
547 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
548 %macro INIT_CPUFLAGS 0-2
549     %if %0 >= 1
550         %xdefine cpuname %1
551         %assign cpuflags cpuflags_%1
552         %if %0 >= 2
553             %xdefine cpuname %1_%2
554             %assign cpuflags cpuflags | cpuflags_%2
555         %endif
556         %xdefine SUFFIX _ %+ cpuname
557         %if cpuflag(avx)
558             %assign avx_enabled 1
559         %endif
560         %if cpuflag(aligned)
561             %define movu mova
562         %elifidn %1, sse3
563             %define movu lddqu
564         %endif
565     %else
566         %xdefine SUFFIX
567         %undef cpuname
568         %undef cpuflags
569     %endif
570 %endmacro
571
572 ; merge mmx and sse*
573
574 %macro CAT_XDEFINE 3
575     %xdefine %1%2 %3
576 %endmacro
577
578 %macro CAT_UNDEF 2
579     %undef %1%2
580 %endmacro
581
582 %macro INIT_MMX 0-1+
583     %assign avx_enabled 0
584     %define RESET_MM_PERMUTATION INIT_MMX %1
585     %define mmsize 8
586     %define num_mmregs 8
587     %define mova movq
588     %define movu movq
589     %define movh movd
590     %define movnta movntq
591     %assign %%i 0
592     %rep 8
593     CAT_XDEFINE m, %%i, mm %+ %%i
594     CAT_XDEFINE nmm, %%i, %%i
595     %assign %%i %%i+1
596     %endrep
597     %rep 8
598     CAT_UNDEF m, %%i
599     CAT_UNDEF nmm, %%i
600     %assign %%i %%i+1
601     %endrep
602     INIT_CPUFLAGS %1
603 %endmacro
604
605 %macro INIT_XMM 0-1+
606     %assign avx_enabled 0
607     %define RESET_MM_PERMUTATION INIT_XMM %1
608     %define mmsize 16
609     %define num_mmregs 8
610     %ifdef ARCH_X86_64
611     %define num_mmregs 16
612     %endif
613     %define mova movdqa
614     %define movu movdqu
615     %define movh movq
616     %define movnta movntdq
617     %assign %%i 0
618     %rep num_mmregs
619     CAT_XDEFINE m, %%i, xmm %+ %%i
620     CAT_XDEFINE nxmm, %%i, %%i
621     %assign %%i %%i+1
622     %endrep
623     INIT_CPUFLAGS %1
624 %endmacro
625
626 %macro INIT_YMM 0-1+
627     %assign avx_enabled 1
628     %define RESET_MM_PERMUTATION INIT_YMM %1
629     %define mmsize 32
630     %define num_mmregs 8
631     %ifdef ARCH_X86_64
632     %define num_mmregs 16
633     %endif
634     %define mova vmovaps
635     %define movu vmovups
636     %undef movh
637     %undef movnta
638     %assign %%i 0
639     %rep num_mmregs
640     CAT_XDEFINE m, %%i, ymm %+ %%i
641     CAT_XDEFINE nymm, %%i, %%i
642     %assign %%i %%i+1
643     %endrep
644     INIT_CPUFLAGS %1
645 %endmacro
646
647 INIT_XMM
648
649 ; I often want to use macros that permute their arguments. e.g. there's no
650 ; efficient way to implement butterfly or transpose or dct without swapping some
651 ; arguments.
652 ;
653 ; I would like to not have to manually keep track of the permutations:
654 ; If I insert a permutation in the middle of a function, it should automatically
655 ; change everything that follows. For more complex macros I may also have multiple
656 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
657 ;
658 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
659 ; permutes its arguments. It's equivalent to exchanging the contents of the
660 ; registers, except that this way you exchange the register names instead, so it
661 ; doesn't cost any cycles.
662
663 %macro PERMUTE 2-* ; takes a list of pairs to swap
664 %rep %0/2
665     %xdefine tmp%2 m%2
666     %xdefine ntmp%2 nm%2
667     %rotate 2
668 %endrep
669 %rep %0/2
670     %xdefine m%1 tmp%2
671     %xdefine nm%1 ntmp%2
672     %undef tmp%2
673     %undef ntmp%2
674     %rotate 2
675 %endrep
676 %endmacro
677
678 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
679 %rep %0-1
680 %ifdef m%1
681     %xdefine tmp m%1
682     %xdefine m%1 m%2
683     %xdefine m%2 tmp
684     CAT_XDEFINE n, m%1, %1
685     CAT_XDEFINE n, m%2, %2
686 %else
687     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
688     ; Be careful using this mode in nested macros though, as in some cases there may be
689     ; other copies of m# that have already been dereferenced and don't get updated correctly.
690     %xdefine %%n1 n %+ %1
691     %xdefine %%n2 n %+ %2
692     %xdefine tmp m %+ %%n1
693     CAT_XDEFINE m, %%n1, m %+ %%n2
694     CAT_XDEFINE m, %%n2, tmp
695     CAT_XDEFINE n, m %+ %%n1, %%n1
696     CAT_XDEFINE n, m %+ %%n2, %%n2
697 %endif
698     %undef tmp
699     %rotate 1
700 %endrep
701 %endmacro
702
703 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
704 ; calls to that function will automatically load the permutation, so values can
705 ; be returned in mmregs.
706 %macro SAVE_MM_PERMUTATION 0-1
707     %if %0
708         %xdefine %%f %1_m
709     %else
710         %xdefine %%f current_function %+ _m
711     %endif
712     %assign %%i 0
713     %rep num_mmregs
714         CAT_XDEFINE %%f, %%i, m %+ %%i
715     %assign %%i %%i+1
716     %endrep
717 %endmacro
718
719 %macro LOAD_MM_PERMUTATION 1 ; name to load from
720     %ifdef %1_m0
721         %assign %%i 0
722         %rep num_mmregs
723             CAT_XDEFINE m, %%i, %1_m %+ %%i
724             CAT_XDEFINE n, m %+ %%i, %%i
725         %assign %%i %%i+1
726         %endrep
727     %endif
728 %endmacro
729
730 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
731 %macro call 1
732     call_internal %1, %1 %+ SUFFIX
733 %endmacro
734 %macro call_internal 2
735     %xdefine %%i %1
736     %ifndef cglobaled_%1
737         %ifdef cglobaled_%2
738             %xdefine %%i %2
739         %endif
740     %endif
741     call %%i
742     LOAD_MM_PERMUTATION %%i
743 %endmacro
744
745 ; Substitutions that reduce instruction size but are functionally equivalent
746 %macro add 2
747     %ifnum %2
748         %if %2==128
749             sub %1, -128
750         %else
751             add %1, %2
752         %endif
753     %else
754         add %1, %2
755     %endif
756 %endmacro
757
758 %macro sub 2
759     %ifnum %2
760         %if %2==128
761             add %1, -128
762         %else
763             sub %1, %2
764         %endif
765     %else
766         sub %1, %2
767     %endif
768 %endmacro
769
770 ;=============================================================================
771 ; AVX abstraction layer
772 ;=============================================================================
773
774 %assign i 0
775 %rep 16
776     %if i < 8
777         CAT_XDEFINE sizeofmm, i, 8
778     %endif
779     CAT_XDEFINE sizeofxmm, i, 16
780     CAT_XDEFINE sizeofymm, i, 32
781 %assign i i+1
782 %endrep
783 %undef i
784
785 ;%1 == instruction
786 ;%2 == 1 if float, 0 if int
787 ;%3 == 0 if 3-operand (xmm, xmm, xmm), 1 if 4-operand (xmm, xmm, xmm, imm)
788 ;%4 == number of operands given
789 ;%5+: operands
790 %macro RUN_AVX_INSTR 6-7+
791     %if sizeof%5==32
792         v%1 %5, %6, %7
793     %else
794         %if sizeof%5==8
795             %define %%regmov movq
796         %elif %2
797             %define %%regmov movaps
798         %else
799             %define %%regmov movdqa
800         %endif
801
802         %if %4>=3+%3
803             %ifnidn %5, %6
804                 %if avx_enabled && sizeof%5==16
805                     v%1 %5, %6, %7
806                 %else
807                     %%regmov %5, %6
808                     %1 %5, %7
809                 %endif
810             %else
811                 %1 %5, %7
812             %endif
813         %elif %3
814             %1 %5, %6, %7
815         %else
816             %1 %5, %6
817         %endif
818     %endif
819 %endmacro
820
821 ;%1 == instruction
822 ;%2 == 1 if float, 0 if int
823 ;%3 == 0 if 3-operand (xmm, xmm, xmm), 1 if 4-operand (xmm, xmm, xmm, imm)
824 %macro AVX_INSTR 3
825     %macro %1 2-8 fnord, fnord, fnord, %1, %2, %3
826         %ifidn %3, fnord
827             RUN_AVX_INSTR %6, %7, %8, 2, %1, %2
828         %elifidn %4, fnord
829             RUN_AVX_INSTR %6, %7, %8, 3, %1, %2, %3
830         %elifidn %5, fnord
831             RUN_AVX_INSTR %6, %7, %8, 4, %1, %2, %3, %4
832         %else
833             RUN_AVX_INSTR %6, %7, %8, 5, %1, %2, %3, %4, %5
834         %endif
835     %endmacro
836 %endmacro
837
838 AVX_INSTR addpd, 1, 0
839 AVX_INSTR addps, 1, 0
840 AVX_INSTR addsd, 1, 0
841 AVX_INSTR addss, 1, 0
842 AVX_INSTR addsubpd, 1, 0
843 AVX_INSTR addsubps, 1, 0
844 AVX_INSTR andpd, 1, 0
845 AVX_INSTR andps, 1, 0
846 AVX_INSTR andnpd, 1, 0
847 AVX_INSTR andnps, 1, 0
848 AVX_INSTR blendpd, 1, 0
849 AVX_INSTR blendps, 1, 0
850 AVX_INSTR blendvpd, 1, 0
851 AVX_INSTR blendvps, 1, 0
852 AVX_INSTR cmppd, 1, 0
853 AVX_INSTR cmpps, 1, 0
854 AVX_INSTR cmpsd, 1, 0
855 AVX_INSTR cmpss, 1, 0
856 AVX_INSTR divpd, 1, 0
857 AVX_INSTR divps, 1, 0
858 AVX_INSTR divsd, 1, 0
859 AVX_INSTR divss, 1, 0
860 AVX_INSTR dppd, 1, 0
861 AVX_INSTR dpps, 1, 0
862 AVX_INSTR haddpd, 1, 0
863 AVX_INSTR haddps, 1, 0
864 AVX_INSTR hsubpd, 1, 0
865 AVX_INSTR hsubps, 1, 0
866 AVX_INSTR maxpd, 1, 0
867 AVX_INSTR maxps, 1, 0
868 AVX_INSTR maxsd, 1, 0
869 AVX_INSTR maxss, 1, 0
870 AVX_INSTR minpd, 1, 0
871 AVX_INSTR minps, 1, 0
872 AVX_INSTR minsd, 1, 0
873 AVX_INSTR minss, 1, 0
874 AVX_INSTR mpsadbw, 0, 1
875 AVX_INSTR mulpd, 1, 0
876 AVX_INSTR mulps, 1, 0
877 AVX_INSTR mulsd, 1, 0
878 AVX_INSTR mulss, 1, 0
879 AVX_INSTR orpd, 1, 0
880 AVX_INSTR orps, 1, 0
881 AVX_INSTR packsswb, 0, 0
882 AVX_INSTR packssdw, 0, 0
883 AVX_INSTR packuswb, 0, 0
884 AVX_INSTR packusdw, 0, 0
885 AVX_INSTR paddb, 0, 0
886 AVX_INSTR paddw, 0, 0
887 AVX_INSTR paddd, 0, 0
888 AVX_INSTR paddq, 0, 0
889 AVX_INSTR paddsb, 0, 0
890 AVX_INSTR paddsw, 0, 0
891 AVX_INSTR paddusb, 0, 0
892 AVX_INSTR paddusw, 0, 0
893 AVX_INSTR palignr, 0, 1
894 AVX_INSTR pand, 0, 0
895 AVX_INSTR pandn, 0, 0
896 AVX_INSTR pavgb, 0, 0
897 AVX_INSTR pavgw, 0, 0
898 AVX_INSTR pblendvb, 0, 0
899 AVX_INSTR pblendw, 0, 1
900 AVX_INSTR pcmpestri, 0, 0
901 AVX_INSTR pcmpestrm, 0, 0
902 AVX_INSTR pcmpistri, 0, 0
903 AVX_INSTR pcmpistrm, 0, 0
904 AVX_INSTR pcmpeqb, 0, 0
905 AVX_INSTR pcmpeqw, 0, 0
906 AVX_INSTR pcmpeqd, 0, 0
907 AVX_INSTR pcmpeqq, 0, 0
908 AVX_INSTR pcmpgtb, 0, 0
909 AVX_INSTR pcmpgtw, 0, 0
910 AVX_INSTR pcmpgtd, 0, 0
911 AVX_INSTR pcmpgtq, 0, 0
912 AVX_INSTR phaddw, 0, 0
913 AVX_INSTR phaddd, 0, 0
914 AVX_INSTR phaddsw, 0, 0
915 AVX_INSTR phsubw, 0, 0
916 AVX_INSTR phsubd, 0, 0
917 AVX_INSTR phsubsw, 0, 0
918 AVX_INSTR pmaddwd, 0, 0
919 AVX_INSTR pmaddubsw, 0, 0
920 AVX_INSTR pmaxsb, 0, 0
921 AVX_INSTR pmaxsw, 0, 0
922 AVX_INSTR pmaxsd, 0, 0
923 AVX_INSTR pmaxub, 0, 0
924 AVX_INSTR pmaxuw, 0, 0
925 AVX_INSTR pmaxud, 0, 0
926 AVX_INSTR pminsb, 0, 0
927 AVX_INSTR pminsw, 0, 0
928 AVX_INSTR pminsd, 0, 0
929 AVX_INSTR pminub, 0, 0
930 AVX_INSTR pminuw, 0, 0
931 AVX_INSTR pminud, 0, 0
932 AVX_INSTR pmulhuw, 0, 0
933 AVX_INSTR pmulhrsw, 0, 0
934 AVX_INSTR pmulhw, 0, 0
935 AVX_INSTR pmullw, 0, 0
936 AVX_INSTR pmulld, 0, 0
937 AVX_INSTR pmuludq, 0, 0
938 AVX_INSTR pmuldq, 0, 0
939 AVX_INSTR por, 0, 0
940 AVX_INSTR psadbw, 0, 0
941 AVX_INSTR pshufb, 0, 0
942 AVX_INSTR psignb, 0, 0
943 AVX_INSTR psignw, 0, 0
944 AVX_INSTR psignd, 0, 0
945 AVX_INSTR psllw, 0, 0
946 AVX_INSTR pslld, 0, 0
947 AVX_INSTR psllq, 0, 0
948 AVX_INSTR pslldq, 0, 0
949 AVX_INSTR psraw, 0, 0
950 AVX_INSTR psrad, 0, 0
951 AVX_INSTR psrlw, 0, 0
952 AVX_INSTR psrld, 0, 0
953 AVX_INSTR psrlq, 0, 0
954 AVX_INSTR psrldq, 0, 0
955 AVX_INSTR psubb, 0, 0
956 AVX_INSTR psubw, 0, 0
957 AVX_INSTR psubd, 0, 0
958 AVX_INSTR psubq, 0, 0
959 AVX_INSTR psubsb, 0, 0
960 AVX_INSTR psubsw, 0, 0
961 AVX_INSTR psubusb, 0, 0
962 AVX_INSTR psubusw, 0, 0
963 AVX_INSTR punpckhbw, 0, 0
964 AVX_INSTR punpckhwd, 0, 0
965 AVX_INSTR punpckhdq, 0, 0
966 AVX_INSTR punpckhqdq, 0, 0
967 AVX_INSTR punpcklbw, 0, 0
968 AVX_INSTR punpcklwd, 0, 0
969 AVX_INSTR punpckldq, 0, 0
970 AVX_INSTR punpcklqdq, 0, 0
971 AVX_INSTR pxor, 0, 0
972 AVX_INSTR shufps, 0, 1
973 AVX_INSTR subpd, 1, 0
974 AVX_INSTR subps, 1, 0
975 AVX_INSTR subsd, 1, 0
976 AVX_INSTR subss, 1, 0
977 AVX_INSTR unpckhpd, 1, 0
978 AVX_INSTR unpckhps, 1, 0
979 AVX_INSTR unpcklpd, 1, 0
980 AVX_INSTR unpcklps, 1, 0
981 AVX_INSTR xorpd, 1, 0
982 AVX_INSTR xorps, 1, 0
983
984 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
985 AVX_INSTR pfadd, 1, 0
986 AVX_INSTR pfsub, 1, 0
987 AVX_INSTR pfmul, 1, 0
988
989
990 ; base-4 constants for shuffles
991 %assign i 0
992 %rep 256
993     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
994     %if j < 10
995         CAT_XDEFINE q000, j, i
996     %elif j < 100
997         CAT_XDEFINE q00, j, i
998     %elif j < 1000
999         CAT_XDEFINE q0, j, i
1000     %else
1001         CAT_XDEFINE q, j, i
1002     %endif
1003 %assign i i+1
1004 %endrep
1005 %undef i
1006 %undef j