Configure: use AC_PATH_PROG for yasm detection
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 2002-2014 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2014"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 # Disable with "./configure --disable-silent-rules" or "make V=1"
31 AM_SILENT_RULES([yes])
32
33 dnl Too many people are not aware of maintainer mode:
34 dnl If you want to use it, you definitely know what you are doing, so
35 dnl you can specify "--disable-maintainer-mode". But if you want the default
36 dnl automake behavior, you've likely never heard of maintainer mode, so we
37 dnl can't expect you to enable it manually.
38 AS_IF([test "x${enable_maintainer_mode}" != "xno"],
39     [enable_maintainer_mode="yes"])
40 AM_MAINTAINER_MODE
41
42 dnl
43 dnl Directories
44 dnl
45 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
46 dnl AC_SUBST(vlcincludedir)
47 vlcdatadir="\${datadir}/\${PKGDIR}"
48 AC_SUBST(vlcdatadir)
49 vlclibdir="\${libdir}/\${PKGDIR}"
50 AC_SUBST(vlclibdir)
51
52 dnl
53 dnl Check for tools
54 dnl
55 AC_PROG_CC_C99
56 AC_USE_SYSTEM_EXTENSIONS
57 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
58 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
59 AH_TOP([
60 #ifndef _REENTRANT
61 # define _REENTRANT
62 #endif
63 ])
64 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
65 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
66 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
67
68 AM_PROG_CC_C_O
69 AC_PROG_CXX
70 AC_PROG_CPP
71 AC_PROG_OBJC
72 _AM_DEPENDENCIES([OBJC])
73 AC_PROG_EGREP
74 AC_PROG_MAKE_SET
75 AC_PROG_INSTALL
76 AM_PROG_AS
77
78 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
79 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
80 AC_PATH_PROG(YASM, yasm)
81
82 dnl Check for compiler properties
83 AC_C_CONST
84 AC_C_INLINE
85 AC_C_RESTRICT
86
87 dnl Extend the --help string at the current spot.
88 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
89
90 dnl Allow binary package maintainer to pass a custom string to avoid
91 dnl cache problem
92 AC_ARG_WITH(binary-version,
93     AS_HELP_STRING([--with-binary-version=STRING],
94          [To avoid plugins cache problem between binary version]),[],[])
95 AS_IF([test -n "${with_binary_version}"],[
96     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
97          [Binary specific version])
98 ])
99
100 dnl
101 dnl  Check the operating system
102 dnl
103 HAVE_WIN64="0"
104 HAVE_IOS="0"
105 HAVE_OSX="0"
106
107 YASMFLAGS=""
108 case "${host}" in
109     i?86*)
110     YASMFLAGS="-f elf32"
111         ;;
112     x86_64*)
113     YASMFLAGS="-f elf64"
114         ;;
115 esac
116
117
118 case "${host_os}" in
119   "")
120     SYS=unknown
121     ;;
122   linux*)
123     SYS=linux
124     ;;
125   bsdi*)
126     SYS=bsdi
127     CFLAGS="${CFLAGS} -pthread"
128     ;;
129   freebsd*)
130     SYS=freebsd
131     CFLAGS="${CFLAGS} -pthread"
132     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
133     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
134     ;;
135   openbsd*)
136     SYS=openbsd
137     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
138     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
139     ;;
140   netbsd*)
141     SYS=netbsd
142     ;;
143   dragonfly*)
144     SYS=dragonfly
145     ;;
146   darwin*)
147
148     dnl Force gcc "-arch" flag
149     ARCH_flag=""
150     case "${host}" in
151       i?86*)
152         ARCH_flag="-arch i386"
153         YASMFLAGS="-f macho32"
154       ;;
155       ppc64*)
156         ARCH_flag="-arch ppc64"
157       ;;
158       ppc*)
159         ARCH_flag="-arch ppc"
160       ;;
161       x86_64*)
162         ARCH_flag="-arch x86_64"
163         YASMFLAGS="-f macho64"
164       ;;
165       arm*)
166         ac_cv_c_bigendian="no"
167         ac_cv_c_attribute_packed="no"
168       ;;
169     esac
170
171     SYS=darwin
172     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
173     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
174     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
175     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu99 ${ARCH_flag}"
176     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
177     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
178     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
179
180     AC_EGREP_CPP(yes,
181             [#import <TargetConditionals.h>
182              #if TARGET_OS_IPHONE
183              yes
184              #endif],
185              [HAVE_IOS="1"],
186              [HAVE_OSX="1"])
187
188     dnl Allow binaries created on Lion to run on earlier releases
189     AC_EGREP_CPP(yes,
190            [#import <Cocoa/Cocoa.h>
191             #ifdef MAC_OS_X_VERSION_10_7
192             yes
193             #endif],
194             [AC_MSG_RESULT([yes])
195             AC_LIBOBJ([getdelim])
196             AC_LIBOBJ([strndup])
197             AC_LIBOBJ([strnlen])],)
198
199     dnl
200     dnl  Handle Mac OS X SDK flags
201     dnl
202     AC_ARG_WITH(macosx-sdk,
203       [AS_HELP_STRING([--with-macosx-sdk=DIR],
204         [compile using the SDK in DIR])])
205     if test "${with_macosx_sdk}" != "" ; then
206         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
207         CPP="${CPP} -isysroot ${with_macosx_sdk}"
208         CC="${CC} -isysroot ${with_macosx_sdk}"
209         CXX="${CXX} -isysroot ${with_macosx_sdk}"
210         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
211         LD="${LD} -syslibroot ${with_macosx_sdk}"
212     fi
213     AC_ARG_WITH(macosx-version-min,
214       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
215         [compile for Mac OS X VERSION and above])])
216     if test "${with_macosx_version_min}" != "" ; then
217         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
218         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
219         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
220         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
221         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
222     fi
223     ;;
224   *mingw32* | *cygwin* | *wince* | *mingwce*)
225     AC_CHECK_TOOL(WINDRES, windres, :)
226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
229     AH_TOP([#endif])
230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
241
242     case "${host_os}" in
243       *mingw32*)
244         SYS=mingw32
245         ;;
246       *cygwin*)
247         dnl Check if we are using the mno-cygwin mode in which case we are
248         dnl actually dealing with a mingw32 compiler.
249         AC_EGREP_CPP(yes,
250             [#ifdef _WIN32
251              yes
252              #endif],
253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
254         ;;
255     esac
256
257     if test "${SYS}" = "mingw32"; then
258         # DEP, ASLR, NO SEH
259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
260
261         VLC_ADD_LIBS([libvlccore],[-lwinmm])
262         VLC_ADD_LDFLAGS([vlc],[-mwindows])
263         VLC_ADD_LIBS([win32text],[-lgdi32])
264         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
265         ac_default_prefix="`pwd`/_win32"
266         DESTDIR="`pwd`/_win32/"
267
268         dnl
269         dnl NSIS/MSI Installer prefix and WIN64
270         dnl
271         case "${host}" in
272             amd64*|x86_64*)
273                 HAVE_WIN64="1"
274                 WINDOWS_ARCH="x64"
275                 PROGRAMFILES="PROGRAMFILES64"
276                 YASMFLAGS="-f win64"
277             ;;
278             *)
279                 WINDOWS_ARCH="x86"
280                 PROGRAMFILES="PROGRAMFILES"
281                 YASMFLAGS="-f win32"
282             ;;
283         esac
284         AC_SUBST(WINDOWS_ARCH)
285         AC_SUBST(PROGRAMFILES)
286
287     fi
288     ;;
289   *nto*)
290     SYS=nto
291     ;;
292   solaris*)
293     SYS=solaris
294     ;;
295   hpux*)
296     SYS=hpux
297     ;;
298   symbian*)
299     SYS=symbian
300     ;;
301   *os2*)
302     SYS=os2
303     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
304     ;;
305   *)
306     SYS="${host_os}"
307     ;;
308 esac
309 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
310 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
311 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
312 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
313 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
314 AM_CONDITIONAL(HAVE_SYMBIAN, test "${SYS}" = "symbian")
315 AM_CONDITIONAL(HAVE_IOS,   test "${HAVE_IOS}" = "1")
316 AM_CONDITIONAL(HAVE_OSX,   test "${HAVE_OSX}" = "1")
317
318 AC_SUBST(YASMFLAGS)
319
320 dnl
321 dnl Sadly autoconf does not think about testing foo.exe when ask to test
322 dnl for program foo on win32
323 case "${build_os}" in
324     cygwin|msys)
325         ac_executable_extensions=".exe"
326     ;;
327     *)
328     ;;
329 esac
330
331 dnl Android is linux, but a bit different
332 AS_IF([test "$SYS" = linux],[
333     AC_MSG_CHECKING([for an Android system])
334     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
335         [[#ifndef __ANDROID__
336          # error Not Android
337          #endif
338         ]],[[;]])
339     ],[
340       HAVE_ANDROID="1"
341       AC_MSG_RESULT([yes])
342     ],[
343       AC_MSG_RESULT([no])
344     ])
345 ])
346 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
347
348
349 dnl
350 dnl  Check for the contrib directory
351 dnl
352 AC_ARG_WITH(contrib,
353   [AS_HELP_STRING([--with-contrib[=DIR]],
354     [search for 3rd party libraries in DIR/include and DIR/lib])
355 ])
356 AC_MSG_CHECKING([for 3rd party libraries path])
357 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
358   CONTRIB_DIR="${srcdir}/contrib/${host}"
359   AS_IF([test ! -d "${CONTRIB_DIR}"], [
360     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
361     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
362     AS_IF([test ! -d "${CONTRIB_DIR}"], [
363       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
364       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
365       AS_IF([test ! -d "${CONTRIB_DIR}"], [
366         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
367         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
368         AS_IF([test ! -d "${CONTRIB_DIR}"], [
369           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
370           CONTRIB_DIR=""
371           AC_MSG_RESULT([not found])
372         ])
373       ])
374     ])
375   ])
376 ], [
377   AS_IF([test "${with_contrib}" != "no"], [
378     CONTRIB_DIR="${with_contrib}"
379   ], [
380     CONTRIB_DIR=""
381     AC_MSG_RESULT([disabled])
382   ])
383 ])
384 AS_IF([test -n "${CONTRIB_DIR}"], [
385   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
386     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
387   ], [
388     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
389     CONTRIB_DIR=""
390     AC_MSG_RESULT([not usable])
391   ])
392
393 ])
394 AS_IF([test -n "${CONTRIB_DIR}"], [
395   AC_MSG_RESULT([${CONTRIB_DIR}])
396   export PATH=${CONTRIB_DIR}/bin:$PATH
397   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
398   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
399   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
400   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
401   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
402   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
403
404   AS_IF([test "${SYS}" = "darwin"], [
405     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
406     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
407   ])
408 ], [
409   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
410     AC_MSG_ERROR([Third party libraries not found!])
411   ])
412 ])
413 AC_SUBST(CONTRIB_DIR)
414
415 dnl Add extras/tools to the PATH
416 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
417 AS_IF([test -d "${TOOLS_DIR}"], [
418     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
419     export PATH="${TOOLS_DIR}":$PATH
420 ])
421
422 dnl
423 dnl  Libtool
424 dnl  It's very bad, but our former custom system was worst
425 dnl  -- Courmisch
426 dnl
427
428 dnl override platform specific check for dependent libraries
429 dnl otherwise libtool linking of shared libraries will
430 dnl fail on anything other than pass_all.
431 AC_CACHE_VAL(lt_cv_deplibs_check_method,
432     [lt_cv_deplibs_check_method=pass_all])
433
434 LT_INIT([dlopen win32-dll shared disable-static])
435 LT_LANG([C++])
436 LT_LANG([Windows Resource])
437
438 DOLT
439
440 lt_cv_deplibs_check_method=pass_all
441
442 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
443   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
444 ])
445
446 dnl
447 dnl Gettext stuff
448 dnl
449 AM_GNU_GETTEXT_VERSION([0.19.2])
450 AM_GNU_GETTEXT([external], [need-ngettext])
451
452 dnl
453 dnl Iconv stuff
454 dnl
455 AM_ICONV
456
457 dnl
458 dnl checks for mingw
459 AS_IF([test "${SYS}" = "mingw32"], [
460 dnl Check for broken versions of mingw-runtime compatability library
461     AC_MSG_CHECKING(for broken mingw-runtime)
462     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
463 #include <_mingw.h>
464 #if defined(__MINGW64_VERSION_MAJOR)
465 # if __MINGW64_VERSION_MAJOR < 3
466 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
467 # endif
468 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
469 # error Attempting to use mingw-runtime with broken vsnprintf support
470 #endif
471     ])], [
472         AC_MSG_RESULT([ok])
473     ], [
474         AC_MSG_RESULT([present])
475         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
476     ])
477     dnl force use of mingw provided c99 *printf over msvcrt
478     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
479
480 dnl Check for the need to include the mingwex lib for mingw32
481     VLC_SAVE_FLAGS
482     AC_CHECK_LIB(mingwex,opendir,
483         AC_CHECK_LIB(mingw32,opendir,,
484             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
485     )
486     VLC_RESTORE_FLAGS
487
488 dnl Check for fnative-struct or mms-bitfields support for mingw32
489     VLC_SAVE_FLAGS
490     CFLAGS="${CFLAGS} -mms-bitfields"
491     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
492     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
493         [ac_cv_c_mms_bitfields],
494         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
495     if test "${ac_cv_c_mms_bitfields}" = "no"; then
496         VLC_RESTORE_FLAGS
497         CFLAGS="${CFLAGS} -fnative-struct"
498         CXXFLAGS="${CXXFLAGS} -fnative-struct"
499         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
500             [ac_cv_c_fnative_struct],
501             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
502         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
503     fi
504 ])
505
506 AC_ARG_ENABLE(winstore_app,
507      AS_HELP_STRING([--enable-winstore-app],
508                     [Build targetted for Windows Store apps (default disabled)]))
509
510 vlc_winstore_app=0
511 AS_IF([test "${SYS}" = "mingw32" -a "${enable_winstore_app}" = "yes"], [
512     vlc_winstore_app=1
513     VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
514     ])
515 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
516 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
517
518
519 dnl
520 dnl Buggy glibc prevention. Purposedly not cached.
521 dnl See sourceware.org bugs 5058 and 5443.
522 dnl Ubuntu alone has 20 bug numbers for this...
523 dnl
524 AC_MSG_CHECKING(for buggy GNU/libc versions)
525 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
526 #include <limits.h>
527 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
528   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
529 # error GNU/libc with dcgettext killer bug!
530 #endif
531 ])], [
532   AC_MSG_RESULT([not present])
533 ], [
534   AC_MSG_RESULT([found])
535   AS_IF([test "x${enable_nls}" != "xno"], [
536     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
537 work-around for this. Check with your distribution vendor on how to update the
538 glibc run-time. Alternatively, build with --disable-nls.])
539   ])
540 ])
541
542 dnl Plugin compilation stuff
543
544 VLC_LIBRARY_SUFFIX
545
546 dnl Check for system libs needed
547 need_libc=false
548
549 dnl Check for usual libc functions
550 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
551 AC_CHECK_FUNCS([daemon fcntl fstatvfs fork getenv getpwuid_r isatty lstat memalign mmap openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
552 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir flockfile fsync getdelim getpid gmtime_r lldiv localtime_r nrand48 poll posix_memalign rewind setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strsep strtof strtok_r strtoll swab tdestroy strverscmp])
553 AC_CHECK_FUNCS(fdatasync,,
554   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
555 ])
556
557 dnl mingw64 implements those as static inline, not functions with C linkage
558 AC_LINK_IFELSE([
559     AC_LANG_PROGRAM([#include <stdio.h>], [
560         char *c;
561         if (asprintf(&c, "%s %d", "string", 1) == -1)
562             c = NULL;
563     ])],[AC_DEFINE([HAVE_ASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([asprintf])])
564 AC_LINK_IFELSE([
565     AC_LANG_PROGRAM([#include <stdio.h>
566                      #include <stdarg.h>], [
567         char *c;
568         va_list ap;
569         if (vasprintf(&c, "%s %d", ap) == -1)
570             c = NULL;
571     ])],[AC_DEFINE([HAVE_VASPRINTF],[1],[Define to 1 if you have asprintf function])],[AC_LIBOBJ([vasprintf])])
572
573 dnl C11 static_assert()
574 AC_MSG_CHECKING([for static_assert in assert.h])
575 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
576 static_assert(1, "The impossible happened.");
577 ])], [
578   AC_MSG_RESULT([yes])
579   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
580 ], [
581   AC_MSG_RESULT([no])
582 ])
583
584 # Windows CE does not have strcoll()
585 AC_FUNC_STRCOLL
586
587 dnl Check for non-standard system calls
588 case "$SYS" in
589   "linux")
590     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
591     ;;
592   "mingw32")
593     AC_CHECK_FUNCS([_lock_file])
594     ;;
595 esac
596
597 AH_BOTTOM([#include <vlc_fixups.h>])
598
599 dnl Check for struct pollfd
600 AC_CHECK_TYPES([struct pollfd],,,
601 [#include <sys/types.h>
602 #if HAVE_POLL
603 # include <poll.h>
604 #elif defined (_WIN32)
605 # include <winsock2.h>
606 #endif
607 ])
608
609 dnl Checks for socket stuff
610 VLC_SAVE_FLAGS
611 SOCKET_LIBS=""
612 AC_SEARCH_LIBS(connect, [socket], [
613   AS_IF([test "$ac_cv_search_connect" != "none required"], [
614     SOCKET_LIBS="$ac_cv_search_connect"
615   ])
616 ], [
617   AS_IF([test "${SYS}" = "mingw32"], [
618     SOCKET_LIBS="-lws2_32"
619   ])
620 ])
621
622 AC_SEARCH_LIBS([inet_pton], [nsl], [
623  AS_IF([test "$ac_cv_search_getaddrinfo" != "none required"], [
624     SOCKET_LIBS="$ac_cv_search_getaddrinfo $SOCKET_LIBS"
625   ])
626 ],, [${SOCKET_LIBS}])
627
628 LIBS="${LIBS} ${SOCKET_LIBS}"
629 AC_LINK_IFELSE([
630     AC_LANG_PROGRAM([#ifdef _WIN32
631         # if _WIN32_WINNT < 0x600
632         #  error Needs vista+
633         # endif
634         #include <ws2tcpip.h>
635         #else
636         #include <sys/socket.h>
637         #include <arpa/inet.h>
638         #endif], [
639         char dst[[sizeof(struct in_addr)]];
640         inet_pton(AF_INET, "127.0.0.1", dst);
641     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
642 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
643 VLC_RESTORE_FLAGS
644
645 AS_IF([test -n "$SOCKET_LIBS"], [
646   VLC_ADD_LIBS([access_rtmp access_output_shout sap stream_out_standard stream_out_rtp stream_out_raop stream_out_chromecast oldrc netsync ts remoteosd audiobargraph_a],[${SOCKET_LIBS}])
647 ])
648 AC_SUBST(SOCKET_LIBS)
649
650 dnl Check for socklen_t
651 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
652 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
653 ac_cv_type_socklen_t,
654 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
655 [#include <sys/types.h>
656 #ifdef _WIN32
657 # include <winsock2.h>
658 # include <ws2tcpip.h>
659 #else
660 # include <sys/socket.h>
661 #endif]], [[socklen_t len; len = 0;]])],
662 ac_cv_type_socklen_t=yes,
663 ac_cv_type_socklen_t=no)])
664 AS_IF([test "$ac_cv_type_socklen_t" = no],
665  [AC_DEFINE(socklen_t, int)])
666
667 dnl Check for struct sockaddr_storage
668 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
669 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
670 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
671   [AC_TRY_COMPILE(
672     [#include <sys/types.h>
673      #if defined( _WIN32 )
674      # include <winsock2.h>
675      #else
676      # include <sys/socket.h>
677      #endif], [struct sockaddr_storage addr;],
678      ac_cv_struct_sockaddr_storage=yes,
679      ac_cv_struct_sockaddr_storage=no)])
680 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
681   AC_DEFINE(sockaddr_storage, sockaddr)
682   AC_DEFINE(ss_family, sa_family)
683 ])
684
685 dnl FreeBSD has a gnugetopt library for this:
686 GNUGETOPT_LIBS=""
687 AC_CHECK_FUNC(getopt_long,, [
688   AC_CHECK_LIB([gnugetopt],[getopt_long], [
689     GNUGETOPT_LIBS="-lgnugetopt"
690   ])
691 ])
692 AC_SUBST(GNUGETOPT_LIBS)
693
694 AC_CHECK_LIB(m,cos,[
695   VLC_ADD_LIBS([adjust wave ripple psychedelic gradient a52tofloat32 dtstofloat32 x264 goom noise grain scene chorus_flanger freetype swscale postproc equalizer spatializer param_eq samplerate freetype mpc qt4 compressor headphone_channel_mixer normvol audiobargraph_a audiobargraph_v mono colorthres extract ball hotkeys mosaic gaussianblur x262 x26410b hqdn3d anaglyph oldrc ncurses oldmovie glspectrum],[-lm])
696   LIBM="-lm"
697 ], [
698   LIBM=""
699 ])
700 AC_SUBST(LIBM)
701
702 AC_CHECK_LIB(m,lrintf, [
703   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
704   VLC_ADD_LIBS([skins2],[-lm])
705 ])
706 AC_CHECK_LIB(m,nanf,
707   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
708 )
709
710 dnl Check for dynamic plugins
711 LIBDL=""
712 have_dynamic_objects="no"
713 VLC_SAVE_FLAGS
714 AC_SEARCH_LIBS(dlsym, [dl svld], [
715   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
716     LIBDL="$ac_cv_search_dlsym"
717   ])
718   have_dynamic_objects="yes"
719 ])
720 VLC_RESTORE_FLAGS
721
722 # Windows
723 AS_IF([test "${SYS}" = "mingw32"], [
724   LIBDL=""
725   have_dynamic_objects="yes" #assume we can use shared objects
726 ])
727
728 AS_IF([test "${enable_shared}" = "no"], [
729   have_dynamic_objects=no
730 ])
731 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
732
733 AC_SUBST(LIBDL)
734
735 dnl Check for thread library
736 LIBPTHREAD=""
737 AS_IF([test "${SYS}" != "mingw32"], [
738   VLC_SAVE_FLAGS
739   LIBS=""
740   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
741     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
742       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
743     ])
744   ])
745   VLC_RESTORE_FLAGS
746
747   AC_CHECK_LIB(rt, clock_nanosleep, [
748     VLC_ADD_LIBS([libvlccore],[-lrt])
749   ], [
750     AC_CHECK_FUNC(nanosleep,,[
751       AC_CHECK_LIB(rt,nanosleep, [
752         VLC_ADD_LIBS([libvlccore],[-lrt])
753       ], [
754         AC_CHECK_LIB(posix4,nanosleep, [
755           VLC_ADD_LIBS([libvlccore],[-lposix4])
756         ])
757       ])
758     ])
759     dnl HP/UX port
760     AC_CHECK_LIB(rt,sem_init, [VLC_ADD_LIBS([libvlccore],[-lrt])])
761   ])
762 ])
763 AC_SUBST(LIBPTHREAD)
764
765 dnl Check for headers
766 dnl  POSIX
767 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h syslog.h sys/shm.h sys/socket.h])
768 AC_CHECK_HEADERS([net/if.h], [], [],
769 [
770 #include <sys/types.h>
771 #include <sys/socket.h>
772 ])
773 dnl  BSD
774 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
775 dnl  GNU/Linux
776 AC_CHECK_HEADERS([getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
777 dnl  MacOS
778 AC_CHECK_HEADERS([xlocale.h])
779
780 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
781 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
782 AC_CHECK_TYPE(ssize_t,, [
783   AC_DEFINE(ssize_t, int)
784 ])
785
786 dnl It seems that autoconf detects pkg-config only during the first
787 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
788 dnl it is nested within a conditional block, so it was not working right.
789 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
790 AC_ARG_VAR(PKG_CONFIG_PATH,
791        [Paths where to find .pc not at the default location])
792 PKG_PROG_PKG_CONFIG()
793
794 dnl On some OS we need static linking
795 AS_IF([test -n "${PKG_CONFIG}" ],[
796     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
797         PKG_CONFIG="${PKG_CONFIG} --static"
798     ])
799 ])
800
801
802 dnl
803 dnl Check for zlib.h and -lz along with system -lminizip if available
804 dnl
805 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
806 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
807 if test "${have_zlib}" = "yes"
808 then
809   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
810   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
811     AC_CHECK_HEADERS([unzip.h], [
812       have_minizip=yes
813       MINIZIP_LIBS="-lminizip -lz"
814     ], [
815       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
816       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
817       have_minizip=no
818     ])
819   ])
820   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
821   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
822 fi
823 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
824
825
826 dnl
827 dnl Domain name i18n support via GNU libidn
828 dnl
829 PKG_CHECK_MODULES([IDN], [libidn], [
830   have_libidn="yes"
831   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
832 ], [
833   have_libidn="no"
834 ])
835
836
837 dnl Check for dbus
838 AC_ARG_ENABLE(dbus,
839   [AS_HELP_STRING([--enable-dbus],
840     [compile D-Bus message bus support (default enabled)])])
841 have_dbus="no"
842 AS_IF([test "${enable_dbus}" != "no"], [
843   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
844     have_dbus="yes"
845   ], [
846     AS_IF([test -n "${enable_dbus}"], [
847       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
848     ], [
849       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
850     ])
851   ])
852 ])
853 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
854
855 dnl Check for ntohl, etc.
856 VLC_SAVE_FLAGS
857 CFLAGS="${CFLAGS} -Wall -Werror"
858 AC_CACHE_CHECK([for ntohl in sys/param.h],
859     [ac_cv_c_ntohl_sys_param_h],
860     [     AC_TRY_COMPILE([#include <sys/param.h>],
861         [int meuh; ntohl(meuh);],
862         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
863 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
864     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
865 fi
866 VLC_RESTORE_FLAGS
867
868 EXTEND_HELP_STRING([Optimization options:])
869 dnl
870 dnl  Compiler warnings
871 dnl
872
873 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op])
874 RDC_PROG_CC_FLAGS([-pipe])
875 AC_LANG_PUSH([C++])
876 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var])
877 AC_LANG_POP([C++])
878
879 dnl
880 dnl  Debugging mode
881 dnl
882 AC_ARG_ENABLE(debug,
883   [AS_HELP_STRING([--enable-debug],
884     [build with run-time assertions (default disabled)])],,
885   [enable_debug="no"])
886 AH_TEMPLATE(NDEBUG,
887             [Define to 1 if debug code should NOT be compiled])
888 AS_IF([test "${enable_debug}" != "no"], [
889   AC_CHECK_HEADERS([valgrind/valgrind.h])
890 ], [
891   AC_DEFINE(NDEBUG)
892 ])
893
894 dnl
895 dnl  Profiling
896 dnl
897 AC_ARG_ENABLE(gprof,
898   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
899   [enable_gprof="no"])
900 AS_IF([test "${enable_gprof}" != "no"], [
901   CFLAGS="${CFLAGS} -pg"
902   CXXFLAGS="${CXXFLAGS} -pg"
903   OBJCFLAGS="${OBJCFLAGS} -pg"
904   LDFLAGS="${LDFLAGS} -pg"
905 ])
906
907 AC_ARG_ENABLE(cprof,
908   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
909   [enable_cprof="no"])
910 AS_IF([test "${enable_gprof}" != "no"], [
911   CFLAGS="${CFLAGS} -finstrument-functions"
912   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
913   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
914   LDFLAGS="${LDFLAGS} -finstrument-functions"
915 ])
916
917 dnl
918 dnl  Test coverage
919 dnl
920 AC_ARG_ENABLE(coverage,
921   [AS_HELP_STRING([--enable-coverage],
922     [build for test coverage (default disabled)])],,
923   [enable_coverage="no"])
924 AS_IF([test "${enable_coverage}" != "no"], [
925   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
926   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
927   LDFLAGS="-lgcov ${LDFLAGS}"
928 ])
929
930 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
931   VLC_SAVE_FLAGS
932   CFLAGS="${CFLAGS} -fvisibility=hidden"
933   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
934   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
935   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
936                  [ac_cv_c_visibility_hidden], [
937     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
938       ac_cv_c_visibility_hidden=yes
939     ], [
940       ac_cv_c_visibility_hidden=no
941     ])
942   ])
943   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
944 ])
945
946
947 dnl
948 dnl  Enable/disable optimizations
949 dnl
950 AC_ARG_ENABLE(optimizations,
951   [AS_HELP_STRING([--disable-optimizations],
952     [disable compiler optimizations (default enabled)])],,
953   [enable_optimizations="yes"])
954
955 dnl Check for various optimization flags
956 AS_IF([test "${enable_optimizations}" != "no"], [
957
958   dnl -O4 and -O3 only in production builds
959   AS_IF([test "${enable_debug}" = "no"], [
960     VLC_SAVE_FLAGS
961     CFLAGS="${CFLAGS} -O4"
962     CXXFLAGS="${CXXFLAGS} -O4"
963     OBJCFLAGS="${OBJCFLAGS} -O4"
964     AC_CACHE_CHECK([if $CC accepts -O4], [ac_cv_c_o4], [
965       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
966         ac_cv_c_o4=yes
967       ], [
968         ac_cv_c_o4=no
969       ])
970     ])
971     AS_IF([test "${ac_cv_c_o4}" = "no"], [
972       VLC_RESTORE_FLAGS
973       CFLAGS="${CFLAGS} -O3"
974       CXXFLAGS="${CXXFLAGS} -O3"
975       OBJCFLAGS="${OBJCFLAGS} -O3"
976       AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
977         AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
978           ac_cv_c_o3=yes
979         ], [
980           ac_cv_c_o3=no
981         ])
982       ])
983       AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
984     ])
985   ])
986
987   dnl Check for -ffast-math
988   VLC_SAVE_FLAGS
989   CFLAGS="${CFLAGS} -ffast-math"
990   CXXFLAGS="${CXXFLAGS} -ffast-math"
991   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
992   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
993     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
994       ac_cv_c_fast_math=yes
995     ], [
996       ac_cv_c_fast_math=no
997     ])
998   ])
999   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
1000   AH_BOTTOM([
1001 #ifndef __FAST_MATH__
1002 # pragma STDC FENV_ACCESS OFF
1003 # pragma STDC FP_CONTRACT ON
1004 #endif
1005 ])
1006
1007   dnl Check for -funroll-loops
1008   VLC_SAVE_FLAGS
1009   CFLAGS="${CFLAGS} -funroll-loops"
1010   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1011   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1012   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1013     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1014       ac_cv_c_unroll_loops=yes
1015     ], [
1016       ac_cv_c_unroll_loops=no
1017     ])
1018   ])
1019   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1020
1021   AS_IF([test "$enable_debug" = "no"], [
1022     dnl Check for -fomit-frame-pointer
1023     VLC_SAVE_FLAGS
1024     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1025     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1026     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1027     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1028       [ac_cv_c_omit_frame_pointer], [
1029       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1030         ac_cv_c_omit_frame_pointer=yes
1031       ], [
1032         ac_cv_c_omit_frame_pointer=no
1033       ])
1034     ])
1035     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1036   ])
1037 ])
1038
1039 VLC_SAVE_FLAGS
1040 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1041 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1042   AC_TRY_LINK([],, [
1043     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1044   ], [
1045     ac_cv_ld_bsymbolic=""
1046   ])
1047 ])
1048 VLC_RESTORE_FLAGS
1049 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1050 AC_SUBST(SYMBOLIC_LDFLAGS)
1051
1052 dnl Checks for __attribute__(aligned()) directive
1053 VLC_SAVE_FLAGS
1054 CFLAGS="${CFLAGS} -Werror"
1055 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1056     [ac_cv_c_attribute_aligned],
1057     [ac_cv_c_attribute_aligned=0
1058     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1059         AC_TRY_COMPILE([],
1060         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1061         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1062     done])
1063 VLC_RESTORE_FLAGS
1064 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1065     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1066         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1067 fi
1068
1069 dnl Check for __attribute__((packed))
1070 AC_CACHE_CHECK([for __attribute__((packed))],
1071   [ac_cv_c_attribute_packed],
1072   [ac_cv_c_attribute_packed=no
1073    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1074                     [ac_cv_c_attribute_packed=yes])])
1075 if test "${ac_cv_c_attribute_packed}" != "no"; then
1076   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1077 fi
1078
1079 dnl
1080 dnl  Check the CPU
1081 dnl
1082 case "${host_cpu}" in
1083   "")
1084     ARCH=unknown
1085     ;;
1086   *)
1087     ARCH="${host_cpu}"
1088     ;;
1089 esac
1090
1091 dnl Check for backtrace() support
1092 AC_CHECK_HEADERS(execinfo.h)
1093 AC_CHECK_FUNCS(backtrace)
1094
1095 dnl
1096 dnl  default modules
1097 dnl
1098 ALIASES="${ALIASES} cvlc rvlc"
1099
1100 dnl
1101 dnl  Accelerated modules
1102 dnl
1103
1104 dnl  Check for fully working MMX intrinsics
1105 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1106 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1107 AC_ARG_ENABLE(mmx,
1108   [AS_HELP_STRING([--disable-mmx],
1109     [disable MMX optimizations (default auto)])],,[
1110   case "${host_cpu}" in
1111     i?86|x86_64)
1112       enable_mmx="yes"
1113       ;;
1114     *)
1115       enable_mmx="no"
1116       ;;
1117   esac
1118 ])
1119 have_mmx="no"
1120 have_mmxext="no"
1121 AS_IF([test "${enable_mmx}" != "no"], [
1122   ARCH="${ARCH} mmx"
1123   VLC_SAVE_FLAGS
1124   CFLAGS="${CFLAGS} -mmmx"
1125   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1126     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1127 [#include <mmintrin.h>
1128 #include <stdint.h>
1129 uint64_t frobzor;]], [
1130 [__m64 a, b, c;
1131 a = b = c = (__m64)frobzor;
1132 a = _mm_slli_pi16(a, 3);
1133 a = _mm_adds_pi16(a, b);
1134 c = _mm_srli_pi16(c, 8);
1135 c = _mm_slli_pi16(c, 3);
1136 b = _mm_adds_pi16(b, c);
1137 a = _mm_unpacklo_pi8(a, b);
1138 frobzor = (uint64_t)a;]])], [
1139       ac_cv_c_mmx_intrinsics=yes
1140     ], [
1141       ac_cv_c_mmx_intrinsics=no
1142     ])
1143   ])
1144   VLC_RESTORE_FLAGS
1145   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1146     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1147   ])
1148
1149   VLC_SAVE_FLAGS
1150   CFLAGS="${CFLAGS} -mmmx"
1151   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1152     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1153 void *p;
1154 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1155 ]])
1156     ], [
1157       ac_cv_mmx_inline=yes
1158     ], [
1159       ac_cv_mmx_inline=no
1160     ])
1161   ])
1162   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1163     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1164     have_mmx="yes"
1165   ])
1166
1167   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1168                  [ac_cv_mmxext_inline], [
1169     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1170 void *p;
1171 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1172 ]])
1173     ], [
1174       ac_cv_mmxext_inline=yes
1175     ], [
1176       ac_cv_mmxext_inline=no
1177     ])
1178   ])
1179   VLC_RESTORE_FLAGS
1180   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1181     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1182     have_mmxext="yes"
1183   ])
1184 ])
1185 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1186 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1187
1188 dnl  Check for fully workin SSE2 intrinsics
1189 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1190 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1191 AC_ARG_ENABLE(sse,
1192   [AS_HELP_STRING([--disable-sse],
1193     [disable SSE (1-4) optimizations (default auto)])],, [
1194   case "${host_cpu}" in
1195     i?86|x86_64)
1196       enable_sse=yes
1197       ;;
1198     *)
1199       enable_sse=no
1200       ;;
1201   esac
1202 ])
1203 have_sse2="no"
1204 AS_IF([test "${enable_sse}" != "no"], [
1205   ARCH="${ARCH} sse sse2"
1206
1207   VLC_SAVE_FLAGS
1208   CFLAGS="${CFLAGS} -msse2"
1209   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1210     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1211 [#include <emmintrin.h>
1212 #include <stdint.h>
1213 uint64_t frobzor;]], [
1214 [__m128i a, b, c;
1215 a = b = c = _mm_set1_epi64((__m64)frobzor);
1216 a = _mm_slli_epi16(a, 3);
1217 a = _mm_adds_epi16(a, b);
1218 c = _mm_srli_epi16(c, 8);
1219 c = _mm_slli_epi16(c, 3);
1220 b = _mm_adds_epi16(b, c);
1221 a = _mm_unpacklo_epi8(a, b);
1222 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1223       ac_cv_c_sse2_intrinsics=yes
1224     ], [
1225       ac_cv_c_sse2_intrinsics=no
1226     ])
1227   ])
1228   VLC_RESTORE_FLAGS
1229   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1230     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1231   ])
1232
1233   VLC_SAVE_FLAGS
1234   CFLAGS="${CFLAGS} -msse"
1235   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1236     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1237 void *p;
1238 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1239 ]])
1240     ], [
1241       ac_cv_sse_inline=yes
1242     ], [
1243       ac_cv_sse_inline=no
1244     ])
1245   ])
1246
1247   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1248     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1249   ])
1250
1251   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1252     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1253 void *p;
1254 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1255 ]])
1256     ], [
1257       ac_cv_sse2_inline=yes
1258     ], [
1259       ac_cv_sse2_inline=no
1260     ])
1261   ])
1262   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1263     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1264     have_sse2="yes"
1265   ])
1266
1267   # SSE3
1268   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1269     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1270 void *p;
1271 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1272 ]])
1273     ], [
1274       ac_cv_sse3_inline=yes
1275     ], [
1276       ac_cv_sse3_inline=no
1277     ])
1278   ])
1279
1280   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1281     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1282   # SSSE3
1283   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1284     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1285 void *p;
1286 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1287 ]])
1288     ], [
1289       ac_cv_ssse3_inline=yes
1290     ], [
1291       ac_cv_ssse3_inline=no
1292     ])
1293   ])
1294
1295   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1296     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1297
1298   # SSE4.1
1299   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1300                  [ac_cv_sse4_1_inline], [
1301     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1302 void *p;
1303 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1304 ]])
1305     ], [
1306       ac_cv_sse4_1_inline=yes
1307     ], [
1308       ac_cv_sse4_1_inline=no
1309     ])
1310   ])
1311
1312   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1313     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1314
1315   # SSE4.2
1316   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1317                  [ac_cv_sse4_2_inline], [
1318     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1319 void *p;
1320 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1321 ]])
1322     ], [
1323       ac_cv_sse4_2_inline=yes
1324     ], [
1325       ac_cv_sse4_2_inline=no
1326     ])
1327   ])
1328
1329   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1330     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1331
1332   # SSE4A
1333   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1334     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1335 void *p;
1336 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1337 ]])
1338     ], [
1339       ac_cv_sse4a_inline=yes
1340     ], [
1341       ac_cv_sse4a_inline=no
1342     ])
1343   ])
1344   VLC_RESTORE_FLAGS
1345   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1346     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1347 ])
1348 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1349
1350 VLC_SAVE_FLAGS
1351 CFLAGS="${CFLAGS} -mmmx"
1352 have_3dnow="no"
1353 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1354   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1355 void *p;
1356 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1357 ]])
1358   ], [
1359     ac_cv_3dnow_inline=yes
1360   ], [
1361     ac_cv_3dnow_inline=no
1362   ])
1363 ])
1364 VLC_RESTORE_FLAGS
1365 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1366   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1367             [Define to 1 if 3D Now! inline assembly is available.])
1368   have_3dnow="yes"
1369 ])
1370 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1371
1372
1373 AC_ARG_ENABLE(neon,
1374   [AS_HELP_STRING([--disable-neon],
1375     [disable NEON optimizations (default auto)])],, [
1376   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1377 ])
1378 AS_IF([test "${enable_neon}" != "no"], [
1379   VLC_SAVE_FLAGS
1380   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1381   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1382     AC_COMPILE_IFELSE([
1383       AC_LANG_PROGRAM(,[[
1384 asm volatile("vqmovun.s64 d0, q1":::"d0");
1385 ]])
1386     ], [
1387       ac_cv_arm_neon="yes"
1388     ], [
1389       ac_cv_arm_neon="no"
1390     ])
1391   ])
1392   VLC_RESTORE_FLAGS
1393 ])
1394 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1395
1396
1397 AC_ARG_ENABLE(altivec,
1398   [AS_HELP_STRING([--disable-altivec],
1399     [disable AltiVec optimizations (default auto)])],, [
1400   AS_CASE("${host_cpu}", [powerpc*],
1401         [enable_altivec=yes], [enable_altivec=no])
1402 ])
1403 have_altivec="no"
1404 ALTIVEC_CFLAGS=""
1405 AS_IF([test "${enable_altivec}" = "yes"], [
1406   ARCH="${ARCH} altivec";
1407   VLC_SAVE_FLAGS
1408   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1409     [ac_cv_altivec_inline],
1410     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1411          ac_cv_altivec_inline="yes",
1412          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1413           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1414             [ac_cv_altivec_inline="-Wa,-maltivec"],
1415             ac_cv_altivec_inline=no)
1416          ])])
1417   VLC_RESTORE_FLAGS
1418   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1419     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1420               [Define to 1 if AltiVec inline assembly is available.])
1421     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1422       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1423       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1424     ])
1425     have_altivec="yes"
1426   ])
1427
1428   VLC_SAVE_FLAGS
1429   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1430   [ac_cv_c_altivec], [
1431     CFLAGS="${CFLAGS} -maltivec"
1432     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1433 [#include <altivec.h>]], [
1434 [vec_ld(0, (unsigned char *)0);]])], [
1435       ac_cv_c_altivec="-maltivec"
1436     ], [
1437       ac_cv_c_altivec="no"
1438     ])
1439   ])
1440   VLC_RESTORE_FLAGS
1441   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1442     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1443     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1444     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1445     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1446     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1447     have_altivec="yes"
1448   ])
1449   AC_CHECK_HEADERS(altivec.h)
1450
1451   VLC_SAVE_FLAGS
1452   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1453   AC_CACHE_CHECK([if linker needs -framework vecLib],
1454     [ac_cv_ld_altivec],
1455     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1456   VLC_RESTORE_FLAGS
1457   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1458     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1459   ])
1460 ])
1461 AC_SUBST(ALTIVEC_CFLAGS)
1462 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1463
1464 dnl
1465 dnl  Memory usage
1466 dnl
1467 AC_ARG_ENABLE(optimize-memory,
1468   [AS_HELP_STRING([--enable-optimize-memory],
1469     [optimize memory usage over performance])])
1470 if test "${enable_optimize_memory}" = "yes"; then
1471   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1472 fi
1473
1474 dnl
1475 dnl Allow running as root (useful for people running on embedded platforms)
1476 dnl
1477 AC_ARG_ENABLE(run-as-root,
1478   [AS_HELP_STRING([--enable-run-as-root],
1479     [allow running VLC as root (default disabled)])])
1480 AS_IF([test "${enable_run_as_root}" = "yes"],[
1481     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1482               [Define to 1 to allow running VLC as root (uid 0).])
1483 ])
1484
1485 dnl
1486 dnl Stream output
1487 dnl
1488 AC_ARG_ENABLE(sout,
1489   [AS_HELP_STRING([--disable-sout],
1490     [disable streaming output (default enabled)])])
1491 AS_IF([test "${enable_sout}" != "no"], [
1492   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1493 ])
1494 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1495
1496 dnl Lua modules
1497 AC_ARG_ENABLE(lua,
1498   [AS_HELP_STRING([--disable-lua],
1499     [disable LUA scripting support (default enabled)])])
1500 if test "${enable_lua}" != "no"
1501 then
1502   PKG_CHECK_MODULES(LUA, lua5.2,
1503     [ have_lua=yes ],
1504     [
1505     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1506
1507     PKG_CHECK_MODULES(LUA, lua5.1,
1508       [ have_lua=yes ],
1509       [
1510       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1511       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1512         [ have_lua=yes ],
1513         [
1514           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1515           have_lua=yes
1516           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1517             [],
1518             [ have_lua=no ] )
1519           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1520             [LUA_LIBS="-llua5.2"],
1521           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1522             [LUA_LIBS="-llua5.1"],
1523             AC_CHECK_LIB( lua51 , luaL_newstate,
1524               [LUA_LIBS="-llua51"],
1525               AC_CHECK_LIB( lua , luaL_newstate,
1526                 [LUA_LIBS="-llua"],
1527                 [ have_lua=no
1528                 ], [-lm])
1529             )))
1530         ])
1531       ])
1532     ])
1533   if test "x${have_lua}" != "xyes" ;  then
1534       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1535   fi
1536   AC_ARG_VAR([LUAC], [LUA byte compiler])
1537   AC_PATH_PROGS(LUAC,[${LUAC} luac], [false])
1538   AS_IF([test "${LUAC}" = "false"], [
1539     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1540   ])
1541   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1542     AC_MSG_ERROR([You need 32-bits luac when using using lua from contrib.])
1543   ])
1544 fi
1545 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1546
1547
1548 dnl
1549 dnl HTTP daemon
1550 dnl
1551 AC_ARG_ENABLE(httpd,
1552   [AS_HELP_STRING([--disable-httpd],
1553     [disable the built-in HTTP server (default enabled)])])
1554 if test "${enable_httpd}" != "no"
1555 then
1556   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1557 fi
1558 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1559
1560
1561 dnl
1562 dnl VideoLAN manager
1563 dnl
1564 AC_ARG_ENABLE(vlm,
1565   [AS_HELP_STRING([--disable-vlm],
1566     [disable the stream manager (default enabled)])],,
1567   [enable_vlm="${enable_sout}"])
1568 AS_IF([test "${enable_vlm}" != "no"], [
1569   AS_IF([test "${enable_sout}" = "no"], [
1570     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1571   ])
1572   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1573 ])
1574 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1575
1576
1577 dnl
1578 dnl Addons manager storage and repositories modules
1579 dnl
1580 AC_ARG_ENABLE(addonmanagermodules,
1581   [AS_HELP_STRING([--disable-addonmanagermodules],
1582     [disable the addons manager modules (default enabled)])])
1583 if test "${enable_addonmanagermodules}" != "no"
1584 then
1585   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1586 fi
1587 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1588
1589
1590 dnl
1591 dnl  Input plugins
1592 dnl
1593
1594 EXTEND_HELP_STRING([Input plugins:])
1595
1596 dnl
1597 dnl  libarchive access module
1598 dnl
1599 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 2.8.5], (libarchive support), [auto])
1600
1601 dnl
1602 dnl  live555 input
1603 dnl
1604 AC_ARG_ENABLE(live555,
1605   [AS_HELP_STRING([--enable-live555],
1606     [enable RTSP input through live555 (default enabled)])])
1607
1608 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1609   PKG_CHECK_MODULES(LIVE555, live555, [
1610     VLC_ADD_PLUGIN([live555])
1611     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1612     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1613   ], [
1614     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1615
1616     AC_LANG_PUSH(C++)
1617     VLC_SAVE_FLAGS
1618
1619     dnl detect include paths
1620     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1621       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1622     ], [
1623       AS_IF([test "${SYS}" != "os2"], [
1624         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1625         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1626       ], [
1627         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1628         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1629         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1630       ])
1631     ])
1632
1633     dnl CPP Flags
1634     AS_IF([test "${SYS}" = "solaris"], [
1635       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1636     ])
1637     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1638     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1639
1640     dnl version check
1641     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1642       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1643 [#include <liveMedia_version.hh>
1644 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1645 # error BOOM
1646 #endif]])
1647       ], [
1648         ac_cv_live555="yes"
1649       ], [
1650         ac_cv_live555="no"
1651       ])
1652     ])
1653
1654     AS_IF([test "$ac_cv_live555" = "no"], [
1655       AC_MSG_WARN([live555 is missing or its installed version is too old:
1656 Version 2011.12.23 or later is required to proceed.
1657 You can get an updated one from http://www.live555.com/liveMedia .])
1658       AS_IF([test -n "${enable_live555}"], [
1659         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1660       ])
1661     ], [
1662       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1663       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1664       AS_IF([test "${SYS}" = "mingw32"], [
1665         # add ws2_32 for closesocket, select, recv
1666         other_libs="$other_libs -lws2_32"
1667       ])
1668
1669       dnl We need to check for pic because live555 don't provide shared libs
1670       dnl and we want to build a plugins so we need -fPIC on some arch.
1671       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1672       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1673       AC_CHECK_LIB(liveMedia_pic, main, [
1674         VLC_ADD_PLUGIN([live555])
1675         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1676       ],[
1677         AC_CHECK_LIB(liveMedia, main, [
1678           VLC_ADD_PLUGIN([live555])
1679           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1680         ],[],[${other_libs}])
1681       ],[${other_libs_pic}])
1682     ])
1683     VLC_RESTORE_FLAGS
1684     AC_LANG_POP(C++)
1685   ])
1686 ])
1687
1688 dnl
1689 dnl IIDC and DV FireWire input modules
1690 dnl
1691 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1692 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1693
1694 dnl
1695 dnl - linsys modules: access module check for libzvbi
1696 dnl
1697 AC_ARG_ENABLE(linsys,
1698   [AS_HELP_STRING([--enable-linsys],
1699     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1700 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1701   VLC_ADD_PLUGIN([linsys_hdsdi])
1702   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1703     VLC_ADD_PLUGIN([linsys_sdi])
1704   ], [
1705     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1706   ])
1707 ])
1708
1709 dnl
1710 dnl dvdread module: check for libdvdread
1711 dnl
1712 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1713
1714 dnl
1715 dnl libdvdnav plugin
1716 dnl
1717 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1718
1719 dnl
1720 dnl  Blu-ray Disc Support with libbluray
1721 dnl
1722 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.3.0], (libbluray for Blu-ray disc support ) )
1723
1724 dnl
1725 dnl  OpenCV wrapper and example filters
1726 dnl
1727 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1728
1729
1730 dnl
1731 dnl  libsmbclient plugin
1732 dnl
1733 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1734 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([access_smb]) ])
1735
1736 dnl
1737 dnl  liBDSM access module
1738 dnl
1739 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm], [libdsm SMB/CIFS access/sd module], [auto])
1740
1741 dnl
1742 dnl sftp access support
1743 dnl
1744 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1745
1746 dnl
1747 dnl  Video4Linux 2
1748 dnl
1749 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1750   [disable Video4Linux version 2 (default auto)])])
1751 have_v4l2="no"
1752 AS_IF([test "$enable_v4l2" != "no"], [
1753   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1754     have_v4l2="yes"
1755   ])
1756 ])
1757 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1758
1759 dnl
1760 dnl special access module for Blackmagic SDI cards
1761 dnl
1762 AC_ARG_ENABLE(decklink,
1763   [AS_HELP_STRING([--disable-decklink],
1764     [disable Blackmagic DeckLink SDI input (default auto)])])
1765 AC_ARG_WITH(decklink_sdk,
1766   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1767     [                        location of Blackmagic DeckLink SDI SDK])])
1768 have_decklink=no
1769 if test "${enable_decklink}" != "no"
1770 then
1771   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1772   then
1773     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1774   fi
1775   VLC_SAVE_FLAGS
1776   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1777   AC_LANG_PUSH(C++)
1778   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1779       have_decklink=yes
1780   ], [
1781       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1782   ])
1783   AC_LANG_POP(C++)
1784   VLC_RESTORE_FLAGS
1785 fi
1786 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1787
1788
1789 dnl
1790 dnl  gnomeVFS access module
1791 dnl
1792 PKG_ENABLE_MODULES_VLC([GNOMEVFS], [gnomevfs], [gnome-vfs-2.0], [GnomeVFS access module], [auto])
1793
1794 dnl
1795 dnl  VCDX modules
1796 dnl
1797 PKG_ENABLE_MODULES_VLC([VCDX], [vcdx], [libcdio >= 0.78.2 libiso9660 >= 0.72 libvcdinfo >= 0.7.22], [navigate VCD with libvcdinfo], [no])
1798
1799 dnl
1800 dnl  Built-in CD-DA and VCD module
1801 dnl
1802 AC_ARG_ENABLE(vcd,
1803   [AS_HELP_STRING([--disable-vcd],
1804     [disable built-in VCD and CD-DA support (default enabled)])])
1805
1806 AC_ARG_ENABLE(libcddb,
1807   [AS_HELP_STRING([--disable-libcddb],
1808     [disable CDDB for Audio CD (default enabled)])])
1809
1810 if test "${enable_vcd}" != "no"
1811 then
1812   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1813   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1814     AC_MSG_RESULT(yes)
1815     VLC_ADD_PLUGIN([vcd cdda])
1816   ],[
1817     AC_MSG_RESULT(no)
1818   ])
1819
1820   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1821   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1822     AC_MSG_RESULT(yes)
1823     VLC_ADD_PLUGIN([vcd cdda])
1824     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1825   ],[
1826     AC_MSG_RESULT(no)
1827   ])
1828
1829   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1830   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1831     AC_MSG_RESULT(yes)
1832     VLC_ADD_PLUGIN([vcd cdda])
1833     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1834   ],[
1835     AC_MSG_RESULT(no)
1836   ])
1837
1838   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1839   then
1840     VLC_ADD_PLUGIN([vcd cdda])
1841   fi
1842
1843   if test "$enable_libcddb" != "no"; then
1844     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1845       HAVE_LIBCDDB=yes
1846       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1847       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1848       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1849       ],:
1850       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1851       HAVE_LIBCDDB=no])
1852   fi
1853 fi
1854
1855 dnl
1856 dnl Linux DVB
1857 dnl
1858 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1859   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1860 [#include <linux/dvb/version.h>
1861 #if (DVB_API_VERSION < 5)
1862 # error Linux DVB API v3.2 and older are not supported.
1863 #endif
1864 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1865 # error Linux DVB API v5.0 is unsupported. Please update.
1866 #endif
1867 ]])], [
1868   ac_cv_linux_dvb_5_1=yes
1869 ], [
1870   ac_cv_linux_dvb_5_1=no
1871 ])])
1872 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1873
1874 dnl
1875 dnl  Screen capture module
1876 dnl
1877 AC_ARG_ENABLE(screen,
1878   [AS_HELP_STRING([--enable-screen],
1879     [disable screen capture (default enabled)])])
1880 if test "${enable_screen}" != "no"; then
1881   if test "${SYS}" = "darwin"; then
1882     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1883       VLC_ADD_PLUGIN([screen])
1884     ])
1885   fi
1886 fi
1887 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1888
1889 dnl
1890 dnl  VNC/RFB access module
1891 dnl
1892 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1893
1894 dnl  RDP/Remote Desktop access module
1895 dnl
1896 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1897
1898 dnl
1899 dnl  Real RTSP plugin
1900 dnl
1901 AC_ARG_ENABLE(realrtsp,
1902   [  --enable-realrtsp       Real RTSP module (default disabled)])
1903 if test "${enable_realrtsp}" = "yes"; then
1904   VLC_ADD_PLUGIN([access_realrtsp])
1905 fi
1906
1907 dnl
1908 dnl MacOS eyeTV
1909 AC_ARG_ENABLE(macosx-eyetv,
1910   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1911 if test "x${enable_macosx_eyetv}" != "xno" &&
1912   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1913 then
1914   VLC_ADD_PLUGIN([access_eyetv])
1915 fi
1916
1917 dnl
1918 dnl QTKit
1919 AC_ARG_ENABLE(macosx-qtkit,
1920   [  --enable-macosx-qtkit Mac OS X qtcapture (video) and qtsound (audio) module (default enabled on Mac OS X)])
1921 if test "x${enable_macosx_qtkit}" != "xno" &&
1922   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1923 then
1924   VLC_ADD_PLUGIN([qtcapture])
1925   VLC_ADD_PLUGIN([qtsound])
1926 fi
1927 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1928
1929 dnl
1930 dnl AVFoundation
1931 AC_SUBST(have_avfoundation, ["no"])
1932 AC_ARG_ENABLE(macosx-avfoundation,
1933   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1934 if test "x${enable_macosx_avfoundation}" != "xno" &&
1935   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1936 then
1937   SAVED_LIBS="${LIBS}"
1938   LIBS="-framework AVFoundation"
1939   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1940   LIBS="${SAVED_LIBS}"
1941   if test "${have_avfoundation}" != "no"
1942   then
1943     VLC_ADD_PLUGIN([avcapture])
1944   fi
1945 fi
1946 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1947
1948 dnl
1949 dnl  DCP plugin (using asdcplib)
1950 dnl
1951 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1952 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1953
1954 dnl
1955 dnl  Demux plugins
1956 dnl
1957
1958 EXTEND_HELP_STRING([Mux/Demux plugins:])
1959
1960 dnl
1961 dnl  libdvbpsi check for ts mux/demux
1962 dnl
1963 have_dvbpsi="no"
1964 PKG_WITH_MODULES([DVBPSI], [libdvbpsi], [have_dvbpsi="yes"])
1965 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1966
1967
1968 dnl
1969 dnl  GME demux plugin
1970 dnl
1971 AC_ARG_ENABLE(gme,
1972   [AS_HELP_STRING([--enable-gme],
1973     [use Game Music Emu (default auto)])])
1974 AS_IF([test "${enable_gme}" != "no"], [
1975   AC_CHECK_HEADER([gme/gme.h], [
1976     VLC_ADD_LIBS([gme], [-lgme])
1977     VLC_ADD_PLUGIN([gme])
1978   ], [
1979     AS_IF([test "x${enable_gme}" != "x"], [
1980       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
1981     ])
1982   ])
1983 ])
1984
1985
1986 dnl
1987 dnl  SIDPlay plugin
1988 dnl
1989 AC_ARG_ENABLE(sid,
1990     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
1991 AS_IF([test "${enable_sid}" != "no"], [
1992     PKG_CHECK_MODULES(SID, [libsidplay2], [
1993         AC_LANG_PUSH(C++)
1994         oldCPPFLAGS="$CPPFLAGS"
1995         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
1996         AC_CHECK_HEADER([sidplay/builders/resid.h], [
1997             VLC_ADD_PLUGIN([sid])
1998             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
1999             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2000         ], [
2001             AS_IF([test -n "${enable_sid}"],
2002                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2003                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2004                 )
2005         ])
2006         CPPFLAGS="$oldCPPFLAGS"
2007         AC_LANG_POP(C++)
2008     ], [
2009         AS_IF([test "x${enable_sid}" = "xyes"],
2010             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2011             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2012             )
2013     ])
2014 ])
2015
2016
2017 dnl
2018 dnl  ogg demux plugin
2019 dnl
2020 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto])
2021 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2022     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2023 ],[true])
2024 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2025 if test "${enable_sout}" != "no"; then
2026     PKG_ENABLE_MODULES_VLC([MUX_OGG], [], [ogg >= 1.0], [Ogg mux support], [auto])
2027 dnl Check for libshout
2028     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2029 fi
2030
2031 dnl
2032 dnl  matroska demux plugin
2033 dnl
2034 AC_ARG_ENABLE(mkv,
2035   [AS_HELP_STRING([--disable-mkv],
2036     [do not use libmatroska (default auto)])])
2037 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2038   AC_LANG_PUSH(C++)
2039   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2040     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2041     AC_EGREP_CPP(yes,
2042       [#include <ebml/EbmlVersion.h>
2043        #ifdef LIBEBML_VERSION
2044        #if LIBEBML_VERSION >= 0x010000
2045        yes
2046        #endif
2047        #endif],
2048       [AC_MSG_RESULT([yes])
2049         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2050           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2051           AC_EGREP_CPP(yes,
2052             [#include <matroska/KaxVersion.h>
2053              #ifdef LIBMATROSKA_VERSION
2054              #if LIBMATROSKA_VERSION >= 0x010000
2055              yes
2056              #endif
2057              #endif],
2058             [AC_MSG_RESULT([yes])
2059               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2060               AC_CHECK_LIB(ebml_pic, main, [
2061                 VLC_ADD_PLUGIN([mkv])
2062                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2063               ],[
2064                 AC_CHECK_LIB(ebml, main, [
2065                   VLC_ADD_PLUGIN([mkv])
2066                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2067                 ])
2068               ])
2069             ], [
2070               AC_MSG_RESULT([no])
2071               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2072           ])
2073         ])
2074       ],
2075       [AC_MSG_RESULT([no])
2076         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2077     ])
2078   ])
2079   AC_LANG_POP(C++)
2080 fi
2081
2082 dnl
2083 dnl  modplug demux plugin
2084 dnl
2085 AC_ARG_ENABLE(mod,
2086   [AS_HELP_STRING([--disable-mod],
2087     [do not use libmodplug (default auto)])])
2088 if test "${enable_mod}" != "no" ; then
2089     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2090           VLC_ADD_PLUGIN([mod])
2091           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2092           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2093           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2094     ],[
2095        AS_IF([test -n "${enable_mod}"],
2096          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2097          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2098     ])
2099 fi
2100
2101 dnl
2102 dnl  mpc demux plugin
2103 dnl
2104 AC_ARG_ENABLE(mpc,
2105   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2106 if test "${enable_mpc}" != "no"
2107 then
2108   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2109     VLC_ADD_PLUGIN([mpc])
2110     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2111     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2112     VLC_ADD_PLUGIN([mpc])
2113     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2114 fi
2115
2116 dnl
2117 dnl  Codec plugins
2118 dnl
2119
2120 EXTEND_HELP_STRING([Codec plugins:])
2121
2122 dnl
2123 dnl wmafixed plugin
2124 dnl
2125 AC_ARG_ENABLE(wma-fixed,
2126   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2127 if test "${enable_wma_fixed}" = "yes"
2128 then
2129   VLC_ADD_PLUGIN([wma_fixed])
2130 fi
2131
2132 dnl
2133 dnl shine encoder plugin
2134 dnl
2135 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2136
2137
2138 dnl
2139 dnl openmax il codec plugin
2140 dnl
2141 AC_ARG_ENABLE(omxil,
2142   [  --enable-omxil          openmax il codec module (default disabled)])
2143 if test "${enable_omxil}" = "yes"
2144 then
2145   VLC_ADD_PLUGIN([omxil])
2146 fi
2147
2148 dnl
2149 dnl openmax il vout plugin
2150 dnl
2151 AC_ARG_ENABLE(omxil-vout,
2152   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2153 if test "${enable_omxil_vout}" = "yes"
2154 then
2155   VLC_ADD_PLUGIN([omxil_vout])
2156 fi
2157
2158 dnl
2159 dnl raspberry pi openmax il configuration
2160 dnl
2161 AC_ARG_ENABLE(rpi-omxil,
2162   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2163 if test "${enable_rpi_omxil}" = "yes"
2164 then
2165   VLC_ADD_PLUGIN([omxil omxil_vout])
2166   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2167 fi
2168
2169 dnl
2170 dnl CrystalHD codec plugin
2171 dnl
2172 AC_ARG_ENABLE(crystalhd,
2173   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2174 if test "${enable_crystalhd}" != "no"; then
2175     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2176       VLC_ADD_PLUGIN([crystalhd])
2177       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2178     ],[
2179       if test "${SYS}" = "mingw32" ; then
2180         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2181           VLC_ADD_PLUGIN([crystalhd])
2182           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2183             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2184             ])
2185         ],[
2186           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2187                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2188                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2189         ],[#define __LINUX_USER__
2190                #include <libcrystalhd/bc_dts_types.h>
2191         ])
2192       fi
2193     ],[
2194        #include <libcrystalhd/bc_dts_types.h>
2195       ])
2196 fi
2197
2198 dnl
2199 dnl  mad plugin
2200 dnl
2201 AC_ARG_ENABLE(mad,
2202   [  --enable-mad            libmad module (default enabled)])
2203 if test "${enable_mad}" != "no"
2204 then
2205   AC_ARG_WITH(mad,
2206     [  --with-mad=PATH         path to libmad],[],[])
2207   if test "${with_mad}" != "no" -a -n "${with_mad}"
2208   then
2209     VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${with_mad}/include])
2210     VLC_ADD_LIBS([mpgatofixed32],[-L${with_mad}/lib])
2211   fi
2212
2213   AC_ARG_WITH(mad-tree,
2214     [  --with-mad-tree=PATH    mad tree for static linking],[],[])
2215   if test "${with_mad_tree}" != "no" -a -n "${with_mad_tree}"
2216   then
2217     real_mad_tree="`cd ${with_mad_tree} 2>/dev/null && pwd`"
2218     if test -z "${real_mad_tree}"
2219     then
2220       dnl  The given directory can't be found
2221       AC_MSG_RESULT(no)
2222       AC_MSG_ERROR([${with_mad_tree} directory does not exist])
2223     fi
2224     dnl  Use a custom libmad
2225     AC_MSG_CHECKING(for mad.h in ${real_mad_tree})
2226     if test -f ${real_mad_tree}/mad.h
2227     then
2228       AC_MSG_RESULT(yes)
2229       VLC_ADD_CPPFLAGS([mpgatofixed32],[-I${real_mad_tree}])
2230       VLC_ADD_LIBS([mpgatofixed32],[-L${real_mad_tree}/.libs])
2231       VLC_SAVE_FLAGS
2232       LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2233       AC_CHECK_LIB(mad, mad_bit_init, [
2234         VLC_ADD_PLUGIN([mpgatofixed32])
2235         VLC_ADD_LIBS([mpgatofixed32],[-lmad])
2236         ],[ AC_MSG_ERROR([the specified tree has not been compiled ])
2237       ],[])
2238       VLC_RESTORE_FLAGS
2239     else
2240       AC_MSG_RESULT(no)
2241       AC_MSG_ERROR([the specified tree does not have mad.h])
2242     fi
2243   else
2244     VLC_SAVE_FLAGS
2245     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_mpgatofixed32}"
2246     LDFLAGS="${LDFLAGS} ${LIBS_mpgatofixed32}"
2247     AC_CHECK_HEADERS(mad.h, ,
2248       [ AC_MSG_ERROR([Could not find libmad on your system: you may get it from http://www.underbit.com/products/mad/. Alternatively you can use --disable-mad to disable the mad plugin.]) ])
2249     AC_CHECK_LIB(mad, mad_bit_init, [
2250       VLC_ADD_PLUGIN([mpgatofixed32])
2251       VLC_ADD_LIBS([mpgatofixed32],[-lmad])],
2252       [ AC_MSG_ERROR([Cannot find libmad library...]) ])
2253     VLC_RESTORE_FLAGS
2254   fi
2255 fi
2256
2257
2258 AC_ARG_ENABLE(merge-ffmpeg,
2259 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2260   enable_merge_ffmpeg="no"
2261 ])
2262 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2263
2264 AC_MSG_CHECKING([for libavutil variant])
2265 PKG_CHECK_EXISTS([libavutil], [
2266   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2267   libavutil_micro="${libavutil_version##*.}"
2268   AS_IF([test ${libavutil_micro} -le 99], [
2269     avfork="libav"
2270   ], [
2271     avfork="ffmpeg"
2272   ])
2273 ], [
2274   avfork="none"
2275 ])
2276 AC_MSG_RESULT([${avfork}])
2277
2278 dnl
2279 dnl gstreamer stuff
2280 dnl
2281 AC_ARG_ENABLE(gst-decode,
2282   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2283
2284 have_gst_decode="no"
2285 AS_IF([test "${enable_gst_decode}" != "no"], [
2286   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2287     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2288       have_gst_decode="yes"
2289     ], [
2290       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2291     ])
2292   ], [
2293     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2294   ])
2295 ])
2296 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2297
2298 dnl
2299 dnl  avcodec decoder/encoder plugin
2300 dnl
2301 AC_ARG_ENABLE(avcodec,
2302 [  --enable-avcodec        libavcodec codec (default enabled)])
2303 AS_IF([test "${enable_avcodec}" != "no"], [
2304   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 54.25.0 libavutil >= 52.0.0], [
2305     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2306     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2307     dnl ])
2308     VLC_SAVE_FLAGS
2309     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2310     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2311     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2312     AC_CHECK_HEADERS(libavutil/avutil.h)
2313     VLC_RESTORE_FLAGS
2314     have_avcodec="yes"
2315   ],[
2316     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2317   ])
2318 ], [
2319   have_avcodec="no"
2320 ])
2321 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2322
2323 dnl
2324 dnl libva needs avcodec
2325 dnl
2326 AC_ARG_ENABLE(libva,
2327   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2328
2329 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2330   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2331 ])
2332
2333 have_vaapi="no"
2334 have_vaapi_drm="no"
2335 have_vaapi_x11="no"
2336 AS_IF([test "${enable_libva}" != "no"], [
2337   PKG_CHECK_EXISTS([libva], [
2338     have_vaapi="yes"
2339   ], [
2340     AS_IF([test -n "${enable_libva}"], [
2341       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2342     ], [
2343       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2344     ])
2345   ])
2346   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2347     have_vaapi_drm="yes"
2348   ], [
2349     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2350   ])
2351   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2352     have_vaapi_x11="yes"
2353   ], [
2354     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2355   ])
2356 ])
2357 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2358 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2359
2360 have_avcodec_vaapi="no"
2361 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2362   VLC_SAVE_FLAGS
2363   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2364   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2365   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2366     AC_MSG_NOTICE([VAAPI acceleration activated])
2367     have_avcodec_vaapi="yes"
2368   ],[
2369     AS_IF([test -n "${enable_libva}"], [
2370       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2371     ], [
2372       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2373     ])
2374   ])
2375   VLC_RESTORE_FLAGS
2376 ])
2377 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2378
2379 dnl
2380 dnl dxva2 needs avcodec
2381 dnl
2382 AC_ARG_ENABLE(dxva2,
2383   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2384
2385 have_avcodec_dxva2="no"
2386 AS_IF([test "${enable_dxva2}" != "no"], [
2387   if test "${SYS}" = "mingw32"; then
2388   AS_IF([test "x${have_avcodec}" = "xyes"], [
2389     AC_CHECK_HEADERS(dxva2api.h,
2390       [
2391         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2392            AC_MSG_NOTICE([DxVA2 acceleration activated])
2393            have_avcodec_dxva2="yes"
2394         ],[
2395     AS_IF([test "${enable_dxva2}" = "yes"],
2396           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2397               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2398         ], [#undef _WIN32_WINNT
2399             /* DXVA2 is only available in Vista and above */
2400             #define _WIN32_WINNT 0x600])
2401       ],[
2402     AS_IF([test "${enable_dxva2}" = "yes"],
2403               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2404               [AC_MSG_WARN([dxva2api.h not found])])
2405       ])
2406   ],[
2407     AS_IF([test "x${enable_dxva2}" != "x"], [
2408       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2409     ])
2410   ])
2411   fi
2412 ])
2413 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2414
2415 dnl
2416 dnl vda needs avcodec
2417 dnl
2418 AC_ARG_ENABLE(vda,
2419   [  --enable-vda          VDA  support (default auto)])
2420
2421 have_avcodec_vda="no"
2422 AS_IF([test "${enable_vda}" != "no"], [
2423   if test "${SYS}" = "darwin"; then
2424   AS_IF([test "x${have_avcodec}" = "xyes"], [
2425     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2426       [
2427         AC_CHECK_HEADERS(libavcodec/vda.h, [
2428            have_avcodec_vda="yes"
2429         ],[
2430         AS_IF([test "${enable_vda}" = "yes"],
2431               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2432               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2433         ])
2434   ],[
2435         AS_IF([test "${enable_vda}" = "yes"],
2436               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2437               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2438       ])
2439   ],[
2440     AS_IF([test "x${enable_vda}" != "x"], [
2441       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2442     ])
2443  ])
2444  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2445      SAVE_LIBS=$LIBS
2446      LIBS="$LIBS $AVCODEC_LIBS"
2447      AC_CHECK_FUNCS([av_vda_alloc_context])
2448      LIBS=$SAVE_LIBS
2449  ])
2450  fi
2451 ])
2452 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2453
2454 dnl
2455 dnl  avformat demuxer/muxer plugin
2456 dnl
2457
2458 AC_ARG_ENABLE(avformat,
2459 [  --enable-avformat       libavformat containers (default enabled)],, [
2460   enable_avformat="${have_avcodec}"
2461 ])
2462 have_avformat="no"
2463 AS_IF([test "${enable_avformat}" != "no"], [
2464   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2465       have_avformat="yes"
2466       VLC_SAVE_FLAGS
2467       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2468       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2469       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2470       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2471       AC_CHECK_HEADERS(libavutil/avutil.h)
2472       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2473         have_avformat="no"
2474       ])
2475       VLC_RESTORE_FLAGS
2476     ],[
2477       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2478   ])
2479 ])
2480 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2481
2482 dnl
2483 dnl  swscale image scaling and conversion plugin
2484 dnl
2485
2486 AC_ARG_ENABLE(swscale,
2487   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2488           (default enabled)]))
2489 if test "${enable_swscale}" != "no"
2490 then
2491   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2492     [
2493       VLC_SAVE_FLAGS
2494       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2495       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2496       AC_CHECK_HEADERS(libswscale/swscale.h)
2497       VLC_ADD_PLUGIN([swscale])
2498       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2499       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2500       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2501         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2502       ])
2503       VLC_RESTORE_FLAGS
2504     ],[
2505       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2506   ])
2507 fi
2508
2509 dnl
2510 dnl  postproc plugin
2511 dnl
2512
2513 AC_ARG_ENABLE(postproc,
2514 [  --enable-postproc       libpostproc image post-processing (default auto)])
2515 if test "${enable_postproc}" != "no"
2516 then
2517   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2518     [
2519       VLC_SAVE_FLAGS
2520       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2521       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2522       AC_CHECK_HEADERS(postproc/postprocess.h)
2523       VLC_ADD_PLUGIN([postproc])
2524       VLC_ADD_LIBS([postproc],[$POSTPROC_LIBS $AVUTIL_LIBS])
2525       VLC_ADD_CFLAGS([postproc],[$POSTPROC_CFLAGS $AVUTIL_CFLAGS])
2526       VLC_RESTORE_FLAGS
2527     ],[
2528       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2529   ])
2530 fi
2531
2532 dnl
2533 dnl  faad decoder plugin
2534 dnl
2535 AC_ARG_ENABLE(faad,
2536 [  --enable-faad           faad codec (default auto)])
2537 if test "${enable_faad}" != "no"; then
2538   AC_ARG_WITH(faad-tree,  [  --with-faad-tree=PATH   faad tree for static linking])
2539   if test -n "${with_faad_tree}"; then
2540     AC_MSG_CHECKING(for libfaad.a in ${with_faad_tree})
2541     real_faad_tree="`cd ${with_faad_tree} 2>/dev/null && pwd`"
2542     if test -z "${real_faad_tree}"; then
2543       dnl  The given directory can't be found
2544       AC_MSG_RESULT(no)
2545       AC_MSG_ERROR([cannot cd to ${with_faad_tree}])
2546     fi
2547     if test -f "${real_faad_tree}/libfaad/.libs/libfaad.a"; then
2548       dnl  Use the custom faad
2549       AC_MSG_RESULT(${real_faad_tree}/libfaad/.libs/libfaad.a)
2550       VLC_ADD_PLUGIN([faad])
2551       VLC_ADD_LIBS([faad],[${real_faad_tree}/libfaad/.libs/libfaad.a])
2552       VLC_ADD_CPPFLAGS([faad],[-I${real_faad_tree}/include])
2553     else
2554       dnl  The given libfaad wasn't built
2555       AC_MSG_RESULT(no)
2556       AC_MSG_ERROR([cannot find ${real_faad_tree}/libfaad/.libs/libfaad.a, make sure you compiled libfaad in ${with_faad_tree}])
2557     fi
2558   else
2559     VLC_SAVE_FLAGS
2560     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_faad}"
2561     LDFLAGS="${LDFLAGS} ${LIBS_faad}"
2562     AC_CHECK_HEADERS(faad.h,
2563       [ AC_CHECK_LIB(faad, faacDecOpen, [
2564           VLC_ADD_PLUGIN([faad])
2565           VLC_ADD_LIBS([faad],[-lfaad]) ], [
2566             AC_CHECK_LIB(faad, NeAACDecOpen, [
2567               VLC_ADD_PLUGIN([faad])
2568               VLC_ADD_LIBS([faad],[-lfaad]) ], [
2569                 AS_IF([test "${enable_faad}" = "yes"],
2570                 [ AC_MSG_ERROR([Cannot find libfaad library...]) ],
2571                 [ AC_MSG_WARN([Cannot find libfaad library...]) ]) ]) ])
2572       ] , [ AS_IF([test "${enable_faad}" = "yes"],
2573         [ AC_MSG_ERROR([Cannot find development headers for libfaad...]) ],
2574         [ AC_MSG_WARN([Cannot find development headers for libfaad...]) ]) ])
2575     VLC_RESTORE_FLAGS
2576   fi
2577 fi
2578
2579 dnl
2580 dnl libvpx decoder plugin
2581 dnl
2582 AC_ARG_ENABLE(vpx,
2583     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 decoder (default auto)]))
2584 AS_IF([test "${enable_vpx}" != "no"],[
2585     PKG_CHECK_MODULES([VPX], [vpx] , [
2586         VLC_ADD_PLUGIN([vpx])
2587         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2588         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2589         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2590             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2591         ], [], [${VPX_LIBS}])
2592         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2593             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2594         ], [], [${VPX_LIBS}])
2595     ], [
2596     AS_IF([test "${enable_vpx}" = "yes"],[
2597         AC_MSG_ERROR([libvpx was not found])
2598     ])])
2599 ])
2600
2601 dnl
2602 dnl twolame encoder plugin
2603 dnl
2604 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2605
2606 dnl
2607 dnl fdk-aac encoder plugin
2608 dnl
2609 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2610
2611 dnl
2612 dnl  QuickTime plugin
2613 dnl
2614 AC_ARG_ENABLE(quicktime,
2615   [  --enable-quicktime      QuickTime module (deprecated)])
2616 if test "${enable_quicktime}" = "yes"; then
2617   if test "${SYS}" = "mingw32"; then
2618     VLC_ADD_PLUGIN([quicktime])
2619   else
2620   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2621     [ VLC_ADD_PLUGIN([quicktime])
2622       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2623     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2624   fi
2625 fi
2626
2627 dnl
2628 dnl A52/AC3 decoder plugin
2629 dnl
2630 AC_ARG_ENABLE(a52,
2631   [  --enable-a52            A/52 support with liba52 (default enabled)])
2632 if test "${enable_a52}" != "no"
2633 then
2634   AC_ARG_WITH(a52,
2635     [  --with-a52=PATH         a52 headers and libraries])
2636   AC_ARG_WITH(a52-tree,
2637     [  --with-a52-tree=PATH    a52dec tree for static linking ],[],[])
2638   if test "${with_a52_tree}" != "no" -a -n "${with_a52_tree}"
2639   then
2640     real_a52_tree="`cd ${with_a52_tree} 2>/dev/null && pwd`"
2641     if test -z "${real_a52_tree}"
2642     then
2643       dnl  The given directory can't be found
2644       AC_MSG_RESULT(no)
2645       AC_MSG_ERROR([${with_a52_tree} directory does not exist])
2646     fi
2647     dnl  Use a custom a52dec
2648     AC_MSG_CHECKING(for a52.h in ${real_a52_tree}/include)
2649     if test -f ${real_a52_tree}/include/a52.h
2650     then
2651       AC_MSG_RESULT(yes)
2652       VLC_ADD_CPPFLAGS([a52tofloat32],[-I${real_a52_tree}])
2653       VLC_ADD_LIBS([a52tofloat32],[-L${real_a52_tree}/liba52/.libs])
2654       VLC_SAVE_FLAGS
2655       LDFLAGS="${LDFLAGS} ${LIBS_a52tofloat32}"
2656       AC_CHECK_LIB(a52, a52_free, [
2657         VLC_ADD_PLUGIN([a52tofloat32])
2658         VLC_ADD_CPPFLAGS([a52tofloat32],[-DUSE_A52DEC_TREE])
2659         VLC_ADD_LIBS([a52tofloat32],[-la52])
2660         ],[
2661         if test -f ${real_a52_tree}/liba52/.libs/liba52.a
2662         then
2663           AC_MSG_ERROR([make sure you have at least a52dec-0.7.3 ($real_a52_tree)])
2664         else
2665           AC_MSG_ERROR([the specified tree has not been compiled])
2666         fi
2667       ])
2668     else
2669       AC_MSG_RESULT(no)
2670       AC_MSG_ERROR([the specified tree does not have a52.h])
2671     fi
2672   else
2673     if test -z "${with_a52}"
2674     then
2675       LDFLAGS_test=""
2676       CPPFLAGS_test=""
2677     else
2678       LDFLAGS_test="-L${with_a52}/lib"
2679       CPPFLAGS_test="-I${with_a52}/include"
2680     fi
2681     VLC_SAVE_FLAGS
2682     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2683     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2684     AC_CHECK_HEADERS(a52dec/a52.h, [
2685       AC_CHECK_LIB(a52, a52_free, [
2686         VLC_ADD_PLUGIN([a52tofloat32])
2687         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2688         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2689       ],[
2690         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2691         ], [$LIBM])
2692     ],[
2693       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2694     ])
2695     VLC_RESTORE_FLAGS
2696   fi
2697 fi
2698
2699 dnl
2700 dnl DTS Coherent Acoustics decoder plugin
2701 dnl
2702 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2703
2704 dnl
2705 dnl  Flac plugin
2706 dnl
2707 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2708
2709 dnl
2710 dnl  Libmpeg2 plugin
2711 dnl
2712 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2713
2714 dnl
2715 dnl  Vorbis plugin
2716 dnl
2717 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2718
2719 dnl
2720 dnl  Tremor plugin
2721 dnl
2722 AC_ARG_ENABLE(tremor,
2723   [  --enable-tremor         Tremor decoder support (default disabled)])
2724 if test "${enable_tremor}" = "yes"
2725 then
2726   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2727     VLC_ADD_PLUGIN([tremor])
2728    ],[])
2729 fi
2730
2731 dnl
2732 dnl  Speex plugins
2733 dnl
2734 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2735 have_speexdsp="no"
2736 AS_IF([test "${enable_speex}" != "no"], [
2737   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2738     have_speexdsp="yes"
2739   ], [
2740     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2741   ])
2742 ])
2743 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2744
2745 dnl
2746 dnl  Opus plugin
2747 dnl
2748 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2749
2750 dnl
2751 dnl  theora decoder plugin
2752 dnl
2753 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2754
2755 dnl
2756 dnl  Daala decoder plugin
2757 dnl
2758 PKG_ENABLE_MODULES_VLC([DAALA], [], [ogg daaladec daalaenc], [experimental daala codec], [disabled])
2759
2760 dnl
2761 dnl  schroedinger decoder plugin (for dirac format video)
2762 dnl
2763 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2764
2765 dnl
2766 dnl  PNG decoder module
2767 dnl
2768 AC_ARG_ENABLE(png,
2769   [  --enable-png            PNG support (default enabled)])
2770 AS_IF([test "${enable_png}" != "no"], [
2771 AC_CHECK_HEADERS(png.h, [
2772   VLC_SAVE_FLAGS
2773   LDFLAGS="${LDFLAGS} -lz $LIBM"
2774   AC_CHECK_LIB(png, png_set_rows, [
2775     VLC_ADD_PLUGIN([png])
2776   ], [], [-lz $LIBM])
2777   VLC_RESTORE_FLAGS
2778   ])
2779 ])
2780
2781 dnl
2782 dnl  JPEG decoder module
2783 dnl
2784 AC_ARG_ENABLE(jpeg,
2785   [  --enable-jpeg           JPEG support (default enabled)])
2786 AS_IF([test "${enable_jpeg}" != "no"], [
2787 AC_CHECK_HEADERS(jpeglib.h, [
2788   VLC_ADD_PLUGIN([jpeg])
2789   ])
2790 ])
2791
2792 dnl
2793 dnl H262 encoder plugin (lib262)
2794 dnl
2795 AC_ARG_ENABLE(x262,
2796   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2797 if test "${enable_x262}" != "no"; then
2798 AC_ARG_WITH(x262-tree,
2799   [ --with-x262-tree=PATH      H262 encoding module with libx262 (static linking)],[],[])
2800   if test "${with_x262_tree}" != "no" -a -n "${with_x262_tree}"
2801   then
2802     real_x262_tree="̧`cd ${with_x262_tree} 2>/dev/null && pwd`"
2803     if test -z "${real_x262_tree}"
2804     then
2805       AC_MSG_RESULT(no)
2806       AC_MSG_ERROR([${with_x262_tree} directory does not exist])
2807     fi
2808     AC_MSG_CHECKING(for x262.h in ${real_x262_tree})
2809     if test -f ${with_x262_tree}/x262_config.h
2810     then
2811       VLC_ADD_PLUGIN([x262])
2812       VLC_ADD_CFLAGS([x262],[-I${with_x262_tree}])
2813       VLC_ADD_LIBS([x262],[-L${with_x262_tree} -lm -lpthread -lx262])
2814     else
2815       AC_MSG_RESULT(no)
2816       AC_MSG_ERROR([${with_x262_tree} doesnt have x262_config.h])
2817     fi
2818   else
2819     PKG_CHECK_MODULES(X262, x262, [
2820         VLC_ADD_PLUGIN([x262])
2821         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2822         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2823           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2824         ])
2825         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2826         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2827           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2828         fi
2829     ], [
2830        if test "${enable_x262}" = "yes"; then
2831         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2832        fi
2833     ])
2834   fi
2835 fi
2836
2837 dnl x265 encoder
2838 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2839
2840 dnl
2841 dnl H264 encoder plugin (10-bit lib264)
2842 dnl
2843 AC_ARG_ENABLE(x26410b,
2844   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2845 if test "${enable_x26410b}" != "no"; then
2846 AC_ARG_WITH(x26410b-tree,
2847   [ --with-x26410b-tree=PATH      H264 10-bit encoding module with libx264 (static linking)],[],[])
2848   if test "${with_x26410b_tree}" != "no" -a -n "${with_x26410b_tree}"
2849   then
2850     real_x26410b_tree="̧`cd ${with_x26410b_tree} 2>/dev/null && pwd`"
2851     if test -z "${real_x26410b_tree}"
2852     then
2853       AC_MSG_RESULT(no)
2854       AC_MSG_ERROR([${with_x26410b_tree} directory does not exist])
2855     fi
2856     AC_MSG_CHECKING(for x264.h in ${real_x26410b_tree})
2857     if test -f ${with_x26410b_tree}/x264_config.h
2858     then
2859       AC_MSG_RESULT(yes)
2860       AC_MSG_CHECKING(for 10-bit build of x264)
2861       if grep -q "BIT_DEPTH.*10"  ${with_x26410b_tree}/x264_config.h ;then
2862         AC_MSG_RESULT(yes)
2863         VLC_ADD_PLUGIN([x26410b])
2864         VLC_ADD_CFLAGS([x26410b],[-I${with_x26410b_tree}])
2865         VLC_ADD_LIBS([x26410b],[-L${with_x26410b_tree} -lm -lpthread -lx264])
2866       else
2867         AC_MSG_RESULT(no)
2868         AC_MSG_ERROR([${with_x26410b_tree} isnt build 10-bit])
2869       fi
2870     else
2871       AC_MSG_RESULT(no)
2872       AC_MSG_ERROR([${with_x26410b_tree} doesnt have x264_config.h])
2873     fi
2874   else
2875     PKG_CHECK_MODULES(X26410B, x26410b, [
2876         VLC_ADD_PLUGIN([x26410b])
2877         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2878         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2879           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2880         ])
2881         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2882         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2883           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2884         fi
2885     ], [
2886        if test "${enable_x26410b}" = "yes"; then
2887         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2888        fi
2889     ])
2890   fi
2891 fi
2892
2893
2894 dnl
2895 dnl H264 encoder plugin (using libx264)
2896 dnl
2897 AC_ARG_ENABLE(x264,
2898   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2899 if test "${enable_x264}" != "no"; then
2900   AC_ARG_WITH(x264-tree,
2901     [  --with-x264-tree=PATH   x264 tree for static linking ],[],[])
2902   if test "${with_x264_tree}" != "no" -a -n "${with_x264_tree}"
2903   then
2904     real_x264_tree="`cd ${with_x264_tree} 2>/dev/null && pwd`"
2905     if test -z "${real_x264_tree}"
2906     then
2907       dnl  The given directory can't be found
2908       AC_MSG_RESULT(no)
2909       AC_MSG_ERROR([${with_x264_tree} directory does not exist])
2910     fi
2911     dnl  Use a custom libx264
2912     AC_MSG_CHECKING(for x264.h in ${real_x264_tree})
2913     if test -f ${real_x264_tree}/x264.h
2914     then
2915       AC_MSG_RESULT(yes)
2916       VLC_ADD_CPPFLAGS([x264],[-I${real_x264_tree}])
2917       VLC_ADD_LIBS([x264],[-L${real_x264_tree}])
2918       PKG_CHECK_MODULES(X264,x264, [
2919         VLC_ADD_PLUGIN([x264])
2920         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2921         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2922         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2923           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2924         fi
2925       ],[
2926         AC_MSG_ERROR([the specified tree has not been compiled])
2927       ])
2928     else
2929       AC_MSG_RESULT(no)
2930       AC_MSG_ERROR([the specified tree does not have x264.h])
2931     fi
2932   else
2933       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2934         VLC_ADD_PLUGIN([x264])
2935         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2936
2937         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2938           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2939         ])
2940
2941         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2942         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2943           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2944         fi
2945       ],[
2946         if test "${enable_x264}" = "yes"; then
2947             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2948           fi
2949       ])
2950   fi
2951 fi
2952
2953 dnl
2954 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2955 dnl
2956 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2957
2958 dnl
2959 dnl libfluidsynth (MIDI synthetizer) plugin
2960 dnl
2961 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2962
2963 dnl
2964 dnl Teletext Modules
2965 dnl vbi decoder plugin (using libzbvi)
2966 dnl telx module
2967 dnl uncompatible
2968 dnl
2969 AC_ARG_ENABLE(zvbi,
2970   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2971                   libzvbi (default enabled)]))
2972 AC_ARG_ENABLE(telx,
2973   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2974                   zvbi) (default enabled if zvbi is absent)]))
2975
2976 AS_IF( [test "${enable_zvbi}" != "no"],[
2977     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2978         [
2979           VLC_ADD_PLUGIN([zvbi])
2980           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2981           AS_IF( [test "${enable_telx}" = "yes"],[
2982                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2983                   ])
2984         ],[
2985           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2986         ])
2987     ])
2988 AS_IF( [test "${enable_telx}" != "no" ],[
2989   VLC_ADD_PLUGIN([telx])
2990   ])
2991
2992 dnl
2993 dnl libass subtitle rendering module
2994 dnl
2995 AC_ARG_ENABLE(libass,
2996   [  --enable-libass         Subtitle support using libass (default enabled)])
2997 AS_IF( [test "${enable_libass}" != "no"], [
2998   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2999       [
3000         VLC_ADD_PLUGIN([libass])
3001
3002         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
3003           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
3004            VLC_ADD_LIBS([libass],[-lfontconfig])
3005        ])
3006       ],[
3007         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
3008       ])
3009   ])
3010
3011 dnl
3012 dnl ARIB subtitles rendering module
3013 dnl
3014 AC_ARG_ENABLE(aribsub,
3015   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
3016 AS_IF( [test "${enable_aribsub}" != "no" ],[
3017   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
3018       have_aribb24="yes"
3019       VLC_ADD_PLUGIN([aribsub])
3020       VLC_ADD_LIBS([aribsub],[-laribb24])
3021       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
3022     ],[
3023       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
3024       have_aribb24="no"
3025   ])
3026   AM_CONDITIONAL([HAVE_ARIBB24], [test "${have_aribb24}" = "yes"])
3027 ])
3028
3029 dnl
3030 dnl  kate decoder plugin
3031 dnl
3032 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
3033
3034 dnl
3035 dnl  tiger rendering for kate decoder plugin
3036 dnl
3037 AC_ARG_ENABLE(tiger,
3038 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
3039 AS_IF([test "${enable_tiger}" != "no"], [
3040   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
3041       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
3042         AS_IF([test -n "${enable_tiger}"], [
3043           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
3044         ])
3045   ])
3046 ])
3047
3048
3049 dnl
3050 dnl  Video plugins
3051 dnl
3052
3053 EXTEND_HELP_STRING([Video plugins:])
3054
3055 dnl
3056 dnl  OpenGL
3057 dnl
3058 PKG_CHECK_MODULES([EGL], [egl], [
3059   have_egl="yes"
3060 ], [
3061   have_egl="no"
3062 ])
3063 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3064
3065 have_gl="no"
3066 PKG_CHECK_MODULES([GL], [gl], [
3067   have_gl="yes"
3068 ], [
3069   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3070 #ifdef _WIN32
3071 # include <GL/glew.h>
3072 #endif
3073 #include <GL/gl.h>
3074 ]], [
3075     [int t0 = GL_TEXTURE0;]])
3076   ], [
3077     GL_CFLAGS=""
3078     have_gl="yes"
3079     AS_IF([test "${SYS}" != "mingw32"], [
3080       GL_LIBS="-lGL"
3081     ], [
3082       GL_LIBS="-lopengl32"
3083     ])
3084   ])
3085 ])
3086 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3087
3088 dnl OpenGL ES 2: depends on EGL 1.1
3089 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3090 dnl OpenGL ES 1: depends on EGL 1.0
3091 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3092
3093 dnl
3094 dnl  Xlib
3095 dnl
3096
3097 AC_PATH_XTRA()
3098 AC_CHECK_HEADERS(X11/Xlib.h)
3099
3100 dnl
3101 dnl  X C Bindings modules
3102 dnl
3103 AC_ARG_ENABLE(xcb,
3104   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3105   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" -a "${SYS}" != "symbian"], [
3106     enable_xcb="yes"
3107   ], [
3108     enable_xcb="no"
3109   ])
3110 ])
3111 AC_ARG_ENABLE(xvideo,
3112   [  --enable-xvideo         XVideo support (default enabled)],, [
3113     enable_xvideo="$enable_xcb"
3114 ])
3115 AC_ARG_ENABLE(glx,
3116   [  --enable-glx            OpenGL support through GLX (default enabled)],, [
3117   enable_glx="$enable_xcb"
3118 ])
3119
3120 have_xcb="no"
3121 have_xcb_keysyms="no"
3122 have_xcb_randr="no"
3123 have_xcb_xvideo="no"
3124 AS_IF([test "${enable_xcb}" != "no"], [
3125   dnl libxcb
3126   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3127   have_xcb="yes"
3128   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3129   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3130   PKG_CHECK_MODULES(XPROTO, [xproto])
3131
3132   AS_IF([test "${enable_xvideo}" != "no"], [
3133     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3134   ])
3135
3136   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3137
3138   dnl xcb-utils
3139   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3140     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3141   ])
3142 ])
3143 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3144 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3145 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3146 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3147
3148
3149 dnl
3150 dnl VDPAU needs X11
3151 dnl
3152 AC_ARG_ENABLE(vdpau,
3153   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3154 have_vdpau="no"
3155 AS_IF([test "${enable_vdpau}" != "no"], [
3156   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3157     have_vdpau="yes"
3158     AS_IF([test "${no_x}" = "yes"], [
3159       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3160     ])
3161   ], [
3162     AS_IF([test -n "${enable_vdpau}"], [
3163       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3164     ])
3165   ])
3166 ])
3167 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3168
3169 have_avcodec_vdpau="no"
3170 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3171   case "${avfork}" in
3172     libav) av_vdpau_ver="55.26.0" ;;
3173     ffmpeg) av_vdpau_ver="55.42.100" ;;
3174   esac
3175   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3176     have_avcodec_vdpau="yes"
3177     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3178   ], [
3179     AS_IF([test -n "${enable_vdpau}"], [
3180       AC_MSG_ERROR([libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3181     ], [
3182       AC_MSG_WARN([libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3183     ])
3184   ])
3185 ])
3186 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3187
3188
3189 dnl
3190 dnl  Wayland
3191 dnl
3192 AC_ARG_ENABLE(wayland,
3193   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3194 have_wayland="no"
3195 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3196
3197 AS_IF([test "${enable_wayland}" != "no"], [
3198   AC_MSG_CHECKING([for the Wayland scanner])
3199   AS_IF([test -z "$WAYLAND_SCANNER"], [
3200     PKG_CHECK_EXISTS([wayland-scanner], [
3201       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3202     ], [
3203       WAYLAND_SCANNER="wayland-scanner"
3204     ])
3205   ])
3206   AC_MSG_RESULT([$WAYLAND_SCANNER])
3207
3208   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3209     have_wayland="yes"
3210   ], [
3211     AS_IF([test -n "${enable_wayland}"], [
3212       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3213     ])
3214   ])
3215
3216   AS_IF([test "${have_egl}" = "yes"], [
3217     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3218       have_wayland_egl="yes"
3219     ], [
3220       AS_IF([test -n "${enable_wayland}"], [
3221         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3222       ])
3223     ])
3224   ])
3225 ])
3226 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3227 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3228
3229
3230 dnl
3231 dnl  SDL module
3232 dnl
3233 AC_ARG_ENABLE(sdl,
3234   [  --enable-sdl            SDL support (default enabled)])
3235 AC_ARG_ENABLE(sdl-image,
3236   [  --enable-sdl-image      SDL image support (default enabled)])
3237 if test "${enable_sdl}" != "no"
3238 then
3239    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3240       # SDL on Darwin is heavily patched and can only run SDL_image
3241       if test "${SYS}" != "darwin"; then
3242         VLC_ADD_PLUGIN([vout_sdl])
3243       fi
3244
3245       # SDL_image
3246       AS_IF([ test "${enable_sdl_image}" != "no"],[
3247         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3248           VLC_ADD_PLUGIN([sdl_image])],
3249           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3250           ])
3251       ])
3252    ],[
3253      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3254    ])
3255 fi
3256
3257 dnl
3258 dnl  freetype module
3259 dnl
3260 AC_ARG_ENABLE(freetype,
3261   [  --enable-freetype       freetype support   (default auto)])
3262 AC_ARG_ENABLE(fribidi,
3263   [  --enable-fribidi        fribidi support    (default auto)])
3264 AC_ARG_ENABLE(fontconfig,
3265   [  --enable-fontconfig     fontconfig support (default auto)])
3266
3267 AC_ARG_WITH([default-font],
3268     AS_HELP_STRING([--with-default-font=PATH],
3269         [Path to the default font]),
3270         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3271             "$withval", [Default font])])
3272 AC_ARG_WITH([default-monospace-font],
3273     AS_HELP_STRING([--with-default-monospace-font=PATH],
3274         [Path to the default font]),
3275         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3276             "$withval", [Default monospace font])])
3277
3278 AC_ARG_WITH([default-font-family],
3279     AS_HELP_STRING([--with-default-font-family=NAME],
3280         [Path to the default font family]),
3281         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3282             "$withval", [Default font family])])
3283 AC_ARG_WITH([default-monospace-font-family],
3284     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3285         [Path to the default font family]),
3286         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3287             "$withval", [Default monospace font family])])
3288
3289 if test "${enable_freetype}" != "no"; then
3290    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3291       have_freetype=yes
3292       VLC_ADD_PLUGIN([freetype])
3293       VLC_ADD_CPPFLAGS([freetype skins2],[${FREETYPE_CFLAGS}])
3294       if test "${SYS}" = "mingw32"; then
3295         VLC_ADD_LIBS([freetype],[-liconv -lz])
3296       fi
3297       VLC_ADD_LIBS([freetype skins2],[${FREETYPE_LIBS}])
3298
3299       AC_CHECK_HEADERS(Carbon/Carbon.h,
3300                        [VLC_ADD_LIBS([freetype],[-Wl,-framework,Carbon])])
3301
3302       dnl fontconfig support
3303       if test "${SYS}" != "mingw32"; then
3304           if test "${enable_fontconfig}" != "no"; then
3305             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3306               VLC_ADD_CPPFLAGS([freetype],[-DHAVE_FONTCONFIG])
3307               VLC_ADD_LIBS([freetype],[-lfontconfig])
3308             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3309           fi
3310       else
3311           VLC_ADD_LIBS([freetype],[-lgdi32])
3312       fi
3313
3314       dnl fribidi support
3315       if test "${enable_fribidi}" != "no"; then
3316         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3317           VLC_ADD_CPPFLAGS([freetype skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3318           VLC_ADD_LIBS([freetype skins2], [${FRIBIDI_LIBS}])
3319         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional support will be disabled in FreeType.])])
3320       fi
3321
3322   ],[
3323   have_freetype=no
3324   AS_IF([test -n "${enable_freetype}"],[
3325     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3326     ])
3327   ])
3328 fi
3329
3330
3331 dnl
3332 dnl  QuartzText vout module (iOS/Mac OS)
3333 dnl
3334 AC_ARG_ENABLE(macosx-quartztext,
3335   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3336 if test "x${enable_macosx_quartztext}" != "xno" &&
3337   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3338 then
3339   VLC_ADD_PLUGIN([quartztext])
3340   VLC_ADD_LIBS([quartztext],[-Wl,-framework,ApplicationServices])
3341 fi
3342
3343 dnl
3344 dnl  SVG module (text rendering and image decoding)
3345 dnl
3346 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3347 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3348
3349 dnl
3350 dnl  android surface module
3351 dnl
3352 AC_ARG_ENABLE(android-surface,
3353   [  --enable-android-surface   Android Surface video output module (default disabled)])
3354 if test "${enable_android_surface}" = "yes"; then
3355      VLC_ADD_PLUGIN([android_surface])
3356      VLC_ADD_PLUGIN([android_opaque])
3357 fi
3358
3359 dnl
3360 dnl  Windows DirectX module
3361 dnl
3362
3363 AC_ARG_ENABLE(directx,
3364   [AS_HELP_STRING([--enable-directx],
3365     [Microsoft DirectX support (default enabled on Windows)])],, [
3366   AS_IF([test "${SYS}" = "mingw32"], [
3367     enable_directx="yes"
3368   ], [
3369     enable_directx="no"
3370   ])
3371 ])
3372 have_directx="no"
3373 AS_IF([test "${enable_directx}" != "no"], [
3374   dnl DirectDraw
3375   AC_CHECK_HEADERS(ddraw.h, [
3376     have_directx="yes"
3377   ], [
3378     AC_MSG_ERROR([Cannot find DirectX headers!])
3379   ])
3380
3381   dnl OpenGL
3382   AC_CHECK_HEADERS(GL/wglew.h, [
3383     VLC_ADD_PLUGIN([glwin32])
3384   ],, [
3385     #include <windows.h>
3386     #include <GL/gl.h>
3387   ])
3388
3389   dnl Direct3D
3390   AC_CHECK_HEADERS(d3d9.h, [
3391     VLC_ADD_PLUGIN([direct3d])
3392   ])
3393
3394   dnl Direct2D
3395   AC_CHECK_HEADERS(d2d1.h, [
3396     VLC_ADD_PLUGIN([direct2d])
3397   ])
3398 ])
3399 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3400
3401 dnl
3402 dnl  Linux framebuffer module
3403 dnl
3404 AC_CHECK_HEADER([linux/fb.h], [
3405   VLC_ADD_PLUGIN([fb])
3406 ])
3407
3408
3409 dnl
3410 dnl  DirectFB module
3411 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3412 dnl  TODO: support for static linking
3413 dnl
3414 AC_ARG_ENABLE(directfb,
3415   [  --enable-directfb       DirectFB support (default disabled)])
3416 AC_ARG_WITH(directfb,
3417   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3418
3419 if test "${enable_directfb}" = "yes"; then
3420     have_directfb="false"
3421     CPPFLAGS_mydirectfb=
3422     LIBS_mydirectfb=
3423     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3424         dnl Trying the given location
3425         VLC_SAVE_FLAGS
3426
3427         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3428         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3429
3430         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3431         LIBS="${LIBS} ${LIBS_new}"
3432
3433         dnl FIXME: too obscure
3434         AC_CHECK_HEADER([directfb.h], [
3435             AC_CHECK_LIB([direct],[direct_initialize], [
3436                 AC_CHECK_LIB([fusion], [fusion_enter], [
3437                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3438                 ], have_directfb="false")
3439             ], have_directfb="false")
3440         ], have_directfb="false")
3441
3442         VLC_RESTORE_FLAGS
3443
3444         if test "${have_directfb}" = "true"; then
3445             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3446             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3447         fi
3448     else
3449         dnl Look for directfb-config
3450         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3451         if test "${DIRECTFB_CONFIG}" != "no"; then
3452             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3453             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3454             have_directfb="true"
3455         else
3456             dnl Trying with pkg-config
3457             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3458                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3459                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3460                 have_directfb="true"
3461                 ], [have_directfb="false"])
3462         fi
3463     fi
3464     if test "${have_directfb}" = "true"; then
3465         VLC_ADD_PLUGIN([directfb])
3466         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3467         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3468     else
3469         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3470     fi
3471 fi
3472
3473 dnl
3474 dnl  AA plugin
3475 dnl
3476 AC_ARG_ENABLE(aa,
3477   [  --enable-aa             aalib output (default disabled)])
3478 if test "${enable_aa}" = "yes"
3479 then
3480   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3481   if test "${have_aa}" = "true"
3482   then
3483     VLC_ADD_PLUGIN([aa])
3484   fi
3485 fi
3486
3487 dnl
3488 dnl  libcaca plugin
3489 dnl
3490 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3491
3492 dnl
3493 dnl  OS/2 KVA plugin
3494 dnl
3495 AC_ARG_ENABLE(kva,
3496   [AS_HELP_STRING([--enable-kva],
3497     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3498   AS_IF([test "$SYS" = "os2"], [
3499     enable_kva="yes"
3500   ])
3501 ])
3502 have_kva="no"
3503 KVA_LIBS=""
3504 AS_IF([test "$enable_kva" != "no"], [
3505   AC_CHECK_HEADERS([kva.h], [
3506     have_kva="yes"
3507     AC_CHECK_LIB(kva, main, [
3508       KVA_LIBS="-lkva"
3509     ])
3510   ])
3511 ])
3512 AC_SUBST(KVA_LIBS)
3513 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3514
3515 dnl
3516 dnl MMAL plugin
3517 dnl
3518 AC_ARG_ENABLE(mmal,
3519   AS_HELP_STRING([--enable-mmal],
3520     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3521 if test "${enable_mmal}" != "no"; then
3522   VLC_SAVE_FLAGS
3523   LDFLAGS="${LDFLAGS} -L/opt/vc/lib"
3524   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3525   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3526     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3527         have_mmal="yes"
3528         VLC_ADD_PLUGIN([mmal])
3529         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3530         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3531         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal ]) ], [
3532           AS_IF([test "${enable_mmal}" = "yes"],
3533             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3534             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3535           ],
3536         [])
3537     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3538       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3539       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3540   VLC_RESTORE_FLAGS
3541 fi
3542 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3543
3544 dnl
3545 dnl  Audio plugins
3546 dnl
3547
3548 EXTEND_HELP_STRING([Audio plugins:])
3549
3550 dnl
3551 dnl  Pulseaudio module
3552 dnl
3553 AC_ARG_ENABLE(pulse,
3554   [AS_HELP_STRING([--enable-pulse],
3555     [use the PulseAudio client library (default auto)])])
3556 have_pulse="no"
3557 AS_IF([test "${enable_pulse}" != "no"], [
3558   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3559     have_pulse="yes"
3560   ], [
3561     AS_IF([test "x${enable_pulse}" != "x"], [
3562       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3563     ])
3564   ])
3565 ])
3566 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3567
3568 dnl
3569 dnl  ALSA module
3570 dnl
3571 AC_ARG_ENABLE(alsa,
3572   [AS_HELP_STRING([--enable-alsa],
3573     [support the Advanced Linux Sound Architecture (default auto)])],, [
3574   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3575     enable_alsa="yes"
3576   ])
3577 ])
3578 have_alsa="no"
3579 AS_IF([test "${enable_alsa}" != "no"], [
3580   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3581     have_alsa="yes"
3582   ], [
3583     AS_IF([test "x${enable_alsa}" != "x"], [
3584       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3585     ])
3586   ])
3587 ])
3588 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3589
3590 dnl
3591 dnl  Open Sound System module
3592 dnl
3593 AC_ARG_ENABLE(oss,
3594   [AS_HELP_STRING([--enable-oss],
3595     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3596   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3597     enable_oss="no"
3598   ])
3599 ])
3600 have_oss="no"
3601 OSS_LIBS=""
3602 AS_IF([test "$enable_oss" != "no"], [
3603   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3604     have_oss="yes"
3605     AC_CHECK_LIB(ossaudio, main, [
3606       OSS_LIBS="-lossaudio"
3607     ])
3608   ])
3609 ])
3610 AC_SUBST(OSS_LIBS)
3611 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3612
3613 dnl
3614 dnl  OpenBSD sndio module
3615 dnl
3616 AC_ARG_ENABLE([sndio],
3617   [AS_HELP_STRING([--disable-sndio],
3618     [support the OpenBSD sndio (default auto)])],, [
3619   AS_IF([test "$SYS" = "openbsd"], [
3620     enable_sndio="yes"
3621   ])
3622 ])
3623 have_sndio="no"
3624 AS_IF([test "$enable_sndio" != "no"], [
3625   AC_CHECK_HEADER([sndio.h], [
3626     have_sndio="yes"
3627   ])
3628 ])
3629 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3630
3631 dnl
3632 dnl  Windows Audio Session plugin
3633 dnl
3634 AC_ARG_ENABLE([wasapi],
3635   [AS_HELP_STRING([--enable-wasapi],
3636     [use the Windows Audio Session API (default auto)])
3637 ])
3638 have_wasapi="no"
3639 AS_IF([test "$enable_wasapi" != "no"], [
3640   AC_CHECK_HEADER([audioclient.h], [
3641     have_wasapi="yes"
3642   ], [
3643     AS_IF([test "x${enable_wasapi}" != "x"], [
3644       AC_MSG_ERROR([Windows Audio Session API not found.])
3645     ])
3646   ])
3647 ])
3648 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3649
3650 dnl
3651 dnl  AudioQueue plugin
3652 dnl
3653 AC_ARG_ENABLE(audioqueue,
3654   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3655 if test "${enable_audioqueue}" = "yes"
3656 then
3657   VLC_ADD_PLUGIN([audioqueue])
3658 fi
3659
3660 dnl
3661 dnl  JACK modules
3662 dnl
3663 AC_ARG_ENABLE(jack,
3664   [AS_HELP_STRING([--disable-jack],
3665     [do not use jack (default auto)])])
3666 have_jack="no"
3667 AS_IF([test "${enable_jack}" != "no"], [
3668     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3669       [ have_jack=yes ],
3670       [
3671       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3672
3673       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3674       [ have_jack=yes ],
3675       [
3676       AS_IF([test -n "${enable_jack}"],
3677          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3678          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3679       ])
3680     ])
3681 ])
3682 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3683
3684 dnl
3685 dnl  OpenSLES Android
3686 dnl
3687 AC_ARG_ENABLE(opensles,
3688   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3689 if test "${HAVE_ANDROID}" = "1"; then
3690   if test "${enable_opensles}" = "yes"; then
3691       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3692         [ VLC_ADD_PLUGIN([opensles_android]) ],
3693         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3694   fi
3695 fi
3696
3697 dnl
3698 dnl libsamplerate plugin
3699 dnl
3700 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3701
3702 dnl
3703 dnl  OS/2 KAI plugin
3704 dnl
3705 AC_ARG_ENABLE(kai,
3706   [AS_HELP_STRING([--enable-kai],
3707     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3708   AS_IF([test "$SYS" = "os2"], [
3709     enable_kai="yes"
3710   ])
3711 ])
3712 have_kai="no"
3713 KAI_LIBS=""
3714 AS_IF([test "$enable_kai" != "no"], [
3715   AC_CHECK_HEADERS([kai.h], [
3716     have_kai="yes"
3717     AC_CHECK_LIB(kai, main, [
3718       KAI_LIBS="-lkai"
3719     ])
3720   ])
3721 ])
3722 AC_SUBST(KAI_LIBS)
3723 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3724
3725 dnl
3726 dnl  chromaprint audio track fingerprinter
3727 dnl
3728 m4_pushdef([libchromaprint_version], 0.6.0)
3729 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3730     VLC_ADD_PLUGIN([stream_out_chromaprint])
3731     VLC_ADD_CFLAGS([stream_out_chromaprint],[${CHROMAPRINT_CFLAGS}] [-I./webservices -I../stream_out])
3732     VLC_ADD_LIBS([stream_out_chromaprint],[${CHROMAPRINT_LIBS}]),
3733     AS_IF([test "${enable_chromaprint}" = "yes"],
3734         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3735         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3736          ),
3737     [(Chromaprint based audio fingerprinter)],[auto])
3738 m4_popdef([libchromaprint_version])
3739
3740 dnl
3741 dnl  Chromecast streaming support
3742 dnl
3743 m4_pushdef([protobuf_lite_version], 2.5.0)
3744 AC_ARG_VAR(PROTOC, [protobuf compiler])
3745 AC_PATH_PROGS(PROTOC, protoc, no )
3746 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3747     AS_IF([test "x${PROTOC}" != "xno"], [
3748         VLC_ADD_PLUGIN([stream_out_chromecast])
3749         VLC_ADD_CXXFLAGS([stream_out_chromecast],[${CHROMECAST_CFLAGS}] [-I./chromecast])
3750         VLC_ADD_LIBS([stream_out_chromecast],[${CHROMECAST_LIBS}])
3751         build_chromecast="yes"
3752     ], [
3753     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3754     ])
3755 ], [
3756     AS_IF([test "${enable_chromecast}" = "yes"],
3757         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3758         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3759     )
3760     enable_chromecast="no"
3761 ], [(Chromecast streaming support)], [auto])
3762 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3763 m4_popdef([protobuf_lite_version])
3764
3765 dnl
3766 dnl  Interface plugins
3767 dnl
3768
3769 EXTEND_HELP_STRING([Interface plugins:])
3770
3771 dnl
3772 dnl QT
3773 dnl
3774 AC_ARG_ENABLE(qt, [
3775   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3776   AS_IF([test "${SYS}" = "darwin"], [
3777     enable_qt="no"
3778   ])
3779 ])
3780 AS_IF([test "${enable_qt}" != "no"], [
3781   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3782       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3783           VLC_ADD_LIBS([qt4],[${QTX11_LIBS}])
3784           VLC_ADD_CXXFLAGS([qt4],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3785       ],[
3786           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3787       ])
3788       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3789       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3790       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, [${QT_HOST_PATH} ${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3791       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, [${QT_HOST_PATH} ${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3792       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, [${QT_HOST_PATH} ${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3793     ], [
3794       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3795         AS_IF([test -n "${enable_qt}"],[
3796           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3797         ],[
3798           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3799         ])
3800         enable_qt="no"
3801       ])
3802       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3803       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3804       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3805       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3806     ])
3807 ])
3808 AS_IF([test "${enable_qt}" != "no"], [
3809   VLC_ADD_PLUGIN([qt4])
3810   ALIASES="${ALIASES} qvlc"
3811 ])
3812 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3813
3814 dnl
3815 dnl Simple test for skins2 dependency
3816 dnl
3817 AS_IF([test "$enable_qt" = "no"], [
3818   AS_IF([test "${enable_skins2}" = "yes"], [
3819     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3820   ], [
3821     enable_skins2="no"
3822     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3823   ])
3824 ])
3825
3826 dnl
3827 dnl Skins2 module
3828 dnl
3829 AC_ARG_ENABLE(skins2,
3830   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3831 AS_IF([test "${enable_skins2}" != "no"], [
3832   have_skins_deps="yes"
3833
3834   dnl Win32
3835   AS_IF([test "${SYS}" = "mingw32"], [
3836     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3837     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3838   dnl MacOS
3839   ], [test "${SYS}" = "darwin"], [
3840     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3841     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3842   dnl OS/2
3843   ], [test "${SYS}" = "os2"], [
3844     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3845   dnl Linux/Unix
3846   ], [
3847     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3848     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3849     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3850     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3851     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3852   ])
3853
3854   dnl for All OSes
3855   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3856
3857   dnl we need freetype
3858   AS_IF([test "${have_freetype}" != "yes"], [
3859     have_skins_deps="no"
3860   ])
3861
3862   AS_IF([test "${have_skins_deps}" = "no"], [
3863     AS_IF([test "x${enable_skins2}" = "x"], [
3864       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3865     ], [
3866       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3867     ])
3868     enable_skins2="no"
3869   ], [
3870     VLC_ADD_PLUGIN([skins2])
3871     ALIASES="${ALIASES} svlc"
3872     enable_skins2="yes"
3873   ])
3874 ])
3875 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3876
3877 AC_ARG_ENABLE(libtar,
3878   [  --enable-libtar         libtar support for skins2 (default auto)])
3879 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3880   AC_CHECK_HEADERS(libtar.h, [
3881     VLC_ADD_LIBS([skins2],[-ltar])
3882   ])
3883 ])
3884
3885 dnl
3886 dnl  MacOS X gui module
3887 dnl
3888 AC_ARG_ENABLE(macosx,
3889   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3890 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3891 then
3892   VLC_ADD_LIBS([macosx], [-Wl,-framework,Cocoa -Wl,-framework,Carbon -Wl,-framework,CoreServices])
3893   VLC_ADD_OBJCFLAGS([macosx], [-fobjc-exceptions] )
3894   VLC_ADD_PLUGIN([macosx])
3895
3896   VLC_ADD_LIBS([macosx], [-Wl,-framework,QTKit -Wl,-framework,IOKit -Wl,-framework,AddressBook -Wl,-framework,WebKit -Wl,-framework,CoreAudio -Wl,-framework,SystemConfiguration -Wl,-framework,ScriptingBridge])
3897
3898   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3899   then
3900     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3901   fi
3902   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,Sparkle])
3903   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3904
3905   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3906   then
3907     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3908   fi
3909   VLC_ADD_LIBS([macosx], [-F${CONTRIB_DIR} -Wl,-framework,BGHUDAppKit])
3910   VLC_ADD_OBJCFLAGS([macosx], [-F${CONTRIB_DIR}])
3911 fi
3912 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3913
3914 dnl
3915 dnl  Minimal Mac OS X module
3916 dnl
3917 AC_ARG_ENABLE(minimal-macosx,
3918   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3919 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3920 then
3921   VLC_ADD_LIBS([minimal_macosx], [-Wl,-framework,Cocoa])
3922   VLC_ADD_OBJCFLAGS([minimal_macosx], [-fobjc-exceptions] )
3923   VLC_ADD_PLUGIN([minimal_macosx])
3924 fi
3925 AM_CONDITIONAL(ENABLE_MINIMAL_MACOSX, [test "$enable_minimal_macosx" != "no"])
3926
3927 dnl
3928 dnl  MacOS X dialog provider
3929 dnl
3930 AC_ARG_ENABLE(macosx-dialog-provider,
3931   [  --enable-macosx-dialog-provider Mac OS X dialog module (default enabled on Mac OS X)])
3932 if test "x${enable_macosx_dialog_provider}" != "xno" &&
3933   (test "${SYS}" = "darwin" || test "${enable_macosx_dialog_provider}" = "yes")
3934 then
3935   VLC_ADD_LIBS([macosx_dialog_provider],[-Wl,-framework,Cocoa])
3936   VLC_ADD_PLUGIN([macosx_dialog_provider])
3937 fi
3938 AM_CONDITIONAL(ENABLE_MACOSX_DIALOG_PROVIDER, [test "$enable_macosx_dialog_provider" != "no"])
3939
3940 dnl
3941 dnl  ncurses module
3942 dnl
3943 AC_ARG_ENABLE(ncurses,
3944 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3945 AS_IF([test "${enable_ncurses}" != "no"] ,[
3946   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3947     VLC_ADD_PLUGIN([ncurses])
3948     VLC_ADD_CFLAGS([ncurses],[${NCURSES_CFLAGS}])
3949     VLC_ADD_LIBS([ncurses],[${NCURSES_LIBS}])
3950     ALIASES="${ALIASES} nvlc"
3951   ], [
3952     AS_IF([test -n "${enable_ncurses}"], [
3953       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3954     ])
3955   ])
3956 ])
3957
3958 dnl
3959 dnl  Lirc plugin
3960 dnl
3961 AC_ARG_ENABLE(lirc,
3962   [  --enable-lirc           lirc support (default disabled)])
3963 if test "${enable_lirc}" = "yes"
3964 then
3965   AC_CHECK_HEADER(lirc/lirc_client.h, AC_CHECK_LIB(lirc_client, lirc_init, have_lirc="true", have_lirc="false"),have_lirc="false")
3966   if test "${have_lirc}" = "true"
3967   then
3968     VLC_ADD_PLUGIN([lirc])
3969     VLC_ADD_LIBS([lirc],[-llirc_client])
3970   fi
3971 fi
3972
3973 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3974 dnl
3975 dnl  goom visualization plugin
3976 dnl
3977 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3978
3979 dnl
3980 dnl libprojectM visualization plugin
3981 dnl
3982 AC_ARG_ENABLE(projectm,
3983   [  --enable-projectm       projectM visualization plugin (default enabled)])
3984 AS_IF([test "${enable_projectm}" != "no"],
3985   [
3986     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3987     [
3988       VLC_ADD_PLUGIN([projectm])
3989       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3990         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3991         [ AC_MSG_WARN( [Using libprojectM version 1] )
3992       ])
3993     ],[
3994       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3995     ])
3996   ])
3997
3998 dnl
3999 dnl Vovoid VSXu visualization plugin
4000 dnl
4001 AC_ARG_ENABLE(vsxu,
4002   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
4003 AS_IF([test "${enable_vsxu}" != "no"],
4004   [
4005     PKG_CHECK_MODULES(VSXU, libvsxu,
4006     [
4007       VLC_ADD_PLUGIN([vsxu])
4008       VLC_ADD_CXXFLAGS([vsxu],[$VSXU_CFLAGS])
4009       VLC_ADD_LIBS([vsxu],[$VSXU_LIBS])
4010     ],[
4011       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4012     ])
4013   ])
4014
4015 dnl
4016 dnl  AtmoLight (homemade Philips Ambilight clone)
4017 dnl
4018 AC_ARG_ENABLE(atmo,
4019 AS_HELP_STRING([--disable-atmo],[AtmoLight (homemade Philips Ambilight clone)
4020                 (default enabled)]),, [enable_atmo="yes"])
4021 AS_IF([test "${enable_atmo}" != no], [
4022   AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "linux"], [
4023     AC_LANG_PUSH(C++)
4024     VLC_ADD_PLUGIN([atmo])
4025     AC_LANG_POP(C++)
4026   ])
4027 ])
4028
4029 dnl
4030 dnl  glSpectrum
4031 dnl
4032 AC_ARG_ENABLE(glspectrum,
4033   [  --enable-glspectrum    3D OpenGL spectrum visualization (default auto)])
4034 if test "${enable_glspectrum}" != "no" && test "${have_gl}" = "yes"
4035 then
4036     VLC_ADD_PLUGIN([glspectrum])
4037     VLC_ADD_LIBS([glspectrum],[$GL_LIBS])
4038 fi
4039
4040 EXTEND_HELP_STRING([Service Discovery plugins:])
4041 dnl
4042 dnl  Bonjour services discovery
4043 PKG_ENABLE_MODULES_VLC([BONJOUR], [], [avahi-client >= 0.6], [Bonjour services discovery], [auto])
4044
4045 dnl
4046 dnl  libudev services discovery
4047 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4048
4049 dnl
4050 dnl MTP devices services discovery
4051 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4052
4053 dnl
4054 dnl UPnP Plugin (Intel SDK)
4055 dnl
4056 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4057
4058 EXTEND_HELP_STRING([Misc options:])
4059
4060 dnl
4061 dnl  libxml2 module
4062 dnl
4063 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4064
4065
4066 dnl
4067 dnl libgcrypt
4068 dnl
4069 AC_ARG_ENABLE(libgcrypt,
4070   [  --disable-libgcrypt     gcrypt support (default enabled)])
4071 AS_IF([test "${enable_libgcrypt}" != "no"], [
4072   AC_CHECK_DECL([GCRYCTL_SET_THREAD_CBS], [
4073     libgcrypt-config --version >/dev/null || \
4074         AC_MSG_ERROR([gcrypt.h present but libgcrypt-config could not be found])
4075     AC_CHECK_LIB(gcrypt, gcry_control, [
4076       have_libgcrypt="yes"
4077       GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
4078       GCRYPT_LIBS="`libgcrypt-config --libs`"
4079     ], [
4080       AC_MSG_ERROR([libgcrypt not found. Install libgcrypt or pass --disable-libgcrypt.])
4081     ], [`libgcrypt-config --libs`])
4082   ], [
4083     AC_MSG_ERROR([libgcrypt version 1.1.94 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4084   ], [#include <gcrypt.h>]
4085   )
4086 ])
4087
4088 AC_SUBST(GCRYPT_CFLAGS)
4089 AC_SUBST(GCRYPT_LIBS)
4090 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
4091
4092 dnl
4093 dnl TLS/SSL
4094 dnl
4095 AC_ARG_ENABLE(gnutls,
4096   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4097 AS_IF([test "${enable_gnutls}" != "no"], [
4098   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4099     VLC_ADD_PLUGIN([gnutls])
4100   ], [
4101     AS_IF([test -n "${enable_gnutls}"], [
4102       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4103     ])
4104   ])
4105 ])
4106
4107
4108 dnl
4109 dnl Taglib plugin
4110 dnl
4111 AC_ARG_ENABLE(taglib,
4112   [AS_HELP_STRING([--disable-taglib],
4113     [do not use TagLib (default enabled)])])
4114 AS_IF([test "${enable_taglib}" != "no"], [
4115   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4116     VLC_ADD_PLUGIN([taglib])
4117   ], [
4118     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4119 ])
4120
4121
4122 dnl
4123 dnl update checking system
4124 dnl
4125 AC_ARG_ENABLE(update-check,
4126   [  --enable-update-check   update checking system (default disabled)])
4127 if test "${enable_update_check}" = "yes"
4128 then
4129   if test "${have_libgcrypt}" != "yes"
4130   then
4131     AC_MSG_ERROR([libgcrypt is required for update checking system])
4132   fi
4133   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4134   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4135   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4136 fi
4137
4138 dnl
4139 dnl Growl notification plugin
4140 dnl
4141 AC_ARG_ENABLE(growl,
4142   [  --enable-growl          growl notification plugin (default disabled)],,
4143   [enable_growl=no])
4144 AS_IF([test "${enable_growl}" != "no"], [
4145     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4146       VLC_ADD_PLUGIN([growl])
4147       VLC_ADD_LIBS([growl], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4148       VLC_ADD_OBJCFLAGS([growl], [-F${CONTRIB_DIR}])
4149       VLC_ADD_OBJCFLAGS([growl], [-fobjc-exceptions] )
4150     ])
4151   ]
4152 )
4153