access: dvb: scan: remove useless includes
[vlc.git] / configure.ac
1 dnl Autoconf settings for vlc
2
3 AC_COPYRIGHT([Copyright 1999-2016 VLC authors and VideoLAN])
4
5 AC_INIT(vlc, 3.0.0-git)
6 VERSION_MAJOR=3
7 VERSION_MINOR=0
8 VERSION_REVISION=0
9 VERSION_EXTRA=0
10 VERSION_DEV=git
11
12 PKGDIR="vlc"
13 AC_SUBST(PKGDIR)
14
15 CONFIGURE_LINE="`echo "$0 $ac_configure_args" | sed -e 's/\\\/\\\\\\\/g'`"
16 CODENAME="Vetinari"
17 COPYRIGHT_YEARS="1996-2016"
18
19 AC_CONFIG_SRCDIR(src/libvlc.c)
20 AC_CONFIG_AUX_DIR(autotools)
21 AC_CONFIG_MACRO_DIR(m4)
22 AC_CONFIG_LIBOBJ_DIR(compat)
23 AC_CANONICAL_BUILD
24 AC_CANONICAL_HOST
25 AC_PRESERVE_HELP_ORDER
26
27 AM_INIT_AUTOMAKE(tar-ustar color-tests foreign)
28 AC_CONFIG_HEADERS([config.h])
29
30 AM_SILENT_RULES([yes])
31 AM_MAINTAINER_MODE([enable])
32
33 dnl
34 dnl Directories
35 dnl
36 dnl vlcincludedir="\${includedir}/\${PKGDIR}"
37 dnl AC_SUBST(vlcincludedir)
38 vlcdatadir="\${datadir}/\${PKGDIR}"
39 AC_SUBST(vlcdatadir)
40 vlclibdir="\${libdir}/\${PKGDIR}"
41 AC_SUBST(vlclibdir)
42
43 dnl
44 dnl Check for tools
45 dnl
46 AC_PROG_CC_C99
47 AC_USE_SYSTEM_EXTENSIONS
48 VLC_PROG_CC_C11
49 AC_DEFINE([_FORTIFY_SOURCE], 2, [Define to 2 to get glibc warnings.])
50 AC_DEFINE([_FILE_OFFSET_BITS], 64, [Define to 64 for large files support.])
51 AH_TOP([
52 #ifndef _REENTRANT
53 # define _REENTRANT
54 #endif
55 ])
56 AC_DEFINE([_THREAD_SAFE],, [Same as _REENTANT for some other OSes.])
57 AC_DEFINE([__LIBVLC__],, [Define within the LibVLC source code tree.])
58 AC_DEFINE([WIN32_LEAN_AND_MEAN],, [Define to limit the scope of <windows.h>.])
59
60 AM_PROG_CC_C_O
61 AC_PROG_CXX
62 AC_PROG_CPP
63 AC_PROG_OBJC
64 _AM_DEPENDENCIES([OBJC])
65 AC_PROG_EGREP
66 AC_PROG_MAKE_SET
67 AC_PROG_INSTALL
68 AM_PROG_AS
69
70 AC_ARG_VAR([DESKTOP_FILE_VALIDATE], [Validator for desktop entry files])
71 AC_CHECK_PROGS(DESKTOP_FILE_VALIDATE, [${DESKTOP_FILE_VALIDATE} desktop-file-validate], :)
72 AC_ARG_VAR([BUILDCC], [Build system C11 or C99 compiler command])
73 AC_CHECK_PROGS(BUILDCC, [c11-gcc c11 c99-gcc c99], [false])
74 AS_IF([test "$BUILDCC" = "false"], [
75   AC_MSG_ERROR([Cannot find native C99 compiler: please define BUILDCC.])
76 ])
77
78 dnl Check for compiler properties
79 AC_C_CONST
80 AC_C_INLINE
81 AC_C_RESTRICT
82 AX_CXX_COMPILE_STDCXX_11(noext, optional)
83
84 dnl Extend the --help string at the current spot.
85 AC_DEFUN([EXTEND_HELP_STRING], [m4_divert_once([HELP_ENABLE], [$1])])
86
87 dnl Allow binary package maintainer to pass a custom string to avoid
88 dnl cache problem
89 AC_ARG_WITH(binary-version,
90     AS_HELP_STRING([--with-binary-version=STRING],
91          [To avoid plugins cache problem between binary version]),[],[])
92 AS_IF([test -n "${with_binary_version}"],[
93     AC_DEFINE_UNQUOTED([DISTRO_VERSION],["${with_binary_version}"],
94          [Binary specific version])
95 ])
96
97 dnl
98 dnl  Check the operating system
99 dnl
100 HAVE_WIN64="0"
101 HAVE_IOS="0"
102 HAVE_OSX="0"
103 HAVE_TVOS="0"
104
105 case "${host_os}" in
106   "")
107     SYS=unknown
108     ;;
109   linux*)
110     SYS=linux
111     ;;
112   bsdi*)
113     SYS=bsdi
114     CFLAGS="${CFLAGS} -pthread"
115     ;;
116   freebsd*)
117     SYS=freebsd
118     CFLAGS="${CFLAGS} -pthread"
119     CPPFLAGS="${CPPFLAGS} -I/usr/local/include"
120     LDFLAGS="${LDFLAGS} -L/usr/local/lib"
121     ;;
122   openbsd*)
123     SYS=openbsd
124     CPPFLAGS="${CPPFLAGS} -I/usr/local/include -I/usr/X11R6/include"
125     LDFLAGS="${LDFLAGS} -L/usr/local/lib -L/usr/X11R6/lib/"
126     ;;
127   netbsd*)
128     SYS=netbsd
129     ;;
130   dragonfly*)
131     SYS=dragonfly
132     ;;
133   darwin*)
134
135     dnl Force gcc "-arch" flag
136     ARCH_flag=""
137     case "${host}" in
138       i?86*)
139         ARCH_flag="-arch i386"
140       ;;
141       ppc64*)
142         ARCH_flag="-arch ppc64"
143       ;;
144       ppc*)
145         ARCH_flag="-arch ppc"
146       ;;
147       x86_64*)
148         ARCH_flag="-arch x86_64"
149       ;;
150       arm*)
151         ac_cv_c_bigendian="no"
152         ac_cv_c_attribute_packed="no"
153       ;;
154     esac
155
156     SYS=darwin
157     CFLAGS="${CFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
158     CXX="${CXX} -stdlib=libc++ -std=c++11"
159     CXXFLAGS="${CXXFLAGS} -D_INTL_REDIRECT_MACROS ${ARCH_flag}"
160     CPPFLAGS="${CPPFLAGS} ${ARCH_flag}"
161     OBJCFLAGS="${OBJCFLAGS} -D_INTL_REDIRECT_MACROS -std=gnu11 ${ARCH_flag}"
162     LDFLAGS="${LDFLAGS} -Wl,-headerpad_max_install_names ${ARCH_flag}"
163     VLC_ADD_LIBS([libvlc vlc],[-Wl,-undefined,dynamic_lookup,-framework,AppKit])
164     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,CoreFoundation,-framework,CoreServices])
165
166     AC_EGREP_CPP(yes,
167             [#import <TargetConditionals.h>
168              #if TARGET_OS_IPHONE
169              yes
170              #endif],
171              [HAVE_IOS="1"],
172              [HAVE_OSX="1"])
173
174     AC_EGREP_CPP(yes,
175             [#import <TargetConditionals.h>
176              #if TARGET_OS_TV
177              yes
178              #endif],
179              [HAVE_TVOS="1"
180              HAVE_IOS="0"
181              HAVE_OSX="0"
182              ],)
183
184     dnl Allow binaries created on Lion to run on earlier releases
185     AC_EGREP_CPP(yes,
186            [#import <Cocoa/Cocoa.h>
187             #ifdef MAC_OS_X_VERSION_10_7
188             yes
189             #endif],
190             [AC_MSG_RESULT([yes])
191             AC_LIBOBJ([getdelim])
192             AC_LIBOBJ([strndup])
193             AC_LIBOBJ([strnlen])],)
194
195     dnl
196     dnl  Handle Mac OS X SDK flags
197     dnl
198     AC_ARG_WITH(macosx-sdk,
199       [AS_HELP_STRING([--with-macosx-sdk=DIR],
200         [compile using the SDK in DIR])])
201     if test "${with_macosx_sdk}" != "" ; then
202         test ! -d "${with_macosx_sdk}" && AC_MSG_ERROR([SDK "${with_macosx_sdk}" not found])
203         CPP="${CPP} -isysroot ${with_macosx_sdk}"
204         CC="${CC} -isysroot ${with_macosx_sdk}"
205         CXX="${CXX} -isysroot ${with_macosx_sdk}"
206         OBJC="${OBJC} -isysroot ${with_macosx_sdk}"
207         LD="${LD} -syslibroot ${with_macosx_sdk}"
208     fi
209     AC_ARG_WITH(macosx-version-min,
210       [AS_HELP_STRING([--with-macosx-version-min=VERSION],
211         [compile for Mac OS X VERSION and above])])
212     if test "${with_macosx_version_min}" != "" ; then
213         CPP="${CPP} -mmacosx-version-min=${with_macosx_version_min}"
214         CC="${CC} -mmacosx-version-min=${with_macosx_version_min}"
215         CXX="${CXX} -mmacosx-version-min=${with_macosx_version_min}"
216         OBJC="${OBJC} -mmacosx-version-min=${with_macosx_version_min}"
217         LD="${LD} -mmacosx_version_min=${with_macosx_version_min}"
218     fi
219     ;;
220   *mingw32* | *cygwin* | *wince* | *mingwce*)
221     AC_CHECK_TOOL(WINDRES, windres, :)
222     AC_CHECK_TOOL(OBJCOPY, objcopy, :)
223     AH_TOP([#if defined(_WIN32) && !defined(_WIN32_WINNT)])
224     AH_TOP([# define _WIN32_WINNT 0x0502 /* Windows XP SP2 */])
225     AH_TOP([#endif])
226     AC_DEFINE([_WIN32_IE], 0x0600, [Define to '0x0600' for IE 6.0 (and shell) APIs.])
227     AC_DEFINE([_UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
228     AC_DEFINE([UNICODE], [1], [Define to 1 for Unicode (Wide Chars) APIs.])
229     AC_DEFINE([_ISOC99_SOURCE], [1], [Extensions to ISO C89 from ISO C99.])
230     AC_DEFINE([_ISOC11_SOURCE], [1], [Extensions to ISO C99 from ISO C11.])
231     AC_DEFINE([_POSIX_SOURCE], [1], [IEEE Std 1003.1.])
232     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [IEEE Std 1003.1.])
233     AC_DEFINE([_XOPEN_SOURCE], [700], [POSIX and XPG 7th edition])
234     AC_DEFINE([_XOPEN_SOURCE_EXTENDED], [1], [XPG things and X/Open Unix extensions.])
235     AC_DEFINE([_BSD_SOURCE], [1], [ISO C, POSIX, and 4.3BSD things.])
236     AC_DEFINE([_SVID_SOURCE], [1], [ISO C, POSIX, and SVID things.])
237
238     case "${host_os}" in
239       *mingw32*)
240         SYS=mingw32
241         ;;
242       *cygwin*)
243         dnl Check if we are using the mno-cygwin mode in which case we are
244         dnl actually dealing with a mingw32 compiler.
245         AC_EGREP_CPP(yes,
246             [#ifdef _WIN32
247              yes
248              #endif],
249             SYS=mingw32, AC_MSG_ERROR([VLC requires -mno-cygwin]))
250         ;;
251     esac
252
253     if test "${SYS}" = "mingw32"; then
254         # DEP, ASLR, NO SEH
255         LDFLAGS="${LDFLAGS} -Wl,--nxcompat -Wl,--no-seh -Wl,--dynamicbase"
256
257         AC_CHECK_PROGS(U2D, [unix2dos todos], unix2dos)
258         ac_default_prefix="`pwd`/_win32"
259         DESTDIR="`pwd`/_win32/"
260
261         dnl
262         dnl NSIS/MSI Installer prefix and WIN64
263         dnl
264         case "${host}" in
265             amd64*|x86_64*)
266                 HAVE_WIN64="1"
267                 WINDOWS_ARCH="x64"
268                 PROGRAMFILES="PROGRAMFILES64"
269             ;;
270             *)
271                 WINDOWS_ARCH="x86"
272                 PROGRAMFILES="PROGRAMFILES"
273             ;;
274         esac
275         AC_SUBST(WINDOWS_ARCH)
276         AC_SUBST(PROGRAMFILES)
277
278     fi
279     ;;
280   *nto*)
281     SYS=nto
282     ;;
283   solaris*)
284     SYS=solaris
285     ;;
286   hpux*)
287     SYS=hpux
288     ;;
289   *os2*)
290     SYS=os2
291     LDFLAGS="${LDFLAGS} -Zomf -Zbin-files -Zargs-wild -Zhigh-mem"
292     AC_LIBOBJ([freeaddrinfo])
293     AC_LIBOBJ([gai_strerror])
294     ;;
295   *)
296     SYS="${host_os}"
297     ;;
298 esac
299 AM_CONDITIONAL(HAVE_DARWIN,  test "${SYS}" = "darwin")
300 AM_CONDITIONAL(HAVE_LINUX,   test "${SYS}" = "linux")
301 AM_CONDITIONAL(HAVE_OS2,     test "${SYS}" = "os2")
302 AM_CONDITIONAL(HAVE_WIN32,   test "${SYS}" = "mingw32")
303 AM_CONDITIONAL(HAVE_WIN64,   test "${HAVE_WIN64}" = "1")
304 AM_CONDITIONAL(HAVE_IOS,     test "${HAVE_IOS}" = "1")
305 AM_CONDITIONAL(HAVE_OSX,     test "${HAVE_OSX}" = "1")
306 AM_CONDITIONAL(HAVE_TVOS,    test "${HAVE_TVOS}" = "1")
307
308 dnl
309 dnl Sadly autoconf does not think about testing foo.exe when ask to test
310 dnl for program foo on win32
311 case "${build_os}" in
312     cygwin|msys)
313         ac_executable_extensions=".exe"
314     ;;
315     os2*)
316         BUILDEXEEXT=".exe"
317     ;;
318     *)
319     ;;
320 esac
321 AC_SUBST(BUILDEXEEXT)
322
323 dnl Android is linux, but a bit different
324 AS_IF([test "$SYS" = linux],[
325     AC_MSG_CHECKING([for an Android system])
326     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
327         [[#ifndef __ANDROID__
328          # error Not Android
329          #endif
330         ]],[[;]])
331     ],[
332       HAVE_ANDROID="1"
333       AC_MSG_RESULT([yes])
334     ],[
335       AC_MSG_RESULT([no])
336     ])
337 ])
338 AM_CONDITIONAL(HAVE_ANDROID, test "${HAVE_ANDROID}" = "1")
339
340 dnl Tizen (minimum SDK version: 2.3)
341 AS_IF([test "$SYS" = linux],[
342     AC_MSG_CHECKING([for Tizen])
343     AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
344         [[#include <tizen.h>
345         ]],[[;]])
346     ],[
347       HAVE_TIZEN="1"
348       AC_DEFINE([HAVE_TIZEN_SDK], [1], [Define to 1 if vlc is built against Tizen SDK])
349       AC_MSG_RESULT([yes])
350     ],[
351       AC_MSG_RESULT([no])
352     ])
353 ])
354 AM_CONDITIONAL(HAVE_TIZEN, test "${HAVE_TIZEN}" = "1")
355
356 dnl
357 dnl  Check for the contrib directory
358 dnl
359 AC_ARG_WITH(contrib,
360   [AS_HELP_STRING([--with-contrib[=DIR]],
361     [search for 3rd party libraries in DIR/include and DIR/lib])
362 ])
363 AC_MSG_CHECKING([for 3rd party libraries path])
364 AS_IF([test -z "${with_contrib}" || test "${with_contrib}" = "yes"], [
365   CONTRIB_DIR="${srcdir}/contrib/${host}"
366   AS_IF([test ! -d "${CONTRIB_DIR}"], [
367     echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
368     CONTRIB_DIR="${srcdir}/contrib/`$CC -dumpmachine`"
369     AS_IF([test ! -d "${CONTRIB_DIR}"], [
370       echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
371       CONTRIB_DIR="${srcdir}/extras/contrib/hosts/${host}"
372       AS_IF([test ! -d "${CONTRIB_DIR}"], [
373         echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
374         CONTRIB_DIR="${srcdir}/extras/contrib/hosts/`$CC -dumpmachine`"
375         AS_IF([test ! -d "${CONTRIB_DIR}"], [
376           echo "${CONTRIB_DIR} not found" >&AS_MESSAGE_LOG_FD
377           CONTRIB_DIR=""
378           AC_MSG_RESULT([not found])
379         ])
380       ])
381     ])
382   ])
383 ], [
384   AS_IF([test "${with_contrib}" != "no"], [
385     CONTRIB_DIR="${with_contrib}"
386   ], [
387     CONTRIB_DIR=""
388     AC_MSG_RESULT([disabled])
389   ])
390 ])
391 AS_IF([test -n "${CONTRIB_DIR}"], [
392   AS_IF([test -d "${CONTRIB_DIR}/lib"],[
393     CONTRIB_DIR=`cd "${CONTRIB_DIR}" && pwd`
394   ], [
395     echo "${CONTRIB_DIR}/lib not found" >&AS_MESSAGE_LOG_FD
396     CONTRIB_DIR=""
397     AC_MSG_RESULT([not usable])
398   ])
399
400 ])
401 AS_IF([test -n "${CONTRIB_DIR}"], [
402   AC_MSG_RESULT([${CONTRIB_DIR}])
403   export PATH=${CONTRIB_DIR}/bin:$PATH
404   CPPFLAGS="${CPPFLAGS} -I${CONTRIB_DIR}/include"
405   CFLAGS="${CFLAGS} -I${CONTRIB_DIR}/include"
406   CXXFLAGS="${CXXFLAGS} -I${CONTRIB_DIR}/include"
407   OBJCFLAGS="${OBJCFLAGS} -I${CONTRIB_DIR}/include"
408   export PKG_CONFIG_PATH="${CONTRIB_DIR}/lib/pkgconfig:$PKG_CONFIG_PATH"
409   LDFLAGS="${LDFLAGS} -L${CONTRIB_DIR}/lib"
410
411   AS_IF([test "${SYS}" = "darwin"], [
412     export LD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$LD_LIBRARY_PATH"
413     export DYLD_LIBRARY_PATH="${CONTRIB_DIR}/lib:$DYLD_LIBRARY_PATH"
414   ])
415 ], [
416   AS_IF([test -n "${with_contrib}" && test "${with_contrib}" != "no"], [
417     AC_MSG_ERROR([Third party libraries not found!])
418   ])
419 ])
420 AC_SUBST(CONTRIB_DIR)
421
422 dnl Add extras/tools to the PATH
423 TOOLS_DIR="${srcdir}/extras/tools/build/bin"
424 AS_IF([test -d "${TOOLS_DIR}"], [
425     TOOLS_DIR=`cd "${TOOLS_DIR}" && pwd`
426     export PATH="${TOOLS_DIR}":$PATH
427 ])
428
429 dnl
430 dnl  Libtool
431 dnl  It's very bad, but our former custom system was worst
432 dnl  -- Courmisch
433 dnl
434
435 dnl override platform specific check for dependent libraries
436 dnl otherwise libtool linking of shared libraries will
437 dnl fail on anything other than pass_all.
438 AC_CACHE_VAL(lt_cv_deplibs_check_method,
439     [lt_cv_deplibs_check_method=pass_all])
440
441 LT_INIT([dlopen win32-dll shared disable-static])
442 LT_LANG([C++])
443 LT_LANG([Windows Resource])
444
445 DOLT
446
447 lt_cv_deplibs_check_method=pass_all
448
449 AS_IF([test "${enable_shared}" = "no" -a "${enable_vlc}" != "no"], [
450   AC_MSG_ERROR([VLC is based on plugins. Shared libraries cannot be disabled.])
451 ])
452
453 dnl
454 dnl Gettext stuff
455 dnl
456 AM_GNU_GETTEXT_VERSION([0.19.6])
457 AM_GNU_GETTEXT([external], [need-formatstring-macros])
458
459 dnl
460 dnl Iconv stuff
461 dnl
462 AM_ICONV
463
464 dnl
465 dnl checks for mingw
466 AS_IF([test "${SYS}" = "mingw32"], [
467
468 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
469 #if !defined(__MINGW32__)
470 # error Not compiling with mingw
471 #endif
472     ])], [
473
474 dnl Check for broken versions of mingw-runtime compatability library
475     AC_MSG_CHECKING(for broken mingw-runtime)
476     AC_PREPROC_IFELSE([AC_LANG_SOURCE([
477 #include <_mingw.h>
478 #if defined(__MINGW64_VERSION_MAJOR)
479 # if __MINGW64_VERSION_MAJOR < 3
480 #  error Attempting to use mingw-runtime with broken vsnprintf and direct2d support
481 # endif
482 #elif __MINGW32_MAJOR_VERSION == 3 && __MINGW32_MINOR_VERSION < 15
483 # error Attempting to use mingw-runtime with broken vsnprintf support
484 #endif
485     ])], [
486         AC_MSG_RESULT([ok])
487     ], [
488         AC_MSG_RESULT([present])
489         AC_MSG_ERROR([LibVLC requires mingw-runtime version 3.15 or higher, or mingw-w64 version 3.0 or higher!])
490     ])
491
492     dnl force use of mingw provided c99 *printf over msvcrt
493     CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO=1"
494
495     dnl Add WinMainCRTStartup entry point to show it's a WinMain application
496     VLC_ADD_LDFLAGS([vlc],[-mwindows])
497
498     dnl Check for the need to include the mingwex lib for mingw32
499     VLC_SAVE_FLAGS
500     AC_CHECK_LIB(mingwex,opendir,
501         AC_CHECK_LIB(mingw32,opendir,,
502             [VLC_ADD_LIBS([libvlccore],[-lmingwex])])
503     )
504     VLC_RESTORE_FLAGS
505     ], [
506         AC_MSG_RESULT([Not compiling with mingw])
507     ])
508
509     dnl Check for fnative-struct or mms-bitfields support for mingw32
510     VLC_SAVE_FLAGS
511     CFLAGS="${CFLAGS} -mms-bitfields"
512     CXXFLAGS="${CXXFLAGS} -mms-bitfields"
513     AC_CACHE_CHECK([if \$CC accepts -mms-bitfields],
514         [ac_cv_c_mms_bitfields],
515         [AC_TRY_COMPILE([],,ac_cv_c_mms_bitfields=yes, ac_cv_c_mms_bitfields=no)])
516     if test "${ac_cv_c_mms_bitfields}" = "no"; then
517         VLC_RESTORE_FLAGS
518         CFLAGS="${CFLAGS} -fnative-struct"
519         CXXFLAGS="${CXXFLAGS} -fnative-struct"
520         AC_CACHE_CHECK([if \$CC accepts -fnative-struct],
521             [ac_cv_c_fnative_struct],
522             [AC_TRY_COMPILE([],,ac_cv_c_fnative_struct=yes, ac_cv_c_fnative_struct=no)])
523         "${ac_cv_c_fnative_struct}" = "no" && VLC_RESTORE_FLAGS
524     fi
525 ])
526
527 AC_ARG_ENABLE(winstore_app,
528      AS_HELP_STRING([--enable-winstore-app],
529                     [Build targetted for Windows Store apps (default disabled)]))
530
531 vlc_winstore_app=0
532 AS_IF([test "${SYS}" = "mingw32"],[
533   AS_IF([test "${enable_winstore_app}" = "yes"], [
534     vlc_winstore_app=1
535      VLC_ADD_LIBS([libvlccore], [-lole32 -lruntimeobject])
536      AC_LIBOBJ([gai_strerror])
537     ],[
538      VLC_ADD_LIBS([libvlccore],[-lwinmm])
539     ])
540   ])
541 AC_DEFINE_UNQUOTED(VLC_WINSTORE_APP, ${vlc_winstore_app}, [Define to 1 if you want to build for Windows Store apps])
542 AM_CONDITIONAL([HAVE_WINSTORE], [test "$vlc_winstore_app" = "1"])
543
544
545 dnl
546 dnl Buggy glibc prevention. Purposedly not cached.
547 dnl See sourceware.org bugs 5058 and 5443.
548 dnl Ubuntu alone has 20 bug numbers for this...
549 dnl
550 AC_MSG_CHECKING(for buggy GNU/libc versions)
551 AC_PREPROC_IFELSE([AC_LANG_SOURCE([
552 #include <limits.h>
553 #if defined (__GLIBC__) && (__GLIBC__ == 2) \
554   && (__GLIBC_MINOR__ >= 5) && (__GLIBC_MINOR__ <= 7)
555 # error GNU/libc with dcgettext killer bug!
556 #endif
557 ])], [
558   AC_MSG_RESULT([not present])
559 ], [
560   AC_MSG_RESULT([found])
561   AS_IF([test "x${enable_nls}" != "xno"], [
562     AC_MSG_ERROR([Buggy GNU/libc (version 2.5 - 2.7) present. VLC would crash; there is no viable
563 work-around for this. Check with your distribution vendor on how to update the
564 glibc run-time. Alternatively, build with --disable-nls.])
565   ])
566 ])
567
568 dnl Plugin compilation stuff
569
570 VLC_LIBRARY_SUFFIX
571
572 dnl Check for system libs needed
573 need_libc=false
574
575 dnl Check for usual libc functions
576 AC_CHECK_DECLS([nanosleep],,,[#include <time.h>])
577 AC_CHECK_FUNCS([daemon fcntl flock fstatvfs fork getenv getpwuid_r isatty lstat memalign mkostemp mmap open_memstream openat pread posix_fadvise posix_madvise setlocale stricmp strnicmp strptime uselocale pthread_cond_timedwait_monotonic_np pthread_condattr_setclock])
578 AC_REPLACE_FUNCS([atof atoll dirfd fdopendir ffsll flockfile fsync getdelim getpid lldiv nrand48 poll posix_memalign recvmsg rewind sendmsg setenv strcasecmp strcasestr strdup strlcpy strndup strnlen strnstr strsep strtof strtok_r strtoll swab tdestroy timegm timespec_get strverscmp])
579 AC_REPLACE_FUNCS([gettimeofday])
580 AC_CHECK_FUNCS(fdatasync,,
581   [AC_DEFINE(fdatasync, fsync, [Alias fdatasync() to fsync() if missing.])
582 ])
583
584 dnl mingw64 implements those as static inline, not functions with C linkage
585 VLC_REPLACE_DECL([asprintf], [#include <stdio.h>])
586 VLC_REPLACE_DECL([vasprintf], [#include <stdio.h>])
587 VLC_REPLACE_DECL([gmtime_r], [#include <time.h>])
588 VLC_REPLACE_DECL([localtime_r], [#include <time.h>])
589
590 dnl C11 static_assert()
591 AC_MSG_CHECKING([for static_assert in assert.h])
592 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <assert.h>], [
593 static_assert(1, "The impossible happened.");
594 ])], [
595   AC_MSG_RESULT([yes])
596   AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if <assert.h> defines static_assert.])
597 ], [
598   AC_MSG_RESULT([no])
599 ])
600
601 # Windows CE does not have strcoll()
602 AC_FUNC_STRCOLL
603
604 dnl Check for non-standard system calls
605 case "$SYS" in
606   "linux")
607     AC_CHECK_FUNCS([accept4 pipe2 eventfd vmsplice sched_getaffinity])
608     ;;
609   "mingw32")
610     AC_CHECK_FUNCS([_lock_file])
611     ;;
612 esac
613
614 AH_BOTTOM([#include <vlc_fixups.h>])
615
616 dnl Check for struct pollfd
617 AC_CHECK_TYPES([struct pollfd],,,
618 [#include <sys/types.h>
619 #if HAVE_POLL
620 # include <poll.h>
621 #elif defined (_WIN32)
622 # include <winsock2.h>
623 #endif
624 ])
625
626 dnl Check for struct timespec
627 AC_CHECK_TYPES([struct timespec],,,
628 [#include <time.h>])
629
630 dnl Checks for socket stuff
631 VLC_SAVE_FLAGS
632 SOCKET_LIBS=""
633 AC_SEARCH_LIBS(connect, [socket], [
634   AS_IF([test "$ac_cv_search_connect" != "none required"], [
635     SOCKET_LIBS="$ac_cv_search_connect"
636   ])
637 ], [
638   AS_IF([test "${SYS}" = "mingw32"], [
639     SOCKET_LIBS="-lws2_32"
640   ])
641 ])
642
643 AC_SEARCH_LIBS([inet_pton], [nsl], [
644  AS_IF([test "$ac_cv_search_inet_pton" != "none required"], [
645     SOCKET_LIBS="$ac_cv_search_inet_pton $SOCKET_LIBS"
646   ])
647 ],, [${SOCKET_LIBS}])
648
649 LIBS="${LIBS} ${SOCKET_LIBS}"
650 AC_LINK_IFELSE([
651     AC_LANG_PROGRAM([#ifdef _WIN32
652         # if _WIN32_WINNT < 0x600
653         #  error Needs vista+
654         # endif
655         #include <ws2tcpip.h>
656         #else
657         #include <sys/socket.h>
658         #include <arpa/inet.h>
659         #endif], [
660         char dst[[sizeof(struct in_addr)]];
661         inet_pton(AF_INET, "127.0.0.1", dst);
662     ])],[AC_DEFINE([HAVE_INET_PTON],[1],[Define to 1 if you have inet_pton function])],[AC_LIBOBJ([inet_pton])])
663 AC_CHECK_FUNCS([if_nameindex if_nametoindex])
664 VLC_RESTORE_FLAGS
665 AC_SUBST(SOCKET_LIBS)
666
667 dnl Check for socklen_t
668 AH_TEMPLATE(socklen_t, [Define to `int' if <sys/socket.h> does not define.])
669 AC_CACHE_CHECK([for socklen_t in sys/socket.h], dnl ` (fix VIM syntax highlight
670 ac_cv_type_socklen_t,
671 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
672 [#include <sys/types.h>
673 #ifdef _WIN32
674 # include <winsock2.h>
675 # include <ws2tcpip.h>
676 #else
677 # include <sys/socket.h>
678 #endif]], [[socklen_t len; len = 0;]])],
679 ac_cv_type_socklen_t=yes,
680 ac_cv_type_socklen_t=no)])
681 AS_IF([test "$ac_cv_type_socklen_t" = no],
682  [AC_DEFINE(socklen_t, int)])
683
684 dnl Check for struct sockaddr_storage
685 AH_TEMPLATE(sockaddr_storage, [Define to `sockaddr' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
686 AH_TEMPLATE(ss_family, [Define to `sa_family' if <sys/socket.h> does not define.]) dnl ` (fix VIM syntax highlight
687 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_struct_sockaddr_storage,
688   [AC_TRY_COMPILE(
689     [#include <sys/types.h>
690      #if defined( _WIN32 )
691      # include <winsock2.h>
692      #else
693      # include <sys/socket.h>
694      #endif], [struct sockaddr_storage addr;],
695      ac_cv_struct_sockaddr_storage=yes,
696      ac_cv_struct_sockaddr_storage=no)])
697 AS_IF([test "${ac_cv_struct_sockaddr_storage}" = no], [
698   AC_DEFINE(sockaddr_storage, sockaddr)
699   AC_DEFINE(ss_family, sa_family)
700 ])
701
702 dnl FreeBSD has a gnugetopt library for this:
703 GNUGETOPT_LIBS=""
704 AC_CHECK_FUNC(getopt_long,, [
705   AC_CHECK_LIB([gnugetopt],[getopt_long], [
706     GNUGETOPT_LIBS="-lgnugetopt"
707   ])
708 ])
709 AC_SUBST(GNUGETOPT_LIBS)
710
711 AC_CHECK_LIB(m,cos,[
712   LIBM="-lm"
713 ], [
714   LIBM=""
715 ])
716 AC_SUBST(LIBM)
717
718 AC_CHECK_LIB(m,lrintf, [
719   AC_DEFINE(HAVE_LRINTF, 1, [Define to 1 if you have the lrintf function])
720   VLC_ADD_LIBS([skins2],[-lm])
721 ])
722 AC_CHECK_LIB(m,nanf,
723   AC_DEFINE(HAVE_NANF, 1, [Define to 1 if you have the NANF function])
724 )
725
726 dnl Check for dynamic plugins
727 LIBDL=""
728 have_dynamic_objects="no"
729 VLC_SAVE_FLAGS
730 AC_SEARCH_LIBS(dlsym, [dl svld], [
731   AS_IF([test "$ac_cv_search_dlsym" != "none required"], [
732     LIBDL="$ac_cv_search_dlsym"
733   ])
734   have_dynamic_objects="yes"
735 ])
736 VLC_RESTORE_FLAGS
737
738 # Windows
739 AS_IF([test "${SYS}" = "mingw32"], [
740   LIBDL=""
741   have_dynamic_objects="yes" #assume we can use shared objects
742 ])
743
744 AS_IF([test "${enable_shared}" = "no"], [
745   have_dynamic_objects=no
746 ])
747 AM_CONDITIONAL(HAVE_DYNAMIC_PLUGINS, [test "${have_dynamic_objects}" != "no"])
748
749 AC_SUBST(LIBDL)
750
751 dnl Check for thread library
752 LIBPTHREAD=""
753 AS_IF([test "${SYS}" != "mingw32"], [
754   VLC_SAVE_FLAGS
755   LIBS=""
756   AC_SEARCH_LIBS(pthread_rwlock_init, pthread pthreads c_r, [
757     AS_IF([test "$ac_cv_search_pthread_rwlock_init" != "none required"], [
758       LIBPTHREAD="$ac_cv_search_pthread_rwlock_init"
759     ])
760   ])
761   VLC_RESTORE_FLAGS
762 ])
763 AC_SUBST(LIBPTHREAD)
764
765 AC_SEARCH_LIBS([clock_nanosleep], [rt pthread], [
766   AS_IF([test "$ac_cv_search_clock_nanosleep" != "none required"], [
767     LIBRT="$ac_cv_search_clock_nanosleep"
768   ])
769 ], [
770   AC_SEARCH_LIBS([nanosleep], [rt pthread posix4], [
771     AS_IF([test "$ac_cv_search_nanosleep" != "none required"], [
772       LIBRT="$ac_cv_search_nanosleep"
773     ])
774   ])
775 ])
776 AC_SUBST(LIBRT)
777
778 dnl
779 dnl Check for headers
780 dnl
781
782 dnl  POSIX
783 AC_CHECK_HEADERS([arpa/inet.h pthread.h search.h sys/shm.h sys/socket.h])
784 AC_CHECK_HEADERS([net/if.h], [], [],
785 [
786 #include <sys/types.h>
787 #include <sys/socket.h>
788 ])
789 AC_CHECK_HEADER([syslog.h], [have_syslog="yes"], [have_syslog="no"])
790 AM_CONDITIONAL([HAVE_SYSLOG], [test "$have_syslog" = "yes"])
791
792 dnl  BSD
793 AC_CHECK_HEADERS([netinet/udplite.h sys/param.h sys/mount.h])
794
795 dnl  GNU/Linux
796 AC_CHECK_HEADERS([features.h getopt.h linux/dccp.h linux/magic.h mntent.h sys/eventfd.h])
797
798 dnl  MacOS
799 AC_CHECK_HEADERS([xlocale.h])
800
801 dnl LP64 and LLP64 architectures had better define ssize_t by themselves...
802 AH_TEMPLATE(ssize_t, [Define to `int' if <stddef.h> does not define.]) dnl ` (fix VIM syntax highlight
803 AC_CHECK_TYPE(ssize_t,, [
804   AC_DEFINE(ssize_t, int)
805 ])
806
807 dnl It seems that autoconf detects pkg-config only during the first
808 dnl PKG_CHECK_MODULES from configure.ac - which makes sense. But in our case,
809 dnl it is nested within a conditional block, so it was not working right.
810 dnl Make PKG_CONFIG_PATH precious so that it appears in the help and get saved
811 AC_ARG_VAR(PKG_CONFIG_PATH,
812        [Paths where to find .pc not at the default location])
813 PKG_PROG_PKG_CONFIG()
814
815 dnl On some OS we need static linking
816 AS_IF([test -n "${PKG_CONFIG}" ],[
817     AS_IF([test "${SYS}" = "mingw32" -o "${SYS}" = "darwin" -o "${SYS}" = "os2" ],[
818         PKG_CONFIG="${PKG_CONFIG} --static"
819     ])
820 ])
821
822
823 dnl
824 dnl Check for zlib.h and -lz along with system -lminizip if available
825 dnl
826 AC_CHECK_HEADERS(zlib.h, [ have_zlib=yes ], [ have_zlib=no ])
827 AM_CONDITIONAL(HAVE_ZLIB, [ test "${have_zlib}" = "yes" ])
828 if test "${have_zlib}" = "yes"
829 then
830   VLC_ADD_LIBS([skins2 sap unzip zip],[-lz])
831   PKG_CHECK_MODULES([MINIZIP], [minizip] , [ have_minizip=yes ], [
832     AC_CHECK_HEADERS([unzip.h], [
833       have_minizip=yes
834       MINIZIP_LIBS="-lminizip -lz"
835     ], [
836       VLC_ADD_CPPFLAGS([skins2], [-I\\\$(top_srcdir)/modules/access/zip/unzip])
837       VLC_ADD_LIBS([skins2], [\\\$(top_builddir)/modules/libunzip.la])
838       have_minizip=no
839     ])
840   ])
841   VLC_ADD_CPPFLAGS([skins2],[$MINIZIP_CFLAGS])
842   VLC_ADD_LIBS([skins2],[$MINIZIP_LIBS])
843 fi
844 AM_CONDITIONAL(HAVE_MINIZIP, [ test "${have_minizip}" = "yes" ])
845
846
847 dnl
848 dnl Domain name i18n support via GNU libidn
849 dnl
850 PKG_CHECK_MODULES([IDN], [libidn], [
851   have_libidn="yes"
852   AC_DEFINE([HAVE_IDN], 1, [Define to 1 if you have GNU libidn.])
853 ], [
854   have_libidn="no"
855 ])
856
857
858 dnl Check for dbus
859 AC_ARG_ENABLE(dbus,
860   [AS_HELP_STRING([--enable-dbus],
861     [compile D-Bus message bus support (default enabled)])])
862 have_dbus="no"
863 AS_IF([test "${enable_dbus}" != "no"], [
864   PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.6.0], [
865     have_dbus="yes"
866   ], [
867     AS_IF([test -n "${enable_dbus}"], [
868       AC_MSG_ERROR([${DBUS_PKG_ERRORS}.])
869     ], [
870       AC_MSG_WARN([${DBUS_PKG_ERRORS}.])
871     ])
872   ])
873 ])
874 AM_CONDITIONAL([HAVE_DBUS], [test "${have_dbus}" = "yes"])
875
876
877 dnl Check for systemd
878 PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [
879   have_systemd="yes"
880 ], [
881   AC_MSG_WARN([${SYSTEMD_PKG_ERRORS}.])
882 ])
883 AM_CONDITIONAL([HAVE_SYSTEMD], [test "${have_systemd}" = "yes"])
884
885
886 dnl Check for ntohl, etc.
887 VLC_SAVE_FLAGS
888 CFLAGS="${CFLAGS} -Wall -Werror"
889 AC_CACHE_CHECK([for ntohl in sys/param.h],
890     [ac_cv_c_ntohl_sys_param_h],
891     [     AC_TRY_COMPILE([#include <sys/param.h>],
892         [int meuh; ntohl(meuh);],
893         ac_cv_c_ntohl_sys_param_h=yes, ac_cv_c_ntohl_sys_param_h=no)])
894 if test "${ac_cv_c_ntohl_sys_param_h}" != "no"; then
895     AC_DEFINE(NTOHL_IN_SYS_PARAM_H, 1, Define if <sys/param.h> defines ntohl.)
896 fi
897 VLC_RESTORE_FLAGS
898
899 EXTEND_HELP_STRING([Optimization options:])
900 dnl
901 dnl  Compiler warnings
902 dnl
903
904 RDC_PROG_CC_WFLAGS([all extra sign-compare undef pointer-arith bad-function-cast write-strings missing-prototypes volatile-register-var error-implicit-function-declaration init-self logical-op format-security])
905 RDC_PROG_CC_FLAGS([-pipe])
906 AC_LANG_PUSH([C++])
907 RDC_PROG_CXX_WFLAGS([all extra sign-compare undef pointer-arith volatile-register-var format-security])
908 AC_LANG_POP([C++])
909
910 dnl
911 dnl  Debugging mode
912 dnl
913 AC_ARG_ENABLE(debug,
914   [AS_HELP_STRING([--enable-debug],
915     [build with run-time assertions (default disabled)])],,
916   [enable_debug="no"])
917 AH_TEMPLATE(NDEBUG,
918             [Define to 1 if debug code should NOT be compiled])
919 AS_IF([test "${enable_debug}" != "no"], [
920   AC_CHECK_HEADERS([valgrind/valgrind.h])
921 ], [
922   AC_DEFINE(NDEBUG)
923 ])
924
925 dnl
926 dnl  Profiling
927 dnl
928 AC_ARG_ENABLE(gprof,
929   [AS_HELP_STRING([--enable-gprof],[profile with gprof (default disabled)])],,
930   [enable_gprof="no"])
931 AS_IF([test "${enable_gprof}" != "no"], [
932   CFLAGS="${CFLAGS} -pg"
933   CXXFLAGS="${CXXFLAGS} -pg"
934   OBJCFLAGS="${OBJCFLAGS} -pg"
935   LDFLAGS="${LDFLAGS} -pg"
936 ])
937
938 AC_ARG_ENABLE(cprof,
939   [AS_HELP_STRING([--enable-cprof],[profile with cprof (default disabled)])],,
940   [enable_cprof="no"])
941 AS_IF([test "${enable_gprof}" != "no"], [
942   CFLAGS="${CFLAGS} -finstrument-functions"
943   CXXFLAGS="${CXXFLAGS} -finstrument-functions"
944   OBJCFLAGS="${OBJCFLAGS} -finstrument-functions"
945   LDFLAGS="${LDFLAGS} -finstrument-functions"
946 ])
947
948 dnl
949 dnl  Test coverage
950 dnl
951 AC_ARG_ENABLE(coverage,
952   [AS_HELP_STRING([--enable-coverage],
953     [build for test coverage (default disabled)])],,
954   [enable_coverage="no"])
955 AS_IF([test "${enable_coverage}" != "no"], [
956   CFLAGS="-fprofile-arcs -ftest-coverage ${CFLAGS}"
957   CXXFLAGS="-fprofile-arcs -ftest-coverage ${CXXFLAGS}"
958   LDFLAGS="-lgcov ${LDFLAGS}"
959 ])
960
961 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "os2"], [
962   VLC_SAVE_FLAGS
963   CFLAGS="${CFLAGS} -fvisibility=hidden"
964   CXXFLAGS="${CXXFLAGS} -fvisibility=hidden"
965   OBJCFLAGS="${OBJCFLAGS} -fvisibility=hidden"
966   AC_CACHE_CHECK([if $CC accepts -fvisibility=hidden],
967                  [ac_cv_c_visibility_hidden], [
968     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
969       ac_cv_c_visibility_hidden=yes
970     ], [
971       ac_cv_c_visibility_hidden=no
972     ])
973   ])
974   AS_IF([test "${ac_cv_c_visibility_hidden}" = "no"], [VLC_RESTORE_FLAGS])
975 ])
976
977
978 dnl
979 dnl  Enable/disable optimizations
980 dnl
981 AC_ARG_ENABLE(optimizations,
982   [AS_HELP_STRING([--disable-optimizations],
983     [disable compiler optimizations (default enabled)])],,
984   [enable_optimizations="yes"])
985
986 dnl Check for various optimization flags
987 AS_IF([test "${enable_optimizations}" != "no"], [
988
989   dnl -O3 only in production builds
990   AS_IF([test "${enable_debug}" = "no"], [
991     VLC_SAVE_FLAGS
992     CFLAGS="${CFLAGS} -O3"
993     CXXFLAGS="${CXXFLAGS} -O3"
994     OBJCFLAGS="${OBJCFLAGS} -O3"
995     AC_CACHE_CHECK([if $CC accepts -O3],  [ac_cv_c_o3], [
996       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
997         ac_cv_c_o3=yes
998       ], [
999         ac_cv_c_o3=no
1000       ])
1001     ])
1002     AS_IF([test "${ac_cv_c_o3}" = "no"], [VLC_RESTORE_FLAGS])
1003   ])
1004
1005   dnl Check for -ffast-math
1006   VLC_SAVE_FLAGS
1007   CFLAGS="${CFLAGS} -ffast-math"
1008   CXXFLAGS="${CXXFLAGS} -ffast-math"
1009   OBJCFLAGS="${OBJCFLAGS} -ffast-math"
1010   AC_CACHE_CHECK([if $CC accepts -ffast-math], [ac_cv_c_fast_math], [
1011     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1012       ac_cv_c_fast_math=yes
1013     ], [
1014       ac_cv_c_fast_math=no
1015     ])
1016   ])
1017   AS_IF([test "${ac_cv_c_fast_math}" = "no"], [VLC_RESTORE_FLAGS])
1018   AH_BOTTOM([
1019 #ifndef __FAST_MATH__
1020 # ifndef _MSC_VER
1021 #  pragma STDC FENV_ACCESS OFF
1022 #  pragma STDC FP_CONTRACT ON
1023 # else
1024 #  pragma fenv_access(off)
1025 #  pragma fp_contract(on)
1026 # endif
1027 #endif
1028 ])
1029
1030   dnl Check for -funroll-loops
1031   VLC_SAVE_FLAGS
1032   CFLAGS="${CFLAGS} -funroll-loops"
1033   CXXFLAGS="${CXXFLAGS} -funroll-loops"
1034   OBJCFLAGS="${OBJCFLAGS} -funroll-loops"
1035   AC_CACHE_CHECK([if $CC accepts -funroll-loops], [ac_cv_c_unroll_loops], [
1036     AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1037       ac_cv_c_unroll_loops=yes
1038     ], [
1039       ac_cv_c_unroll_loops=no
1040     ])
1041   ])
1042   AS_IF([test "${ac_cv_c_unroll_loops}" = "no"], [VLC_RESTORE_FLAGS])
1043
1044   AS_IF([test "$enable_debug" = "no"], [
1045     dnl Check for -fomit-frame-pointer
1046     VLC_SAVE_FLAGS
1047     CFLAGS="${CFLAGS} -fomit-frame-pointer"
1048     CXXFLAGS="${CXXFLAGS} -fomit-frame-pointer"
1049     OBJCFLAGS="${OBJCFLAGS} -fomit-frame-pointer"
1050     AC_CACHE_CHECK([if $CC accepts -fomit-frame-pointer],
1051       [ac_cv_c_omit_frame_pointer], [
1052       AC_COMPILE_IFELSE([AC_LANG_PROGRAM()], [
1053         ac_cv_c_omit_frame_pointer=yes
1054       ], [
1055         ac_cv_c_omit_frame_pointer=no
1056       ])
1057     ])
1058     AS_IF([test "${ac_cv_c_omit_frame_pointer}" = "no"], [VLC_RESTORE_FLAGS])
1059   ])
1060 ])
1061
1062 VLC_SAVE_FLAGS
1063 LDFLAGS="${LDFLAGS} -Wl,-Bsymbolic"
1064 AC_CACHE_CHECK([if linker supports -Bsymbolic], [ac_cv_ld_bsymbolic], [
1065   AC_TRY_LINK([],, [
1066     ac_cv_ld_bsymbolic="-Wl,-Bsymbolic"
1067   ], [
1068     ac_cv_ld_bsymbolic=""
1069   ])
1070 ])
1071 VLC_RESTORE_FLAGS
1072 SYMBOLIC_LDFLAGS="${ac_cv_ld_bsymbolic}"
1073 AC_SUBST(SYMBOLIC_LDFLAGS)
1074
1075 dnl Checks for __attribute__(aligned()) directive
1076 VLC_SAVE_FLAGS
1077 CFLAGS="${CFLAGS} -Werror"
1078 AC_CACHE_CHECK([__attribute__ ((aligned ())) support],
1079     [ac_cv_c_attribute_aligned],
1080     [ac_cv_c_attribute_aligned=0
1081     for ac_cv_c_attr_align_try in 2 4 8 16 32 64; do
1082         AC_TRY_COMPILE([],
1083         [static char c __attribute__ ((aligned(${ac_cv_c_attr_align_try}))) = 0; return c;],
1084         [ac_cv_c_attribute_aligned="${ac_cv_c_attr_align_try}"])
1085     done])
1086 VLC_RESTORE_FLAGS
1087 if test "${ac_cv_c_attribute_aligned}" != "0"; then
1088     AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX],
1089         [${ac_cv_c_attribute_aligned}],[Maximum supported data alignment])
1090 fi
1091
1092 dnl Check for __attribute__((packed))
1093 AC_CACHE_CHECK([for __attribute__((packed))],
1094   [ac_cv_c_attribute_packed],
1095   [ac_cv_c_attribute_packed=no
1096    AC_TRY_COMPILE(, [struct __attribute__((__packed__)) foo { int a; } b; (void)b;],
1097                     [ac_cv_c_attribute_packed=yes])])
1098 if test "${ac_cv_c_attribute_packed}" != "no"; then
1099   AC_DEFINE(HAVE_ATTRIBUTE_PACKED, 1, Support for __attribute__((packed)) for structs)
1100 fi
1101
1102 dnl
1103 dnl  Check the CPU
1104 dnl
1105 case "${host_cpu}" in
1106   "")
1107     ARCH=unknown
1108     ;;
1109   *)
1110     ARCH="${host_cpu}"
1111     ;;
1112 esac
1113
1114 dnl Check for backtrace() support
1115 AC_CHECK_HEADERS(execinfo.h)
1116 AC_CHECK_FUNCS(backtrace)
1117
1118 dnl
1119 dnl  default modules
1120 dnl
1121 ALIASES="${ALIASES} cvlc rvlc"
1122
1123 dnl
1124 dnl  Accelerated modules
1125 dnl
1126
1127 dnl  Check for fully working MMX intrinsics
1128 dnl  We need support for -mmmx, we need <mmintrin.h>, and we also need a
1129 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1130 AC_ARG_ENABLE(mmx,
1131   [AS_HELP_STRING([--disable-mmx],
1132     [disable MMX optimizations (default auto)])],,[
1133   case "${host_cpu}" in
1134     i?86|x86_64)
1135       enable_mmx="yes"
1136       ;;
1137     *)
1138       enable_mmx="no"
1139       ;;
1140   esac
1141 ])
1142 have_mmx="no"
1143 have_mmxext="no"
1144 AS_IF([test "${enable_mmx}" != "no"], [
1145   ARCH="${ARCH} mmx"
1146   VLC_SAVE_FLAGS
1147   CFLAGS="${CFLAGS} -mmmx"
1148   AC_CACHE_CHECK([if $CC groks MMX intrinsics], [ac_cv_c_mmx_intrinsics], [
1149     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1150 [#include <mmintrin.h>
1151 #include <stdint.h>
1152 uint64_t frobzor;]], [
1153 [__m64 a, b, c;
1154 a = b = c = (__m64)frobzor;
1155 a = _mm_slli_pi16(a, 3);
1156 a = _mm_adds_pi16(a, b);
1157 c = _mm_srli_pi16(c, 8);
1158 c = _mm_slli_pi16(c, 3);
1159 b = _mm_adds_pi16(b, c);
1160 a = _mm_unpacklo_pi8(a, b);
1161 frobzor = (uint64_t)a;]])], [
1162       ac_cv_c_mmx_intrinsics=yes
1163     ], [
1164       ac_cv_c_mmx_intrinsics=no
1165     ])
1166   ])
1167   VLC_RESTORE_FLAGS
1168   AS_IF([test "${ac_cv_c_mmx_intrinsics}" != "no"], [
1169     AC_DEFINE(HAVE_MMX_INTRINSICS, 1, [Define to 1 if MMX intrinsics are available.])
1170   ])
1171
1172   VLC_SAVE_FLAGS
1173   CFLAGS="${CFLAGS} -mmmx"
1174   AC_CACHE_CHECK([if $CC groks MMX inline assembly], [ac_cv_mmx_inline], [
1175     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1176 void *p;
1177 asm volatile("packuswb %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1178 ]])
1179     ], [
1180       ac_cv_mmx_inline=yes
1181     ], [
1182       ac_cv_mmx_inline=no
1183     ])
1184   ])
1185   AS_IF([test "${ac_cv_mmx_inline}" != "no"], [
1186     AC_DEFINE(CAN_COMPILE_MMX, 1, [Define to 1 inline MMX assembly is available.])
1187     have_mmx="yes"
1188   ])
1189
1190   AC_CACHE_CHECK([if $CC groks MMX EXT inline assembly],
1191                  [ac_cv_mmxext_inline], [
1192     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1193 void *p;
1194 asm volatile("maskmovq %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1195 ]])
1196     ], [
1197       ac_cv_mmxext_inline=yes
1198     ], [
1199       ac_cv_mmxext_inline=no
1200     ])
1201   ])
1202   VLC_RESTORE_FLAGS
1203   AS_IF([test "${ac_cv_mmxext_inline}" != "no"], [
1204     AC_DEFINE(CAN_COMPILE_MMXEXT, 1, [Define to 1 if MMX EXT inline assembly is available.])
1205     have_mmxext="yes"
1206   ])
1207 ])
1208 AM_CONDITIONAL([HAVE_MMX], [test "${have_mmx}" = "yes"])
1209 AM_CONDITIONAL([HAVE_MMXEXT], [test "${have_mmxext}" = "yes"])
1210
1211 dnl  Check for fully workin SSE2 intrinsics
1212 dnl  We need support for -mmmx, we need <emmintrin.h>, and we also need a
1213 dnl  working compiler (http://gcc.gnu.org/bugzilla/show_bug.cgi?id=23963)
1214 AC_ARG_ENABLE(sse,
1215   [AS_HELP_STRING([--disable-sse],
1216     [disable SSE (1-4) optimizations (default auto)])],, [
1217   case "${host_cpu}" in
1218     i?86|x86_64)
1219       enable_sse=yes
1220       ;;
1221     *)
1222       enable_sse=no
1223       ;;
1224   esac
1225 ])
1226 have_sse2="no"
1227 AS_IF([test "${enable_sse}" != "no"], [
1228   ARCH="${ARCH} sse sse2"
1229
1230   VLC_SAVE_FLAGS
1231   CFLAGS="${CFLAGS} -msse2"
1232   AC_CACHE_CHECK([if $CC groks SSE2 intrinsics], [ac_cv_c_sse2_intrinsics], [
1233     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1234 [#include <emmintrin.h>
1235 #include <stdint.h>
1236 uint64_t frobzor;]], [
1237 [__m128i a, b, c;
1238 a = b = c = _mm_set1_epi64((__m64)frobzor);
1239 a = _mm_slli_epi16(a, 3);
1240 a = _mm_adds_epi16(a, b);
1241 c = _mm_srli_epi16(c, 8);
1242 c = _mm_slli_epi16(c, 3);
1243 b = _mm_adds_epi16(b, c);
1244 a = _mm_unpacklo_epi8(a, b);
1245 frobzor = (uint64_t)_mm_movepi64_pi64(a);]])], [
1246       ac_cv_c_sse2_intrinsics=yes
1247     ], [
1248       ac_cv_c_sse2_intrinsics=no
1249     ])
1250   ])
1251   VLC_RESTORE_FLAGS
1252   AS_IF([test "${ac_cv_c_sse2_intrinsics}" != "no"], [
1253     AC_DEFINE(HAVE_SSE2_INTRINSICS, 1, [Define to 1 if SSE2 intrinsics are available.])
1254   ])
1255
1256   VLC_SAVE_FLAGS
1257   CFLAGS="${CFLAGS} -msse"
1258   AC_CACHE_CHECK([if $CC groks SSE inline assembly], [ac_cv_sse_inline], [
1259     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1260 void *p;
1261 asm volatile("xorps %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1262 ]])
1263     ], [
1264       ac_cv_sse_inline=yes
1265     ], [
1266       ac_cv_sse_inline=no
1267     ])
1268   ])
1269
1270   AS_IF([test "${ac_cv_sse_inline}" != "no" -a "${SYS}" != "solaris"], [
1271     AC_DEFINE(CAN_COMPILE_SSE, 1, [Define to 1 if SSE inline assembly is available.])
1272   ])
1273
1274   AC_CACHE_CHECK([if $CC groks SSE2 inline assembly], [ac_cv_sse2_inline], [
1275     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1276 void *p;
1277 asm volatile("punpckhqdq %%xmm1,%%xmm2"::"r"(p):"xmm1", "xmm2");
1278 ]])
1279     ], [
1280       ac_cv_sse2_inline=yes
1281     ], [
1282       ac_cv_sse2_inline=no
1283     ])
1284   ])
1285   AS_IF([test "${ac_cv_sse2_inline}" != "no" -a "${SYS}" != "solaris"], [
1286     AC_DEFINE(CAN_COMPILE_SSE2, 1, [Define to 1 if SSE2 inline assembly is available.])
1287     have_sse2="yes"
1288   ])
1289
1290   # SSE3
1291   AC_CACHE_CHECK([if $CC groks SSE3 inline assembly], [ac_cv_sse3_inline], [
1292     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1293 void *p;
1294 asm volatile("movsldup %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1295 ]])
1296     ], [
1297       ac_cv_sse3_inline=yes
1298     ], [
1299       ac_cv_sse3_inline=no
1300     ])
1301   ])
1302
1303   AS_IF([test "${ac_cv_sse3_inline}" != "no"], [
1304     AC_DEFINE(CAN_COMPILE_SSE3, 1, [Define to 1 if SSE3 inline assembly is available.]) ])
1305   # SSSE3
1306   AC_CACHE_CHECK([if $CC groks SSSE3 inline assembly], [ac_cv_ssse3_inline], [
1307     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1308 void *p;
1309 asm volatile("pabsw %%xmm0,%%xmm0"::"r"(p):"xmm0");
1310 ]])
1311     ], [
1312       ac_cv_ssse3_inline=yes
1313     ], [
1314       ac_cv_ssse3_inline=no
1315     ])
1316   ])
1317
1318   AS_IF([test "${ac_cv_ssse3_inline}" != "no"], [
1319     AC_DEFINE(CAN_COMPILE_SSSE3, 1, [Define to 1 if SSSE3 inline assembly is available.]) ])
1320
1321   # SSE4.1
1322   AC_CACHE_CHECK([if $CC groks SSE4.1 inline assembly],
1323                  [ac_cv_sse4_1_inline], [
1324     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1325 void *p;
1326 asm volatile("pmaxsb %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1327 ]])
1328     ], [
1329       ac_cv_sse4_1_inline=yes
1330     ], [
1331       ac_cv_sse4_1_inline=no
1332     ])
1333   ])
1334
1335   AS_IF([test "${ac_cv_sse4_1_inline}" != "no"], [
1336     AC_DEFINE(CAN_COMPILE_SSE4_1, 1, [Define to 1 if SSE4_1 inline assembly is available.]) ])
1337
1338   # SSE4.2
1339   AC_CACHE_CHECK([if $CC groks SSE4.2 inline assembly],
1340                  [ac_cv_sse4_2_inline], [
1341     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1342 void *p;
1343 asm volatile("pcmpgtq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1344 ]])
1345     ], [
1346       ac_cv_sse4_2_inline=yes
1347     ], [
1348       ac_cv_sse4_2_inline=no
1349     ])
1350   ])
1351
1352   AS_IF([test "${ac_cv_sse4_2_inline}" != "no"], [
1353     AC_DEFINE(CAN_COMPILE_SSE4_2, 1, [Define to 1 if SSE4_2 inline assembly is available.]) ])
1354
1355   # SSE4A
1356   AC_CACHE_CHECK([if $CC groks SSE4A inline assembly], [ac_cv_sse4a_inline], [
1357     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1358 void *p;
1359 asm volatile("insertq %%xmm1,%%xmm0"::"r"(p):"xmm0", "xmm1");
1360 ]])
1361     ], [
1362       ac_cv_sse4a_inline=yes
1363     ], [
1364       ac_cv_sse4a_inline=no
1365     ])
1366   ])
1367   VLC_RESTORE_FLAGS
1368   AS_IF([test "${ac_cv_sse4a_inline}" != "no"], [
1369     AC_DEFINE(CAN_COMPILE_SSE4A, 1, [Define to 1 if SSE4A inline assembly is available.]) ])
1370 ])
1371 AM_CONDITIONAL([HAVE_SSE2], [test "$have_sse2" = "yes"])
1372
1373 VLC_SAVE_FLAGS
1374 CFLAGS="${CFLAGS} -mmmx"
1375 have_3dnow="no"
1376 AC_CACHE_CHECK([if $CC groks 3D Now! inline assembly], [ac_cv_3dnow_inline], [
1377   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,[[
1378 void *p;
1379 asm volatile("pfadd %%mm1,%%mm2"::"r"(p):"mm1", "mm2");
1380 ]])
1381   ], [
1382     ac_cv_3dnow_inline=yes
1383   ], [
1384     ac_cv_3dnow_inline=no
1385   ])
1386 ])
1387 VLC_RESTORE_FLAGS
1388 AS_IF([test "${ac_cv_3dnow_inline}" != "no"], [
1389   AC_DEFINE(CAN_COMPILE_3DNOW, 1,
1390             [Define to 1 if 3D Now! inline assembly is available.])
1391   have_3dnow="yes"
1392 ])
1393 AM_CONDITIONAL([HAVE_3DNOW], [test "$have_3dnow" = "yes"])
1394
1395
1396 AC_ARG_ENABLE(neon,
1397   [AS_HELP_STRING([--disable-neon],
1398     [disable NEON optimizations (default auto)])],, [
1399   AS_IF([test "${host_cpu}" = "arm"], [enable_neon="yes"] ,[enable_neon="no"])
1400 ])
1401 AS_IF([test "${enable_neon}" != "no"], [
1402   VLC_SAVE_FLAGS
1403   CFLAGS="${CFLAGS} -mfpu=neon -mhard-float"
1404   AC_CACHE_CHECK([if $CCAS groks ARM NEON assembly], [ac_cv_arm_neon], [
1405     AC_COMPILE_IFELSE([
1406       AC_LANG_PROGRAM(,[[
1407 asm volatile("vqmovun.s64 d0, q1":::"d0");
1408 ]])
1409     ], [
1410       ac_cv_arm_neon="yes"
1411     ], [
1412       ac_cv_arm_neon="no"
1413     ])
1414   ])
1415   VLC_RESTORE_FLAGS
1416 ])
1417 AM_CONDITIONAL(HAVE_NEON, [test "${ac_cv_arm_neon}" = "yes"])
1418
1419
1420 AC_ARG_ENABLE(altivec,
1421   [AS_HELP_STRING([--disable-altivec],
1422     [disable AltiVec optimizations (default auto)])],, [
1423   AS_CASE("${host_cpu}", [powerpc*],
1424         [enable_altivec=yes], [enable_altivec=no])
1425 ])
1426 have_altivec="no"
1427 ALTIVEC_CFLAGS=""
1428 AS_IF([test "${enable_altivec}" = "yes"], [
1429   ARCH="${ARCH} altivec";
1430   VLC_SAVE_FLAGS
1431   AC_CACHE_CHECK([if $CC groks AltiVec inline assembly],
1432     [ac_cv_altivec_inline],
1433     [AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1434          ac_cv_altivec_inline="yes",
1435          [CFLAGS="${CFLAGS} -Wa,-maltivec"
1436           AC_TRY_COMPILE(,[asm volatile("vperm 0,1,2,3");],
1437             [ac_cv_altivec_inline="-Wa,-maltivec"],
1438             ac_cv_altivec_inline=no)
1439          ])])
1440   VLC_RESTORE_FLAGS
1441   AS_IF([test "${ac_cv_altivec_inline}" != "no"], [
1442     AC_DEFINE(CAN_COMPILE_ALTIVEC, 1,
1443               [Define to 1 if AltiVec inline assembly is available.])
1444     AS_IF([test "${ac_cv_altivec_inline}" != "yes"], [
1445       ALTIVEC_CFLAGS="${ac_cv_altivec_inline}"
1446       VLC_ADD_CFLAGS([libvlccore],[${ac_cv_altivec_inline}])
1447     ])
1448     have_altivec="yes"
1449   ])
1450
1451   VLC_SAVE_FLAGS
1452   AC_CACHE_CHECK([if \$CC groks AltiVec C extensions],
1453   [ac_cv_c_altivec], [
1454     CFLAGS="${CFLAGS} -maltivec"
1455     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
1456 [#include <altivec.h>]], [
1457 [vec_ld(0, (unsigned char *)0);]])], [
1458       ac_cv_c_altivec="-maltivec"
1459     ], [
1460       ac_cv_c_altivec="no"
1461     ])
1462   ])
1463   VLC_RESTORE_FLAGS
1464   AS_IF([test "${ac_cv_c_altivec}" != "no"], [
1465     CPPFLAGS="${CPPFLAGS} ${ac_cv_c_altivec}"
1466     AC_DEFINE(CAN_COMPILE_C_ALTIVEC, 1, [Define to 1 if C AltiVec extensions are available.])
1467     VLC_ADD_CFLAGS([libvlccore],[${ac_cv_c_altivec}])
1468     ALTIVEC_CFLAGS="$ALTIVEC_FLAGS ${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}"
1469     VLC_ADD_CFLAGS([deinterlace],[${ac_cv_c_altivec} ${ac_cv_c_altivec_abi}])
1470     have_altivec="yes"
1471   ])
1472   AC_CHECK_HEADERS(altivec.h)
1473
1474   VLC_SAVE_FLAGS
1475   LDFLAGS="${LDFLAGS} -Wl,-framework,vecLib"
1476   AC_CACHE_CHECK([if linker needs -framework vecLib],
1477     [ac_cv_ld_altivec],
1478     [AC_TRY_LINK([],,ac_cv_ld_altivec=yes,ac_cv_ld_altivec=no)])
1479   VLC_RESTORE_FLAGS
1480   AS_IF([test "${ac_cv_ld_altivec}" != "no"], [
1481     VLC_ADD_LIBS([libvlccore],[-Wl,-framework,vecLib])
1482   ])
1483 ])
1484 AC_SUBST(ALTIVEC_CFLAGS)
1485 AM_CONDITIONAL([HAVE_ALTIVEC], [test "$have_altivec" = "yes"])
1486
1487 dnl
1488 dnl  Memory usage
1489 dnl
1490 AC_ARG_ENABLE(optimize-memory,
1491   [AS_HELP_STRING([--enable-optimize-memory],
1492     [optimize memory usage over performance])])
1493 if test "${enable_optimize_memory}" = "yes"; then
1494   AC_DEFINE(OPTIMIZE_MEMORY, 1, Define if you want to optimize memory usage over performance)
1495 fi
1496
1497 dnl
1498 dnl Allow running as root (useful for people running on embedded platforms)
1499 dnl
1500 AC_ARG_ENABLE(run-as-root,
1501   [AS_HELP_STRING([--enable-run-as-root],
1502     [allow running VLC as root (default disabled)])])
1503 AS_IF([test "${enable_run_as_root}" = "yes"],[
1504     AC_DEFINE(ALLOW_RUN_AS_ROOT, 1,
1505               [Define to 1 to allow running VLC as root (uid 0).])
1506 ])
1507
1508 dnl
1509 dnl Stream output
1510 dnl
1511 AC_ARG_ENABLE(sout,
1512   [AS_HELP_STRING([--disable-sout],
1513     [disable streaming output (default enabled)])])
1514 AS_IF([test "${enable_sout}" != "no"], [
1515   AC_DEFINE(ENABLE_SOUT, 1, [Define to 1 for stream output support.])
1516 ])
1517 AM_CONDITIONAL(ENABLE_SOUT, [test "${enable_sout}" != "no"])
1518
1519 dnl Lua modules
1520 AC_ARG_ENABLE(lua,
1521   [AS_HELP_STRING([--disable-lua],
1522     [disable LUA scripting support (default enabled)])])
1523 if test "${enable_lua}" != "no"
1524 then
1525   PKG_CHECK_MODULES(LUA, lua5.3, [have_lua=yes], [
1526     AC_MSG_WARN([${LUA_PKG_ERRORS}, trying Lua 5.2 instead])
1527
1528     PKG_CHECK_MODULES(LUA, lua5.2, [have_lua=yes], [
1529       AC_MSG_WARN([${LUA_PKG_ERRORS}, trying Lua 5.1 instead])
1530
1531       PKG_CHECK_MODULES(LUA, lua5.1, [have_lua=yes], [
1532         AC_MSG_WARN([${LUA_PKG_ERRORS}, trying Lua instead])
1533         PKG_CHECK_MODULES(LUA, lua >= 5.1, [have_lua=yes], [
1534             AC_MSG_WARN([${LUA_PKG_ERRORS}, trying manual detection instead])
1535             have_lua=yes
1536             AC_CHECK_HEADERS([lua.h lauxlib.h lualib.h], [], [have_lua=no])
1537             AC_CHECK_LIB(lua5.2, luaL_newstate, [LUA_LIBS="-llua5.2"], [
1538               AC_CHECK_LIB(lua5.1, luaL_newstate, [LUA_LIBS="-llua5.1"], [
1539                 AC_CHECK_LIB(lua51, luaL_newstate, [LUA_LIBS="-llua51"], [
1540                   AC_CHECK_LIB(lua, luaL_newstate, [LUA_LIBS="-llua"], [
1541                     have_lua=no], [-lm])
1542                 ])
1543               ])
1544             ])
1545           ])
1546         ])
1547       ])
1548     ])
1549   if test "x${have_lua}" != "xyes" ;  then
1550       AC_MSG_ERROR([Could not find lua. Lua is needed for some interfaces (rc, telnet, http) as well as many other custom scripts. Use --disable-lua to ignore this error.])
1551   fi
1552   AC_ARG_VAR([LUAC], [LUA byte compiler])
1553   AC_PATH_PROGS(LUAC, [${LUAC} luac5.3 luac], [false])
1554   AS_IF([test "${LUAC}" = "false"], [
1555     AC_MSG_ERROR([Could not find the LUA byte compiler.])
1556   ])
1557   AS_IF([test -d "${CONTRIB_DIR}" -a -f "${CONTRIB_DIR}/lib/liblua.a" -a `echo|${LUAC} -o - -|od -j 8 -N 2 -t x2|head -n 1|tr -s ' '|cut -d' ' -f2` != 0404], [
1558     AC_MSG_WARN([You need 32-bits luac when using lua from contrib.])
1559     have_lua=no
1560   ])
1561 fi
1562 AM_CONDITIONAL(BUILD_LUA, [test "${have_lua}" = "yes"])
1563
1564
1565 dnl
1566 dnl HTTP daemon
1567 dnl
1568 AC_ARG_ENABLE(httpd,
1569   [AS_HELP_STRING([--disable-httpd],
1570     [disable the built-in HTTP server (default enabled)])])
1571 if test "${enable_httpd}" != "no"
1572 then
1573   AC_DEFINE(ENABLE_HTTPD, 1, Define if you want the HTTP daemon support)
1574 fi
1575 AM_CONDITIONAL(BUILD_HTTPD, [test "${enable_httpd}" != "no"])
1576
1577
1578 dnl
1579 dnl VideoLAN manager
1580 dnl
1581 AC_ARG_ENABLE(vlm,
1582   [AS_HELP_STRING([--disable-vlm],
1583     [disable the stream manager (default enabled)])],,
1584   [enable_vlm="${enable_sout}"])
1585 AS_IF([test "${enable_vlm}" != "no"], [
1586   AS_IF([test "${enable_sout}" = "no"], [
1587     AC_MSG_ERROR([VLM requires the stream output. Do not use --disable-sout.])
1588   ])
1589   AC_DEFINE(ENABLE_VLM, 1, [Define if you want the VideoLAN manager support])
1590 ])
1591 AM_CONDITIONAL([ENABLE_VLM], [test "${enable_vlm}" != "no"])
1592
1593
1594 dnl
1595 dnl Addons manager storage and repositories modules
1596 dnl
1597 AC_ARG_ENABLE(addonmanagermodules,
1598   [AS_HELP_STRING([--disable-addonmanagermodules],
1599     [disable the addons manager modules (default enabled)])])
1600 if test "${enable_addonmanagermodules}" != "no"
1601 then
1602   AC_DEFINE(ENABLE_ADDONMANAGERMODULES, 1, [Define if you want the addons manager modules])
1603 fi
1604 AM_CONDITIONAL([ENABLE_ADDONMANAGERMODULES], [test "${enable_addonmanagermodules}" != "no"])
1605
1606
1607 dnl
1608 dnl  Input plugins
1609 dnl
1610
1611 EXTEND_HELP_STRING([Input plugins:])
1612
1613 dnl
1614 dnl  libarchive access module
1615 dnl
1616 PKG_ENABLE_MODULES_VLC([ARCHIVE], [access_archive], [libarchive >= 3.1.0], (libarchive support), [auto])
1617
1618 dnl
1619 dnl  live555 input
1620 dnl
1621 AC_ARG_ENABLE(live555,
1622   [AS_HELP_STRING([--enable-live555],
1623     [enable RTSP input through live555 (default enabled)])])
1624
1625 AS_IF([test "${enable_live555}" != "no" -a -n "${CXX}"], [
1626   PKG_CHECK_MODULES(LIVE555, live555, [
1627     VLC_ADD_PLUGIN([live555])
1628     VLC_ADD_CXXFLAGS([live555], [$LIVE555_CFLAGS])
1629     VLC_ADD_LIBS([live555],[$LIVE555_LIBS])
1630   ], [
1631     AC_MSG_WARN([${LIVE555_PKG_ERRORS}.])
1632
1633     AC_LANG_PUSH(C++)
1634     VLC_SAVE_FLAGS
1635
1636     dnl detect include paths
1637     AS_IF([test -f "${CONTRIB_DIR}/include/UsageEnvironment.hh"], [
1638       CPPFLAGS_live555="-I${CONTRIB_DIR}/include/liveMedia -I${CONTRIB_DIR}/include/groupsock -I${CONTRIB_DIR}/include/BasicUsageEnvironment -I${CONTRIB_DIR}/include/UsageEnvironment"
1639     ], [
1640       AS_IF([test "${SYS}" != "os2"], [
1641         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr"}
1642         CPPFLAGS_live555="-I${LIVE555_PREFIX}/include/liveMedia -I${LIVE555_PREFIX}/include/groupsock -I${LIVE555_PREFIX}/include/BasicUsageEnvironment -I${LIVE555_PREFIX}/include/UsageEnvironment"
1643       ], [
1644         LIVE555_PREFIX=${LIVE555_PREFIX-"/usr/lib/live"}
1645         CPPFLAGS_live555="-I${LIVE555_PREFIX}/liveMedia/include -I${LIVE555_PREFIX}/groupsock/include -I${LIVE555_PREFIX}/BasicUsageEnvironment/include -I${LIVE555_PREFIX}/UsageEnvironment/include"
1646         LDFLAGS_live555="-L${LIVE555_PREFIX}/liveMedia -L${LIVE555_PREFIX}/groupsock -L${LIVE555_PREFIX}/BasicUsageEnvironment -L${LIVE555_PREFIX}/UsageEnvironment"
1647       ])
1648     ])
1649
1650     dnl CPP Flags
1651     AS_IF([test "${SYS}" = "solaris"], [
1652       CPPFLAGS_live555="${CPPFLAGS_live555} -DSOLARIS"
1653     ])
1654     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_live555}"
1655     LDFLAGS="${LDFLAGS} ${LDFLAGS_live555}"
1656
1657     dnl version check
1658     AC_CACHE_CHECK([for live555 version 1324598400 or later], [ac_cv_live555], [
1659       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1660 [#include <liveMedia_version.hh>
1661 #if !defined (LIVEMEDIA_LIBRARY_VERSION_INT) || (LIVEMEDIA_LIBRARY_VERSION_INT < 1324598400)
1662 # error BOOM
1663 #endif]])
1664       ], [
1665         ac_cv_live555="yes"
1666       ], [
1667         ac_cv_live555="no"
1668       ])
1669     ])
1670
1671     AS_IF([test "$ac_cv_live555" = "no"], [
1672       AC_MSG_WARN([live555 is missing or its installed version is too old:
1673 Version 2011.12.23 or later is required to proceed.
1674 You can get an updated one from http://www.live555.com/liveMedia .])
1675       AS_IF([test -n "${enable_live555}"], [
1676         AC_MSG_ERROR([Update live555 or pass --disable-live555 to disable RTSP input support.])
1677       ])
1678     ], [
1679       other_libs="-lgroupsock -lBasicUsageEnvironment -lUsageEnvironment"
1680       other_libs_pic="-lgroupsock_pic -lBasicUsageEnvironment_pic -lUsageEnvironment_pic"
1681       AS_IF([test "${SYS}" = "mingw32"], [
1682         # add ws2_32 for closesocket, select, recv
1683         other_libs="$other_libs -lws2_32"
1684       ])
1685
1686       dnl We need to check for pic because live555 don't provide shared libs
1687       dnl and we want to build a plugins so we need -fPIC on some arch.
1688       VLC_ADD_CXXFLAGS([live555], [${CPPFLAGS_live555}])
1689       VLC_ADD_LDFLAGS([live555], [${LDFLAGS_live555}])
1690       AC_CHECK_LIB(liveMedia_pic, main, [
1691         VLC_ADD_PLUGIN([live555])
1692         VLC_ADD_LIBS([live555], [-lliveMedia_pic ${other_libs_pic}])
1693       ],[
1694         AC_CHECK_LIB(liveMedia, main, [
1695           VLC_ADD_PLUGIN([live555])
1696           VLC_ADD_LIBS([live555], [-lliveMedia ${other_libs}])
1697         ],[],[${other_libs}])
1698       ],[${other_libs_pic}])
1699     ])
1700     VLC_RESTORE_FLAGS
1701     AC_LANG_POP(C++)
1702   ])
1703 ])
1704
1705 dnl
1706 dnl IIDC and DV FireWire input modules
1707 dnl
1708 PKG_ENABLE_MODULES_VLC([DC1394], [], [libdc1394-2 >= 2.1.0], [IIDC FireWire input module], [auto])
1709 PKG_ENABLE_MODULES_VLC([DV1394], [], [libraw1394 >= 2.0.1 libavc1394 >= 0.5.3], [DV FireWire input module], [auto])
1710
1711 dnl
1712 dnl - linsys modules: access module check for libzvbi
1713 dnl
1714 AC_ARG_ENABLE(linsys,
1715   [AS_HELP_STRING([--enable-linsys],
1716     [Linux Linear Systems Ltd. SDI and HD-SDI input cards (default enabled)])])
1717 AS_IF([test "$SYS" = "linux" -a "${enable_linsys}" != "no"], [
1718   VLC_ADD_PLUGIN([linsys_hdsdi])
1719   PKG_CHECK_MODULES(LINSYS_SDI, [zvbi-0.2 >= 0.2.28], [
1720     VLC_ADD_PLUGIN([linsys_sdi])
1721   ], [
1722     AC_MSG_WARN([${LINSYS_SDI_PKG_ERRORS}.])
1723   ])
1724 ])
1725
1726 dnl
1727 dnl dvdread module: check for libdvdread
1728 dnl
1729 PKG_ENABLE_MODULES_VLC([DVDREAD], [], [dvdread > 4.9.0], [dvdread input module], [auto])
1730
1731 dnl
1732 dnl libdvdnav plugin
1733 dnl
1734 PKG_ENABLE_MODULES_VLC([DVDNAV], [], [dvdnav > 4.9.0], [DVD with navigation input module (dvdnav)], [auto])
1735 AS_IF([test "${enable_dvdnav}" != "no"], [
1736   AC_MSG_CHECKING(for dvdnav_stream_cb in dvdnav/dvdnav.h)
1737     AC_EGREP_HEADER(dvdnav_stream_cb,dvdnav/dvdnav.h,[
1738       AC_MSG_RESULT(yes)
1739       AC_DEFINE(HAVE_STREAM_CB_IN_DVDNAV_H, 1, For dvdnav demux support)
1740       ],[
1741       AC_MSG_RESULT(no)
1742     ])
1743 ])
1744
1745 dnl
1746 dnl  Blu-ray Disc Support with libbluray
1747 dnl
1748 PKG_ENABLE_MODULES_VLC([BLURAY], [libbluray], [libbluray >= 0.6.2], (libbluray for Blu-ray disc support ) )
1749
1750 dnl
1751 dnl  OpenCV wrapper and example filters
1752 dnl
1753 PKG_ENABLE_MODULES_VLC([OPENCV], [opencv_example opencv_wrapper], [opencv > 2.0], (OpenCV (computer vision) filter), [auto])
1754
1755
1756 dnl
1757 dnl  libsmbclient plugin
1758 dnl
1759 PKG_ENABLE_MODULES_VLC([SMBCLIENT], [smb], [smbclient], (SMB/CIFS support), [auto])
1760 AS_IF([test "${SYS}" = "mingw32" -a "${enable_smbclient}" != "no"], [ VLC_ADD_PLUGIN([smb]) ])
1761
1762 dnl
1763 dnl  liBDSM access module
1764 dnl
1765 PKG_ENABLE_MODULES_VLC([DSM], [dsm], [libdsm >= 0.2.0], [libdsm SMB/CIFS access/sd module], [auto])
1766
1767 dnl
1768 dnl sftp access support
1769 dnl
1770 PKG_ENABLE_MODULES_VLC([SFTP], [sftp], [libssh2], (support SFTP file transfer via libssh2), [auto])
1771
1772 dnl
1773 dnl nfs access support
1774 dnl
1775 PKG_ENABLE_MODULES_VLC([NFS], [nfs], [libnfs], (support nfs protocol via libnfs), [auto])
1776
1777 dnl
1778 dnl  Video4Linux 2
1779 dnl
1780 AC_ARG_ENABLE(v4l2, [AS_HELP_STRING([--disable-v4l2],
1781   [disable Video4Linux version 2 (default auto)])])
1782 have_v4l2="no"
1783 AS_IF([test "$enable_v4l2" != "no"], [
1784   AC_CHECK_HEADERS([linux/videodev2.h sys/videoio.h], [
1785     have_v4l2="yes"
1786   ])
1787 ])
1788 AM_CONDITIONAL(HAVE_V4L2, [test "${have_v4l2}" != "no"])
1789
1790 dnl
1791 dnl special access module for Blackmagic SDI cards
1792 dnl
1793 AC_ARG_ENABLE(decklink,
1794   [AS_HELP_STRING([--disable-decklink],
1795     [disable Blackmagic DeckLink SDI input (default auto)])])
1796 AC_ARG_WITH(decklink_sdk,
1797   [AS_HELP_STRING[--with-decklink-sdk=DIR],
1798     [                        location of Blackmagic DeckLink SDI SDK])])
1799 have_decklink=no
1800 if test "${enable_decklink}" != "no"
1801 then
1802   if test "${with_decklink_sdk}" != "no" -a -n "${with_decklink_sdk}"
1803   then
1804     VLC_ADD_CPPFLAGS([decklink decklinkoutput],[-I${with_decklink_sdk}/include])
1805   fi
1806   VLC_SAVE_FLAGS
1807   CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_decklink}"
1808   AC_LANG_PUSH(C++)
1809   AC_CHECK_HEADERS(DeckLinkAPIDispatch.cpp, [
1810       have_decklink=yes
1811   ], [
1812       AC_MSG_WARN(Blackmagic DeckLink SDI include files not found, decklink disabled)
1813   ])
1814   AC_LANG_POP(C++)
1815   VLC_RESTORE_FLAGS
1816 fi
1817 AM_CONDITIONAL(HAVE_DECKLINK, [ test "${have_decklink}" != "no" ])
1818
1819
1820 dnl
1821 dnl  Built-in CD-DA and VCD module
1822 dnl
1823 AC_ARG_ENABLE(vcd,
1824   [AS_HELP_STRING([--disable-vcd],
1825     [disable built-in VCD and CD-DA support (default enabled)])])
1826
1827 AC_ARG_ENABLE(libcddb,
1828   [AS_HELP_STRING([--disable-libcddb],
1829     [disable CDDB for Audio CD (default enabled)])])
1830
1831 if test "${enable_vcd}" != "no"
1832 then
1833   AC_MSG_CHECKING(for cdrom_msf0 in linux/cdrom.h)
1834   AC_EGREP_HEADER(cdrom_msf0,linux/cdrom.h,[
1835     AC_MSG_RESULT(yes)
1836     VLC_ADD_PLUGIN([vcd cdda])
1837   ],[
1838     AC_MSG_RESULT(no)
1839   ])
1840
1841   AC_MSG_CHECKING(for scsireq in sys/scsiio.h)
1842   AC_EGREP_HEADER(scsireq,sys/scsiio.h,[
1843     AC_MSG_RESULT(yes)
1844     VLC_ADD_PLUGIN([vcd cdda])
1845     AC_DEFINE(HAVE_SCSIREQ_IN_SYS_SCSIIO_H, 1, For NetBSD VCD support)
1846   ],[
1847     AC_MSG_RESULT(no)
1848   ])
1849
1850   AC_MSG_CHECKING(for ioc_toc_header in sys/cdio.h)
1851   AC_EGREP_HEADER(ioc_toc_header ,sys/cdio.h,[
1852     AC_MSG_RESULT(yes)
1853     VLC_ADD_PLUGIN([vcd cdda])
1854     AC_DEFINE(HAVE_IOC_TOC_HEADER_IN_SYS_CDIO_H, 1, For FreeBSD VCD support)
1855   ],[
1856     AC_MSG_RESULT(no)
1857   ])
1858
1859   if test "${SYS}" = "bsdi" -o "${SYS}" = "mingw32" -o "${SYS}" = "os2" -o "${SYS}" = "darwin"
1860   then
1861     VLC_ADD_PLUGIN([vcd cdda])
1862   fi
1863
1864   if test "$enable_libcddb" != "no"; then
1865     PKG_CHECK_MODULES(LIBCDDB, [libcddb >= 0.9.5], [
1866       HAVE_LIBCDDB=yes
1867       AC_DEFINE(HAVE_LIBCDDB, 1, [Define this if you have libcddb installed])
1868       VLC_ADD_LIBS([cdda],[$LIBCDDB_LIBS])
1869       VLC_ADD_CFLAGS([cdda],[$LIBCDDB_CFLAGS])
1870       ],:
1871       [AC_MSG_WARN([${LIBCDDB_PKG_ERRORS}: CDDB access disabled.])
1872       HAVE_LIBCDDB=no])
1873   fi
1874 fi
1875
1876 dnl
1877 dnl Linux DVB
1878 dnl
1879 AC_CACHE_CHECK([for Linux DVB version 5.1], [ac_cv_linux_dvb_5_1], [
1880   AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
1881 [#include <linux/dvb/version.h>
1882 #if (DVB_API_VERSION < 5)
1883 # error Linux DVB API v3.2 and older are not supported.
1884 #endif
1885 #if (DVB_API_VERSION == 5 && DVB_API_VERSION_MINOR < 1)
1886 # error Linux DVB API v5.0 is unsupported. Please update.
1887 #endif
1888 ]])], [
1889   ac_cv_linux_dvb_5_1=yes
1890 ], [
1891   ac_cv_linux_dvb_5_1=no
1892 ])])
1893 AM_CONDITIONAL([HAVE_LINUX_DVB], [test "$ac_cv_linux_dvb_5_1" = "yes"])
1894
1895 dnl
1896 dnl  Screen capture module
1897 dnl
1898 AC_ARG_ENABLE(screen,
1899   [AS_HELP_STRING([--enable-screen],
1900     [disable screen capture (default enabled)])])
1901 if test "${enable_screen}" != "no"; then
1902   if test "${SYS}" = "darwin"; then
1903     AC_CHECK_HEADERS(ApplicationServices/ApplicationServices.h, [
1904       VLC_ADD_PLUGIN([screen])
1905     ])
1906   fi
1907 fi
1908 AM_CONDITIONAL(HAVE_MAC_SCREEN, [test "${SYS}" = "darwin" -a "x${enable_screen}" != "xno"])
1909
1910 dnl
1911 dnl  VNC/RFB access module
1912 dnl
1913 PKG_ENABLE_MODULES_VLC([VNC], [vnc], [libvncclient >= 0.9.9], (VNC/rfb client support), [auto])
1914
1915 dnl  RDP/Remote Desktop access module
1916 dnl
1917 PKG_ENABLE_MODULES_VLC([FREERDP], [rdp], [freerdp >= 1.0.1], (RDP/Remote Desktop client support) )
1918
1919 dnl
1920 dnl  Real RTSP plugin
1921 dnl
1922 AC_ARG_ENABLE(realrtsp,
1923   [  --enable-realrtsp       Real RTSP module (default disabled)])
1924 if test "${enable_realrtsp}" = "yes"; then
1925   VLC_ADD_PLUGIN([access_realrtsp])
1926 fi
1927
1928 dnl
1929 dnl MacOS eyeTV
1930 AC_ARG_ENABLE(macosx-eyetv,
1931   [  --enable-macosx-eyetv   Mac OS X EyeTV (TNT Tuner) module (default enabled on Mac OS X)])
1932 if test "x${enable_macosx_eyetv}" != "xno" &&
1933   (test "${SYS}" = "darwin" || test "${enable_macosx_eyetv}" = "yes")
1934 then
1935   VLC_ADD_PLUGIN([access_eyetv])
1936 fi
1937
1938 dnl
1939 dnl QTKit
1940 AC_ARG_ENABLE(macosx-qtkit,
1941   [  --enable-macosx-qtkit Mac OS X qtsound (audio) module (default enabled on Mac OS X)])
1942 if test "x${enable_macosx_qtkit}" != "xno" &&
1943   (test "${SYS}" = "darwin" || test "${enable_macosx_qtkit}" = "yes")
1944 then
1945   VLC_ADD_PLUGIN([qtsound])
1946 fi
1947 AM_CONDITIONAL(HAVE_QTKIT, [test "${SYS}" = "darwin" -a "x${enable_macosx_qtkit}" != "xno"])
1948
1949 dnl
1950 dnl AVFoundation
1951 AC_SUBST(have_avfoundation, ["no"])
1952 AC_ARG_ENABLE(macosx-avfoundation,
1953   [  --enable-macosx-avfoundation Mac OS X avcapture (video) module (default enabled on Mac OS X)])
1954 if test "x${enable_macosx_avfoundation}" != "xno" &&
1955   (test "${SYS}" = "darwin" || test "${enable_macosx_avfoundation}" = "yes")
1956 then
1957   SAVED_LIBS="${LIBS}"
1958   LIBS="-framework AVFoundation"
1959   AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [])],[have_avfoundation=yes],[have_avfoundation=no])
1960   LIBS="${SAVED_LIBS}"
1961   if test "${have_avfoundation}" != "no"
1962   then
1963     VLC_ADD_PLUGIN([avcapture])
1964   fi
1965 fi
1966 AM_CONDITIONAL(HAVE_AVFOUNDATION, [test "${have_avfoundation}" != "no"])
1967
1968 dnl
1969 dnl  DCP plugin (using asdcplib)
1970 dnl
1971 PKG_WITH_MODULES([ASDCP], [asdcplib], [have_asdcp="yes"])
1972 AM_CONDITIONAL(HAVE_ASDCP, [test "${have_asdcp}" = "yes"])
1973
1974 dnl
1975 dnl  Demux plugins
1976 dnl
1977
1978 EXTEND_HELP_STRING([Mux/Demux plugins:])
1979
1980 dnl
1981 dnl  libdvbpsi check for ts mux/demux
1982 dnl
1983 have_dvbpsi="no"
1984 PKG_WITH_MODULES([DVBPSI], [libdvbpsi >= 1.2.0], [have_dvbpsi="yes"])
1985 AM_CONDITIONAL(HAVE_DVBPSI, [test "${have_dvbpsi}" = "yes"])
1986
1987
1988 dnl
1989 dnl  GME demux plugin
1990 dnl
1991 AC_ARG_ENABLE(gme,
1992   [AS_HELP_STRING([--enable-gme],
1993     [use Game Music Emu (default auto)])])
1994 AS_IF([test "${enable_gme}" != "no"], [
1995   AC_CHECK_HEADER([gme/gme.h], [
1996     VLC_ADD_LIBS([gme], [-lgme])
1997     VLC_ADD_PLUGIN([gme])
1998   ], [
1999     AS_IF([test "x${enable_gme}" != "x"], [
2000       AC_MSG_ERROR([GME cannot be found. Please install the development files.])
2001     ])
2002   ])
2003 ])
2004
2005
2006 dnl
2007 dnl  SIDPlay plugin
2008 dnl
2009 AC_ARG_ENABLE(sid,
2010     [AS_HELP_STRING([--enable-sid],[C64 sid demux support (default auto)])])
2011 AS_IF([test "${enable_sid}" != "no"], [
2012     PKG_CHECK_MODULES(SID, [libsidplay2], [
2013         AC_LANG_PUSH(C++)
2014         oldCPPFLAGS="$CPPFLAGS"
2015         CPPFLAGS="$CPPFLAGS $SID_CFLAGS"
2016         AC_CHECK_HEADER([sidplay/builders/resid.h], [
2017             VLC_ADD_PLUGIN([sid])
2018             VLC_ADD_CFLAGS([sid], [$SID_CFLAGS])
2019             VLC_ADD_LIBS([sid], [$SID_LIBS] [-lresid-builder])
2020         ], [
2021             AS_IF([test -n "${enable_sid}"],
2022                 [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2023                 [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2024                 )
2025         ])
2026         CPPFLAGS="$oldCPPFLAGS"
2027         AC_LANG_POP(C++)
2028     ], [
2029         AS_IF([test "x${enable_sid}" = "xyes"],
2030             [AC_MSG_ERROR([${SID_PKG_ERRORS} (required for sid).])],
2031             [AC_MSG_WARN([${SID_PKG_ERRORS} (required for sid).])]
2032             )
2033     ])
2034 ])
2035
2036
2037 dnl
2038 dnl  ogg demux plugin
2039 dnl
2040 PKG_ENABLE_MODULES_VLC([OGG], [mux_ogg], [ogg >= 1.0], [Ogg demux support], [auto])
2041 PKG_CHECK_MODULES(LIBVORBIS, [vorbis >= 1.1], [
2042     AC_DEFINE(HAVE_LIBVORBIS, 1, [Define to 1 if you have the libvorbis])
2043 ],[true])
2044 PKG_ENABLE_MODULES_VLC([OGG], [], [ogg >= 1.0], [Ogg demux support], [auto], [${LIBVORBIS_CFLAGS}], [${LIBVORBIS_LIBS}])
2045 if test "${enable_sout}" != "no"; then
2046 dnl Check for libshout
2047     PKG_ENABLE_MODULES_VLC([SHOUT], [access_output_shout], [shout >= 2.1], [libshout output plugin], [auto])
2048 fi
2049
2050 dnl
2051 dnl  matroska demux plugin
2052 dnl
2053 AC_ARG_ENABLE(mkv,
2054   [AS_HELP_STRING([--disable-mkv],
2055     [do not use libmatroska (default auto)])])
2056 if test "${enable_mkv}" != "no" -a "${CXX}" != ""; then
2057   AC_LANG_PUSH(C++)
2058   AC_CHECK_HEADERS(ebml/EbmlVersion.h, [
2059     AC_MSG_CHECKING(for libebml version >= 1.0.0)
2060     AC_EGREP_CPP(yes,
2061       [#include <ebml/EbmlVersion.h>
2062        #ifdef LIBEBML_VERSION
2063        #if LIBEBML_VERSION >= 0x010000
2064        yes
2065        #endif
2066        #endif],
2067       [AC_MSG_RESULT([yes])
2068         AC_CHECK_HEADERS(matroska/KaxVersion.h, [
2069           AC_MSG_CHECKING(for libmatroska version >= 1.0.0)
2070           AC_EGREP_CPP(yes,
2071             [#include <matroska/KaxVersion.h>
2072              #ifdef LIBMATROSKA_VERSION
2073              #if LIBMATROSKA_VERSION >= 0x010000
2074              yes
2075              #endif
2076              #endif],
2077             [AC_MSG_RESULT([yes])
2078               AC_CHECK_HEADERS(matroska/KaxAttachments.h)
2079               AC_CHECK_LIB(ebml_pic, main, [
2080                 VLC_ADD_PLUGIN([mkv])
2081                 VLC_ADD_LIBS([mkv],[-lmatroska -lebml_pic])
2082               ],[
2083                 AC_CHECK_LIB(ebml, main, [
2084                   VLC_ADD_PLUGIN([mkv])
2085                   VLC_ADD_LIBS([mkv],[-lmatroska -lebml])
2086                 ])
2087               ])
2088             ], [
2089               AC_MSG_RESULT([no])
2090               AC_MSG_ERROR([Your libmatroska is too old: you may get a more recent one from http://dl.matroska.org/downloads/libmatroska/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2091           ])
2092         ])
2093       ],
2094       [AC_MSG_RESULT([no])
2095         AC_MSG_ERROR([Your libebml is too old: you may get a more recent one from http://dl.matroska.org/downloads/libebml/. Alternatively you can use --disable-mkv to disable the matroska plugin.])
2096     ])
2097   ])
2098   AC_LANG_POP(C++)
2099 fi
2100
2101 dnl
2102 dnl  modplug demux plugin
2103 dnl
2104 AC_ARG_ENABLE(mod,
2105   [AS_HELP_STRING([--disable-mod],
2106     [do not use libmodplug (default auto)])])
2107 if test "${enable_mod}" != "no" ; then
2108     PKG_CHECK_MODULES(LIBMODPLUG, [libmodplug >= 0.8.4 libmodplug != 0.8.8], [
2109           VLC_ADD_PLUGIN([mod])
2110           VLC_ADD_CXXFLAGS([mod],[$LIBMODPLUG_CFLAGS])
2111           VLC_ADD_CFLAGS([mod],[$LIBMODPLUG_CFLAGS]) #modules/demux/mod.c needs CFLAGS_mod, not CXXFLAGS_mod
2112           VLC_ADD_LIBS([mod],[$LIBMODPLUG_LIBS])
2113     ],[
2114        AS_IF([test -n "${enable_mod}"],
2115          [AC_MSG_ERROR([${LIBMODPLUG_PKG_ERRORS}.])],
2116          [AC_MSG_WARN([${LIBMODPLUG_PKG_ERRORS}.])])
2117     ])
2118 fi
2119
2120 dnl
2121 dnl  mpc demux plugin
2122 dnl
2123 AC_ARG_ENABLE(mpc,
2124   [AS_HELP_STRING([--disable-mpc], [do not use libmpcdec (default auto)])])
2125 if test "${enable_mpc}" != "no"
2126 then
2127   AC_CHECK_HEADERS([mpc/mpcdec.h], [
2128     VLC_ADD_PLUGIN([mpc])
2129     VLC_ADD_LIBS([mpc],[-lmpcdec])],
2130     [AC_CHECK_HEADERS([mpcdec/mpcdec.h], [
2131     VLC_ADD_PLUGIN([mpc])
2132     VLC_ADD_LIBS([mpc],[-lmpcdec])])])
2133 fi
2134
2135 dnl
2136 dnl  Codec plugins
2137 dnl
2138
2139 EXTEND_HELP_STRING([Codec plugins:])
2140
2141 dnl
2142 dnl wmafixed plugin
2143 dnl
2144 AC_ARG_ENABLE(wma-fixed,
2145   [  --enable-wma-fixed      libwma-fixed module (default disabled)])
2146 if test "${enable_wma_fixed}" = "yes"
2147 then
2148   VLC_ADD_PLUGIN([wma_fixed])
2149 fi
2150
2151 dnl
2152 dnl shine encoder plugin
2153 dnl
2154 PKG_ENABLE_MODULES_VLC([SHINE], [], [shine >= 3.0.0], [MPEG Audio Layer 3 encoder], [auto], [], [], [])
2155
2156
2157 dnl
2158 dnl openmax il codec plugin
2159 dnl
2160 AC_ARG_ENABLE(omxil,
2161   [  --enable-omxil          openmax il codec module (default disabled)])
2162 if test "${enable_omxil}" = "yes"
2163 then
2164   VLC_ADD_PLUGIN([omxil])
2165 fi
2166
2167 dnl
2168 dnl openmax il vout plugin
2169 dnl
2170 AC_ARG_ENABLE(omxil-vout,
2171   [  --enable-omxil-vout     openmax il video output module (default disabled)])
2172 if test "${enable_omxil_vout}" = "yes"
2173 then
2174   VLC_ADD_PLUGIN([omxil_vout])
2175 fi
2176
2177 dnl
2178 dnl raspberry pi openmax il configuration
2179 dnl
2180 AC_ARG_ENABLE(rpi-omxil,
2181   [  --enable-rpi-omxil     openmax il configured for raspberry pi (default disabled)])
2182 if test "${enable_rpi_omxil}" = "yes"
2183 then
2184   VLC_ADD_PLUGIN([omxil omxil_vout])
2185   VLC_ADD_CFLAGS([omxil omxil_vout],[-DRPI_OMX])
2186 fi
2187
2188 dnl
2189 dnl CrystalHD codec plugin
2190 dnl
2191 AC_ARG_ENABLE(crystalhd,
2192   [  --enable-crystalhd      crystalhd codec plugin (default auto)])
2193 if test "${enable_crystalhd}" != "no"; then
2194     AC_CHECK_HEADER(libcrystalhd/libcrystalhd_if.h, [
2195       VLC_ADD_PLUGIN([crystalhd])
2196       VLC_ADD_LIBS([crystalhd], [-lcrystalhd])
2197     ],[
2198       if test "${SYS}" = "mingw32" ; then
2199         AC_CHECK_HEADERS(libcrystalhd/bc_dts_defs.h, [
2200           VLC_ADD_PLUGIN([crystalhd])
2201           AC_CHECK_HEADERS(libcrystalhd/bc_drv_if.h, [
2202             VLC_ADD_LIBS([crystalhd], [-lbcmDIL])
2203             ])
2204         ],[
2205           AS_IF([test x"${enable_crystalhd}" = "xyes"],
2206                 [AC_MSG_ERROR("Could not find CrystalHD development headers")],
2207                 [AC_MSG_WARN("Could not find CrystalHD development headers")])
2208         ],[#define __LINUX_USER__
2209                #include <libcrystalhd/bc_dts_types.h>
2210         ])
2211       fi
2212     ],[
2213        #include <libcrystalhd/bc_dts_types.h>
2214       ])
2215 fi
2216
2217 dnl
2218 dnl  mad plugin
2219 dnl
2220 have_mad="no"
2221 MAD_CFLAGS=""
2222 MAD_LIBS=""
2223
2224 AC_ARG_WITH(mad, [  --with-mad=PATH         path to libmad], [
2225   enable_mad="yes"
2226 ], [
2227   with_mad="no"
2228 ])
2229 AS_IF([test "${with_mad}" != "no"], [
2230   MAD_CFLAGS="-I${with_mad}/include"
2231   MAD_LIBS="-L${with_mad}/lib"
2232 ])
2233
2234 AC_ARG_ENABLE(mad,
2235   [  --enable-mad            libmad module (default enabled)])
2236 AS_IF([test "${enable_mad}" != "no"], [
2237   VLC_SAVE_FLAGS
2238   CPPFLAGS="${CPPFLAGS} ${MAD_CFLAGS}"
2239   LDFLAGS="${LDFLAGS} ${MAD_LIBS}"
2240   AC_CHECK_HEADERS(mad.h, [
2241     AC_CHECK_LIB(mad, mad_bit_init, [
2242       have_mad="yes"
2243       MAD_LIBS="${MAD_LIBS} -lmad"
2244     ])
2245   ])
2246   VLC_RESTORE_FLAGS
2247   AS_IF([test -n "$enable_mad" -a "${have_mad}" = "no"], [
2248     AC_MSG_ERROR([Could not find libmad. Install it or pass --disable-mad to disable it.])
2249   ])
2250 ])
2251 AC_SUBST(MAD_CFLAGS)
2252 AC_SUBST(MAD_LIBS)
2253 AM_CONDITIONAL([HAVE_MAD], [test "${have_mad}" = "yes"])
2254
2255 dnl  mpg123 plugin
2256 dnl
2257 dnl
2258 PKG_ENABLE_MODULES_VLC([MPG123], [mpg123], [libmpg123], [libmpg123 decoder support], [auto])
2259
2260
2261 AC_ARG_ENABLE(merge-ffmpeg,
2262 [  --enable-merge-ffmpeg   merge FFmpeg-based plugins (default disabled)],, [
2263   enable_merge_ffmpeg="no"
2264 ])
2265 AM_CONDITIONAL([MERGE_FFMPEG], [test "$enable_merge_ffmpeg" != "no"])
2266
2267 AC_MSG_CHECKING([for libavutil variant])
2268 PKG_CHECK_EXISTS([libavutil], [
2269   libavutil_version="$(${PKG_CONFIG} --modversion libavutil)"
2270   libavutil_micro="${libavutil_version##*.}"
2271   AS_IF([test ${libavutil_micro} -le 99], [
2272     avfork="libav"
2273   ], [
2274     avfork="ffmpeg"
2275   ])
2276 ], [
2277   avfork="none"
2278 ])
2279 AC_MSG_RESULT([${avfork}])
2280
2281 dnl
2282 dnl gstreamer stuff
2283 dnl
2284 AC_ARG_ENABLE(gst-decode,
2285   [  --enable-gst-decode     GStreamer based decoding support (currently supports only video decoding) (default auto)])
2286
2287 have_gst_decode="no"
2288 AS_IF([test "${enable_gst_decode}" != "no"], [
2289   PKG_CHECK_MODULES([GST_APP], [gstreamer-app-1.0], [
2290     PKG_CHECK_MODULES([GST_VIDEO], [gstreamer-video-1.0], [
2291       have_gst_decode="yes"
2292     ], [
2293       AC_MSG_WARN([${GST_VIDEO_PKG_ERRORS}. GStreamer decoder module will not be built.])
2294     ])
2295   ], [
2296     AC_MSG_WARN([${GST_APP_PKG_ERRORS}. GStreamer modules will not be built.])
2297   ])
2298 ])
2299 AM_CONDITIONAL([HAVE_GST_DECODE], [test "${have_gst_decode}" = "yes"])
2300
2301 dnl
2302 dnl  avcodec decoder/encoder plugin
2303 dnl
2304 AC_ARG_ENABLE(avcodec,
2305 [  --enable-avcodec        libavcodec codec (default enabled)])
2306 AS_IF([test "${enable_avcodec}" != "no"], [
2307   PKG_CHECK_MODULES(AVCODEC,[libavcodec >= 55.0.0 libavutil >= 52.0.0], [
2308     dnl PKG_CHECK_EXISTS([libavcodec < 56],, [
2309     dnl   AC_MSG_ERROR([libavcodec versions 56 and later are not supported yet.])
2310     dnl ])
2311     VLC_SAVE_FLAGS
2312     CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2313     CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2314     AC_CHECK_HEADERS(libavcodec/avcodec.h)
2315     AC_CHECK_HEADERS(libavutil/avutil.h)
2316     VLC_RESTORE_FLAGS
2317     have_avcodec="yes"
2318   ],[
2319     AC_MSG_ERROR([${AVCODEC_PKG_ERRORS}. Pass --disable-avcodec to ignore this error.])
2320   ])
2321 ], [
2322   have_avcodec="no"
2323 ])
2324 AM_CONDITIONAL([HAVE_AVCODEC], [test "${have_avcodec}" != "no"])
2325
2326 dnl
2327 dnl libva needs avcodec
2328 dnl
2329 AC_ARG_ENABLE(libva,
2330   [  --enable-libva          VAAPI GPU decoding support (libVA) (default auto)])
2331
2332 AS_IF([test "${enable_libva}" = "yes" -a "${have_avcodec}" != "yes" ], [
2333   AC_MSG_ERROR([--enable-libva and --disable-avcodec options are mutually exclusive. Use --enable-avcodec.])
2334 ])
2335
2336 have_vaapi="no"
2337 have_vaapi_drm="no"
2338 have_vaapi_x11="no"
2339 AS_IF([test "${enable_libva}" != "no"], [
2340   PKG_CHECK_EXISTS([libva], [
2341     have_vaapi="yes"
2342   ], [
2343     AS_IF([test -n "${enable_libva}"], [
2344       AC_MSG_ERROR([${LIBVA_PKG_ERRORS}.])
2345     ], [
2346       AC_MSG_WARN([${LIBVA_PKG_ERRORS}.])
2347     ])
2348   ])
2349   PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm], [
2350     have_vaapi_drm="yes"
2351   ], [
2352     AC_MSG_WARN([${LIBVA_DRM_PKG_ERRORS}.])
2353   ])
2354   PKG_CHECK_MODULES(LIBVA_X11, [libva-x11], [
2355     have_vaapi_x11="yes"
2356   ], [
2357     AC_MSG_WARN([${LIBVA_X11_PKG_ERRORS}.])
2358   ])
2359 ])
2360 AM_CONDITIONAL([HAVE_VAAPI_DRM], [test "${have_vaapi_drm}" = "yes"])
2361 AM_CONDITIONAL([HAVE_VAAPI_X11], [test "${have_vaapi_x11}" = "yes"])
2362
2363 have_avcodec_vaapi="no"
2364 AS_IF([test "${have_vaapi}" = "yes" -a "${have_avcodec}" = "yes"], [
2365   case "${avfork}" in
2366     ffmpeg)
2367       PKG_CHECK_EXISTS([libavcodec >= 57.10.100], [
2368         PKG_CHECK_EXISTS([libavcodec <= 57.12.100], [
2369           AC_MSG_ERROR([VA API requires FFmpeg libavcodec < 57.10 or > 57.12 or libav.])
2370         ])
2371       ])
2372       ;;
2373   esac
2374   VLC_SAVE_FLAGS
2375   CPPFLAGS="${CPPFLAGS} ${AVCODEC_CFLAGS}"
2376   CFLAGS="${CFLAGS} ${AVCODEC_CFLAGS}"
2377   AC_CHECK_HEADERS([libavcodec/vaapi.h], [
2378     AC_MSG_NOTICE([VA API acceleration activated])
2379     have_avcodec_vaapi="yes"
2380   ],[
2381     AS_IF([test -n "${enable_libva}"], [
2382       AC_MSG_ERROR([libva is present but libavcodec/vaapi.h is missing])
2383     ], [
2384       AC_MSG_WARN([libva is present but libavcodec/vaapi.h is missing ])
2385     ])
2386   ])
2387   VLC_RESTORE_FLAGS
2388 ])
2389 AM_CONDITIONAL([HAVE_AVCODEC_VAAPI], [test "${have_avcodec_vaapi}" = "yes"])
2390
2391 dnl
2392 dnl dxva2 needs avcodec
2393 dnl
2394 AC_ARG_ENABLE(dxva2,
2395   [  --enable-dxva2          DxVA2 GPU decoding support (default auto)])
2396
2397 have_avcodec_dxva2="no"
2398 AS_IF([test "${enable_dxva2}" != "no"], [
2399   if test "${SYS}" = "mingw32"; then
2400   AS_IF([test "x${have_avcodec}" = "xyes"], [
2401     AC_CHECK_HEADERS(dxva2api.h,
2402       [
2403         AC_CHECK_HEADERS(libavcodec/dxva2.h, [
2404            AC_MSG_NOTICE([DxVA2 acceleration activated])
2405            have_avcodec_dxva2="yes"
2406         ],[
2407     AS_IF([test "${enable_dxva2}" = "yes"],
2408           [AC_MSG_ERROR([dxva2 is present but libavcodec/dxva2.h is missing])],
2409               [AC_MSG_WARN([dxva2 is present but libavcodec/dxva2.h is missing ])])
2410         ], [#undef _WIN32_WINNT
2411             /* DXVA2 is only available in Vista and above */
2412             #define _WIN32_WINNT 0x600])
2413       ],[
2414     AS_IF([test "${enable_dxva2}" = "yes"],
2415               [AC_MSG_ERROR([Could not find required dxva2api.h])],
2416               [AC_MSG_WARN([dxva2api.h not found])])
2417       ],[#include <d3d9.h>])
2418   ],[
2419     AS_IF([test "x${enable_dxva2}" != "x"], [
2420       AC_MSG_ERROR([--enable-dxva2 and --disable-avcodec options are mutually exclusive.])
2421     ])
2422   ])
2423   fi
2424 ])
2425 AM_CONDITIONAL([HAVE_AVCODEC_DXVA2], [test "${have_avcodec_dxva2}" = "yes"])
2426
2427 dnl
2428 dnl d3d11va needs avcodec
2429 dnl
2430 AC_ARG_ENABLE(d3d11va,
2431   [  --enable-d3d11va          D3D11 GPU decoding support (default auto)])
2432
2433 have_avcodec_d3d11va="no"
2434 AS_IF([test "${enable_d3d11va}" != "no"], [
2435   if test "${SYS}" = "mingw32"; then
2436   AS_IF([test "x${have_avcodec}" = "xyes"], [
2437         AC_CHECK_TYPES([ID3D11VideoDecoder],
2438           [
2439             AC_CHECK_HEADERS(dxva2api.h,
2440               [
2441                 AC_CHECK_HEADERS(libavcodec/d3d11va.h, [
2442                    AC_MSG_NOTICE([D3D11 acceleration activated])
2443                    AC_DEFINE(HAVE_AVCODEC_D3D11VA, 1, [Define if the d3d11va module is built])
2444                    have_avcodec_d3d11va="yes"
2445                 ],[
2446                   AS_IF([test "${enable_d3d11va}" = "yes"],
2447                     [AC_MSG_ERROR([d3d11va is present but libavcodec/d3d11va.h is missing])],
2448                         [AC_MSG_WARN([d3d11va is present but libavcodec/d3d11va.h is missing ])])
2449                   ], [#undef _WIN32_WINNT
2450                       /* D3D11 is only available in Vista and above */
2451                       #define _WIN32_WINNT 0x600])
2452                   ],[
2453                     AS_IF([test "${enable_d3d11va}" = "yes"],
2454                           [AC_MSG_ERROR([Could not find required dxva2api.h])],
2455                           [AC_MSG_WARN([dxva2api.h not found])])
2456                   ],[#include <d3d9.h>])
2457           ],[
2458             AS_IF([test "${enable_d3d11va}" = "yes"],
2459                   [AC_MSG_ERROR([Could not find required ID3D11VideoDecoder in d3d11.h])],
2460                   [AC_MSG_WARN([ID3D11VideoDecoder not found])])
2461           ], [#include <d3d11.h>])
2462   ],[
2463     AS_IF([test "x${enable_d3d11va}" != "x"], [
2464       AC_MSG_ERROR([--enable-d3d11va and --disable-avcodec options are mutually exclusive.])
2465     ])
2466   ])
2467   fi
2468 ])
2469 AM_CONDITIONAL([HAVE_AVCODEC_D3D11VA], [test "${have_avcodec_d3d11va}" = "yes"])
2470
2471 dnl
2472 dnl DXGI debug
2473 dnl
2474 AC_CHECK_HEADERS(dxgidebug.h)
2475
2476 dnl
2477 dnl vda needs avcodec
2478 dnl
2479 AC_ARG_ENABLE(vda,
2480   [  --enable-vda          VDA  support (default auto)])
2481
2482 have_avcodec_vda="no"
2483 AS_IF([test "${enable_vda}" != "no"], [
2484   if test "${SYS}" = "darwin"; then
2485   AS_IF([test "x${have_avcodec}" = "xyes"], [
2486     AC_CHECK_HEADERS(VideoDecodeAcceleration/VDADecoder.h,
2487       [
2488         AC_CHECK_HEADERS(libavcodec/vda.h, [
2489            have_avcodec_vda="yes"
2490         ],[
2491         AS_IF([test "${enable_vda}" = "yes"],
2492               [AC_MSG_ERROR([vda is present but libavcodec/vda.h is missing])],
2493               [AC_MSG_WARN([vda is present but libavcodec/vda.h is missing ])])
2494         ])
2495   ],[
2496         AS_IF([test "${enable_vda}" = "yes"],
2497               [AC_MSG_ERROR([Could not find required VideoDecodeAcceleration/VDADecoder.h])],
2498               [AC_MSG_WARN([VideoDecodeAcceleration/VDADecoder.h not found])])
2499       ])
2500   ],[
2501     AS_IF([test "x${enable_vda}" != "x"], [
2502       AC_MSG_ERROR([--enable-vda and --disable-avcodec options are mutually exclusive.])
2503     ])
2504  ])
2505  AS_IF([test "${have_avcodec_vda}" = "yes"], [
2506      SAVE_LIBS=$LIBS
2507      LIBS="$LIBS $AVCODEC_LIBS"
2508      AC_CHECK_FUNCS([av_vda_alloc_context])
2509      LIBS=$SAVE_LIBS
2510  ])
2511  fi
2512 ])
2513 AM_CONDITIONAL([HAVE_AVCODEC_VDA], [test "${have_avcodec_vda}" = "yes"])
2514
2515 dnl
2516 dnl  avformat demuxer/muxer plugin
2517 dnl
2518
2519 AC_ARG_ENABLE(avformat,
2520 [  --enable-avformat       libavformat containers (default enabled)],, [
2521   enable_avformat="${have_avcodec}"
2522 ])
2523 have_avformat="no"
2524 AS_IF([test "${enable_avformat}" != "no"], [
2525   PKG_CHECK_MODULES(AVFORMAT,[libavformat >= 53.21.0 libavcodec libavutil], [
2526       have_avformat="yes"
2527       VLC_SAVE_FLAGS
2528       CPPFLAGS="${CPPFLAGS} ${AVFORMAT_CFLAGS}"
2529       CFLAGS="${CFLAGS} ${AVFORMAT_CFLAGS}"
2530       AC_CHECK_HEADERS(libavformat/avformat.h libavformat/avio.h)
2531       AC_CHECK_HEADERS(libavcodec/avcodec.h)
2532       AC_CHECK_HEADERS(libavutil/avutil.h)
2533       AS_IF([test "$enable_merge_ffmpeg" = "no"], [
2534         have_avformat="no"
2535       ])
2536       VLC_RESTORE_FLAGS
2537     ],[
2538       AC_MSG_ERROR([${AVFORMAT_PKG_ERRORS}. Pass --disable-avformat to ignore this error.])
2539   ])
2540 ])
2541 AM_CONDITIONAL([HAVE_AVFORMAT], [test "${enable_avformat}" != "no"])
2542
2543 dnl
2544 dnl  swscale image scaling and conversion plugin
2545 dnl
2546
2547 AC_ARG_ENABLE(swscale,
2548   AS_HELP_STRING([--enable-swscale],[libswscale image scaling and conversion
2549           (default enabled)]))
2550 if test "${enable_swscale}" != "no"
2551 then
2552   PKG_CHECK_MODULES(SWSCALE,[libswscale],
2553     [
2554       VLC_SAVE_FLAGS
2555       CPPFLAGS="${CPPFLAGS} ${SWSCALE_CFLAGS}"
2556       CFLAGS="${CFLAGS} ${SWSCALE_CFLAGS}"
2557       AC_CHECK_HEADERS(libswscale/swscale.h)
2558       AC_CHECK_HEADERS(libavutil/avutil.h)
2559       VLC_ADD_PLUGIN([swscale])
2560       VLC_ADD_LIBS([swscale],[$SWSCALE_LIBS])
2561       VLC_ADD_CFLAGS([swscale],[$SWSCALE_CFLAGS])
2562       AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2563         VLC_ADD_LIBS([swscale],[${ac_cv_ld_bsymbolic}])
2564       ])
2565       VLC_RESTORE_FLAGS
2566     ],[
2567       AC_MSG_ERROR([${SWSCALE_PKG_ERRORS}. Pass --disable-swscale to ignore this error. Proper software scaling and some video chroma conversion will be missing.])
2568   ])
2569 fi
2570
2571 dnl
2572 dnl  postproc plugin
2573 dnl
2574
2575 AC_ARG_ENABLE(postproc,
2576 [  --enable-postproc       libpostproc image post-processing (default auto)])
2577 if test "${enable_postproc}" != "no"
2578 then
2579   PKG_CHECK_MODULES(POSTPROC,[libpostproc libavutil],
2580     [
2581       VLC_SAVE_FLAGS
2582       CPPFLAGS="${CPPFLAGS} ${POSTPROC_CFLAGS}"
2583       CFLAGS="${CFLAGS} ${POSTPROC_CFLAGS}"
2584       AC_CHECK_HEADERS(postproc/postprocess.h)
2585       VLC_ADD_PLUGIN([postproc])
2586       VLC_RESTORE_FLAGS
2587     ],[
2588       AC_MSG_WARN([${POSTPROC_PKG_ERRORS}.])
2589   ])
2590 fi
2591
2592 dnl
2593 dnl  faad decoder plugin
2594 dnl
2595 AC_ARG_ENABLE(faad,
2596 [  --enable-faad           faad codec (default auto)])
2597 have_faad="no"
2598 AS_IF([test "${enable_faad}" != "no"], [
2599   AC_CHECK_HEADERS([neaacdec.h], [
2600     AC_CHECK_LIB(faad, NeAACDecOpen, [have_faad="yes"],, [$LIBM])
2601
2602     AS_IF([test "${have_faad}" = "yes"], [
2603       VLC_ADD_PLUGIN([faad])
2604       VLC_ADD_LIBS([faad],[-lfaad])
2605     ], [
2606       AS_IF([test "${enable_faad}" = "yes"], [
2607         AC_MSG_ERROR([cannot find FAAD library])
2608       ], [
2609         AC_MSG_WARN([cannot find FAAD library])
2610       ])
2611     ])
2612   ])
2613 ])
2614
2615 dnl
2616 dnl libvpx decoder plugin
2617 dnl
2618 AC_ARG_ENABLE(vpx,
2619     AS_HELP_STRING([--enable-vpx],[libvpx VP8/VP9 encoder and decoder (default auto)]))
2620 AS_IF([test "${enable_vpx}" != "no"],[
2621     PKG_CHECK_MODULES([VPX], [vpx] , [
2622         VLC_ADD_PLUGIN([vpx])
2623         VLC_ADD_CPPFLAGS([vpx], [${VPX_CFLAGS}])
2624         VLC_ADD_LIBS([vpx], [${VPX_LIBS}])
2625         AC_CHECK_LIB([vpx],[vpx_codec_vp8_dx], [
2626             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_DECODER])
2627         ], [], [${VPX_LIBS}])
2628         AC_CHECK_LIB([vpx],[vpx_codec_vp9_dx], [
2629             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_DECODER])
2630         ], [], [${VPX_LIBS}])
2631         AC_CHECK_LIB([vpx],[vpx_codec_vp8_cx], [
2632             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP8_ENCODER])
2633         ], [], [${VPX_LIBS}])
2634         AC_CHECK_LIB([vpx],[vpx_codec_vp9_cx], [
2635             VLC_ADD_CPPFLAGS([vpx], [-DENABLE_VP9_ENCODER])
2636         ], [], [${VPX_LIBS}])
2637     ], [
2638     AS_IF([test "${enable_vpx}" = "yes"],[
2639         AC_MSG_ERROR([libvpx was not found])
2640     ])])
2641 ])
2642
2643 dnl
2644 dnl twolame encoder plugin
2645 dnl
2646 PKG_ENABLE_MODULES_VLC([TWOLAME], [], [twolame], [MPEG Audio Layer 2 encoder], [auto], [], [], [ -DLIBTWOLAME_STATIC])
2647
2648 dnl
2649 dnl fdk-aac encoder plugin
2650 dnl
2651 PKG_ENABLE_MODULES_VLC([FDKAAC], [], [fdk-aac], [FDK-AAC encoder], [disabled])
2652
2653
2654 dnl
2655 dnl A52/AC3 decoder plugin
2656 dnl
2657 AC_ARG_ENABLE(a52,
2658   [  --enable-a52            A/52 support with liba52 (default enabled)])
2659 if test "${enable_a52}" != "no"
2660 then
2661   AC_ARG_WITH(a52,
2662     [  --with-a52=PATH         a52 headers and libraries])
2663     if test -z "${with_a52}"
2664     then
2665       LDFLAGS_test=""
2666       CPPFLAGS_test=""
2667     else
2668       LDFLAGS_test="-L${with_a52}/lib"
2669       CPPFLAGS_test="-I${with_a52}/include"
2670     fi
2671     VLC_SAVE_FLAGS
2672     CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_test} ${CPPFLAGS_a52tofloat32}"
2673     LDFLAGS="${LDFLAGS} ${LDFLAGS_test} ${LIBS_a52tofloat32}"
2674     AC_CHECK_HEADERS(a52dec/a52.h, [
2675       AC_CHECK_LIB(a52, a52_free, [
2676         VLC_ADD_PLUGIN([a52tofloat32])
2677         VLC_ADD_LIBS([a52tofloat32],[${LDFLAGS_test} -la52])
2678         VLC_ADD_CPPFLAGS([a52tofloat32],[${CPPFLAGS_test}])
2679       ],[
2680         AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2681         ], [$LIBM])
2682     ],[
2683       AC_MSG_ERROR([Could not find liba52 on your system: you may get it from http://liba52.sf.net/. Alternatively you can use --disable-a52 to disable the a52 plugin.])
2684     ])
2685     VLC_RESTORE_FLAGS
2686 fi
2687
2688 dnl
2689 dnl DTS Coherent Acoustics decoder plugin
2690 dnl
2691 PKG_ENABLE_MODULES_VLC([DCA], [dtstofloat32], [libdca >= 0.0.5], [DTS Coherent Acoustics support with libdca], [auto])
2692
2693 dnl
2694 dnl  Flac plugin
2695 dnl
2696 PKG_ENABLE_MODULES_VLC([FLAC], [], [flac], [libflac decoder/encoder support], [auto])
2697
2698 dnl
2699 dnl  Libmpeg2 plugin
2700 dnl
2701 PKG_ENABLE_MODULES_VLC([LIBMPEG2], [], [libmpeg2 > 0.3.2], [libmpeg2 decoder support], [auto])
2702
2703 dnl
2704 dnl  Vorbis plugin
2705 dnl
2706 PKG_ENABLE_MODULES_VLC([VORBIS], [], [ogg vorbis >= 1.1 vorbisenc >= 1.1], [Vorbis decoder and encoder], [auto])
2707
2708 dnl
2709 dnl  Tremor plugin
2710 dnl
2711 AC_ARG_ENABLE(tremor,
2712   [  --enable-tremor         Tremor decoder support (default disabled)])
2713 if test "${enable_tremor}" = "yes"
2714 then
2715   AC_CHECK_HEADERS(tremor/ivorbiscodec.h, [
2716     VLC_ADD_PLUGIN([tremor])
2717    ],[])
2718 fi
2719
2720 dnl
2721 dnl  Speex plugins
2722 dnl
2723 PKG_ENABLE_MODULES_VLC([SPEEX], [], [ogg speex >= 1.0.5], [Speex support], [auto])
2724 have_speexdsp="no"
2725 AS_IF([test "${enable_speex}" != "no"], [
2726   PKG_CHECK_MODULES([SPEEXDSP], [speexdsp], [
2727     have_speexdsp="yes"
2728   ], [
2729     AC_MSG_WARN([${SPEEXDSP_PKG_ERRORS}.])
2730   ])
2731 ])
2732 AM_CONDITIONAL([HAVE_SPEEXDSP], [test "$have_speexdsp" = "yes"])
2733
2734 dnl
2735 dnl  Opus plugin
2736 dnl
2737 PKG_ENABLE_MODULES_VLC([OPUS], [], [ogg opus >= 1.0.3], [Opus support], [auto])
2738
2739 dnl
2740 dnl  theora decoder plugin
2741 dnl
2742 PKG_ENABLE_MODULES_VLC([THEORA], [], [ogg theoradec >= 1.0 theoraenc], [experimental theora codec], [auto])
2743
2744 dnl
2745 dnl  OggSpots decoder plugin
2746 dnl
2747 PKG_ENABLE_MODULES_VLC([OGGSPOTS], [], [ogg], [experimental OggSpots codec], [auto])
2748
2749 dnl
2750 dnl  Daala decoder plugin
2751 dnl
2752 PKG_ENABLE_MODULES_VLC([DAALA], [], [daaladec daalaenc], [experimental daala codec], [disabled])
2753
2754 dnl
2755 dnl  schroedinger decoder plugin (for dirac format video)
2756 dnl
2757 PKG_ENABLE_MODULES_VLC([SCHROEDINGER], [], [schroedinger-1.0 >= 1.0.10], [dirac decoder and encoder using schroedinger], [auto])
2758
2759 dnl
2760 dnl  PNG decoder module
2761 dnl
2762 AC_ARG_ENABLE(png,
2763   [  --enable-png            PNG support (default enabled)])
2764 AS_IF([test "${enable_png}" != "no"], [
2765 AC_CHECK_HEADERS(png.h, [
2766   VLC_SAVE_FLAGS
2767   LDFLAGS="${LDFLAGS} -lz $LIBM"
2768   AC_CHECK_LIB(png, png_set_rows, [
2769     VLC_ADD_PLUGIN([png])
2770   ], [], [-lz $LIBM])
2771   VLC_RESTORE_FLAGS
2772   ])
2773 ])
2774
2775 dnl
2776 dnl  JPEG decoder module
2777 dnl
2778 AC_ARG_ENABLE(jpeg,
2779   [  --enable-jpeg           JPEG support (default enabled)])
2780 AS_IF([test "${enable_jpeg}" != "no"], [
2781 AC_CHECK_HEADERS(jpeglib.h, [
2782   VLC_ADD_PLUGIN([jpeg])
2783   ])
2784 ])
2785
2786 dnl
2787 dnl  BPG decoder module
2788 dnl
2789 AC_ARG_ENABLE(bpg,
2790   [  --enable-bpg           BPG support (default disabled)])
2791 AS_IF([test "${enable_bpg}" != "no"], [
2792 AC_CHECK_HEADERS(libbpg.h, [
2793   VLC_ADD_PLUGIN([bpg])
2794   ])
2795 ])
2796
2797 dnl
2798 dnl H262 encoder plugin (lib262)
2799 dnl
2800 AC_ARG_ENABLE(x262,
2801   [  --enable-x262           H262 encoding support with static libx262 (default disabled)])
2802 if test "${enable_x262}" != "no"; then
2803     PKG_CHECK_MODULES(X262, x262, [
2804         VLC_ADD_PLUGIN([x262])
2805         VLC_ADD_LDFLAGS([x262],[${X262_LIBS}])
2806         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2807           VLC_ADD_LIBS([x262],[${av_cv_ld_bsymbolic}])
2808         ])
2809         VLC_ADD_CFLAGS([x262],[${X262_CFLAGS}])
2810         if echo ${X262_LIBS} |grep -q 'pthreadGC2'; then
2811           VLC_ADD_CFLAGS([x262], [-DPTW32_STATIC_LIB])
2812         fi
2813     ], [
2814        if test "${enable_x262}" = "yes"; then
2815         AC_MSG_ERROR([x262 module doesn't work without staticly compiled libx262.a])
2816        fi
2817     ])
2818 fi
2819
2820 dnl x265 encoder
2821 PKG_ENABLE_MODULES_VLC([X265],, [x265], [HEVC/H.265 encoder], [auto])
2822
2823 dnl
2824 dnl H264 encoder plugin (10-bit lib264)
2825 dnl
2826 AC_ARG_ENABLE(x26410b,
2827   [  --enable-x26410b           H264 10-bit encoding support with static libx264 (default disabled)])
2828 if test "${enable_x26410b}" != "no"; then
2829     PKG_CHECK_MODULES(X26410B, x26410b, [
2830         VLC_ADD_PLUGIN([x26410b])
2831         VLC_ADD_LIBS([x26410b],[${X26410B_LIBS}])
2832         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2833           VLC_ADD_LDFLAGS([x26410b],[${ac_cv_ld_bsymbolic}])
2834         ])
2835         VLC_ADD_CFLAGS([x26410b],[${X26410B_CFLAGS}])
2836         if echo ${X26410B_LIBS} |grep -q 'pthreadGC2'; then
2837           VLC_ADD_CFLAGS([x26410b], [-DPTW32_STATIC_LIB])
2838         fi
2839     ], [
2840        if test "${enable_x26410b}" = "yes"; then
2841         AC_MSG_ERROR([x26410b module doesn't work without staticly compiled libx264.a])
2842        fi
2843     ])
2844 fi
2845
2846
2847 dnl
2848 dnl H264 encoder plugin (using libx264)
2849 dnl
2850 AC_ARG_ENABLE(x264,
2851   [  --enable-x264           H264 encoding support with libx264 (default enabled)])
2852 if test "${enable_x264}" != "no"; then
2853       PKG_CHECK_MODULES(X264,x264 >= 0.86, [
2854         VLC_ADD_PLUGIN([x264])
2855         VLC_ADD_LIBS([x264],[${X264_LIBS}])
2856
2857         AS_IF([test -n "${ac_cv_ld_bsymbolic}"], [
2858           VLC_ADD_LDFLAGS([x264],[${ac_cv_ld_bsymbolic}])
2859         ])
2860
2861         VLC_ADD_CFLAGS([x264],[${X264_CFLAGS}])
2862         if echo ${X264_LIBS} |grep -q 'pthreadGC2'; then
2863           VLC_ADD_CFLAGS([x264], [-DPTW32_STATIC_LIB])
2864         fi
2865       ],[
2866         if test "${enable_x264}" = "yes"; then
2867             AC_MSG_ERROR([${X264_PKG_ERRORS}: you may get it from http://www.videolan.org/x264.html])
2868           fi
2869       ])
2870 fi
2871
2872 dnl
2873 dnl Intel QuickSync (aka MediaSDK) H264/H262 encoder
2874 dnl
2875 PKG_ENABLE_MODULES_VLC([MFX], [qsv], [libmfx], [Intel QuickSync MPEG4-Part10/MPEG2 (aka H.264/H.262) encoder], [auto])
2876
2877 dnl
2878 dnl libfluidsynth (MIDI synthetizer) plugin
2879 dnl
2880 PKG_ENABLE_MODULES_VLC([FLUIDSYNTH], [], [fluidsynth >= 1.1.2], [MIDI synthetiser with libfluidsynth], [auto])
2881
2882 dnl
2883 dnl Teletext Modules
2884 dnl vbi decoder plugin (using libzbvi)
2885 dnl telx module
2886 dnl uncompatible
2887 dnl
2888 AC_ARG_ENABLE(zvbi,
2889   AS_HELP_STRING([--enable-zvbi],[VBI (inc. Teletext) decoding support with
2890                   libzvbi (default enabled)]))
2891 AC_ARG_ENABLE(telx,
2892   AS_HELP_STRING([--enable-telx],[Teletext decoding module (conflicting with
2893                   zvbi) (default enabled if zvbi is absent)]))
2894
2895 AS_IF( [test "${enable_zvbi}" != "no"],[
2896     PKG_CHECK_MODULES(ZVBI, [zvbi-0.2 >= 0.2.28],
2897         [
2898           VLC_ADD_PLUGIN([zvbi])
2899           AC_DEFINE(ZVBI_COMPILED, 1, [Define if the zvbi module is built])
2900           AS_IF( [test "${enable_telx}" = "yes"],[
2901                   AC_MSG_WARN([The zvbi and telx modules are incompatible. Using zvbi.])
2902                   ])
2903         ],[
2904           AC_MSG_WARN([${ZVBI_PKG_ERRORS}. Enabling the telx module instead.])
2905         ])
2906     ])
2907 AS_IF( [test "${enable_telx}" != "no" ],[
2908   VLC_ADD_PLUGIN([telx])
2909   ])
2910
2911 dnl
2912 dnl libass subtitle rendering module
2913 dnl
2914 AC_ARG_ENABLE(libass,
2915   [  --enable-libass         Subtitle support using libass (default enabled)])
2916 AS_IF( [test "${enable_libass}" != "no"], [
2917   PKG_CHECK_MODULES(LIBASS, [libass >= 0.9.8],
2918       [
2919         VLC_ADD_PLUGIN([libass])
2920
2921         AC_CHECK_HEADERS(fontconfig/fontconfig.h,
2922           [VLC_ADD_CPPFLAGS([libass],[-DHAVE_FONTCONFIG])
2923            VLC_ADD_LIBS([libass],[-lfontconfig])
2924        ])
2925       ],[
2926         AC_MSG_WARN([${LIBASS_PKG_ERRORS}.])
2927       ])
2928   ])
2929
2930 dnl
2931 dnl ARIB subtitles rendering module
2932 dnl
2933 AC_ARG_ENABLE(aribsub,
2934   [  --enable-aribsub        ARIB Subtitles support (default enabled)])
2935 AS_IF( [test "${enable_aribsub}" != "no" ],[
2936   PKG_CHECK_MODULES(ARIBB24, [aribb24 >= 1.0.1], [
2937       have_aribb24="yes"
2938       VLC_ADD_PLUGIN([aribsub])
2939       VLC_ADD_LIBS([aribsub],[-laribb24])
2940       AC_DEFINE(HAVE_ARIBB24, 1, [Define if libaribb24 is available.])
2941     ],[
2942       AC_MSG_WARN(Library [aribb24] needed for [aribsub] was not found)
2943       have_aribb24="no"
2944   ])
2945 ])
2946 AM_CONDITIONAL([HAVE_ARIBB24], [test x"${have_aribb24}" = x"yes"])
2947
2948 dnl
2949 dnl ARIB B25
2950 dnl
2951 PKG_ENABLE_MODULES_VLC([ARIBB25], [aribcam], [aribb25 >= 0.2.6], [ARIB STD-B25], [auto])
2952
2953 dnl
2954 dnl  kate decoder plugin
2955 dnl
2956 PKG_ENABLE_MODULES_VLC([KATE], [], [kate >= 0.3.0], [kate codec], [auto])
2957
2958 dnl
2959 dnl  tiger rendering for kate decoder plugin
2960 dnl
2961 AC_ARG_ENABLE(tiger,
2962 [  --enable-tiger          Tiger rendering library for Kate streams (default auto)])
2963 AS_IF([test "${enable_tiger}" != "no"], [
2964   PKG_CHECK_MODULES(TIGER,[tiger >= 0.3.1], [
2965       AC_DEFINE(HAVE_TIGER, 1, [Define if libtiger is available.])],[
2966         AS_IF([test -n "${enable_tiger}"], [
2967           AC_MSG_ERROR([${TIGER_PKG_ERRORS}.])
2968         ])
2969   ])
2970 ])
2971
2972
2973 dnl
2974 dnl  Video plugins
2975 dnl
2976
2977 EXTEND_HELP_STRING([Video plugins:])
2978
2979 dnl
2980 dnl  OpenGL
2981 dnl
2982 PKG_CHECK_MODULES([EGL], [egl], [
2983   have_egl="yes"
2984 ], [
2985   have_egl="no"
2986 ])
2987 AM_CONDITIONAL([HAVE_EGL], [test "${have_egl}" = "yes"])
2988
2989 have_gl="no"
2990 PKG_CHECK_MODULES([GL], [gl], [
2991   have_gl="yes"
2992 ], [
2993   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2994 #ifdef _WIN32
2995 # include <GL/glew.h>
2996 #endif
2997 #include <GL/gl.h>
2998 ]], [
2999     [int t0 = GL_TEXTURE0;]])
3000   ], [
3001     GL_CFLAGS=""
3002     have_gl="yes"
3003     AS_IF([test "${SYS}" != "mingw32"], [
3004       GL_LIBS="-lGL"
3005     ], [
3006       GL_LIBS="-lopengl32"
3007     ])
3008   ])
3009 ])
3010 AM_CONDITIONAL([HAVE_GL], [test "${have_gl}" = "yes"])
3011
3012 dnl OpenGL ES 2: depends on EGL 1.1
3013 PKG_ENABLE_MODULES_VLC([GLES2], [], [glesv2], [OpenGL ES v2 support], [disabled])
3014 dnl OpenGL ES 1: depends on EGL 1.0
3015 PKG_ENABLE_MODULES_VLC([GLES1], [], [glesv1_cm], [OpenGL ES v1 support], [disabled])
3016
3017 dnl
3018 dnl  Xlib
3019 dnl
3020
3021 AC_PATH_XTRA()
3022 AC_CHECK_HEADERS(X11/Xlib.h)
3023
3024 dnl
3025 dnl  X C Bindings modules
3026 dnl
3027 AC_ARG_ENABLE(xcb,
3028   [  --enable-xcb            X11 support with XCB (default enabled)],, [
3029   AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin"], [
3030     enable_xcb="yes"
3031   ], [
3032     enable_xcb="no"
3033   ])
3034 ])
3035 AC_ARG_ENABLE(xvideo,
3036   [  --enable-xvideo         XVideo support (default enabled)],, [
3037     enable_xvideo="$enable_xcb"
3038 ])
3039
3040 have_xcb="no"
3041 have_xcb_keysyms="no"
3042 have_xcb_randr="no"
3043 have_xcb_xvideo="no"
3044 AS_IF([test "${enable_xcb}" != "no"], [
3045   dnl libxcb
3046   PKG_CHECK_MODULES(XCB, [xcb >= 1.6])
3047   have_xcb="yes"
3048   PKG_CHECK_MODULES(XCB_SHM, [xcb-shm])
3049   PKG_CHECK_MODULES(XCB_COMPOSITE, [xcb-composite])
3050   PKG_CHECK_MODULES(XPROTO, [xproto])
3051
3052   AS_IF([test "${enable_xvideo}" != "no"], [
3053     PKG_CHECK_MODULES(XCB_XV, [xcb-xv >= 1.1.90.1], [have_xcb_xvideo="yes"])
3054   ])
3055
3056   PKG_CHECK_MODULES(XCB_RANDR, [xcb-randr >= 1.3], [have_xcb_randr="yes"])
3057
3058   dnl xcb-utils
3059   PKG_CHECK_MODULES(XCB_KEYSYMS, [xcb-keysyms >= 0.3.4], [have_xcb_keysyms="yes"], [
3060     AC_MSG_WARN([${XCB_KEYSYMS_PKG_ERRORS}. Hotkeys will not work.])
3061   ])
3062 ])
3063 AM_CONDITIONAL([HAVE_XCB], [test "${have_xcb}" = "yes"])
3064 AM_CONDITIONAL([HAVE_XCB_KEYSYMS], [test "${have_xcb_keysyms}" = "yes"])
3065 AM_CONDITIONAL([HAVE_XCB_RANDR], [test "${have_xcb_randr}" = "yes"])
3066 AM_CONDITIONAL([HAVE_XCB_XVIDEO], [test "${have_xcb_xvideo}" = "yes"])
3067
3068
3069 dnl
3070 dnl VDPAU needs X11
3071 dnl
3072 AC_ARG_ENABLE(vdpau,
3073   [AS_HELP_STRING([--enable-vdpau], [VDPAU hardware support (default auto)])])
3074 have_vdpau="no"
3075 AS_IF([test "${enable_vdpau}" != "no"], [
3076   PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.6], [
3077     have_vdpau="yes"
3078     AS_IF([test "${no_x}" = "yes"], [
3079       AC_MSG_ERROR([VDPAU requires Xlib (X11).])
3080     ])
3081   ], [
3082     AS_IF([test -n "${enable_vdpau}"], [
3083       AC_MSG_ERROR([${VDPAU_PKG_ERRORS}.])
3084     ])
3085   ])
3086 ])
3087 AM_CONDITIONAL([HAVE_VDPAU], [test "${have_vdpau}" = "yes"])
3088
3089 have_avcodec_vdpau="no"
3090 AS_IF([test "${have_vdpau}" = "yes" -a "${have_avcodec}" = "yes"], [
3091   case "${avfork}" in
3092     libav) av_vdpau_ver="55.26.0" ;;
3093     ffmpeg) av_vdpau_ver="55.42.100" ;;
3094   esac
3095   PKG_CHECK_EXISTS([libavutil >= 52.4.0 libavcodec >= ${av_vdpau_ver}], [
3096     have_avcodec_vdpau="yes"
3097     AC_MSG_NOTICE([VDPAU decoding acceleration activated])
3098   ], [
3099     AS_IF([test -n "${enable_vdpau}"], [
3100       AC_MSG_ERROR([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3101     ], [
3102       AC_MSG_WARN([libav libavutil >= 52.4.0 and libavcodec >= 55.26.0 are required for VDPAU decoding.])
3103     ])
3104   ])
3105 ])
3106 AM_CONDITIONAL([HAVE_AVCODEC_VDPAU], [test "${have_avcodec_vdpau}" = "yes"])
3107
3108
3109 dnl
3110 dnl  Wayland
3111 dnl
3112 AC_ARG_ENABLE(wayland,
3113   [AS_HELP_STRING([--enable-wayland], [Wayland support (default auto)])])
3114 have_wayland="no"
3115 AC_ARG_VAR([WAYLAND_SCANNER], [Wayland scanner utility])
3116
3117 AS_IF([test "${enable_wayland}" != "no"], [
3118   AC_MSG_CHECKING([for the Wayland scanner])
3119   AS_IF([test -z "$WAYLAND_SCANNER"], [
3120     PKG_CHECK_EXISTS([wayland-scanner], [
3121       WAYLAND_SCANNER="$(${PKG_CONFIG} wayland-scanner --variable wayland_scanner)"
3122     ], [
3123       WAYLAND_SCANNER="wayland-scanner"
3124     ])
3125   ])
3126   AC_MSG_RESULT([$WAYLAND_SCANNER])
3127
3128   PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= 1.5.91], [
3129     have_wayland="yes"
3130   ], [
3131     AS_IF([test -n "${enable_wayland}"], [
3132       AC_MSG_ERROR([${WAYLAND_CLIENT_PKG_ERRORS}.])
3133     ])
3134   ])
3135
3136   AS_IF([test "${have_egl}" = "yes"], [
3137     PKG_CHECK_MODULES([WAYLAND_EGL], [wayland-egl], [
3138       have_wayland_egl="yes"
3139     ], [
3140       AS_IF([test -n "${enable_wayland}"], [
3141         AC_MSG_ERROR([${WAYLAND_EGL_PKG_ERRORS}.])
3142       ])
3143     ])
3144   ])
3145 ])
3146 AM_CONDITIONAL([HAVE_WAYLAND], [test "${have_wayland}" = "yes"])
3147 AM_CONDITIONAL([HAVE_WAYLAND_EGL], [test "${have_wayland_egl}" = "yes"])
3148
3149
3150 dnl
3151 dnl  SDL module
3152 dnl
3153 AC_ARG_ENABLE(sdl,
3154   [  --enable-sdl            SDL support (default enabled)])
3155 AC_ARG_ENABLE(sdl-image,
3156   [  --enable-sdl-image      SDL image support (default enabled)])
3157 if test "${enable_sdl}" != "no"
3158 then
3159    PKG_CHECK_MODULES(SDL, [sdl >= 1.2.10], [
3160       # SDL on Darwin is heavily patched and can only run SDL_image
3161       if test "${SYS}" != "darwin"; then
3162         VLC_ADD_PLUGIN([vout_sdl])
3163       fi
3164
3165       # SDL_image
3166       AS_IF([ test "${enable_sdl_image}" != "no"],[
3167         PKG_CHECK_MODULES(SDL_IMAGE, [SDL_image >= 1.2.10], [
3168           VLC_ADD_PLUGIN([sdl_image])],
3169           [ AC_MSG_WARN([${SDL_IMAGE_PKG_ERRORS}. You should install it alongside your SDL package.])
3170           ])
3171       ])
3172    ],[
3173      AC_MSG_WARN([${SDL_PKG_ERRORS}.])
3174    ])
3175 fi
3176
3177 dnl
3178 dnl  freetype module
3179 dnl
3180 AC_ARG_ENABLE(freetype,
3181   [  --enable-freetype       freetype support   (default auto)])
3182 AC_ARG_ENABLE(fribidi,
3183   [  --enable-fribidi        fribidi support    (default auto)])
3184 AC_ARG_ENABLE(harfbuzz,
3185   [  --enable-harfbuzz       harfbuzz support   (default auto)])
3186 AC_ARG_ENABLE(fontconfig,
3187   [  --enable-fontconfig     fontconfig support (default auto)])
3188
3189 AC_ARG_WITH([default-font],
3190     AS_HELP_STRING([--with-default-font=PATH],
3191         [Path to the default font]),
3192         [AC_DEFINE_UNQUOTED([DEFAULT_FONT_FILE],
3193             "$withval", [Default font])])
3194 AC_ARG_WITH([default-monospace-font],
3195     AS_HELP_STRING([--with-default-monospace-font=PATH],
3196         [Path to the default font]),
3197         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FONT_FILE],
3198             "$withval", [Default monospace font])])
3199
3200 AC_ARG_WITH([default-font-family],
3201     AS_HELP_STRING([--with-default-font-family=NAME],
3202         [Path to the default font family]),
3203         [AC_DEFINE_UNQUOTED([DEFAULT_FAMILY],
3204             "$withval", [Default font family])])
3205 AC_ARG_WITH([default-monospace-font-family],
3206     AS_HELP_STRING([--with-default-monospace-font-family=NAME],
3207         [Path to the default font family]),
3208         [AC_DEFINE_UNQUOTED([DEFAULT_MONOSPACE_FAMILY],
3209             "$withval", [Default monospace font family])])
3210
3211 have_freetype="no"
3212 have_fontconfig="no"
3213 have_fribidi="no"
3214 have_harfbuzz="no"
3215
3216 if test "${enable_freetype}" != "no"; then
3217    PKG_CHECK_MODULES(FREETYPE, freetype2, [
3218       have_freetype="yes"
3219       VLC_ADD_CPPFLAGS([skins2],[${FREETYPE_CFLAGS}])
3220       VLC_ADD_LIBS([skins2],[${FREETYPE_LIBS}])
3221
3222       dnl fontconfig support
3223       if test "${SYS}" != "mingw32"; then
3224           if test "${enable_fontconfig}" != "no"; then
3225             AC_CHECK_HEADERS(fontconfig/fontconfig.h, [
3226               have_fontconfig="yes"
3227             ],[AC_MSG_WARN([library fontconfig not found. Styles will be disabled in freetype])])
3228           fi
3229       fi
3230
3231       dnl fribidi support
3232       if test "${enable_fribidi}" != "no"; then
3233         PKG_CHECK_MODULES(FRIBIDI, fribidi, [
3234           have_fribidi="yes"
3235           VLC_ADD_CPPFLAGS([skins2], [${FRIBIDI_CFLAGS} -DHAVE_FRIBIDI])
3236           VLC_ADD_LIBS([skins2], [${FRIBIDI_LIBS}])
3237         ],[AC_MSG_WARN([${FRIBIDI_PKG_ERRORS}. Bidirectional text and complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3238       fi
3239
3240       dnl harfbuzz support
3241       if test "${have_fribidi}" != "no"; then
3242         if test "${enable_harfbuzz}" != "no"; then
3243           PKG_CHECK_MODULES(HARFBUZZ, harfbuzz, [
3244             have_harfbuzz="yes"
3245             VLC_ADD_CPPFLAGS([skins2], [${HARFBUZZ_CFLAGS} -DHAVE_HARFBUZZ])
3246             VLC_ADD_LIBS([skins2], [${HARFBUZZ_LIBS}])
3247           ],[AC_MSG_WARN([${HARFBUZZ_PKG_ERRORS}. Support for complex scripts (Arabic, Farsi, Thai...) will be disabled in FreeType.])])
3248         fi
3249       fi
3250   ],[
3251   AS_IF([test -n "${enable_freetype}"],[
3252     AC_MSG_ERROR([${FREETYPE_PKG_ERRORS}. Install FreeType2 development or configure with --disable-freetype.])
3253     ])
3254   ])
3255 fi
3256
3257 AM_CONDITIONAL([HAVE_FREETYPE], [test "${have_freetype}" = "yes"])
3258 AM_CONDITIONAL([HAVE_FONTCONFIG], [test "${have_fontconfig}" = "yes"])
3259 AM_CONDITIONAL([HAVE_FRIBIDI], [test "${have_fribidi}" = "yes"])
3260 AM_CONDITIONAL([HAVE_HARFBUZZ], [test "${have_harfbuzz}" = "yes"])
3261
3262 dnl
3263 dnl SAPI (text to Speech renderer for Windows)
3264 dnl
3265 AC_LANG_PUSH([C++])
3266 AC_CHECK_TYPES([ISpObjectToken],[
3267               have_sapi="yes"
3268             ],[AC_MSG_WARN([sapi.h not found. Text to Speech renderer for Windows disabled])],
3269               [#include <windows.h>
3270                #include <sapi.h>
3271                #include <sphelper.h>])
3272 AM_CONDITIONAL([HAVE_SAPI], [test "${have_sapi}" = "yes"])
3273 AC_LANG_POP([C++])
3274
3275 dnl
3276 dnl  QuartzText vout module (iOS/Mac OS)
3277 dnl
3278 AC_ARG_ENABLE(macosx-quartztext,
3279   [  --enable-macosx-quartztext   Mac OS X quartz text module (default enabled on Mac OS X)])
3280 if test "x${enable_macosx_quartztext}" != "xno" &&
3281   (test "${SYS}" = "darwin" || test "${enable_macosx_quartztext}" = "yes")
3282 then
3283   VLC_ADD_PLUGIN([quartztext])
3284 fi
3285
3286 dnl
3287 dnl  SVG module (text rendering and image decoding)
3288 dnl
3289 PKG_ENABLE_MODULES_VLC([SVG], [], [librsvg-2.0 >= 2.9.0], [SVG rendering library],[auto])
3290 PKG_ENABLE_MODULES_VLC([SVGDEC], [], [librsvg-2.0 >= 2.9.0 cairo >= 1.13.1], [SVG image decoder library],[auto])
3291
3292 dnl
3293 dnl  Windows DirectX module
3294 dnl
3295
3296 AC_ARG_ENABLE(directx,
3297   [AS_HELP_STRING([--enable-directx],
3298     [Microsoft DirectX support (default enabled on Windows)])],, [
3299   AS_IF([test "${SYS}" = "mingw32"], [
3300     enable_directx="yes"
3301   ], [
3302     enable_directx="no"
3303   ])
3304 ])
3305 have_directx="no"
3306 AS_IF([test "${enable_directx}" != "no"], [
3307   dnl DirectDraw
3308   AC_CHECK_HEADERS(ddraw.h, [
3309     have_directx="yes"
3310   ], [
3311     AC_MSG_ERROR([Cannot find DirectX headers!])
3312   ])
3313
3314   dnl OpenGL
3315   AC_CHECK_HEADERS(GL/wglew.h, [
3316     VLC_ADD_PLUGIN([glwin32])
3317   ],, [
3318     #include <windows.h>
3319     #include <GL/gl.h>
3320   ])
3321
3322   dnl Direct3D11
3323   AC_CHECK_HEADERS(d3d11.h, [
3324     VLC_ADD_PLUGIN([direct3d11])
3325   ])
3326
3327   dnl Direct3D9
3328   AC_CHECK_HEADERS(d3d9.h, [
3329     VLC_ADD_PLUGIN([direct3d9])
3330   ])
3331
3332   dnl Direct2D
3333   AC_CHECK_HEADERS(d2d1.h, [
3334     VLC_ADD_PLUGIN([direct2d])
3335   ])
3336 ])
3337 AM_CONDITIONAL([HAVE_DIRECTX], [test "$have_directx" = "yes"])
3338
3339 dnl
3340 dnl  Linux framebuffer module
3341 dnl
3342 AC_CHECK_HEADER([linux/fb.h], [
3343   VLC_ADD_PLUGIN([fb])
3344 ])
3345
3346
3347 dnl
3348 dnl  DirectFB module
3349 dnl  try to find using: 1 - given location; 2 - directfb-config; 3 - pkg-config
3350 dnl  TODO: support for static linking
3351 dnl
3352 AC_ARG_ENABLE(directfb,
3353   [  --enable-directfb       DirectFB support (default disabled)])
3354 AC_ARG_WITH(directfb,
3355   [  --with-directfb=PATH    path to DirectFB headers and libraries])
3356
3357 if test "${enable_directfb}" = "yes"; then
3358     have_directfb="false"
3359     CPPFLAGS_mydirectfb=
3360     LIBS_mydirectfb=
3361     if test "${with_directfb}" != "no" -a -n "${with_directfb}"; then
3362         dnl Trying the given location
3363         VLC_SAVE_FLAGS
3364
3365         CPPFLAGS_new="-I${with_directfb}/include -D_REENTRANT -D_GNU_SOURCE"
3366         LIBS_new="-L${with_directfb}/lib/fusion/.libs/ -L${with_directfb}/lib/direct/.libs/ -L${with_directfb}/src/.libs/"
3367
3368         CPPFLAGS="${CPPFLAGS} ${CPPFLAGS_new}"
3369         LIBS="${LIBS} ${LIBS_new}"
3370
3371         dnl FIXME: too obscure
3372         AC_CHECK_HEADER([directfb.h], [
3373             AC_CHECK_LIB([direct],[direct_initialize], [
3374                 AC_CHECK_LIB([fusion], [fusion_enter], [
3375                     AC_CHECK_LIB([directfb], [DirectFBInit], have_directfb="true", have_directfb="false")
3376                 ], have_directfb="false")
3377             ], have_directfb="false")
3378         ], have_directfb="false")
3379
3380         VLC_RESTORE_FLAGS
3381
3382         if test "${have_directfb}" = "true"; then
3383             LIBS_mydirectfb="${LIBS_new} -lz $LIBDL -ldirectfb -lfusion -ldirect -lpthread"
3384             CPPFLAGS_mydirectfb="${CPPFLAGS_new}"
3385         fi
3386     else
3387         dnl Look for directfb-config
3388         AC_PATH_PROG(DIRECTFB_CONFIG, directfb-config, no, ${PATH})
3389         if test "${DIRECTFB_CONFIG}" != "no"; then
3390             CPPFLAGS_mydirectfb="`${DIRECTFB_CONFIG} --cflags`"
3391             LIBS_mydirectfb="`${DIRECTFB_CONFIG} --libs`"
3392             have_directfb="true"
3393         else
3394             dnl Trying with pkg-config
3395             PKG_CHECK_MODULES(DIRECTFB, directfb, [
3396                 CPPFLAGS_mydirectfb="${DIRECTFB_CFLAGS}"
3397                 LIBS_mydirectfb="${DIRECTFB_LIBS}"
3398                 have_directfb="true"
3399                 ], [have_directfb="false"])
3400         fi
3401     fi
3402     if test "${have_directfb}" = "true"; then
3403         VLC_ADD_PLUGIN([directfb])
3404         VLC_ADD_CPPFLAGS([directfb],[${CPPFLAGS_mydirectfb}])
3405         VLC_ADD_LIBS([directfb],[${LIBS_mydirectfb}])
3406     else
3407         AC_MSG_ERROR([${DIRECTFB_PKG_ERRORS}.])
3408     fi
3409 fi
3410
3411 dnl
3412 dnl  AA plugin
3413 dnl
3414 AC_ARG_ENABLE(aa,
3415   [  --enable-aa             aalib output (default disabled)])
3416 if test "${enable_aa}" = "yes"
3417 then
3418   AC_CHECK_HEADER(aalib.h,have_aa="true",have_aa="false")
3419   if test "${have_aa}" = "true"
3420   then
3421     VLC_ADD_PLUGIN([aa])
3422   fi
3423 fi
3424
3425 dnl
3426 dnl  libcaca plugin
3427 dnl
3428 PKG_ENABLE_MODULES_VLC([CACA], [], [caca >= 0.99.beta14], [libcaca output],[auto])
3429
3430 dnl
3431 dnl  OS/2 KVA plugin
3432 dnl
3433 AC_ARG_ENABLE(kva,
3434   [AS_HELP_STRING([--enable-kva],
3435     [support the K Video Accelerator KVA (default enabled on OS/2)])],, [
3436   AS_IF([test "$SYS" = "os2"], [
3437     enable_kva="yes"
3438   ])
3439 ])
3440 have_kva="no"
3441 KVA_LIBS=""
3442 AS_IF([test "$enable_kva" != "no"], [
3443   AC_CHECK_HEADERS([kva.h], [
3444     have_kva="yes"
3445     AC_CHECK_LIB(kva, main, [
3446       KVA_LIBS="-lkva"
3447     ])
3448   ])
3449 ])
3450 AC_SUBST(KVA_LIBS)
3451 AM_CONDITIONAL([HAVE_KVA], [test "${have_kva}" = "yes"])
3452
3453 dnl
3454 dnl MMAL plugin
3455 dnl
3456 AC_ARG_ENABLE(mmal,
3457   AS_HELP_STRING([--enable-mmal],
3458     [Multi-Media Abstraction Layer (MMAL) hardware plugin (default enable)]))
3459 if test "${enable_mmal}" != "no"; then
3460   VLC_SAVE_FLAGS
3461   LDFLAGS="${LDFLAGS} -L/opt/vc/lib -lvchostif"
3462   CPPFLAGS="${CPPFLAGS} -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux"
3463   AC_CHECK_HEADERS(interface/mmal/mmal.h,
3464     [ AC_CHECK_LIB(bcm_host, vc_tv_unregister_callback_full, [
3465         have_mmal="yes"
3466         VLC_ADD_PLUGIN([mmal])
3467         VLC_ADD_LDFLAGS([mmal],[ -L/opt/vc/lib ])
3468         VLC_ADD_CFLAGS([mmal],[ -I/opt/vc/include -I/opt/vc/include/interface/vcos/pthreads -I/opt/vc/include/interface/vmcs_host/linux ])
3469         VLC_ADD_LIBS([mmal],[ -lbcm_host -lmmal -lvchostif ]) ], [
3470           AS_IF([test "${enable_mmal}" = "yes"],
3471             [ AC_MSG_ERROR([Cannot find bcm library...]) ],
3472             [ AC_MSG_WARN([Cannot find bcm library...]) ])
3473           ],
3474         [])
3475     ] , [ AS_IF([test "${enable_mmal}" = "yes"],
3476       [ AC_MSG_ERROR([Cannot find development headers for mmal...]) ],
3477       [ AC_MSG_WARN([Cannot find development headers for mmal...]) ]) ])
3478   VLC_RESTORE_FLAGS
3479 fi
3480 AM_CONDITIONAL([HAVE_MMAL], [test "${have_mmal}" = "yes"])
3481
3482 dnl
3483 dnl evas plugin
3484 dnl
3485 AC_ARG_ENABLE(evas,
3486   [AS_HELP_STRING([--enable-evas],
3487     [use evas output module (default disabled)])])
3488 have_evas="no"
3489 AS_IF([test "${enable_evas}" = "yes"], [
3490   PKG_CHECK_MODULES(EVAS, [evas >= 1.15.99 ecore >= 1.15.99], [
3491       have_evas="yes"
3492       AC_DEFINE([HAVE_EVAS], [1], [Define to 1 if evas is enabled.])
3493     ],[
3494     AS_IF([test "x${enable_evas}" != "x"], [
3495       AC_MSG_ERROR([$EVAS_PKG_ERRORS. libevas and libecore 1.15.99 or later required.])
3496     ])
3497   ])
3498 ])
3499 AM_CONDITIONAL([HAVE_EVAS], [test "${have_evas}" = "yes"])
3500
3501 dnl
3502 dnl  Audio plugins
3503 dnl
3504
3505 EXTEND_HELP_STRING([Audio plugins:])
3506
3507 dnl
3508 dnl  Pulseaudio module
3509 dnl
3510 AC_ARG_ENABLE(pulse,
3511   [AS_HELP_STRING([--enable-pulse],
3512     [use the PulseAudio client library (default auto)])])
3513 have_pulse="no"
3514 AS_IF([test "${enable_pulse}" != "no"], [
3515   PKG_CHECK_MODULES([PULSE], [libpulse >= 1.0], [
3516     have_pulse="yes"
3517   ], [
3518     AS_IF([test "x${enable_pulse}" != "x"], [
3519       AC_MSG_ERROR([$PULSE_PKG_ERRORS. PulseAudio 1.0 or later required.])
3520     ])
3521   ])
3522 ])
3523 AM_CONDITIONAL([HAVE_PULSE], [test "${have_pulse}" = "yes"])
3524
3525 dnl
3526 dnl  ALSA module
3527 dnl
3528 AC_ARG_ENABLE(alsa,
3529   [AS_HELP_STRING([--enable-alsa],
3530     [support the Advanced Linux Sound Architecture (default auto)])],, [
3531   AS_IF([test "$SYS" = "linux" -a "${have_pulse}" = "no"], [
3532     enable_alsa="yes"
3533   ])
3534 ])
3535 have_alsa="no"
3536 AS_IF([test "${enable_alsa}" != "no"], [
3537   PKG_CHECK_MODULES([ALSA], [alsa >= 1.0.24], [
3538     have_alsa="yes"
3539   ], [
3540     AS_IF([test "x${enable_alsa}" != "x"], [
3541       AC_MSG_ERROR([$ALSA_PKG_ERRORS. alsa-lib 1.0.24 or later required.])
3542     ])
3543   ])
3544 ])
3545 AM_CONDITIONAL([HAVE_ALSA], [test "${have_alsa}" = "yes"])
3546
3547 dnl
3548 dnl  Open Sound System module
3549 dnl
3550 AC_ARG_ENABLE(oss,
3551   [AS_HELP_STRING([--enable-oss],
3552     [support the Open Sound System OSS (default enabled on FreeBSD/NetBSD/DragonFlyBSD)])],, [
3553   AS_IF([test "$SYS" = "mingw32" -o "$SYS" = "linux" -o "$SYS" = "openbsd"], [
3554     enable_oss="no"
3555   ])
3556 ])
3557 have_oss="no"
3558 OSS_LIBS=""
3559 AS_IF([test "$enable_oss" != "no"], [
3560   AC_CHECK_HEADERS([soundcard.h sys/soundcard.h], [
3561     have_oss="yes"
3562     AC_CHECK_LIB(ossaudio, main, [
3563       OSS_LIBS="-lossaudio"
3564     ])
3565   ])
3566 ])
3567 AC_SUBST(OSS_LIBS)
3568 AM_CONDITIONAL([HAVE_OSS], [test "${have_oss}" = "yes"])
3569
3570 dnl
3571 dnl  OpenBSD sndio module
3572 dnl
3573 AC_ARG_ENABLE([sndio],
3574   [AS_HELP_STRING([--disable-sndio],
3575     [support the OpenBSD sndio (default auto)])],, [
3576   AS_IF([test "$SYS" = "openbsd"], [
3577     enable_sndio="yes"
3578   ])
3579 ])
3580 have_sndio="no"
3581 AS_IF([test "$enable_sndio" != "no"], [
3582   AC_CHECK_HEADER([sndio.h], [
3583     have_sndio="yes"
3584   ])
3585 ])
3586 AM_CONDITIONAL([HAVE_SNDIO], [test "${have_sndio}" = "yes"])
3587
3588 dnl
3589 dnl  Windows Audio Session plugin
3590 dnl
3591 AC_ARG_ENABLE([wasapi],
3592   [AS_HELP_STRING([--enable-wasapi],
3593     [use the Windows Audio Session API (default auto)])
3594 ])
3595 have_wasapi="no"
3596 AS_IF([test "$enable_wasapi" != "no"], [
3597   AC_CHECK_HEADER([audioclient.h], [
3598     have_wasapi="yes"
3599   ], [
3600     AS_IF([test "x${enable_wasapi}" != "x"], [
3601       AC_MSG_ERROR([Windows Audio Session API not found.])
3602     ])
3603   ])
3604 ])
3605 AM_CONDITIONAL([HAVE_WASAPI], [test "${have_wasapi}" = "yes"])
3606
3607 dnl
3608 dnl  AudioQueue plugin
3609 dnl
3610 AC_ARG_ENABLE(audioqueue,
3611   [  --enable-audioqueue     AudioQueue audio module (default disabled)])
3612 if test "${enable_audioqueue}" = "yes"
3613 then
3614   VLC_ADD_PLUGIN([audioqueue])
3615 fi
3616
3617 dnl
3618 dnl  JACK modules
3619 dnl
3620 AC_ARG_ENABLE(jack,
3621   [AS_HELP_STRING([--disable-jack],
3622     [do not use jack (default auto)])])
3623 have_jack="no"
3624 AS_IF([test "${enable_jack}" != "no"], [
3625     PKG_CHECK_MODULES(JACK, jack >= 1.9.7,
3626       [ have_jack=yes ],
3627       [
3628       AC_MSG_WARN([${JACK_PKG_ERRORS}, trying jack1 instead])
3629
3630       PKG_CHECK_MODULES(JACK, jack >= 0.120.1 jack < 1.0,
3631       [ have_jack=yes ],
3632       [
3633       AS_IF([test -n "${enable_jack}"],
3634          [AC_MSG_ERROR([${JACK_PKG_ERRORS}.])],
3635          [AC_MSG_WARN([${JACK_PKG_ERRORS}.])])
3636       ])
3637     ])
3638 ])
3639 AM_CONDITIONAL([HAVE_JACK], [test "${have_jack}" != "no"])
3640
3641 dnl
3642 dnl  OpenSLES Android
3643 dnl
3644 AC_ARG_ENABLE(opensles,
3645   [  --enable-opensles       Android OpenSL ES audio module (default disabled)])
3646 if test "${HAVE_ANDROID}" = "1"; then
3647   if test "${enable_opensles}" = "yes"; then
3648       AC_CHECK_HEADERS(SLES/OpenSLES.h,
3649         [ VLC_ADD_PLUGIN([opensles_android]) ],
3650         [ AC_MSG_ERROR([cannot find OpenSLES headers])] )
3651   fi
3652 fi
3653
3654 dnl
3655 dnl  Tizen audio
3656 dnl
3657 AC_ARG_ENABLE(tizen_audio,
3658   [AS_HELP_STRING([--enable-tizen-audio],
3659     [Tizen audio module (default enabled on Tizen)])],, [
3660   AS_IF([test "$HAVE_TIZEN" = "1"], [
3661     enable_tizen_audio="yes"
3662   ])
3663 ])
3664 if test "${enable_tizen_audio}" = "yes"; then
3665   AC_CHECK_HEADERS(audio_io.h,
3666     [ VLC_ADD_PLUGIN([tizen_audio]) ],
3667     [ AC_MSG_ERROR([cannot find Tizen audio_io headers])] )
3668 fi
3669
3670 dnl
3671 dnl libsamplerate plugin
3672 dnl
3673 PKG_ENABLE_MODULES_VLC([SAMPLERATE], [], [samplerate], [Resampler with libsamplerate], [auto])
3674
3675 dnl
3676 dnl  soxr module
3677 dnl
3678 PKG_ENABLE_MODULES_VLC([SOXR], [], [soxr >= 0.1.2], [SoX Resampler library], [auto])
3679
3680 dnl
3681 dnl  OS/2 KAI plugin
3682 dnl
3683 AC_ARG_ENABLE(kai,
3684   [AS_HELP_STRING([--enable-kai],
3685     [support the K Audio Interface KAI (default enabled on OS/2)])],, [
3686   AS_IF([test "$SYS" = "os2"], [
3687     enable_kai="yes"
3688   ])
3689 ])
3690 have_kai="no"
3691 KAI_LIBS=""
3692 AS_IF([test "$enable_kai" != "no"], [
3693   AC_CHECK_HEADERS([kai.h], [
3694     have_kai="yes"
3695     AC_CHECK_LIB(kai, main, [
3696       KAI_LIBS="-lkai"
3697     ])
3698   ])
3699 ])
3700 AC_SUBST(KAI_LIBS)
3701 AM_CONDITIONAL([HAVE_KAI], [test "${have_kai}" = "yes"])
3702
3703 dnl
3704 dnl  chromaprint audio track fingerprinter
3705 dnl
3706 m4_pushdef([libchromaprint_version], 0.6.0)
3707 PKG_WITH_MODULES([CHROMAPRINT],[libchromaprint >= libchromaprint_version],
3708     VLC_ADD_PLUGIN([stream_out_chromaprint]),
3709     AS_IF([test "${enable_chromaprint}" = "yes"],
3710         [AC_MSG_ERROR(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)],
3711         [AC_MSG_WARN(Library [libchromaprint >= libchromaprint_version] needed for [chromaprint] was not found)]
3712          ),
3713     [(Chromaprint based audio fingerprinter)],[auto])
3714 m4_popdef([libchromaprint_version])
3715
3716 dnl
3717 dnl  Chromecast streaming support
3718 dnl
3719 m4_pushdef([protobuf_lite_version], 2.5.0)
3720 AC_ARG_VAR(PROTOC, [protobuf compiler])
3721 AC_CHECK_PROGS(PROTOC, protoc, no)
3722 PKG_WITH_MODULES([CHROMECAST],[protobuf-lite >= protobuf_lite_version], [
3723     AS_IF([test "x${PROTOC}" != "xno"], [
3724         build_chromecast="yes"
3725     ], [
3726     AC_MSG_ERROR(protoc compiler needed for [chromecast] was not found)
3727     ])
3728 ], [
3729     AS_IF([test "${enable_chromecast}" = "yes"],
3730         AC_MSG_ERROR(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found),
3731         AC_MSG_WARN(Library [protobuf-lite >= protobuf_lite_version] needed for [chromecast] was not found)
3732     )
3733     enable_chromecast="no"
3734 ], [(Chromecast streaming support)], [auto])
3735 AM_CONDITIONAL([BUILD_CHROMECAST], [test "${build_chromecast}" = "yes"])
3736 m4_popdef([protobuf_lite_version])
3737
3738 dnl
3739 dnl  Interface plugins
3740 dnl
3741
3742 EXTEND_HELP_STRING([Interface plugins:])
3743
3744 dnl
3745 dnl QT
3746 dnl
3747 AC_ARG_ENABLE(qt, [
3748   AS_HELP_STRING([--disable-qt], [Qt UI support (default enabled)])],, [
3749   AS_IF([test "${SYS}" = "darwin"], [
3750     enable_qt="no"
3751   ])
3752 ])
3753 AS_IF([test "${enable_qt}" != "no"], [
3754   PKG_CHECK_MODULES([QT], [Qt5Core >= 5.2.0 Qt5Widgets Qt5Gui], [
3755       PKG_CHECK_MODULES([QTX11], [Qt5X11Extras], [
3756           VLC_ADD_LIBS([qt],[${QTX11_LIBS}])
3757           VLC_ADD_CXXFLAGS([qt],[${QTX11_CFLAGS} -DQT5_HAS_X11])
3758           PKG_CHECK_MODULES([XI], [xi], [
3759             VLC_ADD_LIBS([qt], [${XI_LIBS}])
3760             VLC_ADD_CXXFLAGS([qt], [${XI_CFLAGS} -DHAVE_XI])
3761           ], [
3762             PKG_CHECK_EXISTS([Qt5Gui >= 5.5], [
3763               AC_MSG_ERROR([${XI_PKG_ERRORS}.])
3764             ], [
3765               AC_MSG_WARN([${XI_PKG_ERRORS}.])
3766             ])
3767           ])
3768       ],[
3769           AC_MSG_WARN([Not building Qt Interface with X11 helpers.])
3770       ])
3771       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix Qt5Core)"
3772       QT_HOST_PATH="$(eval $PKG_CONFIG --variable=host_bins Qt5Core)"
3773       AC_PATH_PROGS(MOC, [moc-qt5 moc], moc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3774       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], rcc, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3775       AC_PATH_PROGS(UIC, [uic-qt5 uic], uic, ["${QT_HOST_PATH}" "${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3776     ], [
3777       PKG_CHECK_MODULES([QT], [QtCore QtGui >= 4.8.0],, [
3778         AS_IF([test -n "${enable_qt}"],[
3779           AC_MSG_ERROR([${QT_PKG_ERRORS}.])
3780         ],[
3781           AC_MSG_WARN([${QT_PKG_ERRORS}.])
3782         ])
3783         enable_qt="no"
3784       ])
3785       QT_PATH="$(eval $PKG_CONFIG --variable=exec_prefix QtCore)"
3786       AC_PATH_PROGS(MOC, [moc-qt4 moc], moc, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3787       AC_PATH_PROG(RCC, rcc, rcc, [${QT_PATH}/bin ${CONTRIB_DIR}/bin])
3788       AC_PATH_PROGS(UIC, [uic-qt4 uic], uic, ["${QT_PATH}/bin" "${CONTRIB_DIR}/bin"])
3789     ])
3790 ])
3791 AS_IF([test "${enable_qt}" != "no"], [
3792   VLC_ADD_PLUGIN([qt])
3793   ALIASES="${ALIASES} qvlc"
3794 ])
3795 AM_CONDITIONAL(ENABLE_QT, [test "$enable_qt" != "no"])
3796
3797 dnl
3798 dnl detect kde4-config patch (used for kde solids and kwallet).
3799 dnl
3800 AC_ARG_VAR([KDE4_CONFIG], [kde4-config utility])
3801 AS_IF([test "x$KDE4_CONFIG" = "x"], [
3802   KDE4_CONFIG="kde4-config"
3803 ])
3804
3805 dnl
3806 dnl Simple test for skins2 dependency
3807 dnl
3808 AS_IF([test "$enable_qt" = "no"], [
3809   AS_IF([test "${enable_skins2}" = "yes"], [
3810     AC_MSG_ERROR([The skins2 module depends on the Qt interface. Without it you will not be able to open any dialog box from the interface, which makes the skins2 interface rather useless. Install the Qt development package or alternatively you can also configure with: --disable-qt --disable-skins2.])
3811   ], [
3812     enable_skins2="no"
3813     AC_MSG_WARN([The skins2 module depends on the Qt interface, Qt is not built so skins2 is disabled.])
3814   ])
3815 ])
3816
3817 dnl
3818 dnl Skins2 module
3819 dnl
3820 AC_ARG_ENABLE(skins2,
3821   [AS_HELP_STRING([--enable-skins2], [skins interface module (default auto)])])
3822 AS_IF([test "${enable_skins2}" != "no"], [
3823   have_skins_deps="yes"
3824
3825   dnl Win32
3826   AS_IF([test "${SYS}" = "mingw32"], [
3827     VLC_ADD_CPPFLAGS([skins2],[-U_OFF_T_ -U_off_t -DWIN32_SKINS])
3828     VLC_ADD_LIBS([skins2],[-lgdi32 -lole32 -luuid -lmsimg32])
3829   dnl MacOS
3830   ], [test "${SYS}" = "darwin"], [
3831     VLC_ADD_CPPFLAGS([skins2],[ -DMACOSX_SKINS])
3832     VLC_ADD_LIBS([skins2],[-Wl,-framework,Carbon])
3833   dnl OS/2
3834   ], [test "${SYS}" = "os2"], [
3835     VLC_ADD_CPPFLAGS([skins2],[ -DOS2_SKINS])
3836   dnl Linux/Unix
3837   ], [
3838     PKG_CHECK_MODULES([XPM], [xpm],, [have_skins_deps="no"])
3839     PKG_CHECK_MODULES([XINERAMA], [xinerama],, [have_skins_deps="no"])
3840     PKG_CHECK_MODULES([XEXT], [xext],, [have_skins_deps="no"])
3841     VLC_ADD_CPPFLAGS([skins2],[${X_CFLAGS} ${XEXT_CFLAGS} ${XPM_CFLAGS} -DX11_SKINS])
3842     VLC_ADD_LIBS([skins2],[${X_LIBS} ${X_PRE_LIBS} ${XEXT_LIBS} ${XPM_LIBS} ${XINERAMA_LIBS} -lX11])
3843   ])
3844
3845   dnl for All OSes
3846   VLC_ADD_CXXFLAGS([skins2],[-O2 -fno-rtti])
3847
3848   dnl we need freetype
3849   AS_IF([test "${have_freetype}" != "yes"], [
3850     have_skins_deps="no"
3851   ])
3852
3853   AS_IF([test "${have_skins_deps}" = "no"], [
3854     AS_IF([test "x${enable_skins2}" = "x"], [
3855       AC_MSG_WARN([Skins2 interface disabled due to missing dependencies.])
3856     ], [
3857       AC_MSG_ERROR([Skins2 interface requires FreeType, libxpm, libxext and libxinerama])
3858     ])
3859     enable_skins2="no"
3860   ], [
3861     VLC_ADD_PLUGIN([skins2])
3862     ALIASES="${ALIASES} svlc"
3863     enable_skins2="yes"
3864   ])
3865 ])
3866 AM_CONDITIONAL(BUILD_SKINS, [test "${enable_skins2}" = "yes"])
3867
3868 AC_ARG_ENABLE(libtar,
3869   [  --enable-libtar         libtar support for skins2 (default auto)])
3870 AS_IF([test "${enable_skins2}" = "yes" && test "${enable_libtar}" != "no"], [
3871   AC_CHECK_HEADERS(libtar.h, [
3872     VLC_ADD_LIBS([skins2],[-ltar])
3873   ])
3874 ])
3875
3876 dnl
3877 dnl  MacOS X gui module
3878 dnl
3879 AC_ARG_ENABLE(macosx,
3880   [  --enable-macosx         Mac OS X gui support (default enabled on Mac OS X)])
3881 if test "x${enable_macosx}" != "xno" -a "${SYS}" = "darwin"
3882 then
3883   VLC_ADD_PLUGIN([macosx])
3884
3885   if test ! -d ${CONTRIB_DIR}/BGHUDAppKit.framework
3886   then
3887     AC_MSG_ERROR([BGHUDAppKit framework is required and was not found in ${CONTRIB_DIR}])
3888   fi
3889 fi
3890 AM_CONDITIONAL(ENABLE_MACOSX_UI, [test "$enable_macosx" != "no"])
3891
3892 dnl
3893 dnl  MacOS X sparkle update support
3894 dnl
3895 AC_ARG_ENABLE(sparkle,
3896   [  --enable-sparkle        Sparkle update support for OS X (default enabled on Mac OS X)])
3897 if test "x${enable_sparkle}" != "xno" -a "${HAVE_OSX}" = "1"
3898 then
3899   if test ! -d ${CONTRIB_DIR}/Sparkle.framework
3900   then
3901     AC_MSG_ERROR([Sparkle framework is required and was not found in ${CONTRIB_DIR}])
3902   fi
3903
3904   AC_DEFINE([HAVE_SPARKLE], [1], [Define to 1 if sparkle is enabled.])
3905 fi
3906 AM_CONDITIONAL(HAVE_SPARKLE, [test "$enable_sparkle" != "no"])
3907
3908
3909 dnl
3910 dnl  Minimal Mac OS X module
3911 dnl
3912 AC_ARG_ENABLE(minimal-macosx,
3913   [  --enable-minimal-macosx Minimal Mac OS X support (default disabled)])
3914 if test "${enable_minimal_macosx}" = "yes" -a "${SYS}" = "darwin"
3915 then
3916   VLC_ADD_PLUGIN([minimal_macosx])
3917 fi
3918
3919 dnl
3920 dnl  VideoToolbox plugins
3921 AC_CHECK_HEADERS(VideoToolbox/VideoToolbox.h, [
3922     VLC_ADD_PLUGIN([videotoolbox])
3923     VLC_ADD_PLUGIN([cvpx_i420])
3924   ])
3925
3926 dnl
3927 dnl  ncurses module
3928 dnl
3929 AC_ARG_ENABLE(ncurses,
3930 [AS_HELP_STRING([--disable-ncurses],[ncurses text-based interface (default auto)])])
3931 have_ncurses="no"
3932 AS_IF([test "${enable_ncurses}" != "no"] ,[
3933   PKG_CHECK_MODULES([NCURSES], [ncursesw], [
3934     have_ncurses="yes"
3935     ALIASES="${ALIASES} nvlc"
3936   ], [
3937     AS_IF([test -n "${enable_ncurses}"], [
3938       AC_MSG_ERROR([${NCURSES_PKG_ERRORS}.])
3939     ])
3940   ])
3941 ])
3942 AM_CONDITIONAL([HAVE_NCURSES], [test "${have_ncurses}" = "yes"])
3943
3944 dnl
3945 dnl  Lirc plugin
3946 dnl
3947 AC_ARG_ENABLE(lirc,
3948   [  --enable-lirc           lirc support (default disabled)])
3949 have_lirc="no"
3950 AS_IF([test "${enable_lirc}" = "yes"], [
3951   AC_CHECK_HEADER(lirc/lirc_client.h, [
3952     AC_CHECK_LIB(lirc_client, lirc_init, [
3953       have_lirc="true"
3954     ])
3955   ])
3956 ])
3957 AM_CONDITIONAL([HAVE_LIRC], [test "${have_lirc}" = "yes"])
3958
3959 EXTEND_HELP_STRING([Visualisations and Video filter plugins:])
3960 dnl
3961 dnl  goom visualization plugin
3962 dnl
3963 PKG_ENABLE_MODULES_VLC([GOOM], [], [libgoom2], [goom visualization plugin], [auto])
3964
3965 dnl
3966 dnl libprojectM visualization plugin
3967 dnl
3968 AC_ARG_ENABLE(projectm,
3969   [  --enable-projectm       projectM visualization plugin (default enabled)])
3970 AS_IF([test "${enable_projectm}" != "no"],
3971   [
3972     PKG_CHECK_MODULES(PROJECTM, libprojectM,
3973     [
3974       VLC_ADD_PLUGIN([projectm])
3975       PKG_CHECK_EXISTS([libprojectM >= 2.0.0],
3976         [ AC_DEFINE([HAVE_PROJECTM2], 1, [Define to 1 if using libprojectM 2.x]) ],
3977         [ AC_MSG_WARN( [Using libprojectM version 1] )
3978       ])
3979     ],[
3980       AC_MSG_WARN([${PROJECTM_PKG_ERRORS}.])
3981     ])
3982   ])
3983
3984 dnl
3985 dnl Vovoid VSXu visualization plugin
3986 dnl
3987 AC_ARG_ENABLE(vsxu,
3988   [  --enable-vsxu           Vovoid VSXu visualization plugin (default auto)])
3989 AS_IF([test "${enable_vsxu}" != "no"],
3990   [
3991     PKG_CHECK_MODULES(VSXU, libvsxu,
3992     [
3993       VLC_ADD_PLUGIN([vsxu])
3994     ],[
3995       AC_MSG_WARN([${VSXU_PKG_ERRORS}.])
3996     ])
3997   ])
3998
3999 EXTEND_HELP_STRING([Service Discovery plugins:])
4000 dnl
4001 dnl  Avahi-Zeroconf services discovery
4002 PKG_ENABLE_MODULES_VLC([AVAHI], [], [avahi-client >= 0.6], [Zeroconf services discovery], [auto])
4003
4004 dnl
4005 dnl  libudev services discovery
4006 PKG_ENABLE_MODULES_VLC([UDEV], [], [libudev >= 142], [Linux udev services discovery], [auto])
4007
4008 dnl
4009 dnl MTP devices services discovery
4010 PKG_ENABLE_MODULES_VLC([MTP], [mtp access_mtp], [libmtp >= 1.0.0], [MTP devices support], [auto])
4011
4012 dnl
4013 dnl UPnP Plugin (Intel SDK)
4014 dnl
4015 PKG_ENABLE_MODULES_VLC([UPNP], [upnp], [libupnp], [Intel UPNP SDK],[auto])
4016
4017 dnl
4018 dnl mDNS using libmicrodns
4019 dnl
4020 PKG_ENABLE_MODULES_VLC([MICRODNS], [], [microdns], [mDNS services discovery], [auto])
4021
4022
4023 EXTEND_HELP_STRING([Misc options:])
4024
4025 dnl
4026 dnl  libxml2 module
4027 dnl
4028 PKG_ENABLE_MODULES_VLC([LIBXML2], [xml], [libxml-2.0 >= 2.5], [libxml2 support],[auto])
4029
4030
4031 dnl
4032 dnl libgcrypt
4033 dnl
4034 AC_ARG_ENABLE(libgcrypt,
4035   [  --disable-libgcrypt     gcrypt support (default enabled)])
4036 # require libgcrypt >= 1.6.0
4037 AS_IF([test "${enable_libgcrypt}" != "no"], [
4038   AC_TRY_COMPILE([
4039 #include <gcrypt.h>
4040 #if GCRYPT_VERSION_NUMBER < 0x010600
4041 #error
4042 #endif],
4043   [], [
4044     have_libgcrypt="yes"
4045     AC_DEFINE([HAVE_GCRYPT], 1, [Defined if having gcrypt])
4046     GCRYPT_CFLAGS="`libgcrypt-config --cflags`"
4047     GCRYPT_LIBS="`libgcrypt-config --libs`"
4048   ], [
4049     AS_IF([test "${enable_libgcrypt}" == "yes"], [
4050       AC_MSG_ERROR([libgcrypt version 1.6.0 or higher not found. Install libgcrypt or pass --disable-libgcrypt.])
4051     ])
4052   ])
4053 ])
4054
4055 AC_SUBST(GCRYPT_CFLAGS)
4056 AC_SUBST(GCRYPT_LIBS)
4057 AM_CONDITIONAL([HAVE_GCRYPT], [test "${have_libgcrypt}" = "yes"])
4058
4059 dnl
4060 dnl TLS/SSL
4061 dnl
4062 AC_ARG_ENABLE(gnutls,
4063   [  --enable-gnutls         GNU TLS TLS/SSL support (default enabled)])
4064 AS_IF([test "${enable_gnutls}" != "no"], [
4065   PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.2.0], [
4066     VLC_ADD_PLUGIN([gnutls])
4067   ], [
4068     AS_IF([test -n "${enable_gnutls}"], [
4069       AC_MSG_ERROR([${GNUTLS_PKG_ERRORS}.)])
4070     ])
4071   ])
4072 ])
4073
4074
4075 dnl
4076 dnl Taglib plugin
4077 dnl
4078 AC_ARG_ENABLE(taglib,
4079   [AS_HELP_STRING([--disable-taglib],
4080     [do not use TagLib (default enabled)])])
4081 AS_IF([test "${enable_taglib}" != "no"], [
4082   PKG_CHECK_MODULES(TAGLIB, taglib >= 1.9, [
4083     VLC_ADD_PLUGIN([taglib])
4084   ], [
4085     AC_MSG_WARN([${TAGLIB_PKG_ERRORS}.])])
4086 ])
4087
4088 dnl
4089 dnl  libsecret
4090 dnl
4091 PKG_ENABLE_MODULES_VLC([SECRET], [], [libsecret-1], [use libsecret for keystore], [auto])
4092
4093 dnl
4094 dnl  kwallet
4095 dnl
4096 AC_ARG_ENABLE(kwallet,
4097   [AS_HELP_STRING([--enable-kwallet],
4098     [use KWallet for keystore (default auto)])])
4099 have_kwallet="no"
4100 KWALLET_CXXFLAGS=""
4101 KWALLET_LIBS=""
4102 AS_IF([test "${SYS}" != "mingw32" -a "${SYS}" != "darwin" \
4103          -a "${enable_qt}" != "no" -a "${KDE4_CONFIG}" != "no" \
4104          -a "${enable_kwallet}" != "no" ], [
4105   VLC_SAVE_FLAGS
4106   AC_LANG_PUSH([C++])
4107   KWALLET_CXXFLAGS="$QT_CFLAGS $CXXFLAGS_qt -I`$KDE4_CONFIG --path include`"
4108   CPPFLAGS="$CPPFLAGS $KWALLET_CXXFLAGS"
4109   AC_CHECK_HEADER([kwallet.h], [
4110     KWALLET_LIBS="$QT_LIBS -L`$KDE4_CONFIG --install lib` -lkdeui"
4111     LDFLAGS="$LDFLAGS $KWALLET_LIBS"
4112     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <kwallet.h>], [
4113 KWallet::Wallet::LocalWallet();
4114     ])], [
4115       have_kwallet="yes"
4116     ])
4117   ])
4118   AC_LANG_POP([C++])
4119   VLC_RESTORE_FLAGS
4120 ])
4121 AS_IF([test "$enable_kwallet" = "yes" -a "$have_kwallet" = "no" ], [
4122   AC_MSG_ERROR([KWallet headers or so not found])
4123 ])
4124 AC_SUBST(KWALLET_CXXFLAGS)
4125 AC_SUBST(KWALLET_LIBS)
4126 AM_CONDITIONAL([HAVE_KWALLET], [test "${have_kwallet}" = "yes"])
4127
4128 dnl
4129 dnl  Developers helper modules (should be hidden from configure help)
4130 dnl
4131 AC_ARG_ENABLE(devtools, [], [], [enable_devtools="no"])
4132 AS_IF([test "${enable_devtools}" != "no"], [
4133   VLC_ADD_PLUGIN([accesstweaks])
4134 ])
4135
4136 dnl
4137 dnl update checking system
4138 dnl
4139 AC_ARG_ENABLE(update-check,
4140   [  --enable-update-check   update checking system (default disabled)])
4141 if test "${enable_update_check}" = "yes"
4142 then
4143   if test "${have_libgcrypt}" != "yes"
4144   then
4145     AC_MSG_ERROR([libgcrypt is required for update checking system])
4146   fi
4147   VLC_ADD_LIBS([libvlccore], [${GCRYPT_LIBS}])
4148   VLC_ADD_CFLAGS([libvlccore], [${GCRYPT_CFLAGS}])
4149   AC_DEFINE([UPDATE_CHECK], 1, [Define if you want to use the VLC update mechanism])
4150 fi
4151
4152 dnl
4153 dnl OS X notification plugin
4154 dnl
4155 AC_ARG_ENABLE(osx_notifications,
4156   [  --enable-osx-notifications          osx notification plugin (default disabled)],,
4157   [enable_osx_notifications=no])
4158 AS_IF([test "${enable_osx_notifications}" != "no"], [
4159     AC_CHECK_HEADERS(${CONTRIB_DIR}/Growl.framework/Versions/A/Headers/Growl.h, [
4160       VLC_ADD_PLUGIN([osx_notifications])
4161       VLC_ADD_LIBS([osx_notifications], [-F${CONTRIB_DIR} -Wl,-framework,Growl,-framework,Foundation])
4162       VLC_ADD_OBJCFLAGS([osx_notifications], [-F${CONTRIB_DIR}])
4163       VLC_ADD_OBJCFLAGS([osx_notifications], [-fobjc-exceptions] )
4164     ])
4165   ]
4166 )
4167
4168 dnl
4169 dnl Libnotify notification plugin
4170 dnl
4171 PKG_ENABLE_MODULES_VLC([NOTIFY], [], [libnotify gtk+-2.0], [libnotify notification], [auto])
4172
4173 dnl
4174 dnl  Endianness check