x86: lavr: add SSE2 quantize() for dithering
[ffmpeg.git] / libavresample / x86 / dither.asm
1 ;******************************************************************************
2 ;* x86 optimized dithering format conversion
3 ;* Copyright (c) 2012 Justin Ruggles <justin.ruggles@gmail.com>
4 ;*
5 ;* This file is part of Libav.
6 ;*
7 ;* Libav is free software; you can redistribute it and/or
8 ;* modify it under the terms of the GNU Lesser General Public
9 ;* License as published by the Free Software Foundation; either
10 ;* version 2.1 of the License, or (at your option) any later version.
11 ;*
12 ;* Libav is distributed in the hope that it will be useful,
13 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;* Lesser General Public License for more details.
16 ;*
17 ;* You should have received a copy of the GNU Lesser General Public
18 ;* License along with Libav; if not, write to the Free Software
19 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
20 ;******************************************************************************
21
22 %include "libavutil/x86/x86util.asm"
23
24 SECTION_RODATA 32
25
26 pf_s16_scale: times 4 dd 32753.0
27
28 SECTION_TEXT
29
30 ;------------------------------------------------------------------------------
31 ; void ff_quantize(int16_t *dst, float *src, float *dither, int len);
32 ;------------------------------------------------------------------------------
33
34 INIT_XMM sse2
35 cglobal quantize, 4,4,3, dst, src, dither, len
36     lea         lenq, [2*lend]
37     add         dstq, lenq
38     lea         srcq, [srcq+2*lenq]
39     lea      ditherq, [ditherq+2*lenq]
40     neg         lenq
41     mova          m2, [pf_s16_scale]
42 .loop:
43     mulps         m0, m2, [srcq+2*lenq]
44     mulps         m1, m2, [srcq+2*lenq+mmsize]
45     addps         m0, [ditherq+2*lenq]
46     addps         m1, [ditherq+2*lenq+mmsize]
47     cvtps2dq      m0, m0
48     cvtps2dq      m1, m1
49     packssdw      m0, m1
50     mova     [dstq+lenq], m0
51     add         lenq, mmsize
52     jl .loop
53     REP_RET