vp9lpf/x86: store unpacked intermediates for filter6/14 on stack.
[ffmpeg.git] / libavcodec / x86 / vp9lpf.asm
1 ;******************************************************************************
2 ;* VP9 loop filter SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
5 ;*
6 ;* This file is part of Libav.
7 ;*
8 ;* Libav is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* Libav is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with Libav; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23
24 %include "libavutil/x86/x86util.asm"
25
26 %if ARCH_X86_64
27
28 SECTION_RODATA
29
30 cextern pb_3
31 cextern pb_80
32
33 pb_4:   times 16 db 0x04
34 pb_10:  times 16 db 0x10
35 pb_40:  times 16 db 0x40
36 pb_81:  times 16 db 0x81
37 pb_f8:  times 16 db 0xf8
38 pb_fe:  times 16 db 0xfe
39 pb_ff:  times 16 db 0xff
40
41 pw_4:   times  8 dw 4
42 pw_8:   times  8 dw 8
43
44 ; with mix functions, two 8-bit thresholds are stored in a 16-bit storage,
45 ; the following mask is used to splat both in the same register
46 mask_mix: times 8 db 0
47           times 8 db 1
48
49 mask_mix84: times 8 db 0xff
50             times 8 db 0x00
51 mask_mix48: times 8 db 0x00
52             times 8 db 0xff
53
54 SECTION .text
55
56 ; %1 = abs(%2-%3)
57 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
58     psubusb             %1, %3, %2
59     psubusb             %4, %2, %3
60     por                 %1, %4
61 %endmacro
62
63 ; %1 = %1>%2
64 %macro CMP_GT 2-3 ; src/dst, cmp, pb_80
65 %if %0 == 3
66     pxor                %1, %3
67 %endif
68     pcmpgtb             %1, %2
69 %endmacro
70
71 ; %1 = abs(%2-%3) > %4
72 %macro ABSSUB_GT 5-6 [pb_80]; dst, src1, src2, cmp, tmp, [pb_80]
73     ABSSUB              %1, %2, %3, %5      ; dst = abs(src1-src2)
74     CMP_GT              %1, %4, %6          ; dst > cmp
75 %endmacro
76
77 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
78     pand                %1, %3              ; new &= mask
79     pandn               %4, %3, %2          ; tmp = ~mask & old
80     por                 %1, %4              ; new&mask | old&~mask
81 %endmacro
82
83 %macro FILTER_SUBx2_ADDx2 9-10 "" ; %1=dst %2=h/l %3=cache %4=stack_off %5=sub1 %6=sub2 %7=add1 %8=add2 %9=rshift, [unpack]
84     psubw               %3, [rsp+%4+%5*32]
85     psubw               %3, [rsp+%4+%6*32]
86     paddw               %3, [rsp+%4+%7*32]
87 %ifnidn %10, ""
88     punpck%2bw          %1, %10, m0
89     mova    [rsp+%4+%8*32], %1
90     paddw               %3, %1
91 %else
92     paddw               %3, [rsp+%4+%8*32]
93 %endif
94     psraw               %1, %3, %9
95 %endmacro
96
97 ; FIXME interleave l/h better (for instruction pairing)
98 %macro FILTER_INIT 9 ; tmp1, tmp2, cacheL, cacheH, dstp, stack_off, filterid, mask, source
99     FILTER%7_INIT       %1, l, %3, %6 +  0
100     FILTER%7_INIT       %2, h, %4, %6 + 16
101     packuswb            %1, %2
102     MASK_APPLY          %1, %9, %8, %2
103     mova                %5, %1
104 %endmacro
105
106
107 %macro FILTER_UPDATE 12-15 "", "" ; tmp1, tmp2, cacheL, cacheH, dstp, stack_off, -, -, +, +, rshift, mask, [source], [unpack]
108 ; FIXME interleave this properly with the subx2/addx2
109 %if %0 == 15
110     mova               %14, %15
111 %endif
112     FILTER_SUBx2_ADDx2  %1, l, %3, %6 +  0, %7, %8, %9, %10, %11, %14
113     FILTER_SUBx2_ADDx2  %2, h, %4, %6 + 16, %7, %8, %9, %10, %11, %14
114     packuswb            %1, %2
115 %ifnidn %13, ""
116     MASK_APPLY          %1, %13, %12, %2
117 %else
118     MASK_APPLY          %1, %5, %12, %2
119 %endif
120     mova                %5, %1
121 %endmacro
122
123 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
124     mova                %4, [pb_f8]
125     pand                %1, %4
126     pand                %2, %4
127     psrlq               %1, 3
128     psrlq               %2, 3
129     pxor                %1, %3
130     pxor                %2, %3
131     psubb               %1, %3
132     psubb               %2, %3
133 %endmacro
134
135 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
136     pxor                %3, %3
137     pxor                %2, %2
138     pcmpgtb             %3, %1                          ; i8 < 0 mask
139     psubb               %2, %1                          ; neg values (only the originally - will be kept)
140     pand                %2, %3                          ; negative values of i8 (but stored as +)
141     pandn               %3, %1                          ; positive values of i8
142 %endmacro
143
144 ; clip_u8(u8 + i8)
145 %macro SIGN_ADD 5 ; dst, u8, i8, tmp1, tmp2
146     EXTRACT_POS_NEG     %3, %4, %5
147     psubusb             %1, %2, %4                      ; sub the negatives
148     paddusb             %1, %5                          ; add the positives
149 %endmacro
150
151 ; clip_u8(u8 - i8)
152 %macro SIGN_SUB 5 ; dst, u8, i8, tmp1, tmp2
153     EXTRACT_POS_NEG     %3, %4, %5
154     psubusb             %1, %2, %5                      ; sub the positives
155     paddusb             %1, %4                          ; add the negatives
156 %endmacro
157
158 %macro FILTER6_INIT 4 ; %1=dst %2=h/l %3=cache, %4=stack_off
159     punpck%2bw          %1, m14, m0                     ; p3: B->W
160     mova     [rsp+%4+0*32], %1
161     paddw               %3, %1, %1                      ; p3*2
162     paddw               %3, %1                          ; p3*3
163     punpck%2bw          %1, m15, m0                     ; p2: B->W
164     mova     [rsp+%4+1*32], %1
165     paddw               %3, %1                          ; p3*3 + p2
166     paddw               %3, %1                          ; p3*3 + p2*2
167     punpck%2bw          %1, m10, m0                     ; p1: B->W
168     mova     [rsp+%4+2*32], %1
169     paddw               %3, %1                          ; p3*3 + p2*2 + p1
170     punpck%2bw          %1, m11, m0                     ; p0: B->W
171     mova     [rsp+%4+3*32], %1
172     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0
173     punpck%2bw          %1, m12, m0                     ; q0: B->W
174     mova     [rsp+%4+4*32], %1
175     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0 + q0
176     paddw               %3, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
177     psraw               %1, %3, 3                       ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
178 %endmacro
179
180 %macro FILTER14_INIT 4 ; %1=dst %2=h/l %3=cache, %4=stack_off
181     punpck%2bw          %1, m2, m0                      ; p7: B->W
182     mova    [rsp+%4+ 8*32], %1
183     psllw               %3, %1, 3                       ; p7*8
184     psubw               %3, %1                          ; p7*7
185     punpck%2bw          %1, m3, m0                      ; p6: B->W
186     mova    [rsp+%4+ 9*32], %1
187     paddw               %3, %1                          ; p7*7 + p6
188     paddw               %3, %1                          ; p7*7 + p6*2
189     punpck%2bw          %1, m8, m0                      ; p5: B->W
190     mova    [rsp+%4+10*32], %1
191     paddw               %3, %1                          ; p7*7 + p6*2 + p5
192     punpck%2bw          %1, m9, m0                      ; p4: B->W
193     mova    [rsp+%4+11*32], %1
194     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4
195     paddw               %3, [rsp+%4+ 0*32]              ; p7*7 + p6*2 + p5 + p4 + p3
196     paddw               %3, [rsp+%4+ 1*32]              ; p7*7 + p6*2 + p5 + .. + p2
197     paddw               %3, [rsp+%4+ 2*32]              ; p7*7 + p6*2 + p5 + .. + p1
198     paddw               %3, [rsp+%4+ 3*32]              ; p7*7 + p6*2 + p5 + .. + p0
199     paddw               %3, [rsp+%4+ 4*32]              ; p7*7 + p6*2 + p5 + .. + p0 + q0
200     paddw               %3, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
201     psraw               %1, %3, 4                       ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
202 %endmacro
203
204 %macro TRANSPOSE16x16B 17
205     mova %17, m%16
206     SBUTTERFLY bw,  %1,  %2,  %16
207     SBUTTERFLY bw,  %3,  %4,  %16
208     SBUTTERFLY bw,  %5,  %6,  %16
209     SBUTTERFLY bw,  %7,  %8,  %16
210     SBUTTERFLY bw,  %9,  %10, %16
211     SBUTTERFLY bw,  %11, %12, %16
212     SBUTTERFLY bw,  %13, %14, %16
213     mova m%16,  %17
214     mova  %17, m%14
215     SBUTTERFLY bw,  %15, %16, %14
216     SBUTTERFLY wd,  %1,  %3,  %14
217     SBUTTERFLY wd,  %2,  %4,  %14
218     SBUTTERFLY wd,  %5,  %7,  %14
219     SBUTTERFLY wd,  %6,  %8,  %14
220     SBUTTERFLY wd,  %9,  %11, %14
221     SBUTTERFLY wd,  %10, %12, %14
222     SBUTTERFLY wd,  %13, %15, %14
223     mova m%14,  %17
224     mova  %17, m%12
225     SBUTTERFLY wd,  %14, %16, %12
226     SBUTTERFLY dq,  %1,  %5,  %12
227     SBUTTERFLY dq,  %2,  %6,  %12
228     SBUTTERFLY dq,  %3,  %7,  %12
229     SBUTTERFLY dq,  %4,  %8,  %12
230     SBUTTERFLY dq,  %9,  %13, %12
231     SBUTTERFLY dq,  %10, %14, %12
232     SBUTTERFLY dq,  %11, %15, %12
233     mova m%12, %17
234     mova  %17, m%8
235     SBUTTERFLY dq,  %12, %16, %8
236     SBUTTERFLY qdq, %1,  %9,  %8
237     SBUTTERFLY qdq, %2,  %10, %8
238     SBUTTERFLY qdq, %3,  %11, %8
239     SBUTTERFLY qdq, %4,  %12, %8
240     SBUTTERFLY qdq, %5,  %13, %8
241     SBUTTERFLY qdq, %6,  %14, %8
242     SBUTTERFLY qdq, %7,  %15, %8
243     mova m%8, %17
244     mova %17, m%1
245     SBUTTERFLY qdq, %8,  %16, %1
246     mova m%1, %17
247     SWAP %2,  %9
248     SWAP %3,  %5
249     SWAP %4,  %13
250     SWAP %6,  %11
251     SWAP %8,  %15
252     SWAP %12, %14
253 %endmacro
254
255 ; transpose 16 half lines (high part) to 8 full centered lines
256 %macro TRANSPOSE16x8B 16
257     punpcklbw   m%1,  m%2
258     punpcklbw   m%3,  m%4
259     punpcklbw   m%5,  m%6
260     punpcklbw   m%7,  m%8
261     punpcklbw   m%9,  m%10
262     punpcklbw   m%11, m%12
263     punpcklbw   m%13, m%14
264     punpcklbw   m%15, m%16
265     SBUTTERFLY  wd,  %1,  %3,  %2
266     SBUTTERFLY  wd,  %5,  %7,  %2
267     SBUTTERFLY  wd,  %9,  %11, %2
268     SBUTTERFLY  wd,  %13, %15, %2
269     SBUTTERFLY  dq,  %1,  %5,  %2
270     SBUTTERFLY  dq,  %3,  %7,  %2
271     SBUTTERFLY  dq,  %9,  %13, %2
272     SBUTTERFLY  dq,  %11, %15, %2
273     SBUTTERFLY  qdq, %1,  %9,  %2
274     SBUTTERFLY  qdq, %3,  %11, %2
275     SBUTTERFLY  qdq, %5,  %13, %2
276     SBUTTERFLY  qdq, %7,  %15, %2
277     SWAP %5, %1
278     SWAP %6, %9
279     SWAP %7, %1
280     SWAP %8, %13
281     SWAP %9, %3
282     SWAP %10, %11
283     SWAP %11, %1
284     SWAP %12, %15
285 %endmacro
286
287 %macro DEFINE_REAL_P7_TO_Q7 0-1 0
288 %define P7 dstq  + 4*mstrideq  + %1
289 %define P6 dstq  +   mstride3q + %1
290 %define P5 dstq  + 2*mstrideq  + %1
291 %define P4 dstq  +   mstrideq  + %1
292 %define P3 dstq                + %1
293 %define P2 dstq  +    strideq  + %1
294 %define P1 dstq  + 2* strideq  + %1
295 %define P0 dstq  +    stride3q + %1
296 %define Q0 dstq  + 4* strideq  + %1
297 %define Q1 dst2q +   mstride3q + %1
298 %define Q2 dst2q + 2*mstrideq  + %1
299 %define Q3 dst2q +   mstrideq  + %1
300 %define Q4 dst2q               + %1
301 %define Q5 dst2q +    strideq  + %1
302 %define Q6 dst2q + 2* strideq  + %1
303 %define Q7 dst2q +    stride3q + %1
304 %endmacro
305
306 ; ..............AB -> AAAAAAAABBBBBBBB
307 %macro SPLATB_MIX 1-2 [mask_mix]
308 %if cpuflag(ssse3)
309     pshufb     %1, %2
310 %else
311     punpcklbw  %1, %1
312     punpcklwd  %1, %1
313     punpckldq  %1, %1
314 %endif
315 %endmacro
316
317 %macro LOOPFILTER 4 ; %1=v/h %2=size1 %3+%4=stack
318 %if UNIX64
319 cglobal vp9_loop_filter_%1_%2_16, 5, 9, 16, %3 + %4, dst, stride, E, I, H, mstride, dst2, stride3, mstride3
320 %else
321 %if WIN64
322 cglobal vp9_loop_filter_%1_%2_16, 4, 8, 16, %3 + %4, dst, stride, E, I, mstride, dst2, stride3, mstride3
323 %else
324 cglobal vp9_loop_filter_%1_%2_16, 2, 6, 16, %3 + %4, dst, stride, mstride, dst2, stride3, mstride3
325 %define Ed dword r2m
326 %define Id dword r3m
327 %endif
328 %define Hd dword r4m
329 %endif
330
331     mov               mstrideq, strideq
332     neg               mstrideq
333
334     lea               stride3q, [strideq*3]
335     lea              mstride3q, [mstrideq*3]
336
337 %ifidn %1, h
338 %if %2 > 16
339 %define movx movh
340     lea                   dstq, [dstq + 4*strideq - 4]
341 %else
342 %define movx movu
343     lea                   dstq, [dstq + 4*strideq - 8] ; go from top center (h pos) to center left (v pos)
344 %endif
345     lea                  dst2q, [dstq + 8*strideq]
346 %else
347     lea                   dstq, [dstq + 4*mstrideq]
348     lea                  dst2q, [dstq + 8*strideq]
349 %endif
350
351     DEFINE_REAL_P7_TO_Q7
352
353 %ifidn %1, h
354     movx                    m0, [P7]
355     movx                    m1, [P6]
356     movx                    m2, [P5]
357     movx                    m3, [P4]
358     movx                    m4, [P3]
359     movx                    m5, [P2]
360     movx                    m6, [P1]
361     movx                    m7, [P0]
362     movx                    m8, [Q0]
363     movx                    m9, [Q1]
364     movx                   m10, [Q2]
365     movx                   m11, [Q3]
366     movx                   m12, [Q4]
367     movx                   m13, [Q5]
368     movx                   m14, [Q6]
369     movx                   m15, [Q7]
370 %define P7 rsp +   0
371 %define P6 rsp +  16
372 %define P5 rsp +  32
373 %define P4 rsp +  48
374 %define P3 rsp +  64
375 %define P2 rsp +  80
376 %define P1 rsp +  96
377 %define P0 rsp + 112
378 %define Q0 rsp + 128
379 %define Q1 rsp + 144
380 %define Q2 rsp + 160
381 %define Q3 rsp + 176
382 %define Q4 rsp + 192
383 %define Q5 rsp + 208
384 %define Q6 rsp + 224
385 %define Q7 rsp + 240
386
387 %if %2 == 16
388     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
389     mova           [P7],  m0
390     mova           [P6],  m1
391     mova           [P5],  m2
392     mova           [P4],  m3
393 %else
394     TRANSPOSE16x8B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15
395 %endif
396     mova           [P3],  m4
397     mova           [P2],  m5
398     mova           [P1],  m6
399     mova           [P0],  m7
400     mova           [Q0],  m8
401     mova           [Q1],  m9
402     mova           [Q2], m10
403     mova           [Q3], m11
404 %if %2 == 16
405     mova           [Q4], m12
406     mova           [Q5], m13
407     mova           [Q6], m14
408     mova           [Q7], m15
409 %endif
410 %endif
411
412     ; calc fm mask
413 %if %2 == 16
414 %if cpuflag(ssse3)
415     pxor                m0, m0
416 %endif
417     SPLATB_REG          m2, I, m0                       ; I I I I ...
418     SPLATB_REG          m3, E, m0                       ; E E E E ...
419 %else
420 %if cpuflag(ssse3)
421     mova                m0, [mask_mix]
422 %endif
423     movd                m2, Id
424     movd                m3, Ed
425     SPLATB_MIX          m2, m0
426     SPLATB_MIX          m3, m0
427 %endif
428     mova                m0, [pb_80]
429     pxor                m2, m0
430     pxor                m3, m0
431 %ifidn %1, v
432     mova                m8, [P3]
433     mova                m9, [P2]
434     mova               m10, [P1]
435     mova               m11, [P0]
436     mova               m12, [Q0]
437     mova               m13, [Q1]
438     mova               m14, [Q2]
439     mova               m15, [Q3]
440 %else
441     ; In case of horizontal, P3..Q3 are already present in some registers due
442     ; to the previous transpose, so we just swap registers.
443     SWAP                 8,  4, 12
444     SWAP                 9,  5, 13
445     SWAP                10,  6, 14
446     SWAP                11,  7, 15
447 %endif
448     ABSSUB_GT           m5,  m8,  m9, m2, m7, m0        ; m5 = abs(p3-p2) <= I
449     ABSSUB_GT           m1,  m9, m10, m2, m7, m0        ; m1 = abs(p2-p1) <= I
450     por                 m5, m1
451     ABSSUB_GT           m1, m10, m11, m2, m7, m0        ; m1 = abs(p1-p0) <= I
452     por                 m5, m1
453     ABSSUB_GT           m1, m12, m13, m2, m7, m0        ; m1 = abs(q1-q0) <= I
454     por                 m5, m1
455     ABSSUB_GT           m1, m13, m14, m2, m7, m0        ; m1 = abs(q2-q1) <= I
456     por                 m5, m1
457     ABSSUB_GT           m1, m14, m15, m2, m7, m0        ; m1 = abs(q3-q2) <= I
458     por                 m5, m1
459     ABSSUB              m1, m11, m12, m7                ; abs(p0-q0)
460     paddusb             m1, m1                          ; abs(p0-q0) * 2
461     ABSSUB              m2, m10, m13, m7                ; abs(p1-q1)
462     pand                m2, [pb_fe]                     ; drop lsb so shift can work
463     psrlq               m2, 1                           ; abs(p1-q1)/2
464     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
465     pxor                m1, m0
466     pcmpgtb             m1, m3
467     por                 m1, m5                          ; fm final value
468     SWAP                 1, 3
469     pxor                m3, [pb_ff]
470
471     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
472     ; calc flat8in (if not 44_16) and hev masks
473 %if %2 != 44
474     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
475     ABSSUB_GT           m2, m8, m11, m6, m5             ; abs(p3 - p0) <= 1
476     mova                m8, [pb_80]
477     ABSSUB_GT           m1, m9, m11, m6, m5, m8         ; abs(p2 - p0) <= 1
478     por                 m2, m1
479     ABSSUB              m4, m10, m11, m5                ; abs(p1 - p0)
480 %if %2 == 16
481 %if cpuflag(ssse3)
482     pxor                m0, m0
483 %endif
484     SPLATB_REG          m7, H, m0                       ; H H H H ...
485 %else
486     movd                m7, Hd
487     SPLATB_MIX          m7
488 %endif
489     pxor                m7, m8
490     pxor                m4, m8
491     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
492     CMP_GT              m4, m6                          ; abs(p1 - p0) <= 1
493     por                 m2, m4                          ; (flat8in)
494     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
495     pxor                m4, m8
496     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
497     por                 m0, m5                          ; hev final value
498     CMP_GT              m4, m6                          ; abs(q1 - q0) <= 1
499     por                 m2, m4                          ; (flat8in)
500     ABSSUB_GT           m1, m14, m12, m6, m5, m8        ; abs(q2 - q0) <= 1
501     por                 m2, m1
502     ABSSUB_GT           m1, m15, m12, m6, m5, m8        ; abs(q3 - q0) <= 1
503     por                 m2, m1                          ; flat8in final value
504     pxor                m2, [pb_ff]
505 %if %2 == 84 || %2 == 48
506     pand                m2, [mask_mix%2]
507 %endif
508 %else
509     mova                m6, [pb_80]
510     movd                m7, Hd
511     SPLATB_MIX          m7
512     pxor                m7, m6
513     ABSSUB              m4, m10, m11, m1                ; abs(p1 - p0)
514     pxor                m4, m6
515     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
516     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
517     pxor                m4, m6
518     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
519     por                 m0, m5                          ; hev final value
520 %endif
521
522 %if %2 == 16
523     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
524     ; calc flat8out mask
525     mova                m8, [P7]
526     mova                m9, [P6]
527     ABSSUB_GT           m1, m8, m11, m6, m5             ; abs(p7 - p0) <= 1
528     ABSSUB_GT           m7, m9, m11, m6, m5             ; abs(p6 - p0) <= 1
529     por                 m1, m7
530     mova                m8, [P5]
531     mova                m9, [P4]
532     ABSSUB_GT           m7, m8, m11, m6, m5             ; abs(p5 - p0) <= 1
533     por                 m1, m7
534     ABSSUB_GT           m7, m9, m11, m6, m5             ; abs(p4 - p0) <= 1
535     por                 m1, m7
536     mova                m14, [Q4]
537     mova                m15, [Q5]
538     ABSSUB_GT           m7, m14, m12, m6, m5            ; abs(q4 - q0) <= 1
539     por                 m1, m7
540     ABSSUB_GT           m7, m15, m12, m6, m5            ; abs(q5 - q0) <= 1
541     por                 m1, m7
542     mova                m14, [Q6]
543     mova                m15, [Q7]
544     ABSSUB_GT           m7, m14, m12, m6, m5            ; abs(q4 - q0) <= 1
545     por                 m1, m7
546     ABSSUB_GT           m7, m15, m12, m6, m5            ; abs(q5 - q0) <= 1
547     por                 m1, m7                          ; flat8out final value
548     pxor                m1, [pb_ff]
549 %endif
550
551     ; if (fm) {
552     ;     if (out && in) filter_14()
553     ;     else if (in)   filter_6()
554     ;     else if (hev)  filter_2()
555     ;     else           filter_4()
556     ; }
557     ;
558     ; f14:                                                                            fm &  out &  in
559     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
560     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
561     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
562
563     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
564     ; filter2()
565 %if %2 != 44
566     mova                m6, [pb_80]                     ; already in m6 if 44_16
567 %endif
568     pxor                m15, m12, m6                    ; q0 ^ 0x80
569     pxor                m14, m11, m6                    ; p0 ^ 0x80
570     psubsb              m15, m14                        ; (signed) q0 - p0
571     pxor                m4, m10, m6                     ; p1 ^ 0x80
572     pxor                m5, m13, m6                     ; q1 ^ 0x80
573     psubsb              m4, m5                          ; (signed) p1 - q1
574     paddsb              m4, m15                         ;   (q0 - p0) + (p1 - q1)
575     paddsb              m4, m15                         ; 2*(q0 - p0) + (p1 - q1)
576     paddsb              m4, m15                         ; 3*(q0 - p0) + (p1 - q1)
577     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
578     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
579     mova                m14, [pb_10]                    ; will be reused in filter4()
580     SRSHIFT3B_2X        m6, m4, m14, m7                 ; f1 and f2 sign byte shift by 3
581     SIGN_SUB            m7, m12, m6, m5, m9             ; m7 = q0 - f1
582     SIGN_ADD            m8, m11, m4, m5, m9             ; m8 = p0 + f2
583 %if %2 != 44
584     pandn               m6, m2, m3                      ;  ~mask(in) & mask(fm)
585     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
586 %else
587     pand                m6, m3, m0
588 %endif
589     MASK_APPLY          m7, m12, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
590     MASK_APPLY          m8, m11, m6, m5                 ; m8 = filter2(p0) & mask / we write it in filter4()
591
592     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m7..m8: q0' p0', m10..13: p1 p0 q0 q1, m14: pb_10, m15: q0-p0)
593     ; filter4()
594     mova                m4, m15
595     paddsb              m15, m4                         ; 2 * (q0 - p0)
596     paddsb              m15, m4                         ; 3 * (q0 - p0)
597     paddsb              m6, m15, [pb_4]                 ; m6:  f1 = clip(f + 4, 127)
598     paddsb              m15, [pb_3]                     ; m15: f2 = clip(f + 3, 127)
599     SRSHIFT3B_2X        m6, m15, m14, m9                ; f1 and f2 sign byte shift by 3
600 %if %2 != 44
601 %define p0tmp m7
602 %define q0tmp m9
603     pandn               m5, m2, m3                      ;               ~mask(in) & mask(fm)
604     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
605 %else
606 %define p0tmp m1
607 %define q0tmp m2
608     pandn               m0, m3
609 %endif
610     SIGN_SUB            q0tmp, m12, m6, m4, m14         ; q0 - f1
611     MASK_APPLY          q0tmp, m7, m0, m5               ; filter4(q0) & mask
612     mova                [Q0], q0tmp
613     SIGN_ADD            p0tmp, m11, m15, m4, m14        ; p0 + f2
614     MASK_APPLY          p0tmp, m8, m0, m5               ; filter4(p0) & mask
615     mova                [P0], p0tmp
616     paddb               m6, [pb_80]                     ;
617     pxor                m8, m8                          ;   f=(f1+1)>>1
618     pavgb               m6, m8                          ;
619     psubb               m6, [pb_40]                     ;
620     SIGN_ADD            m7, m10, m6, m8, m9             ; p1 + f
621     SIGN_SUB            m4, m13, m6, m8, m9             ; q1 - f
622     MASK_APPLY          m7, m10, m0, m14                ; m7 = filter4(p1)
623     MASK_APPLY          m4, m13, m0, m14                ; m4 = filter4(q1)
624     mova                [P1], m7
625     mova                [Q1], m4
626
627     ; ([m1: flat8out], m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
628     ; filter6()
629 %if %2 != 44
630     pxor                m0, m0
631 %if %2 > 16
632     pand                m3, m2
633 %else
634     pand                m2, m3                          ;               mask(fm) & mask(in)
635     pandn               m3, m1, m2                      ; ~mask(out) & (mask(fm) & mask(in))
636 %endif
637     mova               m14, [P3]
638     mova               m15, [P2]
639     mova                m8, [Q2]
640     mova                m9, [Q3]
641     FILTER_INIT         m4, m5, m6, m7, [P2], %4, 6,             m3, m15      ; [p2]
642     FILTER_UPDATE       m4, m5, m6, m7, [P1], %4, 0, 1, 2, 5, 3, m3,  "", m13 ; [p1] -p3 -p2 +p1 +q1
643     FILTER_UPDATE       m4, m5, m6, m7, [P0], %4, 0, 2, 3, 6, 3, m3,  "", m8  ; [p0] -p3 -p1 +p0 +q2
644     FILTER_UPDATE       m4, m5, m6, m7, [Q0], %4, 0, 3, 4, 7, 3, m3,  "", m9  ; [q0] -p3 -p0 +q0 +q3
645     FILTER_UPDATE       m4, m5, m6, m7, [Q1], %4, 1, 4, 5, 7, 3, m3,  ""      ; [q1] -p2 -q0 +q1 +q3
646     FILTER_UPDATE       m4, m5, m6, m7, [Q2], %4, 2, 5, 6, 7, 3, m3,  m8      ; [q2] -p1 -q1 +q2 +q3
647 %endif
648
649     ; (m0: 0, [m1: flat8out], m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
650     ; filter14()
651     ;
652     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
653     ;
654     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
655     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
656     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
657     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
658     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
659     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
660     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
661     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
662     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
663     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
664     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
665     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
666     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
667     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
668     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
669
670 %if %2 == 16
671     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
672     mova            m2, [P7]
673     mova            m3, [P6]
674     mova            m8, [P5]
675     mova            m9, [P4]
676     FILTER_INIT     m4, m5, m6, m7, [P6], %4, 14,                m1,  m3            ; [p6]
677     FILTER_UPDATE   m4, m5, m6, m7, [P5], %4,  8,  9, 10,  5, 4, m1,  m8            ; [p5] -p7 -p6 +p5 +q1
678     FILTER_UPDATE   m4, m5, m6, m7, [P4], %4,  8, 10, 11,  6, 4, m1,  m9            ; [p4] -p7 -p5 +p4 +q2
679     FILTER_UPDATE   m4, m5, m6, m7, [P3], %4,  8, 11,  0,  7, 4, m1, m14            ; [p3] -p7 -p4 +p3 +q3
680     FILTER_UPDATE   m4, m5, m6, m7, [P2], %4,  8,  0,  1, 12, 4, m1,  "",  m8, [Q4] ; [p2] -p7 -p3 +p2 +q4
681     FILTER_UPDATE   m4, m5, m6, m7, [P1], %4,  8,  1,  2, 13, 4, m1,  "",  m9, [Q5] ; [p1] -p7 -p2 +p1 +q5
682     FILTER_UPDATE   m4, m5, m6, m7, [P0], %4,  8,  2,  3, 14, 4, m1,  "", m14, [Q6] ; [p0] -p7 -p1 +p0 +q6
683     FILTER_UPDATE   m4, m5, m6, m7, [Q0], %4,  8,  3,  4, 15, 4, m1,  "", m15, [Q7] ; [q0] -p7 -p0 +q0 +q7
684     FILTER_UPDATE   m4, m5, m6, m7, [Q1], %4,  9,  4,  5, 15, 4, m1,  ""            ; [q1] -p6 -q0 +q1 +q7
685     FILTER_UPDATE   m4, m5, m6, m7, [Q2], %4, 10,  5,  6, 15, 4, m1,  ""            ; [q2] -p5 -q1 +q2 +q7
686     FILTER_UPDATE   m4, m5, m6, m7, [Q3], %4, 11,  6,  7, 15, 4, m1,  ""            ; [q3] -p4 -q2 +q3 +q7
687     FILTER_UPDATE   m4, m5, m6, m7, [Q4], %4,  0,  7, 12, 15, 4, m1,  m8            ; [q4] -p3 -q3 +q4 +q7
688     FILTER_UPDATE   m4, m5, m6, m7, [Q5], %4,  1, 12, 13, 15, 4, m1,  m9            ; [q5] -p2 -q4 +q5 +q7
689     FILTER_UPDATE   m4, m5, m6, m7, [Q6], %4,  2, 13, 14, 15, 4, m1, m14            ; [q6] -p1 -q5 +q6 +q7
690 %endif
691
692 %ifidn %1, h
693 %if %2 == 16
694     mova                    m0, [P7]
695     mova                    m1, [P6]
696     mova                    m2, [P5]
697     mova                    m3, [P4]
698     mova                    m4, [P3]
699     mova                    m5, [P2]
700     mova                    m6, [P1]
701     mova                    m7, [P0]
702     mova                    m8, [Q0]
703     mova                    m9, [Q1]
704     mova                   m10, [Q2]
705     mova                   m11, [Q3]
706     mova                   m12, [Q4]
707     mova                   m13, [Q5]
708     mova                   m14, [Q6]
709     mova                   m15, [Q7]
710     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
711     DEFINE_REAL_P7_TO_Q7
712     movu  [P7],  m0
713     movu  [P6],  m1
714     movu  [P5],  m2
715     movu  [P4],  m3
716     movu  [P3],  m4
717     movu  [P2],  m5
718     movu  [P1],  m6
719     movu  [P0],  m7
720     movu  [Q0],  m8
721     movu  [Q1],  m9
722     movu  [Q2], m10
723     movu  [Q3], m11
724     movu  [Q4], m12
725     movu  [Q5], m13
726     movu  [Q6], m14
727     movu  [Q7], m15
728 %elif %2 == 44
729     SWAP 0, 7   ; m0 = p1
730     SWAP 3, 4   ; m3 = q1
731     DEFINE_REAL_P7_TO_Q7 2
732     SBUTTERFLY  bw, 0, 1, 8
733     SBUTTERFLY  bw, 2, 3, 8
734     SBUTTERFLY  wd, 0, 2, 8
735     SBUTTERFLY  wd, 1, 3, 8
736     movd  [P7], m0
737     movd  [P3], m2
738     movd  [Q0], m1
739     movd  [Q4], m3
740     psrldq  m0, 4
741     psrldq  m1, 4
742     psrldq  m2, 4
743     psrldq  m3, 4
744     movd  [P6], m0
745     movd  [P2], m2
746     movd  [Q1], m1
747     movd  [Q5], m3
748     psrldq  m0, 4
749     psrldq  m1, 4
750     psrldq  m2, 4
751     psrldq  m3, 4
752     movd  [P5], m0
753     movd  [P1], m2
754     movd  [Q2], m1
755     movd  [Q6], m3
756     psrldq  m0, 4
757     psrldq  m1, 4
758     psrldq  m2, 4
759     psrldq  m3, 4
760     movd  [P4], m0
761     movd  [P0], m2
762     movd  [Q3], m1
763     movd  [Q7], m3
764 %else
765     ; the following code do a transpose of 8 full lines to 16 half
766     ; lines (high part). It is inlined to avoid the need of a staging area
767     mova                    m0, [P3]
768     mova                    m1, [P2]
769     mova                    m2, [P1]
770     mova                    m3, [P0]
771     mova                    m4, [Q0]
772     mova                    m5, [Q1]
773     mova                    m6, [Q2]
774     mova                    m7, [Q3]
775     DEFINE_REAL_P7_TO_Q7
776     SBUTTERFLY  bw,  0,  1, 8
777     SBUTTERFLY  bw,  2,  3, 8
778     SBUTTERFLY  bw,  4,  5, 8
779     SBUTTERFLY  bw,  6,  7, 8
780     SBUTTERFLY  wd,  0,  2, 8
781     SBUTTERFLY  wd,  1,  3, 8
782     SBUTTERFLY  wd,  4,  6, 8
783     SBUTTERFLY  wd,  5,  7, 8
784     SBUTTERFLY  dq,  0,  4, 8
785     SBUTTERFLY  dq,  1,  5, 8
786     SBUTTERFLY  dq,  2,  6, 8
787     SBUTTERFLY  dq,  3,  7, 8
788     movh   [P7], m0
789     movhps [P6], m0
790     movh   [Q0], m1
791     movhps [Q1], m1
792     movh   [P3], m2
793     movhps [P2], m2
794     movh   [Q4], m3
795     movhps [Q5], m3
796     movh   [P5], m4
797     movhps [P4], m4
798     movh   [Q2], m5
799     movhps [Q3], m5
800     movh   [P1], m6
801     movhps [P0], m6
802     movh   [Q6], m7
803     movhps [Q7], m7
804 %endif
805 %endif
806
807     RET
808 %endmacro
809
810 %macro LPF_16_VH 3
811 INIT_XMM %3
812 LOOPFILTER v, %1, %2, 0
813 LOOPFILTER h, %1, %2, 256
814 %endmacro
815
816 %macro LPF_16_VH_ALL_OPTS 2
817 LPF_16_VH %1, %2, sse2
818 LPF_16_VH %1, %2, ssse3
819 LPF_16_VH %1, %2, avx
820 %endmacro
821
822 LPF_16_VH_ALL_OPTS 16, 512
823 LPF_16_VH_ALL_OPTS 44, 0
824 LPF_16_VH_ALL_OPTS 48, 256
825 LPF_16_VH_ALL_OPTS 84, 256
826 LPF_16_VH_ALL_OPTS 88, 256
827
828 %endif ; x86-64