Remove Direct2D module
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2016"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
42
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
59
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
69
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
77
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, mandatory)
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl
98 dnl  Check the operating system
99 dnl
100 HAVE_WIN64="0"
101 HAVE_IOS="0"
102 HAVE_OSX="0"
103 HAVE_TVOS="0"
104
105 case "${host_os}" in
106   "")
107     SYS=unknown
108     ;;
109   linux*)
110     SYS=linux
111     ;;
112   bsdi*)
113     SYS=bsdi
114     CFLAGS="${CFLAGS} -pthread"
115     ;;
116   freebsd*)
117     SYS=freebsd
118     CFLAGS="${CFLAGS} -pthread"
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
121     ac_cv_ld_z_defs=no
122     ;;
123   openbsd*)
124     SYS=openbsd
125     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
126     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
127     ;;
128   netbsd*)
129     SYS=netbsd
130     ;;
131   dragonfly*)
132     SYS=dragonfly
133     ;;
134   darwin*)
135
136     dnl Force gcc "-arch" flag
137     ARCH_flag=""
138     case "${host}" in
139       i?86*)
140         ARCH_flag="-arch i386"
141       ;;
142       ppc64*)
143         ARCH_flag="-arch ppc64"
144       ;;
145       ppc*)
146         ARCH_flag="-arch ppc"
147       ;;
148       x86_64*)
149         ARCH_flag="-arch x86_64"
150       ;;
151       arm*)
152         ac_cv_c_bigendian="no"
153         ac_cv_c_attribute_packed="no"
154       ;;
155     esac
156
157     SYS=darwin
158     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
159     CXX="${CXX} -stdlib=libc++ -std=c++11"
160     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
161     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
162     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
163     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
164     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
165     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
166
167     AC_EGREP_CPP(yes,
168             [#import <TargetConditionals.h>
169              #if TARGET_OS_IPHONE
170              yes
171              #endif],
172              [HAVE_IOS="1"],
173              [HAVE_OSX="1"])
174
175     AC_EGREP_CPP(yes,
176             [#import <TargetConditionals.h>
177              #if TARGET_OS_TV
178              yes
179              #endif],
180              [HAVE_TVOS="1"
181              HAVE_IOS="0"
182              HAVE_OSX="0"
183              ],)
184
185     dnl Allow binaries created on Lion to run on earlier releases
186     AC_EGREP_CPP(yes,
187            [#import <Cocoa/Cocoa.h>
188             #ifdef MAC_OS_X_VERSION_10_7
189             yes
190             #endif],
191             [AC_MSG_RESULT([yes])
192             AC_LIBOBJ([getdelim])
193             AC_LIBOBJ([strndup])
194             AC_LIBOBJ([strnlen])],)
195
196     dnl
197     dnl  Handle Mac OS X SDK flags
198     dnl
199     AC_ARG_WITH(macosx-sdk,
200       [AS_HELP_STRING([--with-macosx-sdk=DIR],
201         [compile using the SDK in DIR])])
202     if test "${with_macosx_sdk}" != "" ; then
203         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
204         CPP="${CPP} -isysroot ${with_macosx_sdk}"
205         CC="${CC} -isysroot ${with_macosx_sdk}"
206         CXX="${CXX} -isysroot ${with_macosx_sdk}"
207         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
208         LD="${LD} -syslibroot ${with_macosx_sdk}"
209     fi
210     AC_ARG_WITH(macosx-version-min,
211       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
212         [compile for Mac OS X VERSION and above])])
213     if test "${with_macosx_version_min}" != "" ; then
214         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
215         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
216         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
217         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
218         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
219     fi
220     ;;
221   *mingw32* | *cygwin* | *wince* | *mingwce*)
222     dnl Force libtool to not link to (shared) libgcc_s when detecting C++ dependencies
223     dnl When doing this test with -static-libgcc it will link on (static) libgcc_eh
224     CXXFLAGS="${CXXFLAGS} -static-libgcc"
225     AC_CHECK_TOOL(WINDRES, windres, :)
226     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
227     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
228     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
229     AH_TOP([#endif])
230     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
231     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
232     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
233     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
234     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
235     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
236     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
237     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
238     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
239     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
240     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
241
242     case "${host_os}" in
243       *mingw32*)
244         SYS=mingw32
245         ;;
246       *cygwin*)
247         dnl Check if we are using the mno-cygwin mode in which case we are
248         dnl actually dealing with a mingw32 compiler.
249         AC_EGREP_CPP(yes,
250             [#ifdef _WIN32
251              yes
252              #endif],
253             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
254         ;;
255     esac
256
257     if test "${SYS}" = "mingw32"; then
258         # DEP, ASLR, NO SEH
259         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
260
261         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
262         ac_default_prefix="`pwd`/_win32"
263         DESTDIR="`pwd`/_win32/"
264
265         dnl
266         dnl NSIS/MSI Installer prefix and WIN64
267         dnl
268         case "${host}" in
269             amd64*|x86_64*)
270                 HAVE_WIN64="1"
271                 WINDOWS_ARCH="x64"
272                 PROGRAMFILES="PROGRAMFILES64"
273                 LDFLAGS="${LDFLAGS} -Wl,--high-entropy-va -Wl,--image-base,0x140000000"
274             ;;
275             *)
276                 WINDOWS_ARCH="x86"
277                 PROGRAMFILES="PROGRAMFILES"
278             ;;
279         esac
280         AC_SUBST(WINDOWS_ARCH)
281         AC_SUBST(PROGRAMFILES)
282
283     fi
284     ;;
285   *nto*)
286     SYS=nto
287     ;;
288   solaris*)
289     SYS=solaris
290     ;;
291   hpux*)
292     SYS=hpux
293     ;;
294   *os2*)
295     SYS=os2
296     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
297     AC_LIBOBJ([freeaddrinfo])
298     AC_LIBOBJ([gai_strerror])
299     ;;
300   *)
301     SYS="${host_os}"
302     ;;
303 esac
304
305 dnl WinRT
306 AC_ARG_ENABLE(winstore_app,
307      AS_HELP_STRING([--enable-winstore-app],
308                     [Build targetted for Windows Store apps (default disabled)]))
309
310 vlc_winstore_app=0
311 AS_IF([test "${SYS}" = "mingw32"],[
312   LIBCOM="-lole32"
313   AS_IF([test "${enable_winstore_app}" = "yes"], [
314     vlc_winstore_app=1
315     LIBCOM=""
316      VLC_ADD_LIBS([libvlccore], [-lruntimeobject])
317      AC_LIBOBJ([gai_strerror])
318     ],[
319      VLC_ADD_LIBS([libvlccore],[-lwinmm])
320     ])
321   AC_SUBST(LIBCOM)
322   ])
323 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
324
325 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
326 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
327
328 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
329 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
330 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
331 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
332
333 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
334 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1") dnl Only used for the packaging
335 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
336 AM_CONDITIONAL([HAVE_WIN32_DESKTOP], [test "${SYS}" = "mingw32" -a "$vlc_winstore_app" = "0"])
337
338 dnl
339 dnl Sadly autoconf does not think about testing foo.exe when ask to test
340 dnl for program foo on win32
341 case "${build_os}" in
342     cygwin|msys|mingw32)
343         ac_executable_extensions=".exe"
344     ;;
345     os2*)
346         BUILDEXEEXT=".exe"
347     ;;
348     *)
349     ;;
350 esac
351 AC_SUBST(BUILDEXEEXT)
352
353 dnl Android is linux, but a bit different
354 AS_IF([test "$SYS" = linux],[
355     AC_MSG_CHECKING([for an Android system])
356     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
357         [[#ifndef __ANDROID__
358          # error Not Android
359          #endif
360         ]],[[;]])
361     ],[
362       HAVE_ANDROID="1"
363       AC_MSG_RESULT([yes])
364     ],[
365       AC_MSG_RESULT([no])
366     ])
367 ])
368 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
369
370 dnl Tizen (minimum SDK version: 2.3)
371 AS_IF([test "$SYS" = linux],[
372     AC_MSG_CHECKING([for Tizen])
373     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
374         [[#include <tizen.h>
375         ]],[[;]])
376     ],[
377       HAVE_TIZEN="1"
378       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
379       AC_MSG_RESULT([yes])
380     ],[
381       AC_MSG_RESULT([no])
382     ])
383 ])
384 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
385
386 dnl
387 dnl  Check for the contrib directory
388 dnl
389 AC_ARG_WITH(contrib,
390   [AS_HELP_STRING([--with-contrib[=DIR]],
391     [search for 3rd party libraries in DIR/include and DIR/lib])
392 ])
393 AC_MSG_CHECKING([for 3rd party libraries path])
394 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
395   CONTRIB_DIR="${srcdir}/contrib/${host}"
396   AS_IF([test ! -d "${CONTRIB_DIR}"], [
397     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
398     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
399     AS_IF([test ! -d "${CONTRIB_DIR}"], [
400       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
401       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
402       AS_IF([test ! -d "${CONTRIB_DIR}"], [
403         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
404         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
405         AS_IF([test ! -d "${CONTRIB_DIR}"], [
406           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
407           CONTRIB_DIR=""
408           AC_MSG_RESULT([not found])
409         ])
410       ])
411     ])
412   ])
413 ], [
414   AS_IF([test "${with_contrib}" != "no"], [
415     CONTRIB_DIR="${with_contrib}"
416   ], [
417     CONTRIB_DIR=""
418     AC_MSG_RESULT([disabled])
419   ])
420 ])
421 AS_IF([test -n "${CONTRIB_DIR}"], [
422   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
423     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
424   ], [
425     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
426     CONTRIB_DIR=""
427     AC_MSG_RESULT([not usable])
428   ])
429
430 ])
431 AS_IF([test -n "${CONTRIB_DIR}"], [
432   AC_MSG_RESULT([${CONTRIB_DIR}])
433   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
434   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
435   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
436   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
437   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
438   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
439
440   AS_IF([test -z "$LUAC"], [
441     dnl Old contribs mixed cross-tools and cross-compiled executables
442     AS_IF([test -x "${CONTRIB_DIR}/bin/luac"], [
443       LUAC="${CONTRIB_DIR}/bin/luac"
444     ])
445
446     dnl Newer contribs follow usual name space rules
447     AS_IF([test -x "${CONTRIB_DIR}/../bin/${host_alias}-luac"], [
448       LUAC="${CONTRIB_DIR}/../bin/${host_alias}-luac"
449     ])
450   ])
451
452   AS_IF([test "${SYS}" = "darwin"], [
453     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
454     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
455   ])
456 ], [
457   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
458     AC_MSG_ERROR([Third party libraries not found!])
459   ])
460 ])
461 AC_SUBST(CONTRIB_DIR)
462
463 dnl Add extras/tools to the PATH
464 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
465 AS_IF([test -d "${TOOLS_DIR}"], [
466     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
467     export PATH="${TOOLS_DIR}":$PATH
468 ])
469
470 dnl
471 dnl  Libtool
472 dnl  It's very bad, but our former custom system was worst
473 dnl  -- Courmisch
474 dnl
475
476 dnl override platform specific check for dependent libraries
477 dnl otherwise libtool linking of shared libraries will
478 dnl fail on anything other than pass_all.
479 AC_CACHE_VAL(lt_cv_deplibs_check_method,
480     [lt_cv_deplibs_check_method=pass_all])
481
482 LT_INIT([dlopen win32-dll shared disable-static])
483 LT_LANG([C++])
484 LT_LANG([Windows Resource])
485
486 DOLT
487
488 lt_cv_deplibs_check_method=pass_all
489
490 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
491   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
492 ])
493
494 dnl
495 dnl Gettext stuff
496 dnl
497 AM_GNU_GETTEXT_VERSION([0.19.8])
498 AM_GNU_GETTEXT([external], [need-formatstring-macros])
499
500 dnl
501 dnl Iconv stuff
502 dnl
503 AM_ICONV
504
505 dnl
506 dnl checks for mingw
507 AS_IF([test "${SYS}" = "mingw32"], [
508
509 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
510 #if !defined(__MINGW32__)
511 # error Not compiling with mingw
512 #endif
513     ])], [
514
515 dnl Check for broken versions of mingw-runtime compatability library
516     AC_MSG_CHECKING(for broken mingw-runtime)
517     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
518 #include <_mingw.h>
519 #if defined(__MINGW64_VERSION_MAJOR)
520 # if __MINGW64_VERSION_MAJOR < 3
521 #  error Attempting to use mingw-runtime with broken vsnprintf support
522 # endif
523 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
524 # error Attempting to use mingw-runtime with broken vsnprintf support
525 #endif
526     ])], [
527         AC_MSG_RESULT([ok])
528     ], [
529         AC_MSG_RESULT([present])
530         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
531     ])
532
533     dnl force use of mingw provided c99 *printf over msvcrt
534     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
535
536     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
537     VLC_ADD_LDFLAGS([vlc],[-mwindows])
538
539     dnl Check for the need to include the mingwex lib for mingw32
540     VLC_SAVE_FLAGS
541     AC_CHECK_LIB(mingwex,opendir,
542         AC_CHECK_LIB(mingw32,opendir,,
543             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
544     )
545     VLC_RESTORE_FLAGS
546     ], [
547         AC_MSG_RESULT([Not compiling with mingw])
548     ])
549
550     dnl Check for fnative-struct or mms-bitfields support for mingw32
551     VLC_SAVE_FLAGS
552     CFLAGS="${CFLAGS} -mms-bitfields"
553     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
554     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
555         [ac_cv_c_mms_bitfields],
556         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
557     if test "${ac_cv_c_mms_bitfields}" = "no"; then
558         VLC_RESTORE_FLAGS
559         CFLAGS="${CFLAGS} -fnative-struct"
560         CXXFLAGS="${CXXFLAGS} -fnative-struct"
561         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
562             [ac_cv_c_fnative_struct],
563             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
564         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
565     fi
566 ])
567
568
569 dnl
570 dnl Buggy glibc prevention. Purposedly not cached.
571 dnl See sourceware.org bugs 5058 and 5443.
572 dnl Ubuntu alone has 20 bug numbers for this...
573 dnl
574 AC_MSG_CHECKING(for buggy GNU/libc versions)
575 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
576 #include <limits.h>
577 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
578   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
579 # error GNU/libc with dcgettext killer bug!
580 #endif
581 ])], [
582   AC_MSG_RESULT([not present])
583 ], [
584   AC_MSG_RESULT([found])
585   AS_IF([test "x${enable_nls}" != "xno"], [
586     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
587 work-around for this. Check with your distribution vendor on how to update the
588 glibc run-time. Alternatively, build with --disable-nls.])
589   ])
590 ])
591
592 dnl Plugin compilation stuff
593
594 VLC_LIBRARY_SUFFIX
595
596 dnl Check for system libs needed
597 need_libc=false
598
599 dnl Check for usual libc functions
600 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime tdestroy uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
601 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv memrchr nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tfind timegm timespec_get strverscmp])
602 AC_REPLACE_FUNCS([gettimeofday])
603 AC_CHECK_FUNC(fdatasync,,
604   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
605 ])
606
607 VLC_REPLACE_DECL([realpath], [#include <stdlib.h>])
608
609 dnl mingw64 implements those as static inline, not functions with C linkage
610 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
611 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
612 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
613 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
614
615 dnl C11 static_assert()
616 AC_MSG_CHECKING([for static_assert in assert.h])
617 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
618 static_assert(1, "The impossible happened.");
619 ])], [
620   AC_MSG_RESULT([yes])
621   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
622 ], [
623   AC_MSG_RESULT([no])
624 ])
625
626 # Windows CE does not have strcoll()
627 AC_FUNC_STRCOLL
628
629 dnl Check for non-standard system calls
630 case "$SYS" in
631   "linux")
632     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity recvmmsg])
633     ;;
634   "mingw32")
635     AC_CHECK_FUNCS([_lock_file])
636     ;;
637 esac
638
639 AH_BOTTOM([#include <vlc_fixups.h>])
640
641 dnl Check for struct pollfd
642 AC_CHECK_TYPES([struct pollfd],,,
643 [#include <sys/types.h>
644 #if HAVE_POLL
645 # include <poll.h>
646 #elif defined (_WIN32)
647 # include <winsock2.h>
648 #endif
649 ])
650
651 dnl Check for struct timespec
652 AC_CHECK_TYPES([struct timespec],,,
653 [#include <time.h>])
654
655 dnl Check for max_align_t
656 AC_CHECK_TYPES([max_align_t],,,
657 [#include <stddef.h>])
658
659 dnl Checks for socket stuff
660 VLC_SAVE_FLAGS
661 SOCKET_LIBS=""
662 AC_SEARCH_LIBS(connect, [socket], [
663   AS_IF([test "$ac_cv_search_connect" != "none required"], [
664     SOCKET_LIBS="$ac_cv_search_connect"
665   ])
666 ], [
667   AS_IF([test "${SYS}" = "mingw32"], [
668     SOCKET_LIBS="-lws2_32"
669   ])
670 ])
671
672 AC_SEARCH_LIBS([inet_pton], [nsl], [
673  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
674     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
675   ])
676 ],, [${SOCKET_LIBS}])
677
678 LIBS="${LIBS} ${SOCKET_LIBS}"
679 AC_LINK_IFELSE([
680     AC_LANG_PROGRAM([#ifdef _WIN32
681         # if _WIN32_WINNT < 0x600
682         #  error Needs vista+
683         # endif
684         #include <ws2tcpip.h>
685         #else
686         #include <sys/socket.h>
687         #include <arpa/inet.h>
688         #endif], [
689         char dst[[sizeof(struct in_addr)]];
690         inet_pton(AF_INET, "127.0.0.1", dst);
691     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
692 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
693 VLC_RESTORE_FLAGS
694 AC_SUBST(SOCKET_LIBS)
695
696 dnl Check for socklen_t
697 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
698 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
699 ac_cv_type_socklen_t,
700 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
701 [#include <sys/types.h>
702 #ifdef _WIN32
703 # include <winsock2.h>
704 # include <ws2tcpip.h>
705 #else
706 # include <sys/socket.h>
707 #endif]], [[socklen_t len; len = 0;]])],
708 ac_cv_type_socklen_t=yes,
709 ac_cv_type_socklen_t=no)])
710 AS_IF([test "$ac_cv_type_socklen_t" = no],
711  [AC_DEFINE(socklen_t, int)])
712
713 dnl Check for struct sockaddr_storage
714 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
715 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
716 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
717   [AC_TRY_COMPILE(
718     [#include <sys/types.h>
719      #if defined( _WIN32 )
720      # include <winsock2.h>
721      #else
722      # include <sys/socket.h>
723      #endif], [struct sockaddr_storage addr;],
724      ac_cv_struct_sockaddr_storage=yes,
725      ac_cv_struct_sockaddr_storage=no)])
726 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
727   AC_DEFINE(sockaddr_storage, sockaddr)
728   AC_DEFINE(ss_family, sa_family)
729 ])
730
731 dnl FreeBSD has a gnugetopt library for this:
732 GNUGETOPT_LIBS=""
733 AC_CHECK_FUNC(getopt_long,, [
734   AC_CHECK_LIB([gnugetopt],[getopt_long], [
735     GNUGETOPT_LIBS="-lgnugetopt"
736   ])
737 ])
738 AC_SUBST(GNUGETOPT_LIBS)
739
740 AC_CHECK_LIB(m,cos,[
741   LIBM="-lm"
742 ], [
743   LIBM=""
744 ])
745 AC_SUBST(LIBM)
746
747 AC_CHECK_LIB(m,lrintf, [
748   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
749   VLC_ADD_LIBS([skins2],[-lm])
750 ])
751 AC_CHECK_LIB(m,nanf,
752   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
753 )
754 AC_CHECK_LIB(m,sincos, [
755   AC_DEFINE(HAVE_SINCOS, 1, [Define to 1 if you have the sincos function.])
756 ], [
757   AC_LIBOBJ([sincos])
758 ])
759
760 dnl Check for dynamic plugins
761 LIBDL=""
762 have_dynamic_objects="no"
763 VLC_SAVE_FLAGS
764 AC_SEARCH_LIBS(dlsym, [dl svld], [
765   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
766     LIBDL="$ac_cv_search_dlsym"
767   ])
768   have_dynamic_objects="yes"
769 ])
770 VLC_RESTORE_FLAGS
771
772 # Windows
773 AS_IF([test "${SYS}" = "mingw32"], [
774   LIBDL=""
775   have_dynamic_objects="yes" #assume we can use shared objects
776 ])
777
778 AS_IF([test "${enable_shared}" = "no"], [
779   have_dynamic_objects=no
780 ])
781 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
782
783 AC_SUBST(LIBDL)
784
785 dnl Check for thread library
786 LIBPTHREAD=""
787 AS_IF([test "${SYS}" != "mingw32"], [
788   VLC_SAVE_FLAGS
789   LIBS=""
790   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
791     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
792       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
793     ])
794   ])
795   VLC_RESTORE_FLAGS
796 ])
797 AC_SUBST(LIBPTHREAD)
798
799 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
800   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
801     LIBRT="$ac_cv_search_clock_nanosleep"
802   ])
803 ], [
804   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
805     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
806       LIBRT="$ac_cv_search_nanosleep"
807     ])
808   ])
809 ])
810 AC_SUBST(LIBRT)
811
812 dnl
813 dnl Check for headers
814 dnl
815
816 dnl  POSIX
817 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h sys/uio.h])
818 AC_CHECK_HEADERS([net/if.h], [], [],
819 [
820 #include <sys/types.h>
821 #include <sys/socket.h>
822 ])
823 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
824 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
825
826 dnl  BSD
827 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
828
829 dnl  GNU/Linux
830 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
831
832 dnl  MacOS
833 AC_CHECK_HEADERS([xlocale.h])
834
835 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
836 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
837 AC_CHECK_TYPE(ssize_t,, [
838   AC_DEFINE(ssize_t, int)
839 ])
840
841 dnl It seems that autoconf detects pkg-config only during the first
842 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
843 dnl it is nested within a conditional block, so it was not working right.
844 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
845 AC_ARG_VAR(PKG_CONFIG_PATH,
846        [Paths where to find .pc not at the default location])
847 PKG_PROG_PKG_CONFIG()
848
849 dnl On some OS we need static linking
850 AS_IF([test -n "${PKG_CONFIG}" ],[
851     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
852         PKG_CONFIG="${PKG_CONFIG} --static"
853     ])
854 ])
855
856
857 dnl
858 dnl Check for zlib.h and -lz along with system -lminizip if available
859 dnl
860 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
861 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
862 if test "${have_zlib}" = "yes"
863 then
864   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
865   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
866     AC_CHECK_HEADERS([unzip.h], [
867       have_minizip=yes
868       MINIZIP_LIBS="-lminizip -lz"
869     ], [
870       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
871       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
872       have_minizip=no
873     ])
874   ])
875   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
876   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
877 fi
878 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
879
880
881 dnl
882 dnl Domain name i18n support via GNU libidn
883 dnl
884 PKG_CHECK_MODULES([IDN], [libidn], [
885   have_libidn="yes"
886   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
887 ], [
888   have_libidn="no"
889 ])
890
891
892 dnl Check for dbus
893 AC_ARG_ENABLE(dbus,
894   [AS_HELP_STRING([--enable-dbus],
895     [compile D-Bus message bus support (default enabled)])])
896 have_dbus="no"
897 AS_IF([test "${enable_dbus}" != "no"], [
898   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
899     have_dbus="yes"
900   ], [
901     AS_IF([test -n "${enable_dbus}"], [
902       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
903     ], [
904       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
905     ])
906   ])
907 ])
908 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
909
910
911 dnl Check for systemd
912 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
913   have_systemd="yes"
914 ], [
915   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
916 ])
917 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
918
919
920 dnl Check for ntohl, etc.
921 VLC_SAVE_FLAGS
922 CFLAGS="${CFLAGS} -Wall -Werror"
923 AC_CACHE_CHECK([for ntohl in sys/param.h],
924     [ac_cv_c_ntohl_sys_param_h],
925     [     AC_TRY_COMPILE([#include <sys/param.h>],
926         [int meuh; ntohl(meuh);],
927         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
928 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
929     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
930 fi
931 VLC_RESTORE_FLAGS
932
933 EXTEND_HELP_STRING([Optimization options:])
934 dnl
935 dnl  Compiler warnings
936 dnl
937
938 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
939 RDC_PROG_CC_FLAGS([-pipe])
940 AC_LANG_PUSH([C++])
941 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
942 AC_LANG_POP([C++])
943
944 dnl
945 dnl  Debugging mode
946 dnl
947 AC_ARG_ENABLE(debug,
948   [AS_HELP_STRING([--enable-debug],
949     [build with run-time assertions (default disabled)])],,
950   [enable_debug="no"])
951 AH_TEMPLATE(NDEBUG,
952             [Define to 1 if debug code should NOT be compiled])
953 AS_IF([test "${enable_debug}" != "no"], [
954   AC_CHECK_HEADERS([valgrind/valgrind.h])
955 ], [
956   AC_DEFINE(NDEBUG)
957 ])
958
959 dnl
960 dnl  Profiling
961 dnl
962 AC_ARG_ENABLE(gprof,
963   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
964   [enable_gprof="no"])
965 AS_IF([test "${enable_gprof}" != "no"], [
966   CFLAGS="${CFLAGS} -pg"
967   CXXFLAGS="${CXXFLAGS} -pg"
968   OBJCFLAGS="${OBJCFLAGS} -pg"
969   LDFLAGS="${LDFLAGS} -pg"
970 ])
971
972 AC_ARG_ENABLE(cprof,
973   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
974   [enable_cprof="no"])
975 AS_IF([test "${enable_gprof}" != "no"], [
976   CFLAGS="${CFLAGS} -finstrument-functions"
977   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
978   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
979   LDFLAGS="${LDFLAGS} -finstrument-functions"
980 ])
981
982 dnl
983 dnl  Test coverage
984 dnl
985 AC_ARG_ENABLE(coverage,
986   [AS_HELP_STRING([--enable-coverage],
987     [build for test coverage (default disabled)])],,
988   [enable_coverage="no"])
989 AS_IF([test "${enable_coverage}" != "no"], [
990   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
991   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
992   LDFLAGS="-lgcov ${LDFLAGS}"
993 ])
994
995 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
996   VLC_SAVE_FLAGS
997   CFLAGS="${CFLAGS} -fvisibility=hidden"
998   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
999   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
1000   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
1001                  [ac_cv_c_visibility_hidden], [
1002     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1003       ac_cv_c_visibility_hidden=yes
1004     ], [
1005       ac_cv_c_visibility_hidden=no
1006     ])
1007   ])
1008   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
1009 ])
1010
1011
1012 dnl
1013 dnl  Enable/disable optimizations
1014 dnl
1015 AC_ARG_ENABLE(optimizations,
1016   [AS_HELP_STRING([--disable-optimizations],
1017     [disable compiler optimizations (default enabled)])],,
1018   [enable_optimizations="yes"])
1019
1020 dnl Check for various optimization flags
1021 AS_IF([test "${enable_optimizations}" != "no"], [
1022
1023   dnl -O3 only in production builds
1024   AS_IF([test "${enable_debug}" = "no"], [
1025     VLC_SAVE_FLAGS
1026     CFLAGS="${CFLAGS} -O3"
1027     CXXFLAGS="${CXXFLAGS} -O3"
1028     OBJCFLAGS="${OBJCFLAGS} -O3"
1029     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
1030       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1031         ac_cv_c_o3=yes
1032       ], [
1033         ac_cv_c_o3=no
1034       ])
1035     ])
1036     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1037   ])
1038
1039   dnl Check for fast maths
1040   RDC_PROG_CC_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1041   AC_LANG_PUSH(C++)
1042   RDC_PROG_CXX_FFLAGS([no-math-errno unsafe-math-optimizations no-rounding-math no-signaling-nans cx-limited-range])
1043   AC_LANG_POP
1044
1045 AH_BOTTOM([
1046 #if defined(_MSC_VER) && !defined(__clang__)
1047 # pragma fenv_access(off)
1048 # pragma fp_contract(on)
1049 #elif defined(__GNUC__)
1050 /* Not supported so far */
1051 #else
1052 # pragma STDC FENV_ACCESS OFF
1053 # pragma STDC FP_CONTRACT ON
1054 #endif
1055 ])
1056
1057   dnl Check for -funroll-loops
1058   VLC_SAVE_FLAGS
1059   CFLAGS="${CFLAGS} -funroll-loops"
1060   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1061   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1062   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1063     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1064       ac_cv_c_unroll_loops=yes
1065     ], [
1066       ac_cv_c_unroll_loops=no
1067     ])
1068   ])
1069   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1070
1071   AS_IF([test "$enable_debug" = "no"], [
1072     dnl Check for -fomit-frame-pointer
1073     VLC_SAVE_FLAGS
1074     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1075     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1076     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1077     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1078       [ac_cv_c_omit_frame_pointer], [
1079       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1080         ac_cv_c_omit_frame_pointer=yes
1081       ], [
1082         ac_cv_c_omit_frame_pointer=no
1083       ])
1084     ])
1085     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1086   ])
1087 ])
1088
1089 VLC_SAVE_FLAGS
1090 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1091 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1092   AC_TRY_LINK([],, [
1093     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1094   ], [
1095     ac_cv_ld_bsymbolic=""
1096   ])
1097 ])
1098 VLC_RESTORE_FLAGS
1099 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1100 AC_SUBST(SYMBOLIC_LDFLAGS)
1101
1102 VLC_SAVE_FLAGS
1103 LDFLAGS="${LDFLAGS} -Wl,-z,defs"
1104 AC_CACHE_CHECK([if linker supports -z,defs], [ac_cv_ld_z_defs], [
1105   AC_TRY_LINK([],, [
1106     ac_cv_ld_z_defs="yes"
1107   ], [
1108     ac_cv_ld_z_defs="no"
1109   ])
1110 ])
1111 AS_IF([test "${ac_cv_ld_z_defs}" = "no"], [VLC_RESTORE_FLAGS])
1112
1113 dnl Checks for __attribute__(aligned()) directive
1114 VLC_SAVE_FLAGS
1115 CFLAGS="${CFLAGS} -Werror"
1116 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1117     [ac_cv_c_attribute_aligned],
1118     [ac_cv_c_attribute_aligned=0
1119     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1120         AC_TRY_COMPILE([],
1121         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1122         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1123     done])
1124 VLC_RESTORE_FLAGS
1125 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1126     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1127         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1128 fi
1129
1130 dnl Check for __attribute__((packed))
1131 AC_CACHE_CHECK([for __attribute__((packed))],
1132   [ac_cv_c_attribute_packed],
1133   [ac_cv_c_attribute_packed=no
1134    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1135                     [ac_cv_c_attribute_packed=yes])])
1136 if test "${ac_cv_c_attribute_packed}" != "no"; then
1137   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1138 fi
1139
1140 dnl
1141 dnl  Check the CPU
1142 dnl
1143 case "${host_cpu}" in
1144   "")
1145     ARCH=unknown
1146     ;;
1147   *)
1148     ARCH="${host_cpu}"
1149     ;;
1150 esac
1151
1152 dnl Check for backtrace() support
1153 AC_CHECK_HEADERS(execinfo.h)
1154 AC_CHECK_FUNCS(backtrace)
1155
1156 dnl
1157 dnl  default modules
1158 dnl
1159 ALIASES="${ALIASES} cvlc rvlc"
1160
1161 dnl
1162 dnl  Accelerated modules
1163 dnl
1164
1165 dnl  Check for fully working MMX intrinsics
1166 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1167 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1168 AC_ARG_ENABLE(mmx,
1169   [AS_HELP_STRING([--disable-mmx],
1170     [disable MMX optimizations (default auto)])],,[
1171   case "${host_cpu}" in
1172     i?86|x86_64)
1173       enable_mmx="yes"
1174       ;;
1175     *)
1176       enable_mmx="no"
1177       ;;
1178   esac
1179 ])
1180 have_mmx="no"
1181 have_mmxext="no"
1182 AS_IF([test "${enable_mmx}" != "no"], [
1183   ARCH="${ARCH} mmx"
1184   VLC_SAVE_FLAGS
1185   CFLAGS="${CFLAGS} -mmmx"
1186   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1187     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1188 [#include <mmintrin.h>
1189 #include <stdint.h>
1190 uint64_t frobzor;]], [
1191 [__m64 a, b, c;
1192 a = b = c = (__m64)frobzor;
1193 a = _mm_slli_pi16(a, 3);
1194 a = _mm_adds_pi16(a, b);
1195 c = _mm_srli_pi16(c, 8);
1196 c = _mm_slli_pi16(c, 3);
1197 b = _mm_adds_pi16(b, c);
1198 a = _mm_unpacklo_pi8(a, b);
1199 frobzor = (uint64_t)a;]])], [
1200       ac_cv_c_mmx_intrinsics=yes
1201     ], [
1202       ac_cv_c_mmx_intrinsics=no
1203     ])
1204   ])
1205   VLC_RESTORE_FLAGS
1206   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1207     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1208   ])
1209
1210   VLC_SAVE_FLAGS
1211   CFLAGS="${CFLAGS} -mmmx"
1212   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1213     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1214 void *p;
1215 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1216 ]])
1217     ], [
1218       ac_cv_mmx_inline=yes
1219     ], [
1220       ac_cv_mmx_inline=no
1221     ])
1222   ])
1223   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1224     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1225     have_mmx="yes"
1226   ])
1227
1228   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1229                  [ac_cv_mmxext_inline], [
1230     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1231 void *p;
1232 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1233 ]])
1234     ], [
1235       ac_cv_mmxext_inline=yes
1236     ], [
1237       ac_cv_mmxext_inline=no
1238     ])
1239   ])
1240   VLC_RESTORE_FLAGS
1241   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1242     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1243     have_mmxext="yes"
1244   ])
1245 ])
1246 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1247 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1248
1249 dnl  Check for fully workin SSE2 intrinsics
1250 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1251 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1252 AC_ARG_ENABLE(sse,
1253   [AS_HELP_STRING([--disable-sse],
1254     [disable SSE (1-4) optimizations (default auto)])],, [
1255   case "${host_cpu}" in
1256     i?86|x86_64)
1257       enable_sse=yes
1258       ;;
1259     *)
1260       enable_sse=no
1261       ;;
1262   esac
1263 ])
1264 have_sse2="no"
1265 AS_IF([test "${enable_sse}" != "no"], [
1266   ARCH="${ARCH} sse sse2"
1267
1268   VLC_SAVE_FLAGS
1269   CFLAGS="${CFLAGS} -msse2"
1270   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1271     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1272 [#include <emmintrin.h>
1273 #include <stdint.h>
1274 uint64_t frobzor;]], [
1275 [__m128i a, b, c;
1276 a = b = c = _mm_set1_epi64((__m64)frobzor);
1277 a = _mm_slli_epi16(a, 3);
1278 a = _mm_adds_epi16(a, b);
1279 c = _mm_srli_epi16(c, 8);
1280 c = _mm_slli_epi16(c, 3);
1281 b = _mm_adds_epi16(b, c);
1282 a = _mm_unpacklo_epi8(a, b);
1283 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1284       ac_cv_c_sse2_intrinsics=yes
1285     ], [
1286       ac_cv_c_sse2_intrinsics=no
1287     ])
1288   ])
1289   VLC_RESTORE_FLAGS
1290   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1291     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1292   ])
1293
1294   VLC_SAVE_FLAGS
1295   CFLAGS="${CFLAGS} -msse"
1296   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1297     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1298 void *p;
1299 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1300 ]])
1301     ], [
1302       ac_cv_sse_inline=yes
1303     ], [
1304       ac_cv_sse_inline=no
1305     ])
1306   ])
1307
1308   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1309     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1310   ])
1311
1312   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1313     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1314 void *p;
1315 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1316 ]])
1317     ], [
1318       ac_cv_sse2_inline=yes
1319     ], [
1320       ac_cv_sse2_inline=no
1321     ])
1322   ])
1323   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1324     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1325     have_sse2="yes"
1326   ])
1327
1328   # SSE3
1329   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1330     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1331 void *p;
1332 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1333 ]])
1334     ], [
1335       ac_cv_sse3_inline=yes
1336     ], [
1337       ac_cv_sse3_inline=no
1338     ])
1339   ])
1340
1341   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1342     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1343   # SSSE3
1344   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1345     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1346 void *p;
1347 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1348 ]])
1349     ], [
1350       ac_cv_ssse3_inline=yes
1351     ], [
1352       ac_cv_ssse3_inline=no
1353     ])
1354   ])
1355
1356   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1357     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1358
1359   # SSE4.1
1360   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1361                  [ac_cv_sse4_1_inline], [
1362     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1363 void *p;
1364 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1365 ]])
1366     ], [
1367       ac_cv_sse4_1_inline=yes
1368     ], [
1369       ac_cv_sse4_1_inline=no
1370     ])
1371   ])
1372
1373   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1374     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1375
1376   # SSE4.2
1377   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1378                  [ac_cv_sse4_2_inline], [
1379     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1380 void *p;
1381 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1382 ]])
1383     ], [
1384       ac_cv_sse4_2_inline=yes
1385     ], [
1386       ac_cv_sse4_2_inline=no
1387     ])
1388   ])
1389
1390   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1391     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1392
1393   # SSE4A
1394   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1395     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1396 void *p;
1397 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1398 ]])
1399     ], [
1400       ac_cv_sse4a_inline=yes
1401     ], [
1402       ac_cv_sse4a_inline=no
1403     ])
1404   ])
1405   VLC_RESTORE_FLAGS
1406   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1407     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1408 ])
1409 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1410
1411 VLC_SAVE_FLAGS
1412 CFLAGS="${CFLAGS} -mmmx"
1413 have_3dnow="no"
1414 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1415   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1416 void *p;
1417 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1418 ]])
1419   ], [
1420     ac_cv_3dnow_inline=yes
1421   ], [
1422     ac_cv_3dnow_inline=no
1423   ])
1424 ])
1425 VLC_RESTORE_FLAGS
1426 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1427   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1428             [Define to 1 if 3D Now! inline assembly is available.])
1429   have_3dnow="yes"
1430 ])
1431 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1432
1433
1434 AC_ARG_ENABLE(neon,
1435   [AS_HELP_STRING([--disable-neon],
1436     [disable NEON optimizations (default auto)])],, [
1437   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1438 ])
1439 AS_IF([test "${enable_neon}" != "no"], [
1440   VLC_SAVE_FLAGS
1441   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1442   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1443     AC_COMPILE_IFELSE([
1444       AC_LANG_PROGRAM(,[[
1445 asm volatile("vqmovun.s64 d0, q1":::"d0");
1446 ]])
1447     ], [
1448       ac_cv_arm_neon="yes"
1449     ], [
1450       ac_cv_arm_neon="no"
1451     ])
1452   ])
1453   VLC_RESTORE_FLAGS
1454 ])
1455 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1456
1457 AC_ARG_ENABLE(arm64,
1458   [AS_HELP_STRING([--disable-arm64],
1459     [disable arm 64-bit optimizations (default auto)])],, [
1460   AS_IF([test "${host_cpu}" = "aarch64"], [enable_arm64="yes"] ,[enable_arm64="no"])
1461 ])
1462 AS_IF([test "${enable_arm64}" != "no"], [
1463   AC_CACHE_CHECK([if $CCAS groks ARM 64 SIMD assembly], [ac_cv_arm64], [
1464     AC_COMPILE_IFELSE([
1465       AC_LANG_PROGRAM(,[[
1466 asm volatile("uhadd v0.8b, v0.8b, v1.8b":::"v0");
1467 ]])
1468     ], [
1469       ac_cv_arm64="yes"
1470     ], [
1471       ac_cv_arm64="no"
1472     ])
1473   ])
1474 ])
1475 AM_CONDITIONAL(HAVE_ARM64, [test "${ac_cv_arm64}" = "yes"])
1476
1477
1478 AC_ARG_ENABLE(altivec,
1479   [AS_HELP_STRING([--disable-altivec],
1480     [disable AltiVec optimizations (default auto)])],, [
1481   AS_CASE("${host_cpu}", [powerpc*],
1482         [enable_altivec=yes], [enable_altivec=no])
1483 ])
1484 have_altivec="no"
1485 ALTIVEC_CFLAGS=""
1486 AS_IF([test "${enable_altivec}" = "yes"], [
1487   ARCH="${ARCH} altivec";
1488   VLC_SAVE_FLAGS
1489   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1490     [ac_cv_altivec_inline],
1491     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1492          ac_cv_altivec_inline="yes",
1493          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1494           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1495             [ac_cv_altivec_inline="-Wa,-maltivec"],
1496             ac_cv_altivec_inline=no)
1497          ])])
1498   VLC_RESTORE_FLAGS
1499   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1500     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1501               [Define to 1 if AltiVec inline assembly is available.])
1502     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1503       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1504       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1505     ])
1506     have_altivec="yes"
1507   ])
1508
1509   VLC_SAVE_FLAGS
1510   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1511   [ac_cv_c_altivec], [
1512     CFLAGS="${CFLAGS} -maltivec"
1513     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1514 [#include <altivec.h>]], [
1515 [vec_ld(0, (unsigned char *)0);]])], [
1516       ac_cv_c_altivec="-maltivec"
1517     ], [
1518       ac_cv_c_altivec="no"
1519     ])
1520   ])
1521   VLC_RESTORE_FLAGS
1522   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1523     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1524     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1525     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1526     ALTIVEC_CFLAGS="$ALTIVEC_CFLAGS ${ac_cv_c_altivec}"
1527     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec}])
1528     have_altivec="yes"
1529   ])
1530   AC_CHECK_HEADERS(altivec.h)
1531
1532   VLC_SAVE_FLAGS
1533   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1534   AC_CACHE_CHECK([if linker needs -framework vecLib],
1535     [ac_cv_ld_altivec],
1536     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1537   VLC_RESTORE_FLAGS
1538   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1539     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1540   ])
1541 ])
1542 AC_SUBST(ALTIVEC_CFLAGS)
1543 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1544
1545 dnl
1546 dnl  Memory usage
1547 dnl
1548 AC_ARG_ENABLE(optimize-memory,
1549   [AS_HELP_STRING([--enable-optimize-memory],
1550     [optimize memory usage over performance])])
1551 if test "${enable_optimize_memory}" = "yes"; then
1552   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1553 fi
1554
1555 dnl
1556 dnl Allow running as root (useful for people running on embedded platforms)
1557 dnl
1558 AC_ARG_ENABLE(run-as-root,
1559   [AS_HELP_STRING([--enable-run-as-root],
1560     [allow running VLC as root (default disabled)])])
1561 AS_IF([test "${enable_run_as_root}" = "yes"],[
1562     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1563               [Define to 1 to allow running VLC as root (uid 0).])
1564 ])
1565
1566 dnl
1567 dnl Stream output
1568 dnl
1569 AC_ARG_ENABLE(sout,
1570   [AS_HELP_STRING([--disable-sout],
1571     [disable streaming output (default enabled)])])
1572 AS_IF([test "${enable_sout}" != "no"], [
1573   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1574 ])
1575 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1576
1577 dnl Lua modules
1578 AC_ARG_ENABLE(lua,
1579   [AS_HELP_STRING([--disable-lua],
1580     [disable LUA scripting support (default enabled)])])
1581 if test "${enable_lua}" != "no"
1582 then
1583   PKG_CHECK_MODULES(LUA, lua5.2,
1584     [ have_lua=yes ],
1585     [
1586     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua 5.1 instead])
1587
1588     PKG_CHECK_MODULES(LUA, lua5.1,
1589       [ have_lua=yes ],
1590       [
1591       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying lua >= 5.1 instead])
1592       PKG_CHECK_MODULES(LUA, lua >= 5.1,
1593         [ have_lua=yes ],
1594         [
1595           AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1596           have_lua=yes
1597           AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h],
1598             [],
1599             [ have_lua=no ] )
1600           AC_CHECK_LIB(  lua5.2 , luaL_newstate,
1601             [LUA_LIBS="-llua5.2"],
1602           AC_CHECK_LIB( lua5.1 , luaL_newstate,
1603             [LUA_LIBS="-llua5.1"],
1604             AC_CHECK_LIB( lua51 , luaL_newstate,
1605               [LUA_LIBS="-llua51"],
1606               AC_CHECK_LIB( lua , luaL_newstate,
1607                 [LUA_LIBS="-llua"],
1608                 [ have_lua=no
1609                 ], [-lm])
1610             )))
1611         ])
1612       ])
1613     ])
1614   if test "x${have_lua}" != "xyes" ;  then
1615       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1616   fi
1617   AC_ARG_VAR([LUAC], [LUA byte compiler])
1618   AS_IF([test -z "$LUAC"], [
1619      AC_CHECK_TOOL(LUAC, [luac], [false])
1620   ])
1621   AS_IF([test "${LUAC}" = "false"], [
1622     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1623   ])
1624   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1625     AC_MSG_ERROR([You need 32-bits luac when using lua from contrib.])
1626   ])
1627 fi
1628 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1629
1630
1631 dnl
1632 dnl HTTP daemon
1633 dnl
1634 AC_ARG_ENABLE(httpd,
1635   [AS_HELP_STRING([--disable-httpd],
1636     [disable the built-in HTTP server (default enabled)])])
1637 if test "${enable_httpd}" != "no"
1638 then
1639   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1640 fi
1641 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1642
1643
1644 dnl
1645 dnl VideoLAN manager
1646 dnl
1647 AC_ARG_ENABLE(vlm,
1648   [AS_HELP_STRING([--disable-vlm],
1649     [disable the stream manager (default enabled)])],,
1650   [enable_vlm="${enable_sout}"])
1651 AS_IF([test "${enable_vlm}" != "no"], [
1652   AS_IF([test "${enable_sout}" = "no"], [
1653     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1654   ])
1655   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1656 ])
1657 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1658
1659
1660 dnl
1661 dnl Addons manager storage and repositories modules
1662 dnl
1663 AC_ARG_ENABLE(addonmanagermodules,
1664   [AS_HELP_STRING([--disable-addonmanagermodules],
1665     [disable the addons manager modules (default enabled)])])
1666 if test "${enable_addonmanagermodules}" != "no"
1667 then
1668   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1669 fi
1670 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1671
1672
1673 dnl
1674 dnl  Input plugins
1675 dnl
1676
1677 EXTEND_HELP_STRING([Input plugins:])
1678
1679 dnl
1680 dnl  libarchive access module
1681 dnl
1682 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1683
1684 dnl
1685 dnl  live555 input
1686 dnl
1687 AC_ARG_ENABLE(live555,
1688   [AS_HELP_STRING([--enable-live555],
1689     [enable RTSP input through live555 (default enabled)])])
1690
1691 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1692   PKG_CHECK_MODULES(LIVE555, live555, [
1693     VLC_ADD_PLUGIN([live555])
1694     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1695     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1696   ], [
1697     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1698
1699     AC_LANG_PUSH(C++)
1700     VLC_SAVE_FLAGS
1701
1702     dnl detect include paths
1703     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1704       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1705     ], [
1706       AS_IF([test "${SYS}" != "os2"], [
1707         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1708         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1709       ], [
1710         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1711         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1712         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1713       ])
1714     ])
1715
1716     dnl CPP Flags
1717     AS_IF([test "${SYS}" = "solaris"], [
1718       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1719     ])
1720     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1721     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1722
1723     dnl version check
1724     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1725       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1726 [#include <liveMedia_version.hh>
1727 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1728 # error BOOM
1729 #endif]])
1730       ], [
1731         ac_cv_live555="yes"
1732       ], [
1733         ac_cv_live555="no"
1734       ])
1735     ])
1736
1737     AS_IF([test "$ac_cv_live555" = "no"], [
1738       AC_MSG_WARN([live555 is missing or its installed version is too old:
1739 Version 2011.12.23 or later is required to proceed.
1740 You can get an updated one from http://www.live555.com/liveMedia .])
1741       AS_IF([test -n "${enable_live555}"], [
1742         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1743       ])
1744     ], [
1745       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1746       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1747       AS_IF([test "${SYS}" = "mingw32"], [
1748         # add ws2_32 for closesocket, select, recv
1749         other_libs="$other_libs -lws2_32"
1750       ])
1751
1752       dnl We need to check for pic because live555 don't provide shared libs
1753       dnl and we want to build a plugins so we need -fPIC on some arch.
1754       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1755       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1756       AC_CHECK_LIB(liveMedia_pic, main, [
1757         VLC_ADD_PLUGIN([live555])
1758         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1759       ],[
1760         AC_CHECK_LIB(liveMedia, main, [
1761           VLC_ADD_PLUGIN([live555])
1762           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1763         ],[],[${other_libs}])
1764       ],[${other_libs_pic}])
1765     ])
1766     VLC_RESTORE_FLAGS
1767     AC_LANG_POP(C++)
1768   ])
1769 ])
1770
1771 dnl
1772 dnl IIDC and DV FireWire input modules
1773 dnl
1774 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1775 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1776
1777 dnl
1778 dnl - linsys modules: access module check for libzvbi
1779 dnl
1780 AC_ARG_ENABLE(linsys,
1781   [AS_HELP_STRING([--enable-linsys],
1782     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1783 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1784   VLC_ADD_PLUGIN([linsys_hdsdi])
1785   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1786     VLC_ADD_PLUGIN([linsys_sdi])
1787   ], [
1788     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1789   ])
1790 ])
1791
1792 dnl
1793 dnl dvdread module: check for libdvdread
1794 dnl
1795 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1796
1797 dnl
1798 dnl libdvdnav plugin
1799 dnl
1800 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1801 AS_IF([test "${enable_dvdnav}" != "no"], [
1802   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1803     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1804       AC_MSG_RESULT(yes)
1805       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1806       ],[
1807       AC_MSG_RESULT(no)
1808     ])
1809 ])
1810
1811 dnl
1812 dnl  Blu-ray Disc Support with libbluray
1813 dnl
1814 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1815
1816 dnl
1817 dnl  OpenCV wrapper and example filters
1818 dnl
1819 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1820
1821
1822 dnl
1823 dnl  libsmbclient plugin
1824 dnl
1825 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1826 AS_IF([test "${SYS}" = "mingw32" -a "${enable_smbclient}" != "no"], [ VLC_ADD_PLUGIN([smb]) ])
1827
1828 dnl
1829 dnl  liBDSM access module
1830 dnl
1831 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1832
1833 dnl
1834 dnl sftp access support
1835 dnl
1836 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1837
1838 dnl
1839 dnl nfs access support
1840 dnl
1841 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs >= 1.10.0], (support nfs protocol via libnfs), [auto])
1842
1843 dnl
1844 dnl  Video4Linux 2
1845 dnl
1846 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1847   [disable Video4Linux version 2 (default auto)])])
1848 have_v4l2="no"
1849 AS_IF([test "$enable_v4l2" != "no"], [
1850   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1851     have_v4l2="yes"
1852   ])
1853 ])
1854 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1855
1856 dnl
1857 dnl special access module for Blackmagic SDI cards
1858 dnl
1859 AC_ARG_ENABLE(decklink,
1860   [AS_HELP_STRING([--disable-decklink],
1861     [disable Blackmagic DeckLink SDI input (default auto)])])
1862 AC_ARG_WITH(decklink_sdk,
1863   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1864     [                        location of Blackmagic DeckLink SDI SDK])])
1865 have_decklink=no
1866 if test "${enable_decklink}" != "no"
1867 then
1868   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1869   then
1870     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1871   fi
1872   VLC_SAVE_FLAGS
1873   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1874   AC_LANG_PUSH(C++)
1875   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1876       have_decklink=yes
1877   ], [
1878       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1879   ])
1880   AC_LANG_POP(C++)
1881   VLC_RESTORE_FLAGS
1882 fi
1883 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1884
1885
1886 dnl
1887 dnl  Built-in CD-DA and VCD module
1888 dnl
1889 AC_ARG_ENABLE(vcd,
1890   [AS_HELP_STRING([--disable-vcd],
1891     [disable built-in VCD and CD-DA support (default enabled)])])
1892
1893 AC_ARG_ENABLE(libcddb,
1894   [AS_HELP_STRING([--disable-libcddb],
1895     [disable CDDB for Audio CD (default enabled)])])
1896
1897 if test "${enable_vcd}" != "no"
1898 then
1899   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1900   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1901     AC_MSG_RESULT(yes)
1902     VLC_ADD_PLUGIN([vcd cdda])
1903   ],[
1904     AC_MSG_RESULT(no)
1905   ])
1906
1907   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1908   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1909     AC_MSG_RESULT(yes)
1910     VLC_ADD_PLUGIN([vcd cdda])
1911     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1912   ],[
1913     AC_MSG_RESULT(no)
1914   ])
1915
1916   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1917   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1918     AC_MSG_RESULT(yes)
1919     VLC_ADD_PLUGIN([vcd cdda])
1920     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1921   ],[
1922     AC_MSG_RESULT(no)
1923   ])
1924
1925   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1926   then
1927     VLC_ADD_PLUGIN([vcd cdda])
1928   fi
1929
1930   if test "$enable_libcddb" != "no"; then
1931     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1932       HAVE_LIBCDDB=yes
1933       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1934       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1935       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1936       ],:
1937       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1938       HAVE_LIBCDDB=no])
1939   fi
1940 fi
1941
1942 dnl
1943 dnl Linux DVB
1944 dnl
1945 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1946   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1947 [#include <linux/dvb/version.h>
1948 #if (DVB_API_VERSION < 5)
1949 # error Linux DVB API v3.2 and older are not supported.
1950 #endif
1951 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1952 # error Linux DVB API v5.0 is unsupported. Please update.
1953 #endif
1954 ]])], [
1955   ac_cv_linux_dvb_5_1=yes
1956 ], [
1957   ac_cv_linux_dvb_5_1=no
1958 ])])
1959 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1960
1961 dnl
1962 dnl  Screen capture module
1963 dnl
1964 AC_ARG_ENABLE(screen,
1965   [AS_HELP_STRING([--enable-screen],
1966     [disable screen capture (default enabled)])])
1967 if test "${enable_screen}" != "no"; then
1968   if test "${SYS}" = "darwin"; then
1969     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1970       VLC_ADD_PLUGIN([screen])
1971     ])
1972   fi
1973 fi
1974 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1975
1976 dnl
1977 dnl  VNC/RFB access module
1978 dnl
1979 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1980
1981 dnl  RDP/Remote Desktop access module
1982 dnl
1983 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1984
1985 dnl
1986 dnl  Real RTSP plugin
1987 dnl
1988 AC_ARG_ENABLE(realrtsp,
1989   [  --enable-realrtsp       Real RTSP module (default disabled)])
1990 if test "${enable_realrtsp}" = "yes"; then
1991   VLC_ADD_PLUGIN([access_realrtsp])
1992 fi
1993
1994 dnl
1995 dnl MacOS eyeTV
1996 AC_ARG_ENABLE(macosx-eyetv,
1997   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1998 if test "x${enable_macosx_eyetv}" != "xno" &&
1999   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
2000 then
2001   VLC_ADD_PLUGIN([access_eyetv])
2002 fi
2003
2004 dnl
2005 dnl QTKit
2006 AC_ARG_ENABLE(macosx-qtkit,
2007   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X <= v10.11)])
2008 if test "x${enable_macosx_qtkit}" != "xno" &&
2009   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
2010 then
2011   AC_CHECK_HEADERS(QTKit/QTKit.h, [
2012       VLC_ADD_PLUGIN([qtsound])
2013     ])
2014 fi
2015
2016 dnl
2017 dnl AVFoundation
2018 AC_SUBST(have_avfoundation, ["no"])
2019 AC_ARG_ENABLE(macosx-avfoundation,
2020   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
2021 if test "x${enable_macosx_avfoundation}" != "xno" &&
2022   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
2023 then
2024   SAVED_LIBS="${LIBS}"
2025   LIBS="-framework AVFoundation"
2026   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
2027   LIBS="${SAVED_LIBS}"
2028   if test "${have_avfoundation}" != "no"
2029   then
2030     VLC_ADD_PLUGIN([avcapture])
2031   fi
2032 fi
2033 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
2034
2035 dnl
2036 dnl  DCP plugin (using asdcplib)
2037 dnl
2038 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
2039 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
2040
2041 dnl
2042 dnl  Demux plugins
2043 dnl
2044
2045 EXTEND_HELP_STRING([Mux/Demux plugins:])
2046
2047 dnl
2048 dnl  libdvbpsi check for ts mux/demux
2049 dnl
2050 have_dvbpsi="no"
2051 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
2052 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
2053
2054
2055 dnl
2056 dnl  GME demux plugin
2057 dnl
2058 AC_ARG_ENABLE(gme,
2059   [AS_HELP_STRING([--enable-gme],
2060     [use Game Music Emu (default auto)])])
2061 AS_IF([test "${enable_gme}" != "no"], [
2062   AC_CHECK_HEADER([gme/gme.h], [
2063     VLC_ADD_LIBS([gme], [-lgme])
2064     VLC_ADD_PLUGIN([gme])
2065   ], [
2066     AS_IF([test "x${enable_gme}" != "x"], [
2067       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2068     ])
2069   ])
2070 ])
2071
2072
2073 dnl
2074 dnl  SIDPlay plugin
2075 dnl
2076 AC_ARG_ENABLE(sid,
2077     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2078 AS_IF([test "${enable_sid}" != "no"], [
2079     PKG_CHECK_MODULES(SID, [libsidplay2], [
2080         AC_LANG_PUSH(C++)
2081         oldCPPFLAGS="$CPPFLAGS"
2082         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2083         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2084             VLC_ADD_PLUGIN([sid])
2085             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2086             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2087         ], [
2088             AS_IF([test -n "${enable_sid}"],
2089                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2090                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2091                 )
2092         ])
2093         CPPFLAGS="$oldCPPFLAGS"
2094         AC_LANG_POP(C++)
2095     ], [
2096         AS_IF([test "x${enable_sid}" = "xyes"],
2097             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2098             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2099             )
2100     ])
2101 ])
2102
2103
2104 dnl
2105 dnl  ogg demux plugin
2106 dnl
2107 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2108 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2109     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2110 ],[true])
2111 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2112 if test "${enable_sout}" != "no"; then
2113 dnl Check for libshout
2114     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2115 fi
2116
2117 dnl
2118 dnl  matroska demux plugin
2119 dnl
2120 PKG_ENABLE_MODULES_VLC([MATROSKA], [mkv], [libebml libmatroska], [MKV format support], [auto])
2121
2122 dnl
2123 dnl  modplug demux plugin
2124 dnl
2125 AC_ARG_ENABLE(mod,
2126   [AS_HELP_STRING([--disable-mod],
2127     [do not use libmodplug (default auto)])])
2128 if test "${enable_mod}" != "no" ; then
2129     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2130           VLC_ADD_PLUGIN([mod])
2131           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2132           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2133           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2134     ],[
2135        AS_IF([test -n "${enable_mod}"],
2136          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2137          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2138     ])
2139 fi
2140
2141 dnl
2142 dnl  mpc demux plugin
2143 dnl
2144 AC_ARG_ENABLE(mpc,
2145   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2146 if test "${enable_mpc}" != "no"
2147 then
2148   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2149     VLC_ADD_PLUGIN([mpc])
2150     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2151     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2152     VLC_ADD_PLUGIN([mpc])
2153     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2154 fi
2155
2156 dnl
2157 dnl  Codec plugins
2158 dnl
2159
2160 EXTEND_HELP_STRING([Codec plugins:])
2161
2162 dnl
2163 dnl wmafixed plugin
2164 dnl
2165 AC_ARG_ENABLE(wma-fixed,
2166   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2167 if test "${enable_wma_fixed}" = "yes"
2168 then
2169   VLC_ADD_PLUGIN([wma_fixed])
2170 fi
2171
2172 dnl
2173 dnl shine encoder plugin
2174 dnl
2175 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2176
2177
2178 dnl
2179 dnl openmax il codec plugin
2180 dnl
2181 AC_ARG_ENABLE(omxil,
2182   [  --enable-omxil          openmax il codec module (default disabled)])
2183 if test "${enable_omxil}" = "yes"
2184 then
2185   VLC_ADD_PLUGIN([omxil])
2186 fi
2187
2188 dnl
2189 dnl openmax il vout plugin
2190 dnl
2191 AC_ARG_ENABLE(omxil-vout,
2192   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2193 if test "${enable_omxil_vout}" = "yes"
2194 then
2195   VLC_ADD_PLUGIN([omxil_vout])
2196 fi
2197
2198 dnl
2199 dnl raspberry pi openmax il configuration
2200 dnl
2201 AC_ARG_ENABLE(rpi-omxil,
2202   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2203 if test "${enable_rpi_omxil}" = "yes"
2204 then
2205   VLC_ADD_PLUGIN([omxil omxil_vout])
2206   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2207 fi
2208
2209 dnl
2210 dnl CrystalHD codec plugin
2211 dnl
2212 AC_ARG_ENABLE(crystalhd,
2213   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2214 if test "${enable_crystalhd}" != "no"; then
2215     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2216       VLC_ADD_PLUGIN([crystalhd])
2217       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2218     ],[
2219       if test "${SYS}" = "mingw32" ; then
2220         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2221           VLC_ADD_PLUGIN([crystalhd])
2222           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2223             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2224             ])
2225         ],[
2226           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2227                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2228                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2229         ],[#define __LINUX_USER__
2230                #include <libcrystalhd/bc_dts_types.h>
2231         ])
2232       fi
2233     ],[
2234        #include <libcrystalhd/bc_dts_types.h>
2235       ])
2236 fi
2237
2238 dnl
2239 dnl  mad plugin
2240 dnl
2241 have_mad="no"
2242 MAD_CFLAGS=""
2243 MAD_LIBS=""
2244
2245 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2246   enable_mad="yes"
2247 ], [
2248   with_mad="no"
2249 ])
2250 AS_IF([test "${with_mad}" != "no"], [
2251   MAD_CFLAGS="-I${with_mad}/include"
2252   MAD_LIBS="-L${with_mad}/lib"
2253 ])
2254
2255 AC_ARG_ENABLE(mad,
2256   [  --enable-mad            libmad module (default enabled)])
2257 AS_IF([test "${enable_mad}" != "no"], [
2258   VLC_SAVE_FLAGS
2259   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2260   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2261   AC_CHECK_HEADERS(mad.h, [
2262     AC_CHECK_LIB(mad, mad_bit_init, [
2263       have_mad="yes"
2264       MAD_LIBS="${MAD_LIBS} -lmad"
2265     ])
2266   ])
2267   VLC_RESTORE_FLAGS
2268   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2269     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2270   ])
2271 ])
2272 AC_SUBST(MAD_CFLAGS)
2273 AC_SUBST(MAD_LIBS)
2274 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2275
2276 dnl  mpg123 plugin
2277 dnl
2278 dnl
2279 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2280
2281
2282 AC_ARG_ENABLE(merge-ffmpeg,
2283 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2284   enable_merge_ffmpeg="no"
2285 ])
2286 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2287
2288 AC_MSG_CHECKING([for libavutil variant])
2289 PKG_CHECK_EXISTS([libavutil], [
2290   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2291   libavutil_micro="${libavutil_version##*.}"
2292   AS_IF([test ${libavutil_micro} -le 99], [
2293     avfork="libav"
2294   ], [
2295     avfork="ffmpeg"
2296   ])
2297 ], [
2298   avfork="none"
2299 ])
2300 AC_MSG_RESULT([${avfork}])
2301
2302 dnl
2303 dnl gstreamer stuff
2304 dnl
2305 AC_ARG_ENABLE(gst-decode,
2306   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2307
2308 have_gst_decode="no"
2309 AS_IF([test "${enable_gst_decode}" != "no"], [
2310   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2311     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2312       have_gst_decode="yes"
2313     ], [
2314       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2315     ])
2316   ], [
2317     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2318   ])
2319 ])
2320 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2321
2322 dnl
2323 dnl  avcodec decoder/encoder plugin
2324 dnl
2325 AC_ARG_ENABLE(avcodec,
2326 [  --enable-avcodec        libavcodec codec (default enabled)])
2327 AS_IF([test "${enable_avcodec}" != "no"], [
2328   dnl We need >=57.16.0 from libav or >=57.37.100 from ffmpeg
2329   case "${avfork}" in
2330     libav) av_codec_ver="57.16.0" ;;
2331     ffmpeg) av_codec_ver="57.37.100" ;;
2332     *) AC_MSG_ERROR([Missing libav or FFmpeg])
2333   esac
2334   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= ${av_codec_ver} libavutil >= 52.0.0], [
2335     VLC_SAVE_FLAGS
2336     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2337     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2338     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2339     AC_CHECK_HEADERS(libavutil/avutil.h)
2340     VLC_RESTORE_FLAGS
2341     have_avcodec="yes"
2342   ],[
2343     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2344   ])
2345 ], [
2346   have_avcodec="no"
2347 ])
2348 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2349
2350 dnl
2351 dnl libva needs avcodec
2352 dnl
2353 AC_ARG_ENABLE(libva,
2354   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2355
2356 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2357   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2358 ])
2359
2360 have_vaapi="no"
2361 have_vaapi_drm="no"
2362 have_vaapi_x11="no"
2363 AS_IF([test "${enable_libva}" != "no"], [
2364   PKG_CHECK_MODULES([LIBVA], [libva], [
2365     have_vaapi="yes"
2366   ], [
2367     AS_IF([test -n "${enable_libva}"], [
2368       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2369     ], [
2370       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2371     ])
2372   ])
2373   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2374     have_vaapi_drm="yes"
2375   ], [
2376     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2377   ])
2378   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2379     have_vaapi_x11="yes"
2380   ], [
2381     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2382   ])
2383 ])
2384 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2385 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2386
2387 have_avcodec_vaapi="no"
2388 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2389   VLC_SAVE_FLAGS
2390   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2391   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2392   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2393     AC_MSG_NOTICE([VA API acceleration activated])
2394     have_avcodec_vaapi="yes"
2395   ],[
2396     AS_IF([test -n "${enable_libva}"], [
2397       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2398     ], [
2399       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2400     ])
2401   ])
2402   VLC_RESTORE_FLAGS
2403 ])
2404 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2405
2406 dnl
2407 dnl dxva2 needs avcodec
2408 dnl
2409 AC_ARG_ENABLE(dxva2,
2410   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2411
2412 have_avcodec_dxva2="no"
2413 AS_IF([test "${enable_dxva2}" != "no"], [
2414   if test "${SYS}" = "mingw32"; then
2415   AS_IF([test "x${have_avcodec}" = "xyes"], [
2416     AC_CHECK_HEADERS(dxva2api.h,
2417       [
2418         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2419            AC_MSG_NOTICE([DxVA2 acceleration activated])
2420            have_avcodec_dxva2="yes"
2421         ],[
2422     AS_IF([test "${enable_dxva2}" = "yes"],
2423           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2424               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2425         ], [#undef _WIN32_WINNT
2426             /* DXVA2 is only available in Vista and above */
2427             #define _WIN32_WINNT 0x600])
2428       ],[
2429     AS_IF([test "${enable_dxva2}" = "yes"],
2430               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2431               [AC_MSG_WARN([dxva2api.h not found])])
2432       ],[#include <d3d9.h>])
2433   ],[
2434     AS_IF([test "x${enable_dxva2}" != "x"], [
2435       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2436     ])
2437   ])
2438   fi
2439 ])
2440 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2441
2442 dnl
2443 dnl d3d11va needs avcodec
2444 dnl
2445 AC_ARG_ENABLE(d3d11va,
2446   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2447
2448 have_avcodec_d3d11va="no"
2449 AS_IF([test "${enable_d3d11va}" != "no"], [
2450   if test "${SYS}" = "mingw32"; then
2451   AS_IF([test "x${have_avcodec}" = "xyes"], [
2452         AC_CHECK_TYPES([ID3D11VideoDecoder],
2453           [
2454             AC_CHECK_HEADERS(dxva2api.h,
2455               [
2456                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2457                    AC_MSG_NOTICE([D3D11 acceleration activated])
2458                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2459                    have_avcodec_d3d11va="yes"
2460                 ],[
2461                   AS_IF([test "${enable_d3d11va}" = "yes"],
2462                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2463                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2464                   ], [#undef _WIN32_WINNT
2465                       /* D3D11 is only available in Vista and above */
2466                       #define _WIN32_WINNT 0x600])
2467                   ],[
2468                     AS_IF([test "${enable_d3d11va}" = "yes"],
2469                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2470                           [AC_MSG_WARN([dxva2api.h not found])])
2471                   ],[#include <d3d9.h>])
2472           ],[
2473             AS_IF([test "${enable_d3d11va}" = "yes"],
2474                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2475                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2476           ], [#include <d3d11.h>])
2477   ],[
2478     AS_IF([test "x${enable_d3d11va}" != "x"], [
2479       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2480     ])
2481   ])
2482   fi
2483 ])
2484 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2485
2486 dnl
2487 dnl DXGI debug
2488 dnl
2489 AC_CHECK_HEADERS(dxgidebug.h)
2490
2491 dnl
2492 dnl vda needs avcodec
2493 dnl
2494 AC_ARG_ENABLE(vda,
2495   [  --enable-vda          VDA  support (default auto)])
2496
2497 have_avcodec_vda="no"
2498 AS_IF([test "${enable_vda}" != "no"], [
2499   if test "${SYS}" = "darwin"; then
2500   AS_IF([test "x${have_avcodec}" = "xyes"], [
2501     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2502       [
2503         AC_CHECK_HEADERS(libavcodec/vda.h, [
2504            have_avcodec_vda="yes"
2505         ],[
2506         AS_IF([test "${enable_vda}" = "yes"],
2507               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2508               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2509         ])
2510   ],[
2511         AS_IF([test "${enable_vda}" = "yes"],
2512               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2513               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2514       ])
2515   ],[
2516     AS_IF([test "x${enable_vda}" != "x"], [
2517       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2518     ])
2519  ])
2520  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2521      SAVE_LIBS=$LIBS
2522      LIBS="$LIBS $AVCODEC_LIBS"
2523      AC_CHECK_FUNCS([av_vda_alloc_context])
2524      LIBS=$SAVE_LIBS
2525  ])
2526  fi
2527 ])
2528 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2529
2530 dnl
2531 dnl  avformat demuxer/muxer plugin
2532 dnl
2533
2534 AC_ARG_ENABLE(avformat,
2535 [  --enable-avformat       libavformat containers (default enabled)],, [
2536   enable_avformat="${have_avcodec}"
2537 ])
2538 have_avformat="no"
2539 AS_IF([test "${enable_avformat}" != "no"], [
2540   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2541       have_avformat="yes"
2542       VLC_SAVE_FLAGS
2543       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2544       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2545       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2546       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2547       AC_CHECK_HEADERS(libavutil/avutil.h)
2548       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2549         have_avformat="no"
2550       ])
2551       VLC_RESTORE_FLAGS
2552     ],[
2553       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2554   ])
2555 ])
2556 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2557
2558 dnl
2559 dnl  swscale image scaling and conversion plugin
2560 dnl
2561
2562 AC_ARG_ENABLE(swscale,
2563   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2564           (default enabled)]))
2565 if test "${enable_swscale}" != "no"
2566 then
2567   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2568     [
2569       VLC_SAVE_FLAGS
2570       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2571       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2572       AC_CHECK_HEADERS(libswscale/swscale.h)
2573       AC_CHECK_HEADERS(libavutil/avutil.h)
2574       VLC_ADD_PLUGIN([swscale])
2575       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2576       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2577       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2578         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2579       ])
2580       VLC_RESTORE_FLAGS
2581     ],[
2582       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2583   ])
2584 fi
2585
2586 dnl
2587 dnl  postproc plugin
2588 dnl
2589
2590 AC_ARG_ENABLE(postproc,
2591 [  --enable-postproc       libpostproc image post-processing (default auto)])
2592 if test "${enable_postproc}" != "no"
2593 then
2594   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2595     [
2596       VLC_SAVE_FLAGS
2597       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2598       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2599       AC_CHECK_HEADERS(postproc/postprocess.h)
2600       VLC_ADD_PLUGIN([postproc])
2601       VLC_RESTORE_FLAGS
2602     ],[
2603       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2604   ])
2605 fi
2606
2607 dnl
2608 dnl  faad decoder plugin
2609 dnl
2610 AC_ARG_ENABLE(faad,
2611 [  --enable-faad           faad codec (default auto)])
2612 have_faad="no"
2613 AS_IF([test "${enable_faad}" != "no"], [
2614   AC_CHECK_HEADERS([neaacdec.h], [
2615     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2616
2617     AS_IF([test "${have_faad}" = "yes"], [
2618       VLC_ADD_PLUGIN([faad])
2619       VLC_ADD_LIBS([faad],[-lfaad])
2620     ], [
2621       AS_IF([test "${enable_faad}" = "yes"], [
2622         AC_MSG_ERROR([cannot find FAAD library])
2623       ], [
2624         AC_MSG_WARN([cannot find FAAD library])
2625       ])
2626     ])
2627   ])
2628 ])
2629
2630 dnl
2631 dnl  AOM decoder plugin
2632 dnl
2633 PKG_ENABLE_MODULES_VLC([AOM], [], [aom], [experimental AV1 codec], [disabled])
2634
2635 dnl
2636 dnl libvpx decoder plugin
2637 dnl
2638 AC_ARG_ENABLE(vpx,
2639     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2640 AS_IF([test "${enable_vpx}" != "no"],[
2641     PKG_CHECK_MODULES([VPX], [vpx >= 1.5.0], [
2642         VLC_ADD_PLUGIN([vpx])
2643         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2644         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2645         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2646             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2647         ], [], [${VPX_LIBS}])
2648         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2649             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2650         ], [], [${VPX_LIBS}])
2651         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2652             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2653         ], [], [${VPX_LIBS}])
2654         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2655             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2656         ], [], [${VPX_LIBS}])
2657     ], [
2658     AS_IF([test "${enable_vpx}" = "yes"],[
2659         AC_MSG_ERROR([libvpx 1.5.0 or higher was not found])
2660     ])])
2661 ])
2662
2663 dnl
2664 dnl twolame encoder plugin
2665 dnl
2666 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2667
2668 dnl
2669 dnl fdk-aac encoder plugin
2670 dnl
2671 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2672
2673
2674 dnl
2675 dnl A52/AC3 decoder plugin
2676 dnl
2677 AC_ARG_ENABLE(a52,
2678   [  --enable-a52            A/52 support with liba52 (default enabled)])
2679 if test "${enable_a52}" != "no"
2680 then
2681   AC_ARG_WITH(a52,
2682     [  --with-a52=PATH         a52 headers and libraries])
2683     if test -z "${with_a52}"
2684     then
2685       LDFLAGS_test=""
2686       CPPFLAGS_test=""
2687     else
2688       LDFLAGS_test="-L${with_a52}/lib"
2689       CPPFLAGS_test="-I${with_a52}/include"
2690     fi
2691     VLC_SAVE_FLAGS
2692     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52}"
2693     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52}"
2694     AC_CHECK_HEADERS(a52dec/a52.h, [
2695       AC_CHECK_LIB(a52, a52_free, [
2696         VLC_ADD_PLUGIN([a52])
2697         VLC_ADD_LIBS([a52],[${LDFLAGS_test} -la52])
2698         VLC_ADD_CPPFLAGS([a52],[${CPPFLAGS_test}])
2699       ],[
2700         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2701         ], [$LIBM])
2702     ],[
2703       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2704     ])
2705     VLC_RESTORE_FLAGS
2706 fi
2707
2708 dnl
2709 dnl DTS Coherent Acoustics decoder plugin
2710 dnl
2711 PKG_ENABLE_MODULES_VLC([DCA], [dca], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2712
2713 dnl
2714 dnl  Flac plugin
2715 dnl
2716 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2717
2718 dnl
2719 dnl  Libmpeg2 plugin
2720 dnl
2721 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2722
2723 dnl
2724 dnl  Vorbis plugin
2725 dnl
2726 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2727
2728 dnl
2729 dnl  Tremor plugin
2730 dnl
2731 AC_ARG_ENABLE(tremor,
2732   [  --enable-tremor         Tremor decoder support (default disabled)])
2733 if test "${enable_tremor}" = "yes"
2734 then
2735   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2736     VLC_ADD_PLUGIN([tremor])
2737    ],[])
2738 fi
2739
2740 dnl
2741 dnl  Speex plugins
2742 dnl
2743 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2744 have_speexdsp="no"
2745 AS_IF([test "${enable_speex}" != "no"], [
2746   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2747     have_speexdsp="yes"
2748   ], [
2749     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2750   ])
2751 ])
2752 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2753
2754 dnl
2755 dnl  Opus plugin
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2758
2759 dnl
2760 dnl  theora decoder plugin
2761 dnl
2762 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2763
2764 dnl
2765 dnl  OggSpots decoder plugin
2766 dnl
2767 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2768
2769 dnl
2770 dnl  Daala decoder plugin
2771 dnl
2772 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2773
2774 dnl
2775 dnl  schroedinger decoder plugin (for dirac format video)
2776 dnl
2777 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2778
2779 dnl
2780 dnl  PNG decoder module
2781 dnl
2782 AC_ARG_ENABLE(png,
2783   [  --enable-png            PNG support (default enabled)])
2784 AS_IF([test "${enable_png}" != "no"], [
2785 AC_CHECK_HEADERS(png.h, [
2786   VLC_SAVE_FLAGS
2787   LDFLAGS="${LDFLAGS} -lz $LIBM"
2788   AC_CHECK_LIB(png, png_set_rows, [
2789     VLC_ADD_PLUGIN([png])
2790   ], [], [-lz $LIBM])
2791   VLC_RESTORE_FLAGS
2792   ])
2793 ])
2794
2795 dnl
2796 dnl  JPEG decoder module
2797 dnl
2798 AC_ARG_ENABLE(jpeg,
2799   [  --enable-jpeg           JPEG support (default enabled)])
2800 AS_IF([test "${enable_jpeg}" != "no"], [
2801 AC_CHECK_HEADERS(jpeglib.h, [
2802   VLC_ADD_PLUGIN([jpeg])
2803   ])
2804 ])
2805
2806 dnl
2807 dnl  BPG decoder module
2808 dnl
2809 AC_ARG_ENABLE(bpg,
2810   [  --enable-bpg           BPG support (default disabled)])
2811 AS_IF([test "${enable_bpg}" != "no"], [
2812 AC_CHECK_HEADERS(libbpg.h, [
2813   VLC_ADD_PLUGIN([bpg])
2814   ])
2815 ])
2816
2817 dnl
2818 dnl H262 encoder plugin (lib262)
2819 dnl
2820 AC_ARG_ENABLE(x262,
2821   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2822 if test "${enable_x262}" != "no"; then
2823     PKG_CHECK_MODULES(X262, x262, [
2824         VLC_ADD_PLUGIN([x262])
2825         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2826         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2827           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2828         ])
2829         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2830         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2831           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2832         fi
2833     ], [
2834        if test "${enable_x262}" = "yes"; then
2835         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2836        fi
2837     ])
2838 fi
2839
2840 dnl x265 encoder
2841 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2842
2843 dnl
2844 dnl H264 encoder plugin (10-bit lib264)
2845 dnl
2846 AC_ARG_ENABLE(x26410b,
2847   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2848 if test "${enable_x26410b}" != "no"; then
2849     PKG_CHECK_MODULES(X26410B, x26410b, [
2850         VLC_ADD_PLUGIN([x26410b])
2851         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2852         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2853           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2854         ])
2855         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2856         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2857           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2858         fi
2859     ], [
2860        if test "${enable_x26410b}" = "yes"; then
2861         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2862        fi
2863     ])
2864 fi
2865
2866
2867 dnl
2868 dnl H264 encoder plugin (using libx264)
2869 dnl
2870 AC_ARG_ENABLE(x264,
2871   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2872 if test "${enable_x264}" != "no"; then
2873       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2874         VLC_ADD_PLUGIN([x264])
2875         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2876
2877         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2878           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2879         ])
2880
2881         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2882         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2883           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2884         fi
2885       ],[
2886         if test "${enable_x264}" = "yes"; then
2887             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2888           fi
2889       ])
2890 fi
2891
2892 dnl
2893 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2894 dnl
2895 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2896
2897 dnl
2898 dnl libfluidsynth (MIDI synthetizer) plugin
2899 dnl
2900 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2901 PKG_ENABLE_MODULES_VLC([FLUIDLITE], [fluidsynth], [fluidlite], [MIDI synthetiser with libfluidsynth], [auto])
2902 AC_CHECK_HEADERS(fluidlite.h, [AC_SUBST([FLUIDSYNTH_LIBS], ${FLUIDLITE_LIBS})])
2903
2904 dnl
2905 dnl Teletext Modules
2906 dnl vbi decoder plugin (using libzbvi)
2907 dnl telx module
2908 dnl uncompatible
2909 dnl
2910 AC_ARG_ENABLE(zvbi,
2911   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2912                   libzvbi (default enabled)]))
2913 AC_ARG_ENABLE(telx,
2914   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2915                   zvbi) (default enabled if zvbi is absent)]))
2916
2917 AS_IF( [test "${enable_zvbi}" != "no"],[
2918     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2919         [
2920           VLC_ADD_PLUGIN([zvbi])
2921           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2922           AS_IF( [test "${enable_telx}" = "yes"],[
2923                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2924                   ])
2925         ],[
2926           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2927         ])
2928     ])
2929 AS_IF( [test "${enable_telx}" != "no" ],[
2930   VLC_ADD_PLUGIN([telx])
2931   ])
2932
2933 dnl
2934 dnl libass subtitle rendering module
2935 dnl
2936 AC_ARG_ENABLE(libass,
2937   [  --enable-libass         Subtitle support using libass (default enabled)])
2938 AS_IF( [test "${enable_libass}" != "no"], [
2939   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2940       [
2941         VLC_ADD_PLUGIN([libass])
2942
2943         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2944           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2945            VLC_ADD_LIBS([libass],[-lfontconfig])
2946        ])
2947       ],[
2948         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2949       ])
2950   ])
2951
2952 dnl
2953 dnl ARIB subtitles rendering module
2954 dnl
2955 AC_ARG_ENABLE(aribsub,
2956   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2957 AS_IF( [test "${enable_aribsub}" != "no" ],[
2958   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2959       have_aribb24="yes"
2960       VLC_ADD_PLUGIN([aribsub])
2961       VLC_ADD_LIBS([aribsub],[-laribb24])
2962       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2963     ],[
2964       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2965       have_aribb24="no"
2966   ])
2967 ])
2968 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2969
2970 dnl
2971 dnl ARIB B25
2972 dnl
2973 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2974
2975 dnl
2976 dnl  kate decoder plugin
2977 dnl
2978 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2979
2980 dnl
2981 dnl  tiger rendering for kate decoder plugin
2982 dnl
2983 AC_ARG_ENABLE(tiger,
2984 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2985 AS_IF([test "${enable_tiger}" != "no"], [
2986   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2987       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2988         AS_IF([test -n "${enable_tiger}"], [
2989           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2990         ])
2991   ])
2992 ])
2993
2994
2995 dnl
2996 dnl  Video plugins
2997 dnl
2998
2999 EXTEND_HELP_STRING([Video plugins:])
3000
3001 dnl
3002 dnl  OpenGL
3003 dnl
3004 PKG_CHECK_MODULES([EGL], [egl], [
3005   have_egl="yes"
3006 ], [
3007   have_egl="no"
3008 ])
3009 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
3010
3011 have_gl="no"
3012 PKG_CHECK_MODULES([GL], [gl], [
3013   have_gl="yes"
3014 ], [
3015   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3016 #ifdef _WIN32
3017 # include <GL/glew.h>
3018 #endif
3019 #include <GL/gl.h>
3020 ]], [
3021     [int t0 = GL_TEXTURE0;]])
3022   ], [
3023     GL_CFLAGS=""
3024     have_gl="yes"
3025     AS_IF([test "${SYS}" != "mingw32"], [
3026       GL_LIBS="-lGL"
3027     ], [
3028       GL_LIBS="-lopengl32"
3029     ])
3030   ])
3031 ])
3032 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3033
3034 dnl OpenGL ES 2: depends on EGL 1.1
3035 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3036 dnl OpenGL ES 1: depends on EGL 1.0
3037 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3038
3039 dnl
3040 dnl  Xlib
3041 dnl
3042
3043 AC_PATH_XTRA()
3044 AC_CHECK_HEADERS(X11/Xlib.h)
3045
3046 dnl
3047 dnl  X C Bindings modules
3048 dnl
3049 AC_ARG_ENABLE(xcb,
3050   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3051   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3052     enable_xcb="yes"
3053   ], [
3054     enable_xcb="no"
3055   ])
3056 ])
3057 AC_ARG_ENABLE(xvideo,
3058   [  --enable-xvideo         XVideo support (default enabled)],, [
3059     enable_xvideo="$enable_xcb"
3060 ])
3061
3062 have_xcb="no"
3063 have_xcb_keysyms="no"
3064 have_xcb_randr="no"
3065 have_xcb_xvideo="no"
3066 AS_IF([test "${enable_xcb}" != "no"], [
3067   dnl libxcb
3068   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3069   have_xcb="yes"
3070   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3071   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3072   PKG_CHECK_MODULES(XPROTO, [xproto])
3073
3074   AS_IF([test "${enable_xvideo}" != "no"], [
3075     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3076   ])
3077
3078   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3079
3080   dnl xcb-utils
3081   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3082     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3083   ])
3084 ])
3085 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3086 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3087 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3088 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3089
3090
3091 dnl
3092 dnl VDPAU needs X11
3093 dnl
3094 AC_ARG_ENABLE(vdpau,
3095   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3096 have_vdpau="no"
3097 AS_IF([test "${enable_vdpau}" != "no"], [
3098   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3099     have_vdpau="yes"
3100     AS_IF([test "${no_x}" = "yes"], [
3101       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3102     ])
3103   ], [
3104     AS_IF([test -n "${enable_vdpau}"], [
3105       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3106     ])
3107   ])
3108 ])
3109 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3110
3111 have_avcodec_vdpau="no"
3112 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3113   case "${avfork}" in
3114     libav) av_vdpau_ver="56.10.0" ;;
3115     ffmpeg) av_vdpau_ver="56.19.100" ;;
3116   esac
3117   PKG_CHECK_EXISTS([libavcodec >= ${av_vdpau_ver}], [
3118     have_avcodec_vdpau="yes"
3119     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3120   ], [
3121     AS_IF([test -n "${enable_vdpau}"], [
3122       AC_MSG_ERROR([libavcodec >= 56.10.0 is required for VDPAU decoding.])
3123     ], [
3124       AC_MSG_WARN([libavcodec >= 56.10.0 are required for VDPAU decoding.])
3125     ])
3126   ])
3127 ])
3128 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3129
3130
3131 dnl
3132 dnl  Wayland
3133 dnl
3134 AC_ARG_ENABLE(wayland,
3135   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3136 have_wayland="no"
3137 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3138
3139 AS_IF([test "${enable_wayland}" != "no"], [
3140   AC_MSG_CHECKING([for the Wayland scanner])
3141   AS_IF([test -z "$WAYLAND_SCANNER"], [
3142     PKG_CHECK_EXISTS([wayland-scanner], [
3143       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3144     ], [
3145       WAYLAND_SCANNER="wayland-scanner"
3146     ])
3147   ])
3148   AC_MSG_RESULT([$WAYLAND_SCANNER])
3149
3150   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3151     have_wayland="yes"
3152   ], [
3153     AS_IF([test -n "${enable_wayland}"], [
3154       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3155     ])
3156   ])
3157
3158   AS_IF([test "${have_egl}" = "yes"], [
3159     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3160       have_wayland_egl="yes"
3161     ], [
3162       AS_IF([test -n "${enable_wayland}"], [
3163         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3164       ])
3165     ])
3166   ])
3167 ])
3168 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3169 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3170
3171
3172 dnl
3173 dnl  SDL module
3174 dnl
3175 AC_ARG_ENABLE(sdl,
3176   [  --enable-sdl            SDL support (default enabled)])
3177 AC_ARG_ENABLE(sdl-image,
3178   [  --enable-sdl-image      SDL image support (default enabled)])
3179 if test "${enable_sdl}" != "no"
3180 then
3181    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3182       # SDL on Darwin is heavily patched and can only run SDL_image
3183       if test "${SYS}" != "darwin"; then
3184         VLC_ADD_PLUGIN([vout_sdl])
3185       fi
3186
3187       # SDL_image
3188       AS_IF([ test "${enable_sdl_image}" != "no"],[
3189         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3190           VLC_ADD_PLUGIN([sdl_image])],
3191           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3192           ])
3193       ])
3194    ],[
3195      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3196    ])
3197 fi
3198
3199 dnl
3200 dnl  freetype module
3201 dnl
3202 AC_ARG_ENABLE(freetype,
3203   [  --enable-freetype       freetype support   (default auto)])
3204 AC_ARG_ENABLE(fribidi,
3205   [  --enable-fribidi        fribidi support    (default auto)])
3206 AC_ARG_ENABLE(harfbuzz,
3207   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3208 AC_ARG_ENABLE(fontconfig,
3209   [  --enable-fontconfig     fontconfig support (default auto)])
3210
3211 AC_ARG_WITH([default-font],
3212     AS_HELP_STRING([--with-default-font=PATH],
3213         [Path to the default font]),
3214         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3215             "$withval", [Default font])])
3216 AC_ARG_WITH([default-monospace-font],
3217     AS_HELP_STRING([--with-default-monospace-font=PATH],
3218         [Path to the default font]),
3219         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3220             "$withval", [Default monospace font])])
3221
3222 AC_ARG_WITH([default-font-family],
3223     AS_HELP_STRING([--with-default-font-family=NAME],
3224         [Path to the default font family]),
3225         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3226             "$withval", [Default font family])])
3227 AC_ARG_WITH([default-monospace-font-family],
3228     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3229         [Path to the default font family]),
3230         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3231             "$withval", [Default monospace font family])])
3232
3233 have_freetype="no"
3234 have_fontconfig="no"
3235 have_fribidi="no"
3236 have_harfbuzz="no"
3237
3238 if test "${enable_freetype}" != "no"; then
3239    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3240       have_freetype="yes"
3241       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3242       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3243
3244       dnl fontconfig support
3245       if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
3246           if test "${enable_fontconfig}" != "no"; then
3247             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3248               have_fontconfig="yes"
3249             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3250           fi
3251       fi
3252
3253       dnl fribidi support
3254       if test "${enable_fribidi}" != "no"; then
3255         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3256           have_fribidi="yes"
3257           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3258           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3259         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3260       fi
3261
3262       dnl harfbuzz support
3263       if test "${have_fribidi}" != "no"; then
3264         if test "${enable_harfbuzz}" != "no"; then
3265           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3266             have_harfbuzz="yes"
3267             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3268             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3269           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3270         fi
3271       fi
3272   ],[
3273   AS_IF([test -n "${enable_freetype}"],[
3274     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3275     ])
3276   ])
3277 fi
3278
3279 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3280 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3281 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3282 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3283
3284 dnl
3285 dnl SAPI (text to Speech renderer for Windows)
3286 dnl
3287 AC_LANG_PUSH([C++])
3288 AC_CHECK_TYPES([ISpObjectToken],[
3289               have_sapi="yes"
3290             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3291               [#include <windows.h>
3292                #include <sapi.h>
3293                #include <sphelper.h>])
3294 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3295 AC_LANG_POP([C++])
3296
3297 dnl
3298 dnl  SVG module (text rendering and image decoding)
3299 dnl
3300 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3301 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3302
3303 dnl
3304 dnl  Windows DirectX module
3305 dnl
3306
3307 AC_ARG_ENABLE(directx,
3308   [AS_HELP_STRING([--enable-directx],
3309     [Microsoft DirectX support (default enabled on Windows)])],, [
3310   AS_IF([test "${SYS}" = "mingw32"], [
3311     enable_directx="yes"
3312   ], [
3313     enable_directx="no"
3314   ])
3315 ])
3316 AS_IF([test "${enable_directx}" != "no"], [
3317   dnl DirectDraw
3318   AC_CHECK_HEADERS(ddraw.h, [
3319     VLC_ADD_PLUGIN([directdraw])
3320   ])
3321
3322   dnl OpenGL
3323   AC_CHECK_HEADERS(GL/wglew.h, [
3324     VLC_ADD_PLUGIN([glwin32 wgl])
3325   ],, [
3326     #include <windows.h>
3327     #include <GL/gl.h>
3328   ])
3329
3330   dnl Direct3D11
3331   AC_CHECK_HEADERS(d3d11.h, [
3332     VLC_ADD_PLUGIN([direct3d11])
3333   ])
3334
3335   dnl Direct3D9
3336   AC_CHECK_HEADERS(d3d9.h, [
3337     VLC_ADD_PLUGIN([direct3d9])
3338   ])
3339
3340 ])
3341
3342 dnl
3343 dnl  Linux framebuffer module
3344 dnl
3345 AC_CHECK_HEADER([linux/fb.h], [
3346   VLC_ADD_PLUGIN([fb])
3347 ])
3348
3349
3350 dnl
3351 dnl  DirectFB module
3352 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3353 dnl  TODO: support for static linking
3354 dnl
3355 AC_ARG_ENABLE(directfb,
3356   [  --enable-directfb       DirectFB support (default disabled)])
3357 AC_ARG_WITH(directfb,
3358   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3359
3360 if test "${enable_directfb}" = "yes"; then
3361     have_directfb="false"
3362     CPPFLAGS_mydirectfb=
3363     LIBS_mydirectfb=
3364     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3365         dnl Trying the given location
3366         VLC_SAVE_FLAGS
3367
3368         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3369         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3370
3371         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3372         LIBS="${LIBS} ${LIBS_new}"
3373
3374         dnl FIXME: too obscure
3375         AC_CHECK_HEADER([directfb.h], [
3376             AC_CHECK_LIB([direct],[direct_initialize], [
3377                 AC_CHECK_LIB([fusion], [fusion_enter], [
3378                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3379                 ], have_directfb="false")
3380             ], have_directfb="false")
3381         ], have_directfb="false")
3382
3383         VLC_RESTORE_FLAGS
3384
3385         if test "${have_directfb}" = "true"; then
3386             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3387             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3388         fi
3389     else
3390         dnl Look for directfb-config
3391         AC_CHECK_PROG(DIRECTFB_CONFIG, [directfb-config], [false])
3392         AS_IF(["${DIRECTFB_CONFIG}" != "false"], [
3393             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3394             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3395             have_directfb="true"
3396         ], [
3397             dnl Trying with pkg-config
3398             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3399                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3400                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3401                 have_directfb="true"
3402                 ], [have_directfb="false"])
3403         ])
3404     fi
3405     if test "${have_directfb}" = "true"; then
3406         VLC_ADD_PLUGIN([directfb])
3407         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3408         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3409     else
3410         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3411     fi
3412 fi
3413
3414 dnl
3415 dnl  AA plugin
3416 dnl
3417 AC_ARG_ENABLE(aa,
3418   [  --enable-aa             aalib output (default disabled)])
3419 if test "${enable_aa}" = "yes"
3420 then
3421   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3422   if test "${have_aa}" = "true"
3423   then
3424     VLC_ADD_PLUGIN([aa])
3425   fi
3426 fi
3427
3428 dnl
3429 dnl  libcaca plugin
3430 dnl
3431 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3432
3433 dnl
3434 dnl  OS/2 KVA plugin
3435 dnl
3436 AC_ARG_ENABLE(kva,
3437   [AS_HELP_STRING([--enable-kva],
3438     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3439   AS_IF([test "$SYS" = "os2"], [
3440     enable_kva="yes"
3441   ])
3442 ])
3443 have_kva="no"
3444 KVA_LIBS=""
3445 AS_IF([test "$enable_kva" != "no"], [
3446   AC_CHECK_HEADERS([kva.h], [
3447     have_kva="yes"
3448     AC_CHECK_LIB(kva, main, [
3449       KVA_LIBS="-lkva"
3450     ])
3451   ])
3452 ])
3453 AC_SUBST(KVA_LIBS)
3454 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3455
3456 dnl
3457 dnl MMAL plugin
3458 dnl
3459 AC_ARG_ENABLE(mmal,
3460   AS_HELP_STRING([--enable-mmal],
3461     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3462 if test "${enable_mmal}" != "no"; then
3463   VLC_SAVE_FLAGS
3464   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3465   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3466   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3467     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3468         have_mmal="yes"
3469         VLC_ADD_PLUGIN([mmal])
3470         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3471         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3472         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3473           AS_IF([test "${enable_mmal}" = "yes"],
3474             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3475             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3476           ],
3477         [])
3478     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3479       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3480       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3481   VLC_RESTORE_FLAGS
3482 fi
3483 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3484
3485 dnl
3486 dnl evas plugin
3487 dnl
3488 AC_ARG_ENABLE(evas,
3489   [AS_HELP_STRING([--enable-evas],
3490     [use evas output module (default disabled)])])
3491 have_evas="no"
3492 AS_IF([test "${enable_evas}" = "yes"], [
3493   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3494       have_evas="yes"
3495       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3496     ],[
3497     AS_IF([test "x${enable_evas}" != "x"], [
3498       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3499     ])
3500   ])
3501 ])
3502 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3503
3504 dnl
3505 dnl  Audio plugins
3506 dnl
3507
3508 EXTEND_HELP_STRING([Audio plugins:])
3509
3510 dnl
3511 dnl  Pulseaudio module
3512 dnl
3513 AC_ARG_ENABLE(pulse,
3514   [AS_HELP_STRING([--enable-pulse],
3515     [use the PulseAudio client library (default auto)])])
3516 have_pulse="no"
3517 AS_IF([test "${enable_pulse}" != "no"], [
3518   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3519     have_pulse="yes"
3520   ], [
3521     AS_IF([test "x${enable_pulse}" != "x"], [
3522       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3523     ])
3524   ])
3525 ])
3526 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3527
3528 dnl
3529 dnl  ALSA module
3530 dnl
3531 AC_ARG_ENABLE(alsa,
3532   [AS_HELP_STRING([--enable-alsa],
3533     [support the Advanced Linux Sound Architecture (default auto)])],, [
3534   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3535     enable_alsa="yes"
3536   ])
3537 ])
3538 have_alsa="no"
3539 AS_IF([test "${enable_alsa}" != "no"], [
3540   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3541     have_alsa="yes"
3542   ], [
3543     AS_IF([test "x${enable_alsa}" != "x"], [
3544       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3545     ])
3546   ])
3547 ])
3548 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3549
3550 dnl
3551 dnl  Open Sound System module
3552 dnl
3553 AC_ARG_ENABLE(oss,
3554   [AS_HELP_STRING([--enable-oss],
3555     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3556   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3557     enable_oss="no"
3558   ])
3559 ])
3560 have_oss="no"
3561 OSS_LIBS=""
3562 AS_IF([test "$enable_oss" != "no"], [
3563   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3564     have_oss="yes"
3565     AC_CHECK_LIB(ossaudio, main, [
3566       OSS_LIBS="-lossaudio"
3567     ])
3568   ])
3569 ])
3570 AC_SUBST(OSS_LIBS)
3571 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3572
3573 dnl
3574 dnl  OpenBSD sndio module
3575 dnl
3576 AC_ARG_ENABLE([sndio],
3577   [AS_HELP_STRING([--disable-sndio],
3578     [support the OpenBSD sndio (default auto)])],, [
3579   AS_IF([test "$SYS" = "openbsd"], [
3580     enable_sndio="yes"
3581   ])
3582 ])
3583 have_sndio="no"
3584 AS_IF([test "$enable_sndio" != "no"], [
3585   AC_CHECK_HEADER([sndio.h], [
3586     have_sndio="yes"
3587   ])
3588 ])
3589 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3590
3591 dnl
3592 dnl  Windows Audio Session plugin
3593 dnl
3594 AC_ARG_ENABLE([wasapi],
3595   [AS_HELP_STRING([--enable-wasapi],
3596     [use the Windows Audio Session API (default auto)])
3597 ])
3598 have_wasapi="no"
3599 AS_IF([test "$enable_wasapi" != "no"], [
3600   AC_CHECK_HEADER([audioclient.h], [
3601     have_wasapi="yes"
3602   ], [
3603     AS_IF([test "x${enable_wasapi}" != "x"], [
3604       AC_MSG_ERROR([Windows Audio Session API not found.])
3605     ])
3606   ])
3607 ])
3608 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3609
3610 dnl
3611 dnl  AudioQueue plugin
3612 dnl
3613 AC_ARG_ENABLE(audioqueue,
3614   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3615 if test "${enable_audioqueue}" = "yes"
3616 then
3617   VLC_ADD_PLUGIN([audioqueue])
3618 fi
3619
3620 dnl
3621 dnl  JACK modules
3622 dnl
3623 AC_ARG_ENABLE(jack,
3624   [AS_HELP_STRING([--disable-jack],
3625     [do not use jack (default auto)])])
3626 have_jack="no"
3627 AS_IF([test "${enable_jack}" != "no"], [
3628     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3629       [ have_jack=yes ],
3630       [
3631       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3632
3633       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3634       [ have_jack=yes ],
3635       [
3636       AS_IF([test -n "${enable_jack}"],
3637          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3638          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3639       ])
3640     ])
3641 ])
3642 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3643
3644 dnl
3645 dnl  OpenSLES Android
3646 dnl
3647 AC_ARG_ENABLE(opensles,
3648   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3649 if test "${HAVE_ANDROID}" = "1"; then
3650   if test "${enable_opensles}" = "yes"; then
3651       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3652         [ VLC_ADD_PLUGIN([opensles_android]) ],
3653         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3654   fi
3655 fi
3656
3657 dnl
3658 dnl  Tizen audio
3659 dnl
3660 AC_ARG_ENABLE(tizen_audio,
3661   [AS_HELP_STRING([--enable-tizen-audio],
3662     [Tizen audio module (default enabled on Tizen)])],, [
3663   AS_IF([test "$HAVE_TIZEN" = "1"], [
3664     enable_tizen_audio="yes"
3665   ])
3666 ])
3667 if test "${enable_tizen_audio}" = "yes"; then
3668   AC_CHECK_HEADERS(audio_io.h,
3669     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3670     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3671 fi
3672
3673 dnl
3674 dnl libsamplerate plugin
3675 dnl
3676 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3677
3678 dnl
3679 dnl  soxr module
3680 dnl
3681 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3682
3683 dnl
3684 dnl  OS/2 KAI plugin
3685 dnl
3686 AC_ARG_ENABLE(kai,
3687   [AS_HELP_STRING([--enable-kai],
3688     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3689   AS_IF([test "$SYS" = "os2"], [
3690     enable_kai="yes"
3691   ])
3692 ])
3693 have_kai="no"
3694 KAI_LIBS=""
3695 AS_IF([test "$enable_kai" != "no"], [
3696   AC_CHECK_HEADERS([kai.h], [
3697     have_kai="yes"
3698     AC_CHECK_LIB(kai, main, [
3699       KAI_LIBS="-lkai"
3700     ])
3701   ])
3702 ])
3703 AC_SUBST(KAI_LIBS)
3704 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3705
3706 dnl
3707 dnl  chromaprint audio track fingerprinter
3708 dnl
3709 m4_pushdef([libchromaprint_version], 0.6.0)
3710 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3711     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3712     AS_IF([test "${enable_chromaprint}" = "yes"],
3713         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3714         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3715          ),
3716     [(Chromaprint based audio fingerprinter)],[auto])
3717 m4_popdef([libchromaprint_version])
3718
3719 dnl
3720 dnl  Chromecast streaming support
3721 dnl
3722 m4_pushdef([protobuf_lite_version], 2.5.0)
3723 AC_ARG_VAR(PROTOC, [protobuf compiler])
3724 AC_CHECK_PROGS(PROTOC, protoc, no)
3725 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3726     AS_IF([test "x${PROTOC}" != "xno"], [
3727         build_chromecast="yes"
3728     ], [
3729     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3730     ])
3731 ], [
3732     AS_IF([test "${enable_chromecast}" = "yes"],
3733         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3734         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3735     )
3736     enable_chromecast="no"
3737 ], [(Chromecast streaming support)], [auto])
3738 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3739 m4_popdef([protobuf_lite_version])
3740
3741 dnl
3742 dnl  Interface plugins
3743 dnl
3744
3745 EXTEND_HELP_STRING([Interface plugins:])
3746
3747 dnl
3748 dnl QT
3749 dnl
3750 AC_ARG_ENABLE(qt, [
3751   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3752   AS_IF([test "${SYS}" = "darwin"], [
3753     enable_qt="no"
3754   ])
3755 ])
3756 AS_IF([test "${enable_qt}" != "no"], [
3757   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3758       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3759           VLC_ADD_LIBS([qt],[${QTX11_LIBS}])
3760           VLC_ADD_CXXFLAGS([qt],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3761           PKG_CHECK_MODULES([XI], [xi], [
3762             VLC_ADD_LIBS([qt], [${XI_LIBS}])
3763             VLC_ADD_CXXFLAGS([qt], [${XI_CFLAGS} -DHAVE_XI])
3764           ], [
3765             PKG_CHECK_EXISTS([Qt5Gui >= 5.5], [
3766               AC_MSG_ERROR([${XI_PKG_ERRORS}.])
3767             ], [
3768               AC_MSG_WARN([${XI_PKG_ERRORS}.])
3769             ])
3770           ])
3771       ],[
3772           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3773       ])
3774       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3775       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3776       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3777       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3778       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
3779     ], [
3780       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3781         AS_IF([test -n "${enable_qt}"],[
3782           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3783         ],[
3784           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3785         ])
3786         enable_qt="no"
3787       ])
3788       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3789       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin"])
3790       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin])
3791       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin"])
3792     ])
3793 ])
3794 AS_IF([test "${enable_qt}" != "no"], [
3795   VLC_ADD_PLUGIN([qt])
3796   ALIASES="${ALIASES} qvlc"
3797 ])
3798 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3799
3800 dnl
3801 dnl detect kde4-config patch (used for kde solids).
3802 dnl
3803 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3804 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3805   KDE4_CONFIG="kde4-config"
3806 ])
3807
3808 dnl
3809 dnl Simple test for skins2 dependency
3810 dnl
3811 AS_IF([test "$enable_qt" = "no"], [
3812   AS_IF([test "${enable_skins2}" = "yes"], [
3813     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3814   ], [
3815     enable_skins2="no"
3816     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3817   ])
3818 ])
3819
3820 dnl
3821 dnl Skins2 module
3822 dnl
3823 AC_ARG_ENABLE(skins2,
3824   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3825 AS_IF([test "${enable_skins2}" != "no"], [
3826   have_skins_deps="yes"
3827
3828   dnl Win32
3829   AS_IF([test "${SYS}" = "mingw32"], [
3830     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3831     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3832   dnl MacOS
3833   ], [test "${SYS}" = "darwin"], [
3834     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3835     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3836   dnl OS/2
3837   ], [test "${SYS}" = "os2"], [
3838     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3839   dnl Linux/Unix
3840   ], [
3841     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3842     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3843     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3844     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3845     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3846   ])
3847
3848   dnl for All OSes
3849   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3850
3851   dnl we need freetype
3852   AS_IF([test "${have_freetype}" != "yes"], [
3853     have_skins_deps="no"
3854   ])
3855
3856   AS_IF([test "${have_skins_deps}" = "no"], [
3857     AS_IF([test "x${enable_skins2}" = "x"], [
3858       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3859     ], [
3860       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3861     ])
3862     enable_skins2="no"
3863   ], [
3864     VLC_ADD_PLUGIN([skins2])
3865     ALIASES="${ALIASES} svlc"
3866     enable_skins2="yes"
3867   ])
3868 ])
3869 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3870
3871 AC_ARG_ENABLE(libtar,
3872   [  --enable-libtar         libtar support for skins2 (default auto)])
3873 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3874   AC_CHECK_HEADERS(libtar.h, [
3875     VLC_ADD_LIBS([skins2],[-ltar])
3876   ])
3877 ])
3878
3879 dnl
3880 dnl  MacOS X gui module
3881 dnl
3882 AC_ARG_ENABLE(macosx,
3883   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3884 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3885 then
3886   VLC_ADD_PLUGIN([macosx])
3887
3888   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3889   then
3890     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3891   fi
3892 fi
3893 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3894
3895 dnl
3896 dnl  MacOS X sparkle update support
3897 dnl
3898 AC_ARG_ENABLE(sparkle,
3899   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3900 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3901 then
3902   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3903   then
3904     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3905   fi
3906
3907   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3908 fi
3909 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3910
3911
3912 dnl
3913 dnl  Minimal Mac OS X module
3914 dnl
3915 AC_ARG_ENABLE(minimal-macosx,
3916   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3917 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3918 then
3919   VLC_ADD_PLUGIN([minimal_macosx])
3920 fi
3921
3922 dnl
3923 dnl  VideoToolbox plugins
3924 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3925     VLC_ADD_PLUGIN([videotoolbox])
3926     VLC_ADD_PLUGIN([cvpx_i420])
3927   ])
3928
3929 dnl
3930 dnl  ncurses module
3931 dnl
3932 AC_ARG_ENABLE(ncurses,
3933 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3934 have_ncurses="no"
3935 AS_IF([test "${enable_ncurses}" != "no"] ,[
3936   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3937     have_ncurses="yes"
3938     ALIASES="${ALIASES} nvlc"
3939   ], [
3940     AS_IF([test -n "${enable_ncurses}"], [
3941       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3942     ])
3943   ])
3944 ])
3945 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3946
3947 dnl
3948 dnl  Lirc plugin
3949 dnl
3950 AC_ARG_ENABLE(lirc,
3951   [  --enable-lirc           lirc support (default disabled)])
3952 have_lirc="no"
3953 AS_IF([test "${enable_lirc}" = "yes"], [
3954   AC_CHECK_HEADER(lirc/lirc_client.h, [
3955     AC_CHECK_LIB(lirc_client, lirc_init, [
3956       have_lirc="true"
3957     ])
3958   ])
3959 ])
3960 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3961
3962 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3963 dnl
3964 dnl  goom visualization plugin
3965 dnl
3966 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3967
3968 dnl
3969 dnl libprojectM visualization plugin
3970 dnl
3971 AC_ARG_ENABLE(projectm,
3972   [  --enable-projectm       projectM visualization plugin (default enabled)])
3973 AS_IF([test "${enable_projectm}" != "no"],
3974   [
3975     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3976     [
3977       VLC_ADD_PLUGIN([projectm])
3978       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3979         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3980         [ AC_MSG_WARN( [Using libprojectM version 1] )
3981       ])
3982     ],[
3983       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3984     ])
3985   ])
3986
3987 dnl
3988 dnl Vovoid VSXu visualization plugin
3989 dnl
3990 AC_ARG_ENABLE(vsxu,
3991   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3992 AS_IF([test "${enable_vsxu}" != "no"],
3993   [
3994     PKG_CHECK_MODULES(VSXU, libvsxu,
3995     [
3996       VLC_ADD_PLUGIN([vsxu])
3997     ],[
3998       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3999     ])
4000   ])
4001
4002 EXTEND_HELP_STRING([Service Discovery plugins:])
4003 dnl
4004 dnl  Avahi-Zeroconf services discovery
4005 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4006
4007 dnl
4008 dnl  libudev services discovery
4009 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4010
4011 dnl
4012 dnl MTP devices services discovery
4013 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4014
4015 dnl
4016 dnl UPnP Plugin (Intel SDK)
4017 dnl
4018 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4019
4020 dnl
4021 dnl mDNS using libmicrodns
4022 dnl
4023 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4024
4025
4026 EXTEND_HELP_STRING([Misc options:])
4027
4028 dnl
4029 dnl  libxml2 module
4030 dnl
4031 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4032
4033
4034 dnl
4035 dnl libgcrypt
4036 dnl
4037 AC_ARG_ENABLE(libgcrypt,
4038   [  --disable-libgcrypt     gcrypt support (default enabled)])
4039 AC_ARG_VAR([GCRYPT_CFLAGS], [C compiler flags for gcrypt])
4040 AC_ARG_VAR([GCRYPT_LIBS], [linker flags flags for gcrypt])
4041
4042 # require libgcrypt >= 1.6.0
4043 AS_IF([test "${enable_libgcrypt}" != "no"], [
4044   AC_CACHE_CHECK([for gcrypt 1.6.0 or later], [ac_cv_lib_gcrypt], [
4045     VLC_SAVE_FLAGS
4046     CFLAGS="${CFLAGS} ${GCRYPT_CFLAGS}"
4047     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
4048 [#include <gcrypt.h>
4049 #if GCRYPT_VERSION_NUMBER < 0x010600
4050 #error
4051 #endif]])], [
4052       ac_cv_lib_gcrypt=yes
4053     ], [
4054       ac_cv_lib_gcrypt=no
4055     ])
4056     VLC_RESTORE_FLAGS
4057   ])
4058
4059   AS_IF([test "${ac_cv_lib_gcrypt}" = "yes"], [
4060     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4061   ], [
4062     AS_IF([test "${enable_libgcrypt}" = "yes"], [
4063       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4064     ])
4065   ])
4066 ])
4067
4068 AS_IF([test -z "$GCRYPT_LIBS"], [
4069   GCRYPT_LIBS="-lgcrypt -lgpg-error"
4070 ])
4071
4072 AC_SUBST(GCRYPT_CFLAGS)
4073 AC_SUBST(GCRYPT_LIBS)
4074 AM_CONDITIONAL([HAVE_GCRYPT], [test "${ac_cv_lib_gcrypt}" = "yes"])
4075
4076 dnl
4077 dnl TLS/SSL
4078 dnl
4079 AC_ARG_ENABLE(gnutls,
4080   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4081 AS_IF([test "${enable_gnutls}" != "no"], [
4082   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4083     VLC_ADD_PLUGIN([gnutls])
4084   ], [
4085     AS_IF([test -n "${enable_gnutls}"], [
4086       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4087     ])
4088   ])
4089 ])
4090
4091
4092 dnl
4093 dnl Taglib plugin
4094 dnl
4095 AC_ARG_ENABLE(taglib,
4096   [AS_HELP_STRING([--disable-taglib],
4097     [do not use TagLib (default enabled)])])
4098 AS_IF([test "${enable_taglib}" != "no"], [
4099   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4100     VLC_ADD_PLUGIN([taglib])
4101   ], [
4102     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4103 ])
4104
4105 dnl
4106 dnl  libsecret
4107 dnl
4108 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1 >= 0.18], [use libsecret for keystore], [auto])
4109
4110 dnl
4111 dnl  kwallet
4112 dnl
4113 AC_ARG_ENABLE(kwallet,
4114   [AS_HELP_STRING([--enable-kwallet],
4115     [use kwallet (via D-Bus) for keystore (default enabled)])])
4116 AS_IF([test "${enable_kwallet}" != "no" -a "${have_dbus}" = "yes"], [
4117   VLC_ADD_PLUGIN([kwallet])
4118 ])
4119
4120 dnl
4121 dnl  Developers helper modules (should be hidden from configure help)
4122 dnl
4123 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4124 AS_IF([test "${enable_devtools}" != "no"], [
4125   VLC_ADD_PLUGIN([accesstweaks])
4126 ])
4127
4128 dnl
4129 dnl update checking system
4130 dnl
4131 AC_ARG_ENABLE(update-check,
4132   [  --enable-update-check   update checking system (default disabled)])
4133 if test "${enable_update_check}" = "yes"
4134 then
4135  AS_IF([test "${ac_cv_lib_gcrypt}" != "yes"],[
4136     AC_MSG_ERROR([libgcrypt is required for update checking system]) ])
4137   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4138   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4139   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4140 fi
4141
4142 dnl
4143 dnl OS X notification plugin
4144 dnl
4145 AC_ARG_ENABLE(osx_notifications,
4146   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4147   [enable_osx_notifications=no])
4148 AS_IF([test "${enable_osx_notifications}" != "no"], [
4149     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4150       VLC_ADD_PLUGIN([osx_notifications])
4151       VLC_ADD_LIBS([osx_notifications], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4152       VLC_ADD_OBJCFLAGS([osx_notifications], [-F${CONTRIB_DIR}])
4153       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4154     ])
4155   ]
4156 )
4157
4158 dnl
4159 dnl Libnotify notification plugin
4160 dnl
4161 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4162
4163 dnl
4164 dnl  Endianness check
4165 dnl
4166 AC_C_BIGENDIAN
4167 AS_IF([test "${ac_cv_c_bigendian}" = "yes"], [
4168   DEFS_BIGENDIAN="-DWORDS_BIGENDIAN=1"
4169 ], [
4170   DEFS_BIGENDIAN=""
4171 ])
4172 AC_SUBST(DEFS_BIGENDIAN)
4173
4174 dnl
4175 dnl Where to install KDE solid .desktop
4176 dnl
4177 AC_ARG_WITH(kde-solid,
4178   AS_HELP_STRING([--with-kde-solid=PATH],
4179                  [KDE Solid actions directory (auto)]),, [
4180
4181 if test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" ; then
4182   with_kde_solid="yes"
4183 fi
4184 ])
4185 soliddatadir=""
4186 AS_IF([test "${with_kde_solid}" != "no"], [