avcodec/x86/vp9dsp: merge a few SWAP together.
[ffmpeg.git] / libavcodec / x86 / vp9dsp.asm
1 ;******************************************************************************
2 ;* VP9 SIMD optimizations
3 ;*
4 ;* Copyright (c) 2013 Ronald S. Bultje <rsbultje gmail com>
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %include "libavutil/x86/x86util.asm"
24
25 SECTION_RODATA
26
27 ; FIXME share with vp8dsp.asm
28 pw_256:   times 8 dw 256
29
30 %macro F8_TAPS 8
31 times 8 db %1, %2
32 times 8 db %3, %4
33 times 8 db %5, %6
34 times 8 db %7, %8
35 %endmacro
36 ; int8_t ff_filters_ssse3[3][15][4][16]
37 const filters_ssse3 ; smooth
38                     F8_TAPS -3, -1,  32,  64,  38,   1, -3,  0
39                     F8_TAPS -2, -2,  29,  63,  41,   2, -3,  0
40                     F8_TAPS -2, -2,  26,  63,  43,   4, -4,  0
41                     F8_TAPS -2, -3,  24,  62,  46,   5, -4,  0
42                     F8_TAPS -2, -3,  21,  60,  49,   7, -4,  0
43                     F8_TAPS -1, -4,  18,  59,  51,   9, -4,  0
44                     F8_TAPS -1, -4,  16,  57,  53,  12, -4, -1
45                     F8_TAPS -1, -4,  14,  55,  55,  14, -4, -1
46                     F8_TAPS -1, -4,  12,  53,  57,  16, -4, -1
47                     F8_TAPS  0, -4,   9,  51,  59,  18, -4, -1
48                     F8_TAPS  0, -4,   7,  49,  60,  21, -3, -2
49                     F8_TAPS  0, -4,   5,  46,  62,  24, -3, -2
50                     F8_TAPS  0, -4,   4,  43,  63,  26, -2, -2
51                     F8_TAPS  0, -3,   2,  41,  63,  29, -2, -2
52                     F8_TAPS  0, -3,   1,  38,  64,  32, -1, -3
53                     ; regular
54                     F8_TAPS  0,  1,  -5, 126,   8,  -3,  1,  0
55                     F8_TAPS -1,  3, -10, 122,  18,  -6,  2,  0
56                     F8_TAPS -1,  4, -13, 118,  27,  -9,  3, -1
57                     F8_TAPS -1,  4, -16, 112,  37, -11,  4, -1
58                     F8_TAPS -1,  5, -18, 105,  48, -14,  4, -1
59                     F8_TAPS -1,  5, -19,  97,  58, -16,  5, -1
60                     F8_TAPS -1,  6, -19,  88,  68, -18,  5, -1
61                     F8_TAPS -1,  6, -19,  78,  78, -19,  6, -1
62                     F8_TAPS -1,  5, -18,  68,  88, -19,  6, -1
63                     F8_TAPS -1,  5, -16,  58,  97, -19,  5, -1
64                     F8_TAPS -1,  4, -14,  48, 105, -18,  5, -1
65                     F8_TAPS -1,  4, -11,  37, 112, -16,  4, -1
66                     F8_TAPS -1,  3,  -9,  27, 118, -13,  4, -1
67                     F8_TAPS  0,  2,  -6,  18, 122, -10,  3, -1
68                     F8_TAPS  0,  1,  -3,   8, 126,  -5,  1,  0
69                     ; sharp
70                     F8_TAPS -1,  3,  -7, 127,   8,  -3,  1,  0
71                     F8_TAPS -2,  5, -13, 125,  17,  -6,  3, -1
72                     F8_TAPS -3,  7, -17, 121,  27, -10,  5, -2
73                     F8_TAPS -4,  9, -20, 115,  37, -13,  6, -2
74                     F8_TAPS -4, 10, -23, 108,  48, -16,  8, -3
75                     F8_TAPS -4, 10, -24, 100,  59, -19,  9, -3
76                     F8_TAPS -4, 11, -24,  90,  70, -21, 10, -4
77                     F8_TAPS -4, 11, -23,  80,  80, -23, 11, -4
78                     F8_TAPS -4, 10, -21,  70,  90, -24, 11, -4
79                     F8_TAPS -3,  9, -19,  59, 100, -24, 10, -4
80                     F8_TAPS -3,  8, -16,  48, 108, -23, 10, -4
81                     F8_TAPS -2,  6, -13,  37, 115, -20,  9, -4
82                     F8_TAPS -2,  5, -10,  27, 121, -17,  7, -3
83                     F8_TAPS -1,  3,  -6,  17, 125, -13,  5, -2
84                     F8_TAPS  0,  1,  -3,   8, 127,  -7,  3, -1
85
86 pw_11585x2: times 8 dw 23170
87
88 %macro VP9_IDCT_COEFFS 2
89 pw_m%1_%2: dw -%1, %2, -%1, %2, -%1, %2, -%1, %2
90 pw_%2_%1:  dw  %2, %1,  %2, %1,  %2, %1,  %2, %1
91 %endmacro
92
93 %macro VP9_IDCT_COEFFS_ALL 2
94 pw_%1x2: times 8 dw %1*2
95 pw_%2x2: times 8 dw %2*2
96 VP9_IDCT_COEFFS %1, %2
97 %endmacro
98
99 VP9_IDCT_COEFFS_ALL 15137,  6270
100 VP9_IDCT_COEFFS_ALL 16069,  3196
101 VP9_IDCT_COEFFS      9102, 13623
102
103 pd_8192: times 4 dd 8192
104 pw_2048: times 8 dw 2048
105 pw_1024: times 8 dw 1024
106
107 SECTION .text
108
109 ;
110 ; IDCT helpers
111 ;
112
113 ; (a*x + b*y + round) >> shift
114 %macro VP9_MULSUB_2W_2X 6 ; dst1, dst2, src (unchanged), round, coefs1, coefs2
115     pmaddwd            m%1, m%3, %5
116     pmaddwd            m%2, m%3, %6
117     paddd              m%1, m%4
118     paddd              m%2, m%4
119     psrad              m%1, 14
120     psrad              m%2, 14
121 %endmacro
122
123 %macro VP9_UNPACK_MULSUB_2W_4X 4 ; dst1, dst2, coef1, coef2
124     punpckhwd           m6, m%2, m%1
125     VP9_MULSUB_2W_2X     4, 5,  6, 7, [pw_m%3_%4], [pw_%4_%3]
126     punpcklwd          m%2, m%1
127     VP9_MULSUB_2W_2X    %1, 6, %2, 7, [pw_m%3_%4], [pw_%4_%3]
128     packssdw           m%1, m4
129     packssdw            m6, m5
130     SWAP                %2, 6
131 %endmacro
132
133 %macro VP9_STORE_2X 2
134     movh                m6, [dstq]
135     movh                m7, [dstq+strideq]
136     punpcklbw           m6, m4
137     punpcklbw           m7, m4
138     paddw               m6, %1
139     paddw               m7, %2
140     packuswb            m6, m4
141     packuswb            m7, m4
142     movh            [dstq], m6
143     movh    [dstq+strideq], m7
144 %endmacro
145
146 ;-------------------------------------------------------------------------------------------
147 ; void vp9_idct_idct_4x4_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
148 ;-------------------------------------------------------------------------------------------
149
150 %macro VP9_IDCT4_1D_FINALIZE 0
151     SUMSUB_BA            w, 3, 2, 4                         ; m3=t3+t0, m2=-t3+t0
152     SUMSUB_BA            w, 1, 0, 4                         ; m1=t2+t1, m0=-t2+t1
153     SWAP                 0, 3, 2                            ; 3102 -> 0123
154 %endmacro
155
156 %macro VP9_IDCT4_1D 0
157     SUMSUB_BA            w, 2, 0, 4                         ; m2=IN(0)+IN(2) m0=IN(0)-IN(2)
158     mova                m4, [pw_11585x2]
159     pmulhrsw            m2, m4                              ; m2=t0
160     pmulhrsw            m0, m4                              ; m0=t1
161     VP9_UNPACK_MULSUB_2W_4X 1, 3, 15137, 6270               ; m1=t2, m3=t3
162     VP9_IDCT4_1D_FINALIZE
163 %endmacro
164
165 ; 2x2 top left corner
166 %macro VP9_IDCT4_2x2_1D 0
167     pmulhrsw            m0, m5                              ; m0=t1
168     mova                m2, m0                              ; m2=t0
169     mova                m3, m1
170     pmulhrsw            m1, m6                              ; m1=t2
171     pmulhrsw            m3, m7                              ; m3=t3
172     VP9_IDCT4_1D_FINALIZE
173 %endmacro
174
175 %macro VP9_IDCT4_WRITEOUT 0
176     mova                m5, [pw_2048]
177     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
178     pmulhrsw            m1, m5
179     VP9_STORE_2X        m0, m1
180     lea               dstq, [dstq+2*strideq]
181     pmulhrsw            m2, m5
182     pmulhrsw            m3, m5
183     VP9_STORE_2X        m2, m3
184 %endmacro
185
186 INIT_MMX ssse3
187 cglobal vp9_idct_idct_4x4_add, 4,4,0, dst, stride, block, eob
188
189     cmp eobd, 4 ; 2x2 or smaller
190     jg .idctfull
191
192     cmp eobd, 1 ; faster path for when only DC is set
193     jne .idct2x2
194
195     movd                m0, [blockq]
196     mova                m5, [pw_11585x2]
197     pmulhrsw            m0, m5
198     pmulhrsw            m0, m5
199     pshufw              m0, m0, 0
200     pxor                m4, m4
201     movh          [blockq], m4
202     mova                m5, [pw_2048]
203     pmulhrsw            m0, m5              ; (x*2048 + (1<<14))>>15 <=> (x+8)>>4
204     VP9_STORE_2X        m0, m0
205     lea               dstq, [dstq+2*strideq]
206     VP9_STORE_2X        m0, m0
207     RET
208
209 ; faster path for when only top left 2x2 block is set
210 .idct2x2:
211     movd                m0, [blockq+0]
212     movd                m1, [blockq+8]
213     mova                m5, [pw_11585x2]
214     mova                m6, [pw_6270x2]
215     mova                m7, [pw_15137x2]
216     VP9_IDCT4_2x2_1D
217     TRANSPOSE4x4W  0, 1, 2, 3, 4
218     VP9_IDCT4_2x2_1D
219     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
220     movh       [blockq+ 0], m4
221     movh       [blockq+ 8], m4
222     VP9_IDCT4_WRITEOUT
223     RET
224
225 .idctfull: ; generic full 4x4 idct/idct
226     mova                m0, [blockq+ 0]
227     mova                m1, [blockq+ 8]
228     mova                m2, [blockq+16]
229     mova                m3, [blockq+24]
230     mova                m7, [pd_8192]       ; rounding
231     VP9_IDCT4_1D
232     TRANSPOSE4x4W  0, 1, 2, 3, 4
233     VP9_IDCT4_1D
234     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
235     mova       [blockq+ 0], m4
236     mova       [blockq+ 8], m4
237     mova       [blockq+16], m4
238     mova       [blockq+24], m4
239     VP9_IDCT4_WRITEOUT
240     RET
241
242 ;-------------------------------------------------------------------------------------------
243 ; void vp9_idct_idct_8x8_add_<opt>(uint8_t *dst, ptrdiff_t stride, int16_t *block, int eob);
244 ;-------------------------------------------------------------------------------------------
245
246 %if ARCH_X86_64 ; TODO: 32-bit? (32-bit limited to 8 xmm reg, we use 13 here)
247 %macro VP9_IDCT8_1D_FINALIZE 0
248     SUMSUB_BA            w,  3, 10, 4                       ;  m3=t0+t7, m10=t0-t7
249     SUMSUB_BA            w,  1,  2, 4                       ;  m1=t1+t6,  m2=t1-t6
250     SUMSUB_BA            w, 11,  0, 4                       ; m11=t2+t5,  m0=t2-t5
251     SUMSUB_BA            w,  9,  8, 4                       ;  m9=t3+t4,  m8=t3-t4
252     SWAP                11, 10, 2
253     SWAP                 3,  9, 0
254 %endmacro
255
256 %macro VP9_IDCT8_1D 0
257     SUMSUB_BA            w, 8, 0, 4                         ; m8=IN(0)+IN(4) m0=IN(0)-IN(4)
258     pmulhrsw            m8, m12                             ; m8=t0a
259     pmulhrsw            m0, m12                             ; m0=t1a
260     VP9_UNPACK_MULSUB_2W_4X 2, 10, 15137,  6270             ; m2=t2a, m10=t3a
261     VP9_UNPACK_MULSUB_2W_4X 1, 11, 16069,  3196             ; m1=t4a, m11=t7a
262     VP9_UNPACK_MULSUB_2W_4X 9,  3,  9102, 13623             ; m9=t5a,  m3=t6a
263     SUMSUB_BA            w, 10,  8, 4                       ; m10=t0a+t3a (t0),  m8=t0a-t3a (t3)
264     SUMSUB_BA            w,  2,  0, 4                       ;  m2=t1a+t2a (t1),  m0=t1a-t2a (t2)
265     SUMSUB_BA            w,  9,  1, 4                       ;  m9=t4a+t5a (t4),  m1=t4a-t5a (t5a)
266     SUMSUB_BA            w,  3, 11, 4                       ;  m3=t7a+t6a (t7), m11=t7a-t6a (t6a)
267     SUMSUB_BA            w,  1, 11, 4                       ;  m1=t6a+t5a (t6), m11=t6a-t5a (t5)
268     pmulhrsw            m1, m12                             ; m1=t6
269     pmulhrsw           m11, m12                             ; m11=t5
270     VP9_IDCT8_1D_FINALIZE
271 %endmacro
272
273 ; TODO: a lot of t* copies can probably be removed and merged with
274 ; following SUMSUBs from VP9_IDCT8_1D_FINALIZE with AVX
275 %macro VP9_IDCT8_2x2_1D 0
276     pmulhrsw            m0, m12                             ;  m0=t0
277     mova                m3, m1
278     pmulhrsw            m1, m6                              ;  m1=t4
279     pmulhrsw            m3, m7                              ;  m3=t7
280     mova                m2, m0                              ;  m2=t1
281     mova               m10, m0                              ; m10=t2
282     mova                m8, m0                              ;  m8=t3
283     mova               m11, m3                              ; t5 = t7a ...
284     mova                m9, m3                              ; t6 = t7a ...
285     psubw              m11, m1                              ; t5 = t7a - t4a
286     paddw               m9, m1                              ; t6 = t7a + t4a
287     pmulhrsw           m11, m12                             ; m11=t5
288     pmulhrsw            m9, m12                             ;  m9=t6
289     SWAP                 0, 10
290     SWAP                 9,  1
291     VP9_IDCT8_1D_FINALIZE
292 %endmacro
293
294 %macro VP9_IDCT8_WRITEOUT 0
295     mova                m5, [pw_1024]
296     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
297     pmulhrsw            m1, m5
298     VP9_STORE_2X        m0, m1
299     lea               dstq, [dstq+2*strideq]
300     pmulhrsw            m2, m5
301     pmulhrsw            m3, m5
302     VP9_STORE_2X        m2, m3
303     lea               dstq, [dstq+2*strideq]
304     pmulhrsw            m8, m5
305     pmulhrsw            m9, m5
306     VP9_STORE_2X        m8, m9
307     lea               dstq, [dstq+2*strideq]
308     pmulhrsw           m10, m5
309     pmulhrsw           m11, m5
310     VP9_STORE_2X       m10, m11
311 %endmacro
312
313 INIT_XMM ssse3
314 cglobal vp9_idct_idct_8x8_add, 4,4,13, dst, stride, block, eob
315
316     mova               m12, [pw_11585x2]    ; often used
317
318     cmp eobd, 3 ; top left corner or less
319     jg .idctfull
320
321     cmp eobd, 1 ; faster path for when only DC is set
322     jne .idcttopleftcorner
323
324     movd                m0, [blockq]
325     pmulhrsw            m0, m12
326     pmulhrsw            m0, m12
327     SPLATW              m0, m0, 0
328     pxor                m4, m4
329     movd          [blockq], m4
330     mova                m5, [pw_1024]
331     pmulhrsw            m0, m5              ; (x*1024 + (1<<14))>>15 <=> (x+16)>>5
332     VP9_STORE_2X        m0, m0
333     lea               dstq, [dstq+2*strideq]
334     VP9_STORE_2X        m0, m0
335     lea               dstq, [dstq+2*strideq]
336     VP9_STORE_2X        m0, m0
337     lea               dstq, [dstq+2*strideq]
338     VP9_STORE_2X        m0, m0
339     RET
340
341 ; faster path for when only left corner is set (3 input: DC, right to DC, below
342 ; to DC). Note: also working with a 2x2 block
343 .idcttopleftcorner:
344     movd                m0, [blockq+0]
345     movd                m1, [blockq+16]
346     mova                m6, [pw_3196x2]
347     mova                m7, [pw_16069x2]
348     VP9_IDCT8_2x2_1D
349     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
350     VP9_IDCT8_2x2_1D
351     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
352     movd       [blockq+ 0], m4
353     movd       [blockq+16], m4
354     VP9_IDCT8_WRITEOUT
355     RET
356
357 .idctfull: ; generic full 8x8 idct/idct
358     mova                m0, [blockq+  0]    ; IN(0)
359     mova                m1, [blockq+ 16]    ; IN(1)
360     mova                m2, [blockq+ 32]    ; IN(2)
361     mova                m3, [blockq+ 48]    ; IN(3)
362     mova                m8, [blockq+ 64]    ; IN(4)
363     mova                m9, [blockq+ 80]    ; IN(5)
364     mova               m10, [blockq+ 96]    ; IN(6)
365     mova               m11, [blockq+112]    ; IN(7)
366     mova                m7, [pd_8192]       ; rounding
367     VP9_IDCT8_1D
368     TRANSPOSE8x8W  0, 1, 2, 3, 8, 9, 10, 11, 4
369     VP9_IDCT8_1D
370     pxor                m4, m4  ; used for the block reset, and VP9_STORE_2X
371     mova      [blockq+  0], m4
372     mova      [blockq+ 16], m4
373     mova      [blockq+ 32], m4
374     mova      [blockq+ 48], m4
375     mova      [blockq+ 64], m4
376     mova      [blockq+ 80], m4
377     mova      [blockq+ 96], m4
378     mova      [blockq+112], m4
379     VP9_IDCT8_WRITEOUT
380     RET
381 %endif
382
383
384 %macro filter_h_fn 1
385 %assign %%px mmsize/2
386 cglobal %1_8tap_1d_h_ %+ %%px, 6, 6, 11, dst, dstride, src, sstride, h, filtery
387     mova        m6, [pw_256]
388     mova        m7, [filteryq+ 0]
389 %if ARCH_X86_64 && mmsize > 8
390     mova        m8, [filteryq+16]
391     mova        m9, [filteryq+32]
392     mova       m10, [filteryq+48]
393 %endif
394 .loop:
395     movh        m0, [srcq-3]
396     movh        m1, [srcq-2]
397     movh        m2, [srcq-1]
398     movh        m3, [srcq+0]
399     movh        m4, [srcq+1]
400     movh        m5, [srcq+2]
401     punpcklbw   m0, m1
402     punpcklbw   m2, m3
403     movh        m1, [srcq+3]
404     movh        m3, [srcq+4]
405     add       srcq, sstrideq
406     punpcklbw   m4, m5
407     punpcklbw   m1, m3
408     pmaddubsw   m0, m7
409 %if ARCH_X86_64 && mmsize > 8
410     pmaddubsw   m2, m8
411     pmaddubsw   m4, m9
412     pmaddubsw   m1, m10
413 %else
414     pmaddubsw   m2, [filteryq+16]
415     pmaddubsw   m4, [filteryq+32]
416     pmaddubsw   m1, [filteryq+48]
417 %endif
418     paddw       m0, m2
419     paddw       m4, m1
420     paddsw      m0, m4
421     pmulhrsw    m0, m6
422 %ifidn %1, avg
423     movh        m1, [dstq]
424 %endif
425     packuswb    m0, m0
426 %ifidn %1, avg
427     pavgb       m0, m1
428 %endif
429     movh    [dstq], m0
430     add       dstq, dstrideq
431     dec         hd
432     jg .loop
433     RET
434 %endmacro
435
436 INIT_MMX ssse3
437 filter_h_fn put
438 filter_h_fn avg
439
440 INIT_XMM ssse3
441 filter_h_fn put
442 filter_h_fn avg
443
444 %macro filter_v_fn 1
445 %assign %%px mmsize/2
446 %if ARCH_X86_64
447 cglobal %1_8tap_1d_v_ %+ %%px, 6, 8, 11, dst, dstride, src, sstride, h, filtery, src4, sstride3
448 %else
449 cglobal %1_8tap_1d_v_ %+ %%px, 4, 7, 11, dst, dstride, src, sstride, filtery, src4, sstride3
450     mov   filteryq, r5mp
451 %define hd r4mp
452 %endif
453     sub       srcq, sstrideq
454     lea  sstride3q, [sstrideq*3]
455     sub       srcq, sstrideq
456     mova        m6, [pw_256]
457     sub       srcq, sstrideq
458     mova        m7, [filteryq+ 0]
459     lea      src4q, [srcq+sstrideq*4]
460 %if ARCH_X86_64 && mmsize > 8
461     mova        m8, [filteryq+16]
462     mova        m9, [filteryq+32]
463     mova       m10, [filteryq+48]
464 %endif
465 .loop:
466     ; FIXME maybe reuse loads from previous rows, or just
467     ; more generally unroll this to prevent multiple loads of
468     ; the same data?
469     movh        m0, [srcq]
470     movh        m1, [srcq+sstrideq]
471     movh        m2, [srcq+sstrideq*2]
472     movh        m3, [srcq+sstride3q]
473     movh        m4, [src4q]
474     movh        m5, [src4q+sstrideq]
475     punpcklbw   m0, m1
476     punpcklbw   m2, m3
477     movh        m1, [src4q+sstrideq*2]
478     movh        m3, [src4q+sstride3q]
479     add       srcq, sstrideq
480     add      src4q, sstrideq
481     punpcklbw   m4, m5
482     punpcklbw   m1, m3
483     pmaddubsw   m0, m7
484 %if ARCH_X86_64 && mmsize > 8
485     pmaddubsw   m2, m8
486     pmaddubsw   m4, m9
487     pmaddubsw   m1, m10
488 %else
489     pmaddubsw   m2, [filteryq+16]
490     pmaddubsw   m4, [filteryq+32]
491     pmaddubsw   m1, [filteryq+48]
492 %endif
493     paddw       m0, m2
494     paddw       m4, m1
495     paddsw      m0, m4
496     pmulhrsw    m0, m6
497 %ifidn %1, avg
498     movh        m1, [dstq]
499 %endif
500     packuswb    m0, m0
501 %ifidn %1, avg
502     pavgb       m0, m1
503 %endif
504     movh    [dstq], m0
505     add       dstq, dstrideq
506     dec         hd
507     jg .loop
508     RET
509 %endmacro
510
511 INIT_MMX ssse3
512 filter_v_fn put
513 filter_v_fn avg
514
515 INIT_XMM ssse3
516 filter_v_fn put
517 filter_v_fn avg
518
519 %macro fpel_fn 6
520 %if %2 == 4
521 %define %%srcfn movh
522 %define %%dstfn movh
523 %else
524 %define %%srcfn movu
525 %define %%dstfn mova
526 %endif
527
528 %if %2 <= 16
529 cglobal %1%2, 5, 7, 4, dst, dstride, src, sstride, h, dstride3, sstride3
530     lea  sstride3q, [sstrideq*3]
531     lea  dstride3q, [dstrideq*3]
532 %else
533 cglobal %1%2, 5, 5, 4, dst, dstride, src, sstride, h
534 %endif
535 .loop:
536     %%srcfn     m0, [srcq]
537     %%srcfn     m1, [srcq+s%3]
538     %%srcfn     m2, [srcq+s%4]
539     %%srcfn     m3, [srcq+s%5]
540     lea       srcq, [srcq+sstrideq*%6]
541 %ifidn %1, avg
542     pavgb       m0, [dstq]
543     pavgb       m1, [dstq+d%3]
544     pavgb       m2, [dstq+d%4]
545     pavgb       m3, [dstq+d%5]
546 %endif
547     %%dstfn [dstq], m0
548     %%dstfn [dstq+d%3], m1
549     %%dstfn [dstq+d%4], m2
550     %%dstfn [dstq+d%5], m3
551     lea       dstq, [dstq+dstrideq*%6]
552     sub         hd, %6
553     jnz .loop
554     RET
555 %endmacro
556
557 %define d16 16
558 %define s16 16
559 INIT_MMX mmx
560 fpel_fn put, 4,  strideq, strideq*2, stride3q, 4
561 fpel_fn put, 8,  strideq, strideq*2, stride3q, 4
562 INIT_MMX sse
563 fpel_fn avg, 4,  strideq, strideq*2, stride3q, 4
564 fpel_fn avg, 8,  strideq, strideq*2, stride3q, 4
565 INIT_XMM sse
566 fpel_fn put, 16, strideq, strideq*2, stride3q, 4
567 fpel_fn put, 32, mmsize,  strideq,   strideq+mmsize, 2
568 fpel_fn put, 64, mmsize,  mmsize*2,  mmsize*3, 1
569 INIT_XMM sse2
570 fpel_fn avg, 16, strideq, strideq*2, stride3q, 4
571 fpel_fn avg, 32, mmsize,  strideq,   strideq+mmsize, 2
572 fpel_fn avg, 64, mmsize,  mmsize*2,  mmsize*3, 1
573 %undef s16
574 %undef d16