Simple: use ITU-R BS.775-2 matrices for 5.x downmixing
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 2002-2013 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 2.1.0-git)
6 VERSION_MAJOR=2
7 VERSION_MINOR=1
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Rincewind"
17 COPYRIGHT_YEARS="1996-2013"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 # Disable with "./configure --disable-silent-rules" or "make V=1"
31 AM_SILENT_RULES([yes])
32
33 dnl Too many people are not aware of maintainer mode:
34 dnl If you want to use it, you definitely know what you are doing, so
35 dnl you can specify "--disable-maintainer-mode". But if you want the default
36 dnl automake behavior, you've likely never heard of maintainer mode, so we
37 dnl can't expect you to enable it manually.
38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
39     [enable_maintainer_mode="yes"])
40 AM_MAINTAINER_MODE
41
42 dnl
43 dnl Directories
44 dnl
45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
46 dnl AC_SUBST(vlcincludedir)
47 vlcdatadir="\${datadir}/\${PKGDIR}"
48 AC_SUBST(vlcdatadir)
49 vlclibdir="\${libdir}/\${PKGDIR}"
50 AC_SUBST(vlclibdir)
51
52 dnl
53 dnl Check for tools
54 dnl
55 AC_PROG_CC_C99
56 AC_USE_SYSTEM_EXTENSIONS
57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
59 AC_DEFINE([_REENTRANT],, [Define to expose reentrant functions.])
60 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
61 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
62 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
63
64 AM_PROG_CC_C_O
65 AC_PROG_CXX
66 AC_PROG_CPP
67 AC_PROG_OBJC
68 _AM_DEPENDENCIES([OBJC])
69 AC_PROG_EGREP
70 AC_PROG_MAKE_SET
71 AC_PROG_INSTALL
72 AM_PROG_AS
73
74 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
75 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
76
77 dnl Check for compiler properties
78 AC_C_CONST
79 AC_C_INLINE
80 AC_C_RESTRICT
81
82 dnl Extend the --help string at the current spot.
83 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
84
85 dnl Allow binary package maintainer to pass a custom string to avoid
86 dnl cache problem
87 AC_ARG_WITH(binary-version,
88     AS_HELP_STRING([--with-binary-version=STRING],
89          [To avoid plugins cache problem between binary version]),[],[])
90 AS_IF([test -n "${with_binary_version}"],[
91     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
92          [Binary specific version])
93 ])
94
95 dnl
96 dnl  Check the operating system
97 dnl
98 HAVE_WIN64="0"
99 case "${host_os}" in
100   "")
101     SYS=unknown
102     ;;
103   linux*)
104     SYS=linux
105     ;;
106   bsdi*)
107     SYS=bsdi
108     CFLAGS="${CFLAGS} -pthread"
109     VLC_ADD_LIBS([vcd cdda vcdx],[-ldvd])
110     ;;
111   freebsd*)
112     SYS=freebsd
113     CFLAGS="${CFLAGS} -pthread"
114     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
115     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
116     ;;
117   openbsd*)
118     SYS=openbsd
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
121     ;;
122   netbsd*)
123     SYS=netbsd
124     ;;
125   dragonfly*)
126     SYS=dragonfly
127     ;;
128   darwin*)
129
130     dnl Force gcc "-arch" flag
131     ARCH_flag=""
132     case "${host}" in
133       i?86*)
134         ARCH_flag="-arch i386"
135       ;;
136       ppc64*)
137         ARCH_flag="-arch ppc64"
138       ;;
139       ppc*)
140         ARCH_flag="-arch ppc"
141       ;;
142       x86_64*)
143         ARCH_flag="-arch x86_64"
144       ;;
145       arm*)
146         ac_cv_c_bigendian="no"
147         ac_cv_c_attribute_packed="no"
148       ;;
149     esac
150
151     SYS=darwin
152     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
153     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
154     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
155     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
156     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
157     VLC_ADD_LIBS([motion rotate], [-Wl,-framework,IOKit,-framework,CoreFoundation])
158     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
159     VLC_ADD_LIBS([avcodec access_avio swscale postproc i420_rgb_mmx x264 x26410b],[-Wl,-read_only_relocs,suppress])
160     VLC_ADD_CFLAGS([motion rotate],[-fconstant-cfstrings])
161     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation])
162
163     dnl Allow binaries created on Lion to run on earlier releases
164     AC_EGREP_CPP(yes,
165            [#import <Cocoa/Cocoa.h>
166             #ifdef MAC_OS_X_VERSION_10_7
167             yes
168             #endif],
169             [AC_MSG_RESULT([yes])
170             AC_LIBOBJ([getdelim])
171             AC_LIBOBJ([strndup])
172             AC_LIBOBJ([strnlen])],)
173
174     dnl
175     dnl  Handle Mac OS X SDK flags
176     dnl
177     AC_ARG_WITH(macosx-sdk,
178       [AS_HELP_STRING([--with-macosx-sdk=DIR],
179         [compile using the SDK in DIR])])
180     if test "${with_macosx_sdk}" != "" ; then
181         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
182         CPP="${CPP} -isysroot ${with_macosx_sdk}"
183         CC="${CC} -isysroot ${with_macosx_sdk}"
184         CXX="${CXX} -isysroot ${with_macosx_sdk}"
185         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
186         LD="${LD} -syslibroot ${with_macosx_sdk}"
187     fi
188     AC_ARG_WITH(macosx-version-min,
189       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
190         [compile for Mac OS X VERSION and above])])
191     if test "${with_macosx_version_min}" != "" ; then
192         MACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}
193         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
194         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
195         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
196         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
197         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
198         CFLAGS="${CFLAGS} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"
199         CXXFLAGS="${CXXFLAGS} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"
200         OBJCFLAGS="${OBJCFLAGS} -DMACOSX_DEPLOYMENT_TARGET=${with_macosx_version_min}"
201         export MACOSX_DEPLOYMENT_TARGET
202     fi
203     ;;
204   *mingw32* | *cygwin* | *wince* | *mingwce*)
205     AC_CHECK_TOOL(WINDRES, windres, :)
206     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
207     AH_TOP([#if defined(WIN32) && !defined(_WIN32_WINNT)])
208     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
209     AH_TOP([#endif])
210     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
211     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
212     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
213
214     case "${host_os}" in
215       *mingw32*)
216         SYS=mingw32
217         CC="$CC -static-libgcc"
218         CXX="$CXX -static-libgcc -static-libstdc++"
219         ;;
220       *cygwin*)
221         dnl Check if we are using the mno-cygwin mode in which case we are
222         dnl actually dealing with a mingw32 compiler.
223         AC_EGREP_CPP(yes,
224             [#ifdef WIN32
225              yes
226              #endif],
227             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
228         ;;
229     esac
230
231     if test "${SYS}" = "mingw32"; then
232         VLC_ADD_LIBS([libvlccore],[-lwinmm])
233         VLC_ADD_LDFLAGS([vlc],[-mwindows])
234         VLC_ADD_LIBS([win32text],[-lgdi32])
235         VLC_ADD_LIBS([vcdx],[-lwinmm])
236         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
237         ac_default_prefix="`pwd`/_win32"
238         DESTDIR="`pwd`/_win32/"
239
240         dnl
241         dnl NSIS/MSI Installer prefix and WIN64
242         dnl
243         case "${host}" in
244             amd64*|x86_64*)
245                 HAVE_WIN64="1"
246                 WINDOWS_ARCH="x64"
247                 PROGRAMFILES="PROGRAMFILES64"
248             ;;
249             *)
250                 WINDOWS_ARCH="x86"
251                 PROGRAMFILES="PROGRAMFILES"
252             ;;
253         esac
254         AC_SUBST(WINDOWS_ARCH)
255         AC_SUBST(PROGRAMFILES)
256
257     fi
258     ;;
259   *nto*)
260     SYS=nto
261     ;;
262   solaris*)
263     SYS=solaris
264     ;;
265   hpux*)
266     SYS=hpux
267     ;;
268   symbian*)
269     SYS=symbian
270     ;;
271   *os2*)
272     SYS=os2
273     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild"
274     ;;
275   *)
276     SYS="${host_os}"
277     ;;
278 esac
279 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
280 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
281 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
282 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
283 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
284 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
285
286 dnl
287 dnl Sadly autoconf does not think about testing foo.exe when ask to test
288 dnl for program foo on win32
289 case "${build_os}" in
290     cygwin|msys)
291         ac_executable_extensions=".exe"
292     ;;
293     *)
294     ;;
295 esac
296
297 dnl Android is linux, but a bit different
298 AS_IF([test "$SYS" = linux],[
299     AC_MSG_CHECKING([for an Android system])
300     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
301         [[#ifndef __ANDROID__
302          # error Not Android
303          #endif
304         ]],[[;]])
305     ],[
306       HAVE_ANDROID="1"
307       AC_MSG_RESULT([yes])
308     ],[
309       AC_MSG_RESULT([no])
310     ])
311 ])
312 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
313
314
315 dnl
316 dnl  Check for the contrib directory
317 dnl
318 AC_ARG_WITH(contrib,
319   [AS_HELP_STRING([--with-contrib[=DIR]],
320     [search for 3rd party libraries in DIR/include and DIR/lib])
321 ])
322 AC_MSG_CHECKING([for 3rd party libraries path])
323 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
324   CONTRIB_DIR="${srcdir}/contrib/${host}"
325   AS_IF([test ! -d "${CONTRIB_DIR}"], [
326     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
327     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
328     AS_IF([test ! -d "${CONTRIB_DIR}"], [
329       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
330       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
331       AS_IF([test ! -d "${CONTRIB_DIR}"], [
332         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
333         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
334         AS_IF([test ! -d "${CONTRIB_DIR}"], [
335           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
336           CONTRIB_DIR=""
337           AC_MSG_RESULT([not found])
338         ])
339       ])
340     ])
341   ])
342 ], [
343   AS_IF([test "${with_contrib}" != "no"], [
344     CONTRIB_DIR="${with_contrib}"
345   ], [
346     CONTRIB_DIR=""
347     AC_MSG_RESULT([disabled])
348   ])
349 ])
350 AS_IF([test -n "${CONTRIB_DIR}"], [
351   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
352     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
353   ], [
354     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
355     CONTRIB_DIR=""
356     AC_MSG_RESULT([not usable])
357   ])
358
359 ])
360 AS_IF([test -n "${CONTRIB_DIR}"], [
361   AC_MSG_RESULT([${CONTRIB_DIR}])
362   export PATH=${CONTRIB_DIR}/bin:$PATH
363   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
364   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
365   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
366   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
367   AS_IF([test "$build" = "$host" -o "$PKG_CONFIG_LIBDIR"], [
368     export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
369   ], [
370     export PKG_CONFIG_LIBDIR="${CONTRIB_DIR}/lib/pkgconfig"
371   ])
372   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
373
374   AS_IF([test "${SYS}" = "darwin"], [
375     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
376     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
377   ])
378 ], [
379   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
380     AC_MSG_ERROR([Third party libraries not found!])
381   ])
382 ])
383 AC_SUBST(CONTRIB_DIR)
384
385 dnl
386 dnl  Libtool
387 dnl  It's very bad, but our former custom system was worst
388 dnl  -- Courmisch
389 dnl
390
391 dnl override platform specific check for dependent libraries
392 dnl otherwise libtool linking of shared libraries will
393 dnl fail on anything other than pass_all.
394 AC_CACHE_VAL(lt_cv_deplibs_check_method,
395     [lt_cv_deplibs_check_method=pass_all])
396
397 LT_INIT([dlopen win32-dll shared disable-static])
398 LT_LANG([C++])
399 LT_LANG([Windows Resource])
400
401 DOLT
402
403 m4_undefine([AC_DEPLIBS_CHECK_METHOD])
404 m4_defun([AC_DEPLIBS_CHECK_METHOD],[])
405
406 lt_cv_deplibs_check_method=pass_all
407
408 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
409   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
410 ])
411
412 dnl
413 dnl Gettext stuff
414 dnl
415 AM_GNU_GETTEXT_VERSION([0.18.1])
416 AM_GNU_GETTEXT([external], [need-ngettext])
417
418 dnl
419 dnl Iconv stuff
420 dnl
421 AM_ICONV
422
423 dnl
424 dnl checks for mingw
425 AS_IF([test "${SYS}" = "mingw32"], [
426 dnl Check for broken versions of mingw-runtime compatability library
427     AC_MSG_CHECKING(for broken mingw-runtime)
428     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
429 #include <_mingw.h>
430 #if defined(__MINGW64_VERSION_MAJOR)
431 # if __MINGW64_VERSION_MAJOR < 3
432 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
433 # endif
434 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
435 # error Attempting to use mingw-runtime with broken vsnprintf support
436 #endif
437     ])], [
438         AC_MSG_RESULT([ok])
439     ], [
440         AC_MSG_RESULT([present])
441         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
442     ])
443     dnl force use of mingw provided c99 *printf over msvcrt
444     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
445
446 dnl Check for the need to include the mingwex lib for mingw32
447     VLC_SAVE_FLAGS
448     AC_CHECK_LIB(mingwex,opendir,
449         AC_CHECK_LIB(mingw32,opendir,,
450             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
451     )
452     VLC_RESTORE_FLAGS
453
454 dnl Check for fnative-struct or mms-bitfields support for mingw32
455     VLC_SAVE_FLAGS
456     CFLAGS="${CFLAGS} -mms-bitfields"
457     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
458     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
459         [ac_cv_c_mms_bitfields],
460         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
461     if test "${ac_cv_c_mms_bitfields}" = "no"; then
462         VLC_RESTORE_FLAGS
463         CFLAGS="${CFLAGS} -fnative-struct"
464         CXXFLAGS="${CXXFLAGS} -fnative-struct"
465         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
466             [ac_cv_c_fnative_struct],
467             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
468         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
469     fi
470 ])
471
472 AC_ARG_ENABLE(winstore_app,
473      AS_HELP_STRING([--enable-winstore-app],
474                     [Build targetted for Windows Store apps (default disabled)]))
475
476 AS_IF([test "${SYS}" = "mingw32"], [
477     AS_IF([test "${enable_winstore_app}" == "yes"], [
478        AC_DEFINE(WINAPI_FAMILY_APP, 1, [Define if you want to build for Windows Store apps])])
479     ])
480
481
482 dnl
483 dnl Buggy glibc prevention. Purposedly not cached.
484 dnl See sourceware.org bugs 5058 and 5443.
485 dnl Ubuntu alone has 20 bug numbers for this...
486 dnl
487 AC_MSG_CHECKING(for buggy GNU/libc versions)
488 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
489 #include <limits.h>
490 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
491   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
492 # error GNU/libc with dcgettext killer bug!
493 #endif
494 ])], [
495   AC_MSG_RESULT([not present])
496 ], [
497   AC_MSG_RESULT([found])
498   AS_IF([test "x${enable_nls}" != "xno"], [
499     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
500 work-around for this. Check with your distribution vendor on how to update the
501 glibc run-time. Alternatively, build with --disable-nls.])
502   ])
503 ])
504
505 dnl Plugin compilation stuff
506
507 VLC_LIBRARY_SUFFIX
508
509 dnl Check for system libs needed
510 need_libc=false
511
512 dnl Check for usual libc functions
513 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
514 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale])
515 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
516 AC_CHECK_FUNCS(fdatasync,,
517   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
518 ])
519
520 dnl mingw64 implements those as static inline, not functions with C linkage
521 AC_LINK_IFELSE([
522     AC_LANG_PROGRAM([#include <stdio.h>], [
523         char *c;
524         if (asprintf(&c, "%s %d", "string", 1) == -1)
525             c = NULL;
526     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
527 AC_LINK_IFELSE([
528     AC_LANG_PROGRAM([#include <stdio.h>
529                      #include <stdarg.h>], [
530         char *c;
531         va_list ap;
532         if (vasprintf(&c, "%s %d", ap) == -1)
533             c = NULL;
534     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
535
536 dnl C11 static_assert()
537 AC_MSG_CHECKING([for static_assert in assert.h])
538 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
539 static_assert(1, "The impossible happened.");
540 ])], [
541   AC_MSG_RESULT([yes])
542   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
543 ], [
544   AC_MSG_RESULT([no])
545 ])
546
547 # Windows CE does not have strcoll()
548 AC_FUNC_STRCOLL
549
550 dnl Check for non-standard system calls
551 case "$SYS" in
552   "linux")
553     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
554     ;;
555   "mingw32")
556     AC_CHECK_FUNCS([_lock_file])
557     ;;
558 esac
559
560 AH_BOTTOM([#include <vlc_fixups.h>])
561
562 dnl Check for struct pollfd
563 AC_CHECK_TYPES([struct pollfd],,,
564 [#include <sys/types.h>
565 #if HAVE_POLL
566 # include <poll.h>
567 #elif defined (WIN32)
568 # include <winsock2.h>
569 #endif
570 ])
571
572 dnl Checks for socket stuff
573 VLC_SAVE_FLAGS
574 SOCKET_LIBS=""
575 AC_SEARCH_LIBS(connect, [socket], [
576   AS_IF([test "$ac_cv_search_connect" != "none required"], [
577     SOCKET_LIBS="$ac_cv_search_connect"
578   ])
579 ], [
580   AS_IF([test "${SYS}" = "mingw32"], [
581     SOCKET_LIBS="-lws2_32"
582   ])
583 ])
584
585 AC_SEARCH_LIBS([getaddrinfo], [nsl], [
586  AS_IF([test "$ac_cv_search_getaddrinfo" != "none required"], [
587     SOCKET_LIBS="$ac_cv_search_getaddrinfo $SOCKET_LIBS"
588   ])
589 ],, [${SOCKET_LIBS}])
590
591 LIBS="${LIBS} ${SOCKET_LIBS}"
592 AC_LINK_IFELSE([
593     AC_LANG_PROGRAM([#ifdef WIN32
594         # if _WIN32_WINNT < 0x600
595         #  error Needs vista+
596         # endif
597         #include <ws2tcpip.h>
598         #else
599         #include <sys/socket.h>
600         #include <arpa/inet.h>
601         #endif], [
602         char dst[[sizeof(struct in_addr)]];
603         inet_pton(AF_INET, "127.0.0.1", dst);
604     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
605 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
606 VLC_RESTORE_FLAGS
607
608 AS_IF([test -n "$SOCKET_LIBS"], [
609   VLC_ADD_LIBS([access_http access_udp access_tcp access_ftp access_rtmp access_output_udp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop vod_rtsp rtp oldrc netsync gnutls ts audioscrobbler lua remoteosd zvbi audiobargraph_a],[${SOCKET_LIBS}])
610 ])
611 AC_SUBST(SOCKET_LIBS)
612
613 dnl Check for socklen_t
614 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
615 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
616 ac_cv_type_socklen_t,
617 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
618 [#include <sys/types.h>
619 #ifdef WIN32
620 # include <winsock2.h>
621 # include <ws2tcpip.h>
622 #else
623 # include <sys/socket.h>
624 #endif]], [[socklen_t len; len = 0;]])],
625 ac_cv_type_socklen_t=yes,
626 ac_cv_type_socklen_t=no)])
627 AS_IF([test "$ac_cv_type_socklen_t" = no],
628  [AC_DEFINE(socklen_t, int)])
629
630 dnl Check for struct sockaddr_storage
631 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
632 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
633 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
634   [AC_TRY_COMPILE(
635     [#include <sys/types.h>
636      #if defined( WIN32 )
637      # include <winsock2.h>
638      #else
639      # include <sys/socket.h>
640      #endif], [struct sockaddr_storage addr;],
641      ac_cv_struct_sockaddr_storage=yes,
642      ac_cv_struct_sockaddr_storage=no)])
643 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
644   AC_DEFINE(sockaddr_storage, sockaddr)
645   AC_DEFINE(ss_family, sa_family)
646 ])
647
648 dnl FreeBSD has a gnugetopt library for this:
649 GNUGETOPT_LIBS=""
650 AC_CHECK_FUNC(getopt_long,, [
651   AC_CHECK_LIB([gnugetopt],[getopt_long], [
652     GNUGETOPT_LIBS="-lgnugetopt"
653   ])
654 ])
655 AC_SUBST(GNUGETOPT_LIBS)
656
657 AC_CHECK_LIB(m,cos,[
658   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom panoramix rotate noise grain scene kate lua chorus_flanger freetype avcodec access_avio swscale postproc i420_rgb faad twolame equalizer spatializer param_eq samplerate freetype mpc dmo quicktime qt4 compressor headphone_channel_mixer normvol audiobargraph_a speex opus mono colorthres extract ball access_imem hotkeys mosaic gaussianblur x26410b hqdn3d anaglyph oldrc ncurses],[-lm])
659   LIBM="-lm"
660 ], [
661   LIBM=""
662 ])
663 AC_SUBST(LIBM)
664
665 AC_CHECK_LIB(m,lrintf, [
666   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
667   VLC_ADD_LIBS([skins2],[-lm])
668 ])
669
670 dnl Check for dynamic plugins
671 LIBDL=""
672 have_dynamic_objects="no"
673 VLC_SAVE_FLAGS
674 AC_SEARCH_LIBS(dlopen, [dl svld], [
675   AS_IF([test "$ac_cv_search_dlopen" != "none required"], [
676     LIBDL="$ac_cv_search_dlopen"
677   ])
678   have_dynamic_objects="yes"
679 ])
680 VLC_RESTORE_FLAGS
681
682 # Windows
683 AS_IF([test "${SYS}" = "mingw32"], [
684   LIBDL=""
685   have_dynamic_objects="yes" #assume we can use shared objects
686 ])
687
688 AS_IF([test "${enable_shared}" = "no"], [
689   have_dynamic_objects=no
690 ])
691 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
692
693 AC_SUBST(LIBDL)
694 VLC_ADD_LIBS([lua],[$LIBDL])
695
696 dnl Check for thread library
697 LIBPTHREAD=""
698 AS_IF([test "${SYS}" != "mingw32"], [
699   VLC_SAVE_FLAGS
700   LIBS=""
701   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
702     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
703       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
704     ])
705   ])
706   VLC_RESTORE_FLAGS
707
708   AC_CHECK_LIB(rt, clock_nanosleep, [
709     VLC_ADD_LIBS([libvlccore],[-lrt])
710   ], [
711     AC_CHECK_FUNC(nanosleep,,[
712       AC_CHECK_LIB(rt,nanosleep, [
713         VLC_ADD_LIBS([libvlccore],[-lrt])
714       ], [
715         AC_CHECK_LIB(posix4,nanosleep, [
716           VLC_ADD_LIBS([libvlccore],[-lposix4])
717         ])
718       ])
719     ])
720     dnl HP/UX port
721     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
722   ])
723 ])
724 AC_SUBST(LIBPTHREAD)
725
726 dnl Check for headers
727 AC_CHECK_HEADERS([search.h])
728 AC_CHECK_HEADERS(getopt.h locale.h xlocale.h)
729 AC_CHECK_HEADERS([sys/time.h sys/ioctl.h])
730 AC_CHECK_HEADERS([arpa/inet.h netinet/udplite.h sys/eventfd.h])
731 AC_CHECK_HEADERS([net/if.h], [], [],
732   [
733     #include <sys/types.h>
734     #include <sys/socket.h>
735   ])
736 AC_CHECK_HEADERS([sys/mount.h], [], [],
737   [
738     #include <sys/param.h>
739   ])
740
741 if test "${SYS}" != "mingw32"; then
742   AC_CHECK_HEADERS(machine/param.h sys/shm.h)
743   AC_CHECK_HEADERS([linux/version.h linux/dccp.h scsi/scsi.h linux/magic.h])
744   AC_CHECK_HEADERS(syslog.h mntent.h)
745 fi # end "${SYS}" != "mingw32"
746
747 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
748 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
749 AC_CHECK_TYPE(ssize_t,, [
750   AC_DEFINE(ssize_t, int)
751 ])
752
753 dnl Check for threads library
754 if test "${SYS}" != "mingw32"; then
755   AC_CHECK_HEADERS(pthread.h)
756 fi # end "${SYS}" != "mingw32"
757
758 dnl It seems that autoconf detects pkg-config only during the first
759 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
760 dnl it is nested within a conditional block, so it was not working right.
761 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
762 AC_ARG_VAR(PKG_CONFIG_PATH,
763        [Paths where to find .pc not at the default location])
764 PKG_PROG_PKG_CONFIG()
765
766 dnl On some OS we need static linking
767 AS_IF([test -n "${PKG_CONFIG}" ],[
768     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
769         PKG_CONFIG="${PKG_CONFIG} --static"
770     ])
771 ])
772
773
774 dnl
775 dnl Check for zlib.h and -lz along with system -lminizip if available
776 dnl
777 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
778 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
779 if test "${have_zlib}" = "yes"
780 then
781   VLC_ADD_LIBS([access_http skins2 sap unzip zip],[-lz])
782   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
783     AC_CHECK_HEADERS([unzip.h], [
784       have_minizip=yes
785       MINIZIP_LIBS="-lminizip -lz"
786     ], [
787       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
788       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/access/libunzip.la])
789       have_minizip=no
790     ])
791   ])
792   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
793   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
794 fi
795 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
796
797
798 dnl
799 dnl Domain name i18n support via GNU libidn
800 dnl
801 PKG_CHECK_MODULES([IDN], [libidn], [
802   have_libidn="yes"
803   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
804 ], [
805   have_libidn="no"
806 ])
807
808
809 dnl Check for dbus
810 AC_ARG_ENABLE(dbus,
811   [AS_HELP_STRING([--enable-dbus],
812     [compile D-Bus message bus support (default enabled)])])
813 have_dbus="no"
814 AS_IF([test "${enable_dbus}" != "no"], [
815   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0.0], [
816     have_dbus="yes"
817   ], [
818     AS_IF([test -n "${enable_dbus}"], [
819       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
820     ], [
821       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
822     ])
823   ])
824 ])
825 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
826
827 dnl Check for ntohl, etc.
828 VLC_SAVE_FLAGS
829 CFLAGS="${CFLAGS} -Wall -Werror"
830 AC_CACHE_CHECK([for ntohl in sys/param.h],
831     [ac_cv_c_ntohl_sys_param_h],
832     [     AC_TRY_COMPILE([#include <sys/param.h>],
833         [int meuh; ntohl(meuh);],
834         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
835 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
836     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
837 fi
838 VLC_RESTORE_FLAGS
839
840 EXTEND_HELP_STRING([Optimization options:])
841 dnl
842 dnl  Compiler warnings
843 dnl
844
845 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration])
846 RDC_PROG_CC_FLAGS([-pipe])
847 AC_LANG_PUSH([C++])
848 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
849 AC_LANG_POP([C++])
850
851 dnl
852 dnl  Debugging mode
853 dnl
854 AC_ARG_ENABLE(debug,
855   [AS_HELP_STRING([--enable-debug],
856     [build with run-time assertions (default disabled)])],,
857   [enable_debug="no"])
858 AH_TEMPLATE(NDEBUG,
859             [Define to 1 if debug code should NOT be compiled])
860 AS_IF([test "${enable_debug}" != "no"], [
861   AC_CHECK_HEADERS([valgrind/valgrind.h])
862 ], [
863   AC_DEFINE(NDEBUG)
864 ])
865
866 dnl
867 dnl  Profiling
868 dnl
869 AC_ARG_ENABLE(gprof,
870   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
871   [enable_gprof="no"])
872 AS_IF([test "${enable_gprof}" != "no"], [
873   CFLAGS="${CFLAGS} -pg"
874   CXXFLAGS="${CXXFLAGS} -pg"
875   OBJCFLAGS="${OBJCFLAGS} -pg"
876   LDFLAGS="${LDFLAGS} -pg"
877 ])
878
879 AC_ARG_ENABLE(cprof,
880   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
881   [enable_cprof="no"])
882 AS_IF([test "${enable_gprof}" != "no"], [
883   CFLAGS="${CFLAGS} -finstrument-functions"
884   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
885   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
886   LDFLAGS="${LDFLAGS} -finstrument-functions"
887 ])
888
889 dnl
890 dnl  Test coverage
891 dnl
892 AC_ARG_ENABLE(coverage,
893   [AS_HELP_STRING([--enable-coverage],
894     [build for test coverage (default disabled)])],,
895   [enable_coverage="no"])
896 AS_IF([test "${enable_coverage}" != "no"], [
897   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
898   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
899   LDFLAGS="-lgcov ${LDFLAGS}"
900 ])
901
902 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
903   VLC_SAVE_FLAGS
904   CFLAGS="${CFLAGS} -fvisibility=hidden"
905   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
906   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
907   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
908                  [ac_cv_c_visibility_hidden], [
909     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
910       ac_cv_c_visibility_hidden=yes
911     ], [
912       ac_cv_c_visibility_hidden=no
913     ])
914   ])
915   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
916 ])
917
918
919 dnl
920 dnl  Enable/disable optimizations
921 dnl
922 AC_ARG_ENABLE(optimizations,
923   [AS_HELP_STRING([--disable-optimizations],
924     [disable compiler optimizations (default enabled)])],,
925   [enable_optimizations="yes"])
926
927 dnl Check for various optimization flags
928 AS_IF([test "${enable_optimizations}" != "no"], [
929
930   dnl -O4 and -O3 only in production builds
931   AS_IF([test "{enable_debug}" = "no"], [
932     VLC_SAVE_FLAGS
933     CFLAGS="${CFLAGS} -O4"
934     CXXFLAGS="${CXXFLAGS} -O4"
935     OBJCFLAGS="${OBJCFLAGS} -O4"
936     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
937       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
938         ac_cv_c_o4=yes
939       ], [
940         ac_cv_c_o4=no
941       ])
942     ])
943     AS_IF([test "${ac_cv_c_o4}" = "no"], [
944       VLC_RESTORE_FLAGS
945       CFLAGS="${CFLAGS} -O3"
946       CXXFLAGS="${CXXFLAGS} -O3"
947       OBJCFLAGS="${OBJCFLAGS} -O3"
948       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
949         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
950           ac_cv_c_o3=yes
951         ], [
952           ac_cv_c_o3=no
953         ])
954       ])
955       AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
956     ])
957   ])
958
959   dnl Check for -ffast-math
960   VLC_SAVE_FLAGS
961   CFLAGS="${CFLAGS} -ffast-math"
962   CXXFLAGS="${CXXFLAGS} -ffast-math"
963   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
964   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
965     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
966       ac_cv_c_fast_math=yes
967     ], [
968       ac_cv_c_fast_math=no
969     ])
970   ])
971   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
972   AH_BOTTOM([
973 #ifndef __FAST_MATH__
974 # pragma STDC FENV_ACCESS OFF
975 # pragma STDC FP_CONTRACT ON
976 #endif
977 ])
978
979   dnl Check for -funroll-loops
980   VLC_SAVE_FLAGS
981   CFLAGS="${CFLAGS} -funroll-loops"
982   CXXFLAGS="${CXXFLAGS} -funroll-loops"
983   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
984   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
985     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
986       ac_cv_c_unroll_loops=yes
987     ], [
988       ac_cv_c_unroll_loops=no
989     ])
990   ])
991   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
992
993   AS_IF([test "$enable_debug" = "no"], [
994     dnl Check for -fomit-frame-pointer
995     VLC_SAVE_FLAGS
996     CFLAGS="${CFLAGS} -fomit-frame-pointer"
997     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
998     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
999     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1000       [ac_cv_c_omit_frame_pointer], [
1001       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1002         ac_cv_c_omit_frame_pointer=yes
1003       ], [
1004         ac_cv_c_omit_frame_pointer=no
1005       ])
1006     ])
1007     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1008   ])
1009 ])
1010
1011 dnl Check for Darwin plugin linking flags
1012 AS_IF([test "${SYS}" = "darwin"], [
1013   VLC_SAVE_FLAGS
1014   CFLAGS="${CFLAGS} -bundle -undefined error"
1015   AC_CACHE_CHECK([if $CC accepts -bundle -undefined error],
1016     [ac_cv_ld_darwin], [
1017     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1018       ac_cv_ld_darwin=yes
1019     ], [
1020       ac_cv_ld_darwin=no
1021     ])
1022   ])
1023   AS_IF([test "${ac_cv_ld_darwin}" != "no"], [
1024     VLC_ADD_LDFLAGS([plugin],[-bundle -undefined error])
1025   ])
1026   VLC_RESTORE_FLAGS
1027 ])
1028
1029 dnl Checks for __attribute__(aligned()) directive
1030 VLC_SAVE_FLAGS
1031 CFLAGS="${CFLAGS} -Werror"
1032 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1033     [ac_cv_c_attribute_aligned],
1034     [ac_cv_c_attribute_aligned=0
1035     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1036         AC_TRY_COMPILE([],
1037         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1038         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1039     done])
1040 VLC_RESTORE_FLAGS
1041 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1042     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1043         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1044 fi
1045
1046 dnl Check for __attribute__((packed))
1047 AC_CACHE_CHECK([for __attribute__((packed))],
1048   [ac_cv_c_attribute_packed],
1049   [ac_cv_c_attribute_packed=no
1050    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1051                     [ac_cv_c_attribute_packed=yes])])
1052 if test "${ac_cv_c_attribute_packed}" != "no"; then
1053   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1054 fi
1055
1056 dnl
1057 dnl  Check the CPU
1058 dnl
1059 case "${host_cpu}" in
1060   "")
1061     ARCH=unknown
1062     ;;
1063   *)
1064     ARCH="${host_cpu}"
1065     ;;
1066 esac
1067
1068 dnl Check for backtrace() support
1069 AC_CHECK_HEADERS(execinfo.h)
1070 AC_CHECK_FUNCS(backtrace)
1071
1072 dnl
1073 dnl  default modules
1074 dnl
1075 ALIASES="${ALIASES} cvlc rvlc"
1076
1077 dnl
1078 dnl  Accelerated modules
1079 dnl
1080
1081 dnl  Check for fully working MMX intrinsics
1082 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1083 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1084 AC_ARG_ENABLE(mmx,
1085   [AS_HELP_STRING([--disable-mmx],
1086     [disable MMX optimizations (default auto)])],,[
1087   case "${host_cpu}" in
1088     i?86|x86_64)
1089       enable_mmx="yes"
1090       ;;
1091     *)
1092       enable_mmx="no"
1093       ;;
1094   esac
1095 ])
1096 have_mmx="no"
1097 have_mmxext="no"
1098 AS_IF([test "${enable_mmx}" != "no"], [
1099   ARCH="${ARCH} mmx"
1100   VLC_SAVE_FLAGS
1101   CFLAGS="${CFLAGS} -mmmx"
1102   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1103     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1104 [#include <mmintrin.h>
1105 #include <stdint.h>
1106 uint64_t frobzor;]], [
1107 [__m64 a, b, c;
1108 a = b = c = (__m64)frobzor;
1109 a = _mm_slli_pi16(a, 3);
1110 a = _mm_adds_pi16(a, b);
1111 c = _mm_srli_pi16(c, 8);
1112 c = _mm_slli_pi16(c, 3);
1113 b = _mm_adds_pi16(b, c);
1114 a = _mm_unpacklo_pi8(a, b);
1115 frobzor = (uint64_t)a;]])], [
1116       ac_cv_c_mmx_intrinsics=yes
1117     ], [
1118       ac_cv_c_mmx_intrinsics=no
1119     ])
1120   ])
1121   VLC_RESTORE_FLAGS
1122   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1123     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1124   ])
1125
1126   VLC_SAVE_FLAGS
1127   CFLAGS="${CFLAGS} -mmmx"
1128   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1129     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1130 void *p;
1131 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1132 ]])
1133     ], [
1134       ac_cv_mmx_inline=yes
1135     ], [
1136       ac_cv_mmx_inline=no
1137     ])
1138   ])
1139   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1140     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1141     have_mmx="yes"
1142   ])
1143
1144   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1145                  [ac_cv_mmxext_inline], [
1146     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1147 void *p;
1148 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1149 ]])
1150     ], [
1151       ac_cv_mmxext_inline=yes
1152     ], [
1153       ac_cv_mmxext_inline=no
1154     ])
1155   ])
1156   VLC_RESTORE_FLAGS
1157   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1158     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1159     have_mmxext="yes"
1160   ])
1161 ])
1162 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1163 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1164
1165 dnl  Check for fully workin SSE2 intrinsics
1166 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1167 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1168 AC_ARG_ENABLE(sse,
1169   [AS_HELP_STRING([--disable-sse],
1170     [disable SSE (1-4) optimizations (default auto)])],, [
1171   case "${host_cpu}" in
1172     i?86|x86_64)
1173       enable_sse=yes
1174       ;;
1175     *)
1176       enable_sse=no
1177       ;;
1178   esac
1179 ])
1180 have_sse2="no"
1181 AS_IF([test "${enable_sse}" != "no"], [
1182   ARCH="${ARCH} sse sse2"
1183
1184   VLC_SAVE_FLAGS
1185   CFLAGS="${CFLAGS} -msse2"
1186   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1187     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1188 [#include <emmintrin.h>
1189 #include <stdint.h>
1190 uint64_t frobzor;]], [
1191 [__m128i a, b, c;
1192 a = b = c = _mm_set1_epi64((__m64)frobzor);
1193 a = _mm_slli_epi16(a, 3);
1194 a = _mm_adds_epi16(a, b);
1195 c = _mm_srli_epi16(c, 8);
1196 c = _mm_slli_epi16(c, 3);
1197 b = _mm_adds_epi16(b, c);
1198 a = _mm_unpacklo_epi8(a, b);
1199 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1200       ac_cv_c_sse2_intrinsics=yes
1201     ], [
1202       ac_cv_c_sse2_intrinsics=no
1203     ])
1204   ])
1205   VLC_RESTORE_FLAGS
1206   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1207     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1208   ])
1209
1210   VLC_SAVE_FLAGS
1211   CFLAGS="${CFLAGS} -msse"
1212   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1213     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1214 void *p;
1215 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1216 ]])
1217     ], [
1218       ac_cv_sse_inline=yes
1219     ], [
1220       ac_cv_sse_inline=no
1221     ])
1222   ])
1223
1224   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1225     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1226   ])
1227
1228   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1229     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1230 void *p;
1231 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1232 ]])
1233     ], [
1234       ac_cv_sse2_inline=yes
1235     ], [
1236       ac_cv_sse2_inline=no
1237     ])
1238   ])
1239   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1240     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1241     have_sse2="yes"
1242   ])
1243
1244   # SSE3
1245   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1246     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1247 void *p;
1248 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1249 ]])
1250     ], [
1251       ac_cv_sse3_inline=yes
1252     ], [
1253       ac_cv_sse3_inline=no
1254     ])
1255   ])
1256
1257   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1258     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1259   # SSSE3
1260   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1261     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1262 void *p;
1263 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1264 ]])
1265     ], [
1266       ac_cv_ssse3_inline=yes
1267     ], [
1268       ac_cv_ssse3_inline=no
1269     ])
1270   ])
1271
1272   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1273     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1274
1275   # SSE4.1
1276   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1277                  [ac_cv_sse4_1_inline], [
1278     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1279 void *p;
1280 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1281 ]])
1282     ], [
1283       ac_cv_sse4_1_inline=yes
1284     ], [
1285       ac_cv_sse4_1_inline=no
1286     ])
1287   ])
1288
1289   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1290     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1291
1292   # SSE4.2
1293   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1294                  [ac_cv_sse4_2_inline], [
1295     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1296 void *p;
1297 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1298 ]])
1299     ], [
1300       ac_cv_sse4_2_inline=yes
1301     ], [
1302       ac_cv_sse4_2_inline=no
1303     ])
1304   ])
1305
1306   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1307     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1308
1309   # SSE4A
1310   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1311     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1312 void *p;
1313 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1314 ]])
1315     ], [
1316       ac_cv_sse4a_inline=yes
1317     ], [
1318       ac_cv_sse4a_inline=no
1319     ])
1320   ])
1321   VLC_RESTORE_FLAGS
1322   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1323     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1324 ])
1325 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1326
1327 VLC_SAVE_FLAGS
1328 CFLAGS="${CFLAGS} -mmmx"
1329 have_3dnow="no"
1330 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1331   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1332 void *p;
1333 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1334 ]])
1335   ], [
1336     ac_cv_3dnow_inline=yes
1337   ], [
1338     ac_cv_3dnow_inline=no
1339   ])
1340 ])
1341 VLC_RESTORE_FLAGS
1342 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1343   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1344             [Define to 1 if 3D Now! inline assembly is available.])
1345   have_3dnow="yes"
1346 ])
1347 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1348
1349
1350 AC_ARG_ENABLE(neon,
1351   [AS_HELP_STRING([--disable-neon],
1352     [disable NEON optimizations (default auto)])],, [
1353   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1354 ])
1355 AS_IF([test "${enable_neon}" != "no"], [
1356   VLC_SAVE_FLAGS
1357   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1358   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1359     AC_COMPILE_IFELSE([
1360       AC_LANG_PROGRAM(,[[
1361 asm volatile("vqmovun.s64 d0, q1":::"d0");
1362 ]])
1363     ], [
1364       ac_cv_arm_neon="yes"
1365     ], [
1366       ac_cv_arm_neon="no"
1367     ])
1368   ])
1369   VLC_RESTORE_FLAGS
1370 ])
1371 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1372
1373
1374 AC_ARG_ENABLE(altivec,
1375   [AS_HELP_STRING([--disable-altivec],
1376     [disable AltiVec optimizations (default auto)])],, [
1377   AS_IF([test "${host_cpu}" = "powerpc"],
1378         [enable_altivec=yes], [enable_altivec=no])
1379 ])
1380 have_altivec="no"
1381 AS_IF([test "${enable_altivec}" = "yes"], [
1382   ARCH="${ARCH} altivec";
1383   VLC_SAVE_FLAGS
1384   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1385     [ac_cv_altivec_inline],
1386     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1387          ac_cv_altivec_inline="yes",
1388          [CFLAGS="${CFLAGS} -Wa,-m7400"
1389           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1390             [ac_cv_altivec_inline="-Wa,-m7400"],
1391             ac_cv_altivec_inline=no)
1392          ])])
1393   VLC_RESTORE_FLAGS
1394   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1395     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1396               [Define to 1 if AltiVec inline assembly is available.])
1397     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1398       VLC_ADD_CFLAGS([memcpyaltivec],[${ac_cv_altivec_inline}])
1399       VLC_ADD_CFLAGS([i420_yuy2_altivec],[${ac_cv_altivec_inline}])
1400       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1401     ])
1402     have_altivec="yes"
1403   ])
1404
1405 dnl The AltiVec C extensions
1406 dnl
1407 dnl There are several possible cases:
1408 dnl - OS X PPC, gcc 4.x: use -mpim-altivec -force_cpusubtype_ALL, don't
1409 dnl                      need <altivec.h>
1410 dnl - OS X PPC, gcc 3.x: need -faltivec, don't need <altivec.h>
1411 dnl - Linux PPC, gcc 3.4, 4.x: need <altivec.h> which requires -maltivec
1412 dnl - Linux PPC, gcc 3.3: need <altivec.h> and -maltivec -mabi=altivec
1413 dnl - Linux PPC, gcc 3.x: need <altivec.h> and -fvec
1414 dnl - Others: test should fail
1415   VLC_SAVE_FLAGS
1416   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1417   [ac_cv_c_altivec],
1418   [# OS X/PPC test (gcc 4.x)
1419    CFLAGS="${CFLAGS} -mpim-altivec -force_cpusubtype_ALL"
1420    AC_TRY_COMPILE([vector unsigned char foo;],
1421      [vec_ld(0, (unsigned char *)0);],
1422      [ac_cv_c_altivec="-mpim-altivec -force_cpusubtype_ALL"],
1423      [# OS X/PPC test (gcc 3.x)
1424       CFLAGS="${CFLAGS} -faltivec"
1425       AC_TRY_COMPILE([vector unsigned char foo;],
1426         [vec_ld(1 * sizeof(vector float), (unsigned char *)0);],
1427         [ac_cv_c_altivec="-faltivec"],
1428         dnl Below this are the Linux tests
1429         [# Linux/PPC test (gcc 4.x)
1430          CFLAGS="${CFLAGS} -maltivec"
1431          AC_TRY_COMPILE([#include <altivec.h>],
1432            [vec_ld(0, (unsigned char *)0);],
1433            [ac_cv_c_altivec="-maltivec"],
1434            [# Linux/PPC test (gcc 3.3)
1435             CFLAGS="${CFLAGS} -maltivec -mabi=altivec"
1436             AC_TRY_COMPILE([#include <altivec.h>],
1437               [vec_ld(0, (unsigned char *)0);],
1438               [ac_cv_c_altivec=""
1439                ac_cv_c_altivec_abi="-maltivec -mabi=altivec"],
1440               [# Linux/PPC test (gcc 3.3)
1441                CFLAGS="${CFLAGS} -fvec"
1442                AC_TRY_COMPILE([#include <altivec.h>],
1443                  [vec_ld(0, (unsigned char *)0);],
1444                  [ac_cv_c_altivec="-fvec"],
1445                  [ac_cv_c_altivec=no])
1446               ])
1447            ])
1448         ])
1449      ])
1450   ])
1451
1452   VLC_RESTORE_FLAGS
1453   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1454     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1455     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1456     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1457     VLC_ADD_CFLAGS([i420_yuy2_altivec memcpyaltivec deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1458     have_altivec="yes"
1459   ])
1460   AC_CHECK_HEADERS(altivec.h)
1461
1462   VLC_SAVE_FLAGS
1463   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1464   AC_CACHE_CHECK([if linker needs -framework vecLib],
1465     [ac_cv_ld_altivec],
1466     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1467   VLC_RESTORE_FLAGS
1468   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1469     VLC_ADD_LIBS([libvlccore memcpyaltivec],[-Wl,-framework,vecLib])
1470   ])
1471 ])
1472 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1473
1474 dnl
1475 dnl  Memory usage
1476 dnl
1477 AC_ARG_ENABLE(optimize-memory,
1478   [AS_HELP_STRING([--enable-optimize-memory],
1479     [optimize memory usage over performance])])
1480 if test "${enable_optimize_memory}" = "yes"; then
1481   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1482 fi
1483
1484 dnl
1485 dnl Allow running as root (useful for people running on embedded platforms)
1486 dnl
1487 AC_ARG_ENABLE(run-as-root,
1488   [AS_HELP_STRING([--enable-run-as-root],
1489     [allow running VLC as root (default disabled)])])
1490 AS_IF([test "${enable_run_as_root}" = "yes"],[
1491     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1492               [Define to 1 to allow running VLC as root (uid 0).])
1493 ])
1494
1495 dnl
1496 dnl Stream output
1497 dnl
1498 AC_ARG_ENABLE(sout,
1499   [AS_HELP_STRING([--disable-sout],
1500     [disable streaming output (default enabled)])])
1501 AS_IF([test "${enable_sout}" != "no"], [
1502   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1503 ])
1504 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1505
1506 dnl Lua modules
1507 AC_ARG_ENABLE(lua,
1508   [AS_HELP_STRING([--disable-lua],
1509     [disable LUA scripting support (default enabled)])])
1510 if test "${enable_lua}" != "no"
1511 then
1512   PKG_CHECK_MODULES(LUA, lua5.1,
1513     [ have_lua=yes ],
1514     [
1515     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1516     PKG_CHECK_MODULES(LUA, lua >= 5.1,
1517       [ have_lua=yes ],
1518       [
1519         AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1520         have_lua=yes
1521         AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1522           [],
1523           [ have_lua=no ] )
1524         AC_CHECK_LIB(  lua5.1 , luaL_newstate,
1525           [LUA_LIBS="-llua5.1"],
1526           AC_CHECK_LIB( lua51 , luaL_newstate,
1527             [LUA_LIBS="-llua51"],
1528             AC_CHECK_LIB( lua , luaL_newstate,
1529               [LUA_LIBS="-llua"],
1530               [ have_lua=no
1531               ], [-lm])
1532           )
1533         )
1534       ])
1535     ])
1536   if test "x${have_lua}" = "xyes" ;  then
1537      VLC_ADD_LIBS([lua],[$LUA_LIBS])
1538      VLC_ADD_CFLAGS([lua],[$LUA_CFLAGS])
1539   else
1540       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1541   fi
1542   AC_ARG_VAR([LUAC], [LUA byte compiler])
1543   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1544   AS_IF([test "${LUAC}" = "false"], [
1545     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1546   ])
1547   AS_IF([test -f ${CONTRIB_DIR}/lib/liblua.a -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|cut -d' ' -f2` != 0404], [
1548     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1549   ])
1550 fi
1551 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1552
1553
1554 dnl
1555 dnl HTTP daemon
1556 dnl
1557 AC_ARG_ENABLE(httpd,
1558   [AS_HELP_STRING([--disable-httpd],
1559     [disable the built-in HTTP server (default enabled)])])
1560 if test "${enable_httpd}" != "no"
1561 then
1562   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1563 fi
1564 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1565
1566
1567 dnl
1568 dnl VideoLAN manager
1569 dnl
1570 AC_ARG_ENABLE(vlm,
1571   [AS_HELP_STRING([--disable-vlm],
1572     [disable the stream manager (default enabled)])],,
1573   [enable_vlm="${enable_sout}"])
1574 AS_IF([test "${enable_vlm}" != "no"], [
1575   AS_IF([test "${enable_sout}" = "no"], [
1576     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1577   ])
1578   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1579 ])
1580 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1581
1582
1583 dnl
1584 dnl  Input plugins
1585 dnl
1586
1587 EXTEND_HELP_STRING([Input plugins:])
1588
1589 dnl
1590 dnl libproxy support
1591 dnl
1592 AC_ARG_ENABLE(libproxy,
1593   [AS_HELP_STRING([--enable-libproxy],[support libproxy (default auto)])])
1594 AS_IF([test "${enable_libproxy}" != "no"], [
1595   PKG_CHECK_MODULES(LIBPROXY, libproxy-1.0, [
1596     AC_DEFINE(HAVE_LIBPROXY, 1, [Define if libproxy is available])
1597     VLC_ADD_CFLAGS([access_http],[$LIBPROXY_CFLAGS])
1598     VLC_ADD_LIBS([access_http],[$LIBPROXY_LIBS])
1599   ], [
1600     AS_IF([test -n "${enable_libproxy}"], [
1601       AC_MSG_ERROR([${LIBPROXY_PKG_ERRORS}.])
1602     ])
1603   ])
1604 ])
1605
1606 dnl
1607 dnl  live555 input
1608 dnl
1609 AC_ARG_ENABLE(live555,
1610   [AS_HELP_STRING([--enable-live555],
1611     [enable RTSP input through live555 (default enabled)])])
1612
1613 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1614   AC_LANG_PUSH(C++)
1615   VLC_SAVE_FLAGS
1616
1617   dnl detect include paths
1618   AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1619     CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1620   ], [
1621     AS_IF([test ${SYS} != "os2"], [
1622       LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1623       CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1624     ], [
1625       LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1626       CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1627       LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1628     ])
1629   ])
1630
1631   dnl CPP Flags
1632   AS_IF([test "${SYS}" = "solaris"], [
1633     CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1634   ])
1635   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1636   LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1637
1638   dnl version check
1639   AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1640     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1641 [#include <liveMedia_version.hh>
1642 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1643 # error BOOM
1644 #endif]])
1645     ], [
1646       ac_cv_live555="yes"
1647     ], [
1648       ac_cv_live555="no"
1649     ])
1650   ])
1651
1652   AS_IF([test "$ac_cv_live555" = "no"], [
1653     AC_MSG_WARN([liveMedia is missing or its installed version is too old:
1654 Version 2011.12.23 or later is required to proceed.
1655 You can get an updated one from http://www.live555.com/liveMedia .])
1656     AS_IF([test -n "${enable_live555}"], [
1657       AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1658     ])
1659   ], [
1660     other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1661     other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1662     AS_IF([test "${SYS}" = "mingw32"], [
1663       # add ws2_32 for closesocket, select, recv
1664       other_libs="$other_libs -lws2_32"
1665     ])
1666
1667     dnl We need to check for pic because live555 don't provide shared libs
1668     dnl and we want to build a plugins so we need -fPIC on some arch.
1669     VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1670     VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1671     AC_CHECK_LIB(liveMedia_pic, main, [
1672       VLC_ADD_PLUGIN([live555])
1673       VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1674     ],[
1675       AC_CHECK_LIB(liveMedia, main, [
1676         VLC_ADD_PLUGIN([live555])
1677         VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1678       ],[],[${other_libs}])],[${other_libs_pic}])
1679   ])
1680   VLC_RESTORE_FLAGS
1681   AC_LANG_POP(C++)
1682 ])
1683
1684 dnl
1685 dnl IIDC and DV FireWire input modules
1686 dnl
1687 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1688 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1689
1690 dnl
1691 dnl - linsys modules: access module check for libzvbi
1692 dnl
1693 AC_ARG_ENABLE(linsys,
1694   [AS_HELP_STRING([--enable-linsys],
1695     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1696 if test "$SYS" = "linux" -a "${enable_linsys}" != "no"; then
1697   VLC_ADD_PLUGIN([linsys_hdsdi])
1698   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28],
1699     [ VLC_ADD_LIBS([linsys_sdi],[$LINSYS_SDI_LIBS])
1700       VLC_ADD_CFLAGS([linsys_sdi],[$LINSYS_SDI_CFLAGS])
1701       VLC_ADD_PLUGIN([linsys_sdi]) ],
1702     [AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])]
1703   )
1704 fi
1705
1706 dnl
1707 dnl dvdread module: check for libdvdread
1708 dnl
1709 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread], [dvdread input module], [auto])
1710
1711 dnl
1712 dnl libdvdnav plugin
1713 dnl
1714 AC_ARG_ENABLE(dvdnav,
1715   [AS_HELP_STRING([--disable-dvdnav],
1716     [disable DVD navigation with libdvdnav (default auto)])])
1717 if test "${enable_dvdnav}" != "no"
1718 then
1719   PKG_CHECK_MODULES(DVDNAV, dvdnav, [
1720     VLC_ADD_PLUGIN([dvdnav])
1721     VLC_ADD_CFLAGS([dvdnav],[${DVDNAV_CFLAGS}])
1722     VLC_ADD_LIBS([dvdnav],[${DVDNAV_LIBS}])
1723     AC_CHECK_LIB(dvdnav, dvdnav_get_video_resolution,
1724       AC_DEFINE(HAVE_DVDNAV_GET_VIDEO_RESOLUTION, 1, [Define if you have dvdnav_get_video_resolution.]),
1725         [], [${LIBS_dvdnav}])
1726     AC_CHECK_LIB(dvdnav, dvdnav_describe_title_chapters,
1727       AC_DEFINE(HAVE_DVDNAV_DESCRIBE_TITLE_CHAPTERS, 1, [Define if you have dvdnav_describe_title_chapters.]),
1728         [], [${LIBS_dvdnav}])],
1729       [AC_MSG_WARN([${DVDNAV_PKG_ERRORS}.])])
1730 fi
1731
1732 dnl
1733 dnl  Blu-ray Disc Support with libbluray
1734 dnl
1735 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.2.1], (libbluray for Blu-ray disc support ) )
1736
1737 dnl
1738 dnl  OpenCV wrapper and example filters
1739 dnl
1740 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1741
1742
1743 dnl
1744 dnl  libsmbclient plugin
1745 dnl
1746 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [access_smb], [smbclient], (SMB/CIFS support), [auto])
1747
1748
1749 dnl
1750 dnl sftp access support
1751 dnl
1752 PKG_ENABLE_MODULES_VLC([SFTP], [access_sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1753
1754 dnl
1755 dnl  Video4Linux 2
1756 dnl
1757 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1758   [disable Video4Linux version 2 (default auto)])])
1759 have_v4l2="no"
1760 AS_IF([test "$enable_v4l2" != "no"], [
1761   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1762     have_v4l2="yes"
1763   ])
1764 ])
1765 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1766
1767 dnl
1768 dnl special access module for Blackmagic SDI cards
1769 dnl
1770 AC_ARG_ENABLE(decklink,
1771   [AS_HELP_STRING([--disable-decklink],
1772     [disable Blackmagic DeckLink SDI input (default auto)])])
1773 AC_ARG_WITH(decklink_sdk,
1774   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1775     [                        location of Blackmagic DeckLink SDI SDK])])
1776 have_decklink=no
1777 if test "${enable_decklink}" != "no"
1778 then
1779   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1780   then
1781     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1782   fi
1783   VLC_SAVE_FLAGS
1784   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1785   AC_LANG_PUSH(C++)
1786   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1787       have_decklink=yes
1788   ], [
1789       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1790   ])
1791   AC_LANG_POP(C++)
1792   VLC_RESTORE_FLAGS
1793 fi
1794 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1795
1796
1797 dnl
1798 dnl  gnomeVFS access module
1799 dnl
1800 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [access_gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1801
1802 dnl
1803 dnl  VCDX modules
1804 dnl
1805 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1806
1807 dnl
1808 dnl  Built-in CD-DA and VCD module
1809 dnl
1810 AC_ARG_ENABLE(vcd,
1811   [AS_HELP_STRING([--disable-vcd],
1812     [disable built-in VCD and CD-DA support (default enabled)])])
1813
1814 AC_ARG_ENABLE(libcddb,
1815   [AS_HELP_STRING([--disable-libcddb],
1816     [disable CDDB for Audio CD (default enabled)])])
1817
1818 if test "${enable_vcd}" != "no"
1819 then
1820   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1821   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1822     AC_MSG_RESULT(yes)
1823     VLC_ADD_PLUGIN([vcd cdda])
1824   ],[
1825     AC_MSG_RESULT(no)
1826   ])
1827
1828   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1829   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1830     AC_MSG_RESULT(yes)
1831     VLC_ADD_PLUGIN([vcd cdda])
1832     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1833   ],[
1834     AC_MSG_RESULT(no)
1835   ])
1836
1837   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1838   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1839     AC_MSG_RESULT(yes)
1840     VLC_ADD_PLUGIN([vcd cdda])
1841     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1842   ],[
1843     AC_MSG_RESULT(no)
1844   ])
1845
1846   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2"
1847   then
1848     VLC_ADD_PLUGIN([vcd cdda])
1849   fi
1850
1851   if test "${SYS}" = "darwin"
1852   then
1853     VLC_ADD_PLUGIN([vcd cdda])
1854     VLC_ADD_LIBS([vcd vcdx cdda],[-Wl,-framework,IOKit,-framework,CoreFoundation])
1855     VLC_ADD_LIBS([vcdx cdda],[-liconv])
1856   fi
1857
1858   if test "$enable_libcddb" != "no"; then
1859     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1860       HAVE_LIBCDDB=yes
1861       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1862       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1863       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1864       ],:
1865       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1866       HAVE_LIBCDDB=no])
1867   fi
1868 fi
1869
1870 dnl
1871 dnl Linux DVB
1872 dnl
1873 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1874   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1875 [#include <linux/dvb/version.h>
1876 #if (DVB_API_VERSION < 5)
1877 # error Linux DVB API v3.2 and older are not supported.
1878 #endif
1879 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1880 # error Linux DVB API v5.0 is unsupported. Please update.
1881 #endif
1882 ]])], [
1883   ac_cv_linux_dvb_5_1=yes
1884 ], [
1885   ac_cv_linux_dvb_5_1=no
1886 ])])
1887 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1888
1889 dnl
1890 dnl  Screen capture module
1891 dnl
1892 AC_ARG_ENABLE(screen,
1893   [AS_HELP_STRING([--enable-screen],
1894     [disable screen capture (default enabled)])])
1895 if test "${enable_screen}" != "no"; then
1896   if test "${SYS}" = "darwin"; then
1897     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1898       VLC_ADD_PLUGIN([screen])
1899     ])
1900   fi
1901 fi
1902 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1903
1904 dnl
1905 dnl  VNC/RFB access module
1906 dnl
1907 PKG_ENABLE_MODULES_VLC([LIBVNC], [libvnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1908
1909 dnl  RDP/Remote Desktop access module
1910 dnl
1911 PKG_ENABLE_MODULES_VLC([LIBFREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1912
1913 dnl
1914 dnl  Real RTSP plugin
1915 dnl
1916 AC_ARG_ENABLE(realrtsp,
1917   [  --enable-realrtsp       Real RTSP module (default disabled)])
1918 if test "${enable_realrtsp}" = "yes"; then
1919   VLC_ADD_PLUGIN([realrtsp])
1920 fi
1921
1922 dnl
1923 dnl MacOS eyeTV
1924 AC_ARG_ENABLE(macosx-eyetv,
1925   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1926 if test "x${enable_macosx_eyetv}" != "xno" &&
1927   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1928 then
1929   VLC_ADD_LIBS([access_eyetv], [-Wl,-framework,Foundation])
1930   VLC_ADD_PLUGIN([access_eyetv])
1931 fi
1932
1933 dnl
1934 dnl QTKit
1935 AC_ARG_ENABLE(macosx-qtkit,
1936   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1937 if test "x${enable_macosx_qtkit}" != "xno" &&
1938   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1939 then
1940   VLC_ADD_PLUGIN([qtcapture])
1941   VLC_ADD_PLUGIN([qtsound])
1942 fi
1943 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1944
1945
1946 dnl
1947 dnl  Demux plugins
1948 dnl
1949
1950 EXTEND_HELP_STRING([Mux/Demux plugins:])
1951
1952 dnl
1953 dnl  libdvbpsi check for ts mux/demux
1954 dnl
1955 have_dvbpsi="no"
1956 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1957 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1958
1959
1960 dnl
1961 dnl  GME demux plugin
1962 dnl
1963 AC_ARG_ENABLE(gme,
1964   [AS_HELP_STRING([--enable-gme],
1965     [use Game Music Emu (default auto)])])
1966 AS_IF([test "${enable_gme}" != "no"], [
1967   AC_CHECK_HEADER([gme/gme.h], [
1968     VLC_ADD_LIBS([gme], [-lgme])
1969     VLC_ADD_PLUGIN([gme])
1970   ], [
1971     AS_IF([test "x${enable_gme}" != "x"], [
1972       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1973     ])
1974   ])
1975 ])
1976
1977
1978 dnl
1979 dnl  SIDPlay plugin
1980 dnl
1981 AC_ARG_ENABLE(sid,
1982     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1983 AS_IF([test "${enable_sid}" != "no"], [
1984     PKG_CHECK_MODULES(SID, [libsidplay2], [
1985         AC_LANG_PUSH(C++)
1986         oldCPPFLAGS="$CPPFLAGS"
1987         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1988         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1989             VLC_ADD_PLUGIN([sid])
1990             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1991             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
1992         ], [
1993             AS_IF([test -n "${enable_sid}"],
1994                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
1995                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
1996                 )
1997         ])
1998         CPPFLAGS="$oldCPPFLAGS"
1999         AC_LANG_POP(C++)
2000     ], [
2001         AS_IF([test "x${enable_sid}" = "xyes"],
2002             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2003             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2004             )
2005     ])
2006 ])
2007
2008
2009 dnl
2010 dnl  ogg demux plugin
2011 dnl
2012 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2013 if test "${enable_sout}" != "no"; then
2014     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2015 dnl Check for libshout
2016     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2017 fi
2018
2019 dnl
2020 dnl  matroska demux plugin
2021 dnl
2022 AC_ARG_ENABLE(mkv,
2023   [AS_HELP_STRING([--disable-mkv],
2024     [do not use libmatroska (default auto)])])
2025 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2026   AC_LANG_PUSH(C++)
2027   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2028     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2029     AC_EGREP_CPP(yes,
2030       [#include <ebml/EbmlVersion.h>
2031        #ifdef LIBEBML_VERSION
2032        #if LIBEBML_VERSION >= 0x010000
2033        yes
2034        #endif
2035        #endif],
2036       [AC_MSG_RESULT([yes])
2037         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2038           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2039           AC_EGREP_CPP(yes,
2040             [#include <matroska/KaxVersion.h>
2041              #ifdef LIBMATROSKA_VERSION
2042              #if LIBMATROSKA_VERSION >= 0x010000
2043              yes
2044              #endif
2045              #endif],
2046             [AC_MSG_RESULT([yes])
2047               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2048               VLC_ADD_CXXFLAGS([mkv],[])
2049               AC_CHECK_LIB(ebml_pic, main, [
2050                 VLC_ADD_PLUGIN([mkv])
2051                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2052               ],[
2053                 AC_CHECK_LIB(ebml, main, [
2054                   VLC_ADD_PLUGIN([mkv])
2055                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2056                 ])
2057               ])
2058             ], [
2059               AC_MSG_RESULT([no])
2060               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2061           ])
2062         ])
2063       ],
2064       [AC_MSG_RESULT([no])
2065         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2066     ])
2067   ])
2068   AC_LANG_POP(C++)
2069 fi
2070
2071 dnl
2072 dnl  modplug demux plugin
2073 dnl
2074 AC_ARG_ENABLE(mod,
2075   [AS_HELP_STRING([--disable-mod],
2076     [do not use libmodplug (default auto)])])
2077 if test "${enable_mod}" != "no" ; then
2078     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2079           VLC_ADD_PLUGIN([mod])
2080           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2081           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2082     ],[
2083        AS_IF([test -n "${enable_mod}"],
2084          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2085          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2086     ])
2087 fi
2088
2089 dnl
2090 dnl  mpc demux plugin
2091 dnl
2092 AC_ARG_ENABLE(mpc,
2093   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2094 if test "${enable_mpc}" != "no"
2095 then
2096   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2097     VLC_ADD_PLUGIN([mpc])
2098     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2099     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2100     VLC_ADD_PLUGIN([mpc])
2101     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2102 fi
2103
2104 dnl
2105 dnl  Codec plugins
2106 dnl
2107
2108 EXTEND_HELP_STRING([Codec plugins:])
2109
2110 dnl
2111 dnl wmafixed plugin
2112 dnl
2113 AC_ARG_ENABLE(wma-fixed,
2114   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2115 if test "${enable_wma_fixed}" = "yes"
2116 then
2117   VLC_ADD_PLUGIN([wma_fixed])
2118 fi
2119
2120 dnl
2121 dnl shine fixed point mp3 encoder
2122 dnl
2123 AC_ARG_ENABLE(shine,
2124   [  --enable-shine          shine mp3 encoding module (default disabled)])
2125 if test "${enable_shine}" = "yes"
2126 then
2127   VLC_ADD_PLUGIN([shine])
2128 fi
2129
2130 dnl
2131 dnl openmax il codec plugin
2132 dnl
2133 AC_ARG_ENABLE(omxil,
2134   [  --enable-omxil          openmax il codec module (default disabled)])
2135 if test "${enable_omxil}" = "yes"
2136 then
2137   VLC_ADD_PLUGIN([omxil])
2138 fi
2139
2140 dnl
2141 dnl openmax il vout plugin
2142 dnl
2143 AC_ARG_ENABLE(omxil-vout,
2144   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2145 if test "${enable_omxil_vout}" = "yes"
2146 then
2147   VLC_ADD_PLUGIN([omxil_vout])
2148 fi
2149
2150 dnl
2151 dnl raspberry pi openmax il configuration
2152 dnl
2153 AC_ARG_ENABLE(rpi-omxil,
2154   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2155 if test "${enable_rpi_omxil}" = "yes"
2156 then
2157   VLC_ADD_PLUGIN([omxil omxil_vout])
2158   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2159 fi
2160
2161 dnl
2162 dnl CrystalHD codec plugin
2163 dnl
2164 AC_ARG_ENABLE(crystalhd,
2165   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2166 if test "${enable_crystalhd}" != "no"; then
2167     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2168       VLC_ADD_PLUGIN([crystalhd])
2169       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2170     ],[
2171       if test "${SYS}" = "mingw32" ; then
2172         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2173           VLC_ADD_PLUGIN([crystalhd])
2174           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2175             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2176             ])
2177         ],[
2178           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2179                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2180                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2181         ],[#define __LINUX_USER__
2182                #include <libcrystalhd/bc_dts_types.h>
2183         ])
2184       fi
2185     ],[
2186        #include <libcrystalhd/bc_dts_types.h>
2187       ])
2188 fi
2189
2190 dnl
2191 dnl  mad plugin
2192 dnl
2193 AC_ARG_ENABLE(mad,
2194   [  --enable-mad            libmad module (default enabled)])
2195 if test "${enable_mad}" != "no"
2196 then
2197   AC_ARG_WITH(mad,
2198     [  --with-mad=PATH         path to libmad],[],[])
2199   if test "${with_mad}" != "no" -a -n "${with_mad}"
2200   then
2201     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2202     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2203   fi
2204
2205   AC_ARG_WITH(mad-tree,
2206     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2207   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2208   then
2209     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2210     if test -z "${real_mad_tree}"
2211     then
2212       dnl  The given directory can't be found
2213       AC_MSG_RESULT(no)
2214       AC_MSG_ERROR([${with_mad_tree} directory does not exist])
2215     fi
2216     dnl  Use a custom libmad
2217     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2218     if test -f ${real_mad_tree}/mad.h
2219     then
2220       AC_MSG_RESULT(yes)
2221       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2222       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2223       VLC_SAVE_FLAGS
2224       LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2225       AC_CHECK_LIB(mad, mad_bit_init, [
2226         VLC_ADD_PLUGIN([mpgatofixed32])
2227         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2228         ],[ AC_MSG_ERROR([the specified tree has not been compiled ])
2229       ],[])
2230       VLC_RESTORE_FLAGS
2231     else
2232       AC_MSG_RESULT(no)
2233       AC_MSG_ERROR([the specified tree does not have mad.h])
2234     fi
2235   else
2236     VLC_SAVE_FLAGS
2237     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_mpgatofixed32}"
2238     LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2239     AC_CHECK_HEADERS(mad.h, ,
2240       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2241     AC_CHECK_LIB(mad, mad_bit_init, [
2242       VLC_ADD_PLUGIN([mpgatofixed32])
2243       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2244       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2245     VLC_RESTORE_FLAGS
2246   fi
2247 fi
2248
2249
2250 AC_ARG_ENABLE(merge-ffmpeg,
2251 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2252   enable_merge_ffmpeg="no"
2253 ])
2254 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2255
2256 VLC_SAVE_FLAGS
2257 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
2258 AC_CACHE_CHECK([if linker supports -Bsymbolic],
2259   [ac_cv_ld_bsymbolic],
2260   [AC_TRY_LINK([],,ac_cv_ld_bsymbolic=yes,ac_cv_ld_bsymbolic=no)])
2261 VLC_RESTORE_FLAGS
2262
2263 dnl
2264 dnl  avcodec decoder/encoder plugin
2265 dnl
2266 AC_ARG_ENABLE(avcodec,
2267 [  --enable-avcodec        libavcodec codec (default enabled)])
2268 AS_IF([test "${enable_avcodec}" != "no"], [
2269   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 53.34.0 libavutil >= 51.22.0], [
2270     PKG_CHECK_EXISTS([libavcodec < 56],, [
2271       AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2272     ])
2273     VLC_SAVE_FLAGS
2274     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2275     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2276     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2277     AC_CHECK_HEADERS(libavutil/avutil.h)
2278     VLC_ADD_PLUGIN([avcodec])
2279     VLC_ADD_LIBS([avcodec],[$AVCODEC_LIBS])
2280     AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2281       VLC_ADD_LIBS([avcodec],[-Wl,-Bsymbolic])
2282     ])
2283     VLC_ADD_CFLAGS([avcodec],[$AVCODEC_CFLAGS])
2284     VLC_RESTORE_FLAGS
2285     have_avcodec="yes"
2286   ],[
2287     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2288   ])
2289 ], [
2290   have_avcodec="no"
2291 ])
2292
2293 dnl
2294 dnl libva needs avcodec
2295 dnl
2296 AC_ARG_ENABLE(libva,
2297   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2298
2299 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2300   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2301 ])
2302 have_avcodec_vaapi="no"
2303 AS_IF([test "${enable_libva}" != "no" -a "${have_avcodec}" == "yes"], [
2304   PKG_CHECK_MODULES(LIBVA, [libva libva-x11], [
2305     VLC_SAVE_FLAGS
2306     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2307     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2308     AC_CHECK_HEADERS(libavcodec/vaapi.h, [
2309       AC_MSG_NOTICE([VAAPI acceleration activated])
2310       have_avcodec_vaapi="yes"
2311     ],[
2312       AS_IF([test -n "${enable_libva}"], [
2313         AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2314       ], [
2315         AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2316       ])
2317     ])
2318     VLC_RESTORE_FLAGS
2319   ],[
2320     AS_IF([test -n "${enable_libva}"], [
2321       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2322     ], [
2323       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2324     ])
2325   ])
2326 ])
2327 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2328
2329 dnl
2330 dnl dxva2 needs avcodec
2331 dnl
2332 AC_ARG_ENABLE(dxva2,
2333   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2334
2335 have_avcodec_dxva2="no"
2336 AS_IF([test "${enable_dxva2}" != "no"], [
2337   if test "${SYS}" = "mingw32"; then
2338   AS_IF([test "x${have_avcodec}" = "xyes"], [
2339     AC_CHECK_HEADERS(dxva2api.h,
2340       [
2341         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2342            AC_MSG_NOTICE([DxVA2 acceleration activated])
2343            have_avcodec_dxva2="yes"
2344         ],[
2345     AS_IF([test "${enable_dxva2}" = "yes"],
2346           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2347               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2348         ], [#undef _WIN32_WINNT
2349             /* DXVA2 is only available in Vista and above */
2350             #define _WIN32_WINNT 0x600])
2351       ],[
2352     AS_IF([test "${enable_dxva2}" = "yes"],
2353               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2354               [AC_MSG_WARN([dxva2api.h not found])])
2355       ])
2356   ],[
2357     AS_IF([test "x${enable_dxva2}" != "x"], [
2358       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2359     ])
2360   ])
2361   fi
2362 ])
2363 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2364
2365 dnl
2366 dnl vda needs avcodec
2367 dnl
2368 AC_ARG_ENABLE(vda,
2369   [  --enable-vda          VDA  support (default auto)])
2370
2371 have_avcodec_vda="no"
2372 AS_IF([test "${enable_vda}" != "no"], [
2373   if test "${SYS}" = "darwin"; then
2374   AS_IF([test "x${have_avcodec}" = "xyes"], [
2375     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2376       [
2377         AC_CHECK_HEADERS(libavcodec/vda.h, [
2378            have_avcodec_vda="yes"
2379         ],[
2380         AS_IF([test "${enable_vda}" = "yes"],
2381               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2382               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2383         ])
2384   ],[
2385         AS_IF([test "${enable_vda}" = "yes"],
2386               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2387               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2388       ])
2389   ],[
2390     AS_IF([test "x${enable_vda}" != "x"], [
2391       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2392     ])
2393  ])
2394   fi
2395 ])
2396 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2397
2398 dnl
2399 dnl  avformat demuxer/muxer plugin
2400 dnl
2401
2402 AC_ARG_ENABLE(avformat,
2403 [  --enable-avformat       libavformat containers (default enabled)],, [
2404   enable_avformat="${have_avcodec}"
2405 ])
2406 if test "${enable_avformat}" != "no"
2407 then
2408   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil],
2409     [
2410       VLC_SAVE_FLAGS
2411       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2412       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2413       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2414       AC_CHECK_HEADERS(libavutil/avutil.h)
2415       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2416         VLC_ADD_PLUGIN([avformat access_avio])
2417         VLC_ADD_LIBS([access_avio],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2418         VLC_ADD_CFLAGS([access_avio],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2419         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2420           VLC_ADD_LDFLAGS([avformat access_avio],[-Wl,-Bsymbolic])
2421         ])
2422       ], [
2423         VLC_ADD_LIBS([avcodec],[$AVFORMAT_LIBS $AVUTIL_LIBS])
2424         VLC_ADD_CFLAGS([avcodec],[$AVFORMAT_CFLAGS $AVUTIL_CFLAGS])
2425       ])
2426       VLC_RESTORE_FLAGS
2427     ],[
2428       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2429   ])
2430 fi
2431
2432 dnl
2433 dnl  swscale image scaling and conversion plugin
2434 dnl
2435
2436 AC_ARG_ENABLE(swscale,
2437   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2438           (default enabled)]))
2439 if test "${enable_swscale}" != "no"
2440 then
2441   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2442     [
2443       VLC_SAVE_FLAGS
2444       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2445       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2446       AC_CHECK_HEADERS(libswscale/swscale.h)
2447       VLC_ADD_PLUGIN([swscale])
2448       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2449       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2450       AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2451         VLC_ADD_LIBS([swscale],[-Wl,-Bsymbolic])
2452       ])
2453       VLC_RESTORE_FLAGS
2454     ],[
2455       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2456   ])
2457 fi
2458
2459 dnl
2460 dnl  postproc plugin
2461 dnl
2462
2463 AC_ARG_ENABLE(postproc,
2464 [  --enable-postproc       libpostproc image post-processing (default auto)])
2465 if test "${enable_postproc}" != "no"
2466 then
2467   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2468     [
2469       VLC_SAVE_FLAGS
2470       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2471       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2472       AC_CHECK_HEADERS(postproc/postprocess.h)
2473       VLC_ADD_PLUGIN([postproc])
2474       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2475       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2476       VLC_RESTORE_FLAGS
2477     ],[
2478       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2479   ])
2480 fi
2481
2482 dnl
2483 dnl  faad decoder plugin
2484 dnl
2485 AC_ARG_ENABLE(faad,
2486 [  --enable-faad           faad codec (default auto)])
2487 if test "${enable_faad}" != "no"; then
2488   AC_ARG_WITH(faad-tree,  [  --with-faad-tree=PATH   faad tree for static linking])
2489   if test -n "${with_faad_tree}"; then
2490     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2491     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2492     if test -z "${real_faad_tree}"; then
2493       dnl  The given directory can't be found
2494       AC_MSG_RESULT(no)
2495       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2496     fi
2497     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"; then
2498       dnl  Use the custom faad
2499       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2500       VLC_ADD_PLUGIN([faad])
2501       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2502       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2503     else
2504       dnl  The given libfaad wasn't built
2505       AC_MSG_RESULT(no)
2506       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2507     fi
2508   else
2509     VLC_SAVE_FLAGS
2510     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_faad}"
2511     LDFLAGS="${LDFLAGS} ${LIBS_faad}"
2512     AC_CHECK_HEADERS(faad.h,
2513       [ AC_CHECK_LIB(faad, faacDecOpen, [
2514           VLC_ADD_PLUGIN([faad])
2515           VLC_ADD_LIBS([faad],[-lfaad]) ], [
2516             AC_CHECK_LIB(faad, NeAACDecOpen, [
2517               VLC_ADD_PLUGIN([faad])
2518               VLC_ADD_LIBS([faad],[-lfaad]) ], [
2519                 AS_IF([test "${enable_faad}" = "yes"],
2520                 [ AC_MSG_ERROR([Cannot find libfaad library...]) ],
2521                 [ AC_MSG_WARN([Cannot find libfaad library...]) ]) ]) ])
2522       ] , [ AS_IF([test "${enable_faad}" = "yes"],
2523         [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ],
2524         [ AC_MSG_WARN([Cannot find development headers for libfaad...]) ]) ])
2525     VLC_RESTORE_FLAGS
2526   fi
2527 fi
2528
2529 dnl
2530 dnl twolame encoder plugin
2531 dnl
2532 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2533
2534 dnl
2535 dnl fdk-aac encoder plugin
2536 dnl
2537 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2538
2539 dnl
2540 dnl  QuickTime plugin
2541 dnl
2542 AC_ARG_ENABLE(quicktime,
2543   [  --enable-quicktime      QuickTime module (deprecated)])
2544 if test "${enable_quicktime}" = "yes"; then
2545   if test "${SYS}" = "mingw32"; then
2546     VLC_ADD_PLUGIN([quicktime])
2547   else
2548   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2549     [ VLC_ADD_PLUGIN([quicktime])
2550       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2551     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2552   fi
2553 fi
2554
2555 dnl
2556 dnl A52/AC3 decoder plugin
2557 dnl
2558 AC_ARG_ENABLE(a52,
2559   [  --enable-a52            A/52 support with liba52 (default enabled)])
2560 if test "${enable_a52}" != "no"
2561 then
2562   AC_ARG_WITH(a52,
2563     [  --with-a52=PATH         a52 headers and libraries])
2564   AC_ARG_WITH(a52-tree,
2565     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2566   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2567   then
2568     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2569     if test -z "${real_a52_tree}"
2570     then
2571       dnl  The given directory can't be found
2572       AC_MSG_RESULT(no)
2573       AC_MSG_ERROR([${with_a52_tree} directory does not exist])
2574     fi
2575     dnl  Use a custom a52dec
2576     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2577     if test -f ${real_a52_tree}/include/a52.h
2578     then
2579       AC_MSG_RESULT(yes)
2580       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2581       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2582       VLC_SAVE_FLAGS
2583       LDFLAGS="${LDFLAGS} ${LIBS_a52tofloat32}"
2584       AC_CHECK_LIB(a52, a52_free, [
2585         VLC_ADD_PLUGIN([a52tofloat32])
2586         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2587         VLC_ADD_LIBS([a52tofloat32],[-la52])
2588         ],[
2589         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2590         then
2591           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2592         else
2593           AC_MSG_ERROR([the specified tree has not been compiled])
2594         fi
2595       ])
2596     else
2597       AC_MSG_RESULT(no)
2598       AC_MSG_ERROR([the specified tree does not have a52.h])
2599     fi
2600   else
2601     if test -z "${with_a52}"
2602     then
2603       LDFLAGS_test=""
2604       CPPFLAGS_test=""
2605     else
2606       LDFLAGS_test="-L${with_a52}/lib"
2607       CPPFLAGS_test="-I${with_a52}/include"
2608     fi
2609     VLC_SAVE_FLAGS
2610     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2611     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2612     AC_CHECK_HEADERS(a52dec/a52.h, [
2613       AC_CHECK_LIB(a52, a52_free, [
2614         VLC_ADD_PLUGIN([a52tofloat32])
2615         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2616         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2617       ],[
2618         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2619         ], [$LIBM])
2620     ],[
2621       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2622     ])
2623     VLC_RESTORE_FLAGS
2624   fi
2625 fi
2626
2627 dnl
2628 dnl DTS Coherent Acoustics decoder plugin
2629 dnl
2630 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2631
2632 dnl
2633 dnl  Flac plugin
2634 dnl
2635 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2636
2637 dnl
2638 dnl  Libmpeg2 plugin
2639 dnl
2640 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2641
2642 dnl
2643 dnl  Vorbis plugin
2644 dnl
2645 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2646
2647 dnl
2648 dnl  Tremor plugin
2649 dnl
2650 AC_ARG_ENABLE(tremor,
2651   [  --enable-tremor         Tremor decoder support (default disabled)])
2652 if test "${enable_tremor}" = "yes"
2653 then
2654   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2655     VLC_ADD_PLUGIN([tremor])
2656     VLC_ADD_LIBS([tremor],[-lvorbisidec -logg])
2657    ],[])
2658 fi
2659
2660 dnl
2661 dnl  Speex plugins
2662 dnl
2663 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2664 have_speexdsp="no"
2665 AS_IF([test "${enable_speex}" != "no"], [
2666   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2667     have_speexdsp="yes"
2668   ], [
2669     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2670   ])
2671 ])
2672 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2673
2674 dnl
2675 dnl  Opus plugin
2676 dnl
2677 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus], [Opus support], [auto])
2678
2679 dnl
2680 dnl  theora decoder plugin
2681 dnl
2682 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2683
2684 dnl
2685 dnl  dirac encoder plugin
2686 dnl
2687 PKG_ENABLE_MODULES_VLC([DIRAC], [], [dirac >= 0.10.0], [dirac encoder], [auto])
2688
2689 dnl
2690 dnl  schroedinger decoder plugin (for dirac format video)
2691 dnl
2692 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2693
2694 dnl
2695 dnl  PNG decoder module
2696 dnl
2697 AC_ARG_ENABLE(png,
2698   [  --enable-png            PNG support (default enabled)])
2699 AS_IF([test "${enable_png}" != "no"], [
2700 AC_CHECK_HEADERS(png.h, [
2701   VLC_SAVE_FLAGS
2702   LDFLAGS="${LDFLAGS} -lz $LIBM"
2703   AC_CHECK_LIB(png, png_set_rows, [
2704     VLC_ADD_LIBS([png],[-lpng -lz $LIBM])
2705     VLC_ADD_PLUGIN([png])
2706   ], [], [-lz $LIBM])
2707   VLC_RESTORE_FLAGS
2708   ])
2709 ])
2710
2711 dnl
2712 dnl H264 encoder plugin (10-bit lib264)
2713 dnl
2714 AC_ARG_ENABLE(x26410b,
2715   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2716 if test "${enable_x26410b}" != "no"; then
2717 AC_ARG_WITH(x26410b-tree,
2718   [ --with-x26410b-tree=PATH      H264 10-bit encoding module with libx264 (static linking)],[],[])
2719   if test "${with_x26410b_tree}" != "no" -a -n "${with_x26410b_tree}"
2720   then
2721     real_x26410b_tree="̧`cd ${with_x26410b_tree} 2>/dev/null && pwd`"
2722     if test -z "${real_x26410b_tree}"
2723     then
2724       AC_MSG_RESULT(no)
2725       AC_MSG_ERROR([${with_x26410b_tree} directory does not exist])
2726     fi
2727     AC_MSG_CHECKING(for x264.h in ${real_x26410b_tree})
2728     if test -f ${with_x26410b_tree}/x264_config.h
2729     then
2730       AC_MSG_RESULT(yes)
2731       AC_MSG_CHECKING(for 10-bit build of x264)
2732       if grep -q "BIT_DEPTH.*10"  ${with_x26410b_tree}/x264_config.h ;then
2733         AC_MSG_RESULT(yes)
2734         VLC_ADD_PLUGIN([x26410b])
2735         VLC_ADD_CFLAGS([x26410b],[-I${with_x26410b_tree}])
2736         VLC_ADD_LIBS([x26410b],[-L${with_x26410b_tree} -lm -lpthread -lx264])
2737       else
2738         AC_MSG_RESULT(no)
2739         AC_MSG_ERROR([${with_x26410b_tree} isnt build 10-bit])
2740       fi
2741     else
2742       AC_MSG_RESULT(no)
2743       AC_MSG_ERROR([${with_x26410b_tree} doesnt have x264_config.h])
2744     fi
2745   else
2746     PKG_CHECK_MODULES(X26410B, x26410b, [
2747         VLC_ADD_PLUGIN([x26410b])
2748         VLC_ADD_LDFLAGS([x26410b],[${X26410B_LIBS}])
2749         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2750           VLC_ADD_LIBS([x26410b],[-Wl,-Bsymbolic])
2751         ])
2752         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2753         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2754           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2755         fi
2756     ], [
2757        if test "${enable_x26410b}" = "yes"; then
2758         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2759        fi
2760     ])
2761   fi
2762 fi
2763
2764
2765 dnl
2766 dnl H264 encoder plugin (using libx264)
2767 dnl
2768 AC_ARG_ENABLE(x264,
2769   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2770 if test "${enable_x264}" != "no"; then
2771   AC_ARG_WITH(x264-tree,
2772     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2773   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2774   then
2775     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2776     if test -z "${real_x264_tree}"
2777     then
2778       dnl  The given directory can't be found
2779       AC_MSG_RESULT(no)
2780       AC_MSG_ERROR([${with_x264_tree} directory does not exist])
2781     fi
2782     dnl  Use a custom libx264
2783     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2784     if test -f ${real_x264_tree}/x264.h
2785     then
2786       AC_MSG_RESULT(yes)
2787       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2788       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2789       PKG_CHECK_MODULES(X264,x264, [
2790         VLC_ADD_PLUGIN([x264])
2791         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2792         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2793         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2794           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2795         fi
2796       ],[
2797         AC_MSG_ERROR([the specified tree has not been compiled])
2798       ])
2799     else
2800       AC_MSG_RESULT(no)
2801       AC_MSG_ERROR([the specified tree does not have x264.h])
2802     fi
2803   else
2804       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2805         VLC_ADD_PLUGIN([x264])
2806         VLC_ADD_LDFLAGS([x264],[${X264_LIBS}])
2807
2808         AS_IF([test "${ac_cv_ld_bsymbolic}" != "no"], [
2809           VLC_ADD_LIBS([x264],[-Wl,-Bsymbolic])
2810         ])
2811
2812         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2813         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2814           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2815         fi
2816       ],[
2817         if test "${enable_x264}" = "yes"; then
2818             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2819           fi
2820       ])
2821   fi
2822 fi
2823
2824 dnl
2825 dnl libfluidsynth (MIDI synthetizer) plugin
2826 dnl
2827 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2828
2829 dnl
2830 dnl Teletext Modules
2831 dnl vbi decoder plugin (using libzbvi)
2832 dnl telx module
2833 dnl uncompatible
2834 dnl
2835 AC_ARG_ENABLE(zvbi,
2836   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2837                   libzvbi (default enabled)]))
2838 AC_ARG_ENABLE(telx,
2839   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2840                   zvbi) (default enabled if zvbi is absent)]))
2841
2842 AS_IF( [test "${enable_zvbi}" != "no"],[
2843     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2844         [
2845           VLC_ADD_LIBS([zvbi],[$ZVBI_LIBS])
2846           if test "${SYS}" = "mingw32"; then
2847               VLC_ADD_LIBS([zvbi],[ -lpthreadGC2])
2848           fi
2849           VLC_ADD_CFLAGS([zvbi],[$ZVBI_CFLAGS])
2850           VLC_ADD_PLUGIN([zvbi])
2851           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2852           AS_IF( [test "${enable_telx}" = "yes"],[
2853                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2854                   ])
2855         ],[
2856           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2857         ])
2858     ])
2859 AS_IF( [test "${enable_telx}" != "no" ],[
2860   VLC_ADD_PLUGIN([telx])
2861   ])
2862
2863 dnl
2864 dnl libass subtitle rendering module
2865 dnl
2866 AC_ARG_ENABLE(libass,
2867   [  --enable-libass         Subtitle support using libass (default enabled)])
2868 AS_IF( [test "${enable_libass}" != "no"], [
2869   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2870       [
2871         VLC_ADD_LIBS([libass],[$LIBASS_LIBS])
2872         VLC_ADD_CFLAGS([libass],[$LIBASS_CFLAGS])
2873         VLC_ADD_PLUGIN([libass])
2874
2875         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2876           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2877            VLC_ADD_LIBS([libass],[-lfontconfig])
2878        ])
2879       ],[
2880         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2881       ])
2882   ])
2883
2884 dnl
2885 dnl  kate decoder plugin
2886 dnl
2887 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2888
2889 dnl
2890 dnl  tiger rendering for kate decoder plugin
2891 dnl
2892 AC_ARG_ENABLE(tiger,
2893 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2894 AS_IF([test "${enable_tiger}" != "no"], [
2895   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2896       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])
2897       VLC_ADD_CFLAGS([kate],[$TIGER_CFLAGS])
2898       VLC_ADD_LIBS([kate],[$TIGER_LIBS]) ],[
2899         AS_IF([test -n "${enable_tiger}"], [
2900           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2901         ])
2902   ])
2903 ])
2904
2905
2906 dnl
2907 dnl  Video plugins
2908 dnl
2909
2910 EXTEND_HELP_STRING([Video plugins:])
2911
2912 dnl
2913 dnl  OpenGL
2914 dnl
2915 PKG_CHECK_MODULES([GL], [gl], [
2916   have_gl="yes"
2917 ], [
2918   AC_CHECK_HEADER([GL/gl.h], [
2919     have_gl="yes"
2920     GL_CFLAGS=""
2921     GL_LIBS="-lGL"
2922   ], [
2923     have_gl="no"
2924   ])
2925 ])
2926
2927 dnl OpenGL ES 2: depends on EGL 1.1
2928 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
2929 dnl OpenGL ES 1: depends on EGL 1.0
2930 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
2931
2932 AC_ARG_ENABLE(egl,
2933   [  --enable-egl            OpenGL support through EGL (default disabled)],, [
2934   enable_egl="no"
2935 ])
2936 AS_IF([test "$enable_egl" != "no"], [
2937   PKG_CHECK_MODULES([EGL], [egl], [
2938     VLC_ADD_PLUGIN([gl])
2939     VLC_ADD_PLUGIN([egl])
2940   ])
2941 ])
2942
2943 dnl
2944 dnl  Xlib
2945 dnl
2946
2947 AC_PATH_XTRA()
2948 AC_CHECK_HEADERS(X11/Xlib.h)
2949
2950 dnl
2951 dnl  X C Bindings modules
2952 dnl
2953 AC_ARG_ENABLE(xcb,
2954   [  --enable-xcb            X11 support with XCB (default enabled)],, [
2955   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
2956     enable_xcb="yes"
2957   ], [
2958     enable_xcb="no"
2959   ])
2960 ])
2961 AC_ARG_ENABLE(xvideo,
2962   [  --enable-xvideo         XVideo support (default enabled)],, [
2963     enable_xvideo="$enable_xcb"
2964 ])
2965 AC_ARG_ENABLE(glx,
2966   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
2967   enable_glx="$enable_xcb"
2968 ])
2969
2970 have_xcb="no"
2971 AS_IF([test "${enable_xcb}" != "no"], [
2972   dnl libxcb
2973   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
2974   have_xcb="yes"
2975   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
2976   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
2977
2978   AS_IF([test "${enable_xvideo}" != "no"], [
2979     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [
2980       VLC_ADD_PLUGIN([xcb_xv])
2981     ])
2982   ])
2983
2984   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [
2985     VLC_ADD_PLUGIN([panoramix])
2986     VLC_ADD_LIBS([panoramix],[${XCB_RANDR_LIBS} ${XCB_LIBS}])
2987     VLC_ADD_CFLAGS([panoramix],[${XCB_RANDR_CFLAGS} ${XCB_CFLAGS}])
2988   ], [
2989     AC_MSG_WARN([${XCB_RANDR_PKG_ERRORS}. Panoramix filter will not be supported.])
2990   ])
2991
2992   PKG_CHECK_MODULES(XPROTO, [xproto], [
2993     VLC_ADD_PLUGIN([xwd])
2994
2995     dnl xcb-utils
2996     PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [
2997       VLC_ADD_PLUGIN([globalhotkeys])
2998       VLC_ADD_CFLAGS([xcb_window], [-DHAVE_XCB_KEYSYMS])
2999     ], [
3000       AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3001     ])
3002   ], [
3003     AC_MSG_WARN([${XPROTO_PKG_ERRORS}. Hotkeys and XWD will not work.])
3004   ])
3005
3006   AS_IF([test "${enable_glx}" != "no"], [
3007     AS_IF([test "${have_gl}" != "yes"], [
3008       AC_MSG_ERROR([${GL_PKG_ERRORS}. Pass --disable-glx if you do not need OpenGL X11 support.])
3009     ])
3010     VLC_ADD_PLUGIN([xcb_glx])
3011     VLC_ADD_PLUGIN([glx])
3012     VLC_ADD_PLUGIN([gl])
3013   ])
3014 ])
3015 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3016
3017
3018 dnl
3019 dnl VDPAU needs X11 and avcodec
3020 dnl
3021 AC_ARG_ENABLE(vdpau,
3022   [AS_HELP_STRING([--enable-vdpau],
3023     [VDPAU hardware decoder support (default auto)])])
3024 have_vdpau="no"
3025 AS_IF([test "${enable_vdpau}" != "no" -a "${have_avcodec}" == "yes"], [
3026   PKG_CHECK_MODULES([VDPAU], [vdpau], [
3027     have_vdpau="yes"
3028     AS_IF([test "${no_x}" = "yes"], [
3029       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3030     ])
3031     AC_MSG_NOTICE([VDPAU acceleration activated])
3032   ], [
3033     AS_IF([test -n "${enable_vdpau}"], [
3034       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3035     ])
3036   ])
3037 ])
3038 dnl AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3039
3040 have_avcodec_vdpau="no"
3041 AS_IF([test "${have_vdpau}" = "yes"], [
3042   PKG_CHECK_EXISTS([libavutil >= 0.52.4 libavcodec >= 54.36.0], [
3043     have_avcodec_vdpau="yes"
3044   ], [
3045     AS_IF([test -n "${enable_vdpau}"], [
3046       AC_MSG_ERROR([libavutil >= 0.52.4 and libavcodec >= 54.36.0 are required for VDPAU decoding.])
3047     ], [
3048       AC_MSG_WARN([libavutil >= 0.52.4 and libavcodec >= 54.36.0 are required for VDPAU decoding.])
3049     ])
3050   ])
3051 ])
3052 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3053
3054
3055 dnl
3056 dnl  SDL module
3057 dnl
3058 AC_ARG_ENABLE(sdl,
3059   [  --enable-sdl            SDL support (default enabled)])
3060 AC_ARG_ENABLE(sdl-image,
3061   [  --enable-sdl-image      SDL image support (default enabled)])
3062 if test "${enable_sdl}" != "no"
3063 then
3064    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3065       # SDL on Darwin is heavily patched and can only run SDL_image
3066       if test "${SYS}" != "darwin"; then
3067         VLC_ADD_PLUGIN([vout_sdl])
3068       fi
3069       if test "${SYS}" != "mingw32" -a "${SYS}" != "os2"; then
3070         VLC_ADD_LIBS([vout_sdl],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3071       fi
3072       VLC_ADD_CFLAGS([vout_sdl],[${SDL_CFLAGS}])
3073       VLC_ADD_LIBS([vout_sdl],[${SDL_LIBS}])
3074
3075       # SDL_image
3076       AS_IF([ test "${enable_sdl_image}" != "no"],[
3077         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3078           VLC_ADD_PLUGIN([sdl_image])
3079           VLC_ADD_LIBS([sdl_image],[${SDL_IMAGE_LIBS}])
3080           VLC_ADD_CFLAGS([sdl_image], [${SDL_IMAGE_CFLAGS}])],
3081           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3082           ])
3083       ])
3084    ],[
3085      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3086    ])
3087 fi
3088
3089
3090 dnl
3091 dnl Mac Vout
3092 AC_ARG_ENABLE(macosx-vout,
3093   [  --enable-macosx-vout    Mac OS X video output module (default enabled on Mac OS X)])
3094 if test "x${enable_macosx_vout}" != "xno" &&
3095   (test "${SYS}" = "darwin" || test "${enable_macosx_vout}" = "yes")
3096 then
3097   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,Cocoa])
3098   VLC_ADD_LIBS([vout_macosx],[-Wl,-framework,OpenGL])
3099   VLC_ADD_PLUGIN([vout_macosx])
3100 fi
3101
3102
3103 dnl
3104 dnl  freetype module
3105 dnl
3106 AC_ARG_ENABLE(freetype,
3107   [  --enable-freetype       freetype support   (default auto)])
3108 AC_ARG_ENABLE(fribidi,
3109   [  --enable-fribidi        fribidi support    (default auto)])
3110 AC_ARG_ENABLE(fontconfig,
3111   [  --enable-fontconfig     fontconfig support (default auto)])
3112
3113 AC_ARG_WITH([default-font],
3114     AS_HELP_STRING([--with-default-font=PATH],
3115         [Path to the default font]),
3116         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3117             "$withval", [Default font])])
3118 AC_ARG_WITH([default-monospace-font],
3119     AS_HELP_STRING([--with-default-monospace-font=PATH],
3120         [Path to the default font]),
3121         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3122             "$withval", [Default monospace font])])
3123
3124 AC_ARG_WITH([default-font-family],
3125     AS_HELP_STRING([--with-default-font-family=NAME],
3126         [Path to the default font family]),
3127         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3128             "$withval", [Default font family])])
3129 AC_ARG_WITH([default-monospace-font-family],
3130     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3131         [Path to the default font family]),
3132         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3133             "$withval", [Default monospace font family])])
3134
3135 if test "${enable_freetype}" != "no"; then
3136    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3137       have_freetype=yes
3138       VLC_ADD_PLUGIN([freetype])
3139       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3140       if test "${SYS}" = "mingw32"; then
3141         VLC_ADD_LIBS([freetype],[-liconv -lz])
3142       fi
3143       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3144
3145       AC_CHECK_HEADERS(Carbon/Carbon.h,
3146                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3147
3148       dnl fontconfig support
3149       if test "${SYS}" != "mingw32"; then
3150           if test "${enable_fontconfig}" != "no"; then
3151             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3152               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3153               VLC_ADD_LIBS([freetype],[-lfontconfig])
3154             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3155           fi
3156       else
3157           VLC_ADD_LIBS([freetype],[-lgdi32])
3158       fi
3159
3160       dnl fribidi support
3161       if test "${enable_fribidi}" != "no"; then
3162         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3163           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3164           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3165         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3166       fi
3167
3168   ],[
3169   have_freetype=no
3170   AS_IF([test -n "${enable_freetype}"],[
3171     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3172     ])
3173   ])
3174 fi
3175
3176
3177 dnl
3178 dnl  QuartzText vout module (iOS/Mac OS)
3179 dnl
3180 AC_ARG_ENABLE(macosx-quartztext,
3181   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3182 if test "x${enable_macosx_quartztext}" != "xno" &&
3183   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3184 then
3185   VLC_ADD_PLUGIN([quartztext])
3186   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3187 fi
3188
3189 dnl
3190 dnl  SVG module
3191 dnl
3192 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3193
3194 dnl
3195 dnl  android surface module
3196 dnl
3197 AC_ARG_ENABLE(android-surface,
3198   [  --enable-android-surface   Android Surface video output module (default disabled)])
3199 if test "${enable_android_surface}" = "yes"; then
3200   if test "${HAVE_ANDROID}" = "1"; then
3201      VLC_ADD_PLUGIN([android_surface])
3202      VLC_ADD_LDFLAGS([android_surface], [-ldl])
3203   fi
3204 fi
3205
3206
3207 dnl
3208 dnl  iOS vout module
3209 dnl
3210 AC_ARG_ENABLE(ios-vout,
3211   [  --enable-ios-vout    iOS video output module (default disabled)])
3212 if test "${enable_ios_vout}" = "yes"
3213 then
3214   VLC_ADD_PLUGIN([vout_ios])
3215   VLC_ADD_LIBS([vout_ios], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit,-framework,Foundation])
3216 fi
3217
3218 dnl
3219 dnl  iOS ES2 vout module
3220 dnl
3221 AC_ARG_ENABLE(ios-vout2,
3222   [  --enable-ios-vout2    iOS video output module (default disabled)])
3223 if test "${enable_ios_vout2}" = "yes"
3224 then
3225   VLC_ADD_PLUGIN([vout_ios2])
3226   VLC_ADD_LIBS([vout_ios2], [-Wl,-framework,OpenGLES,-framework,QuartzCore,-framework,UIKit])
3227 fi
3228
3229
3230 dnl
3231 dnl  Windows DirectX module
3232 dnl
3233
3234 if test "${SYS}" = "mingw32"
3235 then
3236   VLC_ADD_PLUGIN([panoramix])
3237 fi
3238
3239 AC_ARG_ENABLE(directx,
3240   [AS_HELP_STRING([--enable-directx],
3241     [Microsoft DirectX support (default enabled on Windows)])],, [
3242   AS_IF([test "${SYS}" = "mingw32"], [
3243     enable_directx="yes"
3244   ], [
3245     enable_directx="no"
3246   ])
3247 ])
3248 have_directx="no"
3249 AS_IF([test "${enable_directx}" != "no"], [
3250   dnl DirectDraw
3251   AC_CHECK_HEADERS(ddraw.h, [
3252     have_directx="yes"
3253   ], [
3254     AC_MSG_ERROR([Cannot find DirectX headers!])
3255   ])
3256
3257   dnl OpenGL
3258   AC_CHECK_HEADERS(GL/wglew.h, [
3259     VLC_ADD_PLUGIN([glwin32])
3260   ],, [
3261     #include <windows.h>
3262     #include <GL/gl.h>
3263   ])
3264
3265   dnl Direct3D
3266   AC_CHECK_HEADERS(d3d9.h, [
3267     VLC_ADD_PLUGIN([direct3d])
3268   ])
3269
3270   dnl Direct2D
3271   AC_CHECK_HEADERS(d2d1.h, [
3272     VLC_ADD_PLUGIN([direct2d])
3273   ])
3274 ])
3275 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3276
3277 dnl
3278 dnl  Linux framebuffer module
3279 dnl
3280 AC_CHECK_HEADER([linux/fb.h], [
3281   VLC_ADD_PLUGIN([fb])
3282 ])
3283
3284
3285 dnl
3286 dnl  DirectFB module
3287 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3288 dnl  TODO: support for static linking
3289 dnl
3290 AC_ARG_ENABLE(directfb,
3291   [  --enable-directfb       DirectFB support (default disabled)])
3292 AC_ARG_WITH(directfb,
3293   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3294
3295 if test "${enable_directfb}" = "yes"; then
3296     have_directfb="false"
3297     CPPFLAGS_mydirectfb=
3298     LIBS_mydirectfb=
3299     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3300         dnl Trying the given location
3301         VLC_SAVE_FLAGS
3302
3303         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3304         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3305
3306         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3307         LIBS="${LIBS} ${LIBS_new}"
3308
3309         dnl FIXME: too obscure
3310         AC_CHECK_HEADER([directfb.h], [
3311             AC_CHECK_LIB([direct],[direct_initialize], [
3312                 AC_CHECK_LIB([fusion], [fusion_enter], [
3313                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3314                 ], have_directfb="false")
3315             ], have_directfb="false")
3316         ], have_directfb="false")
3317
3318         VLC_RESTORE_FLAGS
3319
3320         if test "${have_directfb}" = "true"; then
3321             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3322             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3323         fi
3324     else
3325         dnl Look for directfb-config
3326         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3327         if test "${DIRECTFB_CONFIG}" != "no"; then
3328             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3329             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3330             have_directfb="true"
3331         else
3332             dnl Trying with pkg-config
3333             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3334                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3335                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3336                 have_directfb="true"
3337                 ], [have_directfb="false"])
3338         fi
3339     fi
3340     if test "${have_directfb}" = "true"; then
3341         VLC_ADD_PLUGIN([directfb])
3342         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3343         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3344     else
3345         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3346     fi
3347 fi
3348
3349 dnl
3350 dnl  AA plugin
3351 dnl
3352 AC_ARG_ENABLE(aa,
3353   [  --enable-aa             aalib output (default disabled)])
3354 if test "${enable_aa}" = "yes"
3355 then
3356   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3357   if test "${have_aa}" = "true"
3358   then
3359     VLC_ADD_PLUGIN([aa])
3360     VLC_ADD_LIBS([aa],[-laa])
3361     if test "${SYS}" != "mingw32"; then
3362       VLC_ADD_LIBS([aa],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3363     fi
3364   fi
3365 fi
3366
3367 dnl
3368 dnl  libcaca plugin
3369 dnl
3370 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3371
3372 dnl
3373 dnl  OS/2 KVA plugin
3374 dnl
3375 AC_ARG_ENABLE(kva,
3376   [AS_HELP_STRING([--enable-kva],
3377     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3378   AS_IF([test "$SYS" = "os2"], [
3379     enable_kva="yes"
3380   ])
3381 ])
3382 have_kva="no"
3383 KVA_LIBS=""
3384 AS_IF([test "$enable_kva" != "no"], [
3385   AC_CHECK_HEADERS([kva.h], [
3386     have_kva="yes"
3387     AC_CHECK_LIB(kva, main, [
3388       KVA_LIBS="-lkva"
3389     ])
3390   ])
3391 ])
3392 AC_SUBST(KVA_LIBS)
3393 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3394
3395 dnl
3396 dnl  Audio plugins
3397 dnl
3398
3399 EXTEND_HELP_STRING([Audio plugins:])
3400
3401 dnl
3402 dnl  Pulseaudio module
3403 dnl
3404 AC_ARG_ENABLE(pulse,
3405   [AS_HELP_STRING([--enable-pulse],
3406     [use the PulseAudio client library (default auto)])])
3407 have_pulse="no"
3408 AS_IF([test "${enable_pulse}" != "no"], [
3409   PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.22], [
3410     have_pulse="yes"
3411   ], [
3412     PKG_CHECK_MODULES([PULSE], [libpulse >= 0.9.16], [
3413       AS_IF([test "${no_x}" != "yes"], [
3414         have_pulse="yes"
3415         PULSE_LIBS="$PULSE_LIBS ${X_LIBS} ${X_PRE_LIBS} -lX11"
3416       ], [
3417         AS_IF([test "${enable_pulse}" = "yes"], [
3418           AC_MSG_ERROR([Xlib is required with PulseAudio pre-0.9.22 versions
3419 (see http://www.pulseaudio.org/ticket/799 for further reference).])
3420         ])
3421       ])
3422     ], [
3423       AS_IF([test "x${enable_pulse}" != "x"], [
3424         AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 0.9.22 or later required.])
3425       ])
3426     ])
3427   ])
3428 ])
3429 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3430
3431 dnl
3432 dnl  ALSA module
3433 dnl
3434 AC_ARG_ENABLE(alsa,
3435   [AS_HELP_STRING([--enable-alsa],
3436     [support the Advanced Linux Sound Architecture (default auto)])],, [
3437   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3438     enable_alsa="yes"
3439   ])
3440 ])
3441 have_alsa="no"
3442 AS_IF([test "${enable_alsa}" != "no"], [
3443   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3444     have_alsa="yes"
3445   ], [
3446     AS_IF([test "x${enable_alsa}" != "x"], [
3447       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3448     ])
3449   ])
3450 ])
3451 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3452
3453 dnl
3454 dnl  Open Sound System module
3455 dnl
3456 AC_ARG_ENABLE(oss,
3457   [AS_HELP_STRING([--enable-oss],
3458     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3459   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3460     enable_oss="no"
3461   ])
3462 ])
3463 have_oss="no"
3464 OSS_LIBS=""
3465 AS_IF([test "$enable_oss" != "no"], [
3466   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3467     have_oss="yes"
3468     AC_CHECK_LIB(ossaudio, main, [
3469       OSS_LIBS="-lossaudio"
3470     ])
3471   ])
3472 ])
3473 AC_SUBST(OSS_LIBS)
3474 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3475
3476 dnl
3477 dnl  OpenBSD sndio module
3478 dnl
3479 AC_ARG_ENABLE([sndio],
3480   [AS_HELP_STRING([--disable-sndio],
3481     [support the OpenBSD sndio (default auto)])],, [
3482   AS_IF([test "$SYS" = "openbsd"], [
3483     enable_sndio="yes"
3484   ])
3485 ])
3486 have_sndio="no"
3487 AS_IF([test "$enable_sndio" != "no"], [
3488   AC_CHECK_HEADER([sndio.h], [
3489     have_sndio="yes"
3490   ])
3491 ])
3492 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3493
3494 dnl
3495 dnl  Windows Audio Session plugin
3496 dnl
3497 AC_ARG_ENABLE([wasapi],
3498   [AS_HELP_STRING([--enable-wasapi],
3499     [use the Windows Audio Session API (default auto)])
3500 ])
3501 have_wasapi="no"
3502 AS_IF([test "$enable_wasapi" != "no"], [
3503   AC_CHECK_HEADER([audioclient.h], [
3504     have_wasapi="yes"
3505   ], [
3506     AS_IF([test "x${enable_wasapi}" != "x"], [
3507       AC_MSG_ERROR([Windows Audio Session API not found.])
3508     ])
3509   ])
3510 ])
3511 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3512
3513 dnl
3514 dnl  win32 waveOut plugin
3515 dnl
3516 AC_ARG_ENABLE(waveout,
3517   [  --enable-waveout        Win32 waveOut module (default enabled on Win32)])
3518 if test "${enable_waveout}" != "no"; then
3519   if test "${SYS}" = "mingw32"; then
3520     VLC_ADD_PLUGIN([waveout])
3521     VLC_ADD_LIBS([waveout],[-lwinmm])
3522   fi
3523 fi
3524
3525 dnl
3526 dnl  CoreAudio plugin
3527 dnl
3528 AC_ARG_ENABLE(macosx-audio,
3529   [  --enable-macosx-audio   Mac OS X audio module (default enabled on MacOS X)])
3530 if test "x${enable_macosx_audio}" != "xno" &&
3531   (test "${SYS}" = "darwin" || test "${enable_macosx_audio}" = "yes")
3532 then
3533   AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,
3534     [ VLC_ADD_PLUGIN([auhal])
3535       VLC_ADD_LIBS([auhal],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,CoreServices])
3536     ], [ AC_MSG_ERROR([cannot find CoreAudio headers]) ])
3537 fi
3538
3539 dnl
3540 dnl  iOS CoreAudio plugin
3541 dnl
3542 AC_ARG_ENABLE(ios-audio,
3543   [  --enable-ios-audio       Audio module for iOS (default disabled)])
3544 if test "${enable_ios_audio}" = "yes"
3545 then
3546   AC_CHECK_HEADERS(AudioUnit/AudioUnit.h,
3547     [ VLC_ADD_PLUGIN([audiounit_ios])
3548       VLC_ADD_LIBS([audiounit_ios],[-Wl,-framework,CoreAudio,-framework,AudioUnit,-framework,AudioToolbox,-framework,CoreServices])
3549     ], [ AC_MSG_ERROR([cannot find AudioUnit headers]) ])
3550 fi
3551
3552 dnl
3553 dnl  AudioQueue plugin
3554 dnl
3555 AC_ARG_ENABLE(audioqueue,
3556   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3557 if test "${enable_audioqueue}" = "yes"
3558 then
3559   VLC_ADD_PLUGIN([audioqueue])
3560   VLC_ADD_LIBS([audioqueue], [-Wl,-framework,AudioToolbox,-framework,CoreFoundation])
3561 fi
3562
3563 dnl
3564 dnl  JACK modules
3565 dnl
3566 PKG_ENABLE_MODULES_VLC([JACK], [jack access_jack], [jack], [JACK audio I/O modules],[auto])
3567
3568 dnl
3569 dnl  OpenSLES Android
3570 dnl
3571 AC_ARG_ENABLE(opensles,
3572   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3573 if test "${HAVE_ANDROID}" = "1"; then
3574   if test "${enable_opensles}" = "yes"; then
3575       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3576         [ VLC_ADD_PLUGIN([opensles_android]) ],
3577         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3578   fi
3579 fi
3580
3581 dnl
3582 dnl libsamplerate plugin
3583 dnl
3584 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3585
3586 dnl
3587 dnl  OS/2 KAI plugin
3588 dnl
3589 AC_ARG_ENABLE(kai,
3590   [AS_HELP_STRING([--enable-kai],
3591     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3592   AS_IF([test "$SYS" = "os2"], [
3593     enable_kai="yes"
3594   ])
3595 ])
3596 have_kai="no"
3597 KAI_LIBS=""
3598 AS_IF([test "$enable_kai" != "no"], [
3599   AC_CHECK_HEADERS([kai.h], [
3600     have_kai="yes"
3601     AC_CHECK_LIB(kai, main, [
3602       KAI_LIBS="-lkai"
3603     ])
3604   ])
3605 ])
3606 AC_SUBST(KAI_LIBS)
3607 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3608
3609 dnl
3610 dnl  chromaprint audio track fingerprinter
3611 dnl
3612 m4_pushdef([libchromaprint_version], 0.6.0)
3613 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3614     VLC_ADD_PLUGIN([stream_out_chromaprint fingerprinter])
3615     VLC_ADD_CFLAGS([stream_out_chromaprint],[${CHROMAPRINT_CFLAGS}] [-I./webservices -I../stream_out])
3616     VLC_ADD_LIBS([stream_out_chromaprint],[${CHROMAPRINT_LIBS}])
3617     VLC_ADD_LIBS([fingerprinter],[-lm]),
3618     AS_IF([test "${enable_chromaprint}" = "yes"],
3619         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3620         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3621          ),
3622     [(Chromaprint based audio fingerprinter)],[auto])
3623 m4_popdef([libchromaprint_version])
3624
3625 dnl
3626 dnl  Interface plugins
3627 dnl
3628
3629 EXTEND_HELP_STRING([Interface plugins:])
3630
3631 dnl
3632 dnl QT
3633 dnl
3634 AC_ARG_ENABLE(qt, [
3635   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3636   AS_IF([test "${SYS}" = "darwin"], [
3637     enable_qt="no"
3638   ])
3639 ])
3640 AS_IF([test "${enable_qt}" != "no"], [
3641   PKG_CHECK_MODULES([QT], [QtCore >= 5 QtWidgets QtGui],, [
3642     PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3643       AS_IF([test -n "${enable_qt}"],[
3644         AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3645       ],[
3646         AC_MSG_WARN([${QT_PKG_ERRORS}.])
3647       ])
3648       enable_qt="no"
3649     ])
3650   ])
3651 ])
3652 AS_IF([test "${enable_qt}" != "no"], [
3653   VLC_ADD_PLUGIN([qt4])
3654   VLC_ADD_LIBS([qt4],[${QT_LIBS}])
3655   VLC_ADD_CXXFLAGS([qt4],[${QT_CFLAGS}])
3656   ALIASES="${ALIASES} qvlc"
3657
3658   AC_LANG_PUSH([C++])
3659   VLC_SAVE_FLAGS
3660
3661   AC_MSG_CHECKING([whether Qt uses Xlib])
3662   CPPFLAGS="${CPPFLAGS} ${QT_CFLAGS}"
3663   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
3664 #include <QWidget>
3665 #if !defined (Q_WS_X11)
3666 # error Fail
3667 #endif
3668   ])], [
3669     AC_MSG_RESULT([yes])
3670     VLC_ADD_LIBS([qt4],[${X_LIBS} ${X_PRE_LIBS} -lX11])
3671     VLC_ADD_CXXFLAGS([qt4],[${X_CFLAGS}])
3672   ], [
3673     AC_MSG_RESULT([no])
3674   ])
3675
3676   VLC_RESTORE_FLAGS
3677   AC_LANG_POP([C++])
3678
3679   AS_IF([test "${SYS}" = "mingw32"], [
3680       VLC_ADD_LIBS([qt4],[-lole32])
3681   ])
3682   AS_IF([test "${SYS}" = "darwin" ],[
3683        VLC_ADD_LIBS([qt4], [-Wl,-framework,Cocoa])
3684   ])
3685
3686   QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3687   AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3688   AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3689   AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3690 ])
3691 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3692
3693 dnl
3694 dnl Simple test for skins2 dependency
3695 dnl
3696 AS_IF([test "$enable_qt" = "no"], [
3697   AS_IF([test "${enable_skins2}" = "yes"], [
3698     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3699   ], [
3700     enable_skins2="no"
3701     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3702   ])
3703 ])
3704
3705 dnl
3706 dnl Skins2 module
3707 dnl
3708 AC_ARG_ENABLE(skins2,
3709   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3710 AS_IF([test "${enable_skins2}" != "no"], [
3711   have_skins_deps="yes"
3712
3713   dnl Win32
3714   AS_IF([test "${SYS}" = "mingw32"], [
3715     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3716     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3717   dnl MacOS
3718   ], [test "${SYS}" = "darwin"], [
3719     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3720     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3721   dnl Linux/Unix
3722   ], [
3723     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3724     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3725     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3726     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3727     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3728   ])
3729
3730   dnl for All OSes
3731   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3732
3733   dnl we need freetype
3734   AS_IF([test "${have_freetype}" != "yes"], [
3735     have_skins_deps="no"
3736   ])
3737
3738   AS_IF([test "${have_skins_deps}" = "no"], [
3739     AS_IF([test "x${enable_skins2}" = "x"], [
3740       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3741     ], [
3742       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3743     ])
3744     enable_skins2="no"
3745   ], [
3746     VLC_ADD_PLUGIN([skins2])
3747     ALIASES="${ALIASES} svlc"
3748     enable_skins2="yes"
3749   ])
3750 ])
3751 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3752
3753 AC_ARG_ENABLE(libtar,
3754   [  --enable-libtar         libtar support for skins2 (default auto)])
3755 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3756   AC_CHECK_HEADERS(libtar.h, [
3757     VLC_ADD_LIBS([skins2],[-ltar])
3758   ])
3759 ])
3760
3761 dnl
3762 dnl  MacOS X gui module
3763 dnl
3764 AC_ARG_ENABLE(macosx,
3765   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3766 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3767 then
3768   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,Carbon -Wl,-framework,CoreServices])
3769   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3770   VLC_ADD_PLUGIN([macosx])
3771
3772   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration -Wl,-framework,ScriptingBridge])
3773
3774   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3775   then
3776     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3777   fi
3778   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3779   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3780
3781   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3782   then
3783     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3784   fi
3785   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3786   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3787 fi
3788 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3789
3790 dnl
3791 dnl  Minimal Mac OS X module
3792 dnl
3793 AC_ARG_ENABLE(minimal-macosx,
3794   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3795 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3796 then
3797   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3798   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3799   VLC_ADD_PLUGIN([minimal_macosx])
3800 fi
3801 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3802
3803 dnl
3804 dnl  MacOS X dialog provider
3805 dnl
3806 AC_ARG_ENABLE(macosx-dialog-provider,
3807   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3808 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3809   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3810 then
3811   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3812   VLC_ADD_PLUGIN([macosx_dialog_provider])
3813 fi
3814 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3815
3816 dnl
3817 dnl  ncurses module
3818 dnl
3819 AC_ARG_ENABLE(ncurses,
3820 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3821 AS_IF([test "${enable_ncurses}" != "no"] ,[
3822   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3823     VLC_ADD_PLUGIN([ncurses])
3824     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3825     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS}])
3826     ALIASES="${ALIASES} nvlc"
3827   ], [
3828     AS_IF([test -n "${enable_ncurses}"], [
3829       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3830     ])
3831   ])
3832 ])
3833
3834 dnl
3835 dnl  Lirc plugin
3836 dnl
3837 AC_ARG_ENABLE(lirc,
3838   [  --enable-lirc           lirc support (default disabled)])
3839 if test "${enable_lirc}" = "yes"
3840 then
3841   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3842   if test "${have_lirc}" = "true"
3843   then
3844     VLC_ADD_PLUGIN([lirc])
3845     VLC_ADD_LIBS([lirc],[-llirc_client])
3846   fi
3847 fi
3848
3849 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3850 dnl
3851 dnl  goom visualization plugin
3852 dnl
3853 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3854
3855 dnl
3856 dnl libprojectM visualization plugin
3857 dnl
3858 AC_ARG_ENABLE(projectm,
3859   [  --enable-projectm       projectM visualization plugin (default enabled)])
3860 AS_IF([test "${enable_projectm}" != "no"],
3861   [
3862     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3863     [
3864       VLC_ADD_PLUGIN([projectm])
3865       VLC_ADD_CXXFLAGS([projectm],[$PROJECTM_CFLAGS])
3866       VLC_ADD_LIBS([projectm],[$PROJECTM_LIBS])
3867       PKG_CHECK_MODULES(PROJECTM2, [libprojectM >= 2.0.0],
3868         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3869         [ AC_MSG_WARN( [Using libprojectM version 1] )
3870       ])
3871     ],[
3872       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3873     ])
3874   ])
3875
3876 dnl
3877 dnl Vovoid VSXu visualization plugin
3878 dnl
3879 AC_ARG_ENABLE(vsxu,
3880   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3881 AS_IF([test "${enable_vsxu}" != "no"],
3882   [
3883     PKG_CHECK_MODULES(VSXU, libvsxu,
3884     [
3885       VLC_ADD_PLUGIN([vsxu])
3886       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
3887       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
3888     ],[
3889       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3890     ])
3891   ])
3892
3893 dnl
3894 dnl  AtmoLight (homemade Philips Ambilight clone)
3895 dnl
3896 AC_ARG_ENABLE(atmo,
3897 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
3898                 (default enabled)]),, [enable_atmo="yes"])
3899 AS_IF([test "${enable_atmo}" != no], [
3900   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
3901     AC_LANG_PUSH(C++)
3902     VLC_ADD_PLUGIN([atmo])
3903     AC_LANG_POP(C++)
3904   ])
3905 ])
3906
3907
3908 EXTEND_HELP_STRING([Service Discovery plugins:])
3909 dnl
3910 dnl  Bonjour services discovery
3911 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
3912
3913 dnl
3914 dnl  libudev services discovery
3915 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
3916
3917 dnl
3918 dnl MTP devices services discovery
3919 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
3920
3921 dnl
3922 dnl UPnP Plugin (Intel SDK)
3923 dnl
3924 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
3925 VLC_ADD_CXXFLAGS([upnp],[${UPNP_CFLAGS}])
3926
3927 EXTEND_HELP_STRING([Misc options:])
3928
3929 dnl
3930 dnl  libxml2 module
3931 dnl
3932 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
3933
3934
3935 dnl
3936 dnl libgcrypt
3937 dnl
3938 AC_ARG_ENABLE(libgcrypt,
3939   [  --disable-libgcrypt     gcrypt support (default enabled)])
3940 AS_IF([test "${enable_libgcrypt}" != "no"], [
3941   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
3942     libgcrypt-config --version >/dev/null || \
3943         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
3944     AC_CHECK_LIB(gcrypt, gcry_control, [
3945       have_libgcrypt="yes"
3946       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
3947       GCRYPT_LIBS="`libgcrypt-config --libs`"
3948     ], [
3949       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3950     ], [`libgcrypt-config --libs`])
3951   ], [
3952     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or use --disable-libgcrypt. Have a nice day.])
3953   ], [#include <gcrypt.h>]
3954   )
3955 ])
3956
3957 AC_SUBST(GCRYPT_CFLAGS)
3958 AC_SUBST(GCRYPT_LIBS)
3959 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
3960
3961 dnl
3962 dnl TLS/SSL
3963 dnl
3964 AC_ARG_ENABLE(gnutls,
3965   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
3966 AS_IF([test "${enable_gnutls}" != "no"], [
3967   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.0.20], [
3968     VLC_ADD_PLUGIN([gnutls])
3969   ], [
3970     AS_IF([test -n "${enable_gnutls}"], [
3971       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
3972     ])
3973   ])
3974 ])
3975
3976
3977 dnl
3978 dnl Taglib plugin
3979 dnl
3980 AC_ARG_ENABLE(taglib,
3981   [AS_HELP_STRING([--disable-taglib],
3982     [do not use TagLib (default enabled)])])
3983 AS_IF([test "${enable_taglib}" != "no"], [
3984   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.6.1, [
3985     VLC_ADD_PLUGIN([taglib])
3986     VLC_ADD_LIBS([taglib],[$TAGLIB_LIBS -lz])
3987     VLC_ADD_CXXFLAGS([taglib],[$TAGLIB_CFLAGS])
3988   ], [
3989     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
3990 ])
3991
3992
3993 dnl
3994 dnl update checking system
3995 dnl
3996 AC_ARG_ENABLE(update-check,
3997   [  --enable-update-check   update checking system (default disabled)])
3998 if test "${enable_update_check}" = "yes"
3999 then
4000   if test "${have_libgcrypt}" != "yes"
4001   then
4002     AC_MSG_ERROR([libgcrypt is required for update checking system])
4003   fi
4004   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4005   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4006   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4007 fi
4008
4009 dnl
4010 dnl Growl notification plugin
4011 dnl
4012 AC_ARG_ENABLE(growl,
4013   [  --enable-growl          growl notification plugin (default disabled)],,
4014   [enable_growl=no])
4015 AS_IF([test "${enable_growl}" != "no"], [
4016     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4017       VLC_ADD_PLUGIN([growl])
4018       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4019       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4020       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4021     ])
4022   ]
4023 )
4024
4025 dnl
4026 dnl Libnotify notification plugin
4027 dnl
4028 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4029
4030 dnl
4031 dnl  Endianness check
4032 dnl
4033 AC_C_BIGENDIAN
4034 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4035   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4036 ], [
4037   DEFS_BIGENDIAN=""
4038 ])
4039 AC_SUBST(DEFS_BIGENDIAN)
4040
4041 dnl
4042 dnl Where to install KDE solid .desktop
4043 dnl
4044 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
4045 AS_IF([test "x$KDE4_CONFIG" = "x"], [
4046   KDE4_CONFIG="kde4-config"
4047 ])
4048
4049 AC_ARG_WITH(kde-solid,
4050   AS_HELP_STRING([--with-kde-solid=PATH],
4051                  [KDE Solid actions directory (auto)]),, [
4052
4053 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4054   with_kde_solid="yes"
4055 fi
4056 ])
4057 soliddatadir=""
4058 AS_IF([test "${with_kde_solid}" != "no"], [
4059   AS_IF([test "${with_kde_solid}" = "yes"], [
4060     kde4datadir="`${KDE4_CONFIG} --install data`"
4061     AS_IF([test "x$kde4datadir" = "x"], [kde4datadir='${datadir}/kde4/apps'])
4062     soliddatadir="${kde4datadir}/solid/actions"
4063   ], [
4064     soliddatadir="${with_kde_solid}"
4065   ])
4066 ])
4067 AC_SUBST(soliddatadir)
4068 AM_CONDITIONAL(KDE_SOLID, [test "x${soliddatadir}" != "x"])
4069
4070 dnl
4071 dnl  DMO codec
4072 AS_IF([test "${SYS}" = "mingw32"], [VLC_ADD_PLUGIN([dmo]) VLC_ADD_LIBS([dmo],[-lole32 -luuid]) ])
4073
4074 EXTEND_HELP_STRING([Components:])
4075
4076 dnl
4077 dnl  the VLC binary
4078 dnl
4079 AC_ARG_ENABLE(vlc,
4080   [  --enable-vlc            build the VLC media player (default enabled)])
4081 AM_CONDITIONAL(BUILD_VLC, [test "${enable_vlc}" != "no"])
4082
4083 AC_ARG_ENABLE(macosx-vlc-app,
4084   [  --enable-macosx-vlc-app build the VLC media player (default enabled on Mac OS X)])
4085 AM_CONDITIONAL(BUILD_MACOSX_VLC_APP, [test "${enable_macosx_vlc_app}" != "no" &&
4086     (test "${SYS}" = "darwin" || test "${enable_macosx_vlc_app}" = "yes") ])
4087
4088 dnl
4089 dnl  Stuff used by the program
4090 dnl
4091 VERSION_MESSAGE="${VERSION} ${CODENAME}"
4092 COPYRIGHT_MESSAGE="Copyright © ${COPYRIGHT_YEARS} the VideoLAN team"
4093 AC_DEFINE_UNQUOTED(VERSION_MESSAGE, "${VERSION_MESSAGE}", [Simple version string])
4094 AC_DEFINE_UNQUOTED(COPYRIGHT_MESSAGE, "${COPYRIGHT_MESSAGE}", [Copyright string])
4095 AC_DEFINE_UNQUOTED(COPYRIGHT_YEARS, "${COPYRIGHT_YEARS}", [The copyright years])
4096 AC_DEFINE_UNQUOTED(CONFIGURE_LINE, "${CONFIGURE_LINE}", [The ./configure command line])
4097 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MAJOR,${VERSION_MAJOR}, [version major number])
4098 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_MINOR,${VERSION_MINOR}, [version minor number])
4099 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_REVISION,${VERSION_REVISION}, [version revision number])
4100 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_EXTRA,${VERSION_EXTRA}, [version extra number])
4101 AC_DEFINE_UNQUOTED(PACKAGE_VERSION_DEV,"${VERSION_DEV}", [version development string])
4102 AC_SUBST(COPYRIGHT_MESSAGE)
4103 AC_SUBST(VERSION_MESSAGE)
4104 AC_SUBST(VERSION_MAJOR)
4105 AC_SUBST(VERSION_MINOR)
4106 AC_SUBST(VERSION_REVISION)
4107 AC_SUBST(VERSION_EXTRA)
4108 AC_SUBST(COPYRIGHT_YEARS)
4109 AC_DEFINE_UNQUOTED(VLC_COMPILE_BY, "`whoami|sed -e 's/\\\/\\\\\\\/g'`", [user who ran configure])
4110 AC_DEFINE_UNQUOTED(VLC_COMPILE_HOST, "`hostname -f 2>/dev/null || hostname`", [host which ran configure])
4111 AC_DEFINE_UNQUOTED(VLC_COMPILER, "`$CC -v 2>&1 | tail -n 1 | sed -e 's/ *$//'`", [compiler])
4112 dnl
4113 dnl  Handle substvars that use $(top_srcdir)
4114 dnl
4115 CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include ${CPPFLAGS}"
4116
4117 dnl
4118 dnl  Configuration is finished
4119 dnl
4120 AC_SUBST(SYS)
4121 AC_SUBST(ARCH)
4122 AC_SUBST(ALIASES)
4123 AC_SUBST(ASM)
4124 AC_SUBST(MOC)
4125 AC_SUBST(RCC)
4126 AC_SUBST(UIC)
4127 AC_SUBST(WINDRES)
4128 AC_SUBST(WINE_SDK_PATH)
4129 AC_SUBST(LIBEXT)
4130 AC_SUBST(AM_CPPFLAGS)
4131 AC_SUBST(MACOSX_DEPLOYMENT_TARGET)
4132 AC_SUBST(FILE_LIBVLCCORE_DLL)
4133 AC_SUBST(FILE_LIBVLC_DLL)
4134
4135 AC_CONFIG_FILES([
4136   Makefile
4137   doc/Makefile
4138   modules/Makefile
4139   m4/Makefile
4140   po/Makefile.in
4141   share/Makefile
4142   compat/Makefile
4143   src/Makefile
4144   lib/Makefile
4145   bin/Makefile
4146   test/Makefile
4147   modules/access/Makefile
4148   modules/access/rtp/Makefile
4149   modules/access_output/Makefile
4150   modules/audio_filter/Makefile
4151   modules/audio_mixer/Makefile
4152   modules/audio_output/Makefile
4153   modules/codec/Makefile
4154   modules/control/Makefile
4155   modules/demux/Makefile
4156   modules/gui/Makefile
4157   modules/gui/macosx/Makefile
4158   modules/gui/minimal_macosx/Makefile
4159   modules/gui/macosx_dialog_provider/Makefile