x86inc: automatically insert vzeroupper for YMM functions.
[ffmpeg.git] / libavutil / x86 / float_dsp.asm
1 ;*****************************************************************************
2 ;* x86-optimized Float DSP functions
3 ;*
4 ;* This file is part of Libav.
5 ;*
6 ;* Libav is free software; you can redistribute it and/or
7 ;* modify it under the terms of the GNU Lesser General Public
8 ;* License as published by the Free Software Foundation; either
9 ;* version 2.1 of the License, or (at your option) any later version.
10 ;*
11 ;* Libav is distributed in the hope that it will be useful,
12 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14 ;* Lesser General Public License for more details.
15 ;*
16 ;* You should have received a copy of the GNU Lesser General Public
17 ;* License along with Libav; if not, write to the Free Software
18 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
19 ;******************************************************************************
20
21 %include "x86inc.asm"
22 %include "x86util.asm"
23
24 SECTION .text
25
26 ;-----------------------------------------------------------------------------
27 ; void vector_fmul(float *dst, const float *src0, const float *src1, int len)
28 ;-----------------------------------------------------------------------------
29 %macro VECTOR_FMUL 0
30 cglobal vector_fmul, 4,4,2, dst, src0, src1, len
31     lea       lenq, [lend*4 - 2*mmsize]
32 ALIGN 16
33 .loop
34     mova      m0,   [src0q + lenq]
35     mova      m1,   [src0q + lenq + mmsize]
36     mulps     m0, m0, [src1q + lenq]
37     mulps     m1, m1, [src1q + lenq + mmsize]
38     mova      [dstq + lenq], m0
39     mova      [dstq + lenq + mmsize], m1
40
41     sub       lenq, 2*mmsize
42     jge       .loop
43     REP_RET
44 %endmacro
45
46 INIT_XMM sse
47 VECTOR_FMUL
48 %if HAVE_AVX
49 INIT_YMM avx
50 VECTOR_FMUL
51 %endif
52
53 ;------------------------------------------------------------------------------
54 ; void ff_vector_fmac_scalar(float *dst, const float *src, float mul, int len)
55 ;------------------------------------------------------------------------------
56
57 %macro VECTOR_FMAC_SCALAR 0
58 %if UNIX64
59 cglobal vector_fmac_scalar, 3,3,3, dst, src, len
60 %else
61 cglobal vector_fmac_scalar, 4,4,3, dst, src, mul, len
62 %endif
63 %if WIN64
64     SWAP 0, 2
65 %endif
66 %if ARCH_X86_32
67     VBROADCASTSS m0, mulm
68 %else
69     shufps     xmm0, xmm0, 0
70 %if cpuflag(avx)
71     vinsertf128  m0, m0, xmm0, 1
72 %endif
73 %endif
74     lea    lenq, [lend*4-2*mmsize]
75 .loop
76     mulps    m1, m0, [srcq+lenq       ]
77     mulps    m2, m0, [srcq+lenq+mmsize]
78     addps    m1, m1, [dstq+lenq       ]
79     addps    m2, m2, [dstq+lenq+mmsize]
80     mova  [dstq+lenq       ], m1
81     mova  [dstq+lenq+mmsize], m2
82     sub    lenq, 2*mmsize
83     jge .loop
84     REP_RET
85 %endmacro
86
87 INIT_XMM sse
88 VECTOR_FMAC_SCALAR
89 %if HAVE_AVX
90 INIT_YMM avx
91 VECTOR_FMAC_SCALAR
92 %endif