Merge commit '5dfe4edad63971d669ae456b0bc40ef9364cca80'
[ffmpeg.git] / libavcodec / x86 / fmtconvert.asm
1 ;******************************************************************************
2 ;* x86 optimized Format Conversion Utils
3 ;* Copyright (c) 2008 Loren Merritt
4 ;*
5 ;* This file is part of FFmpeg.
6 ;*
7 ;* FFmpeg is free software; you can redistribute it and/or
8 ;* modify it under the terms of the GNU Lesser General Public
9 ;* License as published by the Free Software Foundation; either
10 ;* version 2.1 of the License, or (at your option) any later version.
11 ;*
12 ;* FFmpeg is distributed in the hope that it will be useful,
13 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 ;* Lesser General Public License for more details.
16 ;*
17 ;* You should have received a copy of the GNU Lesser General Public
18 ;* License along with FFmpeg; if not, write to the Free Software
19 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
20 ;******************************************************************************
21
22 %include "libavutil/x86/x86util.asm"
23
24 SECTION .text
25
26 ;------------------------------------------------------------------------------
27 ; void ff_int32_to_float_fmul_scalar(float *dst, const int32_t *src, float mul,
28 ;                                    int len);
29 ;------------------------------------------------------------------------------
30 %macro INT32_TO_FLOAT_FMUL_SCALAR 1
31 %if UNIX64
32 cglobal int32_to_float_fmul_scalar, 3, 3, %1, dst, src, len
33 %else
34 cglobal int32_to_float_fmul_scalar, 4, 4, %1, dst, src, mul, len
35 %endif
36 %if WIN64
37     SWAP 0, 2
38 %elif ARCH_X86_32
39     movss   m0, mulm
40 %endif
41 %if ARCH_X86_64
42     movsxd  lenq, lend
43 %endif
44     SPLATD  m0
45     shl     lenq, 2
46     add     srcq, lenq
47     add     dstq, lenq
48     neg     lenq
49 .loop:
50 %if cpuflag(sse2)
51     cvtdq2ps  m1, [srcq+lenq   ]
52     cvtdq2ps  m2, [srcq+lenq+16]
53 %else
54     cvtpi2ps  m1, [srcq+lenq   ]
55     cvtpi2ps  m3, [srcq+lenq+ 8]
56     cvtpi2ps  m2, [srcq+lenq+16]
57     cvtpi2ps  m4, [srcq+lenq+24]
58     movlhps   m1, m3
59     movlhps   m2, m4
60 %endif
61     mulps     m1, m0
62     mulps     m2, m0
63     mova  [dstq+lenq   ], m1
64     mova  [dstq+lenq+16], m2
65     add     lenq, 32
66     jl .loop
67     REP_RET
68 %endmacro
69
70 INIT_XMM sse
71 INT32_TO_FLOAT_FMUL_SCALAR 5
72 INIT_XMM sse2
73 INT32_TO_FLOAT_FMUL_SCALAR 3
74
75 ;------------------------------------------------------------------------------
76 ; void ff_int32_to_float_fmul_array8(FmtConvertContext *c, float *dst, const int32_t *src,
77 ;                                    const float *mul, int len);
78 ;------------------------------------------------------------------------------
79 %macro INT32_TO_FLOAT_FMUL_ARRAY8 0
80 cglobal int32_to_float_fmul_array8, 5, 5, 5, c, dst, src, mul, len
81     shl     lend, 2
82     add     srcq, lenq
83     add     dstq, lenq
84     neg     lenq
85 .loop:
86     movss     m0, [mulq]
87     SPLATD    m0
88 %if cpuflag(sse2)
89     cvtdq2ps  m1, [srcq+lenq   ]
90     cvtdq2ps  m2, [srcq+lenq+16]
91 %else
92     cvtpi2ps  m1, [srcq+lenq   ]
93     cvtpi2ps  m3, [srcq+lenq+ 8]
94     cvtpi2ps  m2, [srcq+lenq+16]
95     cvtpi2ps  m4, [srcq+lenq+24]
96     movlhps   m1, m3
97     movlhps   m2, m4
98 %endif
99     mulps     m1, m0
100     mulps     m2, m0
101     mova  [dstq+lenq   ], m1
102     mova  [dstq+lenq+16], m2
103     add     mulq, 4
104     add     lenq, 32
105     jl .loop
106     REP_RET
107 %endmacro
108
109 INIT_XMM sse
110 INT32_TO_FLOAT_FMUL_ARRAY8
111 INIT_XMM sse2
112 INT32_TO_FLOAT_FMUL_ARRAY8
113