90305dfd44f6af802bef0a7e6533e20a368981c3
[ffmpeg.git] / libavcodec / x86 / v210.asm
1 ;******************************************************************************
2 ;* V210 SIMD unpack
3 ;* Copyright (c) 2011 Loren Merritt <lorenm@u.washington.edu>
4 ;* Copyright (c) 2011 Kieran Kunhya <kieran@kunhya.com>
5 ;*
6 ;* This file is part of Libav.
7 ;*
8 ;* Libav is free software; you can redistribute it and/or
9 ;* modify it under the terms of the GNU Lesser General Public
10 ;* License as published by the Free Software Foundation; either
11 ;* version 2.1 of the License, or (at your option) any later version.
12 ;*
13 ;* Libav is distributed in the hope that it will be useful,
14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 ;* Lesser General Public License for more details.
17 ;*
18 ;* You should have received a copy of the GNU Lesser General Public
19 ;* License along with Libav; if not, write to the Free Software
20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
21 ;******************************************************************************
22
23 %include "libavutil/x86/x86inc.asm"
24 %include "libavutil/x86/x86util.asm"
25
26 SECTION_RODATA
27
28 v210_mask: times 4 dd 0x3ff
29 v210_mult: dw 64,4,64,4,64,4,64,4
30 v210_luma_shuf: db 8,9,0,1,2,3,12,13,4,5,6,7,-1,-1,-1,-1
31 v210_chroma_shuf: db 0,1,8,9,6,7,-1,-1,2,3,4,5,12,13,-1,-1
32
33 SECTION .text
34
35 %macro v210_planar_unpack 2
36
37 ; v210_planar_unpack(const uint32_t *src, uint16_t *y, uint16_t *u, uint16_t *v, int width)
38 cglobal v210_planar_unpack_%1_%2, 5, 5, 7
39     movsxdifnidn r4, r4d
40     lea    r1, [r1+2*r4]
41     add    r2, r4
42     add    r3, r4
43     neg    r4
44
45     mova   m3, [v210_mult]
46     mova   m4, [v210_mask]
47     mova   m5, [v210_luma_shuf]
48     mova   m6, [v210_chroma_shuf]
49 .loop
50 %ifidn %1, unaligned
51     movu   m0, [r0]
52 %else
53     mova   m0, [r0]
54 %endif
55
56     pmullw m1, m0, m3
57     psrld  m0, 10
58     psrlw  m1, 6  ; u0 v0 y1 y2 v1 u2 y4 y5
59     pand   m0, m4 ; y0 __ u1 __ y3 __ v2 __
60
61     shufps m2, m1, m0, 0x8d ; y1 y2 y4 y5 y0 __ y3 __
62     pshufb m2, m5 ; y0 y1 y2 y3 y4 y5 __ __
63     movu   [r1+2*r4], m2
64
65     shufps m1, m0, 0xd8 ; u0 v0 v1 u2 u1 __ v2 __
66     pshufb m1, m6 ; u0 u1 u2 __ v0 v1 v2 __
67     movq   [r2+r4], m1
68     movhps [r3+r4], m1
69
70     add r0, mmsize
71     add r4, 6
72     jl  .loop
73
74     REP_RET
75 %endmacro
76
77 INIT_XMM
78 v210_planar_unpack unaligned, ssse3
79 %if HAVE_AVX_EXTERNAL
80 INIT_AVX
81 v210_planar_unpack unaligned, avx
82 %endif
83
84 INIT_XMM
85 v210_planar_unpack aligned, ssse3
86 %if HAVE_AVX_EXTERNAL
87 INIT_AVX
88 v210_planar_unpack aligned, avx
89 %endif