dv: Don't return EIO upon EOF
[ffmpeg.git] / libavcodec / arm / dcadsp_neon.S
1 /*
2  * Copyright (c) 2010 Mans Rullgard <mans@mansr.com>
3  *
4  * This file is part of Libav.
5  *
6  * Libav is free software; you can redistribute it and/or
7  * modify it under the terms of the GNU Lesser General Public
8  * License as published by the Free Software Foundation; either
9  * version 2.1 of the License, or (at your option) any later version.
10  *
11  * Libav is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14  * Lesser General Public License for more details.
15  *
16  * You should have received a copy of the GNU Lesser General Public
17  * License along with Libav; if not, write to the Free Software
18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
19  */
20
21 #include "libavutil/arm/asm.S"
22
23 function ff_dca_lfe_fir0_neon, export=1
24         push            {r4-r6,lr}
25         mov             r3,  #32                @ decifactor
26         mov             r6,  #256/32
27         b               dca_lfe_fir
28 endfunc
29
30 function ff_dca_lfe_fir1_neon, export=1
31         push            {r4-r6,lr}
32         mov             r3,  #64                @ decifactor
33         mov             r6,  #256/64
34 dca_lfe_fir:
35         add             r4,  r0,  r3,  lsl #2   @ out2
36         add             r5,  r2,  #256*4-16     @ cf1
37         sub             r1,  r1,  #12
38         mov             lr,  #-16
39 1:
40         vmov.f32        q2,  #0.0               @ v0
41         vmov.f32        q3,  #0.0               @ v1
42         mov             r12, r6
43 2:
44         vld1.32         {q8},     [r2,:128]!    @ cf0
45         vld1.32         {q9},     [r5,:128], lr @ cf1
46         vld1.32         {q1},     [r1], lr      @ in
47         subs            r12, r12, #4
48         vrev64.32       q10, q8
49         vmla.f32        q3,  q1,  q9
50         vmla.f32        d4,  d2,  d21
51         vmla.f32        d5,  d3,  d20
52         bne             2b
53
54         add             r1,  r1,  r6,  lsl #2
55         subs            r3,  r3,  #1
56         vadd.f32        d4,  d4,  d5
57         vadd.f32        d6,  d6,  d7
58         vpadd.f32       d5,  d4,  d6
59         vst1.32         {d5[0]},  [r0,:32]!
60         vst1.32         {d5[1]},  [r4,:32]!
61         bne             1b
62
63         pop             {r4-r6,pc}
64 endfunc