vp9lpf/x86: add ff_vp9_loop_filter_[vh]_88_16_{ssse3,avx}.
[ffmpeg.git] / libavcodec / x86 / vp9lpf.asm
1 ;******************************************************************************
2 ;* VP9 loop filter SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
5 ;*
6 ;* This file is part of Libav.
7 ;*
8 ;* Libav is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* Libav is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with Libav; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23
24 %include "libavutil/x86/x86util.asm"
25
26 %if ARCH_X86_64
27
28 SECTION_RODATA
29
30 cextern pb_3
31 cextern pb_80
32
33 pb_4:   times 16 db 0x04
34 pb_10:  times 16 db 0x10
35 pb_40:  times 16 db 0x40
36 pb_81:  times 16 db 0x81
37 pb_f8:  times 16 db 0xf8
38 pb_fe:  times 16 db 0xfe
39
40 pw_4:   times  8 dw 4
41 pw_8:   times  8 dw 8
42
43 ; with mix functions, two 8-bit thresholds are stored in a 16-bit storage,
44 ; the following mask is used to splat both in the same register
45 mask_mix: times 8 db 0
46           times 8 db 1
47
48 SECTION .text
49
50 ; %1 = abs(%2-%3)
51 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
52     psubusb             %1, %3, %2
53     psubusb             %4, %2, %3
54     por                 %1, %4
55 %endmacro
56
57 ; %1 = %1<=%2
58 %macro CMP_LTE 3-4 ; src/dst, cmp, tmp, pb_80
59 %if %0 == 4
60     pxor                %1, %4
61 %endif
62     pcmpgtb             %3, %2, %1          ; cmp > src?
63     pcmpeqb             %1, %2              ; cmp == src? XXX: avoid this with a -1/+1 well placed?
64     por                 %1, %3              ; cmp >= src?
65 %endmacro
66
67 ; %1 = abs(%2-%3) <= %4
68 %macro ABSSUB_CMP 6-7 [pb_80]; dst, src1, src2, cmp, tmp1, tmp2, [pb_80]
69     ABSSUB              %1, %2, %3, %6      ; dst = abs(src1-src2)
70     CMP_LTE             %1, %4, %6, %7      ; dst <= cmp
71 %endmacro
72
73 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
74     pand                %1, %3              ; new &= mask
75     pandn               %4, %3, %2          ; tmp = ~mask & old
76     por                 %1, %4              ; new&mask | old&~mask
77 %endmacro
78
79 %macro FILTER_SUBx2_ADDx2 8 ; %1=dst %2=h/l %3=cache %4=sub1 %5=sub2 %6=add1 %7=add2 %8=rshift
80     punpck%2bw          %3, %4, m0
81     psubw               %1, %3
82     punpck%2bw          %3, %5, m0
83     psubw               %1, %3
84     punpck%2bw          %3, %6, m0
85     paddw               %1, %3
86     punpck%2bw          %3, %7, m0
87     paddw               %3, %1
88     psraw               %1, %3, %8
89 %endmacro
90
91 %macro FILTER_INIT 8 ; tmp1, tmp2, cacheL, cacheH, dstp, filterid, mask, source
92     FILTER%6_INIT       %1, l, %3
93     FILTER%6_INIT       %2, h, %4
94     packuswb            %1, %2
95     MASK_APPLY          %1, %8, %7, %2
96     mova                %5, %1
97 %endmacro
98
99 %macro FILTER_UPDATE 11-14 ; tmp1, tmp2, cacheL, cacheH, dstp, -, -, +, +, rshift, mask, [source], [preload reg + value]
100 %if %0 == 13 ; no source + preload
101     mova                %12, %13
102 %elif %0 == 14 ; source + preload
103     mova                %13, %14
104 %endif
105     FILTER_SUBx2_ADDx2  %1, l, %3, %6, %7, %8, %9, %10
106     FILTER_SUBx2_ADDx2  %2, h, %4, %6, %7, %8, %9, %10
107     packuswb            %1, %2
108 %if %0 == 12 || %0 == 14
109     MASK_APPLY          %1, %12, %11, %2
110 %else
111     MASK_APPLY          %1, %5, %11, %2
112 %endif
113     mova                %5, %1
114 %endmacro
115
116 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
117     mova                %4, [pb_f8]
118     pand                %1, %4
119     pand                %2, %4
120     psrlq               %1, 3
121     psrlq               %2, 3
122     pxor                %1, %3
123     pxor                %2, %3
124     psubb               %1, %3
125     psubb               %2, %3
126 %endmacro
127
128 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
129     pxor                %3, %3
130     pxor                %2, %2
131     pcmpgtb             %3, %1                          ; i8 < 0 mask
132     psubb               %2, %1                          ; neg values (only the originally - will be kept)
133     pand                %2, %3                          ; negative values of i8 (but stored as +)
134     pandn               %3, %1                          ; positive values of i8
135 %endmacro
136
137 ; clip_u8(u8 + i8)
138 %macro SIGN_ADD 5 ; dst, u8, i8, tmp1, tmp2
139     EXTRACT_POS_NEG     %3, %4, %5
140     psubusb             %1, %2, %4                      ; sub the negatives
141     paddusb             %1, %5                          ; add the positives
142 %endmacro
143
144 ; clip_u8(u8 - i8)
145 %macro SIGN_SUB 5 ; dst, u8, i8, tmp1, tmp2
146     EXTRACT_POS_NEG     %3, %4, %5
147     psubusb             %1, %2, %5                      ; sub the positives
148     paddusb             %1, %4                          ; add the negatives
149 %endmacro
150
151 %macro FILTER6_INIT 3 ; %1=dst %2=h/l %3=cache
152     punpck%2bw          %1, m14, m0                     ; p3: B->W
153     paddw               %3, %1, %1                      ; p3*2
154     paddw               %3, %1                          ; p3*3
155     punpck%2bw          %1, m15, m0                     ; p2: B->W
156     paddw               %3, %1                          ; p3*3 + p2
157     paddw               %3, %1                          ; p3*3 + p2*2
158     punpck%2bw          %1, m10, m0                     ; p1: B->W
159     paddw               %3, %1                          ; p3*3 + p2*2 + p1
160     punpck%2bw          %1, m11, m0                     ; p0: B->W
161     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0
162     punpck%2bw          %1, m12, m0                     ; q0: B->W
163     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0 + q0
164     paddw               %3, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
165     psraw               %1, %3, 3                       ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
166 %endmacro
167
168 %macro FILTER14_INIT 3 ; %1=dst %2=h/l %3=cache
169     punpck%2bw          %1, m2, m0                      ; p7: B->W
170     psllw               %3, %1, 3                       ; p7*8
171     psubw               %3, %1                          ; p7*7
172     punpck%2bw          %1, m3, m0                      ; p6: B->W
173     paddw               %3, %1                          ; p7*7 + p6
174     paddw               %3, %1                          ; p7*7 + p6*2
175     punpck%2bw          %1, m8, m0                      ; p5: B->W
176     paddw               %3, %1                          ; p7*7 + p6*2 + p5
177     punpck%2bw          %1, m9, m0                      ; p4: B->W
178     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4
179     punpck%2bw          %1, m14, m0                     ; p3: B->W
180     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4 + p3
181     punpck%2bw          %1, m15, m0                     ; p2: B->W
182     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p2
183     punpck%2bw          %1, m10, m0                     ; p1: B->W
184     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p1
185     punpck%2bw          %1, m11, m0                     ; p0: B->W
186     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p0
187     punpck%2bw          %1, m12, m0                     ; q0: B->W
188     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p0 + q0
189     paddw               %3, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
190     psraw               %1, %3, 4                       ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
191 %endmacro
192
193 %macro TRANSPOSE16x16B 17
194     mova %17, m%16
195     SBUTTERFLY bw,  %1,  %2,  %16
196     SBUTTERFLY bw,  %3,  %4,  %16
197     SBUTTERFLY bw,  %5,  %6,  %16
198     SBUTTERFLY bw,  %7,  %8,  %16
199     SBUTTERFLY bw,  %9,  %10, %16
200     SBUTTERFLY bw,  %11, %12, %16
201     SBUTTERFLY bw,  %13, %14, %16
202     mova m%16,  %17
203     mova  %17, m%14
204     SBUTTERFLY bw,  %15, %16, %14
205     SBUTTERFLY wd,  %1,  %3,  %14
206     SBUTTERFLY wd,  %2,  %4,  %14
207     SBUTTERFLY wd,  %5,  %7,  %14
208     SBUTTERFLY wd,  %6,  %8,  %14
209     SBUTTERFLY wd,  %9,  %11, %14
210     SBUTTERFLY wd,  %10, %12, %14
211     SBUTTERFLY wd,  %13, %15, %14
212     mova m%14,  %17
213     mova  %17, m%12
214     SBUTTERFLY wd,  %14, %16, %12
215     SBUTTERFLY dq,  %1,  %5,  %12
216     SBUTTERFLY dq,  %2,  %6,  %12
217     SBUTTERFLY dq,  %3,  %7,  %12
218     SBUTTERFLY dq,  %4,  %8,  %12
219     SBUTTERFLY dq,  %9,  %13, %12
220     SBUTTERFLY dq,  %10, %14, %12
221     SBUTTERFLY dq,  %11, %15, %12
222     mova m%12, %17
223     mova  %17, m%8
224     SBUTTERFLY dq,  %12, %16, %8
225     SBUTTERFLY qdq, %1,  %9,  %8
226     SBUTTERFLY qdq, %2,  %10, %8
227     SBUTTERFLY qdq, %3,  %11, %8
228     SBUTTERFLY qdq, %4,  %12, %8
229     SBUTTERFLY qdq, %5,  %13, %8
230     SBUTTERFLY qdq, %6,  %14, %8
231     SBUTTERFLY qdq, %7,  %15, %8
232     mova m%8, %17
233     mova %17, m%1
234     SBUTTERFLY qdq, %8,  %16, %1
235     mova m%1, %17
236     SWAP %2,  %9
237     SWAP %3,  %5
238     SWAP %4,  %13
239     SWAP %6,  %11
240     SWAP %8,  %15
241     SWAP %12, %14
242 %endmacro
243
244 ; transpose 16 half lines (high part) to 8 full centered lines
245 %macro TRANSPOSE16x8B 16
246     punpcklbw   m%1,  m%2
247     punpcklbw   m%3,  m%4
248     punpcklbw   m%5,  m%6
249     punpcklbw   m%7,  m%8
250     punpcklbw   m%9,  m%10
251     punpcklbw   m%11, m%12
252     punpcklbw   m%13, m%14
253     punpcklbw   m%15, m%16
254     SBUTTERFLY  wd,  %1,  %3,  %2
255     SBUTTERFLY  wd,  %5,  %7,  %2
256     SBUTTERFLY  wd,  %9,  %11, %2
257     SBUTTERFLY  wd,  %13, %15, %2
258     SBUTTERFLY  dq,  %1,  %5,  %2
259     SBUTTERFLY  dq,  %3,  %7,  %2
260     SBUTTERFLY  dq,  %9,  %13, %2
261     SBUTTERFLY  dq,  %11, %15, %2
262     SBUTTERFLY  qdq, %1,  %9,  %2
263     SBUTTERFLY  qdq, %3,  %11, %2
264     SBUTTERFLY  qdq, %5,  %13, %2
265     SBUTTERFLY  qdq, %7,  %15, %2
266     SWAP %5, %1
267     SWAP %6, %9
268     SWAP %7, %1
269     SWAP %8, %13
270     SWAP %9, %3
271     SWAP %10, %11
272     SWAP %11, %1
273     SWAP %12, %15
274 %endmacro
275
276 %macro DEFINE_REAL_P7_TO_Q7 0
277 %define P7 dst1q + 2*mstrideq
278 %define P6 dst1q +   mstrideq
279 %define P5 dst1q
280 %define P4 dst1q +    strideq
281 %define P3 dstq  + 4*mstrideq
282 %define P2 dstq  +   mstride3q
283 %define P1 dstq  + 2*mstrideq
284 %define P0 dstq  +   mstrideq
285 %define Q0 dstq
286 %define Q1 dstq  +   strideq
287 %define Q2 dstq  + 2*strideq
288 %define Q3 dstq  +   stride3q
289 %define Q4 dstq  + 4*strideq
290 %define Q5 dst2q + mstrideq
291 %define Q6 dst2q
292 %define Q7 dst2q +  strideq
293 %endmacro
294
295 %macro LOOPFILTER 2 ; %1=v/h %2=size1
296     lea mstrideq, [strideq]
297     neg mstrideq
298
299     lea stride3q, [strideq+2*strideq]
300     mov mstride3q, stride3q
301     neg mstride3q
302
303 %ifidn %1, h
304 %if %2 == 88
305 %define movx movh
306     lea dstq, [dstq + 8*strideq - 4]
307 %else
308 %define movx movu
309     lea dstq, [dstq + 8*strideq - 8] ; go from top center (h pos) to center left (v pos)
310 %endif
311 %endif
312
313     lea dst1q, [dstq + 2*mstride3q]                         ; dst1q = &dst[stride * -6]
314     lea dst2q, [dstq + 2* stride3q]                         ; dst2q = &dst[stride * +6]
315
316     DEFINE_REAL_P7_TO_Q7
317
318 %ifidn %1, h
319     movx                    m0, [P7]
320     movx                    m1, [P6]
321     movx                    m2, [P5]
322     movx                    m3, [P4]
323     movx                    m4, [P3]
324     movx                    m5, [P2]
325     movx                    m6, [P1]
326     movx                    m7, [P0]
327     movx                    m8, [Q0]
328     movx                    m9, [Q1]
329     movx                   m10, [Q2]
330     movx                   m11, [Q3]
331     movx                   m12, [Q4]
332     movx                   m13, [Q5]
333     movx                   m14, [Q6]
334     movx                   m15, [Q7]
335 %define P7 rsp +   0
336 %define P6 rsp +  16
337 %define P5 rsp +  32
338 %define P4 rsp +  48
339 %define P3 rsp +  64
340 %define P2 rsp +  80
341 %define P1 rsp +  96
342 %define P0 rsp + 112
343 %define Q0 rsp + 128
344 %define Q1 rsp + 144
345 %define Q2 rsp + 160
346 %define Q3 rsp + 176
347 %define Q4 rsp + 192
348 %define Q5 rsp + 208
349 %define Q6 rsp + 224
350 %define Q7 rsp + 240
351
352 %if %2 != 88
353     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
354     mova           [P7],  m0
355     mova           [P6],  m1
356     mova           [P5],  m2
357     mova           [P4],  m3
358 %else
359     TRANSPOSE16x8B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15
360 %endif
361     mova           [P3],  m4
362     mova           [P2],  m5
363     mova           [P1],  m6
364     mova           [P0],  m7
365     mova           [Q0],  m8
366     mova           [Q1],  m9
367     mova           [Q2], m10
368     mova           [Q3], m11
369 %if %2 != 88
370     mova           [Q4], m12
371     mova           [Q5], m13
372     mova           [Q6], m14
373     mova           [Q7], m15
374 %endif
375 %endif
376
377     ; calc fm mask
378 %if %2 == 16
379 %if cpuflag(ssse3)
380     pxor                m0, m0
381 %endif
382     SPLATB_REG          m2, I, m0                       ; I I I I ...
383     SPLATB_REG          m3, E, m0                       ; E E E E ...
384 %elif %2 == 88
385     mova                m0, [mask_mix]
386     movd                m2, Id
387     movd                m3, Ed
388     pshufb              m2, m0
389     pshufb              m3, m0
390 %endif
391     mova                m0, [pb_80]
392     pxor                m2, m0
393     pxor                m3, m0
394 %ifidn %1, v
395     mova                m8, [P3]
396     mova                m9, [P2]
397     mova               m10, [P1]
398     mova               m11, [P0]
399     mova               m12, [Q0]
400     mova               m13, [Q1]
401     mova               m14, [Q2]
402     mova               m15, [Q3]
403 %else
404     ; In case of horizontal, P3..Q3 are already present in some registers due
405     ; to the previous transpose, so we just swap registers.
406     SWAP                 8,  4, 12
407     SWAP                 9,  5, 13
408     SWAP                10,  6, 14
409     SWAP                11,  7, 15
410 %endif
411     ABSSUB_CMP          m5,  m8,  m9, m2, m6, m7, m0    ; m5 = abs(p3-p2) <= I
412     ABSSUB_CMP          m1,  m9, m10, m2, m6, m7, m0    ; m1 = abs(p2-p1) <= I
413     pand                m5, m1
414     ABSSUB_CMP          m1, m10, m11, m2, m6, m7, m0    ; m1 = abs(p1-p0) <= I
415     pand                m5, m1
416     ABSSUB_CMP          m1, m12, m13, m2, m6, m7, m0    ; m1 = abs(q1-q0) <= I
417     pand                m5, m1
418     ABSSUB_CMP          m1, m13, m14, m2, m6, m7, m0    ; m1 = abs(q2-q1) <= I
419     pand                m5, m1
420     ABSSUB_CMP          m1, m14, m15, m2, m6, m7, m0    ; m1 = abs(q3-q2) <= I
421     pand                m5, m1
422     ABSSUB              m1, m11, m12, m7                ; abs(p0-q0)
423     paddusb             m1, m1                          ; abs(p0-q0) * 2
424     ABSSUB              m2, m10, m13, m7                ; abs(p1-q1)
425     pand                m2, [pb_fe]                     ; drop lsb so shift can work
426     psrlq               m2, 1                           ; abs(p1-q1)/2
427     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
428     pxor                m1, m0
429     pcmpgtb             m4, m3, m1                      ; E > X?
430     pcmpeqb             m3, m1                          ; E == X?
431     por                 m3, m4                          ; E >= X?
432     pand                m3, m5                          ; fm final value
433
434     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
435     ; calc flat8in and hev masks
436     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
437     ABSSUB_CMP          m2, m8, m11, m6, m4, m5         ; abs(p3 - p0) <= 1
438     mova                m8, [pb_80]
439     ABSSUB_CMP          m1, m9, m11, m6, m4, m5, m8     ; abs(p2 - p0) <= 1
440     pand                m2, m1
441     ABSSUB              m4, m10, m11, m5                ; abs(p1 - p0)
442 %if %2 != 88
443 %if cpuflag(ssse3)
444     pxor                m0, m0
445 %endif
446     SPLATB_REG          m7, H, m0                       ; H H H H ...
447 %else
448     movd                m7, Hd
449     pshufb              m7, [mask_mix]
450 %endif
451     pxor                m7, m8
452     pxor                m4, m8
453     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
454     CMP_LTE             m4, m6, m5                      ; abs(p1 - p0) <= 1
455     pand                m2, m4                          ; (flat8in)
456     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
457     pxor                m4, m8
458     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
459     por                 m0, m5                          ; hev final value
460     CMP_LTE             m4, m6, m5                      ; abs(q1 - q0) <= 1
461     pand                m2, m4                          ; (flat8in)
462     ABSSUB_CMP          m1, m14, m12, m6, m4, m5, m8    ; abs(q2 - q0) <= 1
463     pand                m2, m1
464     ABSSUB_CMP          m1, m15, m12, m6, m4, m5, m8    ; abs(q3 - q0) <= 1
465     pand                m2, m1                          ; flat8in final value
466
467 %if %2 != 88
468     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
469     ; calc flat8out mask
470     mova                m8, [P7]
471     mova                m9, [P6]
472     ABSSUB_CMP          m1, m8, m11, m6, m4, m5         ; abs(p7 - p0) <= 1
473     ABSSUB_CMP          m7, m9, m11, m6, m4, m5         ; abs(p6 - p0) <= 1
474     pand                m1, m7
475     mova                m8, [P5]
476     mova                m9, [P4]
477     ABSSUB_CMP          m7, m8, m11, m6, m4, m5         ; abs(p5 - p0) <= 1
478     pand                m1, m7
479     ABSSUB_CMP          m7, m9, m11, m6, m4, m5         ; abs(p4 - p0) <= 1
480     pand                m1, m7
481     mova                m14, [Q4]
482     mova                m15, [Q5]
483     ABSSUB_CMP          m7, m14, m12, m6, m4, m5        ; abs(q4 - q0) <= 1
484     pand                m1, m7
485     ABSSUB_CMP          m7, m15, m12, m6, m4, m5        ; abs(q5 - q0) <= 1
486     pand                m1, m7
487     mova                m14, [Q6]
488     mova                m15, [Q7]
489     ABSSUB_CMP          m7, m14, m12, m6, m4, m5        ; abs(q4 - q0) <= 1
490     pand                m1, m7
491     ABSSUB_CMP          m7, m15, m12, m6, m4, m5        ; abs(q5 - q0) <= 1
492     pand                m1, m7                          ; flat8out final value
493 %endif
494
495     ; if (fm) {
496     ;     if (out && in) filter_14()
497     ;     else if (in)   filter_6()
498     ;     else if (hev)  filter_2()
499     ;     else           filter_4()
500     ; }
501     ;
502     ; f14:                                                                            fm &  out &  in
503     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
504     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
505     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
506
507     ; (m0: hev, [m1: flat8out], m2: flat8in, m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
508     ; filter2()
509     mova                m6, [pb_80]
510     pxor                m15, m12, m6                    ; q0 ^ 0x80
511     pxor                m14, m11, m6                    ; p0 ^ 0x80
512     psubsb              m15, m14                        ; (signed) q0 - p0
513     pxor                m4, m10, m6                     ; p1 ^ 0x80
514     pxor                m5, m13, m6                     ; q1 ^ 0x80
515     psubsb              m4, m5                          ; (signed) p1 - q1
516     paddsb              m4, m15                         ;   (q0 - p0) + (p1 - q1)
517     paddsb              m4, m15                         ; 2*(q0 - p0) + (p1 - q1)
518     paddsb              m4, m15                         ; 3*(q0 - p0) + (p1 - q1)
519     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
520     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
521     mova                m14, [pb_10]                    ; will be reused in filter4()
522     SRSHIFT3B_2X        m6, m4, m14, m7                 ; f1 and f2 sign byte shift by 3
523     SIGN_SUB            m7, m12, m6, m5, m9             ; m7 = q0 - f1
524     SIGN_ADD            m8, m11, m4, m5, m9             ; m8 = p0 + f2
525     pandn               m6, m2, m3                      ;  ~mask(in) & mask(fm)
526     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
527     MASK_APPLY          m7, m12, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
528     MASK_APPLY          m8, m11, m6, m5                 ; m8 = filter2(p0) & mask / we write it in filter4()
529
530     ; (m0: hev, [m1: flat8out], m2: flat8in, m3: fm, m7..m8: q0' p0', m10..13: p1 p0 q0 q1, m14: pb_10, m15: q0-p0)
531     ; filter4()
532     mova                m4, m15
533     paddsb              m15, m4                         ; 2 * (q0 - p0)
534     paddsb              m15, m4                         ; 3 * (q0 - p0)
535     paddsb              m6, m15, [pb_4]                 ; m6:  f1 = clip(f + 4, 127)
536     paddsb              m15, [pb_3]                     ; m15: f2 = clip(f + 3, 127)
537     SRSHIFT3B_2X        m6, m15, m14, m9                ; f1 and f2 sign byte shift by 3
538     pandn               m5, m2, m3                      ;               ~mask(in) & mask(fm)
539     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
540     SIGN_SUB            m9, m12, m6, m4, m14            ; q0 - f1
541     MASK_APPLY          m9, m7, m0, m5                  ; m9 = filter4(q0) & mask
542     mova                [Q0], m9
543     SIGN_ADD            m7, m11, m15, m4, m14           ; p0 + f2
544     MASK_APPLY          m7, m8, m0, m5                  ; m7 = filter4(p0) & mask
545     mova                [P0], m7
546     paddb               m6, [pb_80]                     ;
547     pxor                m8, m8                          ;   f=(f1+1)>>1
548     pavgb               m6, m8                          ;
549     psubb               m6, [pb_40]                     ;
550     SIGN_ADD            m7, m10, m6, m8, m9             ; p1 + f
551     SIGN_SUB            m4, m13, m6, m8, m9             ; q1 - f
552     MASK_APPLY          m7, m10, m0, m14                ; m7 = filter4(p1)
553     MASK_APPLY          m4, m13, m0, m14                ; m4 = filter4(q1)
554     mova                [P1], m7
555     mova                [Q1], m4
556
557     ; ([m1: flat8out], m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
558     ; filter6()
559     pxor                m0, m0
560 %if %2 == 88
561     pand                m3, m2
562 %else
563     pand                m2, m3                          ;               mask(fm) & mask(in)
564     pandn               m3, m1, m2                      ; ~mask(out) & (mask(fm) & mask(in))
565 %endif
566     mova               m14, [P3]
567     mova               m15, [P2]
568     mova                m8, [Q2]
569     mova                m9, [Q3]
570     FILTER_INIT         m4, m5, m6, m7, [P2], 6,                     m3, m15    ; [p2]
571     FILTER_UPDATE       m6, m7, m4, m5, [P1], m14, m15, m10, m13, 3, m3         ; [p1] -p3 -p2 +p1 +q1
572     FILTER_UPDATE       m4, m5, m6, m7, [P0], m14, m10, m11,  m8, 3, m3         ; [p0] -p3 -p1 +p0 +q2
573     FILTER_UPDATE       m6, m7, m4, m5, [Q0], m14, m11, m12,  m9, 3, m3         ; [q0] -p3 -p0 +q0 +q3
574     FILTER_UPDATE       m4, m5, m6, m7, [Q1], m15, m12, m13,  m9, 3, m3         ; [q1] -p2 -q0 +q1 +q3
575     FILTER_UPDATE       m6, m7, m4, m5, [Q2], m10, m13,  m8,  m9, 3, m3,  m8    ; [q2] -p1 -q1 +q2 +q3
576
577     ; (m0: 0, [m1: flat8out], m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
578     ; filter14()
579     ;
580     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
581     ;
582     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
583     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
584     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
585     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
586     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
587     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
588     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
589     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
590     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
591     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
592     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
593     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
594     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
595     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
596     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
597
598 %if %2 != 88
599     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
600     mova            m2, [P7]
601     mova            m3, [P6]
602     mova            m8, [P5]
603     mova            m9, [P4]
604     FILTER_INIT     m4, m5, m6, m7, [P6],  14,                   m1,  m3
605     FILTER_UPDATE   m6, m7, m4, m5, [P5],  m2,  m3,  m8, m13, 4, m1,  m8                ; [p5] -p7 -p6 +p5 +q1
606     FILTER_UPDATE   m4, m5, m6, m7, [P4],  m2,  m8,  m9, m13, 4, m1,  m9, m13, [Q2]     ; [p4] -p7 -p5 +p4 +q2
607     FILTER_UPDATE   m6, m7, m4, m5, [P3],  m2,  m9, m14, m13, 4, m1, m14, m13, [Q3]     ; [p3] -p7 -p4 +p3 +q3
608     FILTER_UPDATE   m4, m5, m6, m7, [P2],  m2, m14, m15, m13, 4, m1,      m13, [Q4]     ; [p2] -p7 -p3 +p2 +q4
609     FILTER_UPDATE   m6, m7, m4, m5, [P1],  m2, m15, m10, m13, 4, m1,      m13, [Q5]     ; [p1] -p7 -p2 +p1 +q5
610     FILTER_UPDATE   m4, m5, m6, m7, [P0],  m2, m10, m11, m13, 4, m1,      m13, [Q6]     ; [p0] -p7 -p1 +p0 +q6
611     FILTER_UPDATE   m6, m7, m4, m5, [Q0],  m2, m11, m12, m13, 4, m1,      m13, [Q7]     ; [q0] -p7 -p0 +q0 +q7
612     FILTER_UPDATE   m4, m5, m6, m7, [Q1],  m3, m12,  m2, m13, 4, m1,       m2, [Q1]     ; [q1] -p6 -q0 +q1 +q7
613     FILTER_UPDATE   m6, m7, m4, m5, [Q2],  m8,  m2,  m3, m13, 4, m1,       m3, [Q2]     ; [q2] -p5 -q1 +q2 +q7
614     FILTER_UPDATE   m4, m5, m6, m7, [Q3],  m9,  m3,  m8, m13, 4, m1,  m8,  m8, [Q3]     ; [q3] -p4 -q2 +q3 +q7
615     FILTER_UPDATE   m6, m7, m4, m5, [Q4], m14,  m8,  m9, m13, 4, m1,  m9,  m9, [Q4]     ; [q4] -p3 -q3 +q4 +q7
616     FILTER_UPDATE   m4, m5, m6, m7, [Q5], m15,  m9, m14, m13, 4, m1, m14, m14, [Q5]     ; [q5] -p2 -q4 +q5 +q7
617     FILTER_UPDATE   m6, m7, m4, m5, [Q6], m10, m14, m15, m13, 4, m1, m15, m15, [Q6]     ; [q6] -p1 -q5 +q6 +q7
618 %endif
619
620 %ifidn %1, h
621 %if %2 != 88
622     mova                    m0, [P7]
623     mova                    m1, [P6]
624     mova                    m2, [P5]
625     mova                    m3, [P4]
626     mova                    m4, [P3]
627     mova                    m5, [P2]
628     mova                    m6, [P1]
629     mova                    m7, [P0]
630     mova                    m8, [Q0]
631     mova                    m9, [Q1]
632     mova                   m10, [Q2]
633     mova                   m11, [Q3]
634     mova                   m12, [Q4]
635     mova                   m13, [Q5]
636     mova                   m14, [Q6]
637     mova                   m15, [Q7]
638     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
639     DEFINE_REAL_P7_TO_Q7
640     movu  [P7],  m0
641     movu  [P6],  m1
642     movu  [P5],  m2
643     movu  [P4],  m3
644     movu  [P3],  m4
645     movu  [P2],  m5
646     movu  [P1],  m6
647     movu  [P0],  m7
648     movu  [Q0],  m8
649     movu  [Q1],  m9
650     movu  [Q2], m10
651     movu  [Q3], m11
652     movu  [Q4], m12
653     movu  [Q5], m13
654     movu  [Q6], m14
655     movu  [Q7], m15
656 %else
657     ; the following code do a transpose of 8 full lines to 16 half
658     ; lines (high part). It is inlined to avoid the need of a staging area
659     mova                    m0, [P3]
660     mova                    m1, [P2]
661     mova                    m2, [P1]
662     mova                    m3, [P0]
663     mova                    m4, [Q0]
664     mova                    m5, [Q1]
665     mova                    m6, [Q2]
666     mova                    m7, [Q3]
667     DEFINE_REAL_P7_TO_Q7
668     SBUTTERFLY  bw,  0,  1, 8
669     SBUTTERFLY  bw,  2,  3, 8
670     SBUTTERFLY  bw,  4,  5, 8
671     SBUTTERFLY  bw,  6,  7, 8
672     SBUTTERFLY  wd,  0,  2, 8
673     SBUTTERFLY  wd,  1,  3, 8
674     SBUTTERFLY  wd,  4,  6, 8
675     SBUTTERFLY  wd,  5,  7, 8
676     SBUTTERFLY  dq,  0,  4, 8
677     SBUTTERFLY  dq,  1,  5, 8
678     SBUTTERFLY  dq,  2,  6, 8
679     SBUTTERFLY  dq,  3,  7, 8
680     movh  [P7], m0
681     punpckhqdq m0, m8
682     movh  [P6], m0
683     movh  [Q0], m1
684     punpckhqdq  m1, m9
685     movh  [Q1], m1
686     movh  [P3], m2
687     punpckhqdq  m2, m10
688     movh  [P2], m2
689     movh  [Q4], m3
690     punpckhqdq m3, m11
691     movh  [Q5], m3
692     movh  [P5], m4
693     punpckhqdq m4, m12
694     movh  [P4], m4
695     movh  [Q2], m5
696     punpckhqdq m5, m13
697     movh  [Q3], m5
698     movh  [P1], m6
699     punpckhqdq m6, m14
700     movh  [P0], m6
701     movh  [Q6], m7
702     punpckhqdq m7, m8
703     movh  [Q7], m7
704 %endif
705 %endif
706
707     RET
708 %endmacro
709
710 %macro LPF_16_16_VH 1
711 INIT_XMM %1
712 cglobal vp9_loop_filter_v_16_16, 5,10,16,      dst, stride, E, I, H, mstride, dst1, dst2, stride3, mstride3
713     LOOPFILTER v, 16
714 cglobal vp9_loop_filter_h_16_16, 5,10,16, 256, dst, stride, E, I, H, mstride, dst1, dst2, stride3, mstride3
715     LOOPFILTER h, 16
716 %endmacro
717
718 %macro LPF_88_16_VH 1
719 INIT_XMM %1
720 cglobal vp9_loop_filter_v_88_16, 5,10,16,      dst, stride, E, I, H, mstride, dst1, dst2, stride3, mstride3
721     LOOPFILTER v, 88
722 cglobal vp9_loop_filter_h_88_16, 5,10,16, 256, dst, stride, E, I, H, mstride, dst1, dst2, stride3, mstride3
723     LOOPFILTER h, 88
724 %endmacro
725
726 LPF_16_16_VH sse2
727 LPF_16_16_VH ssse3
728 LPF_16_16_VH avx
729
730 LPF_88_16_VH ssse3
731 LPF_88_16_VH avx
732
733 %endif ; x86-64