x86inc: Improve handling of %ifid with multi-token parameters
[ffmpeg.git] / libavutil / x86 / x86inc.asm
1 ;*****************************************************************************
2 ;* x86inc.asm: x264asm abstraction layer
3 ;*****************************************************************************
4 ;* Copyright (C) 2005-2016 x264 project
5 ;*
6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
8 ;*          Fiona Glaser <fiona@x264.com>
9 ;*          Henrik Gramner <henrik@gramner.com>
10 ;*
11 ;* Permission to use, copy, modify, and/or distribute this software for any
12 ;* purpose with or without fee is hereby granted, provided that the above
13 ;* copyright notice and this permission notice appear in all copies.
14 ;*
15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
22 ;*****************************************************************************
23
24 ; This is a header file for the x264ASM assembly language, which uses
25 ; NASM/YASM syntax combined with a large number of macros to provide easy
26 ; abstraction between different calling conventions (x86_32, win64, linux64).
27 ; It also has various other useful features to simplify writing the kind of
28 ; DSP functions that are most often used in x264.
29
30 ; Unlike the rest of x264, this file is available under an ISC license, as it
31 ; has significant usefulness outside of x264 and we want it to be available
32 ; to the largest audience possible.  Of course, if you modify it for your own
33 ; purposes to add a new feature, we strongly encourage contributing a patch
34 ; as this feature might be useful for others as well.  Send patches or ideas
35 ; to x264-devel@videolan.org .
36
37 %ifndef private_prefix
38     %define private_prefix x264
39 %endif
40
41 %ifndef public_prefix
42     %define public_prefix private_prefix
43 %endif
44
45 %if HAVE_ALIGNED_STACK
46     %define STACK_ALIGNMENT 16
47 %endif
48 %ifndef STACK_ALIGNMENT
49     %if ARCH_X86_64
50         %define STACK_ALIGNMENT 16
51     %else
52         %define STACK_ALIGNMENT 4
53     %endif
54 %endif
55
56 %define WIN64  0
57 %define UNIX64 0
58 %if ARCH_X86_64
59     %ifidn __OUTPUT_FORMAT__,win32
60         %define WIN64  1
61     %elifidn __OUTPUT_FORMAT__,win64
62         %define WIN64  1
63     %elifidn __OUTPUT_FORMAT__,x64
64         %define WIN64  1
65     %else
66         %define UNIX64 1
67     %endif
68 %endif
69
70 %define FORMAT_ELF 0
71 %ifidn __OUTPUT_FORMAT__,elf
72     %define FORMAT_ELF 1
73 %elifidn __OUTPUT_FORMAT__,elf32
74     %define FORMAT_ELF 1
75 %elifidn __OUTPUT_FORMAT__,elf64
76     %define FORMAT_ELF 1
77 %endif
78
79 %ifdef PREFIX
80     %define mangle(x) _ %+ x
81 %else
82     %define mangle(x) x
83 %endif
84
85 ; aout does not support align=
86 ; NOTE: This section is out of sync with x264, in order to
87 ; keep supporting OS/2.
88 %macro SECTION_RODATA 0-1 16
89     %ifidn __OUTPUT_FORMAT__,aout
90         section .text
91     %else
92         SECTION .rodata align=%1
93     %endif
94 %endmacro
95
96 %if WIN64
97     %define PIC
98 %elif ARCH_X86_64 == 0
99 ; x86_32 doesn't require PIC.
100 ; Some distros prefer shared objects to be PIC, but nothing breaks if
101 ; the code contains a few textrels, so we'll skip that complexity.
102     %undef PIC
103 %endif
104 %ifdef PIC
105     default rel
106 %endif
107
108 %macro CPUNOP 1
109     %if HAVE_CPUNOP
110         CPU %1
111     %endif
112 %endmacro
113
114 ; Macros to eliminate most code duplication between x86_32 and x86_64:
115 ; Currently this works only for leaf functions which load all their arguments
116 ; into registers at the start, and make no other use of the stack. Luckily that
117 ; covers most of x264's asm.
118
119 ; PROLOGUE:
120 ; %1 = number of arguments. loads them from stack if needed.
121 ; %2 = number of registers used. pushes callee-saved regs if needed.
122 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
123 ; %4 = (optional) stack size to be allocated. The stack will be aligned before
124 ;      allocating the specified stack size. If the required stack alignment is
125 ;      larger than the known stack alignment the stack will be manually aligned
126 ;      and an extra register will be allocated to hold the original stack
127 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
128 ;      register as stack pointer, request a negative stack size.
129 ; %4+/%5+ = list of names to define to registers
130 ; PROLOGUE can also be invoked by adding the same options to cglobal
131
132 ; e.g.
133 ; cglobal foo, 2,3,7,0x40, dst, src, tmp
134 ; declares a function (foo) that automatically loads two arguments (dst and
135 ; src) into registers, uses one additional register (tmp) plus 7 vector
136 ; registers (m0-m6) and allocates 0x40 bytes of stack space.
137
138 ; TODO Some functions can use some args directly from the stack. If they're the
139 ; last args then you can just not declare them, but if they're in the middle
140 ; we need more flexible macro.
141
142 ; RET:
143 ; Pops anything that was pushed by PROLOGUE, and returns.
144
145 ; REP_RET:
146 ; Use this instead of RET if it's a branch target.
147
148 ; registers:
149 ; rN and rNq are the native-size register holding function argument N
150 ; rNd, rNw, rNb are dword, word, and byte size
151 ; rNh is the high 8 bits of the word size
152 ; rNm is the original location of arg N (a register or on the stack), dword
153 ; rNmp is native size
154
155 %macro DECLARE_REG 2-3
156     %define r%1q %2
157     %define r%1d %2d
158     %define r%1w %2w
159     %define r%1b %2b
160     %define r%1h %2h
161     %define %2q %2
162     %if %0 == 2
163         %define r%1m  %2d
164         %define r%1mp %2
165     %elif ARCH_X86_64 ; memory
166         %define r%1m [rstk + stack_offset + %3]
167         %define r%1mp qword r %+ %1 %+ m
168     %else
169         %define r%1m [rstk + stack_offset + %3]
170         %define r%1mp dword r %+ %1 %+ m
171     %endif
172     %define r%1  %2
173 %endmacro
174
175 %macro DECLARE_REG_SIZE 3
176     %define r%1q r%1
177     %define e%1q r%1
178     %define r%1d e%1
179     %define e%1d e%1
180     %define r%1w %1
181     %define e%1w %1
182     %define r%1h %3
183     %define e%1h %3
184     %define r%1b %2
185     %define e%1b %2
186     %if ARCH_X86_64 == 0
187         %define r%1 e%1
188     %endif
189 %endmacro
190
191 DECLARE_REG_SIZE ax, al, ah
192 DECLARE_REG_SIZE bx, bl, bh
193 DECLARE_REG_SIZE cx, cl, ch
194 DECLARE_REG_SIZE dx, dl, dh
195 DECLARE_REG_SIZE si, sil, null
196 DECLARE_REG_SIZE di, dil, null
197 DECLARE_REG_SIZE bp, bpl, null
198
199 ; t# defines for when per-arch register allocation is more complex than just function arguments
200
201 %macro DECLARE_REG_TMP 1-*
202     %assign %%i 0
203     %rep %0
204         CAT_XDEFINE t, %%i, r%1
205         %assign %%i %%i+1
206         %rotate 1
207     %endrep
208 %endmacro
209
210 %macro DECLARE_REG_TMP_SIZE 0-*
211     %rep %0
212         %define t%1q t%1 %+ q
213         %define t%1d t%1 %+ d
214         %define t%1w t%1 %+ w
215         %define t%1h t%1 %+ h
216         %define t%1b t%1 %+ b
217         %rotate 1
218     %endrep
219 %endmacro
220
221 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
222
223 %if ARCH_X86_64
224     %define gprsize 8
225 %else
226     %define gprsize 4
227 %endif
228
229 %macro PUSH 1
230     push %1
231     %ifidn rstk, rsp
232         %assign stack_offset stack_offset+gprsize
233     %endif
234 %endmacro
235
236 %macro POP 1
237     pop %1
238     %ifidn rstk, rsp
239         %assign stack_offset stack_offset-gprsize
240     %endif
241 %endmacro
242
243 %macro PUSH_IF_USED 1-*
244     %rep %0
245         %if %1 < regs_used
246             PUSH r%1
247         %endif
248         %rotate 1
249     %endrep
250 %endmacro
251
252 %macro POP_IF_USED 1-*
253     %rep %0
254         %if %1 < regs_used
255             pop r%1
256         %endif
257         %rotate 1
258     %endrep
259 %endmacro
260
261 %macro LOAD_IF_USED 1-*
262     %rep %0
263         %if %1 < num_args
264             mov r%1, r %+ %1 %+ mp
265         %endif
266         %rotate 1
267     %endrep
268 %endmacro
269
270 %macro SUB 2
271     sub %1, %2
272     %ifidn %1, rstk
273         %assign stack_offset stack_offset+(%2)
274     %endif
275 %endmacro
276
277 %macro ADD 2
278     add %1, %2
279     %ifidn %1, rstk
280         %assign stack_offset stack_offset-(%2)
281     %endif
282 %endmacro
283
284 %macro movifnidn 2
285     %ifnidn %1, %2
286         mov %1, %2
287     %endif
288 %endmacro
289
290 %macro movsxdifnidn 2
291     %ifnidn %1, %2
292         movsxd %1, %2
293     %endif
294 %endmacro
295
296 %macro ASSERT 1
297     %if (%1) == 0
298         %error assertion ``%1'' failed
299     %endif
300 %endmacro
301
302 %macro DEFINE_ARGS 0-*
303     %ifdef n_arg_names
304         %assign %%i 0
305         %rep n_arg_names
306             CAT_UNDEF arg_name %+ %%i, q
307             CAT_UNDEF arg_name %+ %%i, d
308             CAT_UNDEF arg_name %+ %%i, w
309             CAT_UNDEF arg_name %+ %%i, h
310             CAT_UNDEF arg_name %+ %%i, b
311             CAT_UNDEF arg_name %+ %%i, m
312             CAT_UNDEF arg_name %+ %%i, mp
313             CAT_UNDEF arg_name, %%i
314             %assign %%i %%i+1
315         %endrep
316     %endif
317
318     %xdefine %%stack_offset stack_offset
319     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
320     %assign %%i 0
321     %rep %0
322         %xdefine %1q r %+ %%i %+ q
323         %xdefine %1d r %+ %%i %+ d
324         %xdefine %1w r %+ %%i %+ w
325         %xdefine %1h r %+ %%i %+ h
326         %xdefine %1b r %+ %%i %+ b
327         %xdefine %1m r %+ %%i %+ m
328         %xdefine %1mp r %+ %%i %+ mp
329         CAT_XDEFINE arg_name, %%i, %1
330         %assign %%i %%i+1
331         %rotate 1
332     %endrep
333     %xdefine stack_offset %%stack_offset
334     %assign n_arg_names %0
335 %endmacro
336
337 %define required_stack_alignment ((mmsize + 15) & ~15)
338
339 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
340     %ifnum %1
341         %if %1 != 0
342             %assign %%pad 0
343             %assign stack_size %1
344             %if stack_size < 0
345                 %assign stack_size -stack_size
346             %endif
347             %if WIN64
348                 %assign %%pad %%pad + 32 ; shadow space
349                 %if mmsize != 8
350                     %assign xmm_regs_used %2
351                     %if xmm_regs_used > 8
352                         %assign %%pad %%pad + (xmm_regs_used-8)*16 ; callee-saved xmm registers
353                     %endif
354                 %endif
355             %endif
356             %if required_stack_alignment <= STACK_ALIGNMENT
357                 ; maintain the current stack alignment
358                 %assign stack_size_padded stack_size + %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
359                 SUB rsp, stack_size_padded
360             %else
361                 %assign %%reg_num (regs_used - 1)
362                 %xdefine rstk r %+ %%reg_num
363                 ; align stack, and save original stack location directly above
364                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
365                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
366                 ; rsp, [rsp+stack_size_padded])
367                 %if %1 < 0 ; need to store rsp on stack
368                     %xdefine rstkm [rsp + stack_size + %%pad]
369                     %assign %%pad %%pad + gprsize
370                 %else ; can keep rsp in rstk during whole function
371                     %xdefine rstkm rstk
372                 %endif
373                 %assign stack_size_padded stack_size + ((%%pad + required_stack_alignment-1) & ~(required_stack_alignment-1))
374                 mov rstk, rsp
375                 and rsp, ~(required_stack_alignment-1)
376                 sub rsp, stack_size_padded
377                 movifnidn rstkm, rstk
378             %endif
379             WIN64_PUSH_XMM
380         %endif
381     %endif
382 %endmacro
383
384 %macro SETUP_STACK_POINTER 1
385     %ifnum %1
386         %if %1 != 0 && required_stack_alignment > STACK_ALIGNMENT
387             %if %1 > 0
388                 %assign regs_used (regs_used + 1)
389             %endif
390             %if ARCH_X86_64 && regs_used < 5 + UNIX64 * 3
391                 ; Ensure that we don't clobber any registers containing arguments. For UNIX64 we also preserve r6 (rax)
392                 ; since it's used as a hidden argument in vararg functions to specify the number of vector registers used.
393                 %assign regs_used 5 + UNIX64 * 3
394             %endif
395         %endif
396     %endif
397 %endmacro
398
399 %macro DEFINE_ARGS_INTERNAL 3+
400     %ifnum %2
401         DEFINE_ARGS %3
402     %elif %1 == 4
403         DEFINE_ARGS %2
404     %elif %1 > 4
405         DEFINE_ARGS %2, %3
406     %endif
407 %endmacro
408
409 %if WIN64 ; Windows x64 ;=================================================
410
411 DECLARE_REG 0,  rcx
412 DECLARE_REG 1,  rdx
413 DECLARE_REG 2,  R8
414 DECLARE_REG 3,  R9
415 DECLARE_REG 4,  R10, 40
416 DECLARE_REG 5,  R11, 48
417 DECLARE_REG 6,  rax, 56
418 DECLARE_REG 7,  rdi, 64
419 DECLARE_REG 8,  rsi, 72
420 DECLARE_REG 9,  rbx, 80
421 DECLARE_REG 10, rbp, 88
422 DECLARE_REG 11, R12, 96
423 DECLARE_REG 12, R13, 104
424 DECLARE_REG 13, R14, 112
425 DECLARE_REG 14, R15, 120
426
427 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
428     %assign num_args %1
429     %assign regs_used %2
430     ASSERT regs_used >= num_args
431     SETUP_STACK_POINTER %4
432     ASSERT regs_used <= 15
433     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
434     ALLOC_STACK %4, %3
435     %if mmsize != 8 && stack_size == 0
436         WIN64_SPILL_XMM %3
437     %endif
438     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
439     DEFINE_ARGS_INTERNAL %0, %4, %5
440 %endmacro
441
442 %macro WIN64_PUSH_XMM 0
443     ; Use the shadow space to store XMM6 and XMM7, the rest needs stack space allocated.
444     %if xmm_regs_used > 6
445         movaps [rstk + stack_offset +  8], xmm6
446     %endif
447     %if xmm_regs_used > 7
448         movaps [rstk + stack_offset + 24], xmm7
449     %endif
450     %if xmm_regs_used > 8
451         %assign %%i 8
452         %rep xmm_regs_used-8
453             movaps [rsp + (%%i-8)*16 + stack_size + 32], xmm %+ %%i
454             %assign %%i %%i+1
455         %endrep
456     %endif
457 %endmacro
458
459 %macro WIN64_SPILL_XMM 1
460     %assign xmm_regs_used %1
461     ASSERT xmm_regs_used <= 16
462     %if xmm_regs_used > 8
463         ; Allocate stack space for callee-saved xmm registers plus shadow space and align the stack.
464         %assign %%pad (xmm_regs_used-8)*16 + 32
465         %assign stack_size_padded %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
466         SUB rsp, stack_size_padded
467     %endif
468     WIN64_PUSH_XMM
469 %endmacro
470
471 %macro WIN64_RESTORE_XMM_INTERNAL 1
472     %assign %%pad_size 0
473     %if xmm_regs_used > 8
474         %assign %%i xmm_regs_used
475         %rep xmm_regs_used-8
476             %assign %%i %%i-1
477             movaps xmm %+ %%i, [%1 + (%%i-8)*16 + stack_size + 32]
478         %endrep
479     %endif
480     %if stack_size_padded > 0
481         %if stack_size > 0 && required_stack_alignment > STACK_ALIGNMENT
482             mov rsp, rstkm
483         %else
484             add %1, stack_size_padded
485             %assign %%pad_size stack_size_padded
486         %endif
487     %endif
488     %if xmm_regs_used > 7
489         movaps xmm7, [%1 + stack_offset - %%pad_size + 24]
490     %endif
491     %if xmm_regs_used > 6
492         movaps xmm6, [%1 + stack_offset - %%pad_size +  8]
493     %endif
494 %endmacro
495
496 %macro WIN64_RESTORE_XMM 1
497     WIN64_RESTORE_XMM_INTERNAL %1
498     %assign stack_offset (stack_offset-stack_size_padded)
499     %assign xmm_regs_used 0
500 %endmacro
501
502 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
503
504 %macro RET 0
505     WIN64_RESTORE_XMM_INTERNAL rsp
506     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
507     %if mmsize == 32
508         vzeroupper
509     %endif
510     AUTO_REP_RET
511 %endmacro
512
513 %elif ARCH_X86_64 ; *nix x64 ;=============================================
514
515 DECLARE_REG 0,  rdi
516 DECLARE_REG 1,  rsi
517 DECLARE_REG 2,  rdx
518 DECLARE_REG 3,  rcx
519 DECLARE_REG 4,  R8
520 DECLARE_REG 5,  R9
521 DECLARE_REG 6,  rax, 8
522 DECLARE_REG 7,  R10, 16
523 DECLARE_REG 8,  R11, 24
524 DECLARE_REG 9,  rbx, 32
525 DECLARE_REG 10, rbp, 40
526 DECLARE_REG 11, R12, 48
527 DECLARE_REG 12, R13, 56
528 DECLARE_REG 13, R14, 64
529 DECLARE_REG 14, R15, 72
530
531 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
532     %assign num_args %1
533     %assign regs_used %2
534     ASSERT regs_used >= num_args
535     SETUP_STACK_POINTER %4
536     ASSERT regs_used <= 15
537     PUSH_IF_USED 9, 10, 11, 12, 13, 14
538     ALLOC_STACK %4
539     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
540     DEFINE_ARGS_INTERNAL %0, %4, %5
541 %endmacro
542
543 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
544
545 %macro RET 0
546     %if stack_size_padded > 0
547         %if required_stack_alignment > STACK_ALIGNMENT
548             mov rsp, rstkm
549         %else
550             add rsp, stack_size_padded
551         %endif
552     %endif
553     POP_IF_USED 14, 13, 12, 11, 10, 9
554     %if mmsize == 32
555         vzeroupper
556     %endif
557     AUTO_REP_RET
558 %endmacro
559
560 %else ; X86_32 ;==============================================================
561
562 DECLARE_REG 0, eax, 4
563 DECLARE_REG 1, ecx, 8
564 DECLARE_REG 2, edx, 12
565 DECLARE_REG 3, ebx, 16
566 DECLARE_REG 4, esi, 20
567 DECLARE_REG 5, edi, 24
568 DECLARE_REG 6, ebp, 28
569 %define rsp esp
570
571 %macro DECLARE_ARG 1-*
572     %rep %0
573         %define r%1m [rstk + stack_offset + 4*%1 + 4]
574         %define r%1mp dword r%1m
575         %rotate 1
576     %endrep
577 %endmacro
578
579 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
580
581 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
582     %assign num_args %1
583     %assign regs_used %2
584     ASSERT regs_used >= num_args
585     %if num_args > 7
586         %assign num_args 7
587     %endif
588     %if regs_used > 7
589         %assign regs_used 7
590     %endif
591     SETUP_STACK_POINTER %4
592     ASSERT regs_used <= 7
593     PUSH_IF_USED 3, 4, 5, 6
594     ALLOC_STACK %4
595     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
596     DEFINE_ARGS_INTERNAL %0, %4, %5
597 %endmacro
598
599 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
600
601 %macro RET 0
602     %if stack_size_padded > 0
603         %if required_stack_alignment > STACK_ALIGNMENT
604             mov rsp, rstkm
605         %else
606             add rsp, stack_size_padded
607         %endif
608     %endif
609     POP_IF_USED 6, 5, 4, 3
610     %if mmsize == 32
611         vzeroupper
612     %endif
613     AUTO_REP_RET
614 %endmacro
615
616 %endif ;======================================================================
617
618 %if WIN64 == 0
619     %macro WIN64_SPILL_XMM 1
620     %endmacro
621     %macro WIN64_RESTORE_XMM 1
622     %endmacro
623     %macro WIN64_PUSH_XMM 0
624     %endmacro
625 %endif
626
627 ; On AMD cpus <=K10, an ordinary ret is slow if it immediately follows either
628 ; a branch or a branch target. So switch to a 2-byte form of ret in that case.
629 ; We can automatically detect "follows a branch", but not a branch target.
630 ; (SSSE3 is a sufficient condition to know that your cpu doesn't have this problem.)
631 %macro REP_RET 0
632     %if has_epilogue
633         RET
634     %else
635         rep ret
636     %endif
637     annotate_function_size
638 %endmacro
639
640 %define last_branch_adr $$
641 %macro AUTO_REP_RET 0
642     %if notcpuflag(ssse3)
643         times ((last_branch_adr-$)>>31)+1 rep ; times 1 iff $ == last_branch_adr.
644     %endif
645     ret
646     annotate_function_size
647 %endmacro
648
649 %macro BRANCH_INSTR 0-*
650     %rep %0
651         %macro %1 1-2 %1
652             %2 %1
653             %if notcpuflag(ssse3)
654                 %%branch_instr equ $
655                 %xdefine last_branch_adr %%branch_instr
656             %endif
657         %endmacro
658         %rotate 1
659     %endrep
660 %endmacro
661
662 BRANCH_INSTR jz, je, jnz, jne, jl, jle, jnl, jnle, jg, jge, jng, jnge, ja, jae, jna, jnae, jb, jbe, jnb, jnbe, jc, jnc, js, jns, jo, jno, jp, jnp
663
664 %macro TAIL_CALL 2 ; callee, is_nonadjacent
665     %if has_epilogue
666         call %1
667         RET
668     %elif %2
669         jmp %1
670     %endif
671     annotate_function_size
672 %endmacro
673
674 ;=============================================================================
675 ; arch-independent part
676 ;=============================================================================
677
678 %assign function_align 16
679
680 ; Begin a function.
681 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
682 ; subsequent uses of the function name automatically refer to the mangled version.
683 ; Appends cpuflags to the function name if cpuflags has been specified.
684 ; The "" empty default parameter is a workaround for nasm, which fails if SUFFIX
685 ; is empty and we call cglobal_internal with just %1 %+ SUFFIX (without %2).
686 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
687     cglobal_internal 1, %1 %+ SUFFIX, %2
688 %endmacro
689 %macro cvisible 1-2+ "" ; name, [PROLOGUE args]
690     cglobal_internal 0, %1 %+ SUFFIX, %2
691 %endmacro
692 %macro cglobal_internal 2-3+
693     annotate_function_size
694     %if %1
695         %xdefine %%FUNCTION_PREFIX private_prefix
696         %xdefine %%VISIBILITY hidden
697     %else
698         %xdefine %%FUNCTION_PREFIX public_prefix
699         %xdefine %%VISIBILITY
700     %endif
701     %ifndef cglobaled_%2
702         %xdefine %2 mangle(%%FUNCTION_PREFIX %+ _ %+ %2)
703         %xdefine %2.skip_prologue %2 %+ .skip_prologue
704         CAT_XDEFINE cglobaled_, %2, 1
705     %endif
706     %xdefine current_function %2
707     %xdefine current_function_section __SECT__
708     %if FORMAT_ELF
709         global %2:function %%VISIBILITY
710     %else
711         global %2
712     %endif
713     align function_align
714     %2:
715     RESET_MM_PERMUTATION        ; needed for x86-64, also makes disassembly somewhat nicer
716     %xdefine rstk rsp           ; copy of the original stack pointer, used when greater alignment than the known stack alignment is required
717     %assign stack_offset 0      ; stack pointer offset relative to the return address
718     %assign stack_size 0        ; amount of stack space that can be freely used inside a function
719     %assign stack_size_padded 0 ; total amount of allocated stack space, including space for callee-saved xmm registers on WIN64 and alignment padding
720     %assign xmm_regs_used 0     ; number of XMM registers requested, used for dealing with callee-saved registers on WIN64
721     %ifnidn %3, ""
722         PROLOGUE %3
723     %endif
724 %endmacro
725
726 %macro cextern 1
727     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
728     CAT_XDEFINE cglobaled_, %1, 1
729     extern %1
730 %endmacro
731
732 ; like cextern, but without the prefix
733 %macro cextern_naked 1
734     %ifdef PREFIX
735         %xdefine %1 mangle(%1)
736     %endif
737     CAT_XDEFINE cglobaled_, %1, 1
738     extern %1
739 %endmacro
740
741 %macro const 1-2+
742     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
743     %if FORMAT_ELF
744         global %1:data hidden
745     %else
746         global %1
747     %endif
748     %1: %2
749 %endmacro
750
751 ; This is needed for ELF, otherwise the GNU linker assumes the stack is executable by default.
752 %if FORMAT_ELF
753     [SECTION .note.GNU-stack noalloc noexec nowrite progbits]
754 %endif
755
756 ; Tell debuggers how large the function was.
757 ; This may be invoked multiple times per function; we rely on later instances overriding earlier ones.
758 ; This is invoked by RET and similar macros, and also cglobal does it for the previous function,
759 ; but if the last function in a source file doesn't use any of the standard macros for its epilogue,
760 ; then its size might be unspecified.
761 %macro annotate_function_size 0
762     %ifdef __YASM_VER__
763         %ifdef current_function
764             %if FORMAT_ELF
765                 current_function_section
766                 %%ecf equ $
767                 size current_function %%ecf - current_function
768                 __SECT__
769             %endif
770         %endif
771     %endif
772 %endmacro
773
774 ; cpuflags
775
776 %assign cpuflags_mmx      (1<<0)
777 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
778 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
779 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
780 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
781 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
782 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
783 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
784 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
785 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
786 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
787 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
788 %assign cpuflags_xop      (1<<12)| cpuflags_avx
789 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
790 %assign cpuflags_fma3     (1<<14)| cpuflags_avx
791 %assign cpuflags_avx2     (1<<15)| cpuflags_fma3
792
793 %assign cpuflags_cache32  (1<<16)
794 %assign cpuflags_cache64  (1<<17)
795 %assign cpuflags_slowctz  (1<<18)
796 %assign cpuflags_lzcnt    (1<<19)
797 %assign cpuflags_aligned  (1<<20) ; not a cpu feature, but a function variant
798 %assign cpuflags_atom     (1<<21)
799 %assign cpuflags_bmi1     (1<<22)|cpuflags_lzcnt
800 %assign cpuflags_bmi2     (1<<23)|cpuflags_bmi1
801
802 ; Returns a boolean value expressing whether or not the specified cpuflag is enabled.
803 %define    cpuflag(x) (((((cpuflags & (cpuflags_ %+ x)) ^ (cpuflags_ %+ x)) - 1) >> 31) & 1)
804 %define notcpuflag(x) (cpuflag(x) ^ 1)
805
806 ; Takes an arbitrary number of cpuflags from the above list.
807 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
808 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
809 %macro INIT_CPUFLAGS 0-*
810     %xdefine SUFFIX
811     %undef cpuname
812     %assign cpuflags 0
813
814     %if %0 >= 1
815         %rep %0
816             %ifdef cpuname
817                 %xdefine cpuname cpuname %+ _%1
818             %else
819                 %xdefine cpuname %1
820             %endif
821             %assign cpuflags cpuflags | cpuflags_%1
822             %rotate 1
823         %endrep
824         %xdefine SUFFIX _ %+ cpuname
825
826         %if cpuflag(avx)
827             %assign avx_enabled 1
828         %endif
829         %if (mmsize == 16 && notcpuflag(sse2)) || (mmsize == 32 && notcpuflag(avx2))
830             %define mova movaps
831             %define movu movups
832             %define movnta movntps
833         %endif
834         %if cpuflag(aligned)
835             %define movu mova
836         %elif cpuflag(sse3) && notcpuflag(ssse3)
837             %define movu lddqu
838         %endif
839     %endif
840
841     %if ARCH_X86_64 || cpuflag(sse2)
842         CPUNOP amdnop
843     %else
844         CPUNOP basicnop
845     %endif
846 %endmacro
847
848 ; Merge mmx and sse*
849 ; m# is a simd register of the currently selected size
850 ; xm# is the corresponding xmm register if mmsize >= 16, otherwise the same as m#
851 ; ym# is the corresponding ymm register if mmsize >= 32, otherwise the same as m#
852 ; (All 3 remain in sync through SWAP.)
853
854 %macro CAT_XDEFINE 3
855     %xdefine %1%2 %3
856 %endmacro
857
858 %macro CAT_UNDEF 2
859     %undef %1%2
860 %endmacro
861
862 %macro INIT_MMX 0-1+
863     %assign avx_enabled 0
864     %define RESET_MM_PERMUTATION INIT_MMX %1
865     %define mmsize 8
866     %define num_mmregs 8
867     %define mova movq
868     %define movu movq
869     %define movh movd
870     %define movnta movntq
871     %assign %%i 0
872     %rep 8
873         CAT_XDEFINE m, %%i, mm %+ %%i
874         CAT_XDEFINE nnmm, %%i, %%i
875         %assign %%i %%i+1
876     %endrep
877     %rep 8
878         CAT_UNDEF m, %%i
879         CAT_UNDEF nnmm, %%i
880         %assign %%i %%i+1
881     %endrep
882     INIT_CPUFLAGS %1
883 %endmacro
884
885 %macro INIT_XMM 0-1+
886     %assign avx_enabled 0
887     %define RESET_MM_PERMUTATION INIT_XMM %1
888     %define mmsize 16
889     %define num_mmregs 8
890     %if ARCH_X86_64
891         %define num_mmregs 16
892     %endif
893     %define mova movdqa
894     %define movu movdqu
895     %define movh movq
896     %define movnta movntdq
897     %assign %%i 0
898     %rep num_mmregs
899         CAT_XDEFINE m, %%i, xmm %+ %%i
900         CAT_XDEFINE nnxmm, %%i, %%i
901         %assign %%i %%i+1
902     %endrep
903     INIT_CPUFLAGS %1
904 %endmacro
905
906 %macro INIT_YMM 0-1+
907     %assign avx_enabled 1
908     %define RESET_MM_PERMUTATION INIT_YMM %1
909     %define mmsize 32
910     %define num_mmregs 8
911     %if ARCH_X86_64
912         %define num_mmregs 16
913     %endif
914     %define mova movdqa
915     %define movu movdqu
916     %undef movh
917     %define movnta movntdq
918     %assign %%i 0
919     %rep num_mmregs
920         CAT_XDEFINE m, %%i, ymm %+ %%i
921         CAT_XDEFINE nnymm, %%i, %%i
922         %assign %%i %%i+1
923     %endrep
924     INIT_CPUFLAGS %1
925 %endmacro
926
927 INIT_XMM
928
929 %macro DECLARE_MMCAST 1
930     %define  mmmm%1   mm%1
931     %define  mmxmm%1  mm%1
932     %define  mmymm%1  mm%1
933     %define xmmmm%1   mm%1
934     %define xmmxmm%1 xmm%1
935     %define xmmymm%1 xmm%1
936     %define ymmmm%1   mm%1
937     %define ymmxmm%1 xmm%1
938     %define ymmymm%1 ymm%1
939     %define xm%1 xmm %+ m%1
940     %define ym%1 ymm %+ m%1
941 %endmacro
942
943 %assign i 0
944 %rep 16
945     DECLARE_MMCAST i
946     %assign i i+1
947 %endrep
948
949 ; I often want to use macros that permute their arguments. e.g. there's no
950 ; efficient way to implement butterfly or transpose or dct without swapping some
951 ; arguments.
952 ;
953 ; I would like to not have to manually keep track of the permutations:
954 ; If I insert a permutation in the middle of a function, it should automatically
955 ; change everything that follows. For more complex macros I may also have multiple
956 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
957 ;
958 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
959 ; permutes its arguments. It's equivalent to exchanging the contents of the
960 ; registers, except that this way you exchange the register names instead, so it
961 ; doesn't cost any cycles.
962
963 %macro PERMUTE 2-* ; takes a list of pairs to swap
964     %rep %0/2
965         %xdefine %%tmp%2 m%2
966         %rotate 2
967     %endrep
968     %rep %0/2
969         %xdefine m%1 %%tmp%2
970         CAT_XDEFINE nn, m%1, %1
971         %rotate 2
972     %endrep
973 %endmacro
974
975 %macro SWAP 2+ ; swaps a single chain (sometimes more concise than pairs)
976     %ifnum %1 ; SWAP 0, 1, ...
977         SWAP_INTERNAL_NUM %1, %2
978     %else ; SWAP m0, m1, ...
979         SWAP_INTERNAL_NAME %1, %2
980     %endif
981 %endmacro
982
983 %macro SWAP_INTERNAL_NUM 2-*
984     %rep %0-1
985         %xdefine %%tmp m%1
986         %xdefine m%1 m%2
987         %xdefine m%2 %%tmp
988         CAT_XDEFINE nn, m%1, %1
989         CAT_XDEFINE nn, m%2, %2
990         %rotate 1
991     %endrep
992 %endmacro
993
994 %macro SWAP_INTERNAL_NAME 2-*
995     %xdefine %%args nn %+ %1
996     %rep %0-1
997         %xdefine %%args %%args, nn %+ %2
998         %rotate 1
999     %endrep
1000     SWAP_INTERNAL_NUM %%args
1001 %endmacro
1002
1003 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
1004 ; calls to that function will automatically load the permutation, so values can
1005 ; be returned in mmregs.
1006 %macro SAVE_MM_PERMUTATION 0-1
1007     %if %0
1008         %xdefine %%f %1_m
1009     %else
1010         %xdefine %%f current_function %+ _m
1011     %endif
1012     %assign %%i 0
1013     %rep num_mmregs
1014         CAT_XDEFINE %%f, %%i, m %+ %%i
1015         %assign %%i %%i+1
1016     %endrep
1017 %endmacro
1018
1019 %macro LOAD_MM_PERMUTATION 1 ; name to load from
1020     %ifdef %1_m0
1021         %assign %%i 0
1022         %rep num_mmregs
1023             CAT_XDEFINE m, %%i, %1_m %+ %%i
1024             CAT_XDEFINE nn, m %+ %%i, %%i
1025             %assign %%i %%i+1
1026         %endrep
1027     %endif
1028 %endmacro
1029
1030 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
1031 %macro call 1
1032     call_internal %1 %+ SUFFIX, %1
1033 %endmacro
1034 %macro call_internal 2
1035     %xdefine %%i %2
1036     %ifndef cglobaled_%2
1037         %ifdef cglobaled_%1
1038             %xdefine %%i %1
1039         %endif
1040     %endif
1041     call %%i
1042     LOAD_MM_PERMUTATION %%i
1043 %endmacro
1044
1045 ; Substitutions that reduce instruction size but are functionally equivalent
1046 %macro add 2
1047     %ifnum %2
1048         %if %2==128
1049             sub %1, -128
1050         %else
1051             add %1, %2
1052         %endif
1053     %else
1054         add %1, %2
1055     %endif
1056 %endmacro
1057
1058 %macro sub 2
1059     %ifnum %2
1060         %if %2==128
1061             add %1, -128
1062         %else
1063             sub %1, %2
1064         %endif
1065     %else
1066         sub %1, %2
1067     %endif
1068 %endmacro
1069
1070 ;=============================================================================
1071 ; AVX abstraction layer
1072 ;=============================================================================
1073
1074 %assign i 0
1075 %rep 16
1076     %if i < 8
1077         CAT_XDEFINE sizeofmm, i, 8
1078     %endif
1079     CAT_XDEFINE sizeofxmm, i, 16
1080     CAT_XDEFINE sizeofymm, i, 32
1081     %assign i i+1
1082 %endrep
1083 %undef i
1084
1085 %macro CHECK_AVX_INSTR_EMU 3-*
1086     %xdefine %%opcode %1
1087     %xdefine %%dst %2
1088     %rep %0-2
1089         %ifidn %%dst, %3
1090             %error non-avx emulation of ``%%opcode'' is not supported
1091         %endif
1092         %rotate 1
1093     %endrep
1094 %endmacro
1095
1096 ;%1 == instruction
1097 ;%2 == minimal instruction set
1098 ;%3 == 1 if float, 0 if int
1099 ;%4 == 1 if 4-operand emulation, 0 if 3-operand emulation, 255 otherwise (no emulation)
1100 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1101 ;%6+: operands
1102 %macro RUN_AVX_INSTR 6-9+
1103     %ifnum sizeof%7
1104         %assign __sizeofreg sizeof%7
1105     %elifnum sizeof%6
1106         %assign __sizeofreg sizeof%6
1107     %else
1108         %assign __sizeofreg mmsize
1109     %endif
1110     %assign __emulate_avx 0
1111     %if avx_enabled && __sizeofreg >= 16
1112         %xdefine __instr v%1
1113     %else
1114         %xdefine __instr %1
1115         %if %0 >= 8+%4
1116             %assign __emulate_avx 1
1117         %endif
1118     %endif
1119     %ifnidn %2, fnord
1120         %ifdef cpuname
1121             %if notcpuflag(%2)
1122                 %error use of ``%1'' %2 instruction in cpuname function: current_function
1123             %elif cpuflags_%2 < cpuflags_sse && notcpuflag(sse2) && __sizeofreg > 8
1124                 %error use of ``%1'' sse2 instruction in cpuname function: current_function
1125             %endif
1126         %endif
1127     %endif
1128
1129     %if __emulate_avx
1130         %xdefine __src1 %7
1131         %xdefine __src2 %8
1132         %ifnidn %6, %7
1133             %if %0 >= 9
1134                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8, %9}, %6, %8, %9
1135             %else
1136                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8}, %6, %8
1137             %endif
1138             %if %5 && %4 == 0
1139                 %ifnnum sizeof%8
1140                     ; 3-operand AVX instructions with a memory arg can only have it in src2,
1141                     ; whereas SSE emulation prefers to have it in src1 (i.e. the mov).
1142                     ; So, if the instruction is commutative with a memory arg, swap them.
1143                     %xdefine __src1 %8
1144                     %xdefine __src2 %7
1145                 %endif
1146             %endif
1147             %if __sizeofreg == 8
1148                 MOVQ %6, __src1
1149             %elif %3
1150                 MOVAPS %6, __src1
1151             %else
1152                 MOVDQA %6, __src1
1153             %endif
1154         %endif
1155         %if %0 >= 9
1156             %1 %6, __src2, %9
1157         %else
1158             %1 %6, __src2
1159         %endif
1160     %elif %0 >= 9
1161         __instr %6, %7, %8, %9
1162     %elif %0 == 8
1163         __instr %6, %7, %8
1164     %elif %0 == 7
1165         __instr %6, %7
1166     %else
1167         __instr %6
1168     %endif
1169 %endmacro
1170
1171 ;%1 == instruction
1172 ;%2 == minimal instruction set
1173 ;%3 == 1 if float, 0 if int
1174 ;%4 == 1 if 4-operand emulation, 0 if 3-operand emulation, 255 otherwise (no emulation)
1175 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1176 %macro AVX_INSTR 1-5 fnord, 0, 255, 0
1177     %macro %1 1-10 fnord, fnord, fnord, fnord, %1, %2, %3, %4, %5
1178         %ifidn %2, fnord
1179             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1
1180         %elifidn %3, fnord
1181             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2
1182         %elifidn %4, fnord
1183             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3
1184         %elifidn %5, fnord
1185             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4
1186         %else
1187             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4, %5
1188         %endif
1189     %endmacro
1190 %endmacro
1191
1192 ; Instructions with both VEX and non-VEX encodings
1193 ; Non-destructive instructions are written without parameters
1194 AVX_INSTR addpd, sse2, 1, 0, 1
1195 AVX_INSTR addps, sse, 1, 0, 1
1196 AVX_INSTR addsd, sse2, 1, 0, 0
1197 AVX_INSTR addss, sse, 1, 0, 0
1198 AVX_INSTR addsubpd, sse3, 1, 0, 0
1199 AVX_INSTR addsubps, sse3, 1, 0, 0
1200 AVX_INSTR aesdec, fnord, 0, 0, 0
1201 AVX_INSTR aesdeclast, fnord, 0, 0, 0
1202 AVX_INSTR aesenc, fnord, 0, 0, 0
1203 AVX_INSTR aesenclast, fnord, 0, 0, 0
1204 AVX_INSTR aesimc
1205 AVX_INSTR aeskeygenassist
1206 AVX_INSTR andnpd, sse2, 1, 0, 0
1207 AVX_INSTR andnps, sse, 1, 0, 0
1208 AVX_INSTR andpd, sse2, 1, 0, 1
1209 AVX_INSTR andps, sse, 1, 0, 1
1210 AVX_INSTR blendpd, sse4, 1, 1, 0
1211 AVX_INSTR blendps, sse4, 1, 1, 0
1212 AVX_INSTR blendvpd, sse4 ; can't be emulated
1213 AVX_INSTR blendvps, sse4 ; can't be emulated
1214 AVX_INSTR cmppd, sse2, 1, 1, 0
1215 AVX_INSTR cmpps, sse, 1, 1, 0
1216 AVX_INSTR cmpsd, sse2, 1, 1, 0
1217 AVX_INSTR cmpss, sse, 1, 1, 0
1218 AVX_INSTR comisd, sse2
1219 AVX_INSTR comiss, sse
1220 AVX_INSTR cvtdq2pd, sse2
1221 AVX_INSTR cvtdq2ps, sse2
1222 AVX_INSTR cvtpd2dq, sse2
1223 AVX_INSTR cvtpd2ps, sse2
1224 AVX_INSTR cvtps2dq, sse2
1225 AVX_INSTR cvtps2pd, sse2
1226 AVX_INSTR cvtsd2si, sse2
1227 AVX_INSTR cvtsd2ss, sse2, 1, 0, 0
1228 AVX_INSTR cvtsi2sd, sse2, 1, 0, 0
1229 AVX_INSTR cvtsi2ss, sse, 1, 0, 0
1230 AVX_INSTR cvtss2sd, sse2, 1, 0, 0
1231 AVX_INSTR cvtss2si, sse
1232 AVX_INSTR cvttpd2dq, sse2
1233 AVX_INSTR cvttps2dq, sse2
1234 AVX_INSTR cvttsd2si, sse2
1235 AVX_INSTR cvttss2si, sse
1236 AVX_INSTR divpd, sse2, 1, 0, 0
1237 AVX_INSTR divps, sse, 1, 0, 0
1238 AVX_INSTR divsd, sse2, 1, 0, 0
1239 AVX_INSTR divss, sse, 1, 0, 0
1240 AVX_INSTR dppd, sse4, 1, 1, 0
1241 AVX_INSTR dpps, sse4, 1, 1, 0
1242 AVX_INSTR extractps, sse4
1243 AVX_INSTR haddpd, sse3, 1, 0, 0
1244 AVX_INSTR haddps, sse3, 1, 0, 0
1245 AVX_INSTR hsubpd, sse3, 1, 0, 0
1246 AVX_INSTR hsubps, sse3, 1, 0, 0
1247 AVX_INSTR insertps, sse4, 1, 1, 0
1248 AVX_INSTR lddqu, sse3
1249 AVX_INSTR ldmxcsr, sse
1250 AVX_INSTR maskmovdqu, sse2
1251 AVX_INSTR maxpd, sse2, 1, 0, 1
1252 AVX_INSTR maxps, sse, 1, 0, 1
1253 AVX_INSTR maxsd, sse2, 1, 0, 0
1254 AVX_INSTR maxss, sse, 1, 0, 0
1255 AVX_INSTR minpd, sse2, 1, 0, 1
1256 AVX_INSTR minps, sse, 1, 0, 1
1257 AVX_INSTR minsd, sse2, 1, 0, 0
1258 AVX_INSTR minss, sse, 1, 0, 0
1259 AVX_INSTR movapd, sse2
1260 AVX_INSTR movaps, sse
1261 AVX_INSTR movd, mmx
1262 AVX_INSTR movddup, sse3
1263 AVX_INSTR movdqa, sse2
1264 AVX_INSTR movdqu, sse2
1265 AVX_INSTR movhlps, sse, 1, 0, 0
1266 AVX_INSTR movhpd, sse2, 1, 0, 0
1267 AVX_INSTR movhps, sse, 1, 0, 0
1268 AVX_INSTR movlhps, sse, 1, 0, 0
1269 AVX_INSTR movlpd, sse2, 1, 0, 0
1270 AVX_INSTR movlps, sse, 1, 0, 0
1271 AVX_INSTR movmskpd, sse2
1272 AVX_INSTR movmskps, sse
1273 AVX_INSTR movntdq, sse2
1274 AVX_INSTR movntdqa, sse4
1275 AVX_INSTR movntpd, sse2
1276 AVX_INSTR movntps, sse
1277 AVX_INSTR movq, mmx
1278 AVX_INSTR movsd, sse2, 1, 0, 0
1279 AVX_INSTR movshdup, sse3
1280 AVX_INSTR movsldup, sse3
1281 AVX_INSTR movss, sse, 1, 0, 0
1282 AVX_INSTR movupd, sse2
1283 AVX_INSTR movups, sse
1284 AVX_INSTR mpsadbw, sse4, 0, 1, 0
1285 AVX_INSTR mulpd, sse2, 1, 0, 1
1286 AVX_INSTR mulps, sse, 1, 0, 1
1287 AVX_INSTR mulsd, sse2, 1, 0, 0
1288 AVX_INSTR mulss, sse, 1, 0, 0
1289 AVX_INSTR orpd, sse2, 1, 0, 1
1290 AVX_INSTR orps, sse, 1, 0, 1
1291 AVX_INSTR pabsb, ssse3
1292 AVX_INSTR pabsd, ssse3
1293 AVX_INSTR pabsw, ssse3
1294 AVX_INSTR packsswb, mmx, 0, 0, 0
1295 AVX_INSTR packssdw, mmx, 0, 0, 0
1296 AVX_INSTR packuswb, mmx, 0, 0, 0
1297 AVX_INSTR packusdw, sse4, 0, 0, 0
1298 AVX_INSTR paddb, mmx, 0, 0, 1
1299 AVX_INSTR paddw, mmx, 0, 0, 1
1300 AVX_INSTR paddd, mmx, 0, 0, 1
1301 AVX_INSTR paddq, sse2, 0, 0, 1
1302 AVX_INSTR paddsb, mmx, 0, 0, 1
1303 AVX_INSTR paddsw, mmx, 0, 0, 1
1304 AVX_INSTR paddusb, mmx, 0, 0, 1
1305 AVX_INSTR paddusw, mmx, 0, 0, 1
1306 AVX_INSTR palignr, ssse3, 0, 1, 0
1307 AVX_INSTR pand, mmx, 0, 0, 1
1308 AVX_INSTR pandn, mmx, 0, 0, 0
1309 AVX_INSTR pavgb, mmx2, 0, 0, 1
1310 AVX_INSTR pavgw, mmx2, 0, 0, 1
1311 AVX_INSTR pblendvb, sse4 ; can't be emulated
1312 AVX_INSTR pblendw, sse4, 0, 1, 0
1313 AVX_INSTR pclmulqdq, fnord, 0, 1, 0
1314 AVX_INSTR pclmulhqhqdq, fnord, 0, 0, 0
1315 AVX_INSTR pclmulhqlqdq, fnord, 0, 0, 0
1316 AVX_INSTR pclmullqhqdq, fnord, 0, 0, 0
1317 AVX_INSTR pclmullqlqdq, fnord, 0, 0, 0
1318 AVX_INSTR pcmpestri, sse42
1319 AVX_INSTR pcmpestrm, sse42
1320 AVX_INSTR pcmpistri, sse42
1321 AVX_INSTR pcmpistrm, sse42
1322 AVX_INSTR pcmpeqb, mmx, 0, 0, 1
1323 AVX_INSTR pcmpeqw, mmx, 0, 0, 1
1324 AVX_INSTR pcmpeqd, mmx, 0, 0, 1
1325 AVX_INSTR pcmpeqq, sse4, 0, 0, 1
1326 AVX_INSTR pcmpgtb, mmx, 0, 0, 0
1327 AVX_INSTR pcmpgtw, mmx, 0, 0, 0
1328 AVX_INSTR pcmpgtd, mmx, 0, 0, 0
1329 AVX_INSTR pcmpgtq, sse42, 0, 0, 0
1330 AVX_INSTR pextrb, sse4
1331 AVX_INSTR pextrd, sse4
1332 AVX_INSTR pextrq, sse4
1333 AVX_INSTR pextrw, mmx2
1334 AVX_INSTR phaddw, ssse3, 0, 0, 0
1335 AVX_INSTR phaddd, ssse3, 0, 0, 0
1336 AVX_INSTR phaddsw, ssse3, 0, 0, 0
1337 AVX_INSTR phminposuw, sse4
1338 AVX_INSTR phsubw, ssse3, 0, 0, 0
1339 AVX_INSTR phsubd, ssse3, 0, 0, 0
1340 AVX_INSTR phsubsw, ssse3, 0, 0, 0
1341 AVX_INSTR pinsrb, sse4, 0, 1, 0
1342 AVX_INSTR pinsrd, sse4, 0, 1, 0
1343 AVX_INSTR pinsrq, sse4, 0, 1, 0
1344 AVX_INSTR pinsrw, mmx2, 0, 1, 0
1345 AVX_INSTR pmaddwd, mmx, 0, 0, 1
1346 AVX_INSTR pmaddubsw, ssse3, 0, 0, 0
1347 AVX_INSTR pmaxsb, sse4, 0, 0, 1
1348 AVX_INSTR pmaxsw, mmx2, 0, 0, 1
1349 AVX_INSTR pmaxsd, sse4, 0, 0, 1
1350 AVX_INSTR pmaxub, mmx2, 0, 0, 1
1351 AVX_INSTR pmaxuw, sse4, 0, 0, 1
1352 AVX_INSTR pmaxud, sse4, 0, 0, 1
1353 AVX_INSTR pminsb, sse4, 0, 0, 1
1354 AVX_INSTR pminsw, mmx2, 0, 0, 1
1355 AVX_INSTR pminsd, sse4, 0, 0, 1
1356 AVX_INSTR pminub, mmx2, 0, 0, 1
1357 AVX_INSTR pminuw, sse4, 0, 0, 1
1358 AVX_INSTR pminud, sse4, 0, 0, 1
1359 AVX_INSTR pmovmskb, mmx2
1360 AVX_INSTR pmovsxbw, sse4
1361 AVX_INSTR pmovsxbd, sse4
1362 AVX_INSTR pmovsxbq, sse4
1363 AVX_INSTR pmovsxwd, sse4
1364 AVX_INSTR pmovsxwq, sse4
1365 AVX_INSTR pmovsxdq, sse4
1366 AVX_INSTR pmovzxbw, sse4
1367 AVX_INSTR pmovzxbd, sse4
1368 AVX_INSTR pmovzxbq, sse4
1369 AVX_INSTR pmovzxwd, sse4
1370 AVX_INSTR pmovzxwq, sse4
1371 AVX_INSTR pmovzxdq, sse4
1372 AVX_INSTR pmuldq, sse4, 0, 0, 1
1373 AVX_INSTR pmulhrsw, ssse3, 0, 0, 1
1374 AVX_INSTR pmulhuw, mmx2, 0, 0, 1
1375 AVX_INSTR pmulhw, mmx, 0, 0, 1
1376 AVX_INSTR pmullw, mmx, 0, 0, 1
1377 AVX_INSTR pmulld, sse4, 0, 0, 1
1378 AVX_INSTR pmuludq, sse2, 0, 0, 1
1379 AVX_INSTR por, mmx, 0, 0, 1
1380 AVX_INSTR psadbw, mmx2, 0, 0, 1
1381 AVX_INSTR pshufb, ssse3, 0, 0, 0
1382 AVX_INSTR pshufd, sse2
1383 AVX_INSTR pshufhw, sse2
1384 AVX_INSTR pshuflw, sse2
1385 AVX_INSTR psignb, ssse3, 0, 0, 0
1386 AVX_INSTR psignw, ssse3, 0, 0, 0
1387 AVX_INSTR psignd, ssse3, 0, 0, 0
1388 AVX_INSTR psllw, mmx, 0, 0, 0
1389 AVX_INSTR pslld, mmx, 0, 0, 0
1390 AVX_INSTR psllq, mmx, 0, 0, 0
1391 AVX_INSTR pslldq, sse2, 0, 0, 0
1392 AVX_INSTR psraw, mmx, 0, 0, 0
1393 AVX_INSTR psrad, mmx, 0, 0, 0
1394 AVX_INSTR psrlw, mmx, 0, 0, 0
1395 AVX_INSTR psrld, mmx, 0, 0, 0
1396 AVX_INSTR psrlq, mmx, 0, 0, 0
1397 AVX_INSTR psrldq, sse2, 0, 0, 0
1398 AVX_INSTR psubb, mmx, 0, 0, 0
1399 AVX_INSTR psubw, mmx, 0, 0, 0
1400 AVX_INSTR psubd, mmx, 0, 0, 0
1401 AVX_INSTR psubq, sse2, 0, 0, 0
1402 AVX_INSTR psubsb, mmx, 0, 0, 0
1403 AVX_INSTR psubsw, mmx, 0, 0, 0
1404 AVX_INSTR psubusb, mmx, 0, 0, 0
1405 AVX_INSTR psubusw, mmx, 0, 0, 0
1406 AVX_INSTR ptest, sse4
1407 AVX_INSTR punpckhbw, mmx, 0, 0, 0
1408 AVX_INSTR punpckhwd, mmx, 0, 0, 0
1409 AVX_INSTR punpckhdq, mmx, 0, 0, 0
1410 AVX_INSTR punpckhqdq, sse2, 0, 0, 0
1411 AVX_INSTR punpcklbw, mmx, 0, 0, 0
1412 AVX_INSTR punpcklwd, mmx, 0, 0, 0
1413 AVX_INSTR punpckldq, mmx, 0, 0, 0
1414 AVX_INSTR punpcklqdq, sse2, 0, 0, 0
1415 AVX_INSTR pxor, mmx, 0, 0, 1
1416 AVX_INSTR rcpps, sse
1417 AVX_INSTR rcpss, sse, 1, 0, 0
1418 AVX_INSTR roundpd, sse4
1419 AVX_INSTR roundps, sse4
1420 AVX_INSTR roundsd, sse4, 1, 1, 0
1421 AVX_INSTR roundss, sse4, 1, 1, 0
1422 AVX_INSTR rsqrtps, sse
1423 AVX_INSTR rsqrtss, sse, 1, 0, 0
1424 AVX_INSTR shufpd, sse2, 1, 1, 0
1425 AVX_INSTR shufps, sse, 1, 1, 0
1426 AVX_INSTR sqrtpd, sse2
1427 AVX_INSTR sqrtps, sse
1428 AVX_INSTR sqrtsd, sse2, 1, 0, 0
1429 AVX_INSTR sqrtss, sse, 1, 0, 0
1430 AVX_INSTR stmxcsr, sse
1431 AVX_INSTR subpd, sse2, 1, 0, 0
1432 AVX_INSTR subps, sse, 1, 0, 0
1433 AVX_INSTR subsd, sse2, 1, 0, 0
1434 AVX_INSTR subss, sse, 1, 0, 0
1435 AVX_INSTR ucomisd, sse2
1436 AVX_INSTR ucomiss, sse
1437 AVX_INSTR unpckhpd, sse2, 1, 0, 0
1438 AVX_INSTR unpckhps, sse, 1, 0, 0
1439 AVX_INSTR unpcklpd, sse2, 1, 0, 0
1440 AVX_INSTR unpcklps, sse, 1, 0, 0
1441 AVX_INSTR xorpd, sse2, 1, 0, 1
1442 AVX_INSTR xorps, sse, 1, 0, 1
1443
1444 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1445 AVX_INSTR pfadd, 3dnow, 1, 0, 1
1446 AVX_INSTR pfsub, 3dnow, 1, 0, 0
1447 AVX_INSTR pfmul, 3dnow, 1, 0, 1
1448
1449 ; base-4 constants for shuffles
1450 %assign i 0
1451 %rep 256
1452     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1453     %if j < 10
1454         CAT_XDEFINE q000, j, i
1455     %elif j < 100
1456         CAT_XDEFINE q00, j, i
1457     %elif j < 1000
1458         CAT_XDEFINE q0, j, i
1459     %else
1460         CAT_XDEFINE q, j, i
1461     %endif
1462     %assign i i+1
1463 %endrep
1464 %undef i
1465 %undef j
1466
1467 %macro FMA_INSTR 3
1468     %macro %1 4-7 %1, %2, %3
1469         %if cpuflag(xop)
1470             v%5 %1, %2, %3, %4
1471         %elifnidn %1, %4
1472             %6 %1, %2, %3
1473             %7 %1, %4
1474         %else
1475             %error non-xop emulation of ``%5 %1, %2, %3, %4'' is not supported
1476         %endif
1477     %endmacro
1478 %endmacro
1479
1480 FMA_INSTR  pmacsww,  pmullw, paddw
1481 FMA_INSTR  pmacsdd,  pmulld, paddd ; sse4 emulation
1482 FMA_INSTR pmacsdql,  pmuldq, paddq ; sse4 emulation
1483 FMA_INSTR pmadcswd, pmaddwd, paddd
1484
1485 ; tzcnt is equivalent to "rep bsf" and is backwards-compatible with bsf.
1486 ; This lets us use tzcnt without bumping the yasm version requirement yet.
1487 %define tzcnt rep bsf
1488
1489 ; Macros for consolidating FMA3 and FMA4 using 4-operand (dst, src1, src2, src3) syntax.
1490 ; FMA3 is only possible if dst is the same as one of the src registers.
1491 ; Either src2 or src3 can be a memory operand.
1492 %macro FMA4_INSTR 2-*
1493     %push fma4_instr
1494     %xdefine %$prefix %1
1495     %rep %0 - 1
1496         %macro %$prefix%2 4-6 %$prefix, %2
1497             %if notcpuflag(fma3) && notcpuflag(fma4)
1498                 %error use of ``%5%6'' fma instruction in cpuname function: current_function
1499             %elif cpuflag(fma4)
1500                 v%5%6 %1, %2, %3, %4
1501             %elifidn %1, %2
1502                 ; If %3 or %4 is a memory operand it needs to be encoded as the last operand.
1503                 %ifnum sizeof%3
1504                     v%{5}213%6 %2, %3, %4
1505                 %else
1506                     v%{5}132%6 %2, %4, %3
1507                 %endif
1508             %elifidn %1, %3
1509                 v%{5}213%6 %3, %2, %4
1510             %elifidn %1, %4
1511                 v%{5}231%6 %4, %2, %3
1512             %else
1513                 %error fma3 emulation of ``%5%6 %1, %2, %3, %4'' is not supported
1514             %endif
1515         %endmacro
1516         %rotate 1
1517     %endrep
1518     %pop
1519 %endmacro
1520
1521 FMA4_INSTR fmadd,    pd, ps, sd, ss
1522 FMA4_INSTR fmaddsub, pd, ps
1523 FMA4_INSTR fmsub,    pd, ps, sd, ss
1524 FMA4_INSTR fmsubadd, pd, ps
1525 FMA4_INSTR fnmadd,   pd, ps, sd, ss
1526 FMA4_INSTR fnmsub,   pd, ps, sd, ss
1527
1528 ; workaround: vpbroadcastq is broken in x86_32 due to a yasm bug (fixed in 1.3.0)
1529 %ifdef __YASM_VER__
1530     %if __YASM_VERSION_ID__ < 0x01030000 && ARCH_X86_64 == 0
1531         %macro vpbroadcastq 2
1532             %if sizeof%1 == 16
1533                 movddup %1, %2
1534             %else
1535                 vbroadcastsd %1, %2
1536             %endif
1537         %endmacro
1538     %endif
1539 %endif