vp9/x86: idct_32x32_add_ssse3 sub-8x8-idct.
[ffmpeg.git] / libavcodec / x86 / vp9itxfm.asm
1 ;******************************************************************************
2 ;* VP9 IDCT SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013 Clément Bœsch <u pkh me>
5 ;* Copyright (C) 2013 Ronald S. Bultje <rsbultje gmail com>
6 ;*
7 ;* This file is part of FFmpeg.
8 ;*
9 ;* FFmpeg is free software; you can redistribute it and/or
10 ;* modify it under the terms of the GNU Lesser General Public
11 ;* License as published by the Free Software Foundation; either
12 ;* version 2.1 of the License, or (at your option) any later version.
13 ;*
14 ;* FFmpeg is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;* Lesser General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU Lesser General Public
20 ;* License along with FFmpeg; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
22 ;******************************************************************************
23
24 %include "libavutil/x86/x86util.asm"
25
26 SECTION_RODATA
27
28 pw_11585x2: times 8 dw 23170
29
30 %macro VP9_IDCT_COEFFS 2
31 pw_m%1_%2:  times 4 dw -%1,  %2
32 pw_%2_%1:   times 4 dw  %2,  %1
33 pw_m%2_m%1: times 4 dw -%2, -%1
34 %endmacro
35
36 %macro VP9_IDCT_COEFFS_ALL 2
37 pw_%1x2: times 8 dw %1*2
38 pw_m%1x2: times 8 dw -%1*2
39 pw_%2x2: times 8 dw %2*2
40 pw_m%2x2: times 8 dw -%2*2
41 VP9_IDCT_COEFFS %1, %2
42 %endmacro
43
44 VP9_IDCT_COEFFS_ALL 15137,  6270
45 VP9_IDCT_COEFFS_ALL 16069,  3196
46 VP9_IDCT_COEFFS_ALL  9102, 13623
47 VP9_IDCT_COEFFS_ALL 16305,  1606
48 VP9_IDCT_COEFFS_ALL 10394, 12665
49 VP9_IDCT_COEFFS_ALL 14449,  7723
50 VP9_IDCT_COEFFS_ALL  4756, 15679
51 VP9_IDCT_COEFFS_ALL 16364,   804
52 VP9_IDCT_COEFFS_ALL 11003, 12140
53 VP9_IDCT_COEFFS_ALL 14811,  7005
54 VP9_IDCT_COEFFS_ALL  5520, 15426
55 VP9_IDCT_COEFFS_ALL 15893,  3981
56 VP9_IDCT_COEFFS_ALL  8423, 14053
57 VP9_IDCT_COEFFS_ALL 13160,  9760
58 VP9_IDCT_COEFFS_ALL  2404, 16207
59
60 pd_8192: times 4 dd 8192
61 pw_2048: times 8 dw 2048
62 pw_1024: times 8 dw 1024
63 pw_512:  times 8 dw 512
64
65 SECTION .text
66
67 ; (a*x + b*y + round) >> shift
68 %macro VP9_MULSUB_2W_2X 6 ; dst1, dst2, src (unchanged), round, coefs1, coefs2
69     pmaddwd            m%1, m%3, %5
70     pmaddwd            m%2, m%3, %6
71     paddd              m%1,  %4
72     paddd              m%2,  %4
73     psrad              m%1,  14
74     psrad              m%2,  14
75 %endmacro
76
77 %macro VP9_UNPACK_MULSUB_2W_4X 7-9 ; dst1, dst2, (src1, src2,) coef1, coef2, rnd, tmp1, tmp2
78 %if %0 == 7
79     punpckhwd          m%6, m%2, m%1
80     VP9_MULSUB_2W_2X    %7,  %6,  %6, %5, [pw_m%3_%4], [pw_%4_%3]
81     punpcklwd          m%2, m%1
82     VP9_MULSUB_2W_2X    %1,  %2,  %2, %5, [pw_m%3_%4], [pw_%4_%3]
83     packssdw           m%1, m%7
84     packssdw           m%2, m%6
85 %else
86     punpckhwd          m%8, m%4, m%3
87     VP9_MULSUB_2W_2X    %9,  %8,  %8, %7, [pw_m%5_%6], [pw_%6_%5]
88     punpcklwd          m%2, m%4, m%3
89     VP9_MULSUB_2W_2X    %1,  %2,  %2, %7, [pw_m%5_%6], [pw_%6_%5]
90     packssdw           m%1, m%9
91     packssdw           m%2, m%8
92 %endif
93 %endmacro
94
95 %macro VP9_STORE_2X 5-6 dstq ; reg1, reg2, tmp1, tmp2, zero, dst
96     movh               m%3, [%6]
97     movh               m%4, [%6+strideq]
98     punpcklbw          m%3, m%5
99     punpcklbw          m%4, m%5
100     paddw              m%3, m%1
101     paddw              m%4, m%2
102     packuswb           m%3, m%5
103     packuswb           m%4, m%5
104     movh              [%6], m%3
105     movh      [%6+strideq], m%4
106 %endmacro
107
108 ;-------------------------------------------------------------------------------------------
109 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
110 ;-------------------------------------------------------------------------------------------
111
112 %macro VP9_IDCT4_1D_FINALIZE 0
113     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
114     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
115     SWAP                 0, 3, 2                            ; 3102 -> 0123
116 %endmacro
117
118 %macro VP9_IDCT4_1D 0
119     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
120     pmulhrsw            m2, m6                              ; m2=t0
121     pmulhrsw            m0, m6                              ; m0=t1
122     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270, m7, 4, 5     ; m1=t2, m3=t3
123     VP9_IDCT4_1D_FINALIZE
124 %endmacro
125
126 ; 2x2 top left corner
127 %macro VP9_IDCT4_2x2_1D 0
128     pmulhrsw            m0, m5                              ; m0=t1
129     mova                m2, m0                              ; m2=t0
130     mova                m3, m1
131     pmulhrsw            m1, m6                              ; m1=t2
132     pmulhrsw            m3, m7                              ; m3=t3
133     VP9_IDCT4_1D_FINALIZE
134 %endmacro
135
136 %macro VP9_IDCT4_WRITEOUT 0
137     mova                m5, [pw_2048]
138     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
139     pmulhrsw            m1, m5
140     VP9_STORE_2X         0,  1,  6,  7,  4
141     lea               dstq, [dstq+2*strideq]
142     pmulhrsw            m2, m5
143     pmulhrsw            m3, m5
144     VP9_STORE_2X         2,  3,  6,  7,  4
145 %endmacro
146
147 INIT_MMX ssse3
148 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
149
150     cmp eobd, 4 ; 2x2 or smaller
151     jg .idctfull
152
153     cmp eobd, 1 ; faster path for when only DC is set
154     jne .idct2x2
155
156     movd                m0, [blockq]
157     mova                m5, [pw_11585x2]
158     pmulhrsw            m0, m5
159     pmulhrsw            m0, m5
160     pshufw              m0, m0, 0
161     pxor                m4, m4
162     movh          [blockq], m4
163     pmulhrsw            m0, [pw_2048]       ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
164     VP9_STORE_2X         0,  0,  6,  7,  4
165     lea               dstq, [dstq+2*strideq]
166     VP9_STORE_2X         0,  0,  6,  7,  4
167     RET
168
169 ; faster path for when only top left 2x2 block is set
170 .idct2x2:
171     movd                m0, [blockq+0]
172     movd                m1, [blockq+8]
173     mova                m5, [pw_11585x2]
174     mova                m6, [pw_6270x2]
175     mova                m7, [pw_15137x2]
176     VP9_IDCT4_2x2_1D
177     TRANSPOSE4x4W  0, 1, 2, 3, 4
178     VP9_IDCT4_2x2_1D
179     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
180     movh       [blockq+ 0], m4
181     movh       [blockq+ 8], m4
182     VP9_IDCT4_WRITEOUT
183     RET
184
185 .idctfull: ; generic full 4x4 idct/idct
186     mova                m0, [blockq+ 0]
187     mova                m1, [blockq+ 8]
188     mova                m2, [blockq+16]
189     mova                m3, [blockq+24]
190     mova                m6, [pw_11585x2]
191     mova                m7, [pd_8192]       ; rounding
192     VP9_IDCT4_1D
193     TRANSPOSE4x4W  0, 1, 2, 3, 4
194     VP9_IDCT4_1D
195     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
196     mova       [blockq+ 0], m4
197     mova       [blockq+ 8], m4
198     mova       [blockq+16], m4
199     mova       [blockq+24], m4
200     VP9_IDCT4_WRITEOUT
201     RET
202
203 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use more)
204
205 ;-------------------------------------------------------------------------------------------
206 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
207 ;-------------------------------------------------------------------------------------------
208
209 %macro VP9_IDCT8_1D_FINALIZE 0
210     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
211     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
212     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
213     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
214     SWAP                11, 10, 2
215     SWAP                 3,  9, 0
216 %endmacro
217
218 %macro VP9_IDCT8_1D 0
219     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
220     pmulhrsw            m8, m12                             ; m8=t0a
221     pmulhrsw            m0, m12                             ; m0=t1a
222     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270, m7, 4, 5   ; m2=t2a, m10=t3a
223     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196, m7, 4, 5   ; m1=t4a, m11=t7a
224     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623, m7, 4, 5   ; m9=t5a,  m3=t6a
225     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
226     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
227     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
228     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
229     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
230     pmulhrsw            m1, m12                             ; m1=t6
231     pmulhrsw           m11, m12                             ; m11=t5
232     VP9_IDCT8_1D_FINALIZE
233 %endmacro
234
235 %macro VP9_IDCT8_4x4_1D 0
236     pmulhrsw            m0, m12                             ; m0=t1a/t0a
237     pmulhrsw           m10, m2, [pw_15137x2]                ; m10=t3a
238     pmulhrsw            m2, [pw_6270x2]                     ; m2=t2a
239     pmulhrsw           m11, m1, [pw_16069x2]                ; m11=t7a
240     pmulhrsw            m1, [pw_3196x2]                     ; m1=t4a
241     pmulhrsw            m9, m3, [pw_9102x2]                 ; m9=-t5a
242     pmulhrsw            m3, [pw_13623x2]                    ; m3=t6a
243     psubw               m8, m0, m10                         ; m8=t0a-t3a (t3)
244     paddw              m10, m0                              ; m10=t0a+t3a (t0)
245     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
246     SUMSUB_BA            w,  9,  1, 4                       ;  m1=t4a+t5a (t4),  m9=t4a-t5a (t5a)
247     SWAP                 1,  9
248     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
249     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
250     pmulhrsw            m1, m12                             ; m1=t6
251     pmulhrsw           m11, m12                             ; m11=t5
252     VP9_IDCT8_1D_FINALIZE
253 %endmacro
254
255 ; TODO: a lot of t* copies can probably be removed and merged with
256 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
257 %macro VP9_IDCT8_2x2_1D 0
258     pmulhrsw            m0, m12                             ;  m0=t0
259     mova                m3, m1
260     pmulhrsw            m1, m6                              ;  m1=t4
261     pmulhrsw            m3, m7                              ;  m3=t7
262     mova                m2, m0                              ;  m2=t1
263     mova               m10, m0                              ; m10=t2
264     mova                m8, m0                              ;  m8=t3
265     mova               m11, m3                              ; t5 = t7a ...
266     mova                m9, m3                              ; t6 = t7a ...
267     psubw              m11, m1                              ; t5 = t7a - t4a
268     paddw               m9, m1                              ; t6 = t7a + t4a
269     pmulhrsw           m11, m12                             ; m11=t5
270     pmulhrsw            m9, m12                             ;  m9=t6
271     SWAP                 0, 10
272     SWAP                 9,  1
273     VP9_IDCT8_1D_FINALIZE
274 %endmacro
275
276 %macro VP9_IDCT8_WRITEOUT 0
277     mova                m5, [pw_1024]
278     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
279     pmulhrsw            m1, m5
280     VP9_STORE_2X         0,  1,  6,  7,  4
281     lea               dstq, [dstq+2*strideq]
282     pmulhrsw            m2, m5
283     pmulhrsw            m3, m5
284     VP9_STORE_2X         2,  3,  6,  7,  4
285     lea               dstq, [dstq+2*strideq]
286     pmulhrsw            m8, m5
287     pmulhrsw            m9, m5
288     VP9_STORE_2X         8,  9,  6,  7,  4
289     lea               dstq, [dstq+2*strideq]
290     pmulhrsw           m10, m5
291     pmulhrsw           m11, m5
292     VP9_STORE_2X        10, 11,  6,  7,  4
293 %endmacro
294
295 INIT_XMM ssse3
296 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
297
298     mova               m12, [pw_11585x2]    ; often used
299
300     cmp eobd, 12 ; top left half or less
301     jg .idctfull
302
303     cmp eobd, 3  ; top left corner or less
304     jg .idcthalf
305
306     cmp eobd, 1 ; faster path for when only DC is set
307     jne .idcttopleftcorner
308
309     movd                m0, [blockq]
310     pmulhrsw            m0, m12
311     pmulhrsw            m0, m12
312     SPLATW              m0, m0, 0
313     pxor                m4, m4
314     movd          [blockq], m4
315     mova                m5, [pw_1024]
316     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
317     VP9_STORE_2X         0,  0,  6,  7,  4
318     lea               dstq, [dstq+2*strideq]
319     VP9_STORE_2X         0,  0,  6,  7,  4
320     lea               dstq, [dstq+2*strideq]
321     VP9_STORE_2X         0,  0,  6,  7,  4
322     lea               dstq, [dstq+2*strideq]
323     VP9_STORE_2X         0,  0,  6,  7,  4
324     RET
325
326 ; faster path for when only left corner is set (3 input: DC, right to DC, below
327 ; to DC). Note: also working with a 2x2 block
328 .idcttopleftcorner:
329     movd                m0, [blockq+0]
330     movd                m1, [blockq+16]
331     mova                m6, [pw_3196x2]
332     mova                m7, [pw_16069x2]
333     VP9_IDCT8_2x2_1D
334     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
335     VP9_IDCT8_2x2_1D
336     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
337     movd       [blockq+ 0], m4
338     movd       [blockq+16], m4
339     VP9_IDCT8_WRITEOUT
340     RET
341
342 .idcthalf:
343     movh                m0, [blockq + 0]
344     movh                m1, [blockq +16]
345     movh                m2, [blockq +32]
346     movh                m3, [blockq +48]
347     VP9_IDCT8_4x4_1D
348     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
349     VP9_IDCT8_4x4_1D
350     pxor                m4, m4
351     movh       [blockq+ 0], m4
352     movh       [blockq+16], m4
353     movh       [blockq+32], m4
354     movh       [blockq+48], m4
355     VP9_IDCT8_WRITEOUT
356     RET
357
358 .idctfull: ; generic full 8x8 idct/idct
359     mova                m0, [blockq+  0]    ; IN(0)
360     mova                m1, [blockq+ 16]    ; IN(1)
361     mova                m2, [blockq+ 32]    ; IN(2)
362     mova                m3, [blockq+ 48]    ; IN(3)
363     mova                m8, [blockq+ 64]    ; IN(4)
364     mova                m9, [blockq+ 80]    ; IN(5)
365     mova               m10, [blockq+ 96]    ; IN(6)
366     mova               m11, [blockq+112]    ; IN(7)
367     mova                m7, [pd_8192]       ; rounding
368     VP9_IDCT8_1D
369     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
370     VP9_IDCT8_1D
371     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
372     mova      [blockq+  0], m4
373     mova      [blockq+ 16], m4
374     mova      [blockq+ 32], m4
375     mova      [blockq+ 48], m4
376     mova      [blockq+ 64], m4
377     mova      [blockq+ 80], m4
378     mova      [blockq+ 96], m4
379     mova      [blockq+112], m4
380     VP9_IDCT8_WRITEOUT
381     RET
382
383 ;---------------------------------------------------------------------------------------------
384 ; void vp9_idct_idct_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
385 ;---------------------------------------------------------------------------------------------
386
387 ; at the end of this macro, m7 is stored in stack_scratch
388 ; everything else (t0-6 and t8-15) is stored in m0-6 and m8-15
389 ; the following sumsubs have not been done yet:
390 ;    SUMSUB_BA            w,  6,  9, 15      ; t6, t9
391 ;    SUMSUB_BA            w,  7,  8, 15      ; t7, t8
392 %macro VP9_IDCT16_1D_START 4 ; src, nnzc, stride, stack_scratch
393 %if %2 <= 4
394     mova                m3, [%1+ 1*%3]      ; IN(1)
395     mova               m12, [%1+ 2*%3]      ; IN(2)
396     mova                m0, [%1+ 3*%3]      ; IN(3)
397
398     pmulhrsw           m15, m12, [pw_16069x2]       ; t6-7
399     pmulhrsw           m12, [pw_3196x2]             ; t4-5
400     pmulhrsw            m4, m3,  [pw_16305x2]       ; t14-15
401     pmulhrsw            m3, [pw_1606x2]             ; t8-9
402     pmulhrsw            m7, m0,  [pw_m4756x2]       ; t10-11
403     pmulhrsw            m0, [pw_15679x2]            ; t12-13
404
405     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
406     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
407
408     paddw              m14, m15, m12
409     psubw              m13, m15, m12
410     pmulhrsw           m13, [pw_11585x2]            ; t5
411     pmulhrsw           m14, [pw_11585x2]            ; t6
412
413     VP9_UNPACK_MULSUB_2W_4X 2, 5, 4, 3, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
414     VP9_UNPACK_MULSUB_2W_4X 6, 1, 0, 7, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
415
416     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
417     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
418 %else
419     mova                m5, [%1+ 1*%3]     ; IN(1)
420     mova               m14, [%1+ 2*%3]     ; IN(2)
421     mova                m6, [%1+ 3*%3]     ; IN(3)
422     mova                m9, [%1+ 4*%3]     ; IN(4)
423     mova                m7, [%1+ 5*%3]     ; IN(5)
424     mova               m15, [%1+ 6*%3]     ; IN(6)
425     mova                m4, [%1+ 7*%3]     ; IN(7)
426 %if %2 <= 8
427     pmulhrsw            m8, m9,  [pw_15137x2]       ; t3
428     pmulhrsw            m9, [pw_6270x2]             ; t2
429     pmulhrsw           m13, m14, [pw_16069x2]       ; t7
430     pmulhrsw           m14, [pw_3196x2]             ; t4
431     pmulhrsw           m12, m15, [pw_m9102x2]       ; t5
432     pmulhrsw           m15, [pw_13623x2]            ; t6
433     pmulhrsw            m2, m5,  [pw_16305x2]       ; t15
434     pmulhrsw            m5, [pw_1606x2]             ; t8
435     pmulhrsw            m3, m4,  [pw_m10394x2]      ; t9
436     pmulhrsw            m4, [pw_12665x2]            ; t14
437     pmulhrsw            m0, m7,  [pw_14449x2]       ; t13
438     pmulhrsw            m7, [pw_7723x2]             ; t10
439     pmulhrsw            m1, m6,  [pw_m4756x2]       ; t11
440     pmulhrsw            m6, [pw_15679x2]            ; t12
441 %else
442     mova                m3, [%1+ 9*%3]     ; IN(9)
443     mova               m12, [%1+10*%3]     ; IN(10)
444     mova                m0, [%1+11*%3]     ; IN(11)
445     mova                m8, [%1+12*%3]     ; IN(12)
446     mova                m1, [%1+13*%3]     ; IN(13)
447     mova               m13, [%1+14*%3]     ; IN(14)
448     mova                m2, [%1+15*%3]     ; IN(15)
449
450     ; m10=in0, m5=in1, m14=in2, m6=in3, m9=in4, m7=in5, m15=in6, m4=in7
451     ; m11=in8, m3=in9, m12=in10 m0=in11, m8=in12, m1=in13, m13=in14, m2=in15
452
453     VP9_UNPACK_MULSUB_2W_4X   9,   8, 15137,  6270, [pd_8192], 10, 11 ; t2,  t3
454     VP9_UNPACK_MULSUB_2W_4X  14,  13, 16069,  3196, [pd_8192], 10, 11 ; t4,  t7
455     VP9_UNPACK_MULSUB_2W_4X  12,  15,  9102, 13623, [pd_8192], 10, 11 ; t5,  t6
456     VP9_UNPACK_MULSUB_2W_4X   5,   2, 16305,  1606, [pd_8192], 10, 11 ; t8,  t15
457     VP9_UNPACK_MULSUB_2W_4X   3,   4, 10394, 12665, [pd_8192], 10, 11 ; t9,  t14
458     VP9_UNPACK_MULSUB_2W_4X   7,   0, 14449,  7723, [pd_8192], 10, 11 ; t10, t13
459     VP9_UNPACK_MULSUB_2W_4X   1,   6,  4756, 15679, [pd_8192], 10, 11 ; t11, t12
460 %endif
461
462     ; m11=t0, m10=t1, m9=t2, m8=t3, m14=t4, m12=t5, m15=t6, m13=t7
463     ; m5=t8, m3=t9, m7=t10, m1=t11, m6=t12, m0=t13, m4=t14, m2=t15
464
465     SUMSUB_BA            w, 12, 14, 10      ; t4,  t5
466     SUMSUB_BA            w, 15, 13, 10      ; t7,  t6
467     SUMSUB_BA            w,  3,  5, 10      ; t8,  t9
468     SUMSUB_BA            w,  7,  1, 10      ; t11, t10
469     SUMSUB_BA            w,  0,  6, 10      ; t12, t13
470     SUMSUB_BA            w,  4,  2, 10      ; t15, t14
471
472     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
473     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
474
475     SUMSUB_BA            w, 14, 13, 10
476     pmulhrsw           m13, [pw_11585x2]                              ; t5
477     pmulhrsw           m14, [pw_11585x2]                              ; t6
478     VP9_UNPACK_MULSUB_2W_4X   2,   5, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
479     VP9_UNPACK_MULSUB_2W_4X   6,   1, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
480 %endif
481
482     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m13=t5, m14=t6, m15=t7
483     ; m3=t8, m2=t9, m6=t10, m7=t11, m0=t12, m1=t13, m5=t14, m4=t15
484
485     SUMSUB_BA            w,  7,  3, 10      ; t8,  t11
486     SUMSUB_BA            w,  6,  2, 10      ; t9,  t10
487     SUMSUB_BA            w,  0,  4, 10      ; t15, t12
488     SUMSUB_BA            w,  1,  5, 10      ; t14. t13
489
490     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
491     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
492
493     SUMSUB_BA            w,  2,  5, 10
494     SUMSUB_BA            w,  3,  4, 10
495     pmulhrsw            m5, [pw_11585x2]    ; t10
496     pmulhrsw            m4, [pw_11585x2]    ; t11
497     pmulhrsw            m3, [pw_11585x2]    ; t12
498     pmulhrsw            m2, [pw_11585x2]    ; t13
499
500     ; backup first register
501     mova              [%4], m7
502
503     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
504     ; m7=t8, m6=t9, m5=t10, m4=t11, m3=t12, m2=t13, m1=t14, m0=t15
505
506     ; from load/start
507 %if %2 <= 4
508     mova               m11, [%1+ 0*%3]      ; IN(0)
509     pmulhrsw           m11, [pw_11585x2]    ; t0-t3
510
511     psubw               m8, m11, m15
512     paddw              m15, m11
513     psubw               m9, m11, m14
514     paddw              m14, m11
515     psubw              m10, m11, m13
516     paddw              m13, m11
517 %else
518     mova               m10, [%1+ 0*%3]      ; IN(0)
519 %if %2 <= 8
520     pmulhrsw           m10, [pw_11585x2]    ; t0 and t1
521     psubw              m11, m10, m8
522     paddw               m8, m10
523 %else
524     mova               m11, [%1+ 8*%3]      ; IN(8)
525
526     ; from 3 stages back
527     SUMSUB_BA            w, 11, 10, 7
528     pmulhrsw           m11, [pw_11585x2]    ; t0
529     pmulhrsw           m10, [pw_11585x2]    ; t1
530
531     ; from 2 stages back
532     SUMSUB_BA            w,  8, 11, 7       ; t0,  t3
533 %endif
534     SUMSUB_BA            w,  9, 10, 7       ; t1,  t2
535
536     ; from 1 stage back
537     SUMSUB_BA            w, 15,  8, 7       ; t0,  t7
538     SUMSUB_BA            w, 14,  9, 7       ; t1,  t6
539     SUMSUB_BA            w, 13, 10, 7       ; t2,  t5
540 %endif
541     SUMSUB_BA            w, 12, 11, 7       ; t3,  t4
542
543     SUMSUB_BA            w,  0, 15, 7       ; t0, t15
544     SUMSUB_BA            w,  1, 14, 7       ; t1, t14
545     SUMSUB_BA            w,  2, 13, 7       ; t2, t13
546     SUMSUB_BA            w,  3, 12, 7       ; t3, t12
547     SUMSUB_BA            w,  4, 11, 7       ; t4, t11
548     SUMSUB_BA            w,  5, 10, 7       ; t5, t10
549 %endmacro
550
551 %macro VP9_IDCT16_1D 2-3 16 ; src, pass, nnzc
552     VP9_IDCT16_1D_START %1, %3, 32, rsp+32
553
554 %if %2 == 1
555     ; backup a different register
556     mova          [rsp+16], m15
557     mova                m7, [rsp+32]
558
559     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
560     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
561
562     TRANSPOSE8x8W        0, 1, 2, 3, 4, 5, 6, 7, 15
563     mova         [rsp+  0], m0
564     mova         [rsp+ 32], m1
565     mova         [rsp+ 64], m2
566     mova         [rsp+ 96], m3
567     mova         [rsp+128], m4
568     mova         [rsp+160], m5
569     mova         [rsp+192], m6
570     mova         [rsp+224], m7
571
572     mova               m15, [rsp+16]
573     TRANSPOSE8x8W        8, 9, 10, 11, 12, 13, 14, 15, 0
574     mova         [rsp+ 16], m8
575     mova         [rsp+ 48], m9
576     mova         [rsp+ 80], m10
577     mova         [rsp+112], m11
578     mova         [rsp+144], m12
579     mova         [rsp+176], m13
580     mova         [rsp+208], m14
581     mova         [rsp+240], m15
582 %else ; %2 == 2
583     ; backup more registers
584     mova          [rsp+64], m8
585     mova          [rsp+96], m9
586
587     pxor                m7, m7
588     pmulhrsw            m0, [pw_512]
589     pmulhrsw            m1, [pw_512]
590     VP9_STORE_2X         0,  1,  8,  9,  7
591     lea               dstq, [dstq+strideq*2]
592     pmulhrsw            m2, [pw_512]
593     pmulhrsw            m3, [pw_512]
594     VP9_STORE_2X         2,  3,  8,  9,  7
595     lea               dstq, [dstq+strideq*2]
596     pmulhrsw            m4, [pw_512]
597     pmulhrsw            m5, [pw_512]
598     VP9_STORE_2X         4,  5,  8,  9,  7
599     lea               dstq, [dstq+strideq*2]
600
601     ; restore from cache
602     SWAP                 0, 7               ; move zero from m7 to m0
603     mova                m7, [rsp+32]
604     mova                m8, [rsp+64]
605     mova                m9, [rsp+96]
606
607     SUMSUB_BA            w,  6,  9, 1       ; t6, t9
608     SUMSUB_BA            w,  7,  8, 1       ; t7, t8
609
610     pmulhrsw            m6, [pw_512]
611     pmulhrsw            m7, [pw_512]
612     VP9_STORE_2X         6,  7,  1,  2,  0
613     lea               dstq, [dstq+strideq*2]
614     pmulhrsw            m8, [pw_512]
615     pmulhrsw            m9, [pw_512]
616     VP9_STORE_2X         8,  9,  1,  2,  0
617     lea               dstq, [dstq+strideq*2]
618     pmulhrsw           m10, [pw_512]
619     pmulhrsw           m11, [pw_512]
620     VP9_STORE_2X        10, 11,  1,  2,  0
621     lea               dstq, [dstq+strideq*2]
622     pmulhrsw           m12, [pw_512]
623     pmulhrsw           m13, [pw_512]
624     VP9_STORE_2X        12, 13,  1,  2,  0
625     lea               dstq, [dstq+strideq*2]
626     pmulhrsw           m14, [pw_512]
627     pmulhrsw           m15, [pw_512]
628     VP9_STORE_2X        14, 15,  1,  2,  0
629 %endif ; %2 == 1/2
630 %endmacro
631
632 %macro ZERO_BLOCK 4 ; mem, stride, nnzcpl, zero_reg
633 %assign %%y 0
634 %rep %3
635 %assign %%x 0
636 %rep %3*2/mmsize
637     mova      [%1+%%y+%%x], %4
638 %assign %%x (%%x+mmsize)
639 %endrep
640 %assign %%y (%%y+%2)
641 %endrep
642 %endmacro
643
644 %macro VP9_STORE_2XFULL 6-7 strideq; dc, tmp1, tmp2, tmp3, tmp4, zero, stride
645     mova               m%3, [dstq]
646     mova               m%5, [dstq+%7]
647     punpcklbw          m%2, m%3, m%6
648     punpckhbw          m%3, m%6
649     punpcklbw          m%4, m%5, m%6
650     punpckhbw          m%5, m%6
651     paddw              m%2, m%1
652     paddw              m%3, m%1
653     paddw              m%4, m%1
654     paddw              m%5, m%1
655     packuswb           m%2, m%3
656     packuswb           m%4, m%5
657     mova            [dstq], m%2
658     mova         [dstq+%7], m%4
659 %endmacro
660
661 INIT_XMM ssse3
662 cglobal vp9_idct_idct_16x16_add, 4, 5, 16, 512, dst, stride, block, eob
663     ; 2x2=eob=3, 4x4=eob=10
664     cmp eobd, 38
665     jg .idctfull
666     cmp eobd, 1 ; faster path for when only DC is set
667     jne .idct8x8
668
669     ; dc-only
670     movd                m0, [blockq]
671     mova                m1, [pw_11585x2]
672     pmulhrsw            m0, m1
673     pmulhrsw            m0, m1
674     SPLATW              m0, m0, q0000
675     pmulhrsw            m0, [pw_512]
676     pxor                m5, m5
677     movd          [blockq], m5
678 %rep 7
679     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
680     lea               dstq, [dstq+2*strideq]
681 %endrep
682     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
683     RET
684
685 .idct8x8:
686     DEFINE_ARGS dst, stride, block, cnt, dst_bak
687     VP9_IDCT16_1D   blockq, 1, 8
688
689     mov               cntd, 2
690     mov           dst_bakq, dstq
691 .loop2_8x8:
692     VP9_IDCT16_1D      rsp, 2, 8
693     lea               dstq, [dst_bakq+8]
694     add                rsp, 16
695     dec               cntd
696     jg .loop2_8x8
697     sub                rsp, 32
698
699     ; at the end of the loop, m0 should still be zero
700     ; use that to zero out block coefficients
701     ZERO_BLOCK      blockq, 32, 8, m0
702     RET
703
704 .idctfull:
705     DEFINE_ARGS dst, stride, block, cnt, dst_bak
706     mov               cntd, 2
707 .loop1_full:
708     VP9_IDCT16_1D   blockq, 1
709     add             blockq, 16
710     add                rsp, 256
711     dec               cntd
712     jg .loop1_full
713     sub             blockq, 32
714     sub                rsp, 512
715
716     mov               cntd, 2
717     mov           dst_bakq, dstq
718 .loop2_full:
719     VP9_IDCT16_1D      rsp, 2
720     lea               dstq, [dst_bakq+8]
721     add                rsp, 16
722     dec               cntd
723     jg .loop2_full
724     sub                rsp, 32
725
726     ; at the end of the loop, m0 should still be zero
727     ; use that to zero out block coefficients
728     ZERO_BLOCK      blockq, 32, 16, m0
729     RET
730
731 ;---------------------------------------------------------------------------------------------
732 ; void vp9_idct_idct_32x32_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
733 ;---------------------------------------------------------------------------------------------
734
735 %macro VP9_IDCT32_1D 2-3 32 ; src, pass, nnzc
736 %assign %%str 16*%2*%2
737     ; first do t0-15, this can be done identical to idct16x16
738     VP9_IDCT16_1D_START %1, %3/2, 64*2, rsp+ 4*%%str
739
740     ; backup a different register
741     mova     [rsp+30*%%str], m15    ; t15
742     mova                m7, [rsp+ 4*%%str]
743
744     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
745     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
746
747     ; store everything on stack to make space available for t16-31
748     ; we store interleaved with the output of the second half (t16-31)
749     ; so we don't need to allocate extra stack space
750     mova     [rsp+ 0*%%str], m0     ; t0
751     mova     [rsp+ 4*%%str], m1     ; t1
752     mova     [rsp+ 8*%%str], m2     ; t2
753     mova     [rsp+12*%%str], m3     ; t3
754     mova     [rsp+16*%%str], m4     ; t4
755     mova     [rsp+20*%%str], m5     ; t5
756     mova     [rsp+24*%%str], m6     ; t6
757     mova     [rsp+28*%%str], m7     ; t7
758     mova     [rsp+ 2*%%str], m8     ; t8
759     mova     [rsp+ 6*%%str], m9     ; t9
760     mova     [rsp+10*%%str], m10    ; t10
761     mova     [rsp+14*%%str], m11    ; t11
762     mova     [rsp+18*%%str], m12    ; t12
763     mova     [rsp+22*%%str], m13    ; t13
764     mova     [rsp+26*%%str], m14    ; t14
765
766     ; then, secondly, do t16-31
767 %if %3 <= 8
768     mova                 m4, [%1+ 1*64]
769     mova                 m3, [%1+ 3*64]
770     mova                 m0, [%1+ 5*64]
771     mova                 m7, [%1+ 7*64]
772
773     pmulhrsw            m11,  m4, [pw_16364x2] ;t31
774     pmulhrsw             m4, [pw_804x2] ;t16
775     pmulhrsw             m8,  m7, [pw_m5520x2] ;t19
776     pmulhrsw             m7, [pw_15426x2] ;t28
777     pmulhrsw            m15,  m0, [pw_15893x2] ;t27
778     pmulhrsw             m0, [pw_3981x2] ;t20
779     pmulhrsw            m12,  m3, [pw_m2404x2] ;t23
780     pmulhrsw             m3, [pw_16207x2] ;t24
781
782     ; m4=t16/17, m8=t18/19, m0=t20/21, m12=t22/23,
783     ; m3=t24/25, m15=t26/27, m7=t28/29, m11=t30/31
784
785     VP9_UNPACK_MULSUB_2W_4X   5, 10, 11,  4, 16069,  3196, [pd_8192], 6,  9 ; t17, t30
786     VP9_UNPACK_MULSUB_2W_4X   9,  6,  7,  8, 3196, m16069, [pd_8192], 1, 14 ; t18, t29
787     ; from 1 stage forward
788     SUMSUB_BA                 w,  8,  4,  1
789     ; temporary storage
790     mova     [rsp+17*%%str], m8             ; t16
791     mova     [rsp+21*%%str], m4             ; t19
792     VP9_UNPACK_MULSUB_2W_4X   1, 14, 15,  0,  9102, 13623, [pd_8192], 4,  8 ; t21, t26
793     VP9_UNPACK_MULSUB_2W_4X  13,  2,  3, 12, 13623, m9102, [pd_8192], 4,  8 ; t22, t25
794
795     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
796     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
797 %else
798     mova                m10, [%1+ 1*64]
799     mova                m13, [%1+ 3*64]
800     mova                m14, [%1+ 5*64]
801     mova                 m9, [%1+ 7*64]
802     mova                 m8, [%1+ 9*64]
803     mova                m15, [%1+11*64]
804     mova                m12, [%1+13*64]
805     mova                m11, [%1+15*64]
806 %if %3 <= 16
807     pmulhrsw             m5, m10, [pw_16364x2]
808     pmulhrsw            m10, [pw_804x2]
809     pmulhrsw             m4, m11, [pw_m11003x2]
810     pmulhrsw            m11, [pw_12140x2]
811     pmulhrsw             m7,  m8, [pw_14811x2]
812     pmulhrsw             m8, [pw_7005x2]
813     pmulhrsw             m6,  m9, [pw_m5520x2]
814     pmulhrsw             m9, [pw_15426x2]
815     pmulhrsw             m1, m14, [pw_15893x2]
816     pmulhrsw            m14, [pw_3981x2]
817     pmulhrsw             m0, m15, [pw_m8423x2]
818     pmulhrsw            m15, [pw_14053x2]
819 %else
820     mova                 m4, [%1+17*64]
821     mova                 m0, [%1+21*64]
822     mova                 m7, [%1+23*64]
823     mova                 m6, [%1+25*64]
824     mova                 m1, [%1+27*64]
825     mova                 m5, [%1+31*64]
826
827     ; m10=in1, m4=in17, m8=in9, m6=in25, m14=in5, m0=in21, m12=in13, m2=in29,
828     ; m13=in3, m3=in19, m15=in11, m1=in27, m9=in7, m7=in23, m11=in15, m5=in31
829
830     VP9_UNPACK_MULSUB_2W_4X  10,  5, 16364,   804, [pd_8192], 2, 3 ; t16, t31
831     VP9_UNPACK_MULSUB_2W_4X   4, 11, 11003, 12140, [pd_8192], 2, 3 ; t17, t30
832     VP9_UNPACK_MULSUB_2W_4X   8,  7, 14811,  7005, [pd_8192], 2, 3 ; t18, t29
833     VP9_UNPACK_MULSUB_2W_4X   6,  9,  5520, 15426, [pd_8192], 2, 3 ; t19, t28
834     VP9_UNPACK_MULSUB_2W_4X  14,  1, 15893,  3981, [pd_8192], 2, 3 ; t20, t27
835     VP9_UNPACK_MULSUB_2W_4X   0, 15,  8423, 14053, [pd_8192], 2, 3 ; t21, t26
836 %endif
837
838     ; from 1 stage forward
839     SUMSUB_BA             w,  4, 10,  2
840     SUMSUB_BA             w,  8,  6,  2
841     ; from 2 stages forward
842     SUMSUB_BA             w,  8,  4,  2
843     ; temporary storage
844     mova     [rsp+17*%%str], m8             ; t16
845     mova     [rsp+21*%%str], m4             ; t19
846 %if %3 <= 16
847     pmulhrsw             m3, m12, [pw_13160x2]
848     pmulhrsw            m12, [pw_9760x2]
849     pmulhrsw             m2, m13, [pw_m2404x2]
850     pmulhrsw            m13, [pw_16207x2]
851 %else
852     mova                 m2, [%1+29*64]
853     mova                 m3, [%1+19*64]
854     VP9_UNPACK_MULSUB_2W_4X  12,  3, 13160,  9760, [pd_8192], 4, 8 ; t22, t25
855     VP9_UNPACK_MULSUB_2W_4X   2, 13,  2404, 16207, [pd_8192], 4, 8 ; t23, t24
856 %endif
857
858     ; m10=t16, m4=t17, m8=t18, m6=t19, m14=t20, m0=t21, m12=t22, m2=t23,
859     ; m13=t24, m3=t25, m15=t26, m1=t27, m9=t28, m7=t29, m11=t30, m5=t31
860
861     SUMSUB_BA             w,  0, 14,  4
862     SUMSUB_BA             w, 12,  2,  4
863     SUMSUB_BA             w,  3, 13,  4
864     SUMSUB_BA             w, 15,  1,  4
865     SUMSUB_BA             w,  7,  9,  4
866     SUMSUB_BA             w, 11,  5,  4
867
868     ; m4=t16, m10=t17, m6=t18, m8=t19, m0=t20, m14=t21, m2=t22, m12=t23,
869     ; m3=t24, m13=t25, m1=t26, m15=t27, m7=t28, m9=t29, m5=t30, m11=t31
870
871     VP9_UNPACK_MULSUB_2W_4X   5, 10, 16069,  3196, [pd_8192], 4, 8 ; t17, t30
872     VP9_UNPACK_MULSUB_2W_4X   9,  6, 3196, m16069, [pd_8192], 4, 8 ; t18, t29
873     VP9_UNPACK_MULSUB_2W_4X   1, 14,  9102, 13623, [pd_8192], 4, 8 ; t21, t26
874     VP9_UNPACK_MULSUB_2W_4X  13,  2, 13623, m9102, [pd_8192], 4, 8 ; t22, t25
875 %endif
876
877     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
878     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
879
880     SUMSUB_BA             w,  9,  5,  4
881     SUMSUB_BA             w,  1, 13,  4
882     SUMSUB_BA             w,  0, 12,  4
883     SUMSUB_BA             w, 15,  3,  4
884     SUMSUB_BA             w, 14,  2,  4
885     SUMSUB_BA             w,  6, 10,  4
886     SUMSUB_BA             w,  7, 11,  4
887
888     ; m8[s]=t16, m9=t17, m5=t18, m4[s]=t19, m12=t20, m13=t21, m1=t22, m0=t23,
889     ; m15=t24, m14=t25, m2=t26, m3=t27, m11=t28, m10=t29, m6=t30, m7=t31
890
891     mova                 m8, [rsp+17*%%str] ; t16
892     ; from 2 stages forward
893     SUMSUB_BA             w,  0,  8,  4
894     SUMSUB_BA             w, 15,  7,  4
895     ; from 3 stages forward
896     SUMSUB_BA             w,  8,  7,  4
897     pmulhrsw             m7, [pw_11585x2]
898     pmulhrsw             m8, [pw_11585x2]
899     ; store t16/t23
900     mova     [rsp+ 1*%%str], m0     ; t16
901     mova     [rsp+29*%%str], m7     ; t23
902
903     mova                 m4, [rsp+21*%%str] ; t19
904     VP9_UNPACK_MULSUB_2W_4X  10,  5, 15137,  6270, [pd_8192], 0, 7 ; t18, t29
905     VP9_UNPACK_MULSUB_2W_4X  11,  4, 15137,  6270, [pd_8192], 0, 7 ; t19, t28
906     VP9_UNPACK_MULSUB_2W_4X   3, 12, 6270, m15137, [pd_8192], 0, 7 ; t20, t27
907     VP9_UNPACK_MULSUB_2W_4X   2, 13, 6270, m15137, [pd_8192], 0, 7 ; t21, t26
908
909     ; m8=t16, m9=t17, m10=t18, m11=t19, m3=t20, m2=t21, m1=t22, m0=t23,
910     ; m15=t24, m14=t25, m13=t26, m12=t27, m4=t28, m5=t29, m6=t30, m7=t31
911
912     SUMSUB_BA             w,  1,  9,  0
913     SUMSUB_BA             w,  2, 10,  0
914     SUMSUB_BA             w,  3, 11,  0
915     SUMSUB_BA             w, 12,  4,  0
916     SUMSUB_BA             w, 13,  5,  0
917     SUMSUB_BA             w, 14,  6,  0
918
919     ; m0=t16, m1=t17, m2=t18, m3=t19, m11=t20, m10=t21, m9=t22, m8=t23,
920     ; m7=t24, m6=t25, m5=t26, m4=t27, m12=t28, m13=t29, m14=t30, m15=t31
921
922     SUMSUB_BA             w,  9,  6,  0
923     SUMSUB_BA             w, 10,  5,  0
924     SUMSUB_BA             w, 11,  4,  0
925
926     pmulhrsw             m6, [pw_11585x2]
927     pmulhrsw             m9, [pw_11585x2]
928     pmulhrsw             m5, [pw_11585x2]
929     pmulhrsw            m10, [pw_11585x2]
930     pmulhrsw             m4, [pw_11585x2]
931     pmulhrsw            m11, [pw_11585x2]
932
933     ; m0=t16, m1=t17, m2=t18, m3=t19, m4=t20, m5=t21, m6=t22, m7=t23,
934     ; m8=t24, m9=t25, m10=t26, m11=t27, m12=t28, m13=t29, m14=t30, m15=t31
935
936     ; store t17-19 (and t20-22 for pass 1) - keep t24-31 in registers for
937     ; final sumsub in pass 1, or keep t20-22 and t24-31 in registers for
938     ; final sumsub of pass 2
939     mova     [rsp+ 5*%%str], m1     ; t17
940     mova     [rsp+ 9*%%str], m2     ; t18
941     mova     [rsp+13*%%str], m3     ; t19
942
943     ; then do final pass to sumsub+store the two halves
944 %if %2 == 1
945     mova     [rsp+17*%%str], m4     ; t20
946     mova     [rsp+21*%%str], m5     ; t21
947     mova     [rsp+25*%%str], m6     ; t22
948
949     mova                 m0, [rsp+ 0*%%str] ; t0
950     mova                 m1, [rsp+ 4*%%str] ; t1
951     mova                 m2, [rsp+ 8*%%str] ; t2
952     mova                 m3, [rsp+12*%%str] ; t3
953     mova                 m4, [rsp+16*%%str] ; t4
954     mova                 m5, [rsp+20*%%str] ; t5
955     mova                 m6, [rsp+24*%%str] ; t6
956
957     SUMSUB_BA             w, 15,  0, 7
958     mova     [rsp+ 3*%%str], m0             ; t15
959     mova                 m7, [rsp+28*%%str] ; t7
960     SUMSUB_BA             w, 14,  1, 0
961     SUMSUB_BA             w, 13,  2, 0
962     SUMSUB_BA             w, 12,  3, 0
963     SUMSUB_BA             w, 11,  4, 0
964     SUMSUB_BA             w, 10,  5, 0
965     SUMSUB_BA             w,  9,  6, 0
966     SUMSUB_BA             w,  8,  7, 0
967
968     TRANSPOSE8x8W        15, 14, 13, 12, 11, 10, 9, 8, 0
969     mova     [rsp+ 0*%%str], m15
970     mova     [rsp+ 4*%%str], m14
971     mova     [rsp+ 8*%%str], m13
972     mova     [rsp+12*%%str], m12
973     mova     [rsp+16*%%str], m11
974     mova     [rsp+20*%%str], m10
975     mova     [rsp+24*%%str], m9
976     mova     [rsp+28*%%str], m8
977
978     mova                  m0, [rsp+ 3*%%str] ; t15
979     TRANSPOSE8x8W          7, 6, 5, 4, 3, 2, 1, 0, 8
980     mova     [rsp+ 3*%%str], m7
981     mova     [rsp+ 7*%%str], m6
982     mova     [rsp+11*%%str], m5
983     mova     [rsp+15*%%str], m4
984     mova     [rsp+19*%%str], m3
985     mova     [rsp+23*%%str], m2
986     mova     [rsp+27*%%str], m1
987     mova     [rsp+31*%%str], m0
988
989     mova                m15, [rsp+ 2*%%str] ; t8
990     mova                m14, [rsp+ 6*%%str] ; t9
991     mova                m13, [rsp+10*%%str] ; t10
992     mova                m12, [rsp+14*%%str] ; t11
993     mova                m11, [rsp+18*%%str] ; t12
994     mova                m10, [rsp+22*%%str] ; t13
995     mova                 m9, [rsp+26*%%str] ; t14
996     mova                 m8, [rsp+30*%%str] ; t15
997     mova                 m7, [rsp+ 1*%%str] ; t16
998     mova                 m6, [rsp+ 5*%%str] ; t17
999     mova                 m5, [rsp+ 9*%%str] ; t18
1000     mova                 m4, [rsp+13*%%str] ; t19
1001     mova                 m3, [rsp+17*%%str] ; t20
1002     mova                 m2, [rsp+21*%%str] ; t21
1003     mova                 m1, [rsp+25*%%str] ; t22
1004
1005     SUMSUB_BA             w,  7,  8, 0
1006     mova     [rsp+ 2*%%str], m8
1007     mova                 m0, [rsp+29*%%str] ; t23
1008     SUMSUB_BA             w,  6,  9, 8
1009     SUMSUB_BA             w,  5, 10, 8
1010     SUMSUB_BA             w,  4, 11, 8
1011     SUMSUB_BA             w,  3, 12, 8
1012     SUMSUB_BA             w,  2, 13, 8
1013     SUMSUB_BA             w,  1, 14, 8
1014     SUMSUB_BA             w,  0, 15, 8
1015
1016     TRANSPOSE8x8W         0, 1, 2, 3, 4, 5, 6, 7, 8
1017     mova     [rsp+ 1*%%str], m0
1018     mova     [rsp+ 5*%%str], m1
1019     mova     [rsp+ 9*%%str], m2
1020     mova     [rsp+13*%%str], m3
1021     mova     [rsp+17*%%str], m4
1022     mova     [rsp+21*%%str], m5
1023     mova     [rsp+25*%%str], m6
1024     mova     [rsp+29*%%str], m7
1025
1026     mova                 m8, [rsp+ 2*%%str]
1027     TRANSPOSE8x8W         8, 9, 10, 11, 12, 13, 14, 15, 0
1028     mova     [rsp+ 2*%%str], m8
1029     mova     [rsp+ 6*%%str], m9
1030     mova     [rsp+10*%%str], m10
1031     mova     [rsp+14*%%str], m11
1032     mova     [rsp+18*%%str], m12
1033     mova     [rsp+22*%%str], m13
1034     mova     [rsp+26*%%str], m14
1035     mova     [rsp+30*%%str], m15
1036 %else
1037     ; t0-7 is in [rsp+{0,4,8,12,16,20,24,28}*%%str]
1038     ; t8-15 is in [rsp+{2,6,10,14,18,22,26,30}*%%str]
1039     ; t16-19 and t23 is in [rsp+{1,5,9,13,29}*%%str]
1040     ; t20-22 is in m4-6
1041     ; t24-31 is in m8-15
1042     pxor                m7, m7
1043
1044 %macro STORE_2X2 7-8 1 ; src[1-4], tmp[1-2], zero, inc_dst_ptrs
1045     SUMSUB_BA            w, %4, %1, %5
1046     SUMSUB_BA            w, %3, %2, %5
1047     pmulhrsw           m%4, [pw_512]
1048     pmulhrsw           m%3, [pw_512]
1049     VP9_STORE_2X        %4, %3, %5, %6, %7
1050 %if %8 == 1
1051     add               dstq, stride2q
1052 %endif
1053     pmulhrsw           m%2, [pw_512]
1054     pmulhrsw           m%1, [pw_512]
1055     VP9_STORE_2X        %2, %1, %5, %6, %7, dst_endq
1056 %if %8 == 1
1057     sub           dst_endq, stride2q
1058 %endif
1059 %endmacro
1060
1061     ; store t0-1 and t30-31
1062     mova                m0, [rsp+ 0*%%str]
1063     mova                m1, [rsp+ 4*%%str]
1064     STORE_2X2            0,  1, 14, 15, 2, 3, 7
1065
1066     ; store t2-3 and t28-29
1067     mova                m0, [rsp+ 8*%%str]
1068     mova                m1, [rsp+12*%%str]
1069     STORE_2X2            0,  1, 12, 13, 2, 3, 7
1070
1071     ; store t4-5 and t26-27
1072     mova                m0, [rsp+16*%%str]
1073     mova                m1, [rsp+20*%%str]
1074     STORE_2X2            0,  1, 10, 11, 2, 3, 7
1075
1076     ; store t6-7 and t24-25
1077     mova                m0, [rsp+24*%%str]
1078     mova                m1, [rsp+28*%%str]
1079     STORE_2X2            0,  1,  8,  9, 2, 3, 7
1080
1081     ; store t8-9 and t22-23
1082     mova                m0, [rsp+ 2*%%str]
1083     mova                m1, [rsp+ 6*%%str]
1084     mova                m8, [rsp+29*%%str]
1085     STORE_2X2            0,  1,  6,  8, 2, 3, 7
1086
1087     ; store t10-11 and t20-21
1088     mova                m0, [rsp+10*%%str]
1089     mova                m1, [rsp+14*%%str]
1090     STORE_2X2            0,  1,  4,  5, 2, 3, 7
1091
1092     ; store t12-13 and t18-19
1093     mova                m0, [rsp+18*%%str]
1094     mova                m1, [rsp+22*%%str]
1095     mova                m5, [rsp+13*%%str]
1096     mova                m4, [rsp+ 9*%%str]
1097     STORE_2X2            0,  1,  4,  5, 2, 3, 7
1098
1099     ; store t14-17
1100     mova                m0, [rsp+26*%%str]
1101     mova                m1, [rsp+30*%%str]
1102     mova                m5, [rsp+ 5*%%str]
1103     mova                m4, [rsp+ 1*%%str]
1104     STORE_2X2            0,  1,  4,  5, 2, 3, 7, 0
1105 %endif
1106 %endmacro
1107
1108 INIT_XMM ssse3
1109 cglobal vp9_idct_idct_32x32_add, 4, 8, 16, 2048, dst, stride, block, eob
1110     cmp eobd, 135
1111     jg .idctfull
1112     cmp eobd, 34
1113     jg .idct16x16
1114     cmp eobd, 1
1115     jg .idct8x8
1116
1117     ; dc-only case
1118     movd                m0, [blockq]
1119     mova                m1, [pw_11585x2]
1120     pmulhrsw            m0, m1
1121     pmulhrsw            m0, m1
1122     SPLATW              m0, m0, q0000
1123     pmulhrsw            m0, [pw_512]
1124     pxor                m5, m5
1125     movd          [blockq], m5
1126     DEFINE_ARGS        dst, stride, block, cnt
1127 %rep 31
1128     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1129     add               dstq, strideq
1130 %endrep
1131     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1132     RET
1133
1134     DEFINE_ARGS dst_bak, stride, block, cnt, dst, stride30, dst_end, stride2
1135 .idct8x8:
1136     VP9_IDCT32_1D   blockq, 1, 8
1137
1138     mov          stride30q, strideq         ; stride
1139     lea           stride2q, [strideq*2]     ; stride*2
1140     shl          stride30q, 5               ; stride*32
1141     mov               cntd, 4
1142     sub          stride30q, stride2q        ; stride*30
1143 .loop2_8x8:
1144     mov               dstq, dst_bakq
1145     lea           dst_endq, [dst_bakq+stride30q]
1146     VP9_IDCT32_1D      rsp, 2, 8
1147     add           dst_bakq, 8
1148     add                rsp, 16
1149     dec               cntd
1150     jg .loop2_8x8
1151     sub                rsp, 64
1152
1153     ; at the end of the loop, m7 should still be zero
1154     ; use that to zero out block coefficients
1155     ZERO_BLOCK      blockq, 64,  8, m7
1156     RET
1157
1158 .idct16x16:
1159     mov               cntd, 2
1160 .loop1_16x16:
1161     VP9_IDCT32_1D   blockq, 1, 16
1162     add             blockq, 16
1163     add                rsp, 512
1164     dec               cntd
1165     jg .loop1_16x16
1166     sub             blockq, 32
1167     sub                rsp, 1024
1168
1169     mov          stride30q, strideq         ; stride
1170     lea           stride2q, [strideq*2]     ; stride*2
1171     shl          stride30q, 5               ; stride*32
1172     mov               cntd, 4
1173     sub          stride30q, stride2q        ; stride*30
1174 .loop2_16x16:
1175     mov               dstq, dst_bakq
1176     lea           dst_endq, [dst_bakq+stride30q]
1177     VP9_IDCT32_1D      rsp, 2, 16
1178     add           dst_bakq, 8
1179     add                rsp, 16
1180     dec               cntd
1181     jg .loop2_16x16
1182     sub                rsp, 64
1183
1184     ; at the end of the loop, m7 should still be zero
1185     ; use that to zero out block coefficients
1186     ZERO_BLOCK      blockq, 64, 16, m7
1187     RET
1188
1189 .idctfull:
1190     mov               cntd, 4
1191 .loop1_full:
1192     VP9_IDCT32_1D   blockq, 1
1193     add             blockq, 16
1194     add                rsp, 512
1195     dec               cntd
1196     jg .loop1_full
1197     sub             blockq, 64
1198     sub                rsp, 2048
1199
1200     mov          stride30q, strideq         ; stride
1201     lea           stride2q, [strideq*2]     ; stride*2
1202     shl          stride30q, 5               ; stride*32
1203     mov               cntd, 4
1204     sub          stride30q, stride2q        ; stride*30
1205 .loop2_full:
1206     mov               dstq, dst_bakq
1207     lea           dst_endq, [dst_bakq+stride30q]
1208     VP9_IDCT32_1D      rsp, 2
1209     add           dst_bakq, 8
1210     add                rsp, 16
1211     dec               cntd
1212     jg .loop2_full
1213     sub                rsp, 64
1214
1215     ; at the end of the loop, m7 should still be zero
1216     ; use that to zero out block coefficients
1217     ZERO_BLOCK      blockq, 64, 32, m7
1218     RET
1219
1220 %endif ; x86-64