b137df83d465d266d6a4109d0dd9944100d06398
[ffmpeg.git] / libavcodec / x86 / vp9itxfm.asm
1 ;******************************************************************************
2 ;* VP9 IDCT SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013 Clément Bœsch <u pkh me>
5 ;* Copyright (C) 2013 Ronald S. Bultje <rsbultje gmail com>
6 ;*
7 ;* This file is part of FFmpeg.
8 ;*
9 ;* FFmpeg is free software; you can redistribute it and/or
10 ;* modify it under the terms of the GNU Lesser General Public
11 ;* License as published by the Free Software Foundation; either
12 ;* version 2.1 of the License, or (at your option) any later version.
13 ;*
14 ;* FFmpeg is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;* Lesser General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU Lesser General Public
20 ;* License along with FFmpeg; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
22 ;******************************************************************************
23
24 %include "libavutil/x86/x86util.asm"
25
26 SECTION_RODATA
27
28 pw_11585x2: times 8 dw 23170
29
30 %macro VP9_IDCT_COEFFS 2
31 pw_m%1_%2:  times 4 dw -%1,  %2
32 pw_%2_%1:   times 4 dw  %2,  %1
33 pw_m%2_m%1: times 4 dw -%2, -%1
34 %endmacro
35
36 %macro VP9_IDCT_COEFFS_ALL 2
37 pw_%1x2: times 8 dw %1*2
38 pw_m%1x2: times 8 dw -%1*2
39 pw_%2x2: times 8 dw %2*2
40 pw_m%2x2: times 8 dw -%2*2
41 VP9_IDCT_COEFFS %1, %2
42 %endmacro
43
44 VP9_IDCT_COEFFS_ALL 15137,  6270
45 VP9_IDCT_COEFFS_ALL 16069,  3196
46 VP9_IDCT_COEFFS_ALL  9102, 13623
47 VP9_IDCT_COEFFS_ALL 16305,  1606
48 VP9_IDCT_COEFFS_ALL 10394, 12665
49 VP9_IDCT_COEFFS_ALL 14449,  7723
50 VP9_IDCT_COEFFS_ALL  4756, 15679
51 VP9_IDCT_COEFFS_ALL 16364,   804
52 VP9_IDCT_COEFFS_ALL 11003, 12140
53 VP9_IDCT_COEFFS_ALL 14811,  7005
54 VP9_IDCT_COEFFS_ALL  5520, 15426
55 VP9_IDCT_COEFFS_ALL 15893,  3981
56 VP9_IDCT_COEFFS_ALL  8423, 14053
57 VP9_IDCT_COEFFS_ALL 13160,  9760
58 VP9_IDCT_COEFFS_ALL  2404, 16207
59
60 pd_8192: times 4 dd 8192
61 pw_2048: times 8 dw 2048
62 pw_1024: times 8 dw 1024
63 pw_512:  times 8 dw 512
64
65 SECTION .text
66
67 ; (a*x + b*y + round) >> shift
68 %macro VP9_MULSUB_2W_2X 6 ; dst1, dst2, src (unchanged), round, coefs1, coefs2
69     pmaddwd            m%1, m%3, %5
70     pmaddwd            m%2, m%3, %6
71     paddd              m%1,  %4
72     paddd              m%2,  %4
73     psrad              m%1,  14
74     psrad              m%2,  14
75 %endmacro
76
77 %macro VP9_UNPACK_MULSUB_2W_4X 7 ; dst1, dst2, coef1, coef2, rnd, tmp1, tmp2
78     punpckhwd          m%6, m%2, m%1
79     VP9_MULSUB_2W_2X    %7,  %6,  %6, %5, [pw_m%3_%4], [pw_%4_%3]
80     punpcklwd          m%2, m%1
81     VP9_MULSUB_2W_2X    %1,  %2,  %2, %5, [pw_m%3_%4], [pw_%4_%3]
82     packssdw           m%1, m%7
83     packssdw           m%2, m%6
84 %endmacro
85
86 %macro VP9_STORE_2X 5-6 dstq ; reg1, reg2, tmp1, tmp2, zero, dst
87     movh               m%3, [%6]
88     movh               m%4, [%6+strideq]
89     punpcklbw          m%3, m%5
90     punpcklbw          m%4, m%5
91     paddw              m%3, m%1
92     paddw              m%4, m%2
93     packuswb           m%3, m%5
94     packuswb           m%4, m%5
95     movh              [%6], m%3
96     movh      [%6+strideq], m%4
97 %endmacro
98
99 ;-------------------------------------------------------------------------------------------
100 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
101 ;-------------------------------------------------------------------------------------------
102
103 %macro VP9_IDCT4_1D_FINALIZE 0
104     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
105     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
106     SWAP                 0, 3, 2                            ; 3102 -> 0123
107 %endmacro
108
109 %macro VP9_IDCT4_1D 0
110     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
111     pmulhrsw            m2, m6                              ; m2=t0
112     pmulhrsw            m0, m6                              ; m0=t1
113     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270, m7, 4, 5     ; m1=t2, m3=t3
114     VP9_IDCT4_1D_FINALIZE
115 %endmacro
116
117 ; 2x2 top left corner
118 %macro VP9_IDCT4_2x2_1D 0
119     pmulhrsw            m0, m5                              ; m0=t1
120     mova                m2, m0                              ; m2=t0
121     mova                m3, m1
122     pmulhrsw            m1, m6                              ; m1=t2
123     pmulhrsw            m3, m7                              ; m3=t3
124     VP9_IDCT4_1D_FINALIZE
125 %endmacro
126
127 %macro VP9_IDCT4_WRITEOUT 0
128     mova                m5, [pw_2048]
129     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
130     pmulhrsw            m1, m5
131     VP9_STORE_2X         0,  1,  6,  7,  4
132     lea               dstq, [dstq+2*strideq]
133     pmulhrsw            m2, m5
134     pmulhrsw            m3, m5
135     VP9_STORE_2X         2,  3,  6,  7,  4
136 %endmacro
137
138 INIT_MMX ssse3
139 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
140
141     cmp eobd, 4 ; 2x2 or smaller
142     jg .idctfull
143
144     cmp eobd, 1 ; faster path for when only DC is set
145     jne .idct2x2
146
147     movd                m0, [blockq]
148     mova                m5, [pw_11585x2]
149     pmulhrsw            m0, m5
150     pmulhrsw            m0, m5
151     pshufw              m0, m0, 0
152     pxor                m4, m4
153     movh          [blockq], m4
154     pmulhrsw            m0, [pw_2048]       ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
155     VP9_STORE_2X         0,  0,  6,  7,  4
156     lea               dstq, [dstq+2*strideq]
157     VP9_STORE_2X         0,  0,  6,  7,  4
158     RET
159
160 ; faster path for when only top left 2x2 block is set
161 .idct2x2:
162     movd                m0, [blockq+0]
163     movd                m1, [blockq+8]
164     mova                m5, [pw_11585x2]
165     mova                m6, [pw_6270x2]
166     mova                m7, [pw_15137x2]
167     VP9_IDCT4_2x2_1D
168     TRANSPOSE4x4W  0, 1, 2, 3, 4
169     VP9_IDCT4_2x2_1D
170     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
171     movh       [blockq+ 0], m4
172     movh       [blockq+ 8], m4
173     VP9_IDCT4_WRITEOUT
174     RET
175
176 .idctfull: ; generic full 4x4 idct/idct
177     mova                m0, [blockq+ 0]
178     mova                m1, [blockq+ 8]
179     mova                m2, [blockq+16]
180     mova                m3, [blockq+24]
181     mova                m6, [pw_11585x2]
182     mova                m7, [pd_8192]       ; rounding
183     VP9_IDCT4_1D
184     TRANSPOSE4x4W  0, 1, 2, 3, 4
185     VP9_IDCT4_1D
186     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
187     mova       [blockq+ 0], m4
188     mova       [blockq+ 8], m4
189     mova       [blockq+16], m4
190     mova       [blockq+24], m4
191     VP9_IDCT4_WRITEOUT
192     RET
193
194 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use more)
195
196 ;-------------------------------------------------------------------------------------------
197 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
198 ;-------------------------------------------------------------------------------------------
199
200 %macro VP9_IDCT8_1D_FINALIZE 0
201     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
202     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
203     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
204     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
205     SWAP                11, 10, 2
206     SWAP                 3,  9, 0
207 %endmacro
208
209 %macro VP9_IDCT8_1D 0
210     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
211     pmulhrsw            m8, m12                             ; m8=t0a
212     pmulhrsw            m0, m12                             ; m0=t1a
213     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270, m7, 4, 5   ; m2=t2a, m10=t3a
214     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196, m7, 4, 5   ; m1=t4a, m11=t7a
215     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623, m7, 4, 5   ; m9=t5a,  m3=t6a
216     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
217     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
218     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
219     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
220     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
221     pmulhrsw            m1, m12                             ; m1=t6
222     pmulhrsw           m11, m12                             ; m11=t5
223     VP9_IDCT8_1D_FINALIZE
224 %endmacro
225
226 %macro VP9_IDCT8_4x4_1D 0
227     pmulhrsw            m0, m12                             ; m0=t1a/t0a
228     pmulhrsw           m10, m2, [pw_15137x2]                ; m10=t3a
229     pmulhrsw            m2, [pw_6270x2]                     ; m2=t2a
230     pmulhrsw           m11, m1, [pw_16069x2]                ; m11=t7a
231     pmulhrsw            m1, [pw_3196x2]                     ; m1=t4a
232     pmulhrsw            m9, m3, [pw_9102x2]                 ; m9=-t5a
233     pmulhrsw            m3, [pw_13623x2]                    ; m3=t6a
234     psubw               m8, m0, m10                         ; m8=t0a-t3a (t3)
235     paddw              m10, m0                              ; m10=t0a+t3a (t0)
236     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
237     SUMSUB_BA            w,  9,  1, 4                       ;  m1=t4a+t5a (t4),  m9=t4a-t5a (t5a)
238     SWAP                 1,  9
239     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
240     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
241     pmulhrsw            m1, m12                             ; m1=t6
242     pmulhrsw           m11, m12                             ; m11=t5
243     VP9_IDCT8_1D_FINALIZE
244 %endmacro
245
246 ; TODO: a lot of t* copies can probably be removed and merged with
247 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
248 %macro VP9_IDCT8_2x2_1D 0
249     pmulhrsw            m0, m12                             ;  m0=t0
250     mova                m3, m1
251     pmulhrsw            m1, m6                              ;  m1=t4
252     pmulhrsw            m3, m7                              ;  m3=t7
253     mova                m2, m0                              ;  m2=t1
254     mova               m10, m0                              ; m10=t2
255     mova                m8, m0                              ;  m8=t3
256     mova               m11, m3                              ; t5 = t7a ...
257     mova                m9, m3                              ; t6 = t7a ...
258     psubw              m11, m1                              ; t5 = t7a - t4a
259     paddw               m9, m1                              ; t6 = t7a + t4a
260     pmulhrsw           m11, m12                             ; m11=t5
261     pmulhrsw            m9, m12                             ;  m9=t6
262     SWAP                 0, 10
263     SWAP                 9,  1
264     VP9_IDCT8_1D_FINALIZE
265 %endmacro
266
267 %macro VP9_IDCT8_WRITEOUT 0
268     mova                m5, [pw_1024]
269     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
270     pmulhrsw            m1, m5
271     VP9_STORE_2X         0,  1,  6,  7,  4
272     lea               dstq, [dstq+2*strideq]
273     pmulhrsw            m2, m5
274     pmulhrsw            m3, m5
275     VP9_STORE_2X         2,  3,  6,  7,  4
276     lea               dstq, [dstq+2*strideq]
277     pmulhrsw            m8, m5
278     pmulhrsw            m9, m5
279     VP9_STORE_2X         8,  9,  6,  7,  4
280     lea               dstq, [dstq+2*strideq]
281     pmulhrsw           m10, m5
282     pmulhrsw           m11, m5
283     VP9_STORE_2X        10, 11,  6,  7,  4
284 %endmacro
285
286 INIT_XMM ssse3
287 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
288
289     mova               m12, [pw_11585x2]    ; often used
290
291     cmp eobd, 12 ; top left half or less
292     jg .idctfull
293
294     cmp eobd, 3  ; top left corner or less
295     jg .idcthalf
296
297     cmp eobd, 1 ; faster path for when only DC is set
298     jne .idcttopleftcorner
299
300     movd                m0, [blockq]
301     pmulhrsw            m0, m12
302     pmulhrsw            m0, m12
303     SPLATW              m0, m0, 0
304     pxor                m4, m4
305     movd          [blockq], m4
306     mova                m5, [pw_1024]
307     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
308     VP9_STORE_2X         0,  0,  6,  7,  4
309     lea               dstq, [dstq+2*strideq]
310     VP9_STORE_2X         0,  0,  6,  7,  4
311     lea               dstq, [dstq+2*strideq]
312     VP9_STORE_2X         0,  0,  6,  7,  4
313     lea               dstq, [dstq+2*strideq]
314     VP9_STORE_2X         0,  0,  6,  7,  4
315     RET
316
317 ; faster path for when only left corner is set (3 input: DC, right to DC, below
318 ; to DC). Note: also working with a 2x2 block
319 .idcttopleftcorner:
320     movd                m0, [blockq+0]
321     movd                m1, [blockq+16]
322     mova                m6, [pw_3196x2]
323     mova                m7, [pw_16069x2]
324     VP9_IDCT8_2x2_1D
325     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
326     VP9_IDCT8_2x2_1D
327     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
328     movd       [blockq+ 0], m4
329     movd       [blockq+16], m4
330     VP9_IDCT8_WRITEOUT
331     RET
332
333 .idcthalf:
334     movh                m0, [blockq + 0]
335     movh                m1, [blockq +16]
336     movh                m2, [blockq +32]
337     movh                m3, [blockq +48]
338     VP9_IDCT8_4x4_1D
339     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
340     VP9_IDCT8_4x4_1D
341     pxor                m4, m4
342     movh       [blockq+ 0], m4
343     movh       [blockq+16], m4
344     movh       [blockq+32], m4
345     movh       [blockq+48], m4
346     VP9_IDCT8_WRITEOUT
347     RET
348
349 .idctfull: ; generic full 8x8 idct/idct
350     mova                m0, [blockq+  0]    ; IN(0)
351     mova                m1, [blockq+ 16]    ; IN(1)
352     mova                m2, [blockq+ 32]    ; IN(2)
353     mova                m3, [blockq+ 48]    ; IN(3)
354     mova                m8, [blockq+ 64]    ; IN(4)
355     mova                m9, [blockq+ 80]    ; IN(5)
356     mova               m10, [blockq+ 96]    ; IN(6)
357     mova               m11, [blockq+112]    ; IN(7)
358     mova                m7, [pd_8192]       ; rounding
359     VP9_IDCT8_1D
360     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
361     VP9_IDCT8_1D
362     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
363     mova      [blockq+  0], m4
364     mova      [blockq+ 16], m4
365     mova      [blockq+ 32], m4
366     mova      [blockq+ 48], m4
367     mova      [blockq+ 64], m4
368     mova      [blockq+ 80], m4
369     mova      [blockq+ 96], m4
370     mova      [blockq+112], m4
371     VP9_IDCT8_WRITEOUT
372     RET
373
374 ;---------------------------------------------------------------------------------------------
375 ; void vp9_idct_idct_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
376 ;---------------------------------------------------------------------------------------------
377
378 ; at the end of this macro, m7 is stored in stack_scratch
379 ; everything else (t0-6 and t8-15) is stored in m0-6 and m8-15
380 ; the following sumsubs have not been done yet:
381 ;    SUMSUB_BA            w,  6,  9, 15      ; t6, t9
382 ;    SUMSUB_BA            w,  7,  8, 15      ; t7, t8
383 %macro VP9_IDCT16_1D_START 4 ; src, nnzc, stride, stack_scratch
384     mova                m5, [%1+ 1*%3]     ; IN(1)
385     mova               m14, [%1+ 2*%3]     ; IN(2)
386     mova                m6, [%1+ 3*%3]     ; IN(3)
387     mova                m9, [%1+ 4*%3]     ; IN(4)
388     mova                m7, [%1+ 5*%3]     ; IN(5)
389     mova               m15, [%1+ 6*%3]     ; IN(6)
390     mova                m4, [%1+ 7*%3]     ; IN(7)
391 %if %2 <= 8
392     pmulhrsw            m8, m9,  [pw_15137x2]       ; t3
393     pmulhrsw            m9, [pw_6270x2]             ; t2
394     pmulhrsw           m13, m14, [pw_16069x2]       ; t7
395     pmulhrsw           m14, [pw_3196x2]             ; t4
396     pmulhrsw           m12, m15, [pw_m9102x2]       ; t5
397     pmulhrsw           m15, [pw_13623x2]            ; t6
398     pmulhrsw            m2, m5,  [pw_16305x2]       ; t15
399     pmulhrsw            m5, [pw_1606x2]             ; t8
400     pmulhrsw            m3, m4,  [pw_m10394x2]      ; t9
401     pmulhrsw            m4, [pw_12665x2]            ; t14
402     pmulhrsw            m0, m7,  [pw_14449x2]       ; t13
403     pmulhrsw            m7, [pw_7723x2]             ; t10
404     pmulhrsw            m1, m6,  [pw_m4756x2]       ; t11
405     pmulhrsw            m6, [pw_15679x2]            ; t12
406 %else
407     mova                m3, [%1+ 9*%3]     ; IN(9)
408     mova               m12, [%1+10*%3]     ; IN(10)
409     mova                m0, [%1+11*%3]     ; IN(11)
410     mova                m8, [%1+12*%3]     ; IN(12)
411     mova                m1, [%1+13*%3]     ; IN(13)
412     mova               m13, [%1+14*%3]     ; IN(14)
413     mova                m2, [%1+15*%3]     ; IN(15)
414
415     ; m10=in0, m5=in1, m14=in2, m6=in3, m9=in4, m7=in5, m15=in6, m4=in7
416     ; m11=in8, m3=in9, m12=in10 m0=in11, m8=in12, m1=in13, m13=in14, m2=in15
417
418     VP9_UNPACK_MULSUB_2W_4X   9,   8, 15137,  6270, [pd_8192], 10, 11 ; t2,  t3
419     VP9_UNPACK_MULSUB_2W_4X  14,  13, 16069,  3196, [pd_8192], 10, 11 ; t4,  t7
420     VP9_UNPACK_MULSUB_2W_4X  12,  15,  9102, 13623, [pd_8192], 10, 11 ; t5,  t6
421     VP9_UNPACK_MULSUB_2W_4X   5,   2, 16305,  1606, [pd_8192], 10, 11 ; t8,  t15
422     VP9_UNPACK_MULSUB_2W_4X   3,   4, 10394, 12665, [pd_8192], 10, 11 ; t9,  t14
423     VP9_UNPACK_MULSUB_2W_4X   7,   0, 14449,  7723, [pd_8192], 10, 11 ; t10, t13
424     VP9_UNPACK_MULSUB_2W_4X   1,   6,  4756, 15679, [pd_8192], 10, 11 ; t11, t12
425 %endif
426
427     ; m11=t0, m10=t1, m9=t2, m8=t3, m14=t4, m12=t5, m15=t6, m13=t7
428     ; m5=t8, m3=t9, m7=t10, m1=t11, m6=t12, m0=t13, m4=t14, m2=t15
429
430     SUMSUB_BA            w, 12, 14, 10      ; t4,  t5
431     SUMSUB_BA            w, 15, 13, 10      ; t7,  t6
432     SUMSUB_BA            w,  3,  5, 10      ; t8,  t9
433     SUMSUB_BA            w,  7,  1, 10      ; t11, t10
434     SUMSUB_BA            w,  0,  6, 10      ; t12, t13
435     SUMSUB_BA            w,  4,  2, 10      ; t15, t14
436
437     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
438     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
439
440     SUMSUB_BA            w, 14, 13, 10
441     pmulhrsw           m13, [pw_11585x2]                              ; t5
442     pmulhrsw           m14, [pw_11585x2]                              ; t6
443     VP9_UNPACK_MULSUB_2W_4X   2,   5, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
444     VP9_UNPACK_MULSUB_2W_4X   6,   1, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
445
446     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m13=t5, m14=t6, m15=t7
447     ; m3=t8, m2=t9, m6=t10, m7=t11, m0=t12, m1=t13, m5=t14, m4=t15
448
449     SUMSUB_BA            w,  7,  3, 10      ; t8,  t11
450     SUMSUB_BA            w,  6,  2, 10      ; t9,  t10
451     SUMSUB_BA            w,  0,  4, 10      ; t15, t12
452     SUMSUB_BA            w,  1,  5, 10      ; t14. t13
453
454     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
455     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
456
457     SUMSUB_BA            w,  2,  5, 10
458     SUMSUB_BA            w,  3,  4, 10
459     pmulhrsw            m5, [pw_11585x2]    ; t10
460     pmulhrsw            m4, [pw_11585x2]    ; t11
461     pmulhrsw            m3, [pw_11585x2]    ; t12
462     pmulhrsw            m2, [pw_11585x2]    ; t13
463
464     ; backup first register
465     mova              [%4], m7
466
467     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
468     ; m7=t8, m6=t9, m5=t10, m4=t11, m3=t12, m2=t13, m1=t14, m0=t15
469
470     ; from load/start
471     mova               m10, [%1+ 0*%3]      ; IN(0)
472 %if %2 <= 8
473     pmulhrsw           m10, [pw_11585x2]    ; t0 and t1
474     psubw              m11, m10, m8
475     paddw               m8, m10
476 %else
477     mova               m11, [%1+ 8*%3]      ; IN(8)
478
479     ; from 3 stages back
480     SUMSUB_BA            w, 11, 10, 7
481     pmulhrsw           m11, [pw_11585x2]    ; t0
482     pmulhrsw           m10, [pw_11585x2]    ; t1
483
484     ; from 2 stages back
485     SUMSUB_BA            w,  8, 11, 7       ; t0,  t3
486 %endif
487     SUMSUB_BA            w,  9, 10, 7       ; t1,  t2
488
489     ; from 1 stage back
490     SUMSUB_BA            w, 15,  8, 7       ; t0,  t7
491     SUMSUB_BA            w, 14,  9, 7       ; t1,  t6
492     SUMSUB_BA            w, 13, 10, 7       ; t2,  t5
493     SUMSUB_BA            w, 12, 11, 7       ; t3,  t4
494
495     SUMSUB_BA            w,  0, 15, 7       ; t0, t15
496     SUMSUB_BA            w,  1, 14, 7       ; t1, t14
497     SUMSUB_BA            w,  2, 13, 7       ; t2, t13
498     SUMSUB_BA            w,  3, 12, 7       ; t3, t12
499     SUMSUB_BA            w,  4, 11, 7       ; t4, t11
500     SUMSUB_BA            w,  5, 10, 7       ; t5, t10
501 %endmacro
502
503 %macro VP9_IDCT16_1D 2-3 16 ; src, pass, nnzc
504     VP9_IDCT16_1D_START %1, %3, 32, rsp+32
505
506 %if %2 == 1
507     ; backup a different register
508     mova          [rsp+16], m15
509     mova                m7, [rsp+32]
510
511     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
512     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
513
514     TRANSPOSE8x8W        0, 1, 2, 3, 4, 5, 6, 7, 15
515     mova         [rsp+  0], m0
516     mova         [rsp+ 32], m1
517     mova         [rsp+ 64], m2
518     mova         [rsp+ 96], m3
519     mova         [rsp+128], m4
520     mova         [rsp+160], m5
521     mova         [rsp+192], m6
522     mova         [rsp+224], m7
523
524     mova               m15, [rsp+16]
525     TRANSPOSE8x8W        8, 9, 10, 11, 12, 13, 14, 15, 0
526     mova         [rsp+ 16], m8
527     mova         [rsp+ 48], m9
528     mova         [rsp+ 80], m10
529     mova         [rsp+112], m11
530     mova         [rsp+144], m12
531     mova         [rsp+176], m13
532     mova         [rsp+208], m14
533     mova         [rsp+240], m15
534 %else ; %2 == 2
535     ; backup more registers
536     mova          [rsp+64], m8
537     mova          [rsp+96], m9
538
539     pxor                m7, m7
540     pmulhrsw            m0, [pw_512]
541     pmulhrsw            m1, [pw_512]
542     VP9_STORE_2X         0,  1,  8,  9,  7
543     lea               dstq, [dstq+strideq*2]
544     pmulhrsw            m2, [pw_512]
545     pmulhrsw            m3, [pw_512]
546     VP9_STORE_2X         2,  3,  8,  9,  7
547     lea               dstq, [dstq+strideq*2]
548     pmulhrsw            m4, [pw_512]
549     pmulhrsw            m5, [pw_512]
550     VP9_STORE_2X         4,  5,  8,  9,  7
551     lea               dstq, [dstq+strideq*2]
552
553     ; restore from cache
554     SWAP                 0, 7               ; move zero from m7 to m0
555     mova                m7, [rsp+32]
556     mova                m8, [rsp+64]
557     mova                m9, [rsp+96]
558
559     SUMSUB_BA            w,  6,  9, 1       ; t6, t9
560     SUMSUB_BA            w,  7,  8, 1       ; t7, t8
561
562     pmulhrsw            m6, [pw_512]
563     pmulhrsw            m7, [pw_512]
564     VP9_STORE_2X         6,  7,  1,  2,  0
565     lea               dstq, [dstq+strideq*2]
566     pmulhrsw            m8, [pw_512]
567     pmulhrsw            m9, [pw_512]
568     VP9_STORE_2X         8,  9,  1,  2,  0
569     lea               dstq, [dstq+strideq*2]
570     pmulhrsw           m10, [pw_512]
571     pmulhrsw           m11, [pw_512]
572     VP9_STORE_2X        10, 11,  1,  2,  0
573     lea               dstq, [dstq+strideq*2]
574     pmulhrsw           m12, [pw_512]
575     pmulhrsw           m13, [pw_512]
576     VP9_STORE_2X        12, 13,  1,  2,  0
577     lea               dstq, [dstq+strideq*2]
578     pmulhrsw           m14, [pw_512]
579     pmulhrsw           m15, [pw_512]
580     VP9_STORE_2X        14, 15,  1,  2,  0
581 %endif ; %2 == 1/2
582 %endmacro
583
584 %macro ZERO_BLOCK 4 ; mem, stride, nnzcpl, zero_reg
585 %assign %%y 0
586 %rep %3
587 %assign %%x 0
588 %rep %3*2/mmsize
589     mova      [%1+%%y+%%x], %4
590 %assign %%x (%%x+mmsize)
591 %endrep
592 %assign %%y (%%y+%2)
593 %endrep
594 %endmacro
595
596 %macro VP9_STORE_2XFULL 6-7 strideq; dc, tmp1, tmp2, tmp3, tmp4, zero, stride
597     mova               m%3, [dstq]
598     mova               m%5, [dstq+%7]
599     punpcklbw          m%2, m%3, m%6
600     punpckhbw          m%3, m%6
601     punpcklbw          m%4, m%5, m%6
602     punpckhbw          m%5, m%6
603     paddw              m%2, m%1
604     paddw              m%3, m%1
605     paddw              m%4, m%1
606     paddw              m%5, m%1
607     packuswb           m%2, m%3
608     packuswb           m%4, m%5
609     mova            [dstq], m%2
610     mova         [dstq+%7], m%4
611 %endmacro
612
613 INIT_XMM ssse3
614 cglobal vp9_idct_idct_16x16_add, 4, 5, 16, 512, dst, stride, block, eob
615     ; 2x2=eob=3, 4x4=eob=10
616     cmp eobd, 38
617     jg .idctfull
618     cmp eobd, 1 ; faster path for when only DC is set
619     jne .idct8x8
620
621     ; dc-only
622     movd                m0, [blockq]
623     mova                m1, [pw_11585x2]
624     pmulhrsw            m0, m1
625     pmulhrsw            m0, m1
626     SPLATW              m0, m0, q0000
627     pmulhrsw            m0, [pw_512]
628     pxor                m5, m5
629     movd          [blockq], m5
630 %rep 7
631     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
632     lea               dstq, [dstq+2*strideq]
633 %endrep
634     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
635     RET
636
637 .idct8x8:
638     DEFINE_ARGS dst, stride, block, cnt, dst_bak
639     VP9_IDCT16_1D   blockq, 1, 8
640
641     mov               cntd, 2
642     mov           dst_bakq, dstq
643 .loop2_8x8:
644     VP9_IDCT16_1D      rsp, 2, 8
645     lea               dstq, [dst_bakq+8]
646     add                rsp, 16
647     dec               cntd
648     jg .loop2_8x8
649     sub                rsp, 32
650
651     ; at the end of the loop, m0 should still be zero
652     ; use that to zero out block coefficients
653     ZERO_BLOCK      blockq, 32, 8, m0
654     RET
655
656 .idctfull:
657     DEFINE_ARGS dst, stride, block, cnt, dst_bak
658     mov               cntd, 2
659 .loop1_full:
660     VP9_IDCT16_1D   blockq, 1
661     add             blockq, 16
662     add                rsp, 256
663     dec               cntd
664     jg .loop1_full
665     sub             blockq, 32
666     sub                rsp, 512
667
668     mov               cntd, 2
669     mov           dst_bakq, dstq
670 .loop2_full:
671     VP9_IDCT16_1D      rsp, 2
672     lea               dstq, [dst_bakq+8]
673     add                rsp, 16
674     dec               cntd
675     jg .loop2_full
676     sub                rsp, 32
677
678     ; at the end of the loop, m0 should still be zero
679     ; use that to zero out block coefficients
680     ZERO_BLOCK      blockq, 32, 16, m0
681     RET
682
683 ;---------------------------------------------------------------------------------------------
684 ; void vp9_idct_idct_32x32_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
685 ;---------------------------------------------------------------------------------------------
686
687 %macro VP9_IDCT32_1D 2-3 32 ; src, pass, nnzc
688 %assign %%str 16*%2*%2
689     ; first do t0-15, this can be done identical to idct16x16
690     VP9_IDCT16_1D_START %1, %3/2, 64*2, rsp+ 4*%%str
691
692     ; backup a different register
693     mova     [rsp+30*%%str], m15    ; t15
694     mova                m7, [rsp+ 4*%%str]
695
696     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
697     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
698
699     ; store everything on stack to make space available for t16-31
700     ; we store interleaved with the output of the second half (t16-31)
701     ; so we don't need to allocate extra stack space
702     mova     [rsp+ 0*%%str], m0     ; t0
703     mova     [rsp+ 4*%%str], m1     ; t1
704     mova     [rsp+ 8*%%str], m2     ; t2
705     mova     [rsp+12*%%str], m3     ; t3
706     mova     [rsp+16*%%str], m4     ; t4
707     mova     [rsp+20*%%str], m5     ; t5
708     mova     [rsp+24*%%str], m6     ; t6
709     mova     [rsp+28*%%str], m7     ; t7
710     mova     [rsp+ 2*%%str], m8     ; t8
711     mova     [rsp+ 6*%%str], m9     ; t9
712     mova     [rsp+10*%%str], m10    ; t10
713     mova     [rsp+14*%%str], m11    ; t11
714     mova     [rsp+18*%%str], m12    ; t12
715     mova     [rsp+22*%%str], m13    ; t13
716     mova     [rsp+26*%%str], m14    ; t14
717
718     ; then, secondly, do t16-31
719     mova                m10, [%1+ 1*64]
720     mova                m13, [%1+ 3*64]
721     mova                m14, [%1+ 5*64]
722     mova                 m9, [%1+ 7*64]
723     mova                 m8, [%1+ 9*64]
724     mova                m15, [%1+11*64]
725     mova                m12, [%1+13*64]
726     mova                m11, [%1+15*64]
727 %if %3 <= 16
728     pmulhrsw             m5, m10, [pw_16364x2]
729     pmulhrsw            m10, [pw_804x2]
730     pmulhrsw             m4, m11, [pw_m11003x2]
731     pmulhrsw            m11, [pw_12140x2]
732     pmulhrsw             m7,  m8, [pw_14811x2]
733     pmulhrsw             m8, [pw_7005x2]
734     pmulhrsw             m6,  m9, [pw_m5520x2]
735     pmulhrsw             m9, [pw_15426x2]
736     pmulhrsw             m1, m14, [pw_15893x2]
737     pmulhrsw            m14, [pw_3981x2]
738     pmulhrsw             m0, m15, [pw_m8423x2]
739     pmulhrsw            m15, [pw_14053x2]
740 %else
741     mova                 m4, [%1+17*64]
742     mova                 m0, [%1+21*64]
743     mova                 m7, [%1+23*64]
744     mova                 m6, [%1+25*64]
745     mova                 m1, [%1+27*64]
746     mova                 m5, [%1+31*64]
747
748     ; m10=in1, m4=in17, m8=in9, m6=in25, m14=in5, m0=in21, m12=in13, m2=in29,
749     ; m13=in3, m3=in19, m15=in11, m1=in27, m9=in7, m7=in23, m11=in15, m5=in31
750
751     VP9_UNPACK_MULSUB_2W_4X  10,  5, 16364,   804, [pd_8192], 2, 3 ; t16, t31
752     VP9_UNPACK_MULSUB_2W_4X   4, 11, 11003, 12140, [pd_8192], 2, 3 ; t17, t30
753     VP9_UNPACK_MULSUB_2W_4X   8,  7, 14811,  7005, [pd_8192], 2, 3 ; t18, t29
754     VP9_UNPACK_MULSUB_2W_4X   6,  9,  5520, 15426, [pd_8192], 2, 3 ; t19, t28
755     VP9_UNPACK_MULSUB_2W_4X  14,  1, 15893,  3981, [pd_8192], 2, 3 ; t20, t27
756     VP9_UNPACK_MULSUB_2W_4X   0, 15,  8423, 14053, [pd_8192], 2, 3 ; t21, t26
757 %endif
758
759     ; from 1 stage forward
760     SUMSUB_BA             w,  4, 10,  2
761     SUMSUB_BA             w,  8,  6,  2
762     ; from 2 stages forward
763     SUMSUB_BA             w,  8,  4,  2
764     ; temporary storage
765     mova     [rsp+17*%%str], m8             ; t16
766     mova     [rsp+21*%%str], m4             ; t19
767 %if %3 <= 16
768     pmulhrsw             m3, m12, [pw_13160x2]
769     pmulhrsw            m12, [pw_9760x2]
770     pmulhrsw             m2, m13, [pw_m2404x2]
771     pmulhrsw            m13, [pw_16207x2]
772 %else
773     mova                 m2, [%1+29*64]
774     mova                 m3, [%1+19*64]
775     VP9_UNPACK_MULSUB_2W_4X  12,  3, 13160,  9760, [pd_8192], 4, 8 ; t22, t25
776     VP9_UNPACK_MULSUB_2W_4X   2, 13,  2404, 16207, [pd_8192], 4, 8 ; t23, t24
777 %endif
778
779     ; m10=t16, m4=t17, m8=t18, m6=t19, m14=t20, m0=t21, m12=t22, m2=t23,
780     ; m13=t24, m3=t25, m15=t26, m1=t27, m9=t28, m7=t29, m11=t30, m5=t31
781
782     SUMSUB_BA             w,  0, 14,  4
783     SUMSUB_BA             w, 12,  2,  4
784     SUMSUB_BA             w,  3, 13,  4
785     SUMSUB_BA             w, 15,  1,  4
786     SUMSUB_BA             w,  7,  9,  4
787     SUMSUB_BA             w, 11,  5,  4
788
789     ; m4=t16, m10=t17, m6=t18, m8=t19, m0=t20, m14=t21, m2=t22, m12=t23,
790     ; m3=t24, m13=t25, m1=t26, m15=t27, m7=t28, m9=t29, m5=t30, m11=t31
791
792     VP9_UNPACK_MULSUB_2W_4X   5, 10, 16069,  3196, [pd_8192], 4, 8 ; t17, t30
793     VP9_UNPACK_MULSUB_2W_4X   9,  6, 3196, m16069, [pd_8192], 4, 8 ; t18, t29
794     VP9_UNPACK_MULSUB_2W_4X   1, 14,  9102, 13623, [pd_8192], 4, 8 ; t21, t26
795     VP9_UNPACK_MULSUB_2W_4X  13,  2, 13623, m9102, [pd_8192], 4, 8 ; t22, t25
796
797     ; m4=t16, m5=t17, m9=t18, m8=t19, m0=t20, m1=t21, m13=t22, m12=t23,
798     ; m3=t24, m2=t25, m14=t26, m15=t27, m7=t28, m6=t29, m10=t30, m11=t31
799
800     SUMSUB_BA             w,  9,  5,  4
801     SUMSUB_BA             w,  1, 13,  4
802     SUMSUB_BA             w,  0, 12,  4
803     SUMSUB_BA             w, 15,  3,  4
804     SUMSUB_BA             w, 14,  2,  4
805     SUMSUB_BA             w,  6, 10,  4
806     SUMSUB_BA             w,  7, 11,  4
807
808     ; m8[s]=t16, m9=t17, m5=t18, m4[s]=t19, m12=t20, m13=t21, m1=t22, m0=t23,
809     ; m15=t24, m14=t25, m2=t26, m3=t27, m11=t28, m10=t29, m6=t30, m7=t31
810
811     mova                 m8, [rsp+17*%%str] ; t16
812     ; from 2 stages forward
813     SUMSUB_BA             w,  0,  8,  4
814     SUMSUB_BA             w, 15,  7,  4
815     ; from 3 stages forward
816     SUMSUB_BA             w,  8,  7,  4
817     pmulhrsw             m7, [pw_11585x2]
818     pmulhrsw             m8, [pw_11585x2]
819     ; store t16/t23
820     mova     [rsp+ 1*%%str], m0     ; t16
821     mova     [rsp+29*%%str], m7     ; t23
822
823     mova                 m4, [rsp+21*%%str] ; t19
824     VP9_UNPACK_MULSUB_2W_4X  10,  5, 15137,  6270, [pd_8192], 0, 7 ; t18, t29
825     VP9_UNPACK_MULSUB_2W_4X  11,  4, 15137,  6270, [pd_8192], 0, 7 ; t19, t28
826     VP9_UNPACK_MULSUB_2W_4X   3, 12, 6270, m15137, [pd_8192], 0, 7 ; t20, t27
827     VP9_UNPACK_MULSUB_2W_4X   2, 13, 6270, m15137, [pd_8192], 0, 7 ; t21, t26
828
829     ; m8=t16, m9=t17, m10=t18, m11=t19, m3=t20, m2=t21, m1=t22, m0=t23,
830     ; m15=t24, m14=t25, m13=t26, m12=t27, m4=t28, m5=t29, m6=t30, m7=t31
831
832     SUMSUB_BA             w,  1,  9,  0
833     SUMSUB_BA             w,  2, 10,  0
834     SUMSUB_BA             w,  3, 11,  0
835     SUMSUB_BA             w, 12,  4,  0
836     SUMSUB_BA             w, 13,  5,  0
837     SUMSUB_BA             w, 14,  6,  0
838
839     ; m0=t16, m1=t17, m2=t18, m3=t19, m11=t20, m10=t21, m9=t22, m8=t23,
840     ; m7=t24, m6=t25, m5=t26, m4=t27, m12=t28, m13=t29, m14=t30, m15=t31
841
842     SUMSUB_BA             w,  9,  6,  0
843     SUMSUB_BA             w, 10,  5,  0
844     SUMSUB_BA             w, 11,  4,  0
845
846     pmulhrsw             m6, [pw_11585x2]
847     pmulhrsw             m9, [pw_11585x2]
848     pmulhrsw             m5, [pw_11585x2]
849     pmulhrsw            m10, [pw_11585x2]
850     pmulhrsw             m4, [pw_11585x2]
851     pmulhrsw            m11, [pw_11585x2]
852
853     ; m0=t16, m1=t17, m2=t18, m3=t19, m4=t20, m5=t21, m6=t22, m7=t23,
854     ; m8=t24, m9=t25, m10=t26, m11=t27, m12=t28, m13=t29, m14=t30, m15=t31
855
856     ; store t17-19 (and t20-22 for pass 1) - keep t24-31 in registers for
857     ; final sumsub in pass 1, or keep t20-22 and t24-31 in registers for
858     ; final sumsub of pass 2
859     mova     [rsp+ 5*%%str], m1     ; t17
860     mova     [rsp+ 9*%%str], m2     ; t18
861     mova     [rsp+13*%%str], m3     ; t19
862
863     ; then do final pass to sumsub+store the two halves
864 %if %2 == 1
865     mova     [rsp+17*%%str], m4     ; t20
866     mova     [rsp+21*%%str], m5     ; t21
867     mova     [rsp+25*%%str], m6     ; t22
868
869     mova                 m0, [rsp+ 0*%%str] ; t0
870     mova                 m1, [rsp+ 4*%%str] ; t1
871     mova                 m2, [rsp+ 8*%%str] ; t2
872     mova                 m3, [rsp+12*%%str] ; t3
873     mova                 m4, [rsp+16*%%str] ; t4
874     mova                 m5, [rsp+20*%%str] ; t5
875     mova                 m6, [rsp+24*%%str] ; t6
876
877     SUMSUB_BA             w, 15,  0, 7
878     mova     [rsp+ 3*%%str], m0             ; t15
879     mova                 m7, [rsp+28*%%str] ; t7
880     SUMSUB_BA             w, 14,  1, 0
881     SUMSUB_BA             w, 13,  2, 0
882     SUMSUB_BA             w, 12,  3, 0
883     SUMSUB_BA             w, 11,  4, 0
884     SUMSUB_BA             w, 10,  5, 0
885     SUMSUB_BA             w,  9,  6, 0
886     SUMSUB_BA             w,  8,  7, 0
887
888     TRANSPOSE8x8W        15, 14, 13, 12, 11, 10, 9, 8, 0
889     mova     [rsp+ 0*%%str], m15
890     mova     [rsp+ 4*%%str], m14
891     mova     [rsp+ 8*%%str], m13
892     mova     [rsp+12*%%str], m12
893     mova     [rsp+16*%%str], m11
894     mova     [rsp+20*%%str], m10
895     mova     [rsp+24*%%str], m9
896     mova     [rsp+28*%%str], m8
897
898     mova                  m0, [rsp+ 3*%%str] ; t15
899     TRANSPOSE8x8W          7, 6, 5, 4, 3, 2, 1, 0, 8
900     mova     [rsp+ 3*%%str], m7
901     mova     [rsp+ 7*%%str], m6
902     mova     [rsp+11*%%str], m5
903     mova     [rsp+15*%%str], m4
904     mova     [rsp+19*%%str], m3
905     mova     [rsp+23*%%str], m2
906     mova     [rsp+27*%%str], m1
907     mova     [rsp+31*%%str], m0
908
909     mova                m15, [rsp+ 2*%%str] ; t8
910     mova                m14, [rsp+ 6*%%str] ; t9
911     mova                m13, [rsp+10*%%str] ; t10
912     mova                m12, [rsp+14*%%str] ; t11
913     mova                m11, [rsp+18*%%str] ; t12
914     mova                m10, [rsp+22*%%str] ; t13
915     mova                 m9, [rsp+26*%%str] ; t14
916     mova                 m8, [rsp+30*%%str] ; t15
917     mova                 m7, [rsp+ 1*%%str] ; t16
918     mova                 m6, [rsp+ 5*%%str] ; t17
919     mova                 m5, [rsp+ 9*%%str] ; t18
920     mova                 m4, [rsp+13*%%str] ; t19
921     mova                 m3, [rsp+17*%%str] ; t20
922     mova                 m2, [rsp+21*%%str] ; t21
923     mova                 m1, [rsp+25*%%str] ; t22
924
925     SUMSUB_BA             w,  7,  8, 0
926     mova     [rsp+ 2*%%str], m8
927     mova                 m0, [rsp+29*%%str] ; t23
928     SUMSUB_BA             w,  6,  9, 8
929     SUMSUB_BA             w,  5, 10, 8
930     SUMSUB_BA             w,  4, 11, 8
931     SUMSUB_BA             w,  3, 12, 8
932     SUMSUB_BA             w,  2, 13, 8
933     SUMSUB_BA             w,  1, 14, 8
934     SUMSUB_BA             w,  0, 15, 8
935
936     TRANSPOSE8x8W         0, 1, 2, 3, 4, 5, 6, 7, 8
937     mova     [rsp+ 1*%%str], m0
938     mova     [rsp+ 5*%%str], m1
939     mova     [rsp+ 9*%%str], m2
940     mova     [rsp+13*%%str], m3
941     mova     [rsp+17*%%str], m4
942     mova     [rsp+21*%%str], m5
943     mova     [rsp+25*%%str], m6
944     mova     [rsp+29*%%str], m7
945
946     mova                 m8, [rsp+ 2*%%str]
947     TRANSPOSE8x8W         8, 9, 10, 11, 12, 13, 14, 15, 0
948     mova     [rsp+ 2*%%str], m8
949     mova     [rsp+ 6*%%str], m9
950     mova     [rsp+10*%%str], m10
951     mova     [rsp+14*%%str], m11
952     mova     [rsp+18*%%str], m12
953     mova     [rsp+22*%%str], m13
954     mova     [rsp+26*%%str], m14
955     mova     [rsp+30*%%str], m15
956 %else
957     ; t0-7 is in [rsp+{0,4,8,12,16,20,24,28}*%%str]
958     ; t8-15 is in [rsp+{2,6,10,14,18,22,26,30}*%%str]
959     ; t16-19 and t23 is in [rsp+{1,5,9,13,29}*%%str]
960     ; t20-22 is in m4-6
961     ; t24-31 is in m8-15
962     pxor                m7, m7
963
964 %macro STORE_2X2 7-8 1 ; src[1-4], tmp[1-2], zero, inc_dst_ptrs
965     SUMSUB_BA            w, %4, %1, %5
966     SUMSUB_BA            w, %3, %2, %5
967     pmulhrsw           m%4, [pw_512]
968     pmulhrsw           m%3, [pw_512]
969     VP9_STORE_2X        %4, %3, %5, %6, %7
970 %if %8 == 1
971     add               dstq, stride2q
972 %endif
973     pmulhrsw           m%2, [pw_512]
974     pmulhrsw           m%1, [pw_512]
975     VP9_STORE_2X        %2, %1, %5, %6, %7, dst_endq
976 %if %8 == 1
977     sub           dst_endq, stride2q
978 %endif
979 %endmacro
980
981     ; store t0-1 and t30-31
982     mova                m0, [rsp+ 0*%%str]
983     mova                m1, [rsp+ 4*%%str]
984     STORE_2X2            0,  1, 14, 15, 2, 3, 7
985
986     ; store t2-3 and t28-29
987     mova                m0, [rsp+ 8*%%str]
988     mova                m1, [rsp+12*%%str]
989     STORE_2X2            0,  1, 12, 13, 2, 3, 7
990
991     ; store t4-5 and t26-27
992     mova                m0, [rsp+16*%%str]
993     mova                m1, [rsp+20*%%str]
994     STORE_2X2            0,  1, 10, 11, 2, 3, 7
995
996     ; store t6-7 and t24-25
997     mova                m0, [rsp+24*%%str]
998     mova                m1, [rsp+28*%%str]
999     STORE_2X2            0,  1,  8,  9, 2, 3, 7
1000
1001     ; store t8-9 and t22-23
1002     mova                m0, [rsp+ 2*%%str]
1003     mova                m1, [rsp+ 6*%%str]
1004     mova                m8, [rsp+29*%%str]
1005     STORE_2X2            0,  1,  6,  8, 2, 3, 7
1006
1007     ; store t10-11 and t20-21
1008     mova                m0, [rsp+10*%%str]
1009     mova                m1, [rsp+14*%%str]
1010     STORE_2X2            0,  1,  4,  5, 2, 3, 7
1011
1012     ; store t12-13 and t18-19
1013     mova                m0, [rsp+18*%%str]
1014     mova                m1, [rsp+22*%%str]
1015     mova                m5, [rsp+13*%%str]
1016     mova                m4, [rsp+ 9*%%str]
1017     STORE_2X2            0,  1,  4,  5, 2, 3, 7
1018
1019     ; store t14-17
1020     mova                m0, [rsp+26*%%str]
1021     mova                m1, [rsp+30*%%str]
1022     mova                m5, [rsp+ 5*%%str]
1023     mova                m4, [rsp+ 1*%%str]
1024     STORE_2X2            0,  1,  4,  5, 2, 3, 7, 0
1025 %endif
1026 %endmacro
1027
1028 INIT_XMM ssse3
1029 cglobal vp9_idct_idct_32x32_add, 4, 8, 16, 2048, dst, stride, block, eob
1030     cmp eobd, 135
1031     jg .idctfull
1032     cmp eobd, 1
1033     jg .idct16x16
1034
1035     ; dc-only case
1036     movd                m0, [blockq]
1037     mova                m1, [pw_11585x2]
1038     pmulhrsw            m0, m1
1039     pmulhrsw            m0, m1
1040     SPLATW              m0, m0, q0000
1041     pmulhrsw            m0, [pw_512]
1042     pxor                m5, m5
1043     movd          [blockq], m5
1044     DEFINE_ARGS        dst, stride, block, cnt
1045 %rep 31
1046     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1047     add               dstq, strideq
1048 %endrep
1049     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5, mmsize
1050     RET
1051
1052     DEFINE_ARGS dst_bak, stride, block, cnt, dst, stride30, dst_end, stride2
1053 .idct16x16:
1054     mov               cntd, 2
1055 .loop1_16x16:
1056     VP9_IDCT32_1D   blockq, 1, 16
1057     add             blockq, 16
1058     add                rsp, 512
1059     dec               cntd
1060     jg .loop1_16x16
1061     sub             blockq, 32
1062     sub                rsp, 1024
1063
1064     mov          stride30q, strideq         ; stride
1065     lea           stride2q, [strideq*2]     ; stride*2
1066     shl          stride30q, 5               ; stride*32
1067     mov               cntd, 4
1068     sub          stride30q, stride2q        ; stride*30
1069 .loop2_16x16:
1070     mov               dstq, dst_bakq
1071     lea           dst_endq, [dst_bakq+stride30q]
1072     VP9_IDCT32_1D      rsp, 2, 16
1073     add           dst_bakq, 8
1074     add                rsp, 16
1075     dec               cntd
1076     jg .loop2_16x16
1077     sub                rsp, 64
1078
1079     ; at the end of the loop, m7 should still be zero
1080     ; use that to zero out block coefficients
1081     ZERO_BLOCK      blockq, 64, 16, m7
1082     RET
1083
1084 .idctfull:
1085     mov               cntd, 4
1086 .loop1_full:
1087     VP9_IDCT32_1D   blockq, 1
1088     add             blockq, 16
1089     add                rsp, 512
1090     dec               cntd
1091     jg .loop1_full
1092     sub             blockq, 64
1093     sub                rsp, 2048
1094
1095     mov          stride30q, strideq         ; stride
1096     lea           stride2q, [strideq*2]     ; stride*2
1097     shl          stride30q, 5               ; stride*32
1098     mov               cntd, 4
1099     sub          stride30q, stride2q        ; stride*30
1100 .loop2_full:
1101     mov               dstq, dst_bakq
1102     lea           dst_endq, [dst_bakq+stride30q]
1103     VP9_IDCT32_1D      rsp, 2
1104     add           dst_bakq, 8
1105     add                rsp, 16
1106     dec               cntd
1107     jg .loop2_full
1108     sub                rsp, 64
1109
1110     ; at the end of the loop, m7 should still be zero
1111     ; use that to zero out block coefficients
1112     ZERO_BLOCK      blockq, 64, 32, m7
1113     RET
1114
1115 %endif ; x86-64