drop support for x86_32 PIC.
[x262.git] / common / x86 / cabac-a.asm
1 ;*****************************************************************************
2 ;* cabac-a.asm: h264 encoder library
3 ;*****************************************************************************
4 ;* Copyright (C) 2008 x264 project
5 ;*
6 ;* Author: Loren Merritt <lorenm@u.washington.edu>
7 ;*         Jason Garrett-Glaser <darkshikari@gmail.com>
8 ;*
9 ;* This program is free software; you can redistribute it and/or modify
10 ;* it under the terms of the GNU General Public License as published by
11 ;* the Free Software Foundation; either version 2 of the License, or
12 ;* (at your option) any later version.
13 ;*
14 ;* This program is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17 ;* GNU General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU General Public License
20 ;* along with this program; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02111, USA.
22 ;*****************************************************************************
23
24 %include "x86inc.asm"
25
26 SECTION_RODATA
27
28 SECTION .text
29
30 cextern x264_cabac_range_lps
31 cextern x264_cabac_transition
32 cextern x264_cabac_renorm_shift
33
34 %macro DEF_TMP 16
35     %rep 8
36         %define t%1d r%9d
37         %define t%1b r%9b
38         %define t%1  r%9
39         %rotate 1
40     %endrep
41 %endmacro
42
43 ; t3 must be ecx, since it's used for shift.
44 %ifdef ARCH_X86_64
45     DEF_TMP 0,1,2,3,4,5,6,7, 0,1,2,3,4,5,6,10
46     %define pointer resq
47 %else
48     DEF_TMP 0,1,2,3,4,5,6,7, 0,3,2,1,4,5,6,3
49     %define pointer resd
50 %endif
51
52 struc cb
53     .low: resd 1
54     .range: resd 1
55     .queue: resd 1
56     .bytes_outstanding: resd 1
57     .start: pointer 1
58     .p: pointer 1
59     .end: pointer 1
60     align 16, resb 1
61     .bits_encoded: resd 1
62     .state: resb 460
63 endstruc
64
65 %macro LOAD_GLOBAL 4
66 %ifdef PIC
67     ; this would be faster if the arrays were declared in asm, so that I didn't have to duplicate the lea
68     lea   r11, [%2 GLOBAL]
69     %ifnidn %3, 0
70     add   r11, %3
71     %endif
72     movzx %1, byte [r11+%4]
73 %else
74     movzx %1, byte [%2+%3+%4]
75 %endif
76 %endmacro
77
78 cglobal x264_cabac_encode_decision_asm, 0,7
79     movifnidn t0d, r0m
80     movifnidn t1d, r1m
81     mov   t5d, [r0+cb.range]
82     movzx t3d, byte [r0+cb.state+t1]
83     mov   t4d, t5d
84     shr   t5d, 6
85     and   t5d, 3
86     LOAD_GLOBAL t5d, x264_cabac_range_lps, t5, t3*4
87     sub   t4d, t5d
88     mov   t6d, t3d
89     shr   t6d, 6
90     movifnidn t2d, r2m
91     cmp   t6d, t2d
92     mov   t6d, [r0+cb.low]
93     lea   t7,  [t6+t4]
94     cmovne t4d, t5d
95     cmovne t6d, t7d
96     LOAD_GLOBAL t3d, x264_cabac_transition, t2, t3*2
97     movifnidn t1d, r1m
98     mov   [r0+cb.state+t1], t3b
99 .renorm:
100     mov   t3d, t4d
101     shr   t3d, 3
102     LOAD_GLOBAL t3d, x264_cabac_renorm_shift, 0, t3
103     shl   t4d, t3b
104     shl   t6d, t3b
105     add   t3d, [r0+cb.queue]
106     mov   [r0+cb.range], t4d
107     mov   [r0+cb.low], t6d
108     mov   [r0+cb.queue], t3d
109     cmp   t3d, 8
110     jge .putbyte
111     REP_RET
112 .putbyte:
113     ; alive: t0=cb t3=queue t6=low
114     add   t3d, 2
115     mov   t1d, 1
116     mov   t2d, t6d
117     shl   t1d, t3b
118     shr   t2d, t3b ; out
119     dec   t1d
120     sub   t3d, 10
121     and   t6d, t1d
122     cmp   t2b, 0xff ; FIXME is a 32bit op faster?
123     mov   [r0+cb.queue], t3d
124     mov   [r0+cb.low], t6d
125     mov   t1d, t2d
126     mov   t4,  [r0+cb.p]
127     je .postpone
128     mov   t5d, [r0+cb.bytes_outstanding]
129     shr   t1d, 8 ; carry
130     add   [t4-1], t1b
131     test  t5d, t5d
132     jz .no_outstanding
133     dec   t1d
134 .loop_outstanding:
135     mov   [t4], t1b
136     inc   t4
137     dec   t5d
138     jg .loop_outstanding
139 .no_outstanding:
140     mov   [t4], t2b
141     inc   t4
142     mov   [r0+cb.bytes_outstanding], t5d ; is zero, but a reg has smaller opcode than an immediate
143     mov   [r0+cb.p], t4
144     RET
145 .postpone:
146     inc   dword [r0+cb.bytes_outstanding]
147     RET
148