* ALL: the build mechanism now uses automake. See HACKING for more details.
[vlc.git] / m4 / progtest.m4
1 # Search path for a program which passes the given test.
2 # Ulrich Drepper <drepper@cygnus.com>, 1996.
3 #
4 # This file can be copied and used freely without restrictions.  It can
5 # be used in projects which are not available under the GNU General Public
6 # License or the GNU Library General Public License but which still want
7 # to provide support for the GNU gettext functionality.
8 # Please note that the actual code of the GNU gettext library is covered
9 # by the GNU Library General Public License, and the rest of the GNU
10 # gettext package package is covered by the GNU General Public License.
11 # They are *not* in the public domain.
12
13 # serial 2
14
15 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
16 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
17 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
18 [# Extract the first word of "$2", so it can be a program name with args.
19 set dummy $2; ac_word=[$]2
20 AC_MSG_CHECKING([for $ac_word])
21 AC_CACHE_VAL(ac_cv_path_$1,
22 [case "[$]$1" in
23   /*)
24   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
25   ;;
26   *)
27   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
28   for ac_dir in ifelse([$5], , $PATH, [$5]); do
29     test -z "$ac_dir" && ac_dir=.
30     if test -f $ac_dir/$ac_word; then
31       if [$3]; then
32         ac_cv_path_$1="$ac_dir/$ac_word"
33         break
34       fi
35     fi
36   done
37   IFS="$ac_save_ifs"
38 dnl If no 4th arg is given, leave the cache variable unset,
39 dnl so AC_PATH_PROGS will keep looking.
40 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
41 ])dnl
42   ;;
43 esac])dnl
44 $1="$ac_cv_path_$1"
45 if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
46   AC_MSG_RESULT([$]$1)
47 else
48   AC_MSG_RESULT(no)
49 fi
50 AC_SUBST($1)dnl
51 ])