vp9/x86: 16x16 sub-IDCT for top-left 8x8 subblock (eob <= 38).
[ffmpeg.git] / libavcodec / x86 / vp9itxfm.asm
1 ;******************************************************************************
2 ;* VP9 IDCT SIMD optimizations
3 ;*
4 ;* Copyright (C) 2013 Clément Bœsch <u pkh me>
5 ;* Copyright (C) 2013 Ronald S. Bultje <rsbultje gmail com>
6 ;*
7 ;* This file is part of FFmpeg.
8 ;*
9 ;* FFmpeg is free software; you can redistribute it and/or
10 ;* modify it under the terms of the GNU Lesser General Public
11 ;* License as published by the Free Software Foundation; either
12 ;* version 2.1 of the License, or (at your option) any later version.
13 ;*
14 ;* FFmpeg is distributed in the hope that it will be useful,
15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17 ;* Lesser General Public License for more details.
18 ;*
19 ;* You should have received a copy of the GNU Lesser General Public
20 ;* License along with FFmpeg; if not, write to the Free Software
21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
22 ;******************************************************************************
23
24 %include "libavutil/x86/x86util.asm"
25
26 SECTION_RODATA
27
28 pw_11585x2: times 8 dw 23170
29
30 %macro VP9_IDCT_COEFFS 2
31 pw_m%1_%2:  times 4 dw -%1,  %2
32 pw_%2_%1:   times 4 dw  %2,  %1
33 pw_m%2_m%1: times 4 dw -%2, -%1
34 %endmacro
35
36 %macro VP9_IDCT_COEFFS_ALL 2
37 pw_%1x2: times 8 dw %1*2
38 pw_m%1x2: times 8 dw -%1*2
39 pw_%2x2: times 8 dw %2*2
40 pw_m%2x2: times 8 dw -%2*2
41 VP9_IDCT_COEFFS %1, %2
42 %endmacro
43
44 VP9_IDCT_COEFFS_ALL 15137,  6270
45 VP9_IDCT_COEFFS_ALL 16069,  3196
46 VP9_IDCT_COEFFS_ALL  9102, 13623
47 VP9_IDCT_COEFFS_ALL 16305,  1606
48 VP9_IDCT_COEFFS_ALL 10394, 12665
49 VP9_IDCT_COEFFS_ALL 14449,  7723
50 VP9_IDCT_COEFFS_ALL  4756, 15679
51
52 pd_8192: times 4 dd 8192
53 pw_2048: times 8 dw 2048
54 pw_1024: times 8 dw 1024
55 pw_512:  times 8 dw 512
56
57 SECTION .text
58
59 ; (a*x + b*y + round) >> shift
60 %macro VP9_MULSUB_2W_2X 6 ; dst1, dst2, src (unchanged), round, coefs1, coefs2
61     pmaddwd            m%1, m%3, %5
62     pmaddwd            m%2, m%3, %6
63     paddd              m%1,  %4
64     paddd              m%2,  %4
65     psrad              m%1,  14
66     psrad              m%2,  14
67 %endmacro
68
69 %macro VP9_UNPACK_MULSUB_2W_4X 7 ; dst1, dst2, coef1, coef2, rnd, tmp1, tmp2
70     punpckhwd          m%6, m%2, m%1
71     VP9_MULSUB_2W_2X    %7,  %6,  %6, %5, [pw_m%3_%4], [pw_%4_%3]
72     punpcklwd          m%2, m%1
73     VP9_MULSUB_2W_2X    %1,  %2,  %2, %5, [pw_m%3_%4], [pw_%4_%3]
74     packssdw           m%1, m%7
75     packssdw           m%2, m%6
76 %endmacro
77
78 %macro VP9_STORE_2X 5 ; reg1, reg2, tmp1, tmp2, zero
79     movh               m%3, [dstq]
80     movh               m%4, [dstq+strideq]
81     punpcklbw          m%3, m%5
82     punpcklbw          m%4, m%5
83     paddw              m%3, m%1
84     paddw              m%4, m%2
85     packuswb           m%3, m%5
86     packuswb           m%4, m%5
87     movh            [dstq], m%3
88     movh    [dstq+strideq], m%4
89 %endmacro
90
91 ;-------------------------------------------------------------------------------------------
92 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
93 ;-------------------------------------------------------------------------------------------
94
95 %macro VP9_IDCT4_1D_FINALIZE 0
96     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
97     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
98     SWAP                 0, 3, 2                            ; 3102 -> 0123
99 %endmacro
100
101 %macro VP9_IDCT4_1D 0
102     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
103     pmulhrsw            m2, m6                              ; m2=t0
104     pmulhrsw            m0, m6                              ; m0=t1
105     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270, m7, 4, 5     ; m1=t2, m3=t3
106     VP9_IDCT4_1D_FINALIZE
107 %endmacro
108
109 ; 2x2 top left corner
110 %macro VP9_IDCT4_2x2_1D 0
111     pmulhrsw            m0, m5                              ; m0=t1
112     mova                m2, m0                              ; m2=t0
113     mova                m3, m1
114     pmulhrsw            m1, m6                              ; m1=t2
115     pmulhrsw            m3, m7                              ; m3=t3
116     VP9_IDCT4_1D_FINALIZE
117 %endmacro
118
119 %macro VP9_IDCT4_WRITEOUT 0
120     mova                m5, [pw_2048]
121     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
122     pmulhrsw            m1, m5
123     VP9_STORE_2X         0,  1,  6,  7,  4
124     lea               dstq, [dstq+2*strideq]
125     pmulhrsw            m2, m5
126     pmulhrsw            m3, m5
127     VP9_STORE_2X         2,  3,  6,  7,  4
128 %endmacro
129
130 INIT_MMX ssse3
131 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
132
133     cmp eobd, 4 ; 2x2 or smaller
134     jg .idctfull
135
136     cmp eobd, 1 ; faster path for when only DC is set
137     jne .idct2x2
138
139     movd                m0, [blockq]
140     mova                m5, [pw_11585x2]
141     pmulhrsw            m0, m5
142     pmulhrsw            m0, m5
143     pshufw              m0, m0, 0
144     pxor                m4, m4
145     movh          [blockq], m4
146     pmulhrsw            m0, [pw_2048]       ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
147     VP9_STORE_2X         0,  0,  6,  7,  4
148     lea               dstq, [dstq+2*strideq]
149     VP9_STORE_2X         0,  0,  6,  7,  4
150     RET
151
152 ; faster path for when only top left 2x2 block is set
153 .idct2x2:
154     movd                m0, [blockq+0]
155     movd                m1, [blockq+8]
156     mova                m5, [pw_11585x2]
157     mova                m6, [pw_6270x2]
158     mova                m7, [pw_15137x2]
159     VP9_IDCT4_2x2_1D
160     TRANSPOSE4x4W  0, 1, 2, 3, 4
161     VP9_IDCT4_2x2_1D
162     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
163     movh       [blockq+ 0], m4
164     movh       [blockq+ 8], m4
165     VP9_IDCT4_WRITEOUT
166     RET
167
168 .idctfull: ; generic full 4x4 idct/idct
169     mova                m0, [blockq+ 0]
170     mova                m1, [blockq+ 8]
171     mova                m2, [blockq+16]
172     mova                m3, [blockq+24]
173     mova                m6, [pw_11585x2]
174     mova                m7, [pd_8192]       ; rounding
175     VP9_IDCT4_1D
176     TRANSPOSE4x4W  0, 1, 2, 3, 4
177     VP9_IDCT4_1D
178     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
179     mova       [blockq+ 0], m4
180     mova       [blockq+ 8], m4
181     mova       [blockq+16], m4
182     mova       [blockq+24], m4
183     VP9_IDCT4_WRITEOUT
184     RET
185
186 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use more)
187
188 ;-------------------------------------------------------------------------------------------
189 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
190 ;-------------------------------------------------------------------------------------------
191
192 %macro VP9_IDCT8_1D_FINALIZE 0
193     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
194     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
195     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
196     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
197     SWAP                11, 10, 2
198     SWAP                 3,  9, 0
199 %endmacro
200
201 %macro VP9_IDCT8_1D 0
202     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
203     pmulhrsw            m8, m12                             ; m8=t0a
204     pmulhrsw            m0, m12                             ; m0=t1a
205     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270, m7, 4, 5   ; m2=t2a, m10=t3a
206     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196, m7, 4, 5   ; m1=t4a, m11=t7a
207     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623, m7, 4, 5   ; m9=t5a,  m3=t6a
208     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
209     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
210     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
211     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
212     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
213     pmulhrsw            m1, m12                             ; m1=t6
214     pmulhrsw           m11, m12                             ; m11=t5
215     VP9_IDCT8_1D_FINALIZE
216 %endmacro
217
218 %macro VP9_IDCT8_4x4_1D 0
219     pmulhrsw            m0, m12                             ; m0=t1a/t0a
220     pmulhrsw           m10, m2, [pw_15137x2]                ; m10=t3a
221     pmulhrsw            m2, [pw_6270x2]                     ; m2=t2a
222     pmulhrsw           m11, m1, [pw_16069x2]                ; m11=t7a
223     pmulhrsw            m1, [pw_3196x2]                     ; m1=t4a
224     pmulhrsw            m9, m3, [pw_9102x2]                 ; m9=-t5a
225     pmulhrsw            m3, [pw_13623x2]                    ; m3=t6a
226     psubw               m8, m0, m10                         ; m8=t0a-t3a (t3)
227     paddw              m10, m0                              ; m10=t0a+t3a (t0)
228     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
229     SUMSUB_BA            w,  9,  1, 4                       ;  m1=t4a+t5a (t4),  m9=t4a-t5a (t5a)
230     SWAP                 1,  9
231     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
232     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
233     pmulhrsw            m1, m12                             ; m1=t6
234     pmulhrsw           m11, m12                             ; m11=t5
235     VP9_IDCT8_1D_FINALIZE
236 %endmacro
237
238 ; TODO: a lot of t* copies can probably be removed and merged with
239 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
240 %macro VP9_IDCT8_2x2_1D 0
241     pmulhrsw            m0, m12                             ;  m0=t0
242     mova                m3, m1
243     pmulhrsw            m1, m6                              ;  m1=t4
244     pmulhrsw            m3, m7                              ;  m3=t7
245     mova                m2, m0                              ;  m2=t1
246     mova               m10, m0                              ; m10=t2
247     mova                m8, m0                              ;  m8=t3
248     mova               m11, m3                              ; t5 = t7a ...
249     mova                m9, m3                              ; t6 = t7a ...
250     psubw              m11, m1                              ; t5 = t7a - t4a
251     paddw               m9, m1                              ; t6 = t7a + t4a
252     pmulhrsw           m11, m12                             ; m11=t5
253     pmulhrsw            m9, m12                             ;  m9=t6
254     SWAP                 0, 10
255     SWAP                 9,  1
256     VP9_IDCT8_1D_FINALIZE
257 %endmacro
258
259 %macro VP9_IDCT8_WRITEOUT 0
260     mova                m5, [pw_1024]
261     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
262     pmulhrsw            m1, m5
263     VP9_STORE_2X         0,  1,  6,  7,  4
264     lea               dstq, [dstq+2*strideq]
265     pmulhrsw            m2, m5
266     pmulhrsw            m3, m5
267     VP9_STORE_2X         2,  3,  6,  7,  4
268     lea               dstq, [dstq+2*strideq]
269     pmulhrsw            m8, m5
270     pmulhrsw            m9, m5
271     VP9_STORE_2X         8,  9,  6,  7,  4
272     lea               dstq, [dstq+2*strideq]
273     pmulhrsw           m10, m5
274     pmulhrsw           m11, m5
275     VP9_STORE_2X        10, 11,  6,  7,  4
276 %endmacro
277
278 INIT_XMM ssse3
279 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
280
281     mova               m12, [pw_11585x2]    ; often used
282
283     cmp eobd, 12 ; top left half or less
284     jg .idctfull
285
286     cmp eobd, 3  ; top left corner or less
287     jg .idcthalf
288
289     cmp eobd, 1 ; faster path for when only DC is set
290     jne .idcttopleftcorner
291
292     movd                m0, [blockq]
293     pmulhrsw            m0, m12
294     pmulhrsw            m0, m12
295     SPLATW              m0, m0, 0
296     pxor                m4, m4
297     movd          [blockq], m4
298     mova                m5, [pw_1024]
299     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
300     VP9_STORE_2X         0,  0,  6,  7,  4
301     lea               dstq, [dstq+2*strideq]
302     VP9_STORE_2X         0,  0,  6,  7,  4
303     lea               dstq, [dstq+2*strideq]
304     VP9_STORE_2X         0,  0,  6,  7,  4
305     lea               dstq, [dstq+2*strideq]
306     VP9_STORE_2X         0,  0,  6,  7,  4
307     RET
308
309 ; faster path for when only left corner is set (3 input: DC, right to DC, below
310 ; to DC). Note: also working with a 2x2 block
311 .idcttopleftcorner:
312     movd                m0, [blockq+0]
313     movd                m1, [blockq+16]
314     mova                m6, [pw_3196x2]
315     mova                m7, [pw_16069x2]
316     VP9_IDCT8_2x2_1D
317     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
318     VP9_IDCT8_2x2_1D
319     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
320     movd       [blockq+ 0], m4
321     movd       [blockq+16], m4
322     VP9_IDCT8_WRITEOUT
323     RET
324
325 .idcthalf:
326     movh                m0, [blockq + 0]
327     movh                m1, [blockq +16]
328     movh                m2, [blockq +32]
329     movh                m3, [blockq +48]
330     VP9_IDCT8_4x4_1D
331     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
332     VP9_IDCT8_4x4_1D
333     pxor                m4, m4
334     movh       [blockq+ 0], m4
335     movh       [blockq+16], m4
336     movh       [blockq+32], m4
337     movh       [blockq+48], m4
338     VP9_IDCT8_WRITEOUT
339     RET
340
341 .idctfull: ; generic full 8x8 idct/idct
342     mova                m0, [blockq+  0]    ; IN(0)
343     mova                m1, [blockq+ 16]    ; IN(1)
344     mova                m2, [blockq+ 32]    ; IN(2)
345     mova                m3, [blockq+ 48]    ; IN(3)
346     mova                m8, [blockq+ 64]    ; IN(4)
347     mova                m9, [blockq+ 80]    ; IN(5)
348     mova               m10, [blockq+ 96]    ; IN(6)
349     mova               m11, [blockq+112]    ; IN(7)
350     mova                m7, [pd_8192]       ; rounding
351     VP9_IDCT8_1D
352     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
353     VP9_IDCT8_1D
354     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
355     mova      [blockq+  0], m4
356     mova      [blockq+ 16], m4
357     mova      [blockq+ 32], m4
358     mova      [blockq+ 48], m4
359     mova      [blockq+ 64], m4
360     mova      [blockq+ 80], m4
361     mova      [blockq+ 96], m4
362     mova      [blockq+112], m4
363     VP9_IDCT8_WRITEOUT
364     RET
365
366 ;---------------------------------------------------------------------------------------------
367 ; void vp9_idct_idct_16x16_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
368 ;---------------------------------------------------------------------------------------------
369
370 %macro VP9_IDCT16_1D 2-3 16 ; src, pass, nnzc
371     mova                m5, [%1+ 32]       ; IN(1)
372     mova               m14, [%1+ 64]       ; IN(2)
373     mova                m6, [%1+ 96]       ; IN(3)
374     mova                m9, [%1+128]       ; IN(4)
375     mova                m7, [%1+160]       ; IN(5)
376     mova               m15, [%1+192]       ; IN(6)
377     mova                m4, [%1+224]       ; IN(7)
378 %if %3 <= 8
379     pmulhrsw            m8, m9,  [pw_15137x2]       ; t3
380     pmulhrsw            m9, [pw_6270x2]             ; t2
381     pmulhrsw           m13, m14, [pw_16069x2]       ; t7
382     pmulhrsw           m14, [pw_3196x2]             ; t4
383     pmulhrsw           m12, m15, [pw_m9102x2]       ; t5
384     pmulhrsw           m15, [pw_13623x2]            ; t6
385     pmulhrsw            m2, m5,  [pw_16305x2]       ; t15
386     pmulhrsw            m5, [pw_1606x2]             ; t8
387     pmulhrsw            m3, m4,  [pw_m10394x2]      ; t9
388     pmulhrsw            m4, [pw_12665x2]            ; t14
389     pmulhrsw            m0, m7,  [pw_14449x2]       ; t13
390     pmulhrsw            m7, [pw_7723x2]             ; t10
391     pmulhrsw            m1, m6,  [pw_m4756x2]       ; t11
392     pmulhrsw            m6, [pw_15679x2]            ; t12
393 %else
394     mova                m3, [%1+288]       ; IN(9)
395     mova               m12, [%1+320]       ; IN(10)
396     mova                m0, [%1+352]       ; IN(11)
397     mova                m8, [%1+384]       ; IN(12)
398     mova                m1, [%1+416]       ; IN(13)
399     mova               m13, [%1+448]       ; IN(14)
400     mova                m2, [%1+480]       ; IN(15)
401
402     ; m10=in0, m5=in1, m14=in2, m6=in3, m9=in4, m7=in5, m15=in6, m4=in7
403     ; m11=in8, m3=in9, m12=in10 m0=in11, m8=in12, m1=in13, m13=in14, m2=in15
404
405     VP9_UNPACK_MULSUB_2W_4X   9,   8, 15137,  6270, [pd_8192], 10, 11 ; t2,  t3
406     VP9_UNPACK_MULSUB_2W_4X  14,  13, 16069,  3196, [pd_8192], 10, 11 ; t4,  t7
407     VP9_UNPACK_MULSUB_2W_4X  12,  15,  9102, 13623, [pd_8192], 10, 11 ; t5,  t6
408     VP9_UNPACK_MULSUB_2W_4X   5,   2, 16305,  1606, [pd_8192], 10, 11 ; t8,  t15
409     VP9_UNPACK_MULSUB_2W_4X   3,   4, 10394, 12665, [pd_8192], 10, 11 ; t9,  t14
410     VP9_UNPACK_MULSUB_2W_4X   7,   0, 14449,  7723, [pd_8192], 10, 11 ; t10, t13
411     VP9_UNPACK_MULSUB_2W_4X   1,   6,  4756, 15679, [pd_8192], 10, 11 ; t11, t12
412 %endif
413
414     ; m11=t0, m10=t1, m9=t2, m8=t3, m14=t4, m12=t5, m15=t6, m13=t7
415     ; m5=t8, m3=t9, m7=t10, m1=t11, m6=t12, m0=t13, m4=t14, m2=t15
416
417     SUMSUB_BA            w, 12, 14, 10      ; t4,  t5
418     SUMSUB_BA            w, 15, 13, 10      ; t7,  t6
419     SUMSUB_BA            w,  3,  5, 10      ; t8,  t9
420     SUMSUB_BA            w,  7,  1, 10      ; t11, t10
421     SUMSUB_BA            w,  0,  6, 10      ; t12, t13
422     SUMSUB_BA            w,  4,  2, 10      ; t15, t14
423
424     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m14=t5, m13=t6, m15=t7
425     ; m3=t8, m5=t9, m1=t10, m7=t11, m0=t12, m6=t13, m2=t14, m4=t15
426
427     SUMSUB_BA            w, 14, 13, 10
428     pmulhrsw           m13, [pw_11585x2]                              ; t5
429     pmulhrsw           m14, [pw_11585x2]                              ; t6
430     VP9_UNPACK_MULSUB_2W_4X   2,   5, 15137,  6270, [pd_8192], 10, 11 ; t9,  t14
431     VP9_UNPACK_MULSUB_2W_4X   6,   1, 6270, m15137, [pd_8192], 10, 11 ; t10, t13
432
433     ; m8=t0, m9=t1, m10=t2, m11=t3, m12=t4, m13=t5, m14=t6, m15=t7
434     ; m3=t8, m2=t9, m6=t10, m7=t11, m0=t12, m1=t13, m5=t14, m4=t15
435
436     SUMSUB_BA            w,  7,  3, 10      ; t8,  t11
437     SUMSUB_BA            w,  6,  2, 10      ; t9,  t10
438     SUMSUB_BA            w,  0,  4, 10      ; t15, t12
439     SUMSUB_BA            w,  1,  5, 10      ; t14. t13
440
441     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
442     ; m7=t8, m6=t9, m2=t10, m3=t11, m4=t12, m5=t13, m1=t14, m0=t15
443
444     SUMSUB_BA            w,  2,  5, 10
445     SUMSUB_BA            w,  3,  4, 10
446     pmulhrsw            m5, [pw_11585x2]    ; t10
447     pmulhrsw            m4, [pw_11585x2]    ; t11
448     pmulhrsw            m3, [pw_11585x2]    ; t12
449     pmulhrsw            m2, [pw_11585x2]    ; t13
450
451     ; backup first register
452     mova          [rsp+32], m7
453
454     ; m15=t0, m14=t1, m13=t2, m12=t3, m11=t4, m10=t5, m9=t6, m8=t7
455     ; m7=t8, m6=t9, m5=t10, m4=t11, m3=t12, m2=t13, m1=t14, m0=t15
456
457     ; from load/start
458     mova               m10, [%1+  0]        ; IN(0)
459 %if %3 <= 8
460     pmulhrsw           m10, [pw_11585x2]    ; t0 and t1
461     psubw              m11, m10, m8
462     paddw               m8, m10
463 %else
464     mova               m11, [%1+256]        ; IN(8)
465
466     ; from 3 stages back
467     SUMSUB_BA            w, 11, 10, 7
468     pmulhrsw           m11, [pw_11585x2]    ; t0
469     pmulhrsw           m10, [pw_11585x2]    ; t1
470
471     ; from 2 stages back
472     SUMSUB_BA            w,  8, 11, 7       ; t0,  t3
473 %endif
474     SUMSUB_BA            w,  9, 10, 7       ; t1,  t2
475
476     ; from 1 stage back
477     SUMSUB_BA            w, 15,  8, 7       ; t0,  t7
478     SUMSUB_BA            w, 14,  9, 7       ; t1,  t6
479     SUMSUB_BA            w, 13, 10, 7       ; t2,  t5
480     SUMSUB_BA            w, 12, 11, 7       ; t3,  t4
481
482     SUMSUB_BA            w,  0, 15, 7       ; t0, t15
483     SUMSUB_BA            w,  1, 14, 7       ; t1, t14
484     SUMSUB_BA            w,  2, 13, 7       ; t2, t13
485     SUMSUB_BA            w,  3, 12, 7       ; t3, t12
486     SUMSUB_BA            w,  4, 11, 7       ; t4, t11
487     SUMSUB_BA            w,  5, 10, 7       ; t5, t10
488
489 %if %2 == 1
490     ; backup a different register
491     mova          [rsp+16], m15
492     mova                m7, [rsp+32]
493
494     SUMSUB_BA            w,  6,  9, 15      ; t6, t9
495     SUMSUB_BA            w,  7,  8, 15      ; t7, t8
496
497     TRANSPOSE8x8W        0, 1, 2, 3, 4, 5, 6, 7, 15
498     mova         [rsp+  0], m0
499     mova         [rsp+ 32], m1
500     mova         [rsp+ 64], m2
501     mova         [rsp+ 96], m3
502     mova         [rsp+128], m4
503     mova         [rsp+160], m5
504     mova         [rsp+192], m6
505     mova         [rsp+224], m7
506
507     mova               m15, [rsp+16]
508     TRANSPOSE8x8W        8, 9, 10, 11, 12, 13, 14, 15, 0
509     mova         [rsp+ 16], m8
510     mova         [rsp+ 48], m9
511     mova         [rsp+ 80], m10
512     mova         [rsp+112], m11
513     mova         [rsp+144], m12
514     mova         [rsp+176], m13
515     mova         [rsp+208], m14
516     mova         [rsp+240], m15
517 %else ; %2 == 2
518     ; backup more registers
519     mova          [rsp+64], m8
520     mova          [rsp+96], m9
521
522     pxor                m7, m7
523     pmulhrsw            m0, [pw_512]
524     pmulhrsw            m1, [pw_512]
525     VP9_STORE_2X         0,  1,  8,  9,  7
526     lea               dstq, [dstq+strideq*2]
527     pmulhrsw            m2, [pw_512]
528     pmulhrsw            m3, [pw_512]
529     VP9_STORE_2X         2,  3,  8,  9,  7
530     lea               dstq, [dstq+strideq*2]
531     pmulhrsw            m4, [pw_512]
532     pmulhrsw            m5, [pw_512]
533     VP9_STORE_2X         4,  5,  8,  9,  7
534     lea               dstq, [dstq+strideq*2]
535
536     ; restore from cache
537     SWAP                 0, 7               ; move zero from m7 to m0
538     mova                m7, [rsp+32]
539     mova                m8, [rsp+64]
540     mova                m9, [rsp+96]
541
542     SUMSUB_BA            w,  6,  9, 1       ; t6, t9
543     SUMSUB_BA            w,  7,  8, 1       ; t7, t8
544
545     pmulhrsw            m6, [pw_512]
546     pmulhrsw            m7, [pw_512]
547     VP9_STORE_2X         6,  7,  1,  2,  0
548     lea               dstq, [dstq+strideq*2]
549     pmulhrsw            m8, [pw_512]
550     pmulhrsw            m9, [pw_512]
551     VP9_STORE_2X         8,  9,  1,  2,  0
552     lea               dstq, [dstq+strideq*2]
553     pmulhrsw           m10, [pw_512]
554     pmulhrsw           m11, [pw_512]
555     VP9_STORE_2X        10, 11,  1,  2,  0
556     lea               dstq, [dstq+strideq*2]
557     pmulhrsw           m12, [pw_512]
558     pmulhrsw           m13, [pw_512]
559     VP9_STORE_2X        12, 13,  1,  2,  0
560     lea               dstq, [dstq+strideq*2]
561     pmulhrsw           m14, [pw_512]
562     pmulhrsw           m15, [pw_512]
563     VP9_STORE_2X        14, 15,  1,  2,  0
564 %endif ; %2 == 1/2
565 %endmacro
566
567 %macro ZERO_BLOCK 4 ; mem, stride, nnzcpl, zero_reg
568 %assign %%y 0
569 %rep %3
570 %assign %%x 0
571 %rep %3*2/mmsize
572     mova      [%1+%%y+%%x], %4
573 %assign %%x (%%x+mmsize)
574 %endrep
575 %assign %%y (%%y+%2)
576 %endrep
577 %endmacro
578
579 %macro VP9_STORE_2XFULL 6; dc, tmp1, tmp2, tmp3, tmp4, zero
580     mova               m%3, [dstq]
581     mova               m%5, [dstq+strideq]
582     punpcklbw          m%2, m%3, m%6
583     punpckhbw          m%3, m%6
584     punpcklbw          m%4, m%5, m%6
585     punpckhbw          m%5, m%6
586     paddw              m%2, m%1
587     paddw              m%3, m%1
588     paddw              m%4, m%1
589     paddw              m%5, m%1
590     packuswb           m%2, m%3
591     packuswb           m%4, m%5
592     mova            [dstq], m%2
593     mova    [dstq+strideq], m%4
594 %endmacro
595
596 INIT_XMM ssse3
597 cglobal vp9_idct_idct_16x16_add, 4, 5, 16, 512, dst, stride, block, eob
598     ; 2x2=eob=3, 4x4=eob=10
599     cmp eobd, 38
600     jg .idctfull
601     cmp eobd, 1 ; faster path for when only DC is set
602     jne .idct8x8
603
604     ; dc-only
605     movd                m0, [blockq]
606     mova                m1, [pw_11585x2]
607     pmulhrsw            m0, m1
608     pmulhrsw            m0, m1
609     SPLATW              m0, m0, q0000
610     pmulhrsw            m0, [pw_512]
611     pxor                m5, m5
612     movd          [blockq], m5
613 %rep 7
614     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
615     lea               dstq, [dstq+2*strideq]
616 %endrep
617     VP9_STORE_2XFULL    0, 1, 2, 3, 4, 5
618     RET
619
620 .idct8x8:
621     DEFINE_ARGS dst, stride, block, cnt, dst_bak
622     VP9_IDCT16_1D   blockq, 1, 8
623
624     mov               cntd, 2
625     mov           dst_bakq, dstq
626 .loop2_8x8:
627     VP9_IDCT16_1D      rsp, 2, 8
628     lea               dstq, [dst_bakq+8]
629     add                rsp, 16
630     dec               cntd
631     jg .loop2_8x8
632     sub                rsp, 32
633
634     ; at the end of the loop, m0 should still be zero
635     ; use that to zero out block coefficients
636     ZERO_BLOCK      blockq, 32, 8, m0
637     RET
638
639 .idctfull:
640     DEFINE_ARGS dst, stride, block, cnt, dst_bak
641     mov               cntd, 2
642 .loop1_full:
643     VP9_IDCT16_1D   blockq, 1
644     add             blockq, 16
645     add                rsp, 256
646     dec               cntd
647     jg .loop1_full
648     sub             blockq, 32
649     sub                rsp, 512
650
651     mov               cntd, 2
652     mov           dst_bakq, dstq
653 .loop2_full:
654     VP9_IDCT16_1D      rsp, 2
655     lea               dstq, [dst_bakq+8]
656     add                rsp, 16
657     dec               cntd
658     jg .loop2_full
659     sub                rsp, 32
660
661     ; at the end of the loop, m0 should still be zero
662     ; use that to zero out block coefficients
663     ZERO_BLOCK      blockq, 32, 16, m0
664     RET
665
666 %endif ; x86-64