07512d18d85457b71c7ea9496896564ab7f5c05b
[ffmpeg.git] / libavutil / x86 / x86inc.asm
1 ;*****************************************************************************
2 ;* x86inc.asm: x264asm abstraction layer
3 ;*****************************************************************************
4 ;* Copyright (C) 2005-2012 x264 project
5 ;*
6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
8 ;*          Jason Garrett-Glaser <darkshikari@gmail.com>
9 ;*          Henrik Gramner <hengar-6@student.ltu.se>
10 ;*
11 ;* Permission to use, copy, modify, and/or distribute this software for any
12 ;* purpose with or without fee is hereby granted, provided that the above
13 ;* copyright notice and this permission notice appear in all copies.
14 ;*
15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
22 ;*****************************************************************************
23
24 ; This is a header file for the x264ASM assembly language, which uses
25 ; NASM/YASM syntax combined with a large number of macros to provide easy
26 ; abstraction between different calling conventions (x86_32, win64, linux64).
27 ; It also has various other useful features to simplify writing the kind of
28 ; DSP functions that are most often used in x264.
29
30 ; Unlike the rest of x264, this file is available under an ISC license, as it
31 ; has significant usefulness outside of x264 and we want it to be available
32 ; to the largest audience possible.  Of course, if you modify it for your own
33 ; purposes to add a new feature, we strongly encourage contributing a patch
34 ; as this feature might be useful for others as well.  Send patches or ideas
35 ; to x264-devel@videolan.org .
36
37 %ifndef private_prefix
38     %define private_prefix x264
39 %endif
40
41 %ifndef public_prefix
42     %define public_prefix private_prefix
43 %endif
44
45 %define WIN64  0
46 %define UNIX64 0
47 %if ARCH_X86_64
48     %ifidn __OUTPUT_FORMAT__,win32
49         %define WIN64  1
50     %elifidn __OUTPUT_FORMAT__,win64
51         %define WIN64  1
52     %else
53         %define UNIX64 1
54     %endif
55 %endif
56
57 %ifdef PREFIX
58     %define mangle(x) _ %+ x
59 %else
60     %define mangle(x) x
61 %endif
62
63 ; Name of the .rodata section.
64 ; Kludge: Something on OS X fails to align .rodata even given an align attribute,
65 ; so use a different read-only section.
66 %macro SECTION_RODATA 0-1 16
67     %ifidn __OUTPUT_FORMAT__,macho64
68         SECTION .text align=%1
69     %elifidn __OUTPUT_FORMAT__,macho
70         SECTION .text align=%1
71         fakegot:
72     %elifidn __OUTPUT_FORMAT__,aout
73         section .text
74     %else
75         SECTION .rodata align=%1
76     %endif
77 %endmacro
78
79 ; aout does not support align=
80 %macro SECTION_TEXT 0-1 16
81     %ifidn __OUTPUT_FORMAT__,aout
82         SECTION .text
83     %else
84         SECTION .text align=%1
85     %endif
86 %endmacro
87
88 %if WIN64
89     %define PIC
90 %elif ARCH_X86_64 == 0
91 ; x86_32 doesn't require PIC.
92 ; Some distros prefer shared objects to be PIC, but nothing breaks if
93 ; the code contains a few textrels, so we'll skip that complexity.
94     %undef PIC
95 %endif
96 %ifdef PIC
97     default rel
98 %endif
99
100 %macro CPUNOP 1
101     %if HAVE_CPUNOP
102         CPU %1
103     %endif
104 %endmacro
105
106 ; Always use long nops (reduces 0x90 spam in disassembly on x86_32)
107 CPUNOP amdnop
108
109 ; Macros to eliminate most code duplication between x86_32 and x86_64:
110 ; Currently this works only for leaf functions which load all their arguments
111 ; into registers at the start, and make no other use of the stack. Luckily that
112 ; covers most of x264's asm.
113
114 ; PROLOGUE:
115 ; %1 = number of arguments. loads them from stack if needed.
116 ; %2 = number of registers used. pushes callee-saved regs if needed.
117 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
118 ; %4 = (optional) stack size to be allocated. If not aligned (x86-32 ICC 10.x,
119 ;      MSVC or YMM), the stack will be manually aligned (to 16 or 32 bytes),
120 ;      and an extra register will be allocated to hold the original stack
121 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
122 ;      register as stack pointer, request a negative stack size.
123 ; %4+/%5+ = list of names to define to registers
124 ; PROLOGUE can also be invoked by adding the same options to cglobal
125
126 ; e.g.
127 ; cglobal foo, 2,3,0, dst, src, tmp
128 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
129
130 ; TODO Some functions can use some args directly from the stack. If they're the
131 ; last args then you can just not declare them, but if they're in the middle
132 ; we need more flexible macro.
133
134 ; RET:
135 ; Pops anything that was pushed by PROLOGUE, and returns.
136
137 ; REP_RET:
138 ; Use this instead of RET if it's a branch target.
139
140 ; registers:
141 ; rN and rNq are the native-size register holding function argument N
142 ; rNd, rNw, rNb are dword, word, and byte size
143 ; rNh is the high 8 bits of the word size
144 ; rNm is the original location of arg N (a register or on the stack), dword
145 ; rNmp is native size
146
147 %macro DECLARE_REG 2-3
148     %define r%1q %2
149     %define r%1d %2d
150     %define r%1w %2w
151     %define r%1b %2b
152     %define r%1h %2h
153     %define %2q %2
154     %if %0 == 2
155         %define r%1m  %2d
156         %define r%1mp %2
157     %elif ARCH_X86_64 ; memory
158         %define r%1m [rstk + stack_offset + %3]
159         %define r%1mp qword r %+ %1 %+ m
160     %else
161         %define r%1m [rstk + stack_offset + %3]
162         %define r%1mp dword r %+ %1 %+ m
163     %endif
164     %define r%1  %2
165 %endmacro
166
167 %macro DECLARE_REG_SIZE 3
168     %define r%1q r%1
169     %define e%1q r%1
170     %define r%1d e%1
171     %define e%1d e%1
172     %define r%1w %1
173     %define e%1w %1
174     %define r%1h %3
175     %define e%1h %3
176     %define r%1b %2
177     %define e%1b %2
178 %if ARCH_X86_64 == 0
179     %define r%1  e%1
180 %endif
181 %endmacro
182
183 DECLARE_REG_SIZE ax, al, ah
184 DECLARE_REG_SIZE bx, bl, bh
185 DECLARE_REG_SIZE cx, cl, ch
186 DECLARE_REG_SIZE dx, dl, dh
187 DECLARE_REG_SIZE si, sil, null
188 DECLARE_REG_SIZE di, dil, null
189 DECLARE_REG_SIZE bp, bpl, null
190
191 ; t# defines for when per-arch register allocation is more complex than just function arguments
192
193 %macro DECLARE_REG_TMP 1-*
194     %assign %%i 0
195     %rep %0
196         CAT_XDEFINE t, %%i, r%1
197         %assign %%i %%i+1
198         %rotate 1
199     %endrep
200 %endmacro
201
202 %macro DECLARE_REG_TMP_SIZE 0-*
203     %rep %0
204         %define t%1q t%1 %+ q
205         %define t%1d t%1 %+ d
206         %define t%1w t%1 %+ w
207         %define t%1h t%1 %+ h
208         %define t%1b t%1 %+ b
209         %rotate 1
210     %endrep
211 %endmacro
212
213 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
214
215 %if ARCH_X86_64
216     %define gprsize 8
217 %else
218     %define gprsize 4
219 %endif
220
221 %macro PUSH 1
222     push %1
223     %ifidn rstk, rsp
224         %assign stack_offset stack_offset+gprsize
225     %endif
226 %endmacro
227
228 %macro POP 1
229     pop %1
230     %ifidn rstk, rsp
231         %assign stack_offset stack_offset-gprsize
232     %endif
233 %endmacro
234
235 %macro PUSH_IF_USED 1-*
236     %rep %0
237         %if %1 < regs_used
238             PUSH r%1
239         %endif
240         %rotate 1
241     %endrep
242 %endmacro
243
244 %macro POP_IF_USED 1-*
245     %rep %0
246         %if %1 < regs_used
247             pop r%1
248         %endif
249         %rotate 1
250     %endrep
251 %endmacro
252
253 %macro LOAD_IF_USED 1-*
254     %rep %0
255         %if %1 < num_args
256             mov r%1, r %+ %1 %+ mp
257         %endif
258         %rotate 1
259     %endrep
260 %endmacro
261
262 %macro SUB 2
263     sub %1, %2
264     %ifidn %1, rstk
265         %assign stack_offset stack_offset+(%2)
266     %endif
267 %endmacro
268
269 %macro ADD 2
270     add %1, %2
271     %ifidn %1, rstk
272         %assign stack_offset stack_offset-(%2)
273     %endif
274 %endmacro
275
276 %macro movifnidn 2
277     %ifnidn %1, %2
278         mov %1, %2
279     %endif
280 %endmacro
281
282 %macro movsxdifnidn 2
283     %ifnidn %1, %2
284         movsxd %1, %2
285     %endif
286 %endmacro
287
288 %macro ASSERT 1
289     %if (%1) == 0
290         %error assert failed
291     %endif
292 %endmacro
293
294 %macro DEFINE_ARGS 0-*
295     %ifdef n_arg_names
296         %assign %%i 0
297         %rep n_arg_names
298             CAT_UNDEF arg_name %+ %%i, q
299             CAT_UNDEF arg_name %+ %%i, d
300             CAT_UNDEF arg_name %+ %%i, w
301             CAT_UNDEF arg_name %+ %%i, h
302             CAT_UNDEF arg_name %+ %%i, b
303             CAT_UNDEF arg_name %+ %%i, m
304             CAT_UNDEF arg_name %+ %%i, mp
305             CAT_UNDEF arg_name, %%i
306             %assign %%i %%i+1
307         %endrep
308     %endif
309
310     %xdefine %%stack_offset stack_offset
311     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
312     %assign %%i 0
313     %rep %0
314         %xdefine %1q r %+ %%i %+ q
315         %xdefine %1d r %+ %%i %+ d
316         %xdefine %1w r %+ %%i %+ w
317         %xdefine %1h r %+ %%i %+ h
318         %xdefine %1b r %+ %%i %+ b
319         %xdefine %1m r %+ %%i %+ m
320         %xdefine %1mp r %+ %%i %+ mp
321         CAT_XDEFINE arg_name, %%i, %1
322         %assign %%i %%i+1
323         %rotate 1
324     %endrep
325     %xdefine stack_offset %%stack_offset
326     %assign n_arg_names %0
327 %endmacro
328
329 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
330     %ifnum %1
331         %if %1 != 0
332             %assign %%stack_alignment ((mmsize + 15) & ~15)
333             %assign stack_size %1
334             %if stack_size < 0
335                 %assign stack_size -stack_size
336             %endif
337             %if mmsize != 8
338                 %assign xmm_regs_used %2
339             %endif
340             %if mmsize <= 16 && HAVE_ALIGNED_STACK
341                 %assign stack_size_padded stack_size + %%stack_alignment - gprsize - (stack_offset & (%%stack_alignment - 1))
342                 %if xmm_regs_used > 6
343                     %assign stack_size_padded stack_size_padded + (xmm_regs_used - 6) * 16
344                 %endif
345                 SUB rsp, stack_size_padded
346             %else
347                 %assign %%reg_num (regs_used - 1)
348                 %xdefine rstk r %+ %%reg_num
349                 ; align stack, and save original stack location directly above
350                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
351                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
352                 ; rsp, [rsp+stack_size_padded])
353                 mov  rstk, rsp
354                 %assign stack_size_padded stack_size
355                 %if xmm_regs_used > 6
356                     %assign stack_size_padded stack_size_padded + (xmm_regs_used - 6) * 16
357                     %if mmsize == 32 && xmm_regs_used & 1
358                         ; re-align to 32 bytes
359                         %assign stack_size_padded (stack_size_padded + 16)
360                     %endif
361                 %endif
362                 %if %1 < 0 ; need to store rsp on stack
363                     sub  rsp, gprsize+stack_size_padded
364                     and  rsp, ~(%%stack_alignment-1)
365                     %xdefine rstkm [rsp+stack_size_padded]
366                     mov rstkm, rstk
367                 %else ; can keep rsp in rstk during whole function
368                     sub  rsp, stack_size_padded
369                     and  rsp, ~(%%stack_alignment-1)
370                     %xdefine rstkm rstk
371                 %endif
372             %endif
373             %if xmm_regs_used > 6
374                 WIN64_PUSH_XMM
375             %endif
376         %endif
377     %endif
378 %endmacro
379
380 %macro SETUP_STACK_POINTER 1
381     %ifnum %1
382         %if %1 != 0 && (HAVE_ALIGNED_STACK == 0 || mmsize == 32)
383             %if %1 > 0
384                 %assign regs_used (regs_used + 1)
385             %elif ARCH_X86_64 && regs_used == num_args && num_args <= 4 + UNIX64 * 2
386                 %warning "Stack pointer will overwrite register argument"
387             %endif
388         %endif
389     %endif
390 %endmacro
391
392 %macro DEFINE_ARGS_INTERNAL 3+
393     %ifnum %2
394         DEFINE_ARGS %3
395     %elif %1 == 4
396         DEFINE_ARGS %2
397     %elif %1 > 4
398         DEFINE_ARGS %2, %3
399     %endif
400 %endmacro
401
402 %if WIN64 ; Windows x64 ;=================================================
403
404 DECLARE_REG 0,  rcx
405 DECLARE_REG 1,  rdx
406 DECLARE_REG 2,  R8
407 DECLARE_REG 3,  R9
408 DECLARE_REG 4,  R10, 40
409 DECLARE_REG 5,  R11, 48
410 DECLARE_REG 6,  rax, 56
411 DECLARE_REG 7,  rdi, 64
412 DECLARE_REG 8,  rsi, 72
413 DECLARE_REG 9,  rbx, 80
414 DECLARE_REG 10, rbp, 88
415 DECLARE_REG 11, R12, 96
416 DECLARE_REG 12, R13, 104
417 DECLARE_REG 13, R14, 112
418 DECLARE_REG 14, R15, 120
419
420 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
421     %assign num_args %1
422     %assign regs_used %2
423     ASSERT regs_used >= num_args
424     SETUP_STACK_POINTER %4
425     ASSERT regs_used <= 15
426     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
427     ALLOC_STACK %4, %3
428     %if mmsize != 8 && stack_size == 0
429         WIN64_SPILL_XMM %3
430     %endif
431     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
432     DEFINE_ARGS_INTERNAL %0, %4, %5
433 %endmacro
434
435 %macro WIN64_PUSH_XMM 0
436     %assign %%i xmm_regs_used
437     %rep (xmm_regs_used-6)
438         %assign %%i %%i-1
439         movdqa [rsp + (%%i-6)*16 + stack_size + (~stack_offset&8)], xmm %+ %%i
440     %endrep
441 %endmacro
442
443 %macro WIN64_SPILL_XMM 1
444     %assign xmm_regs_used %1
445     ASSERT xmm_regs_used <= 16
446     %if xmm_regs_used > 6
447         SUB rsp, (xmm_regs_used-6)*16+16
448         WIN64_PUSH_XMM
449     %endif
450 %endmacro
451
452 %macro WIN64_RESTORE_XMM_INTERNAL 1
453     %if xmm_regs_used > 6
454         %assign %%i xmm_regs_used
455         %rep (xmm_regs_used-6)
456             %assign %%i %%i-1
457             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+stack_size+(~stack_offset&8)]
458         %endrep
459         %if stack_size_padded == 0
460             add %1, (xmm_regs_used-6)*16+16
461         %endif
462     %endif
463     %if stack_size_padded > 0
464         %if stack_size > 0 && (mmsize == 32 || HAVE_ALIGNED_STACK == 0)
465             mov rsp, rstkm
466         %else
467             add %1, stack_size_padded
468         %endif
469     %endif
470 %endmacro
471
472 %macro WIN64_RESTORE_XMM 1
473     WIN64_RESTORE_XMM_INTERNAL %1
474     %assign stack_offset (stack_offset-stack_size_padded)
475     %assign xmm_regs_used 0
476 %endmacro
477
478 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
479
480 %macro RET 0
481     WIN64_RESTORE_XMM_INTERNAL rsp
482     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
483 %if mmsize == 32
484     vzeroupper
485 %endif
486     AUTO_REP_RET
487 %endmacro
488
489 %elif ARCH_X86_64 ; *nix x64 ;=============================================
490
491 DECLARE_REG 0,  rdi
492 DECLARE_REG 1,  rsi
493 DECLARE_REG 2,  rdx
494 DECLARE_REG 3,  rcx
495 DECLARE_REG 4,  R8
496 DECLARE_REG 5,  R9
497 DECLARE_REG 6,  rax, 8
498 DECLARE_REG 7,  R10, 16
499 DECLARE_REG 8,  R11, 24
500 DECLARE_REG 9,  rbx, 32
501 DECLARE_REG 10, rbp, 40
502 DECLARE_REG 11, R12, 48
503 DECLARE_REG 12, R13, 56
504 DECLARE_REG 13, R14, 64
505 DECLARE_REG 14, R15, 72
506
507 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
508     %assign num_args %1
509     %assign regs_used %2
510     ASSERT regs_used >= num_args
511     SETUP_STACK_POINTER %4
512     ASSERT regs_used <= 15
513     PUSH_IF_USED 9, 10, 11, 12, 13, 14
514     ALLOC_STACK %4
515     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
516     DEFINE_ARGS_INTERNAL %0, %4, %5
517 %endmacro
518
519 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
520
521 %macro RET 0
522 %if stack_size_padded > 0
523 %if mmsize == 32 || HAVE_ALIGNED_STACK == 0
524     mov rsp, rstkm
525 %else
526     add rsp, stack_size_padded
527 %endif
528 %endif
529     POP_IF_USED 14, 13, 12, 11, 10, 9
530 %if mmsize == 32
531     vzeroupper
532 %endif
533     AUTO_REP_RET
534 %endmacro
535
536 %else ; X86_32 ;==============================================================
537
538 DECLARE_REG 0, eax, 4
539 DECLARE_REG 1, ecx, 8
540 DECLARE_REG 2, edx, 12
541 DECLARE_REG 3, ebx, 16
542 DECLARE_REG 4, esi, 20
543 DECLARE_REG 5, edi, 24
544 DECLARE_REG 6, ebp, 28
545 %define rsp esp
546
547 %macro DECLARE_ARG 1-*
548     %rep %0
549         %define r%1m [rstk + stack_offset + 4*%1 + 4]
550         %define r%1mp dword r%1m
551         %rotate 1
552     %endrep
553 %endmacro
554
555 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
556
557 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
558     %assign num_args %1
559     %assign regs_used %2
560     ASSERT regs_used >= num_args
561     %if num_args > 7
562         %assign num_args 7
563     %endif
564     %if regs_used > 7
565         %assign regs_used 7
566     %endif
567     SETUP_STACK_POINTER %4
568     ASSERT regs_used <= 7
569     PUSH_IF_USED 3, 4, 5, 6
570     ALLOC_STACK %4
571     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
572     DEFINE_ARGS_INTERNAL %0, %4, %5
573 %endmacro
574
575 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
576
577 %macro RET 0
578 %if stack_size_padded > 0
579 %if mmsize == 32 || HAVE_ALIGNED_STACK == 0
580     mov rsp, rstkm
581 %else
582     add rsp, stack_size_padded
583 %endif
584 %endif
585     POP_IF_USED 6, 5, 4, 3
586 %if mmsize == 32
587     vzeroupper
588 %endif
589     AUTO_REP_RET
590 %endmacro
591
592 %endif ;======================================================================
593
594 %if WIN64 == 0
595 %macro WIN64_SPILL_XMM 1
596 %endmacro
597 %macro WIN64_RESTORE_XMM 1
598 %endmacro
599 %macro WIN64_PUSH_XMM 0
600 %endmacro
601 %endif
602
603 ; On AMD cpus <=K10, an ordinary ret is slow if it immediately follows either
604 ; a branch or a branch target. So switch to a 2-byte form of ret in that case.
605 ; We can automatically detect "follows a branch", but not a branch target.
606 ; (SSSE3 is a sufficient condition to know that your cpu doesn't have this problem.)
607 %macro REP_RET 0
608     %if has_epilogue
609         RET
610     %else
611         rep ret
612     %endif
613 %endmacro
614
615 %define last_branch_adr $$
616 %macro AUTO_REP_RET 0
617     %ifndef cpuflags
618         times ((last_branch_adr-$)>>31)+1 rep ; times 1 iff $ != last_branch_adr.
619     %elif notcpuflag(ssse3)
620         times ((last_branch_adr-$)>>31)+1 rep
621     %endif
622     ret
623 %endmacro
624
625 %macro BRANCH_INSTR 0-*
626     %rep %0
627         %macro %1 1-2 %1
628             %2 %1
629             %%branch_instr:
630             %xdefine last_branch_adr %%branch_instr
631         %endmacro
632         %rotate 1
633     %endrep
634 %endmacro
635
636 BRANCH_INSTR jz, je, jnz, jne, jl, jle, jnl, jnle, jg, jge, jng, jnge, ja, jae, jna, jnae, jb, jbe, jnb, jnbe, jc, jnc, js, jns, jo, jno, jp, jnp
637
638 %macro TAIL_CALL 2 ; callee, is_nonadjacent
639     %if has_epilogue
640         call %1
641         RET
642     %elif %2
643         jmp %1
644     %endif
645 %endmacro
646
647 ;=============================================================================
648 ; arch-independent part
649 ;=============================================================================
650
651 %assign function_align 16
652
653 ; Begin a function.
654 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
655 ; subsequent uses of the function name automatically refer to the mangled version.
656 ; Appends cpuflags to the function name if cpuflags has been specified.
657 ; The "" empty default parameter is a workaround for nasm, which fails if SUFFIX
658 ; is empty and we call cglobal_internal with just %1 %+ SUFFIX (without %2).
659 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
660     cglobal_internal 1, %1 %+ SUFFIX, %2
661 %endmacro
662 %macro cvisible 1-2+ "" ; name, [PROLOGUE args]
663     cglobal_internal 0, %1 %+ SUFFIX, %2
664 %endmacro
665 %macro cglobal_internal 2-3+
666     %if %1
667         %xdefine %%FUNCTION_PREFIX private_prefix
668         %xdefine %%VISIBILITY hidden
669     %else
670         %xdefine %%FUNCTION_PREFIX public_prefix
671         %xdefine %%VISIBILITY
672     %endif
673     %ifndef cglobaled_%2
674         %xdefine %2 mangle(%%FUNCTION_PREFIX %+ _ %+ %2)
675         %xdefine %2.skip_prologue %2 %+ .skip_prologue
676         CAT_XDEFINE cglobaled_, %2, 1
677     %endif
678     %xdefine current_function %2
679     %ifidn __OUTPUT_FORMAT__,elf
680         global %2:function %%VISIBILITY
681     %else
682         global %2
683     %endif
684     align function_align
685     %2:
686     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
687     %xdefine rstk rsp
688     %assign stack_offset 0
689     %assign stack_size 0
690     %assign stack_size_padded 0
691     %assign xmm_regs_used 0
692     %ifnidn %3, ""
693         PROLOGUE %3
694     %endif
695 %endmacro
696
697 %macro cextern 1
698     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
699     CAT_XDEFINE cglobaled_, %1, 1
700     extern %1
701 %endmacro
702
703 ; like cextern, but without the prefix
704 %macro cextern_naked 1
705     %xdefine %1 mangle(%1)
706     CAT_XDEFINE cglobaled_, %1, 1
707     extern %1
708 %endmacro
709
710 %macro const 2+
711     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
712     global %1
713     %1: %2
714 %endmacro
715
716 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
717 ; executable by default.
718 %ifidn __OUTPUT_FORMAT__,elf
719 SECTION .note.GNU-stack noalloc noexec nowrite progbits
720 %endif
721
722 ; cpuflags
723
724 %assign cpuflags_mmx      (1<<0)
725 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
726 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
727 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
728 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
729 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
730 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
731 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
732 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
733 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
734 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
735 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
736 %assign cpuflags_xop      (1<<12)| cpuflags_avx
737 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
738 %assign cpuflags_avx2     (1<<14)| cpuflags_avx
739 %assign cpuflags_fma3     (1<<15)| cpuflags_avx
740
741 %assign cpuflags_cache32  (1<<16)
742 %assign cpuflags_cache64  (1<<17)
743 %assign cpuflags_slowctz  (1<<18)
744 %assign cpuflags_lzcnt    (1<<19)
745 %assign cpuflags_misalign (1<<20)
746 %assign cpuflags_aligned  (1<<21) ; not a cpu feature, but a function variant
747 %assign cpuflags_atom     (1<<22)
748 %assign cpuflags_bmi1     (1<<23)
749 %assign cpuflags_bmi2     (1<<24)|cpuflags_bmi1
750 %assign cpuflags_tbm      (1<<25)|cpuflags_bmi1
751
752 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
753 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
754
755 ; Takes up to 2 cpuflags from the above list.
756 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
757 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
758 %macro INIT_CPUFLAGS 0-2
759     CPUNOP amdnop
760     %if %0 >= 1
761         %xdefine cpuname %1
762         %assign cpuflags cpuflags_%1
763         %if %0 >= 2
764             %xdefine cpuname %1_%2
765             %assign cpuflags cpuflags | cpuflags_%2
766         %endif
767         %xdefine SUFFIX _ %+ cpuname
768         %if cpuflag(avx)
769             %assign avx_enabled 1
770         %endif
771         %if mmsize == 16 && notcpuflag(sse2)
772             %define mova movaps
773             %define movu movups
774             %define movnta movntps
775         %endif
776         %if cpuflag(aligned)
777             %define movu mova
778         %elifidn %1, sse3
779             %define movu lddqu
780         %endif
781         %if notcpuflag(sse2)
782             CPUNOP basicnop
783         %endif
784     %else
785         %xdefine SUFFIX
786         %undef cpuname
787         %undef cpuflags
788     %endif
789 %endmacro
790
791 ; merge mmx and sse*
792
793 %macro CAT_XDEFINE 3
794     %xdefine %1%2 %3
795 %endmacro
796
797 %macro CAT_UNDEF 2
798     %undef %1%2
799 %endmacro
800
801 %macro INIT_MMX 0-1+
802     %assign avx_enabled 0
803     %define RESET_MM_PERMUTATION INIT_MMX %1
804     %define mmsize 8
805     %define num_mmregs 8
806     %define mova movq
807     %define movu movq
808     %define movh movd
809     %define movnta movntq
810     %assign %%i 0
811     %rep 8
812     CAT_XDEFINE m, %%i, mm %+ %%i
813     CAT_XDEFINE nmm, %%i, %%i
814     %assign %%i %%i+1
815     %endrep
816     %rep 8
817     CAT_UNDEF m, %%i
818     CAT_UNDEF nmm, %%i
819     %assign %%i %%i+1
820     %endrep
821     INIT_CPUFLAGS %1
822 %endmacro
823
824 %macro INIT_XMM 0-1+
825     %assign avx_enabled 0
826     %define RESET_MM_PERMUTATION INIT_XMM %1
827     %define mmsize 16
828     %define num_mmregs 8
829     %if ARCH_X86_64
830     %define num_mmregs 16
831     %endif
832     %define mova movdqa
833     %define movu movdqu
834     %define movh movq
835     %define movnta movntdq
836     %assign %%i 0
837     %rep num_mmregs
838     CAT_XDEFINE m, %%i, xmm %+ %%i
839     CAT_XDEFINE nxmm, %%i, %%i
840     %assign %%i %%i+1
841     %endrep
842     INIT_CPUFLAGS %1
843 %endmacro
844
845 %macro INIT_YMM 0-1+
846     %assign avx_enabled 1
847     %define RESET_MM_PERMUTATION INIT_YMM %1
848     %define mmsize 32
849     %define num_mmregs 8
850     %if ARCH_X86_64
851     %define num_mmregs 16
852     %endif
853     %define mova vmovaps
854     %define movu vmovups
855     %undef movh
856     %define movnta vmovntps
857     %assign %%i 0
858     %rep num_mmregs
859     CAT_XDEFINE m, %%i, ymm %+ %%i
860     CAT_XDEFINE nymm, %%i, %%i
861     %assign %%i %%i+1
862     %endrep
863     INIT_CPUFLAGS %1
864 %endmacro
865
866 INIT_XMM
867
868 ; I often want to use macros that permute their arguments. e.g. there's no
869 ; efficient way to implement butterfly or transpose or dct without swapping some
870 ; arguments.
871 ;
872 ; I would like to not have to manually keep track of the permutations:
873 ; If I insert a permutation in the middle of a function, it should automatically
874 ; change everything that follows. For more complex macros I may also have multiple
875 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
876 ;
877 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
878 ; permutes its arguments. It's equivalent to exchanging the contents of the
879 ; registers, except that this way you exchange the register names instead, so it
880 ; doesn't cost any cycles.
881
882 %macro PERMUTE 2-* ; takes a list of pairs to swap
883 %rep %0/2
884     %xdefine tmp%2 m%2
885     %xdefine ntmp%2 nm%2
886     %rotate 2
887 %endrep
888 %rep %0/2
889     %xdefine m%1 tmp%2
890     %xdefine nm%1 ntmp%2
891     %undef tmp%2
892     %undef ntmp%2
893     %rotate 2
894 %endrep
895 %endmacro
896
897 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
898 %rep %0-1
899 %ifdef m%1
900     %xdefine tmp m%1
901     %xdefine m%1 m%2
902     %xdefine m%2 tmp
903     CAT_XDEFINE n, m%1, %1
904     CAT_XDEFINE n, m%2, %2
905 %else
906     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
907     ; Be careful using this mode in nested macros though, as in some cases there may be
908     ; other copies of m# that have already been dereferenced and don't get updated correctly.
909     %xdefine %%n1 n %+ %1
910     %xdefine %%n2 n %+ %2
911     %xdefine tmp m %+ %%n1
912     CAT_XDEFINE m, %%n1, m %+ %%n2
913     CAT_XDEFINE m, %%n2, tmp
914     CAT_XDEFINE n, m %+ %%n1, %%n1
915     CAT_XDEFINE n, m %+ %%n2, %%n2
916 %endif
917     %undef tmp
918     %rotate 1
919 %endrep
920 %endmacro
921
922 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
923 ; calls to that function will automatically load the permutation, so values can
924 ; be returned in mmregs.
925 %macro SAVE_MM_PERMUTATION 0-1
926     %if %0
927         %xdefine %%f %1_m
928     %else
929         %xdefine %%f current_function %+ _m
930     %endif
931     %assign %%i 0
932     %rep num_mmregs
933         CAT_XDEFINE %%f, %%i, m %+ %%i
934     %assign %%i %%i+1
935     %endrep
936 %endmacro
937
938 %macro LOAD_MM_PERMUTATION 1 ; name to load from
939     %ifdef %1_m0
940         %assign %%i 0
941         %rep num_mmregs
942             CAT_XDEFINE m, %%i, %1_m %+ %%i
943             CAT_XDEFINE n, m %+ %%i, %%i
944         %assign %%i %%i+1
945         %endrep
946     %endif
947 %endmacro
948
949 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
950 %macro call 1
951     call_internal %1 %+ SUFFIX, %1
952 %endmacro
953 %macro call_internal 2
954     %xdefine %%i %2
955     %ifndef cglobaled_%2
956         %ifdef cglobaled_%1
957             %xdefine %%i %1
958         %endif
959     %endif
960     call %%i
961     LOAD_MM_PERMUTATION %%i
962 %endmacro
963
964 ; Substitutions that reduce instruction size but are functionally equivalent
965 %macro add 2
966     %ifnum %2
967         %if %2==128
968             sub %1, -128
969         %else
970             add %1, %2
971         %endif
972     %else
973         add %1, %2
974     %endif
975 %endmacro
976
977 %macro sub 2
978     %ifnum %2
979         %if %2==128
980             add %1, -128
981         %else
982             sub %1, %2
983         %endif
984     %else
985         sub %1, %2
986     %endif
987 %endmacro
988
989 ;=============================================================================
990 ; AVX abstraction layer
991 ;=============================================================================
992
993 %assign i 0
994 %rep 16
995     %if i < 8
996         CAT_XDEFINE sizeofmm, i, 8
997     %endif
998     CAT_XDEFINE sizeofxmm, i, 16
999     CAT_XDEFINE sizeofymm, i, 32
1000 %assign i i+1
1001 %endrep
1002 %undef i
1003
1004 %macro CHECK_AVX_INSTR_EMU 3-*
1005     %xdefine %%opcode %1
1006     %xdefine %%dst %2
1007     %rep %0-2
1008         %ifidn %%dst, %3
1009             %error non-avx emulation of ``%%opcode'' is not supported
1010         %endif
1011         %rotate 1
1012     %endrep
1013 %endmacro
1014
1015 ;%1 == instruction
1016 ;%2 == 1 if float, 0 if int
1017 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
1018 ;%4 == number of operands given
1019 ;%5+: operands
1020 %macro RUN_AVX_INSTR 6-7+
1021     %ifid %6
1022         %define %%sizeofreg sizeof%6
1023     %elifid %5
1024         %define %%sizeofreg sizeof%5
1025     %else
1026         %define %%sizeofreg mmsize
1027     %endif
1028     %if %%sizeofreg==32
1029         %if %4>=3
1030             v%1 %5, %6, %7
1031         %else
1032             v%1 %5, %6
1033         %endif
1034     %else
1035         %if %%sizeofreg==8
1036             %define %%regmov movq
1037         %elif %2
1038             %define %%regmov movaps
1039         %else
1040             %define %%regmov movdqa
1041         %endif
1042
1043         %if %4>=3+%3
1044             %ifnidn %5, %6
1045                 %if avx_enabled && %%sizeofreg==16
1046                     v%1 %5, %6, %7
1047                 %else
1048                     CHECK_AVX_INSTR_EMU {%1 %5, %6, %7}, %5, %7
1049                     %%regmov %5, %6
1050                     %1 %5, %7
1051                 %endif
1052             %else
1053                 %1 %5, %7
1054             %endif
1055         %elif %4>=3
1056             %1 %5, %6, %7
1057         %else
1058             %1 %5, %6
1059         %endif
1060     %endif
1061 %endmacro
1062
1063 ; 3arg AVX ops with a memory arg can only have it in src2,
1064 ; whereas SSE emulation of 3arg prefers to have it in src1 (i.e. the mov).
1065 ; So, if the op is symmetric and the wrong one is memory, swap them.
1066 %macro RUN_AVX_INSTR1 8
1067     %assign %%swap 0
1068     %if avx_enabled
1069         %ifnid %6
1070             %assign %%swap 1
1071         %endif
1072     %elifnidn %5, %6
1073         %ifnid %7
1074             %assign %%swap 1
1075         %endif
1076     %endif
1077     %if %%swap && %3 == 0 && %8 == 1
1078         RUN_AVX_INSTR %1, %2, %3, %4, %5, %7, %6
1079     %else
1080         RUN_AVX_INSTR %1, %2, %3, %4, %5, %6, %7
1081     %endif
1082 %endmacro
1083
1084 ;%1 == instruction
1085 ;%2 == 1 if float, 0 if int
1086 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
1087 ;%4 == 1 if symmetric (i.e. doesn't matter which src arg is which), 0 if not
1088 %macro AVX_INSTR 4
1089     %macro %1 2-9 fnord, fnord, fnord, %1, %2, %3, %4
1090         %ifidn %3, fnord
1091             RUN_AVX_INSTR %6, %7, %8, 2, %1, %2
1092         %elifidn %4, fnord
1093             RUN_AVX_INSTR1 %6, %7, %8, 3, %1, %2, %3, %9
1094         %elifidn %5, fnord
1095             RUN_AVX_INSTR %6, %7, %8, 4, %1, %2, %3, %4
1096         %else
1097             RUN_AVX_INSTR %6, %7, %8, 5, %1, %2, %3, %4, %5
1098         %endif
1099     %endmacro
1100 %endmacro
1101
1102 AVX_INSTR addpd, 1, 0, 1
1103 AVX_INSTR addps, 1, 0, 1
1104 AVX_INSTR addsd, 1, 0, 1
1105 AVX_INSTR addss, 1, 0, 1
1106 AVX_INSTR addsubpd, 1, 0, 0
1107 AVX_INSTR addsubps, 1, 0, 0
1108 AVX_INSTR andpd, 1, 0, 1
1109 AVX_INSTR andps, 1, 0, 1
1110 AVX_INSTR andnpd, 1, 0, 0
1111 AVX_INSTR andnps, 1, 0, 0
1112 AVX_INSTR blendpd, 1, 0, 0
1113 AVX_INSTR blendps, 1, 0, 0
1114 AVX_INSTR blendvpd, 1, 0, 0
1115 AVX_INSTR blendvps, 1, 0, 0
1116 AVX_INSTR cmppd, 1, 1, 0
1117 AVX_INSTR cmpps, 1, 1, 0
1118 AVX_INSTR cmpsd, 1, 1, 0
1119 AVX_INSTR cmpss, 1, 1, 0
1120 AVX_INSTR cvtdq2ps, 1, 0, 0
1121 AVX_INSTR cvtpd2dq, 1, 0, 0
1122 AVX_INSTR cvtps2dq, 1, 0, 0
1123 AVX_INSTR divpd, 1, 0, 0
1124 AVX_INSTR divps, 1, 0, 0
1125 AVX_INSTR divsd, 1, 0, 0
1126 AVX_INSTR divss, 1, 0, 0
1127 AVX_INSTR dppd, 1, 1, 0
1128 AVX_INSTR dpps, 1, 1, 0
1129 AVX_INSTR haddpd, 1, 0, 0
1130 AVX_INSTR haddps, 1, 0, 0
1131 AVX_INSTR hsubpd, 1, 0, 0
1132 AVX_INSTR hsubps, 1, 0, 0
1133 AVX_INSTR maxpd, 1, 0, 1
1134 AVX_INSTR maxps, 1, 0, 1
1135 AVX_INSTR maxsd, 1, 0, 1
1136 AVX_INSTR maxss, 1, 0, 1
1137 AVX_INSTR minpd, 1, 0, 1
1138 AVX_INSTR minps, 1, 0, 1
1139 AVX_INSTR minsd, 1, 0, 1
1140 AVX_INSTR minss, 1, 0, 1
1141 AVX_INSTR movhlps, 1, 0, 0
1142 AVX_INSTR movlhps, 1, 0, 0
1143 AVX_INSTR movsd, 1, 0, 0
1144 AVX_INSTR movss, 1, 0, 0
1145 AVX_INSTR mpsadbw, 0, 1, 0
1146 AVX_INSTR mulpd, 1, 0, 1
1147 AVX_INSTR mulps, 1, 0, 1
1148 AVX_INSTR mulsd, 1, 0, 1
1149 AVX_INSTR mulss, 1, 0, 1
1150 AVX_INSTR orpd, 1, 0, 1
1151 AVX_INSTR orps, 1, 0, 1
1152 AVX_INSTR pabsb, 0, 0, 0
1153 AVX_INSTR pabsw, 0, 0, 0
1154 AVX_INSTR pabsd, 0, 0, 0
1155 AVX_INSTR packsswb, 0, 0, 0
1156 AVX_INSTR packssdw, 0, 0, 0
1157 AVX_INSTR packuswb, 0, 0, 0
1158 AVX_INSTR packusdw, 0, 0, 0
1159 AVX_INSTR paddb, 0, 0, 1
1160 AVX_INSTR paddw, 0, 0, 1
1161 AVX_INSTR paddd, 0, 0, 1
1162 AVX_INSTR paddq, 0, 0, 1
1163 AVX_INSTR paddsb, 0, 0, 1
1164 AVX_INSTR paddsw, 0, 0, 1
1165 AVX_INSTR paddusb, 0, 0, 1
1166 AVX_INSTR paddusw, 0, 0, 1
1167 AVX_INSTR palignr, 0, 1, 0
1168 AVX_INSTR pand, 0, 0, 1
1169 AVX_INSTR pandn, 0, 0, 0
1170 AVX_INSTR pavgb, 0, 0, 1
1171 AVX_INSTR pavgw, 0, 0, 1
1172 AVX_INSTR pblendvb, 0, 0, 0
1173 AVX_INSTR pblendw, 0, 1, 0
1174 AVX_INSTR pcmpestri, 0, 0, 0
1175 AVX_INSTR pcmpestrm, 0, 0, 0
1176 AVX_INSTR pcmpistri, 0, 0, 0
1177 AVX_INSTR pcmpistrm, 0, 0, 0
1178 AVX_INSTR pcmpeqb, 0, 0, 1
1179 AVX_INSTR pcmpeqw, 0, 0, 1
1180 AVX_INSTR pcmpeqd, 0, 0, 1
1181 AVX_INSTR pcmpeqq, 0, 0, 1
1182 AVX_INSTR pcmpgtb, 0, 0, 0
1183 AVX_INSTR pcmpgtw, 0, 0, 0
1184 AVX_INSTR pcmpgtd, 0, 0, 0
1185 AVX_INSTR pcmpgtq, 0, 0, 0
1186 AVX_INSTR phaddw, 0, 0, 0
1187 AVX_INSTR phaddd, 0, 0, 0
1188 AVX_INSTR phaddsw, 0, 0, 0
1189 AVX_INSTR phsubw, 0, 0, 0
1190 AVX_INSTR phsubd, 0, 0, 0
1191 AVX_INSTR phsubsw, 0, 0, 0
1192 AVX_INSTR pmaddwd, 0, 0, 1
1193 AVX_INSTR pmaddubsw, 0, 0, 0
1194 AVX_INSTR pmaxsb, 0, 0, 1
1195 AVX_INSTR pmaxsw, 0, 0, 1
1196 AVX_INSTR pmaxsd, 0, 0, 1
1197 AVX_INSTR pmaxub, 0, 0, 1
1198 AVX_INSTR pmaxuw, 0, 0, 1
1199 AVX_INSTR pmaxud, 0, 0, 1
1200 AVX_INSTR pminsb, 0, 0, 1
1201 AVX_INSTR pminsw, 0, 0, 1
1202 AVX_INSTR pminsd, 0, 0, 1
1203 AVX_INSTR pminub, 0, 0, 1
1204 AVX_INSTR pminuw, 0, 0, 1
1205 AVX_INSTR pminud, 0, 0, 1
1206 AVX_INSTR pmovmskb, 0, 0, 0
1207 AVX_INSTR pmulhuw, 0, 0, 1
1208 AVX_INSTR pmulhrsw, 0, 0, 1
1209 AVX_INSTR pmulhw, 0, 0, 1
1210 AVX_INSTR pmullw, 0, 0, 1
1211 AVX_INSTR pmulld, 0, 0, 1
1212 AVX_INSTR pmuludq, 0, 0, 1
1213 AVX_INSTR pmuldq, 0, 0, 1
1214 AVX_INSTR por, 0, 0, 1
1215 AVX_INSTR psadbw, 0, 0, 1
1216 AVX_INSTR pshufb, 0, 0, 0
1217 AVX_INSTR pshufd, 0, 1, 0
1218 AVX_INSTR pshufhw, 0, 1, 0
1219 AVX_INSTR pshuflw, 0, 1, 0
1220 AVX_INSTR psignb, 0, 0, 0
1221 AVX_INSTR psignw, 0, 0, 0
1222 AVX_INSTR psignd, 0, 0, 0
1223 AVX_INSTR psllw, 0, 0, 0
1224 AVX_INSTR pslld, 0, 0, 0
1225 AVX_INSTR psllq, 0, 0, 0
1226 AVX_INSTR pslldq, 0, 0, 0
1227 AVX_INSTR psraw, 0, 0, 0
1228 AVX_INSTR psrad, 0, 0, 0
1229 AVX_INSTR psrlw, 0, 0, 0
1230 AVX_INSTR psrld, 0, 0, 0
1231 AVX_INSTR psrlq, 0, 0, 0
1232 AVX_INSTR psrldq, 0, 0, 0
1233 AVX_INSTR psubb, 0, 0, 0
1234 AVX_INSTR psubw, 0, 0, 0
1235 AVX_INSTR psubd, 0, 0, 0
1236 AVX_INSTR psubq, 0, 0, 0
1237 AVX_INSTR psubsb, 0, 0, 0
1238 AVX_INSTR psubsw, 0, 0, 0
1239 AVX_INSTR psubusb, 0, 0, 0
1240 AVX_INSTR psubusw, 0, 0, 0
1241 AVX_INSTR ptest, 0, 0, 0
1242 AVX_INSTR punpckhbw, 0, 0, 0
1243 AVX_INSTR punpckhwd, 0, 0, 0
1244 AVX_INSTR punpckhdq, 0, 0, 0
1245 AVX_INSTR punpckhqdq, 0, 0, 0
1246 AVX_INSTR punpcklbw, 0, 0, 0
1247 AVX_INSTR punpcklwd, 0, 0, 0
1248 AVX_INSTR punpckldq, 0, 0, 0
1249 AVX_INSTR punpcklqdq, 0, 0, 0
1250 AVX_INSTR pxor, 0, 0, 1
1251 AVX_INSTR shufps, 1, 1, 0
1252 AVX_INSTR subpd, 1, 0, 0
1253 AVX_INSTR subps, 1, 0, 0
1254 AVX_INSTR subsd, 1, 0, 0
1255 AVX_INSTR subss, 1, 0, 0
1256 AVX_INSTR unpckhpd, 1, 0, 0
1257 AVX_INSTR unpckhps, 1, 0, 0
1258 AVX_INSTR unpcklpd, 1, 0, 0
1259 AVX_INSTR unpcklps, 1, 0, 0
1260 AVX_INSTR xorpd, 1, 0, 1
1261 AVX_INSTR xorps, 1, 0, 1
1262
1263 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1264 AVX_INSTR pfadd, 1, 0, 1
1265 AVX_INSTR pfsub, 1, 0, 0
1266 AVX_INSTR pfmul, 1, 0, 1
1267
1268 ; base-4 constants for shuffles
1269 %assign i 0
1270 %rep 256
1271     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1272     %if j < 10
1273         CAT_XDEFINE q000, j, i
1274     %elif j < 100
1275         CAT_XDEFINE q00, j, i
1276     %elif j < 1000
1277         CAT_XDEFINE q0, j, i
1278     %else
1279         CAT_XDEFINE q, j, i
1280     %endif
1281 %assign i i+1
1282 %endrep
1283 %undef i
1284 %undef j
1285
1286 %macro FMA_INSTR 3
1287     %macro %1 5-8 %1, %2, %3
1288         %if cpuflag(xop) || cpuflag(fma4)
1289             v%6 %1, %2, %3, %4
1290         %else
1291             %ifidn %1, %4
1292                 %7 %5, %2, %3
1293                 %8 %1, %4, %5
1294             %else
1295                 %7 %1, %2, %3
1296                 %8 %1, %4
1297             %endif
1298         %endif
1299     %endmacro
1300 %endmacro
1301
1302 FMA_INSTR  fmaddps,   mulps, addps
1303 FMA_INSTR  pmacsdd,  pmulld, paddd
1304 FMA_INSTR  pmacsww,  pmullw, paddw
1305 FMA_INSTR pmadcswd, pmaddwd, paddd
1306
1307 ; tzcnt is equivalent to "rep bsf" and is backwards-compatible with bsf.
1308 ; This lets us use tzcnt without bumping the yasm version requirement yet.
1309 %define tzcnt rep bsf