demux/mkv: do not give up if BlockGet fails
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2016"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
42
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
59
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
69
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
77
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl
98 dnl  Check the operating system
99 dnl
100 HAVE_WIN64="0"
101 HAVE_IOS="0"
102 HAVE_OSX="0"
103 HAVE_TVOS="0"
104
105 case "${host_os}" in
106   "")
107     SYS=unknown
108     ;;
109   linux*)
110     SYS=linux
111     ;;
112   bsdi*)
113     SYS=bsdi
114     CFLAGS="${CFLAGS} -pthread"
115     ;;
116   freebsd*)
117     SYS=freebsd
118     CFLAGS="${CFLAGS} -pthread"
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
121     ac_cv_ld_z_defs=no
122     ;;
123   openbsd*)
124     SYS=openbsd
125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
127     ;;
128   netbsd*)
129     SYS=netbsd
130     ;;
131   dragonfly*)
132     SYS=dragonfly
133     ;;
134   darwin*)
135
136     dnl Force gcc "-arch" flag
137     ARCH_flag=""
138     case "${host}" in
139       i?86*)
140         ARCH_flag="-arch i386"
141       ;;
142       ppc64*)
143         ARCH_flag="-arch ppc64"
144       ;;
145       ppc*)
146         ARCH_flag="-arch ppc"
147       ;;
148       x86_64*)
149         ARCH_flag="-arch x86_64"
150       ;;
151       arm*)
152         ac_cv_c_bigendian="no"
153         ac_cv_c_attribute_packed="no"
154       ;;
155     esac
156
157     SYS=darwin
158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
159     CXX="${CXX} -stdlib=libc++ -std=c++11"
160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
166
167     AC_EGREP_CPP(yes,
168             [#import <TargetConditionals.h>
169              #if TARGET_OS_IPHONE
170              yes
171              #endif],
172              [HAVE_IOS="1"],
173              [HAVE_OSX="1"])
174
175     AC_EGREP_CPP(yes,
176             [#import <TargetConditionals.h>
177              #if TARGET_OS_TV
178              yes
179              #endif],
180              [HAVE_TVOS="1"
181              HAVE_IOS="0"
182              HAVE_OSX="0"
183              ],)
184
185     dnl Allow binaries created on Lion to run on earlier releases
186     AC_EGREP_CPP(yes,
187            [#import <Cocoa/Cocoa.h>
188             #ifdef MAC_OS_X_VERSION_10_7
189             yes
190             #endif],
191             [AC_MSG_RESULT([yes])
192             AC_LIBOBJ([getdelim])
193             AC_LIBOBJ([strndup])
194             AC_LIBOBJ([strnlen])],)
195
196     dnl
197     dnl  Handle Mac OS X SDK flags
198     dnl
199     AC_ARG_WITH(macosx-sdk,
200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
201         [compile using the SDK in DIR])])
202     if test "${with_macosx_sdk}" != "" ; then
203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
205         CC="${CC} -isysroot ${with_macosx_sdk}"
206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
208         LD="${LD} -syslibroot ${with_macosx_sdk}"
209     fi
210     AC_ARG_WITH(macosx-version-min,
211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
212         [compile for Mac OS X VERSION and above])])
213     if test "${with_macosx_version_min}" != "" ; then
214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
219     fi
220     ;;
221   *mingw32* | *cygwin* | *wince* | *mingwce*)
222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
225     AC_CHECK_TOOL(WINDRES, windres, :)
226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
229     AH_TOP([#endif])
230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
241
242     case "${host_os}" in
243       *mingw32*)
244         SYS=mingw32
245         ;;
246       *cygwin*)
247         dnl Check if we are using the mno-cygwin mode in which case we are
248         dnl actually dealing with a mingw32 compiler.
249         AC_EGREP_CPP(yes,
250             [#ifdef _WIN32
251              yes
252              #endif],
253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
254         ;;
255     esac
256
257     if test "${SYS}" = "mingw32"; then
258         # DEP, ASLR, NO SEH
259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
260
261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
262         ac_default_prefix="`pwd`/_win32"
263         DESTDIR="`pwd`/_win32/"
264
265         dnl
266         dnl NSIS/MSI Installer prefix and WIN64
267         dnl
268         case "${host}" in
269             amd64*|x86_64*)
270                 HAVE_WIN64="1"
271                 WINDOWS_ARCH="x64"
272                 PROGRAMFILES="PROGRAMFILES64"
273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
274             ;;
275             *)
276                 WINDOWS_ARCH="x86"
277                 PROGRAMFILES="PROGRAMFILES"
278             ;;
279         esac
280         AC_SUBST(WINDOWS_ARCH)
281         AC_SUBST(PROGRAMFILES)
282
283     fi
284     ;;
285   *nto*)
286     SYS=nto
287     ;;
288   solaris*)
289     SYS=solaris
290     ;;
291   hpux*)
292     SYS=hpux
293     ;;
294   *os2*)
295     SYS=os2
296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
297     AC_LIBOBJ([freeaddrinfo])
298     AC_LIBOBJ([gai_strerror])
299     ;;
300   *)
301     SYS="${host_os}"
302     ;;
303 esac
304
305 dnl WinRT
306 AC_ARG_ENABLE(winstore_app,
307      AS_HELP_STRING([--enable-winstore-app],
308                     [Build targetted for Windows Store apps (default disabled)]))
309
310 vlc_winstore_app=0
311 AS_IF([test "${SYS}" = "mingw32"],[
312   LIBCOM="-lole32"
313   AS_IF([test "${enable_winstore_app}" = "yes"], [
314     vlc_winstore_app=1
315     LIBCOM=""
316      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
317      AC_LIBOBJ([gai_strerror])
318     ],[
319      VLC_ADD_LIBS([libvlccore],[-lwinmm])
320     ])
321   AC_SUBST(LIBCOM)
322   ])
323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
324
325 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
326 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
327
328 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
329 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
330 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
331 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
332
333 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
334 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
335 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
336 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
337
338 dnl
339 dnl Sadly autoconf does not think about testing foo.exe when ask to test
340 dnl for program foo on win32
341 case "${build_os}" in
342     cygwin|msys|mingw32)
343         ac_executable_extensions=".exe"
344     ;;
345     os2*)
346         BUILDEXEEXT=".exe"
347     ;;
348     *)
349     ;;
350 esac
351 AC_SUBST(BUILDEXEEXT)
352
353 dnl Android is linux, but a bit different
354 AS_IF([test "$SYS" = linux],[
355     AC_MSG_CHECKING([for an Android system])
356     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
357         [[#ifndef __ANDROID__
358          # error Not Android
359          #endif
360         ]],[[;]])
361     ],[
362       HAVE_ANDROID="1"
363       AC_MSG_RESULT([yes])
364     ],[
365       AC_MSG_RESULT([no])
366     ])
367 ])
368 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
369
370 dnl Tizen (minimum SDK version: 2.3)
371 AS_IF([test "$SYS" = linux],[
372     AC_MSG_CHECKING([for Tizen])
373     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
374         [[#include <tizen.h>
375         ]],[[;]])
376     ],[
377       HAVE_TIZEN="1"
378       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
379       AC_MSG_RESULT([yes])
380     ],[
381       AC_MSG_RESULT([no])
382     ])
383 ])
384 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
385
386 dnl
387 dnl  Check for the contrib directory
388 dnl
389 AC_ARG_WITH(contrib,
390   [AS_HELP_STRING([--with-contrib[=DIR]],
391     [search for 3rd party libraries in DIR/include and DIR/lib])
392 ])
393 AC_MSG_CHECKING([for 3rd party libraries path])
394 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
395   CONTRIB_DIR="${srcdir}/contrib/${host}"
396   AS_IF([test ! -d "${CONTRIB_DIR}"], [
397     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
398     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
399     AS_IF([test ! -d "${CONTRIB_DIR}"], [
400       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
401       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
402       AS_IF([test ! -d "${CONTRIB_DIR}"], [
403         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
404         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
405         AS_IF([test ! -d "${CONTRIB_DIR}"], [
406           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
407           CONTRIB_DIR=""
408           AC_MSG_RESULT([not found])
409         ])
410       ])
411     ])
412   ])
413 ], [
414   AS_IF([test "${with_contrib}" != "no"], [
415     CONTRIB_DIR="${with_contrib}"
416   ], [
417     CONTRIB_DIR=""
418     AC_MSG_RESULT([disabled])
419   ])
420 ])
421 AS_IF([test -n "${CONTRIB_DIR}"], [
422   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
423     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
424   ], [
425     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
426     CONTRIB_DIR=""
427     AC_MSG_RESULT([not usable])
428   ])
429
430 ])
431 AS_IF([test -n "${CONTRIB_DIR}"], [
432   AC_MSG_RESULT([${CONTRIB_DIR}])
433   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
434   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
435   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
436   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
437   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
438   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
439
440   AS_IF([test -z "$LUAC"], [
441     dnl Old contribs mixed cross-tools and cross-compiled executables
442     AS_IF([test -x "${CONTRIB_DIR}/bin/luac"], [
443       LUAC="${CONTRIB_DIR}/bin/luac"
444     ])
445
446     dnl Newer contribs follow usual name space rules
447     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac"], [
448       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac"
449     ])
450   ])
451
452   AS_IF([test "${SYS}" = "darwin"], [
453     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
454     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
455   ])
456 ], [
457   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
458     AC_MSG_ERROR([Third party libraries not found!])
459   ])
460 ])
461 AC_SUBST(CONTRIB_DIR)
462
463 dnl Add extras/tools to the PATH
464 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
465 AS_IF([test -d "${TOOLS_DIR}"], [
466     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
467     export PATH="${TOOLS_DIR}":$PATH
468 ])
469
470 dnl
471 dnl  Libtool
472 dnl  It's very bad, but our former custom system was worst
473 dnl  -- Courmisch
474 dnl
475
476 dnl override platform specific check for dependent libraries
477 dnl otherwise libtool linking of shared libraries will
478 dnl fail on anything other than pass_all.
479 AC_CACHE_VAL(lt_cv_deplibs_check_method,
480     [lt_cv_deplibs_check_method=pass_all])
481
482 LT_INIT([dlopen win32-dll shared disable-static])
483 LT_LANG([C++])
484 LT_LANG([Windows Resource])
485
486 DOLT
487
488 lt_cv_deplibs_check_method=pass_all
489
490 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
491   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
492 ])
493
494 dnl
495 dnl Gettext stuff
496 dnl
497 AM_GNU_GETTEXT_VERSION([0.19.7])
498 AM_GNU_GETTEXT([external], [need-formatstring-macros])
499
500 dnl
501 dnl Iconv stuff
502 dnl
503 AM_ICONV
504
505 dnl
506 dnl checks for mingw
507 AS_IF([test "${SYS}" = "mingw32"], [
508
509 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
510 #if !defined(__MINGW32__)
511 # error Not compiling with mingw
512 #endif
513     ])], [
514
515 dnl Check for broken versions of mingw-runtime compatability library
516     AC_MSG_CHECKING(for broken mingw-runtime)
517     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
518 #include <_mingw.h>
519 #if defined(__MINGW64_VERSION_MAJOR)
520 # if __MINGW64_VERSION_MAJOR < 3
521 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
522 # endif
523 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
524 # error Attempting to use mingw-runtime with broken vsnprintf support
525 #endif
526     ])], [
527         AC_MSG_RESULT([ok])
528     ], [
529         AC_MSG_RESULT([present])
530         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
531     ])
532
533     dnl force use of mingw provided c99 *printf over msvcrt
534     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
535
536     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
537     VLC_ADD_LDFLAGS([vlc],[-mwindows])
538
539     dnl Check for the need to include the mingwex lib for mingw32
540     VLC_SAVE_FLAGS
541     AC_CHECK_LIB(mingwex,opendir,
542         AC_CHECK_LIB(mingw32,opendir,,
543             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
544     )
545     VLC_RESTORE_FLAGS
546     ], [
547         AC_MSG_RESULT([Not compiling with mingw])
548     ])
549
550     dnl Check for fnative-struct or mms-bitfields support for mingw32
551     VLC_SAVE_FLAGS
552     CFLAGS="${CFLAGS} -mms-bitfields"
553     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
554     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
555         [ac_cv_c_mms_bitfields],
556         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
557     if test "${ac_cv_c_mms_bitfields}" = "no"; then
558         VLC_RESTORE_FLAGS
559         CFLAGS="${CFLAGS} -fnative-struct"
560         CXXFLAGS="${CXXFLAGS} -fnative-struct"
561         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
562             [ac_cv_c_fnative_struct],
563             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
564         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
565     fi
566 ])
567
568
569 dnl
570 dnl Buggy glibc prevention. Purposedly not cached.
571 dnl See sourceware.org bugs 5058 and 5443.
572 dnl Ubuntu alone has 20 bug numbers for this...
573 dnl
574 AC_MSG_CHECKING(for buggy GNU/libc versions)
575 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
576 #include <limits.h>
577 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
578   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
579 # error GNU/libc with dcgettext killer bug!
580 #endif
581 ])], [
582   AC_MSG_RESULT([not present])
583 ], [
584   AC_MSG_RESULT([found])
585   AS_IF([test "x${enable_nls}" != "xno"], [
586     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
587 work-around for this. Check with your distribution vendor on how to update the
588 glibc run-time. Alternatively, build with --disable-nls.])
589   ])
590 ])
591
592 dnl Plugin compilation stuff
593
594 VLC_LIBRARY_SUFFIX
595
596 dnl Check for system libs needed
597 need_libc=false
598
599 dnl Check for usual libc functions
600 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
601 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime tdestroy uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
602 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp])
603 AC_REPLACE_FUNCS([gettimeofday])
604 AC_CHECK_FUNC(fdatasync,,
605   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
606 ])
607
608 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
609
610 dnl mingw64 implements those as static inline, not functions with C linkage
611 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
612 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
613 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
614 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
615
616 dnl C11 static_assert()
617 AC_MSG_CHECKING([for static_assert in assert.h])
618 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
619 static_assert(1, "The impossible happened.");
620 ])], [
621   AC_MSG_RESULT([yes])
622   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
623 ], [
624   AC_MSG_RESULT([no])
625 ])
626
627 # Windows CE does not have strcoll()
628 AC_FUNC_STRCOLL
629
630 dnl Check for non-standard system calls
631 case "$SYS" in
632   "linux")
633     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
634     ;;
635   "mingw32")
636     AC_CHECK_FUNCS([_lock_file])
637     ;;
638 esac
639
640 AH_BOTTOM([#include <vlc_fixups.h>])
641
642 dnl Check for struct pollfd
643 AC_CHECK_TYPES([struct pollfd],,,
644 [#include <sys/types.h>
645 #if HAVE_POLL
646 # include <poll.h>
647 #elif defined (_WIN32)
648 # include <winsock2.h>
649 #endif
650 ])
651
652 dnl Check for struct timespec
653 AC_CHECK_TYPES([struct timespec],,,
654 [#include <time.h>])
655
656 dnl Check for max_align_t
657 AC_CHECK_TYPES([max_align_t],,,
658 [#include <stddef.h>])
659
660 dnl Checks for socket stuff
661 VLC_SAVE_FLAGS
662 SOCKET_LIBS=""
663 AC_SEARCH_LIBS(connect, [socket], [
664   AS_IF([test "$ac_cv_search_connect" != "none required"], [
665     SOCKET_LIBS="$ac_cv_search_connect"
666   ])
667 ], [
668   AS_IF([test "${SYS}" = "mingw32"], [
669     SOCKET_LIBS="-lws2_32"
670   ])
671 ])
672
673 AC_SEARCH_LIBS([inet_pton], [nsl], [
674  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
675     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
676   ])
677 ],, [${SOCKET_LIBS}])
678
679 LIBS="${LIBS} ${SOCKET_LIBS}"
680 AC_LINK_IFELSE([
681     AC_LANG_PROGRAM([#ifdef _WIN32
682         # if _WIN32_WINNT < 0x600
683         #  error Needs vista+
684         # endif
685         #include <ws2tcpip.h>
686         #else
687         #include <sys/socket.h>
688         #include <arpa/inet.h>
689         #endif], [
690         char dst[[sizeof(struct in_addr)]];
691         inet_pton(AF_INET, "127.0.0.1", dst);
692     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
693 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
694 VLC_RESTORE_FLAGS
695 AC_SUBST(SOCKET_LIBS)
696
697 dnl Check for socklen_t
698 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
699 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
700 ac_cv_type_socklen_t,
701 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
702 [#include <sys/types.h>
703 #ifdef _WIN32
704 # include <winsock2.h>
705 # include <ws2tcpip.h>
706 #else
707 # include <sys/socket.h>
708 #endif]], [[socklen_t len; len = 0;]])],
709 ac_cv_type_socklen_t=yes,
710 ac_cv_type_socklen_t=no)])
711 AS_IF([test "$ac_cv_type_socklen_t" = no],
712  [AC_DEFINE(socklen_t, int)])
713
714 dnl Check for struct sockaddr_storage
715 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
716 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
717 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
718   [AC_TRY_COMPILE(
719     [#include <sys/types.h>
720      #if defined( _WIN32 )
721      # include <winsock2.h>
722      #else
723      # include <sys/socket.h>
724      #endif], [struct sockaddr_storage addr;],
725      ac_cv_struct_sockaddr_storage=yes,
726      ac_cv_struct_sockaddr_storage=no)])
727 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
728   AC_DEFINE(sockaddr_storage, sockaddr)
729   AC_DEFINE(ss_family, sa_family)
730 ])
731
732 dnl FreeBSD has a gnugetopt library for this:
733 GNUGETOPT_LIBS=""
734 AC_CHECK_FUNC(getopt_long,, [
735   AC_CHECK_LIB([gnugetopt],[getopt_long], [
736     GNUGETOPT_LIBS="-lgnugetopt"
737   ])
738 ])
739 AC_SUBST(GNUGETOPT_LIBS)
740
741 AC_CHECK_LIB(m,cos,[
742   LIBM="-lm"
743 ], [
744   LIBM=""
745 ])
746 AC_SUBST(LIBM)
747
748 AC_CHECK_LIB(m,lrintf, [
749   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
750   VLC_ADD_LIBS([skins2],[-lm])
751 ])
752 AC_CHECK_LIB(m,nanf,
753   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
754 )
755
756 dnl Check for dynamic plugins
757 LIBDL=""
758 have_dynamic_objects="no"
759 VLC_SAVE_FLAGS
760 AC_SEARCH_LIBS(dlsym, [dl svld], [
761   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
762     LIBDL="$ac_cv_search_dlsym"
763   ])
764   have_dynamic_objects="yes"
765 ])
766 VLC_RESTORE_FLAGS
767
768 # Windows
769 AS_IF([test "${SYS}" = "mingw32"], [
770   LIBDL=""
771   have_dynamic_objects="yes" #assume we can use shared objects
772 ])
773
774 AS_IF([test "${enable_shared}" = "no"], [
775   have_dynamic_objects=no
776 ])
777 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
778
779 AC_SUBST(LIBDL)
780
781 dnl Check for thread library
782 LIBPTHREAD=""
783 AS_IF([test "${SYS}" != "mingw32"], [
784   VLC_SAVE_FLAGS
785   LIBS=""
786   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
787     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
788       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
789     ])
790   ])
791   VLC_RESTORE_FLAGS
792 ])
793 AC_SUBST(LIBPTHREAD)
794
795 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
796   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
797     LIBRT="$ac_cv_search_clock_nanosleep"
798   ])
799 ], [
800   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
801     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
802       LIBRT="$ac_cv_search_nanosleep"
803     ])
804   ])
805 ])
806 AC_SUBST(LIBRT)
807
808 dnl
809 dnl Check for headers
810 dnl
811
812 dnl  POSIX
813 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
814 AC_CHECK_HEADERS([net/if.h], [], [],
815 [
816 #include <sys/types.h>
817 #include <sys/socket.h>
818 ])
819 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
820 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
821
822 dnl  BSD
823 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
824
825 dnl  GNU/Linux
826 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
827
828 dnl  MacOS
829 AC_CHECK_HEADERS([xlocale.h])
830
831 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
832 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
833 AC_CHECK_TYPE(ssize_t,, [
834   AC_DEFINE(ssize_t, int)
835 ])
836
837 dnl It seems that autoconf detects pkg-config only during the first
838 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
839 dnl it is nested within a conditional block, so it was not working right.
840 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
841 AC_ARG_VAR(PKG_CONFIG_PATH,
842        [Paths where to find .pc not at the default location])
843 PKG_PROG_PKG_CONFIG()
844
845 dnl On some OS we need static linking
846 AS_IF([test -n "${PKG_CONFIG}" ],[
847     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
848         PKG_CONFIG="${PKG_CONFIG} --static"
849     ])
850 ])
851
852
853 dnl
854 dnl Check for zlib.h and -lz along with system -lminizip if available
855 dnl
856 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
857 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
858 if test "${have_zlib}" = "yes"
859 then
860   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
861   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
862     AC_CHECK_HEADERS([unzip.h], [
863       have_minizip=yes
864       MINIZIP_LIBS="-lminizip -lz"
865     ], [
866       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
867       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
868       have_minizip=no
869     ])
870   ])
871   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
872   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
873 fi
874 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
875
876
877 dnl
878 dnl Domain name i18n support via GNU libidn
879 dnl
880 PKG_CHECK_MODULES([IDN], [libidn], [
881   have_libidn="yes"
882   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
883 ], [
884   have_libidn="no"
885 ])
886
887
888 dnl Check for dbus
889 AC_ARG_ENABLE(dbus,
890   [AS_HELP_STRING([--enable-dbus],
891     [compile D-Bus message bus support (default enabled)])])
892 have_dbus="no"
893 AS_IF([test "${enable_dbus}" != "no"], [
894   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
895     have_dbus="yes"
896   ], [
897     AS_IF([test -n "${enable_dbus}"], [
898       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
899     ], [
900       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
901     ])
902   ])
903 ])
904 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
905
906
907 dnl Check for systemd
908 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
909   have_systemd="yes"
910 ], [
911   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
912 ])
913 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
914
915
916 dnl Check for ntohl, etc.
917 VLC_SAVE_FLAGS
918 CFLAGS="${CFLAGS} -Wall -Werror"
919 AC_CACHE_CHECK([for ntohl in sys/param.h],
920     [ac_cv_c_ntohl_sys_param_h],
921     [     AC_TRY_COMPILE([#include <sys/param.h>],
922         [int meuh; ntohl(meuh);],
923         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
924 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
925     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
926 fi
927 VLC_RESTORE_FLAGS
928
929 EXTEND_HELP_STRING([Optimization options:])
930 dnl
931 dnl  Compiler warnings
932 dnl
933
934 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
935 RDC_PROG_CC_FLAGS([-pipe])
936 AC_LANG_PUSH([C++])
937 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
938 AC_LANG_POP([C++])
939
940 dnl
941 dnl  Debugging mode
942 dnl
943 AC_ARG_ENABLE(debug,
944   [AS_HELP_STRING([--enable-debug],
945     [build with run-time assertions (default disabled)])],,
946   [enable_debug="no"])
947 AH_TEMPLATE(NDEBUG,
948             [Define to 1 if debug code should NOT be compiled])
949 AS_IF([test "${enable_debug}" != "no"], [
950   AC_CHECK_HEADERS([valgrind/valgrind.h])
951 ], [
952   AC_DEFINE(NDEBUG)
953 ])
954
955 dnl
956 dnl  Profiling
957 dnl
958 AC_ARG_ENABLE(gprof,
959   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
960   [enable_gprof="no"])
961 AS_IF([test "${enable_gprof}" != "no"], [
962   CFLAGS="${CFLAGS} -pg"
963   CXXFLAGS="${CXXFLAGS} -pg"
964   OBJCFLAGS="${OBJCFLAGS} -pg"
965   LDFLAGS="${LDFLAGS} -pg"
966 ])
967
968 AC_ARG_ENABLE(cprof,
969   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
970   [enable_cprof="no"])
971 AS_IF([test "${enable_gprof}" != "no"], [
972   CFLAGS="${CFLAGS} -finstrument-functions"
973   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
974   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
975   LDFLAGS="${LDFLAGS} -finstrument-functions"
976 ])
977
978 dnl
979 dnl  Test coverage
980 dnl
981 AC_ARG_ENABLE(coverage,
982   [AS_HELP_STRING([--enable-coverage],
983     [build for test coverage (default disabled)])],,
984   [enable_coverage="no"])
985 AS_IF([test "${enable_coverage}" != "no"], [
986   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
987   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
988   LDFLAGS="-lgcov ${LDFLAGS}"
989 ])
990
991 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
992   VLC_SAVE_FLAGS
993   CFLAGS="${CFLAGS} -fvisibility=hidden"
994   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
995   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
996   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
997                  [ac_cv_c_visibility_hidden], [
998     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
999       ac_cv_c_visibility_hidden=yes
1000     ], [
1001       ac_cv_c_visibility_hidden=no
1002     ])
1003   ])
1004   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1005 ])
1006
1007
1008 dnl
1009 dnl  Enable/disable optimizations
1010 dnl
1011 AC_ARG_ENABLE(optimizations,
1012   [AS_HELP_STRING([--disable-optimizations],
1013     [disable compiler optimizations (default enabled)])],,
1014   [enable_optimizations="yes"])
1015
1016 dnl Check for various optimization flags
1017 AS_IF([test "${enable_optimizations}" != "no"], [
1018
1019   dnl -O3 only in production builds
1020   AS_IF([test "${enable_debug}" = "no"], [
1021     VLC_SAVE_FLAGS
1022     CFLAGS="${CFLAGS} -O3"
1023     CXXFLAGS="${CXXFLAGS} -O3"
1024     OBJCFLAGS="${OBJCFLAGS} -O3"
1025     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1026       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1027         ac_cv_c_o3=yes
1028       ], [
1029         ac_cv_c_o3=no
1030       ])
1031     ])
1032     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1033   ])
1034
1035   dnl Check for fast maths
1036   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1037   AC_LANG_PUSH(C++)
1038   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1039   AC_LANG_POP
1040
1041 AH_BOTTOM([
1042 #if defined(_MSC_VER) && !defined(__clang__)
1043 # pragma fenv_access(off)
1044 # pragma fp_contract(on)
1045 #elif defined(__GNUC__)
1046 /* Not supported so far */
1047 #else
1048 # pragma STDC FENV_ACCESS OFF
1049 # pragma STDC FP_CONTRACT ON
1050 #endif
1051 ])
1052
1053   dnl Check for -funroll-loops
1054   VLC_SAVE_FLAGS
1055   CFLAGS="${CFLAGS} -funroll-loops"
1056   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1057   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1058   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1059     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1060       ac_cv_c_unroll_loops=yes
1061     ], [
1062       ac_cv_c_unroll_loops=no
1063     ])
1064   ])
1065   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1066
1067   AS_IF([test "$enable_debug" = "no"], [
1068     dnl Check for -fomit-frame-pointer
1069     VLC_SAVE_FLAGS
1070     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1071     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1072     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1073     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1074       [ac_cv_c_omit_frame_pointer], [
1075       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1076         ac_cv_c_omit_frame_pointer=yes
1077       ], [
1078         ac_cv_c_omit_frame_pointer=no
1079       ])
1080     ])
1081     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1082   ])
1083 ])
1084
1085 VLC_SAVE_FLAGS
1086 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1087 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1088   AC_TRY_LINK([],, [
1089     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1090   ], [
1091     ac_cv_ld_bsymbolic=""
1092   ])
1093 ])
1094 VLC_RESTORE_FLAGS
1095 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1096 AC_SUBST(SYMBOLIC_LDFLAGS)
1097
1098 VLC_SAVE_FLAGS
1099 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1100 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1101   AC_TRY_LINK([],, [
1102     ac_cv_ld_z_defs="yes"
1103   ], [
1104     ac_cv_ld_z_defs="no"
1105   ])
1106 ])
1107 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1108
1109 dnl Checks for __attribute__(aligned()) directive
1110 VLC_SAVE_FLAGS
1111 CFLAGS="${CFLAGS} -Werror"
1112 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1113     [ac_cv_c_attribute_aligned],
1114     [ac_cv_c_attribute_aligned=0
1115     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1116         AC_TRY_COMPILE([],
1117         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1118         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1119     done])
1120 VLC_RESTORE_FLAGS
1121 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1122     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1123         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1124 fi
1125
1126 dnl Check for __attribute__((packed))
1127 AC_CACHE_CHECK([for __attribute__((packed))],
1128   [ac_cv_c_attribute_packed],
1129   [ac_cv_c_attribute_packed=no
1130    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1131                     [ac_cv_c_attribute_packed=yes])])
1132 if test "${ac_cv_c_attribute_packed}" != "no"; then
1133   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1134 fi
1135
1136 dnl
1137 dnl  Check the CPU
1138 dnl
1139 case "${host_cpu}" in
1140   "")
1141     ARCH=unknown
1142     ;;
1143   *)
1144     ARCH="${host_cpu}"
1145     ;;
1146 esac
1147
1148 dnl Check for backtrace() support
1149 AC_CHECK_HEADERS(execinfo.h)
1150 AC_CHECK_FUNCS(backtrace)
1151
1152 dnl
1153 dnl  default modules
1154 dnl
1155 ALIASES="${ALIASES} cvlc rvlc"
1156
1157 dnl
1158 dnl  Accelerated modules
1159 dnl
1160
1161 dnl  Check for fully working MMX intrinsics
1162 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1163 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1164 AC_ARG_ENABLE(mmx,
1165   [AS_HELP_STRING([--disable-mmx],
1166     [disable MMX optimizations (default auto)])],,[
1167   case "${host_cpu}" in
1168     i?86|x86_64)
1169       enable_mmx="yes"
1170       ;;
1171     *)
1172       enable_mmx="no"
1173       ;;
1174   esac
1175 ])
1176 have_mmx="no"
1177 have_mmxext="no"
1178 AS_IF([test "${enable_mmx}" != "no"], [
1179   ARCH="${ARCH} mmx"
1180   VLC_SAVE_FLAGS
1181   CFLAGS="${CFLAGS} -mmmx"
1182   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1183     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1184 [#include <mmintrin.h>
1185 #include <stdint.h>
1186 uint64_t frobzor;]], [
1187 [__m64 a, b, c;
1188 a = b = c = (__m64)frobzor;
1189 a = _mm_slli_pi16(a, 3);
1190 a = _mm_adds_pi16(a, b);
1191 c = _mm_srli_pi16(c, 8);
1192 c = _mm_slli_pi16(c, 3);
1193 b = _mm_adds_pi16(b, c);
1194 a = _mm_unpacklo_pi8(a, b);
1195 frobzor = (uint64_t)a;]])], [
1196       ac_cv_c_mmx_intrinsics=yes
1197     ], [
1198       ac_cv_c_mmx_intrinsics=no
1199     ])
1200   ])
1201   VLC_RESTORE_FLAGS
1202   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1203     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1204   ])
1205
1206   VLC_SAVE_FLAGS
1207   CFLAGS="${CFLAGS} -mmmx"
1208   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1209     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1210 void *p;
1211 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1212 ]])
1213     ], [
1214       ac_cv_mmx_inline=yes
1215     ], [
1216       ac_cv_mmx_inline=no
1217     ])
1218   ])
1219   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1220     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1221     have_mmx="yes"
1222   ])
1223
1224   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1225                  [ac_cv_mmxext_inline], [
1226     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1227 void *p;
1228 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1229 ]])
1230     ], [
1231       ac_cv_mmxext_inline=yes
1232     ], [
1233       ac_cv_mmxext_inline=no
1234     ])
1235   ])
1236   VLC_RESTORE_FLAGS
1237   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1238     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1239     have_mmxext="yes"
1240   ])
1241 ])
1242 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1243 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1244
1245 dnl  Check for fully workin SSE2 intrinsics
1246 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1247 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1248 AC_ARG_ENABLE(sse,
1249   [AS_HELP_STRING([--disable-sse],
1250     [disable SSE (1-4) optimizations (default auto)])],, [
1251   case "${host_cpu}" in
1252     i?86|x86_64)
1253       enable_sse=yes
1254       ;;
1255     *)
1256       enable_sse=no
1257       ;;
1258   esac
1259 ])
1260 have_sse2="no"
1261 AS_IF([test "${enable_sse}" != "no"], [
1262   ARCH="${ARCH} sse sse2"
1263
1264   VLC_SAVE_FLAGS
1265   CFLAGS="${CFLAGS} -msse2"
1266   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1267     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1268 [#include <emmintrin.h>
1269 #include <stdint.h>
1270 uint64_t frobzor;]], [
1271 [__m128i a, b, c;
1272 a = b = c = _mm_set1_epi64((__m64)frobzor);
1273 a = _mm_slli_epi16(a, 3);
1274 a = _mm_adds_epi16(a, b);
1275 c = _mm_srli_epi16(c, 8);
1276 c = _mm_slli_epi16(c, 3);
1277 b = _mm_adds_epi16(b, c);
1278 a = _mm_unpacklo_epi8(a, b);
1279 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1280       ac_cv_c_sse2_intrinsics=yes
1281     ], [
1282       ac_cv_c_sse2_intrinsics=no
1283     ])
1284   ])
1285   VLC_RESTORE_FLAGS
1286   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1287     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1288   ])
1289
1290   VLC_SAVE_FLAGS
1291   CFLAGS="${CFLAGS} -msse"
1292   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1293     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1294 void *p;
1295 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1296 ]])
1297     ], [
1298       ac_cv_sse_inline=yes
1299     ], [
1300       ac_cv_sse_inline=no
1301     ])
1302   ])
1303
1304   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1305     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1306   ])
1307
1308   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1309     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1310 void *p;
1311 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1312 ]])
1313     ], [
1314       ac_cv_sse2_inline=yes
1315     ], [
1316       ac_cv_sse2_inline=no
1317     ])
1318   ])
1319   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1320     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1321     have_sse2="yes"
1322   ])
1323
1324   # SSE3
1325   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1326     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1327 void *p;
1328 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1329 ]])
1330     ], [
1331       ac_cv_sse3_inline=yes
1332     ], [
1333       ac_cv_sse3_inline=no
1334     ])
1335   ])
1336
1337   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1338     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1339   # SSSE3
1340   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1341     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1342 void *p;
1343 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1344 ]])
1345     ], [
1346       ac_cv_ssse3_inline=yes
1347     ], [
1348       ac_cv_ssse3_inline=no
1349     ])
1350   ])
1351
1352   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1353     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1354
1355   # SSE4.1
1356   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1357                  [ac_cv_sse4_1_inline], [
1358     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1359 void *p;
1360 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1361 ]])
1362     ], [
1363       ac_cv_sse4_1_inline=yes
1364     ], [
1365       ac_cv_sse4_1_inline=no
1366     ])
1367   ])
1368
1369   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1370     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1371
1372   # SSE4.2
1373   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1374                  [ac_cv_sse4_2_inline], [
1375     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1376 void *p;
1377 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1378 ]])
1379     ], [
1380       ac_cv_sse4_2_inline=yes
1381     ], [
1382       ac_cv_sse4_2_inline=no
1383     ])
1384   ])
1385
1386   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1387     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1388
1389   # SSE4A
1390   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1391     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1392 void *p;
1393 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1394 ]])
1395     ], [
1396       ac_cv_sse4a_inline=yes
1397     ], [
1398       ac_cv_sse4a_inline=no
1399     ])
1400   ])
1401   VLC_RESTORE_FLAGS
1402   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1403     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1404 ])
1405 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1406
1407 VLC_SAVE_FLAGS
1408 CFLAGS="${CFLAGS} -mmmx"
1409 have_3dnow="no"
1410 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1411   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1412 void *p;
1413 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1414 ]])
1415   ], [
1416     ac_cv_3dnow_inline=yes
1417   ], [
1418     ac_cv_3dnow_inline=no
1419   ])
1420 ])
1421 VLC_RESTORE_FLAGS
1422 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1423   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1424             [Define to 1 if 3D Now! inline assembly is available.])
1425   have_3dnow="yes"
1426 ])
1427 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1428
1429
1430 AC_ARG_ENABLE(neon,
1431   [AS_HELP_STRING([--disable-neon],
1432     [disable NEON optimizations (default auto)])],, [
1433   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1434 ])
1435 AS_IF([test "${enable_neon}" != "no"], [
1436   VLC_SAVE_FLAGS
1437   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1438   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1439     AC_COMPILE_IFELSE([
1440       AC_LANG_PROGRAM(,[[
1441 asm volatile("vqmovun.s64 d0, q1":::"d0");
1442 ]])
1443     ], [
1444       ac_cv_arm_neon="yes"
1445     ], [
1446       ac_cv_arm_neon="no"
1447     ])
1448   ])
1449   VLC_RESTORE_FLAGS
1450 ])
1451 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1452
1453 AC_ARG_ENABLE(arm64,
1454   [AS_HELP_STRING([--disable-arm64],
1455     [disable arm 64-bit optimizations (default auto)])],, [
1456   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1457 ])
1458 AS_IF([test "${enable_arm64}" != "no"], [
1459   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1460     AC_COMPILE_IFELSE([
1461       AC_LANG_PROGRAM(,[[
1462 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1463 ]])
1464     ], [
1465       ac_cv_arm64="yes"
1466     ], [
1467       ac_cv_arm64="no"
1468     ])
1469   ])
1470 ])
1471 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1472
1473
1474 AC_ARG_ENABLE(altivec,
1475   [AS_HELP_STRING([--disable-altivec],
1476     [disable AltiVec optimizations (default auto)])],, [
1477   AS_CASE("${host_cpu}", [powerpc*],
1478         [enable_altivec=yes], [enable_altivec=no])
1479 ])
1480 have_altivec="no"
1481 ALTIVEC_CFLAGS=""
1482 AS_IF([test "${enable_altivec}" = "yes"], [
1483   ARCH="${ARCH} altivec";
1484   VLC_SAVE_FLAGS
1485   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1486     [ac_cv_altivec_inline],
1487     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1488          ac_cv_altivec_inline="yes",
1489          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1490           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1491             [ac_cv_altivec_inline="-Wa,-maltivec"],
1492             ac_cv_altivec_inline=no)
1493          ])])
1494   VLC_RESTORE_FLAGS
1495   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1496     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1497               [Define to 1 if AltiVec inline assembly is available.])
1498     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1499       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1500       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1501     ])
1502     have_altivec="yes"
1503   ])
1504
1505   VLC_SAVE_FLAGS
1506   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1507   [ac_cv_c_altivec], [
1508     CFLAGS="${CFLAGS} -maltivec"
1509     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1510 [#include <altivec.h>]], [
1511 [vec_ld(0, (unsigned char *)0);]])], [
1512       ac_cv_c_altivec="-maltivec"
1513     ], [
1514       ac_cv_c_altivec="no"
1515     ])
1516   ])
1517   VLC_RESTORE_FLAGS
1518   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1519     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1520     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1521     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1522     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1523     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1524     have_altivec="yes"
1525   ])
1526   AC_CHECK_HEADERS(altivec.h)
1527
1528   VLC_SAVE_FLAGS
1529   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1530   AC_CACHE_CHECK([if linker needs -framework vecLib],
1531     [ac_cv_ld_altivec],
1532     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1533   VLC_RESTORE_FLAGS
1534   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1535     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1536   ])
1537 ])
1538 AC_SUBST(ALTIVEC_CFLAGS)
1539 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1540
1541 dnl
1542 dnl  Memory usage
1543 dnl
1544 AC_ARG_ENABLE(optimize-memory,
1545   [AS_HELP_STRING([--enable-optimize-memory],
1546     [optimize memory usage over performance])])
1547 if test "${enable_optimize_memory}" = "yes"; then
1548   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1549 fi
1550
1551 dnl
1552 dnl Allow running as root (useful for people running on embedded platforms)
1553 dnl
1554 AC_ARG_ENABLE(run-as-root,
1555   [AS_HELP_STRING([--enable-run-as-root],
1556     [allow running VLC as root (default disabled)])])
1557 AS_IF([test "${enable_run_as_root}" = "yes"],[
1558     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1559               [Define to 1 to allow running VLC as root (uid 0).])
1560 ])
1561
1562 dnl
1563 dnl Stream output
1564 dnl
1565 AC_ARG_ENABLE(sout,
1566   [AS_HELP_STRING([--disable-sout],
1567     [disable streaming output (default enabled)])])
1568 AS_IF([test "${enable_sout}" != "no"], [
1569   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1570 ])
1571 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1572
1573 dnl Lua modules
1574 AC_ARG_ENABLE(lua,
1575   [AS_HELP_STRING([--disable-lua],
1576     [disable LUA scripting support (default enabled)])])
1577 if test "${enable_lua}" != "no"
1578 then
1579   PKG_CHECK_MODULES(LUA, lua5.2,
1580     [ have_lua=yes ],
1581     [
1582     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1583
1584     PKG_CHECK_MODULES(LUA, lua5.1,
1585       [ have_lua=yes ],
1586       [
1587       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1588       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1589         [ have_lua=yes ],
1590         [
1591           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1592           have_lua=yes
1593           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1594             [],
1595             [ have_lua=no ] )
1596           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1597             [LUA_LIBS="-llua5.2"],
1598           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1599             [LUA_LIBS="-llua5.1"],
1600             AC_CHECK_LIB( lua51 , luaL_newstate,
1601               [LUA_LIBS="-llua51"],
1602               AC_CHECK_LIB( lua , luaL_newstate,
1603                 [LUA_LIBS="-llua"],
1604                 [ have_lua=no
1605                 ], [-lm])
1606             )))
1607         ])
1608       ])
1609     ])
1610   if test "x${have_lua}" != "xyes" ;  then
1611       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1612   fi
1613   AC_ARG_VAR([LUAC], [LUA byte compiler])
1614   AS_IF([test -z "$LUAC"], [
1615      AC_CHECK_TOOL(LUAC, [luac], [false])
1616   ])
1617   AS_IF([test "${LUAC}" = "false"], [
1618     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1619   ])
1620   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1621     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1622   ])
1623 fi
1624 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1625
1626
1627 dnl
1628 dnl HTTP daemon
1629 dnl
1630 AC_ARG_ENABLE(httpd,
1631   [AS_HELP_STRING([--disable-httpd],
1632     [disable the built-in HTTP server (default enabled)])])
1633 if test "${enable_httpd}" != "no"
1634 then
1635   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1636 fi
1637 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1638
1639
1640 dnl
1641 dnl VideoLAN manager
1642 dnl
1643 AC_ARG_ENABLE(vlm,
1644   [AS_HELP_STRING([--disable-vlm],
1645     [disable the stream manager (default enabled)])],,
1646   [enable_vlm="${enable_sout}"])
1647 AS_IF([test "${enable_vlm}" != "no"], [
1648   AS_IF([test "${enable_sout}" = "no"], [
1649     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1650   ])
1651   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1652 ])
1653 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1654
1655
1656 dnl
1657 dnl Addons manager storage and repositories modules
1658 dnl
1659 AC_ARG_ENABLE(addonmanagermodules,
1660   [AS_HELP_STRING([--disable-addonmanagermodules],
1661     [disable the addons manager modules (default enabled)])])
1662 if test "${enable_addonmanagermodules}" != "no"
1663 then
1664   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1665 fi
1666 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1667
1668
1669 dnl
1670 dnl  Input plugins
1671 dnl
1672
1673 EXTEND_HELP_STRING([Input plugins:])
1674
1675 dnl
1676 dnl  libarchive access module
1677 dnl
1678 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1679
1680 dnl
1681 dnl  live555 input
1682 dnl
1683 AC_ARG_ENABLE(live555,
1684   [AS_HELP_STRING([--enable-live555],
1685     [enable RTSP input through live555 (default enabled)])])
1686
1687 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1688   PKG_CHECK_MODULES(LIVE555, live555, [
1689     VLC_ADD_PLUGIN([live555])
1690     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1691     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1692   ], [
1693     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1694
1695     AC_LANG_PUSH(C++)
1696     VLC_SAVE_FLAGS
1697
1698     dnl detect include paths
1699     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1700       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1701     ], [
1702       AS_IF([test "${SYS}" != "os2"], [
1703         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1704         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1705       ], [
1706         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1707         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1708         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1709       ])
1710     ])
1711
1712     dnl CPP Flags
1713     AS_IF([test "${SYS}" = "solaris"], [
1714       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1715     ])
1716     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1717     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1718
1719     dnl version check
1720     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1721       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1722 [#include <liveMedia_version.hh>
1723 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1724 # error BOOM
1725 #endif]])
1726       ], [
1727         ac_cv_live555="yes"
1728       ], [
1729         ac_cv_live555="no"
1730       ])
1731     ])
1732
1733     AS_IF([test "$ac_cv_live555" = "no"], [
1734       AC_MSG_WARN([live555 is missing or its installed version is too old:
1735 Version 2011.12.23 or later is required to proceed.
1736 You can get an updated one from http://www.live555.com/liveMedia .])
1737       AS_IF([test -n "${enable_live555}"], [
1738         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1739       ])
1740     ], [
1741       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1742       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1743       AS_IF([test "${SYS}" = "mingw32"], [
1744         # add ws2_32 for closesocket, select, recv
1745         other_libs="$other_libs -lws2_32"
1746       ])
1747
1748       dnl We need to check for pic because live555 don't provide shared libs
1749       dnl and we want to build a plugins so we need -fPIC on some arch.
1750       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1751       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1752       AC_CHECK_LIB(liveMedia_pic, main, [
1753         VLC_ADD_PLUGIN([live555])
1754         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1755       ],[
1756         AC_CHECK_LIB(liveMedia, main, [
1757           VLC_ADD_PLUGIN([live555])
1758           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1759         ],[],[${other_libs}])
1760       ],[${other_libs_pic}])
1761     ])
1762     VLC_RESTORE_FLAGS
1763     AC_LANG_POP(C++)
1764   ])
1765 ])
1766
1767 dnl
1768 dnl IIDC and DV FireWire input modules
1769 dnl
1770 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1771 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1772
1773 dnl
1774 dnl - linsys modules: access module check for libzvbi
1775 dnl
1776 AC_ARG_ENABLE(linsys,
1777   [AS_HELP_STRING([--enable-linsys],
1778     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1779 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1780   VLC_ADD_PLUGIN([linsys_hdsdi])
1781   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1782     VLC_ADD_PLUGIN([linsys_sdi])
1783   ], [
1784     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1785   ])
1786 ])
1787
1788 dnl
1789 dnl dvdread module: check for libdvdread
1790 dnl
1791 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1792
1793 dnl
1794 dnl libdvdnav plugin
1795 dnl
1796 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1797 AS_IF([test "${enable_dvdnav}" != "no"], [
1798   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1799     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1800       AC_MSG_RESULT(yes)
1801       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1802       ],[
1803       AC_MSG_RESULT(no)
1804     ])
1805 ])
1806
1807 dnl
1808 dnl  Blu-ray Disc Support with libbluray
1809 dnl
1810 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1811
1812 dnl
1813 dnl  OpenCV wrapper and example filters
1814 dnl
1815 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1816
1817
1818 dnl
1819 dnl  libsmbclient plugin
1820 dnl
1821 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1822 AS_IF([test "${SYS}" = "mingw32" -a "${enable_smbclient}" != "no"], [ VLC_ADD_PLUGIN([smb]) ])
1823
1824 dnl
1825 dnl  liBDSM access module
1826 dnl
1827 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1828
1829 dnl
1830 dnl sftp access support
1831 dnl
1832 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1833
1834 dnl
1835 dnl nfs access support
1836 dnl
1837 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1838
1839 dnl
1840 dnl  Video4Linux 2
1841 dnl
1842 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1843   [disable Video4Linux version 2 (default auto)])])
1844 have_v4l2="no"
1845 AS_IF([test "$enable_v4l2" != "no"], [
1846   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1847     have_v4l2="yes"
1848   ])
1849 ])
1850 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1851
1852 dnl
1853 dnl special access module for Blackmagic SDI cards
1854 dnl
1855 AC_ARG_ENABLE(decklink,
1856   [AS_HELP_STRING([--disable-decklink],
1857     [disable Blackmagic DeckLink SDI input (default auto)])])
1858 AC_ARG_WITH(decklink_sdk,
1859   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1860     [                        location of Blackmagic DeckLink SDI SDK])])
1861 have_decklink=no
1862 if test "${enable_decklink}" != "no"
1863 then
1864   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1865   then
1866     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1867   fi
1868   VLC_SAVE_FLAGS
1869   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1870   AC_LANG_PUSH(C++)
1871   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1872       have_decklink=yes
1873   ], [
1874       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1875   ])
1876   AC_LANG_POP(C++)
1877   VLC_RESTORE_FLAGS
1878 fi
1879 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1880
1881
1882 dnl
1883 dnl  Built-in CD-DA and VCD module
1884 dnl
1885 AC_ARG_ENABLE(vcd,
1886   [AS_HELP_STRING([--disable-vcd],
1887     [disable built-in VCD and CD-DA support (default enabled)])])
1888
1889 AC_ARG_ENABLE(libcddb,
1890   [AS_HELP_STRING([--disable-libcddb],
1891     [disable CDDB for Audio CD (default enabled)])])
1892
1893 if test "${enable_vcd}" != "no"
1894 then
1895   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1896   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1897     AC_MSG_RESULT(yes)
1898     VLC_ADD_PLUGIN([vcd cdda])
1899   ],[
1900     AC_MSG_RESULT(no)
1901   ])
1902
1903   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1904   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1905     AC_MSG_RESULT(yes)
1906     VLC_ADD_PLUGIN([vcd cdda])
1907     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1908   ],[
1909     AC_MSG_RESULT(no)
1910   ])
1911
1912   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1913   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1914     AC_MSG_RESULT(yes)
1915     VLC_ADD_PLUGIN([vcd cdda])
1916     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1917   ],[
1918     AC_MSG_RESULT(no)
1919   ])
1920
1921   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1922   then
1923     VLC_ADD_PLUGIN([vcd cdda])
1924   fi
1925
1926   if test "$enable_libcddb" != "no"; then
1927     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1928       HAVE_LIBCDDB=yes
1929       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1930       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1931       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1932       ],:
1933       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1934       HAVE_LIBCDDB=no])
1935   fi
1936 fi
1937
1938 dnl
1939 dnl Linux DVB
1940 dnl
1941 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1942   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1943 [#include <linux/dvb/version.h>
1944 #if (DVB_API_VERSION < 5)
1945 # error Linux DVB API v3.2 and older are not supported.
1946 #endif
1947 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1948 # error Linux DVB API v5.0 is unsupported. Please update.
1949 #endif
1950 ]])], [
1951   ac_cv_linux_dvb_5_1=yes
1952 ], [
1953   ac_cv_linux_dvb_5_1=no
1954 ])])
1955 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1956
1957 dnl
1958 dnl  Screen capture module
1959 dnl
1960 AC_ARG_ENABLE(screen,
1961   [AS_HELP_STRING([--enable-screen],
1962     [disable screen capture (default enabled)])])
1963 if test "${enable_screen}" != "no"; then
1964   if test "${SYS}" = "darwin"; then
1965     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1966       VLC_ADD_PLUGIN([screen])
1967     ])
1968   fi
1969 fi
1970 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1971
1972 dnl
1973 dnl  VNC/RFB access module
1974 dnl
1975 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1976
1977 dnl  RDP/Remote Desktop access module
1978 dnl
1979 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1980
1981 dnl
1982 dnl  Real RTSP plugin
1983 dnl
1984 AC_ARG_ENABLE(realrtsp,
1985   [  --enable-realrtsp       Real RTSP module (default disabled)])
1986 if test "${enable_realrtsp}" = "yes"; then
1987   VLC_ADD_PLUGIN([access_realrtsp])
1988 fi
1989
1990 dnl
1991 dnl MacOS eyeTV
1992 AC_ARG_ENABLE(macosx-eyetv,
1993   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1994 if test "x${enable_macosx_eyetv}" != "xno" &&
1995   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1996 then
1997   VLC_ADD_PLUGIN([access_eyetv])
1998 fi
1999
2000 dnl
2001 dnl QTKit
2002 AC_ARG_ENABLE(macosx-qtkit,
2003   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2004 if test "x${enable_macosx_qtkit}" != "xno" &&
2005   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2006 then
2007   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2008       VLC_ADD_PLUGIN([qtsound])
2009     ])
2010 fi
2011
2012 dnl
2013 dnl AVFoundation
2014 AC_SUBST(have_avfoundation, ["no"])
2015 AC_ARG_ENABLE(macosx-avfoundation,
2016   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2017 if test "x${enable_macosx_avfoundation}" != "xno" &&
2018   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2019 then
2020   SAVED_LIBS="${LIBS}"
2021   LIBS="-framework AVFoundation"
2022   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2023   LIBS="${SAVED_LIBS}"
2024   if test "${have_avfoundation}" != "no"
2025   then
2026     VLC_ADD_PLUGIN([avcapture])
2027   fi
2028 fi
2029 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2030
2031 dnl
2032 dnl  DCP plugin (using asdcplib)
2033 dnl
2034 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2035 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2036
2037 dnl
2038 dnl  Demux plugins
2039 dnl
2040
2041 EXTEND_HELP_STRING([Mux/Demux plugins:])
2042
2043 dnl
2044 dnl  libdvbpsi check for ts mux/demux
2045 dnl
2046 have_dvbpsi="no"
2047 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2048 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2049
2050
2051 dnl
2052 dnl  GME demux plugin
2053 dnl
2054 AC_ARG_ENABLE(gme,
2055   [AS_HELP_STRING([--enable-gme],
2056     [use Game Music Emu (default auto)])])
2057 AS_IF([test "${enable_gme}" != "no"], [
2058   AC_CHECK_HEADER([gme/gme.h], [
2059     VLC_ADD_LIBS([gme], [-lgme])
2060     VLC_ADD_PLUGIN([gme])
2061   ], [
2062     AS_IF([test "x${enable_gme}" != "x"], [
2063       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2064     ])
2065   ])
2066 ])
2067
2068
2069 dnl
2070 dnl  SIDPlay plugin
2071 dnl
2072 AC_ARG_ENABLE(sid,
2073     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2074 AS_IF([test "${enable_sid}" != "no"], [
2075     PKG_CHECK_MODULES(SID, [libsidplay2], [
2076         AC_LANG_PUSH(C++)
2077         oldCPPFLAGS="$CPPFLAGS"
2078         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2079         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2080             VLC_ADD_PLUGIN([sid])
2081             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2082             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2083         ], [
2084             AS_IF([test -n "${enable_sid}"],
2085                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2086                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2087                 )
2088         ])
2089         CPPFLAGS="$oldCPPFLAGS"
2090         AC_LANG_POP(C++)
2091     ], [
2092         AS_IF([test "x${enable_sid}" = "xyes"],
2093             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2094             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2095             )
2096     ])
2097 ])
2098
2099
2100 dnl
2101 dnl  ogg demux plugin
2102 dnl
2103 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2104 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2105     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2106 ],[true])
2107 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2108 if test "${enable_sout}" != "no"; then
2109 dnl Check for libshout
2110     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2111 fi
2112
2113 dnl
2114 dnl  matroska demux plugin
2115 dnl
2116 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2117
2118 dnl
2119 dnl  modplug demux plugin
2120 dnl
2121 AC_ARG_ENABLE(mod,
2122   [AS_HELP_STRING([--disable-mod],
2123     [do not use libmodplug (default auto)])])
2124 if test "${enable_mod}" != "no" ; then
2125     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2126           VLC_ADD_PLUGIN([mod])
2127           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2128           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2129           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2130     ],[
2131        AS_IF([test -n "${enable_mod}"],
2132          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2133          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2134     ])
2135 fi
2136
2137 dnl
2138 dnl  mpc demux plugin
2139 dnl
2140 AC_ARG_ENABLE(mpc,
2141   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2142 if test "${enable_mpc}" != "no"
2143 then
2144   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2145     VLC_ADD_PLUGIN([mpc])
2146     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2147     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2148     VLC_ADD_PLUGIN([mpc])
2149     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2150 fi
2151
2152 dnl
2153 dnl  Codec plugins
2154 dnl
2155
2156 EXTEND_HELP_STRING([Codec plugins:])
2157
2158 dnl
2159 dnl wmafixed plugin
2160 dnl
2161 AC_ARG_ENABLE(wma-fixed,
2162   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2163 if test "${enable_wma_fixed}" = "yes"
2164 then
2165   VLC_ADD_PLUGIN([wma_fixed])
2166 fi
2167
2168 dnl
2169 dnl shine encoder plugin
2170 dnl
2171 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2172
2173
2174 dnl
2175 dnl openmax il codec plugin
2176 dnl
2177 AC_ARG_ENABLE(omxil,
2178   [  --enable-omxil          openmax il codec module (default disabled)])
2179 if test "${enable_omxil}" = "yes"
2180 then
2181   VLC_ADD_PLUGIN([omxil])
2182 fi
2183
2184 dnl
2185 dnl openmax il vout plugin
2186 dnl
2187 AC_ARG_ENABLE(omxil-vout,
2188   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2189 if test "${enable_omxil_vout}" = "yes"
2190 then
2191   VLC_ADD_PLUGIN([omxil_vout])
2192 fi
2193
2194 dnl
2195 dnl raspberry pi openmax il configuration
2196 dnl
2197 AC_ARG_ENABLE(rpi-omxil,
2198   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2199 if test "${enable_rpi_omxil}" = "yes"
2200 then
2201   VLC_ADD_PLUGIN([omxil omxil_vout])
2202   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2203 fi
2204
2205 dnl
2206 dnl CrystalHD codec plugin
2207 dnl
2208 AC_ARG_ENABLE(crystalhd,
2209   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2210 if test "${enable_crystalhd}" != "no"; then
2211     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2212       VLC_ADD_PLUGIN([crystalhd])
2213       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2214     ],[
2215       if test "${SYS}" = "mingw32" ; then
2216         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2217           VLC_ADD_PLUGIN([crystalhd])
2218           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2219             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2220             ])
2221         ],[
2222           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2223                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2224                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2225         ],[#define __LINUX_USER__
2226                #include <libcrystalhd/bc_dts_types.h>
2227         ])
2228       fi
2229     ],[
2230        #include <libcrystalhd/bc_dts_types.h>
2231       ])
2232 fi
2233
2234 dnl
2235 dnl  mad plugin
2236 dnl
2237 have_mad="no"
2238 MAD_CFLAGS=""
2239 MAD_LIBS=""
2240
2241 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2242   enable_mad="yes"
2243 ], [
2244   with_mad="no"
2245 ])
2246 AS_IF([test "${with_mad}" != "no"], [
2247   MAD_CFLAGS="-I${with_mad}/include"
2248   MAD_LIBS="-L${with_mad}/lib"
2249 ])
2250
2251 AC_ARG_ENABLE(mad,
2252   [  --enable-mad            libmad module (default enabled)])
2253 AS_IF([test "${enable_mad}" != "no"], [
2254   VLC_SAVE_FLAGS
2255   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2256   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2257   AC_CHECK_HEADERS(mad.h, [
2258     AC_CHECK_LIB(mad, mad_bit_init, [
2259       have_mad="yes"
2260       MAD_LIBS="${MAD_LIBS} -lmad"
2261     ])
2262   ])
2263   VLC_RESTORE_FLAGS
2264   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2265     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2266   ])
2267 ])
2268 AC_SUBST(MAD_CFLAGS)
2269 AC_SUBST(MAD_LIBS)
2270 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2271
2272 dnl  mpg123 plugin
2273 dnl
2274 dnl
2275 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2276
2277
2278 AC_ARG_ENABLE(merge-ffmpeg,
2279 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2280   enable_merge_ffmpeg="no"
2281 ])
2282 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2283
2284 AC_MSG_CHECKING([for libavutil variant])
2285 PKG_CHECK_EXISTS([libavutil], [
2286   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2287   libavutil_micro="${libavutil_version##*.}"
2288   AS_IF([test ${libavutil_micro} -le 99], [
2289     avfork="libav"
2290   ], [
2291     avfork="ffmpeg"
2292   ])
2293 ], [
2294   avfork="none"
2295 ])
2296 AC_MSG_RESULT([${avfork}])
2297
2298 dnl
2299 dnl gstreamer stuff
2300 dnl
2301 AC_ARG_ENABLE(gst-decode,
2302   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2303
2304 have_gst_decode="no"
2305 AS_IF([test "${enable_gst_decode}" != "no"], [
2306   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2307     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2308       have_gst_decode="yes"
2309     ], [
2310       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2311     ])
2312   ], [
2313     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2314   ])
2315 ])
2316 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2317
2318 dnl
2319 dnl  avcodec decoder/encoder plugin
2320 dnl
2321 AC_ARG_ENABLE(avcodec,
2322 [  --enable-avcodec        libavcodec codec (default enabled)])
2323 AS_IF([test "${enable_avcodec}" != "no"], [
2324   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2325   case "${avfork}" in
2326     libav) av_codec_ver="57.16.0" ;;
2327     ffmpeg) av_codec_ver="57.37.100" ;;
2328     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2329   esac
2330   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2331     VLC_SAVE_FLAGS
2332     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2333     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2334     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2335     AC_CHECK_HEADERS(libavutil/avutil.h)
2336     VLC_RESTORE_FLAGS
2337     have_avcodec="yes"
2338   ],[
2339     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2340   ])
2341 ], [
2342   have_avcodec="no"
2343 ])
2344 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2345
2346 dnl
2347 dnl libva needs avcodec
2348 dnl
2349 AC_ARG_ENABLE(libva,
2350   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2351
2352 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2353   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2354 ])
2355
2356 have_vaapi="no"
2357 have_vaapi_drm="no"
2358 have_vaapi_x11="no"
2359 AS_IF([test "${enable_libva}" != "no"], [
2360   PKG_CHECK_MODULES([LIBVA], [libva], [
2361     have_vaapi="yes"
2362   ], [
2363     AS_IF([test -n "${enable_libva}"], [
2364       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2365     ], [
2366       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2367     ])
2368   ])
2369   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2370     have_vaapi_drm="yes"
2371   ], [
2372     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2373   ])
2374   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2375     have_vaapi_x11="yes"
2376   ], [
2377     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2378   ])
2379 ])
2380 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2381 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2382
2383 have_avcodec_vaapi="no"
2384 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2385   VLC_SAVE_FLAGS
2386   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2387   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2388   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2389     AC_MSG_NOTICE([VA API acceleration activated])
2390     have_avcodec_vaapi="yes"
2391   ],[
2392     AS_IF([test -n "${enable_libva}"], [
2393       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2394     ], [
2395       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2396     ])
2397   ])
2398   VLC_RESTORE_FLAGS
2399 ])
2400 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2401
2402 dnl
2403 dnl dxva2 needs avcodec
2404 dnl
2405 AC_ARG_ENABLE(dxva2,
2406   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2407
2408 have_avcodec_dxva2="no"
2409 AS_IF([test "${enable_dxva2}" != "no"], [
2410   if test "${SYS}" = "mingw32"; then
2411   AS_IF([test "x${have_avcodec}" = "xyes"], [
2412     AC_CHECK_HEADERS(dxva2api.h,
2413       [
2414         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2415            AC_MSG_NOTICE([DxVA2 acceleration activated])
2416            have_avcodec_dxva2="yes"
2417         ],[
2418     AS_IF([test "${enable_dxva2}" = "yes"],
2419           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2420               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2421         ], [#undef _WIN32_WINNT
2422             /* DXVA2 is only available in Vista and above */
2423             #define _WIN32_WINNT 0x600])
2424       ],[
2425     AS_IF([test "${enable_dxva2}" = "yes"],
2426               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2427               [AC_MSG_WARN([dxva2api.h not found])])
2428       ],[#include <d3d9.h>])
2429   ],[
2430     AS_IF([test "x${enable_dxva2}" != "x"], [
2431       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2432     ])
2433   ])
2434   fi
2435 ])
2436 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2437
2438 dnl
2439 dnl d3d11va needs avcodec
2440 dnl
2441 AC_ARG_ENABLE(d3d11va,
2442   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2443
2444 have_avcodec_d3d11va="no"
2445 AS_IF([test "${enable_d3d11va}" != "no"], [
2446   if test "${SYS}" = "mingw32"; then
2447   AS_IF([test "x${have_avcodec}" = "xyes"], [
2448         AC_CHECK_TYPES([ID3D11VideoDecoder],
2449           [
2450             AC_CHECK_HEADERS(dxva2api.h,
2451               [
2452                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2453                    AC_MSG_NOTICE([D3D11 acceleration activated])
2454                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2455                    have_avcodec_d3d11va="yes"
2456                 ],[
2457                   AS_IF([test "${enable_d3d11va}" = "yes"],
2458                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2459                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2460                   ], [#undef _WIN32_WINNT
2461                       /* D3D11 is only available in Vista and above */
2462                       #define _WIN32_WINNT 0x600])
2463                   ],[
2464                     AS_IF([test "${enable_d3d11va}" = "yes"],
2465                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2466                           [AC_MSG_WARN([dxva2api.h not found])])
2467                   ],[#include <d3d9.h>])
2468           ],[
2469             AS_IF([test "${enable_d3d11va}" = "yes"],
2470                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2471                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2472           ], [#include <d3d11.h>])
2473   ],[
2474     AS_IF([test "x${enable_d3d11va}" != "x"], [
2475       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2476     ])
2477   ])
2478   fi
2479 ])
2480 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2481
2482 dnl
2483 dnl DXGI debug
2484 dnl
2485 AC_CHECK_HEADERS(dxgidebug.h)
2486
2487 dnl
2488 dnl vda needs avcodec
2489 dnl
2490 AC_ARG_ENABLE(vda,
2491   [  --enable-vda          VDA  support (default auto)])
2492
2493 have_avcodec_vda="no"
2494 AS_IF([test "${enable_vda}" != "no"], [
2495   if test "${SYS}" = "darwin"; then
2496   AS_IF([test "x${have_avcodec}" = "xyes"], [
2497     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2498       [
2499         AC_CHECK_HEADERS(libavcodec/vda.h, [
2500            have_avcodec_vda="yes"
2501         ],[
2502         AS_IF([test "${enable_vda}" = "yes"],
2503               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2504               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2505         ])
2506   ],[
2507         AS_IF([test "${enable_vda}" = "yes"],
2508               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2509               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2510       ])
2511   ],[
2512     AS_IF([test "x${enable_vda}" != "x"], [
2513       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2514     ])
2515  ])
2516  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2517      SAVE_LIBS=$LIBS
2518      LIBS="$LIBS $AVCODEC_LIBS"
2519      AC_CHECK_FUNCS([av_vda_alloc_context])
2520      LIBS=$SAVE_LIBS
2521  ])
2522  fi
2523 ])
2524 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2525
2526 dnl
2527 dnl  avformat demuxer/muxer plugin
2528 dnl
2529
2530 AC_ARG_ENABLE(avformat,
2531 [  --enable-avformat       libavformat containers (default enabled)],, [
2532   enable_avformat="${have_avcodec}"
2533 ])
2534 have_avformat="no"
2535 AS_IF([test "${enable_avformat}" != "no"], [
2536   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2537       have_avformat="yes"
2538       VLC_SAVE_FLAGS
2539       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2540       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2541       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2542       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2543       AC_CHECK_HEADERS(libavutil/avutil.h)
2544       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2545         have_avformat="no"
2546       ])
2547       VLC_RESTORE_FLAGS
2548     ],[
2549       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2550   ])
2551 ])
2552 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2553
2554 dnl
2555 dnl  swscale image scaling and conversion plugin
2556 dnl
2557
2558 AC_ARG_ENABLE(swscale,
2559   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2560           (default enabled)]))
2561 if test "${enable_swscale}" != "no"
2562 then
2563   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2564     [
2565       VLC_SAVE_FLAGS
2566       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2567       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2568       AC_CHECK_HEADERS(libswscale/swscale.h)
2569       AC_CHECK_HEADERS(libavutil/avutil.h)
2570       VLC_ADD_PLUGIN([swscale])
2571       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2572       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2573       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2574         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2575       ])
2576       VLC_RESTORE_FLAGS
2577     ],[
2578       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2579   ])
2580 fi
2581
2582 dnl
2583 dnl  postproc plugin
2584 dnl
2585
2586 AC_ARG_ENABLE(postproc,
2587 [  --enable-postproc       libpostproc image post-processing (default auto)])
2588 if test "${enable_postproc}" != "no"
2589 then
2590   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2591     [
2592       VLC_SAVE_FLAGS
2593       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2594       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2595       AC_CHECK_HEADERS(postproc/postprocess.h)
2596       VLC_ADD_PLUGIN([postproc])
2597       VLC_RESTORE_FLAGS
2598     ],[
2599       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2600   ])
2601 fi
2602
2603 dnl
2604 dnl  faad decoder plugin
2605 dnl
2606 AC_ARG_ENABLE(faad,
2607 [  --enable-faad           faad codec (default auto)])
2608 have_faad="no"
2609 AS_IF([test "${enable_faad}" != "no"], [
2610   AC_CHECK_HEADERS([neaacdec.h], [
2611     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2612
2613     AS_IF([test "${have_faad}" = "yes"], [
2614       VLC_ADD_PLUGIN([faad])
2615       VLC_ADD_LIBS([faad],[-lfaad])
2616     ], [
2617       AS_IF([test "${enable_faad}" = "yes"], [
2618         AC_MSG_ERROR([cannot find FAAD library])
2619       ], [
2620         AC_MSG_WARN([cannot find FAAD library])
2621       ])
2622     ])
2623   ])
2624 ])
2625
2626 dnl
2627 dnl  AOM decoder plugin
2628 dnl
2629 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2630
2631 dnl
2632 dnl libvpx decoder plugin
2633 dnl
2634 AC_ARG_ENABLE(vpx,
2635     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2636 AS_IF([test "${enable_vpx}" != "no"],[
2637     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2638         VLC_ADD_PLUGIN([vpx])
2639         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2640         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2641         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2642             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2643         ], [], [${VPX_LIBS}])
2644         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2645             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2646         ], [], [${VPX_LIBS}])
2647         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2648             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2649         ], [], [${VPX_LIBS}])
2650         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2651             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2652         ], [], [${VPX_LIBS}])
2653     ], [
2654     AS_IF([test "${enable_vpx}" = "yes"],[
2655         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2656     ])])
2657 ])
2658
2659 dnl
2660 dnl twolame encoder plugin
2661 dnl
2662 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2663
2664 dnl
2665 dnl fdk-aac encoder plugin
2666 dnl
2667 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2668
2669
2670 dnl
2671 dnl A52/AC3 decoder plugin
2672 dnl
2673 AC_ARG_ENABLE(a52,
2674   [  --enable-a52            A/52 support with liba52 (default enabled)])
2675 if test "${enable_a52}" != "no"
2676 then
2677   AC_ARG_WITH(a52,
2678     [  --with-a52=PATH         a52 headers and libraries])
2679     if test -z "${with_a52}"
2680     then
2681       LDFLAGS_test=""
2682       CPPFLAGS_test=""
2683     else
2684       LDFLAGS_test="-L${with_a52}/lib"
2685       CPPFLAGS_test="-I${with_a52}/include"
2686     fi
2687     VLC_SAVE_FLAGS
2688     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2689     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2690     AC_CHECK_HEADERS(a52dec/a52.h, [
2691       AC_CHECK_LIB(a52, a52_free, [
2692         VLC_ADD_PLUGIN([a52])
2693         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52])
2694         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2695       ],[
2696         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2697         ], [$LIBM])
2698     ],[
2699       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2700     ])
2701     VLC_RESTORE_FLAGS
2702 fi
2703
2704 dnl
2705 dnl DTS Coherent Acoustics decoder plugin
2706 dnl
2707 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2708
2709 dnl
2710 dnl  Flac plugin
2711 dnl
2712 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2713
2714 dnl
2715 dnl  Libmpeg2 plugin
2716 dnl
2717 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2718
2719 dnl
2720 dnl  Vorbis plugin
2721 dnl
2722 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2723
2724 dnl
2725 dnl  Tremor plugin
2726 dnl
2727 AC_ARG_ENABLE(tremor,
2728   [  --enable-tremor         Tremor decoder support (default disabled)])
2729 if test "${enable_tremor}" = "yes"
2730 then
2731   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2732     VLC_ADD_PLUGIN([tremor])
2733    ],[])
2734 fi
2735
2736 dnl
2737 dnl  Speex plugins
2738 dnl
2739 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2740 have_speexdsp="no"
2741 AS_IF([test "${enable_speex}" != "no"], [
2742   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2743     have_speexdsp="yes"
2744   ], [
2745     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2746   ])
2747 ])
2748 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2749
2750 dnl
2751 dnl  Opus plugin
2752 dnl
2753 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2754
2755 dnl
2756 dnl  theora decoder plugin
2757 dnl
2758 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2759
2760 dnl
2761 dnl  OggSpots decoder plugin
2762 dnl
2763 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2764
2765 dnl
2766 dnl  Daala decoder plugin
2767 dnl
2768 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2769
2770 dnl
2771 dnl  schroedinger decoder plugin (for dirac format video)
2772 dnl
2773 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2774
2775 dnl
2776 dnl  PNG decoder module
2777 dnl
2778 AC_ARG_ENABLE(png,
2779   [  --enable-png            PNG support (default enabled)])
2780 AS_IF([test "${enable_png}" != "no"], [
2781 AC_CHECK_HEADERS(png.h, [
2782   VLC_SAVE_FLAGS
2783   LDFLAGS="${LDFLAGS} -lz $LIBM"
2784   AC_CHECK_LIB(png, png_set_rows, [
2785     VLC_ADD_PLUGIN([png])
2786   ], [], [-lz $LIBM])
2787   VLC_RESTORE_FLAGS
2788   ])
2789 ])
2790
2791 dnl
2792 dnl  JPEG decoder module
2793 dnl
2794 AC_ARG_ENABLE(jpeg,
2795   [  --enable-jpeg           JPEG support (default enabled)])
2796 AS_IF([test "${enable_jpeg}" != "no"], [
2797 AC_CHECK_HEADERS(jpeglib.h, [
2798   VLC_ADD_PLUGIN([jpeg])
2799   ])
2800 ])
2801
2802 dnl
2803 dnl  BPG decoder module
2804 dnl
2805 AC_ARG_ENABLE(bpg,
2806   [  --enable-bpg           BPG support (default disabled)])
2807 AS_IF([test "${enable_bpg}" != "no"], [
2808 AC_CHECK_HEADERS(libbpg.h, [
2809   VLC_ADD_PLUGIN([bpg])
2810   ])
2811 ])
2812
2813 dnl
2814 dnl H262 encoder plugin (lib262)
2815 dnl
2816 AC_ARG_ENABLE(x262,
2817   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2818 if test "${enable_x262}" != "no"; then
2819     PKG_CHECK_MODULES(X262, x262, [
2820         VLC_ADD_PLUGIN([x262])
2821         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2822         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2823           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2824         ])
2825         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2826         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2827           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2828         fi
2829     ], [
2830        if test "${enable_x262}" = "yes"; then
2831         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2832        fi
2833     ])
2834 fi
2835
2836 dnl x265 encoder
2837 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2838
2839 dnl
2840 dnl H264 encoder plugin (10-bit lib264)
2841 dnl
2842 AC_ARG_ENABLE(x26410b,
2843   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2844 if test "${enable_x26410b}" != "no"; then
2845     PKG_CHECK_MODULES(X26410B, x26410b, [
2846         VLC_ADD_PLUGIN([x26410b])
2847         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2848         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2849           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2850         ])
2851         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2852         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2853           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2854         fi
2855     ], [
2856        if test "${enable_x26410b}" = "yes"; then
2857         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2858        fi
2859     ])
2860 fi
2861
2862
2863 dnl
2864 dnl H264 encoder plugin (using libx264)
2865 dnl
2866 AC_ARG_ENABLE(x264,
2867   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2868 if test "${enable_x264}" != "no"; then
2869       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2870         VLC_ADD_PLUGIN([x264])
2871         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2872
2873         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2874           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2875         ])
2876
2877         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2878         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2879           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2880         fi
2881       ],[
2882         if test "${enable_x264}" = "yes"; then
2883             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2884           fi
2885       ])
2886 fi
2887
2888 dnl
2889 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2890 dnl
2891 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2892
2893 dnl
2894 dnl libfluidsynth (MIDI synthetizer) plugin
2895 dnl
2896 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2897 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2898 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2899
2900 dnl
2901 dnl Teletext Modules
2902 dnl vbi decoder plugin (using libzbvi)
2903 dnl telx module
2904 dnl uncompatible
2905 dnl
2906 AC_ARG_ENABLE(zvbi,
2907   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2908                   libzvbi (default enabled)]))
2909 AC_ARG_ENABLE(telx,
2910   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2911                   zvbi) (default enabled if zvbi is absent)]))
2912
2913 AS_IF( [test "${enable_zvbi}" != "no"],[
2914     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2915         [
2916           VLC_ADD_PLUGIN([zvbi])
2917           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2918           AS_IF( [test "${enable_telx}" = "yes"],[
2919                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2920                   ])
2921         ],[
2922           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2923         ])
2924     ])
2925 AS_IF( [test "${enable_telx}" != "no" ],[
2926   VLC_ADD_PLUGIN([telx])
2927   ])
2928
2929 dnl
2930 dnl libass subtitle rendering module
2931 dnl
2932 AC_ARG_ENABLE(libass,
2933   [  --enable-libass         Subtitle support using libass (default enabled)])
2934 AS_IF( [test "${enable_libass}" != "no"], [
2935   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2936       [
2937         VLC_ADD_PLUGIN([libass])
2938
2939         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2940           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2941            VLC_ADD_LIBS([libass],[-lfontconfig])
2942        ])
2943       ],[
2944         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2945       ])
2946   ])
2947
2948 dnl
2949 dnl ARIB subtitles rendering module
2950 dnl
2951 AC_ARG_ENABLE(aribsub,
2952   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2953 AS_IF( [test "${enable_aribsub}" != "no" ],[
2954   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2955       have_aribb24="yes"
2956       VLC_ADD_PLUGIN([aribsub])
2957       VLC_ADD_LIBS([aribsub],[-laribb24])
2958       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2959     ],[
2960       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2961       have_aribb24="no"
2962   ])
2963 ])
2964 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2965
2966 dnl
2967 dnl ARIB B25
2968 dnl
2969 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2970
2971 dnl
2972 dnl  kate decoder plugin
2973 dnl
2974 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2975
2976 dnl
2977 dnl  tiger rendering for kate decoder plugin
2978 dnl
2979 AC_ARG_ENABLE(tiger,
2980 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2981 AS_IF([test "${enable_tiger}" != "no"], [
2982   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2983       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2984         AS_IF([test -n "${enable_tiger}"], [
2985           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2986         ])
2987   ])
2988 ])
2989
2990
2991 dnl
2992 dnl  Video plugins
2993 dnl
2994
2995 EXTEND_HELP_STRING([Video plugins:])
2996
2997 dnl
2998 dnl  OpenGL
2999 dnl
3000 PKG_CHECK_MODULES([EGL], [egl], [
3001   have_egl="yes"
3002 ], [
3003   have_egl="no"
3004 ])
3005 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3006
3007 have_gl="no"
3008 PKG_CHECK_MODULES([GL], [gl], [
3009   have_gl="yes"
3010 ], [
3011   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3012 #ifdef _WIN32
3013 # include <GL/glew.h>
3014 #endif
3015 #include <GL/gl.h>
3016 ]], [
3017     [int t0 = GL_TEXTURE0;]])
3018   ], [
3019     GL_CFLAGS=""
3020     have_gl="yes"
3021     AS_IF([test "${SYS}" != "mingw32"], [
3022       GL_LIBS="-lGL"
3023     ], [
3024       GL_LIBS="-lopengl32"
3025     ])
3026   ])
3027 ])
3028 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3029
3030 dnl OpenGL ES 2: depends on EGL 1.1
3031 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3032 dnl OpenGL ES 1: depends on EGL 1.0
3033 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3034
3035 dnl
3036 dnl  Xlib
3037 dnl
3038
3039 AC_PATH_XTRA()
3040 AC_CHECK_HEADERS(X11/Xlib.h)
3041
3042 dnl
3043 dnl  X C Bindings modules
3044 dnl
3045 AC_ARG_ENABLE(xcb,
3046   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3047   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3048     enable_xcb="yes"
3049   ], [
3050     enable_xcb="no"
3051   ])
3052 ])
3053 AC_ARG_ENABLE(xvideo,
3054   [  --enable-xvideo         XVideo support (default enabled)],, [
3055     enable_xvideo="$enable_xcb"
3056 ])
3057
3058 have_xcb="no"
3059 have_xcb_keysyms="no"
3060 have_xcb_randr="no"
3061 have_xcb_xvideo="no"
3062 AS_IF([test "${enable_xcb}" != "no"], [
3063   dnl libxcb
3064   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3065   have_xcb="yes"
3066   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3067   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3068   PKG_CHECK_MODULES(XPROTO, [xproto])
3069
3070   AS_IF([test "${enable_xvideo}" != "no"], [
3071     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3072   ])
3073
3074   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3075
3076   dnl xcb-utils
3077   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3078     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3079   ])
3080 ])
3081 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3082 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3083 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3084 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3085
3086
3087 dnl
3088 dnl VDPAU needs X11
3089 dnl
3090 AC_ARG_ENABLE(vdpau,
3091   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3092 have_vdpau="no"
3093 AS_IF([test "${enable_vdpau}" != "no"], [
3094   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3095     have_vdpau="yes"
3096     AS_IF([test "${no_x}" = "yes"], [
3097       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3098     ])
3099   ], [
3100     AS_IF([test -n "${enable_vdpau}"], [
3101       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3102     ])
3103   ])
3104 ])
3105 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3106
3107 have_avcodec_vdpau="no"
3108 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3109   case "${avfork}" in
3110     libav) av_vdpau_ver="55.26.0" ;;
3111     ffmpeg) av_vdpau_ver="55.42.100" ;;
3112   esac
3113   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3114     have_avcodec_vdpau="yes"
3115     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3116   ], [
3117     AS_IF([test -n "${enable_vdpau}"], [
3118       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3119     ], [
3120       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3121     ])
3122   ])
3123 ])
3124 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3125
3126
3127 dnl
3128 dnl  Wayland
3129 dnl
3130 AC_ARG_ENABLE(wayland,
3131   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3132 have_wayland="no"
3133 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3134
3135 AS_IF([test "${enable_wayland}" != "no"], [
3136   AC_MSG_CHECKING([for the Wayland scanner])
3137   AS_IF([test -z "$WAYLAND_SCANNER"], [
3138     PKG_CHECK_EXISTS([wayland-scanner], [
3139       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3140     ], [
3141       WAYLAND_SCANNER="wayland-scanner"
3142     ])
3143   ])
3144   AC_MSG_RESULT([$WAYLAND_SCANNER])
3145
3146   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3147     have_wayland="yes"
3148   ], [
3149     AS_IF([test -n "${enable_wayland}"], [
3150       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3151     ])
3152   ])
3153
3154   AS_IF([test "${have_egl}" = "yes"], [
3155     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3156       have_wayland_egl="yes"
3157     ], [
3158       AS_IF([test -n "${enable_wayland}"], [
3159         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3160       ])
3161     ])
3162   ])
3163 ])
3164 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3165 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3166
3167
3168 dnl
3169 dnl  SDL module
3170 dnl
3171 AC_ARG_ENABLE(sdl,
3172   [  --enable-sdl            SDL support (default enabled)])
3173 AC_ARG_ENABLE(sdl-image,
3174   [  --enable-sdl-image      SDL image support (default enabled)])
3175 if test "${enable_sdl}" != "no"
3176 then
3177    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3178       # SDL on Darwin is heavily patched and can only run SDL_image
3179       if test "${SYS}" != "darwin"; then
3180         VLC_ADD_PLUGIN([vout_sdl])
3181       fi
3182
3183       # SDL_image
3184       AS_IF([ test "${enable_sdl_image}" != "no"],[
3185         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3186           VLC_ADD_PLUGIN([sdl_image])],
3187           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3188           ])
3189       ])
3190    ],[
3191      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3192    ])
3193 fi
3194
3195 dnl
3196 dnl  freetype module
3197 dnl
3198 AC_ARG_ENABLE(freetype,
3199   [  --enable-freetype       freetype support   (default auto)])
3200 AC_ARG_ENABLE(fribidi,
3201   [  --enable-fribidi        fribidi support    (default auto)])
3202 AC_ARG_ENABLE(harfbuzz,
3203   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3204 AC_ARG_ENABLE(fontconfig,
3205   [  --enable-fontconfig     fontconfig support (default auto)])
3206
3207 AC_ARG_WITH([default-font],
3208     AS_HELP_STRING([--with-default-font=PATH],
3209         [Path to the default font]),
3210         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3211             "$withval", [Default font])])
3212 AC_ARG_WITH([default-monospace-font],
3213     AS_HELP_STRING([--with-default-monospace-font=PATH],
3214         [Path to the default font]),
3215         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3216             "$withval", [Default monospace font])])
3217
3218 AC_ARG_WITH([default-font-family],
3219     AS_HELP_STRING([--with-default-font-family=NAME],
3220         [Path to the default font family]),
3221         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3222             "$withval", [Default font family])])
3223 AC_ARG_WITH([default-monospace-font-family],
3224     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3225         [Path to the default font family]),
3226         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3227             "$withval", [Default monospace font family])])
3228
3229 have_freetype="no"
3230 have_fontconfig="no"
3231 have_fribidi="no"
3232 have_harfbuzz="no"
3233
3234 if test "${enable_freetype}" != "no"; then
3235    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3236       have_freetype="yes"
3237       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3238       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3239
3240       dnl fontconfig support
3241       if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
3242           if test "${enable_fontconfig}" != "no"; then
3243             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3244               have_fontconfig="yes"
3245             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3246           fi
3247       fi
3248
3249       dnl fribidi support
3250       if test "${enable_fribidi}" != "no"; then
3251         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3252           have_fribidi="yes"
3253           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3254           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3255         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3256       fi
3257
3258       dnl harfbuzz support
3259       if test "${have_fribidi}" != "no"; then
3260         if test "${enable_harfbuzz}" != "no"; then
3261           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3262             have_harfbuzz="yes"
3263             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3264             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3265           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3266         fi
3267       fi
3268   ],[
3269   AS_IF([test -n "${enable_freetype}"],[
3270     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3271     ])
3272   ])
3273 fi
3274
3275 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3276 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3277 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3278 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3279
3280 dnl
3281 dnl SAPI (text to Speech renderer for Windows)
3282 dnl
3283 AC_LANG_PUSH([C++])
3284 AC_CHECK_TYPES([ISpObjectToken],[
3285               have_sapi="yes"
3286             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3287               [#include <windows.h>
3288                #include <sapi.h>
3289                #include <sphelper.h>])
3290 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3291 AC_LANG_POP([C++])
3292
3293 dnl
3294 dnl  SVG module (text rendering and image decoding)
3295 dnl
3296 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3297 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3298
3299 dnl
3300 dnl  Windows DirectX module
3301 dnl
3302
3303 AC_ARG_ENABLE(directx,
3304   [AS_HELP_STRING([--enable-directx],
3305     [Microsoft DirectX support (default enabled on Windows)])],, [
3306   AS_IF([test "${SYS}" = "mingw32"], [
3307     enable_directx="yes"
3308   ], [
3309     enable_directx="no"
3310   ])
3311 ])
3312 AS_IF([test "${enable_directx}" != "no"], [
3313   dnl DirectDraw
3314   AC_CHECK_HEADERS(ddraw.h, [
3315     VLC_ADD_PLUGIN([directdraw])
3316   ])
3317
3318   dnl OpenGL
3319   AC_CHECK_HEADERS(GL/wglew.h, [
3320     VLC_ADD_PLUGIN([glwin32 wgl])
3321   ],, [
3322     #include <windows.h>
3323     #include <GL/gl.h>
3324   ])
3325
3326   dnl Direct3D11
3327   AC_CHECK_HEADERS(d3d11.h, [
3328     VLC_ADD_PLUGIN([direct3d11])
3329   ])
3330
3331   dnl Direct3D9
3332   AC_CHECK_HEADERS(d3d9.h, [
3333     VLC_ADD_PLUGIN([direct3d9])
3334   ])
3335
3336   dnl Direct2D
3337   AC_CHECK_HEADERS(d2d1.h, [
3338     VLC_ADD_PLUGIN([direct2d])
3339   ])
3340 ])
3341
3342 dnl
3343 dnl  Linux framebuffer module
3344 dnl
3345 AC_CHECK_HEADER([linux/fb.h], [
3346   VLC_ADD_PLUGIN([fb])
3347 ])
3348
3349
3350 dnl
3351 dnl  DirectFB module
3352 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3353 dnl  TODO: support for static linking
3354 dnl
3355 AC_ARG_ENABLE(directfb,
3356   [  --enable-directfb       DirectFB support (default disabled)])
3357 AC_ARG_WITH(directfb,
3358   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3359
3360 if test "${enable_directfb}" = "yes"; then
3361     have_directfb="false"
3362     CPPFLAGS_mydirectfb=
3363     LIBS_mydirectfb=
3364     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3365         dnl Trying the given location
3366         VLC_SAVE_FLAGS
3367
3368         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3369         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3370
3371         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3372         LIBS="${LIBS} ${LIBS_new}"
3373
3374         dnl FIXME: too obscure
3375         AC_CHECK_HEADER([directfb.h], [
3376             AC_CHECK_LIB([direct],[direct_initialize], [
3377                 AC_CHECK_LIB([fusion], [fusion_enter], [
3378                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3379                 ], have_directfb="false")
3380             ], have_directfb="false")
3381         ], have_directfb="false")
3382
3383         VLC_RESTORE_FLAGS
3384
3385         if test "${have_directfb}" = "true"; then
3386             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3387             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3388         fi
3389     else
3390         dnl Look for directfb-config
3391         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3392         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3393             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3394             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3395             have_directfb="true"
3396         ], [
3397             dnl Trying with pkg-config
3398             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3399                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3400                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3401                 have_directfb="true"
3402                 ], [have_directfb="false"])
3403         ])
3404     fi
3405     if test "${have_directfb}" = "true"; then
3406         VLC_ADD_PLUGIN([directfb])
3407         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3408         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3409     else
3410         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3411     fi
3412 fi
3413
3414 dnl
3415 dnl  AA plugin
3416 dnl
3417 AC_ARG_ENABLE(aa,
3418   [  --enable-aa             aalib output (default disabled)])
3419 if test "${enable_aa}" = "yes"
3420 then
3421   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3422   if test "${have_aa}" = "true"
3423   then
3424     VLC_ADD_PLUGIN([aa])
3425   fi
3426 fi
3427
3428 dnl
3429 dnl  libcaca plugin
3430 dnl
3431 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3432
3433 dnl
3434 dnl  OS/2 KVA plugin
3435 dnl
3436 AC_ARG_ENABLE(kva,
3437   [AS_HELP_STRING([--enable-kva],
3438     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3439   AS_IF([test "$SYS" = "os2"], [
3440     enable_kva="yes"
3441   ])
3442 ])
3443 have_kva="no"
3444 KVA_LIBS=""
3445 AS_IF([test "$enable_kva" != "no"], [
3446   AC_CHECK_HEADERS([kva.h], [
3447     have_kva="yes"
3448     AC_CHECK_LIB(kva, main, [
3449       KVA_LIBS="-lkva"
3450     ])
3451   ])
3452 ])
3453 AC_SUBST(KVA_LIBS)
3454 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3455
3456 dnl
3457 dnl MMAL plugin
3458 dnl
3459 AC_ARG_ENABLE(mmal,
3460   AS_HELP_STRING([--enable-mmal],
3461     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3462 if test "${enable_mmal}" != "no"; then
3463   VLC_SAVE_FLAGS
3464   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3465   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3466   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3467     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3468         have_mmal="yes"
3469         VLC_ADD_PLUGIN([mmal])
3470         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3471         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3472         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3473           AS_IF([test "${enable_mmal}" = "yes"],
3474             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3475             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3476           ],
3477         [])
3478     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3479       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3480       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3481   VLC_RESTORE_FLAGS
3482 fi
3483 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3484
3485 dnl
3486 dnl evas plugin
3487 dnl
3488 AC_ARG_ENABLE(evas,
3489   [AS_HELP_STRING([--enable-evas],
3490     [use evas output module (default disabled)])])
3491 have_evas="no"
3492 AS_IF([test "${enable_evas}" = "yes"], [
3493   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3494       have_evas="yes"
3495       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3496     ],[
3497     AS_IF([test "x${enable_evas}" != "x"], [
3498       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3499     ])
3500   ])
3501 ])
3502 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3503
3504 dnl
3505 dnl  Audio plugins
3506 dnl
3507
3508 EXTEND_HELP_STRING([Audio plugins:])
3509
3510 dnl
3511 dnl  Pulseaudio module
3512 dnl
3513 AC_ARG_ENABLE(pulse,
3514   [AS_HELP_STRING([--enable-pulse],
3515     [use the PulseAudio client library (default auto)])])
3516 have_pulse="no"
3517 AS_IF([test "${enable_pulse}" != "no"], [
3518   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3519     have_pulse="yes"
3520   ], [
3521     AS_IF([test "x${enable_pulse}" != "x"], [
3522       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3523     ])
3524   ])
3525 ])
3526 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3527
3528 dnl
3529 dnl  ALSA module
3530 dnl
3531 AC_ARG_ENABLE(alsa,
3532   [AS_HELP_STRING([--enable-alsa],
3533     [support the Advanced Linux Sound Architecture (default auto)])],, [
3534   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3535     enable_alsa="yes"
3536   ])
3537 ])
3538 have_alsa="no"
3539 AS_IF([test "${enable_alsa}" != "no"], [
3540   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3541     have_alsa="yes"
3542   ], [
3543     AS_IF([test "x${enable_alsa}" != "x"], [
3544       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3545     ])
3546   ])
3547 ])
3548 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3549
3550 dnl
3551 dnl  Open Sound System module
3552 dnl
3553 AC_ARG_ENABLE(oss,
3554   [AS_HELP_STRING([--enable-oss],
3555     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3556   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3557     enable_oss="no"
3558   ])
3559 ])
3560 have_oss="no"
3561 OSS_LIBS=""
3562 AS_IF([test "$enable_oss" != "no"], [
3563   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3564     have_oss="yes"
3565     AC_CHECK_LIB(ossaudio, main, [
3566       OSS_LIBS="-lossaudio"
3567     ])
3568   ])
3569 ])
3570 AC_SUBST(OSS_LIBS)
3571 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3572
3573 dnl
3574 dnl  OpenBSD sndio module
3575 dnl
3576 AC_ARG_ENABLE([sndio],
3577   [AS_HELP_STRING([--disable-sndio],
3578     [support the OpenBSD sndio (default auto)])],, [
3579   AS_IF([test "$SYS" = "openbsd"], [
3580     enable_sndio="yes"
3581   ])
3582 ])
3583 have_sndio="no"
3584 AS_IF([test "$enable_sndio" != "no"], [
3585   AC_CHECK_HEADER([sndio.h], [
3586     have_sndio="yes"
3587   ])
3588 ])
3589 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3590
3591 dnl
3592 dnl  Windows Audio Session plugin
3593 dnl
3594 AC_ARG_ENABLE([wasapi],
3595   [AS_HELP_STRING([--enable-wasapi],
3596     [use the Windows Audio Session API (default auto)])
3597 ])
3598 have_wasapi="no"
3599 AS_IF([test "$enable_wasapi" != "no"], [
3600   AC_CHECK_HEADER([audioclient.h], [
3601     have_wasapi="yes"
3602   ], [
3603     AS_IF([test "x${enable_wasapi}" != "x"], [
3604       AC_MSG_ERROR([Windows Audio Session API not found.])
3605     ])
3606   ])
3607 ])
3608 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3609
3610 dnl
3611 dnl  AudioQueue plugin
3612 dnl
3613 AC_ARG_ENABLE(audioqueue,
3614   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3615 if test "${enable_audioqueue}" = "yes"
3616 then
3617   VLC_ADD_PLUGIN([audioqueue])
3618 fi
3619
3620 dnl
3621 dnl  JACK modules
3622 dnl
3623 AC_ARG_ENABLE(jack,
3624   [AS_HELP_STRING([--disable-jack],
3625     [do not use jack (default auto)])])
3626 have_jack="no"
3627 AS_IF([test "${enable_jack}" != "no"], [
3628     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3629       [ have_jack=yes ],
3630       [
3631       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3632
3633       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3634       [ have_jack=yes ],
3635       [
3636       AS_IF([test -n "${enable_jack}"],
3637          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3638          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3639       ])
3640     ])
3641 ])
3642 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3643
3644 dnl
3645 dnl  OpenSLES Android
3646 dnl
3647 AC_ARG_ENABLE(opensles,
3648   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3649 if test "${HAVE_ANDROID}" = "1"; then
3650   if test "${enable_opensles}" = "yes"; then
3651       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3652         [ VLC_ADD_PLUGIN([opensles_android]) ],
3653         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3654   fi
3655 fi
3656
3657 dnl
3658 dnl  Tizen audio
3659 dnl
3660 AC_ARG_ENABLE(tizen_audio,
3661   [AS_HELP_STRING([--enable-tizen-audio],
3662     [Tizen audio module (default enabled on Tizen)])],, [
3663   AS_IF([test "$HAVE_TIZEN" = "1"], [
3664     enable_tizen_audio="yes"
3665   ])
3666 ])
3667 if test "${enable_tizen_audio}" = "yes"; then
3668   AC_CHECK_HEADERS(audio_io.h,
3669     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3670     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3671 fi
3672
3673 dnl
3674 dnl libsamplerate plugin
3675 dnl
3676 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3677
3678 dnl
3679 dnl  soxr module
3680 dnl
3681 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3682
3683 dnl
3684 dnl  OS/2 KAI plugin
3685 dnl
3686 AC_ARG_ENABLE(kai,
3687   [AS_HELP_STRING([--enable-kai],
3688     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3689   AS_IF([test "$SYS" = "os2"], [
3690     enable_kai="yes"
3691   ])
3692 ])
3693 have_kai="no"
3694 KAI_LIBS=""
3695 AS_IF([test "$enable_kai" != "no"], [
3696   AC_CHECK_HEADERS([kai.h], [
3697     have_kai="yes"
3698     AC_CHECK_LIB(kai, main, [
3699       KAI_LIBS="-lkai"
3700     ])
3701   ])
3702 ])
3703 AC_SUBST(KAI_LIBS)
3704 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3705
3706 dnl
3707 dnl  chromaprint audio track fingerprinter
3708 dnl
3709 m4_pushdef([libchromaprint_version], 0.6.0)
3710 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3711     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3712     AS_IF([test "${enable_chromaprint}" = "yes"],
3713         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3714         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3715          ),
3716     [(Chromaprint based audio fingerprinter)],[auto])
3717 m4_popdef([libchromaprint_version])
3718
3719 dnl
3720 dnl  Chromecast streaming support
3721 dnl
3722 m4_pushdef([protobuf_lite_version], 2.5.0)
3723 AC_ARG_VAR(PROTOC, [protobuf compiler])
3724 AC_CHECK_PROGS(PROTOC, protoc, no)
3725 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3726     AS_IF([test "x${PROTOC}" != "xno"], [
3727         build_chromecast="yes"
3728     ], [
3729     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3730     ])
3731 ], [
3732     AS_IF([test "${enable_chromecast}" = "yes"],
3733         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3734         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3735     )
3736     enable_chromecast="no"
3737 ], [(Chromecast streaming support)], [auto])
3738 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3739 m4_popdef([protobuf_lite_version])
3740
3741 dnl
3742 dnl  Interface plugins
3743 dnl
3744
3745 EXTEND_HELP_STRING([Interface plugins:])
3746
3747 dnl
3748 dnl QT
3749 dnl
3750 AC_ARG_ENABLE(qt, [
3751   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3752   AS_IF([test "${SYS}" = "darwin"], [
3753     enable_qt="no"
3754   ])
3755 ])
3756 AS_IF([test "${enable_qt}" != "no"], [
3757   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3758       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3759           VLC_ADD_LIBS([qt],[${QTX11_LIBS}])
3760           VLC_ADD_CXXFLAGS([qt],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3761           PKG_CHECK_MODULES([XI], [xi], [
3762             VLC_ADD_LIBS([qt], [${XI_LIBS}])
3763             VLC_ADD_CXXFLAGS([qt], [${XI_CFLAGS} -DHAVE_XI])
3764           ], [
3765             PKG_CHECK_EXISTS([Qt5Gui >= 5.5], [
3766               AC_MSG_ERROR([${XI_PKG_ERRORS}.])
3767             ], [
3768               AC_MSG_WARN([${XI_PKG_ERRORS}.])
3769             ])
3770           ])
3771       ],[
3772           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3773       ])
3774       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3775       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3776       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3777       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3778       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3779     ], [
3780       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3781         AS_IF([test -n "${enable_qt}"],[
3782           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3783         ],[
3784           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3785         ])
3786         enable_qt="no"
3787       ])
3788       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3789       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3790       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin])
3791       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3792     ])
3793 ])
3794 AS_IF([test "${enable_qt}" != "no"], [
3795   VLC_ADD_PLUGIN([qt])
3796   ALIASES="${ALIASES} qvlc"
3797 ])
3798 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3799
3800 dnl
3801 dnl detect kde4-config patch (used for kde solids).
3802 dnl
3803 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3804 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3805   KDE4_CONFIG="kde4-config"
3806 ])
3807
3808 dnl
3809 dnl Simple test for skins2 dependency
3810 dnl
3811 AS_IF([test "$enable_qt" = "no"], [
3812   AS_IF([test "${enable_skins2}" = "yes"], [
3813     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3814   ], [
3815     enable_skins2="no"
3816     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3817   ])
3818 ])
3819
3820 dnl
3821 dnl Skins2 module
3822 dnl
3823 AC_ARG_ENABLE(skins2,
3824   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3825 AS_IF([test "${enable_skins2}" != "no"], [
3826   have_skins_deps="yes"
3827
3828   dnl Win32
3829   AS_IF([test "${SYS}" = "mingw32"], [
3830     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3831     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3832   dnl MacOS
3833   ], [test "${SYS}" = "darwin"], [
3834     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3835     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3836   dnl OS/2
3837   ], [test "${SYS}" = "os2"], [
3838     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3839   dnl Linux/Unix
3840   ], [
3841     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3842     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3843     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3844     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3845     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3846   ])
3847
3848   dnl for All OSes
3849   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3850
3851   dnl we need freetype
3852   AS_IF([test "${have_freetype}" != "yes"], [
3853     have_skins_deps="no"
3854   ])
3855
3856   AS_IF([test "${have_skins_deps}" = "no"], [
3857     AS_IF([test "x${enable_skins2}" = "x"], [
3858       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3859     ], [
3860       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3861     ])
3862     enable_skins2="no"
3863   ], [
3864     VLC_ADD_PLUGIN([skins2])
3865     ALIASES="${ALIASES} svlc"
3866     enable_skins2="yes"
3867   ])
3868 ])
3869 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3870
3871 AC_ARG_ENABLE(libtar,
3872   [  --enable-libtar         libtar support for skins2 (default auto)])
3873 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3874   AC_CHECK_HEADERS(libtar.h, [
3875     VLC_ADD_LIBS([skins2],[-ltar])
3876   ])
3877 ])
3878
3879 dnl
3880 dnl  MacOS X gui module
3881 dnl
3882 AC_ARG_ENABLE(macosx,
3883   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3884 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3885 then
3886   VLC_ADD_PLUGIN([macosx])
3887
3888   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3889   then
3890     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3891   fi
3892 fi
3893 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3894
3895 dnl
3896 dnl  MacOS X sparkle update support
3897 dnl
3898 AC_ARG_ENABLE(sparkle,
3899   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3900 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3901 then
3902   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3903   then
3904     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3905   fi
3906
3907   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3908 fi
3909 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3910
3911
3912 dnl
3913 dnl  Minimal Mac OS X module
3914 dnl
3915 AC_ARG_ENABLE(minimal-macosx,
3916   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3917 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3918 then
3919   VLC_ADD_PLUGIN([minimal_macosx])
3920 fi
3921
3922 dnl
3923 dnl  VideoToolbox plugins
3924 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3925     VLC_ADD_PLUGIN([videotoolbox])
3926     VLC_ADD_PLUGIN([cvpx_i420])
3927   ])
3928
3929 dnl
3930 dnl  ncurses module
3931 dnl
3932 AC_ARG_ENABLE(ncurses,
3933 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3934 have_ncurses="no"
3935 AS_IF([test "${enable_ncurses}" != "no"] ,[
3936   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3937     have_ncurses="yes"
3938     ALIASES="${ALIASES} nvlc"
3939   ], [
3940     AS_IF([test -n "${enable_ncurses}"], [
3941       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3942     ])
3943   ])
3944 ])
3945 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3946
3947 dnl
3948 dnl  Lirc plugin
3949 dnl
3950 AC_ARG_ENABLE(lirc,
3951   [  --enable-lirc           lirc support (default disabled)])
3952 have_lirc="no"
3953 AS_IF([test "${enable_lirc}" = "yes"], [
3954   AC_CHECK_HEADER(lirc/lirc_client.h, [
3955     AC_CHECK_LIB(lirc_client, lirc_init, [
3956       have_lirc="true"
3957     ])
3958   ])
3959 ])
3960 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3961
3962 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3963 dnl
3964 dnl  goom visualization plugin
3965 dnl
3966 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3967
3968 dnl
3969 dnl libprojectM visualization plugin
3970 dnl
3971 AC_ARG_ENABLE(projectm,
3972   [  --enable-projectm       projectM visualization plugin (default enabled)])
3973 AS_IF([test "${enable_projectm}" != "no"],
3974   [
3975     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3976     [
3977       VLC_ADD_PLUGIN([projectm])
3978       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3979         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3980         [ AC_MSG_WARN( [Using libprojectM version 1] )
3981       ])
3982     ],[
3983       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3984     ])
3985   ])
3986
3987 dnl
3988 dnl Vovoid VSXu visualization plugin
3989 dnl
3990 AC_ARG_ENABLE(vsxu,
3991   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3992 AS_IF([test "${enable_vsxu}" != "no"],
3993   [
3994     PKG_CHECK_MODULES(VSXU, libvsxu,
3995     [
3996       VLC_ADD_PLUGIN([vsxu])
3997     ],[
3998       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3999     ])
4000   ])
4001
4002 EXTEND_HELP_STRING([Service Discovery plugins:])
4003 dnl
4004 dnl  Avahi-Zeroconf services discovery
4005 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4006
4007 dnl
4008 dnl  libudev services discovery
4009 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4010
4011 dnl
4012 dnl MTP devices services discovery
4013 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4014
4015 dnl
4016 dnl UPnP Plugin (Intel SDK)
4017 dnl
4018 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4019
4020 dnl
4021 dnl mDNS using libmicrodns
4022 dnl
4023 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4024
4025
4026 EXTEND_HELP_STRING([Misc options:])
4027
4028 dnl
4029 dnl  libxml2 module
4030 dnl
4031 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4032
4033
4034 dnl
4035 dnl libgcrypt
4036 dnl
4037 AC_ARG_ENABLE(libgcrypt,
4038   [  --disable-libgcrypt     gcrypt support (default enabled)])
4039 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4040 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4041
4042 # require libgcrypt >= 1.6.0
4043 AS_IF([test "${enable_libgcrypt}" != "no"], [
4044   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4045     VLC_SAVE_FLAGS
4046     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4047     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4048 [#include <gcrypt.h>
4049 #if GCRYPT_VERSION_NUMBER < 0x010600
4050 #error
4051 #endif]])], [
4052       ac_cv_lib_gcrypt=yes
4053     ], [
4054       ac_cv_lib_gcrypt=no
4055     ])
4056     VLC_RESTORE_FLAGS
4057   ])
4058
4059   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4060     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4061   ], [
4062     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4063       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4064     ])
4065   ])
4066 ])
4067
4068 AS_IF([test -z "$GCRYPT_LIBS"], [
4069   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4070 ])
4071
4072 AC_SUBST(GCRYPT_CFLAGS)
4073 AC_SUBST(GCRYPT_LIBS)
4074 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4075
4076 dnl
4077 dnl TLS/SSL
4078 dnl
4079 AC_ARG_ENABLE(gnutls,
4080   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4081 AS_IF([test "${enable_gnutls}" != "no"], [
4082   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4083     VLC_ADD_PLUGIN([gnutls])
4084   ], [
4085     AS_IF([test -n "${enable_gnutls}"], [
4086       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4087     ])
4088   ])
4089 ])
4090
4091
4092 dnl
4093 dnl Taglib plugin
4094 dnl
4095 AC_ARG_ENABLE(taglib,
4096   [AS_HELP_STRING([--disable-taglib],
4097     [do not use TagLib (default enabled)])])
4098 AS_IF([test "${enable_taglib}" != "no"], [
4099   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4100     VLC_ADD_PLUGIN([taglib])
4101   ], [
4102     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4103 ])
4104
4105 dnl
4106 dnl  libsecret
4107 dnl
4108 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4109
4110 dnl
4111 dnl  kwallet
4112 dnl
4113 AC_ARG_ENABLE(kwallet,
4114   [AS_HELP_STRING([--enable-kwallet],
4115     [use kwallet (via D-Bus) for keystore (default enabled)])])
4116 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4117   VLC_ADD_PLUGIN([kwallet])
4118 ])
4119
4120 dnl
4121 dnl  Developers helper modules (should be hidden from configure help)
4122 dnl
4123 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4124 AS_IF([test "${enable_devtools}" != "no"], [
4125   VLC_ADD_PLUGIN([accesstweaks])
4126 ])
4127
4128 dnl
4129 dnl update checking system
4130 dnl
4131 AC_ARG_ENABLE(update-check,
4132   [  --enable-update-check   update checking system (default disabled)])
4133 if test "${enable_update_check}" = "yes"
4134 then
4135  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4136     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4137   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4138   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4139   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4140 fi
4141
4142 dnl
4143 dnl OS X notification plugin
4144 dnl
4145 AC_ARG_ENABLE(osx_notifications,
4146   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4147   [enable_osx_notifications=no])
4148 AS_IF([test "${enable_osx_notifications}" != "no"], [
4149     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4150       VLC_ADD_PLUGIN([osx_notifications])
4151       VLC_ADD_LIBS([osx_notifications], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4152       VLC_ADD_OBJCFLAGS([osx_notifications], [-F${CONTRIB_DIR}])
4153       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4154     ])
4155   ]
4156 )
4157
4158 dnl
4159 dnl Libnotify notification plugin
4160 dnl
4161 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4162
4163 dnl
4164 dnl  Endianness check
4165 dnl
4166 AC_C_BIGENDIAN
4167 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4168   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4169 ], [
4170   DEFS_BIGENDIAN=""
4171 ])
4172 AC_SUBST(DEFS_BIGENDIAN)
4173
4174 dnl
4175 dnl Where to install KDE solid .desktop
4176 dnl
4177 AC_ARG_WITH(kde-solid,
4178   AS_HELP_STRING([--with-kde-solid=PATH],
4179                  [KDE Solid actions directory (auto)]),, [
4180
4181 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4182   with_kde_solid="yes"
4183 fi
4184 ])
4185 soliddatadir=""