vp9/x86: add AVX for itxfm and lpf.
[ffmpeg.git] / libavcodec / x86 / vp9lpf.asm
1 ;******************************************************************************
2 ;* VP9 loop filter SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %if ARCH_X86_64
24
25 %include "libavutil/x86/x86util.asm"
26
27 SECTION_RODATA
28
29 cextern pb_3
30 cextern pb_80
31
32 pb_4:   times 16 db 0x04
33 pb_10:  times 16 db 0x10
34 pb_40:  times 16 db 0x40
35 pb_81:  times 16 db 0x81
36 pb_f8:  times 16 db 0xf8
37 pb_fe:  times 16 db 0xfe
38
39 pw_4:   times  8 dw 4
40 pw_8:   times  8 dw 8
41
42 SECTION .text
43
44 ; %1 = abs(%2-%3)
45 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
46     psubusb             %1, %3, %2
47     psubusb             %4, %2, %3
48     por                 %1, %4
49 %endmacro
50
51 ; %1 = %1<=%2
52 %macro CMP_LTE 4 ; src/dst, cmp, tmp, pb_80
53     pxor                %1, %4
54     pcmpgtb             %3, %2, %1          ; cmp > src?
55     pcmpeqb             %1, %2              ; cmp == src? XXX: avoid this with a -1/+1 well placed?
56     por                 %1, %3              ; cmp >= src?
57 %endmacro
58
59 ; %1 = abs(%2-%3) <= %4
60 %macro ABSSUB_CMP 6-7 [pb_80]; dst, src1, src2, cmp, tmp1, tmp2, [pb_80]
61     ABSSUB              %1, %2, %3, %6      ; dst = abs(src1-src2)
62     CMP_LTE             %1, %4, %6, %7      ; dst <= cmp
63 %endmacro
64
65 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
66     pand                %1, %3              ; new &= mask
67     pandn               %4, %3, %2          ; tmp = ~mask & old
68     por                 %1, %4              ; new&mask | old&~mask
69 %endmacro
70
71 %macro FILTER_SUBx2_ADDx2 8 ; %1=dst %2=h/l %3=cache %4=sub1 %5=sub2 %6=add1 %7=add2 %8=rshift
72     punpck%2bw          %3, %4, m0
73     psubw               %1, %3
74     punpck%2bw          %3, %5, m0
75     psubw               %1, %3
76     punpck%2bw          %3, %6, m0
77     paddw               %1, %3
78     punpck%2bw          %3, %7, m0
79     paddw               %1, %3
80     mova                %3, %1
81     psraw               %1, %8
82 %endmacro
83
84 %macro FILTER_INIT 7-8 ; tmp1, tmp2, cacheL, cacheH, dstp, filterid, [source]
85     FILTER%6_INIT       %1, l, %3
86     FILTER%6_INIT       %2, h, %4
87     packuswb            %1, %2
88 %if %0 == 8
89     MASK_APPLY          %1, %8, %7, %2
90 %else
91     MASK_APPLY          %1, %5, %7, %2
92 %endif
93     mova                %5, %1
94 %endmacro
95
96 %macro FILTER_UPDATE 11-12 ; tmp1, tmp2, cacheL, cacheH, dstp, -, -, +, +, rshift, [source]
97     FILTER_SUBx2_ADDx2  %1, l, %3, %6, %7, %8, %9, %10
98     FILTER_SUBx2_ADDx2  %2, h, %4, %6, %7, %8, %9, %10
99     packuswb            %1, %2
100 %if %0 == 12
101     MASK_APPLY          %1, %12, %11, %2
102 %else
103     MASK_APPLY          %1, %5, %11, %2
104 %endif
105     mova                %5, %1
106 %endmacro
107
108 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
109     mova                %4, [pb_f8]
110     pand                %1, %4
111     pand                %2, %4
112     psrlq               %1, 3
113     psrlq               %2, 3
114     pxor                %1, %3
115     pxor                %2, %3
116     psubb               %1, %3
117     psubb               %2, %3
118 %endmacro
119
120 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
121     pxor                %3, %3
122     pxor                %2, %2
123     pcmpgtb             %3, %1                          ; i8 < 0 mask
124     psubb               %2, %1                          ; neg values (only the originally - will be kept)
125     pand                %2, %3                          ; negative values of i8 (but stored as +)
126     pandn               %3, %1                          ; positive values of i8
127 %endmacro
128
129 ; clip_u8(u8 + i8)
130 %macro SIGN_ADD 5 ; dst, u8, i8, tmp1, tmp2
131     EXTRACT_POS_NEG     %3, %4, %5
132     psubusb             %1, %2, %4                      ; sub the negatives
133     paddusb             %1, %5                          ; add the positives
134 %endmacro
135
136 ; clip_u8(u8 - i8)
137 %macro SIGN_SUB 5 ; dst, u8, i8, tmp1, tmp2
138     EXTRACT_POS_NEG     %3, %4, %5
139     psubusb             %1, %2, %5                      ; sub the positives
140     paddusb             %1, %4                          ; add the negatives
141 %endmacro
142
143 %macro FILTER6_INIT 3 ; %1=dst %2=h/l %3=cache
144     punpck%2bw          %3, m14, m0                     ; p3: B->W
145     mova                %1, %3                          ; p3
146     paddw               %1, %3                          ; p3*2
147     paddw               %1, %3                          ; p3*3
148     punpck%2bw          %3, m15, m0                     ; p2: B->W
149     paddw               %1, %3                          ; p3*3 + p2
150     paddw               %1, %3                          ; p3*3 + p2*2
151     punpck%2bw          %3, m10, m0                     ; p1: B->W
152     paddw               %1, %3                          ; p3*3 + p2*2 + p1
153     punpck%2bw          %3, m11, m0                     ; p0: B->W
154     paddw               %1, %3                          ; p3*3 + p2*2 + p1 + p0
155     punpck%2bw          %3, m12, m0                     ; q0: B->W
156     paddw               %1, %3                          ; p3*3 + p2*2 + p1 + p0 + q0
157     paddw               %1, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
158     mova                %3, %1                          ; base for next line (cache)
159     psraw               %1, 3                           ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
160 %endmacro
161
162 %macro FILTER14_INIT 3 ; %1=dst %2=h/l %3=cache
163     punpck%2bw          %1, m2, m0                      ; p7: B->W
164     mova                %3, %1
165     psllw               %1, 3                           ; p7*8
166     psubw               %1, %3                          ; p7*7
167     punpck%2bw          %3, m3, m0                      ; p6: B->W
168     paddw               %1, %3                          ; p7*7 + p6
169     paddw               %1, %3                          ; p7*7 + p6*2
170     punpck%2bw          %3, m8, m0                      ; p5: B->W
171     paddw               %1, %3                          ; p7*7 + p6*2 + p5
172     punpck%2bw          %3, m9, m0                      ; p4: B->W
173     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + p4
174     punpck%2bw          %3, m14, m0                     ; p3: B->W
175     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + p4 + p3
176     punpck%2bw          %3, m15, m0                     ; p2: B->W
177     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p2
178     punpck%2bw          %3, m10, m0                     ; p1: B->W
179     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p1
180     punpck%2bw          %3, m11, m0                     ; p0: B->W
181     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p0
182     punpck%2bw          %3, m12, m0                     ; q0: B->W
183     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p0 + q0
184     paddw               %1, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
185     mova                %3, %1                          ; base for next line (cache)
186     psraw               %1, 4                           ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
187 %endmacro
188
189 %macro TRANSPOSE16x16B 17
190     mova %17, m%16
191     SBUTTERFLY bw,  %1,  %2,  %16
192     SBUTTERFLY bw,  %3,  %4,  %16
193     SBUTTERFLY bw,  %5,  %6,  %16
194     SBUTTERFLY bw,  %7,  %8,  %16
195     SBUTTERFLY bw,  %9,  %10, %16
196     SBUTTERFLY bw,  %11, %12, %16
197     SBUTTERFLY bw,  %13, %14, %16
198     mova m%16,  %17
199     mova  %17, m%14
200     SBUTTERFLY bw,  %15, %16, %14
201     SBUTTERFLY wd,  %1,  %3,  %14
202     SBUTTERFLY wd,  %2,  %4,  %14
203     SBUTTERFLY wd,  %5,  %7,  %14
204     SBUTTERFLY wd,  %6,  %8,  %14
205     SBUTTERFLY wd,  %9,  %11, %14
206     SBUTTERFLY wd,  %10, %12, %14
207     SBUTTERFLY wd,  %13, %15, %14
208     mova m%14,  %17
209     mova  %17, m%12
210     SBUTTERFLY wd,  %14, %16, %12
211     SBUTTERFLY dq,  %1,  %5,  %12
212     SBUTTERFLY dq,  %2,  %6,  %12
213     SBUTTERFLY dq,  %3,  %7,  %12
214     SBUTTERFLY dq,  %4,  %8,  %12
215     SBUTTERFLY dq,  %9,  %13, %12
216     SBUTTERFLY dq,  %10, %14, %12
217     SBUTTERFLY dq,  %11, %15, %12
218     mova m%12, %17
219     mova  %17, m%8
220     SBUTTERFLY dq,  %12, %16, %8
221     SBUTTERFLY qdq, %1,  %9,  %8
222     SBUTTERFLY qdq, %2,  %10, %8
223     SBUTTERFLY qdq, %3,  %11, %8
224     SBUTTERFLY qdq, %4,  %12, %8
225     SBUTTERFLY qdq, %5,  %13, %8
226     SBUTTERFLY qdq, %6,  %14, %8
227     SBUTTERFLY qdq, %7,  %15, %8
228     mova m%8, %17
229     mova %17, m%1
230     SBUTTERFLY qdq, %8,  %16, %1
231     mova m%1, %17
232     SWAP %2,  %9
233     SWAP %3,  %5
234     SWAP %4,  %13
235     SWAP %6,  %11
236     SWAP %8,  %15
237     SWAP %12, %14
238 %endmacro
239
240 %macro LPF_16_16 1
241     lea mstrideq, [strideq]
242     neg mstrideq
243
244 %ifidn %1, h
245     lea dstq, [dstq + 8*strideq - 8] ; go from top center (h pos) to center left (v pos)
246     lea                  dst1q, [dstq  + 8*mstrideq]        ; dst1 = &dst[stride * -8]
247     lea                  dst2q, [dst1q + 1* strideq]        ; dst2 = &dst[stride * -7]
248     movu                    m0, [dst1q             ]        ;  m0 = dst[stride * -8] (p7)
249     movu                    m1, [dst2q             ]        ;  m1 = dst[stride * -7] (p6)
250     movu                    m2, [dst1q + 2* strideq]        ;  m2 = dst[stride * -6] (p5)
251     movu                    m3, [dst2q + 2* strideq]        ;  m3 = dst[stride * -5] (p4)
252     lea                  dst1q, [dstq]                      ; dst1 = &dst[stride * +0]
253     lea                  dst2q, [dstq + 1*strideq]          ; dst2 = &dst[stride * +1]
254     movu                    m4, [dst1q + 4*mstrideq]        ;  m4 = dst[stride * -4] (p3)
255     movu                    m5, [dst2q + 4*mstrideq]        ;  m5 = dst[stride * -3] (p2)
256     movu                    m6, [dst1q + 2*mstrideq]        ;  m6 = dst[stride * -2] (p1)
257     movu                    m7, [dst2q + 2*mstrideq]        ;  m7 = dst[stride * -1] (p0)
258     movu                    m8, [dst1q]                     ;  m8 = dst[stride * +0] (q0)
259     movu                    m9, [dst2q]                     ;  m9 = dst[stride * +1] (q1)
260     movu                   m10, [dst1q + 2* strideq]        ; m10 = dst[stride * +2] (q2)
261     movu                   m11, [dst2q + 2* strideq]        ; m11 = dst[stride * +3] (q3)
262     movu                   m12, [dst1q + 4* strideq]        ; m12 = dst[stride * +4] (q4)
263     movu                   m13, [dst2q + 4* strideq]        ; m13 = dst[stride * +5] (q5)
264     lea                  dst1q, [dstq  + 8* strideq]        ; dst1 = &dst[stride * +8]
265     movu                   m14, [dst1q + 2*mstrideq]        ; m14 = dst[stride * +6] (q6)
266     movu                   m15, [dst1q + 1*mstrideq]        ; m15 = dst[stride * +7] (q7)
267     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
268     mova           [rsp +   0],  m0                         ; dst[stride * -8] (p7)
269     mova           [rsp +  16],  m1                         ; dst[stride * -7] (p6)
270     mova           [rsp +  32],  m2                         ; dst[stride * -6] (p5)
271     mova           [rsp +  48],  m3                         ; dst[stride * -5] (p4)
272     mova           [rsp +  64],  m4                         ; dst[stride * -4] (p3)
273     mova           [rsp +  80],  m5                         ; dst[stride * -3] (p2)
274     mova           [rsp +  96],  m6                         ; dst[stride * -2] (p1)
275     mova           [rsp + 112],  m7                         ; dst[stride * -1] (p0)
276     mova           [rsp + 128],  m8                         ; dst[stride * +0] (q0)
277     mova           [rsp + 144],  m9                         ; dst[stride * +1] (q1)
278     mova           [rsp + 160], m10                         ; dst[stride * +2] (q2)
279     mova           [rsp + 176], m11                         ; dst[stride * +3] (q3)
280     mova           [rsp + 192], m12                         ; dst[stride * +4] (q4)
281     mova           [rsp + 208], m13                         ; dst[stride * +5] (q5)
282     mova           [rsp + 224], m14                         ; dst[stride * +6] (q6)
283     mova           [rsp + 240], m15                         ; dst[stride * +7] (q7)
284 %endif
285
286     ; calc fm mask
287     pxor                m0, m0
288     movd                m2, Id
289     movd                m3, Ed
290     pshufb              m2, m0                          ; I I I I ...
291     pshufb              m3, m0                          ; E E E E ...
292     mova                m0, [pb_80]
293     pxor                m2, m0
294     pxor                m3, m0
295 %ifidn %1, v
296     lea              dst1q, [dstq  + 2*mstrideq]        ; dst1 = &dst[stride * -2]
297     lea              dst2q, [dstq  + 2* strideq]        ; dst2 = &dst[stride * +2]
298     mova                m8, [dstq  + 4*mstrideq]        ; m8  = dst[stride * -4] (p3)
299     mova                m9, [dst1q + 1*mstrideq]        ; m9  = dst[stride * -3] (p2)
300     mova               m10, [dstq  + 2*mstrideq]        ; m10 = dst[stride * -2] (p1)
301     mova               m11, [dstq  + 1*mstrideq]        ; m11 = dst[stride * -1] (p0)
302     mova               m12, [dstq              ]        ; m12 = dst[stride * +0] (q0)
303     mova               m13, [dstq  + 1* strideq]        ; m13 = dst[stride * +1] (q1)
304     mova               m14, [dstq  + 2* strideq]        ; m14 = dst[stride * +2] (q2)
305     mova               m15, [dst2q + 1* strideq]        ; m15 = dst[stride * +3] (q3)
306 %else
307     SWAP                 8,  4, 12
308     SWAP                 9,  5, 13
309     SWAP                10,  6, 14
310     SWAP                11,  7, 15
311 %endif
312     ABSSUB_CMP          m5,  m8,  m9, m2, m6, m7, m0    ; m5 = abs(p3-p2) <= I
313     ABSSUB_CMP          m1,  m9, m10, m2, m6, m7, m0    ; m1 = abs(p2-p1) <= I
314     pand                m5, m1
315     ABSSUB_CMP          m1, m10, m11, m2, m6, m7, m0    ; m1 = abs(p1-p0) <= I
316     pand                m5, m1
317     ABSSUB_CMP          m1, m12, m13, m2, m6, m7, m0    ; m1 = abs(q1-q0) <= I
318     pand                m5, m1
319     ABSSUB_CMP          m1, m13, m14, m2, m6, m7, m0    ; m1 = abs(q2-q1) <= I
320     pand                m5, m1
321     ABSSUB_CMP          m1, m14, m15, m2, m6, m7, m0    ; m1 = abs(q3-q2) <= I
322     pand                m5, m1
323     ABSSUB              m1, m11, m12, m7                ; abs(p0-q0)
324     paddusb             m1, m1                          ; abs(p0-q0) * 2
325     ABSSUB              m2, m10, m13, m7                ; abs(p1-q1)
326     pand                m2, [pb_fe]                     ; drop lsb so shift can work
327     psrlq               m2, 1                           ; abs(p1-q1)/2
328     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
329     pxor                m1, m0
330     pcmpgtb             m4, m3, m1                      ; E > X?
331     pcmpeqb             m3, m1                          ; E == X?
332     por                 m3, m4                          ; E >= X?
333     pand                m3, m5                          ; fm final value
334
335     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
336     ; calc flat8in and hev masks
337     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
338     ABSSUB_CMP          m2, m8, m11, m6, m4, m5         ; abs(p3 - p0) <= 1
339     mova                m8, [pb_80]
340     ABSSUB_CMP          m1, m9, m11, m6, m4, m5, m8     ; abs(p2 - p0) <= 1
341     pand                m2, m1
342     ABSSUB              m4, m10, m11, m5                ; abs(p1 - p0)
343     pxor                m0, m0
344     movd                m7, Hd
345     pshufb              m7, m0                          ; H H H H ...
346     pxor                m7, m8
347     pxor                m4, m8
348     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
349     pxor                m4, m8
350     mova                m1, m4
351     CMP_LTE             m1, m6, m5, m8                  ; abs(p1 - p0) <= 1
352     pand                m2, m1                          ; (flat8in)
353     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
354     pxor                m4, m8
355     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
356     pxor                m4, m8
357     por                 m0, m5                          ; hev final value
358     mova                m1, m4
359     CMP_LTE             m1, m6, m5, m8                  ; abs(q1 - q0) <= 1
360     pand                m2, m1                          ; (flat8in)
361     ABSSUB_CMP          m1, m14, m12, m6, m4, m5, m8    ; abs(q2 - q0) <= 1
362     pand                m2, m1
363     ABSSUB_CMP          m1, m15, m12, m6, m4, m5, m8    ; abs(q3 - q0) <= 1
364     pand                m2, m1                          ; flat8in final value
365
366     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
367     ; calc flat8out mask
368 %ifidn %1, v
369     lea                 dst2q, [dstq  + 8*mstrideq]     ; dst2 = &dst[stride * -8] (p7)
370     lea                 dst1q, [dst2q + 1*strideq]      ; dst1 = &dst[stride * -7] (p6)
371     mova                m8, [dst2q]                     ; m8 = p7
372     mova                m9, [dst1q]                     ; m9 = p6
373 %else
374     mova                m8, [rsp +  0]                  ; m8 = p7
375     mova                m9, [rsp + 16]                  ; m9 = p6
376 %endif
377     ABSSUB_CMP          m1, m8, m11, m6, m4, m5         ; abs(p7 - p0) <= 1
378     ABSSUB_CMP          m7, m9, m11, m6, m4, m5         ; abs(p6 - p0) <= 1
379     pand                m1, m7
380 %ifidn %1, v
381     mova                m8, [dst1q + 1*strideq]         ; m8 = dst[stride * -6] (p5)
382     mova                m9, [dst1q + 2*strideq]         ; m9 = dst[stride * -5] (p4)
383 %else
384     mova                m8, [rsp + 32]                  ; m8 = p5
385     mova                m9, [rsp + 48]                  ; m9 = p4
386 %endif
387     ABSSUB_CMP          m7, m8, m11, m6, m4, m5         ; abs(p5 - p0) <= 1
388     pand                m1, m7
389     ABSSUB_CMP          m7, m9, m11, m6, m4, m5         ; abs(p4 - p0) <= 1
390     pand                m1, m7
391 %ifidn %1, v
392     lea                 dst2q, [dstq  + 4*strideq]      ; dst2 = &dst[stride * +4] (q4)
393     lea                 dst1q, [dst2q + 1*strideq]      ; dst1 = &dst[stride * +5] (q5)
394     mova                m14, [dst2q]                    ; m14 = q4
395     mova                m15, [dst1q]                    ; m15 = q5
396 %else
397     mova                m14, [rsp + 192]                ; m14 = q4
398     mova                m15, [rsp + 208]                ; m15 = q5
399 %endif
400     ABSSUB_CMP          m7, m14, m12, m6, m4, m5        ; abs(q4 - q0) <= 1
401     pand                m1, m7
402     ABSSUB_CMP          m7, m15, m12, m6, m4, m5        ; abs(q5 - q0) <= 1
403     pand                m1, m7
404 %ifidn %1, v
405     mova                m14, [dst1q + 1*strideq]        ; m14 = dst[stride * +6] (q6)
406     mova                m15, [dst1q + 2*strideq]        ; m15 = dst[stride * +7] (q7)
407 %else
408     mova                m14, [rsp + 224]                ; m14 = q6
409     mova                m15, [rsp + 240]                ; m15 = q7
410 %endif
411     ABSSUB_CMP          m7, m14, m12, m6, m4, m5        ; abs(q4 - q0) <= 1
412     pand                m1, m7
413     ABSSUB_CMP          m7, m15, m12, m6, m4, m5        ; abs(q5 - q0) <= 1
414     pand                m1, m7                          ; flat8out final value
415
416     ; if (fm) {
417     ;     if (out && in) filter_14()
418     ;     else if (in)   filter_6()
419     ;     else if (hev)  filter_2()
420     ;     else           filter_4()
421     ; }
422     ;
423     ; f14:                                                                            fm &  out &  in
424     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
425     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
426     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
427
428     ; (m0: hev, m1: flat8out, m2: flat8in, m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
429     ; filter2()
430     mova                m6, [pb_80]
431     pxor                m15, m12, m6                    ; q0 ^ 0x80
432     pxor                m14, m11, m6                    ; p0 ^ 0x80
433     psubsb              m15, m14                        ; (signed) q0 - p0
434     pxor                m4, m10, m6                     ; p1 ^ 0x80
435     pxor                m5, m13, m6                     ; q1 ^ 0x80
436     psubsb              m4, m5                          ; (signed) p1 - q1
437     paddsb              m4, m15                         ;   (q0 - p0) + (p1 - q1)
438     paddsb              m4, m15                         ; 2*(q0 - p0) + (p1 - q1)
439     paddsb              m4, m15                         ; 3*(q0 - p0) + (p1 - q1)
440     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
441     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
442     mova                m14, [pb_10]                    ; will be reused in filter4()
443     SRSHIFT3B_2X        m6, m4, m14, m7                 ; f1 and f2 sign byte shift by 3
444     SIGN_SUB            m7, m12, m6, m5, m9             ; m7 = q0 - f1
445     SIGN_ADD            m8, m11, m4, m5, m9             ; m8 = p0 + f2
446     pandn               m6, m2, m3                      ;  ~mask(in) & mask(fm)
447     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
448     MASK_APPLY          m7, m12, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
449     MASK_APPLY          m8, m11, m6, m5                 ; m8 = filter2(p0) & mask / we write it in filter4()
450
451     ; (m0: hev, m1: flat8out, m2: flat8in, m3: fm, m7..m8: q0' p0', m10..13: p1 p0 q0 q1, m14: pb_10, m15: q0-p0)
452     ; filter4()
453     mova                m4, m15
454     paddsb              m15, m4                         ; 2 * (q0 - p0)
455     paddsb              m15, m4                         ; 3 * (q0 - p0)
456     paddsb              m6, m15, [pb_4]                 ; m6:  f1 = clip(f + 4, 127)
457     paddsb              m15, [pb_3]                     ; m15: f2 = clip(f + 3, 127)
458     SRSHIFT3B_2X        m6, m15, m14, m9                ; f1 and f2 sign byte shift by 3
459     pandn               m5, m2, m3                      ;               ~mask(in) & mask(fm)
460     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
461     SIGN_SUB            m9, m12, m6, m4, m14            ; q0 - f1
462     MASK_APPLY          m9, m7, m0, m5                  ; m9 = filter4(q0) & mask
463 %ifidn %1, v
464     mova                [dstq], m9                      ; update q0
465 %else
466     mova                [rsp + 128], m9                 ; update q0
467 %endif
468     SIGN_ADD            m7, m11, m15, m4, m14           ; p0 + f2
469     MASK_APPLY          m7, m8, m0, m5                  ; m7 = filter4(p0) & mask
470 %ifidn %1, v
471     mova                [dstq + 1*mstrideq], m7         ; update p0
472 %else
473     mova                [rsp + 112], m7                 ; update p0
474 %endif
475     paddb               m6, [pb_80]                     ;
476     pxor                m8, m8                          ;   f=(f1+1)>>1
477     pavgb               m6, m8                          ;
478     psubb               m6, [pb_40]                     ;
479     SIGN_ADD            m7, m10, m6, m8, m9             ; p1 + f
480     SIGN_SUB            m4, m13, m6, m8, m9             ; q1 - f
481     MASK_APPLY          m7, m10, m0, m14                ; m7 = filter4(p1)
482     MASK_APPLY          m4, m13, m0, m14                ; m4 = filter4(q1)
483 %ifidn %1, v
484     mova                [dstq + 2*mstrideq], m7         ; update p1
485     mova                [dstq + 1* strideq], m4         ; update q1
486 %else
487     mova                [rsp +  96], m7                 ; update p1
488     mova                [rsp + 144], m4                 ; update q1
489 %endif
490
491     ; (m1: flat8out, m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
492     ; filter6()
493     pxor                m0, m0
494     pand                m2, m3                          ;               mask(fm) & mask(in)
495     pandn               m3, m1, m2                      ; ~mask(out) & (mask(fm) & mask(in))
496 %ifidn %1, v
497     lea              dst1q, [dstq + 2*strideq]          ; dst1 = &dst[stride * +2] (q2)
498     mova                m8, [dst1q]                     ; m8 = q2
499     mova                m9, [dst1q + 1*strideq]         ; m9 = q3
500     lea              dst1q, [dstq + 4*mstrideq]         ; dst1 = &dst[stride * -4] (p3)
501     lea              dst2q, [dst1q + 1*strideq]         ; dst2 = &dst[stride * -3] (p2)
502     mova               m14, [dst1q]                     ; m14 = p3
503     mova               m15, [dst2q]                     ; m15 = p2
504     FILTER_INIT         m4, m5, m6, m7, [dst2q            ], 6,                     m3, m15 ; [p2]
505     FILTER_UPDATE       m6, m7, m4, m5, [dst2q + 1*strideq], m14, m15, m10, m13, 3, m3      ; [p1] -p3 -p2 +p1 +q1
506     FILTER_UPDATE       m4, m5, m6, m7, [dst2q + 2*strideq], m14, m10, m11,  m8, 3, m3      ; [p0] -p3 -p1 +p0 +q2
507     FILTER_UPDATE       m6, m7, m4, m5, [dstq             ], m14, m11, m12,  m9, 3, m3      ; [q0] -p3 -p0 +q0 +q3
508     FILTER_UPDATE       m4, m5, m6, m7, [dstq  + 1*strideq], m15, m12, m13,  m9, 3, m3      ; [q1] -p2 -q0 +q1 +q3
509     FILTER_UPDATE       m6, m7, m4, m5, [dstq  + 2*strideq], m10, m13,  m8,  m9, 3, m3,  m8 ; [q2] -p1 -q1 +q2 +q3
510 %else
511     mova               m14, [rsp +  64]                 ; m14 = p3
512     mova               m15, [rsp +  80]                 ; m15 = p2
513     mova                m8, [rsp + 160]                 ;  m8 = q2
514     mova                m9, [rsp + 176]                 ;  m9 = q3
515     FILTER_INIT         m4, m5, m6, m7, [rsp +  80], 6,                     m3, m15 ; [p2]
516     FILTER_UPDATE       m6, m7, m4, m5, [rsp +  96], m14, m15, m10, m13, 3, m3      ; [p1] -p3 -p2 +p1 +q1
517     FILTER_UPDATE       m4, m5, m6, m7, [rsp + 112], m14, m10, m11,  m8, 3, m3      ; [p0] -p3 -p1 +p0 +q2
518     FILTER_UPDATE       m6, m7, m4, m5, [rsp + 128], m14, m11, m12,  m9, 3, m3      ; [q0] -p3 -p0 +q0 +q3
519     FILTER_UPDATE       m4, m5, m6, m7, [rsp + 144], m15, m12, m13,  m9, 3, m3      ; [q1] -p2 -q0 +q1 +q3
520     FILTER_UPDATE       m6, m7, m4, m5, [rsp + 160], m10, m13,  m8,  m9, 3, m3,  m8 ; [q2] -p1 -q1 +q2 +q3
521 %endif
522
523     ; (m0: 0, m1: flat8out, m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
524     ; filter14()
525     ;
526     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
527     ;
528     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
529     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
530     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
531     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
532     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
533     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
534     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
535     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
536     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
537     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
538     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
539     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
540     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
541     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
542     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
543
544     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
545 %ifidn %1, v
546     lea             dst1q, [dstq  + 8*mstrideq]                                         ; dst1 = &dst[stride * -8] (p7)
547     lea             dst2q, [dst1q + 1* strideq]                                         ; dst2 = &dst[stride * -7] (p6)
548     mova            m2, [dst1q]                                                         ; m2 = p7
549     mova            m3, [dst2q]                                                         ; m3 = p6
550     mova            m8, [dst1q + 2*strideq]                                             ; m8 = p5 (dst[stride * -6])
551     mova            m9, [dst2q + 2*strideq]                                             ; m9 = p4 (dst[stride * -5])
552     FILTER_INIT     m4, m5, m6, m7, [dst2q], 14,                                m1,  m3 ; [p6]
553     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*strideq],  m2,  m3,  m8, m13, 4, m1,  m8 ; [p5] -p7 -p6 +p5 +q1
554     lea             dst1q, [dstq + 1*strideq]                                           ; dst1 = &dst[stride * +1] (q1)
555     mova            m13, [dst1q + 1*strideq]                                            ; m13=dst[stride * +2] (q2)
556     FILTER_UPDATE   m4, m5, m6, m7, [dst2q + 2*strideq],  m2,  m8,  m9, m13, 4, m1,  m9 ; [p4] -p7 -p5 +p4 +q2
557     lea             dst2q, [dst2q + 4*strideq]
558     mova            m13, [dst1q + 2*strideq]                                            ; m13=dst[stride * +3] (q3)
559     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*mstrideq], m2,  m9, m14, m13, 4, m1, m14 ; [p3] -p7 -p4 +p3 +q3
560     mova            m13, [dstq  + 4*strideq]                                            ; m13=dst[stride * +4] (q4)
561     FILTER_UPDATE   m4, m5, m6, m7, [dst2q],              m2, m14, m15, m13, 4, m1      ; [p2] -p7 -p3 +p2 +q4
562     mova            m13, [dst1q + 4*strideq]                                            ; m13=dst[stride * +5] (q5)
563     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*strideq],  m2, m15, m10, m13, 4, m1      ; [p1] -p7 -p2 +p1 +q5
564     lea             dst1q, [dst1q + 4*strideq]                                          ; dst1 = &dst[stride * +5] (q5)
565     mova            m13, [dst1q + 1*strideq]                                            ; m13=dst[stride * +6] (q6)
566     FILTER_UPDATE   m4, m5, m6, m7, [dst2q + 2*strideq],  m2, m10, m11, m13, 4, m1      ; [p0] -p7 -p1 +p0 +q6
567     lea             dst2q, [dst2q + 4*strideq]
568     mova            m13, [dst1q + 2*strideq]                                            ; m13=dst[stride * +7] (q7)
569     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*mstrideq], m2, m11, m12, m13, 4, m1      ; [q0] -p7 -p0 +q0 +q7
570     mova            m2, [dst2q]                                                         ; m2=dst[stride * +1] (q1)
571     FILTER_UPDATE   m4, m5, m6, m7, [dst2q],              m3, m12,  m2, m13, 4, m1      ; [q1] -p6 -q0 +q1 +q7
572     mova            m3, [dst2q + 1*strideq]                                             ; m3=dst[stride * +2] (q2)
573     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*strideq],  m8,  m2,  m3, m13, 4, m1      ; [q2] -p5 -q1 +q2 +q7
574     mova            m8, [dst2q + 2*strideq]                                             ; m8=dst[stride * +3] (q3)
575     FILTER_UPDATE   m4, m5, m6, m7, [dst2q + 2*strideq],  m9,  m3,  m8, m13, 4, m1,  m8 ; [q3] -p4 -q2 +q3 +q7
576     lea             dst2q, [dst2q + 4*strideq]
577     mova            m9, [dst2q + 1*mstrideq]                                            ; m9=dst[stride * +4] (q4)
578     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*mstrideq],m14,  m8,  m9, m13, 4, m1,  m9 ; [q4] -p3 -q3 +q4 +q7
579     mova            m14, [dst2q]                                                        ; m14=dst[stride * +5] (q5)
580     FILTER_UPDATE   m4, m5, m6, m7, [dst2q],             m15,  m9, m14, m13, 4, m1, m14 ; [q5] -p2 -q4 +q5 +q7
581     mova            m15, [dst2q + 1*strideq]                                            ; m15=dst[stride * +6] (q6)
582     FILTER_UPDATE   m6, m7, m4, m5, [dst2q + 1*strideq], m10, m14, m15, m13, 4, m1, m15 ; [q6] -p1 -q5 +q6 +q7
583 %else
584     mova            m2, [rsp +  0]                                                      ; m2 = p7
585     mova            m3, [rsp + 16]                                                      ; m3 = p6
586     mova            m8, [rsp + 32]                                                      ; m8 = p5
587     mova            m9, [rsp + 48]                                                      ; m9 = p4
588     FILTER_INIT     m4, m5, m6, m7, [rsp +  16],  14,                   m1,  m3         ; [p6]
589     FILTER_UPDATE   m6, m7, m4, m5, [rsp +  32],  m2,  m3,  m8, m13, 4, m1,  m8         ; [p5] -p7 -p6 +p5 +q1
590     mova            m13, [rsp + 160]                                                    ; m13 = q2
591     FILTER_UPDATE   m4, m5, m6, m7, [rsp +  48],  m2,  m8,  m9, m13, 4, m1,  m9         ; [p4] -p7 -p5 +p4 +q2
592     mova            m13, [rsp + 176]                                                    ; m13 = q3
593     FILTER_UPDATE   m6, m7, m4, m5, [rsp +  64],  m2,  m9, m14, m13, 4, m1, m14         ; [p3] -p7 -p4 +p3 +q3
594     mova            m13, [rsp + 192]                                                    ; m13 = q4
595     FILTER_UPDATE   m4, m5, m6, m7, [rsp +  80],  m2, m14, m15, m13, 4, m1              ; [p2] -p7 -p3 +p2 +q4
596     mova            m13, [rsp + 208]                                                    ; m13 = q5
597     FILTER_UPDATE   m6, m7, m4, m5, [rsp +  96],  m2, m15, m10, m13, 4, m1              ; [p1] -p7 -p2 +p1 +q5
598     mova            m13, [rsp + 224]                                                    ; m13 = q6
599     FILTER_UPDATE   m4, m5, m6, m7, [rsp + 112],  m2, m10, m11, m13, 4, m1              ; [p0] -p7 -p1 +p0 +q6
600     mova            m13, [rsp + 240]                                                    ; m13 = q7
601     FILTER_UPDATE   m6, m7, m4, m5, [rsp + 128],  m2, m11, m12, m13, 4, m1              ; [q0] -p7 -p0 +q0 +q7
602     mova            m2,  [rsp + 144]                                                    ; m2 = q1
603     FILTER_UPDATE   m4, m5, m6, m7, [rsp + 144],  m3, m12,  m2, m13, 4, m1              ; [q1] -p6 -q0 +q1 +q7
604     mova            m3,  [rsp + 160]                                                    ; m3 = q2
605     FILTER_UPDATE   m6, m7, m4, m5, [rsp + 160],  m8,  m2,  m3, m13, 4, m1              ; [q2] -p5 -q1 +q2 +q7
606     mova            m8,  [rsp + 176]                                                    ; m8 = q3
607     FILTER_UPDATE   m4, m5, m6, m7, [rsp + 176],  m9,  m3,  m8, m13, 4, m1,  m8         ; [q3] -p4 -q2 +q3 +q7
608     mova            m9,  [rsp + 192]                                                    ; m9 = q4
609     FILTER_UPDATE   m6, m7, m4, m5, [rsp + 192], m14,  m8,  m9, m13, 4, m1,  m9         ; [q4] -p3 -q3 +q4 +q7
610     mova            m14, [rsp + 208]                                                    ; m14 = q5
611     FILTER_UPDATE   m4, m5, m6, m7, [rsp + 208], m15,  m9, m14, m13, 4, m1, m14         ; [q5] -p2 -q4 +q5 +q7
612     mova            m15, [rsp + 224]                                                    ; m15 = q6
613     FILTER_UPDATE   m6, m7, m4, m5, [rsp + 224], m10, m14, m15, m13, 4, m1, m15         ; [q6] -p1 -q5 +q6 +q7
614 %endif
615
616 %ifidn %1, h
617     mova                    m0, [rsp +   0]                                             ; dst[stride * -8] (p7)
618     mova                    m1, [rsp +  16]                                             ; dst[stride * -7] (p6)
619     mova                    m2, [rsp +  32]                                             ; dst[stride * -6] (p5)
620     mova                    m3, [rsp +  48]                                             ; dst[stride * -5] (p4)
621     mova                    m4, [rsp +  64]                                             ; dst[stride * -4] (p3)
622     mova                    m5, [rsp +  80]                                             ; dst[stride * -3] (p2)
623     mova                    m6, [rsp +  96]                                             ; dst[stride * -2] (p1)
624     mova                    m7, [rsp + 112]                                             ; dst[stride * -1] (p0)
625     mova                    m8, [rsp + 128]                                             ; dst[stride * +0] (q0)
626     mova                    m9, [rsp + 144]                                             ; dst[stride * +1] (q1)
627     mova                   m10, [rsp + 160]                                             ; dst[stride * +2] (q2)
628     mova                   m11, [rsp + 176]                                             ; dst[stride * +3] (q3)
629     mova                   m12, [rsp + 192]                                             ; dst[stride * +4] (q4)
630     mova                   m13, [rsp + 208]                                             ; dst[stride * +5] (q5)
631     mova                   m14, [rsp + 224]                                             ; dst[stride * +6] (q6)
632     mova                   m15, [rsp + 240]                                             ; dst[stride * +7] (q7)
633     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
634     lea                  dst1q, [dstq  + 8*mstrideq]                                    ; dst1 = &dst[stride * -8]
635     lea                  dst2q, [dst1q + 1* strideq]                                    ; dst2 = &dst[stride * -7]
636     movu  [dst1q             ],  m0                                                     ; dst[stride * -8] (p7)
637     movu  [dst2q             ],  m1                                                     ; dst[stride * -7] (p6)
638     movu  [dst1q + 2* strideq],  m2                                                     ; dst[stride * -6] (p5)
639     movu  [dst2q + 2* strideq],  m3                                                     ; dst[stride * -5] (p4)
640     lea                  dst1q, [dstq]                                                  ; dst1 = &dst[stride * +0]
641     lea                  dst2q, [dstq + 1*strideq]                                      ; dst2 = &dst[stride * +1]
642     movu  [dst1q + 4*mstrideq],  m4                                                     ; dst[stride * -4] (p3)
643     movu  [dst2q + 4*mstrideq],  m5                                                     ; dst[stride * -3] (p2)
644     movu  [dst1q + 2*mstrideq],  m6                                                     ; dst[stride * -2] (p1)
645     movu  [dst2q + 2*mstrideq],  m7                                                     ; dst[stride * -1] (p0)
646     movu  [dst1q             ],  m8                                                     ; dst[stride * +0] (q0)
647     movu  [dst2q             ],  m9                                                     ; dst[stride * +1] (q1)
648     movu  [dst1q + 2* strideq], m10                                                     ; dst[stride * +2] (q2)
649     movu  [dst2q + 2* strideq], m11                                                     ; dst[stride * +3] (q3)
650     movu  [dst1q + 4* strideq], m12                                                     ; dst[stride * +4] (q4)
651     movu  [dst2q + 4* strideq], m13                                                     ; dst[stride * +5] (q5)
652     lea                  dst1q, [dstq + 8*strideq]                                      ; dst1 = &dst[stride * +8]
653     movu  [dst1q + 2*mstrideq], m14                                                     ; dst[stride * +6] (q6)
654     movu  [dst1q + 1*mstrideq], m15                                                     ; dst[stride * +7] (q7)
655 %endif
656 %endmacro
657
658 %macro LPF_16_16_VH 1
659 INIT_XMM %1
660 cglobal vp9_loop_filter_v_16_16, 5,8,16,      dst, stride, E, I, H, mstride, dst1, dst2
661     LPF_16_16 v
662     RET
663 cglobal vp9_loop_filter_h_16_16, 5,8,16, 256, dst, stride, E, I, H, mstride, dst1, dst2
664     LPF_16_16 h
665     RET
666 %endmacro
667
668 LPF_16_16_VH ssse3
669 LPF_16_16_VH avx
670
671 %endif ; x86-64