vp9lpf/x86: move variable assigned inside macro branch.
[ffmpeg.git] / libavcodec / x86 / vp9lpf.asm
1 ;******************************************************************************
2 ;* VP9 loop filter SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
5 ;*
6 ;* This file is part of Libav.
7 ;*
8 ;* Libav is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* Libav is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with Libav; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23
24 %include "libavutil/x86/x86util.asm"
25
26 %if ARCH_X86_64
27
28 SECTION_RODATA
29
30 cextern pb_3
31 cextern pb_80
32
33 pb_4:   times 16 db 0x04
34 pb_10:  times 16 db 0x10
35 pb_40:  times 16 db 0x40
36 pb_81:  times 16 db 0x81
37 pb_f8:  times 16 db 0xf8
38 pb_fe:  times 16 db 0xfe
39 pb_ff:  times 16 db 0xff
40
41 pw_4:   times  8 dw 4
42 pw_8:   times  8 dw 8
43
44 ; with mix functions, two 8-bit thresholds are stored in a 16-bit storage,
45 ; the following mask is used to splat both in the same register
46 mask_mix: times 8 db 0
47           times 8 db 1
48
49 mask_mix84: times 8 db 0xff
50             times 8 db 0x00
51 mask_mix48: times 8 db 0x00
52             times 8 db 0xff
53
54 SECTION .text
55
56 ; %1 = abs(%2-%3)
57 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
58     psubusb             %1, %3, %2
59     psubusb             %4, %2, %3
60     por                 %1, %4
61 %endmacro
62
63 ; %1 = %1>%2
64 %macro CMP_GT 2-3 ; src/dst, cmp, pb_80
65 %if %0 == 3
66     pxor                %1, %3
67 %endif
68     pcmpgtb             %1, %2
69 %endmacro
70
71 ; %1 = abs(%2-%3) > %4
72 %macro ABSSUB_GT 5-6 [pb_80]; dst, src1, src2, cmp, tmp, [pb_80]
73     ABSSUB              %1, %2, %3, %5      ; dst = abs(src1-src2)
74     CMP_GT              %1, %4, %6          ; dst > cmp
75 %endmacro
76
77 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
78     pand                %1, %3              ; new &= mask
79     pandn               %4, %3, %2          ; tmp = ~mask & old
80     por                 %1, %4              ; new&mask | old&~mask
81 %endmacro
82
83 %macro FILTER_SUBx2_ADDx2 8 ; %1=dst %2=h/l %3=cache %4=sub1 %5=sub2 %6=add1 %7=add2 %8=rshift
84     punpck%2bw          %3, %4, m0
85     psubw               %1, %3
86     punpck%2bw          %3, %5, m0
87     psubw               %1, %3
88     punpck%2bw          %3, %6, m0
89     paddw               %1, %3
90     punpck%2bw          %3, %7, m0
91     paddw               %3, %1
92     psraw               %1, %3, %8
93 %endmacro
94
95 %macro FILTER_INIT 8 ; tmp1, tmp2, cacheL, cacheH, dstp, filterid, mask, source
96     FILTER%6_INIT       %1, l, %3
97     FILTER%6_INIT       %2, h, %4
98     packuswb            %1, %2
99     MASK_APPLY          %1, %8, %7, %2
100     mova                %5, %1
101 %endmacro
102
103 %macro FILTER_UPDATE 11-14 ; tmp1, tmp2, cacheL, cacheH, dstp, -, -, +, +, rshift, mask, [source], [preload reg + value]
104 %if %0 == 13 ; no source + preload
105     mova                %12, %13
106 %elif %0 == 14 ; source + preload
107     mova                %13, %14
108 %endif
109     FILTER_SUBx2_ADDx2  %1, l, %3, %6, %7, %8, %9, %10
110     FILTER_SUBx2_ADDx2  %2, h, %4, %6, %7, %8, %9, %10
111     packuswb            %1, %2
112 %if %0 == 12 || %0 == 14
113     MASK_APPLY          %1, %12, %11, %2
114 %else
115     MASK_APPLY          %1, %5, %11, %2
116 %endif
117     mova                %5, %1
118 %endmacro
119
120 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
121     mova                %4, [pb_f8]
122     pand                %1, %4
123     pand                %2, %4
124     psrlq               %1, 3
125     psrlq               %2, 3
126     pxor                %1, %3
127     pxor                %2, %3
128     psubb               %1, %3
129     psubb               %2, %3
130 %endmacro
131
132 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
133     pxor                %3, %3
134     pxor                %2, %2
135     pcmpgtb             %3, %1                          ; i8 < 0 mask
136     psubb               %2, %1                          ; neg values (only the originally - will be kept)
137     pand                %2, %3                          ; negative values of i8 (but stored as +)
138     pandn               %3, %1                          ; positive values of i8
139 %endmacro
140
141 ; clip_u8(u8 + i8)
142 %macro SIGN_ADD 5 ; dst, u8, i8, tmp1, tmp2
143     EXTRACT_POS_NEG     %3, %4, %5
144     psubusb             %1, %2, %4                      ; sub the negatives
145     paddusb             %1, %5                          ; add the positives
146 %endmacro
147
148 ; clip_u8(u8 - i8)
149 %macro SIGN_SUB 5 ; dst, u8, i8, tmp1, tmp2
150     EXTRACT_POS_NEG     %3, %4, %5
151     psubusb             %1, %2, %5                      ; sub the positives
152     paddusb             %1, %4                          ; add the negatives
153 %endmacro
154
155 %macro FILTER6_INIT 3 ; %1=dst %2=h/l %3=cache
156     punpck%2bw          %1, m14, m0                     ; p3: B->W
157     paddw               %3, %1, %1                      ; p3*2
158     paddw               %3, %1                          ; p3*3
159     punpck%2bw          %1, m15, m0                     ; p2: B->W
160     paddw               %3, %1                          ; p3*3 + p2
161     paddw               %3, %1                          ; p3*3 + p2*2
162     punpck%2bw          %1, m10, m0                     ; p1: B->W
163     paddw               %3, %1                          ; p3*3 + p2*2 + p1
164     punpck%2bw          %1, m11, m0                     ; p0: B->W
165     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0
166     punpck%2bw          %1, m12, m0                     ; q0: B->W
167     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0 + q0
168     paddw               %3, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
169     psraw               %1, %3, 3                       ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
170 %endmacro
171
172 %macro FILTER14_INIT 3 ; %1=dst %2=h/l %3=cache
173     punpck%2bw          %1, m2, m0                      ; p7: B->W
174     psllw               %3, %1, 3                       ; p7*8
175     psubw               %3, %1                          ; p7*7
176     punpck%2bw          %1, m3, m0                      ; p6: B->W
177     paddw               %3, %1                          ; p7*7 + p6
178     paddw               %3, %1                          ; p7*7 + p6*2
179     punpck%2bw          %1, m8, m0                      ; p5: B->W
180     paddw               %3, %1                          ; p7*7 + p6*2 + p5
181     punpck%2bw          %1, m9, m0                      ; p4: B->W
182     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4
183     punpck%2bw          %1, m14, m0                     ; p3: B->W
184     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4 + p3
185     punpck%2bw          %1, m15, m0                     ; p2: B->W
186     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p2
187     punpck%2bw          %1, m10, m0                     ; p1: B->W
188     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p1
189     punpck%2bw          %1, m11, m0                     ; p0: B->W
190     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p0
191     punpck%2bw          %1, m12, m0                     ; q0: B->W
192     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p0 + q0
193     paddw               %3, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
194     psraw               %1, %3, 4                       ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
195 %endmacro
196
197 %macro TRANSPOSE16x16B 17
198     mova %17, m%16
199     SBUTTERFLY bw,  %1,  %2,  %16
200     SBUTTERFLY bw,  %3,  %4,  %16
201     SBUTTERFLY bw,  %5,  %6,  %16
202     SBUTTERFLY bw,  %7,  %8,  %16
203     SBUTTERFLY bw,  %9,  %10, %16
204     SBUTTERFLY bw,  %11, %12, %16
205     SBUTTERFLY bw,  %13, %14, %16
206     mova m%16,  %17
207     mova  %17, m%14
208     SBUTTERFLY bw,  %15, %16, %14
209     SBUTTERFLY wd,  %1,  %3,  %14
210     SBUTTERFLY wd,  %2,  %4,  %14
211     SBUTTERFLY wd,  %5,  %7,  %14
212     SBUTTERFLY wd,  %6,  %8,  %14
213     SBUTTERFLY wd,  %9,  %11, %14
214     SBUTTERFLY wd,  %10, %12, %14
215     SBUTTERFLY wd,  %13, %15, %14
216     mova m%14,  %17
217     mova  %17, m%12
218     SBUTTERFLY wd,  %14, %16, %12
219     SBUTTERFLY dq,  %1,  %5,  %12
220     SBUTTERFLY dq,  %2,  %6,  %12
221     SBUTTERFLY dq,  %3,  %7,  %12
222     SBUTTERFLY dq,  %4,  %8,  %12
223     SBUTTERFLY dq,  %9,  %13, %12
224     SBUTTERFLY dq,  %10, %14, %12
225     SBUTTERFLY dq,  %11, %15, %12
226     mova m%12, %17
227     mova  %17, m%8
228     SBUTTERFLY dq,  %12, %16, %8
229     SBUTTERFLY qdq, %1,  %9,  %8
230     SBUTTERFLY qdq, %2,  %10, %8
231     SBUTTERFLY qdq, %3,  %11, %8
232     SBUTTERFLY qdq, %4,  %12, %8
233     SBUTTERFLY qdq, %5,  %13, %8
234     SBUTTERFLY qdq, %6,  %14, %8
235     SBUTTERFLY qdq, %7,  %15, %8
236     mova m%8, %17
237     mova %17, m%1
238     SBUTTERFLY qdq, %8,  %16, %1
239     mova m%1, %17
240     SWAP %2,  %9
241     SWAP %3,  %5
242     SWAP %4,  %13
243     SWAP %6,  %11
244     SWAP %8,  %15
245     SWAP %12, %14
246 %endmacro
247
248 ; transpose 16 half lines (high part) to 8 full centered lines
249 %macro TRANSPOSE16x8B 16
250     punpcklbw   m%1,  m%2
251     punpcklbw   m%3,  m%4
252     punpcklbw   m%5,  m%6
253     punpcklbw   m%7,  m%8
254     punpcklbw   m%9,  m%10
255     punpcklbw   m%11, m%12
256     punpcklbw   m%13, m%14
257     punpcklbw   m%15, m%16
258     SBUTTERFLY  wd,  %1,  %3,  %2
259     SBUTTERFLY  wd,  %5,  %7,  %2
260     SBUTTERFLY  wd,  %9,  %11, %2
261     SBUTTERFLY  wd,  %13, %15, %2
262     SBUTTERFLY  dq,  %1,  %5,  %2
263     SBUTTERFLY  dq,  %3,  %7,  %2
264     SBUTTERFLY  dq,  %9,  %13, %2
265     SBUTTERFLY  dq,  %11, %15, %2
266     SBUTTERFLY  qdq, %1,  %9,  %2
267     SBUTTERFLY  qdq, %3,  %11, %2
268     SBUTTERFLY  qdq, %5,  %13, %2
269     SBUTTERFLY  qdq, %7,  %15, %2
270     SWAP %5, %1
271     SWAP %6, %9
272     SWAP %7, %1
273     SWAP %8, %13
274     SWAP %9, %3
275     SWAP %10, %11
276     SWAP %11, %1
277     SWAP %12, %15
278 %endmacro
279
280 %macro DEFINE_REAL_P7_TO_Q7 0-1 0
281 %define P7 dstq  + 4*mstrideq  + %1
282 %define P6 dstq  +   mstride3q + %1
283 %define P5 dstq  + 2*mstrideq  + %1
284 %define P4 dstq  +   mstrideq  + %1
285 %define P3 dstq                + %1
286 %define P2 dstq  +    strideq  + %1
287 %define P1 dstq  + 2* strideq  + %1
288 %define P0 dstq  +    stride3q + %1
289 %define Q0 dstq  + 4* strideq  + %1
290 %define Q1 dst2q +   mstride3q + %1
291 %define Q2 dst2q + 2*mstrideq  + %1
292 %define Q3 dst2q +   mstrideq  + %1
293 %define Q4 dst2q               + %1
294 %define Q5 dst2q +    strideq  + %1
295 %define Q6 dst2q + 2* strideq  + %1
296 %define Q7 dst2q +    stride3q + %1
297 %endmacro
298
299 ; ..............AB -> AAAAAAAABBBBBBBB
300 %macro SPLATB_MIX 1-2 [mask_mix]
301 %if cpuflag(ssse3)
302     pshufb     %1, %2
303 %else
304     punpcklbw  %1, %1
305     punpcklwd  %1, %1
306     punpckldq  %1, %1
307 %endif
308 %endmacro
309
310 %macro LOOPFILTER 3 ; %1=v/h %2=size1 %3=stack
311 %if UNIX64
312 cglobal vp9_loop_filter_%1_%2_16, 5, 9, 16, %3, dst, stride, E, I, H, mstride, dst2, stride3, mstride3
313 %else
314 %if WIN64
315 cglobal vp9_loop_filter_%1_%2_16, 4, 8, 16, %3, dst, stride, E, I, mstride, dst2, stride3, mstride3
316 %else
317 cglobal vp9_loop_filter_%1_%2_16, 2, 6, 16, %3, dst, stride, mstride, dst2, stride3, mstride3
318 %define Ed dword r2m
319 %define Id dword r3m
320 %endif
321 %define Hd dword r4m
322 %endif
323
324     mov               mstrideq, strideq
325     neg               mstrideq
326
327     lea               stride3q, [strideq*3]
328     lea              mstride3q, [mstrideq*3]
329
330 %ifidn %1, h
331 %if %2 > 16
332 %define movx movh
333     lea                   dstq, [dstq + 4*strideq - 4]
334 %else
335 %define movx movu
336     lea                   dstq, [dstq + 4*strideq - 8] ; go from top center (h pos) to center left (v pos)
337 %endif
338     lea                  dst2q, [dstq + 8*strideq]
339 %else
340     lea                   dstq, [dstq + 4*mstrideq]
341     lea                  dst2q, [dstq + 8*strideq]
342 %endif
343
344     DEFINE_REAL_P7_TO_Q7
345
346 %ifidn %1, h
347     movx                    m0, [P7]
348     movx                    m1, [P6]
349     movx                    m2, [P5]
350     movx                    m3, [P4]
351     movx                    m4, [P3]
352     movx                    m5, [P2]
353     movx                    m6, [P1]
354     movx                    m7, [P0]
355     movx                    m8, [Q0]
356     movx                    m9, [Q1]
357     movx                   m10, [Q2]
358     movx                   m11, [Q3]
359     movx                   m12, [Q4]
360     movx                   m13, [Q5]
361     movx                   m14, [Q6]
362     movx                   m15, [Q7]
363 %define P7 rsp +   0
364 %define P6 rsp +  16
365 %define P5 rsp +  32
366 %define P4 rsp +  48
367 %define P3 rsp +  64
368 %define P2 rsp +  80
369 %define P1 rsp +  96
370 %define P0 rsp + 112
371 %define Q0 rsp + 128
372 %define Q1 rsp + 144
373 %define Q2 rsp + 160
374 %define Q3 rsp + 176
375 %define Q4 rsp + 192
376 %define Q5 rsp + 208
377 %define Q6 rsp + 224
378 %define Q7 rsp + 240
379
380 %if %2 == 16
381     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
382     mova           [P7],  m0
383     mova           [P6],  m1
384     mova           [P5],  m2
385     mova           [P4],  m3
386 %else
387     TRANSPOSE16x8B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15
388 %endif
389     mova           [P3],  m4
390     mova           [P2],  m5
391     mova           [P1],  m6
392     mova           [P0],  m7
393     mova           [Q0],  m8
394     mova           [Q1],  m9
395     mova           [Q2], m10
396     mova           [Q3], m11
397 %if %2 == 16
398     mova           [Q4], m12
399     mova           [Q5], m13
400     mova           [Q6], m14
401     mova           [Q7], m15
402 %endif
403 %endif
404
405     ; calc fm mask
406 %if %2 == 16
407 %if cpuflag(ssse3)
408     pxor                m0, m0
409 %endif
410     SPLATB_REG          m2, I, m0                       ; I I I I ...
411     SPLATB_REG          m3, E, m0                       ; E E E E ...
412 %else
413 %if cpuflag(ssse3)
414     mova                m0, [mask_mix]
415 %endif
416     movd                m2, Id
417     movd                m3, Ed
418     SPLATB_MIX          m2, m0
419     SPLATB_MIX          m3, m0
420 %endif
421     mova                m0, [pb_80]
422     pxor                m2, m0
423     pxor                m3, m0
424 %ifidn %1, v
425     mova                m8, [P3]
426     mova                m9, [P2]
427     mova               m10, [P1]
428     mova               m11, [P0]
429     mova               m12, [Q0]
430     mova               m13, [Q1]
431     mova               m14, [Q2]
432     mova               m15, [Q3]
433 %else
434     ; In case of horizontal, P3..Q3 are already present in some registers due
435     ; to the previous transpose, so we just swap registers.
436     SWAP                 8,  4, 12
437     SWAP                 9,  5, 13
438     SWAP                10,  6, 14
439     SWAP                11,  7, 15
440 %endif
441     ABSSUB_GT           m5,  m8,  m9, m2, m7, m0        ; m5 = abs(p3-p2) <= I
442     ABSSUB_GT           m1,  m9, m10, m2, m7, m0        ; m1 = abs(p2-p1) <= I
443     por                 m5, m1
444     ABSSUB_GT           m1, m10, m11, m2, m7, m0        ; m1 = abs(p1-p0) <= I
445     por                 m5, m1
446     ABSSUB_GT           m1, m12, m13, m2, m7, m0        ; m1 = abs(q1-q0) <= I
447     por                 m5, m1
448     ABSSUB_GT           m1, m13, m14, m2, m7, m0        ; m1 = abs(q2-q1) <= I
449     por                 m5, m1
450     ABSSUB_GT           m1, m14, m15, m2, m7, m0        ; m1 = abs(q3-q2) <= I
451     por                 m5, m1
452     ABSSUB              m1, m11, m12, m7                ; abs(p0-q0)
453     paddusb             m1, m1                          ; abs(p0-q0) * 2
454     ABSSUB              m2, m10, m13, m7                ; abs(p1-q1)
455     pand                m2, [pb_fe]                     ; drop lsb so shift can work
456     psrlq               m2, 1                           ; abs(p1-q1)/2
457     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
458     pxor                m1, m0
459     pcmpgtb             m1, m3
460     por                 m1, m5                          ; fm final value
461     SWAP                 1, 3
462     pxor                m3, [pb_ff]
463
464     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
465     ; calc flat8in (if not 44_16) and hev masks
466 %if %2 != 44
467     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
468     ABSSUB_GT           m2, m8, m11, m6, m5             ; abs(p3 - p0) <= 1
469     mova                m8, [pb_80]
470     ABSSUB_GT           m1, m9, m11, m6, m5, m8         ; abs(p2 - p0) <= 1
471     por                 m2, m1
472     ABSSUB              m4, m10, m11, m5                ; abs(p1 - p0)
473 %if %2 == 16
474 %if cpuflag(ssse3)
475     pxor                m0, m0
476 %endif
477     SPLATB_REG          m7, H, m0                       ; H H H H ...
478 %else
479     movd                m7, Hd
480     SPLATB_MIX          m7
481 %endif
482     pxor                m7, m8
483     pxor                m4, m8
484     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
485     CMP_GT              m4, m6                          ; abs(p1 - p0) <= 1
486     por                 m2, m4                          ; (flat8in)
487     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
488     pxor                m4, m8
489     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
490     por                 m0, m5                          ; hev final value
491     CMP_GT              m4, m6                          ; abs(q1 - q0) <= 1
492     por                 m2, m4                          ; (flat8in)
493     ABSSUB_GT           m1, m14, m12, m6, m5, m8        ; abs(q2 - q0) <= 1
494     por                 m2, m1
495     ABSSUB_GT           m1, m15, m12, m6, m5, m8        ; abs(q3 - q0) <= 1
496     por                 m2, m1                          ; flat8in final value
497     pxor                m2, [pb_ff]
498 %if %2 == 84 || %2 == 48
499     pand                m2, [mask_mix%2]
500 %endif
501 %else
502     mova                m6, [pb_80]
503     movd                m7, Hd
504     SPLATB_MIX          m7
505     pxor                m7, m6
506     ABSSUB              m4, m10, m11, m1                ; abs(p1 - p0)
507     pxor                m4, m6
508     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
509     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
510     pxor                m4, m6
511     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
512     por                 m0, m5                          ; hev final value
513 %endif
514
515 %if %2 == 16
516     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
517     ; calc flat8out mask
518     mova                m8, [P7]
519     mova                m9, [P6]
520     ABSSUB_GT           m1, m8, m11, m6, m5             ; abs(p7 - p0) <= 1
521     ABSSUB_GT           m7, m9, m11, m6, m5             ; abs(p6 - p0) <= 1
522     por                 m1, m7
523     mova                m8, [P5]
524     mova                m9, [P4]
525     ABSSUB_GT           m7, m8, m11, m6, m5             ; abs(p5 - p0) <= 1
526     por                 m1, m7
527     ABSSUB_GT           m7, m9, m11, m6, m5             ; abs(p4 - p0) <= 1
528     por                 m1, m7
529     mova                m14, [Q4]
530     mova                m15, [Q5]
531     ABSSUB_GT           m7, m14, m12, m6, m5            ; abs(q4 - q0) <= 1
532     por                 m1, m7
533     ABSSUB_GT           m7, m15, m12, m6, m5            ; abs(q5 - q0) <= 1
534     por                 m1, m7
535     mova                m14, [Q6]
536     mova                m15, [Q7]
537     ABSSUB_GT           m7, m14, m12, m6, m5            ; abs(q4 - q0) <= 1
538     por                 m1, m7
539     ABSSUB_GT           m7, m15, m12, m6, m5            ; abs(q5 - q0) <= 1
540     por                 m1, m7                          ; flat8out final value
541     pxor                m1, [pb_ff]
542 %endif
543
544     ; if (fm) {
545     ;     if (out && in) filter_14()
546     ;     else if (in)   filter_6()
547     ;     else if (hev)  filter_2()
548     ;     else           filter_4()
549     ; }
550     ;
551     ; f14:                                                                            fm &  out &  in
552     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
553     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
554     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
555
556     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
557     ; filter2()
558 %if %2 != 44
559     mova                m6, [pb_80]                     ; already in m6 if 44_16
560 %endif
561     pxor                m15, m12, m6                    ; q0 ^ 0x80
562     pxor                m14, m11, m6                    ; p0 ^ 0x80
563     psubsb              m15, m14                        ; (signed) q0 - p0
564     pxor                m4, m10, m6                     ; p1 ^ 0x80
565     pxor                m5, m13, m6                     ; q1 ^ 0x80
566     psubsb              m4, m5                          ; (signed) p1 - q1
567     paddsb              m4, m15                         ;   (q0 - p0) + (p1 - q1)
568     paddsb              m4, m15                         ; 2*(q0 - p0) + (p1 - q1)
569     paddsb              m4, m15                         ; 3*(q0 - p0) + (p1 - q1)
570     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
571     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
572     mova                m14, [pb_10]                    ; will be reused in filter4()
573     SRSHIFT3B_2X        m6, m4, m14, m7                 ; f1 and f2 sign byte shift by 3
574     SIGN_SUB            m7, m12, m6, m5, m9             ; m7 = q0 - f1
575     SIGN_ADD            m8, m11, m4, m5, m9             ; m8 = p0 + f2
576 %if %2 != 44
577     pandn               m6, m2, m3                      ;  ~mask(in) & mask(fm)
578     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
579 %else
580     pand                m6, m3, m0
581 %endif
582     MASK_APPLY          m7, m12, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
583     MASK_APPLY          m8, m11, m6, m5                 ; m8 = filter2(p0) & mask / we write it in filter4()
584
585     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m7..m8: q0' p0', m10..13: p1 p0 q0 q1, m14: pb_10, m15: q0-p0)
586     ; filter4()
587     mova                m4, m15
588     paddsb              m15, m4                         ; 2 * (q0 - p0)
589     paddsb              m15, m4                         ; 3 * (q0 - p0)
590     paddsb              m6, m15, [pb_4]                 ; m6:  f1 = clip(f + 4, 127)
591     paddsb              m15, [pb_3]                     ; m15: f2 = clip(f + 3, 127)
592     SRSHIFT3B_2X        m6, m15, m14, m9                ; f1 and f2 sign byte shift by 3
593 %if %2 != 44
594 %define p0tmp m7
595 %define q0tmp m9
596     pandn               m5, m2, m3                      ;               ~mask(in) & mask(fm)
597     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
598 %else
599 %define p0tmp m1
600 %define q0tmp m2
601     pandn               m0, m3
602 %endif
603     SIGN_SUB            q0tmp, m12, m6, m4, m14         ; q0 - f1
604     MASK_APPLY          q0tmp, m7, m0, m5               ; filter4(q0) & mask
605     mova                [Q0], q0tmp
606     SIGN_ADD            p0tmp, m11, m15, m4, m14        ; p0 + f2
607     MASK_APPLY          p0tmp, m8, m0, m5               ; filter4(p0) & mask
608     mova                [P0], p0tmp
609     paddb               m6, [pb_80]                     ;
610     pxor                m8, m8                          ;   f=(f1+1)>>1
611     pavgb               m6, m8                          ;
612     psubb               m6, [pb_40]                     ;
613     SIGN_ADD            m7, m10, m6, m8, m9             ; p1 + f
614     SIGN_SUB            m4, m13, m6, m8, m9             ; q1 - f
615     MASK_APPLY          m7, m10, m0, m14                ; m7 = filter4(p1)
616     MASK_APPLY          m4, m13, m0, m14                ; m4 = filter4(q1)
617     mova                [P1], m7
618     mova                [Q1], m4
619
620     ; ([m1: flat8out], m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
621     ; filter6()
622 %if %2 != 44
623     pxor                m0, m0
624 %if %2 > 16
625     pand                m3, m2
626 %else
627     pand                m2, m3                          ;               mask(fm) & mask(in)
628     pandn               m3, m1, m2                      ; ~mask(out) & (mask(fm) & mask(in))
629 %endif
630     mova               m14, [P3]
631     mova               m15, [P2]
632     mova                m8, [Q2]
633     mova                m9, [Q3]
634     FILTER_INIT         m4, m5, m6, m7, [P2], 6,                     m3, m15    ; [p2]
635     FILTER_UPDATE       m6, m7, m4, m5, [P1], m14, m15, m10, m13, 3, m3         ; [p1] -p3 -p2 +p1 +q1
636     FILTER_UPDATE       m4, m5, m6, m7, [P0], m14, m10, m11,  m8, 3, m3         ; [p0] -p3 -p1 +p0 +q2
637     FILTER_UPDATE       m6, m7, m4, m5, [Q0], m14, m11, m12,  m9, 3, m3         ; [q0] -p3 -p0 +q0 +q3
638     FILTER_UPDATE       m4, m5, m6, m7, [Q1], m15, m12, m13,  m9, 3, m3         ; [q1] -p2 -q0 +q1 +q3
639     FILTER_UPDATE       m6, m7, m4, m5, [Q2], m10, m13,  m8,  m9, 3, m3,  m8    ; [q2] -p1 -q1 +q2 +q3
640 %endif
641
642     ; (m0: 0, [m1: flat8out], m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
643     ; filter14()
644     ;
645     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
646     ;
647     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
648     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
649     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
650     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
651     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
652     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
653     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
654     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
655     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
656     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
657     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
658     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
659     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
660     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
661     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
662
663 %if %2 == 16
664     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
665     mova            m2, [P7]
666     mova            m3, [P6]
667     mova            m8, [P5]
668     mova            m9, [P4]
669     FILTER_INIT     m4, m5, m6, m7, [P6],  14,                   m1,  m3
670     FILTER_UPDATE   m6, m7, m4, m5, [P5],  m2,  m3,  m8, m13, 4, m1,  m8                ; [p5] -p7 -p6 +p5 +q1
671     FILTER_UPDATE   m4, m5, m6, m7, [P4],  m2,  m8,  m9, m13, 4, m1,  m9, m13, [Q2]     ; [p4] -p7 -p5 +p4 +q2
672     FILTER_UPDATE   m6, m7, m4, m5, [P3],  m2,  m9, m14, m13, 4, m1, m14, m13, [Q3]     ; [p3] -p7 -p4 +p3 +q3
673     FILTER_UPDATE   m4, m5, m6, m7, [P2],  m2, m14, m15, m13, 4, m1,      m13, [Q4]     ; [p2] -p7 -p3 +p2 +q4
674     FILTER_UPDATE   m6, m7, m4, m5, [P1],  m2, m15, m10, m13, 4, m1,      m13, [Q5]     ; [p1] -p7 -p2 +p1 +q5
675     FILTER_UPDATE   m4, m5, m6, m7, [P0],  m2, m10, m11, m13, 4, m1,      m13, [Q6]     ; [p0] -p7 -p1 +p0 +q6
676     FILTER_UPDATE   m6, m7, m4, m5, [Q0],  m2, m11, m12, m13, 4, m1,      m13, [Q7]     ; [q0] -p7 -p0 +q0 +q7
677     FILTER_UPDATE   m4, m5, m6, m7, [Q1],  m3, m12,  m2, m13, 4, m1,       m2, [Q1]     ; [q1] -p6 -q0 +q1 +q7
678     FILTER_UPDATE   m6, m7, m4, m5, [Q2],  m8,  m2,  m3, m13, 4, m1,       m3, [Q2]     ; [q2] -p5 -q1 +q2 +q7
679     FILTER_UPDATE   m4, m5, m6, m7, [Q3],  m9,  m3,  m8, m13, 4, m1,  m8,  m8, [Q3]     ; [q3] -p4 -q2 +q3 +q7
680     FILTER_UPDATE   m6, m7, m4, m5, [Q4], m14,  m8,  m9, m13, 4, m1,  m9,  m9, [Q4]     ; [q4] -p3 -q3 +q4 +q7
681     FILTER_UPDATE   m4, m5, m6, m7, [Q5], m15,  m9, m14, m13, 4, m1, m14, m14, [Q5]     ; [q5] -p2 -q4 +q5 +q7
682     FILTER_UPDATE   m6, m7, m4, m5, [Q6], m10, m14, m15, m13, 4, m1, m15, m15, [Q6]     ; [q6] -p1 -q5 +q6 +q7
683 %endif
684
685 %ifidn %1, h
686 %if %2 == 16
687     mova                    m0, [P7]
688     mova                    m1, [P6]
689     mova                    m2, [P5]
690     mova                    m3, [P4]
691     mova                    m4, [P3]
692     mova                    m5, [P2]
693     mova                    m6, [P1]
694     mova                    m7, [P0]
695     mova                    m8, [Q0]
696     mova                    m9, [Q1]
697     mova                   m10, [Q2]
698     mova                   m11, [Q3]
699     mova                   m12, [Q4]
700     mova                   m13, [Q5]
701     mova                   m14, [Q6]
702     mova                   m15, [Q7]
703     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
704     DEFINE_REAL_P7_TO_Q7
705     movu  [P7],  m0
706     movu  [P6],  m1
707     movu  [P5],  m2
708     movu  [P4],  m3
709     movu  [P3],  m4
710     movu  [P2],  m5
711     movu  [P1],  m6
712     movu  [P0],  m7
713     movu  [Q0],  m8
714     movu  [Q1],  m9
715     movu  [Q2], m10
716     movu  [Q3], m11
717     movu  [Q4], m12
718     movu  [Q5], m13
719     movu  [Q6], m14
720     movu  [Q7], m15
721 %elif %2 == 44
722     SWAP 0, 7   ; m0 = p1
723     SWAP 3, 4   ; m3 = q1
724     DEFINE_REAL_P7_TO_Q7 2
725     SBUTTERFLY  bw, 0, 1, 8
726     SBUTTERFLY  bw, 2, 3, 8
727     SBUTTERFLY  wd, 0, 2, 8
728     SBUTTERFLY  wd, 1, 3, 8
729     movd  [P7], m0
730     movd  [P3], m2
731     movd  [Q0], m1
732     movd  [Q4], m3
733     psrldq  m0, 4
734     psrldq  m1, 4
735     psrldq  m2, 4
736     psrldq  m3, 4
737     movd  [P6], m0
738     movd  [P2], m2
739     movd  [Q1], m1
740     movd  [Q5], m3
741     psrldq  m0, 4
742     psrldq  m1, 4
743     psrldq  m2, 4
744     psrldq  m3, 4
745     movd  [P5], m0
746     movd  [P1], m2
747     movd  [Q2], m1
748     movd  [Q6], m3
749     psrldq  m0, 4
750     psrldq  m1, 4
751     psrldq  m2, 4
752     psrldq  m3, 4
753     movd  [P4], m0
754     movd  [P0], m2
755     movd  [Q3], m1
756     movd  [Q7], m3
757 %else
758     ; the following code do a transpose of 8 full lines to 16 half
759     ; lines (high part). It is inlined to avoid the need of a staging area
760     mova                    m0, [P3]
761     mova                    m1, [P2]
762     mova                    m2, [P1]
763     mova                    m3, [P0]
764     mova                    m4, [Q0]
765     mova                    m5, [Q1]
766     mova                    m6, [Q2]
767     mova                    m7, [Q3]
768     DEFINE_REAL_P7_TO_Q7
769     SBUTTERFLY  bw,  0,  1, 8
770     SBUTTERFLY  bw,  2,  3, 8
771     SBUTTERFLY  bw,  4,  5, 8
772     SBUTTERFLY  bw,  6,  7, 8
773     SBUTTERFLY  wd,  0,  2, 8
774     SBUTTERFLY  wd,  1,  3, 8
775     SBUTTERFLY  wd,  4,  6, 8
776     SBUTTERFLY  wd,  5,  7, 8
777     SBUTTERFLY  dq,  0,  4, 8
778     SBUTTERFLY  dq,  1,  5, 8
779     SBUTTERFLY  dq,  2,  6, 8
780     SBUTTERFLY  dq,  3,  7, 8
781     movh   [P7], m0
782     movhps [P6], m0
783     movh   [Q0], m1
784     movhps [Q1], m1
785     movh   [P3], m2
786     movhps [P2], m2
787     movh   [Q4], m3
788     movhps [Q5], m3
789     movh   [P5], m4
790     movhps [P4], m4
791     movh   [Q2], m5
792     movhps [Q3], m5
793     movh   [P1], m6
794     movhps [P0], m6
795     movh   [Q6], m7
796     movhps [Q7], m7
797 %endif
798 %endif
799
800     RET
801 %endmacro
802
803 %macro LPF_16_VH 2
804 INIT_XMM %2
805 LOOPFILTER v, %1, 0
806 LOOPFILTER h, %1, 256
807 %endmacro
808
809 %macro LPF_16_VH_ALL_OPTS 1
810 LPF_16_VH %1, sse2
811 LPF_16_VH %1, ssse3
812 LPF_16_VH %1, avx
813 %endmacro
814
815 LPF_16_VH_ALL_OPTS 16
816 LPF_16_VH_ALL_OPTS 44
817 LPF_16_VH_ALL_OPTS 48
818 LPF_16_VH_ALL_OPTS 84
819 LPF_16_VH_ALL_OPTS 88
820
821 %endif ; x86-64