avcodec/vp9: add ff_vp9_idct_idct_{4x4,8x8}_ssse3().
[ffmpeg.git] / libavcodec / x86 / vp9dsp.asm
1 ;******************************************************************************
2 ;* VP9 SIMD optimizations
3 ;*
4 ;* Copyright (c) 2013 Ronald S. Bultje <rsbultje gmail com>
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %include "libavutil/x86/x86util.asm"
24
25 SECTION_RODATA
26
27 ; FIXME share with vp8dsp.asm
28 pw_256:   times 8 dw 256
29
30 %macro F8_TAPS 8
31 times 8 db %1, %2
32 times 8 db %3, %4
33 times 8 db %5, %6
34 times 8 db %7, %8
35 %endmacro
36 ; int8_t ff_filters_ssse3[3][15][4][16]
37 const filters_ssse3 ; smooth
38                     F8_TAPS -3, -1,  32,  64,  38,   1, -3,  0
39                     F8_TAPS -2, -2,  29,  63,  41,   2, -3,  0
40                     F8_TAPS -2, -2,  26,  63,  43,   4, -4,  0
41                     F8_TAPS -2, -3,  24,  62,  46,   5, -4,  0
42                     F8_TAPS -2, -3,  21,  60,  49,   7, -4,  0
43                     F8_TAPS -1, -4,  18,  59,  51,   9, -4,  0
44                     F8_TAPS -1, -4,  16,  57,  53,  12, -4, -1
45                     F8_TAPS -1, -4,  14,  55,  55,  14, -4, -1
46                     F8_TAPS -1, -4,  12,  53,  57,  16, -4, -1
47                     F8_TAPS  0, -4,   9,  51,  59,  18, -4, -1
48                     F8_TAPS  0, -4,   7,  49,  60,  21, -3, -2
49                     F8_TAPS  0, -4,   5,  46,  62,  24, -3, -2
50                     F8_TAPS  0, -4,   4,  43,  63,  26, -2, -2
51                     F8_TAPS  0, -3,   2,  41,  63,  29, -2, -2
52                     F8_TAPS  0, -3,   1,  38,  64,  32, -1, -3
53                     ; regular
54                     F8_TAPS  0,  1,  -5, 126,   8,  -3,  1,  0
55                     F8_TAPS -1,  3, -10, 122,  18,  -6,  2,  0
56                     F8_TAPS -1,  4, -13, 118,  27,  -9,  3, -1
57                     F8_TAPS -1,  4, -16, 112,  37, -11,  4, -1
58                     F8_TAPS -1,  5, -18, 105,  48, -14,  4, -1
59                     F8_TAPS -1,  5, -19,  97,  58, -16,  5, -1
60                     F8_TAPS -1,  6, -19,  88,  68, -18,  5, -1
61                     F8_TAPS -1,  6, -19,  78,  78, -19,  6, -1
62                     F8_TAPS -1,  5, -18,  68,  88, -19,  6, -1
63                     F8_TAPS -1,  5, -16,  58,  97, -19,  5, -1
64                     F8_TAPS -1,  4, -14,  48, 105, -18,  5, -1
65                     F8_TAPS -1,  4, -11,  37, 112, -16,  4, -1
66                     F8_TAPS -1,  3,  -9,  27, 118, -13,  4, -1
67                     F8_TAPS  0,  2,  -6,  18, 122, -10,  3, -1
68                     F8_TAPS  0,  1,  -3,   8, 126,  -5,  1,  0
69                     ; sharp
70                     F8_TAPS -1,  3,  -7, 127,   8,  -3,  1,  0
71                     F8_TAPS -2,  5, -13, 125,  17,  -6,  3, -1
72                     F8_TAPS -3,  7, -17, 121,  27, -10,  5, -2
73                     F8_TAPS -4,  9, -20, 115,  37, -13,  6, -2
74                     F8_TAPS -4, 10, -23, 108,  48, -16,  8, -3
75                     F8_TAPS -4, 10, -24, 100,  59, -19,  9, -3
76                     F8_TAPS -4, 11, -24,  90,  70, -21, 10, -4
77                     F8_TAPS -4, 11, -23,  80,  80, -23, 11, -4
78                     F8_TAPS -4, 10, -21,  70,  90, -24, 11, -4
79                     F8_TAPS -3,  9, -19,  59, 100, -24, 10, -4
80                     F8_TAPS -3,  8, -16,  48, 108, -23, 10, -4
81                     F8_TAPS -2,  6, -13,  37, 115, -20,  9, -4
82                     F8_TAPS -2,  5, -10,  27, 121, -17,  7, -3
83                     F8_TAPS -1,  3,  -6,  17, 125, -13,  5, -2
84                     F8_TAPS  0,  1,  -3,   8, 127,  -7,  3, -1
85
86 pw_11585x2: times 8 dw 23170
87
88 %macro VP9_IDCT_COEFFS 2
89 pw_m%1_%2: dw -%1, %2, -%1, %2, -%1, %2, -%1, %2
90 pw_%2_%1:  dw  %2, %1,  %2, %1,  %2, %1,  %2, %1
91 %endmacro
92
93 %macro VP9_IDCT_COEFFS_ALL 2
94 pw_%1x2: times 8 dw %1*2
95 pw_%2x2: times 8 dw %2*2
96 VP9_IDCT_COEFFS %1, %2
97 %endmacro
98
99 VP9_IDCT_COEFFS_ALL 15137,  6270
100 VP9_IDCT_COEFFS_ALL 16069,  3196
101 VP9_IDCT_COEFFS      9102, 13623
102
103 pd_8192: times 4 dd 8192
104 pw_2048: times 8 dw 2048
105 pw_1024: times 8 dw 1024
106
107 SECTION .text
108
109 ;
110 ; IDCT helpers
111 ;
112
113 ; (a*x + b*y + round) >> shift
114 %macro VP9_MULSUB_2W_2X 6 ; dst1, dst2, src (unchanged), round, coefs1, coefs2
115     pmaddwd            m%1, m%3, %5
116     pmaddwd            m%2, m%3, %6
117     paddd              m%1, m%4
118     paddd              m%2, m%4
119     psrad              m%1, 14
120     psrad              m%2, 14
121 %endmacro
122
123 %macro VP9_UNPACK_MULSUB_2W_4X 4 ; dst1, dst2, coef1, coef2
124     punpckhwd           m6, m%2, m%1
125     VP9_MULSUB_2W_2X     4, 5,  6, 7, [pw_m%3_%4], [pw_%4_%3]
126     punpcklwd          m%2, m%1
127     VP9_MULSUB_2W_2X    %1, 6, %2, 7, [pw_m%3_%4], [pw_%4_%3]
128     packssdw           m%1, m4
129     packssdw            m6, m5
130     SWAP                %2, 6
131 %endmacro
132
133 %macro VP9_STORE_2X 2
134     movh                m6, [dstq]
135     movh                m7, [dstq+strideq]
136     punpcklbw           m6, m4
137     punpcklbw           m7, m4
138     paddw               m6, %1
139     paddw               m7, %2
140     packuswb            m6, m4
141     packuswb            m7, m4
142     movh            [dstq], m6
143     movh    [dstq+strideq], m7
144 %endmacro
145
146 ;-------------------------------------------------------------------------------------------
147 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
148 ;-------------------------------------------------------------------------------------------
149
150 %macro VP9_IDCT4_1D_FINALIZE 0
151     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
152     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
153     SWAP                 0, 3                               ; 3102 -> 0132
154     SWAP                 3, 2                               ; 0132 -> 0123
155 %endmacro
156
157 %macro VP9_IDCT4_1D 0
158     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
159     mova                m4, [pw_11585x2]
160     pmulhrsw            m2, m4                              ; m2=t0
161     pmulhrsw            m0, m4                              ; m0=t1
162     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270               ; m1=t2, m3=t3
163     VP9_IDCT4_1D_FINALIZE
164 %endmacro
165
166 ; 2x2 top left corner
167 %macro VP9_IDCT4_2x2_1D 0
168     pmulhrsw            m0, m5                              ; m0=t1
169     mova                m2, m0                              ; m2=t0
170     mova                m3, m1
171     pmulhrsw            m1, m6                              ; m1=t2
172     pmulhrsw            m3, m7                              ; m3=t3
173     VP9_IDCT4_1D_FINALIZE
174 %endmacro
175
176 %macro VP9_IDCT4_WRITEOUT 0
177     mova                m5, [pw_2048]
178     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
179     pmulhrsw            m1, m5
180     VP9_STORE_2X        m0, m1
181     lea               dstq, [dstq+2*strideq]
182     pmulhrsw            m2, m5
183     pmulhrsw            m3, m5
184     VP9_STORE_2X        m2, m3
185 %endmacro
186
187 INIT_MMX ssse3
188 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
189
190     cmp eobd, 4 ; 2x2 or smaller
191     jg .idctfull
192
193     cmp eobd, 1 ; faster path for when only DC is set
194     jne .idct2x2
195
196     movd                m0, [blockq]
197     mova                m5, [pw_11585x2]
198     pmulhrsw            m0, m5
199     pmulhrsw            m0, m5
200     pshufw              m0, m0, 0
201     pxor                m4, m4
202     movh          [blockq], m4
203     mova                m5, [pw_2048]
204     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
205     VP9_STORE_2X        m0, m0
206     lea               dstq, [dstq+2*strideq]
207     VP9_STORE_2X        m0, m0
208     RET
209
210 ; faster path for when only top left 2x2 block is set
211 .idct2x2:
212     movd                m0, [blockq+0]
213     movd                m1, [blockq+8]
214     mova                m5, [pw_11585x2]
215     mova                m6, [pw_6270x2]
216     mova                m7, [pw_15137x2]
217     VP9_IDCT4_2x2_1D
218     TRANSPOSE4x4W  0, 1, 2, 3, 4
219     VP9_IDCT4_2x2_1D
220     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
221     movh       [blockq+ 0], m4
222     movh       [blockq+ 8], m4
223     VP9_IDCT4_WRITEOUT
224     RET
225
226 .idctfull: ; generic full 4x4 idct/idct
227     mova                m0, [blockq+ 0]
228     mova                m1, [blockq+ 8]
229     mova                m2, [blockq+16]
230     mova                m3, [blockq+24]
231     mova                m7, [pd_8192]       ; rounding
232     VP9_IDCT4_1D
233     TRANSPOSE4x4W  0, 1, 2, 3, 4
234     VP9_IDCT4_1D
235     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
236     mova       [blockq+ 0], m4
237     mova       [blockq+ 8], m4
238     mova       [blockq+16], m4
239     mova       [blockq+24], m4
240     VP9_IDCT4_WRITEOUT
241     RET
242
243 ;-------------------------------------------------------------------------------------------
244 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
245 ;-------------------------------------------------------------------------------------------
246
247 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use 13 here)
248 %macro VP9_IDCT8_1D_FINALIZE 0
249     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
250     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
251     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
252     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
253     SWAP                11, 10
254     SWAP                 9,  3
255     SWAP                10,  2
256     SWAP                 9,  0
257 %endmacro
258
259 %macro VP9_IDCT8_1D 0
260     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
261     pmulhrsw            m8, m12                             ; m8=t0a
262     pmulhrsw            m0, m12                             ; m0=t1a
263     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270             ; m2=t2a, m10=t3a
264     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196             ; m1=t4a, m11=t7a
265     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623             ; m9=t5a,  m3=t6a
266     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
267     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
268     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
269     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
270     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
271     pmulhrsw            m1, m12                             ; m1=t6
272     pmulhrsw           m11, m12                             ; m11=t5
273     VP9_IDCT8_1D_FINALIZE
274 %endmacro
275
276 ; TODO: a lot of t* copies can probably be removed and merged with
277 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
278 %macro VP9_IDCT8_2x2_1D 0
279     pmulhrsw            m0, m12                             ;  m0=t0
280     mova                m3, m1
281     pmulhrsw            m1, m6                              ;  m1=t4
282     pmulhrsw            m3, m7                              ;  m3=t7
283     mova                m2, m0                              ;  m2=t1
284     mova               m10, m0                              ; m10=t2
285     mova                m8, m0                              ;  m8=t3
286     mova               m11, m3                              ; t5 = t7a ...
287     mova                m9, m3                              ; t6 = t7a ...
288     psubw              m11, m1                              ; t5 = t7a - t4a
289     paddw               m9, m1                              ; t6 = t7a + t4a
290     pmulhrsw           m11, m12                             ; m11=t5
291     pmulhrsw            m9, m12                             ;  m9=t6
292     SWAP                 0, 10
293     SWAP                 9,  1
294     VP9_IDCT8_1D_FINALIZE
295 %endmacro
296
297 %macro VP9_IDCT8_WRITEOUT 0
298     mova                m5, [pw_1024]
299     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
300     pmulhrsw            m1, m5
301     VP9_STORE_2X        m0, m1
302     lea               dstq, [dstq+2*strideq]
303     pmulhrsw            m2, m5
304     pmulhrsw            m3, m5
305     VP9_STORE_2X        m2, m3
306     lea               dstq, [dstq+2*strideq]
307     pmulhrsw            m8, m5
308     pmulhrsw            m9, m5
309     VP9_STORE_2X        m8, m9
310     lea               dstq, [dstq+2*strideq]
311     pmulhrsw           m10, m5
312     pmulhrsw           m11, m5
313     VP9_STORE_2X       m10, m11
314 %endmacro
315
316 INIT_XMM ssse3
317 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
318
319     mova               m12, [pw_11585x2]    ; often used
320
321     cmp eobd, 3 ; top left corner or less
322     jg .idctfull
323
324     cmp eobd, 1 ; faster path for when only DC is set
325     jne .idcttopleftcorner
326
327     movd                m0, [blockq]
328     pmulhrsw            m0, m12
329     pmulhrsw            m0, m12
330     SPLATW              m0, m0, 0
331     pxor                m4, m4
332     movd          [blockq], m4
333     mova                m5, [pw_1024]
334     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
335     VP9_STORE_2X        m0, m0
336     lea               dstq, [dstq+2*strideq]
337     VP9_STORE_2X        m0, m0
338     lea               dstq, [dstq+2*strideq]
339     VP9_STORE_2X        m0, m0
340     lea               dstq, [dstq+2*strideq]
341     VP9_STORE_2X        m0, m0
342     RET
343
344 ; faster path for when only left corner is set (3 input: DC, right to DC, below
345 ; to DC). Note: also working with a 2x2 block
346 .idcttopleftcorner:
347     movd                m0, [blockq+0]
348     movd                m1, [blockq+16]
349     mova                m6, [pw_3196x2]
350     mova                m7, [pw_16069x2]
351     VP9_IDCT8_2x2_1D
352     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
353     VP9_IDCT8_2x2_1D
354     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
355     movd       [blockq+ 0], m4
356     movd       [blockq+16], m4
357     VP9_IDCT8_WRITEOUT
358     RET
359
360 .idctfull: ; generic full 8x8 idct/idct
361     mova                m0, [blockq+  0]    ; IN(0)
362     mova                m1, [blockq+ 16]    ; IN(1)
363     mova                m2, [blockq+ 32]    ; IN(2)
364     mova                m3, [blockq+ 48]    ; IN(3)
365     mova                m8, [blockq+ 64]    ; IN(4)
366     mova                m9, [blockq+ 80]    ; IN(5)
367     mova               m10, [blockq+ 96]    ; IN(6)
368     mova               m11, [blockq+112]    ; IN(7)
369     mova                m7, [pd_8192]       ; rounding
370     VP9_IDCT8_1D
371     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
372     VP9_IDCT8_1D
373     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
374     mova      [blockq+  0], m4
375     mova      [blockq+ 16], m4
376     mova      [blockq+ 32], m4
377     mova      [blockq+ 48], m4
378     mova      [blockq+ 64], m4
379     mova      [blockq+ 80], m4
380     mova      [blockq+ 96], m4
381     mova      [blockq+112], m4
382     VP9_IDCT8_WRITEOUT
383     RET
384 %endif
385
386
387 %macro filter_h_fn 1
388 %assign %%px mmsize/2
389 cglobal %1_8tap_1d_h_ %+ %%px, 6, 6, 11, dst, dstride, src, sstride, h, filtery
390     mova        m6, [pw_256]
391     mova        m7, [filteryq+ 0]
392 %if ARCH_X86_64 && mmsize > 8
393     mova        m8, [filteryq+16]
394     mova        m9, [filteryq+32]
395     mova       m10, [filteryq+48]
396 %endif
397 .loop:
398     movh        m0, [srcq-3]
399     movh        m1, [srcq-2]
400     movh        m2, [srcq-1]
401     movh        m3, [srcq+0]
402     movh        m4, [srcq+1]
403     movh        m5, [srcq+2]
404     punpcklbw   m0, m1
405     punpcklbw   m2, m3
406     movh        m1, [srcq+3]
407     movh        m3, [srcq+4]
408     add       srcq, sstrideq
409     punpcklbw   m4, m5
410     punpcklbw   m1, m3
411     pmaddubsw   m0, m7
412 %if ARCH_X86_64 && mmsize > 8
413     pmaddubsw   m2, m8
414     pmaddubsw   m4, m9
415     pmaddubsw   m1, m10
416 %else
417     pmaddubsw   m2, [filteryq+16]
418     pmaddubsw   m4, [filteryq+32]
419     pmaddubsw   m1, [filteryq+48]
420 %endif
421     paddw       m0, m2
422     paddw       m4, m1
423     paddsw      m0, m4
424     pmulhrsw    m0, m6
425 %ifidn %1, avg
426     movh        m1, [dstq]
427 %endif
428     packuswb    m0, m0
429 %ifidn %1, avg
430     pavgb       m0, m1
431 %endif
432     movh    [dstq], m0
433     add       dstq, dstrideq
434     dec         hd
435     jg .loop
436     RET
437 %endmacro
438
439 INIT_MMX ssse3
440 filter_h_fn put
441 filter_h_fn avg
442
443 INIT_XMM ssse3
444 filter_h_fn put
445 filter_h_fn avg
446
447 %macro filter_v_fn 1
448 %assign %%px mmsize/2
449 %if ARCH_X86_64
450 cglobal %1_8tap_1d_v_ %+ %%px, 6, 8, 11, dst, dstride, src, sstride, h, filtery, src4, sstride3
451 %else
452 cglobal %1_8tap_1d_v_ %+ %%px, 4, 7, 11, dst, dstride, src, sstride, filtery, src4, sstride3
453     mov   filteryq, r5mp
454 %define hd r4mp
455 %endif
456     sub       srcq, sstrideq
457     lea  sstride3q, [sstrideq*3]
458     sub       srcq, sstrideq
459     mova        m6, [pw_256]
460     sub       srcq, sstrideq
461     mova        m7, [filteryq+ 0]
462     lea      src4q, [srcq+sstrideq*4]
463 %if ARCH_X86_64 && mmsize > 8
464     mova        m8, [filteryq+16]
465     mova        m9, [filteryq+32]
466     mova       m10, [filteryq+48]
467 %endif
468 .loop:
469     ; FIXME maybe reuse loads from previous rows, or just
470     ; more generally unroll this to prevent multiple loads of
471     ; the same data?
472     movh        m0, [srcq]
473     movh        m1, [srcq+sstrideq]
474     movh        m2, [srcq+sstrideq*2]
475     movh        m3, [srcq+sstride3q]
476     movh        m4, [src4q]
477     movh        m5, [src4q+sstrideq]
478     punpcklbw   m0, m1
479     punpcklbw   m2, m3
480     movh        m1, [src4q+sstrideq*2]
481     movh        m3, [src4q+sstride3q]
482     add       srcq, sstrideq
483     add      src4q, sstrideq
484     punpcklbw   m4, m5
485     punpcklbw   m1, m3
486     pmaddubsw   m0, m7
487 %if ARCH_X86_64 && mmsize > 8
488     pmaddubsw   m2, m8
489     pmaddubsw   m4, m9
490     pmaddubsw   m1, m10
491 %else
492     pmaddubsw   m2, [filteryq+16]
493     pmaddubsw   m4, [filteryq+32]
494     pmaddubsw   m1, [filteryq+48]
495 %endif
496     paddw       m0, m2
497     paddw       m4, m1
498     paddsw      m0, m4
499     pmulhrsw    m0, m6
500 %ifidn %1, avg
501     movh        m1, [dstq]
502 %endif
503     packuswb    m0, m0
504 %ifidn %1, avg
505     pavgb       m0, m1
506 %endif
507     movh    [dstq], m0
508     add       dstq, dstrideq
509     dec         hd
510     jg .loop
511     RET
512 %endmacro
513
514 INIT_MMX ssse3
515 filter_v_fn put
516 filter_v_fn avg
517
518 INIT_XMM ssse3
519 filter_v_fn put
520 filter_v_fn avg
521
522 %macro fpel_fn 6
523 %if %2 == 4
524 %define %%srcfn movh
525 %define %%dstfn movh
526 %else
527 %define %%srcfn movu
528 %define %%dstfn mova
529 %endif
530
531 %if %2 <= 16
532 cglobal %1%2, 5, 7, 4, dst, dstride, src, sstride, h, dstride3, sstride3
533     lea  sstride3q, [sstrideq*3]
534     lea  dstride3q, [dstrideq*3]
535 %else
536 cglobal %1%2, 5, 5, 4, dst, dstride, src, sstride, h
537 %endif
538 .loop:
539     %%srcfn     m0, [srcq]
540     %%srcfn     m1, [srcq+s%3]
541     %%srcfn     m2, [srcq+s%4]
542     %%srcfn     m3, [srcq+s%5]
543     lea       srcq, [srcq+sstrideq*%6]
544 %ifidn %1, avg
545     pavgb       m0, [dstq]
546     pavgb       m1, [dstq+d%3]
547     pavgb       m2, [dstq+d%4]
548     pavgb       m3, [dstq+d%5]
549 %endif
550     %%dstfn [dstq], m0
551     %%dstfn [dstq+d%3], m1
552     %%dstfn [dstq+d%4], m2
553     %%dstfn [dstq+d%5], m3
554     lea       dstq, [dstq+dstrideq*%6]
555     sub         hd, %6
556     jnz .loop
557     RET
558 %endmacro
559
560 %define d16 16
561 %define s16 16
562 INIT_MMX mmx
563 fpel_fn put, 4,  strideq, strideq*2, stride3q, 4
564 fpel_fn put, 8,  strideq, strideq*2, stride3q, 4
565 INIT_MMX sse
566 fpel_fn avg, 4,  strideq, strideq*2, stride3q, 4
567 fpel_fn avg, 8,  strideq, strideq*2, stride3q, 4
568 INIT_XMM sse
569 fpel_fn put, 16, strideq, strideq*2, stride3q, 4
570 fpel_fn put, 32, mmsize,  strideq,   strideq+mmsize, 2
571 fpel_fn put, 64, mmsize,  mmsize*2,  mmsize*3, 1
572 INIT_XMM sse2
573 fpel_fn avg, 16, strideq, strideq*2, stride3q, 4
574 fpel_fn avg, 32, mmsize,  strideq,   strideq+mmsize, 2
575 fpel_fn avg, 64, mmsize,  mmsize*2,  mmsize*3, 1
576 %undef s16
577 %undef d16