vlm: remove some spurious calls to asprintf: vlm_MessageNew does it already.
[vlc/vlc-austin.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 2002-2010 the VideoLAN team])
4
5 AC_INIT(vlc, 1.2.0-git)
6 VERSION_MAJOR="1"
7 VERSION_MINOR="2"
8 VERSION_REVISION="0"
9 VERSION_EXTRA="-git"
10 PKGDIR="vlc"
11 AC_SUBST(PKGDIR)
12
13 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
14 CODENAME="Twoflower"
15 COPYRIGHT_YEARS="1996-2010"
16
17 AC_CONFIG_SRCDIR(src/libvlc.c)
18 AC_CONFIG_AUX_DIR(autotools)
19 AC_CONFIG_MACRO_DIR(m4)
20 AC_CONFIG_LIBOBJ_DIR(compat)
21 AC_CANONICAL_BUILD
22 AC_CANONICAL_HOST
23 AC_PRESERVE_HELP_ORDER
24
25 AM_INIT_AUTOMAKE(tar-ustar color-tests)
26 AM_CONFIG_HEADER(config.h)
27
28 # Disable with "./configure --disable-silent-rules" or "make V=1"
29 AM_SILENT_RULES([yes])
30
31 dnl Too many people are not aware of maintainer mode:
32 dnl If you want to use it, you definitely know what you are doing, so
33 dnl you can specify "--disable-maintainer-mode". But if you want the default
34 dnl automake behavior, you've likely never heard of maintainer mode, so we
35 dnl can't expect you to enable it manually.
36
37 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
38     [enable_maintainer_mode="yes"])
39 AM_MAINTAINER_MODE
40
41 dnl
42 dnl Directories
43 dnl
44 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
45 dnl AC_SUBST(vlcincludedir)
46 vlcdatadir="\${datadir}/\${PKGDIR}"
47 AC_SUBST(vlcdatadir)
48 vlclibdir="\${libdir}/\${PKGDIR}"
49 AC_SUBST(vlclibdir)
50
51 dnl
52 dnl  Save *FLAGS
53 dnl
54 VLC_SAVE_FLAGS
55
56 dnl
57 dnl Check for tools
58 dnl
59 AC_PROG_CC_C99
60 AC_USE_SYSTEM_EXTENSIONS
61 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to '2' to get glibc warnings.])
62
63 AM_PROG_CC_C_O
64 AC_PROG_CXX
65 AC_PROG_CPP
66 AC_PROG_OBJC
67 _AM_DEPENDENCIES([OBJC])
68 AC_PROG_EGREP
69 AC_PROG_MAKE_SET
70 AC_PROG_INSTALL
71 AM_PROG_AS
72
73 dnl Find the right ranlib, even when cross-compiling
74 AC_CHECK_TOOL(RANLIB, ranlib, :)
75 AC_CHECK_TOOL(STRIP, strip, :)
76 AC_CHECK_TOOL(AR, ar, :)
77 AC_CHECK_TOOL(LD, ld, :)
78 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
79
80 dnl Check for compiler properties
81 AC_C_CONST
82 AC_C_INLINE
83 AC_C_RESTRICT
84
85 dnl Extend the --help string at the current spot.
86 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
87
88 dnl Allow binary package maintainer to pass a custom string to avoid
89 dnl cache problem
90 AC_ARG_WITH(binary-version,
91         AS_HELP_STRING([--with-binary-version=STRING],
92              [To avoid plugins cache problem between binary version]),[],[])
93 AS_IF([test -n "${with_binary_version}"],[
94       AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
95                          [Binary specific version])
96       ])
97
98
99 dnl
100 dnl  Check for the contrib directory
101 dnl
102 AC_ARG_WITH(contrib,
103     [  --without-contrib       do not use the libraries in CONTRIB_DIR],[],[])
104 AC_ARG_VAR([CONTRIB_DIR], [directory containing pre-built contrib, overriding extras/contrib])
105 AS_IF([test "${with_contrib}" != "no"],[
106   AS_IF([test -z "$CONTRIB_DIR"], [
107       topdir="`dirname $0`"
108       if test "`echo \"$topdir\" | cut -c 1`" != "/"; then
109          topdir="`pwd`/$topdir"
110       fi
111       CONTRIB_DIR="${topdir}/extras/contrib/hosts/${host}"
112       if ! test -d "$CONTRIB_DIR"
113       then
114         gccmachine=`$CC -dumpmachine`
115         CONTRIB_DIR="${topdir}/extras/contrib/hosts/${gccmachine}"
116       fi
117   ])
118   AC_MSG_CHECKING([for libs in ${CONTRIB_DIR}])
119   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
120     AC_MSG_RESULT([yes])
121     AC_SUBST(CONTRIB_DIR)
122     export PATH=${CONTRIB_DIR}/bin:$PATH
123     CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
124     CPPFLAGS_save="${CPPFLAGS_save} -I${CONTRIB_DIR}/include"
125     CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
126     CFLAGS_save="${CFLAGS_save} -I${CONTRIB_DIR}/include"
127     CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
128     CXXFLAGS_save="${CXXFLAGS_save} -I${CONTRIB_DIR}/include"
129     OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
130     OBJCFLAGS_save="${OBJCFLAGS_save} -I${CONTRIB_DIR}/include"
131     if test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"; then
132         export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
133     else
134         export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
135     fi
136     LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
137     LDFLAGS_save="${LDFLAGS_save} -L${CONTRIB_DIR}/lib"
138
139     if test -z "$with_mozilla_sdk_path"; then
140        with_mozilla_sdk_path="${CONTRIB_DIR}/gecko-sdk"
141     fi
142     if test -z "$with_cyberlink_tree"; then
143        with_cyberlink_tree="${CONTRIB_DIR}/src/clinkcc"
144     fi
145
146     if test "${SYS}" = "darwin"; then
147       export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
148       export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
149     elif test "${SYS}" = "beos"; then
150       export LIBRARY_PATH="${CONTRIB_DIR}/lib:$LIBRARY_PATH"
151       export BELIBRARIES="${CONTRIB_DIR}/lib:$BELIBRARIES"
152     fi
153   ],[
154     AC_MSG_RESULT([no])
155     CONTRIB_DIR=""
156   ])
157 ])
158 dnl
159 dnl  Set default values
160 dnl
161 LDFLAGS_vlc="${LDFLAGS}"
162
163 dnl
164 dnl  Check the operating system
165 dnl
166 case "${host_os}" in
167   "")
168     SYS=unknown
169     ;;
170   linux*)
171     SYS=linux
172     ;;
173   bsdi*)
174     SYS=bsdi
175     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
176     VLC_ADD_LIBS([vcd cdda vcdx],[-ldvd])
177     ;;
178   *bsd*)
179     SYS="${host_os}"
180     CFLAGS_save="${CFLAGS_save} -pthread"; CFLAGS="${CFLAGS_save}"
181     case "${host_os}" in
182       freebsd*)
183         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include"
184         CPPFLAGS="${CPPFLAGS_save}"
185         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib"
186         LDFLAGS="${LDFLAGS_save}"
187         ;;
188       openbsd*)
189         CPPFLAGS_save="${CPPFLAGS_save} -I/usr/local/include -I/usr/X11R6/include"
190         CPPFLAGS="${CPPFLAGS_save}"
191         LDFLAGS_save="${LDFLAGS_save} -L/usr/local/lib -L/usr/X11R6/lib/"
192         LDFLAGS="${LDFLAGS_save}"
193         ;;
194     esac
195     ;;
196   darwin*)
197
198     dnl Force gcc "-arch" flag
199     ARCH_flag=""
200     case "${host}" in
201       i386*)
202         ARCH_flag="-arch i386"
203       ;;
204       ppc64*)
205         ARCH_flag="-arch ppc64"
206       ;;
207       ppc*)
208         ARCH_flag="-arch ppc"
209       ;;
210       x86_64*)
211         ARCH_flag="-arch x86_64"
212       ;;
213     esac
214
215     SYS=darwin
216     CFLAGS_save="${CFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CFLAGS="${CFLAGS_save}"
217     CXXFLAGS_save="${CXXFLAGS_save} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"; CXXFLAGS="${CXXFLAGS_save}"
218     CPPFLAGS_save="${CPPFLAGS_save} ${ARCH_flag}"; CPPFLAGS="${CPPFLAGS_save}"
219     OBJCFLAGS_save="${OBJCFLAGS_save} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"; OBJCFLAGS="${OBJCFLAGS_save}"
220     LDFLAGS_save="${LDFLAGS_save} -Wl,-headerpad_max_install_names ${ARCH_flag}"; LDFLAGS="${LDFLAGS_save}"
221     VLC_ADD_LDFLAGS([mkv mp4 motion], [-Wl,-framework,IOKit,-framework,CoreFoundation])
222     VLC_ADD_LDFLAGS([libvlc vlc],[-Wl,-undefined,dynamic_lookup])
223     VLC_ADD_LDFLAGS([avcodec avformat access_avio swscale postproc i420_rgb_mmx x264],[-Wl,-read_only_relocs,suppress])
224     VLC_ADD_CFLAGS([motion],[-fconstant-cfstrings])
225     VLC_ADD_LDFLAGS([libvlccore],[-Wl,-framework,CoreFoundation])
226     AC_ARG_ENABLE(macosx-defaults,
227       AS_HELP_STRING([--enable-macosx-defaults],[Build the default configuration on Mac OS X (default enabled)]))
228     if test "x${enable_macosx_defaults}" != "xno"
229     then
230         echo ""
231         echo "Building with Mac OS X defaults:"
232         with_macosx_version_min="10.5"
233         echo "  Assuming --with-macosx-version-min=10.5"
234         with_macosx_sdk="/Developer/SDKs/MacOSX${with_macosx_version_min}.sdk"
235         echo "  Assuming --with-macosx-sdk=/Developer/SDKs/MacOSX${with_macosx_version_min}.sdk"
236         build_dir=`pwd`
237         echo "  Assuming --prefix=${build_dir}/vlc_install_dir"
238         ac_default_prefix="${build_dir}/vlc_install_dir"
239         enable_faad="yes"
240         echo "  Assuming --enable-faad"
241         enable_flac="yes"
242         echo "  Assuming --enable-flac"
243         enable_theora="yes"
244         echo "  Assuming --enable-theora"
245         enable_shout="yes"
246         echo "  Assuming --enable-shout"
247         enable_vcdx="yes"
248         echo "  Assuming --enable-vcdx"
249         enable_caca="yes"
250         echo "  Assuming --enable-caca"
251         enable_ncurses="yes"
252         echo "  Assuming --enable-ncurses"
253         enable_twolame="yes"
254         echo "  Assuming --enable-twolame"
255         enable_realrtsp="yes"
256         echo "  Assuming --enable-realrtsp"
257         enable_libass="yes"
258         echo "  Assuming --enable-libass"
259         enable_asademux="yes"
260         echo "  Assuming --enable-asademux"
261
262         enable_skins2="no"
263         echo "  Assuming --disable-skins2"
264         enable_xcb="no"
265         echo "  Assuming --disable-xcb"
266     fi
267     dnl
268     dnl  Check for Mac OS X SDK settings
269     dnl
270     AC_ARG_WITH(macosx-sdk,
271        [  --with-macosx-sdk=DIR   compile using the SDK in DIR])
272     if test "${with_macosx_sdk}" != "" ; then
273         CPP="${CPP} -isysroot ${with_macosx_sdk}"
274         CC="${CC} -isysroot ${with_macosx_sdk}"
275         CXX="${CXX} -isysroot ${with_macosx_sdk}"
276         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
277         LD="${LD} -syslibroot ${with_macosx_sdk}"
278     fi
279     AC_ARG_WITH(macosx-version-min,
280        [  --with-macosx-version-min=VERSION compile for MacOSX VERSION and above])
281     if test "${with_macosx_version_min}" != "" ; then
282         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
283         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
284         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
285         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
286         LD="${LD} -macosx_version_min=${with_macosx_version_min}"
287         CFLAGS_save="${CFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CFLAGS="${CFLAGS_save}"
288         CXXFLAGS_save="${CXXFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; CXXFLAGS="${CXXFLAGS_save}"
289         OBJCFLAGS_save="${OBJCFLAGS_save} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"; OBJCFLAGS="${OBJCFLAGS_save}"
290         MACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}
291         export MACOSX_DEPLOYMENT_TARGET
292     fi
293     ;;
294   *mingw32* | *cygwin* | *wince* | *mingwce*)
295     AC_CHECK_TOOL(WINDRES, windres, :)
296     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
297
298     case "${host_os}" in
299       *wince* | *mingwce* | *mingw32ce*)
300         SYS=mingwce
301         dnl Sadly CeGCC still needs non-wince macros
302         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0500' for Windows 2000 APIs.])
303         ;;
304       *mingw32*)
305         SYS=mingw32
306         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0500' for Windows XP APIs.])
307         ;;
308       *cygwin*)
309         dnl Check if we are using the mno-cygwin mode in which case we are
310         dnl actually dealing with a mingw32 compiler.
311         AC_DEFINE([_WIN32_WINNT], 0x0501, [Define to '0x0501' for Windows XP APIs.])
312         AC_EGREP_CPP(yes,
313             [#ifdef WIN32
314              yes
315              #endif],
316             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
317         ;;
318     esac
319
320     if test "${SYS}" = "mingw32"; then
321         # add ws2_32 for closesocket, select, recv
322         VLC_ADD_LIBS([libvlccore],[-lws2_32 -lnetapi32 -lwinmm])
323         VLC_ADD_LDFLAGS([vlc],[-mwindows])
324         VLC_ADD_LIBS([activex mozilla win32text],[-lgdi32])
325         VLC_ADD_LIBS([cdda vcdx sdl_image aout_sdl vout_sdl],[-lwinmm])
326         VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_shout access_output_rtmp sap oldhttp stream_out_standard stream_out_rtp stream_out_raop vod_rtsp access_realrtsp rtp oldrc netsync gnutls growl_udp flac ts audioscrobbler lua remoteosd zvbi audiobargraph_a netsync],[-lws2_32])
327         VLC_ADD_LIBS([filesystem], [-lshlwapi])
328         dnl
329         dnl DEP and ASLR options
330         dnl
331         AC_ARG_ENABLE(peflags,
332           [  --enable-peflags        peflags use (default enabled on Windows)])
333         if test "${enable_peflags}" != "no" ; then
334           AC_CHECK_TOOL(PEFLAGS, peflags, :)
335         fi
336         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
337         ac_default_prefix="`pwd`/_win32"
338         DESTDIR="`pwd`/_win32/"
339     fi
340     if test "${SYS}" = "mingwce"; then
341         # add ws2 for closesocket, select, recv
342         VLC_ADD_LIBS([libvlccore access_http access_mms access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_rtmp sap oldhttp netsync audioscrobbler growl rtp stream_out_standard stream_out_rtp remoteosd ts audiobargraph_a netsync],[-lws2])
343         VLC_ADD_LIBS([libvlccore],[-lmmtimer])
344         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
345         ac_default_prefix="`pwd`/_wince"
346         DESTDIR="`pwd`/_wince/"
347    fi
348     ;;
349   *nto*)
350     SYS=nto
351     ;;
352   solaris*)
353     SYS=solaris
354     ;;
355   hpux*)
356     SYS=hpux
357     ;;
358   beos)
359     SYS=beos
360     CFLAGS_save="${CFLAGS_save} -Wno-multichar"; CFLAGS="${CFLAGS_save}"
361     CXXFLAGS_save="${CXXFLAGS_save} -Wno-multichar"; CXXFLAGS="${CXXFLAGS_save}"
362     VLC_ADD_CXXFLAGS([beos],[])
363     VLC_ADD_LIBS([vlc libvlccore logger],[-lbe])
364     VLC_ADD_LIBS([dvdnav dvdread],[-ldl])
365     VLC_ADD_LIBS([filesystem],[-lpoll])
366     LDFLAGS_save="${LDFLAGS_save} -lintl"; LDFLAGS="${LDFLAGS_save}"
367     dnl Check for BONE
368     if test -f /boot/beos/system/lib/libbind.so; then
369         VLC_ADD_LIBS([filesystem access_ftp access_mms access_output_udp netsync sap libvlccore growl_udp],[-lbind -lsocket])
370     else
371         VLC_ADD_LIBS([filesystem access_ftp access_mms access_output_udp netsync sap libvlccore growl_udp],[-lnet])
372     fi
373     ;;
374   *)
375     SYS="${host_os}"
376     ;;
377 esac
378 AM_CONDITIONAL(HAVE_BEOS, test "${SYS}" = "beos")
379 AM_CONDITIONAL(HAVE_DARWIN, test "${SYS}" = "darwin")
380 AM_CONDITIONAL(HAVE_LINUX, [test "${SYS}" = "linux"])
381 AM_CONDITIONAL(HAVE_WIN32, test "${SYS}" = "mingw32")
382 AM_CONDITIONAL(HAVE_WINCE, test "${SYS}" = "mingwce")
383 AM_CONDITIONAL(USE_PEFLAGS, [test "${enable_peflags}" = "yes"])
384
385 dnl
386 dnl Sadly autoconf doesn't think about testing foo.exe when ask to test
387 dnl for program foo on win32
388
389 case "${build_os}" in
390     cygwin|msys)
391         ac_executable_extensions=".exe"
392     ;;
393     *)
394     ;;
395 esac
396
397 dnl
398 dnl  Libtool
399 dnl  It's very bad, but our former custom system was worst
400 dnl  -- Courmisch
401 dnl
402
403 dnl override platform specific check for dependent libraries
404 dnl otherwise libtool linking of shared libraries will
405 dnl fail on anything other than pass_all.
406 AC_CACHE_VAL(lt_cv_deplibs_check_method,
407     [lt_cv_deplibs_check_method=pass_all])
408
409 AC_DISABLE_STATIC
410 dnl AC_DISABLE_FAST_INSTALL
411 AC_LIBTOOL_DLOPEN
412 AC_LIBTOOL_WIN32_DLL
413 m4_undefine([AC_PROG_F77])
414 m4_defun([AC_PROG_F77],[])
415 AC_PROG_LIBTOOL
416
417 m4_undefine([AC_DEPLIBS_CHECK_METHOD])
418 m4_defun([AC_DEPLIBS_CHECK_METHOD],[])
419
420 lt_cv_deplibs_check_method=pass_all
421
422 AS_IF([test "${enable_shared}" = "no"], [
423   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
424 ])
425
426 dnl
427 dnl Gettext stuff
428 dnl
429 AM_GNU_GETTEXT_VERSION([0.18.1])
430 AM_GNU_GETTEXT([external])
431 VLC_ADD_LIBS([libvlccore vlc], [${LTLIBINTL}])
432
433 dnl
434 dnl Iconv stuff
435 dnl
436 AM_ICONV
437 VLC_ADD_CFLAGS([libvlccore],[${INCICONV}])
438 VLC_ADD_LIBS([libvlccore],[${LTLIBICONV}])
439
440 dnl Check for broken versions of mingw-runtime compatability library
441 AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
442     AC_MSG_CHECKING(for broken mingw-runtime)
443     AC_PREPROC_IFELSE([
444 #include <_mingw.h>
445 #if (__MINGW32_MAJOR_VERSION == 3) && (__MINGW32_MINOR_VERSION < 15)
446 # error Attempting to use mingw-runtime with broken vsnprintf support
447 #endif
448 ], [
449         AC_MSG_RESULT([ok])
450 ], [
451         AC_MSG_RESULT([present])
452         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher!])
453 ])
454     dnl force use of mingw provided c99 *printf over msvcrt
455     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
456     CPPFLAGS_save="${CPPFLAGS_save} -D__USE_MINGW_ANSI_STDIO=1"
457 ])
458
459 dnl Check for the need to include the mingwex lib for mingw32
460 if test "${SYS}" = "mingw32"
461 then
462     AC_CHECK_LIB(mingwex,opendir,
463         AC_CHECK_LIB(mingw32,opendir,,
464             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
465     )
466 fi
467
468 dnl Check for fnative-struct or mms-bitfields support for mingw32
469 if test "${SYS}" = "mingw32"
470 then
471     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
472         [ac_cv_c_mms_bitfields],
473         [CFLAGS="${CFLAGS_save} -mms-bitfields"
474          AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
475     if test "${ac_cv_c_mms_bitfields}" != "no"; then
476         CFLAGS_save="${CFLAGS_save} -mms-bitfields";
477         CXXFLAGS_save="${CXXFLAGS_save} -mms-bitfields";
478     else
479         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
480             [ac_cv_c_fnative_struct],
481             [CFLAGS="${CFLAGS_save} -fnative-struct"
482              AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
483         if test "${ac_cv_c_fnative_struct}" != "no"; then
484             CFLAGS_save="${CFLAGS_save} -fnative-struct";
485             CXXFLAGS_save="${CXXFLAGS_save} -fnative-struct";
486         fi
487     fi
488
489     CFLAGS="${CFLAGS_save}"; CXXFLAGS="${CXXFLAGS_save}"
490 fi
491
492 dnl Check for fvtable-thunks support for mingw32
493 if test "${SYS}" = "mingw32" -a "${CXX}" != ""
494 then
495 AC_LANG_PUSH(C++)
496     AC_CACHE_CHECK([if \$CXX accepts -fvtable-thunks],
497         [ac_cv_cxx_fvtable_thunks],
498         [CXXFLAGS="${CXXFLAGS_save} -Wall -Werror -fvtable-thunks"
499          AC_TRY_COMPILE([],,ac_cv_cxx_fvtable_thunks=yes,
500                         ac_cv_cxx_fvtable_thunks=no)])
501     if test "${ac_cv_cxx_fvtable_thunks}" = "yes"; then
502         CXXFLAGS_mingw32_special="-fvtable-thunks"
503     fi
504
505     CXXFLAGS_save="${CXXFLAGS_save} ${CXXFLAGS_mingw32_special}"; CXXFLAGS="${CXXFLAGS_save}"
506 AC_LANG_POP(C++)
507 fi
508
509 dnl
510 dnl Buggy glibc prevention. Purposedly not cached.
511 dnl See sourceware.org bugs 5058 and 5443.
512 dnl Ubuntu alone has 20 bug numbers for this...
513 dnl
514 AC_MSG_CHECKING(for buggy GNU/libc versions)
515 AC_PREPROC_IFELSE([
516 #include <limits.h>
517 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
518   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
519 # error GNU/libc with dcgettext killer bug!
520 #endif
521 ], [
522   AC_MSG_RESULT([not present])
523 ], [
524   AC_MSG_RESULT([found])
525   AS_IF([test "x${enable_nls}" != "xno" || test "x${enable_mozilla}" != "xno"], [
526     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
527 work-around for this. Check with your distribution vendor on how to update the
528 glibc run-time. Alternatively, build with --disable-nls --disable-mozilla and
529 be sure to not use LibVLC from other applications/wrappers.])
530   ], [
531     AC_DEFINE(DISABLE_BUGGY_GLIBC_CHECK, 1, [Disables runtime check for buggy glibc.])
532   ])
533 ])
534
535 dnl Plugin compilation stuff
536
537 VLC_LIBRARY_SUFFIX
538
539 dnl The -DSYS_FOO flag
540 CPPFLAGS_save="${CPPFLAGS_save} -DSYS_`echo ${SYS} | sed -e 's/-.*//' | tr 'abcdefghijklmnopqrstuvwxyz.' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`"; CPPFLAGS="${CPPFLAGS_save}"
541
542 dnl Check for system libs needed
543 need_libc=false
544
545 dnl Check for usual libc functions
546 AC_CHECK_FUNCS([ctime_r daemon fcntl fdopendir fstatvfs fork getenv getpwuid_r gettimeofday isatty lstat memalign openat posix_fadvise posix_madvise posix_memalign setenv setlocale stricmp strnicmp tdestroy uselocale])
547 AC_REPLACE_FUNCS([asprintf atof atoll getcwd getdelim getpid gmtime_r lldiv localtime_r nrand48 rewind strcasecmp strcasestr strdup strlcpy strncasecmp strndup strnlen strsep strtof strtok_r strtoll swab vasprintf])
548 AC_CHECK_FUNCS(fdatasync,,
549   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
550 ])
551
552 dnl Check for non-standard system calls
553 AC_CHECK_FUNCS([accept4 dup3 eventfd vmsplice sched_getaffinity])
554
555 AH_BOTTOM([#include <vlc_fixups.h>])
556
557 AC_CHECK_FUNCS(mmap, [VLC_ADD_PLUGIN([access_mmap])])
558
559 SOCKET_LIBS=""
560 AC_CHECK_FUNCS(connect,,[
561   AC_CHECK_LIB(socket,connect,[
562     VLC_ADD_LIBS([libvlccore cdda],-lsocket)
563     SOCKET_LIBS="-lsocket"
564   ])
565 ])
566 AC_SUBST(SOCKET_LIBS)
567
568 AC_CHECK_FUNCS(send,,[
569   AC_CHECK_LIB(socket,send,[
570     VLC_ADD_LIBS([access_http access_mms access_udp access_tcp access_ftp access_rtmp sap access_output_udp access_output_rtmp stream_out_standard growl_udp remoteosd netsync],[-lsocket])
571   ])
572 ])
573
574
575 dnl Check for socklen_t
576 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
577 AC_CACHE_CHECK([for socklen_t in sys/socket.h],
578 ac_cv_type_socklen_t,
579 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
580 [#include <sys/types.h>
581 #ifdef WIN32
582 # include <winsock2.h>
583 # include <ws2tcpip.h>
584 #else
585 # include <sys/socket.h>
586 #endif]], [[socklen_t len; len = 0;]])],
587 ac_cv_type_socklen_t=yes,
588 ac_cv_type_socklen_t=no)])
589 AS_IF([test "$ac_cv_type_socklen_t" = no],
590  [AC_DEFINE(socklen_t, int)])
591
592 dnl Check for struct sockaddr_storage
593 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.])
594 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.])
595 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
596   [AC_TRY_COMPILE(
597     [#include <sys/types.h>
598      #if defined( UNDER_CE )
599      # include <winsock2.h>
600      #elif defined( WIN32 )
601      # include <winsock2.h>
602      #else
603      # include <sys/socket.h>
604      #endif], [struct sockaddr_storage addr;],
605      ac_cv_struct_sockaddr_storage=yes,
606      ac_cv_struct_sockaddr_storage=no)])
607 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
608   AC_DEFINE(sockaddr_storage, sockaddr)
609   AC_DEFINE(ss_family, sa_family)
610 ])
611
612 dnl getaddrinfo, getnameinfo and gai_strerror check
613 dnl  -lnsl and -lsocket are needed on Solaris;
614 dnl  we purposedly make the test fail on Windows
615 LIBS_save="${LIBS}"
616 AC_SEARCH_LIBS([getaddrinfo], [nsl],,, [${SOCKET_LIBS}])
617 LIBS="${LIBS_save}"
618
619 dnl Check for va_copy
620 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
621   AC_TRY_LINK(
622     [#include <stdarg.h>],
623     [va_list ap1, ap2; va_copy(ap1,ap2);],
624     [ac_cv_c_va_copy="yes"],
625     [ac_cv_c_va_copy="no"]))
626 if test "${ac_cv_c_va_copy}" = "yes"; then
627   AC_DEFINE(HAVE_VA_COPY, 1, [Define if <stdarg.h> defines va_copy.])
628 fi
629 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
630   AC_TRY_LINK(
631     [#include <stdarg.h>],
632     [va_list ap1, ap2; __va_copy(ap1,ap2);],
633     [ac_cv_c___va_copy="yes"],
634     [ac_cv_c___va_copy="no"]))
635 if test "${ac_cv_c___va_copy}" = "yes"; then
636   AC_DEFINE(HAVE___VA_COPY, 1, [Define if <stdarg.h> defines __va_copy.])
637 fi
638
639 AC_CHECK_FUNCS(inet_aton,,[
640   AC_CHECK_LIB(resolv,inet_aton,[
641     VLC_ADD_LIBS([libvlccore],[-lresolv])
642   ])
643 ])
644
645 dnl FreeBSD has a gnugetopt library for this:
646 GNUGETOPT_LIBS=""
647 AC_CHECK_FUNC(getopt_long,, [
648   AC_CHECK_LIB([gnugetopt],[getopt_long], [
649     GNUGETOPT_LIBS="-lgnugetopt"
650   ])
651 ])
652 AC_SUBST(GNUGETOPT_LIBS)
653
654 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
655 AC_CHECK_LIB(m,cos,[
656   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom visual panoramix rotate noise grain scene kate flac lua chorus_flanger],[-lm])
657 ])
658 AC_CHECK_LIB(m,pow,[
659   VLC_ADD_LIBS([avcodec avformat access_avio swscale postproc ffmpegaltivec i420_rgb faad twolame equalizer spatializer param_eq libvlccore freetype mod mpc dmo quicktime realvideo qt4],[-lm])
660 ])
661 AC_CHECK_LIB(m,sqrt,[
662   VLC_ADD_LIBS([headphone_channel_mixer normvol audiobargraph_a speex mono colorthres extract ball],[-lm])
663 ])
664 AC_CHECK_LIB(m,ceil,[
665   VLC_ADD_LIBS([access_imem hotkeys mosaic swscale_omap],[-lm])
666 ])
667 AC_CHECK_LIB(m,exp,[
668   VLC_ADD_LIBS([gaussianblur],[-lm])
669 ])
670 AC_CHECK_LIB(m,round,[
671   VLC_ADD_LIBS([dbus],[-lm])
672 ])
673 AC_CHECK_LIB(m,sqrtf,[
674   VLC_ADD_LIBS([x264],[-lm])
675 ])
676 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
677
678 AC_CHECK_LIB(m,lrintf, [
679   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
680   VLC_ADD_LIBS([skins2],[-lm])
681 ])
682
683 dnl Check for dynamic plugins
684 ac_cv_have_plugins=no
685
686 # HP-UX style
687 if test "${ac_cv_have_plugins}" = "no"; then
688   AC_CHECK_HEADERS(dl.h)
689   ac_cv_my_have_shl_load=no
690   AC_CHECK_FUNC(shl_load,
691    [ac_cv_my_have_shl_load=yes,
692     AC_CHECK_LIB(dld, shl_load,
693      [ac_cv_my_have_shl_load=yes
694       VLC_ADD_LIBS([libvlccore],[-ldld])])])
695   if test "${ac_cv_my_have_shl_load}" = "yes"; then
696     AC_DEFINE(HAVE_DL_SHL_LOAD, 1, [Define if you have the shl_load API])
697     ac_cv_have_plugins=yes
698   fi
699 fi
700
701 # Win32 style
702 if test "${ac_cv_have_plugins}" = "no"; then
703   if test "${SYS}" = "mingw32" ; then
704     AC_CHECK_LIB(kernel32, main,
705      [VLC_ADD_LIBS([libvlccore],[-lkernel32])
706       AC_DEFINE(HAVE_DL_WINDOWS, 1, [Define if you have Windows' LoadLibrary])
707       ac_cv_have_plugins=yes])
708   fi
709 fi
710
711 # WinCE style
712 if test "${ac_cv_have_plugins}" = "no"; then
713   if test "${SYS}" = "mingwce"; then
714     AC_DEFINE(HAVE_DL_WINDOWS, 1, [Define if you have Windows' LoadLibrary])
715     ac_cv_have_plugins=yes
716   fi
717 fi
718
719 # BeOS style
720 if test "${ac_cv_have_plugins}" = "no"; then
721   AC_CHECK_HEADERS(image.h)
722   AC_CHECK_FUNCS(load_add_on,
723    [AC_DEFINE(HAVE_DL_BEOS, 1, [Define if you have the BeOS dl])
724     ac_cv_have_plugins=yes])
725 fi
726
727 # Only test for dlopen() if the others didn't work
728 LIBDL=""
729 if test "${ac_cv_have_plugins}" = "no" -o "${SYS}" = "darwin"; then
730   AC_CHECK_HEADERS(dlfcn.h sys/dl.h)
731   ac_cv_my_have_dlopen=no
732   AC_CHECK_FUNC(dlopen, [
733     ac_cv_my_have_dlopen=yes
734   ], [
735     AC_CHECK_LIB(dl, dlopen, [
736       ac_cv_my_have_dlopen=yes
737       LIBDL="-ldl"
738     ], [
739       AC_CHECK_LIB(svld, dlopen, [
740         ac_cv_my_have_dlopen=yes
741         LIBDL="-lsvld"
742       ])
743     ])
744   ])
745   if test "${ac_cv_my_have_dlopen}" = "yes"; then
746     AC_DEFINE(HAVE_DL_DLOPEN, 1, [Define if you have the dlopen API])
747     ac_cv_have_plugins=yes
748     VLC_ADD_LIBS([libvlccore realvideo lua],[$LIBDL])
749   fi
750 fi
751 AC_SUBST(LIBDL)
752
753 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
754 dnl Check for pthreads - borrowed from XMMS
755 THREAD_LIB=error
756 if test "${THREAD_LIB}" = "error"; then
757   AC_CHECK_LIB(pthread,main,THREAD_LIB="-lpthread")
758 fi
759 if test "${THREAD_LIB}" = "error"; then
760   AC_CHECK_LIB(pthreads,main,THREAD_LIB="-lpthreads")
761 fi
762 if test "${THREAD_LIB}" = "error"; then
763   AC_CHECK_LIB(c_r,main,THREAD_LIB="-lc_r")
764 fi
765 if test "${THREAD_LIB}" = "error"; then
766   AC_CHECK_FUNCS(pthread_mutex_lock)
767   THREAD_LIB=""
768 fi
769
770 VLC_ADD_LIBS([libvlccore libvlc vlc plugin],[${THREAD_LIB}])
771
772 AC_CHECK_LIB(rt, clock_nanosleep, [
773   VLC_ADD_LIBS([libvlccore],[-lrt])
774   AC_DEFINE(HAVE_CLOCK_NANOSLEEP, 1, [Define to 1 if you have clock_nanosleep.])
775 ], [
776   dnl HP/UX port
777   AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
778 ])
779
780 have_nanosleep=false
781 AC_CHECK_FUNCS(nanosleep,have_nanosleep=:,[
782   AC_CHECK_LIB(rt,nanosleep,
783     [VLC_ADD_LIBS([libvlccore],[-lrt]) have_nanosleep=:],
784     [AC_CHECK_LIB(posix4,nanosleep,
785         [VLC_ADD_LIBS([libvlccore],[-lposix4]) have_nanosleep=:])]
786   )
787 ])
788 if ${have_nanosleep}; then
789   AC_DEFINE(HAVE_NANOSLEEP, 1, [Define if nanosleep is available.])
790 fi
791 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
792
793 dnl Check for misc headers
794 AC_MSG_CHECKING(for strncasecmp in strings.h)
795 AC_EGREP_HEADER(strncasecmp,strings.h,[
796   AC_MSG_RESULT(yes)
797   AC_DEFINE(STRNCASECMP_IN_STRINGS_H, 1,
798             Define if <strings.h> defines strncasecmp.)],[
799   AC_MSG_RESULT(no)])
800
801 dnl Check for headers
802 AC_CHECK_HEADERS(getopt.h strings.h locale.h xlocale.h)
803 AC_CHECK_HEADERS(fcntl.h sys/time.h sys/ioctl.h sys/stat.h)
804 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h netinet/udplite.h sys/eventfd.h])
805 AC_CHECK_HEADERS([net/if.h], [], [],
806   [
807     #include <sys/types.h>
808     #include <sys/socket.h>
809   ])
810 AC_CHECK_HEADERS([sys/mount.h], [], [],
811   [
812     #include <sys/param.h>
813   ])
814 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
815 AC_CHECK_HEADERS(machine/param.h sys/shm.h)
816 AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
817 AC_CHECK_HEADERS(syslog.h)
818 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
819
820 dnl LP64 adn LLP64 architectures had better define ssize_t by themselves...
821 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.])
822 AC_CHECK_TYPE(ssize_t,, [
823   AC_DEFINE(ssize_t, int)
824 ])
825
826 dnl Check for poll
827 AC_SEARCH_LIBS(poll, [poll], [AC_DEFINE(HAVE_POLL, 1, [Define to 1 if the OS is usabl... err, has poll().])], [
828 if test ${SYS} != "mingw32" -a ${SYS} != "mingwce"
829 then
830     AC_MSG_WARN([Your platform does not support poll(). VLC has it's own poll() implementation, but it is only intended to be used on Windows. VLC might crash or be insecure when you see this message. Either switch to an OS with a proper poll() implementation, or implement one for your OS in VLC])
831 fi
832 ])
833
834 dnl Mac OS X and other OSes don't have declaration for nanosleep
835 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
836 AC_MSG_CHECKING(for nanosleep in time.h)
837 AC_EGREP_HEADER(nanosleep,time.h,[
838   AC_MSG_RESULT(yes)
839   AC_DEFINE(HAVE_DECL_NANOSLEEP, 1,
840             Define if <time.h> defines nanosleep.)
841 ],[
842   AC_MSG_RESULT(no)
843 ])
844 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
845
846 dnl Make sure we have timespecs
847 AC_MSG_CHECKING(for timespec in sys/time.h)
848 AC_EGREP_HEADER(timespec,sys/time.h,[
849   AC_MSG_RESULT(yes)
850   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
851             Define if <sys/time.h> defines struct timespec.)
852 ],[
853   AC_MSG_RESULT(no)
854 ])
855
856 dnl Check for threads library
857 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
858 AC_CHECK_HEADERS(pthread.h)
859 fi # end "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
860
861 dnl It seems that autoconf detects pkg-config only during the first
862 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
863 dnl it is nested within a conditional block, so it was not working right.
864 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
865 AC_ARG_VAR(PKG_CONFIG_PATH,
866            [Paths where to find .pc not at the default location])
867 PKG_PROG_PKG_CONFIG()
868
869 dnl On some OS we need static linking 
870        AS_IF([test -n "${PKG_CONFIG}" ],[
871               AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce" -o "${SYS}" = "darwin" ],[
872                   PKG_CONFIG="${PKG_CONFIG} --static"
873               ])
874        ])
875
876
877 dnl
878 dnl Check for zlib.h and -lz along with system -lminizip if available
879 dnl 
880 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
881 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
882 if test "${have_zlib}" = "yes"
883 then
884   VLC_ADD_LIBS([access_http gme mp4 skins2 sap mkv unzip zip],[-lz])
885   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
886     AC_CHECK_HEADERS([unzip.h], [ 
887       have_minizip=yes
888       MINIZIP_LIBS="-lminizip -lz"
889     ], [
890       have_minizip=no
891       MINIZIP_CFLAGS="-I\\\${top_srcdir}/libs/unzip"
892       MINIZIP_LIBS="\\\${top_builddir}/libs/unzip/libunzip.la"
893     ])
894   ])
895   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
896   VLC_ADD_CFLAGS([zip],[$MINIZIP_CFLAGS])
897   VLC_ADD_LIBS([skins2 zip],[$MINIZIP_LIBS])
898   VLC_ADD_PLUGIN([unzip zip])
899 fi
900 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
901
902
903 dnl Manual switch for UTF-8
904 AC_ARG_ENABLE(non-utf8,
905   [  --enable-non-utf8       Legacy non-UTF-8 systems support (default disabled)],, [
906   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"], [
907     enable_non_utf8="no"
908   ])
909 ])
910 AS_IF([test "${enable_non_utf8}" != "no"], [
911   AC_DEFINE([ASSUME_UTF8], [1],
912             [Define to 1 if the operating system uses UTF-8 internally])
913 ])
914
915
916 dnl Check for dbus
917 AC_ARG_ENABLE(dbus,
918   [  --enable-dbus           Linux D-BUS message bus system (default enabled)])
919 case "${SYS}" in
920     linux*|*bsd*)
921 if test "${enable_dbus}" != "no" -a "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"
922 then
923   dnl api stable dbus
924   PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0.0,
925     [ AC_DEFINE( HAVE_DBUS, 1, [Define if you have the D-BUS library] )
926       VLC_ADD_LIBS([libvlccore],[$DBUS_LIBS])
927       VLC_ADD_CFLAGS([libvlccore],[$DBUS_CFLAGS])
928       dnl Check for dbus control interface
929         AC_ARG_ENABLE(dbus-control, [  --disable-dbus-control  D-BUS control interface (default enabled)])
930         if test "${enable_dbus_control}" != "no"
931         then
932           VLC_ADD_PLUGIN([dbus])
933           VLC_ADD_LIBS([dbus],[$DBUS_LIBS])
934           VLC_ADD_CFLAGS([dbus],[$DBUS_CFLAGS])
935         fi
936       dnl Check for Telepathy
937         AC_ARG_ENABLE(telepathy,
938           AS_HELP_STRING([--enable-telepathy],[Telepathy Presence plugin through DBus(default enabled)]))
939         if test "${enable_telepathy}" != "no"; then
940           VLC_ADD_PLUGIN([telepathy])
941           VLC_ADD_LIBS([telepathy],[$DBUS_LIBS])
942           VLC_ADD_CFLAGS([telepathy],[$DBUS_CFLAGS])
943         fi
944         dnl Power Management Inhibiter
945         VLC_ADD_PLUGIN([inhibit])
946         VLC_ADD_LIBS([inhibit],[$DBUS_LIBS])
947         VLC_ADD_CFLAGS([inhibit],[$DBUS_CFLAGS])
948     ],
949     [AC_MSG_ERROR([Couldn't find DBus >= 1.0.0, install libdbus-dev ?])]
950   )
951 fi
952 ;;
953 esac
954
955 dnl Check for ntohl, etc.
956 AC_CACHE_CHECK([for ntohl in sys/param.h],
957     [ac_cv_c_ntohl_sys_param_h],
958     [CFLAGS="${CFLAGS_save} -Wall -Werror"
959      AC_TRY_COMPILE([#include <sys/param.h>],
960         [int meuh; ntohl(meuh);],
961         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
962 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
963     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
964 fi
965 CFLAGS="${CFLAGS_save}"
966
967 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
968 RDC_PROG_CC_FLAGS([-pipe])
969
970 dnl Check for various optimization flags
971 AC_CACHE_CHECK([if \$CC accepts -Os],
972     [ac_cv_c_os],
973     [CFLAGS="${CFLAGS_save} -Os"
974      AC_TRY_COMPILE([],,ac_cv_c_os=yes, ac_cv_c_os=no)])
975 if test "${ac_cv_c_os}" != "no"; then
976     CFLAGS_OPTIM_SIZE="${CFLAGS_OPTIM_SIZE} -Os"
977 else
978     AC_CACHE_CHECK([if \$CC accepts -O],
979         [ac_cv_c_o],
980         [CFLAGS="${CFLAGS_save} -O"
981          AC_TRY_COMPILE([],,ac_cv_c_o=yes, ac_cv_c_o=no)])
982     if test "${ac_cv_c_o}" != "no"; then
983         if test "${ac_cv_c_o3}" = "no"; then
984             CFLAGS_OPTIM_SIZE="${CFLAGS_OPTIM_SIZE} -O"
985         fi
986     fi
987 fi
988
989 AC_CACHE_CHECK([if \$CC accepts -O4],
990     [ac_cv_c_o4],
991     [CFLAGS="${CFLAGS_save} -O4"
992      AC_TRY_COMPILE([],,ac_cv_c_o4=yes, ac_cv_c_o4=no)])
993 if test "${ac_cv_c_o4}" != "no" -a "x${enable_debug}" = "xno"; then
994     CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O4"
995 else
996     AC_CACHE_CHECK([if \$CC accepts -O3],
997         [ac_cv_c_o3],
998         [CFLAGS="${CFLAGS_save} -O3"
999          AC_TRY_COMPILE([],,ac_cv_c_o3=yes, ac_cv_c_o3=no)])
1000     if test "${ac_cv_c_o3}" != "no" -a "x${enable_debug}" = "xno"; then
1001         CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O3"
1002     else
1003         AC_CACHE_CHECK([if \$CC accepts -O2],
1004             [ac_cv_c_o2],
1005             [CFLAGS="${CFLAGS_save} -O2"
1006              AC_TRY_COMPILE([],,ac_cv_c_o2=yes, ac_cv_c_o2=no)])
1007         if test "${ac_cv_c_o2}" != "no"; then
1008             CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O2"
1009         else
1010             AC_CACHE_CHECK([if \$CC accepts -O],
1011                 [ac_cv_c_o],
1012                 [CFLAGS="${CFLAGS_save} -O"
1013                  AC_TRY_COMPILE([],,ac_cv_c_o=yes, ac_cv_c_o=no)])
1014             if test "${ac_cv_c_o}" != "no"; then
1015                 CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -O"
1016             fi
1017         fi
1018     fi
1019 fi
1020
1021 AC_CACHE_CHECK([if \$CC accepts -O0],
1022     [ac_cv_c_o0],
1023     [CFLAGS="${CFLAGS_save} -O0"
1024      AC_TRY_COMPILE([],,ac_cv_c_o0=yes, ac_cv_c_o0=no)])
1025 if test "${ac_cv_c_o0}" != "no"; then
1026     CFLAGS_NOOPTIM="${CFLAGS_NOOPTIM} -O0"
1027 fi
1028
1029 dnl Check for -ffast-math
1030 AC_CACHE_CHECK([if \$CC accepts -ffast-math],
1031     [ac_cv_c_fast_math],
1032     [CFLAGS="${CFLAGS_save} -ffast-math"
1033      AC_TRY_COMPILE([],,ac_cv_c_fast_math=yes, ac_cv_c_fast_math=no)])
1034 if test "${ac_cv_c_fast_math}" != "no"; then
1035     CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -ffast-math"
1036 fi
1037
1038 dnl Check for -funroll-loops
1039 dnl Disabled on BeOS because BeOS' gcc is buggy and may crash with it
1040 if test "${SYS}" != "beos"
1041 then
1042   AC_CACHE_CHECK([if \$CC accepts -funroll-loops],
1043       [ac_cv_c_unroll_loops],
1044       [CFLAGS="${CFLAGS_save} -funroll-loops"
1045        AC_TRY_COMPILE([],,ac_cv_c_unroll_loops=yes, ac_cv_c_unroll_loops=no)])
1046   if test "${ac_cv_c_unroll_loops}" != "no"; then
1047       CFLAGS_OPTIM_SPEED="${CFLAGS_OPTIM_SPEED} -funroll-loops"
1048   fi
1049 fi
1050
1051 dnl Check for -fomit-frame-pointer
1052 AC_CACHE_CHECK([if \$CC accepts -fomit-frame-pointer],
1053     [ac_cv_c_omit_frame_pointer],
1054     [CFLAGS="${CFLAGS_save} -fomit-frame-pointer"
1055      AC_TRY_COMPILE([],,ac_cv_c_omit_frame_pointer=yes, ac_cv_c_omit_frame_pointer=no)])
1056 if test "${ac_cv_c_omit_frame_pointer}" != "no"; then
1057  if test "${SYS}" != "darwin"; then
1058     CFLAGS_OPTIM_NODEBUG="${CFLAGS_OPTIM_NODEBUG} -fomit-frame-pointer"
1059  else
1060     dnl On darwin we explicitely disable it.
1061     CFLAGS_OPTIM_NODEBUG="${CFLAGS_OPTIM_NODEBUG} -fno-omit-frame-pointer"
1062  fi
1063 fi
1064
1065 dnl Check for Darwin plugin linking flags
1066 AC_CACHE_CHECK([if \$CC accepts -bundle -undefined error],
1067     [ac_cv_ld_darwin],
1068     [CFLAGS="${CFLAGS_save} -bundle -undefined error"
1069      AC_TRY_COMPILE([],,ac_cv_ld_darwin=yes, ac_cv_ld_darwin=no)])
1070 if test "${ac_cv_ld_darwin}" != "no"; then
1071     VLC_ADD_LDFLAGS([plugin],[-bundle -undefined error])
1072 fi
1073
1074 dnl Checks for __attribute__(aligned()) directive
1075 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1076     [ac_cv_c_attribute_aligned],
1077     [ac_cv_c_attribute_aligned=0
1078         CFLAGS="${CFLAGS_save} -Werror"
1079     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1080         AC_TRY_COMPILE([],
1081         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1082         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1083     done
1084         CFLAGS="${CFLAGS_save}"])
1085 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1086     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1087         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1088 fi
1089
1090 dnl Check for __attribute__((packed))
1091 AC_CACHE_CHECK([for __attribute__((packed))],
1092   [ac_cv_c_attribute_packed],
1093   [ac_cv_c_attribute_packed=no
1094    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1095                     [ac_cv_c_attribute_packed=yes])])
1096 if test "${ac_cv_c_attribute_packed}" != "no"; then
1097   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1098 fi
1099
1100 dnl
1101 dnl  Check the CPU
1102 dnl
1103 case "${host_cpu}" in
1104   "")
1105     ARCH=unknown
1106     ;;
1107   *)
1108     ARCH="${host_cpu}"
1109     ;;
1110 esac
1111
1112 dnl Check for backtrace() support
1113 AC_CHECK_HEADERS(execinfo.h)
1114 AC_CHECK_FUNCS(backtrace)
1115
1116 dnl
1117 dnl  Enable profiling
1118 dnl
1119 AC_ARG_ENABLE(gprof,
1120 [  --enable-gprof          gprof profiling (default disabled)])
1121 AC_ARG_ENABLE(cprof,
1122 [  --enable-cprof          cprof profiling (default disabled)])
1123 test "${enable_gprof}" != "yes" && enable_gprof="no"
1124 test "${enable_cprof}" != "yes" && enable_cprof="no"
1125
1126 dnl
1127 dnl  default modules
1128 dnl
1129 ALIASES="${ALIASES} cvlc rvlc"
1130
1131 dnl
1132 dnl Some plugins aren't useful on some platforms
1133 dnl
1134 if test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce"; then
1135     VLC_ADD_PLUGIN([dynamicoverlay])
1136 elif test "${SYS}" != "mingwce"; then
1137     VLC_ADD_PLUGIN([access_smb dmo globalhotkeys])
1138     VLC_ADD_LIBS([dmo],[-lole32 -luuid])
1139 fi
1140 if test "${SYS}" = "darwin"; then
1141     VLC_ADD_LDFLAGS([quartztext],[-Wl,-framework,ApplicationServices])
1142 fi
1143
1144 dnl
1145 dnl  Accelerated modules
1146 dnl
1147 EXTEND_HELP_STRING([Optimization options:])
1148
1149 dnl  Check for fully working MMX intrinsics
1150 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1151 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1152 AC_ARG_ENABLE(mmx,
1153 [  --disable-mmx           disable MMX optimizations (default auto)],,[
1154   case "${host_cpu}" in
1155     i?86|x86_64)
1156       enable_mmx="yes"
1157       ;;
1158     *)
1159       enable_mmx="no"
1160       ;;
1161   esac
1162 ])
1163 have_mmx="no"
1164 have_mmxext="no"
1165 AS_IF([test "${enable_mmx}" != "no"], [
1166   ARCH="${ARCH} mmx"
1167
1168   AC_CACHE_CHECK([if $CC groks MMX intrinsics],
1169     [ac_cv_c_mmx_intrinsics],
1170     [CFLAGS="${CFLAGS_save} -O -mmmx"
1171      AC_TRY_COMPILE([#include <mmintrin.h>
1172                      #include <stdint.h>
1173                      uint64_t frobzor;],
1174                     [__m64 a, b, c;
1175                      a = b = c = (__m64)frobzor;
1176                      a = _mm_slli_pi16(a, 3);
1177                      a = _mm_adds_pi16(a, b);
1178                      c = _mm_srli_pi16(c, 8);
1179                      c = _mm_slli_pi16(c, 3);
1180                      b = _mm_adds_pi16(b, c);
1181                      a = _mm_unpacklo_pi8(a, b);
1182                      frobzor = (uint64_t)a;],
1183                     [ac_cv_c_mmx_intrinsics=yes],
1184                     [ac_cv_c_mmx_intrinsics=no])])
1185   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1186     AC_DEFINE(HAVE_MMX_INTRINSICS, 1,
1187               [Define to 1 if MMX intrinsics are available.])
1188     MMX_CFLAGS="-mmmx"
1189   ])
1190
1191   AC_CACHE_CHECK([if $CC groks MMX inline assembly],
1192     [ac_cv_mmx_inline],
1193     [CFLAGS="${CFLAGS_save}"
1194      AC_TRY_COMPILE(,[void *p;asm volatile("packuswb %%mm1,%%mm2"::"r"(p));],
1195                     ac_cv_mmx_inline=yes, ac_cv_mmx_inline=no)])
1196   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1197     AC_DEFINE(CAN_COMPILE_MMX, 1,
1198               [Define to 1 inline MMX assembly is available.])
1199     have_mmx="yes"
1200   ])
1201
1202   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1203     [ac_cv_mmxext_inline],
1204     [CFLAGS="${CFLAGS_save}"
1205      AC_TRY_COMPILE(,[void *p;asm volatile("maskmovq %%mm1,%%mm2"::"r"(p));],
1206                     ac_cv_mmxext_inline=yes, ac_cv_mmxext_inline=no)])
1207   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1208     AC_DEFINE(CAN_COMPILE_MMXEXT, 1,
1209               [Define to 1 if MMX EXT inline assembly is available.])
1210     have_mmxext="yes"
1211   ])
1212 ])
1213 AC_SUBST(MMX_CFLAGS)
1214 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1215 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1216
1217 dnl  Check for fully workin SSE2 intrinsics
1218 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1219 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1220 AC_ARG_ENABLE(sse,
1221 [  --disable-sse           disable SSE (1, 2, 3 and 4) optimizations (default auto)],
1222 , [
1223   case "${host_cpu}" in
1224     i686|x86_64)
1225       enable_sse=yes
1226       ;;
1227     *)
1228       enable_sse=no
1229       ;;
1230   esac
1231 ])
1232 have_sse2="no"
1233 AS_IF([test "${enable_sse}" != "no"], [
1234   ARCH="${ARCH} sse sse2"
1235
1236   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics],
1237     [ac_cv_c_sse2_intrinsics],
1238     [CFLAGS="${CFLAGS_save} -O -msse2"
1239      AC_TRY_COMPILE([#include <emmintrin.h>
1240                      #include <stdint.h>
1241                      uint64_t frobzor;],
1242                     [__m128i a, b, c;
1243                      a = b = c = _mm_set1_epi64((__m64)frobzor);
1244                      a = _mm_slli_epi16(a, 3);
1245                      a = _mm_adds_epi16(a, b);
1246                      c = _mm_srli_epi16(c, 8);
1247                      c = _mm_slli_epi16(c, 3);
1248                      b = _mm_adds_epi16(b, c);
1249                      a = _mm_unpacklo_epi8(a, b);
1250                      frobzor = (uint64_t)_mm_movepi64_pi64(a);],
1251                     [ac_cv_c_sse2_intrinsics=yes],
1252                     [ac_cv_c_sse2_intrinsics=no])])
1253   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1254     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1,
1255               [Define to 1 if SSE2 intrinsics are available.])
1256     SSE2_CFLAGS="-msse2"
1257   ])
1258
1259   AC_CACHE_CHECK([if $CC groks SSE inline assembly],
1260     [ac_cv_sse_inline],
1261     [CFLAGS="${CFLAGS_save}"
1262      AC_TRY_COMPILE(,[void *p;asm volatile("xorps %%xmm1,%%xmm2"::"r"(p));],
1263                     ac_cv_sse_inline=yes, ac_cv_sse_inline=no)])
1264   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1265     AC_DEFINE(CAN_COMPILE_SSE, 1,
1266               [Define to 1 if SSE inline assembly is available.])
1267   ])
1268
1269   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly],
1270     [ac_cv_sse2_inline],
1271     [CFLAGS="${CFLAGS_save}"
1272      AC_TRY_COMPILE(,[void *p;asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p));],
1273                     ac_cv_sse2_inline=yes, ac_cv_sse2_inline=no)])
1274   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1275     AC_DEFINE(CAN_COMPILE_SSE2, 1,
1276               [Define to 1 if SSE2 inline assembly is available.])
1277     have_sse2="yes"
1278   ])
1279
1280   # SSE3
1281   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly],
1282     [ac_cv_sse3_inline],
1283     [CFLAGS="${CFLAGS_save}"
1284      AC_TRY_COMPILE(,[void *p;asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p));],
1285                     ac_cv_sse3_inline=yes, ac_cv_sse3_inline=no)])
1286   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1287     AC_DEFINE(CAN_COMPILE_SSE3, 1,
1288               [Define to 1 if SSE3 inline assembly is available.]) ])
1289   # SSSE3
1290   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly],
1291     [ac_cv_ssse3_inline],
1292     [CFLAGS="${CFLAGS_save}"
1293      AC_TRY_COMPILE(,[void *p;asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p));],
1294                     ac_cv_ssse3_inline=yes, ac_cv_ssse3_inline=no)])
1295   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1296     AC_DEFINE(CAN_COMPILE_SSSE3, 1,
1297               [Define to 1 if SSSE3 inline assembly is available.]) ])
1298
1299   # SSE4.1
1300   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1301     [ac_cv_sse4_1_inline],
1302     [CFLAGS="${CFLAGS_save}"
1303      AC_TRY_COMPILE(,[void *p;asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p));],
1304                     ac_cv_sse4_1_inline=yes, ac_cv_sse4_1_inline=no)])
1305   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1306     AC_DEFINE(CAN_COMPILE_SSE4_1, 1,
1307               [Define to 1 if SSE4_1 inline assembly is available.]) ])
1308
1309   # SSE4.2
1310   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1311     [ac_cv_sse4_2_inline],
1312     [CFLAGS="${CFLAGS_save}"
1313      AC_TRY_COMPILE(,[void *p;asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p));],
1314                     ac_cv_sse4_2_inline=yes, ac_cv_sse4_2_inline=no)])
1315   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1316     AC_DEFINE(CAN_COMPILE_SSE4_2, 1,
1317               [Define to 1 if SSE4_2 inline assembly is available.]) ])
1318
1319   # SSE4A
1320   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly],
1321     [ac_cv_sse4a_inline],
1322     [CFLAGS="${CFLAGS_save}"
1323      AC_TRY_COMPILE(,[void *p;asm volatile("insertq %%xmm1,%%xmm0"::"r"(p));],
1324                     ac_cv_sse4a_inline=yes, ac_cv_sse4a_inline=no)])
1325   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1326     AC_DEFINE(CAN_COMPILE_SSE4A, 1,
1327               [Define to 1 if SSE4A inline assembly is available.]) ])
1328 ])
1329 AC_SUBST(SSE2_CFLAGS)
1330 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1331
1332 have_3dnow="no"
1333 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly],
1334     [ac_cv_3dnow_inline],
1335     [CFLAGS="${CFLAGS_save}"
1336      AC_TRY_COMPILE(,[void *p;asm volatile("pfadd %%mm1,%%mm2"::"r"(p));],
1337                     ac_cv_3dnow_inline=yes, ac_cv_3dnow_inline=no)])
1338 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1339   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1340             [Define to 1 if 3D Now! inline assembly is available.])
1341   have_3dnow="yes"
1342 ])
1343 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1344
1345
1346 AC_ARG_ENABLE(neon,
1347 [  --disable-neon          disable NEON optimizations (default auto)],, [
1348   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1349 ])
1350 AS_IF([test "${enable_neon}" != "no"], [
1351   AC_CACHE_CHECK([if $CC groks NEON inline assembly], [ac_cv_neon_inline], [
1352     CFLAGS="${CFLAGS_save} -mfpu=neon"
1353     AC_COMPILE_IFELSE([
1354       AC_LANG_PROGRAM(,[[asm volatile("vqmovun.s64 d0, q1":::"d0");]])
1355     ], [
1356       ac_cv_neon_inline="-mfpu=neon"
1357     ], [
1358       ac_cv_neon_inline="no"
1359     ])
1360     CFLAGS="${CFLAGS_save}"
1361   ])
1362   ARM_NEON_CFLAGS="$ac_cv_neon_inline"
1363 ], [
1364   ac_cv_neon_inline="no"
1365 ])
1366 AC_SUBST(ARM_NEON_CFLAGS)
1367 AM_CONDITIONAL(HAVE_ARM_NEON, [test "${ac_cv_neon_inline}" != "no"])
1368
1369
1370 AC_ARG_ENABLE(altivec,
1371 [  --disable-altivec       disable AltiVec optimizations (default auto)],, [
1372   AS_IF([test "${host_cpu}" = "powerpc"],
1373         [enable_altivec=yes], [enable_altivec=no])
1374 ])
1375 have_altivec="no"
1376 AS_IF([test "${enable_altivec}" = "yes"], [
1377   ARCH="${ARCH} altivec";
1378   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1379     [ac_cv_altivec_inline],
1380     [CFLAGS="${CFLAGS_save}"
1381      AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1382          ac_cv_altivec_inline="yes",
1383          [CFLAGS="${CFLAGS_save} -Wa,-m7400"
1384           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1385             [ac_cv_altivec_inline="-Wa,-m7400"],
1386             ac_cv_altivec_inline=no)
1387          ])])
1388   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1389     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1390               [Define to 1 if AltiVec inline assembly is available.])
1391     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1392       VLC_ADD_CFLAGS([idctaltivec],[${ac_cv_altivec_inline}])
1393       VLC_ADD_CFLAGS([motionaltivec],[${ac_cv_altivec_inline}])
1394       VLC_ADD_CFLAGS([memcpyaltivec],[${ac_cv_altivec_inline}])
1395       VLC_ADD_CFLAGS([i420_yuy2_altivec],[${ac_cv_altivec_inline}])
1396       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1397     ])
1398     have_altivec="yes"
1399   ])
1400
1401 dnl The AltiVec C extensions
1402 dnl
1403 dnl There are several possible cases:
1404 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1405 dnl                      need <altivec.h>
1406 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1407 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1408 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1409 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1410 dnl - Others: test should fail
1411   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1412   [ac_cv_c_altivec],
1413   [# OS X/PPC test (gcc 4.x)
1414    CFLAGS="${CFLAGS_save} -mpim-altivec -force_cpusubtype_ALL"
1415    AC_TRY_COMPILE([vector unsigned char foo;],
1416      [vec_ld(0, (unsigned char *)0);],
1417      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1418      [# OS X/PPC test (gcc 3.x)
1419       CFLAGS="${CFLAGS_save} -faltivec"
1420       AC_TRY_COMPILE([vector unsigned char foo;],
1421         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1422         [ac_cv_c_altivec="-faltivec"],
1423         dnl Below this are the Linux tests
1424         [# Linux/PPC test (gcc 4.x)
1425          CFLAGS="${CFLAGS_save} -maltivec"
1426          AC_TRY_COMPILE([#include <altivec.h>],
1427            [vec_ld(0, (unsigned char *)0);],
1428            [ac_cv_c_altivec="-maltivec"],
1429            [# Linux/PPC test (gcc 3.3)
1430             CFLAGS="${CFLAGS_save} -maltivec -mabi=altivec"
1431             AC_TRY_COMPILE([#include <altivec.h>],
1432               [vec_ld(0, (unsigned char *)0);],
1433               [ac_cv_c_altivec=""
1434                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1435               [# Linux/PPC test (gcc 3.3)
1436                CFLAGS="${CFLAGS_save} -fvec"
1437                AC_TRY_COMPILE([#include <altivec.h>],
1438                  [vec_ld(0, (unsigned char *)0);],
1439                  [ac_cv_c_altivec="-fvec"],
1440                  [ac_cv_c_altivec=no])
1441               ])
1442            ])
1443         ])
1444      ])
1445    CFLAGS="${CFLAGS_save}"
1446   ])
1447   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1448     CPPFLAGS="${CPPFLAGS_save} ${ac_cv_c_altivec}"
1449   ])
1450
1451   AC_CHECK_HEADERS(altivec.h)
1452   CPPFLAGS="${CPPFLAGS_save}"
1453
1454   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1455     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1,
1456               [Define to 1 if C AltiVec extensions are available.])
1457     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1458     VLC_ADD_CFLAGS([idctaltivec motionaltivec],[${ac_cv_c_altivec}])
1459     VLC_ADD_CFLAGS([i420_yuy2_altivec memcpyaltivec deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1460     have_altivec="yes"
1461   ])
1462
1463   AC_CACHE_CHECK([if linker needs -framework vecLib],
1464     [ac_cv_ld_altivec],
1465     [LDFLAGS="${LDFLAGS_vlc} -Wl,-framework,vecLib"
1466      AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)
1467      LDFLAGS="${LDFLAGS_save}"
1468     ])
1469   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1470     VLC_ADD_LDFLAGS([libvlccore idctaltivec motionaltivec memcpyaltivec],[-Wl,-framework,vecLib])
1471   ])
1472 ])
1473 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1474
1475 dnl
1476 dnl  Special arch tuning
1477 dnl
1478 AC_ARG_WITH(tuning,
1479 [  --with-tuning=ARCH      enable special tuning for an architecture
1480                           (default Pentium 2 on IA-32 and G4 on PPC)])
1481 if test -n "${with_tuning}"; then
1482     if test "${with_tuning}" != "no"; then
1483         CFLAGS_TUNING="-mtune=${with_tuning}"
1484     fi
1485 else
1486     if test "${SYS}" = "darwin" -a "${host_cpu}" != "powerpc"; then
1487         CFLAGS_TUNING="-march=prescott -mtune=generic"
1488     elif test "${host_cpu}" = "i686" -o "${host_cpu}" = "i586" -o "${host_cpu}" = "i486" -o "${host_cpu}" = "i386"; then
1489         CFLAGS_TUNING="-mtune=pentium2"
1490     elif test "${host_cpu}" = "x86_64"; then
1491         CFLAGS_TUNING="-mtune=athlon64"
1492     elif test "${host_cpu}" = "powerpc"; then
1493         CFLAGS_TUNING="-mtune=G4";
1494     fi
1495 fi
1496
1497 dnl NOTE: this can't be cached cleanly
1498 AS_IF([test "${CFLAGS_TUNING}"],
1499    [CFLAGS_save="${CFLAGS}"
1500     CFLAGS="${CFLAGS} ${CFLAGS_TUNING}"
1501
1502     AC_MSG_CHECKING([whether $CC accepts ${CFLAGS_TUNING}])
1503     AC_COMPILE_IFELSE([ ],
1504                       [tuning="yes"],
1505                       [CFLAGS_TUNING=""; tuning="no"
1506                        AS_IF([test "${with_tuning}"],
1507                              [AC_MSG_ERROR([requested tuning not supported])])])
1508
1509     AC_MSG_RESULT([$tuning])
1510     CFLAGS="${CFLAGS_save}"
1511 ])
1512
1513 dnl
1514 dnl  Memory usage
1515 dnl
1516 AC_ARG_ENABLE(optimize-memory,
1517 [  --enable-optimize-memory optimize memory usage over performance])
1518 if test "${enable_optimize_memory}" = "yes"; then
1519   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1520 fi
1521
1522 dnl
1523 dnl  Enable/disable optimizations
1524 dnl
1525 AC_ARG_ENABLE(optimizations,
1526 [  --disable-optimizations disable compiler optimizations (default enabled)])
1527 if test "${enable_optimizations}" != "no"; then
1528    if test "${enable_optimize_memory}" = "yes"; then
1529       enable_optimizations="size"
1530    else
1531       enable_optimizations="speed"
1532    fi
1533 fi
1534
1535 dnl
1536 dnl  Debugging mode
1537 dnl
1538 AC_ARG_ENABLE(debug,
1539 [  --enable-debug          debug mode (default disabled)])
1540 test "${enable_debug}" != "yes" && enable_debug="no"
1541 AH_TEMPLATE(NDEBUG,
1542             [Define to 1 if debug code should NOT be compiled])
1543 AS_IF([test "x${enable_debug}" = "xno"], [
1544   AC_DEFINE(NDEBUG)
1545 ], [
1546   AC_CHECK_HEADERS([valgrind/valgrind.h])
1547 ])
1548
1549 dnl
1550 dnl Allow running as root (useful for people running on embedded platforms)
1551 dnl
1552 AC_ARG_ENABLE(run-as-root,
1553 [  --enable-run-as-root    allow running VLC as root (default disabled)])
1554 AS_IF([test "${enable_run_as_root}" = "yes"],[
1555     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1556               [Define to 1 to allow running VLC as root (uid 0).])
1557 ])
1558
1559 dnl
1560 dnl  Test coverage
1561 dnl
1562 AC_ARG_ENABLE(coverage,
1563         [  --enable-coverage       build for test coverage (default disabled)],,
1564         [enable_coverage="no"])
1565 AS_IF([test "${enable_coverage}" != "no"], [
1566         CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
1567         CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
1568         LDFLAGS="-lgcov ${LDFLAGS}"
1569         dnl ugly...
1570         CFLAGS_save="${CFLAGS}"
1571         CXXFLAGS_save="${CXXFLAGS}"
1572         LDFLAGS_save="${LDFLAGS}"
1573 ])
1574
1575 dnl
1576 dnl Stream output
1577 dnl
1578 AC_ARG_ENABLE(sout,
1579   [  --enable-sout           Stream output modules (default enabled)])
1580 AS_IF([test "${enable_sout}" != "no"], [
1581   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1582 ])
1583 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1584
1585 dnl Lua modules
1586 AC_ARG_ENABLE(lua,
1587   AS_HELP_STRING([--enable-lua],[lua playlist, metafetcher and interface
1588                   plugins (default enabled)]))
1589 if test "${enable_lua}" != "no"
1590 then
1591   PKG_CHECK_MODULES(LUA, lua5.1,
1592     [ have_lua=yes ],
1593     [
1594     AC_MSG_WARN([lua5.1 not found, trying lua >= 5.1 instead])
1595     PKG_CHECK_MODULES(LUA, lua >= 5.1,
1596       [ have_lua=yes ],
1597       [
1598         have_lua=yes
1599         AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1600           [],
1601           [ have_lua=no ] )
1602         AC_CHECK_LIB(  lua5.1 , luaL_newstate,
1603           [LUA_LIBS="-llua5.1"],
1604           AC_CHECK_LIB( lua51 , luaL_newstate,
1605             [LUA_LIBS="-llua51"],
1606             AC_CHECK_LIB( lua , luaL_newstate,
1607               [LUA_LIBS="-llua"],
1608               [ have_lua=no
1609               ], [-lm])
1610           )
1611         )
1612       ])
1613     ])
1614   if test "x${have_lua}" = "xyes" ;  then
1615      VLC_ADD_LIBS([lua],[$LUA_LIBS])
1616      VLC_ADD_CFLAGS([lua],[$LUA_CFLAGS])
1617   else
1618       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1619   fi
1620   AC_ARG_VAR([LUAC], [LUA byte compiler])
1621   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1622   AS_IF([test "${LUAC}" = "false"], [
1623     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1624   ])
1625 fi
1626 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1627
1628 dnl
1629 dnl HTTP daemon
1630 dnl
1631 AC_ARG_ENABLE(httpd,
1632   [  --enable-httpd          HTTP daemon (default enabled)])
1633 if test "${enable_httpd}" != "no"
1634 then
1635   VLC_ADD_PLUGIN([oldhttp])
1636   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP dameon support)
1637 fi
1638 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1639
1640 dnl
1641 dnl libproxy support
1642 dnl
1643 AC_ARG_ENABLE(libproxy,
1644   [  --enable-libproxy       libproxy support (default auto)])
1645 AS_IF([test "${enable_libproxy}" != "no"], [
1646   PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0, [
1647     AC_DEFINE(HAVE_LIBPROXY, 1, [Define if libproxy is available])
1648     VLC_ADD_CFLAGS([access_http],[$LIBPROXY_CFLAGS])
1649     VLC_ADD_LIBS([access_http],[$LIBPROXY_LIBS])
1650   ], [
1651     AS_IF([test "x${enable_libproxy}" != "x"], [
1652       AC_MSG_ERROR([libproxy could not be found on your system])
1653     ])
1654   ])
1655 ])
1656
1657
1658 dnl
1659 dnl VideoLAN manager
1660 dnl
1661 AC_ARG_ENABLE(vlm,
1662   [  --enable-vlm            VideoLAN manager (default enabled)],,
1663   [enable_vlm="${enable_sout}"])
1664 AS_IF([test "${enable_vlm}" != "no"], [
1665   AS_IF([test "${enable_sout}" = "no"], [
1666     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1667   ])
1668   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1669 ])
1670 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1671
1672 dnl
1673 dnl Growl notification plugin
1674 dnl
1675 AC_ARG_ENABLE(growl,
1676   [  --enable-growl          growl notification plugin (default disabled)],,
1677   [enable_growl=no])
1678 AS_IF([test "${enable_growl}" != "no"], [
1679     VLC_ADD_PLUGIN([growl_udp])
1680     AC_CHECK_HEADERS(Growl/GrowlDefines.h, [
1681       VLC_ADD_PLUGIN([growl])
1682       VLC_ADD_LDFLAGS([growl], [-Wl,-framework,Growl,-framework,AppKit])
1683       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
1684     ])
1685   ]
1686 )
1687
1688 dnl
1689 dnl Libnotify notification plugin
1690 dnl
1691 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify], [libnotify notification], [auto])
1692
1693 dnl
1694 dnl Taglibplugin
1695 dnl
1696 AC_ARG_ENABLE(taglib,
1697   [  --disable-taglib        Taglib support (default enabled) ])
1698   AS_IF([test "${enable_taglib}" != "no"],[
1699     PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5,
1700       [ VLC_ADD_PLUGIN([taglib])
1701         VLC_ADD_LIBS([taglib],[$TAGLIB_LIBS -lz])
1702         VLC_ADD_CXXFLAGS([taglib],[$TAGLIB_CFLAGS])
1703         AC_LANG_PUSH(C++)
1704         AC_CHECK_HEADERS(taglib/mp4coverart.h)
1705         AC_LANG_POP(C++)
1706       ],
1707       [AC_MSG_WARN(TagLib library not found)])
1708   ])
1709
1710 dnl
1711 dnl  Input plugins
1712 dnl
1713
1714 EXTEND_HELP_STRING([Input plugins:])
1715
1716 dnl  live555 input
1717 dnl
1718 AC_ARG_ENABLE(live555,
1719 [  --enable-live555        live555 RTSP input plugin (default enabled)])
1720 if test "${enable_live555}" != "no"; then
1721   AC_ARG_WITH(live555-tree,
1722     [  --with-live555-tree=PATH live.com tree for static linking])
1723
1724   dnl
1725   dnl test for --with-live555-tree
1726   dnl
1727   if test -z "${with_live555_tree}" -a "${CXX}" != ""; then
1728     AC_LANG_PUSH(C++)
1729     CPPFLAGS_save="${CPPFLAGS}"
1730     if test -z "${CONTRIB_DIR}"; then
1731         CPPFLAGS_live555="-I/usr/include/liveMedia -I/usr/include/groupsock -I/usr/include/BasicUsageEnvironment -I/usr/include/UsageEnvironment"
1732     else
1733         CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1734     fi
1735     if test "${SYS}" = "solaris"; then
1736       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1737     fi
1738     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1739
1740     AC_CHECK_HEADERS(liveMedia_version.hh, [
1741       AC_MSG_CHECKING(for liveMedia version >= 1214895600 )
1742       AC_EGREP_CPP(yes,
1743         [#include <liveMedia_version.hh>
1744          #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1745          #if LIVEMEDIA_LIBRARY_VERSION_INT < 1214895600
1746          yes
1747          #endif
1748          #endif],
1749         [AC_MSG_RESULT([no])
1750          AC_MSG_ERROR([Your version of liveMedia is too old: you may get a more recent one from http://www.live555.com/liveMedia.
1751 lternatively you can use --disable-live555 to disable the liveMedia plugin.])
1752       ],[
1753          AC_MSG_RESULT([yes])
1754          ])
1755     ])
1756      other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1757      other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1758       if test "${SYS}" = "mingw32"; then
1759         # add ws2_32 for closesocket, select, recv
1760         other_libs="$other_libs -lws2_32"
1761       elif test "${SYS}" = "mingwce"; then
1762         # add ws2 for closesocket, select, recv
1763         other_libs="$other_libs -lws2"
1764       fi
1765     dnl We need to check for pic because live555 don't provide shared libs
1766     dnl and we want to build a plugins so we need -fPIC on some arch.
1767     AC_CHECK_HEADERS(liveMedia.hh, [
1768       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1769         AC_CHECK_LIB(liveMedia_pic, main, [
1770           VLC_ADD_PLUGIN([live555])
1771          VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1772          ],[
1773         AC_CHECK_LIB(liveMedia, main, [
1774           VLC_ADD_PLUGIN([live555])
1775           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1776         ],[],[${other_libs}]) ],[${other_libs_pic}])
1777     ],[
1778        AC_MSG_WARN([The development files for liveMedia (live555) can't be found])
1779     ])
1780     CPPFLAGS="${CPPFLAGS_save}"
1781     AC_LANG_POP(C++)
1782   else
1783     AC_MSG_CHECKING(for liveMedia/libliveMedia.a in ${with_live555_tree})
1784     real_live555_tree="`cd ${with_live555_tree} 2>/dev/null && pwd`"
1785     if test -z "${real_live555_tree}"; then
1786       dnl  The given directory can't be found
1787       AC_MSG_RESULT(no)
1788       AC_MSG_ERROR([cannot cd to ${with_live555_tree}])
1789     fi
1790     if test -f "${real_live555_tree}/liveMedia/libliveMedia.a"; then
1791       AC_MSG_RESULT(${real_live555_tree}/liveMedia/libliveMedia.a)
1792
1793       AC_CHECK_HEADERS(${real_live555_tree}/liveMedia/include/liveMedia_version.hh,[
1794         AC_MSG_CHECKING(for liveMedia version >= 1214895600 )
1795         AC_EGREP_CPP(yes,
1796           [#include "${real_live555_tree}/liveMedia/include/liveMedia_version.hh"
1797            #ifdef LIVEMEDIA_LIBRARY_VERSION_INT
1798            #if LIVEMEDIA_LIBRARY_VERSION_INT < 1214895600
1799            yes
1800            #endif
1801            #endif],
1802           [AC_MSG_RESULT([no])
1803            AC_MSG_ERROR([Your version of liveMedia is too old: you may get a more recent one from http://www.live555.com/liveMedia.
1804 lternatively you can use --disable-live555 to disable the liveMedia plugin.])
1805         ],[
1806            AC_MSG_RESULT([yes])
1807            ])
1808       ])
1809
1810       VLC_ADD_PLUGIN([live555])
1811
1812       if test "${SYS}" = "mingw32"; then
1813         # add ws2_32 for closesocket, select, recv
1814         VLC_ADD_LIBS([live555],[-lws2_32])
1815       fi
1816
1817       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/UsageEnvironment -lUsageEnvironment])
1818       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/BasicUsageEnvironment -lBasicUsageEnvironment])
1819       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/groupsock -lgroupsock])
1820       VLC_ADD_LIBS([live555],[-L${real_live555_tree}/liveMedia -lliveMedia])
1821
1822       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/BasicUsageEnvironment/include])
1823       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/groupsock/include])
1824       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/liveMedia/include])
1825       VLC_ADD_CXXFLAGS([live555],[-I${real_live555_tree}/UsageEnvironment/include ])
1826       if test "${SYS}" = "solaris"; then
1827         VLC_ADD_CXXFLAGS([live555],[-DSOLARIS])
1828       fi
1829     else
1830       dnl  The given live555 wasn't built
1831         AC_MSG_RESULT(no)
1832       if test "${enable_live555}" = "yes"; then
1833         AC_MSG_ERROR([cannot find ${real_live555_tree}/liveMedia/libliveMedia.a, make sure you compiled live555 in ${with_live555_tree}])
1834       fi        
1835     fi
1836   fi
1837 fi
1838
1839 dnl
1840 dnl - special access module for dc1394 input
1841 dnl - dv module: digital video module check for libraw1394
1842 dnl
1843 PKG_ENABLE_MODULES_VLC([DC1394], [], [libraw1394 >= 2.0.1 libdc1394-2 >= 2.1.0], [dc1394 access module], [auto])
1844 PKG_ENABLE_MODULES_VLC([DV], [access_dv], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV input module], [auto])
1845
1846 dnl
1847 dnl dvdread module: check for libdvdread
1848 dnl
1849 AC_ARG_ENABLE(dvdread,
1850 [  --enable-dvdread        dvdread input module (default enabled)])
1851 if test "${enable_dvdread}" != "no"
1852 then
1853   AC_ARG_WITH(dvdread,
1854   [  --with-dvdread=PATH     libdvdread headers and libraries])
1855   AC_ARG_WITH(dvdread-tree,
1856   [  --with-dvdread-tree=PATH libdvdread tree for static linking])
1857
1858   dnl prepend -ldvdcss on OS that need it
1859   AS_CASE(["${SYS}"], [mingw32|darwin|beos], [VLC_ADD_LIBS([dvdread], [-ldvdcss])])
1860
1861   if test -z "${with_dvdread}"
1862   then
1863     if test -z "${with_dvdread_tree}"
1864     then
1865       AC_CHECK_HEADERS(dvdread/dvd_reader.h,
1866         [ VLC_ADD_PLUGIN([dvdread])
1867           VLC_ADD_LIBS([dvdread],[-ldvdread])
1868         ],[
1869           AC_CHECK_HEADERS(libdvdread/dvd_reader.h,
1870             [ VLC_ADD_PLUGIN([dvdread])
1871               VLC_ADD_LIBS([dvdread],[-ldvdread])
1872             ],[
1873               if test -n "${enable_dvdread}"
1874               then
1875               AC_MSG_ERROR([cannot find libdvdread headers])
1876              fi
1877            ])
1878         ])
1879     else
1880       AC_MSG_CHECKING(for libdvdread.a in ${with_dvdread_tree})
1881       real_dvdread_tree="`cd ${with_dvdread_tree} 2>/dev/null && pwd`"
1882       if test -z "${real_dvdread_tree}"
1883       then
1884         dnl  The given directory can't be found
1885         AC_MSG_RESULT(no)
1886         AC_MSG_ERROR([cannot cd to ${with_dvdread_tree}])
1887       fi
1888       if test -f "${real_dvdread_tree}/dvdread/.libs/libdvdread.a"
1889       then
1890         dnl  Use a custom libdvdread
1891         AC_MSG_RESULT(${real_dvdread_tree}/dvdread/.libs/libdvdread.a)
1892         VLC_ADD_PLUGIN([dvdread])
1893         VLC_ADD_LIBS([dvdread],[-L${real_dvdread_tree}/dvdread/.libs -ldvdread])
1894         VLC_ADD_CPPFLAGS([dvdread],[-I${real_dvdread_tree}])
1895       else
1896         dnl  The given libdvdread wasn't built
1897         AC_MSG_RESULT(no)
1898         AC_MSG_ERROR([cannot find ${real_dvdread_tree}/dvdread/.libs/libdvdread.a, make sure you compiled libdvdread in ${with_dvdread_tree}])
1899       fi
1900     fi
1901   else
1902     AC_MSG_CHECKING(for dvdread headers in ${with_dvdread})
1903     if test -f ${with_dvdread}/include/dvdread/dvd_reader.h
1904     then
1905       dnl  Use ${with_dvdread}/include/dvdread/dvd_reader.h
1906       AC_MSG_RESULT(yes)
1907       VLC_ADD_PLUGIN([dvdread])
1908       VLC_ADD_LIBS([dvdread],[-L${with_dvdread}/lib -ldvdread])
1909       VLC_ADD_CPPFLAGS([dvdread],[-I${with_dvdread}/include])
1910     else
1911       dnl  No libdvdread could be found, sorry
1912       AC_MSG_RESULT(no)
1913       AC_MSG_ERROR([cannot find ${with_dvdread}/include/dvdread/dvd_reader.h])
1914     fi
1915   fi
1916
1917   dnl append -ldvd on OS that need it
1918   AS_CASE(["${SYS}"], [bsdi], [VLC_ADD_LIBS([dvdread], [-ldvd])])
1919 fi
1920
1921 dnl
1922 dnl  libdvdnav plugin
1923 dnl
1924 AC_ARG_ENABLE(dvdnav,
1925   [  --enable-dvdnav         dvdnav input module (default enabled)])
1926 if test "${enable_dvdnav}" != "no"
1927 then
1928   dnl prepend -ldvdcss on OS that need it
1929   AS_CASE(["${SYS}"], [mingw32|darwin|beos], [VLC_ADD_LIBS([dvdnav], [-ldvdcss])])
1930
1931   DVDNAV_PATH="${PATH}"
1932   AC_ARG_WITH(dvdnav-config-path,
1933     [  --with-dvdnav-config-path=PATH dvdnav-config path (default search in \$PATH)],
1934     [ if test "${with_dvdnav_config_path}" != "no"
1935       then
1936         DVDNAV_PATH="${with_dvdnav_config_path}:${PATH}"
1937       fi ])
1938   AC_PATH_PROG(DVDNAV_CONFIG, dvdnav-config, no, ${DVDNAV_PATH})
1939   if test "${DVDNAV_CONFIG}" != "no"
1940   then
1941     VLC_ADD_PLUGIN([dvdnav])
1942     VLC_ADD_CFLAGS([dvdnav],[`${DVDNAV_CONFIG} --cflags`])
1943     VLC_ADD_LIBS([dvdnav],[`${DVDNAV_CONFIG} --libs`])
1944     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1945                 AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1946                 [], [${LIBS_dvdnav}])
1947   fi
1948 fi
1949
1950 dnl
1951 dnl  Windows DirectShow access module
1952 dnl
1953 AC_ARG_ENABLE(dshow,
1954   [  --enable-dshow          Win32 DirectShow support (default enabled on Win32)])
1955 if test "${enable_dshow}" != "no"
1956 then
1957   if test "${SYS}" = "mingw32"
1958   then
1959     AC_LANG_PUSH(C++)
1960       AC_CHECK_HEADERS(dshow.h,
1961       [ VLC_ADD_PLUGIN([dshow])
1962         VLC_ADD_CXXFLAGS([dshow],[])
1963         VLC_ADD_LIBS([dshow],[-lole32 -loleaut32 -luuid]) ])
1964     AC_LANG_POP(C++)
1965   fi
1966 fi
1967
1968 dnl
1969 dnl  Windows DirectShow BDA access module
1970 dnl
1971 AC_ARG_ENABLE(bda,
1972   AS_HELP_STRING([--enable-bda],[Win32 DirectShow BDA support (default
1973                   enabled on Win32)]))
1974 if test "${enable_bda}" != "no"
1975 then
1976   if test "${SYS}" = "mingw32"
1977   then
1978       AC_CHECK_HEADERS(dshow.h,
1979       [ VLC_ADD_PLUGIN([bda])
1980         VLC_ADD_CXXFLAGS([bda],[])
1981         VLC_ADD_LIBS([bda],[-lstrmiids -lole32 -loleaut32 -luuid]) ])
1982   fi
1983 fi
1984
1985
1986 dnl
1987 dnl  OpenCV wrapper and example filters
1988 dnl
1989 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example], [opencv], (OpenCV (computer vision) filter), [off])
1990
1991
1992 dnl
1993 dnl  libsmbclient plugin
1994 dnl
1995 AC_ARG_ENABLE(smb,
1996   [  --enable-smb            smb input module (default enabled)])
1997 if test "${enable_smb}" != "no"; then
1998   AC_CHECK_HEADERS(libsmbclient.h,
1999     [ VLC_ADD_PLUGIN([access_smb])
2000       VLC_ADD_LIBS([access_smb],[-lsmbclient]) ],
2001     [ if test -n "${enable_smb}"; then
2002         AC_MSG_ERROR([cannot find libsmbclient headers])
2003      fi ])
2004 fi
2005
2006
2007 dnl
2008 dnl sftp access support
2009 dnl
2010 AC_ARG_ENABLE(sftp,
2011   [  --enable-sftp           sftp input access module (default disable)])
2012 if test "${enable_sftp}" = "yes"; then
2013   AC_CHECK_HEADERS(libssh2.h, [
2014     VLC_ADD_PLUGIN([access_sftp])
2015     VLC_ADD_LIBS([access_sftp], [-lssh2])
2016   ])
2017 fi
2018
2019 dnl
2020 dnl  libdvbpsi ts demux/mux
2021 dnl
2022 AC_ARG_ENABLE(dvbpsi,
2023   [  --enable-dvbpsi         dvbpsi ts mux and demux module (default enabled)])
2024 have_dvbpsi=no
2025 if test "${enable_dvbpsi}" != "no"
2026 then
2027   AC_ARG_WITH(dvbpsi,
2028   [  --with-dvbpsi=PATH      libdvbpsi headers and libraries])
2029   AC_ARG_WITH(dvbpsi,
2030   [  --with-dvbpsi-tree=PATH libdvbpsi tree for static linking])
2031   case "${with_dvbpsi}" in
2032   ""|yes)
2033     if test -z "${with_dvbpsi_tree}"
2034     then
2035       AC_CHECK_HEADERS(dvbpsi/dr.h,
2036         [ VLC_ADD_PLUGIN([ts])
2037           if test "${enable_sout}" != "no"; then
2038             VLC_ADD_PLUGIN([mux_ts])
2039           fi
2040           VLC_ADD_LIBS([mux_ts ts dvb],[-ldvbpsi])
2041           have_dvbpsi=yes],
2042         [  AC_MSG_WARN([cannot find libdvbpsi headers]) ],
2043         [#if defined( HAVE_STDINT_H )
2044 #   include <stdint.h>
2045 #elif defined( HAVE_INTTYPES_H )
2046 #   include <inttypes.h>
2047 #endif
2048 #include <dvbpsi/dvbpsi.h>
2049 #include <dvbpsi/descriptor.h>
2050 #include <dvbpsi/pat.h>
2051 #include <dvbpsi/pmt.h>])
2052     else
2053       AC_MSG_CHECKING(for libdvbpsi.a in ${with_dvbpsi_tree})
2054       real_dvbpsi_tree="`cd ${with_dvbpsi_tree} 2>/dev/null && pwd`"
2055       if test -z "${real_dvbpsi_tree}"
2056       then
2057         dnl  The given directory can't be found
2058         AC_MSG_RESULT(no)
2059         AC_MSG_ERROR([cannot cd to ${with_dvbpsi_tree}])
2060       fi
2061       if test -f "${real_dvbpsi_tree}/src/.libs/libdvbpsi.a"
2062       then
2063         dnl  Use a custom libdvbpsi
2064         AC_MSG_RESULT(${real_dvbpsi_tree}/src/.libs/libdvbpsi.a)
2065         VLC_ADD_PLUGIN([ts])
2066         if test "${enable_sout}" != "no"; then
2067           VLC_ADD_PLUGIN([mux_ts])
2068         fi
2069         VLC_ADD_CPPFLAGS([mux_ts ts dvb],[-I${real_dvbpsi_tree}/src])
2070         VLC_ADD_LIBS([mux_ts ts dvb],[${real_dvbpsi_tree}/src/.libs/libdvbpsi.a])
2071         have_dvbpsi=yes
2072       else
2073         dnl  The given libdvbpsi wasn't built
2074         AC_MSG_RESULT(no)
2075         AC_MSG_ERROR([cannot find ${real_dvbpsi_tree}/src/.libs/libdvbpsi.a, make sure you compiled libdvbpsi in ${with_dvbpsi_tree}])
2076       fi
2077     fi
2078   ;;
2079   no)
2080     dnl  Compile without dvbpsi
2081   ;;
2082   *)
2083     AC_MSG_CHECKING(for dvbpsi headers in ${with_dvbpsi})
2084     if test -z "${with_dvbpsi}"
2085     then
2086       LDFLAGS_test=""
2087       CPPFLAGS_test=""
2088     else
2089       LDFLAGS_test="-L${with_dvbpsi}/lib"
2090       CPPFLAGS_test="-I${with_dvbpsi}/include"
2091     fi
2092     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_test}"
2093     AC_CHECK_HEADERS([dvbpsi/dr.h],[
2094       VLC_ADD_PLUGIN([ts])
2095       if test "${enable_sout}" != "no"; then
2096         AC_CHECK_LIB(dvbpsi, dvbpsi_SDTServiceAddDescriptor,
2097            [VLC_ADD_PLUGIN([mux_ts])], [], [${LDFLAGS_test} -ldvbpsi])
2098       fi
2099       VLC_ADD_CPPFLAGS([mux_ts ts dvb],[${CPPFLAGS_test}])
2100       VLC_ADD_LIBS([mux_ts ts dvb],[${LDFLAGS_test} -ldvbpsi])
2101       have_dvbpsi=yes
2102     ],[
2103       if test -n "${enable_dvbpsi}"
2104       then
2105         AC_MSG_ERROR([Could not find libdvbpsi on your system: you may get it from www.videolan.org, you'll need at least version 0.1.6])
2106       fi
2107     ],
2108     [#if defined( HAVE_STDINT_H )
2109 #   include <stdint.h>
2110 #elif defined( HAVE_INTTYPES_H )
2111 #   include <inttypes.h>
2112 #endif
2113 #include <dvbpsi/dvbpsi.h>
2114 #include <dvbpsi/descriptor.h>
2115 #include <dvbpsi/pat.h>
2116 #include <dvbpsi/pmt.h>])
2117     CPPFLAGS="${CPPFLAGS_save}"
2118   ;;
2119   esac
2120   AC_CHECK_LIB(dvbpsi, dvbpsi_GenSDTSections, [
2121     AC_DEFINE(HAVE_DVBPSI_SDT, 1, [Define if you have dvbpsi_GenSDTSections.])
2122   ], [], [${LIBS_ts}])
2123
2124 fi
2125
2126 dnl
2127 dnl  Video4Linux2 plugin
2128 dnl
2129 AC_ARG_ENABLE(v4l2,
2130   [  --enable-v4l2           Video4Linux2 input support (default enabled)])
2131 if test "${enable_v4l2}" != "no"
2132 then
2133   AC_ARG_WITH(v4l2,
2134     [  --with-v4l2=PATH        path to a v4l2-enabled kernel tree],[],[])
2135   if test "${with_v4l2}" != "no" -a -n "${with_v4l2}"
2136   then
2137     VLC_ADD_CPPFLAGS([v4l2],[-I${with_v4l2}/include])
2138   fi
2139
2140   CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_v4l2}"
2141   AC_CHECK_HEADERS(linux/videodev2.h sys/videoio.h, [
2142     VLC_ADD_PLUGIN([v4l2])
2143   ],[])
2144   CPPFLAGS="${CPPFLAGS_save}"
2145 fi
2146
2147 dnl
2148 dnl libv4l2 support for video4linux.
2149 dnl
2150 AC_ARG_ENABLE( libv4l2,
2151   [  --enable-libv4l2        Libv4l2 Video4Linux2 support (default enabled)])
2152 if test "${enable_libv4l2}" != "no" -a "${enable_v4l2}" != "no"
2153 then
2154     PKG_CHECK_MODULES( LIBV4L2, libv4l2, [
2155       VLC_ADD_LDFLAGS([v4l2],[${LIBV4L2_LIBS}])
2156       VLC_ADD_CFLAGS([v4l2],[${LIBV4L2_CFLAGS}])
2157       AC_DEFINE(HAVE_LIBV4L2, 1, Define if libv4l2 is available)],
2158       AC_MSG_WARN([LibV4L2 support disabled because libv4l2 development headers were not found])
2159     )
2160 fi
2161
2162 dnl
2163 dnl  special access module for Hauppauge PVR cards
2164 dnl
2165 AC_ARG_ENABLE(pvr,
2166   [  --enable-pvr            PVR cards access module (default disabled)])
2167 if test "${enable_pvr}" = "yes"
2168 then
2169   VLC_ADD_PLUGIN([pvr])
2170   AC_ARG_WITH(videodev2,
2171     [  --with-videodev2=FILE   Location of videodev2.h file (default /usr/include/linux/videodev2.h)],[],[])
2172   if test "${with_videodev2}" != "no" -a -n "${with_videodev2}"
2173   then
2174     AC_DEFINE_UNQUOTED(VIDEODEV2_H_FILE, "${with_videodev2}", [Location of videodev2.h])
2175   fi
2176
2177   AC_CACHE_CHECK([for new linux/videodev2.h],
2178       [ac_cv_new_linux_videodev2_h],
2179       [AC_TRY_COMPILE([
2180           #include <sys/types.h>
2181           #   ifdef VIDEODEV2_H_FILE
2182           #   include VIDEODEV2_H_FILE
2183           #   else
2184           #   include <linux/videodev2.h>
2185           #   endif
2186           ],
2187           [struct v4l2_ext_controls ctrls; ctrls.ctrl_class = V4L2_CTRL_CLASS_MPEG; ],
2188           ac_cv_new_linux_videodev2_h=yes,
2189           ac_cv_new_linux_videodev2_h=no)])
2190   if test "${ac_cv_new_linux_videodev2_h}" != "no"; then
2191     AC_DEFINE(HAVE_NEW_LINUX_VIDEODEV2_H, 1, [Define if new linux/videodev2.h present])
2192   fi
2193 fi
2194
2195 dnl
2196 dnl  gnomeVFS access module
2197 dnl
2198 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [access_gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
2199
2200 dnl
2201 dnl  VCDX modules
2202 dnl
2203 AC_ARG_ENABLE(vcdx,
2204   [  --enable-vcdx           VCD with navigation via libvcdinfo (default disabled)])
2205
2206 if test "${enable_vcdx}" = "yes"
2207 then
2208         PKG_CHECK_MODULES(LIBCDIO, [libcdio >= 0.78.2 libiso9660 >= 0.72],
2209           [VLC_ADD_LIBS([vcdx],[$LIBCDIO_LIBS])
2210                  VLC_ADD_CFLAGS([vcdx],[$LIBCDIO_CFLAGS])],
2211                 [AC_MSG_ERROR([vcdx plugin requires libcdio >= 0.78.2 and libiso9660 >= 0.72])])
2212         PKG_CHECK_MODULES(LIBVCDINFO, libvcdinfo >= 0.7.22,
2213                 [VLC_ADD_LIBS([vcdx],[$LIBVCDINFO_LIBS])
2214                  VLC_ADD_CFLAGS([vcdx],[$LIBVCDINFO_CFLAGS])],
2215           [AC_MSG_ERROR([vcdx plugin requires libvcdinfo library >= 0.7.22])])
2216         VLC_ADD_PLUGIN([vcdx])
2217 fi
2218
2219 dnl
2220 dnl  Built-in CD-DA and VCD module
2221 dnl
2222 AC_ARG_ENABLE(vcd,
2223   [  --enable-vcd            built-in VCD and CD-DA (default enabled)])
2224
2225 AC_ARG_ENABLE(libcddb,
2226   [  --enable-libcddb        CDDB support for libcdio audio CD (default enabled)])
2227
2228 if test "${enable_vcd}" != "no"
2229 then
2230   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
2231   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
2232     AC_MSG_RESULT(yes)
2233     VLC_ADD_PLUGIN([vcd cdda])
2234   ],[
2235     AC_MSG_RESULT(no)
2236   ])
2237
2238   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
2239   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
2240     AC_MSG_RESULT(yes)
2241     VLC_ADD_PLUGIN([vcd cdda])
2242     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
2243   ],[
2244     AC_MSG_RESULT(no)
2245   ])
2246
2247   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
2248   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
2249     AC_MSG_RESULT(yes)
2250     VLC_ADD_PLUGIN([vcd cdda])
2251     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
2252   ],[
2253     AC_MSG_RESULT(no)
2254   ])
2255
2256   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32"
2257   then
2258     VLC_ADD_PLUGIN([vcd cdda])
2259   fi
2260
2261   if test "${SYS}" = "darwin"
2262   then
2263     VLC_ADD_PLUGIN([vcd cdda])
2264     VLC_ADD_LDFLAGS([vcd vcdx cdda],[-Wl,-framework,IOKit,-framework,CoreFoundation])
2265     VLC_ADD_LIBS([vcdx cdda],[-liconv])
2266   fi
2267
2268   if test "$enable_libcddb" != "no"; then
2269     PKG_CHECK_MODULES(LIBCDDB, libcddb >= 0.9.5, [
2270       HAVE_LIBCDDB=yes
2271       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
2272       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
2273       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
2274       ],:
2275       [AC_MSG_WARN(new enough libcddb not found. CDDB access disabled)
2276       HAVE_LIBCDDB=no])
2277   fi
2278 fi
2279
2280 dnl
2281 dnl  DVB-S/DVB-T/DVB-C satellite/teresterial/cable input using v4l2
2282 dnl
2283 AC_ARG_ENABLE(dvb,
2284   [  --enable-dvb            DVB-S/T/C card support (default enabled)])
2285
2286 if test "${enable_dvb}" != "no"
2287 then
2288     AS_IF([test "${have_dvbpsi}" = "yes" ],[
2289     AC_ARG_WITH(dvb,
2290      [  --with-dvb=PATH         path to a dvb- and v4l2-enabled kernel tree],[],[])
2291      if test "${with_dvb}" != "no" -a -n "${with_dvb}"
2292      then
2293        VLC_ADD_CFLAGS([dvb],[-I${with_dvb}/include])
2294      fi
2295      CPPFLAGS="${CPPFLAGS_save} -I${with_dvb}/include"
2296      AC_CHECK_HEADERS(linux/dvb/version.h linux/dvb/frontend.h, [
2297      VLC_ADD_PLUGIN([dvb])
2298      ],[AC_MSG_WARN(linux-dvb headers not found, dvb disabled)])
2299      CPPFLAGS="${CPPFLAGS_save}"
2300    ],[
2301      AC_MSG_WARN([the dvb access module requires libdvbpsi])
2302     ])
2303 fi
2304
2305 dnl
2306 dnl  Screen capture module
2307 dnl
2308 AC_ARG_ENABLE(screen,
2309   [  --enable-screen         Screen capture support (default enabled)])
2310 if test "${enable_screen}" != "no"; then
2311   if test "${SYS}" = "darwin"; then
2312     AC_CHECK_HEADERS(OpenGL/gl.h, [
2313       AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
2314         VLC_ADD_PLUGIN([screen])
2315         VLC_ADD_LDFLAGS([screen],[-Wl,-framework,OpenGL,-framework,ApplicationServices])
2316       ])
2317     ])
2318   elif test "${SYS}" = "mingw32"; then
2319     VLC_ADD_PLUGIN([screen])
2320     VLC_ADD_LIBS([screen],[-lgdi32])
2321   elif test "${SYS}" = "mingwce"; then
2322     CPPFLAGS="${CPPFLAGS_save}"
2323   elif test "${SYS}" = "beos"; then
2324     VLC_ADD_PLUGIN([screen])
2325     VLC_ADD_CXXFLAGS([screen],[])
2326     VLC_ADD_LIBS([screen],[-lbe])
2327   fi
2328 fi
2329
2330 dnl
2331 dnl  ipv6 plugin
2332 dnl
2333 have_ipv6=no
2334 AC_CHECK_FUNCS(inet_pton,[have_ipv6=yes],[
2335   AC_CHECK_LIB(nsl,inet_pton, [have_ipv6=yes])
2336 ])
2337
2338 AS_IF([test "${have_ipv6}" = "yes"], [
2339   AC_DEFINE(HAVE_INET_PTON, 1, [Define to 1 if you have inet_pton().])])
2340
2341
2342 AC_CHECK_FUNCS(inet_ntop,[
2343   AC_DEFINE(HAVE_INET_NTOP, 1, [Define to 1 if you have inet_ntop().])])
2344
2345
2346 dnl
2347 dnl  ogg demux plugin
2348 dnl
2349 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2350 if test "${enable_sout}" != "no"; then
2351     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2352 fi
2353
2354 if test "${enable_sout}" != "no"; then
2355 dnl Check for libshout
2356 PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2357 fi
2358
2359 dnl
2360 dnl  matroska demux plugin
2361 dnl
2362 AC_ARG_ENABLE(mkv,
2363   [  --enable-mkv            Matroska demux support (default enabled)])
2364 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2365   AC_LANG_PUSH(C++)
2366   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2367     AC_MSG_CHECKING(for libebml version >= 0.7.7)
2368     AC_EGREP_CPP(yes,
2369       [#include <ebml/EbmlVersion.h>
2370        #ifdef LIBEBML_VERSION
2371        #if LIBEBML_VERSION >= 0x000706
2372        yes
2373        #endif
2374        #endif],
2375       [AC_MSG_RESULT([yes])
2376         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2377           AC_MSG_CHECKING(for libmatroska version >= 0.8.0)
2378           AC_EGREP_CPP(yes,
2379             [#include <matroska/KaxVersion.h>
2380              #ifdef LIBMATROSKA_VERSION
2381              #if LIBMATROSKA_VERSION >= 0x000705
2382              yes
2383              #endif
2384              #endif],
2385             [AC_MSG_RESULT([yes])
2386               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2387               VLC_ADD_CXXFLAGS([mkv],[])
2388               if test "${SYS}" = "darwin"; then
2389                 VLC_ADD_CXXFLAGS([mkv],[-O1])
2390               fi
2391               AC_CHECK_LIB(ebml_pic, main, [
2392                 VLC_ADD_PLUGIN([mkv])
2393                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2394               ],
2395                 AC_CHECK_LIB(ebml, main, [
2396                   VLC_ADD_PLUGIN([mkv])
2397                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2398                 ])
2399               )
2400             ],
2401             [AC_MSG_RESULT([no])
2402               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2403           ])
2404         ])
2405       ],
2406       [AC_MSG_RESULT([no])
2407         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2408     ])
2409   ])
2410   AC_LANG_POP(C++)
2411 fi
2412
2413 dnl
2414 dnl  modplug demux plugin
2415 dnl
2416 AC_ARG_ENABLE(mod,
2417   [  --enable-mod            Mod demux support (default auto)])
2418 if test "${enable_mod}" != "no" ; then
2419     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2420           VLC_ADD_PLUGIN([mod])
2421           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2422           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2423     ],[
2424        AS_IF([test x"${enable_mod}" = "xyes"],
2425          [AC_MSG_ERROR(libmodplug not found or a broken version (0.8.8.0) was found!)],
2426          [AC_MSG_WARN(libmodplug not found or a broken version (0.8.8.0) was found!)])
2427     ])
2428 fi
2429
2430 dnl
2431 dnl  mpc demux plugin
2432 dnl
2433 AC_ARG_ENABLE(mpc,
2434   [  --enable-mpc            Mpc demux support (default enabled)])
2435 if test "${enable_mpc}" != "no"
2436 then
2437   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2438     VLC_ADD_PLUGIN([mpc])
2439     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2440     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2441     VLC_ADD_PLUGIN([mpc])
2442     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2443 fi
2444
2445 dnl
2446 dnl  game music emu demux plugin
2447 dnl
2448 AC_ARG_ENABLE(gme,
2449   [  --enable-gme            Game Music Emu demux support (default enabled)])
2450 if test "${enable_gme}" != "no" -a "${CXX}" != "";
2451 then
2452   AC_LANG_PUSH(C++)
2453   AC_ARG_WITH(gme-tree,
2454   [  --with-gme-tree=PATH    gme tree for static linking])
2455   if test -n "${with_gme_tree}"
2456   then
2457     AC_MSG_CHECKING(for libgme.a in ${with_mod_tree})
2458     real_gme_tree="`cd ${with_gme_tree} 2>/dev/null && pwd`"
2459     if test -z "${real_gme_tree}"
2460     then
2461       dnl  The given directory can't be found
2462       AC_MSG_RESULT(no)
2463       AC_MSG_ERROR([cannot cd to ${with_gme_tree}])
2464     fi
2465     if test -f "${real_gme_tree}/gme/libgme.a"
2466     then
2467       dnl  Use a custom gme
2468       AC_MSG_RESULT(${real_gme_tree}/gme/libgme.a)
2469       VLC_ADD_PLUGIN([gme])
2470       VLC_ADD_LIBS([gme],[${real_gme_tree}/gme/libgme.a])
2471       VLC_ADD_CXXFLAGS([gme],[-I${real_gme_tree}/gme])
2472     else
2473       dnl  The given gme wasn't built
2474       AC_MSG_RESULT(no)
2475       AC_MSG_ERROR([cannot find ${real_mod_tree}/gme/libgme.a, make sure you compiled gme in ${with_gme_tree}])
2476     fi
2477   else
2478       AC_MSG_WARN([only static linking is available, you must provide a gme-tree])
2479   fi
2480   AC_LANG_POP(C++)
2481 fi
2482
2483 dnl
2484 dnl  Codec plugins
2485 dnl
2486
2487 EXTEND_HELP_STRING([Codec plugins:])
2488
2489 dnl
2490 dnl wmafixed plugin
2491 dnl
2492 AC_ARG_ENABLE(wma-fixed,
2493   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2494 if test "${enable_wma_fixed}" = "yes"
2495 then
2496   VLC_ADD_PLUGIN([wma_fixed])
2497 fi
2498
2499 dnl
2500 dnl shine fixed point mp3 encoder
2501 dnl
2502 AC_ARG_ENABLE(shine,
2503   [  --enable-shine          shine mp3 encoding module (default disabled)])
2504 if test "${enable_shine}" = "yes"
2505 then
2506   VLC_ADD_PLUGIN([shine])
2507 fi
2508
2509 dnl
2510 dnl openmax il codec plugin
2511 dnl
2512 AC_ARG_ENABLE(omxil,
2513   [  --enable-omxil          openmax il codec module (default disabled)])
2514 if test "${enable_omxil}" = "yes"
2515 then
2516   VLC_ADD_PLUGIN([omxil])
2517   VLC_ADD_LIBS([omxil], [$LIBDL])
2518 fi
2519
2520 dnl
2521 dnl  mad plugin
2522 dnl
2523 AC_ARG_ENABLE(mad,
2524   [  --enable-mad            libmad module (default enabled)])
2525 if test "${enable_mad}" != "no"
2526 then
2527   AC_ARG_WITH(mad,
2528     [  --with-mad=PATH         path to libmad],[],[])
2529   if test "${with_mad}" != "no" -a -n "${with_mad}"
2530   then
2531     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2532     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2533   fi
2534
2535   AC_ARG_WITH(mad-tree,
2536     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2537   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2538   then
2539     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2540     if test -z "${real_mad_tree}"
2541     then
2542       dnl  The given directory can't be found
2543       AC_MSG_RESULT(no)
2544       AC_MSG_ERROR([${with_mad_tree} directory doesn't exist])
2545     fi
2546     dnl  Use a custom libmad
2547     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2548     if test -f ${real_mad_tree}/mad.h
2549     then
2550       AC_MSG_RESULT(yes)
2551       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2552       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2553       LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2554       AC_CHECK_LIB(mad, mad_bit_init, [
2555         VLC_ADD_PLUGIN([mpgatofixed32])
2556         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2557         ],[ AC_MSG_ERROR([the specified tree hasn't been compiled ])
2558       ],[])
2559       LDFLAGS="${LDFLAGS_save}"
2560     else
2561       AC_MSG_RESULT(no)
2562       AC_MSG_ERROR([the specified tree doesn't have mad.h])
2563     fi
2564   else
2565     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_mpgatofixed32}"
2566     LDFLAGS="${LDFLAGS_save} ${LIBS_mpgatofixed32}"
2567     AC_CHECK_HEADERS(mad.h, ,
2568       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2569     AC_CHECK_LIB(mad, mad_bit_init, [
2570       VLC_ADD_PLUGIN([mpgatofixed32])
2571       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2572       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2573     CPPFLAGS="${CPPFLAGS_save}"
2574     LDFLAGS="${LDFLAGS_save}"
2575   fi
2576 fi
2577
2578
2579 AC_ARG_ENABLE(merge-ffmpeg,
2580 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2581   enable_merge_ffmpeg="no"
2582 ])
2583 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2584
2585 dnl
2586 dnl  avcodec decoder/encoder plugin
2587 dnl
2588 AC_ARG_ENABLE(avcodec,
2589 [  --enable-avcodec        libavcodec codec (default enabled)])
2590 AS_IF([test "${enable_avcodec}" != "no"], [
2591   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 52.25.0 libavutil],
2592     [
2593       VLC_SAVE_FLAGS
2594       CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2595       CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2596       AC_CHECK_HEADERS(libavcodec/avcodec.h ffmpeg/avcodec.h)
2597       AC_CHECK_HEADERS(libavutil/avutil.h ffmpeg/avutil.h)
2598       VLC_ADD_PLUGIN([avcodec])
2599       VLC_ADD_LIBS([avcodec],[$AVCODEC_LIBS])
2600       VLC_ADD_CFLAGS([avcodec],[$AVCODEC_CFLAGS])
2601       VLC_RESTORE_FLAGS
2602       have_avcodec="yes"
2603     ],[
2604       AC_MSG_ERROR([Could not find libavcodec or libavutil. Use --disable-avcodec to ignore this error.])
2605   ])
2606 ], [
2607   have_avcodec="no"
2608 ])
2609
2610 dnl
2611 dnl libva needs avcodec
2612 dnl
2613 AC_ARG_ENABLE(libva,
2614   [  --enable-libva          libva VAAPI support (default auto)])
2615
2616 AS_IF([test "${enable_libva}" != "no"], [
2617   AS_IF([test "x${have_avcodec}" = "xyes"], [
2618     PKG_CHECK_MODULES(LIBVA, [libva libva-x11],
2619       [
2620         VLC_SAVE_FLAGS
2621         CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2622         CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2623         AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2624            VLC_ADD_LIBS([avcodec],[$LIBVA_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11])
2625            VLC_ADD_CFLAGS([avcodec],[$LIBVA_CFLAGS ${X_CFLAGS}])
2626            AC_DEFINE(HAVE_AVCODEC_VAAPI, 1, [Define if avcodec has to be built with VAAPI support.])
2627            echo "VAAPI acceleration activated"
2628         ],[
2629         AS_IF([test "${enable_libva}" == "yes"],
2630               [AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])],
2631               [AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])])
2632         ])
2633         VLC_RESTORE_FLAGS
2634       ],[
2635         AS_IF([test "${enable_libva}" == "yes"],
2636               [AC_MSG_ERROR([Could not find required libva.])],
2637               [AC_MSG_WARN([libva not found  ])])
2638       ])
2639   ],[
2640     AS_IF([test "x${enable_libva}" != "x"], [
2641       AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive.])
2642     ])
2643   ])
2644 ])
2645
2646 dnl
2647 dnl dxva2 needs avcodec
2648 dnl
2649 AC_ARG_ENABLE(dxva2,
2650   [  --enable-dxva2          DxVA2  support (default auto)])
2651
2652 AS_IF([test "${enable_dxva2}" != "no"], [
2653   if test "${SYS}" = "mingw32"; then
2654   AS_IF([test "x${have_avcodec}" = "xyes"], [
2655     AC_CHECK_HEADERS(dxva2api.h, 
2656       [
2657         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2658            VLC_ADD_LIBS([avcodec],[-lole32 -lshlwapi -luuid])
2659            AC_DEFINE(HAVE_AVCODEC_DXVA2, 1, [Define if avcodec has to be built with DxVA2 support.])
2660            echo "DxVA2 acceleration activated"
2661         ],[
2662         AS_IF([test "${enable_dxva2}" == "yes"],
2663               [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2664               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2665         ])
2666       ],[
2667         AS_IF([test "${enable_dxva2}" == "yes"],
2668               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2669               [AC_MSG_WARN([dxva2api.h not found])])
2670       ])
2671   ],[
2672     AS_IF([test "x${enable_dxva2}" != "x"], [
2673       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2674     ])
2675   ])
2676   fi
2677 ])
2678
2679
2680 dnl
2681 dnl stream_out switcher needs libavcodec
2682 dnl
2683 AC_ARG_ENABLE(switcher,
2684   [  --enable-switcher       Stream-out switcher plugin (default disabled)])
2685 AS_IF([test "${enable_switcher}" = "yes"], [
2686   AS_IF([test "x${have_avcodec}" = "xyes"], [
2687     VLC_ADD_PLUGIN([stream_out_switcher])
2688     VLC_ADD_LIBS([stream_out_switcher],[$AVCODEC_LIBS $AVUTIL_LIBS])
2689     VLC_ADD_CFLAGS([stream_out_switcher],[$AVCODEC_CFLAGS $AVUTIL_CFLAGS])
2690   ],[AC_MSG_ERROR([Stream_out switcher depends on avcodec])
2691   ])
2692 ])
2693
2694
2695 dnl
2696 dnl  avformat demuxer/muxer plugin
2697 dnl
2698
2699 AC_ARG_ENABLE(avformat,
2700 [  --enable-avformat       libavformat containers (default enabled)],, [
2701   enable_avformat="${have_avcodec}"
2702 ])
2703 if test "${enable_avformat}" != "no"
2704 then
2705   PKG_CHECK_MODULES(AVFORMAT,[libavformat > 52.30.0 libavcodec libavutil],
2706     [
2707       VLC_SAVE_FLAGS
2708       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2709       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2710       AC_CHECK_HEADERS(libavformat/avformat.h ffmpeg/avformat.h)
2711       AC_CHECK_HEADERS(libavutil/avutil.h ffmpeg/avutil.h)
2712       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2713         VLC_ADD_PLUGIN([avformat access_avio])
2714         VLC_ADD_LIBS([avformat access_avio],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2715         VLC_ADD_CFLAGS([avformat access_avio],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2716       ], [
2717         VLC_ADD_LIBS([avcodec],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2718         VLC_ADD_CFLAGS([avcodec],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2719       ])
2720       VLC_RESTORE_FLAGS
2721     ],[
2722       AC_MSG_ERROR([Could not find libavformat or libavutil. Use --disable-avformat to ignore this error.])
2723   ])
2724 fi
2725
2726 dnl
2727 dnl  swscale image scaling and conversion plugin
2728 dnl
2729
2730 AC_ARG_ENABLE(swscale,
2731   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2732                   (default enabled)]))
2733 if test "${enable_swscale}" != "no"
2734 then
2735   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2736     [
2737       VLC_SAVE_FLAGS
2738       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2739       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2740       AC_CHECK_HEADERS(libswscale/swscale.h ffmpeg/swscale.h)
2741       VLC_ADD_PLUGIN([swscale])
2742       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2743       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2744       VLC_RESTORE_FLAGS
2745     ],[
2746       AC_MSG_ERROR([Could not find libswscale. Use --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2747   ])
2748 fi
2749
2750 dnl
2751 dnl  postproc plugin
2752 dnl
2753
2754 AC_ARG_ENABLE(postproc,
2755 [  --enable-postproc       libpostproc image post-processing (default enabled)])
2756 if test "${enable_postproc}" != "no"
2757 then
2758   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2759     [
2760       VLC_SAVE_FLAGS
2761       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2762       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2763       AC_CHECK_HEADERS(postproc/postprocess.h)
2764       VLC_ADD_PLUGIN([postproc])
2765       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2766       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2767       VLC_RESTORE_FLAGS
2768     ],[
2769       AC_MSG_ERROR([Could not find libpostproc. Use --disable-postproc to ignore this error.])
2770   ])
2771 fi
2772
2773 dnl
2774 dnl  faad decoder plugin
2775 dnl
2776 AC_ARG_ENABLE(faad,
2777 [  --enable-faad           faad codec (default disabled)])
2778 if test "${enable_faad}" = "yes"
2779 then
2780   AC_ARG_WITH(faad-tree,
2781   [  --with-faad-tree=PATH   faad tree for static linking])
2782   if test -n "${with_faad_tree}"
2783   then
2784     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2785     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2786     if test -z "${real_faad_tree}"
2787     then
2788       dnl  The given directory can't be found
2789       AC_MSG_RESULT(no)
2790       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2791     fi
2792     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"
2793     then
2794       dnl  Use a custom faad
2795       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2796       VLC_ADD_PLUGIN([faad])
2797       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2798       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2799     else
2800       dnl  The given libfaad wasn't built
2801       AC_MSG_RESULT(no)
2802       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2803     fi
2804   else
2805     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_faad}"
2806     LDFLAGS="${LDFLAGS_save} ${LIBS_faad}"
2807     AC_CHECK_HEADERS(faad.h, ,
2808       [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ])
2809     AC_CHECK_LIB(faad, faacDecOpen, [
2810       VLC_ADD_PLUGIN([faad])
2811       VLC_ADD_LIBS([faad],[-lfaad]) ],
2812       AC_CHECK_LIB(faad, NeAACDecOpen, [
2813         VLC_ADD_PLUGIN([faad])
2814         VLC_ADD_LIBS([faad],[-lfaad]) ],
2815         [ AC_MSG_ERROR([Cannot find libfaad library...]) ]))
2816     LDFLAGS="${LDFLAGS_save}"
2817     CPPFLAGS="${CPPFLAGS_save}"
2818   fi
2819 fi
2820
2821 dnl
2822 dnl twolame encoder plugin
2823 dnl
2824 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2825
2826 dnl
2827 dnl  QuickTime plugin
2828 dnl
2829 AC_ARG_ENABLE(quicktime,
2830   [  --enable-quicktime      QuickTime module (deprecated)])
2831 if test "${enable_quicktime}" = "yes"; then
2832   if test "${SYS}" = "mingw32"; then
2833     VLC_ADD_PLUGIN([quicktime])
2834   else
2835   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2836     [ VLC_ADD_PLUGIN([quicktime])
2837       VLC_ADD_LDFLAGS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2838     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2839   fi
2840 fi
2841
2842 dnl
2843 dnl  Real plugin
2844 dnl
2845 AC_ARG_ENABLE(real,
2846   [  --enable-real           Real media module (default disabled)])
2847 if test "${enable_real}" = "yes"; then
2848   VLC_ADD_PLUGIN([realvideo])
2849 fi
2850
2851 dnl
2852 dnl  Real RTSP plugin
2853 dnl
2854 AC_ARG_ENABLE(realrtsp,
2855   [  --enable-realrtsp       Real RTSP module (default disabled)])
2856 if test "${enable_realrtsp}" = "yes"; then
2857   VLC_ADD_PLUGIN([access_realrtsp])
2858 fi
2859
2860 dnl
2861 dnl skins2 module
2862 dnl
2863 AC_ARG_ENABLE(libtar,
2864   [  --enable-libtar         libtar support for skins2 (default enabled)])
2865
2866 AS_IF([test "${enable_libtar}" != "no"],[
2867   AC_CHECK_HEADERS(libtar.h, [
2868     VLC_ADD_LIBS([skins2],[-ltar])
2869   ] )
2870 ])
2871
2872 dnl
2873 dnl A52/AC3 decoder plugin
2874 dnl
2875 AC_ARG_ENABLE(a52,
2876   [  --enable-a52            A/52 support with liba52 (default enabled)])
2877 if test "${enable_a52}" != "no"
2878 then
2879   AC_ARG_WITH(a52,
2880     [  --with-a52=PATH         a52 headers and libraries])
2881   AC_ARG_WITH(a52-tree,
2882     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2883   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2884   then
2885     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2886     if test -z "${real_a52_tree}"
2887     then
2888       dnl  The given directory can't be found
2889       AC_MSG_RESULT(no)
2890       AC_MSG_ERROR([${with_a52_tree} directory doesn't exist])
2891     fi
2892     dnl  Use a custom a52dec
2893     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2894     if test -f ${real_a52_tree}/include/a52.h
2895     then
2896       AC_MSG_RESULT(yes)
2897       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2898       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2899       LDFLAGS="${LDFLAGS_save} ${LIBS_a52tofloat32}"
2900       AC_CHECK_LIB(a52, a52_free, [
2901         VLC_ADD_PLUGIN([a52tofloat32])
2902         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2903         VLC_ADD_LIBS([a52tofloat32],[-la52])
2904         ],[
2905         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2906         then
2907           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2908         else
2909           AC_MSG_ERROR([the specified tree hasn't been compiled])
2910         fi
2911       ])
2912       LDFLAGS="${LDFLAGS_save}"
2913     else
2914       AC_MSG_RESULT(no)
2915       AC_MSG_ERROR([the specified tree doesn't have a52.h])
2916     fi
2917   else
2918     if test -z "${with_a52}"
2919     then
2920       LDFLAGS_test=""
2921       CPPFLAGS_test=""
2922     else
2923       LDFLAGS_test="-L${with_a52}/lib"
2924       CPPFLAGS_test="-I${with_a52}/include"
2925     fi
2926     CPPFLAGS="${CPPFLAGS_save} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2927     LDFLAGS="${LDFLAGS_save} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2928     AC_CHECK_HEADERS(a52dec/a52.h, [
2929       AC_CHECK_LIB(a52, a52_free, [
2930         VLC_ADD_PLUGIN([a52tofloat32])
2931         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2932         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2933       ],[
2934         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2935         ])
2936     ],[
2937       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2938     ])
2939     CPPFLAGS="${CPPFLAGS_save}"
2940     LDFLAGS="${LDFLAGS_save}"
2941   fi
2942 fi
2943
2944 AC_ARG_WITH(a52-fixed,
2945       [  --with-a52-fixed        specify if liba52 has been compiled with fixed point support],
2946       [
2947         VLC_ADD_CPPFLAGS([a52tofloat32],[-DLIBA52_FIXED]) ])
2948
2949 dnl
2950 dnl DTS Coherent Acoustics decoder plugin
2951 dnl
2952 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2953
2954 dnl
2955 dnl  Flac plugin
2956 dnl
2957 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2958
2959 dnl
2960 dnl  Libmpeg2 plugin
2961 dnl
2962 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2963
2964 dnl
2965 dnl  Vorbis plugin
2966 dnl
2967 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2968
2969 dnl
2970 dnl  Tremor plugin
2971 dnl
2972 AC_ARG_ENABLE(tremor,
2973   [  --enable-tremor         Tremor decoder support (default disabled)])
2974 if test "${enable_tremor}" = "yes"
2975 then
2976   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2977     VLC_ADD_PLUGIN([tremor])
2978     VLC_ADD_LIBS([tremor],[-lvorbisidec -logg])
2979    ],[])
2980 fi
2981
2982 dnl
2983 dnl  Speex plugin
2984 dnl
2985 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex decoder support], [auto])
2986
2987 dnl
2988 dnl  theora decoder plugin
2989 dnl
2990 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theora >= 1.0], [experimental theora codec], [auto])
2991
2992 dnl
2993 dnl  dirac encoder plugin
2994 dnl
2995 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2996
2997 dnl
2998 dnl  schroedinger decoder plugin (for dirac format video)
2999 dnl
3000 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.6], [dirac decoder using schroedinger], [auto])
3001
3002 dnl
3003 dnl  PNG decoder module
3004 dnl
3005 AC_ARG_ENABLE(png,
3006   [  --enable-png            PNG support (default enabled)])
3007 if test "${enable_png}" != "no"; then
3008 AC_CHECK_HEADERS(png.h, [
3009   LDFLAGS="${LDFLAGS_save} -lz"
3010   AC_CHECK_LIB(png, png_set_rows, [
3011     VLC_ADD_LIBS([png],[-lpng -lz])
3012     VLC_ADD_PLUGIN([png osdmenu osd_parser])],
3013     [],[-lz])
3014     LDFLAGS="${LDFLAGS_save}"
3015   ])
3016 fi
3017 AM_CONDITIONAL(BUILD_OSDMENU, [test "${enable_png}" != "no"])
3018
3019 dnl
3020 dnl H264 encoder plugin (using libx264)
3021 dnl
3022 AC_ARG_ENABLE(x264,
3023   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
3024 if test "${enable_x264}" != "no"; then
3025   AC_ARG_WITH(x264-tree,
3026     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
3027   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
3028   then
3029     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
3030     if test -z "${real_x264_tree}"
3031     then
3032       dnl  The given directory can't be found
3033       AC_MSG_RESULT(no)
3034       AC_MSG_ERROR([${with_x264_tree} directory doesn't exist])
3035     fi
3036     dnl  Use a custom libx264
3037     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
3038     if test -f ${real_x264_tree}/x264.h
3039     then
3040       AC_MSG_RESULT(yes)
3041       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
3042       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
3043       PKG_CHECK_MODULES(X264,x264, [
3044         VLC_ADD_PLUGIN([x264])
3045         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
3046         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
3047         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3048           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
3049         fi
3050       ],[
3051         AC_MSG_ERROR([the specified tree hasn't been compiled])
3052       ])
3053       LDFLAGS="${LDFLAGS_save}"
3054     else
3055       AC_MSG_RESULT(no)
3056       AC_MSG_ERROR([the specified tree doesn't have x264.h])
3057     fi
3058   else
3059       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
3060         VLC_ADD_PLUGIN([x264])
3061         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
3062
3063         AC_CACHE_CHECK([if linker supports -Bsymbolic],
3064           [ac_cv_ld_bsymbolic],
3065           [LDFLAGS="${LDFLAGS_vlc} -Wl,-Bsymbolic"
3066             AC_TRY_LINK([],,ac_cv_ld_bsymbolic=yes,ac_cv_ld_bsymbolic=no)
3067             LDFLAGS="${LDFLAGS_save}"
3068           ])
3069         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
3070           VLC_ADD_LDFLAGS([x264],[-Wl,-Bsymbolic])
3071         ])
3072
3073         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
3074         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
3075           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
3076         fi
3077       ],[
3078         if test "${enable_x264}" = "yes"; then
3079             AC_MSG_ERROR([Could not find libx264 >= 0.86 on your system: you may get it from http://www.videolan.org/x264.html])
3080           fi
3081       ])
3082     LDFLAGS="${LDFLAGS_save}"
3083   fi
3084 fi
3085
3086 dnl
3087 dnl libfluidsynth (MIDI synthetizer) plugin
3088 dnl
3089 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth], [MIDI synthetiser with libfluidsynth], [auto])
3090
3091 dnl
3092 dnl Teletext Modules
3093 dnl vbi decoder plugin (using libzbvi)
3094 dnl telx module
3095 dnl uncompatible
3096 dnl
3097 AC_ARG_ENABLE(zvbi,
3098   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
3099                   libzvbi (default enabled)]))
3100 AC_ARG_ENABLE(telx,
3101   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
3102                   zvbi) (default enabled if zvbi is absent)]))
3103
3104 AS_IF( [test "${enable_zvbi}" != "no"],[
3105     PKG_CHECK_MODULES(ZVBI,
3106         zvbi-0.2 >= 0.2.28,
3107         [
3108           VLC_ADD_LIBS([zvbi],[$ZVBI_LIBS])
3109           if test "${SYS}" = "mingw32"; then
3110               VLC_ADD_LIBS([zvbi],[ -lpthreadGC2])
3111           fi
3112           VLC_ADD_CFLAGS([zvbi],[$ZVBI_CFLAGS])
3113           VLC_ADD_PLUGIN([zvbi])
3114           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
3115           AS_IF( [test "${enable_telx}" = "yes"],[
3116                   AC_MSG_WARN([The zvbi and telx modules are uncompatibles.
3117                                Using zvbi.])
3118                   ])
3119         ],[
3120           AC_MSG_WARN(ZVBI library not found. Enabling the telx module instead)
3121         ])
3122     ])
3123 AS_IF( [test "${enable_telx}" != "no" ],[
3124   VLC_ADD_PLUGIN([telx])
3125   ])
3126
3127 dnl
3128 dnl libass subtitle rendering module
3129 dnl
3130 AC_ARG_ENABLE(libass,
3131   [  --enable-libass         Subtitle support using libass (default enabled)])
3132 AS_IF( [test "${enable_libass}" != "no"], [
3133   PKG_CHECK_MODULES(LIBASS, libass >= 0.9.6,
3134       [
3135         VLC_ADD_LIBS([libass],[$LIBASS_LIBS])
3136         VLC_ADD_CFLAGS([libass],[$LIBASS_CFLAGS])
3137         VLC_ADD_PLUGIN([libass])
3138
3139         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3140           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3141            VLC_ADD_LIBS([libass],[-lfontconfig])
3142        ])
3143       ],[
3144         AC_MSG_WARN([LIBASS library not found])
3145       ])
3146   ])
3147
3148 dnl
3149 dnl asa demuxer
3150 dnl
3151 AC_ARG_ENABLE(asademux,
3152   [  --enable-asademux       asa subtitle demuxing (default disabled)])
3153 AS_IF( [test "${enable_asademux}" = "yes"], [
3154   PKG_CHECK_MODULES(PCRE,
3155       libpcre >= 6.5,
3156       [
3157         VLC_ADD_LDFLAGS([asademux],[$PCRE_LIBS])
3158         VLC_ADD_CFLAGS([asademux],[$PCRE_CFLAGS])
3159         if test "${SYS}" = "mingw32"; then
3160             VLC_ADD_CPPFLAGS([asademux],[-DPCRE_STATIC])
3161         fi
3162         VLC_ADD_PLUGIN([asademux])
3163       ],[
3164         AC_MSG_WARN([PCRE library not found (required for asademux)])
3165       ])
3166   ])
3167
3168 dnl
3169 dnl  kate decoder plugin
3170 dnl
3171 AC_ARG_ENABLE(kate,
3172 [  --enable-kate           kate codec (default enabled)])
3173 AS_IF([test "${enable_kate}" != "no"], [
3174   PKG_CHECK_MODULES(KATE,[kate >= 0.1.5], [
3175       VLC_ADD_PLUGIN([kate])
3176       VLC_ADD_CFLAGS([kate],[$KATE_CFLAGS])
3177       VLC_ADD_LIBS([kate],[$KATE_LIBS]) ],[
3178         AC_CHECK_HEADERS(kate/kate.h, [
3179           AC_CHECK_LIB(kate, kate_decode_init, [
3180             VLC_ADD_PLUGIN([kate])
3181             kate_libs="-lkate -logg"
3182             VLC_ADD_LDFLAGS([kate],[${kate_libs}]) ],[
3183             AS_IF([test "x${enable_kate}" != "x"], [
3184               AC_MSG_ERROR([libkate doesn't appear to be installed on your system.
3185               You also need to check that you have a libogg posterior to the 1.0 release.])
3186             ])
3187           ], [-lkate -logg])
3188         ],[
3189           AS_IF([test "x${enable_kate}" != "x"], [
3190             AC_MSG_ERROR([libkate headers do not appear to be installed on your system.
3191             You also need to check that you have a libogg posterior to the 1.0 release.])
3192           ])
3193         ])
3194   ])
3195 ])
3196
3197
3198 dnl
3199 dnl  tiger rendering for kate decoder plugin
3200 dnl
3201 AC_ARG_ENABLE(tiger,
3202 [  --enable-tiger          Tiger rendering library for Kate streams (default enabled)])
3203 AS_IF([test "${enable_tiger}" != "no"], [
3204   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3205       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])
3206       VLC_ADD_CFLAGS([kate],[$TIGER_CFLAGS])
3207       VLC_ADD_LIBS([kate],[$TIGER_LIBS]) ],[
3208         AS_IF([test "x${enable_tiger}" != "x"], [
3209           AC_MSG_ERROR([libtiger does not appear to be installed on your system.])
3210         ])
3211   ])
3212 ])
3213
3214
3215
3216 dnl
3217 dnl  Video plugins
3218 dnl
3219
3220 EXTEND_HELP_STRING([Video plugins:])
3221
3222 dnl
3223 dnl  Xlib
3224 dnl
3225
3226 AC_PATH_XTRA()
3227 AC_CHECK_HEADERS(X11/Xlib.h)
3228
3229 dnl
3230 dnl  X C Bindings modules
3231 dnl
3232 AC_ARG_ENABLE(xcb,
3233   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3234   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" -a "${SYS}" != "darwin"], [
3235     enable_xcb="yes"
3236   ], [
3237     enable_xcb="no"
3238   ])
3239 ])
3240 AC_ARG_ENABLE(xvideo,
3241   [  --enable-xvideo         XVideo support (default enabled)],, [
3242     enable_xvideo="$enable_xcb"
3243 ])
3244
3245 need_xid_provider="no"
3246 AS_IF([test "${enable_xcb}" != "no"], [
3247   dnl libxcb
3248   PKG_CHECK_MODULES(XCB, [xcb])
3249   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3250   VLC_ADD_PLUGIN([screensaver xcb_x11 xcb_window xcb_screen xcb_apps])
3251
3252   AS_IF([test "${enable_xvideo}" != "no"], [
3253     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [
3254       VLC_ADD_PLUGIN([xcb_xv])
3255     ], [
3256       PKG_CHECK_MODULES(XCB_XV, [xcb-xv], [
3257         VLC_ADD_PLUGIN([xcb_xv])
3258         VLC_ADD_CFLAGS([xcb_xv], [-DXCB_XV_OLD])
3259       ])
3260     ])
3261   ])
3262
3263   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [
3264     VLC_ADD_PLUGIN([panoramix])
3265     VLC_ADD_LIBS([panoramix],[${XCB_RANDR_LIBS} ${XCB_LIBS}])
3266     VLC_ADD_CFLAGS([panoramix],[${XCB_RANDR_CFLAGS} ${XCB_CFLAGS}])
3267   ], [true])
3268
3269   dnl xcb-utils
3270   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [
3271     have_xcb_keysyms="yes"
3272   ], [
3273     PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms], [
3274       have_xcb_keysyms="yes"
3275       VLC_ADD_CFLAGS([globalhotkeys], [-DXCB_KEYSYM_OLD_API])
3276     ], [
3277       have_xcb_keysyms="no"
3278       need_xid_provider="yes"
3279       AC_MSG_WARN([libxcb-keysyms not found. Hotkeys will not be supported.])
3280     ])
3281   ])
3282
3283   AS_IF([test "${have_xcb_keysyms}" = "yes"], [
3284     PKG_CHECK_MODULES(XPROTO, [xproto])
3285     VLC_ADD_PLUGIN([globalhotkeys])
3286     VLC_ADD_CFLAGS([globalhotkeys], [${XCB_KEYSYMS_CFLAGS} ${XCB_CFLAGS}])
3287     VLC_ADD_LIBS([globalhotkeys], [${XCB_KEYSYMS_LIBS} ${XCB_LIBS}])
3288     VLC_ADD_CFLAGS([xcb_window], [-DHAVE_XCB_KEYSYMS])
3289   ])
3290   VLC_ADD_PLUGIN([xdg_screensaver])
3291 ])
3292
3293 AC_ARG_ENABLE(glx,
3294   [  --enable-glx            X11 OpenGL (GLX) support (default enabled)],, [
3295   enable_glx="$enable_xcb"
3296 ])
3297 AS_IF([test "${enable_glx}" != "no"], [
3298   PKG_CHECK_MODULES(XLIB_XCB, [x11-xcb])
3299   PKG_CHECK_MODULES(GL, [gl],, [
3300     AC_CHECK_HEADER([GL/gl.h], [
3301       GL_CFLAGS=""
3302       GL_LIBS="-lGL"
3303     ], [
3304       AC_MSG_ERROR([GLX (libGL) cannot be found. If you do not need OpenGL with X11, use --disable-glx.])
3305     ])
3306   ])
3307   VLC_ADD_PLUGIN([xcb_glx])
3308 ])
3309 AC_SUBST([GL_CFLAGS])
3310 AC_SUBST([GL_LIBS])
3311
3312 dnl
3313 dnl  SDL module
3314 dnl
3315 AC_ARG_ENABLE(sdl,
3316   [  --enable-sdl            SDL support (default enabled)])
3317 AC_ARG_ENABLE(sdl-image,
3318   [  --enable-sdl-image      SDL image support (default enabled)])
3319 if test "${enable_sdl}" != "no"
3320 then
3321    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3322       # SDL on Darwin is heavily patched and can only run SDL_image
3323       if test "${SYS}" != "darwin"; then
3324         VLC_ADD_PLUGIN([vout_sdl aout_sdl])
3325       fi
3326       if test "${SYS}" != "mingw32"; then
3327         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3328       fi
3329       VLC_ADD_CFLAGS([vout_sdl aout_sdl],[${SDL_CFLAGS}])
3330       VLC_ADD_LIBS([vout_sdl aout_sdl],[${SDL_LIBS}])
3331
3332       # SDL_image
3333       AS_IF([ test "${enable_sdl_image}" != "no"],[
3334         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3335           VLC_ADD_PLUGIN([sdl_image])
3336           VLC_ADD_LIBS([sdl_image],[${SDL_IMAGE_LIBS}])
3337           VLC_ADD_CFLAGS([sdl_image], [${SDL_IMAGE_CFLAGS}])],
3338           [ AC_MSG_WARN([The development package for SDL_image is not installed.
3339     You should install it alongside your SDL package.])
3340           ])
3341       ])
3342    ],[
3343      AC_MSG_WARN([The development package for SDL is not present or too old.
3344                   You need 1.2.10. Alternatively you can also configure with
3345                   --disable-sdl.])
3346    ])
3347 fi
3348
3349 dnl
3350 dnl  freetype module
3351 dnl
3352 AC_ARG_ENABLE(freetype,
3353   [  --enable-freetype       freetype support (default enabled)])
3354 AC_ARG_ENABLE(fribidi,
3355   [  --enable-fribidi        fribidi support (default enabled)])
3356 AC_ARG_ENABLE(fontconfig,
3357   [  --enable-fontconfig     fontconfig support (default enabled)])
3358 if test "${enable_freetype}" != "no"
3359 then
3360    PKG_CHECK_MODULES(FREETYPE, freetype2,[
3361       VLC_ADD_PLUGIN([freetype])
3362       have_freetype=yes
3363       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3364       if test "${SYS}" = "mingw32"; then
3365         VLC_ADD_LIBS([freetype],[-liconv -lz])
3366       fi
3367       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3368       if test "${enable_fontconfig}" != "no"
3369       then
3370         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3371           [VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3372            VLC_ADD_LIBS([freetype],[-lfontconfig])])
3373         AC_CHECK_HEADERS(Carbon/Carbon.h,
3374           [VLC_ADD_LDFLAGS([freetype],[-Wl,-framework,Carbon])])
3375       fi
3376
3377      dnl fribidi support
3378       if test "${enable_fribidi}" != "no"
3379       then
3380         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3381           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3382           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3383         ])
3384       fi
3385
3386   ],[
3387   have_freetype=no
3388   AS_IF([ test "${enable_freetype}" =  "yes"],[
3389     AC_MSG_ERROR([I couldn't find the freetype package. You can download libfreetype2
3390 from http://www.freetype.org/, or configure with --disable-freetype. Have a nice day.
3391       ])
3392     ])
3393   ])
3394
3395 fi
3396
3397 dnl
3398 dnl  libxml2 module
3399 dnl
3400 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3401
3402 dnl
3403 dnl  SVG module
3404 dnl
3405 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3406
3407 dnl
3408 dnl Snapshot vout module (with cache)
3409 dnl
3410 AC_ARG_ENABLE(snapshot,
3411   [  --enable-snapshot       snapshot module (default disabled)])
3412 if test "${enable_snapshot}" = "yes"
3413 then
3414   VLC_ADD_PLUGIN([snapshot])
3415 fi
3416
3417 dnl
3418 dnl  Windows DirectX module
3419 dnl
3420
3421 if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3422 then
3423   VLC_ADD_PLUGIN([panoramix])
3424 fi
3425
3426 AC_ARG_ENABLE(directx,
3427   [  --enable-directx        Win32 DirectX support (default enabled on Win32)])
3428 if test "${enable_directx}" != "no"
3429 then
3430   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3431   then
3432       AC_CHECK_HEADERS(ddraw.h,
3433       [ VLC_ADD_PLUGIN([directx aout_directx])
3434         VLC_ADD_LIBS([directx],[-lgdi32])
3435       ],[AC_MSG_ERROR([Cannot find DirectX headers!])]
3436       )
3437       AC_CHECK_HEADERS(GL/gl.h,
3438       [ VLC_ADD_PLUGIN([glwin32])
3439         VLC_ADD_LIBS([glwin32],[-lopengl32 -lgdi32])
3440       ])
3441       AC_CHECK_HEADERS(d3d9.h,
3442       [ VLC_ADD_PLUGIN([direct3d])
3443         VLC_ADD_LIBS([direct3d],[-lgdi32])
3444       ])
3445       VLC_ADD_LIBS([direct3d directx glwin32],[-lole32])
3446   fi
3447 fi
3448
3449 dnl
3450 dnl  Windows Direct2D plugin
3451 dnl
3452 AC_ARG_ENABLE(direct2d,
3453   [  --enable-direct2d         Win7/VistaPU Direct2D support (default auto on Win32)])
3454 if test "${enable_direct2d}" != "no"; then
3455   if test "${SYS}" = "mingw32" -o "${SYS}" = "mingwce"
3456   then
3457     AC_CHECK_HEADERS(d2d1.h,
3458       [
3459         VLC_ADD_PLUGIN([direct2d])
3460         VLC_ADD_LIBS([direct2d],[-lgdi32 -lole32])
3461       ], [AC_MSG_WARN([Cannot find Direct2D headers!])]
3462     )
3463   fi
3464 fi
3465
3466 dnl
3467 dnl  win32 GDI plugin
3468 dnl
3469 AC_ARG_ENABLE(wingdi,
3470   [  --enable-wingdi         Win32 GDI module (default enabled on Win32)])
3471 if test "${enable_wingdi}" != "no"; then
3472   if test "${SYS}" = "mingw32"; then
3473     VLC_ADD_PLUGIN([wingdi])
3474     VLC_ADD_LIBS([wingdi],[-lgdi32 -lole32])
3475   fi
3476   if test "${SYS}" = "mingwce"; then
3477     VLC_ADD_PLUGIN([wingdi wingapi])
3478     VLC_ADD_LIBS([wingdi],[-laygshell])
3479     VLC_ADD_LIBS([wingapi],[-laygshell])
3480   fi
3481 fi
3482
3483
3484 dnl
3485 dnl  Linux framebuffer module
3486 dnl
3487 AC_ARG_ENABLE(fb,
3488   [  --enable-fb             Linux framebuffer support (default enabled on Linux)])
3489     if test "${enable_fb}" != "no"
3490     then
3491       AC_CHECK_HEADERS(linux/fb.h, [
3492         VLC_ADD_PLUGIN([fb])
3493       ])
3494     fi
3495
3496 dnl
3497 dnl  DirectFB module
3498 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3499 dnl  TODO: support for static linking
3500 dnl
3501 AC_ARG_ENABLE(directfb,
3502   [  --enable-directfb       DirectFB support (default disabled)])
3503 AC_ARG_WITH(directfb,
3504   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3505
3506 if test "${enable_directfb}" = "yes"; then
3507     have_directfb="false"
3508     CPPFLAGS_mydirectfb=
3509     LIBS_mydirectfb=
3510     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3511         dnl Trying the given location
3512         CPPFLAGS_save="${CPPFLAGS}"
3513         LIBS_save="${LIBS}"
3514
3515         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3516         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/"
3517         LIBS_new="${LIBS_new} -L${with_directfb}/src/.libs/"
3518
3519         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3520         LIBS="${LIBS} ${LIBS_new}"
3521
3522         dnl FIXME: too obscure
3523         AC_CHECK_HEADER([directfb.h], [
3524             AC_CHECK_LIB([direct],[direct_initialize], [
3525                 AC_CHECK_LIB([fusion], [fusion_enter], [
3526                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3527                 ], have_directfb="false")
3528             ], have_directfb="false")
3529         ], have_directfb="false")
3530
3531         dnl Restore flags
3532         CPPFLAGS="${CPPFLAGS_save}"
3533         LIBS="${LIBS_save}"
3534
3535         if test "${have_directfb}" = "true"; then
3536             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3537             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3538         fi
3539     else
3540         dnl Look for directfb-config
3541         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3542         if test "${DIRECTFB_CONFIG}" != "no"; then
3543             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3544             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3545             have_directfb="true"
3546         else
3547             dnl Trying with pkg-config
3548             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3549                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3550                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3551                 have_directfb="true"
3552                 ], [have_directfb="false"])
3553         fi
3554     fi
3555     if test "${have_directfb}" = "true"; then
3556         VLC_ADD_PLUGIN([directfb])
3557         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3558         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3559     else
3560         AC_MSG_ERROR([cannot find directfb headers and/or libraries ])
3561     fi
3562 fi
3563
3564 dnl
3565 dnl  AA plugin
3566 dnl
3567 AC_ARG_ENABLE(aa,
3568   [  --enable-aa             aalib output (default disabled)])
3569 if test "${enable_aa}" = "yes"
3570 then
3571   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3572   if test "${have_aa}" = "true"
3573   then
3574     VLC_ADD_PLUGIN([aa])
3575     VLC_ADD_LIBS([aa],[-laa])
3576     if test "${SYS}" != "mingw32"; then
3577       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3578     fi
3579   fi
3580 fi
3581
3582 dnl
3583 dnl  libcaca plugin
3584 dnl
3585 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3586
3587 dnl
3588 dnl  Audio plugins
3589 dnl
3590
3591 EXTEND_HELP_STRING([Audio plugins:])
3592
3593 dnl
3594 dnl  OSS /dev/dsp module (enabled by default except on win32)
3595 dnl
3596 AC_ARG_ENABLE(oss,
3597   [  --enable-oss            Open Sound System OSS support (default enabled)])
3598
3599 if test "${enable_oss}" != "no" &&
3600   (test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" ||
3601    test "${enable_oss}" = "yes")
3602 then
3603   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3604     VLC_ADD_PLUGIN([oss access_oss])
3605     AC_CHECK_LIB(ossaudio,main,[VLC_ADD_LIBS([oss access_oss],[-lossaudio])])
3606   ])
3607 fi
3608
3609 dnl
3610 dnl  Pulseaudio module
3611 dnl
3612 AS_IF([test "${no_x}" = "yes"], [
3613   AS_IF([test "${enable_pulse}" = "yes"], [
3614     AC_MSG_ERROR([Xlib is required for VLC PulseAudio support
3615 (see http://www.pulseaudio.org/ticket/799 for further reference).])
3616   ])
3617 ], [
3618   PKG_ENABLE_MODULES_VLC([PULSE], [], [libpulse >= 0.9.11], [Pulseaudio support], [auto])
3619   VLC_ADD_LIBS([pulse], [${X_LIBS} ${X_PRE_LIBS} -lX11])
3620 ])
3621
3622 dnl
3623 dnl  Portaudio module
3624 dnl
3625 PKG_ENABLE_MODULES_VLC([PORTAUDIO], [], [portaudio-2.0], [Portaudio library support], [auto])
3626
3627 dnl
3628 dnl  ALSA module
3629 dnl
3630 AC_ARG_ENABLE(alsa,
3631   [  --enable-alsa           Advanced Linux Sound Architecture (default auto)])
3632 have_alsa="no"
3633 AS_IF([test "${enable_alsa}" != "no"], [
3634   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.0], [
3635     have_alsa="yes"
3636   ], [
3637     AS_IF([test "x${enable_alsa}" != "x"], [
3638       AC_MSG_ERROR([alsa-lib not found])
3639     ])
3640   ])
3641 ])
3642 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3643
3644 dnl
3645 dnl  win32 waveOut plugin
3646 dnl
3647 AC_ARG_ENABLE(waveout,
3648   [  --enable-waveout        Win32 waveOut module (default enabled on Win32)])
3649 if test "${enable_waveout}" != "no"; then
3650   if test "${SYS}" = "mingw32"; then
3651     VLC_ADD_PLUGIN([waveout])
3652     VLC_ADD_LIBS([waveout],[-lwinmm])
3653   fi
3654   if test "${SYS}" = "mingwce"; then
3655     VLC_ADD_PLUGIN([waveout])
3656   fi
3657 fi
3658
3659 dnl
3660 dnl  CoreAudio plugin
3661 dnl
3662 AC_ARG_ENABLE(macosx-audio,
3663   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3664 if test "x${enable_macosx_audio}" != "xno" &&
3665   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3666 then
3667   AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,
3668     [ VLC_ADD_PLUGIN([auhal])
3669       VLC_ADD_LDFLAGS([auhal],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,Carbon])
3670     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3671 fi
3672
3673 dnl
3674 dnl  Roku HD1000 audio
3675 dnl
3676 AC_ARG_ENABLE(hd1000a,
3677   [  --enable-hd1000a        HD1000 audio module (default enabled on HD1000)])
3678 if test "${enable_hd1000a}" != "no" -a "${CXX}" != "" &&
3679   (test "${SYS}" != "mingw32" -a "${SYS}" != "mingwce" ||
3680    test "${enable_hd1000a}" = "yes")
3681 then
3682   AC_LANG_PUSH([C++])
3683   AC_CHECK_HEADERS(deschutes/libraries/hdmachinex225/PCMAudioPlayer.h, [
3684     VLC_ADD_PLUGIN([hd1000a])
3685     AC_CHECK_LIB(HDMachineX225,main,VLC_ADD_LIBS([hd1000a],[-lHDMachineX225]))  ])
3686   AC_LANG_POP([C++])
3687 fi
3688
3689 dnl
3690 dnl  JACK modules
3691 dnl
3692 PKG_ENABLE_MODULES_VLC([JACK], [jack access_jack], [jack], [JACK audio I/O modules],[auto])
3693
3694
3695 dnl
3696 dnl  CyberLink for C++ UPnP stack
3697 dnl
3698 AC_ARG_ENABLE(cyberlink,
3699   [  --enable-cyberlink      CyberLink for C++ UPnP stack (default disabled)])
3700   AS_IF([test "${enable_cyberlink}" = "yes" ], [
3701   AC_ARG_WITH(cyberlink-tree,
3702     [  --with-cyberlink-tree=PATH CyberLink for C++ tree for static linking])
3703
3704   dnl
3705   dnl test for --with-cyberlink-tree
3706   dnl
3707   AS_IF([test ! -z "${with_cyberlink_tree}" -a "${CXX}" != ""], [
3708     AC_LANG_PUSH(C++)
3709     real_cyberlink_tree="`cd ${with_cyberlink_tree} 2>/dev/null && pwd`"
3710     AS_IF([test -z "${real_cyberlink_tree}"], [
3711       dnl  The given directory can't be found
3712       AC_MSG_RESULT(no)
3713       AC_MSG_ERROR([cannot cd to ${with_cyberlink_tree}])
3714     ])
3715     CPPFLAGS_save="${CPPFLAGS}"
3716     CPPFLAGS_cyberlink="-I${real_cyberlink_tree}/include"
3717     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_cyberlink}"
3718     AC_CHECK_HEADERS([cybergarage/upnp/MediaServer.h],
3719       [ VLC_ADD_CXXFLAGS([upnp_cc], [${CPPFLAGS_cyberlink}])
3720         VLC_ADD_PLUGIN([upnp_cc])
3721       ],[
3722         AC_MSG_ERROR([cannot find CyberLink for C++ headers])
3723       ])
3724     AC_MSG_CHECKING(for libclink.a in ${with_cyberlink_tree})
3725     AS_IF([test -f "${real_cyberlink_tree}/lib/unix/libclink.a"], [
3726       AC_MSG_RESULT(${real_cyberlink_tree}/lib/unix/libclink.a)
3727       dnl The mere fact that we have to make such an ugly check sucks
3728       AC_MSG_CHECKING(for XML parser to link CyberLink with)
3729       LIBS_save="$LIBS"
3730       LIBS_cclink="no"
3731       for l in "`xml2-config --libs`" -lexpat -lxerces-c; do
3732         LIBS="$LIBS_save ${real_cyberlink_tree}/lib/unix/libclink.a -lpthread $l"
3733         AC_LINK_IFELSE([AC_LANG_PROGRAM([
3734 #include <cybergarage/upnp/media/player/MediaPlayer.h>
3735 using namespace CyberLink;
3736
3737 class testclass : public SearchResponseListener, public MediaPlayer
3738 {
3739     virtual void deviceSearchResponseReceived( SSDPPacket *)
3740     {
3741     }
3742
3743     public:
3744       testclass (void)
3745       {
3746         addSearchResponseListener (this);
3747         start ();
3748       }
3749 };
3750 ],[testclass l;])],[LIBS_cclink="$l"])
3751       done
3752       LIBS="${LIBS_save}"
3753       dnl should not happen - otherwise this needs fixing - hence FAILURE
3754       AS_IF([test "${LIBS_cclink}" = "no"],
3755         [AC_MSG_FAILURE([cannot find XML parser for CyberLink])])
3756       AC_MSG_RESULT([${LIBS_cclink}])
3757       VLC_ADD_LIBS([upnp_cc], [${real_cyberlink_tree}/lib/unix/libclink.a -lpthread ${LIBS_cclink}])
3758     ], [
3759       AC_MSG_RESULT(no)
3760       AC_MSG_ERROR([cannot find ${real_cyberlink_tree}/lib/unix/libclink.a, make sure you compiled CyberLink for C++ in ${with_cyberlink_tree}])
3761     ])
3762     CPPFLAGS="${CPPFLAGS_save}"
3763     AC_LANG_POP([C++])
3764   ])
3765 ])
3766
3767 dnl
3768 dnl UPnP Plugin (Intel SDK)
3769 dnl
3770 PKG_ENABLE_MODULES_VLC([UPNP], [upnp_intel], [libupnp], [Intel UPnp SDK],[auto])
3771
3772
3773 dnl
3774 dnl  Interface plugins
3775 dnl
3776
3777 EXTEND_HELP_STRING([Interface plugins:])
3778
3779 dnl
3780 dnl Skins2 module
3781 dnl
3782 AC_ARG_ENABLE(skins2,
3783   [AS_HELP_STRING([--enable-skins2],[Skins2 interface module (default
3784    enabled except on MacOSX, BeOS and WinCE)])])
3785 if test "${enable_skins2}" = "yes" ||
3786   (test "${SYS}" != "darwin" && test "${SYS}" != "beos" &&
3787    test "${SYS}" != "mingwce" && test "${enable_skins2}" != "no"); then
3788
3789   dnl test for the required libraries
3790   skins2_missing_lib="no"
3791
3792   dnl freetype
3793   if test "${have_freetype}" != "yes"; then
3794     skins2_missing_lib="yes"
3795     if test "${enable_skins2}" = "yes"; then
3796       AC_MSG_ERROR([Could not find freetype (required for skins2)])
3797     fi
3798   fi
3799
3800   if test "${skins2_missing_lib}" = "no" && (test "${SYS}" = "mingw32"); then
3801     VLC_ADD_PLUGIN([skins2])
3802     ALIASES="${ALIASES} svlc"
3803     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -Imodules/gui/skins2 -DWIN32_SKINS])
3804     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3805     VLC_ADD_LIBS([skins2],[-loleaut32 -lwinspool -lwinmm -lshell32 -lctl3d32 -ladvapi32 -lwsock32 -lgdi32 -lcomdlg32 -lole32 -luuid -lcomctl32])
3806
3807   else if test "${skins2_missing_lib}" = "no" && (test "${SYS}" = "darwin"); then
3808     VLC_ADD_PLUGIN([skins2])
3809     ALIASES="${ALIASES} svlc"
3810     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 -DMACOSX_SKINS])
3811     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3812     VLC_ADD_LDFLAGS([skins2],[-Wl,-framework,Carbon])
3813
3814   else if test "${skins2_missing_lib}" = "no"; then
3815     VLC_ADD_PLUGIN([skins2])
3816     ALIASES="${ALIASES} svlc"
3817     VLC_ADD_CPPFLAGS([skins2],[-Imodules/gui/skins2 ${X_CFLAGS} -DX11_SKINS])
3818     VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3819     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} -lXext -lX11])
3820     need_xid_provider="no"
3821   fi fi fi
3822 fi
3823 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes" ||
3824          (test "${SYS}" != "darwin" && test "${SYS}" != "beos" &&
3825           test "${SYS}" != "mingwce" && test "${enable_skins2}" != "no")])
3826
3827 dnl
3828 dnl Hildon UI
3829 dnl
3830 AC_ARG_ENABLE(hildon,
3831   [  --enable-hildon         Hildon touchscreen UI (default disabled)])
3832 AS_IF([test "${enable_hildon}" = "yes"], [
3833   PKG_CHECK_MODULES(HILDON, [hildon-1], [
3834     PKG_CHECK_MODULES(HILDON_FM, hildon-fm-2, [
3835       VLC_ADD_CFLAGS([hildon],[${HILDON_FM_CFLAGS} -DHAVE_HILDON_FM])
3836       VLC_ADD_LIBS([hildon],[${HILDON_FM_LIBS}])
3837     ], [
3838       AC_MSG_WARN(hildon-fm-2 not found)
3839     ])
3840     VLC_ADD_CFLAGS([hildon],[${HILDON_CFLAGS} ${X_CFLAGS}])
3841     VLC_ADD_LIBS([hildon],[${HILDON_LIBS} ${X_LIBS} ${X_PRE_LIBS} -lX11])
3842     VLC_ADD_PLUGIN([hildon])
3843     ALIASES="${ALIASES} mvlc"
3844     need_xid_provider="no"
3845   ], [
3846     AS_IF([test "${enable_hildon}" = "yes"],[
3847       AC_MSG_ERROR([Hildon libraries not found])
3848     ])
3849     enable_hildon="no"
3850   ])
3851 ])
3852 AM_CONDITIONAL(BUILD_HILDON, [test "${enable_hildon}" = "yes"])
3853
3854 dnl
3855 dnl QT 4
3856 dnl
3857 AC_ARG_ENABLE(qt4,
3858   [  --enable-qt4            Qt 4 support (default enabled) ],, [
3859   AS_IF([test "${SYS}" = "darwin"], [enable_qt4=no])
3860 ])
3861 AS_IF([test "${enable_qt4}" != "no"], [
3862   PKG_CHECK_MODULES(QT4, [QtCore QtGui >= 4.4.0], [
3863     VLC_ADD_PLUGIN([qt4])
3864     VLC_ADD_LIBS([qt4],[${QT4_LIBS}])
3865     VLC_ADD_CXXFLAGS([qt4],[${QT4_CFLAGS}])