probetest: fix possible use of uninitialized data
[ffmpeg.git] / libavcodec / x86 / vp56dsp.asm
1 ;******************************************************************************
2 ;* MMX/SSE2-optimized functions for the VP6 decoder
3 ;* Copyright (C) 2009  Sebastien Lucas <sebastien.lucas@gmail.com>
4 ;* Copyright (C) 2009  Zuxy Meng <zuxy.meng@gmail.com>
5 ;*
6 ;* This file is part of FFmpeg.
7 ;*
8 ;* FFmpeg is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* FFmpeg is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with FFmpeg; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %include "libavutil/x86/x86inc.asm"
24 %include "libavutil/x86/x86util.asm"
25
26 cextern pw_64
27
28 SECTION .text
29
30 %macro DIAG4 6
31 %if mmsize == 8
32     movq          m0, [%1+%2]
33     movq          m1, [%1+%3]
34     movq          m3, m0
35     movq          m4, m1
36     punpcklbw     m0, m7
37     punpcklbw     m1, m7
38     punpckhbw     m3, m7
39     punpckhbw     m4, m7
40     pmullw        m0, [rsp+8*11] ; src[x-8 ] * biweight [0]
41     pmullw        m1, [rsp+8*12] ; src[x   ] * biweight [1]
42     pmullw        m3, [rsp+8*11] ; src[x-8 ] * biweight [0]
43     pmullw        m4, [rsp+8*12] ; src[x   ] * biweight [1]
44     paddw         m0, m1
45     paddw         m3, m4
46     movq          m1, [%1+%4]
47     movq          m2, [%1+%5]
48     movq          m4, m1
49     movq          m5, m2
50     punpcklbw     m1, m7
51     punpcklbw     m2, m7
52     punpckhbw     m4, m7
53     punpckhbw     m5, m7
54     pmullw        m1, [rsp+8*13] ; src[x+8 ] * biweight [2]
55     pmullw        m2, [rsp+8*14] ; src[x+16] * biweight [3]
56     pmullw        m4, [rsp+8*13] ; src[x+8 ] * biweight [2]
57     pmullw        m5, [rsp+8*14] ; src[x+16] * biweight [3]
58     paddw         m1, m2
59     paddw         m4, m5
60     paddsw        m0, m1
61     paddsw        m3, m4
62     paddsw        m0, m6         ; Add 64
63     paddsw        m3, m6         ; Add 64
64     psraw         m0, 7
65     psraw         m3, 7
66     packuswb      m0, m3
67     movq        [%6], m0
68 %else ; mmsize == 16
69     movq          m0, [%1+%2]
70     movq          m1, [%1+%3]
71     punpcklbw     m0, m7
72     punpcklbw     m1, m7
73     pmullw        m0, m4         ; src[x-8 ] * biweight [0]
74     pmullw        m1, m5         ; src[x   ] * biweight [1]
75     paddw         m0, m1
76     movq          m1, [%1+%4]
77     movq          m2, [%1+%5]
78     punpcklbw     m1, m7
79     punpcklbw     m2, m7
80     pmullw        m1, m6         ; src[x+8 ] * biweight [2]
81     pmullw        m2, m3         ; src[x+16] * biweight [3]
82     paddw         m1, m2
83     paddsw        m0, m1
84     paddsw        m0, [pw_64]    ; Add 64
85     psraw         m0, 7
86     packuswb      m0, m0
87     movq        [%6], m0
88 %endif ; mmsize == 8/16
89 %endmacro
90
91 %macro SPLAT4REGS 0
92 %if mmsize == 8
93     movq         m5, m3
94     punpcklwd    m3, m3
95     movq         m4, m3
96     punpckldq    m3, m3
97     punpckhdq    m4, m4
98     punpckhwd    m5, m5
99     movq         m2, m5
100     punpckhdq    m2, m2
101     punpckldq    m5, m5
102     movq [rsp+8*11], m3
103     movq [rsp+8*12], m4
104     movq [rsp+8*13], m5
105     movq [rsp+8*14], m2
106 %else ; mmsize == 16
107     pshuflw      m4, m3, 0x0
108     pshuflw      m5, m3, 0x55
109     pshuflw      m6, m3, 0xAA
110     pshuflw      m3, m3, 0xFF
111     punpcklqdq   m4, m4
112     punpcklqdq   m5, m5
113     punpcklqdq   m6, m6
114     punpcklqdq   m3, m3
115 %endif ; mmsize == 8/16
116 %endmacro
117
118 %macro vp6_filter_diag4 0
119 ; void ff_vp6_filter_diag4_<opt>(uint8_t *dst, uint8_t *src, int stride,
120 ;                                const int16_t h_weight[4], const int16_t v_weights[4])
121 cglobal vp6_filter_diag4, 5, 7, 8
122     mov          r5, rsp         ; backup stack pointer
123     and         rsp, ~(mmsize-1) ; align stack
124 %if mmsize == 16
125     sub         rsp, 8*11
126 %else
127     sub         rsp, 8*15
128     movq         m6, [pw_64]
129 %endif
130 %if ARCH_X86_64
131     movsxd       r2, r2d
132 %endif
133
134     sub          r1, r2
135
136     pxor         m7, m7
137     movq         m3, [r3]
138     SPLAT4REGS
139
140     mov          r3, rsp
141     mov          r6, 11
142 .nextrow:
143     DIAG4        r1, -1, 0, 1, 2, r3
144     add          r3, 8
145     add          r1, r2
146     dec          r6
147     jnz .nextrow
148
149     movq         m3, [r4]
150     SPLAT4REGS
151
152     lea          r3, [rsp+8]
153     mov          r6, 8
154 .nextcol:
155     DIAG4        r3, -8, 0, 8, 16, r0
156     add          r3, 8
157     add          r0, r2
158     dec          r6
159     jnz .nextcol
160
161     mov         rsp, r5          ; restore stack pointer
162     RET
163 %endmacro
164
165 %if ARCH_X86_32
166 INIT_MMX mmx
167 vp6_filter_diag4
168 %endif
169
170 INIT_XMM sse2
171 vp6_filter_diag4