preparser: send PreparseEnded when input can't be created
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2016"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
42
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
59
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
69
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
77
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, optional)
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl
98 dnl  Check the operating system
99 dnl
100 HAVE_WIN64="0"
101 HAVE_IOS="0"
102 HAVE_OSX="0"
103 HAVE_TVOS="0"
104
105 case "${host_os}" in
106   "")
107     SYS=unknown
108     ;;
109   linux*)
110     SYS=linux
111     ;;
112   bsdi*)
113     SYS=bsdi
114     CFLAGS="${CFLAGS} -pthread"
115     ;;
116   freebsd*)
117     SYS=freebsd
118     CFLAGS="${CFLAGS} -pthread"
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
121     ;;
122   openbsd*)
123     SYS=openbsd
124     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
125     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
126     ;;
127   netbsd*)
128     SYS=netbsd
129     ;;
130   dragonfly*)
131     SYS=dragonfly
132     ;;
133   darwin*)
134
135     dnl Force gcc "-arch" flag
136     ARCH_flag=""
137     case "${host}" in
138       i?86*)
139         ARCH_flag="-arch i386"
140       ;;
141       ppc64*)
142         ARCH_flag="-arch ppc64"
143       ;;
144       ppc*)
145         ARCH_flag="-arch ppc"
146       ;;
147       x86_64*)
148         ARCH_flag="-arch x86_64"
149       ;;
150       arm*)
151         ac_cv_c_bigendian="no"
152         ac_cv_c_attribute_packed="no"
153       ;;
154     esac
155
156     SYS=darwin
157     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
158     CXX="${CXX} -stdlib=libc++ -std=c++11"
159     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
160     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
161     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
162     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
163     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
164     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
165
166     AC_EGREP_CPP(yes,
167             [#import <TargetConditionals.h>
168              #if TARGET_OS_IPHONE
169              yes
170              #endif],
171              [HAVE_IOS="1"],
172              [HAVE_OSX="1"])
173
174     AC_EGREP_CPP(yes,
175             [#import <TargetConditionals.h>
176              #if TARGET_OS_TV
177              yes
178              #endif],
179              [HAVE_TVOS="1"
180              HAVE_IOS="0"
181              HAVE_OSX="0"
182              ],)
183
184     dnl Allow binaries created on Lion to run on earlier releases
185     AC_EGREP_CPP(yes,
186            [#import <Cocoa/Cocoa.h>
187             #ifdef MAC_OS_X_VERSION_10_7
188             yes
189             #endif],
190             [AC_MSG_RESULT([yes])
191             AC_LIBOBJ([getdelim])
192             AC_LIBOBJ([strndup])
193             AC_LIBOBJ([strnlen])],)
194
195     dnl
196     dnl  Handle Mac OS X SDK flags
197     dnl
198     AC_ARG_WITH(macosx-sdk,
199       [AS_HELP_STRING([--with-macosx-sdk=DIR],
200         [compile using the SDK in DIR])])
201     if test "${with_macosx_sdk}" != "" ; then
202         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
203         CPP="${CPP} -isysroot ${with_macosx_sdk}"
204         CC="${CC} -isysroot ${with_macosx_sdk}"
205         CXX="${CXX} -isysroot ${with_macosx_sdk}"
206         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
207         LD="${LD} -syslibroot ${with_macosx_sdk}"
208     fi
209     AC_ARG_WITH(macosx-version-min,
210       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
211         [compile for Mac OS X VERSION and above])])
212     if test "${with_macosx_version_min}" != "" ; then
213         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
214         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
215         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
216         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
217         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
218     fi
219     ;;
220   *mingw32* | *cygwin* | *wince* | *mingwce*)
221     AC_CHECK_TOOL(WINDRES, windres, :)
222     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
223     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
224     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
225     AH_TOP([#endif])
226     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
227     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
228     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
229     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
230     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
231     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
232     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
233     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
234     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
235     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
236     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
237
238     case "${host_os}" in
239       *mingw32*)
240         SYS=mingw32
241         ;;
242       *cygwin*)
243         dnl Check if we are using the mno-cygwin mode in which case we are
244         dnl actually dealing with a mingw32 compiler.
245         AC_EGREP_CPP(yes,
246             [#ifdef _WIN32
247              yes
248              #endif],
249             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
250         ;;
251     esac
252
253     if test "${SYS}" = "mingw32"; then
254         # DEP, ASLR, NO SEH
255         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
256
257         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
258         ac_default_prefix="`pwd`/_win32"
259         DESTDIR="`pwd`/_win32/"
260
261         dnl
262         dnl NSIS/MSI Installer prefix and WIN64
263         dnl
264         case "${host}" in
265             amd64*|x86_64*)
266                 HAVE_WIN64="1"
267                 WINDOWS_ARCH="x64"
268                 PROGRAMFILES="PROGRAMFILES64"
269             ;;
270             *)
271                 WINDOWS_ARCH="x86"
272                 PROGRAMFILES="PROGRAMFILES"
273             ;;
274         esac
275         AC_SUBST(WINDOWS_ARCH)
276         AC_SUBST(PROGRAMFILES)
277
278     fi
279     ;;
280   *nto*)
281     SYS=nto
282     ;;
283   solaris*)
284     SYS=solaris
285     ;;
286   hpux*)
287     SYS=hpux
288     ;;
289   *os2*)
290     SYS=os2
291     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
292     AC_LIBOBJ([freeaddrinfo])
293     AC_LIBOBJ([gai_strerror])
294     ;;
295   *)
296     SYS="${host_os}"
297     ;;
298 esac
299 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
300 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
301 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
302 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
303 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
304 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
305 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
306 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
307
308 dnl
309 dnl Sadly autoconf does not think about testing foo.exe when ask to test
310 dnl for program foo on win32
311 case "${build_os}" in
312     cygwin|msys)
313         ac_executable_extensions=".exe"
314     ;;
315     os2*)
316         BUILDEXEEXT=".exe"
317     ;;
318     *)
319     ;;
320 esac
321 AC_SUBST(BUILDEXEEXT)
322
323 dnl Android is linux, but a bit different
324 AS_IF([test "$SYS" = linux],[
325     AC_MSG_CHECKING([for an Android system])
326     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
327         [[#ifndef __ANDROID__
328          # error Not Android
329          #endif
330         ]],[[;]])
331     ],[
332       HAVE_ANDROID="1"
333       AC_MSG_RESULT([yes])
334     ],[
335       AC_MSG_RESULT([no])
336     ])
337 ])
338 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
339
340 dnl Tizen (minimum SDK version: 2.3)
341 AS_IF([test "$SYS" = linux],[
342     AC_MSG_CHECKING([for Tizen])
343     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
344         [[#include <tizen.h>
345         ]],[[;]])
346     ],[
347       HAVE_TIZEN="1"
348       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
349       AC_MSG_RESULT([yes])
350     ],[
351       AC_MSG_RESULT([no])
352     ])
353 ])
354 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
355
356 dnl
357 dnl  Check for the contrib directory
358 dnl
359 AC_ARG_WITH(contrib,
360   [AS_HELP_STRING([--with-contrib[=DIR]],
361     [search for 3rd party libraries in DIR/include and DIR/lib])
362 ])
363 AC_MSG_CHECKING([for 3rd party libraries path])
364 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
365   CONTRIB_DIR="${srcdir}/contrib/${host}"
366   AS_IF([test ! -d "${CONTRIB_DIR}"], [
367     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
368     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
369     AS_IF([test ! -d "${CONTRIB_DIR}"], [
370       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
371       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
372       AS_IF([test ! -d "${CONTRIB_DIR}"], [
373         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
374         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
375         AS_IF([test ! -d "${CONTRIB_DIR}"], [
376           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
377           CONTRIB_DIR=""
378           AC_MSG_RESULT([not found])
379         ])
380       ])
381     ])
382   ])
383 ], [
384   AS_IF([test "${with_contrib}" != "no"], [
385     CONTRIB_DIR="${with_contrib}"
386   ], [
387     CONTRIB_DIR=""
388     AC_MSG_RESULT([disabled])
389   ])
390 ])
391 AS_IF([test -n "${CONTRIB_DIR}"], [
392   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
393     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
394   ], [
395     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
396     CONTRIB_DIR=""
397     AC_MSG_RESULT([not usable])
398   ])
399
400 ])
401 AS_IF([test -n "${CONTRIB_DIR}"], [
402   AC_MSG_RESULT([${CONTRIB_DIR}])
403   export PATH=${CONTRIB_DIR}/bin:$PATH
404   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
405   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
406   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
407   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
408   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
409   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
410
411   AS_IF([test "${SYS}" = "darwin"], [
412     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
413     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
414   ])
415 ], [
416   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
417     AC_MSG_ERROR([Third party libraries not found!])
418   ])
419 ])
420 AC_SUBST(CONTRIB_DIR)
421
422 dnl Add extras/tools to the PATH
423 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
424 AS_IF([test -d "${TOOLS_DIR}"], [
425     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
426     export PATH="${TOOLS_DIR}":$PATH
427 ])
428
429 dnl
430 dnl  Libtool
431 dnl  It's very bad, but our former custom system was worst
432 dnl  -- Courmisch
433 dnl
434
435 dnl override platform specific check for dependent libraries
436 dnl otherwise libtool linking of shared libraries will
437 dnl fail on anything other than pass_all.
438 AC_CACHE_VAL(lt_cv_deplibs_check_method,
439     [lt_cv_deplibs_check_method=pass_all])
440
441 LT_INIT([dlopen win32-dll shared disable-static])
442 LT_LANG([C++])
443 LT_LANG([Windows Resource])
444
445 DOLT
446
447 lt_cv_deplibs_check_method=pass_all
448
449 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
450   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
451 ])
452
453 dnl
454 dnl Gettext stuff
455 dnl
456 AM_GNU_GETTEXT_VERSION([0.19.6])
457 AM_GNU_GETTEXT([external], [need-formatstring-macros])
458
459 dnl
460 dnl Iconv stuff
461 dnl
462 AM_ICONV
463
464 dnl
465 dnl checks for mingw
466 AS_IF([test "${SYS}" = "mingw32"], [
467
468 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
469 #if !defined(__MINGW32__)
470 # error Not compiling with mingw
471 #endif
472     ])], [
473
474 dnl Check for broken versions of mingw-runtime compatability library
475     AC_MSG_CHECKING(for broken mingw-runtime)
476     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
477 #include <_mingw.h>
478 #if defined(__MINGW64_VERSION_MAJOR)
479 # if __MINGW64_VERSION_MAJOR < 3
480 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
481 # endif
482 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
483 # error Attempting to use mingw-runtime with broken vsnprintf support
484 #endif
485     ])], [
486         AC_MSG_RESULT([ok])
487     ], [
488         AC_MSG_RESULT([present])
489         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
490     ])
491
492     dnl force use of mingw provided c99 *printf over msvcrt
493     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
494
495     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
496     VLC_ADD_LDFLAGS([vlc],[-mwindows])
497
498     dnl Check for the need to include the mingwex lib for mingw32
499     VLC_SAVE_FLAGS
500     AC_CHECK_LIB(mingwex,opendir,
501         AC_CHECK_LIB(mingw32,opendir,,
502             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
503     )
504     VLC_RESTORE_FLAGS
505     ], [
506         AC_MSG_RESULT([Not compiling with mingw])
507     ])
508
509     dnl Check for fnative-struct or mms-bitfields support for mingw32
510     VLC_SAVE_FLAGS
511     CFLAGS="${CFLAGS} -mms-bitfields"
512     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
513     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
514         [ac_cv_c_mms_bitfields],
515         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
516     if test "${ac_cv_c_mms_bitfields}" = "no"; then
517         VLC_RESTORE_FLAGS
518         CFLAGS="${CFLAGS} -fnative-struct"
519         CXXFLAGS="${CXXFLAGS} -fnative-struct"
520         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
521             [ac_cv_c_fnative_struct],
522             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
523         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
524     fi
525 ])
526
527 AC_ARG_ENABLE(winstore_app,
528      AS_HELP_STRING([--enable-winstore-app],
529                     [Build targetted for Windows Store apps (default disabled)]))
530
531 vlc_winstore_app=0
532 AS_IF([test "${SYS}" = "mingw32"],[
533   AS_IF([test "${enable_winstore_app}" = "yes"], [
534     vlc_winstore_app=1
535      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
536      AC_LIBOBJ([gai_strerror])
537     ],[
538      VLC_ADD_LIBS([libvlccore],[-lwinmm])
539     ])
540   ])
541 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
542 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
543
544
545 dnl
546 dnl Buggy glibc prevention. Purposedly not cached.
547 dnl See sourceware.org bugs 5058 and 5443.
548 dnl Ubuntu alone has 20 bug numbers for this...
549 dnl
550 AC_MSG_CHECKING(for buggy GNU/libc versions)
551 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
552 #include <limits.h>
553 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
554   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
555 # error GNU/libc with dcgettext killer bug!
556 #endif
557 ])], [
558   AC_MSG_RESULT([not present])
559 ], [
560   AC_MSG_RESULT([found])
561   AS_IF([test "x${enable_nls}" != "xno"], [
562     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
563 work-around for this. Check with your distribution vendor on how to update the
564 glibc run-time. Alternatively, build with --disable-nls.])
565   ])
566 ])
567
568 dnl Plugin compilation stuff
569
570 VLC_LIBRARY_SUFFIX
571
572 dnl Check for system libs needed
573 need_libc=false
574
575 dnl Check for usual libc functions
576 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
577 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
578 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy timegm timespec_get strverscmp])
579 AC_REPLACE_FUNCS([gettimeofday])
580 AC_CHECK_FUNCS(fdatasync,,
581   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
582 ])
583
584 dnl mingw64 implements those as static inline, not functions with C linkage
585 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
586 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
587 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
588 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
589
590 dnl C11 static_assert()
591 AC_MSG_CHECKING([for static_assert in assert.h])
592 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
593 static_assert(1, "The impossible happened.");
594 ])], [
595   AC_MSG_RESULT([yes])
596   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
597 ], [
598   AC_MSG_RESULT([no])
599 ])
600
601 # Windows CE does not have strcoll()
602 AC_FUNC_STRCOLL
603
604 dnl Check for non-standard system calls
605 case "$SYS" in
606   "linux")
607     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
608     ;;
609   "mingw32")
610     AC_CHECK_FUNCS([_lock_file])
611     ;;
612 esac
613
614 AH_BOTTOM([#include <vlc_fixups.h>])
615
616 dnl Check for struct pollfd
617 AC_CHECK_TYPES([struct pollfd],,,
618 [#include <sys/types.h>
619 #if HAVE_POLL
620 # include <poll.h>
621 #elif defined (_WIN32)
622 # include <winsock2.h>
623 #endif
624 ])
625
626 dnl Check for struct timespec
627 AC_CHECK_TYPES([struct timespec],,,
628 [#include <time.h>])
629
630 dnl Checks for socket stuff
631 VLC_SAVE_FLAGS
632 SOCKET_LIBS=""
633 AC_SEARCH_LIBS(connect, [socket], [
634   AS_IF([test "$ac_cv_search_connect" != "none required"], [
635     SOCKET_LIBS="$ac_cv_search_connect"
636   ])
637 ], [
638   AS_IF([test "${SYS}" = "mingw32"], [
639     SOCKET_LIBS="-lws2_32"
640   ])
641 ])
642
643 AC_SEARCH_LIBS([inet_pton], [nsl], [
644  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
645     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
646   ])
647 ],, [${SOCKET_LIBS}])
648
649 LIBS="${LIBS} ${SOCKET_LIBS}"
650 AC_LINK_IFELSE([
651     AC_LANG_PROGRAM([#ifdef _WIN32
652         # if _WIN32_WINNT < 0x600
653         #  error Needs vista+
654         # endif
655         #include <ws2tcpip.h>
656         #else
657         #include <sys/socket.h>
658         #include <arpa/inet.h>
659         #endif], [
660         char dst[[sizeof(struct in_addr)]];
661         inet_pton(AF_INET, "127.0.0.1", dst);
662     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
663 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
664 VLC_RESTORE_FLAGS
665 AC_SUBST(SOCKET_LIBS)
666
667 dnl Check for socklen_t
668 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
669 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
670 ac_cv_type_socklen_t,
671 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
672 [#include <sys/types.h>
673 #ifdef _WIN32
674 # include <winsock2.h>
675 # include <ws2tcpip.h>
676 #else
677 # include <sys/socket.h>
678 #endif]], [[socklen_t len; len = 0;]])],
679 ac_cv_type_socklen_t=yes,
680 ac_cv_type_socklen_t=no)])
681 AS_IF([test "$ac_cv_type_socklen_t" = no],
682  [AC_DEFINE(socklen_t, int)])
683
684 dnl Check for struct sockaddr_storage
685 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
686 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
687 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
688   [AC_TRY_COMPILE(
689     [#include <sys/types.h>
690      #if defined( _WIN32 )
691      # include <winsock2.h>
692      #else
693      # include <sys/socket.h>
694      #endif], [struct sockaddr_storage addr;],
695      ac_cv_struct_sockaddr_storage=yes,
696      ac_cv_struct_sockaddr_storage=no)])
697 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
698   AC_DEFINE(sockaddr_storage, sockaddr)
699   AC_DEFINE(ss_family, sa_family)
700 ])
701
702 dnl FreeBSD has a gnugetopt library for this:
703 GNUGETOPT_LIBS=""
704 AC_CHECK_FUNC(getopt_long,, [
705   AC_CHECK_LIB([gnugetopt],[getopt_long], [
706     GNUGETOPT_LIBS="-lgnugetopt"
707   ])
708 ])
709 AC_SUBST(GNUGETOPT_LIBS)
710
711 AC_CHECK_LIB(m,cos,[
712   LIBM="-lm"
713 ], [
714   LIBM=""
715 ])
716 AC_SUBST(LIBM)
717
718 AC_CHECK_LIB(m,lrintf, [
719   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
720   VLC_ADD_LIBS([skins2],[-lm])
721 ])
722 AC_CHECK_LIB(m,nanf,
723   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
724 )
725
726 dnl Check for dynamic plugins
727 LIBDL=""
728 have_dynamic_objects="no"
729 VLC_SAVE_FLAGS
730 AC_SEARCH_LIBS(dlsym, [dl svld], [
731   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
732     LIBDL="$ac_cv_search_dlsym"
733   ])
734   have_dynamic_objects="yes"
735 ])
736 VLC_RESTORE_FLAGS
737
738 # Windows
739 AS_IF([test "${SYS}" = "mingw32"], [
740   LIBDL=""
741   have_dynamic_objects="yes" #assume we can use shared objects
742 ])
743
744 AS_IF([test "${enable_shared}" = "no"], [
745   have_dynamic_objects=no
746 ])
747 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
748
749 AC_SUBST(LIBDL)
750
751 dnl Check for thread library
752 LIBPTHREAD=""
753 AS_IF([test "${SYS}" != "mingw32"], [
754   VLC_SAVE_FLAGS
755   LIBS=""
756   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
757     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
758       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
759     ])
760   ])
761   VLC_RESTORE_FLAGS
762 ])
763 AC_SUBST(LIBPTHREAD)
764
765 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
766   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
767     LIBRT="$ac_cv_search_clock_nanosleep"
768   ])
769 ], [
770   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
771     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
772       LIBRT="$ac_cv_search_nanosleep"
773     ])
774   ])
775 ])
776 AC_SUBST(LIBRT)
777
778 dnl
779 dnl Check for headers
780 dnl
781
782 dnl  POSIX
783 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h])
784 AC_CHECK_HEADERS([net/if.h], [], [],
785 [
786 #include <sys/types.h>
787 #include <sys/socket.h>
788 ])
789 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
790 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
791
792 dnl  BSD
793 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
794
795 dnl  GNU/Linux
796 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
797
798 dnl  MacOS
799 AC_CHECK_HEADERS([xlocale.h])
800
801 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
802 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
803 AC_CHECK_TYPE(ssize_t,, [
804   AC_DEFINE(ssize_t, int)
805 ])
806
807 dnl It seems that autoconf detects pkg-config only during the first
808 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
809 dnl it is nested within a conditional block, so it was not working right.
810 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
811 AC_ARG_VAR(PKG_CONFIG_PATH,
812        [Paths where to find .pc not at the default location])
813 PKG_PROG_PKG_CONFIG()
814
815 dnl On some OS we need static linking
816 AS_IF([test -n "${PKG_CONFIG}" ],[
817     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
818         PKG_CONFIG="${PKG_CONFIG} --static"
819     ])
820 ])
821
822
823 dnl
824 dnl Check for zlib.h and -lz along with system -lminizip if available
825 dnl
826 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
827 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
828 if test "${have_zlib}" = "yes"
829 then
830   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
831   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
832     AC_CHECK_HEADERS([unzip.h], [
833       have_minizip=yes
834       MINIZIP_LIBS="-lminizip -lz"
835     ], [
836       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
837       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
838       have_minizip=no
839     ])
840   ])
841   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
842   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
843 fi
844 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
845
846
847 dnl
848 dnl Domain name i18n support via GNU libidn
849 dnl
850 PKG_CHECK_MODULES([IDN], [libidn], [
851   have_libidn="yes"
852   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
853 ], [
854   have_libidn="no"
855 ])
856
857
858 dnl Check for dbus
859 AC_ARG_ENABLE(dbus,
860   [AS_HELP_STRING([--enable-dbus],
861     [compile D-Bus message bus support (default enabled)])])
862 have_dbus="no"
863 AS_IF([test "${enable_dbus}" != "no"], [
864   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
865     have_dbus="yes"
866   ], [
867     AS_IF([test -n "${enable_dbus}"], [
868       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
869     ], [
870       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
871     ])
872   ])
873 ])
874 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
875
876
877 dnl Check for systemd
878 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
879   have_systemd="yes"
880 ], [
881   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
882 ])
883 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
884
885
886 dnl Check for ntohl, etc.
887 VLC_SAVE_FLAGS
888 CFLAGS="${CFLAGS} -Wall -Werror"
889 AC_CACHE_CHECK([for ntohl in sys/param.h],
890     [ac_cv_c_ntohl_sys_param_h],
891     [     AC_TRY_COMPILE([#include <sys/param.h>],
892         [int meuh; ntohl(meuh);],
893         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
894 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
895     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
896 fi
897 VLC_RESTORE_FLAGS
898
899 EXTEND_HELP_STRING([Optimization options:])
900 dnl
901 dnl  Compiler warnings
902 dnl
903
904 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
905 RDC_PROG_CC_FLAGS([-pipe])
906 AC_LANG_PUSH([C++])
907 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
908 AC_LANG_POP([C++])
909
910 dnl
911 dnl  Debugging mode
912 dnl
913 AC_ARG_ENABLE(debug,
914   [AS_HELP_STRING([--enable-debug],
915     [build with run-time assertions (default disabled)])],,
916   [enable_debug="no"])
917 AH_TEMPLATE(NDEBUG,
918             [Define to 1 if debug code should NOT be compiled])
919 AS_IF([test "${enable_debug}" != "no"], [
920   AC_CHECK_HEADERS([valgrind/valgrind.h])
921 ], [
922   AC_DEFINE(NDEBUG)
923 ])
924
925 dnl
926 dnl  Profiling
927 dnl
928 AC_ARG_ENABLE(gprof,
929   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
930   [enable_gprof="no"])
931 AS_IF([test "${enable_gprof}" != "no"], [
932   CFLAGS="${CFLAGS} -pg"
933   CXXFLAGS="${CXXFLAGS} -pg"
934   OBJCFLAGS="${OBJCFLAGS} -pg"
935   LDFLAGS="${LDFLAGS} -pg"
936 ])
937
938 AC_ARG_ENABLE(cprof,
939   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
940   [enable_cprof="no"])
941 AS_IF([test "${enable_gprof}" != "no"], [
942   CFLAGS="${CFLAGS} -finstrument-functions"
943   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
944   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
945   LDFLAGS="${LDFLAGS} -finstrument-functions"
946 ])
947
948 dnl
949 dnl  Test coverage
950 dnl
951 AC_ARG_ENABLE(coverage,
952   [AS_HELP_STRING([--enable-coverage],
953     [build for test coverage (default disabled)])],,
954   [enable_coverage="no"])
955 AS_IF([test "${enable_coverage}" != "no"], [
956   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
957   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
958   LDFLAGS="-lgcov ${LDFLAGS}"
959 ])
960
961 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
962   VLC_SAVE_FLAGS
963   CFLAGS="${CFLAGS} -fvisibility=hidden"
964   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
965   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
966   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
967                  [ac_cv_c_visibility_hidden], [
968     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
969       ac_cv_c_visibility_hidden=yes
970     ], [
971       ac_cv_c_visibility_hidden=no
972     ])
973   ])
974   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
975 ])
976
977
978 dnl
979 dnl  Enable/disable optimizations
980 dnl
981 AC_ARG_ENABLE(optimizations,
982   [AS_HELP_STRING([--disable-optimizations],
983     [disable compiler optimizations (default enabled)])],,
984   [enable_optimizations="yes"])
985
986 dnl Check for various optimization flags
987 AS_IF([test "${enable_optimizations}" != "no"], [
988
989   dnl -O3 only in production builds
990   AS_IF([test "${enable_debug}" = "no"], [
991     VLC_SAVE_FLAGS
992     CFLAGS="${CFLAGS} -O3"
993     CXXFLAGS="${CXXFLAGS} -O3"
994     OBJCFLAGS="${OBJCFLAGS} -O3"
995     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
996       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
997         ac_cv_c_o3=yes
998       ], [
999         ac_cv_c_o3=no
1000       ])
1001     ])
1002     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1003   ])
1004
1005   dnl Check for -ffast-math
1006   VLC_SAVE_FLAGS
1007   CFLAGS="${CFLAGS} -ffast-math"
1008   CXXFLAGS="${CXXFLAGS} -ffast-math"
1009   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
1010   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
1011     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1012       ac_cv_c_fast_math=yes
1013     ], [
1014       ac_cv_c_fast_math=no
1015     ])
1016   ])
1017   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
1018   AH_BOTTOM([
1019 #ifndef __FAST_MATH__
1020 # ifndef _MSC_VER
1021 #  pragma STDC FENV_ACCESS OFF
1022 #  pragma STDC FP_CONTRACT ON
1023 # else
1024 #  pragma fenv_access(off)
1025 #  pragma fp_contract(on)
1026 # endif
1027 #endif
1028 ])
1029
1030   dnl Check for -funroll-loops
1031   VLC_SAVE_FLAGS
1032   CFLAGS="${CFLAGS} -funroll-loops"
1033   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1034   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1035   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1036     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1037       ac_cv_c_unroll_loops=yes
1038     ], [
1039       ac_cv_c_unroll_loops=no
1040     ])
1041   ])
1042   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1043
1044   AS_IF([test "$enable_debug" = "no"], [
1045     dnl Check for -fomit-frame-pointer
1046     VLC_SAVE_FLAGS
1047     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1048     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1049     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1050     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1051       [ac_cv_c_omit_frame_pointer], [
1052       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1053         ac_cv_c_omit_frame_pointer=yes
1054       ], [
1055         ac_cv_c_omit_frame_pointer=no
1056       ])
1057     ])
1058     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1059   ])
1060 ])
1061
1062 VLC_SAVE_FLAGS
1063 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1064 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1065   AC_TRY_LINK([],, [
1066     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1067   ], [
1068     ac_cv_ld_bsymbolic=""
1069   ])
1070 ])
1071 VLC_RESTORE_FLAGS
1072 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1073 AC_SUBST(SYMBOLIC_LDFLAGS)
1074
1075 dnl Checks for __attribute__(aligned()) directive
1076 VLC_SAVE_FLAGS
1077 CFLAGS="${CFLAGS} -Werror"
1078 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1079     [ac_cv_c_attribute_aligned],
1080     [ac_cv_c_attribute_aligned=0
1081     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1082         AC_TRY_COMPILE([],
1083         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1084         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1085     done])
1086 VLC_RESTORE_FLAGS
1087 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1088     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1089         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1090 fi
1091
1092 dnl Check for __attribute__((packed))
1093 AC_CACHE_CHECK([for __attribute__((packed))],
1094   [ac_cv_c_attribute_packed],
1095   [ac_cv_c_attribute_packed=no
1096    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1097                     [ac_cv_c_attribute_packed=yes])])
1098 if test "${ac_cv_c_attribute_packed}" != "no"; then
1099   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1100 fi
1101
1102 dnl
1103 dnl  Check the CPU
1104 dnl
1105 case "${host_cpu}" in
1106   "")
1107     ARCH=unknown
1108     ;;
1109   *)
1110     ARCH="${host_cpu}"
1111     ;;
1112 esac
1113
1114 dnl Check for backtrace() support
1115 AC_CHECK_HEADERS(execinfo.h)
1116 AC_CHECK_FUNCS(backtrace)
1117
1118 dnl
1119 dnl  default modules
1120 dnl
1121 ALIASES="${ALIASES} cvlc rvlc"
1122
1123 dnl
1124 dnl  Accelerated modules
1125 dnl
1126
1127 dnl  Check for fully working MMX intrinsics
1128 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1129 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1130 AC_ARG_ENABLE(mmx,
1131   [AS_HELP_STRING([--disable-mmx],
1132     [disable MMX optimizations (default auto)])],,[
1133   case "${host_cpu}" in
1134     i?86|x86_64)
1135       enable_mmx="yes"
1136       ;;
1137     *)
1138       enable_mmx="no"
1139       ;;
1140   esac
1141 ])
1142 have_mmx="no"
1143 have_mmxext="no"
1144 AS_IF([test "${enable_mmx}" != "no"], [
1145   ARCH="${ARCH} mmx"
1146   VLC_SAVE_FLAGS
1147   CFLAGS="${CFLAGS} -mmmx"
1148   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1149     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1150 [#include <mmintrin.h>
1151 #include <stdint.h>
1152 uint64_t frobzor;]], [
1153 [__m64 a, b, c;
1154 a = b = c = (__m64)frobzor;
1155 a = _mm_slli_pi16(a, 3);
1156 a = _mm_adds_pi16(a, b);
1157 c = _mm_srli_pi16(c, 8);
1158 c = _mm_slli_pi16(c, 3);
1159 b = _mm_adds_pi16(b, c);
1160 a = _mm_unpacklo_pi8(a, b);
1161 frobzor = (uint64_t)a;]])], [
1162       ac_cv_c_mmx_intrinsics=yes
1163     ], [
1164       ac_cv_c_mmx_intrinsics=no
1165     ])
1166   ])
1167   VLC_RESTORE_FLAGS
1168   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1169     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1170   ])
1171
1172   VLC_SAVE_FLAGS
1173   CFLAGS="${CFLAGS} -mmmx"
1174   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1175     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1176 void *p;
1177 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1178 ]])
1179     ], [
1180       ac_cv_mmx_inline=yes
1181     ], [
1182       ac_cv_mmx_inline=no
1183     ])
1184   ])
1185   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1186     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1187     have_mmx="yes"
1188   ])
1189
1190   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1191                  [ac_cv_mmxext_inline], [
1192     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1193 void *p;
1194 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1195 ]])
1196     ], [
1197       ac_cv_mmxext_inline=yes
1198     ], [
1199       ac_cv_mmxext_inline=no
1200     ])
1201   ])
1202   VLC_RESTORE_FLAGS
1203   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1204     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1205     have_mmxext="yes"
1206   ])
1207 ])
1208 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1209 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1210
1211 dnl  Check for fully workin SSE2 intrinsics
1212 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1213 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1214 AC_ARG_ENABLE(sse,
1215   [AS_HELP_STRING([--disable-sse],
1216     [disable SSE (1-4) optimizations (default auto)])],, [
1217   case "${host_cpu}" in
1218     i?86|x86_64)
1219       enable_sse=yes
1220       ;;
1221     *)
1222       enable_sse=no
1223       ;;
1224   esac
1225 ])
1226 have_sse2="no"
1227 AS_IF([test "${enable_sse}" != "no"], [
1228   ARCH="${ARCH} sse sse2"
1229
1230   VLC_SAVE_FLAGS
1231   CFLAGS="${CFLAGS} -msse2"
1232   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1233     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1234 [#include <emmintrin.h>
1235 #include <stdint.h>
1236 uint64_t frobzor;]], [
1237 [__m128i a, b, c;
1238 a = b = c = _mm_set1_epi64((__m64)frobzor);
1239 a = _mm_slli_epi16(a, 3);
1240 a = _mm_adds_epi16(a, b);
1241 c = _mm_srli_epi16(c, 8);
1242 c = _mm_slli_epi16(c, 3);
1243 b = _mm_adds_epi16(b, c);
1244 a = _mm_unpacklo_epi8(a, b);
1245 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1246       ac_cv_c_sse2_intrinsics=yes
1247     ], [
1248       ac_cv_c_sse2_intrinsics=no
1249     ])
1250   ])
1251   VLC_RESTORE_FLAGS
1252   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1253     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1254   ])
1255
1256   VLC_SAVE_FLAGS
1257   CFLAGS="${CFLAGS} -msse"
1258   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1259     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1260 void *p;
1261 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1262 ]])
1263     ], [
1264       ac_cv_sse_inline=yes
1265     ], [
1266       ac_cv_sse_inline=no
1267     ])
1268   ])
1269
1270   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1271     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1272   ])
1273
1274   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1275     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1276 void *p;
1277 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1278 ]])
1279     ], [
1280       ac_cv_sse2_inline=yes
1281     ], [
1282       ac_cv_sse2_inline=no
1283     ])
1284   ])
1285   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1286     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1287     have_sse2="yes"
1288   ])
1289
1290   # SSE3
1291   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1292     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1293 void *p;
1294 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1295 ]])
1296     ], [
1297       ac_cv_sse3_inline=yes
1298     ], [
1299       ac_cv_sse3_inline=no
1300     ])
1301   ])
1302
1303   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1304     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1305   # SSSE3
1306   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1307     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1308 void *p;
1309 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1310 ]])
1311     ], [
1312       ac_cv_ssse3_inline=yes
1313     ], [
1314       ac_cv_ssse3_inline=no
1315     ])
1316   ])
1317
1318   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1319     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1320
1321   # SSE4.1
1322   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1323                  [ac_cv_sse4_1_inline], [
1324     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1325 void *p;
1326 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1327 ]])
1328     ], [
1329       ac_cv_sse4_1_inline=yes
1330     ], [
1331       ac_cv_sse4_1_inline=no
1332     ])
1333   ])
1334
1335   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1336     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1337
1338   # SSE4.2
1339   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1340                  [ac_cv_sse4_2_inline], [
1341     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1342 void *p;
1343 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1344 ]])
1345     ], [
1346       ac_cv_sse4_2_inline=yes
1347     ], [
1348       ac_cv_sse4_2_inline=no
1349     ])
1350   ])
1351
1352   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1353     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1354
1355   # SSE4A
1356   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1357     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1358 void *p;
1359 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1360 ]])
1361     ], [
1362       ac_cv_sse4a_inline=yes
1363     ], [
1364       ac_cv_sse4a_inline=no
1365     ])
1366   ])
1367   VLC_RESTORE_FLAGS
1368   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1369     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1370 ])
1371 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1372
1373 VLC_SAVE_FLAGS
1374 CFLAGS="${CFLAGS} -mmmx"
1375 have_3dnow="no"
1376 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1377   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1378 void *p;
1379 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1380 ]])
1381   ], [
1382     ac_cv_3dnow_inline=yes
1383   ], [
1384     ac_cv_3dnow_inline=no
1385   ])
1386 ])
1387 VLC_RESTORE_FLAGS
1388 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1389   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1390             [Define to 1 if 3D Now! inline assembly is available.])
1391   have_3dnow="yes"
1392 ])
1393 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1394
1395
1396 AC_ARG_ENABLE(neon,
1397   [AS_HELP_STRING([--disable-neon],
1398     [disable NEON optimizations (default auto)])],, [
1399   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1400 ])
1401 AS_IF([test "${enable_neon}" != "no"], [
1402   VLC_SAVE_FLAGS
1403   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1404   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1405     AC_COMPILE_IFELSE([
1406       AC_LANG_PROGRAM(,[[
1407 asm volatile("vqmovun.s64 d0, q1":::"d0");
1408 ]])
1409     ], [
1410       ac_cv_arm_neon="yes"
1411     ], [
1412       ac_cv_arm_neon="no"
1413     ])
1414   ])
1415   VLC_RESTORE_FLAGS
1416 ])
1417 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1418
1419
1420 AC_ARG_ENABLE(altivec,
1421   [AS_HELP_STRING([--disable-altivec],
1422     [disable AltiVec optimizations (default auto)])],, [
1423   AS_CASE("${host_cpu}", [powerpc*],
1424         [enable_altivec=yes], [enable_altivec=no])
1425 ])
1426 have_altivec="no"
1427 ALTIVEC_CFLAGS=""
1428 AS_IF([test "${enable_altivec}" = "yes"], [
1429   ARCH="${ARCH} altivec";
1430   VLC_SAVE_FLAGS
1431   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1432     [ac_cv_altivec_inline],
1433     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1434          ac_cv_altivec_inline="yes",
1435          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1436           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1437             [ac_cv_altivec_inline="-Wa,-maltivec"],
1438             ac_cv_altivec_inline=no)
1439          ])])
1440   VLC_RESTORE_FLAGS
1441   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1442     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1443               [Define to 1 if AltiVec inline assembly is available.])
1444     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1445       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1446       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1447     ])
1448     have_altivec="yes"
1449   ])
1450
1451   VLC_SAVE_FLAGS
1452   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1453   [ac_cv_c_altivec], [
1454     CFLAGS="${CFLAGS} -maltivec"
1455     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1456 [#include <altivec.h>]], [
1457 [vec_ld(0, (unsigned char *)0);]])], [
1458       ac_cv_c_altivec="-maltivec"
1459     ], [
1460       ac_cv_c_altivec="no"
1461     ])
1462   ])
1463   VLC_RESTORE_FLAGS
1464   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1465     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1466     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1467     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1468     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1469     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1470     have_altivec="yes"
1471   ])
1472   AC_CHECK_HEADERS(altivec.h)
1473
1474   VLC_SAVE_FLAGS
1475   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1476   AC_CACHE_CHECK([if linker needs -framework vecLib],
1477     [ac_cv_ld_altivec],
1478     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1479   VLC_RESTORE_FLAGS
1480   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1481     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1482   ])
1483 ])
1484 AC_SUBST(ALTIVEC_CFLAGS)
1485 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1486
1487 dnl
1488 dnl  Memory usage
1489 dnl
1490 AC_ARG_ENABLE(optimize-memory,
1491   [AS_HELP_STRING([--enable-optimize-memory],
1492     [optimize memory usage over performance])])
1493 if test "${enable_optimize_memory}" = "yes"; then
1494   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1495 fi
1496
1497 dnl
1498 dnl Allow running as root (useful for people running on embedded platforms)
1499 dnl
1500 AC_ARG_ENABLE(run-as-root,
1501   [AS_HELP_STRING([--enable-run-as-root],
1502     [allow running VLC as root (default disabled)])])
1503 AS_IF([test "${enable_run_as_root}" = "yes"],[
1504     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1505               [Define to 1 to allow running VLC as root (uid 0).])
1506 ])
1507
1508 dnl
1509 dnl Stream output
1510 dnl
1511 AC_ARG_ENABLE(sout,
1512   [AS_HELP_STRING([--disable-sout],
1513     [disable streaming output (default enabled)])])
1514 AS_IF([test "${enable_sout}" != "no"], [
1515   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1516 ])
1517 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1518
1519 dnl Lua modules
1520 AC_ARG_ENABLE(lua,
1521   [AS_HELP_STRING([--disable-lua],
1522     [disable LUA scripting support (default enabled)])])
1523 if test "${enable_lua}" != "no"
1524 then
1525   PKG_CHECK_MODULES(LUA, lua5.3, [have_lua=yes], [
1526     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying Lua 5.2 instead])
1527
1528     PKG_CHECK_MODULES(LUA, lua5.2, [have_lua=yes], [
1529       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying Lua 5.1 instead])
1530
1531       PKG_CHECK_MODULES(LUA, lua5.1, [have_lua=yes], [
1532         AC_MSG_WARN([${LUA_PKG_ERRORS}, trying Lua instead])
1533         PKG_CHECK_MODULES(LUA, lua >= 5.1, [have_lua=yes], [
1534             AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1535             have_lua=yes
1536             AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h], [], [have_lua=no])
1537             AC_CHECK_LIB(lua5.2, luaL_newstate, [LUA_LIBS="-llua5.2"], [
1538               AC_CHECK_LIB(lua5.1, luaL_newstate, [LUA_LIBS="-llua5.1"], [
1539                 AC_CHECK_LIB(lua51, luaL_newstate, [LUA_LIBS="-llua51"], [
1540                   AC_CHECK_LIB(lua, luaL_newstate, [LUA_LIBS="-llua"], [
1541                     have_lua=no], [-lm])
1542                 ])
1543               ])
1544             ])
1545           ])
1546         ])
1547       ])
1548     ])
1549   if test "x${have_lua}" != "xyes" ;  then
1550       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1551   fi
1552   AC_ARG_VAR([LUAC], [LUA byte compiler])
1553   AC_PATH_PROGS(LUAC, [${LUAC} luac5.3 luac], [false])
1554   AS_IF([test "${LUAC}" = "false"], [
1555     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1556   ])
1557   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1558     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1559   ])
1560 fi
1561 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1562
1563
1564 dnl
1565 dnl HTTP daemon
1566 dnl
1567 AC_ARG_ENABLE(httpd,
1568   [AS_HELP_STRING([--disable-httpd],
1569     [disable the built-in HTTP server (default enabled)])])
1570 if test "${enable_httpd}" != "no"
1571 then
1572   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1573 fi
1574 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1575
1576
1577 dnl
1578 dnl VideoLAN manager
1579 dnl
1580 AC_ARG_ENABLE(vlm,
1581   [AS_HELP_STRING([--disable-vlm],
1582     [disable the stream manager (default enabled)])],,
1583   [enable_vlm="${enable_sout}"])
1584 AS_IF([test "${enable_vlm}" != "no"], [
1585   AS_IF([test "${enable_sout}" = "no"], [
1586     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1587   ])
1588   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1589 ])
1590 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1591
1592
1593 dnl
1594 dnl Addons manager storage and repositories modules
1595 dnl
1596 AC_ARG_ENABLE(addonmanagermodules,
1597   [AS_HELP_STRING([--disable-addonmanagermodules],
1598     [disable the addons manager modules (default enabled)])])
1599 if test "${enable_addonmanagermodules}" != "no"
1600 then
1601   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1602 fi
1603 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1604
1605
1606 dnl
1607 dnl  Input plugins
1608 dnl
1609
1610 EXTEND_HELP_STRING([Input plugins:])
1611
1612 dnl
1613 dnl  libarchive access module
1614 dnl
1615 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1616
1617 dnl
1618 dnl  live555 input
1619 dnl
1620 AC_ARG_ENABLE(live555,
1621   [AS_HELP_STRING([--enable-live555],
1622     [enable RTSP input through live555 (default enabled)])])
1623
1624 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1625   PKG_CHECK_MODULES(LIVE555, live555, [
1626     VLC_ADD_PLUGIN([live555])
1627     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1628     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1629   ], [
1630     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1631
1632     AC_LANG_PUSH(C++)
1633     VLC_SAVE_FLAGS
1634
1635     dnl detect include paths
1636     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1637       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1638     ], [
1639       AS_IF([test "${SYS}" != "os2"], [
1640         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1641         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1642       ], [
1643         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1644         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1645         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1646       ])
1647     ])
1648
1649     dnl CPP Flags
1650     AS_IF([test "${SYS}" = "solaris"], [
1651       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1652     ])
1653     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1654     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1655
1656     dnl version check
1657     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1658       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1659 [#include <liveMedia_version.hh>
1660 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1661 # error BOOM
1662 #endif]])
1663       ], [
1664         ac_cv_live555="yes"
1665       ], [
1666         ac_cv_live555="no"
1667       ])
1668     ])
1669
1670     AS_IF([test "$ac_cv_live555" = "no"], [
1671       AC_MSG_WARN([live555 is missing or its installed version is too old:
1672 Version 2011.12.23 or later is required to proceed.
1673 You can get an updated one from http://www.live555.com/liveMedia .])
1674       AS_IF([test -n "${enable_live555}"], [
1675         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1676       ])
1677     ], [
1678       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1679       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1680       AS_IF([test "${SYS}" = "mingw32"], [
1681         # add ws2_32 for closesocket, select, recv
1682         other_libs="$other_libs -lws2_32"
1683       ])
1684
1685       dnl We need to check for pic because live555 don't provide shared libs
1686       dnl and we want to build a plugins so we need -fPIC on some arch.
1687       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1688       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1689       AC_CHECK_LIB(liveMedia_pic, main, [
1690         VLC_ADD_PLUGIN([live555])
1691         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1692       ],[
1693         AC_CHECK_LIB(liveMedia, main, [
1694           VLC_ADD_PLUGIN([live555])
1695           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1696         ],[],[${other_libs}])
1697       ],[${other_libs_pic}])
1698     ])
1699     VLC_RESTORE_FLAGS
1700     AC_LANG_POP(C++)
1701   ])
1702 ])
1703
1704 dnl
1705 dnl IIDC and DV FireWire input modules
1706 dnl
1707 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1708 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1709
1710 dnl
1711 dnl - linsys modules: access module check for libzvbi
1712 dnl
1713 AC_ARG_ENABLE(linsys,
1714   [AS_HELP_STRING([--enable-linsys],
1715     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1716 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1717   VLC_ADD_PLUGIN([linsys_hdsdi])
1718   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1719     VLC_ADD_PLUGIN([linsys_sdi])
1720   ], [
1721     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1722   ])
1723 ])
1724
1725 dnl
1726 dnl dvdread module: check for libdvdread
1727 dnl
1728 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1729
1730 dnl
1731 dnl libdvdnav plugin
1732 dnl
1733 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1734 AS_IF([test "${enable_dvdnav}" != "no"], [
1735   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1736     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1737       AC_MSG_RESULT(yes)
1738       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1739       ],[
1740       AC_MSG_RESULT(no)
1741     ])
1742 ])
1743
1744 dnl
1745 dnl  Blu-ray Disc Support with libbluray
1746 dnl
1747 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1748
1749 dnl
1750 dnl  OpenCV wrapper and example filters
1751 dnl
1752 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1753
1754
1755 dnl
1756 dnl  libsmbclient plugin
1757 dnl
1758 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1759 AS_IF([test "${SYS}" = "mingw32"], [ VLC_ADD_PLUGIN([smb]) ])
1760
1761 dnl
1762 dnl  liBDSM access module
1763 dnl
1764 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1765
1766 dnl
1767 dnl sftp access support
1768 dnl
1769 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1770
1771 dnl
1772 dnl nfs access support
1773 dnl
1774 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs], (support nfs protocol via libnfs), [auto])
1775
1776 dnl
1777 dnl  Video4Linux 2
1778 dnl
1779 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1780   [disable Video4Linux version 2 (default auto)])])
1781 have_v4l2="no"
1782 AS_IF([test "$enable_v4l2" != "no"], [
1783   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1784     have_v4l2="yes"
1785   ])
1786 ])
1787 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1788
1789 dnl
1790 dnl special access module for Blackmagic SDI cards
1791 dnl
1792 AC_ARG_ENABLE(decklink,
1793   [AS_HELP_STRING([--disable-decklink],
1794     [disable Blackmagic DeckLink SDI input (default auto)])])
1795 AC_ARG_WITH(decklink_sdk,
1796   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1797     [                        location of Blackmagic DeckLink SDI SDK])])
1798 have_decklink=no
1799 if test "${enable_decklink}" != "no"
1800 then
1801   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1802   then
1803     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1804   fi
1805   VLC_SAVE_FLAGS
1806   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1807   AC_LANG_PUSH(C++)
1808   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1809       have_decklink=yes
1810   ], [
1811       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1812   ])
1813   AC_LANG_POP(C++)
1814   VLC_RESTORE_FLAGS
1815 fi
1816 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1817
1818
1819 dnl
1820 dnl  Built-in CD-DA and VCD module
1821 dnl
1822 AC_ARG_ENABLE(vcd,
1823   [AS_HELP_STRING([--disable-vcd],
1824     [disable built-in VCD and CD-DA support (default enabled)])])
1825
1826 AC_ARG_ENABLE(libcddb,
1827   [AS_HELP_STRING([--disable-libcddb],
1828     [disable CDDB for Audio CD (default enabled)])])
1829
1830 if test "${enable_vcd}" != "no"
1831 then
1832   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1833   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1834     AC_MSG_RESULT(yes)
1835     VLC_ADD_PLUGIN([vcd cdda])
1836   ],[
1837     AC_MSG_RESULT(no)
1838   ])
1839
1840   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1841   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1842     AC_MSG_RESULT(yes)
1843     VLC_ADD_PLUGIN([vcd cdda])
1844     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1845   ],[
1846     AC_MSG_RESULT(no)
1847   ])
1848
1849   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1850   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1851     AC_MSG_RESULT(yes)
1852     VLC_ADD_PLUGIN([vcd cdda])
1853     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1854   ],[
1855     AC_MSG_RESULT(no)
1856   ])
1857
1858   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1859   then
1860     VLC_ADD_PLUGIN([vcd cdda])
1861   fi
1862
1863   if test "$enable_libcddb" != "no"; then
1864     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1865       HAVE_LIBCDDB=yes
1866       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1867       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1868       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1869       ],:
1870       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1871       HAVE_LIBCDDB=no])
1872   fi
1873 fi
1874
1875 dnl
1876 dnl Linux DVB
1877 dnl
1878 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1879   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1880 [#include <linux/dvb/version.h>
1881 #if (DVB_API_VERSION < 5)
1882 # error Linux DVB API v3.2 and older are not supported.
1883 #endif
1884 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1885 # error Linux DVB API v5.0 is unsupported. Please update.
1886 #endif
1887 ]])], [
1888   ac_cv_linux_dvb_5_1=yes
1889 ], [
1890   ac_cv_linux_dvb_5_1=no
1891 ])])
1892 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1893
1894 dnl
1895 dnl  Screen capture module
1896 dnl
1897 AC_ARG_ENABLE(screen,
1898   [AS_HELP_STRING([--enable-screen],
1899     [disable screen capture (default enabled)])])
1900 if test "${enable_screen}" != "no"; then
1901   if test "${SYS}" = "darwin"; then
1902     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1903       VLC_ADD_PLUGIN([screen])
1904     ])
1905   fi
1906 fi
1907 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1908
1909 dnl
1910 dnl  VNC/RFB access module
1911 dnl
1912 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1913
1914 dnl  RDP/Remote Desktop access module
1915 dnl
1916 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1917
1918 dnl
1919 dnl  Real RTSP plugin
1920 dnl
1921 AC_ARG_ENABLE(realrtsp,
1922   [  --enable-realrtsp       Real RTSP module (default disabled)])
1923 if test "${enable_realrtsp}" = "yes"; then
1924   VLC_ADD_PLUGIN([access_realrtsp])
1925 fi
1926
1927 dnl
1928 dnl MacOS eyeTV
1929 AC_ARG_ENABLE(macosx-eyetv,
1930   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1931 if test "x${enable_macosx_eyetv}" != "xno" &&
1932   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1933 then
1934   VLC_ADD_PLUGIN([access_eyetv])
1935 fi
1936
1937 dnl
1938 dnl QTKit
1939 AC_ARG_ENABLE(macosx-qtkit,
1940   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X)])
1941 if test "x${enable_macosx_qtkit}" != "xno" &&
1942   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1943 then
1944   VLC_ADD_PLUGIN([qtsound])
1945 fi
1946 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1947
1948 dnl
1949 dnl AVFoundation
1950 AC_SUBST(have_avfoundation, ["no"])
1951 AC_ARG_ENABLE(macosx-avfoundation,
1952   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1953 if test "x${enable_macosx_avfoundation}" != "xno" &&
1954   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1955 then
1956   SAVED_LIBS="${LIBS}"
1957   LIBS="-framework AVFoundation"
1958   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1959   LIBS="${SAVED_LIBS}"
1960   if test "${have_avfoundation}" != "no"
1961   then
1962     VLC_ADD_PLUGIN([avcapture])
1963   fi
1964 fi
1965 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1966
1967 dnl
1968 dnl  DCP plugin (using asdcplib)
1969 dnl
1970 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1971 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1972
1973 dnl
1974 dnl  Demux plugins
1975 dnl
1976
1977 EXTEND_HELP_STRING([Mux/Demux plugins:])
1978
1979 dnl
1980 dnl  libdvbpsi check for ts mux/demux
1981 dnl
1982 have_dvbpsi="no"
1983 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
1984 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1985
1986
1987 dnl
1988 dnl  GME demux plugin
1989 dnl
1990 AC_ARG_ENABLE(gme,
1991   [AS_HELP_STRING([--enable-gme],
1992     [use Game Music Emu (default auto)])])
1993 AS_IF([test "${enable_gme}" != "no"], [
1994   AC_CHECK_HEADER([gme/gme.h], [
1995     VLC_ADD_LIBS([gme], [-lgme])
1996     VLC_ADD_PLUGIN([gme])
1997   ], [
1998     AS_IF([test "x${enable_gme}" != "x"], [
1999       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2000     ])
2001   ])
2002 ])
2003
2004
2005 dnl
2006 dnl  SIDPlay plugin
2007 dnl
2008 AC_ARG_ENABLE(sid,
2009     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2010 AS_IF([test "${enable_sid}" != "no"], [
2011     PKG_CHECK_MODULES(SID, [libsidplay2], [
2012         AC_LANG_PUSH(C++)
2013         oldCPPFLAGS="$CPPFLAGS"
2014         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2015         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2016             VLC_ADD_PLUGIN([sid])
2017             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2018             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2019         ], [
2020             AS_IF([test -n "${enable_sid}"],
2021                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2022                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2023                 )
2024         ])
2025         CPPFLAGS="$oldCPPFLAGS"
2026         AC_LANG_POP(C++)
2027     ], [
2028         AS_IF([test "x${enable_sid}" = "xyes"],
2029             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2030             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2031             )
2032     ])
2033 ])
2034
2035
2036 dnl
2037 dnl  ogg demux plugin
2038 dnl
2039 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2040 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2041     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2042 ],[true])
2043 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2044 if test "${enable_sout}" != "no"; then
2045 dnl Check for libshout
2046     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2047 fi
2048
2049 dnl
2050 dnl  matroska demux plugin
2051 dnl
2052 AC_ARG_ENABLE(mkv,
2053   [AS_HELP_STRING([--disable-mkv],
2054     [do not use libmatroska (default auto)])])
2055 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2056   AC_LANG_PUSH(C++)
2057   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2058     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2059     AC_EGREP_CPP(yes,
2060       [#include <ebml/EbmlVersion.h>
2061        #ifdef LIBEBML_VERSION
2062        #if LIBEBML_VERSION >= 0x010000
2063        yes
2064        #endif
2065        #endif],
2066       [AC_MSG_RESULT([yes])
2067         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2068           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2069           AC_EGREP_CPP(yes,
2070             [#include <matroska/KaxVersion.h>
2071              #ifdef LIBMATROSKA_VERSION
2072              #if LIBMATROSKA_VERSION >= 0x010000
2073              yes
2074              #endif
2075              #endif],
2076             [AC_MSG_RESULT([yes])
2077               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2078               AC_CHECK_LIB(ebml_pic, main, [
2079                 VLC_ADD_PLUGIN([mkv])
2080                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2081               ],[
2082                 AC_CHECK_LIB(ebml, main, [
2083                   VLC_ADD_PLUGIN([mkv])
2084                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2085                 ])
2086               ])
2087             ], [
2088               AC_MSG_RESULT([no])
2089               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2090           ])
2091         ])
2092       ],
2093       [AC_MSG_RESULT([no])
2094         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2095     ])
2096   ])
2097   AC_LANG_POP(C++)
2098 fi
2099
2100 dnl
2101 dnl  modplug demux plugin
2102 dnl
2103 AC_ARG_ENABLE(mod,
2104   [AS_HELP_STRING([--disable-mod],
2105     [do not use libmodplug (default auto)])])
2106 if test "${enable_mod}" != "no" ; then
2107     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2108           VLC_ADD_PLUGIN([mod])
2109           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2110           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2111           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2112     ],[
2113        AS_IF([test -n "${enable_mod}"],
2114          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2115          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2116     ])
2117 fi
2118
2119 dnl
2120 dnl  mpc demux plugin
2121 dnl
2122 AC_ARG_ENABLE(mpc,
2123   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2124 if test "${enable_mpc}" != "no"
2125 then
2126   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2127     VLC_ADD_PLUGIN([mpc])
2128     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2129     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2130     VLC_ADD_PLUGIN([mpc])
2131     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2132 fi
2133
2134 dnl
2135 dnl  Codec plugins
2136 dnl
2137
2138 EXTEND_HELP_STRING([Codec plugins:])
2139
2140 dnl
2141 dnl wmafixed plugin
2142 dnl
2143 AC_ARG_ENABLE(wma-fixed,
2144   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2145 if test "${enable_wma_fixed}" = "yes"
2146 then
2147   VLC_ADD_PLUGIN([wma_fixed])
2148 fi
2149
2150 dnl
2151 dnl shine encoder plugin
2152 dnl
2153 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2154
2155
2156 dnl
2157 dnl openmax il codec plugin
2158 dnl
2159 AC_ARG_ENABLE(omxil,
2160   [  --enable-omxil          openmax il codec module (default disabled)])
2161 if test "${enable_omxil}" = "yes"
2162 then
2163   VLC_ADD_PLUGIN([omxil])
2164 fi
2165
2166 dnl
2167 dnl openmax il vout plugin
2168 dnl
2169 AC_ARG_ENABLE(omxil-vout,
2170   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2171 if test "${enable_omxil_vout}" = "yes"
2172 then
2173   VLC_ADD_PLUGIN([omxil_vout])
2174 fi
2175
2176 dnl
2177 dnl raspberry pi openmax il configuration
2178 dnl
2179 AC_ARG_ENABLE(rpi-omxil,
2180   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2181 if test "${enable_rpi_omxil}" = "yes"
2182 then
2183   VLC_ADD_PLUGIN([omxil omxil_vout])
2184   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2185 fi
2186
2187 dnl
2188 dnl CrystalHD codec plugin
2189 dnl
2190 AC_ARG_ENABLE(crystalhd,
2191   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2192 if test "${enable_crystalhd}" != "no"; then
2193     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2194       VLC_ADD_PLUGIN([crystalhd])
2195       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2196     ],[
2197       if test "${SYS}" = "mingw32" ; then
2198         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2199           VLC_ADD_PLUGIN([crystalhd])
2200           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2201             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2202             ])
2203         ],[
2204           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2205                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2206                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2207         ],[#define __LINUX_USER__
2208                #include <libcrystalhd/bc_dts_types.h>
2209         ])
2210       fi
2211     ],[
2212        #include <libcrystalhd/bc_dts_types.h>
2213       ])
2214 fi
2215
2216 dnl
2217 dnl  mad plugin
2218 dnl
2219 have_mad="no"
2220 MAD_CFLAGS=""
2221 MAD_LIBS=""
2222
2223 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2224   enable_mad="yes"
2225 ], [
2226   with_mad="no"
2227 ])
2228 AS_IF([test "${with_mad}" != "no"], [
2229   MAD_CFLAGS="-I${with_mad}/include"
2230   MAD_LIBS="-L${with_mad}/lib"
2231 ])
2232
2233 AC_ARG_ENABLE(mad,
2234   [  --enable-mad            libmad module (default enabled)])
2235 AS_IF([test "${enable_mad}" != "no"], [
2236   VLC_SAVE_FLAGS
2237   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2238   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2239   AC_CHECK_HEADERS(mad.h, [
2240     AC_CHECK_LIB(mad, mad_bit_init, [
2241       have_mad="yes"
2242       MAD_LIBS="${MAD_LIBS} -lmad"
2243     ])
2244   ])
2245   VLC_RESTORE_FLAGS
2246   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2247     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2248   ])
2249 ])
2250 AC_SUBST(MAD_CFLAGS)
2251 AC_SUBST(MAD_LIBS)
2252 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2253
2254 dnl  mpg123 plugin
2255 dnl
2256 dnl
2257 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2258
2259
2260 AC_ARG_ENABLE(merge-ffmpeg,
2261 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2262   enable_merge_ffmpeg="no"
2263 ])
2264 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2265
2266 AC_MSG_CHECKING([for libavutil variant])
2267 PKG_CHECK_EXISTS([libavutil], [
2268   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2269   libavutil_micro="${libavutil_version##*.}"
2270   AS_IF([test ${libavutil_micro} -le 99], [
2271     avfork="libav"
2272   ], [
2273     avfork="ffmpeg"
2274   ])
2275 ], [
2276   avfork="none"
2277 ])
2278 AC_MSG_RESULT([${avfork}])
2279
2280 dnl
2281 dnl gstreamer stuff
2282 dnl
2283 AC_ARG_ENABLE(gst-decode,
2284   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2285
2286 have_gst_decode="no"
2287 AS_IF([test "${enable_gst_decode}" != "no"], [
2288   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2289     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2290       have_gst_decode="yes"
2291     ], [
2292       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2293     ])
2294   ], [
2295     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2296   ])
2297 ])
2298 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2299
2300 dnl
2301 dnl  avcodec decoder/encoder plugin
2302 dnl
2303 AC_ARG_ENABLE(avcodec,
2304 [  --enable-avcodec        libavcodec codec (default enabled)])
2305 AS_IF([test "${enable_avcodec}" != "no"], [
2306   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 55.0.0 libavutil >= 52.0.0], [
2307     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2308     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2309     dnl ])
2310     VLC_SAVE_FLAGS
2311     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2312     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2313     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2314     AC_CHECK_HEADERS(libavutil/avutil.h)
2315     VLC_RESTORE_FLAGS
2316     have_avcodec="yes"
2317   ],[
2318     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2319   ])
2320 ], [
2321   have_avcodec="no"
2322 ])
2323 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2324
2325 dnl
2326 dnl libva needs avcodec
2327 dnl
2328 AC_ARG_ENABLE(libva,
2329   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2330
2331 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2332   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2333 ])
2334
2335 have_vaapi="no"
2336 have_vaapi_drm="no"
2337 have_vaapi_x11="no"
2338 AS_IF([test "${enable_libva}" != "no"], [
2339   PKG_CHECK_EXISTS([libva], [
2340     have_vaapi="yes"
2341   ], [
2342     AS_IF([test -n "${enable_libva}"], [
2343       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2344     ], [
2345       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2346     ])
2347   ])
2348   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2349     have_vaapi_drm="yes"
2350   ], [
2351     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2352   ])
2353   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2354     have_vaapi_x11="yes"
2355   ], [
2356     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2357   ])
2358 ])
2359 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2360 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2361
2362 have_avcodec_vaapi="no"
2363 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2364   case "${avfork}" in
2365     ffmpeg)
2366       PKG_CHECK_EXISTS([libavcodec >= 57.10.100], [
2367         PKG_CHECK_EXISTS([libavcodec <= 57.12.100], [
2368           AC_MSG_ERROR([VA API requires FFmpeg libavcodec < 57.10 or > 57.12 or libav.])
2369         ])
2370       ])
2371       ;;
2372   esac
2373   VLC_SAVE_FLAGS
2374   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2375   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2376   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2377     AC_MSG_NOTICE([VA API acceleration activated])
2378     have_avcodec_vaapi="yes"
2379   ],[
2380     AS_IF([test -n "${enable_libva}"], [
2381       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2382     ], [
2383       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2384     ])
2385   ])
2386   VLC_RESTORE_FLAGS
2387 ])
2388 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2389
2390 dnl
2391 dnl dxva2 needs avcodec
2392 dnl
2393 AC_ARG_ENABLE(dxva2,
2394   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2395
2396 have_avcodec_dxva2="no"
2397 AS_IF([test "${enable_dxva2}" != "no"], [
2398   if test "${SYS}" = "mingw32"; then
2399   AS_IF([test "x${have_avcodec}" = "xyes"], [
2400     AC_CHECK_HEADERS(dxva2api.h,
2401       [
2402         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2403            AC_MSG_NOTICE([DxVA2 acceleration activated])
2404            have_avcodec_dxva2="yes"
2405         ],[
2406     AS_IF([test "${enable_dxva2}" = "yes"],
2407           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2408               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2409         ], [#undef _WIN32_WINNT
2410             /* DXVA2 is only available in Vista and above */
2411             #define _WIN32_WINNT 0x600])
2412       ],[
2413     AS_IF([test "${enable_dxva2}" = "yes"],
2414               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2415               [AC_MSG_WARN([dxva2api.h not found])])
2416       ],[#include <d3d9.h>])
2417   ],[
2418     AS_IF([test "x${enable_dxva2}" != "x"], [
2419       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2420     ])
2421   ])
2422   fi
2423 ])
2424 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2425
2426 dnl
2427 dnl d3d11va needs avcodec
2428 dnl
2429 AC_ARG_ENABLE(d3d11va,
2430   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2431
2432 have_avcodec_d3d11va="no"
2433 AS_IF([test "${enable_d3d11va}" != "no"], [
2434   if test "${SYS}" = "mingw32"; then
2435   AS_IF([test "x${have_avcodec}" = "xyes"], [
2436         AC_CHECK_TYPES([ID3D11VideoDecoder],
2437           [
2438             AC_CHECK_HEADERS(dxva2api.h,
2439               [
2440                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2441                    AC_MSG_NOTICE([D3D11 acceleration activated])
2442                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2443                    have_avcodec_d3d11va="yes"
2444                 ],[
2445                   AS_IF([test "${enable_d3d11va}" = "yes"],
2446                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2447                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2448                   ], [#undef _WIN32_WINNT
2449                       /* D3D11 is only available in Vista and above */
2450                       #define _WIN32_WINNT 0x600])
2451                   ],[
2452                     AS_IF([test "${enable_d3d11va}" = "yes"],
2453                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2454                           [AC_MSG_WARN([dxva2api.h not found])])
2455                   ],[#include <d3d9.h>])
2456           ],[
2457             AS_IF([test "${enable_d3d11va}" = "yes"],
2458                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2459                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2460           ], [#include <d3d11.h>])
2461   ],[
2462     AS_IF([test "x${enable_d3d11va}" != "x"], [
2463       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2464     ])
2465   ])
2466   fi
2467 ])
2468 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2469
2470 dnl
2471 dnl DXGI debug
2472 dnl
2473 AC_CHECK_HEADERS(dxgidebug.h)
2474
2475 dnl
2476 dnl vda needs avcodec
2477 dnl
2478 AC_ARG_ENABLE(vda,
2479   [  --enable-vda          VDA  support (default auto)])
2480
2481 have_avcodec_vda="no"
2482 AS_IF([test "${enable_vda}" != "no"], [
2483   if test "${SYS}" = "darwin"; then
2484   AS_IF([test "x${have_avcodec}" = "xyes"], [
2485     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2486       [
2487         AC_CHECK_HEADERS(libavcodec/vda.h, [
2488            have_avcodec_vda="yes"
2489         ],[
2490         AS_IF([test "${enable_vda}" = "yes"],
2491               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2492               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2493         ])
2494   ],[
2495         AS_IF([test "${enable_vda}" = "yes"],
2496               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2497               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2498       ])
2499   ],[
2500     AS_IF([test "x${enable_vda}" != "x"], [
2501       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2502     ])
2503  ])
2504  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2505      SAVE_LIBS=$LIBS
2506      LIBS="$LIBS $AVCODEC_LIBS"
2507      AC_CHECK_FUNCS([av_vda_alloc_context])
2508      LIBS=$SAVE_LIBS
2509  ])
2510  fi
2511 ])
2512 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2513
2514 dnl
2515 dnl  avformat demuxer/muxer plugin
2516 dnl
2517
2518 AC_ARG_ENABLE(avformat,
2519 [  --enable-avformat       libavformat containers (default enabled)],, [
2520   enable_avformat="${have_avcodec}"
2521 ])
2522 have_avformat="no"
2523 AS_IF([test "${enable_avformat}" != "no"], [
2524   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2525       have_avformat="yes"
2526       VLC_SAVE_FLAGS
2527       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2528       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2529       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2530       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2531       AC_CHECK_HEADERS(libavutil/avutil.h)
2532       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2533         have_avformat="no"
2534       ])
2535       VLC_RESTORE_FLAGS
2536     ],[
2537       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2538   ])
2539 ])
2540 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2541
2542 dnl
2543 dnl  swscale image scaling and conversion plugin
2544 dnl
2545
2546 AC_ARG_ENABLE(swscale,
2547   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2548           (default enabled)]))
2549 if test "${enable_swscale}" != "no"
2550 then
2551   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2552     [
2553       VLC_SAVE_FLAGS
2554       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2555       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2556       AC_CHECK_HEADERS(libswscale/swscale.h)
2557       AC_CHECK_HEADERS(libavutil/avutil.h)
2558       VLC_ADD_PLUGIN([swscale])
2559       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2560       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2561       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2562         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2563       ])
2564       VLC_RESTORE_FLAGS
2565     ],[
2566       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2567   ])
2568 fi
2569
2570 dnl
2571 dnl  postproc plugin
2572 dnl
2573
2574 AC_ARG_ENABLE(postproc,
2575 [  --enable-postproc       libpostproc image post-processing (default auto)])
2576 if test "${enable_postproc}" != "no"
2577 then
2578   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2579     [
2580       VLC_SAVE_FLAGS
2581       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2582       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2583       AC_CHECK_HEADERS(postproc/postprocess.h)
2584       VLC_ADD_PLUGIN([postproc])
2585       VLC_RESTORE_FLAGS
2586     ],[
2587       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2588   ])
2589 fi
2590
2591 dnl
2592 dnl  faad decoder plugin
2593 dnl
2594 AC_ARG_ENABLE(faad,
2595 [  --enable-faad           faad codec (default auto)])
2596 have_faad="no"
2597 AS_IF([test "${enable_faad}" != "no"], [
2598   AC_CHECK_HEADERS([neaacdec.h], [
2599     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2600
2601     AS_IF([test "${have_faad}" = "yes"], [
2602       VLC_ADD_PLUGIN([faad])
2603       VLC_ADD_LIBS([faad],[-lfaad])
2604     ], [
2605       AS_IF([test "${enable_faad}" = "yes"], [
2606         AC_MSG_ERROR([cannot find FAAD library])
2607       ], [
2608         AC_MSG_WARN([cannot find FAAD library])
2609       ])
2610     ])
2611   ])
2612 ])
2613
2614 dnl
2615 dnl libvpx decoder plugin
2616 dnl
2617 AC_ARG_ENABLE(vpx,
2618     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2619 AS_IF([test "${enable_vpx}" != "no"],[
2620     PKG_CHECK_MODULES([VPX], [vpx] , [
2621         VLC_ADD_PLUGIN([vpx])
2622         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2623         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2624         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2625             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2626         ], [], [${VPX_LIBS}])
2627         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2628             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2629         ], [], [${VPX_LIBS}])
2630         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2631             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2632         ], [], [${VPX_LIBS}])
2633         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2634             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2635         ], [], [${VPX_LIBS}])
2636     ], [
2637     AS_IF([test "${enable_vpx}" = "yes"],[
2638         AC_MSG_ERROR([libvpx was not found])
2639     ])])
2640 ])
2641
2642 dnl
2643 dnl twolame encoder plugin
2644 dnl
2645 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2646
2647 dnl
2648 dnl fdk-aac encoder plugin
2649 dnl
2650 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2651
2652 dnl
2653 dnl  QuickTime plugin
2654 dnl
2655 AC_ARG_ENABLE(quicktime,
2656   [  --enable-quicktime      QuickTime module (deprecated)])
2657 if test "${enable_quicktime}" = "yes"; then
2658   if test "${SYS}" = "mingw32"; then
2659     VLC_ADD_PLUGIN([quicktime])
2660   else
2661   AC_CHECK_HEADERS(QuickTime/QuickTime.h,
2662     [ VLC_ADD_PLUGIN([quicktime])
2663       VLC_ADD_LIBS([quicktime],[-Wl,-framework,QuickTime,-framework,Carbon])
2664     ], [ AC_MSG_ERROR([cannot find QuickTime headers]) ])
2665   fi
2666 fi
2667
2668 dnl
2669 dnl A52/AC3 decoder plugin
2670 dnl
2671 AC_ARG_ENABLE(a52,
2672   [  --enable-a52            A/52 support with liba52 (default enabled)])
2673 if test "${enable_a52}" != "no"
2674 then
2675   AC_ARG_WITH(a52,
2676     [  --with-a52=PATH         a52 headers and libraries])
2677     if test -z "${with_a52}"
2678     then
2679       LDFLAGS_test=""
2680       CPPFLAGS_test=""
2681     else
2682       LDFLAGS_test="-L${with_a52}/lib"
2683       CPPFLAGS_test="-I${with_a52}/include"
2684     fi
2685     VLC_SAVE_FLAGS
2686     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2687     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2688     AC_CHECK_HEADERS(a52dec/a52.h, [
2689       AC_CHECK_LIB(a52, a52_free, [
2690         VLC_ADD_PLUGIN([a52tofloat32])
2691         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2692         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2693       ],[
2694         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2695         ], [$LIBM])
2696     ],[
2697       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2698     ])
2699     VLC_RESTORE_FLAGS
2700 fi
2701
2702 dnl
2703 dnl DTS Coherent Acoustics decoder plugin
2704 dnl
2705 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2706
2707 dnl
2708 dnl  Flac plugin
2709 dnl
2710 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2711
2712 dnl
2713 dnl  Libmpeg2 plugin
2714 dnl
2715 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2716
2717 dnl
2718 dnl  Vorbis plugin
2719 dnl
2720 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2721
2722 dnl
2723 dnl  Tremor plugin
2724 dnl
2725 AC_ARG_ENABLE(tremor,
2726   [  --enable-tremor         Tremor decoder support (default disabled)])
2727 if test "${enable_tremor}" = "yes"
2728 then
2729   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2730     VLC_ADD_PLUGIN([tremor])
2731    ],[])
2732 fi
2733
2734 dnl
2735 dnl  Speex plugins
2736 dnl
2737 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2738 have_speexdsp="no"
2739 AS_IF([test "${enable_speex}" != "no"], [
2740   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2741     have_speexdsp="yes"
2742   ], [
2743     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2744   ])
2745 ])
2746 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2747
2748 dnl
2749 dnl  Opus plugin
2750 dnl
2751 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2752
2753 dnl
2754 dnl  theora decoder plugin
2755 dnl
2756 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2757
2758 dnl
2759 dnl  OggSpots decoder plugin
2760 dnl
2761 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2762
2763 dnl
2764 dnl  Daala decoder plugin
2765 dnl
2766 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2767
2768 dnl
2769 dnl  schroedinger decoder plugin (for dirac format video)
2770 dnl
2771 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2772
2773 dnl
2774 dnl  PNG decoder module
2775 dnl
2776 AC_ARG_ENABLE(png,
2777   [  --enable-png            PNG support (default enabled)])
2778 AS_IF([test "${enable_png}" != "no"], [
2779 AC_CHECK_HEADERS(png.h, [
2780   VLC_SAVE_FLAGS
2781   LDFLAGS="${LDFLAGS} -lz $LIBM"
2782   AC_CHECK_LIB(png, png_set_rows, [
2783     VLC_ADD_PLUGIN([png])
2784   ], [], [-lz $LIBM])
2785   VLC_RESTORE_FLAGS
2786   ])
2787 ])
2788
2789 dnl
2790 dnl  JPEG decoder module
2791 dnl
2792 AC_ARG_ENABLE(jpeg,
2793   [  --enable-jpeg           JPEG support (default enabled)])
2794 AS_IF([test "${enable_jpeg}" != "no"], [
2795 AC_CHECK_HEADERS(jpeglib.h, [
2796   VLC_ADD_PLUGIN([jpeg])
2797   ])
2798 ])
2799
2800 dnl
2801 dnl  BPG decoder module
2802 dnl
2803 AC_ARG_ENABLE(bpg,
2804   [  --enable-bpg           BPG support (default disabled)])
2805 AS_IF([test "${enable_bpg}" != "no"], [
2806 AC_CHECK_HEADERS(libbpg.h, [
2807   VLC_ADD_PLUGIN([bpg])
2808   ])
2809 ])
2810
2811 dnl
2812 dnl H262 encoder plugin (lib262)
2813 dnl
2814 AC_ARG_ENABLE(x262,
2815   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2816 if test "${enable_x262}" != "no"; then
2817     PKG_CHECK_MODULES(X262, x262, [
2818         VLC_ADD_PLUGIN([x262])
2819         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2820         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2821           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2822         ])
2823         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2824         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2825           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2826         fi
2827     ], [
2828        if test "${enable_x262}" = "yes"; then
2829         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2830        fi
2831     ])
2832 fi
2833
2834 dnl x265 encoder
2835 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2836
2837 dnl
2838 dnl H264 encoder plugin (10-bit lib264)
2839 dnl
2840 AC_ARG_ENABLE(x26410b,
2841   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2842 if test "${enable_x26410b}" != "no"; then
2843     PKG_CHECK_MODULES(X26410B, x26410b, [
2844         VLC_ADD_PLUGIN([x26410b])
2845         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2846         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2847           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2848         ])
2849         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2850         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2851           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2852         fi
2853     ], [
2854        if test "${enable_x26410b}" = "yes"; then
2855         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2856        fi
2857     ])
2858 fi
2859
2860
2861 dnl
2862 dnl H264 encoder plugin (using libx264)
2863 dnl
2864 AC_ARG_ENABLE(x264,
2865   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2866 if test "${enable_x264}" != "no"; then
2867       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2868         VLC_ADD_PLUGIN([x264])
2869         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2870
2871         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2872           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2873         ])
2874
2875         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2876         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2877           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2878         fi
2879       ],[
2880         if test "${enable_x264}" = "yes"; then
2881             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2882           fi
2883       ])
2884 fi
2885
2886 dnl
2887 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2888 dnl
2889 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2890
2891 dnl
2892 dnl libfluidsynth (MIDI synthetizer) plugin
2893 dnl
2894 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2895
2896 dnl
2897 dnl Teletext Modules
2898 dnl vbi decoder plugin (using libzbvi)
2899 dnl telx module
2900 dnl uncompatible
2901 dnl
2902 AC_ARG_ENABLE(zvbi,
2903   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2904                   libzvbi (default enabled)]))
2905 AC_ARG_ENABLE(telx,
2906   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2907                   zvbi) (default enabled if zvbi is absent)]))
2908
2909 AS_IF( [test "${enable_zvbi}" != "no"],[
2910     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2911         [
2912           VLC_ADD_PLUGIN([zvbi])
2913           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2914           AS_IF( [test "${enable_telx}" = "yes"],[
2915                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2916                   ])
2917         ],[
2918           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2919         ])
2920     ])
2921 AS_IF( [test "${enable_telx}" != "no" ],[
2922   VLC_ADD_PLUGIN([telx])
2923   ])
2924
2925 dnl
2926 dnl libass subtitle rendering module
2927 dnl
2928 AC_ARG_ENABLE(libass,
2929   [  --enable-libass         Subtitle support using libass (default enabled)])
2930 AS_IF( [test "${enable_libass}" != "no"], [
2931   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2932       [
2933         VLC_ADD_PLUGIN([libass])
2934
2935         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2936           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2937            VLC_ADD_LIBS([libass],[-lfontconfig])
2938        ])
2939       ],[
2940         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2941       ])
2942   ])
2943
2944 dnl
2945 dnl ARIB subtitles rendering module
2946 dnl
2947 AC_ARG_ENABLE(aribsub,
2948   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2949 AS_IF( [test "${enable_aribsub}" != "no" ],[
2950   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2951       have_aribb24="yes"
2952       VLC_ADD_PLUGIN([aribsub])
2953       VLC_ADD_LIBS([aribsub],[-laribb24])
2954       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2955     ],[
2956       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2957       have_aribb24="no"
2958   ])
2959 ])
2960 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2961
2962 dnl
2963 dnl ARIB B25
2964 dnl
2965 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2966
2967 dnl
2968 dnl  kate decoder plugin
2969 dnl
2970 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2971
2972 dnl
2973 dnl  tiger rendering for kate decoder plugin
2974 dnl
2975 AC_ARG_ENABLE(tiger,
2976 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2977 AS_IF([test "${enable_tiger}" != "no"], [
2978   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2979       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2980         AS_IF([test -n "${enable_tiger}"], [
2981           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2982         ])
2983   ])
2984 ])
2985
2986
2987 dnl
2988 dnl  Video plugins
2989 dnl
2990
2991 EXTEND_HELP_STRING([Video plugins:])
2992
2993 dnl
2994 dnl  OpenGL
2995 dnl
2996 PKG_CHECK_MODULES([EGL], [egl], [
2997   have_egl="yes"
2998 ], [
2999   have_egl="no"
3000 ])
3001 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3002
3003 have_gl="no"
3004 PKG_CHECK_MODULES([GL], [gl], [
3005   have_gl="yes"
3006 ], [
3007   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3008 #ifdef _WIN32
3009 # include <GL/glew.h>
3010 #endif
3011 #include <GL/gl.h>
3012 ]], [
3013     [int t0 = GL_TEXTURE0;]])
3014   ], [
3015     GL_CFLAGS=""
3016     have_gl="yes"
3017     AS_IF([test "${SYS}" != "mingw32"], [
3018       GL_LIBS="-lGL"
3019     ], [
3020       GL_LIBS="-lopengl32"
3021     ])
3022   ])
3023 ])
3024 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3025
3026 dnl OpenGL ES 2: depends on EGL 1.1
3027 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3028 dnl OpenGL ES 1: depends on EGL 1.0
3029 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3030
3031 dnl
3032 dnl  Xlib
3033 dnl
3034
3035 AC_PATH_XTRA()
3036 AC_CHECK_HEADERS(X11/Xlib.h)
3037
3038 dnl
3039 dnl  X C Bindings modules
3040 dnl
3041 AC_ARG_ENABLE(xcb,
3042   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3043   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3044     enable_xcb="yes"
3045   ], [
3046     enable_xcb="no"
3047   ])
3048 ])
3049 AC_ARG_ENABLE(xvideo,
3050   [  --enable-xvideo         XVideo support (default enabled)],, [
3051     enable_xvideo="$enable_xcb"
3052 ])
3053
3054 have_xcb="no"
3055 have_xcb_keysyms="no"
3056 have_xcb_randr="no"
3057 have_xcb_xvideo="no"
3058 AS_IF([test "${enable_xcb}" != "no"], [
3059   dnl libxcb
3060   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3061   have_xcb="yes"
3062   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3063   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3064   PKG_CHECK_MODULES(XPROTO, [xproto])
3065
3066   AS_IF([test "${enable_xvideo}" != "no"], [
3067     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3068   ])
3069
3070   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3071
3072   dnl xcb-utils
3073   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3074     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3075   ])
3076 ])
3077 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3078 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3079 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3080 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3081
3082
3083 dnl
3084 dnl VDPAU needs X11
3085 dnl
3086 AC_ARG_ENABLE(vdpau,
3087   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3088 have_vdpau="no"
3089 AS_IF([test "${enable_vdpau}" != "no"], [
3090   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3091     have_vdpau="yes"
3092     AS_IF([test "${no_x}" = "yes"], [
3093       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3094     ])
3095   ], [
3096     AS_IF([test -n "${enable_vdpau}"], [
3097       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3098     ])
3099   ])
3100 ])
3101 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3102
3103 have_avcodec_vdpau="no"
3104 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3105   case "${avfork}" in
3106     libav) av_vdpau_ver="55.26.0" ;;
3107     ffmpeg) av_vdpau_ver="55.42.100" ;;
3108   esac
3109   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3110     have_avcodec_vdpau="yes"
3111     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3112   ], [
3113     AS_IF([test -n "${enable_vdpau}"], [
3114       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3115     ], [
3116       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3117     ])
3118   ])
3119 ])
3120 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3121
3122
3123 dnl
3124 dnl  Wayland
3125 dnl
3126 AC_ARG_ENABLE(wayland,
3127   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3128 have_wayland="no"
3129 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3130
3131 AS_IF([test "${enable_wayland}" != "no"], [
3132   AC_MSG_CHECKING([for the Wayland scanner])
3133   AS_IF([test -z "$WAYLAND_SCANNER"], [
3134     PKG_CHECK_EXISTS([wayland-scanner], [
3135       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3136     ], [
3137       WAYLAND_SCANNER="wayland-scanner"
3138     ])
3139   ])
3140   AC_MSG_RESULT([$WAYLAND_SCANNER])
3141
3142   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3143     have_wayland="yes"
3144   ], [
3145     AS_IF([test -n "${enable_wayland}"], [
3146       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3147     ])
3148   ])
3149
3150   AS_IF([test "${have_egl}" = "yes"], [
3151     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3152       have_wayland_egl="yes"
3153     ], [
3154       AS_IF([test -n "${enable_wayland}"], [
3155         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3156       ])
3157     ])
3158   ])
3159 ])
3160 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3161 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3162
3163
3164 dnl
3165 dnl  SDL module
3166 dnl
3167 AC_ARG_ENABLE(sdl,
3168   [  --enable-sdl            SDL support (default enabled)])
3169 AC_ARG_ENABLE(sdl-image,
3170   [  --enable-sdl-image      SDL image support (default enabled)])
3171 if test "${enable_sdl}" != "no"
3172 then
3173    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3174       # SDL on Darwin is heavily patched and can only run SDL_image
3175       if test "${SYS}" != "darwin"; then
3176         VLC_ADD_PLUGIN([vout_sdl])
3177       fi
3178
3179       # SDL_image
3180       AS_IF([ test "${enable_sdl_image}" != "no"],[
3181         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3182           VLC_ADD_PLUGIN([sdl_image])],
3183           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3184           ])
3185       ])
3186    ],[
3187      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3188    ])
3189 fi
3190
3191 dnl
3192 dnl  freetype module
3193 dnl
3194 AC_ARG_ENABLE(freetype,
3195   [  --enable-freetype       freetype support   (default auto)])
3196 AC_ARG_ENABLE(fribidi,
3197   [  --enable-fribidi        fribidi support    (default auto)])
3198 AC_ARG_ENABLE(harfbuzz,
3199   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3200 AC_ARG_ENABLE(fontconfig,
3201   [  --enable-fontconfig     fontconfig support (default auto)])
3202
3203 AC_ARG_WITH([default-font],
3204     AS_HELP_STRING([--with-default-font=PATH],
3205         [Path to the default font]),
3206         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3207             "$withval", [Default font])])
3208 AC_ARG_WITH([default-monospace-font],
3209     AS_HELP_STRING([--with-default-monospace-font=PATH],
3210         [Path to the default font]),
3211         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3212             "$withval", [Default monospace font])])
3213
3214 AC_ARG_WITH([default-font-family],
3215     AS_HELP_STRING([--with-default-font-family=NAME],
3216         [Path to the default font family]),
3217         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3218             "$withval", [Default font family])])
3219 AC_ARG_WITH([default-monospace-font-family],
3220     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3221         [Path to the default font family]),
3222         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3223             "$withval", [Default monospace font family])])
3224
3225 have_freetype="no"
3226 have_fontconfig="no"
3227 have_fribidi="no"
3228 have_harfbuzz="no"
3229
3230 if test "${enable_freetype}" != "no"; then
3231    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3232       have_freetype="yes"
3233       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3234       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3235
3236       dnl fontconfig support
3237       if test "${SYS}" != "mingw32"; then
3238           if test "${enable_fontconfig}" != "no"; then
3239             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3240               have_fontconfig="yes"
3241             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3242           fi
3243       fi
3244
3245       dnl fribidi support
3246       if test "${enable_fribidi}" != "no"; then
3247         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3248           have_fribidi="yes"
3249           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3250           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3251         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3252       fi
3253
3254       dnl harfbuzz support
3255       if test "${have_fribidi}" != "no"; then
3256         if test "${enable_harfbuzz}" != "no"; then
3257           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3258             have_harfbuzz="yes"
3259             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3260             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3261           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3262         fi
3263       fi
3264   ],[
3265   AS_IF([test -n "${enable_freetype}"],[
3266     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3267     ])
3268   ])
3269 fi
3270
3271 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3272 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3273 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3274 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3275
3276 dnl
3277 dnl SAPI (text to Speech renderer for Windows)
3278 dnl
3279 AC_LANG_PUSH([C++])
3280 AC_CHECK_TYPES([ISpObjectToken],[
3281               have_sapi="yes"
3282             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3283               [#include <windows.h>
3284                #include <sapi.h>
3285                #include <sphelper.h>])
3286 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3287 AC_LANG_POP([C++])
3288
3289 dnl
3290 dnl  QuartzText vout module (iOS/Mac OS)
3291 dnl
3292 AC_ARG_ENABLE(macosx-quartztext,
3293   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3294 if test "x${enable_macosx_quartztext}" != "xno" &&
3295   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3296 then
3297   VLC_ADD_PLUGIN([quartztext])
3298 fi
3299
3300 dnl
3301 dnl  SVG module (text rendering and image decoding)
3302 dnl
3303 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3304 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3305
3306 dnl
3307 dnl  Windows DirectX module
3308 dnl
3309
3310 AC_ARG_ENABLE(directx,
3311   [AS_HELP_STRING([--enable-directx],
3312     [Microsoft DirectX support (default enabled on Windows)])],, [
3313   AS_IF([test "${SYS}" = "mingw32"], [
3314     enable_directx="yes"
3315   ], [
3316     enable_directx="no"
3317   ])
3318 ])
3319 have_directx="no"
3320 AS_IF([test "${enable_directx}" != "no"], [
3321   dnl DirectDraw
3322   AC_CHECK_HEADERS(ddraw.h, [
3323     have_directx="yes"
3324   ], [
3325     AC_MSG_ERROR([Cannot find DirectX headers!])
3326   ])
3327
3328   dnl OpenGL
3329   AC_CHECK_HEADERS(GL/wglew.h, [
3330     VLC_ADD_PLUGIN([glwin32])
3331   ],, [
3332     #include <windows.h>
3333     #include <GL/gl.h>
3334   ])
3335
3336   dnl Direct3D11
3337   AC_CHECK_HEADERS(d3d11.h, [
3338     VLC_ADD_PLUGIN([direct3d11])
3339   ])
3340
3341   dnl Direct3D9
3342   AC_CHECK_HEADERS(d3d9.h, [
3343     VLC_ADD_PLUGIN([direct3d9])
3344   ])
3345
3346   dnl Direct2D
3347   AC_CHECK_HEADERS(d2d1.h, [
3348     VLC_ADD_PLUGIN([direct2d])
3349   ])
3350 ])
3351 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3352
3353 dnl
3354 dnl  Linux framebuffer module
3355 dnl
3356 AC_CHECK_HEADER([linux/fb.h], [
3357   VLC_ADD_PLUGIN([fb])
3358 ])
3359
3360
3361 dnl
3362 dnl  DirectFB module
3363 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3364 dnl  TODO: support for static linking
3365 dnl
3366 AC_ARG_ENABLE(directfb,
3367   [  --enable-directfb       DirectFB support (default disabled)])
3368 AC_ARG_WITH(directfb,
3369   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3370
3371 if test "${enable_directfb}" = "yes"; then
3372     have_directfb="false"
3373     CPPFLAGS_mydirectfb=
3374     LIBS_mydirectfb=
3375     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3376         dnl Trying the given location
3377         VLC_SAVE_FLAGS
3378
3379         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3380         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3381
3382         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3383         LIBS="${LIBS} ${LIBS_new}"
3384
3385         dnl FIXME: too obscure
3386         AC_CHECK_HEADER([directfb.h], [
3387             AC_CHECK_LIB([direct],[direct_initialize], [
3388                 AC_CHECK_LIB([fusion], [fusion_enter], [
3389                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3390                 ], have_directfb="false")
3391             ], have_directfb="false")
3392         ], have_directfb="false")
3393
3394         VLC_RESTORE_FLAGS
3395
3396         if test "${have_directfb}" = "true"; then
3397             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3398             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3399         fi
3400     else
3401         dnl Look for directfb-config
3402         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3403         if test "${DIRECTFB_CONFIG}" != "no"; then
3404             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3405             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3406             have_directfb="true"
3407         else
3408             dnl Trying with pkg-config
3409             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3410                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3411                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3412                 have_directfb="true"
3413                 ], [have_directfb="false"])
3414         fi
3415     fi
3416     if test "${have_directfb}" = "true"; then
3417         VLC_ADD_PLUGIN([directfb])
3418         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3419         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3420     else
3421         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3422     fi
3423 fi
3424
3425 dnl
3426 dnl  AA plugin
3427 dnl
3428 AC_ARG_ENABLE(aa,
3429   [  --enable-aa             aalib output (default disabled)])
3430 if test "${enable_aa}" = "yes"
3431 then
3432   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3433   if test "${have_aa}" = "true"
3434   then
3435     VLC_ADD_PLUGIN([aa])
3436   fi
3437 fi
3438
3439 dnl
3440 dnl  libcaca plugin
3441 dnl
3442 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3443
3444 dnl
3445 dnl  OS/2 KVA plugin
3446 dnl
3447 AC_ARG_ENABLE(kva,
3448   [AS_HELP_STRING([--enable-kva],
3449     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3450   AS_IF([test "$SYS" = "os2"], [
3451     enable_kva="yes"
3452   ])
3453 ])
3454 have_kva="no"
3455 KVA_LIBS=""
3456 AS_IF([test "$enable_kva" != "no"], [
3457   AC_CHECK_HEADERS([kva.h], [
3458     have_kva="yes"
3459     AC_CHECK_LIB(kva, main, [
3460       KVA_LIBS="-lkva"
3461     ])
3462   ])
3463 ])
3464 AC_SUBST(KVA_LIBS)
3465 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3466
3467 dnl
3468 dnl MMAL plugin
3469 dnl
3470 AC_ARG_ENABLE(mmal,
3471   AS_HELP_STRING([--enable-mmal],
3472     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3473 if test "${enable_mmal}" != "no"; then
3474   VLC_SAVE_FLAGS
3475   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3476   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3477   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3478     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3479         have_mmal="yes"
3480         VLC_ADD_PLUGIN([mmal])
3481         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3482         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3483         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3484           AS_IF([test "${enable_mmal}" = "yes"],
3485             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3486             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3487           ],
3488         [])
3489     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3490       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3491       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3492   VLC_RESTORE_FLAGS
3493 fi
3494 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3495
3496 dnl
3497 dnl evas plugin
3498 dnl
3499 AC_ARG_ENABLE(evas,
3500   [AS_HELP_STRING([--enable-evas],
3501     [use evas output module (default disabled)])])
3502 have_evas="no"
3503 AS_IF([test "${enable_evas}" = "yes"], [
3504   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3505       have_evas="yes"
3506       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3507     ],[
3508     AS_IF([test "x${enable_evas}" != "x"], [
3509       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3510     ])
3511   ])
3512 ])
3513 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3514
3515 dnl
3516 dnl  Audio plugins
3517 dnl
3518
3519 EXTEND_HELP_STRING([Audio plugins:])
3520
3521 dnl
3522 dnl  Pulseaudio module
3523 dnl
3524 AC_ARG_ENABLE(pulse,
3525   [AS_HELP_STRING([--enable-pulse],
3526     [use the PulseAudio client library (default auto)])])
3527 have_pulse="no"
3528 AS_IF([test "${enable_pulse}" != "no"], [
3529   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3530     have_pulse="yes"
3531   ], [
3532     AS_IF([test "x${enable_pulse}" != "x"], [
3533       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3534     ])
3535   ])
3536 ])
3537 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3538
3539 dnl
3540 dnl  ALSA module
3541 dnl
3542 AC_ARG_ENABLE(alsa,
3543   [AS_HELP_STRING([--enable-alsa],
3544     [support the Advanced Linux Sound Architecture (default auto)])],, [
3545   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3546     enable_alsa="yes"
3547   ])
3548 ])
3549 have_alsa="no"
3550 AS_IF([test "${enable_alsa}" != "no"], [
3551   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3552     have_alsa="yes"
3553   ], [
3554     AS_IF([test "x${enable_alsa}" != "x"], [
3555       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3556     ])
3557   ])
3558 ])
3559 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3560
3561 dnl
3562 dnl  Open Sound System module
3563 dnl
3564 AC_ARG_ENABLE(oss,
3565   [AS_HELP_STRING([--enable-oss],
3566     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3567   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3568     enable_oss="no"
3569   ])
3570 ])
3571 have_oss="no"
3572 OSS_LIBS=""
3573 AS_IF([test "$enable_oss" != "no"], [
3574   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3575     have_oss="yes"
3576     AC_CHECK_LIB(ossaudio, main, [
3577       OSS_LIBS="-lossaudio"
3578     ])
3579   ])
3580 ])
3581 AC_SUBST(OSS_LIBS)
3582 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3583
3584 dnl
3585 dnl  OpenBSD sndio module
3586 dnl
3587 AC_ARG_ENABLE([sndio],
3588   [AS_HELP_STRING([--disable-sndio],
3589     [support the OpenBSD sndio (default auto)])],, [
3590   AS_IF([test "$SYS" = "openbsd"], [
3591     enable_sndio="yes"
3592   ])
3593 ])
3594 have_sndio="no"
3595 AS_IF([test "$enable_sndio" != "no"], [
3596   AC_CHECK_HEADER([sndio.h], [
3597     have_sndio="yes"
3598   ])
3599 ])
3600 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3601
3602 dnl
3603 dnl  Windows Audio Session plugin
3604 dnl
3605 AC_ARG_ENABLE([wasapi],
3606   [AS_HELP_STRING([--enable-wasapi],
3607     [use the Windows Audio Session API (default auto)])
3608 ])
3609 have_wasapi="no"
3610 AS_IF([test "$enable_wasapi" != "no"], [
3611   AC_CHECK_HEADER([audioclient.h], [
3612     have_wasapi="yes"
3613   ], [
3614     AS_IF([test "x${enable_wasapi}" != "x"], [
3615       AC_MSG_ERROR([Windows Audio Session API not found.])
3616     ])
3617   ])
3618 ])
3619 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3620
3621 dnl
3622 dnl  AudioQueue plugin
3623 dnl
3624 AC_ARG_ENABLE(audioqueue,
3625   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3626 if test "${enable_audioqueue}" = "yes"
3627 then
3628   VLC_ADD_PLUGIN([audioqueue])
3629 fi
3630
3631 dnl
3632 dnl  JACK modules
3633 dnl
3634 AC_ARG_ENABLE(jack,
3635   [AS_HELP_STRING([--disable-jack],
3636     [do not use jack (default auto)])])
3637 have_jack="no"
3638 AS_IF([test "${enable_jack}" != "no"], [
3639     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3640       [ have_jack=yes ],
3641       [
3642       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3643
3644       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3645       [ have_jack=yes ],
3646       [
3647       AS_IF([test -n "${enable_jack}"],
3648          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3649          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3650       ])
3651     ])
3652 ])
3653 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3654
3655 dnl
3656 dnl  OpenSLES Android
3657 dnl
3658 AC_ARG_ENABLE(opensles,
3659   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3660 if test "${HAVE_ANDROID}" = "1"; then
3661   if test "${enable_opensles}" = "yes"; then
3662       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3663         [ VLC_ADD_PLUGIN([opensles_android]) ],
3664         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3665   fi
3666 fi
3667
3668 dnl
3669 dnl  Tizen audio
3670 dnl
3671 AC_ARG_ENABLE(tizen_audio,
3672   [AS_HELP_STRING([--enable-tizen-audio],
3673     [Tizen audio module (default enabled on Tizen)])],, [
3674   AS_IF([test "$HAVE_TIZEN" = "1"], [
3675     enable_tizen_audio="yes"
3676   ])
3677 ])
3678 if test "${enable_tizen_audio}" = "yes"; then
3679   AC_CHECK_HEADERS(audio_io.h,
3680     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3681     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3682 fi
3683
3684 dnl
3685 dnl libsamplerate plugin
3686 dnl
3687 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3688
3689 dnl
3690 dnl  soxr module
3691 dnl
3692 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3693
3694 dnl
3695 dnl  OS/2 KAI plugin
3696 dnl
3697 AC_ARG_ENABLE(kai,
3698   [AS_HELP_STRING([--enable-kai],
3699     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3700   AS_IF([test "$SYS" = "os2"], [
3701     enable_kai="yes"
3702   ])
3703 ])
3704 have_kai="no"
3705 KAI_LIBS=""
3706 AS_IF([test "$enable_kai" != "no"], [
3707   AC_CHECK_HEADERS([kai.h], [
3708     have_kai="yes"
3709     AC_CHECK_LIB(kai, main, [
3710       KAI_LIBS="-lkai"
3711     ])
3712   ])
3713 ])
3714 AC_SUBST(KAI_LIBS)
3715 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3716
3717 dnl
3718 dnl  chromaprint audio track fingerprinter
3719 dnl
3720 m4_pushdef([libchromaprint_version], 0.6.0)
3721 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3722     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3723     AS_IF([test "${enable_chromaprint}" = "yes"],
3724         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3725         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3726          ),
3727     [(Chromaprint based audio fingerprinter)],[auto])
3728 m4_popdef([libchromaprint_version])
3729
3730 dnl
3731 dnl  Chromecast streaming support
3732 dnl
3733 m4_pushdef([protobuf_lite_version], 2.5.0)
3734 AC_ARG_VAR(PROTOC, [protobuf compiler])
3735 AC_CHECK_PROGS(PROTOC, protoc, no)
3736 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3737     AS_IF([test "x${PROTOC}" != "xno"], [
3738         build_chromecast="yes"
3739     ], [
3740     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3741     ])
3742 ], [
3743     AS_IF([test "${enable_chromecast}" = "yes"],
3744         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3745         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3746     )
3747     enable_chromecast="no"
3748 ], [(Chromecast streaming support)], [auto])
3749 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3750 m4_popdef([protobuf_lite_version])
3751
3752 dnl
3753 dnl  Interface plugins
3754 dnl
3755
3756 EXTEND_HELP_STRING([Interface plugins:])
3757
3758 dnl
3759 dnl QT
3760 dnl
3761 AC_ARG_ENABLE(qt, [
3762   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3763   AS_IF([test "${SYS}" = "darwin"], [
3764     enable_qt="no"
3765   ])
3766 ])
3767 AS_IF([test "${enable_qt}" != "no"], [
3768   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3769       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3770           VLC_ADD_LIBS([qt],[${QTX11_LIBS}])
3771           VLC_ADD_CXXFLAGS([qt],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3772           PKG_CHECK_MODULES([XI], [xi], [
3773             VLC_ADD_LIBS([qt], [${XI_LIBS}])
3774             VLC_ADD_CXXFLAGS([qt], [${XI_CFLAGS} -DHAVE_XI])
3775           ], [
3776             PKG_CHECK_EXISTS([Qt5Gui >= 5.5], [
3777               AC_MSG_ERROR([${XI_PKG_ERRORS}.])
3778             ], [
3779               AC_MSG_WARN([${XI_PKG_ERRORS}.])
3780             ])
3781           ])
3782       ],[
3783           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3784       ])
3785       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3786       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3787       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3788       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3789       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3790     ], [
3791       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3792         AS_IF([test -n "${enable_qt}"],[
3793           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3794         ],[
3795           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3796         ])
3797         enable_qt="no"
3798       ])
3799       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3800       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3801       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3802       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3803     ])
3804 ])
3805 AS_IF([test "${enable_qt}" != "no"], [
3806   VLC_ADD_PLUGIN([qt])
3807   ALIASES="${ALIASES} qvlc"
3808 ])
3809 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3810
3811 dnl
3812 dnl detect kde4-config patch (used for kde solids and kwallet).
3813 dnl
3814 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3815 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3816   KDE4_CONFIG="kde4-config"
3817 ])
3818
3819 dnl
3820 dnl Simple test for skins2 dependency
3821 dnl
3822 AS_IF([test "$enable_qt" = "no"], [
3823   AS_IF([test "${enable_skins2}" = "yes"], [
3824     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3825   ], [
3826     enable_skins2="no"
3827     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3828   ])
3829 ])
3830
3831 dnl
3832 dnl Skins2 module
3833 dnl
3834 AC_ARG_ENABLE(skins2,
3835   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3836 AS_IF([test "${enable_skins2}" != "no"], [
3837   have_skins_deps="yes"
3838
3839   dnl Win32
3840   AS_IF([test "${SYS}" = "mingw32"], [
3841     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3842     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3843   dnl MacOS
3844   ], [test "${SYS}" = "darwin"], [
3845     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3846     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3847   dnl OS/2
3848   ], [test "${SYS}" = "os2"], [
3849     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3850   dnl Linux/Unix
3851   ], [
3852     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3853     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3854     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3855     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3856     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3857   ])
3858
3859   dnl for All OSes
3860   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3861
3862   dnl we need freetype
3863   AS_IF([test "${have_freetype}" != "yes"], [
3864     have_skins_deps="no"
3865   ])
3866
3867   AS_IF([test "${have_skins_deps}" = "no"], [
3868     AS_IF([test "x${enable_skins2}" = "x"], [
3869       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3870     ], [
3871       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3872     ])
3873     enable_skins2="no"
3874   ], [
3875     VLC_ADD_PLUGIN([skins2])
3876     ALIASES="${ALIASES} svlc"
3877     enable_skins2="yes"
3878   ])
3879 ])
3880 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3881
3882 AC_ARG_ENABLE(libtar,
3883   [  --enable-libtar         libtar support for skins2 (default auto)])
3884 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3885   AC_CHECK_HEADERS(libtar.h, [
3886     VLC_ADD_LIBS([skins2],[-ltar])
3887   ])
3888 ])
3889
3890 dnl
3891 dnl  MacOS X gui module
3892 dnl
3893 AC_ARG_ENABLE(macosx,
3894   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3895 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3896 then
3897   VLC_ADD_PLUGIN([macosx])
3898
3899   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3900   then
3901     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3902   fi
3903 fi
3904 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3905
3906 dnl
3907 dnl  MacOS X sparkle update support
3908 dnl
3909 AC_ARG_ENABLE(sparkle,
3910   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3911 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3912 then
3913   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3914   then
3915     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3916   fi
3917
3918   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3919 fi
3920 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3921
3922
3923 dnl
3924 dnl  Minimal Mac OS X module
3925 dnl
3926 AC_ARG_ENABLE(minimal-macosx,
3927   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3928 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3929 then
3930   VLC_ADD_PLUGIN([minimal_macosx])
3931 fi
3932
3933 dnl
3934 dnl  VideoToolbox plugins
3935 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3936     VLC_ADD_PLUGIN([videotoolbox])
3937     VLC_ADD_PLUGIN([cvpx_i420])
3938   ])
3939
3940 dnl
3941 dnl  ncurses module
3942 dnl
3943 AC_ARG_ENABLE(ncurses,
3944 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3945 have_ncurses="no"
3946 AS_IF([test "${enable_ncurses}" != "no"] ,[
3947   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3948     have_ncurses="yes"
3949     ALIASES="${ALIASES} nvlc"
3950   ], [
3951     AS_IF([test -n "${enable_ncurses}"], [
3952       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3953     ])
3954   ])
3955 ])
3956 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3957
3958 dnl
3959 dnl  Lirc plugin
3960 dnl
3961 AC_ARG_ENABLE(lirc,
3962   [  --enable-lirc           lirc support (default disabled)])
3963 have_lirc="no"
3964 AS_IF([test "${enable_lirc}" = "yes"], [
3965   AC_CHECK_HEADER(lirc/lirc_client.h, [
3966     AC_CHECK_LIB(lirc_client, lirc_init, [
3967       have_lirc="true"
3968     ])
3969   ])
3970 ])
3971 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3972
3973 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3974 dnl
3975 dnl  goom visualization plugin
3976 dnl
3977 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3978
3979 dnl
3980 dnl libprojectM visualization plugin
3981 dnl
3982 AC_ARG_ENABLE(projectm,
3983   [  --enable-projectm       projectM visualization plugin (default enabled)])
3984 AS_IF([test "${enable_projectm}" != "no"],
3985   [
3986     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3987     [
3988       VLC_ADD_PLUGIN([projectm])
3989       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3990         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3991         [ AC_MSG_WARN( [Using libprojectM version 1] )
3992       ])
3993     ],[
3994       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3995     ])
3996   ])
3997
3998 dnl
3999 dnl Vovoid VSXu visualization plugin
4000 dnl
4001 AC_ARG_ENABLE(vsxu,
4002   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
4003 AS_IF([test "${enable_vsxu}" != "no"],
4004   [
4005     PKG_CHECK_MODULES(VSXU, libvsxu,
4006     [
4007       VLC_ADD_PLUGIN([vsxu])
4008     ],[
4009       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
4010     ])
4011   ])
4012
4013 EXTEND_HELP_STRING([Service Discovery plugins:])
4014 dnl
4015 dnl  Avahi-Zeroconf services discovery
4016 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4017
4018 dnl
4019 dnl  libudev services discovery
4020 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4021
4022 dnl
4023 dnl MTP devices services discovery
4024 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4025
4026 dnl
4027 dnl UPnP Plugin (Intel SDK)
4028 dnl
4029 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4030
4031 dnl
4032 dnl mDNS using libmicrodns
4033 dnl
4034 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4035
4036
4037 EXTEND_HELP_STRING([Misc options:])
4038
4039 dnl
4040 dnl  libxml2 module
4041 dnl
4042 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4043
4044
4045 dnl
4046 dnl libgcrypt
4047 dnl
4048 AC_ARG_ENABLE(libgcrypt,
4049   [  --disable-libgcrypt     gcrypt support (default enabled)])
4050 # require libgcrypt >= 1.6.0
4051 AS_IF([test "${enable_libgcrypt}" != "no"], [
4052   AC_TRY_COMPILE([
4053 #include <gcrypt.h>
4054 #if GCRYPT_VERSION_NUMBER < 0x010600
4055 #error
4056 #endif],
4057   [], [
4058     have_libgcrypt="yes"
4059     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4060     GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
4061     GCRYPT_LIBS="`libgcrypt-config --libs`"
4062   ], [
4063     AS_IF([test "${enable_libgcrypt}" == "yes"], [
4064       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4065     ])
4066   ])
4067 ])
4068
4069 AC_SUBST(GCRYPT_CFLAGS)
4070 AC_SUBST(GCRYPT_LIBS)
4071 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
4072
4073 dnl
4074 dnl TLS/SSL
4075 dnl
4076 AC_ARG_ENABLE(gnutls,
4077   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4078 AS_IF([test "${enable_gnutls}" != "no"], [
4079   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4080     VLC_ADD_PLUGIN([gnutls])
4081   ], [
4082     AS_IF([test -n "${enable_gnutls}"], [
4083       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4084     ])
4085   ])
4086 ])
4087
4088
4089 dnl
4090 dnl Taglib plugin
4091 dnl
4092 AC_ARG_ENABLE(taglib,
4093   [AS_HELP_STRING([--disable-taglib],
4094     [do not use TagLib (default enabled)])])
4095 AS_IF([test "${enable_taglib}" != "no"], [
4096   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4097     VLC_ADD_PLUGIN([taglib])
4098   ], [
4099     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4100 ])
4101
4102 dnl
4103 dnl  libsecret
4104 dnl
4105 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1], [use libsecret for keystore], [auto])
4106
4107 dnl
4108 dnl  kwallet
4109 dnl
4110 AC_ARG_ENABLE(kwallet,
4111   [AS_HELP_STRING([--enable-kwallet],
4112     [use KWallet for keystore (default auto)])])
4113 have_kwallet="no"
4114 KWALLET_CXXFLAGS=""
4115 KWALLET_LIBS=""
4116 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" \
4117          -a "${enable_qt}" != "no" -a "${KDE4_CONFIG}" != "no" \
4118          -a "${enable_kwallet}" != "no" ], [
4119   VLC_SAVE_FLAGS
4120   AC_LANG_PUSH([C++])
4121   KWALLET_CXXFLAGS="$QT_CFLAGS $CXXFLAGS_qt -I`$KDE4_CONFIG --path include`"
4122   CPPFLAGS="$CPPFLAGS $KWALLET_CXXFLAGS"
4123   AC_CHECK_HEADER([kwallet.h], [
4124     KWALLET_LIBS="$QT_LIBS -L`$KDE4_CONFIG --install lib` -lkdeui"
4125     LDFLAGS="$LDFLAGS $KWALLET_LIBS"
4126     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <kwallet.h>], [
4127 KWallet::Wallet::LocalWallet();
4128     ])], [
4129       have_kwallet="yes"
4130     ])
4131   ])
4132   AC_LANG_POP([C++])
4133   VLC_RESTORE_FLAGS
4134 ])
4135 AS_IF([test "$enable_kwallet" = "yes" -a "$have_kwallet" = "no" ], [
4136   AC_MSG_ERROR([KWallet headers or so not found])
4137 ])
4138 AC_SUBST(KWALLET_CXXFLAGS)
4139 AC_SUBST(KWALLET_LIBS)
4140 AM_CONDITIONAL([HAVE_KWALLET], [test "${have_kwallet}" = "yes"])
4141
4142 dnl
4143 dnl  Developers helper modules (should be hidden from configure help)
4144 dnl
4145 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4146 AS_IF([test "${enable_devtools}" != "no"], [
4147   VLC_ADD_PLUGIN([accesstweaks])
4148 ])
4149
4150 dnl
4151 dnl update checking system
4152 dnl
4153 AC_ARG_ENABLE(update-check,
4154   [  --enable-update-check   update checking system (default disabled)])
4155 if test "${enable_update_check}" = "yes"
4156 then
4157   if test "${have_libgcrypt}" != "yes"
4158   then
4159     AC_MSG_ERROR([libgcrypt is required for update checking system])
4160   fi
4161   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4162   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4163   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4164 fi
4165
4166 dnl
4167 dnl OS X notification plugin
4168 dnl
4169 AC_ARG_ENABLE(osx_notifications,
4170   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4171   [enable_osx_notifications=no])
4172 AS_IF([test "${enable_osx_notifications}" != "no"], [
4173     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4174       VLC_ADD_PLUGIN([osx_notifications])