Merge remote-tracking branch 'qatar/master'
[ffmpeg.git] / libswscale / x86 / input.asm
1 ;******************************************************************************
2 ;* x86-optimized input routines; does shuffling of packed
3 ;* YUV formats into individual planes, and converts RGB
4 ;* into YUV planes also.
5 ;* Copyright (c) 2012 Ronald S. Bultje <rsbultje@gmail.com>
6 ;*
7 ;* This file is part of Libav.
8 ;*
9 ;* Libav is free software; you can redistribute it and/or
10 ;* modify it under the terms of the GNU Lesser General Public
11 ;* License as published by the Free Software Foundation; either
12 ;* version 2.1 of the License, or (at your option) any later version.
13 ;*
14 ;* Libav is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;* Lesser General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU Lesser General Public
20 ;* License along with Libav; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
22 ;******************************************************************************
23
24 %include "x86inc.asm"
25 %include "x86util.asm"
26
27 SECTION_RODATA
28
29 %define RY 0x20DE
30 %define GY 0x4087
31 %define BY 0x0C88
32 %define RU 0xECFF
33 %define GU 0xDAC8
34 %define BU 0x3838
35 %define RV 0x3838
36 %define GV 0xD0E3
37 %define BV 0xF6E4
38
39 rgb_Yrnd:        times 4 dd 0x80100        ;  16.5 << 15
40 rgb_UVrnd:       times 4 dd 0x400100       ; 128.5 << 15
41 bgr_Ycoeff_12x4: times 2 dw BY, GY, 0, BY
42 bgr_Ycoeff_3x56: times 2 dw RY, 0, GY, RY
43 rgb_Ycoeff_12x4: times 2 dw RY, GY, 0, RY
44 rgb_Ycoeff_3x56: times 2 dw BY, 0, GY, BY
45 bgr_Ucoeff_12x4: times 2 dw BU, GU, 0, BU
46 bgr_Ucoeff_3x56: times 2 dw RU, 0, GU, RU
47 rgb_Ucoeff_12x4: times 2 dw RU, GU, 0, RU
48 rgb_Ucoeff_3x56: times 2 dw BU, 0, GU, BU
49 bgr_Vcoeff_12x4: times 2 dw BV, GV, 0, BV
50 bgr_Vcoeff_3x56: times 2 dw RV, 0, GV, RV
51 rgb_Vcoeff_12x4: times 2 dw RV, GV, 0, RV
52 rgb_Vcoeff_3x56: times 2 dw BV, 0, GV, BV
53
54 shuf_rgb_12x4:   db 0, 0x80, 1, 0x80,  2, 0x80,  3, 0x80, \
55                     6, 0x80, 7, 0x80,  8, 0x80,  9, 0x80
56 shuf_rgb_3x56:   db 2, 0x80, 3, 0x80,  4, 0x80,  5, 0x80, \
57                     8, 0x80, 9, 0x80, 10, 0x80, 11, 0x80
58
59 SECTION .text
60
61 ;-----------------------------------------------------------------------------
62 ; RGB to Y/UV.
63 ;
64 ; void <fmt>ToY_<opt>(uint8_t *dst, const uint8_t *src, int w);
65 ; and
66 ; void <fmt>toUV_<opt>(uint8_t *dstU, uint8_t *dstV, const uint8_t *src,
67 ;                      const uint8_t *unused, int w);
68 ;-----------------------------------------------------------------------------
69
70 ; %1 = nr. of XMM registers
71 ; %2 = rgb or bgr
72 %macro RGB24_TO_Y_FN 2-3
73 cglobal %2 %+ 24ToY, 6, 6, %1, dst, src, u1, u2, w, u3
74 %if mmsize == 8
75     mova           m5, [%2_Ycoeff_12x4]
76     mova           m6, [%2_Ycoeff_3x56]
77 %define coeff1 m5
78 %define coeff2 m6
79 %elif ARCH_X86_64
80     mova           m8, [%2_Ycoeff_12x4]
81     mova           m9, [%2_Ycoeff_3x56]
82 %define coeff1 m8
83 %define coeff2 m9
84 %else ; x86-32 && mmsize == 16
85 %define coeff1 [%2_Ycoeff_12x4]
86 %define coeff2 [%2_Ycoeff_3x56]
87 %endif ; x86-32/64 && mmsize == 8/16
88 %if (ARCH_X86_64 || mmsize == 8) && %0 == 3
89     jmp mangle(program_name %+ _ %+ %3 %+ 24ToY %+ SUFFIX).body
90 %else ; (ARCH_X86_64 && %0 == 3) || mmsize == 8
91 .body:
92 %if cpuflag(ssse3)
93     mova           m7, [shuf_rgb_12x4]
94 %define shuf_rgb1 m7
95 %if ARCH_X86_64
96     mova          m10, [shuf_rgb_3x56]
97 %define shuf_rgb2 m10
98 %else ; x86-32
99 %define shuf_rgb2 [shuf_rgb_3x56]
100 %endif ; x86-32/64
101 %endif ; cpuflag(ssse3)
102 %if ARCH_X86_64
103     movsxd         wq, wd
104 %endif
105     add            wq, wq
106     add          dstq, wq
107     neg            wq
108 %if notcpuflag(ssse3)
109     pxor           m7, m7
110 %endif ; !cpuflag(ssse3)
111     mova           m4, [rgb_Yrnd]
112 .loop:
113 %if cpuflag(ssse3)
114     movu           m0, [srcq+0]           ; (byte) { Bx, Gx, Rx }[0-3]
115     movu           m2, [srcq+12]          ; (byte) { Bx, Gx, Rx }[4-7]
116     pshufb         m1, m0, shuf_rgb2      ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
117     pshufb         m0, shuf_rgb1          ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
118     pshufb         m3, m2, shuf_rgb2      ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
119     pshufb         m2, shuf_rgb1          ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
120 %else ; !cpuflag(ssse3)
121     movd           m0, [srcq+0]           ; (byte) { B0, G0, R0, B1 }
122     movd           m1, [srcq+2]           ; (byte) { R0, B1, G1, R1 }
123     movd           m2, [srcq+6]           ; (byte) { B2, G2, R2, B3 }
124     movd           m3, [srcq+8]           ; (byte) { R2, B3, G3, R3 }
125 %if mmsize == 16 ; i.e. sse2
126     punpckldq      m0, m2                 ; (byte) { B0, G0, R0, B1, B2, G2, R2, B3 }
127     punpckldq      m1, m3                 ; (byte) { R0, B1, G1, R1, R2, B3, G3, R3 }
128     movd           m2, [srcq+12]          ; (byte) { B4, G4, R4, B5 }
129     movd           m3, [srcq+14]          ; (byte) { R4, B5, G5, R5 }
130     movd           m5, [srcq+18]          ; (byte) { B6, G6, R6, B7 }
131     movd           m6, [srcq+20]          ; (byte) { R6, B7, G7, R7 }
132     punpckldq      m2, m5                 ; (byte) { B4, G4, R4, B5, B6, G6, R6, B7 }
133     punpckldq      m3, m6                 ; (byte) { R4, B5, G5, R5, R6, B7, G7, R7 }
134 %endif ; mmsize == 16
135     punpcklbw      m0, m7                 ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
136     punpcklbw      m1, m7                 ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
137     punpcklbw      m2, m7                 ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
138     punpcklbw      m3, m7                 ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
139 %endif ; cpuflag(ssse3)
140     add          srcq, 3 * mmsize / 2
141     pmaddwd        m0, coeff1             ; (dword) { B0*BY + G0*GY, B1*BY, B2*BY + G2*GY, B3*BY }
142     pmaddwd        m1, coeff2             ; (dword) { R0*RY, G1+GY + R1*RY, R2*RY, G3+GY + R3*RY }
143     pmaddwd        m2, coeff1             ; (dword) { B4*BY + G4*GY, B5*BY, B6*BY + G6*GY, B7*BY }
144     pmaddwd        m3, coeff2             ; (dword) { R4*RY, G5+GY + R5*RY, R6*RY, G7+GY + R7*RY }
145     paddd          m0, m1                 ; (dword) { Bx*BY + Gx*GY + Rx*RY }[0-3]
146     paddd          m2, m3                 ; (dword) { Bx*BY + Gx*GY + Rx*RY }[4-7]
147     paddd          m0, m4                 ; += rgb_Yrnd, i.e. (dword) { Y[0-3] }
148     paddd          m2, m4                 ; += rgb_Yrnd, i.e. (dword) { Y[4-7] }
149     psrad          m0, 9
150     psrad          m2, 9
151     packssdw       m0, m2                 ; (word) { Y[0-7] }
152     mova    [dstq+wq], m0
153     add            wq, mmsize
154     jl .loop
155     REP_RET
156 %endif ; (ARCH_X86_64 && %0 == 3) || mmsize == 8
157 %endmacro
158
159 ; %1 = nr. of XMM registers
160 ; %2 = rgb or bgr
161 %macro RGB24_TO_UV_FN 2-3
162 cglobal %2 %+ 24ToUV, 7, 7, %1, dstU, dstV, u1, src, u2, w, u3
163 %if ARCH_X86_64
164     mova           m8, [%2_Ucoeff_12x4]
165     mova           m9, [%2_Ucoeff_3x56]
166     mova          m10, [%2_Vcoeff_12x4]
167     mova          m11, [%2_Vcoeff_3x56]
168 %define coeffU1 m8
169 %define coeffU2 m9
170 %define coeffV1 m10
171 %define coeffV2 m11
172 %else ; x86-32
173 %define coeffU1 [%2_Ucoeff_12x4]
174 %define coeffU2 [%2_Ucoeff_3x56]
175 %define coeffV1 [%2_Vcoeff_12x4]
176 %define coeffV2 [%2_Vcoeff_3x56]
177 %endif ; x86-32/64
178 %if ARCH_X86_64 && %0 == 3
179     jmp mangle(program_name %+ _ %+ %3 %+ 24ToUV %+ SUFFIX).body
180 %else ; ARCH_X86_64 && %0 == 3
181 .body:
182 %if cpuflag(ssse3)
183     mova           m7, [shuf_rgb_12x4]
184 %define shuf_rgb1 m7
185 %if ARCH_X86_64
186     mova          m12, [shuf_rgb_3x56]
187 %define shuf_rgb2 m12
188 %else ; x86-32
189 %define shuf_rgb2 [shuf_rgb_3x56]
190 %endif ; x86-32/64
191 %endif ; cpuflag(ssse3)
192 %if ARCH_X86_64
193     movsxd         wq, dword r5m
194 %else ; x86-32
195     mov            wq, r5m
196 %endif
197     add            wq, wq
198     add         dstUq, wq
199     add         dstVq, wq
200     neg            wq
201     mova           m6, [rgb_UVrnd]
202 %if notcpuflag(ssse3)
203     pxor           m7, m7
204 %endif
205 .loop:
206 %if cpuflag(ssse3)
207     movu           m0, [srcq+0]           ; (byte) { Bx, Gx, Rx }[0-3]
208     movu           m4, [srcq+12]          ; (byte) { Bx, Gx, Rx }[4-7]
209     pshufb         m1, m0, shuf_rgb2      ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
210     pshufb         m0, shuf_rgb1          ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
211 %else ; !cpuflag(ssse3)
212     movd           m0, [srcq+0]           ; (byte) { B0, G0, R0, B1 }
213     movd           m1, [srcq+2]           ; (byte) { R0, B1, G1, R1 }
214     movd           m4, [srcq+6]           ; (byte) { B2, G2, R2, B3 }
215     movd           m5, [srcq+8]           ; (byte) { R2, B3, G3, R3 }
216 %if mmsize == 16
217     punpckldq      m0, m4                 ; (byte) { B0, G0, R0, B1, B2, G2, R2, B3 }
218     punpckldq      m1, m5                 ; (byte) { R0, B1, G1, R1, R2, B3, G3, R3 }
219     movd           m4, [srcq+12]          ; (byte) { B4, G4, R4, B5 }
220     movd           m5, [srcq+14]          ; (byte) { R4, B5, G5, R5 }
221 %endif ; mmsize == 16
222     punpcklbw      m0, m7                 ; (word) { B0, G0, R0, B1, B2, G2, R2, B3 }
223     punpcklbw      m1, m7                 ; (word) { R0, B1, G1, R1, R2, B3, G3, R3 }
224 %endif ; cpuflag(ssse3)
225     pmaddwd        m2, m0, coeffV1        ; (dword) { B0*BV + G0*GV, B1*BV, B2*BV + G2*GV, B3*BV }
226     pmaddwd        m3, m1, coeffV2        ; (dword) { R0*BV, G1*GV + R1*BV, R2*BV, G3*GV + R3*BV }
227     pmaddwd        m0, coeffU1            ; (dword) { B0*BU + G0*GU, B1*BU, B2*BU + G2*GU, B3*BU }
228     pmaddwd        m1, coeffU2            ; (dword) { R0*BU, G1*GU + R1*BU, R2*BU, G3*GU + R3*BU }
229     paddd          m0, m1                 ; (dword) { Bx*BU + Gx*GU + Rx*RU }[0-3]
230     paddd          m2, m3                 ; (dword) { Bx*BV + Gx*GV + Rx*RV }[0-3]
231 %if cpuflag(ssse3)
232     pshufb         m5, m4, shuf_rgb2      ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
233     pshufb         m4, shuf_rgb1          ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
234 %else ; !cpuflag(ssse3)
235 %if mmsize == 16
236     movd           m1, [srcq+18]          ; (byte) { B6, G6, R6, B7 }
237     movd           m3, [srcq+20]          ; (byte) { R6, B7, G7, R7 }
238     punpckldq      m4, m1                 ; (byte) { B4, G4, R4, B5, B6, G6, R6, B7 }
239     punpckldq      m5, m3                 ; (byte) { R4, B5, G5, R5, R6, B7, G7, R7 }
240 %endif ; mmsize == 16 && !cpuflag(ssse3)
241     punpcklbw      m4, m7                 ; (word) { B4, G4, R4, B5, B6, G6, R6, B7 }
242     punpcklbw      m5, m7                 ; (word) { R4, B5, G5, R5, R6, B7, G7, R7 }
243 %endif ; cpuflag(ssse3)
244     add          srcq, 3 * mmsize / 2
245     pmaddwd        m1, m4, coeffU1        ; (dword) { B4*BU + G4*GU, B5*BU, B6*BU + G6*GU, B7*BU }
246     pmaddwd        m3, m5, coeffU2        ; (dword) { R4*BU, G5*GU + R5*BU, R6*BU, G7*GU + R7*BU }
247     pmaddwd        m4, coeffV1            ; (dword) { B4*BV + G4*GV, B5*BV, B6*BV + G6*GV, B7*BV }
248     pmaddwd        m5, coeffV2            ; (dword) { R4*BV, G5*GV + R5*BV, R6*BV, G7*GV + R7*BV }
249     paddd          m1, m3                 ; (dword) { Bx*BU + Gx*GU + Rx*RU }[4-7]
250     paddd          m4, m5                 ; (dword) { Bx*BV + Gx*GV + Rx*RV }[4-7]
251     paddd          m0, m6                 ; += rgb_UVrnd, i.e. (dword) { U[0-3] }
252     paddd          m2, m6                 ; += rgb_UVrnd, i.e. (dword) { V[0-3] }
253     paddd          m1, m6                 ; += rgb_UVrnd, i.e. (dword) { U[4-7] }
254     paddd          m4, m6                 ; += rgb_UVrnd, i.e. (dword) { V[4-7] }
255     psrad          m0, 9
256     psrad          m2, 9
257     psrad          m1, 9
258     psrad          m4, 9
259     packssdw       m0, m1                 ; (word) { U[0-7] }
260     packssdw       m2, m4                 ; (word) { V[0-7] }
261 %if mmsize == 8
262     mova   [dstUq+wq], m0
263     mova   [dstVq+wq], m2
264 %else ; mmsize == 16
265     mova   [dstUq+wq], m0
266     mova   [dstVq+wq], m2
267 %endif ; mmsize == 8/16
268     add            wq, mmsize
269     jl .loop
270     REP_RET
271 %endif ; ARCH_X86_64 && %0 == 3
272 %endmacro
273
274 ; %1 = nr. of XMM registers for rgb-to-Y func
275 ; %2 = nr. of XMM registers for rgb-to-UV func
276 %macro RGB24_FUNCS 2
277 RGB24_TO_Y_FN %1, rgb
278 RGB24_TO_Y_FN %1, bgr, rgb
279 RGB24_TO_UV_FN %2, rgb
280 RGB24_TO_UV_FN %2, bgr, rgb
281 %endmacro
282
283 %if ARCH_X86_32
284 INIT_MMX mmx
285 RGB24_FUNCS 0, 0
286 %endif
287
288 INIT_XMM sse2
289 RGB24_FUNCS 10, 12
290
291 INIT_XMM ssse3
292 RGB24_FUNCS 11, 13
293
294 INIT_XMM avx
295 RGB24_FUNCS 11, 13
296
297 ;-----------------------------------------------------------------------------
298 ; YUYV/UYVY/NV12/NV21 packed pixel shuffling.
299 ;
300 ; void <fmt>ToY_<opt>(uint8_t *dst, const uint8_t *src, int w);
301 ; and
302 ; void <fmt>toUV_<opt>(uint8_t *dstU, uint8_t *dstV, const uint8_t *src,
303 ;                      const uint8_t *unused, int w);
304 ;-----------------------------------------------------------------------------
305
306 ; %1 = a (aligned) or u (unaligned)
307 ; %2 = yuyv or uyvy
308 %macro LOOP_YUYV_TO_Y 2
309 .loop_%1:
310     mov%1          m0, [srcq+wq*2]        ; (byte) { Y0, U0, Y1, V0, ... }
311     mov%1          m1, [srcq+wq*2+mmsize] ; (byte) { Y8, U4, Y9, V4, ... }
312 %ifidn %2, yuyv
313     pand           m0, m2                 ; (word) { Y0, Y1, ..., Y7 }
314     pand           m1, m2                 ; (word) { Y8, Y9, ..., Y15 }
315 %else ; uyvy
316     psrlw          m0, 8                  ; (word) { Y0, Y1, ..., Y7 }
317     psrlw          m1, 8                  ; (word) { Y8, Y9, ..., Y15 }
318 %endif ; yuyv/uyvy
319     packuswb       m0, m1                 ; (byte) { Y0, ..., Y15 }
320     mova    [dstq+wq], m0
321     add            wq, mmsize
322     jl .loop_%1
323     REP_RET
324 %endmacro
325
326 ; %1 = nr. of XMM registers
327 ; %2 = yuyv or uyvy
328 ; %3 = if specified, it means that unaligned and aligned code in loop
329 ;      will be the same (i.e. YUYV+AVX), and thus we don't need to
330 ;      split the loop in an aligned and unaligned case
331 %macro YUYV_TO_Y_FN 2-3
332 cglobal %2ToY, 5, 5, %1, dst, unused0, unused1, src, w
333 %if ARCH_X86_64
334     movsxd         wq, wd
335 %endif
336     add          dstq, wq
337 %if mmsize == 16
338     test         srcq, 15
339 %endif
340     lea          srcq, [srcq+wq*2]
341 %ifidn %2, yuyv
342     pcmpeqb        m2, m2                 ; (byte) { 0xff } x 16
343     psrlw          m2, 8                  ; (word) { 0x00ff } x 8
344 %endif ; yuyv
345 %if mmsize == 16
346     jnz .loop_u_start
347     neg            wq
348     LOOP_YUYV_TO_Y  a, %2
349 .loop_u_start:
350     neg            wq
351     LOOP_YUYV_TO_Y  u, %2
352 %else ; mmsize == 8
353     neg            wq
354     LOOP_YUYV_TO_Y  a, %2
355 %endif ; mmsize == 8/16
356 %endmacro
357
358 ; %1 = a (aligned) or u (unaligned)
359 ; %2 = yuyv or uyvy
360 %macro LOOP_YUYV_TO_UV 2
361 .loop_%1:
362 %ifidn %2, yuyv
363     mov%1          m0, [srcq+wq*4]        ; (byte) { Y0, U0, Y1, V0, ... }
364     mov%1          m1, [srcq+wq*4+mmsize] ; (byte) { Y8, U4, Y9, V4, ... }
365     psrlw          m0, 8                  ; (word) { U0, V0, ..., U3, V3 }
366     psrlw          m1, 8                  ; (word) { U4, V4, ..., U7, V7 }
367 %else ; uyvy
368 %if cpuflag(avx)
369     vpand          m0, m2, [srcq+wq*4]        ; (word) { U0, V0, ..., U3, V3 }
370     vpand          m1, m2, [srcq+wq*4+mmsize] ; (word) { U4, V4, ..., U7, V7 }
371 %else
372     mov%1          m0, [srcq+wq*4]        ; (byte) { Y0, U0, Y1, V0, ... }
373     mov%1          m1, [srcq+wq*4+mmsize] ; (byte) { Y8, U4, Y9, V4, ... }
374     pand           m0, m2                 ; (word) { U0, V0, ..., U3, V3 }
375     pand           m1, m2                 ; (word) { U4, V4, ..., U7, V7 }
376 %endif
377 %endif ; yuyv/uyvy
378     packuswb       m0, m1                 ; (byte) { U0, V0, ..., U7, V7 }
379     pand           m1, m0, m2             ; (word) { U0, U1, ..., U7 }
380     psrlw          m0, 8                  ; (word) { V0, V1, ..., V7 }
381 %if mmsize == 16
382     packuswb       m1, m0                 ; (byte) { U0, ... U7, V1, ... V7 }
383     movh   [dstUq+wq], m1
384     movhps [dstVq+wq], m1
385 %else ; mmsize == 8
386     packuswb       m1, m1                 ; (byte) { U0, ... U3 }
387     packuswb       m0, m0                 ; (byte) { V0, ... V3 }
388     movh   [dstUq+wq], m1
389     movh   [dstVq+wq], m0
390 %endif ; mmsize == 8/16
391     add            wq, mmsize / 2
392     jl .loop_%1
393     REP_RET
394 %endmacro
395
396 ; %1 = nr. of XMM registers
397 ; %2 = yuyv or uyvy
398 ; %3 = if specified, it means that unaligned and aligned code in loop
399 ;      will be the same (i.e. UYVY+AVX), and thus we don't need to
400 ;      split the loop in an aligned and unaligned case
401 %macro YUYV_TO_UV_FN 2-3
402 cglobal %2ToUV, 4, 5, %1, dstU, dstV, unused, src, w
403 %if ARCH_X86_64
404     movsxd         wq, dword r5m
405 %else ; x86-32
406     mov            wq, r5m
407 %endif
408     add         dstUq, wq
409     add         dstVq, wq
410 %if mmsize == 16 && %0 == 2
411     test         srcq, 15
412 %endif
413     lea          srcq, [srcq+wq*4]
414     pcmpeqb        m2, m2                 ; (byte) { 0xff } x 16
415     psrlw          m2, 8                  ; (word) { 0x00ff } x 8
416     ; NOTE: if uyvy+avx, u/a are identical
417 %if mmsize == 16 && %0 == 2
418     jnz .loop_u_start
419     neg            wq
420     LOOP_YUYV_TO_UV a, %2
421 .loop_u_start:
422     neg            wq
423     LOOP_YUYV_TO_UV u, %2
424 %else ; mmsize == 8
425     neg            wq
426     LOOP_YUYV_TO_UV a, %2
427 %endif ; mmsize == 8/16
428 %endmacro
429
430 ; %1 = a (aligned) or u (unaligned)
431 ; %2 = nv12 or nv21
432 %macro LOOP_NVXX_TO_UV 2
433 .loop_%1:
434     mov%1          m0, [srcq+wq*2]        ; (byte) { U0, V0, U1, V1, ... }
435     mov%1          m1, [srcq+wq*2+mmsize] ; (byte) { U8, V8, U9, V9, ... }
436     pand           m2, m0, m5             ; (word) { U0, U1, ..., U7 }
437     pand           m3, m1, m5             ; (word) { U8, U9, ..., U15 }
438     psrlw          m0, 8                  ; (word) { V0, V1, ..., V7 }
439     psrlw          m1, 8                  ; (word) { V8, V9, ..., V15 }
440     packuswb       m2, m3                 ; (byte) { U0, ..., U15 }
441     packuswb       m0, m1                 ; (byte) { V0, ..., V15 }
442 %ifidn %2, nv12
443     mova   [dstUq+wq], m2
444     mova   [dstVq+wq], m0
445 %else ; nv21
446     mova   [dstVq+wq], m2
447     mova   [dstUq+wq], m0
448 %endif ; nv12/21
449     add            wq, mmsize
450     jl .loop_%1
451     REP_RET
452 %endmacro
453
454 ; %1 = nr. of XMM registers
455 ; %2 = nv12 or nv21
456 %macro NVXX_TO_UV_FN 2
457 cglobal %2ToUV, 4, 5, %1, dstU, dstV, unused, src, w
458 %if ARCH_X86_64
459     movsxd         wq, dword r5m
460 %else ; x86-32
461     mov            wq, r5m
462 %endif
463     add         dstUq, wq
464     add         dstVq, wq
465 %if mmsize == 16
466     test         srcq, 15
467 %endif
468     lea          srcq, [srcq+wq*2]
469     pcmpeqb        m5, m5                 ; (byte) { 0xff } x 16
470     psrlw          m5, 8                  ; (word) { 0x00ff } x 8
471 %if mmsize == 16
472     jnz .loop_u_start
473     neg            wq
474     LOOP_NVXX_TO_UV a, %2
475 .loop_u_start:
476     neg            wq
477     LOOP_NVXX_TO_UV u, %2
478 %else ; mmsize == 8
479     neg            wq
480     LOOP_NVXX_TO_UV a, %2
481 %endif ; mmsize == 8/16
482 %endmacro
483
484 %if ARCH_X86_32
485 INIT_MMX mmx
486 YUYV_TO_Y_FN  0, yuyv
487 YUYV_TO_Y_FN  0, uyvy
488 YUYV_TO_UV_FN 0, yuyv
489 YUYV_TO_UV_FN 0, uyvy
490 NVXX_TO_UV_FN 0, nv12
491 NVXX_TO_UV_FN 0, nv21
492 %endif
493
494 INIT_XMM sse2
495 YUYV_TO_Y_FN  3, yuyv
496 YUYV_TO_Y_FN  2, uyvy
497 YUYV_TO_UV_FN 3, yuyv
498 YUYV_TO_UV_FN 3, uyvy
499 NVXX_TO_UV_FN 5, nv12
500 NVXX_TO_UV_FN 5, nv21
501
502 %ifdef HAVE_AVX
503 INIT_XMM avx
504 ; in theory, we could write a yuy2-to-y using vpand (i.e. AVX), but
505 ; that's not faster in practice
506 YUYV_TO_UV_FN 3, yuyv
507 YUYV_TO_UV_FN 3, uyvy, 1
508 NVXX_TO_UV_FN 5, nv12
509 NVXX_TO_UV_FN 5, nv21
510 %endif