ARM: fix Thumb PIC on Apple
[ffmpeg.git] / libavutil / arm / asm.S
1 /*
2  * Copyright (c) 2008 Mans Rullgard <mans@mansr.com>
3  *
4  * This file is part of Libav.
5  *
6  * Libav is free software; you can redistribute it and/or
7  * modify it under the terms of the GNU Lesser General Public
8  * License as published by the Free Software Foundation; either
9  * version 2.1 of the License, or (at your option) any later version.
10  *
11  * Libav is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14  * Lesser General Public License for more details.
15  *
16  * You should have received a copy of the GNU Lesser General Public
17  * License along with Libav; if not, write to the Free Software
18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
19  */
20
21 #include "config.h"
22
23 #ifdef __ELF__
24 #   define ELF
25 #else
26 #   define ELF @
27 #endif
28
29 #if CONFIG_THUMB
30 #   define A @
31 #   define T
32 #else
33 #   define A
34 #   define T @
35 #endif
36
37 #if   HAVE_NEON
38         .arch           armv7-a
39 #elif HAVE_ARMV6T2
40         .arch           armv6t2
41 #elif HAVE_ARMV6
42         .arch           armv6
43 #elif HAVE_ARMV5TE
44         .arch           armv5te
45 #endif
46
47 #if   HAVE_NEON
48         .fpu            neon
49 #elif HAVE_ARMVFP
50         .fpu            vfp
51 #endif
52
53         .syntax unified
54 T       .thumb
55
56 .macro  require8 val=1
57 ELF     .eabi_attribute 24, \val
58 .endm
59
60 .macro  preserve8 val=1
61 ELF     .eabi_attribute 25, \val
62 .endm
63
64 .macro  function name, export=0
65         .set            .Lpic_idx, 0
66         .set            .Lpic_gp, 0
67     .macro endfunc
68       .if .Lpic_idx
69         .align          2
70         .altmacro
71         put_pic         %(.Lpic_idx - 1)
72         .noaltmacro
73       .endif
74 ELF     .size   \name, . - \name
75         .endfunc
76         .purgem endfunc
77     .endm
78         .text
79         .align          2
80     .if \export
81         .global EXTERN_ASM\name
82 EXTERN_ASM\name:
83     .endif
84 ELF     .type   \name, %function
85         .func   \name
86 \name:
87 .endm
88
89 .macro  const   name, align=2
90     .macro endconst
91 ELF     .size   \name, . - \name
92         .purgem endconst
93     .endm
94         .section        .rodata
95         .align          \align
96 \name:
97 .endm
98
99 #if !HAVE_ARMV6T2
100 .macro  movw    rd, val
101         mov     \rd, \val &  255
102         orr     \rd, \val & ~255
103 .endm
104 #endif
105
106 .macro  mov32   rd, val
107 #if HAVE_ARMV6T2
108         movw            \rd, #(\val) & 0xffff
109     .if (\val) >> 16
110         movt            \rd, #(\val) >> 16
111     .endif
112 #else
113         ldr             \rd, =\val
114 #endif
115 .endm
116
117 .macro  put_pic         num
118         put_pic_\num
119 .endm
120
121 .macro  do_def_pic      num, val, label
122     .macro put_pic_\num
123       .if \num
124         .altmacro
125         put_pic         %(\num - 1)
126         .noaltmacro
127       .endif
128 \label: .word           \val
129         .purgem         put_pic_\num
130     .endm
131 .endm
132
133 .macro  def_pic         val, label
134         .altmacro
135         do_def_pic      %.Lpic_idx, \val, \label
136         .noaltmacro
137         .set            .Lpic_idx, .Lpic_idx + 1
138 .endm
139
140 .macro  ldpic           rd,  val, indir=0
141         ldr             \rd, .Lpicoff\@
142 .Lpic\@:
143     .if \indir
144 A       ldr             \rd, [pc, \rd]
145 T       add             \rd, pc
146 T       ldr             \rd, [\rd]
147     .else
148         add             \rd, pc
149     .endif
150         def_pic         \val - (.Lpic\@ + (8 >> CONFIG_THUMB)), .Lpicoff\@
151 .endm
152
153 .macro  movrel rd, val
154 #if CONFIG_PIC
155         ldpic           \rd, \val
156 #elif HAVE_ARMV6T2 && !defined(__APPLE__)
157         movw            \rd, #:lower16:\val
158         movt            \rd, #:upper16:\val
159 #else
160         ldr             \rd, =\val
161 #endif
162 .endm
163
164 .macro  movrelx         rd,  val, gp
165 #if CONFIG_PIC && defined(__ELF__)
166     .ifnb \gp
167       .if .Lpic_gp
168         .unreq          gp
169       .endif
170         gp      .req    \gp
171         ldpic           gp,  _GLOBAL_OFFSET_TABLE_
172     .elseif !.Lpic_gp
173         gp      .req    r12
174         ldpic           gp,  _GLOBAL_OFFSET_TABLE_
175     .endif
176         .set            .Lpic_gp, 1
177         ldr             \rd, .Lpicoff\@
178         ldr             \rd, [gp, \rd]
179         def_pic         \val(GOT), .Lpicoff\@
180 #elif CONFIG_PIC && defined(__APPLE__)
181         ldpic           \rd, .Lpic\@, indir=1
182         .non_lazy_symbol_pointer
183 .Lpic\@:
184         .indirect_symbol \val
185         .word           0
186         .text
187 #else
188         movrel          \rd, \val
189 #endif
190 .endm
191
192 .macro  add_sh          rd,  rn,  rm,  sh:vararg
193 A       add             \rd, \rn, \rm, \sh
194 T       mov             \rm, \rm, \sh
195 T       add             \rd, \rn, \rm
196 .endm
197
198 .macro  ldr_pre         rt,  rn,  rm:vararg
199 A       ldr             \rt, [\rn, \rm]!
200 T       add             \rn, \rn, \rm
201 T       ldr             \rt, [\rn]
202 .endm
203
204 .macro  ldr_dpre        rt,  rn,  rm:vararg
205 A       ldr             \rt, [\rn, -\rm]!
206 T       sub             \rn, \rn, \rm
207 T       ldr             \rt, [\rn]
208 .endm
209
210 .macro  ldr_nreg        rt,  rn,  rm:vararg
211 A       ldr             \rt, [\rn, -\rm]
212 T       sub             \rt, \rn, \rm
213 T       ldr             \rt, [\rt]
214 .endm
215
216 .macro  ldr_post        rt,  rn,  rm:vararg
217 A       ldr             \rt, [\rn], \rm
218 T       ldr             \rt, [\rn]
219 T       add             \rn, \rn, \rm
220 .endm
221
222 .macro  ldrd_reg        rt,  rt2, rn,  rm
223 A       ldrd            \rt, \rt2, [\rn, \rm]
224 T       add             \rt, \rn, \rm
225 T       ldrd            \rt, \rt2, [\rt]
226 .endm
227
228 .macro  ldrd_post       rt,  rt2, rn,  rm
229 A       ldrd            \rt, \rt2, [\rn], \rm
230 T       ldrd            \rt, \rt2, [\rn]
231 T       add             \rn, \rn, \rm
232 .endm
233
234 .macro  ldrh_pre        rt,  rn,  rm
235 A       ldrh            \rt, [\rn, \rm]!
236 T       add             \rn, \rn, \rm
237 T       ldrh            \rt, [\rn]
238 .endm
239
240 .macro  ldrh_dpre       rt,  rn,  rm
241 A       ldrh            \rt, [\rn, -\rm]!
242 T       sub             \rn, \rn, \rm
243 T       ldrh            \rt, [\rn]
244 .endm
245
246 .macro  ldrh_post       rt,  rn,  rm
247 A       ldrh            \rt, [\rn], \rm
248 T       ldrh            \rt, [\rn]
249 T       add             \rn, \rn, \rm
250 .endm
251
252 .macro  ldrb_post       rt,  rn,  rm
253 A       ldrb            \rt, [\rn], \rm
254 T       ldrb            \rt, [\rn]
255 T       add             \rn, \rn, \rm
256 .endm
257
258 .macro  str_post       rt,  rn,  rm:vararg
259 A       str             \rt, [\rn], \rm
260 T       str             \rt, [\rn]
261 T       add             \rn, \rn, \rm
262 .endm
263
264 .macro  strb_post       rt,  rn,  rm:vararg
265 A       strb            \rt, [\rn], \rm
266 T       strb            \rt, [\rn]
267 T       add             \rn, \rn, \rm
268 .endm
269
270 .macro  strd_post       rt,  rt2, rn,  rm
271 A       strd            \rt, \rt2, [\rn], \rm
272 T       strd            \rt, \rt2, [\rn]
273 T       add             \rn, \rn, \rm
274 .endm
275
276 .macro  strh_pre        rt,  rn,  rm
277 A       strh            \rt, [\rn, \rm]!
278 T       add             \rn, \rn, \rm
279 T       strh            \rt, [\rn]
280 .endm
281
282 .macro  strh_dpre       rt,  rn,  rm
283 A       strh            \rt, [\rn, -\rm]!
284 T       sub             \rn, \rn, \rm
285 T       strh            \rt, [\rn]
286 .endm
287
288 .macro  strh_post       rt,  rn,  rm
289 A       strh            \rt, [\rn], \rm
290 T       strh            \rt, [\rn]
291 T       add             \rn, \rn, \rm
292 .endm
293
294 .macro  strh_dpost       rt,  rn,  rm
295 A       strh            \rt, [\rn], -\rm
296 T       strh            \rt, [\rn]
297 T       sub             \rn, \rn, \rm
298 .endm
299
300 #if HAVE_VFP_ARGS
301         .eabi_attribute 28, 1
302 #   define VFP
303 #   define NOVFP @
304 #else
305 #   define VFP   @
306 #   define NOVFP
307 #endif
308
309 #define GLUE(a, b) a ## b
310 #define JOIN(a, b) GLUE(a, b)
311 #define X(s) JOIN(EXTERN_ASM, s)