swscale/rgb : add X86 SIMD (SSSE3) for shuffle_bytes_2103 and shuffle_bytes_0321
[ffmpeg.git] / libswscale / x86 / rgb_2_rgb.asm
1 ;******************************************************************************
2 ;* Copyright Nick Kurshev
3 ;* Copyright Michael (michaelni@gmx.at)
4 ;* Copyright 2018 Jokyo Images
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %include "libavutil/x86/x86util.asm"
24
25 SECTION_RODATA
26
27 pb_shuffle2103: db 2, 1, 0, 3, 6, 5, 4, 7, 10, 9, 8, 11, 14, 13, 12, 15
28 pb_shuffle0321: db 0, 3, 2, 1, 4, 7, 6, 5, 8, 11, 10, 9, 12, 15, 14, 13
29
30 SECTION .text
31
32 ;------------------------------------------------------------------------------
33 ; shuffle_bytes_## (const uint8_t *src, uint8_t *dst, int src_size)
34 ;------------------------------------------------------------------------------
35 ; %1-4 index shuffle
36 %macro SHUFFLE_BYTES 4
37 cglobal shuffle_bytes_%1%2%3%4, 3, 5, 2, src, dst, w, tmp, x
38     VBROADCASTI128    m0, [pb_shuffle%1%2%3%4]
39     movsxdifnidn wq, wd
40     mov xq, wq
41
42     add        srcq, wq
43     add        dstq, wq
44     neg          wq
45
46 ;calc scalar loop
47     and xq, mmsize-4
48     je .loop_simd
49
50 .loop_scalar:
51    mov          tmpb, [srcq + wq + %1]
52    mov [dstq+wq + 0], tmpb
53    mov          tmpb, [srcq + wq + %2]
54    mov [dstq+wq + 1], tmpb
55    mov          tmpb, [srcq + wq + %3]
56    mov [dstq+wq + 2], tmpb
57    mov          tmpb, [srcq + wq + %4]
58    mov [dstq+wq + 3], tmpb
59    add            wq, 4
60    sub            xq, 4
61    jg .loop_scalar
62
63 ;check if src_size < mmsize
64 cmp wq, 0
65 jge .end
66
67 .loop_simd:
68     movu           m1, [srcq+wq]
69     pshufb         m1, m0
70     movu    [dstq+wq], m1
71     add            wq, mmsize
72     jl .loop_simd
73
74 .end:
75     RET
76 %endmacro
77
78 INIT_XMM ssse3
79 SHUFFLE_BYTES 2, 1, 0, 3
80 SHUFFLE_BYTES 0, 3, 2, 1