avfilter/interlace: prevent over-sharpening with the complex low-pass filter
[ffmpeg.git] / libavfilter / x86 / vf_interlace.asm
1 ;*****************************************************************************
2 ;* x86-optimized functions for interlace filter
3 ;*
4 ;* Copyright (C) 2014 Kieran Kunhya <kierank@obe.tv>
5 ;* Copyright (c) 2014 Michael Niedermayer <michaelni@gmx.at>
6 ;* Copyright (c) 2017 Thomas Mundt <tmundt75@gmail.com>
7 ;*
8 ;* This file is part of FFmpeg.
9 ;*
10 ;* FFmpeg is free software; you can redistribute it and/or modify
11 ;* it under the terms of the GNU General Public License as published by
12 ;* the Free Software Foundation; either version 2 of the License, or
13 ;* (at your option) any later version.
14 ;*
15 ;* FFmpeg is distributed in the hope that it will be useful,
16 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
18 ;* GNU General Public License for more details.
19 ;*
20 ;* You should have received a copy of the GNU General Public License along
21 ;* with FFmpeg; if not, write to the Free Software Foundation, Inc.,
22 ;* 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
23 ;******************************************************************************
24
25 %include "libavutil/x86/x86util.asm"
26
27 SECTION_RODATA
28
29 pw_4: times 8 dw 4
30
31 SECTION .text
32
33 %macro LOWPASS_LINE 0
34 cglobal lowpass_line, 5, 5, 7, dst, h, src, mref, pref
35     add dstq, hq
36     add srcq, hq
37     add mrefq, srcq
38     add prefq, srcq
39     neg hq
40
41     pcmpeqb m6, m6
42
43 .loop:
44     mova m0, [mrefq+hq]
45     mova m1, [mrefq+hq+mmsize]
46     pavgb m0, [prefq+hq]
47     pavgb m1, [prefq+hq+mmsize]
48     pxor m0, m6
49     pxor m1, m6
50     pxor m2, m6, [srcq+hq]
51     pxor m3, m6, [srcq+hq+mmsize]
52     pavgb m0, m2
53     pavgb m1, m3
54     pxor m0, m6
55     pxor m1, m6
56     mova [dstq+hq], m0
57     mova [dstq+hq+mmsize], m1
58
59     add hq, 2*mmsize
60     jl .loop
61 REP_RET
62
63 %endmacro
64
65 %macro LOWPASS_LINE_COMPLEX 0
66 cglobal lowpass_line_complex, 5, 5, 8, dst, h, src, mref, pref
67     pxor m7, m7
68 .loop:
69     mova m0, [srcq+mrefq]
70     mova m2, [srcq+prefq]
71     mova m1, m0
72     mova m3, m2
73     punpcklbw m0, m7
74     punpcklbw m2, m7
75     punpckhbw m1, m7
76     punpckhbw m3, m7
77     paddw m0, m2
78     paddw m1, m3
79     mova m6, m0
80     mova m5, m1
81     mova m2, [srcq]
82     mova m3, m2
83     punpcklbw m2, m7
84     punpckhbw m3, m7
85     paddw m0, m2
86     paddw m1, m3
87     psllw m2, 1
88     psllw m3, 1
89     paddw m0, m2
90     paddw m1, m3
91     psllw m0, 1
92     psllw m1, 1
93     pcmpgtw m6, m2
94     pcmpgtw m5, m3
95     packsswb m6, m5
96     mova m2, [srcq+mrefq*2]
97     mova m4, [srcq+prefq*2]
98     mova m3, m2
99     mova m5, m4
100     punpcklbw m2, m7
101     punpcklbw m4, m7
102     punpckhbw m3, m7
103     punpckhbw m5, m7
104     paddw m2, m4
105     paddw m3, m5
106     paddw m0, [pw_4]
107     paddw m1, [pw_4]
108     psubusw m0, m2
109     psubusw m1, m3
110     psrlw m0, 3
111     psrlw m1, 3
112     packuswb m0, m1
113     mova m1, m0
114     pmaxub m0, [srcq]
115     pminub m1, [srcq]
116     pand m0, m6
117     pandn m6, m1
118     por m0, m6
119     mova [dstq], m0
120
121     add dstq, mmsize
122     add srcq, mmsize
123     sub hd, mmsize
124     jg .loop
125 REP_RET
126
127 %endmacro
128
129 INIT_XMM sse2
130 LOWPASS_LINE
131
132 INIT_XMM avx
133 LOWPASS_LINE
134
135 INIT_XMM sse2
136 LOWPASS_LINE_COMPLEX