7dc40a393ca5ad51cdd4299dce005b56c46227f0
[ffmpeg.git] / libavcodec / x86 / vp9lpf.asm
1 ;******************************************************************************
2 ;* VP9 loop filter SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
5 ;*
6 ;* This file is part of Libav.
7 ;*
8 ;* Libav is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* Libav is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with Libav; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23
24 %include "libavutil/x86/x86util.asm"
25
26 %if ARCH_X86_64
27
28 SECTION_RODATA
29
30 cextern pb_3
31 cextern pb_80
32
33 pb_4:   times 16 db 0x04
34 pb_10:  times 16 db 0x10
35 pb_40:  times 16 db 0x40
36 pb_81:  times 16 db 0x81
37 pb_f8:  times 16 db 0xf8
38 pb_fe:  times 16 db 0xfe
39
40 pw_4:   times  8 dw 4
41 pw_8:   times  8 dw 8
42
43 ; with mix functions, two 8-bit thresholds are stored in a 16-bit storage,
44 ; the following mask is used to splat both in the same register
45 mask_mix: times 8 db 0
46           times 8 db 1
47
48 mask_mix84: times 8 db 0xff
49             times 8 db 0x00
50 mask_mix48: times 8 db 0x00
51             times 8 db 0xff
52
53 SECTION .text
54
55 ; %1 = abs(%2-%3)
56 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
57     psubusb             %1, %3, %2
58     psubusb             %4, %2, %3
59     por                 %1, %4
60 %endmacro
61
62 ; %1 = %1<=%2
63 %macro CMP_LTE 3-4 ; src/dst, cmp, tmp, pb_80
64 %if %0 == 4
65     pxor                %1, %4
66 %endif
67     pcmpgtb             %3, %2, %1          ; cmp > src?
68     pcmpeqb             %1, %2              ; cmp == src? XXX: avoid this with a -1/+1 well placed?
69     por                 %1, %3              ; cmp >= src?
70 %endmacro
71
72 ; %1 = abs(%2-%3) <= %4
73 %macro ABSSUB_CMP 5-6 [pb_80]; dst, src1, src2, cmp, tmp, [pb_80]
74     ABSSUB              %1, %2, %3, %5      ; dst = abs(src1-src2)
75     CMP_LTE             %1, %4, %5, %6      ; dst <= cmp
76 %endmacro
77
78 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
79     pand                %1, %3              ; new &= mask
80     pandn               %4, %3, %2          ; tmp = ~mask & old
81     por                 %1, %4              ; new&mask | old&~mask
82 %endmacro
83
84 %macro FILTER_SUBx2_ADDx2 8 ; %1=dst %2=h/l %3=cache %4=sub1 %5=sub2 %6=add1 %7=add2 %8=rshift
85     punpck%2bw          %3, %4, m0
86     psubw               %1, %3
87     punpck%2bw          %3, %5, m0
88     psubw               %1, %3
89     punpck%2bw          %3, %6, m0
90     paddw               %1, %3
91     punpck%2bw          %3, %7, m0
92     paddw               %3, %1
93     psraw               %1, %3, %8
94 %endmacro
95
96 %macro FILTER_INIT 8 ; tmp1, tmp2, cacheL, cacheH, dstp, filterid, mask, source
97     FILTER%6_INIT       %1, l, %3
98     FILTER%6_INIT       %2, h, %4
99     packuswb            %1, %2
100     MASK_APPLY          %1, %8, %7, %2
101     mova                %5, %1
102 %endmacro
103
104 %macro FILTER_UPDATE 11-14 ; tmp1, tmp2, cacheL, cacheH, dstp, -, -, +, +, rshift, mask, [source], [preload reg + value]
105 %if %0 == 13 ; no source + preload
106     mova                %12, %13
107 %elif %0 == 14 ; source + preload
108     mova                %13, %14
109 %endif
110     FILTER_SUBx2_ADDx2  %1, l, %3, %6, %7, %8, %9, %10
111     FILTER_SUBx2_ADDx2  %2, h, %4, %6, %7, %8, %9, %10
112     packuswb            %1, %2
113 %if %0 == 12 || %0 == 14
114     MASK_APPLY          %1, %12, %11, %2
115 %else
116     MASK_APPLY          %1, %5, %11, %2
117 %endif
118     mova                %5, %1
119 %endmacro
120
121 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
122     mova                %4, [pb_f8]
123     pand                %1, %4
124     pand                %2, %4
125     psrlq               %1, 3
126     psrlq               %2, 3
127     pxor                %1, %3
128     pxor                %2, %3
129     psubb               %1, %3
130     psubb               %2, %3
131 %endmacro
132
133 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
134     pxor                %3, %3
135     pxor                %2, %2
136     pcmpgtb             %3, %1                          ; i8 < 0 mask
137     psubb               %2, %1                          ; neg values (only the originally - will be kept)
138     pand                %2, %3                          ; negative values of i8 (but stored as +)
139     pandn               %3, %1                          ; positive values of i8
140 %endmacro
141
142 ; clip_u8(u8 + i8)
143 %macro SIGN_ADD 5 ; dst, u8, i8, tmp1, tmp2
144     EXTRACT_POS_NEG     %3, %4, %5
145     psubusb             %1, %2, %4                      ; sub the negatives
146     paddusb             %1, %5                          ; add the positives
147 %endmacro
148
149 ; clip_u8(u8 - i8)
150 %macro SIGN_SUB 5 ; dst, u8, i8, tmp1, tmp2
151     EXTRACT_POS_NEG     %3, %4, %5
152     psubusb             %1, %2, %5                      ; sub the positives
153     paddusb             %1, %4                          ; add the negatives
154 %endmacro
155
156 %macro FILTER6_INIT 3 ; %1=dst %2=h/l %3=cache
157     punpck%2bw          %1, m14, m0                     ; p3: B->W
158     paddw               %3, %1, %1                      ; p3*2
159     paddw               %3, %1                          ; p3*3
160     punpck%2bw          %1, m15, m0                     ; p2: B->W
161     paddw               %3, %1                          ; p3*3 + p2
162     paddw               %3, %1                          ; p3*3 + p2*2
163     punpck%2bw          %1, m10, m0                     ; p1: B->W
164     paddw               %3, %1                          ; p3*3 + p2*2 + p1
165     punpck%2bw          %1, m11, m0                     ; p0: B->W
166     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0
167     punpck%2bw          %1, m12, m0                     ; q0: B->W
168     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0 + q0
169     paddw               %3, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
170     psraw               %1, %3, 3                       ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
171 %endmacro
172
173 %macro FILTER14_INIT 3 ; %1=dst %2=h/l %3=cache
174     punpck%2bw          %1, m2, m0                      ; p7: B->W
175     psllw               %3, %1, 3                       ; p7*8
176     psubw               %3, %1                          ; p7*7
177     punpck%2bw          %1, m3, m0                      ; p6: B->W
178     paddw               %3, %1                          ; p7*7 + p6
179     paddw               %3, %1                          ; p7*7 + p6*2
180     punpck%2bw          %1, m8, m0                      ; p5: B->W
181     paddw               %3, %1                          ; p7*7 + p6*2 + p5
182     punpck%2bw          %1, m9, m0                      ; p4: B->W
183     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4
184     punpck%2bw          %1, m14, m0                     ; p3: B->W
185     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4 + p3
186     punpck%2bw          %1, m15, m0                     ; p2: B->W
187     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p2
188     punpck%2bw          %1, m10, m0                     ; p1: B->W
189     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p1
190     punpck%2bw          %1, m11, m0                     ; p0: B->W
191     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p0
192     punpck%2bw          %1, m12, m0                     ; q0: B->W
193     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + .. + p0 + q0
194     paddw               %3, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
195     psraw               %1, %3, 4                       ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
196 %endmacro
197
198 %macro TRANSPOSE16x16B 17
199     mova %17, m%16
200     SBUTTERFLY bw,  %1,  %2,  %16
201     SBUTTERFLY bw,  %3,  %4,  %16
202     SBUTTERFLY bw,  %5,  %6,  %16
203     SBUTTERFLY bw,  %7,  %8,  %16
204     SBUTTERFLY bw,  %9,  %10, %16
205     SBUTTERFLY bw,  %11, %12, %16
206     SBUTTERFLY bw,  %13, %14, %16
207     mova m%16,  %17
208     mova  %17, m%14
209     SBUTTERFLY bw,  %15, %16, %14
210     SBUTTERFLY wd,  %1,  %3,  %14
211     SBUTTERFLY wd,  %2,  %4,  %14
212     SBUTTERFLY wd,  %5,  %7,  %14
213     SBUTTERFLY wd,  %6,  %8,  %14
214     SBUTTERFLY wd,  %9,  %11, %14
215     SBUTTERFLY wd,  %10, %12, %14
216     SBUTTERFLY wd,  %13, %15, %14
217     mova m%14,  %17
218     mova  %17, m%12
219     SBUTTERFLY wd,  %14, %16, %12
220     SBUTTERFLY dq,  %1,  %5,  %12
221     SBUTTERFLY dq,  %2,  %6,  %12
222     SBUTTERFLY dq,  %3,  %7,  %12
223     SBUTTERFLY dq,  %4,  %8,  %12
224     SBUTTERFLY dq,  %9,  %13, %12
225     SBUTTERFLY dq,  %10, %14, %12
226     SBUTTERFLY dq,  %11, %15, %12
227     mova m%12, %17
228     mova  %17, m%8
229     SBUTTERFLY dq,  %12, %16, %8
230     SBUTTERFLY qdq, %1,  %9,  %8
231     SBUTTERFLY qdq, %2,  %10, %8
232     SBUTTERFLY qdq, %3,  %11, %8
233     SBUTTERFLY qdq, %4,  %12, %8
234     SBUTTERFLY qdq, %5,  %13, %8
235     SBUTTERFLY qdq, %6,  %14, %8
236     SBUTTERFLY qdq, %7,  %15, %8
237     mova m%8, %17
238     mova %17, m%1
239     SBUTTERFLY qdq, %8,  %16, %1
240     mova m%1, %17
241     SWAP %2,  %9
242     SWAP %3,  %5
243     SWAP %4,  %13
244     SWAP %6,  %11
245     SWAP %8,  %15
246     SWAP %12, %14
247 %endmacro
248
249 ; transpose 16 half lines (high part) to 8 full centered lines
250 %macro TRANSPOSE16x8B 16
251     punpcklbw   m%1,  m%2
252     punpcklbw   m%3,  m%4
253     punpcklbw   m%5,  m%6
254     punpcklbw   m%7,  m%8
255     punpcklbw   m%9,  m%10
256     punpcklbw   m%11, m%12
257     punpcklbw   m%13, m%14
258     punpcklbw   m%15, m%16
259     SBUTTERFLY  wd,  %1,  %3,  %2
260     SBUTTERFLY  wd,  %5,  %7,  %2
261     SBUTTERFLY  wd,  %9,  %11, %2
262     SBUTTERFLY  wd,  %13, %15, %2
263     SBUTTERFLY  dq,  %1,  %5,  %2
264     SBUTTERFLY  dq,  %3,  %7,  %2
265     SBUTTERFLY  dq,  %9,  %13, %2
266     SBUTTERFLY  dq,  %11, %15, %2
267     SBUTTERFLY  qdq, %1,  %9,  %2
268     SBUTTERFLY  qdq, %3,  %11, %2
269     SBUTTERFLY  qdq, %5,  %13, %2
270     SBUTTERFLY  qdq, %7,  %15, %2
271     SWAP %5, %1
272     SWAP %6, %9
273     SWAP %7, %1
274     SWAP %8, %13
275     SWAP %9, %3
276     SWAP %10, %11
277     SWAP %11, %1
278     SWAP %12, %15
279 %endmacro
280
281 %macro DEFINE_REAL_P7_TO_Q7 0-1 0
282 %define P7 dstq  + 4*mstrideq  + %1
283 %define P6 dstq  +   mstride3q + %1
284 %define P5 dstq  + 2*mstrideq  + %1
285 %define P4 dstq  +   mstrideq  + %1
286 %define P3 dstq                + %1
287 %define P2 dstq  +    strideq  + %1
288 %define P1 dstq  + 2* strideq  + %1
289 %define P0 dstq  +    stride3q + %1
290 %define Q0 dstq  + 4* strideq  + %1
291 %define Q1 dst2q +   mstride3q + %1
292 %define Q2 dst2q + 2*mstrideq  + %1
293 %define Q3 dst2q +   mstrideq  + %1
294 %define Q4 dst2q               + %1
295 %define Q5 dst2q +    strideq  + %1
296 %define Q6 dst2q + 2* strideq  + %1
297 %define Q7 dst2q +    stride3q + %1
298 %endmacro
299
300 ; ..............AB -> AAAAAAAABBBBBBBB
301 %macro SPLATB_MIX 1-2 [mask_mix]
302 %if cpuflag(ssse3)
303     pshufb     %1, %2
304 %else
305     punpcklbw  %1, %1
306     punpcklwd  %1, %1
307     punpckldq  %1, %1
308 %endif
309 %endmacro
310
311 %macro LOOPFILTER 3 ; %1=v/h %2=size1 %3=stack
312 %if UNIX64
313 cglobal vp9_loop_filter_%1_%2_16, 5, 9, 16, %3, dst, stride, E, I, H, mstride, dst2, stride3, mstride3
314 %else
315 %if WIN64
316 cglobal vp9_loop_filter_%1_%2_16, 4, 8, 16, %3, dst, stride, E, I, mstride, dst2, stride3, mstride3
317 %else
318 cglobal vp9_loop_filter_%1_%2_16, 2, 6, 16, %3, dst, stride, mstride, dst2, stride3, mstride3
319 %define Ed dword r2m
320 %define Id dword r3m
321 %endif
322 %define Hd dword r4m
323 %endif
324
325     mov               mstrideq, strideq
326     neg               mstrideq
327
328     lea               stride3q, [strideq*3]
329     lea              mstride3q, [mstrideq*3]
330
331 %ifidn %1, h
332 %if %2 > 16
333 %define movx movh
334     lea                   dstq, [dstq + 4*strideq - 4]
335 %else
336 %define movx movu
337     lea                   dstq, [dstq + 4*strideq - 8] ; go from top center (h pos) to center left (v pos)
338 %endif
339     lea                  dst2q, [dstq + 8*strideq]
340 %else
341     lea                   dstq, [dstq + 4*mstrideq]
342     lea                  dst2q, [dstq + 8*strideq]
343 %endif
344
345     DEFINE_REAL_P7_TO_Q7
346
347 %ifidn %1, h
348     movx                    m0, [P7]
349     movx                    m1, [P6]
350     movx                    m2, [P5]
351     movx                    m3, [P4]
352     movx                    m4, [P3]
353     movx                    m5, [P2]
354     movx                    m6, [P1]
355     movx                    m7, [P0]
356     movx                    m8, [Q0]
357     movx                    m9, [Q1]
358     movx                   m10, [Q2]
359     movx                   m11, [Q3]
360     movx                   m12, [Q4]
361     movx                   m13, [Q5]
362     movx                   m14, [Q6]
363     movx                   m15, [Q7]
364 %define P7 rsp +   0
365 %define P6 rsp +  16
366 %define P5 rsp +  32
367 %define P4 rsp +  48
368 %define P3 rsp +  64
369 %define P2 rsp +  80
370 %define P1 rsp +  96
371 %define P0 rsp + 112
372 %define Q0 rsp + 128
373 %define Q1 rsp + 144
374 %define Q2 rsp + 160
375 %define Q3 rsp + 176
376 %define Q4 rsp + 192
377 %define Q5 rsp + 208
378 %define Q6 rsp + 224
379 %define Q7 rsp + 240
380
381 %if %2 == 16
382     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
383     mova           [P7],  m0
384     mova           [P6],  m1
385     mova           [P5],  m2
386     mova           [P4],  m3
387 %else
388     TRANSPOSE16x8B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15
389 %endif
390     mova           [P3],  m4
391     mova           [P2],  m5
392     mova           [P1],  m6
393     mova           [P0],  m7
394     mova           [Q0],  m8
395     mova           [Q1],  m9
396     mova           [Q2], m10
397     mova           [Q3], m11
398 %if %2 == 16
399     mova           [Q4], m12
400     mova           [Q5], m13
401     mova           [Q6], m14
402     mova           [Q7], m15
403 %endif
404 %endif
405
406     ; calc fm mask
407 %if %2 == 16
408 %if cpuflag(ssse3)
409     pxor                m0, m0
410 %endif
411     SPLATB_REG          m2, I, m0                       ; I I I I ...
412     SPLATB_REG          m3, E, m0                       ; E E E E ...
413 %else
414 %if cpuflag(ssse3)
415     mova                m0, [mask_mix]
416 %endif
417     movd                m2, Id
418     movd                m3, Ed
419     SPLATB_MIX          m2, m0
420     SPLATB_MIX          m3, m0
421 %endif
422     mova                m0, [pb_80]
423     pxor                m2, m0
424     pxor                m3, m0
425 %ifidn %1, v
426     mova                m8, [P3]
427     mova                m9, [P2]
428     mova               m10, [P1]
429     mova               m11, [P0]
430     mova               m12, [Q0]
431     mova               m13, [Q1]
432     mova               m14, [Q2]
433     mova               m15, [Q3]
434 %else
435     ; In case of horizontal, P3..Q3 are already present in some registers due
436     ; to the previous transpose, so we just swap registers.
437     SWAP                 8,  4, 12
438     SWAP                 9,  5, 13
439     SWAP                10,  6, 14
440     SWAP                11,  7, 15
441 %endif
442     ABSSUB_CMP          m5,  m8,  m9, m2, m7, m0        ; m5 = abs(p3-p2) <= I
443     ABSSUB_CMP          m1,  m9, m10, m2, m7, m0        ; m1 = abs(p2-p1) <= I
444     pand                m5, m1
445     ABSSUB_CMP          m1, m10, m11, m2, m7, m0        ; m1 = abs(p1-p0) <= I
446     pand                m5, m1
447     ABSSUB_CMP          m1, m12, m13, m2, m7, m0        ; m1 = abs(q1-q0) <= I
448     pand                m5, m1
449     ABSSUB_CMP          m1, m13, m14, m2, m7, m0        ; m1 = abs(q2-q1) <= I
450     pand                m5, m1
451     ABSSUB_CMP          m1, m14, m15, m2, m7, m0        ; m1 = abs(q3-q2) <= I
452     pand                m5, m1
453     ABSSUB              m1, m11, m12, m7                ; abs(p0-q0)
454     paddusb             m1, m1                          ; abs(p0-q0) * 2
455     ABSSUB              m2, m10, m13, m7                ; abs(p1-q1)
456     pand                m2, [pb_fe]                     ; drop lsb so shift can work
457     psrlq               m2, 1                           ; abs(p1-q1)/2
458     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
459     pxor                m1, m0
460     pcmpgtb             m4, m3, m1                      ; E > X?
461     pcmpeqb             m3, m1                          ; E == X?
462     por                 m3, m4                          ; E >= X?
463     pand                m3, m5                          ; fm final value
464
465     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
466     ; calc flat8in (if not 44_16) and hev masks
467     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
468 %if %2 != 44
469     ABSSUB_CMP          m2, m8, m11, m6, m5             ; abs(p3 - p0) <= 1
470     mova                m8, [pb_80]
471     ABSSUB_CMP          m1, m9, m11, m6, m5, m8         ; abs(p2 - p0) <= 1
472     pand                m2, m1
473     ABSSUB              m4, m10, m11, m5                ; abs(p1 - p0)
474 %if %2 == 16
475 %if cpuflag(ssse3)
476     pxor                m0, m0
477 %endif
478     SPLATB_REG          m7, H, m0                       ; H H H H ...
479 %else
480     movd                m7, Hd
481     SPLATB_MIX          m7
482 %endif
483     pxor                m7, m8
484     pxor                m4, m8
485     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
486     CMP_LTE             m4, m6, m5                      ; abs(p1 - p0) <= 1
487     pand                m2, m4                          ; (flat8in)
488     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
489     pxor                m4, m8
490     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
491     por                 m0, m5                          ; hev final value
492     CMP_LTE             m4, m6, m5                      ; abs(q1 - q0) <= 1
493     pand                m2, m4                          ; (flat8in)
494     ABSSUB_CMP          m1, m14, m12, m6, m5, m8        ; abs(q2 - q0) <= 1
495     pand                m2, m1
496     ABSSUB_CMP          m1, m15, m12, m6, m5, m8        ; abs(q3 - q0) <= 1
497     pand                m2, m1                          ; flat8in final value
498 %if %2 == 84 || %2 == 48
499     pand                m2, [mask_mix%2]
500 %endif
501 %else
502     mova                m6, [pb_80]
503     movd                m7, Hd
504     SPLATB_MIX          m7
505     pxor                m7, m6
506     ABSSUB              m4, m10, m11, m1                ; abs(p1 - p0)
507     pxor                m4, m6
508     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
509     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
510     pxor                m4, m6
511     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
512     por                 m0, m5                          ; hev final value
513 %endif
514
515 %if %2 == 16
516     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
517     ; calc flat8out mask
518     mova                m8, [P7]
519     mova                m9, [P6]
520     ABSSUB_CMP          m1, m8, m11, m6, m5             ; abs(p7 - p0) <= 1
521     ABSSUB_CMP          m7, m9, m11, m6, m5             ; abs(p6 - p0) <= 1
522     pand                m1, m7
523     mova                m8, [P5]
524     mova                m9, [P4]
525     ABSSUB_CMP          m7, m8, m11, m6, m5             ; abs(p5 - p0) <= 1
526     pand                m1, m7
527     ABSSUB_CMP          m7, m9, m11, m6, m5             ; abs(p4 - p0) <= 1
528     pand                m1, m7
529     mova                m14, [Q4]
530     mova                m15, [Q5]
531     ABSSUB_CMP          m7, m14, m12, m6, m5            ; abs(q4 - q0) <= 1
532     pand                m1, m7
533     ABSSUB_CMP          m7, m15, m12, m6, m5            ; abs(q5 - q0) <= 1
534     pand                m1, m7
535     mova                m14, [Q6]
536     mova                m15, [Q7]
537     ABSSUB_CMP          m7, m14, m12, m6, m5            ; abs(q4 - q0) <= 1
538     pand                m1, m7
539     ABSSUB_CMP          m7, m15, m12, m6, m5            ; abs(q5 - q0) <= 1
540     pand                m1, m7                          ; flat8out final value
541 %endif
542
543     ; if (fm) {
544     ;     if (out && in) filter_14()
545     ;     else if (in)   filter_6()
546     ;     else if (hev)  filter_2()
547     ;     else           filter_4()
548     ; }
549     ;
550     ; f14:                                                                            fm &  out &  in
551     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
552     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
553     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
554
555     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
556     ; filter2()
557 %if %2 != 44
558     mova                m6, [pb_80]                     ; already in m6 if 44_16
559 %endif
560     pxor                m15, m12, m6                    ; q0 ^ 0x80
561     pxor                m14, m11, m6                    ; p0 ^ 0x80
562     psubsb              m15, m14                        ; (signed) q0 - p0
563     pxor                m4, m10, m6                     ; p1 ^ 0x80
564     pxor                m5, m13, m6                     ; q1 ^ 0x80
565     psubsb              m4, m5                          ; (signed) p1 - q1
566     paddsb              m4, m15                         ;   (q0 - p0) + (p1 - q1)
567     paddsb              m4, m15                         ; 2*(q0 - p0) + (p1 - q1)
568     paddsb              m4, m15                         ; 3*(q0 - p0) + (p1 - q1)
569     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
570     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
571     mova                m14, [pb_10]                    ; will be reused in filter4()
572     SRSHIFT3B_2X        m6, m4, m14, m7                 ; f1 and f2 sign byte shift by 3
573     SIGN_SUB            m7, m12, m6, m5, m9             ; m7 = q0 - f1
574     SIGN_ADD            m8, m11, m4, m5, m9             ; m8 = p0 + f2
575 %if %2 != 44
576     pandn               m6, m2, m3                      ;  ~mask(in) & mask(fm)
577     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
578 %else
579     pand                m6, m3, m0
580 %endif
581     MASK_APPLY          m7, m12, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
582     MASK_APPLY          m8, m11, m6, m5                 ; m8 = filter2(p0) & mask / we write it in filter4()
583
584     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m7..m8: q0' p0', m10..13: p1 p0 q0 q1, m14: pb_10, m15: q0-p0)
585     ; filter4()
586     mova                m4, m15
587     paddsb              m15, m4                         ; 2 * (q0 - p0)
588     paddsb              m15, m4                         ; 3 * (q0 - p0)
589     paddsb              m6, m15, [pb_4]                 ; m6:  f1 = clip(f + 4, 127)
590     paddsb              m15, [pb_3]                     ; m15: f2 = clip(f + 3, 127)
591     SRSHIFT3B_2X        m6, m15, m14, m9                ; f1 and f2 sign byte shift by 3
592 %if %2 != 44
593 %define p0tmp m7
594 %define q0tmp m9
595     pandn               m5, m2, m3                      ;               ~mask(in) & mask(fm)
596     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
597 %else
598 %define p0tmp m1
599 %define q0tmp m2
600     pandn               m0, m3
601 %endif
602     SIGN_SUB            q0tmp, m12, m6, m4, m14         ; q0 - f1
603     MASK_APPLY          q0tmp, m7, m0, m5               ; filter4(q0) & mask
604     mova                [Q0], q0tmp
605     SIGN_ADD            p0tmp, m11, m15, m4, m14        ; p0 + f2
606     MASK_APPLY          p0tmp, m8, m0, m5               ; filter4(p0) & mask
607     mova                [P0], p0tmp
608     paddb               m6, [pb_80]                     ;
609     pxor                m8, m8                          ;   f=(f1+1)>>1
610     pavgb               m6, m8                          ;
611     psubb               m6, [pb_40]                     ;
612     SIGN_ADD            m7, m10, m6, m8, m9             ; p1 + f
613     SIGN_SUB            m4, m13, m6, m8, m9             ; q1 - f
614     MASK_APPLY          m7, m10, m0, m14                ; m7 = filter4(p1)
615     MASK_APPLY          m4, m13, m0, m14                ; m4 = filter4(q1)
616     mova                [P1], m7
617     mova                [Q1], m4
618
619     ; ([m1: flat8out], m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
620     ; filter6()
621 %if %2 != 44
622     pxor                m0, m0
623 %if %2 > 16
624     pand                m3, m2
625 %else
626     pand                m2, m3                          ;               mask(fm) & mask(in)
627     pandn               m3, m1, m2                      ; ~mask(out) & (mask(fm) & mask(in))
628 %endif
629     mova               m14, [P3]
630     mova               m15, [P2]
631     mova                m8, [Q2]
632     mova                m9, [Q3]
633     FILTER_INIT         m4, m5, m6, m7, [P2], 6,                     m3, m15    ; [p2]
634     FILTER_UPDATE       m6, m7, m4, m5, [P1], m14, m15, m10, m13, 3, m3         ; [p1] -p3 -p2 +p1 +q1
635     FILTER_UPDATE       m4, m5, m6, m7, [P0], m14, m10, m11,  m8, 3, m3         ; [p0] -p3 -p1 +p0 +q2
636     FILTER_UPDATE       m6, m7, m4, m5, [Q0], m14, m11, m12,  m9, 3, m3         ; [q0] -p3 -p0 +q0 +q3
637     FILTER_UPDATE       m4, m5, m6, m7, [Q1], m15, m12, m13,  m9, 3, m3         ; [q1] -p2 -q0 +q1 +q3
638     FILTER_UPDATE       m6, m7, m4, m5, [Q2], m10, m13,  m8,  m9, 3, m3,  m8    ; [q2] -p1 -q1 +q2 +q3
639 %endif
640
641     ; (m0: 0, [m1: flat8out], m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
642     ; filter14()
643     ;
644     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
645     ;
646     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
647     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
648     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
649     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
650     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
651     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
652     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
653     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
654     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
655     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
656     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
657     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
658     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
659     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
660     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
661
662 %if %2 == 16
663     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
664     mova            m2, [P7]
665     mova            m3, [P6]
666     mova            m8, [P5]
667     mova            m9, [P4]
668     FILTER_INIT     m4, m5, m6, m7, [P6],  14,                   m1,  m3
669     FILTER_UPDATE   m6, m7, m4, m5, [P5],  m2,  m3,  m8, m13, 4, m1,  m8                ; [p5] -p7 -p6 +p5 +q1
670     FILTER_UPDATE   m4, m5, m6, m7, [P4],  m2,  m8,  m9, m13, 4, m1,  m9, m13, [Q2]     ; [p4] -p7 -p5 +p4 +q2
671     FILTER_UPDATE   m6, m7, m4, m5, [P3],  m2,  m9, m14, m13, 4, m1, m14, m13, [Q3]     ; [p3] -p7 -p4 +p3 +q3
672     FILTER_UPDATE   m4, m5, m6, m7, [P2],  m2, m14, m15, m13, 4, m1,      m13, [Q4]     ; [p2] -p7 -p3 +p2 +q4
673     FILTER_UPDATE   m6, m7, m4, m5, [P1],  m2, m15, m10, m13, 4, m1,      m13, [Q5]     ; [p1] -p7 -p2 +p1 +q5
674     FILTER_UPDATE   m4, m5, m6, m7, [P0],  m2, m10, m11, m13, 4, m1,      m13, [Q6]     ; [p0] -p7 -p1 +p0 +q6
675     FILTER_UPDATE   m6, m7, m4, m5, [Q0],  m2, m11, m12, m13, 4, m1,      m13, [Q7]     ; [q0] -p7 -p0 +q0 +q7
676     FILTER_UPDATE   m4, m5, m6, m7, [Q1],  m3, m12,  m2, m13, 4, m1,       m2, [Q1]     ; [q1] -p6 -q0 +q1 +q7
677     FILTER_UPDATE   m6, m7, m4, m5, [Q2],  m8,  m2,  m3, m13, 4, m1,       m3, [Q2]     ; [q2] -p5 -q1 +q2 +q7
678     FILTER_UPDATE   m4, m5, m6, m7, [Q3],  m9,  m3,  m8, m13, 4, m1,  m8,  m8, [Q3]     ; [q3] -p4 -q2 +q3 +q7
679     FILTER_UPDATE   m6, m7, m4, m5, [Q4], m14,  m8,  m9, m13, 4, m1,  m9,  m9, [Q4]     ; [q4] -p3 -q3 +q4 +q7
680     FILTER_UPDATE   m4, m5, m6, m7, [Q5], m15,  m9, m14, m13, 4, m1, m14, m14, [Q5]     ; [q5] -p2 -q4 +q5 +q7
681     FILTER_UPDATE   m6, m7, m4, m5, [Q6], m10, m14, m15, m13, 4, m1, m15, m15, [Q6]     ; [q6] -p1 -q5 +q6 +q7
682 %endif
683
684 %ifidn %1, h
685 %if %2 == 16
686     mova                    m0, [P7]
687     mova                    m1, [P6]
688     mova                    m2, [P5]
689     mova                    m3, [P4]
690     mova                    m4, [P3]
691     mova                    m5, [P2]
692     mova                    m6, [P1]
693     mova                    m7, [P0]
694     mova                    m8, [Q0]
695     mova                    m9, [Q1]
696     mova                   m10, [Q2]
697     mova                   m11, [Q3]
698     mova                   m12, [Q4]
699     mova                   m13, [Q5]
700     mova                   m14, [Q6]
701     mova                   m15, [Q7]
702     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
703     DEFINE_REAL_P7_TO_Q7
704     movu  [P7],  m0
705     movu  [P6],  m1
706     movu  [P5],  m2
707     movu  [P4],  m3
708     movu  [P3],  m4
709     movu  [P2],  m5
710     movu  [P1],  m6
711     movu  [P0],  m7
712     movu  [Q0],  m8
713     movu  [Q1],  m9
714     movu  [Q2], m10
715     movu  [Q3], m11
716     movu  [Q4], m12
717     movu  [Q5], m13
718     movu  [Q6], m14
719     movu  [Q7], m15
720 %elif %2 == 44
721     SWAP 0, 7   ; m0 = p1
722     SWAP 3, 4   ; m3 = q1
723     DEFINE_REAL_P7_TO_Q7 2
724     SBUTTERFLY  bw, 0, 1, 8
725     SBUTTERFLY  bw, 2, 3, 8
726     SBUTTERFLY  wd, 0, 2, 8
727     SBUTTERFLY  wd, 1, 3, 8
728     movd  [P7], m0
729     movd  [P3], m2
730     movd  [Q0], m1
731     movd  [Q4], m3
732     psrldq  m0, 4
733     psrldq  m1, 4
734     psrldq  m2, 4
735     psrldq  m3, 4
736     movd  [P6], m0
737     movd  [P2], m2
738     movd  [Q1], m1
739     movd  [Q5], m3
740     psrldq  m0, 4
741     psrldq  m1, 4
742     psrldq  m2, 4
743     psrldq  m3, 4
744     movd  [P5], m0
745     movd  [P1], m2
746     movd  [Q2], m1
747     movd  [Q6], m3
748     psrldq  m0, 4
749     psrldq  m1, 4
750     psrldq  m2, 4
751     psrldq  m3, 4
752     movd  [P4], m0
753     movd  [P0], m2
754     movd  [Q3], m1
755     movd  [Q7], m3
756 %else
757     ; the following code do a transpose of 8 full lines to 16 half
758     ; lines (high part). It is inlined to avoid the need of a staging area
759     mova                    m0, [P3]
760     mova                    m1, [P2]
761     mova                    m2, [P1]
762     mova                    m3, [P0]
763     mova                    m4, [Q0]
764     mova                    m5, [Q1]
765     mova                    m6, [Q2]
766     mova                    m7, [Q3]
767     DEFINE_REAL_P7_TO_Q7
768     SBUTTERFLY  bw,  0,  1, 8
769     SBUTTERFLY  bw,  2,  3, 8
770     SBUTTERFLY  bw,  4,  5, 8
771     SBUTTERFLY  bw,  6,  7, 8
772     SBUTTERFLY  wd,  0,  2, 8
773     SBUTTERFLY  wd,  1,  3, 8
774     SBUTTERFLY  wd,  4,  6, 8
775     SBUTTERFLY  wd,  5,  7, 8
776     SBUTTERFLY  dq,  0,  4, 8
777     SBUTTERFLY  dq,  1,  5, 8
778     SBUTTERFLY  dq,  2,  6, 8
779     SBUTTERFLY  dq,  3,  7, 8
780     movh   [P7], m0
781     movhps [P6], m0
782     movh   [Q0], m1
783     movhps [Q1], m1
784     movh   [P3], m2
785     movhps [P2], m2
786     movh   [Q4], m3
787     movhps [Q5], m3
788     movh   [P5], m4
789     movhps [P4], m4
790     movh   [Q2], m5
791     movhps [Q3], m5
792     movh   [P1], m6
793     movhps [P0], m6
794     movh   [Q6], m7
795     movhps [Q7], m7
796 %endif
797 %endif
798
799     RET
800 %endmacro
801
802 %macro LPF_16_VH 2
803 INIT_XMM %2
804 LOOPFILTER v, %1, 0
805 LOOPFILTER h, %1, 256
806 %endmacro
807
808 %macro LPF_16_VH_ALL_OPTS 1
809 LPF_16_VH %1, sse2
810 LPF_16_VH %1, ssse3
811 LPF_16_VH %1, avx
812 %endmacro
813
814 LPF_16_VH_ALL_OPTS 16
815 LPF_16_VH_ALL_OPTS 44
816 LPF_16_VH_ALL_OPTS 48
817 LPF_16_VH_ALL_OPTS 84
818 LPF_16_VH_ALL_OPTS 88
819
820 %endif ; x86-64