keystore/plaintext: rename to memory
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2016"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
42
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
59
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
69
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
77
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, optional)
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl
98 dnl  Check the operating system
99 dnl
100 HAVE_WIN64="0"
101 HAVE_IOS="0"
102 HAVE_OSX="0"
103 HAVE_TVOS="0"
104
105 case "${host_os}" in
106   "")
107     SYS=unknown
108     ;;
109   linux*)
110     SYS=linux
111     ;;
112   bsdi*)
113     SYS=bsdi
114     CFLAGS="${CFLAGS} -pthread"
115     ;;
116   freebsd*)
117     SYS=freebsd
118     CFLAGS="${CFLAGS} -pthread"
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
121     ;;
122   openbsd*)
123     SYS=openbsd
124     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
125     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
126     ;;
127   netbsd*)
128     SYS=netbsd
129     ;;
130   dragonfly*)
131     SYS=dragonfly
132     ;;
133   darwin*)
134
135     dnl Force gcc "-arch" flag
136     ARCH_flag=""
137     case "${host}" in
138       i?86*)
139         ARCH_flag="-arch i386"
140       ;;
141       ppc64*)
142         ARCH_flag="-arch ppc64"
143       ;;
144       ppc*)
145         ARCH_flag="-arch ppc"
146       ;;
147       x86_64*)
148         ARCH_flag="-arch x86_64"
149       ;;
150       arm*)
151         ac_cv_c_bigendian="no"
152         ac_cv_c_attribute_packed="no"
153       ;;
154     esac
155
156     SYS=darwin
157     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
158     CXX="${CXX} -stdlib=libc++ -std=c++11"
159     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
160     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
161     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
162     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
163     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
164     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
165
166     AC_EGREP_CPP(yes,
167             [#import <TargetConditionals.h>
168              #if TARGET_OS_IPHONE
169              yes
170              #endif],
171              [HAVE_IOS="1"],
172              [HAVE_OSX="1"])
173
174     AC_EGREP_CPP(yes,
175             [#import <TargetConditionals.h>
176              #if TARGET_OS_TV
177              yes
178              #endif],
179              [HAVE_TVOS="1"
180              HAVE_IOS="0"
181              HAVE_OSX="0"
182              ],)
183
184     dnl Allow binaries created on Lion to run on earlier releases
185     AC_EGREP_CPP(yes,
186            [#import <Cocoa/Cocoa.h>
187             #ifdef MAC_OS_X_VERSION_10_7
188             yes
189             #endif],
190             [AC_MSG_RESULT([yes])
191             AC_LIBOBJ([getdelim])
192             AC_LIBOBJ([strndup])
193             AC_LIBOBJ([strnlen])],)
194
195     dnl
196     dnl  Handle Mac OS X SDK flags
197     dnl
198     AC_ARG_WITH(macosx-sdk,
199       [AS_HELP_STRING([--with-macosx-sdk=DIR],
200         [compile using the SDK in DIR])])
201     if test "${with_macosx_sdk}" != "" ; then
202         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
203         CPP="${CPP} -isysroot ${with_macosx_sdk}"
204         CC="${CC} -isysroot ${with_macosx_sdk}"
205         CXX="${CXX} -isysroot ${with_macosx_sdk}"
206         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
207         LD="${LD} -syslibroot ${with_macosx_sdk}"
208     fi
209     AC_ARG_WITH(macosx-version-min,
210       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
211         [compile for Mac OS X VERSION and above])])
212     if test "${with_macosx_version_min}" != "" ; then
213         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
214         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
215         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
216         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
217         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
218     fi
219     ;;
220   *mingw32* | *cygwin* | *wince* | *mingwce*)
221     AC_CHECK_TOOL(WINDRES, windres, :)
222     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
223     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
224     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
225     AH_TOP([#endif])
226     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
227     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
228     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
229     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
230     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
231     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
232     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
233     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
234     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
235     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
236     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
237
238     case "${host_os}" in
239       *mingw32*)
240         SYS=mingw32
241         ;;
242       *cygwin*)
243         dnl Check if we are using the mno-cygwin mode in which case we are
244         dnl actually dealing with a mingw32 compiler.
245         AC_EGREP_CPP(yes,
246             [#ifdef _WIN32
247              yes
248              #endif],
249             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
250         ;;
251     esac
252
253     if test "${SYS}" = "mingw32"; then
254         # DEP, ASLR, NO SEH
255         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
256
257         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
258         ac_default_prefix="`pwd`/_win32"
259         DESTDIR="`pwd`/_win32/"
260
261         dnl
262         dnl NSIS/MSI Installer prefix and WIN64
263         dnl
264         case "${host}" in
265             amd64*|x86_64*)
266                 HAVE_WIN64="1"
267                 WINDOWS_ARCH="x64"
268                 PROGRAMFILES="PROGRAMFILES64"
269             ;;
270             *)
271                 WINDOWS_ARCH="x86"
272                 PROGRAMFILES="PROGRAMFILES"
273             ;;
274         esac
275         AC_SUBST(WINDOWS_ARCH)
276         AC_SUBST(PROGRAMFILES)
277
278     fi
279     ;;
280   *nto*)
281     SYS=nto
282     ;;
283   solaris*)
284     SYS=solaris
285     ;;
286   hpux*)
287     SYS=hpux
288     ;;
289   *os2*)
290     SYS=os2
291     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
292     AC_LIBOBJ([freeaddrinfo])
293     AC_LIBOBJ([gai_strerror])
294     ;;
295   *)
296     SYS="${host_os}"
297     ;;
298 esac
299 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
300 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
301 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
302 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
303 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
304 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
305 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
306 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
307
308 dnl
309 dnl Sadly autoconf does not think about testing foo.exe when ask to test
310 dnl for program foo on win32
311 case "${build_os}" in
312     cygwin|msys)
313         ac_executable_extensions=".exe"
314     ;;
315     os2*)
316         BUILDEXEEXT=".exe"
317     ;;
318     *)
319     ;;
320 esac
321 AC_SUBST(BUILDEXEEXT)
322
323 dnl Android is linux, but a bit different
324 AS_IF([test "$SYS" = linux],[
325     AC_MSG_CHECKING([for an Android system])
326     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
327         [[#ifndef __ANDROID__
328          # error Not Android
329          #endif
330         ]],[[;]])
331     ],[
332       HAVE_ANDROID="1"
333       AC_MSG_RESULT([yes])
334     ],[
335       AC_MSG_RESULT([no])
336     ])
337 ])
338 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
339
340 dnl Tizen (minimum SDK version: 2.3)
341 AS_IF([test "$SYS" = linux],[
342     AC_MSG_CHECKING([for Tizen])
343     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
344         [[#include <tizen.h>
345         ]],[[;]])
346     ],[
347       HAVE_TIZEN="1"
348       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
349       AC_MSG_RESULT([yes])
350     ],[
351       AC_MSG_RESULT([no])
352     ])
353 ])
354 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
355
356 dnl
357 dnl  Check for the contrib directory
358 dnl
359 AC_ARG_WITH(contrib,
360   [AS_HELP_STRING([--with-contrib[=DIR]],
361     [search for 3rd party libraries in DIR/include and DIR/lib])
362 ])
363 AC_MSG_CHECKING([for 3rd party libraries path])
364 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
365   CONTRIB_DIR="${srcdir}/contrib/${host}"
366   AS_IF([test ! -d "${CONTRIB_DIR}"], [
367     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
368     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
369     AS_IF([test ! -d "${CONTRIB_DIR}"], [
370       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
371       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
372       AS_IF([test ! -d "${CONTRIB_DIR}"], [
373         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
374         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
375         AS_IF([test ! -d "${CONTRIB_DIR}"], [
376           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
377           CONTRIB_DIR=""
378           AC_MSG_RESULT([not found])
379         ])
380       ])
381     ])
382   ])
383 ], [
384   AS_IF([test "${with_contrib}" != "no"], [
385     CONTRIB_DIR="${with_contrib}"
386   ], [
387     CONTRIB_DIR=""
388     AC_MSG_RESULT([disabled])
389   ])
390 ])
391 AS_IF([test -n "${CONTRIB_DIR}"], [
392   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
393     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
394   ], [
395     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
396     CONTRIB_DIR=""
397     AC_MSG_RESULT([not usable])
398   ])
399
400 ])
401 AS_IF([test -n "${CONTRIB_DIR}"], [
402   AC_MSG_RESULT([${CONTRIB_DIR}])
403   export PATH=${CONTRIB_DIR}/bin:$PATH
404   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
405   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
406   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
407   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
408   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
409   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
410
411   AS_IF([test "${SYS}" = "darwin"], [
412     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
413     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
414   ])
415 ], [
416   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
417     AC_MSG_ERROR([Third party libraries not found!])
418   ])
419 ])
420 AC_SUBST(CONTRIB_DIR)
421
422 dnl Add extras/tools to the PATH
423 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
424 AS_IF([test -d "${TOOLS_DIR}"], [
425     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
426     export PATH="${TOOLS_DIR}":$PATH
427 ])
428
429 dnl
430 dnl  Libtool
431 dnl  It's very bad, but our former custom system was worst
432 dnl  -- Courmisch
433 dnl
434
435 dnl override platform specific check for dependent libraries
436 dnl otherwise libtool linking of shared libraries will
437 dnl fail on anything other than pass_all.
438 AC_CACHE_VAL(lt_cv_deplibs_check_method,
439     [lt_cv_deplibs_check_method=pass_all])
440
441 LT_INIT([dlopen win32-dll shared disable-static])
442 LT_LANG([C++])
443 LT_LANG([Windows Resource])
444
445 DOLT
446
447 lt_cv_deplibs_check_method=pass_all
448
449 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
450   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
451 ])
452
453 dnl
454 dnl Gettext stuff
455 dnl
456 AM_GNU_GETTEXT_VERSION([0.19.6])
457 AM_GNU_GETTEXT([external], [need-formatstring-macros])
458
459 dnl
460 dnl Iconv stuff
461 dnl
462 AM_ICONV
463
464 dnl
465 dnl checks for mingw
466 AS_IF([test "${SYS}" = "mingw32"], [
467
468 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
469 #if !defined(__MINGW32__)
470 # error Not compiling with mingw
471 #endif
472     ])], [
473
474 dnl Check for broken versions of mingw-runtime compatability library
475     AC_MSG_CHECKING(for broken mingw-runtime)
476     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
477 #include <_mingw.h>
478 #if defined(__MINGW64_VERSION_MAJOR)
479 # if __MINGW64_VERSION_MAJOR < 3
480 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
481 # endif
482 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
483 # error Attempting to use mingw-runtime with broken vsnprintf support
484 #endif
485     ])], [
486         AC_MSG_RESULT([ok])
487     ], [
488         AC_MSG_RESULT([present])
489         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
490     ])
491
492     dnl force use of mingw provided c99 *printf over msvcrt
493     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
494
495     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
496     VLC_ADD_LDFLAGS([vlc],[-mwindows])
497
498     dnl Check for the need to include the mingwex lib for mingw32
499     VLC_SAVE_FLAGS
500     AC_CHECK_LIB(mingwex,opendir,
501         AC_CHECK_LIB(mingw32,opendir,,
502             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
503     )
504     VLC_RESTORE_FLAGS
505     ], [
506         AC_MSG_RESULT([Not compiling with mingw])
507     ])
508
509     dnl Check for fnative-struct or mms-bitfields support for mingw32
510     VLC_SAVE_FLAGS
511     CFLAGS="${CFLAGS} -mms-bitfields"
512     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
513     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
514         [ac_cv_c_mms_bitfields],
515         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
516     if test "${ac_cv_c_mms_bitfields}" = "no"; then
517         VLC_RESTORE_FLAGS
518         CFLAGS="${CFLAGS} -fnative-struct"
519         CXXFLAGS="${CXXFLAGS} -fnative-struct"
520         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
521             [ac_cv_c_fnative_struct],
522             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
523         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
524     fi
525 ])
526
527 AC_ARG_ENABLE(winstore_app,
528      AS_HELP_STRING([--enable-winstore-app],
529                     [Build targetted for Windows Store apps (default disabled)]))
530
531 vlc_winstore_app=0
532 AS_IF([test "${SYS}" = "mingw32"],[
533   AS_IF([test "${enable_winstore_app}" = "yes"], [
534     vlc_winstore_app=1
535      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
536      AC_LIBOBJ([gai_strerror])
537     ],[
538      VLC_ADD_LIBS([libvlccore],[-lwinmm])
539     ])
540   ])
541 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
542 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
543
544
545 dnl
546 dnl Buggy glibc prevention. Purposedly not cached.
547 dnl See sourceware.org bugs 5058 and 5443.
548 dnl Ubuntu alone has 20 bug numbers for this...
549 dnl
550 AC_MSG_CHECKING(for buggy GNU/libc versions)
551 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
552 #include <limits.h>
553 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
554   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
555 # error GNU/libc with dcgettext killer bug!
556 #endif
557 ])], [
558   AC_MSG_RESULT([not present])
559 ], [
560   AC_MSG_RESULT([found])
561   AS_IF([test "x${enable_nls}" != "xno"], [
562     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
563 work-around for this. Check with your distribution vendor on how to update the
564 glibc run-time. Alternatively, build with --disable-nls.])
565   ])
566 ])
567
568 dnl Plugin compilation stuff
569
570 VLC_LIBRARY_SUFFIX
571
572 dnl Check for system libs needed
573 need_libc=false
574
575 dnl Check for usual libc functions
576 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
577 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
578 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy timegm timespec_get strverscmp])
579 AC_REPLACE_FUNCS([gettimeofday])
580 AC_CHECK_FUNCS(fdatasync,,
581   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
582 ])
583
584 dnl mingw64 implements those as static inline, not functions with C linkage
585 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
586 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
587 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
588 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
589
590 dnl C11 static_assert()
591 AC_MSG_CHECKING([for static_assert in assert.h])
592 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
593 static_assert(1, "The impossible happened.");
594 ])], [
595   AC_MSG_RESULT([yes])
596   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
597 ], [
598   AC_MSG_RESULT([no])
599 ])
600
601 # Windows CE does not have strcoll()
602 AC_FUNC_STRCOLL
603
604 dnl Check for non-standard system calls
605 case "$SYS" in
606   "linux")
607     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
608     ;;
609   "mingw32")
610     AC_CHECK_FUNCS([_lock_file])
611     ;;
612 esac
613
614 AH_BOTTOM([#include <vlc_fixups.h>])
615
616 dnl Check for struct pollfd
617 AC_CHECK_TYPES([struct pollfd],,,
618 [#include <sys/types.h>
619 #if HAVE_POLL
620 # include <poll.h>
621 #elif defined (_WIN32)
622 # include <winsock2.h>
623 #endif
624 ])
625
626 dnl Check for struct timespec
627 AC_CHECK_TYPES([struct timespec],,,
628 [#include <time.h>])
629
630 dnl Checks for socket stuff
631 VLC_SAVE_FLAGS
632 SOCKET_LIBS=""
633 AC_SEARCH_LIBS(connect, [socket], [
634   AS_IF([test "$ac_cv_search_connect" != "none required"], [
635     SOCKET_LIBS="$ac_cv_search_connect"
636   ])
637 ], [
638   AS_IF([test "${SYS}" = "mingw32"], [
639     SOCKET_LIBS="-lws2_32"
640   ])
641 ])
642
643 AC_SEARCH_LIBS([inet_pton], [nsl], [
644  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
645     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
646   ])
647 ],, [${SOCKET_LIBS}])
648
649 LIBS="${LIBS} ${SOCKET_LIBS}"
650 AC_LINK_IFELSE([
651     AC_LANG_PROGRAM([#ifdef _WIN32
652         # if _WIN32_WINNT < 0x600
653         #  error Needs vista+
654         # endif
655         #include <ws2tcpip.h>
656         #else
657         #include <sys/socket.h>
658         #include <arpa/inet.h>
659         #endif], [
660         char dst[[sizeof(struct in_addr)]];
661         inet_pton(AF_INET, "127.0.0.1", dst);
662     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
663 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
664 VLC_RESTORE_FLAGS
665 AC_SUBST(SOCKET_LIBS)
666
667 dnl Check for socklen_t
668 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
669 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
670 ac_cv_type_socklen_t,
671 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
672 [#include <sys/types.h>
673 #ifdef _WIN32
674 # include <winsock2.h>
675 # include <ws2tcpip.h>
676 #else
677 # include <sys/socket.h>
678 #endif]], [[socklen_t len; len = 0;]])],
679 ac_cv_type_socklen_t=yes,
680 ac_cv_type_socklen_t=no)])
681 AS_IF([test "$ac_cv_type_socklen_t" = no],
682  [AC_DEFINE(socklen_t, int)])
683
684 dnl Check for struct sockaddr_storage
685 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
686 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
687 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
688   [AC_TRY_COMPILE(
689     [#include <sys/types.h>
690      #if defined( _WIN32 )
691      # include <winsock2.h>
692      #else
693      # include <sys/socket.h>
694      #endif], [struct sockaddr_storage addr;],
695      ac_cv_struct_sockaddr_storage=yes,
696      ac_cv_struct_sockaddr_storage=no)])
697 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
698   AC_DEFINE(sockaddr_storage, sockaddr)
699   AC_DEFINE(ss_family, sa_family)
700 ])
701
702 dnl FreeBSD has a gnugetopt library for this:
703 GNUGETOPT_LIBS=""
704 AC_CHECK_FUNC(getopt_long,, [
705   AC_CHECK_LIB([gnugetopt],[getopt_long], [
706     GNUGETOPT_LIBS="-lgnugetopt"
707   ])
708 ])
709 AC_SUBST(GNUGETOPT_LIBS)
710
711 AC_CHECK_LIB(m,cos,[
712   LIBM="-lm"
713 ], [
714   LIBM=""
715 ])
716 AC_SUBST(LIBM)
717
718 AC_CHECK_LIB(m,lrintf, [
719   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
720   VLC_ADD_LIBS([skins2],[-lm])
721 ])
722 AC_CHECK_LIB(m,nanf,
723   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
724 )
725
726 dnl Check for dynamic plugins
727 LIBDL=""
728 have_dynamic_objects="no"
729 VLC_SAVE_FLAGS
730 AC_SEARCH_LIBS(dlsym, [dl svld], [
731   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
732     LIBDL="$ac_cv_search_dlsym"
733   ])
734   have_dynamic_objects="yes"
735 ])
736 VLC_RESTORE_FLAGS
737
738 # Windows
739 AS_IF([test "${SYS}" = "mingw32"], [
740   LIBDL=""
741   have_dynamic_objects="yes" #assume we can use shared objects
742 ])
743
744 AS_IF([test "${enable_shared}" = "no"], [
745   have_dynamic_objects=no
746 ])
747 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
748
749 AC_SUBST(LIBDL)
750
751 dnl Check for thread library
752 LIBPTHREAD=""
753 AS_IF([test "${SYS}" != "mingw32"], [
754   VLC_SAVE_FLAGS
755   LIBS=""
756   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
757     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
758       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
759     ])
760   ])
761   VLC_RESTORE_FLAGS
762 ])
763 AC_SUBST(LIBPTHREAD)
764
765 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
766   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
767     LIBRT="$ac_cv_search_clock_nanosleep"
768   ])
769 ], [
770   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
771     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
772       LIBRT="$ac_cv_search_nanosleep"
773     ])
774   ])
775 ])
776 AC_SUBST(LIBRT)
777
778 dnl
779 dnl Check for headers
780 dnl
781
782 dnl  POSIX
783 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h])
784 AC_CHECK_HEADERS([net/if.h], [], [],
785 [
786 #include <sys/types.h>
787 #include <sys/socket.h>
788 ])
789 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
790 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
791
792 dnl  BSD
793 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
794
795 dnl  GNU/Linux
796 AC_CHECK_HEADERS([getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
797
798 dnl  MacOS
799 AC_CHECK_HEADERS([xlocale.h])
800
801 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
802 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
803 AC_CHECK_TYPE(ssize_t,, [
804   AC_DEFINE(ssize_t, int)
805 ])
806
807 dnl It seems that autoconf detects pkg-config only during the first
808 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
809 dnl it is nested within a conditional block, so it was not working right.
810 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
811 AC_ARG_VAR(PKG_CONFIG_PATH,
812        [Paths where to find .pc not at the default location])
813 PKG_PROG_PKG_CONFIG()
814
815 dnl On some OS we need static linking
816 AS_IF([test -n "${PKG_CONFIG}" ],[
817     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
818         PKG_CONFIG="${PKG_CONFIG} --static"
819     ])
820 ])
821
822
823 dnl
824 dnl Check for zlib.h and -lz along with system -lminizip if available
825 dnl
826 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
827 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
828 if test "${have_zlib}" = "yes"
829 then
830   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
831   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
832     AC_CHECK_HEADERS([unzip.h], [
833       have_minizip=yes
834       MINIZIP_LIBS="-lminizip -lz"
835     ], [
836       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
837       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
838       have_minizip=no
839     ])
840   ])
841   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
842   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
843 fi
844 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
845
846
847 dnl
848 dnl Domain name i18n support via GNU libidn
849 dnl
850 PKG_CHECK_MODULES([IDN], [libidn], [
851   have_libidn="yes"
852   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
853 ], [
854   have_libidn="no"
855 ])
856
857
858 dnl Check for dbus
859 AC_ARG_ENABLE(dbus,
860   [AS_HELP_STRING([--enable-dbus],
861     [compile D-Bus message bus support (default enabled)])])
862 have_dbus="no"
863 AS_IF([test "${enable_dbus}" != "no"], [
864   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
865     have_dbus="yes"
866   ], [
867     AS_IF([test -n "${enable_dbus}"], [
868       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
869     ], [
870       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
871     ])
872   ])
873 ])
874 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
875
876
877 dnl Check for systemd
878 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
879   have_systemd="yes"
880 ], [
881   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
882 ])
883 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
884
885
886 dnl Check for ntohl, etc.
887 VLC_SAVE_FLAGS
888 CFLAGS="${CFLAGS} -Wall -Werror"
889 AC_CACHE_CHECK([for ntohl in sys/param.h],
890     [ac_cv_c_ntohl_sys_param_h],
891     [     AC_TRY_COMPILE([#include <sys/param.h>],
892         [int meuh; ntohl(meuh);],
893         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
894 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
895     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
896 fi
897 VLC_RESTORE_FLAGS
898
899 EXTEND_HELP_STRING([Optimization options:])
900 dnl
901 dnl  Compiler warnings
902 dnl
903
904 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
905 RDC_PROG_CC_FLAGS([-pipe])
906 AC_LANG_PUSH([C++])
907 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
908 AC_LANG_POP([C++])
909
910 dnl
911 dnl  Debugging mode
912 dnl
913 AC_ARG_ENABLE(debug,
914   [AS_HELP_STRING([--enable-debug],
915     [build with run-time assertions (default disabled)])],,
916   [enable_debug="no"])
917 AH_TEMPLATE(NDEBUG,
918             [Define to 1 if debug code should NOT be compiled])
919 AS_IF([test "${enable_debug}" != "no"], [
920   AC_CHECK_HEADERS([valgrind/valgrind.h])
921 ], [
922   AC_DEFINE(NDEBUG)
923 ])
924
925 dnl
926 dnl  Profiling
927 dnl
928 AC_ARG_ENABLE(gprof,
929   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
930   [enable_gprof="no"])
931 AS_IF([test "${enable_gprof}" != "no"], [
932   CFLAGS="${CFLAGS} -pg"
933   CXXFLAGS="${CXXFLAGS} -pg"
934   OBJCFLAGS="${OBJCFLAGS} -pg"
935   LDFLAGS="${LDFLAGS} -pg"
936 ])
937
938 AC_ARG_ENABLE(cprof,
939   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
940   [enable_cprof="no"])
941 AS_IF([test "${enable_gprof}" != "no"], [
942   CFLAGS="${CFLAGS} -finstrument-functions"
943   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
944   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
945   LDFLAGS="${LDFLAGS} -finstrument-functions"
946 ])
947
948 dnl
949 dnl  Test coverage
950 dnl
951 AC_ARG_ENABLE(coverage,
952   [AS_HELP_STRING([--enable-coverage],
953     [build for test coverage (default disabled)])],,
954   [enable_coverage="no"])
955 AS_IF([test "${enable_coverage}" != "no"], [
956   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
957   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
958   LDFLAGS="-lgcov ${LDFLAGS}"
959 ])
960
961 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
962   VLC_SAVE_FLAGS
963   CFLAGS="${CFLAGS} -fvisibility=hidden"
964   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
965   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
966   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
967                  [ac_cv_c_visibility_hidden], [
968     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
969       ac_cv_c_visibility_hidden=yes
970     ], [
971       ac_cv_c_visibility_hidden=no
972     ])
973   ])
974   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
975 ])
976
977
978 dnl
979 dnl  Enable/disable optimizations
980 dnl
981 AC_ARG_ENABLE(optimizations,
982   [AS_HELP_STRING([--disable-optimizations],
983     [disable compiler optimizations (default enabled)])],,
984   [enable_optimizations="yes"])
985
986 dnl Check for various optimization flags
987 AS_IF([test "${enable_optimizations}" != "no"], [
988
989   dnl -O3 only in production builds
990   AS_IF([test "${enable_debug}" = "no"], [
991     VLC_SAVE_FLAGS
992     CFLAGS="${CFLAGS} -O3"
993     CXXFLAGS="${CXXFLAGS} -O3"
994     OBJCFLAGS="${OBJCFLAGS} -O3"
995     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
996       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
997         ac_cv_c_o3=yes
998       ], [
999         ac_cv_c_o3=no
1000       ])
1001     ])
1002     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1003   ])
1004
1005   dnl Check for -ffast-math
1006   VLC_SAVE_FLAGS
1007   CFLAGS="${CFLAGS} -ffast-math"
1008   CXXFLAGS="${CXXFLAGS} -ffast-math"
1009   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
1010   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
1011     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1012       ac_cv_c_fast_math=yes
1013     ], [
1014       ac_cv_c_fast_math=no
1015     ])
1016   ])
1017   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
1018   AH_BOTTOM([
1019 #ifndef __FAST_MATH__
1020 # ifndef _MSC_VER
1021 #  pragma STDC FENV_ACCESS OFF
1022 #  pragma STDC FP_CONTRACT ON
1023 # else
1024 #  pragma fenv_access(off)
1025 #  pragma fp_contract(on)
1026 # endif
1027 #endif
1028 ])
1029
1030   dnl Check for -funroll-loops
1031   VLC_SAVE_FLAGS
1032   CFLAGS="${CFLAGS} -funroll-loops"
1033   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1034   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1035   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1036     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1037       ac_cv_c_unroll_loops=yes
1038     ], [
1039       ac_cv_c_unroll_loops=no
1040     ])
1041   ])
1042   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1043
1044   AS_IF([test "$enable_debug" = "no"], [
1045     dnl Check for -fomit-frame-pointer
1046     VLC_SAVE_FLAGS
1047     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1048     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1049     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1050     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1051       [ac_cv_c_omit_frame_pointer], [
1052       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1053         ac_cv_c_omit_frame_pointer=yes
1054       ], [
1055         ac_cv_c_omit_frame_pointer=no
1056       ])
1057     ])
1058     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1059   ])
1060 ])
1061
1062 VLC_SAVE_FLAGS
1063 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1064 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1065   AC_TRY_LINK([],, [
1066     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1067   ], [
1068     ac_cv_ld_bsymbolic=""
1069   ])
1070 ])
1071 VLC_RESTORE_FLAGS
1072 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1073 AC_SUBST(SYMBOLIC_LDFLAGS)
1074
1075 dnl Checks for __attribute__(aligned()) directive
1076 VLC_SAVE_FLAGS
1077 CFLAGS="${CFLAGS} -Werror"
1078 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1079     [ac_cv_c_attribute_aligned],
1080     [ac_cv_c_attribute_aligned=0
1081     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1082         AC_TRY_COMPILE([],
1083         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1084         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1085     done])
1086 VLC_RESTORE_FLAGS
1087 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1088     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1089         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1090 fi
1091
1092 dnl Check for __attribute__((packed))
1093 AC_CACHE_CHECK([for __attribute__((packed))],
1094   [ac_cv_c_attribute_packed],
1095   [ac_cv_c_attribute_packed=no
1096    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1097                     [ac_cv_c_attribute_packed=yes])])
1098 if test "${ac_cv_c_attribute_packed}" != "no"; then
1099   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1100 fi
1101
1102 dnl
1103 dnl  Check the CPU
1104 dnl
1105 case "${host_cpu}" in
1106   "")
1107     ARCH=unknown
1108     ;;
1109   *)
1110     ARCH="${host_cpu}"
1111     ;;
1112 esac
1113
1114 dnl Check for backtrace() support
1115 AC_CHECK_HEADERS(execinfo.h)
1116 AC_CHECK_FUNCS(backtrace)
1117
1118 dnl
1119 dnl  default modules
1120 dnl
1121 ALIASES="${ALIASES} cvlc rvlc"
1122
1123 dnl
1124 dnl  Accelerated modules
1125 dnl
1126
1127 dnl  Check for fully working MMX intrinsics
1128 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1129 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1130 AC_ARG_ENABLE(mmx,
1131   [AS_HELP_STRING([--disable-mmx],
1132     [disable MMX optimizations (default auto)])],,[
1133   case "${host_cpu}" in
1134     i?86|x86_64)
1135       enable_mmx="yes"
1136       ;;
1137     *)
1138       enable_mmx="no"
1139       ;;
1140   esac
1141 ])
1142 have_mmx="no"
1143 have_mmxext="no"
1144 AS_IF([test "${enable_mmx}" != "no"], [
1145   ARCH="${ARCH} mmx"
1146   VLC_SAVE_FLAGS
1147   CFLAGS="${CFLAGS} -mmmx"
1148   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1149     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1150 [#include <mmintrin.h>
1151 #include <stdint.h>
1152 uint64_t frobzor;]], [
1153 [__m64 a, b, c;
1154 a = b = c = (__m64)frobzor;
1155 a = _mm_slli_pi16(a, 3);
1156 a = _mm_adds_pi16(a, b);
1157 c = _mm_srli_pi16(c, 8);
1158 c = _mm_slli_pi16(c, 3);
1159 b = _mm_adds_pi16(b, c);
1160 a = _mm_unpacklo_pi8(a, b);
1161 frobzor = (uint64_t)a;]])], [
1162       ac_cv_c_mmx_intrinsics=yes
1163     ], [
1164       ac_cv_c_mmx_intrinsics=no
1165     ])
1166   ])
1167   VLC_RESTORE_FLAGS
1168   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1169     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1170   ])
1171
1172   VLC_SAVE_FLAGS
1173   CFLAGS="${CFLAGS} -mmmx"
1174   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1175     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1176 void *p;
1177 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1178 ]])
1179     ], [
1180       ac_cv_mmx_inline=yes
1181     ], [
1182       ac_cv_mmx_inline=no
1183     ])
1184   ])
1185   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1186     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1187     have_mmx="yes"
1188   ])
1189
1190   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1191                  [ac_cv_mmxext_inline], [
1192     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1193 void *p;
1194 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1195 ]])
1196     ], [
1197       ac_cv_mmxext_inline=yes
1198     ], [
1199       ac_cv_mmxext_inline=no
1200     ])
1201   ])
1202   VLC_RESTORE_FLAGS
1203   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1204     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1205     have_mmxext="yes"
1206   ])
1207 ])
1208 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1209 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1210
1211 dnl  Check for fully workin SSE2 intrinsics
1212 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1213 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1214 AC_ARG_ENABLE(sse,
1215   [AS_HELP_STRING([--disable-sse],
1216     [disable SSE (1-4) optimizations (default auto)])],, [
1217   case "${host_cpu}" in
1218     i?86|x86_64)
1219       enable_sse=yes
1220       ;;
1221     *)
1222       enable_sse=no
1223       ;;
1224   esac
1225 ])
1226 have_sse2="no"
1227 AS_IF([test "${enable_sse}" != "no"], [
1228   ARCH="${ARCH} sse sse2"
1229
1230   VLC_SAVE_FLAGS
1231   CFLAGS="${CFLAGS} -msse2"
1232   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1233     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1234 [#include <emmintrin.h>
1235 #include <stdint.h>
1236 uint64_t frobzor;]], [
1237 [__m128i a, b, c;
1238 a = b = c = _mm_set1_epi64((__m64)frobzor);
1239 a = _mm_slli_epi16(a, 3);
1240 a = _mm_adds_epi16(a, b);
1241 c = _mm_srli_epi16(c, 8);
1242 c = _mm_slli_epi16(c, 3);
1243 b = _mm_adds_epi16(b, c);
1244 a = _mm_unpacklo_epi8(a, b);
1245 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1246       ac_cv_c_sse2_intrinsics=yes
1247     ], [
1248       ac_cv_c_sse2_intrinsics=no
1249     ])
1250   ])
1251   VLC_RESTORE_FLAGS
1252   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1253     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1254   ])
1255
1256   VLC_SAVE_FLAGS
1257   CFLAGS="${CFLAGS} -msse"
1258   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1259     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1260 void *p;
1261 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1262 ]])
1263     ], [
1264       ac_cv_sse_inline=yes
1265     ], [
1266       ac_cv_sse_inline=no
1267     ])
1268   ])
1269
1270   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1271     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1272   ])
1273
1274   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1275     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1276 void *p;
1277 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1278 ]])
1279     ], [
1280       ac_cv_sse2_inline=yes
1281     ], [
1282       ac_cv_sse2_inline=no
1283     ])
1284   ])
1285   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1286     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1287     have_sse2="yes"
1288   ])
1289
1290   # SSE3
1291   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1292     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1293 void *p;
1294 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1295 ]])
1296     ], [
1297       ac_cv_sse3_inline=yes
1298     ], [
1299       ac_cv_sse3_inline=no
1300     ])
1301   ])
1302
1303   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1304     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1305   # SSSE3
1306   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1307     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1308 void *p;
1309 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1310 ]])
1311     ], [
1312       ac_cv_ssse3_inline=yes
1313     ], [
1314       ac_cv_ssse3_inline=no
1315     ])
1316   ])
1317
1318   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1319     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1320
1321   # SSE4.1
1322   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1323                  [ac_cv_sse4_1_inline], [
1324     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1325 void *p;
1326 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1327 ]])
1328     ], [
1329       ac_cv_sse4_1_inline=yes
1330     ], [
1331       ac_cv_sse4_1_inline=no
1332     ])
1333   ])
1334
1335   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1336     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1337
1338   # SSE4.2
1339   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1340                  [ac_cv_sse4_2_inline], [
1341     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1342 void *p;
1343 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1344 ]])
1345     ], [
1346       ac_cv_sse4_2_inline=yes
1347     ], [
1348       ac_cv_sse4_2_inline=no
1349     ])
1350   ])
1351
1352   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1353     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1354
1355   # SSE4A
1356   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1357     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1358 void *p;
1359 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1360 ]])
1361     ], [
1362       ac_cv_sse4a_inline=yes
1363     ], [
1364       ac_cv_sse4a_inline=no
1365     ])
1366   ])
1367   VLC_RESTORE_FLAGS
1368   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1369     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1370 ])
1371 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1372
1373 VLC_SAVE_FLAGS
1374 CFLAGS="${CFLAGS} -mmmx"
1375 have_3dnow="no"
1376 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1377   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1378 void *p;
1379 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1380 ]])
1381   ], [
1382     ac_cv_3dnow_inline=yes
1383   ], [
1384     ac_cv_3dnow_inline=no
1385   ])
1386 ])
1387 VLC_RESTORE_FLAGS
1388 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1389   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1390             [Define to 1 if 3D Now! inline assembly is available.])
1391   have_3dnow="yes"
1392 ])
1393 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1394
1395
1396 AC_ARG_ENABLE(neon,
1397   [AS_HELP_STRING([--disable-neon],
1398     [disable NEON optimizations (default auto)])],, [
1399   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1400 ])
1401 AS_IF([test "${enable_neon}" != "no"], [
1402   VLC_SAVE_FLAGS
1403   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1404   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1405     AC_COMPILE_IFELSE([
1406       AC_LANG_PROGRAM(,[[
1407 asm volatile("vqmovun.s64 d0, q1":::"d0");
1408 ]])
1409     ], [
1410       ac_cv_arm_neon="yes"
1411     ], [
1412       ac_cv_arm_neon="no"
1413     ])
1414   ])
1415   VLC_RESTORE_FLAGS
1416 ])
1417 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1418
1419
1420 AC_ARG_ENABLE(altivec,
1421   [AS_HELP_STRING([--disable-altivec],
1422     [disable AltiVec optimizations (default auto)])],, [
1423   AS_CASE("${host_cpu}", [powerpc*],
1424         [enable_altivec=yes], [enable_altivec=no])
1425 ])
1426 have_altivec="no"
1427 ALTIVEC_CFLAGS=""
1428 AS_IF([test "${enable_altivec}" = "yes"], [
1429   ARCH="${ARCH} altivec";
1430   VLC_SAVE_FLAGS
1431   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1432     [ac_cv_altivec_inline],
1433     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1434          ac_cv_altivec_inline="yes",
1435          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1436           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1437             [ac_cv_altivec_inline="-Wa,-maltivec"],
1438             ac_cv_altivec_inline=no)
1439          ])])
1440   VLC_RESTORE_FLAGS
1441   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1442     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1443               [Define to 1 if AltiVec inline assembly is available.])
1444     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1445       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1446       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1447     ])
1448     have_altivec="yes"
1449   ])
1450
1451   VLC_SAVE_FLAGS
1452   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1453   [ac_cv_c_altivec], [
1454     CFLAGS="${CFLAGS} -maltivec"
1455     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1456 [#include <altivec.h>]], [
1457 [vec_ld(0, (unsigned char *)0);]])], [
1458       ac_cv_c_altivec="-maltivec"
1459     ], [
1460       ac_cv_c_altivec="no"
1461     ])
1462   ])
1463   VLC_RESTORE_FLAGS
1464   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1465     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1466     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1467     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1468     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1469     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1470     have_altivec="yes"
1471   ])
1472   AC_CHECK_HEADERS(altivec.h)
1473
1474   VLC_SAVE_FLAGS
1475   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1476   AC_CACHE_CHECK([if linker needs -framework vecLib],
1477     [ac_cv_ld_altivec],
1478     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1479   VLC_RESTORE_FLAGS
1480   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1481     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1482   ])
1483 ])
1484 AC_SUBST(ALTIVEC_CFLAGS)
1485 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1486
1487 dnl
1488 dnl  Memory usage
1489 dnl
1490 AC_ARG_ENABLE(optimize-memory,
1491   [AS_HELP_STRING([--enable-optimize-memory],
1492     [optimize memory usage over performance])])
1493 if test "${enable_optimize_memory}" = "yes"; then
1494   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1495 fi
1496
1497 dnl
1498 dnl Allow running as root (useful for people running on embedded platforms)
1499 dnl
1500 AC_ARG_ENABLE(run-as-root,
1501   [AS_HELP_STRING([--enable-run-as-root],
1502     [allow running VLC as root (default disabled)])])
1503 AS_IF([test "${enable_run_as_root}" = "yes"],[
1504     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1505               [Define to 1 to allow running VLC as root (uid 0).])
1506 ])
1507
1508 dnl
1509 dnl Stream output
1510 dnl
1511 AC_ARG_ENABLE(sout,
1512   [AS_HELP_STRING([--disable-sout],
1513     [disable streaming output (default enabled)])])
1514 AS_IF([test "${enable_sout}" != "no"], [
1515   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1516 ])
1517 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1518
1519 dnl Lua modules
1520 AC_ARG_ENABLE(lua,
1521   [AS_HELP_STRING([--disable-lua],
1522     [disable LUA scripting support (default enabled)])])
1523 if test "${enable_lua}" != "no"
1524 then
1525   PKG_CHECK_MODULES(LUA, lua5.2,
1526     [ have_lua=yes ],
1527     [
1528     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1529
1530     PKG_CHECK_MODULES(LUA, lua5.1,
1531       [ have_lua=yes ],
1532       [
1533       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1534       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1535         [ have_lua=yes ],
1536         [
1537           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1538           have_lua=yes
1539           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1540             [],
1541             [ have_lua=no ] )
1542           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1543             [LUA_LIBS="-llua5.2"],
1544           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1545             [LUA_LIBS="-llua5.1"],
1546             AC_CHECK_LIB( lua51 , luaL_newstate,
1547               [LUA_LIBS="-llua51"],
1548               AC_CHECK_LIB( lua , luaL_newstate,
1549                 [LUA_LIBS="-llua"],
1550                 [ have_lua=no
1551                 ], [-lm])
1552             )))
1553         ])
1554       ])
1555     ])
1556   if test "x${have_lua}" != "xyes" ;  then
1557       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1558   fi
1559   AC_ARG_VAR([LUAC], [LUA byte compiler])
1560   AC_CHECK_PROGS(LUAC, [${LUAC} luac], [false])
1561   AS_IF([test "${LUAC}" = "false"], [
1562     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1563   ])
1564   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1565     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1566   ])
1567 fi
1568 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1569
1570
1571 dnl
1572 dnl HTTP daemon
1573 dnl
1574 AC_ARG_ENABLE(httpd,
1575   [AS_HELP_STRING([--disable-httpd],
1576     [disable the built-in HTTP server (default enabled)])])
1577 if test "${enable_httpd}" != "no"
1578 then
1579   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1580 fi
1581 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1582
1583
1584 dnl
1585 dnl VideoLAN manager
1586 dnl
1587 AC_ARG_ENABLE(vlm,
1588   [AS_HELP_STRING([--disable-vlm],
1589     [disable the stream manager (default enabled)])],,
1590   [enable_vlm="${enable_sout}"])
1591 AS_IF([test "${enable_vlm}" != "no"], [
1592   AS_IF([test "${enable_sout}" = "no"], [
1593     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1594   ])
1595   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1596 ])
1597 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1598
1599
1600 dnl
1601 dnl Addons manager storage and repositories modules
1602 dnl
1603 AC_ARG_ENABLE(addonmanagermodules,
1604   [AS_HELP_STRING([--disable-addonmanagermodules],
1605     [disable the addons manager modules (default enabled)])])
1606 if test "${enable_addonmanagermodules}" != "no"
1607 then
1608   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1609 fi
1610 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1611
1612
1613 dnl
1614 dnl  Input plugins
1615 dnl
1616
1617 EXTEND_HELP_STRING([Input plugins:])
1618
1619 dnl
1620 dnl  libarchive access module
1621 dnl
1622 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1623
1624 dnl
1625 dnl  live555 input
1626 dnl
1627 AC_ARG_ENABLE(live555,
1628   [AS_HELP_STRING([--enable-live555],
1629     [enable RTSP input through live555 (default enabled)])])
1630
1631 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1632   PKG_CHECK_MODULES(LIVE555, live555, [
1633     VLC_ADD_PLUGIN([live555])
1634     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1635     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1636   ], [
1637     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1638
1639     AC_LANG_PUSH(C++)
1640     VLC_SAVE_FLAGS
1641
1642     dnl detect include paths
1643     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1644       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1645     ], [
1646       AS_IF([test "${SYS}" != "os2"], [
1647         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1648         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1649       ], [
1650         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1651         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1652         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1653       ])
1654     ])
1655
1656     dnl CPP Flags
1657     AS_IF([test "${SYS}" = "solaris"], [
1658       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1659     ])
1660     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1661     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1662
1663     dnl version check
1664     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1665       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1666 [#include <liveMedia_version.hh>
1667 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1668 # error BOOM
1669 #endif]])
1670       ], [
1671         ac_cv_live555="yes"
1672       ], [
1673         ac_cv_live555="no"
1674       ])
1675     ])
1676
1677     AS_IF([test "$ac_cv_live555" = "no"], [
1678       AC_MSG_WARN([live555 is missing or its installed version is too old:
1679 Version 2011.12.23 or later is required to proceed.
1680 You can get an updated one from http://www.live555.com/liveMedia .])
1681       AS_IF([test -n "${enable_live555}"], [
1682         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1683       ])
1684     ], [
1685       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1686       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1687       AS_IF([test "${SYS}" = "mingw32"], [
1688         # add ws2_32 for closesocket, select, recv
1689         other_libs="$other_libs -lws2_32"
1690       ])
1691
1692       dnl We need to check for pic because live555 don't provide shared libs
1693       dnl and we want to build a plugins so we need -fPIC on some arch.
1694       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1695       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1696       AC_CHECK_LIB(liveMedia_pic, main, [
1697         VLC_ADD_PLUGIN([live555])
1698         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1699       ],[
1700         AC_CHECK_LIB(liveMedia, main, [
1701           VLC_ADD_PLUGIN([live555])
1702           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1703         ],[],[${other_libs}])
1704       ],[${other_libs_pic}])
1705     ])
1706     VLC_RESTORE_FLAGS
1707     AC_LANG_POP(C++)
1708   ])
1709 ])
1710
1711 dnl
1712 dnl IIDC and DV FireWire input modules
1713 dnl
1714 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1715 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1716
1717 dnl
1718 dnl - linsys modules: access module check for libzvbi
1719 dnl
1720 AC_ARG_ENABLE(linsys,
1721   [AS_HELP_STRING([--enable-linsys],
1722     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1723 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1724   VLC_ADD_PLUGIN([linsys_hdsdi])
1725   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1726     VLC_ADD_PLUGIN([linsys_sdi])
1727   ], [
1728     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1729   ])
1730 ])
1731
1732 dnl
1733 dnl dvdread module: check for libdvdread
1734 dnl
1735 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1736
1737 dnl
1738 dnl libdvdnav plugin
1739 dnl
1740 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1741 AS_IF([test "${enable_dvdnav}" != "no"], [
1742   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1743     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1744       AC_MSG_RESULT(yes)
1745       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1746       ],[
1747       AC_MSG_RESULT(no)
1748     ])
1749 ])
1750
1751 dnl
1752 dnl  Blu-ray Disc Support with libbluray
1753 dnl
1754 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1755
1756 dnl
1757 dnl  OpenCV wrapper and example filters
1758 dnl
1759 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1760
1761
1762 dnl
1763 dnl  libsmbclient plugin
1764 dnl
1765 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1766 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([smb]) ])
1767
1768 dnl
1769 dnl  liBDSM access module
1770 dnl
1771 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.0.7], [libdsm SMB/CIFS access/sd module], [auto])
1772
1773 dnl
1774 dnl sftp access support
1775 dnl
1776 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1777
1778 dnl
1779 dnl nfs access support
1780 dnl
1781 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs], (support nfs protocol via libnfs), [auto])
1782
1783 dnl
1784 dnl  Video4Linux 2
1785 dnl
1786 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1787   [disable Video4Linux version 2 (default auto)])])
1788 have_v4l2="no"
1789 AS_IF([test "$enable_v4l2" != "no"], [
1790   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1791     have_v4l2="yes"
1792   ])
1793 ])
1794 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1795
1796 dnl
1797 dnl special access module for Blackmagic SDI cards
1798 dnl
1799 AC_ARG_ENABLE(decklink,
1800   [AS_HELP_STRING([--disable-decklink],
1801     [disable Blackmagic DeckLink SDI input (default auto)])])
1802 AC_ARG_WITH(decklink_sdk,
1803   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1804     [                        location of Blackmagic DeckLink SDI SDK])])
1805 have_decklink=no
1806 if test "${enable_decklink}" != "no"
1807 then
1808   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1809   then
1810     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1811   fi
1812   VLC_SAVE_FLAGS
1813   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1814   AC_LANG_PUSH(C++)
1815   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1816       have_decklink=yes
1817   ], [
1818       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1819   ])
1820   AC_LANG_POP(C++)
1821   VLC_RESTORE_FLAGS
1822 fi
1823 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1824
1825
1826 dnl
1827 dnl  Built-in CD-DA and VCD module
1828 dnl
1829 AC_ARG_ENABLE(vcd,
1830   [AS_HELP_STRING([--disable-vcd],
1831     [disable built-in VCD and CD-DA support (default enabled)])])
1832
1833 AC_ARG_ENABLE(libcddb,
1834   [AS_HELP_STRING([--disable-libcddb],
1835     [disable CDDB for Audio CD (default enabled)])])
1836
1837 if test "${enable_vcd}" != "no"
1838 then
1839   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1840   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1841     AC_MSG_RESULT(yes)
1842     VLC_ADD_PLUGIN([vcd cdda])
1843   ],[
1844     AC_MSG_RESULT(no)
1845   ])
1846
1847   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1848   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1849     AC_MSG_RESULT(yes)
1850     VLC_ADD_PLUGIN([vcd cdda])
1851     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1852   ],[
1853     AC_MSG_RESULT(no)
1854   ])
1855
1856   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1857   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1858     AC_MSG_RESULT(yes)
1859     VLC_ADD_PLUGIN([vcd cdda])
1860     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1861   ],[
1862     AC_MSG_RESULT(no)
1863   ])
1864
1865   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1866   then
1867     VLC_ADD_PLUGIN([vcd cdda])
1868   fi
1869
1870   if test "$enable_libcddb" != "no"; then
1871     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1872       HAVE_LIBCDDB=yes
1873       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1874       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1875       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1876       ],:
1877       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1878       HAVE_LIBCDDB=no])
1879   fi
1880 fi
1881
1882 dnl
1883 dnl Linux DVB
1884 dnl
1885 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1886   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1887 [#include <linux/dvb/version.h>
1888 #if (DVB_API_VERSION < 5)
1889 # error Linux DVB API v3.2 and older are not supported.
1890 #endif
1891 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1892 # error Linux DVB API v5.0 is unsupported. Please update.
1893 #endif
1894 ]])], [
1895   ac_cv_linux_dvb_5_1=yes
1896 ], [
1897   ac_cv_linux_dvb_5_1=no
1898 ])])
1899 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1900
1901 dnl
1902 dnl  Screen capture module
1903 dnl
1904 AC_ARG_ENABLE(screen,
1905   [AS_HELP_STRING([--enable-screen],
1906     [disable screen capture (default enabled)])])
1907 if test "${enable_screen}" != "no"; then
1908   if test "${SYS}" = "darwin"; then
1909     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1910       VLC_ADD_PLUGIN([screen])
1911     ])
1912   fi
1913 fi
1914 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1915
1916 dnl
1917 dnl  VNC/RFB access module
1918 dnl
1919 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1920
1921 dnl  RDP/Remote Desktop access module
1922 dnl
1923 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1924
1925 dnl
1926 dnl  Real RTSP plugin
1927 dnl
1928 AC_ARG_ENABLE(realrtsp,
1929   [  --enable-realrtsp       Real RTSP module (default disabled)])
1930 if test "${enable_realrtsp}" = "yes"; then
1931   VLC_ADD_PLUGIN([access_realrtsp])
1932 fi
1933
1934 dnl
1935 dnl MacOS eyeTV
1936 AC_ARG_ENABLE(macosx-eyetv,
1937   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1938 if test "x${enable_macosx_eyetv}" != "xno" &&
1939   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1940 then
1941   VLC_ADD_PLUGIN([access_eyetv])
1942 fi
1943
1944 dnl
1945 dnl QTKit
1946 AC_ARG_ENABLE(macosx-qtkit,
1947   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X)])
1948 if test "x${enable_macosx_qtkit}" != "xno" &&
1949   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1950 then
1951   VLC_ADD_PLUGIN([qtsound])
1952 fi
1953 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1954
1955 dnl
1956 dnl AVFoundation
1957 AC_SUBST(have_avfoundation, ["no"])
1958 AC_ARG_ENABLE(macosx-avfoundation,
1959   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1960 if test "x${enable_macosx_avfoundation}" != "xno" &&
1961   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1962 then
1963   SAVED_LIBS="${LIBS}"
1964   LIBS="-framework AVFoundation"
1965   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1966   LIBS="${SAVED_LIBS}"
1967   if test "${have_avfoundation}" != "no"
1968   then
1969     VLC_ADD_PLUGIN([avcapture])
1970   fi
1971 fi
1972 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1973
1974 dnl
1975 dnl  DCP plugin (using asdcplib)
1976 dnl
1977 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1978 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1979
1980 dnl
1981 dnl  Demux plugins
1982 dnl
1983
1984 EXTEND_HELP_STRING([Mux/Demux plugins:])
1985
1986 dnl
1987 dnl  libdvbpsi check for ts mux/demux
1988 dnl
1989 have_dvbpsi="no"
1990 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
1991 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1992
1993
1994 dnl
1995 dnl  GME demux plugin
1996 dnl
1997 AC_ARG_ENABLE(gme,
1998   [AS_HELP_STRING([--enable-gme],
1999     [use Game Music Emu (default auto)])])
2000 AS_IF([test "${enable_gme}" != "no"], [
2001   AC_CHECK_HEADER([gme/gme.h], [
2002     VLC_ADD_LIBS([gme], [-lgme])
2003     VLC_ADD_PLUGIN([gme])
2004   ], [
2005     AS_IF([test "x${enable_gme}" != "x"], [
2006       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2007     ])
2008   ])
2009 ])
2010
2011
2012 dnl
2013 dnl  SIDPlay plugin
2014 dnl
2015 AC_ARG_ENABLE(sid,
2016     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2017 AS_IF([test "${enable_sid}" != "no"], [
2018     PKG_CHECK_MODULES(SID, [libsidplay2], [
2019         AC_LANG_PUSH(C++)
2020         oldCPPFLAGS="$CPPFLAGS"
2021         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2022         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2023             VLC_ADD_PLUGIN([sid])
2024             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2025             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2026         ], [
2027             AS_IF([test -n "${enable_sid}"],
2028                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2029                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2030                 )
2031         ])
2032         CPPFLAGS="$oldCPPFLAGS"
2033         AC_LANG_POP(C++)
2034     ], [
2035         AS_IF([test "x${enable_sid}" = "xyes"],
2036             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2037             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2038             )
2039     ])
2040 ])
2041
2042
2043 dnl
2044 dnl  ogg demux plugin
2045 dnl
2046 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2047 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2048     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2049 ],[true])
2050 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2051 if test "${enable_sout}" != "no"; then
2052 dnl Check for libshout
2053     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2054 fi
2055
2056 dnl
2057 dnl  matroska demux plugin
2058 dnl
2059 AC_ARG_ENABLE(mkv,
2060   [AS_HELP_STRING([--disable-mkv],
2061     [do not use libmatroska (default auto)])])
2062 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2063   AC_LANG_PUSH(C++)
2064   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2065     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2066     AC_EGREP_CPP(yes,
2067       [#include <ebml/EbmlVersion.h>
2068        #ifdef LIBEBML_VERSION
2069        #if LIBEBML_VERSION >= 0x010000
2070        yes
2071        #endif
2072        #endif],
2073       [AC_MSG_RESULT([yes])
2074         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2075           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2076           AC_EGREP_CPP(yes,
2077             [#include <matroska/KaxVersion.h>
2078              #ifdef LIBMATROSKA_VERSION
2079              #if LIBMATROSKA_VERSION >= 0x010000
2080              yes
2081              #endif
2082              #endif],
2083             [AC_MSG_RESULT([yes])
2084               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2085               AC_CHECK_LIB(ebml_pic, main, [
2086                 VLC_ADD_PLUGIN([mkv])
2087                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2088               ],[
2089                 AC_CHECK_LIB(ebml, main, [
2090                   VLC_ADD_PLUGIN([mkv])
2091                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2092                 ])
2093               ])
2094             ], [
2095               AC_MSG_RESULT([no])
2096               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2097           ])
2098         ])
2099       ],
2100       [AC_MSG_RESULT([no])
2101         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2102     ])
2103   ])
2104   AC_LANG_POP(C++)
2105 fi
2106
2107 dnl
2108 dnl  modplug demux plugin
2109 dnl
2110 AC_ARG_ENABLE(mod,
2111   [AS_HELP_STRING([--disable-mod],
2112     [do not use libmodplug (default auto)])])
2113 if test "${enable_mod}" != "no" ; then
2114     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2115           VLC_ADD_PLUGIN([mod])
2116           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2117           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2118           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2119     ],[
2120        AS_IF([test -n "${enable_mod}"],
2121          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2122          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2123     ])
2124 fi
2125
2126 dnl
2127 dnl  mpc demux plugin
2128 dnl
2129 AC_ARG_ENABLE(mpc,
2130   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2131 if test "${enable_mpc}" != "no"
2132 then
2133   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2134     VLC_ADD_PLUGIN([mpc])
2135     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2136     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2137     VLC_ADD_PLUGIN([mpc])
2138     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2139 fi
2140
2141 dnl
2142 dnl  Codec plugins
2143 dnl
2144
2145 EXTEND_HELP_STRING([Codec plugins:])
2146
2147 dnl
2148 dnl wmafixed plugin
2149 dnl
2150 AC_ARG_ENABLE(wma-fixed,
2151   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2152 if test "${enable_wma_fixed}" = "yes"
2153 then
2154   VLC_ADD_PLUGIN([wma_fixed])
2155 fi
2156
2157 dnl
2158 dnl shine encoder plugin
2159 dnl
2160 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2161
2162
2163 dnl
2164 dnl openmax il codec plugin
2165 dnl
2166 AC_ARG_ENABLE(omxil,
2167   [  --enable-omxil          openmax il codec module (default disabled)])
2168 if test "${enable_omxil}" = "yes"
2169 then
2170   VLC_ADD_PLUGIN([omxil])
2171 fi
2172
2173 dnl
2174 dnl openmax il vout plugin
2175 dnl
2176 AC_ARG_ENABLE(omxil-vout,
2177   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2178 if test "${enable_omxil_vout}" = "yes"
2179 then
2180   VLC_ADD_PLUGIN([omxil_vout])
2181 fi
2182
2183 dnl
2184 dnl raspberry pi openmax il configuration
2185 dnl
2186 AC_ARG_ENABLE(rpi-omxil,
2187   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2188 if test "${enable_rpi_omxil}" = "yes"
2189 then
2190   VLC_ADD_PLUGIN([omxil omxil_vout])
2191   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2192 fi
2193
2194 dnl
2195 dnl CrystalHD codec plugin
2196 dnl
2197 AC_ARG_ENABLE(crystalhd,
2198   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2199 if test "${enable_crystalhd}" != "no"; then
2200     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2201       VLC_ADD_PLUGIN([crystalhd])
2202       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2203     ],[
2204       if test "${SYS}" = "mingw32" ; then
2205         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2206           VLC_ADD_PLUGIN([crystalhd])
2207           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2208             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2209             ])
2210         ],[
2211           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2212                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2213                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2214         ],[#define __LINUX_USER__
2215                #include <libcrystalhd/bc_dts_types.h>
2216         ])
2217       fi
2218     ],[
2219        #include <libcrystalhd/bc_dts_types.h>
2220       ])
2221 fi
2222
2223 dnl
2224 dnl  mad plugin
2225 dnl
2226 have_mad="no"
2227 MAD_CFLAGS=""
2228 MAD_LIBS=""
2229
2230 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2231   enable_mad="yes"
2232 ], [
2233   with_mad="no"
2234 ])
2235 AS_IF([test "${with_mad}" != "no"], [
2236   MAD_CFLAGS="-I${with_mad}/include"
2237   MAD_LIBS="-L${with_mad}/lib"
2238 ])
2239
2240 AC_ARG_ENABLE(mad,
2241   [  --enable-mad            libmad module (default enabled)])
2242 AS_IF([test "${enable_mad}" != "no"], [
2243   VLC_SAVE_FLAGS
2244   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2245   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2246   AC_CHECK_HEADERS(mad.h, [
2247     AC_CHECK_LIB(mad, mad_bit_init, [
2248       have_mad="yes"
2249       MAD_LIBS="${MAD_LIBS} -lmad"
2250     ])
2251   ])
2252   VLC_RESTORE_FLAGS
2253   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2254     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2255   ])
2256 ])
2257 AC_SUBST(MAD_CFLAGS)
2258 AC_SUBST(MAD_LIBS)
2259 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2260
2261 dnl  mpg123 plugin
2262 dnl
2263 dnl
2264 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2265
2266
2267 AC_ARG_ENABLE(merge-ffmpeg,
2268 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2269   enable_merge_ffmpeg="no"
2270 ])
2271 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2272
2273 AC_MSG_CHECKING([for libavutil variant])
2274 PKG_CHECK_EXISTS([libavutil], [
2275   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2276   libavutil_micro="${libavutil_version##*.}"
2277   AS_IF([test ${libavutil_micro} -le 99], [
2278     avfork="libav"
2279   ], [
2280     avfork="ffmpeg"
2281   ])
2282 ], [
2283   avfork="none"
2284 ])
2285 AC_MSG_RESULT([${avfork}])
2286
2287 dnl
2288 dnl gstreamer stuff
2289 dnl
2290 AC_ARG_ENABLE(gst-decode,
2291   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2292
2293 have_gst_decode="no"
2294 AS_IF([test "${enable_gst_decode}" != "no"], [
2295   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2296     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2297       have_gst_decode="yes"
2298     ], [
2299       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2300     ])
2301   ], [
2302     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2303   ])
2304 ])
2305 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2306
2307 dnl
2308 dnl  avcodec decoder/encoder plugin
2309 dnl
2310 AC_ARG_ENABLE(avcodec,
2311 [  --enable-avcodec        libavcodec codec (default enabled)])
2312 AS_IF([test "${enable_avcodec}" != "no"], [
2313   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 55.0.0 libavutil >= 52.0.0], [
2314     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2315     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2316     dnl ])
2317     VLC_SAVE_FLAGS
2318     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2319     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2320     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2321     AC_CHECK_HEADERS(libavutil/avutil.h)
2322     VLC_RESTORE_FLAGS
2323     have_avcodec="yes"
2324   ],[
2325     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2326   ])
2327 ], [
2328   have_avcodec="no"
2329 ])
2330 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2331
2332 dnl
2333 dnl libva needs avcodec
2334 dnl
2335 AC_ARG_ENABLE(libva,
2336   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2337
2338 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2339   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2340 ])
2341
2342 have_vaapi="no"
2343 have_vaapi_drm="no"
2344 have_vaapi_x11="no"
2345 AS_IF([test "${enable_libva}" != "no"], [
2346   PKG_CHECK_EXISTS([libva], [
2347     have_vaapi="yes"
2348   ], [
2349     AS_IF([test -n "${enable_libva}"], [
2350       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2351     ], [
2352       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2353     ])
2354   ])
2355   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2356     have_vaapi_drm="yes"
2357   ], [
2358     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2359   ])
2360   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2361     have_vaapi_x11="yes"
2362   ], [
2363     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2364   ])
2365 ])
2366 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2367 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2368
2369 have_avcodec_vaapi="no"
2370 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2371   case "${avfork}" in
2372     ffmpeg)
2373       PKG_CHECK_EXISTS([libavcodec >= 57.10.100], [
2374         AC_MSG_ERROR([VA API requires FFmpeg libavcodec < 57.10 or libav.])
2375       ])
2376       ;;
2377   esac
2378   VLC_SAVE_FLAGS
2379   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2380   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2381   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2382     AC_MSG_NOTICE([VA API acceleration activated])
2383     have_avcodec_vaapi="yes"
2384   ],[
2385     AS_IF([test -n "${enable_libva}"], [
2386       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2387     ], [
2388       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2389     ])
2390   ])
2391   VLC_RESTORE_FLAGS
2392 ])
2393 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2394
2395 dnl
2396 dnl dxva2 needs avcodec
2397 dnl
2398 AC_ARG_ENABLE(dxva2,
2399   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2400
2401 have_avcodec_dxva2="no"
2402 AS_IF([test "${enable_dxva2}" != "no"], [
2403   if test "${SYS}" = "mingw32"; then
2404   AS_IF([test "x${have_avcodec}" = "xyes"], [
2405     case "${avfork}" in
2406       ffmpeg)
2407         PKG_CHECK_EXISTS([libavcodec >= 57.10.100], [
2408           AC_MSG_ERROR([DXVA2 requires FFmpeg libavcodec < 57.10 or libav.])
2409         ])
2410         ;;
2411     esac
2412     AC_CHECK_HEADERS(dxva2api.h,
2413       [
2414         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2415            AC_MSG_NOTICE([DxVA2 acceleration activated])
2416            have_avcodec_dxva2="yes"
2417         ],[
2418     AS_IF([test "${enable_dxva2}" = "yes"],
2419           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2420               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2421         ], [#undef _WIN32_WINNT
2422             /* DXVA2 is only available in Vista and above */
2423             #define _WIN32_WINNT 0x600])
2424       ],[
2425     AS_IF([test "${enable_dxva2}" = "yes"],
2426               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2427               [AC_MSG_WARN([dxva2api.h not found])])
2428       ])
2429   ],[
2430     AS_IF([test "x${enable_dxva2}" != "x"], [
2431       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2432     ])
2433   ])
2434   fi
2435 ])
2436 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2437
2438 dnl
2439 dnl d3d11va needs avcodec
2440 dnl
2441 AC_ARG_ENABLE(d3d11va,
2442   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2443
2444 have_avcodec_d3d11va="no"
2445 AS_IF([test "${enable_d3d11va}" != "no"], [
2446   if test "${SYS}" = "mingw32"; then
2447   AS_IF([test "x${have_avcodec}" = "xyes"], [
2448         AC_CHECK_TYPES([ID3D11VideoDecoder],
2449           [
2450             AC_CHECK_HEADERS(dxva2api.h,
2451               [
2452                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2453                    AC_MSG_NOTICE([D3D11 acceleration activated])
2454                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2455                    have_avcodec_d3d11va="yes"
2456                 ],[
2457                   AS_IF([test "${enable_d3d11va}" = "yes"],
2458                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2459                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2460                   ], [#undef _WIN32_WINNT
2461                       /* D3D11 is only available in Vista and above */
2462                       #define _WIN32_WINNT 0x600])
2463                   ],[
2464                     AS_IF([test "${enable_d3d11va}" = "yes"],
2465                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2466                           [AC_MSG_WARN([dxva2api.h not found])])
2467                   ])
2468           ],[
2469             AS_IF([test "${enable_d3d11va}" = "yes"],
2470                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2471                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2472           ], [#include <d3d11.h>])
2473   ],[
2474     AS_IF([test "x${enable_d3d11va}" != "x"], [
2475       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2476     ])
2477   ])
2478   fi
2479 ])
2480 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2481
2482 dnl
2483 dnl DXGI debug
2484 dnl
2485 AC_CHECK_HEADERS(dxgidebug.h)
2486
2487 dnl
2488 dnl vda needs avcodec
2489 dnl
2490 AC_ARG_ENABLE(vda,
2491   [  --enable-vda          VDA  support (default auto)])
2492
2493 have_avcodec_vda="no"
2494 AS_IF([test "${enable_vda}" != "no"], [
2495   if test "${SYS}" = "darwin"; then
2496   AS_IF([test "x${have_avcodec}" = "xyes"], [
2497     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2498       [
2499         AC_CHECK_HEADERS(libavcodec/vda.h, [
2500            have_avcodec_vda="yes"
2501         ],[
2502         AS_IF([test "${enable_vda}" = "yes"],
2503               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2504               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2505         ])
2506   ],[
2507         AS_IF([test "${enable_vda}" = "yes"],
2508               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2509               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2510       ])
2511   ],[
2512     AS_IF([test "x${enable_vda}" != "x"], [
2513       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2514     ])
2515  ])
2516  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2517      SAVE_LIBS=$LIBS
2518      LIBS="$LIBS $AVCODEC_LIBS"
2519      AC_CHECK_FUNCS([av_vda_alloc_context])
2520      LIBS=$SAVE_LIBS
2521  ])
2522  fi
2523 ])
2524 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2525
2526 dnl
2527 dnl  avformat demuxer/muxer plugin
2528 dnl
2529
2530 AC_ARG_ENABLE(avformat,
2531 [  --enable-avformat       libavformat containers (default enabled)],, [
2532   enable_avformat="${have_avcodec}"
2533 ])
2534 have_avformat="no"
2535 AS_IF([test "${enable_avformat}" != "no"], [
2536   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2537       have_avformat="yes"
2538       VLC_SAVE_FLAGS
2539       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2540       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2541       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2542       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2543       AC_CHECK_HEADERS(libavutil/avutil.h)
2544       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2545         have_avformat="no"
2546       ])
2547       VLC_RESTORE_FLAGS
2548     ],[
2549       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2550   ])
2551 ])
2552 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2553
2554 dnl
2555 dnl  swscale image scaling and conversion plugin
2556 dnl
2557
2558 AC_ARG_ENABLE(swscale,
2559   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2560           (default enabled)]))
2561 if test "${enable_swscale}" != "no"
2562 then
2563   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2564     [
2565       VLC_SAVE_FLAGS
2566       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2567       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2568       AC_CHECK_HEADERS(libswscale/swscale.h)
2569       AC_CHECK_HEADERS(libavutil/avutil.h)
2570       VLC_ADD_PLUGIN([swscale])
2571       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2572       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2573       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2574         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2575       ])
2576       VLC_RESTORE_FLAGS
2577     ],[
2578       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2579   ])
2580 fi
2581
2582 dnl
2583 dnl  postproc plugin
2584 dnl
2585
2586 AC_ARG_ENABLE(postproc,
2587 [  --enable-postproc       libpostproc image post-processing (default auto)])
2588 if test "${enable_postproc}" != "no"
2589 then
2590   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2591     [
2592       VLC_SAVE_FLAGS
2593       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2594       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2595       AC_CHECK_HEADERS(postproc/postprocess.h)
2596       VLC_ADD_PLUGIN([postproc])
2597       VLC_RESTORE_FLAGS
2598     ],[
2599       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2600   ])
2601 fi
2602
2603 dnl
2604 dnl  faad decoder plugin
2605 dnl
2606 AC_ARG_ENABLE(faad,
2607 [  --enable-faad           faad codec (default auto)])
2608 have_faad="no"
2609 AS_IF([test "${enable_faad}" != "no"], [
2610   AC_CHECK_HEADERS([neaacdec.h], [
2611     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2612
2613     AS_IF([test "${have_faad}" = "yes"], [
2614       VLC_ADD_PLUGIN([faad])
2615       VLC_ADD_LIBS([faad],[-lfaad])
2616     ], [
2617       AS_IF([test "${enable_faad}" = "yes"], [
2618         AC_MSG_ERROR([cannot find FAAD library])
2619       ], [
2620         AC_MSG_WARN([cannot find FAAD library])
2621       ])
2622     ])
2623   ])
2624 ])
2625
2626 dnl
2627 dnl libvpx decoder plugin
2628 dnl
2629 AC_ARG_ENABLE(vpx,
2630     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2631 AS_IF([test "${enable_vpx}" != "no"],[
2632     PKG_CHECK_MODULES([VPX], [vpx] , [
2633         VLC_ADD_PLUGIN([vpx])
2634         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2635         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2636         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2637             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2638         ], [], [${VPX_LIBS}])
2639         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2640             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2641         ], [], [${VPX_LIBS}])
2642         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2643             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2644         ], [], [${VPX_LIBS}])
2645         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2646             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2647         ], [], [${VPX_LIBS}])
2648     ], [
2649     AS_IF([test "${enable_vpx}" = "yes"],[
2650         AC_MSG_ERROR([libvpx was not found])
2651     ])])
2652 ])
2653
2654 dnl
2655 dnl twolame encoder plugin
2656 dnl
2657 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2658
2659 dnl
2660 dnl fdk-aac encoder plugin
2661 dnl
2662 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2663
2664 dnl
2665 dnl  QuickTime plugin
2666 dnl
2667 AC_ARG_ENABLE(quicktime,
2668   [  --enable-quicktime      QuickTime module (deprecated)])
2669 if test "${enable_quicktime}" = "yes"; then
2670   if test "${SYS}" = "mingw32"; then
2671     VLC_ADD_PLUGIN([quicktime])
2672   else
2673   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2674     [ VLC_ADD_PLUGIN([quicktime])
2675       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2676     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2677   fi
2678 fi
2679
2680 dnl
2681 dnl A52/AC3 decoder plugin
2682 dnl
2683 AC_ARG_ENABLE(a52,
2684   [  --enable-a52            A/52 support with liba52 (default enabled)])
2685 if test "${enable_a52}" != "no"
2686 then
2687   AC_ARG_WITH(a52,
2688     [  --with-a52=PATH         a52 headers and libraries])
2689     if test -z "${with_a52}"
2690     then
2691       LDFLAGS_test=""
2692       CPPFLAGS_test=""
2693     else
2694       LDFLAGS_test="-L${with_a52}/lib"
2695       CPPFLAGS_test="-I${with_a52}/include"
2696     fi
2697     VLC_SAVE_FLAGS
2698     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2699     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2700     AC_CHECK_HEADERS(a52dec/a52.h, [
2701       AC_CHECK_LIB(a52, a52_free, [
2702         VLC_ADD_PLUGIN([a52tofloat32])
2703         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2704         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2705       ],[
2706         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2707         ], [$LIBM])
2708     ],[
2709       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2710     ])
2711     VLC_RESTORE_FLAGS
2712 fi
2713
2714 dnl
2715 dnl DTS Coherent Acoustics decoder plugin
2716 dnl
2717 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2718
2719 dnl
2720 dnl  Flac plugin
2721 dnl
2722 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2723
2724 dnl
2725 dnl  Libmpeg2 plugin
2726 dnl
2727 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2728
2729 dnl
2730 dnl  Vorbis plugin
2731 dnl
2732 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2733
2734 dnl
2735 dnl  Tremor plugin
2736 dnl
2737 AC_ARG_ENABLE(tremor,
2738   [  --enable-tremor         Tremor decoder support (default disabled)])
2739 if test "${enable_tremor}" = "yes"
2740 then
2741   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2742     VLC_ADD_PLUGIN([tremor])
2743    ],[])
2744 fi
2745
2746 dnl
2747 dnl  Speex plugins
2748 dnl
2749 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2750 have_speexdsp="no"
2751 AS_IF([test "${enable_speex}" != "no"], [
2752   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2753     have_speexdsp="yes"
2754   ], [
2755     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2756   ])
2757 ])
2758 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2759
2760 dnl
2761 dnl  Opus plugin
2762 dnl
2763 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2764
2765 dnl
2766 dnl  theora decoder plugin
2767 dnl
2768 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2769
2770 dnl
2771 dnl  Daala decoder plugin
2772 dnl
2773 PKG_ENABLE_MODULES_VLC([DAALA], [], [ogg daaladec daalaenc], [experimental daala codec], [disabled])
2774
2775 dnl
2776 dnl  schroedinger decoder plugin (for dirac format video)
2777 dnl
2778 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2779
2780 dnl
2781 dnl  PNG decoder module
2782 dnl
2783 AC_ARG_ENABLE(png,
2784   [  --enable-png            PNG support (default enabled)])
2785 AS_IF([test "${enable_png}" != "no"], [
2786 AC_CHECK_HEADERS(png.h, [
2787   VLC_SAVE_FLAGS
2788   LDFLAGS="${LDFLAGS} -lz $LIBM"
2789   AC_CHECK_LIB(png, png_set_rows, [
2790     VLC_ADD_PLUGIN([png])
2791   ], [], [-lz $LIBM])
2792   VLC_RESTORE_FLAGS
2793   ])
2794 ])
2795
2796 dnl
2797 dnl  JPEG decoder module
2798 dnl
2799 AC_ARG_ENABLE(jpeg,
2800   [  --enable-jpeg           JPEG support (default enabled)])
2801 AS_IF([test "${enable_jpeg}" != "no"], [
2802 AC_CHECK_HEADERS(jpeglib.h, [
2803   VLC_ADD_PLUGIN([jpeg])
2804   ])
2805 ])
2806
2807 dnl
2808 dnl  BPG decoder module
2809 dnl
2810 AC_ARG_ENABLE(bpg,
2811   [  --enable-bpg           BPG support (default disabled)])
2812 AS_IF([test "${enable_bpg}" != "no"], [
2813 AC_CHECK_HEADERS(libbpg.h, [
2814   VLC_ADD_PLUGIN([bpg])
2815   ])
2816 ])
2817
2818 dnl
2819 dnl H262 encoder plugin (lib262)
2820 dnl
2821 AC_ARG_ENABLE(x262,
2822   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2823 if test "${enable_x262}" != "no"; then
2824     PKG_CHECK_MODULES(X262, x262, [
2825         VLC_ADD_PLUGIN([x262])
2826         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2827         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2828           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2829         ])
2830         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2831         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2832           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2833         fi
2834     ], [
2835        if test "${enable_x262}" = "yes"; then
2836         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2837        fi
2838     ])
2839 fi
2840
2841 dnl x265 encoder
2842 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2843
2844 dnl
2845 dnl H264 encoder plugin (10-bit lib264)
2846 dnl
2847 AC_ARG_ENABLE(x26410b,
2848   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2849 if test "${enable_x26410b}" != "no"; then
2850     PKG_CHECK_MODULES(X26410B, x26410b, [
2851         VLC_ADD_PLUGIN([x26410b])
2852         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2853         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2854           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2855         ])
2856         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2857         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2858           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2859         fi
2860     ], [
2861        if test "${enable_x26410b}" = "yes"; then
2862         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2863        fi
2864     ])
2865 fi
2866
2867
2868 dnl
2869 dnl H264 encoder plugin (using libx264)
2870 dnl
2871 AC_ARG_ENABLE(x264,
2872   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2873 if test "${enable_x264}" != "no"; then
2874       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2875         VLC_ADD_PLUGIN([x264])
2876         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2877
2878         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2879           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2880         ])
2881
2882         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2883         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2884           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2885         fi
2886       ],[
2887         if test "${enable_x264}" = "yes"; then
2888             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2889           fi
2890       ])
2891 fi
2892
2893 dnl
2894 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2895 dnl
2896 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2897
2898 dnl
2899 dnl libfluidsynth (MIDI synthetizer) plugin
2900 dnl
2901 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2902
2903 dnl
2904 dnl Teletext Modules
2905 dnl vbi decoder plugin (using libzbvi)
2906 dnl telx module
2907 dnl uncompatible
2908 dnl
2909 AC_ARG_ENABLE(zvbi,
2910   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2911                   libzvbi (default enabled)]))
2912 AC_ARG_ENABLE(telx,
2913   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2914                   zvbi) (default enabled if zvbi is absent)]))
2915
2916 AS_IF( [test "${enable_zvbi}" != "no"],[
2917     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2918         [
2919           VLC_ADD_PLUGIN([zvbi])
2920           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2921           AS_IF( [test "${enable_telx}" = "yes"],[
2922                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2923                   ])
2924         ],[
2925           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2926         ])
2927     ])
2928 AS_IF( [test "${enable_telx}" != "no" ],[
2929   VLC_ADD_PLUGIN([telx])
2930   ])
2931
2932 dnl
2933 dnl libass subtitle rendering module
2934 dnl
2935 AC_ARG_ENABLE(libass,
2936   [  --enable-libass         Subtitle support using libass (default enabled)])
2937 AS_IF( [test "${enable_libass}" != "no"], [
2938   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2939       [
2940         VLC_ADD_PLUGIN([libass])
2941
2942         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2943           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2944            VLC_ADD_LIBS([libass],[-lfontconfig])
2945        ])
2946       ],[
2947         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2948       ])
2949   ])
2950
2951 dnl
2952 dnl ARIB subtitles rendering module
2953 dnl
2954 AC_ARG_ENABLE(aribsub,
2955   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2956 AS_IF( [test "${enable_aribsub}" != "no" ],[
2957   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2958       have_aribb24="yes"
2959       VLC_ADD_PLUGIN([aribsub])
2960       VLC_ADD_LIBS([aribsub],[-laribb24])
2961       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2962     ],[
2963       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2964       have_aribb24="no"
2965   ])
2966 ])
2967 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2968
2969 dnl
2970 dnl ARIB B25
2971 dnl
2972 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2973
2974 dnl
2975 dnl  kate decoder plugin
2976 dnl
2977 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2978
2979 dnl
2980 dnl  tiger rendering for kate decoder plugin
2981 dnl
2982 AC_ARG_ENABLE(tiger,
2983 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2984 AS_IF([test "${enable_tiger}" != "no"], [
2985   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2986       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2987         AS_IF([test -n "${enable_tiger}"], [
2988           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2989         ])
2990   ])
2991 ])
2992
2993
2994 dnl
2995 dnl  Video plugins
2996 dnl
2997
2998 EXTEND_HELP_STRING([Video plugins:])
2999
3000 dnl
3001 dnl  OpenGL
3002 dnl
3003 PKG_CHECK_MODULES([EGL], [egl], [
3004   have_egl="yes"
3005 ], [
3006   have_egl="no"
3007 ])
3008 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3009
3010 have_gl="no"
3011 PKG_CHECK_MODULES([GL], [gl], [
3012   have_gl="yes"
3013 ], [
3014   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3015 #ifdef _WIN32
3016 # include <GL/glew.h>
3017 #endif
3018 #include <GL/gl.h>
3019 ]], [
3020     [int t0 = GL_TEXTURE0;]])
3021   ], [
3022     GL_CFLAGS=""
3023     have_gl="yes"
3024     AS_IF([test "${SYS}" != "mingw32"], [
3025       GL_LIBS="-lGL"
3026     ], [
3027       GL_LIBS="-lopengl32"
3028     ])
3029   ])
3030 ])
3031 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3032
3033 dnl OpenGL ES 2: depends on EGL 1.1
3034 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3035 dnl OpenGL ES 1: depends on EGL 1.0
3036 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3037
3038 dnl
3039 dnl  Xlib
3040 dnl
3041
3042 AC_PATH_XTRA()
3043 AC_CHECK_HEADERS(X11/Xlib.h)
3044
3045 dnl
3046 dnl  X C Bindings modules
3047 dnl
3048 AC_ARG_ENABLE(xcb,
3049   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3050   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3051     enable_xcb="yes"
3052   ], [
3053     enable_xcb="no"
3054   ])
3055 ])
3056 AC_ARG_ENABLE(xvideo,
3057   [  --enable-xvideo         XVideo support (default enabled)],, [
3058     enable_xvideo="$enable_xcb"
3059 ])
3060
3061 have_xcb="no"
3062 have_xcb_keysyms="no"
3063 have_xcb_randr="no"
3064 have_xcb_xvideo="no"
3065 AS_IF([test "${enable_xcb}" != "no"], [
3066   dnl libxcb
3067   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3068   have_xcb="yes"
3069   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3070   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3071   PKG_CHECK_MODULES(XPROTO, [xproto])
3072
3073   AS_IF([test "${enable_xvideo}" != "no"], [
3074     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3075   ])
3076
3077   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3078
3079   dnl xcb-utils
3080   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3081     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3082   ])
3083 ])
3084 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3085 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3086 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3087 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3088
3089
3090 dnl
3091 dnl VDPAU needs X11
3092 dnl
3093 AC_ARG_ENABLE(vdpau,
3094   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3095 have_vdpau="no"
3096 AS_IF([test "${enable_vdpau}" != "no"], [
3097   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3098     have_vdpau="yes"
3099     AS_IF([test "${no_x}" = "yes"], [
3100       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3101     ])
3102   ], [
3103     AS_IF([test -n "${enable_vdpau}"], [
3104       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3105     ])
3106   ])
3107 ])
3108 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3109
3110 have_avcodec_vdpau="no"
3111 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3112   case "${avfork}" in
3113     libav) av_vdpau_ver="55.26.0" ;;
3114     ffmpeg) av_vdpau_ver="55.42.100"
3115       PKG_CHECK_EXISTS([libavcodec >= 57.10.100], [
3116         AC_MSG_ERROR([VDPAU requires FFmpeg libavcodec < 57.10 or libav.])
3117       ])
3118       ;;
3119   esac
3120   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3121     have_avcodec_vdpau="yes"
3122     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3123   ], [
3124     AS_IF([test -n "${enable_vdpau}"], [
3125       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3126     ], [
3127       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3128     ])
3129   ])
3130 ])
3131 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3132
3133
3134 dnl
3135 dnl  Wayland
3136 dnl
3137 AC_ARG_ENABLE(wayland,
3138   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3139 have_wayland="no"
3140 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3141
3142 AS_IF([test "${enable_wayland}" != "no"], [
3143   AC_MSG_CHECKING([for the Wayland scanner])
3144   AS_IF([test -z "$WAYLAND_SCANNER"], [
3145     PKG_CHECK_EXISTS([wayland-scanner], [
3146       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3147     ], [
3148       WAYLAND_SCANNER="wayland-scanner"
3149     ])
3150   ])
3151   AC_MSG_RESULT([$WAYLAND_SCANNER])
3152
3153   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3154     have_wayland="yes"
3155   ], [
3156     AS_IF([test -n "${enable_wayland}"], [
3157       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3158     ])
3159   ])
3160
3161   AS_IF([test "${have_egl}" = "yes"], [
3162     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3163       have_wayland_egl="yes"
3164     ], [
3165       AS_IF([test -n "${enable_wayland}"], [
3166         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3167       ])
3168     ])
3169   ])
3170 ])
3171 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3172 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3173
3174
3175 dnl
3176 dnl  SDL module
3177 dnl
3178 AC_ARG_ENABLE(sdl,
3179   [  --enable-sdl            SDL support (default enabled)])
3180 AC_ARG_ENABLE(sdl-image,
3181   [  --enable-sdl-image      SDL image support (default enabled)])
3182 if test "${enable_sdl}" != "no"
3183 then
3184    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3185       # SDL on Darwin is heavily patched and can only run SDL_image
3186       if test "${SYS}" != "darwin"; then
3187         VLC_ADD_PLUGIN([vout_sdl])
3188       fi
3189
3190       # SDL_image
3191       AS_IF([ test "${enable_sdl_image}" != "no"],[
3192         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3193           VLC_ADD_PLUGIN([sdl_image])],
3194           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3195           ])
3196       ])
3197    ],[
3198      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3199    ])
3200 fi
3201
3202 dnl
3203 dnl  freetype module
3204 dnl
3205 AC_ARG_ENABLE(freetype,
3206   [  --enable-freetype       freetype support   (default auto)])
3207 AC_ARG_ENABLE(fribidi,
3208   [  --enable-fribidi        fribidi support    (default auto)])
3209 AC_ARG_ENABLE(harfbuzz,
3210   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3211 AC_ARG_ENABLE(fontconfig,
3212   [  --enable-fontconfig     fontconfig support (default auto)])
3213
3214 AC_ARG_WITH([default-font],
3215     AS_HELP_STRING([--with-default-font=PATH],
3216         [Path to the default font]),
3217         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3218             "$withval", [Default font])])
3219 AC_ARG_WITH([default-monospace-font],
3220     AS_HELP_STRING([--with-default-monospace-font=PATH],
3221         [Path to the default font]),
3222         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3223             "$withval", [Default monospace font])])
3224
3225 AC_ARG_WITH([default-font-family],
3226     AS_HELP_STRING([--with-default-font-family=NAME],
3227         [Path to the default font family]),
3228         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3229             "$withval", [Default font family])])
3230 AC_ARG_WITH([default-monospace-font-family],
3231     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3232         [Path to the default font family]),
3233         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3234             "$withval", [Default monospace font family])])
3235
3236 have_freetype="no"
3237 have_fontconfig="no"
3238 have_fribidi="no"
3239 have_harfbuzz="no"
3240
3241 if test "${enable_freetype}" != "no"; then
3242    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3243       have_freetype="yes"
3244       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3245       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3246
3247       dnl fontconfig support
3248       if test "${SYS}" != "mingw32"; then
3249           if test "${enable_fontconfig}" != "no"; then
3250             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3251               have_fontconfig="yes"
3252             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3253           fi
3254       fi
3255
3256       dnl fribidi support
3257       if test "${enable_fribidi}" != "no"; then
3258         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3259           have_fribidi="yes"
3260           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3261           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3262         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3263       fi
3264
3265       dnl harfbuzz support
3266       if test "${have_fribidi}" != "no"; then
3267         if test "${enable_harfbuzz}" != "no"; then
3268           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3269             have_harfbuzz="yes"
3270             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3271             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3272           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3273         fi
3274       fi
3275   ],[
3276   AS_IF([test -n "${enable_freetype}"],[
3277     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3278     ])
3279   ])
3280 fi
3281
3282 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3283 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3284 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3285 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3286
3287 dnl
3288 dnl SAPI (text to Speech renderer for Windows)
3289 dnl
3290 AC_LANG_PUSH([C++])
3291 AC_CHECK_TYPES([ISpObjectToken],[
3292               have_sapi="yes"
3293             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3294               [#include <windows.h>
3295                #include <sapi.h>
3296                #include <sphelper.h>])
3297 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3298 AC_LANG_POP([C++])
3299
3300 dnl
3301 dnl  QuartzText vout module (iOS/Mac OS)
3302 dnl
3303 AC_ARG_ENABLE(macosx-quartztext,
3304   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3305 if test "x${enable_macosx_quartztext}" != "xno" &&
3306   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3307 then
3308   VLC_ADD_PLUGIN([quartztext])
3309 fi
3310
3311 dnl
3312 dnl  SVG module (text rendering and image decoding)
3313 dnl
3314 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3315 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3316
3317 dnl
3318 dnl  Windows DirectX module
3319 dnl
3320
3321 AC_ARG_ENABLE(directx,
3322   [AS_HELP_STRING([--enable-directx],
3323     [Microsoft DirectX support (default enabled on Windows)])],, [
3324   AS_IF([test "${SYS}" = "mingw32"], [
3325     enable_directx="yes"
3326   ], [
3327     enable_directx="no"
3328   ])
3329 ])
3330 have_directx="no"
3331 AS_IF([test "${enable_directx}" != "no"], [
3332   dnl DirectDraw
3333   AC_CHECK_HEADERS(ddraw.h, [
3334     have_directx="yes"
3335   ], [
3336     AC_MSG_ERROR([Cannot find DirectX headers!])
3337   ])
3338
3339   dnl OpenGL
3340   AC_CHECK_HEADERS(GL/wglew.h, [
3341     VLC_ADD_PLUGIN([glwin32])
3342   ],, [
3343     #include <windows.h>
3344     #include <GL/gl.h>
3345   ])
3346
3347   dnl Direct3D11
3348   AC_CHECK_HEADERS(d3d11.h, [
3349     VLC_ADD_PLUGIN([direct3d11])
3350   ])
3351
3352   dnl Direct3D9
3353   AC_CHECK_HEADERS(d3d9.h, [
3354     VLC_ADD_PLUGIN([direct3d9])
3355   ])
3356
3357   dnl Direct2D
3358   AC_CHECK_HEADERS(d2d1.h, [
3359     VLC_ADD_PLUGIN([direct2d])
3360   ])
3361 ])
3362 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3363
3364 dnl
3365 dnl  Linux framebuffer module
3366 dnl
3367 AC_CHECK_HEADER([linux/fb.h], [
3368   VLC_ADD_PLUGIN([fb])
3369 ])
3370
3371
3372 dnl
3373 dnl  DirectFB module
3374 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3375 dnl  TODO: support for static linking
3376 dnl
3377 AC_ARG_ENABLE(directfb,
3378   [  --enable-directfb       DirectFB support (default disabled)])
3379 AC_ARG_WITH(directfb,
3380   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3381
3382 if test "${enable_directfb}" = "yes"; then
3383     have_directfb="false"
3384     CPPFLAGS_mydirectfb=
3385     LIBS_mydirectfb=
3386     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3387         dnl Trying the given location
3388         VLC_SAVE_FLAGS
3389
3390         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3391         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3392
3393         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3394         LIBS="${LIBS} ${LIBS_new}"
3395
3396         dnl FIXME: too obscure
3397         AC_CHECK_HEADER([directfb.h], [
3398             AC_CHECK_LIB([direct],[direct_initialize], [
3399                 AC_CHECK_LIB([fusion], [fusion_enter], [
3400                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3401                 ], have_directfb="false")
3402             ], have_directfb="false")
3403         ], have_directfb="false")
3404
3405         VLC_RESTORE_FLAGS
3406
3407         if test "${have_directfb}" = "true"; then
3408             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3409             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3410         fi
3411     else
3412         dnl Look for directfb-config
3413         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3414         if test "${DIRECTFB_CONFIG}" != "no"; then
3415             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3416             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3417             have_directfb="true"
3418         else
3419             dnl Trying with pkg-config
3420             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3421                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3422                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3423                 have_directfb="true"
3424                 ], [have_directfb="false"])
3425         fi
3426     fi
3427     if test "${have_directfb}" = "true"; then
3428         VLC_ADD_PLUGIN([directfb])
3429         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3430         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3431     else
3432         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3433     fi
3434 fi
3435
3436 dnl
3437 dnl  AA plugin
3438 dnl
3439 AC_ARG_ENABLE(aa,
3440   [  --enable-aa             aalib output (default disabled)])
3441 if test "${enable_aa}" = "yes"
3442 then
3443   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3444   if test "${have_aa}" = "true"
3445   then
3446     VLC_ADD_PLUGIN([aa])
3447   fi
3448 fi
3449
3450 dnl
3451 dnl  libcaca plugin
3452 dnl
3453 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3454
3455 dnl
3456 dnl  OS/2 KVA plugin
3457 dnl
3458 AC_ARG_ENABLE(kva,
3459   [AS_HELP_STRING([--enable-kva],
3460     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3461   AS_IF([test "$SYS" = "os2"], [
3462     enable_kva="yes"
3463   ])
3464 ])
3465 have_kva="no"
3466 KVA_LIBS=""
3467 AS_IF([test "$enable_kva" != "no"], [
3468   AC_CHECK_HEADERS([kva.h], [
3469     have_kva="yes"
3470     AC_CHECK_LIB(kva, main, [
3471       KVA_LIBS="-lkva"
3472     ])
3473   ])
3474 ])
3475 AC_SUBST(KVA_LIBS)
3476 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3477
3478 dnl
3479 dnl MMAL plugin
3480 dnl
3481 AC_ARG_ENABLE(mmal,
3482   AS_HELP_STRING([--enable-mmal],
3483     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3484 if test "${enable_mmal}" != "no"; then
3485   VLC_SAVE_FLAGS
3486   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3487   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3488   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3489     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3490         have_mmal="yes"
3491         VLC_ADD_PLUGIN([mmal])
3492         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3493         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3494         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3495           AS_IF([test "${enable_mmal}" = "yes"],
3496             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3497             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3498           ],
3499         [])
3500     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3501       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3502       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3503   VLC_RESTORE_FLAGS
3504 fi
3505 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3506
3507 dnl
3508 dnl evas plugin
3509 dnl
3510 AC_ARG_ENABLE(evas,
3511   [AS_HELP_STRING([--enable-evas],
3512     [use evas output module (default disabled)])])
3513 have_evas="no"
3514 AS_IF([test "${enable_evas}" = "yes"], [
3515   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3516       have_evas="yes"
3517       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3518     ],[
3519     AS_IF([test "x${enable_evas}" != "x"], [
3520       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3521     ])
3522   ])
3523 ])
3524 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3525
3526 dnl
3527 dnl  Audio plugins
3528 dnl
3529
3530 EXTEND_HELP_STRING([Audio plugins:])
3531
3532 dnl
3533 dnl  Pulseaudio module
3534 dnl
3535 AC_ARG_ENABLE(pulse,
3536   [AS_HELP_STRING([--enable-pulse],
3537     [use the PulseAudio client library (default auto)])])
3538 have_pulse="no"
3539 AS_IF([test "${enable_pulse}" != "no"], [
3540   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3541     have_pulse="yes"
3542   ], [
3543     AS_IF([test "x${enable_pulse}" != "x"], [
3544       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3545     ])
3546   ])
3547 ])
3548 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3549
3550 dnl
3551 dnl  ALSA module
3552 dnl
3553 AC_ARG_ENABLE(alsa,
3554   [AS_HELP_STRING([--enable-alsa],
3555     [support the Advanced Linux Sound Architecture (default auto)])],, [
3556   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3557     enable_alsa="yes"
3558   ])
3559 ])
3560 have_alsa="no"
3561 AS_IF([test "${enable_alsa}" != "no"], [
3562   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3563     have_alsa="yes"
3564   ], [
3565     AS_IF([test "x${enable_alsa}" != "x"], [
3566       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3567     ])
3568   ])
3569 ])
3570 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3571
3572 dnl
3573 dnl  Open Sound System module
3574 dnl
3575 AC_ARG_ENABLE(oss,
3576   [AS_HELP_STRING([--enable-oss],
3577     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3578   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3579     enable_oss="no"
3580   ])
3581 ])
3582 have_oss="no"
3583 OSS_LIBS=""
3584 AS_IF([test "$enable_oss" != "no"], [
3585   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3586     have_oss="yes"
3587     AC_CHECK_LIB(ossaudio, main, [
3588       OSS_LIBS="-lossaudio"
3589     ])
3590   ])
3591 ])
3592 AC_SUBST(OSS_LIBS)
3593 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3594
3595 dnl
3596 dnl  OpenBSD sndio module
3597 dnl
3598 AC_ARG_ENABLE([sndio],
3599   [AS_HELP_STRING([--disable-sndio],
3600     [support the OpenBSD sndio (default auto)])],, [
3601   AS_IF([test "$SYS" = "openbsd"], [
3602     enable_sndio="yes"
3603   ])
3604 ])
3605 have_sndio="no"
3606 AS_IF([test "$enable_sndio" != "no"], [
3607   AC_CHECK_HEADER([sndio.h], [
3608     have_sndio="yes"
3609   ])
3610 ])
3611 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3612
3613 dnl
3614 dnl  Windows Audio Session plugin
3615 dnl
3616 AC_ARG_ENABLE([wasapi],
3617   [AS_HELP_STRING([--enable-wasapi],
3618     [use the Windows Audio Session API (default auto)])
3619 ])
3620 have_wasapi="no"
3621 AS_IF([test "$enable_wasapi" != "no"], [
3622   AC_CHECK_HEADER([audioclient.h], [
3623     have_wasapi="yes"
3624   ], [
3625     AS_IF([test "x${enable_wasapi}" != "x"], [
3626       AC_MSG_ERROR([Windows Audio Session API not found.])
3627     ])
3628   ])
3629 ])
3630 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3631
3632 dnl
3633 dnl  AudioQueue plugin
3634 dnl
3635 AC_ARG_ENABLE(audioqueue,
3636   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3637 if test "${enable_audioqueue}" = "yes"
3638 then
3639   VLC_ADD_PLUGIN([audioqueue])
3640 fi
3641
3642 dnl
3643 dnl  JACK modules
3644 dnl
3645 AC_ARG_ENABLE(jack,
3646   [AS_HELP_STRING([--disable-jack],
3647     [do not use jack (default auto)])])
3648 have_jack="no"
3649 AS_IF([test "${enable_jack}" != "no"], [
3650     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3651       [ have_jack=yes ],
3652       [
3653       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3654
3655       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3656       [ have_jack=yes ],
3657       [
3658       AS_IF([test -n "${enable_jack}"],
3659          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3660          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3661       ])
3662     ])
3663 ])
3664 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3665
3666 dnl
3667 dnl  OpenSLES Android
3668 dnl
3669 AC_ARG_ENABLE(opensles,
3670   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3671 if test "${HAVE_ANDROID}" = "1"; then
3672   if test "${enable_opensles}" = "yes"; then
3673       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3674         [ VLC_ADD_PLUGIN([opensles_android]) ],
3675         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3676   fi
3677 fi
3678
3679 dnl
3680 dnl  Tizen audio
3681 dnl
3682 AC_ARG_ENABLE(tizen_audio,
3683   [AS_HELP_STRING([--enable-tizen-audio],
3684     [Tizen audio module (default enabled on Tizen)])],, [
3685   AS_IF([test "$HAVE_TIZEN" = "1"], [
3686     enable_tizen_audio="yes"
3687   ])
3688 ])
3689 if test "${enable_tizen_audio}" = "yes"; then
3690   AC_CHECK_HEADERS(audio_io.h,
3691     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3692     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3693 fi
3694
3695 dnl
3696 dnl libsamplerate plugin
3697 dnl
3698 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3699
3700 dnl
3701 dnl  soxr module
3702 dnl
3703 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3704
3705 dnl
3706 dnl  OS/2 KAI plugin
3707 dnl
3708 AC_ARG_ENABLE(kai,
3709   [AS_HELP_STRING([--enable-kai],
3710     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3711   AS_IF([test "$SYS" = "os2"], [
3712     enable_kai="yes"
3713   ])
3714 ])
3715 have_kai="no"
3716 KAI_LIBS=""
3717 AS_IF([test "$enable_kai" != "no"], [
3718   AC_CHECK_HEADERS([kai.h], [
3719     have_kai="yes"
3720     AC_CHECK_LIB(kai, main, [
3721       KAI_LIBS="-lkai"
3722     ])
3723   ])
3724 ])
3725 AC_SUBST(KAI_LIBS)
3726 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3727
3728 dnl
3729 dnl  chromaprint audio track fingerprinter
3730 dnl
3731 m4_pushdef([libchromaprint_version], 0.6.0)
3732 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3733     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3734     AS_IF([test "${enable_chromaprint}" = "yes"],
3735         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3736         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3737          ),
3738     [(Chromaprint based audio fingerprinter)],[auto])
3739 m4_popdef([libchromaprint_version])
3740
3741 dnl
3742 dnl  Chromecast streaming support
3743 dnl
3744 m4_pushdef([protobuf_lite_version], 2.5.0)
3745 AC_ARG_VAR(PROTOC, [protobuf compiler])
3746 AC_CHECK_PROGS(PROTOC, protoc, no)
3747 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3748     AS_IF([test "x${PROTOC}" != "xno"], [
3749         build_chromecast="yes"
3750     ], [
3751     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3752     ])
3753 ], [
3754     AS_IF([test "${enable_chromecast}" = "yes"],
3755         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3756         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3757     )
3758     enable_chromecast="no"
3759 ], [(Chromecast streaming support)], [auto])
3760 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3761 m4_popdef([protobuf_lite_version])
3762
3763 dnl
3764 dnl  Interface plugins
3765 dnl
3766
3767 EXTEND_HELP_STRING([Interface plugins:])
3768
3769 dnl
3770 dnl QT
3771 dnl
3772 AC_ARG_ENABLE(qt, [
3773   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3774   AS_IF([test "${SYS}" = "darwin"], [
3775     enable_qt="no"
3776   ])
3777 ])
3778 AS_IF([test "${enable_qt}" != "no"], [
3779   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.1.0 Qt5Widgets Qt5Gui], [
3780       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3781           VLC_ADD_LIBS([qt4],[${QTX11_LIBS}])
3782           VLC_ADD_CXXFLAGS([qt4],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3783           PKG_CHECK_MODULES([XI], [xi], [
3784             VLC_ADD_LIBS([qt4], [${XI_LIBS}])
3785             VLC_ADD_CXXFLAGS([qt4], [${XI_CFLAGS} -DHAVE_XI])
3786           ], [
3787             PKG_CHECK_EXISTS([Qt5Gui >= 5.5], [
3788               AC_MSG_ERROR([${XI_PKG_ERRORS}.])
3789             ], [
3790               AC_MSG_WARN([${XI_PKG_ERRORS}.])
3791             ])
3792           ])
3793       ],[
3794           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3795       ])
3796       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3797       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3798       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3799       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3800       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3801     ], [
3802       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.6.0],, [
3803         AS_IF([test -n "${enable_qt}"],[
3804           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3805         ],[
3806           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3807         ])
3808         enable_qt="no"
3809       ])
3810       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3811       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3812       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3813       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3814     ])
3815 ])
3816 AS_IF([test "${enable_qt}" != "no"], [
3817   VLC_ADD_PLUGIN([qt4])
3818   ALIASES="${ALIASES} qvlc"
3819 ])
3820 AM_CONDITIONAL(ENABLE_QT4, [test "$enable_qt" != "no"])
3821
3822 dnl
3823 dnl detect kde4-config patch (used for kde solids and kwallet).
3824 dnl
3825 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3826 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3827   KDE4_CONFIG="kde4-config"
3828 ])
3829
3830 dnl
3831 dnl Simple test for skins2 dependency
3832 dnl
3833 AS_IF([test "$enable_qt" = "no"], [
3834   AS_IF([test "${enable_skins2}" = "yes"], [
3835     AC_MSG_ERROR([The skins2 module depends on the Qt4 interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt4 development package or alternatively you can also configure with: --disable-qt4 --disable-skins2.])
3836   ], [
3837     enable_skins2="no"
3838     AC_MSG_WARN([The skins2 module depends on the Qt4 interface, Qt4 is not built so skins2 is disabled.])
3839   ])
3840 ])
3841
3842 dnl
3843 dnl Skins2 module
3844 dnl
3845 AC_ARG_ENABLE(skins2,
3846   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3847 AS_IF([test "${enable_skins2}" != "no"], [
3848   have_skins_deps="yes"
3849
3850   dnl Win32
3851   AS_IF([test "${SYS}" = "mingw32"], [
3852     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3853     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3854   dnl MacOS
3855   ], [test "${SYS}" = "darwin"], [
3856     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3857     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3858   dnl OS/2
3859   ], [test "${SYS}" = "os2"], [
3860     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3861   dnl Linux/Unix
3862   ], [
3863     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3864     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3865     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3866     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3867     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3868   ])
3869
3870   dnl for All OSes
3871   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3872
3873   dnl we need freetype
3874   AS_IF([test "${have_freetype}" != "yes"], [
3875     have_skins_deps="no"
3876   ])
3877
3878   AS_IF([test "${have_skins_deps}" = "no"], [
3879     AS_IF([test "x${enable_skins2}" = "x"], [
3880       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3881     ], [
3882       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3883     ])
3884     enable_skins2="no"
3885   ], [
3886     VLC_ADD_PLUGIN([skins2])
3887     ALIASES="${ALIASES} svlc"
3888     enable_skins2="yes"
3889   ])
3890 ])
3891 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3892
3893 AC_ARG_ENABLE(libtar,
3894   [  --enable-libtar         libtar support for skins2 (default auto)])
3895 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3896   AC_CHECK_HEADERS(libtar.h, [
3897     VLC_ADD_LIBS([skins2],[-ltar])
3898   ])
3899 ])
3900
3901 dnl
3902 dnl  MacOS X gui module
3903 dnl
3904 AC_ARG_ENABLE(macosx,
3905   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3906 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3907 then
3908   VLC_ADD_PLUGIN([macosx])
3909
3910   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3911   then
3912     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3913   fi
3914 fi
3915 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3916
3917 dnl
3918 dnl  MacOS X sparkle update support
3919 dnl
3920 AC_ARG_ENABLE(sparkle,
3921   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3922 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3923 then
3924   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3925   then
3926     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3927   fi
3928
3929   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3930 fi
3931 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3932
3933
3934 dnl
3935 dnl  Minimal Mac OS X module
3936 dnl
3937 AC_ARG_ENABLE(minimal-macosx,
3938   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3939 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3940 then
3941   VLC_ADD_PLUGIN([minimal_macosx])
3942 fi
3943
3944 dnl
3945 dnl  VideoToolbox plugins
3946 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3947     VLC_ADD_PLUGIN([videotoolbox])
3948     VLC_ADD_PLUGIN([cvpx_i420])
3949   ])
3950
3951 dnl
3952 dnl  ncurses module
3953 dnl
3954 AC_ARG_ENABLE(ncurses,
3955 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3956 have_ncurses="no"
3957 AS_IF([test "${enable_ncurses}" != "no"] ,[
3958   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3959     have_ncurses="yes"
3960     ALIASES="${ALIASES} nvlc"
3961   ], [
3962     AS_IF([test -n "${enable_ncurses}"], [
3963       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3964     ])
3965   ])
3966 ])
3967 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3968
3969 dnl
3970 dnl  Lirc plugin
3971 dnl
3972 AC_ARG_ENABLE(lirc,
3973   [  --enable-lirc           lirc support (default disabled)])
3974 have_lirc="no"
3975 AS_IF([test "${enable_lirc}" = "yes"], [
3976   AC_CHECK_HEADER(lirc/lirc_client.h, [
3977     AC_CHECK_LIB(lirc_client, lirc_init, [
3978       have_lirc="true"
3979     ])
3980   ])
3981 ])
3982 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3983
3984 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3985 dnl
3986 dnl  goom visualization plugin
3987 dnl
3988 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3989
3990 dnl
3991 dnl libprojectM visualization plugin
3992 dnl
3993 AC_ARG_ENABLE(projectm,
3994   [  --enable-projectm       projectM visualization plugin (default enabled)])
3995 AS_IF([test "${enable_projectm}" != "no"],
3996   [
3997     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3998     [
3999       VLC_ADD_PLUGIN([projectm])
4000       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
4001         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
4002         [ AC_MSG_WARN( [Using libprojectM version 1] )
4003       ])
4004     ],[
4005       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
4006     ])
4007   ])
4008
4009 dnl
4010 dnl Vovoid VSXu visualization plugin
4011 dnl
4012 AC_ARG_ENABLE(vsxu,
4013   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
4014 AS_IF([test "${enable_vsxu}" != "no"],
4015   [
4016     PKG_CHECK_MODULES(VSXU, libvsxu,
4017     [
4018       VLC_ADD_PLUGIN([vsxu])
4019     ],[
4020       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4021     ])
4022   ])
4023
4024 EXTEND_HELP_STRING([Service Discovery plugins:])
4025 dnl
4026 dnl  Avahi-Zeroconf services discovery
4027 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4028
4029 dnl
4030 dnl  libudev services discovery
4031 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4032
4033 dnl
4034 dnl MTP devices services discovery
4035 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4036
4037 dnl
4038 dnl UPnP Plugin (Intel SDK)
4039 dnl
4040 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4041
4042 dnl
4043 dnl mDNS using libmicrodns
4044 dnl
4045 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4046
4047
4048 EXTEND_HELP_STRING([Misc options:])
4049
4050 dnl
4051 dnl  libxml2 module
4052 dnl
4053 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4054
4055
4056 dnl
4057 dnl libgcrypt
4058 dnl
4059 AC_ARG_ENABLE(libgcrypt,
4060   [  --disable-libgcrypt     gcrypt support (default enabled)])
4061 # require libgcrypt >= 1.6.0
4062 AS_IF([test "${enable_libgcrypt}" != "no"], [
4063   AC_TRY_COMPILE([
4064 #include <gcrypt.h>
4065 #if GCRYPT_VERSION_NUMBER < 0x010600
4066 #error
4067 #endif],
4068   [], [
4069     have_libgcrypt="yes"
4070     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4071     GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
4072     GCRYPT_LIBS="`libgcrypt-config --libs`"
4073   ], [
4074     AS_IF([test "${enable_libgcrypt}" == "yes"], [
4075       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4076     ])
4077   ])
4078 ])
4079
4080 AC_SUBST(GCRYPT_CFLAGS)
4081 AC_SUBST(GCRYPT_LIBS)
4082 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
4083
4084 dnl
4085 dnl TLS/SSL
4086 dnl
4087 AC_ARG_ENABLE(gnutls,
4088   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4089 AS_IF([test "${enable_gnutls}" != "no"], [
4090   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4091     VLC_ADD_PLUGIN([gnutls])
4092   ], [
4093     AS_IF([test -n "${enable_gnutls}"], [
4094       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4095     ])
4096   ])
4097 ])
4098
4099
4100 dnl
4101 dnl Taglib plugin
4102 dnl
4103 AC_ARG_ENABLE(taglib,
4104   [AS_HELP_STRING([--disable-taglib],
4105     [do not use TagLib (default enabled)])])
4106 AS_IF([test "${enable_taglib}" != "no"], [
4107   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4108     VLC_ADD_PLUGIN([taglib])
4109   ], [
4110     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4111 ])
4112
4113 dnl
4114 dnl  libsecret
4115 dnl
4116 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1], [use libsecret for keystore], [auto])
4117
4118 dnl
4119 dnl  kwallet
4120 dnl
4121 AC_ARG_ENABLE(kwallet,
4122   [AS_HELP_STRING([--enable-kwallet],
4123     [use KWallet for keystore (default auto)])])
4124 have_kwallet="no"
4125 KWALLET_CXXFLAGS=""
4126 KWALLET_LIBS=""
4127 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" \
4128          -a "${enable_qt}" != "no" -a "${KDE4_CONFIG}" != "no" \
4129          -a "${enable_kwallet}" != "no" ], [
4130   VLC_SAVE_FLAGS
4131   AC_LANG_PUSH([C++])
4132   KWALLET_CXXFLAGS="$QT_CFLAGS $CXXFLAGS_qt4 -I`$KDE4_CONFIG --path include`"
4133   CPPFLAGS="$CPPFLAGS $KWALLET_CXXFLAGS"
4134   AC_CHECK_HEADER([kwallet.h], [
4135     KWALLET_LIBS="$QT_LIBS -L`$KDE4_CONFIG --install lib` -lkdeui"
4136     LDFLAGS="$LDFLAGS $KWALLET_LIBS"
4137     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <kwallet.h>], [
4138 KWallet::Wallet::LocalWallet();
4139     ])], [
4140       have_kwallet="yes"
4141     ])
4142   ])
4143   AC_LANG_POP([C++])
4144   VLC_RESTORE_FLAGS
4145 ])
4146 AS_IF([test "$enable_kwallet" = "yes" -a "$have_kwallet" = "no" ], [
4147   AC_MSG_ERROR([KWallet headers or so not found])
4148 ])
4149 AC_SUBST(KWALLET_CXXFLAGS)
4150 AC_SUBST(KWALLET_LIBS)
4151 AM_CONDITIONAL([HAVE_KWALLET], [test "${have_kwallet}" = "yes"])
4152
4153 dnl
4154 dnl  Developers helper modules (should be hidden from configure help)
4155 dnl
4156 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4157 AS_IF([test "${enable_devtools}" != "no"], [
4158   VLC_ADD_PLUGIN([accesstweaks])
4159 ])
4160
4161 dnl
4162 dnl update checking system
4163 dnl
4164 AC_ARG_ENABLE(update-check,
4165   [  --enable-update-check   update checking system (default disabled)])
4166 if test "${enable_update_check}" = "yes"
4167 then
4168   if test "${have_libgcrypt}" != "yes"
4169   then
4170     AC_MSG_ERROR([libgcrypt is required for update checking system])
4171   fi
4172   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4173   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4174   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])